config.bat

   1 @echo off
   2 rem   ----------------------------------------------------------------------
   3 rem   Configuration script for MSDOS
   4 rem   Copyright (C) 1994-1999, 2001-2014 Free Software Foundation, Inc.
   5
   6 rem   This file is part of GNU Emacs.
   7
   8 rem   GNU Emacs is free software: you can redistribute it and/or modify
   9 rem   it under the terms of the GNU General Public License as published by
  10 rem   the Free Software Foundation, either version 3 of the License, or
  11 rem   (at your option) any later version.
  12
  13 rem   GNU Emacs is distributed in the hope that it will be useful,
  14 rem   but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 rem   GNU General Public License for more details.
  17
  18 rem   You should have received a copy of the GNU General Public License
  19 rem   along with GNU Emacs.  If not, see http://www.gnu.org/licenses/.
  20
  21 rem   ----------------------------------------------------------------------
  22 rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:
  23 rem
  24 rem   + msdos version 3 or better.
  25 rem   + DJGPP version 2.0 or later (version 2.03 or later recommended).
  26 rem   + make utility that allows breaking of the 128 chars limit on
  27 rem     command lines.  ndmake (as of version 4.5) won't work due to a
  28 rem     line length limit.  The make that comes with DJGPP does work (and is
  29 rem     recommended).
  30 rem   + rm, mv, and cp (from GNU file utilities).
  31 rem   + sed (you can use the port that comes with DJGPP).
  32 rem
  33 rem   You should be able to get all the above utilities from the DJGPP FTP
  34 rem   site, ftp.delorie.com, in the directory "pub/djgpp/current/v2gnu".
  35 rem   ----------------------------------------------------------------------
  36 set X11=
  37 set nodebug=
  38 set djgpp_ver=
  39 set sys_malloc=
  40 set libxml=
  41 if "%1" == "" goto usage
  42 rem   ----------------------------------------------------------------------
  43 rem   See if their environment is large enough.  We need 28 bytes.
  44 set $foo$=789012345678901234567
  45 if not "%$foo$%" == "789012345678901234567" goto SmallEnv
  46 set $foo$=
  47 :again
  48 if "%1" == "" goto usage
  49 if "%1" == "--with-x" goto withx
  50 if "%1" == "--no-debug" goto nodebug
  51 if "%1" == "msdos" goto msdos
  52 if "%1" == "--with-system-malloc" goto sysmalloc
  53 :usage
  54 echo Usage: config [--no-debug] [--with-system-malloc] [--with-x] msdos
  55 echo [Read the script before you run it.]
  56 goto end
  57 rem   ----------------------------------------------------------------------
  58 :withx
  59 set X11=Y
  60 shift
  61 goto again
  62 rem   ----------------------------------------------------------------------
  63 :nodebug
  64 set nodebug=Y
  65 shift
  66 goto again
  67 rem   ----------------------------------------------------------------------
  68 :sysmalloc
  69 set sys_malloc=Y
  70 shift
  71 goto again
  72 rem   ----------------------------------------------------------------------
  73 :msdos
  74 Echo Checking whether 'sed' is available...
  75 sed -e "w junk.$$$" <Nul
  76 If Exist junk.$$$ Goto sedOk
  77 Echo To configure 'Emacs' you need to have 'sed'!
  78 Goto End
  79 :sedOk
  80 Echo Checking whether 'rm' is available...
  81 rm -f junk.$$$
  82 If Not Exist junk.$$$ Goto rmOk
  83 Echo To configure 'Emacs' you need to have 'rm'!
  84 Goto End
  85 :rmOk
  86 Echo Checking whether 'mv' is available...
  87 rm -f junk.1 junk.2
  88 echo foo >junk.1
  89 mv junk.1 ./junk.2
  90 If Exist junk.2 Goto mvOk
  91 Echo To configure 'Emacs' you need to have 'mv'!
  92 rm -f junk.1
  93 Goto End
  94 :mvOk
  95 rm -f junk.2
  96 Echo Checking whether 'gcc' is available...
  97 echo main(){} >junk.c
  98 gcc -c junk.c
  99 if exist junk.o goto gccOk
 100 Echo To configure 'Emacs' you need to have 'gcc'!
 101 rm -f junk.c
 102 Goto End
 103 :gccOk
 104 rm -f junk.c junk.o junk junk.exe
 105 Echo Checking what version of DJGPP is installed...
 106 If Not "%DJGPP%" == "" goto djgppOk
 107 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 108 Goto End
 109 :djgppOk
 110 echo int main()           >junk.c
 111 echo #ifdef __DJGPP__    >>junk.c
 112 echo {return (__DJGPP__)*10;} >>junk.c
 113 echo #else               >>junk.c
 114 echo #ifdef __GO32__     >>junk.c
 115 echo {return 10;}         >>junk.c
 116 echo #else               >>junk.c
 117 echo {return 0;}         >>junk.c
 118 echo #endif              >>junk.c
 119 echo #endif              >>junk.c
 120 gcc -o junk junk.c
 121 if not exist junk.exe coff2exe junk
 122 junk
 123 If ErrorLevel 10 Goto go32Ok
 124 rm -f junk.c junk junk.exe
 125 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 126 Goto End
 127 :go32Ok
 128 set djgpp_ver=2
 129 If Not ErrorLevel 20 Echo To build 'Emacs' you need DJGPP v2.0 or later!
 130 If Not ErrorLevel 20 Goto End
 131 rm -f junk.c junk junk.exe
 132 rem DJECHO is used by the top-level Makefile in the v2.x build
 133 Echo Checking whether 'djecho' is available...
 134 redir -o Nul -eo djecho -o junk.$$$ foo
 135 If Exist junk.$$$ Goto djechoOk
 136 Echo To build 'Emacs' you need the 'djecho.exe' program!
 137 Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.
 138 Echo Versions of DJGPP before 2.02 called this program 'echo.exe'.
 139 Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,
 140 Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.
 141 Echo Then run CONFIG.BAT again with the same arguments you did now.
 142 Goto End
 143 :djechoOk
 144 rm -f junk.$$$
 145 Echo Configuring for DJGPP Version %DJGPP_VER% ...
 146 Rem   ----------------------------------------------------------------------
 147 Echo Configuring the source directory...
 148 cd src
 149
 150 rem   Create "epaths.h"
 151 sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp
 152 update epaths.tmp epaths.h >nul
 153 rm -f epaths.tmp
 154
 155 rem   Create "config.h"
 156 rm -f config.h2 config.tmp
 157 if exist config.in sed -e '' config.in > config.tmp
 158 if exist ..\msdos\autogen\config.in sed -e '' ../msdos/autogen/config.in > config.tmp
 159 if "%X11%" == "" goto src4
 160 if exist config.in sed -f ../msdos/sed2x.inp < config.in > config.tmp
 161 if exist ..\msdos\autogen\config.in sed -f ../msdos/sed2x.inp < ..\msdos\autogen\config.in > config.tmp
 162 :src4
 163 sed -f ../msdos/sed2v2.inp <config.tmp >config.h2
 164 Rem See if they have libxml2 later than v2.2.0 installed
 165 Echo Checking whether libxml2 v2.2.1 or later is installed ...
 166 rm -f junk.c junk.o junk junk.exe
 167 rem Use djecho here because we need to quote brackets
 168 djecho "#include <libxml/xmlversion.h>"             >junk.c
 169 djecho "int main()"                                 >>junk.c
 170 djecho "{return (LIBXML_VERSION > 20200 ? 0 : 1);}" >>junk.c
 171 redir -o Nul -eo gcc -I/dev/env/DJDIR/include/libxml2 -o junk junk.c
 172 if not exist junk Goto xmlDone
 173 if not exist junk.exe coff2exe junk
 174 junk
 175 If ErrorLevel 1 Goto xmlDone
 176 Echo Configuring with libxml2 ...
 177 sed -e "/#undef HAVE_LIBXML2/s/^.*$/#define HAVE_LIBXML2 1/" <config.h2 >config.h3
 178 mv config.h3 config.h2
 179 set libxml=1
 180 :xmlDone
 181 rm -f junk.c junk junk.exe
 182 Rem See if they requested a SYSTEM_MALLOC build
 183 if "%sys_malloc%" == "" Goto cfgDone
 184 rm -f config.tmp
 185 ren config.h2 config.tmp
 186 sed -f ../msdos/sedalloc.inp <config.tmp >config.h2
 187
 188 :cfgDone
 189 rm -f junk.c junk junk.exe
 190 update config.h2 config.h >nul
 191 rm -f config.tmp config.h2
 192
 193 rem   On my system dir.h gets in the way.  It's a VMS file so who cares.
 194 if exist dir.h ren dir.h vmsdir.h
 195
 196 rem   Create "makefile" from "makefile.in".
 197 rm -f Makefile makefile.tmp
 198 copy Makefile.in+lisp.mk+deps.mk makefile.tmp
 199 sed -f ../msdos/sed1v2.inp <makefile.tmp >Makefile
 200 rm -f makefile.tmp
 201
 202 if "%X11%" == "" goto src5
 203 mv Makefile makefile.tmp
 204 sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile
 205 rm -f makefile.tmp
 206 :src5
 207
 208 if "%sys_malloc%" == "" goto src5a
 209 sed -e "/^GMALLOC_OBJ *=/s/gmalloc.o//" <Makefile >makefile.tmp
 210 sed -e "/^VMLIMIT_OBJ *=/s/vm-limit.o//" <makefile.tmp >makefile.tmp2
 211 sed -e "/^RALLOC_OBJ *=/s/ralloc.o//" <makefile.tmp2 >Makefile
 212 rm -f makefile.tmp makefile.tmp2
 213 :src5a
 214
 215 if "%nodebug%" == "" goto src6
 216 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 217 sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile
 218 rm -f makefile.tmp
 219 :src6
 220
 221 if "%libxml%" == "" goto src7
 222 sed -e "/^LIBXML2_LIBS *=/s/=/= -lxml2 -lz -liconv/" <Makefile >makefile.tmp
 223 sed -e "/^LIBXML2_CFLAGS *=/s|=|= -I/dev/env/DJDIR/include/libxml2|" <makefile.tmp >Makefile
 224 rm -f makefile.tmp
 225 :src7
 226 cd ..
 227 rem   ----------------------------------------------------------------------
 228 Echo Configuring the library source directory...
 229 cd lib-src
 230 sed -f ../msdos/sed3v2.inp <Makefile.in >Makefile
 231 if "%X11%" == "" goto libsrc2a
 232 mv Makefile makefile.tmp
 233 sed -f ../msdos/sed3x.inp <makefile.tmp >Makefile
 234 rm -f makefile.tmp
 235 :libsrc2a
 236 if "%nodebug%" == "" goto libsrc3
 237 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 238 sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile
 239 rm -f makefile.tmp
 240 :libsrc3
 241 cd ..
 242 rem   ----------------------------------------------------------------------
 243 if "%X11%" == "" goto oldx1
 244 Echo Configuring the oldxmenu directory...
 245 cd oldxmenu
 246 sed -f ../msdos/sed5x.inp <Makefile.in >Makefile
 247 if "%nodebug%" == "" goto oldx2
 248 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 249 mv -f makefile.tmp Makefile
 250 :oldx2
 251 cd ..
 252 :oldx1
 253 rem   ----------------------------------------------------------------------
 254 Echo Configuring the doc directory, expect one "File not found" message...
 255 cd doc
 256 Rem The two variants for lispintro below is for when the shell
 257 Rem supports long file names but DJGPP does not
 258 for %%d in (emacs lispref lispintro lispintr misc) do sed -f ../msdos/sed6.inp < %%d\Makefile.in > %%d\Makefile
 259 cd ..
 260 rem   ----------------------------------------------------------------------
 261 Echo Configuring the lib directory...
 262 If Exist build-aux\snippet\c++defs.h update build-aux/snippet/c++defs.h build-aux/snippet/cxxdefs.h
 263 cd lib
 264 Rem Rename files like djtar on plain DOS filesystem would.
 265 If Exist build-aux\snippet\c++defs.h update build-aux/snippet/c++defs.h build-aux/snippet/cxxdefs.h
 266 If Exist alloca.in.h update alloca.in.h alloca.in-h
 267 If Exist byteswap.in.h update byteswap.in.h byteswap.in-h
 268 If Exist dirent.in.h update dirent.in.h dirent.in-h
 269 If Exist errno.in.h update errno.in.h errno.in-h
 270 If Exist execinfo.in.h update execinfo.in.h execinfo.in-h
 271 If Exist fcntl.in.h update fcntl.in.h fcntl.in-h
 272 If Exist getopt.in.h update getopt.in.h getopt.in-h
 273 If Exist inttypes.in.h update inttypes.in.h inttypes.in-h
 274 If Exist stdarg.in.h update stdarg.in.h stdarg.in-h
 275 If Exist stdalign.in.h update stdalign.in.h stdalign.in-h
 276 If Exist stdbool.in.h update stdbool.in.h stdbool.in-h
 277 If Exist signal.in.h update signal.in.h signal.in-h
 278 If Exist stdalign.in.h update stdalign.in.h  stdalign.in-h
 279 If Exist stddef.in.h update stddef.in.h  stddef.in-h
 280 If Exist stdint.in.h update stdint.in.h  stdint.in-h
 281 If Exist stdio.in.h update stdio.in.h stdio.in-h
 282 If Exist stdlib.in.h update stdlib.in.h stdlib.in-h
 283 If Exist string.in.h update string.in.h string.in-h
 284 If Exist sys_select.in.h update sys_select.in.h sys_select.in-h
 285 If Exist sys_stat.in.h update sys_stat.in.h sys_stat.in-h
 286 If Exist sys_types.in.h update sys_types.in.h sys_types.in-h
 287 If Exist sys_time.in.h update sys_time.in.h sys_time.in-h
 288 If Exist time.in.h update time.in.h time.in-h
 289 If Exist unistd.in.h update unistd.in.h unistd.in-h
 290 If Exist Makefile.in sed -f ../msdos/sedlibcf.inp < Makefile.in > makefile.tmp
 291 If Exist ..\msdos\autogen\Makefile.in sed -f ../msdos/sedlibcf.inp < ..\msdos\autogen\Makefile.in > makefile.tmp
 292 sed -f ../msdos/sedlibmk.inp < makefile.tmp > Makefile
 293 rm -f makefile.tmp
 294 Rem Create .Po files for new files in lib/
 295 If Not Exist deps\stamp mkdir deps
 296 for %%f in (*.c) do @call ..\msdos\depfiles.bat %%f
 297 echo deps-stamp > deps\stamp
 298 cd ..
 299 rem   ----------------------------------------------------------------------
 300 Echo Configuring the lisp directory...
 301 cd lisp
 302 If Exist gnus\.dir-locals.el update gnus/.dir-locals.el gnus/_dir-locals.el
 303 sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile
 304 cd ..
 305 rem   ----------------------------------------------------------------------
 306 Echo Configuring the leim directory...
 307 cd leim
 308 sed -f ../msdos/sedleim.inp < Makefile.in > Makefile
 309 cd ..
 310 rem   ----------------------------------------------------------------------
 311 If Not Exist admin\unidata goto noadmin
 312 Echo Configuring the admin/unidata directory...
 313 cd admin\unidata
 314 sed -f ../../msdos/sedadmin.inp < Makefile.in > Makefile
 315 cd ..\..
 316 :noadmin
 317 rem   ----------------------------------------------------------------------
 318 Echo Configuring the main directory...
 319 If Exist .dir-locals.el update .dir-locals.el _dir-locals.el
 320 If Exist src\.dbxinit update src/.dbxinit src/_dbxinit
 321 Echo Looking for the GDB init file...
 322 If Exist src\.gdbinit update src/.gdbinit src/_gdbinit
 323 If Exist src\_gdbinit goto gdbinitOk
 324 Echo ERROR:
 325 Echo I cannot find the GDB init file.  It was called ".gdbinit" in
 326 Echo the Emacs distribution, but was probably renamed to some other
 327 Echo name without the leading dot when you untarred the archive.
 328 Echo It should be in the "src/" subdirectory.  Please make sure this
 329 Echo file exists and is called "_gdbinit" with a leading underscore.
 330 Echo Then run CONFIG.BAT again with the same arguments you did now.
 331 goto End
 332 :gdbinitOk
 333 Echo Looking for the GDB init file...found
 334 rem GNUMakefile is not appropriate for MS-DOS so move it out of the way
 335 If Exist GNUmakefile mv -f GNUmakefile GNUmakefile.unix
 336 copy msdos\mainmake.v2 Makefile >nul
 337 rem   ----------------------------------------------------------------------
 338 goto End
 339 :SmallEnv
 340 echo Your environment size is too small.  Please enlarge it and run me again.
 341 echo For example, type "command.com /e:2048" to have 2048 bytes available.
 342 set $foo$=
 343 :end
 344 set X11=
 345 set nodebug=
 346 set djgpp_ver=
 347 set sys_malloc=
 348 set libxml=