config.bat

   1 @echo off
   2 rem   ----------------------------------------------------------------------
   3 rem   Configuration script for MSDOS
   4 rem   Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003
   5 rem   2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011  Free Software Foundation,
   6 rem   Inc.
   7
   8 rem   This file is part of GNU Emacs.
   9
  10 rem   GNU Emacs is free software: you can redistribute it and/or modify
  11 rem   it under the terms of the GNU General Public License as published by
  12 rem   the Free Software Foundation, either version 3 of the License, or
  13 rem   (at your option) any later version.
  14
  15 rem   GNU Emacs is distributed in the hope that it will be useful,
  16 rem   but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 rem   GNU General Public License for more details.
  19
  20 rem   You should have received a copy of the GNU General Public License
  21 rem   along with GNU Emacs.  If not, see http://www.gnu.org/licenses/.
  22
  23 rem   ----------------------------------------------------------------------
  24 rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:
  25 rem
  26 rem   + msdos version 3 or better.
  27 rem   + DJGPP version 2.0 or later (version 2.03 or later recommended).
  28 rem   + make utility that allows breaking of the 128 chars limit on
  29 rem     command lines.  ndmake (as of version 4.5) won't work due to a
  30 rem     line length limit.  The make that comes with DJGPP does work (and is
  31 rem     recommended).
  32 rem   + rm, mv, and cp (from GNU file utilities).
  33 rem   + sed (you can use the port that comes with DJGPP).
  34 rem
  35 rem   You should be able to get all the above utilities from the DJGPP FTP
  36 rem   site, ftp.delorie.com, in the directory "pub/djgpp/current/v2gnu".
  37 rem   ----------------------------------------------------------------------
  38 set X11=
  39 set nodebug=
  40 set djgpp_ver=
  41 set sys_malloc=
  42 set libxml=
  43 if "%1" == "" goto usage
  44 rem   ----------------------------------------------------------------------
  45 rem   See if their environment is large enough.  We need 28 bytes.
  46 set $foo$=789012345678901234567
  47 if not "%$foo$%" == "789012345678901234567" goto SmallEnv
  48 set $foo$=
  49 :again
  50 if "%1" == "" goto usage
  51 if "%1" == "--with-x" goto withx
  52 if "%1" == "--no-debug" goto nodebug
  53 if "%1" == "msdos" goto msdos
  54 if "%1" == "--with-system-malloc" goto sysmalloc
  55 :usage
  56 echo Usage: config [--no-debug] [--with-system-malloc] [--with-x] msdos
  57 echo [Read the script before you run it.]
  58 goto end
  59 rem   ----------------------------------------------------------------------
  60 :withx
  61 set X11=Y
  62 shift
  63 goto again
  64 rem   ----------------------------------------------------------------------
  65 :nodebug
  66 set nodebug=Y
  67 shift
  68 goto again
  69 rem   ----------------------------------------------------------------------
  70 :sysmalloc
  71 set sys_malloc=Y
  72 shift
  73 goto again
  74 rem   ----------------------------------------------------------------------
  75 :msdos
  76 Echo Checking whether 'sed' is available...
  77 sed -e "w junk.$$$" <Nul
  78 If Exist junk.$$$ Goto sedOk
  79 Echo To configure 'Emacs' you need to have 'sed'!
  80 Goto End
  81 :sedOk
  82 Echo Checking whether 'rm' is available...
  83 rm -f junk.$$$
  84 If Not Exist junk.$$$ Goto rmOk
  85 Echo To configure 'Emacs' you need to have 'rm'!
  86 Goto End
  87 :rmOk
  88 Echo Checking whether 'mv' is available...
  89 rm -f junk.1 junk.2
  90 echo foo >junk.1
  91 mv junk.1 ./junk.2
  92 If Exist junk.2 Goto mvOk
  93 Echo To configure 'Emacs' you need to have 'mv'!
  94 rm -f junk.1
  95 Goto End
  96 :mvOk
  97 rm -f junk.2
  98 Echo Checking whether 'gcc' is available...
  99 echo main(){} >junk.c
 100 gcc -c junk.c
 101 if exist junk.o goto gccOk
 102 Echo To configure 'Emacs' you need to have 'gcc'!
 103 rm -f junk.c
 104 Goto End
 105 :gccOk
 106 rm -f junk.c junk.o junk junk.exe
 107 Echo Checking what version of DJGPP is installed...
 108 If Not "%DJGPP%" == "" goto djgppOk
 109 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 110 Goto End
 111 :djgppOk
 112 echo int main()           >junk.c
 113 echo #ifdef __DJGPP__    >>junk.c
 114 echo {return (__DJGPP__)*10;} >>junk.c
 115 echo #else               >>junk.c
 116 echo #ifdef __GO32__     >>junk.c
 117 echo {return 10;}         >>junk.c
 118 echo #else               >>junk.c
 119 echo {return 0;}         >>junk.c
 120 echo #endif              >>junk.c
 121 echo #endif              >>junk.c
 122 gcc -o junk junk.c
 123 if not exist junk.exe coff2exe junk
 124 junk
 125 If ErrorLevel 10 Goto go32Ok
 126 rm -f junk.c junk junk.exe
 127 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 128 Goto End
 129 :go32Ok
 130 set djgpp_ver=2
 131 If Not ErrorLevel 20 Echo To build 'Emacs' you need DJGPP v2.0 or later!
 132 If Not ErrorLevel 20 Goto End
 133 rm -f junk.c junk junk.exe
 134 rem DJECHO is used by the top-level Makefile in the v2.x build
 135 Echo Checking whether 'djecho' is available...
 136 redir -o Nul -eo djecho -o junk.$$$ foo
 137 If Exist junk.$$$ Goto djechoOk
 138 Echo To build 'Emacs' you need the 'djecho.exe' program!
 139 Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.
 140 Echo Versions of DJGPP before 2.02 called this program 'echo.exe'.
 141 Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,
 142 Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.
 143 Echo Then run CONFIG.BAT again with the same arguments you did now.
 144 Goto End
 145 :djechoOk
 146 rm -f junk.$$$
 147 Echo Configuring for DJGPP Version %DJGPP_VER% ...
 148 Rem   ----------------------------------------------------------------------
 149 Echo Configuring the source directory...
 150 cd src
 151
 152 rem   Create "epaths.h"
 153 sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp
 154 update epaths.tmp epaths.h >nul
 155 rm -f epaths.tmp
 156
 157 rem   Create "config.h"
 158 rm -f config.h2 config.tmp
 159 sed -e '' ../autogen/config.in > config.tmp
 160 if "%X11%" == "" goto src4
 161 sed -f ../msdos/sed2x.inp < ..\autogen\config.in > config.tmp
 162 :src4
 163 sed -f ../msdos/sed2v2.inp <config.tmp >config.h2
 164 Rem See if DECL_ALIGN can be supported with this GCC
 165 rm -f junk.c junk.o junk junk.exe
 166 echo struct { int i; char *p; } __attribute__((__aligned__(8))) foo;  >junk.c
 167 rem Two percent signs because it is a special character for COMMAND.COM/CMD
 168 rem Filter thru Sed because "&" is special for CMD.EXE
 169 echo int main(void) { return (unsigned long)"&"foo %% 8; } | sed "s/.&./\&/"         >>junk.c
 170 gcc -o junk junk.c
 171 if not exist junk.exe coff2exe junk
 172 junk
 173 If Not ErrorLevel 1 Goto alignOk
 174 Echo WARNING: Your GCC does not support 8-byte aligned variables.
 175 Echo WARNING: Therefore Emacs cannot support buffers larger than 128MB.
 176 rem The following line disables DECL_ALIGN which in turn disables USE_LSB_TAG
 177 rem For details see lisp.h where it defines USE_LSB_TAG
 178 echo #define NO_DECL_ALIGN >>config.h2
 179 :alignOk
 180 Rem See if they have libxml2 later than v2.2.0 installed
 181 Echo Checking whether libxml2 v2.2.1 or later is installed ...
 182 rm -f junk.c junk.o junk junk.exe
 183 rem Use djecho here because we need to quote brackets
 184 djecho "#include <libxml/xmlversion.h>"             >junk.c
 185 djecho "int main()"                                 >>junk.c
 186 djecho "{return (LIBXML_VERSION > 20200 ? 0 : 1);}" >>junk.c
 187 redir -o Nul -eo gcc -I/dev/env/DJDIR/include/libxml2 -o junk junk.c
 188 if not exist junk Goto xmlDone
 189 if not exist junk.exe coff2exe junk
 190 junk
 191 If ErrorLevel 1 Goto xmlDone
 192 Echo Configuring with libxml2 ...
 193 sed -e "/#undef HAVE_LIBXML2/s/^.*$/#define HAVE_LIBXML2 1/" <config.h2 >config.h3
 194 mv config.h3 config.h2
 195 set libxml=1
 196 :xmlDone
 197 rm -f junk.c junk junk.exe
 198 Rem See if they requested a SYSTEM_MALLOC build
 199 if "%sys_malloc%" == "" Goto cfgDone
 200 rm -f config.tmp
 201 ren config.h2 config.tmp
 202 sed -f ../msdos/sedalloc.inp <config.tmp >config.h2
 203
 204 :cfgDone
 205 rm -f junk.c junk junk.exe
 206 update config.h2 config.h >nul
 207 rm -f config.tmp config.h2
 208
 209 rem   On my system dir.h gets in the way.  It's a VMS file so who cares.
 210 if exist dir.h ren dir.h vmsdir.h
 211
 212 rem   Create "makefile" from "makefile.in".
 213 rm -f Makefile makefile.tmp
 214 copy Makefile.in+lisp.mk+deps.mk makefile.tmp
 215 sed -f ../msdos/sed1v2.inp <makefile.tmp >Makefile
 216 rm -f makefile.tmp
 217
 218 if "%X11%" == "" goto src5
 219 mv Makefile makefile.tmp
 220 sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile
 221 rm -f makefile.tmp
 222 :src5
 223
 224 if "%sys_malloc%" == "" goto src5a
 225 sed -e "/^GMALLOC_OBJ *=/s/gmalloc.o//" <Makefile >makefile.tmp
 226 sed -e "/^VMLIMIT_OBJ *=/s/vm-limit.o//" <makefile.tmp >makefile.tmp2
 227 sed -e "/^RALLOC_OBJ *=/s/ralloc.o//" <makefile.tmp2 >Makefile
 228 rm -f makefile.tmp makefile.tmp2
 229 :src5a
 230
 231 if "%nodebug%" == "" goto src6
 232 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 233 sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile
 234 rm -f makefile.tmp
 235 :src6
 236
 237 if "%libxml%" == "" goto src7
 238 sed -e "/^LIBXML2_LIBS *=/s/=/= -lxml2 -lz -liconv/" <Makefile >makefile.tmp
 239 sed -e "/^LIBXML2_CFLAGS *=/s|=|= -I/dev/env/DJDIR/include/libxml2|" <makefile.tmp >Makefile
 240 rm -f makefile.tmp
 241 :src7
 242 cd ..
 243 rem   ----------------------------------------------------------------------
 244 Echo Configuring the library source directory...
 245 cd lib-src
 246 sed -f ../msdos/sed3v2.inp <Makefile.in >Makefile
 247 if "%X11%" == "" goto libsrc2a
 248 mv Makefile makefile.tmp
 249 sed -f ../msdos/sed3x.inp <makefile.tmp >Makefile
 250 rm -f makefile.tmp
 251 :libsrc2a
 252 if "%nodebug%" == "" goto libsrc3
 253 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 254 sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile
 255 rm -f makefile.tmp
 256 :libsrc3
 257 cd ..
 258 rem   ----------------------------------------------------------------------
 259 if "%X11%" == "" goto oldx1
 260 Echo Configuring the oldxmenu directory...
 261 cd oldxmenu
 262 sed -f ../msdos/sed5x.inp <Makefile.in >Makefile
 263 if "%nodebug%" == "" goto oldx2
 264 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 265 mv -f makefile.tmp Makefile
 266 :oldx2
 267 cd ..
 268 :oldx1
 269 rem   ----------------------------------------------------------------------
 270 Echo Configuring the doc directory, expect one "File not found" message...
 271 cd doc
 272 Rem The two variants for lispintro below is for when the shell
 273 Rem supports long file names but DJGPP does not
 274 for %%d in (emacs lispref lispintro lispintr misc) do sed -f ../msdos/sed6.inp < %%d\Makefile.in > %%d\Makefile
 275 cd ..
 276 rem   ----------------------------------------------------------------------
 277 Echo Configuring the lib directory...
 278 If Exist c++defs.h update c++defs.h cxxdefs.h
 279 cd lib
 280 Rem Rename files like djtar on plain DOS filesystem would.
 281 If Exist c++defs.h update c++defs.h cxxdefs.h
 282 If Exist getopt.in.h update getopt.in.h getopt.in-h
 283 If Exist stdbool.in.h update stdbool.in.h stdbool.in-h
 284 If Exist stddef.in.h update stddef.in.h  stddef.in-h
 285 If Exist stdint.in.h update stdint.in.h  stdint.in-h
 286 If Exist stdio.in.h update stdio.in.h stdio.in-h
 287 If Exist stdlib.in.h update stdlib.in.h stdlib.in-h
 288 If Exist sys_stat.in.h update sys_stat.in.h sys_stat.in-h
 289 If Exist time.in.h update time.in.h time.in-h
 290 If Exist unistd.in.h update unistd.in.h unistd.in-h
 291 sed -f ../msdos/sedlibcf.inp < ..\autogen\Makefile.in > makefile.tmp
 292 sed -f ../msdos/sedlibmk.inp < makefile.tmp > Makefile
 293 rm -f makefile.tmp
 294 Rem Create .Po files for new files in lib/
 295 If Not Exist deps\stamp mkdir deps
 296 for %%f in (*.c) do @call ..\msdos\depfiles.bat %%f
 297 echo deps-stamp > deps\stamp
 298 cd ..
 299 rem   ----------------------------------------------------------------------
 300 Echo Configuring the lisp directory...
 301 cd lisp
 302 If Exist gnus\.dir-locals.el update gnus/.dir-locals.el gnus/_dir-locals.el
 303 sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile
 304 cd ..
 305 rem   ----------------------------------------------------------------------
 306 If not Exist leim\quail\latin-pre.el goto maindir
 307 Echo Configuring the leim directory...
 308 cd leim
 309 sed -f ../msdos/sedleim.inp < Makefile.in > Makefile
 310 cd ..
 311 rem   ----------------------------------------------------------------------
 312 :maindir
 313 Echo Configuring the main directory...
 314 If Exist .dir-locals.el update .dir-locals.el _dir-locals.el
 315 If Exist src\.dbxinit update src/.dbxinit src/_dbxinit
 316 Echo Looking for the GDB init file...
 317 If Exist src\.gdbinit update src/.gdbinit src/_gdbinit
 318 If Exist src\_gdbinit goto gdbinitOk
 319 Echo ERROR:
 320 Echo I cannot find the GDB init file.  It was called ".gdbinit" in
 321 Echo the Emacs distribution, but was probably renamed to some other
 322 Echo name without the leading dot when you untarred the archive.
 323 Echo It should be in the "src/" subdirectory.  Please make sure this
 324 Echo file exists and is called "_gdbinit" with a leading underscore.
 325 Echo Then run CONFIG.BAT again with the same arguments you did now.
 326 goto End
 327 :gdbinitOk
 328 Echo Looking for the GDB init file...found
 329 copy msdos\mainmake.v2 Makefile >nul
 330 rem   ----------------------------------------------------------------------
 331 goto End
 332 :SmallEnv
 333 echo Your environment size is too small.  Please enlarge it and run me again.
 334 echo For example, type "command.com /e:2048" to have 2048 bytes available.
 335 set $foo$=
 336 :end
 337 set X11=
 338 set nodebug=
 339 set djgpp_ver=
 340 set sys_malloc=
 341 set libxml=
 342