configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AM_INIT_AUTOMAKE
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 dnl It is important that variables on the RHS not be expanded here,
  35 dnl hence the single quotes.  This is per the GNU coding standards, see
  36 dnl (autoconf) Installation Directory Variables
  37 dnl See also epaths.h below.
  38 lispdir='${datadir}/emacs/${version}/lisp'
  39 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  40 '${datadir}/emacs/site-lisp'
  41 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  42 etcdir='${datadir}/emacs/${version}/etc'
  43 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  44 docdir='${datadir}/emacs/${version}/etc'
  45 gamedir='${localstatedir}/games/emacs'
  46
  47 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  48 dnl Create a new --with option that defaults to being disabled.
  49 dnl NAME is the base name of the option.  The shell variable with_NAME
  50 dnl   will be set to either the user's value (if the option is
  51 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  52 dnl   option is not specified).  Note that the shell variable name is
  53 dnl   constructed as autoconf does, by replacing non-alphanumeric
  54 dnl   characters with "_".
  55 dnl HELP-STRING is the help text for the option.
  56 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  57   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  58     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  59 ])dnl
  60
  61 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  62 dnl Create a new --with option that defaults to being enabled.  NAME
  63 dnl   is the base name of the option.  The shell variable with_NAME
  64 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  65 dnl   'yes' (if the option is not specified).  Note that the shell
  66 dnl   variable name is constructed as autoconf does, by replacing
  67 dnl   non-alphanumeric characters with "_".
  68 dnl HELP-STRING is the help text for the option.
  69 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  70   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  71    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  72 ])dnl
  73
  74 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  75 if test "$with_pop" = yes; then
  76    AC_DEFINE(MAIL_USE_POP)
  77 fi
  78 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  79
  80 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  81 if test "$with_kerberos" != no; then
  82    AC_DEFINE(KERBEROS)
  83 fi
  84 AH_TEMPLATE(KERBEROS,
  85             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  86
  87 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  88 if test "${with_kerberos5}" != no; then
  89   if test "${with_kerberos}" = no; then
  90     with_kerberos=yes
  91     AC_DEFINE(KERBEROS)
  92   fi
  93   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  94 fi
  95
  96 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  97 dnl FIXME hesiod support may not be present, so it seems like an error
  98 dnl to define, or at least use, this unconditionally.
  99 if test "$with_hesiod" != no; then
 100   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 101 fi
 102
 103 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 104 if test "$with_mmdf" != no; then
 105    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 109 if test "$with_mail_unlink" != no; then
 110    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 111 fi
 112
 113 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 114     [string giving default POP mail host])],
 115     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 116
 117 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 118
 119 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 120 if test "$with_sync_input" = yes; then
 121    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 122 fi
 123
 124 dnl FIXME currently it is not the last.
 125 dnl This should be the last --with option, because --with-x is
 126 dnl added later on when we find the path of X, and it's best to
 127 dnl keep them together visually.
 128 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 129  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 130 [         case "${withval}" in
 131             y | ye | yes )      val=gtk ;;
 132             n | no )            val=no  ;;
 133             l | lu | luc | luci | lucid )       val=lucid ;;
 134             a | at | ath | athe | athen | athena )      val=athena ;;
 135             m | mo | mot | moti | motif )       val=motif ;;
 136             g | gt | gtk  )     val=gtk ;;
 137             gtk3  )     val=gtk3 ;;
 138             * )
 139 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 140 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 141 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 142             ;;
 143           esac
 144           with_x_toolkit=$val
 145 ])
 146
 147 dnl _ON results in a '--without' option in the --help output, so
 148 dnl the help text should refer to "don't compile", etc.
 149 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 150 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 151 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 152 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 153 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 154 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 155 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 156 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 157
 158 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 159 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 160 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 161
 162 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 163 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 164 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 165 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 166
 167 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 168 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 169 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 170 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 171 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH(gameuser,dnl
 204 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 205 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 206   && gameuser="${with_gameuser}"
 207 test "X$gameuser" = X && gameuser=games
 208
 209 AC_ARG_WITH([gnustep-conf],dnl
 210 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 211 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 212   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 213 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 214      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 215
 216 AC_ARG_ENABLE(ns-self-contained,
 217 [AS_HELP_STRING([--disable-ns-self-contained],
 218                 [disable self contained build under NeXTstep])],
 219    EN_NS_SELF_CONTAINED=$enableval,
 220    EN_NS_SELF_CONTAINED=yes)
 221
 222 AC_ARG_ENABLE(asserts,
 223 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 224       USE_XASSERTS=$enableval,
 225       USE_XASSERTS=no)
 226
 227 AC_ARG_ENABLE(maintainer-mode,
 228 [AS_HELP_STRING([--enable-maintainer-mode],
 229                 [enable make rules and dependencies not useful (and sometimes
 230                  confusing) to the casual installer])],
 231       USE_MAINTAINER_MODE=$enableval,
 232       USE_MAINTAINER_MODE=yes)
 233 if test $USE_MAINTAINER_MODE = yes; then
 234   MAINT=
 235 else
 236   MAINT=#
 237 fi
 238 AC_SUBST(MAINT)
 239
 240 AC_ARG_ENABLE(locallisppath,
 241 [AS_HELP_STRING([--enable-locallisppath=PATH],
 242                 [directories Emacs should search for lisp files specific
 243                  to this site])],
 244 if test "${enableval}" = "no"; then
 245   locallisppath=
 246 elif test "${enableval}" != "yes"; then
 247   locallisppath=${enableval}
 248 fi)
 249
 250 AC_ARG_ENABLE(checking,
 251 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 252                 [enable expensive run-time checks.  With LIST,
 253                  enable only specific categories of checks.
 254                  Categories are: all,yes,no.
 255                  Flags are: stringbytes, stringoverrun, stringfreelist,
 256                  xmallocoverrun, conslist])],
 257 [ac_checking_flags="${enableval}"],[])
 258 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 259 for check in $ac_checking_flags
 260 do
 261         case $check in
 262         # these set all the flags to specific states
 263         yes)            ac_enable_checking=1 ;;
 264         no)             ac_enable_checking= ;
 265                         ac_gc_check_stringbytes= ;
 266                         ac_gc_check_string_overrun= ;
 267                         ac_gc_check_string_free_list= ;
 268                         ac_xmalloc_overrun= ;
 269                         ac_gc_check_cons_list= ;;
 270         all)            ac_enable_checking=1 ;
 271                         ac_gc_check_stringbytes=1 ;
 272                         ac_gc_check_string_overrun=1 ;
 273                         ac_gc_check_string_free_list=1 ;
 274                         ac_xmalloc_overrun=1 ;
 275                         ac_gc_check_cons_list=1 ;;
 276         # these enable particular checks
 277         stringbytes)    ac_gc_check_stringbytes=1 ;;
 278         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 279         stringfreelist) ac_gc_check_string_free_list=1 ;;
 280         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 281         conslist)       ac_gc_check_cons_list=1 ;;
 282         *)      AC_MSG_ERROR(unknown check category $check) ;;
 283         esac
 284 done
 285 IFS="$ac_save_IFS"
 286
 287 if test x$ac_enable_checking != x ; then
 288   AC_DEFINE(ENABLE_CHECKING, 1,
 289 [Enable expensive run-time checking of data types?])
 290 fi
 291 if test x$ac_gc_check_stringbytes != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 293 [Define this temporarily to hunt a bug.  If defined, the size of
 294    strings is redundantly recorded in sdata structures so that it can
 295    be compared to the sizes recorded in Lisp strings.])
 296 fi
 297 if test x$ac_gc_check_stringoverrun != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 299 [Define this to check for short string overrun.])
 300 fi
 301 if test x$ac_gc_check_string_free_list != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 303 [Define this to check the string free list.])
 304 fi
 305 if test x$ac_xmalloc_overrun != x ; then
 306   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 307 [Define this to check for malloc buffer overrun.])
 308 fi
 309 if test x$ac_gc_check_cons_list != x ; then
 310   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 311 [Define this to check for errors in cons list.])
 312 fi
 313
 314 AC_ARG_ENABLE(use-lisp-union-type,
 315 [AS_HELP_STRING([--enable-use-lisp-union-type],
 316                 [use a union for the Lisp_Object data type.
 317                 This is only useful for development for catching certain types of bugs.])],
 318 if test "${enableval}" != "no"; then
 319    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 320    [Define this to use a lisp union for the Lisp_Object data type.])
 321 fi)
 322
 323
 324 AC_ARG_ENABLE(profiling,
 325 [AS_HELP_STRING([--enable-profiling],
 326                 [build emacs with profiling support.
 327                  This might not work on all platforms])],
 328 [ac_enable_profiling="${enableval}"],[])
 329 if test x$ac_enable_profiling != x ; then
 330    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 331 else
 332    PROFILING_CFLAGS=
 333 fi
 334 AC_SUBST(PROFILING_CFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Check if the source directory already has a configured system in it.
 368 if test `pwd` != `(cd ${srcdir} && pwd)` \
 369    && test -f "${srcdir}/src/config.h" ; then
 370   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 371    as a build directory right now; it has been configured in its own
 372    right.  To configure in another directory as well, you MUST
 373    use GNU make.  If you do not have GNU make, then you must
 374    now do `make distclean' in ${srcdir},
 375    and then run $0 again.]])
 376 fi
 377
 378 #### Given the configuration name, set machfile and opsysfile to the
 379 #### names of the m/*.h and s/*.h files we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system and machine description files.
 400
 401 ### You would hope that you could choose an m/*.h file pretty much
 402 ### based on the machine portion of the configuration name, and an s/*.h
 403 ### file based on the operating system portion.  However, it turns out
 404 ### that each m/*.h file is pretty manufacturer-specific - for
 405 ### example mips.h is MIPS
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 machine='' opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## GNU/Linux ports
 419   *-*-linux-gnu*)
 420     opsys=gnu-linux
 421     case ${canonical} in
 422       alpha*)   machine=alpha ;;
 423       s390-*)   machine=ibms390 ;;
 424       s390x-*)  machine=ibms390x ;;
 425       powerpc*) machine=macppc ;;
 426       sparc*)   machine=sparc ;;
 427       ia64*)    machine=ia64 ;;
 428       m68k*)    machine=m68k ;;
 429       x86_64*)  machine=amdx86-64 ;;
 430     esac
 431   ;;
 432
 433   ## FreeBSD ports
 434   *-*-freebsd* )
 435     opsys=freebsd
 436     case "${canonical}" in
 437       alpha*)           machine=alpha ;;
 438       amd64-*|x86_64-*) machine=amdx86-64 ;;
 439       ia64-*)           machine=ia64 ;;
 440       i[3456]86-*)      machine=intel386 ;;
 441       powerpc-*)        machine=macppc ;;
 442       sparc-*)          machine=sparc ;;
 443       sparc64-*)        machine=sparc ;;
 444     esac
 445   ;;
 446
 447   ## FreeBSD kernel + glibc based userland
 448   *-*-kfreebsd*gnu* )
 449     opsys=gnu-kfreebsd
 450     case "${canonical}" in
 451       alpha*)           machine=alpha ;;
 452       amd64-*|x86_64-*) machine=amdx86-64 ;;
 453       ia64-*)           machine=ia64 ;;
 454       i[3456]86-*)      machine=intel386 ;;
 455       powerpc-*)        machine=macppc ;;
 456       sparc-*)          machine=sparc ;;
 457       sparc64-*)        machine=sparc ;;
 458     esac
 459   ;;
 460
 461   ## NetBSD ports
 462   *-*-netbsd* )
 463     opsys=netbsd
 464     case "${canonical}" in
 465       alpha*)      machine=alpha ;;
 466       x86_64-*)    machine=amdx86-64 ;;
 467       i[3456]86-*) machine=intel386 ;;
 468       m68k-*)      machine=m68k ;;
 469       powerpc-*)   machine=macppc ;;
 470       sparc*-)     machine=sparc ;;
 471       vax-*)       machine=vax ;;
 472     esac
 473   ;;
 474
 475   ## OpenBSD ports
 476   *-*-openbsd* )
 477     opsys=openbsd
 478     case "${canonical}" in
 479       alpha*)    machine=alpha ;;
 480       x86_64-*)  machine=amdx86-64 ;;
 481       i386-*)    machine=intel386 ;;
 482       powerpc-*) machine=macppc ;;
 483       sparc*)    machine=sparc ;;
 484       vax-*)     machine=vax ;;
 485     esac
 486   ;;
 487
 488   ## Apple Darwin / Mac OS X
 489   *-apple-darwin* )
 490     case "${canonical}" in
 491       i[3456]86-* )  machine=intel386 ;;
 492       powerpc-* )    machine=macppc ;;
 493       x86_64-* )     machine=amdx86-64 ;;
 494       * )            unported=yes ;;
 495     esac
 496     opsys=darwin
 497     # Define CPP as follows to make autoconf work correctly.
 498     CPP="${CC-cc} -E -no-cpp-precomp"
 499     # Use fink packages if available.
 500     if test -d /sw/include && test -d /sw/lib; then
 501       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 502       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 503       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 504     fi
 505   ;;
 506
 507   ## HP 9000 series 700 and 800, running HP/UX
 508   hppa*-hp-hpux10.2* )
 509     opsys=hpux10-20
 510   ;;
 511   hppa*-hp-hpux1[1-9]* )
 512     opsys=hpux11
 513     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 514   ;;
 515
 516   ia64*-hp-hpux1[1-9]* )
 517     machine=hp800 opsys=hpux11
 518     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 519     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 520     CANNOT_DUMP=yes
 521   ;;
 522
 523   hppa*-*-linux-gnu* )
 524     machine=hp800 opsys=gnu-linux
 525   ;;
 526
 527   ## IBM machines
 528   rs6000-ibm-aix4.[23]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix4.[23]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   rs6000-ibm-aix[56]* )
 535     machine=ibmrs6000 opsys=aix4-2
 536   ;;
 537   powerpc-ibm-aix[56]*  )
 538     machine=ibmrs6000 opsys=aix4-2
 539   ;;
 540
 541   ## Silicon Graphics machines
 542   ## Iris 4D
 543   mips-sgi-irix6.5 )
 544     machine=iris4d opsys=irix6-5
 545     # Without defining _LANGUAGE_C, things get masked out in the headers
 546     # so that, for instance, grepping for `free' in stdlib.h fails and
 547     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 548     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 549     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 550   ;;
 551
 552   ## Suns
 553   *-sun-solaris* \
 554     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 555     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 556     case "${canonical}" in
 557       i[3456]86-*-* )     machine=intel386 ;;
 558       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 559       sparc* )          machine=sparc ;;
 560       * )               unported=yes ;;
 561     esac
 562     case "${canonical}" in
 563       *-sunos5.6* | *-solaris2.6* )
 564                 opsys=sol2-6
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 RANLIB="ar -ts"
 567                 ;;
 568       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 569                 opsys=sol2-6
 570                 emacs_check_sunpro_c=yes
 571                 NON_GNU_CPP=/usr/ccs/lib/cpp
 572                 ;;
 573       *-sunos5* | *-solaris* )
 574                 opsys=sol2-10
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578     esac
 579     ## Watch out for a compiler that we know will not work.
 580     case "${canonical}" in
 581      *-solaris* | *-sunos5* )
 582                 if [ "x$CC" = x/usr/ucb/cc ]; then
 583                   ## /usr/ucb/cc doesn't work;
 584                   ## we should find some other compiler that does work.
 585                   unset CC
 586                 fi
 587                 ;;
 588       *) ;;
 589     esac
 590   ;;
 591
 592   ## Intel 386 machines where we don't care about the manufacturer.
 593   i[3456]86-*-* )
 594     machine=intel386
 595     case "${canonical}" in
 596       *-cygwin )                opsys=cygwin ;;
 597       *-darwin* )               opsys=darwin
 598                                 CPP="${CC-cc} -E -no-cpp-precomp"
 599                                 ;;
 600       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 604     esac
 605   ;;
 606
 607   * )
 608     unported=yes
 609   ;;
 610 esac
 611
 612 ### If the code above didn't choose an operating system, just choose
 613 ### an operating system based on the configuration name.  You really
 614 ### only want to use this when you have no idea what the right
 615 ### operating system is; if you know what operating systems a machine
 616 ### runs, it's cleaner to make it explicit in the case statement
 617 ### above.
 618 if test x"${opsys}" = x; then
 619   case "${canonical}" in
 620     *-gnu* )                            opsys=gnu ;;
 621     * )
 622       unported=yes
 623     ;;
 624   esac
 625 fi
 626
 627 ]
 628 dnl quotation ends
 629
 630 if test $unported = yes; then
 631   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 632 Check `etc/MACHINES' for recognized configuration names.])
 633 fi
 634
 635 if test -n "$machine"; then
 636   machfile="m/${machine}.h"
 637 else
 638   machfile=
 639 fi
 640 opsysfile="s/${opsys}.h"
 641
 642
 643 #### Choose a compiler.
 644 test -n "$CC" && cc_specified=yes
 645
 646 # Save the value of CFLAGS that the user specified.
 647 SPECIFIED_CFLAGS="$CFLAGS"
 648
 649 dnl Sets GCC=yes if using gcc.
 650 AC_PROG_CC
 651 AM_PROG_CC_C_O
 652
 653 # Initialize gnulib right after verifying that the C compiler works.
 654 gl_EARLY
 655
 656 # On Suns, sometimes $CPP names a directory.
 657 if test -n "$CPP" && test -d "$CPP"; then
 658   CPP=
 659 fi
 660
 661 ## If not using gcc, and on Solaris, and no CPP specified, see if
 662 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 663 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 664  test x"$CPP" = x; then
 665   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 666   AC_CACHE_VAL(emacs_cv_sunpro_c,
 667   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 668 [[#ifndef __SUNPRO_C
 669 fail;
 670 #endif
 671 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 672   AC_MSG_RESULT($emacs_cv_sunpro_c)
 673
 674   if test x"$emacs_cv_sunpro_c" = xyes; then
 675     NON_GNU_CPP="$CC -E -Xs"
 676   fi
 677 fi
 678
 679 #### Some systems specify a CPP to use unless we are using GCC.
 680 #### Now that we know whether we are using GCC, we can decide whether
 681 #### to use that one.
 682 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 683 then
 684   CPP="$NON_GNU_CPP"
 685 fi
 686
 687 #### Some systems specify a CC to use unless we are using GCC.
 688 #### Now that we know whether we are using GCC, we can decide whether
 689 #### to use that one.
 690 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 691   test x$cc_specified != xyes
 692 then
 693   CC="$NON_GNU_CC"
 694 fi
 695
 696 if test x$GCC = xyes; then
 697   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 698 else
 699   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 700 fi
 701
 702 ### Use -Wdeclaration-after-statement if the compiler supports it
 703 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 704 SAVE_CFLAGS="$CFLAGS"
 705 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 706 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 707 if test $has_option = yes; then
 708    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 709 fi
 710 AC_MSG_RESULT($has_option)
 711 CFLAGS="$SAVE_CFLAGS"
 712 unset has_option
 713 unset SAVE_CFLAGS
 714
 715 ### Use -Wold-style-definition if the compiler supports it
 716 # This can be removed when conversion to standard C is finished.
 717 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 718 SAVE_CFLAGS="$CFLAGS"
 719 CFLAGS="$CFLAGS -Wold-style-definition"
 720 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 721 if test $has_option = yes; then
 722    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 723 fi
 724 AC_MSG_RESULT($has_option)
 725 CFLAGS="$SAVE_CFLAGS"
 726 unset has_option
 727 unset SAVE_CFLAGS
 728
 729 ### Use -Wimplicit-function-declaration if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 733 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 AC_SUBST(C_WARNINGS_SWITCH)
 743
 744
 745 #### Some other nice autoconf tests.
 746
 747 dnl checks for programs
 748 AC_PROG_CPP
 749 AC_PROG_INSTALL
 750 if test "x$RANLIB" = x; then
 751   AC_PROG_RANLIB
 752 fi
 753
 754 ## Although we're running on an amd64 kernel, we're actually compiling for
 755 ## the x86 architecture.  The user should probably have provided an
 756 ## explicit --build to `configure', but if everything else than the kernel
 757 ## is running in i386 mode, we can help them out.
 758 if test "$machine" = "amdx86-64"; then
 759   AC_CHECK_DECL([i386])
 760   if test "$ac_cv_have_decl_i386" = "yes"; then
 761     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 762     machine=intel386
 763     machfile="m/${machine}.h"
 764   fi
 765 fi
 766
 767 AC_PATH_PROG(INSTALL_INFO, install-info)
 768 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 769 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 770 dnl Don't use GZIP, which is used by gzip for additional parameters.
 771 AC_PATH_PROG(GZIP_PROG, gzip)
 772
 773
 774 ## Need makeinfo >= 4.6 (?) to build the manuals.
 775 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 776 dnl By this stage, configure has already checked for egrep and set EGREP,
 777 dnl or exited with an error if no egrep was found.
 778 if test "$MAKEINFO" != "no" && \
 779   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 780    MAKEINFO=no
 781 fi
 782
 783 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 784 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 785 ## therefore in the category of "special tools" not normally required, which
 786 ## configure does not have to check for (eg autoconf itself).
 787 ## In a Bazaar checkout on the other hand, the manuals are not included.
 788 ## So makeinfo is a requirement to build from Bazaar, and configure
 789 ## should test for it as it does for any other build requirement.
 790 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 791 ## with pre-built manuals, from a Bazaar checkout.
 792 HAVE_MAKEINFO=yes
 793
 794 if test "$MAKEINFO" = "no"; then
 795   MAKEINFO=makeinfo
 796   if test "x${with_makeinfo}" = "xno"; then
 797     HAVE_MAKEINFO=no
 798   elif test ! -e $srcdir/info/emacs; then
 799     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 800 source tree does not seem to have pre-built manuals in the `info' directory.
 801 Either install a suitable version of makeinfo, or re-run configure
 802 with the `--without-makeinfo' option to build without the manuals.] )
 803   fi
 804 fi
 805 AC_SUBST(HAVE_MAKEINFO)
 806
 807 dnl Add our options to ac_link now, after it is set up.
 808
 809 if test x$GCC = xyes; then
 810   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 811     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 812 else
 813   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 814     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 815 fi
 816
 817 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 818 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 819 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 820 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 821 dnl if not built to support GNU ld.
 822
 823 late_LDFLAGS=$LDFLAGS
 824 if test x$GCC = xyes; then
 825   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 826 else
 827   LDFLAGS="$LDFLAGS -znocombreloc"
 828 fi
 829
 830 AC_MSG_CHECKING([for -znocombreloc])
 831 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 832   [AC_MSG_RESULT(yes)],
 833   LDFLAGS=$late_LDFLAGS
 834   [AC_MSG_RESULT(no)])
 835
 836
 837 # The value of CPP is a quoted variable reference, so we need to do this
 838 # to get its actual value...
 839 CPP=`eval "echo $CPP"`
 840
 841
 842 dnl The function dump-emacs will not be defined and temacs will do
 843 dnl (load "loadup") automatically unless told otherwise.
 844 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 845 case "$opsys" in
 846   your-opsys-here) CANNOT_DUMP=yes ;;
 847 esac
 848
 849 test "$CANNOT_DUMP" = "yes" && \
 850   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 851
 852 AC_SUBST(CANNOT_DUMP)
 853
 854
 855 UNEXEC_OBJ=unexelf.o
 856 case "$opsys" in
 857   # MSDOS uses unexcoff.o
 858   # MSWindows uses unexw32.o
 859   aix4-2)
 860    UNEXEC_OBJ=unexaix.o
 861    ;;
 862   cygwin)
 863    UNEXEC_OBJ=unexcw.o
 864    ;;
 865   darwin)
 866    UNEXEC_OBJ=unexmacosx.o
 867    ;;
 868   hpux10-20 | hpux11)
 869    UNEXEC_OBJ=unexhp9k800.o
 870    ;;
 871   sol2-10)
 872    # Use the Solaris dldump() function, called from unexsol.c, to dump
 873    # emacs, instead of the generic ELF dump code found in unexelf.c.
 874    # The resulting binary has a complete symbol table, and is better
 875    # for debugging and other observability tools (debuggers, pstack, etc).
 876    #
 877    # If you encounter a problem using dldump(), please consider sending
 878    # a message to the OpenSolaris tools-linking mailing list:
 879    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 880    #
 881    # It is likely that dldump() works with older Solaris too, but this has
 882    # not been tested, so for now this change is for Solaris 10 or newer.
 883    UNEXEC_OBJ=unexsol.o
 884    ;;
 885 esac
 886
 887 LD_SWITCH_SYSTEM=
 888 case "$opsys" in
 889   freebsd)
 890    ## Let `ld' find image libs and similar things in /usr/local/lib.
 891    ## The system compiler, GCC, has apparently been modified to not
 892    ## look there, contrary to what a stock GCC would do.
 893    LD_SWITCH_SYSTEM=-L/usr/local/lib
 894    ;;
 895
 896   gnu-linux)
 897    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 898    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 899    ;;
 900
 901   netbsd)
 902    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 903    ;;
 904
 905   openbsd)
 906    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 907    ## otherwise Emacs dumps core on elf systems.
 908    LD_SWITCH_SYSTEM="-Z"
 909    ;;
 910 esac
 911 AC_SUBST(LD_SWITCH_SYSTEM)
 912
 913 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 914
 915 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 916 ## which has not been defined yet.  When this was handled with cpp,
 917 ## it was expanded to null when configure sourced the s/*.h file.
 918 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 919 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 920 ## (or somesuch), but because it is supposed to go at the _front_
 921 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 922 ## Compare with the gnu-linux case below, which added to the end
 923 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 924 ## LD_SWITCH_SYSTEM_TEMACS.
 925 case "$opsys" in
 926   netbsd|openbsd)
 927    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 928    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 929 esac
 930
 931
 932 C_SWITCH_MACHINE=
 933 if test "$machine" = "alpha"; then
 934   AC_CHECK_DECL([__ELF__])
 935   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 936     ## With ELF, make sure that all common symbols get allocated to in the
 937     ## data section.  Otherwise, the dump of temacs may miss variables in
 938     ## the shared library that have been initialized.  For example, with
 939     ## GNU libc, __malloc_initialized would normally be resolved to the
 940     ## shared library's .bss section, which is fatal.
 941     if test "x$GCC" = "xyes"; then
 942       C_SWITCH_MACHINE="-fno-common"
 943     else
 944       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 945     fi
 946   else
 947     UNEXEC_OBJ=unexalpha.o
 948   fi
 949 fi
 950 AC_SUBST(C_SWITCH_MACHINE)
 951
 952 AC_SUBST(UNEXEC_OBJ)
 953
 954 C_SWITCH_SYSTEM=
 955 ## Some programs in src produce warnings saying certain subprograms
 956 ## are too complex and need a MAXMEM value greater than 2000 for
 957 ## additional optimization.  --nils@exp-math.uni-essen.de
 958 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 959   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 960 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 961 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 962 AC_SUBST(C_SWITCH_SYSTEM)
 963
 964
 965 LIBS_SYSTEM=
 966 case "$opsys" in
 967   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 968   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 969
 970   freebsd) LIBS_SYSTEM="-lutil" ;;
 971
 972   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 973
 974   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 975
 976   ## Motif needs -lgen.
 977   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 978 esac
 979 AC_SUBST(LIBS_SYSTEM)
 980
 981
 982 ### Make sure subsequent tests use flags consistent with the build flags.
 983
 984 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 985   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 986 else
 987   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 988 fi
 989
 990 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 991 AC_SYS_LARGEFILE
 992
 993
 994 ## If user specified a crt-dir, use that unconditionally.
 995 if test "X$CRT_DIR" = "X"; then
 996
 997   case "$canonical" in
 998     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
 999     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1000     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1001     ## For anything else (eg /usr/lib32), it is up the user to specify
1002     ## the location (bug#5655).
1003     ## Test for crtn.o, not just the directory, because sometimes the
1004     ## directory exists but does not have the relevant files (bug#1287).
1005     ## FIXME better to test for binary compatibility somehow.
1006     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1007     ;;
1008
1009     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1010   esac
1011
1012   case "$opsys" in
1013     hpux10-20) CRT_DIR=/lib ;;
1014   esac
1015
1016   ## Default is /usr/lib.
1017   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1018
1019 else
1020
1021   ## Some platforms don't use any of these files, so it is not
1022   ## appropriate to put this test outside the if block.
1023   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1024     AC_MSG_ERROR([crt*.o not found in specified location.])
1025
1026 fi
1027
1028 AC_SUBST(CRT_DIR)
1029
1030 LIB_MATH=-lm
1031 LIB_STANDARD=
1032 START_FILES=
1033
1034 case $opsys in
1035   cygwin )
1036     LIB_MATH=
1037     START_FILES='pre-crt0.o'
1038     ;;
1039   darwin )
1040     ## Adding -lm confuses the dynamic linker, so omit it.
1041     LIB_MATH=
1042     START_FILES='pre-crt0.o'
1043     ;;
1044   freebsd )
1045     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1046     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1047     ;;
1048   gnu-linux | gnu-kfreebsd )
1049     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1050     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1051     ;;
1052   hpux10-20 | hpux11 )
1053     LIB_STANDARD=-lc
1054     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1055     ;;
1056   netbsd | openbsd )
1057     if test -f $CRT_DIR/crti.o; then
1058         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1059         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1060     else
1061         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1062         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1063     fi
1064     ;;
1065 esac
1066
1067 AC_SUBST(LIB_MATH)
1068 AC_SUBST(START_FILES)
1069
1070 dnl This function definition taken from Gnome 2.0
1071 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1072 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1073 dnl also defines GSTUFF_PKG_ERRORS on error
1074 AC_DEFUN([PKG_CHECK_MODULES], [
1075   succeeded=no
1076
1077   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1078
1079   if test "$PKG_CONFIG" = "no" ; then
1080      ifelse([$4], , [AC_MSG_ERROR([
1081       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1082   else
1083      PKG_CONFIG_MIN_VERSION=0.9.0
1084      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1085         AC_MSG_CHECKING(for $2)
1086
1087         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1088             AC_MSG_RESULT(yes)
1089             succeeded=yes
1090
1091             AC_MSG_CHECKING($1_CFLAGS)
1092             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1093             AC_MSG_RESULT($$1_CFLAGS)
1094
1095             AC_MSG_CHECKING($1_LIBS)
1096             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1097             AC_MSG_RESULT($$1_LIBS)
1098         else
1099             AC_MSG_RESULT(no)
1100             $1_CFLAGS=""
1101             $1_LIBS=""
1102             ## If we have a custom action on failure, don't print errors, but
1103             ## do set a variable so people can do so.
1104             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1105             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1106         fi
1107
1108         AC_SUBST($1_CFLAGS)
1109         AC_SUBST($1_LIBS)
1110      else
1111         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1112         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1113      fi
1114   fi
1115
1116   if test $succeeded = yes; then
1117      ifelse([$3], , :, [$3])
1118   else
1119      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1120   fi
1121 ])
1122
1123
1124 if test "${with_sound}" != "no"; then
1125   # Sound support for GNU/Linux and the free BSDs.
1126   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1127     have_sound_header=yes)
1128   # Emulation library used on NetBSD.
1129   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1130   AC_SUBST(LIBSOUND)
1131
1132   ALSA_REQUIRED=1.0.0
1133   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1134   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1135   if test $HAVE_ALSA = yes; then
1136     SAVE_CFLAGS="$CFLAGS"
1137     SAVE_LDFLAGS="$LDFLAGS"
1138     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1139     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1140     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1141                     emacs_alsa_normal=yes,
1142                     emacs_alsa_normal=no)
1143     if test "$emacs_alsa_normal" != yes; then
1144       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1145                      [[snd_lib_error_set_handler (0);]])],
1146                      emacs_alsa_subdir=yes,
1147                      emacs_alsa_subdir=no)
1148       if test "$emacs_alsa_subdir" != yes; then
1149         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1150       fi
1151       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1152     fi
1153
1154     CFLAGS="$SAVE_CFLAGS"
1155     LDFLAGS="$SAVE_LDFLAGS"
1156     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1157     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1158     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1159   fi
1160
1161   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1162   dnl compiles only on the specified platforms.  For others, it
1163   dnl probably doesn't make sense to try.
1164   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1165      case "$opsys" in
1166        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1167        gnu-linux|freebsd|netbsd)
1168          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1169          ;;
1170      esac
1171   fi
1172
1173   AC_SUBST(CFLAGS_SOUND)
1174 fi
1175
1176 dnl checks for header files
1177 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1178   linux/version.h sys/systeminfo.h limits.h \
1179   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1180   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1181   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1182
1183 AC_MSG_CHECKING(if personality LINUX32 can be set)
1184 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1185                emacs_cv_personality_linux32=yes,
1186                emacs_cv_personality_linux32=no)
1187 AC_MSG_RESULT($emacs_cv_personality_linux32)
1188
1189 if test $emacs_cv_personality_linux32 = yes; then
1190   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1191             [Define to 1 if personality LINUX32 can be set.])
1192 fi
1193
1194 dnl On Solaris 8 there's a compilation warning for term.h because
1195 dnl it doesn't define `bool'.
1196 AC_CHECK_HEADERS(term.h, , , -)
1197 AC_HEADER_STDC
1198 AC_HEADER_TIME
1199 AC_CHECK_DECLS([sys_siglist])
1200 if test $ac_cv_have_decl_sys_siglist != yes; then
1201   # For Tru64, at least:
1202   AC_CHECK_DECLS([__sys_siglist])
1203   if test $ac_cv_have_decl___sys_siglist = yes; then
1204     AC_DEFINE(sys_siglist, __sys_siglist,
1205               [Define to any substitute for sys_siglist.])
1206   fi
1207 fi
1208 AC_HEADER_SYS_WAIT
1209
1210 dnl Some systems have utime.h but don't declare the struct anyplace.
1211 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1212 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1213 #include <sys/time.h>
1214 #include <time.h>
1215 #else
1216 #ifdef HAVE_SYS_TIME_H
1217 #include <sys/time.h>
1218 #else
1219 #include <time.h>
1220 #endif
1221 #endif
1222 #ifdef HAVE_UTIME_H
1223 #include <utime.h>
1224 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1225   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1226 if test $emacs_cv_struct_utimbuf = yes; then
1227   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1228 fi
1229
1230 dnl Check for speed_t typedef.
1231 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1232   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1233     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1234 if test $emacs_cv_speed_t = yes; then
1235   AC_DEFINE(HAVE_SPEED_T, 1,
1236            [Define to 1 if `speed_t' is declared by <termios.h>.])
1237 fi
1238
1239 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1240 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1241 #include <sys/time.h>
1242 #include <time.h>
1243 #else
1244 #ifdef HAVE_SYS_TIME_H
1245 #include <sys/time.h>
1246 #else
1247 #include <time.h>
1248 #endif
1249 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1250   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1251 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1252 if test $emacs_cv_struct_timeval = yes; then
1253   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1254 fi
1255
1256 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1257 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1258 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1259   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1260 HAVE_EXCEPTION=$emacs_cv_struct_exception
1261 if test $emacs_cv_struct_exception != yes; then
1262   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1263 fi
1264
1265 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1266 #if HAVE_SYS_SOCKET_H
1267 #include <sys/socket.h>
1268 #endif])
1269
1270 dnl checks for structure members
1271 AC_STRUCT_TM
1272 AC_STRUCT_TIMEZONE
1273 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1274                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1275                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1276                 [#include <time.h>])
1277 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1278                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1279                   struct ifreq.ifr_addr], , ,
1280                  [AC_INCLUDES_DEFAULT
1281 #if HAVE_SYS_SOCKET_H
1282 #include <sys/socket.h>
1283 #endif
1284 #if HAVE_NET_IF_H
1285 #include <net/if.h>
1286 #endif])
1287
1288 dnl checks for compiler characteristics
1289
1290 dnl Testing __STDC__ to determine prototype support isn't good enough.
1291 dnl DEC C, for instance, doesn't define it with default options, and
1292 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1293 dnl and void *.
1294 AC_C_PROTOTYPES
1295 AC_C_VOLATILE
1296 AC_C_CONST
1297 dnl This isn't useful because we can't turn on use of `inline' unless
1298 dnl the compiler groks `extern inline'.
1299 dnl AC_C_INLINE
1300 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1301   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1302                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1303 if test $emacs_cv_void_star = yes; then
1304   AC_DEFINE(POINTER_TYPE, void)
1305 else
1306   AC_DEFINE(POINTER_TYPE, char)
1307 fi
1308 AH_TEMPLATE(POINTER_TYPE,
1309             [Define as `void' if your compiler accepts `void *'; otherwise
1310              define as `char'.])dnl
1311
1312 dnl Check for endianess
1313 AC_C_BIGENDIAN
1314
1315 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1316   [emacs_cv_attribute_aligned],
1317   [AC_COMPILE_IFELSE(
1318      [AC_LANG_PROGRAM(
1319         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1320         [[]])],
1321      [emacs_cv_attribute_aligned=yes],
1322      [emacs_cv_attribute_aligned=no])])
1323 if test $emacs_cv_attribute_aligned = yes; then
1324   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1325     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1326 fi
1327
1328 dnl check for Make feature
1329 AC_PROG_MAKE_SET
1330
1331 DEPFLAGS=
1332 MKDEPDIR=":"
1333 deps_frag=deps.mk
1334 dnl check for GNU Make if we have GCC and autodepend is on.
1335 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1336    AC_MSG_CHECKING([whether we are using GNU Make])
1337    HAVE_GNU_MAKE=no
1338    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1339    if test "x$testval" != x; then
1340       HAVE_GNU_MAKE=yes
1341    else
1342       ac_enable_autodepend=no
1343    fi
1344    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1345    if test $HAVE_GNU_MAKE = yes; then
1346       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1347       SAVE_CFLAGS="$CFLAGS"
1348       CFLAGS="$CFLAGS -MMD -MF deps.d"
1349       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1350       CFLAGS="$SAVE_CFLAGS"
1351       test -f deps.d || ac_enable_autodepend=no
1352       rm -rf deps.d
1353       AC_MSG_RESULT([$ac_enable_autodepend])
1354    fi
1355    if test $ac_enable_autodepend = yes; then
1356       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1357       ## In parallel builds, another make might create depdir between
1358       ## the first test and mkdir, so stick another test on the end.
1359       ## Or use install-sh -d?  mkdir -p is not portable.
1360       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1361       deps_frag=autodeps.mk
1362    fi
1363 fi
1364 deps_frag=$srcdir/src/$deps_frag
1365 AC_SUBST(MKDEPDIR)
1366 AC_SUBST(DEPFLAGS)
1367 AC_SUBST_FILE(deps_frag)
1368
1369
1370 dnl checks for operating system services
1371 AC_SYS_LONG_FILE_NAMES
1372
1373 #### Choose a window system.
1374
1375 AC_PATH_X
1376 if test "$no_x" = yes; then
1377   window_system=none
1378 else
1379   window_system=x11
1380 fi
1381
1382 ## Workaround for bug in autoconf <= 2.62.
1383 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1384 ## No need to do anything special for these standard directories.
1385 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1386
1387    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1388
1389 fi
1390
1391 LD_SWITCH_X_SITE_AUX=
1392 LD_SWITCH_X_SITE_AUX_RPATH=
1393 if test "${x_libraries}" != NONE; then
1394   if test -n "${x_libraries}"; then
1395     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1396     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1397     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1398   fi
1399   x_default_search_path=""
1400   x_search_path=${x_libraries}
1401   if test -z "${x_search_path}"; then
1402     x_search_path=/usr/lib
1403   fi
1404   for x_library in `echo ${x_search_path}: | \
1405                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1406     x_search_path="\
1407 ${x_library}/X11/%L/%T/%N%C%S:\
1408 ${x_library}/X11/%l/%T/%N%C%S:\
1409 ${x_library}/X11/%T/%N%C%S:\
1410 ${x_library}/X11/%L/%T/%N%S:\
1411 ${x_library}/X11/%l/%T/%N%S:\
1412 ${x_library}/X11/%T/%N%S"
1413     if test x"${x_default_search_path}" = x; then
1414       x_default_search_path=${x_search_path}
1415     else
1416       x_default_search_path="${x_search_path}:${x_default_search_path}"
1417     fi
1418   done
1419 fi
1420 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1421 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1422
1423 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1424   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1425 fi
1426
1427 if test x"${x_includes}" = x; then
1428   bitmapdir=/usr/include/X11/bitmaps
1429 else
1430   # accumulate include directories that have X11 bitmap subdirectories
1431   bmd_acc="dummyval"
1432   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1433     if test -d "${bmd}/X11/bitmaps"; then
1434       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1435     fi
1436     if test -d "${bmd}/bitmaps"; then
1437       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1438     fi
1439   done
1440   if test ${bmd_acc} != "dummyval"; then
1441     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1442   fi
1443 fi
1444
1445 HAVE_NS=no
1446 NS_IMPL_COCOA=no
1447 NS_IMPL_GNUSTEP=no
1448 tmp_CPPFLAGS="$CPPFLAGS"
1449 tmp_CFLAGS="$CFLAGS"
1450 CPPFLAGS="$CPPFLAGS -x objective-c"
1451 CFLAGS="$CFLAGS -x objective-c"
1452 TEMACS_LDFLAGS2="\${LDFLAGS}"
1453 dnl I don't think it's especially important, but src/Makefile.in
1454 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1455 dnl trailing "/" to it, so now we do it here.
1456 if test "${with_ns}" != no; then
1457   if test "${opsys}" = darwin; then
1458      NS_IMPL_COCOA=yes
1459      ns_appdir=`pwd`/nextstep/Emacs.app
1460      ns_appbindir=${ns_appdir}/Contents/MacOS/
1461      ns_appresdir=${ns_appdir}/Contents/Resources
1462      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1463   elif test -f $GNUSTEP_CONFIG_FILE; then
1464      NS_IMPL_GNUSTEP=yes
1465      ns_appdir=`pwd`/nextstep/Emacs.app
1466      ns_appbindir=${ns_appdir}/
1467      ns_appresdir=${ns_appdir}/Resources
1468      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1469      dnl FIXME sourcing this several times in subshells seems inefficient.
1470      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1471      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1472      dnl I seemed to need these as well with GNUstep-startup 0.25.
1473      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1474      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1475      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1476        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1477      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1478        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1479      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1480      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1481      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1482      LIB_STANDARD=
1483      START_FILES=
1484      TEMACS_LDFLAGS2=
1485   fi
1486   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1487                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1488   files are missing or cannot be compiled.])])
1489   NS_HAVE_NSINTEGER=yes
1490   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1491                                      [NSInteger i;])],
1492                     ns_have_nsinteger=yes,
1493                     ns_have_nsinteger=no)
1494   if test $ns_have_nsinteger = no; then
1495     NS_HAVE_NSINTEGER=no
1496   fi
1497 fi
1498 AC_SUBST(TEMACS_LDFLAGS2)
1499
1500 ns_frag=/dev/null
1501 NS_OBJ=
1502 NS_OBJC_OBJ=
1503 NS_SUPPORT=
1504 if test "${HAVE_NS}" = yes; then
1505   window_system=nextstep
1506   with_xft=no
1507   # set up packaging dirs
1508   exec_prefix=${ns_appbindir}
1509   libexecdir=${ns_appbindir}/libexec
1510   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1511      prefix=${ns_appresdir}
1512   fi
1513   ns_frag=$srcdir/src/ns.mk
1514   NS_OBJ="fontset.o fringe.o image.o"
1515   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1516   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1517 fi
1518 CFLAGS="$tmp_CFLAGS"
1519 CPPFLAGS="$tmp_CPPFLAGS"
1520 AC_SUBST(NS_OBJ)
1521 AC_SUBST(NS_OBJC_OBJ)
1522 AC_SUBST(NS_SUPPORT)
1523 AC_SUBST(LIB_STANDARD)
1524 AC_SUBST_FILE(ns_frag)
1525
1526 case "${window_system}" in
1527   x11 )
1528     HAVE_X_WINDOWS=yes
1529     HAVE_X11=yes
1530     case "${with_x_toolkit}" in
1531       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1532       motif ) USE_X_TOOLKIT=MOTIF ;;
1533       gtk ) with_gtk=yes
1534 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1535 dnl USE_X_TOOLKIT is set.
1536             USE_X_TOOLKIT=none ;;
1537       gtk3 ) with_gtk3=yes
1538              USE_X_TOOLKIT=none ;;
1539       no ) USE_X_TOOLKIT=none ;;
1540 dnl If user did not say whether to use a toolkit, make this decision later:
1541 dnl use the toolkit if we have gtk, or X11R5 or newer.
1542       * ) USE_X_TOOLKIT=maybe ;;
1543     esac
1544   ;;
1545   nextstep | none )
1546     HAVE_X_WINDOWS=no
1547     HAVE_X11=no
1548     USE_X_TOOLKIT=none
1549   ;;
1550 esac
1551
1552 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1553    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1554    if test "$HAVE_XSERVER" = true ||
1555       test -n "$DISPLAY" ||
1556       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1557         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1558 were found.  You should install the relevant development files for X
1559 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1560 sure you have development files for image handling, i.e.
1561 tiff, gif, jpeg, png and xpm.
1562 If you are sure you want Emacs compiled without X window support, pass
1563   --without-x
1564 to configure.])
1565    fi
1566 fi
1567
1568 ### If we're using X11, we should use the X menu package.
1569 HAVE_MENUS=no
1570 case ${HAVE_X11} in
1571   yes ) HAVE_MENUS=yes ;;
1572 esac
1573
1574 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1575 # Assume not, until told otherwise.
1576 GNU_MALLOC=yes
1577 doug_lea_malloc=yes
1578 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1579 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1580 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1581                emacs_cv_var___after_morecore_hook,
1582 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1583   emacs_cv_var___after_morecore_hook=yes,
1584   emacs_cv_var___after_morecore_hook=no)])
1585 if test $emacs_cv_var___after_morecore_hook = no; then
1586   doug_lea_malloc=no
1587 fi
1588
1589
1590 dnl See comments in aix4-2.h about maybe using system malloc there.
1591 system_malloc=no
1592 case "$opsys" in
1593   ## darwin ld insists on the use of malloc routines in the System framework.
1594   darwin|sol2-10) system_malloc=yes ;;
1595 esac
1596
1597 if test "${system_malloc}" = "yes"; then
1598   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1599   GNU_MALLOC=no
1600   GNU_MALLOC_reason="
1601     (The GNU allocators don't work with this system configuration.)"
1602   GMALLOC_OBJ=
1603   VMLIMIT_OBJ=
1604 else
1605   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1606   VMLIMIT_OBJ=vm-limit.o
1607 fi
1608 AC_SUBST(GMALLOC_OBJ)
1609 AC_SUBST(VMLIMIT_OBJ)
1610
1611 if test "$doug_lea_malloc" = "yes" ; then
1612   if test "$GNU_MALLOC" = yes ; then
1613     GNU_MALLOC_reason="
1614       (Using Doug Lea's new malloc from the GNU C Library.)"
1615   fi
1616   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1617             [Define to 1 if you are using the GNU C Library.])
1618
1619   ## Use mmap directly for allocating larger buffers.
1620   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1621   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1622   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1623   case "$opsys" in
1624     gnu*) REL_ALLOC=no ;;
1625   esac
1626 fi
1627
1628 if test x"${REL_ALLOC}" = x; then
1629   REL_ALLOC=${GNU_MALLOC}
1630 fi
1631
1632 use_mmap_for_buffers=no
1633 case "$opsys" in
1634   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1635 esac
1636
1637 AC_FUNC_MMAP
1638 if test $use_mmap_for_buffers = yes; then
1639   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1640   REL_ALLOC=no
1641 fi
1642
1643 LIBS="$LIBS_SYSTEM $LIBS"
1644
1645 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1646 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1647 AC_CHECK_LIB(dnet, dnet_ntoa)
1648 dnl This causes -lresolv to get used in subsequent tests,
1649 dnl which causes failures on some systems such as HPUX 9.
1650 dnl AC_CHECK_LIB(resolv, gethostbyname)
1651
1652 dnl FIXME replace main with a function we actually want from this library.
1653 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1654
1655 AC_CHECK_LIB(pthreads, cma_open)
1656
1657 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1658 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1659 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1660 ## added to LIBS in configure would never contain the pthreads part,
1661 ## but the value used in Makefiles might.  FIXME?
1662 ##
1663 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1664 ## be harmless on older versions of X where it happens to exist.
1665 test "$opsys" = "aix4-2" && \
1666   test $ac_cv_lib_pthreads_cma_open = yes && \
1667   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1668
1669 dnl Check for need for bigtoc support on IBM AIX
1670
1671 case ${host_os} in
1672 aix*)
1673   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1674     case $GCC in
1675     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1676     *) gdb_cv_bigtoc=-bbigtoc ;;
1677     esac
1678
1679     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1680     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1681   ])
1682   ;;
1683 esac
1684
1685 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1686 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1687 # REAL_CPPFLAGS later on.
1688
1689 REAL_CFLAGS="$CFLAGS"
1690 REAL_CPPFLAGS="$CPPFLAGS"
1691
1692 if test "${HAVE_X11}" = "yes"; then
1693   DEFS="$C_SWITCH_X_SITE $DEFS"
1694   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1695   LIBS="-lX11 $LIBS"
1696   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1697   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1698
1699   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1700   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1701   # but it's more convenient here to set LD_RUN_PATH
1702   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1703   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1704     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1705     export LD_RUN_PATH
1706   fi
1707
1708   if test "${opsys}" = "gnu-linux"; then
1709     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1710     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1711      [[XOpenDisplay ("foo");]])],
1712      [xlinux_first_failure=no],
1713      [xlinux_first_failure=yes])
1714     if test "${xlinux_first_failure}" = "yes"; then
1715       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1716       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1717       OLD_CPPFLAGS="$CPPFLAGS"
1718       OLD_LIBS="$LIBS"
1719       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1720       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1721       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1722       LIBS="$LIBS -b i486-linuxaout"
1723       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1724        [[XOpenDisplay ("foo");]])],
1725        [xlinux_second_failure=no],
1726        [xlinux_second_failure=yes])
1727       if test "${xlinux_second_failure}" = "yes"; then
1728         # If we get the same failure with -b, there is no use adding -b.
1729         # So take it out.  This plays safe.
1730         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1731         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1732         CPPFLAGS="$OLD_CPPFLAGS"
1733         LIBS="$OLD_LIBS"
1734         AC_MSG_RESULT(no)
1735       else
1736         AC_MSG_RESULT(yes)
1737       fi
1738     else
1739       AC_MSG_RESULT(no)
1740     fi
1741   fi
1742
1743   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1744   # header files included from there.
1745   AC_MSG_CHECKING(for Xkb)
1746   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1747 #include <X11/XKBlib.h>]],
1748         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1749         emacs_xkb=yes, emacs_xkb=no)
1750   AC_MSG_RESULT($emacs_xkb)
1751   if test $emacs_xkb = yes; then
1752     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1753   fi
1754
1755   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1756 XScreenNumberOfScreen XSetWMProtocols)
1757 fi
1758
1759 if test "${window_system}" = "x11"; then
1760   AC_MSG_CHECKING(X11 version 6)
1761   AC_CACHE_VAL(emacs_cv_x11_version_6,
1762   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1763 [[#if XlibSpecificationRelease < 6
1764 fail;
1765 #endif
1766 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1767   if test $emacs_cv_x11_version_6 = yes; then
1768     AC_MSG_RESULT(6 or newer)
1769     AC_DEFINE(HAVE_X11R6, 1,
1770               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1771     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1772     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1773     ## XIM support.
1774     case "$opsys" in
1775       sol2-*) : ;;
1776       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1777            [Define if you have usable X11R6-style XIM support.])
1778          ;;
1779     esac
1780   else
1781     AC_MSG_RESULT(before 6)
1782   fi
1783 fi
1784
1785
1786 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1787 HAVE_RSVG=no
1788 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1789   if test "${with_rsvg}" != "no"; then
1790     RSVG_REQUIRED=2.11.0
1791     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1792
1793     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1794     AC_SUBST(RSVG_CFLAGS)
1795     AC_SUBST(RSVG_LIBS)
1796
1797     if test $HAVE_RSVG = yes; then
1798       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1799       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1800       LIBS="$RSVG_LIBS $LIBS"
1801     fi
1802   fi
1803 fi
1804
1805 HAVE_IMAGEMAGICK=no
1806 if test "${HAVE_X11}" = "yes"; then
1807   if test "${with_imagemagick}" != "no"; then
1808     ## 6.2.8 is the earliest version known to work, but earlier versions
1809     ## might work - let us know if you find one.
1810     ## 6.0.7 does not work.  See bug#7955.
1811     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1812     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1813     AC_SUBST(IMAGEMAGICK_CFLAGS)
1814     AC_SUBST(IMAGEMAGICK_LIBS)
1815
1816     if test $HAVE_IMAGEMAGICK = yes; then
1817       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1818       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1819       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1820       AC_CHECK_FUNCS(MagickExportImagePixels)
1821     fi
1822   fi
1823 fi
1824
1825
1826 HAVE_GTK=no
1827 if test "${with_gtk3}" = "yes"; then
1828   GLIB_REQUIRED=2.28
1829   GTK_REQUIRED=3.0
1830   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1831
1832   dnl Checks for libraries.
1833   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1834   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1835      AC_MSG_ERROR($GTK_PKG_ERRORS)
1836   fi
1837   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1838 fi
1839
1840 if test "$pkg_check_gtk" != "yes"; then
1841   HAVE_GTK=no
1842 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1843   GLIB_REQUIRED=2.6
1844   GTK_REQUIRED=2.6
1845   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1846
1847   dnl Checks for libraries.
1848   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1849   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1850      AC_MSG_ERROR($GTK_PKG_ERRORS)
1851   fi
1852 fi
1853 fi
1854
1855 GTK_OBJ=
1856 if test x"$pkg_check_gtk" = xyes; then
1857
1858   AC_SUBST(GTK_CFLAGS)
1859   AC_SUBST(GTK_LIBS)
1860   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1861   CFLAGS="$CFLAGS $GTK_CFLAGS"
1862   LIBS="$GTK_LIBS $LIBS"
1863   dnl Try to compile a simple GTK program.
1864   GTK_COMPILES=no
1865   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1866   if test "${GTK_COMPILES}" != "yes"; then
1867     if test "$USE_X_TOOLKIT" != "maybe"; then
1868       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1869     fi
1870   else
1871     HAVE_GTK=yes
1872     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1873     GTK_OBJ=gtkutil.o
1874     USE_X_TOOLKIT=none
1875     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1876       :
1877     else
1878       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1879        closing open displays.  This is no problem if you just use
1880        one display, but if you use more than one and close one of them
1881        Emacs may crash.]])
1882       sleep 3
1883     fi
1884   fi
1885
1886 fi
1887 AC_SUBST(GTK_OBJ)
1888
1889
1890 if test "${HAVE_GTK}" = "yes"; then
1891
1892   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1893   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1894   if test "$with_toolkit_scroll_bars" != no; then
1895     with_toolkit_scroll_bars=yes
1896   fi
1897
1898   dnl  Check if we have the old file selection dialog declared and
1899   dnl  in the link library.  In 2.x it may be in the library,
1900   dnl  but not declared if deprecated featured has been selected out.
1901   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1902   HAVE_GTK_FILE_SELECTION=no
1903   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1904                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1905 #include <gtk/gtk.h>])
1906   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1907     AC_CHECK_FUNCS(gtk_file_selection_new)
1908   fi
1909
1910   dnl Check if pthreads are available.  Emacs only needs this when using
1911   dnl gtk_file_chooser under Gnome.
1912     HAVE_GTK_AND_PTHREAD=no
1913     AC_CHECK_HEADERS(pthread.h)
1914     if test "$ac_cv_header_pthread_h"; then
1915       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1916     fi
1917     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1918       case "${canonical}" in
1919         *-hpux*) ;;
1920         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1921       esac
1922       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1923                [Define to 1 if you have GTK and pthread (-lpthread).])
1924     fi
1925
1926   dnl Check for functions introduced in 2.14 and later.
1927   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1928                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1929                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1930                  gtk_orientable_set_orientation)
1931
1932 fi
1933
1934 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1935 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1936 dnl also not configured.
1937 HAVE_DBUS=no
1938 DBUS_OBJ=
1939 if test "${with_dbus}" = "yes"; then
1940    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1941    if test "$HAVE_DBUS" = yes; then
1942      LIBS="$LIBS $DBUS_LIBS"
1943      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1944      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1945      DBUS_OBJ=dbusbind.o
1946    fi
1947 fi
1948 AC_SUBST(DBUS_OBJ)
1949
1950 dnl GConf has been tested under GNU/Linux only.
1951 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1952 HAVE_GCONF=no
1953 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1954    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1955    if test "$HAVE_GCONF" = yes; then
1956       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1957       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1958       AC_CHECK_FUNCS([g_type_init])
1959    fi
1960 fi
1961
1962 dnl SELinux is available for GNU/Linux only.
1963 HAVE_LIBSELINUX=no
1964 LIBSELINUX_LIBS=
1965 if test "${with_selinux}" = "yes"; then
1966    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1967    if test "$HAVE_LIBSELINUX" = yes; then
1968       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1969       LIBSELINUX_LIBS=-lselinux
1970    fi
1971 fi
1972 AC_SUBST(LIBSELINUX_LIBS)
1973
1974 HAVE_GNUTLS=no
1975 if test "${with_gnutls}" = "yes" ; then
1976   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1977   if test "${HAVE_GNUTLS}" = "yes"; then
1978     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1979   fi
1980 fi
1981 AC_SUBST(LIBGNUTLS_LIBS)
1982 AC_SUBST(LIBGNUTLS_CFLAGS)
1983
1984 dnl Do not put whitespace before the #include statements below.
1985 dnl Older compilers (eg sunos4 cc) choke on it.
1986 HAVE_XAW3D=no
1987 LUCID_LIBW=
1988 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1989   if test "$with_xaw3d" != no; then
1990     AC_MSG_CHECKING(for xaw3d)
1991     AC_CACHE_VAL(emacs_cv_xaw3d,
1992     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1993 #include <X11/Intrinsic.h>
1994 #include <X11/Xaw3d/Simple.h>]],
1995       [[]])],
1996       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
1997                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
1998       emacs_cv_xaw3d=no)])
1999   else
2000     emacs_cv_xaw3d=no
2001   fi
2002   if test $emacs_cv_xaw3d = yes; then
2003     AC_MSG_RESULT([yes; using Lucid toolkit])
2004     USE_X_TOOLKIT=LUCID
2005     HAVE_XAW3D=yes
2006     LUCID_LIBW=-lXaw3d
2007     AC_DEFINE(HAVE_XAW3D, 1,
2008               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2009   else
2010     AC_MSG_RESULT(no)
2011     AC_MSG_CHECKING(for libXaw)
2012     AC_CACHE_VAL(emacs_cv_xaw,
2013     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2014 #include <X11/Intrinsic.h>
2015 #include <X11/Xaw/Simple.h>]],
2016       [[]])],
2017       emacs_cv_xaw=yes,
2018       emacs_cv_xaw=no)])
2019     if test $emacs_cv_xaw = yes; then
2020       AC_MSG_RESULT([yes; using Lucid toolkit])
2021       USE_X_TOOLKIT=LUCID
2022       LUCID_LIBW=-lXaw
2023     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2024       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2025     else
2026       AC_MSG_RESULT([no; do not use toolkit by default])
2027       USE_X_TOOLKIT=none
2028     fi
2029   fi
2030 fi
2031
2032 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2033
2034 LIBXTR6=
2035 if test "${USE_X_TOOLKIT}" != "none"; then
2036   AC_MSG_CHECKING(X11 toolkit version)
2037   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2038   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2039 [[#if XtSpecificationRelease < 6
2040 fail;
2041 #endif
2042 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2043   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2044   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2045     AC_MSG_RESULT(6 or newer)
2046     AC_DEFINE(HAVE_X11XTR6, 1,
2047               [Define to 1 if you have the X11R6 or newer version of Xt.])
2048     LIBXTR6="-lSM -lICE"
2049     case "$opsys" in
2050       ## Use libw.a along with X11R6 Xt.
2051       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2052     esac
2053   else
2054     AC_MSG_RESULT(before 6)
2055   fi
2056
2057 dnl If using toolkit, check whether libXmu.a exists.
2058 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2059   OLDLIBS="$LIBS"
2060   if test x$HAVE_X11XTR6 = xyes; then
2061     LIBS="-lXt -lSM -lICE $LIBS"
2062   else
2063     LIBS="-lXt $LIBS"
2064   fi
2065   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2066   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2067 fi
2068 AC_SUBST(LIBXTR6)
2069
2070 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2071 dnl Why not just test for libxmu in the normal way?
2072 LIBXMU=-lXmu
2073 case $opsys in
2074   ## These systems don't supply Xmu.
2075   hpux* | aix4-2 )
2076     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2077     ;;
2078 esac
2079 AC_SUBST(LIBXMU)
2080
2081 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2082 if test "${HAVE_X11}" = "yes"; then
2083   if test "${USE_X_TOOLKIT}" != "none"; then
2084     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2085   fi
2086 fi
2087
2088 LIBXP=
2089 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2090   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2091   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2092     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2093 int x = 5;
2094 #else
2095 Motif version prior to 2.1.
2096 #endif]])],
2097     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2098   if test $emacs_cv_motif_version_2_1 = yes; then
2099     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2100   else
2101     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2102     # We put this in CFLAGS temporarily to precede other -I options
2103     # that might be in CFLAGS temporarily.
2104     # We put this in CPPFLAGS where it precedes the other -I options.
2105     OLD_CPPFLAGS=$CPPFLAGS
2106     OLD_CFLAGS=$CFLAGS
2107     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2108     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2109     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2110       [[int x = 5;]])],
2111       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2112     if test $emacs_cv_lesstif = yes; then
2113       # Make sure this -I option remains in CPPFLAGS after it is set
2114       # back to REAL_CPPFLAGS.
2115       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2116       # have those other -I options anyway.  Ultimately, having this
2117       # directory ultimately in CPPFLAGS will be enough.
2118       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2119       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2120     else
2121       CFLAGS=$OLD_CFLAGS
2122       CPPFLAGS=$OLD_CPPFLAGS
2123     fi
2124   fi
2125 fi
2126
2127 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2128 dnl using Motif or Xaw3d is available, and unless
2129 dnl --with-toolkit-scroll-bars=no was specified.
2130
2131 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2132             [Define to 1 if we should use toolkit scroll bars.])dnl
2133 USE_TOOLKIT_SCROLL_BARS=no
2134 if test "${with_toolkit_scroll_bars}" != "no"; then
2135   if test "${USE_X_TOOLKIT}" != "none"; then
2136     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2137       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2138       HAVE_XAW3D=no
2139       USE_TOOLKIT_SCROLL_BARS=yes
2140     elif test "${HAVE_XAW3D}" = "yes"; then
2141       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2142       USE_TOOLKIT_SCROLL_BARS=yes
2143     fi
2144   elif test "${HAVE_GTK}" = "yes"; then
2145     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2146     USE_TOOLKIT_SCROLL_BARS=yes
2147   elif test "${HAVE_NS}" = "yes"; then
2148     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2149     USE_TOOLKIT_SCROLL_BARS=yes
2150   fi
2151 fi
2152
2153 dnl See if XIM is available.
2154 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2155           #include <X11/Xlib.h>
2156           #include <X11/Xresource.h>]],
2157          [[XIMProc  callback;]])],
2158          [HAVE_XIM=yes
2159          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2160          HAVE_XIM=no)
2161
2162 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2163
2164 if test "${with_xim}" != "no"; then
2165   AC_DEFINE(USE_XIM, 1,
2166             [Define to 1 if we should use XIM, if it is available.])
2167 fi
2168
2169
2170 if test "${HAVE_XIM}" != "no"; then
2171   late_CFLAGS=$CFLAGS
2172   if test "$GCC" = yes; then
2173     CFLAGS="$CFLAGS --pedantic-errors"
2174   fi
2175   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2176 #include <X11/Xlib.h>
2177 #include <X11/Xresource.h>]],
2178 [[Display *display;
2179 XrmDatabase db;
2180 char *res_name;
2181 char *res_class;
2182 XIMProc  callback;
2183 XPointer *client_data;
2184 #ifndef __GNUC__
2185 /* If we're not using GCC, it's probably not XFree86, and this is
2186    probably right, but we can't use something like --pedantic-errors.  */
2187 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2188                                            char*, XIMProc, XPointer*);
2189 #endif
2190 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2191    client_data);]])],
2192     [emacs_cv_arg6_star=yes])
2193   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2194          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2195 either XPointer or XPointer*.])dnl
2196   if test "$emacs_cv_arg6_star" = yes; then
2197     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2198   else
2199     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2200   fi
2201   CFLAGS=$late_CFLAGS
2202 fi
2203
2204 ### Start of font-backend (under any platform) section.
2205 # (nothing here yet -- this is a placeholder)
2206 ### End of font-backend (under any platform) section.
2207
2208 ### Start of font-backend (under X11) section.
2209 if test "${HAVE_X11}" = "yes"; then
2210    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2211
2212    ## Use -lXft if available, unless `--with-xft=no'.
2213    HAVE_XFT=maybe
2214     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2215       with_xft="no";
2216     fi
2217     if test "x${with_xft}" != "xno"; then
2218
2219       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2220       ## Because xftfont.c uses XRenderQueryExtension, we also
2221       ## need to link to -lXrender.
2222       HAVE_XRENDER=no
2223       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2224       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2225         OLD_CPPFLAGS="$CPPFLAGS"
2226         OLD_CFLAGS="$CFLAGS"
2227         OLD_LIBS="$LIBS"
2228         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2229         CFLAGS="$CFLAGS $XFT_CFLAGS"
2230         XFT_LIBS="-lXrender $XFT_LIBS"
2231         LIBS="$XFT_LIBS $LIBS"
2232         AC_CHECK_HEADER(X11/Xft/Xft.h,
2233           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2234
2235         if test "${HAVE_XFT}" = "yes"; then
2236           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2237             AC_SUBST(XFT_LIBS)
2238           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2239         else
2240           CPPFLAGS="$OLD_CPPFLAGS"
2241           CFLAGS="$OLD_CFLAGS"
2242           LIBS="$OLD_LIBS"
2243         fi                        # "${HAVE_XFT}" = "yes"
2244       fi                          # "$HAVE_XFT" != no
2245     fi                            # "x${with_xft}" != "xno"
2246
2247     ## We used to allow building with FreeType and without Xft.
2248     ## However, the ftx font backend driver is not in good shape.
2249     if test "$HAVE_XFT" != "yes"; then
2250        dnl For the "Does Emacs use" message at the end.
2251        HAVE_XFT=no
2252        HAVE_FREETYPE=no
2253     else
2254        dnl Strict linkers fail with
2255        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2256        dnl if -lfreetype is not specified.
2257        dnl The following is needed to set FREETYPE_LIBS.
2258        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2259                          HAVE_FREETYPE=no)
2260
2261        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2262     fi
2263
2264     HAVE_LIBOTF=no
2265     if test "${HAVE_FREETYPE}" = "yes"; then
2266       AC_DEFINE(HAVE_FREETYPE, 1,
2267                 [Define to 1 if using the freetype and fontconfig libraries.])
2268       if test "${with_libotf}" != "no"; then
2269         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2270                           HAVE_LIBOTF=no)
2271         if test "$HAVE_LIBOTF" = "yes"; then
2272           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2273           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2274                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2275                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2276           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2277             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2278                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2279           fi
2280         fi
2281       fi
2282     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2283     dnl Does the new font backend require it, or can it work without it?
2284     fi
2285
2286     HAVE_M17N_FLT=no
2287     if test "${HAVE_LIBOTF}" = yes; then
2288       if test "${with_m17n_flt}" != "no"; then
2289         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2290         if test "$HAVE_M17N_FLT" = "yes"; then
2291           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2292         fi
2293       fi
2294     fi
2295 else
2296     HAVE_XFT=no
2297     HAVE_FREETYPE=no
2298     HAVE_LIBOTF=no
2299     HAVE_M17N_FLT=no
2300 fi
2301
2302 ### End of font-backend (under X11) section.
2303
2304 AC_SUBST(FREETYPE_CFLAGS)
2305 AC_SUBST(FREETYPE_LIBS)
2306 AC_SUBST(FONTCONFIG_CFLAGS)
2307 AC_SUBST(FONTCONFIG_LIBS)
2308 AC_SUBST(LIBOTF_CFLAGS)
2309 AC_SUBST(LIBOTF_LIBS)
2310 AC_SUBST(M17N_FLT_CFLAGS)
2311 AC_SUBST(M17N_FLT_LIBS)
2312
2313 ### Use -lXpm if available, unless `--with-xpm=no'.
2314 HAVE_XPM=no
2315 LIBXPM=
2316 if test "${HAVE_X11}" = "yes"; then
2317   if test "${with_xpm}" != "no"; then
2318     AC_CHECK_HEADER(X11/xpm.h,
2319       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2320     if test "${HAVE_XPM}" = "yes"; then
2321       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2322       AC_EGREP_CPP(no_return_alloc_pixels,
2323       [#include "X11/xpm.h"
2324 #ifndef XpmReturnAllocPixels
2325 no_return_alloc_pixels
2326 #endif
2327       ], HAVE_XPM=no, HAVE_XPM=yes)
2328
2329       if test "${HAVE_XPM}" = "yes"; then
2330         AC_MSG_RESULT(yes)
2331       else
2332         AC_MSG_RESULT(no)
2333       fi
2334     fi
2335   fi
2336
2337   if test "${HAVE_XPM}" = "yes"; then
2338     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2339     LIBXPM=-lXpm
2340   fi
2341 fi
2342 AC_SUBST(LIBXPM)
2343
2344 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2345 HAVE_JPEG=no
2346 LIBJPEG=
2347 if test "${HAVE_X11}" = "yes"; then
2348   if test "${with_jpeg}" != "no"; then
2349     dnl Checking for jpeglib.h can lose because of a redefinition of
2350     dnl  HAVE_STDLIB_H.
2351     AC_CHECK_HEADER(jerror.h,
2352       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2353   fi
2354
2355   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2356   if test "${HAVE_JPEG}" = "yes"; then
2357     AC_DEFINE(HAVE_JPEG)
2358     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2359         [#include <jpeglib.h>
2360          version=JPEG_LIB_VERSION
2361 ],
2362         [AC_DEFINE(HAVE_JPEG)],
2363         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2364         HAVE_JPEG=no])
2365   fi
2366   if test "${HAVE_JPEG}" = "yes"; then
2367     LIBJPEG=-ljpeg
2368   fi
2369 fi
2370 AC_SUBST(LIBJPEG)
2371
2372 ### Use -lpng if available, unless `--with-png=no'.
2373 HAVE_PNG=no
2374 LIBPNG=
2375 if test "${HAVE_X11}" = "yes"; then
2376   if test "${with_png}" != "no"; then
2377     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2378     # in /usr/include/libpng.
2379     AC_CHECK_HEADERS(png.h libpng/png.h)
2380     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2381       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2382     fi
2383   fi
2384
2385   if test "${HAVE_PNG}" = "yes"; then
2386     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2387     LIBPNG="-lpng -lz -lm"
2388   fi
2389 fi
2390 AC_SUBST(LIBPNG)
2391
2392 ### Use -ltiff if available, unless `--with-tiff=no'.
2393 HAVE_TIFF=no
2394 LIBTIFF=
2395 if test "${HAVE_X11}" = "yes"; then
2396   if test "${with_tiff}" != "no"; then
2397     AC_CHECK_HEADER(tiffio.h,
2398       [tifflibs="-lz -lm"
2399       # At least one tiff package requires the jpeg library.
2400       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2401       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2402   fi
2403
2404   if test "${HAVE_TIFF}" = "yes"; then
2405     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2406     dnl FIXME -lz -lm, as per libpng?
2407     LIBTIFF=-ltiff
2408   fi
2409 fi
2410 AC_SUBST(LIBTIFF)
2411
2412 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2413 HAVE_GIF=no
2414 LIBGIF=
2415 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2416   AC_CHECK_HEADER(gif_lib.h,
2417 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2418 # Earlier versions can crash Emacs.
2419     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2420
2421   if test "$HAVE_GIF" = yes; then
2422     LIBGIF=-lgif
2423   elif test "$HAVE_GIF" = maybe; then
2424 # If gif_lib.h but no libgif, try libungif.
2425     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2426     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2427   fi
2428
2429   if test "${HAVE_GIF}" = "yes"; then
2430     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2431   fi
2432 fi
2433 AC_SUBST(LIBGIF)
2434
2435 dnl Check for required libraries.
2436 if test "${HAVE_X11}" = "yes"; then
2437   MISSING=""
2438   WITH_NO=""
2439   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2440     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2441   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2442     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2443   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2444     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2445   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2446     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2447   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2448     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2449
2450   if test "X${MISSING}" != X; then
2451     AC_MSG_ERROR([The following required libraries were not found:
2452     $MISSING
2453 Maybe some development libraries/packages are missing?
2454 If you don't want to link with them give
2455     $WITH_NO
2456 as options to configure])
2457   fi
2458 fi
2459
2460 ### Use -lgpm if available, unless `--with-gpm=no'.
2461 HAVE_GPM=no
2462 LIBGPM=
2463 MOUSE_SUPPORT=
2464 if test "${with_gpm}" != "no"; then
2465   AC_CHECK_HEADER(gpm.h,
2466     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2467
2468   if test "${HAVE_GPM}" = "yes"; then
2469     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2470     LIBGPM=-lgpm
2471     ## May be reset below.
2472     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2473   fi
2474 fi
2475 AC_SUBST(LIBGPM)
2476
2477 dnl Check for malloc/malloc.h on darwin
2478 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2479
2480 C_SWITCH_X_SYSTEM=
2481 ### Use NeXTstep API to implement GUI.
2482 if test "${HAVE_NS}" = "yes"; then
2483   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2484   if test "${NS_IMPL_COCOA}" = "yes"; then
2485     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2486     GNU_OBJC_CFLAGS=
2487   fi
2488   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2489     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2490     # See also .m.o rule in Makefile.in */
2491     # FIXME: are all these flags really needed?  Document here why.  */
2492     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2493     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2494   fi
2495   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2496     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2497   fi
2498   # We also have mouse menus.
2499   HAVE_MENUS=yes
2500   OTHER_FILES=ns-app
2501 fi
2502
2503
2504 ### Use session management (-lSM -lICE) if available
2505 HAVE_X_SM=no
2506 LIBXSM=
2507 if test "${HAVE_X11}" = "yes"; then
2508   AC_CHECK_HEADER(X11/SM/SMlib.h,
2509     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2510
2511   if test "${HAVE_X_SM}" = "yes"; then
2512     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2513     LIBXSM="-lSM -lICE"
2514     case "$LIBS" in
2515       *-lSM*) ;;
2516       *)      LIBS="$LIBXSM $LIBS" ;;
2517     esac
2518   fi
2519 fi
2520 AC_SUBST(LIBXSM)
2521
2522 ### Use libxml (-lxml2) if available
2523 if test "${with_xml2}" != "no"; then
2524   ### I'm not sure what the version number should be, so I just guessed.
2525   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2526   if test "${HAVE_LIBXML2}" = "yes"; then
2527     LIBS="$LIBXML2_LIBS $LIBS"
2528     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2529     if test "${HAVE_LIBXML2}" = "yes"; then
2530       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2531     else
2532       LIBXML2_LIBS=""
2533       LIBXML2_CFLAGS=""
2534     fi
2535   fi
2536 fi
2537 AC_SUBST(LIBXML2_LIBS)
2538 AC_SUBST(LIBXML2_CFLAGS)
2539
2540 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2541 AC_CACHE_CHECK(whether netdb declares h_errno,
2542                emacs_cv_netdb_declares_h_errno,
2543 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2544   [[return h_errno;]])],
2545   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2546 if test $emacs_cv_netdb_declares_h_errno = yes; then
2547   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2548 fi
2549
2550 AC_FUNC_ALLOCA
2551
2552 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2553 dnl FIXME is there an autoconf test that does the right thing, without
2554 dnl needing to call A_M_E afterwards?
2555 if test x"$ac_cv_func_alloca_works" != xyes; then
2556    AC_MSG_ERROR( [a system implementation of alloca is required] )
2557 fi
2558
2559 # fmod, logb, and frexp are found in -lm on most systems.
2560 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2561 AC_CHECK_LIB(m, sqrt)
2562
2563 # Check for mail-locking functions in a "mail" library.  Probably this should
2564 # have the same check as for liblockfile below.
2565 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2566 if test $have_mail = yes; then
2567   LIBS_MAIL=-lmail
2568   LIBS="$LIBS_MAIL $LIBS"
2569   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2570 else
2571   LIBS_MAIL=
2572 fi
2573 dnl Debian, at least:
2574 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2575 if test $have_lockfile = yes; then
2576    LIBS_MAIL=-llockfile
2577    LIBS="$LIBS_MAIL $LIBS"
2578    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2579 else
2580 # If we have the shared liblockfile, assume we must use it for mail
2581 # locking (e.g. Debian).  If we couldn't link against liblockfile
2582 # (no liblockfile.a installed), ensure that we don't need to.
2583   dnl This works for files generally, not just executables.
2584   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2585   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2586                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2587   if test $ac_cv_prog_liblockfile = yes; then
2588     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2589 This probably means that movemail could lose mail.
2590 There may be a `development' package to install containing liblockfile.])
2591   fi
2592 fi
2593 AC_CHECK_FUNCS(touchlock)
2594 AC_CHECK_HEADERS(maillock.h)
2595 AC_SUBST(LIBS_MAIL)
2596
2597 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2598 ## interlock access to the mail spool.  The alternative is a lock file named
2599 ## /usr/spool/mail/$USER.lock.
2600 mail_lock=no
2601 case "$opsys" in
2602   aix4-2) mail_lock="lockf" ;;
2603
2604   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2605
2606   ## On GNU/Linux systems, both methods are used by various mail programs.
2607   ## I assume most people are using newer mailers that have heard of flock.
2608   ## Change this if you need to.
2609   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2610   ## configure gets the right answers, and that means *NOT* using flock.
2611   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2612   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2613   ## Debian maintainer hasn't provided a clean fix for Emacs.
2614   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2615   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2616   ## correct logic.  -- fx
2617   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2618   ## liblockfile is a Free Software replacement for libmail, used on
2619   ## Debian systems and elsewhere. -rfr.
2620   gnu-*)
2621     mail_lock="flock"
2622     if test $have_mail = yes || test $have_lockfile = yes; then
2623       test $ac_cv_header_maillock_h = yes && mail_lock=no
2624     fi
2625     ;;
2626 esac
2627
2628 BLESSMAIL_TARGET=
2629 case "$mail_lock" in
2630   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2631
2632   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2633
2634   *) BLESSMAIL_TARGET="need-blessmail" ;;
2635 esac
2636 AC_SUBST(BLESSMAIL_TARGET)
2637
2638
2639 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2640 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2641 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2642 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2643 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2644 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2645 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2646 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2647 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2648 cfmakeraw cfsetspeed isnan copysign __executable_start)
2649
2650 dnl Cannot use AC_CHECK_FUNCS
2651 AC_CACHE_CHECK([for __builtin_unwind_init],
2652                emacs_cv_func___builtin_unwind_init,
2653 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2654                 emacs_cv_func___builtin_unwind_init=yes,
2655                 emacs_cv_func___builtin_unwind_init=no)])
2656 if test $emacs_cv_func___builtin_unwind_init = yes; then
2657   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2658             [Define to 1 if you have the `__builtin_unwind_init' function.])
2659 fi
2660
2661 AC_CHECK_HEADERS(sys/un.h)
2662
2663 AC_FUNC_FSEEKO
2664
2665 AC_FUNC_GETPGRP
2666
2667 # Configure gnulib.
2668 gl_ASSERT_NO_GNULIB_POSIXCHECK
2669 gl_ASSERT_NO_GNULIB_TESTS
2670 gl_INIT
2671
2672 # UNIX98 PTYs.
2673 AC_CHECK_FUNCS(grantpt)
2674
2675 # PTY-related GNU extensions.
2676 AC_CHECK_FUNCS(getpt)
2677
2678 # Check this now, so that we will NOT find the above functions in ncurses.
2679 # That is because we have not set up to link ncurses in lib-src.
2680 # It's better to believe a function is not available
2681 # than to expect to find it in ncurses.
2682 # Also we need tputs and friends to be able to build at all.
2683 have_tputs_et_al=true
2684 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2685 if test "$have_tputs_et_al" != true; then
2686   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2687 Maybe some development libraries/packages are missing?  Try installing
2688 libncurses-dev(el), libterminfo-dev(el) or similar.])
2689 fi
2690 # Must define this when any termcap library is found.
2691 AC_DEFINE(HAVE_LIBNCURSES, 1,
2692           [Define to 1 if you have the `ncurses' library (-lncurses).])
2693 ## FIXME This was the cpp logic, but I am not sure it is right.
2694 ## The above test has not necessarily found libncurses.
2695 HAVE_LIBNCURSES=yes
2696
2697 ## Use terminfo instead of termcap?
2698 ## Note only system files NOT using terminfo are:
2699 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2700 ## darwin|gnu without ncurses.
2701 TERMINFO=no
2702 LIBS_TERMCAP=
2703 case "$opsys" in
2704   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2705   ## hpux10-20: Use the system provided termcap(3) library.
2706   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2707   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2708   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2709
2710   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2711   ##  The ncurses library has been moved out of the System framework in
2712   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2713   ##  option to use it.
2714   darwin|gnu*)
2715     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2716     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2717       TERMINFO=yes
2718       LIBS_TERMCAP="-lncurses"
2719     fi
2720     ;;
2721
2722   freebsd)
2723     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2724     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2725     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2726 [[#if __FreeBSD_version < 400000
2727 fail;
2728 #endif
2729 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2730
2731     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2732
2733     if test $emacs_cv_freebsd_terminfo = yes; then
2734       TERMINFO=yes
2735       LIBS_TERMCAP="-lncurses"
2736     else
2737       LIBS_TERMCAP="-ltermcap"
2738     fi
2739     ;;
2740
2741   netbsd)
2742     if test $ac_cv_search_tputs = -lterminfo; then
2743       TERMINFO=yes
2744       LIBS_TERMCAP="-lterminfo"
2745     else
2746       LIBS_TERMCAP="-ltermcap"
2747     fi
2748     ;;
2749
2750 esac
2751
2752 case "$opsys" in
2753   ## hpux: Make sure we get select from libc rather than from libcurses
2754   ##  because libcurses on HPUX 10.10 has a broken version of select.
2755   ##  We used to use -lc -lcurses, but this may be cleaner.
2756   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2757
2758   openbsd) LIBS_TERMCAP="-lncurses" ;;
2759
2760   ## Must use system termcap, if we use any termcap.  It does special things.
2761   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2762 esac
2763
2764 TERMCAP_OBJ=tparam.o
2765 if test $TERMINFO = yes; then
2766   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2767
2768   ## Default used to be -ltermcap.  Add a case above if need something else.
2769   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2770
2771   TERMCAP_OBJ=terminfo.o
2772 fi
2773 AC_SUBST(LIBS_TERMCAP)
2774 AC_SUBST(TERMCAP_OBJ)
2775
2776
2777 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2778 resolv=no
2779 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2780 #include <arpa/nameser.h>
2781 #include <resolv.h>]],
2782     [[return res_init();]])],
2783     have_res_init=yes, have_res_init=no)
2784 if test "$have_res_init" = no; then
2785   OLIBS="$LIBS"
2786   LIBS="$LIBS -lresolv"
2787   AC_MSG_CHECKING(for res_init with -lresolv)
2788   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2789 #include <arpa/nameser.h>
2790 #include <resolv.h>]],
2791     [[return res_init();]])],
2792     have_res_init=yes, have_res_init=no)
2793   AC_MSG_RESULT($have_res_init)
2794   if test "$have_res_init" = yes ; then
2795     resolv=yes
2796   fi
2797   LIBS="$OLIBS"
2798 fi
2799
2800 if test "$have_res_init" = yes; then
2801   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2802 fi
2803
2804 # Do we need the Hesiod library to provide the support routines?
2805 LIBHESIOD=
2806 if test "$with_hesiod" != no ; then
2807   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2808   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2809      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2810                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2811   if test "$resolv" = yes ; then
2812     RESOLVLIB=-lresolv
2813   else
2814     RESOLVLIB=
2815   fi
2816   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2817         hesiod=yes, :, $RESOLVLIB)])
2818
2819   if test x"$hesiod" = xyes; then
2820     AC_DEFINE(HAVE_LIBHESIOD, 1,
2821               [Define to 1 if you have the hesiod library (-lhesiod).])
2822     LIBHESIOD=-lhesiod
2823   fi
2824 fi
2825 AC_SUBST(LIBHESIOD)
2826
2827 # Do we need libresolv (due to res_init or Hesiod)?
2828 if test "$resolv" = yes ; then
2829   AC_DEFINE(HAVE_LIBRESOLV, 1,
2830             [Define to 1 if you have the resolv library (-lresolv).])
2831   LIBRESOLV=-lresolv
2832 else
2833   LIBRESOLV=
2834 fi
2835 AC_SUBST(LIBRESOLV)
2836
2837 # These tell us which Kerberos-related libraries to use.
2838 COM_ERRLIB=
2839 CRYPTOLIB=
2840 KRB5LIB=
2841 DESLIB=
2842 KRB4LIB=
2843
2844 if test "${with_kerberos}" != no; then
2845   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2846   if test $have_com_err = yes; then
2847     COM_ERRLIB=-lcom_err
2848     LIBS="$COM_ERRLIB $LIBS"
2849     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2850   fi
2851   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2852   if test $have_crypto = yes; then
2853     CRYPTOLIB=-lcrypto
2854     LIBS="$CRYPTOLIB $LIBS"
2855     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2856   fi
2857   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2858   if test $have_k5crypto = yes; then
2859     CRYPTOLIB=-lk5crypto
2860     LIBS="$CRYPTOLIB $LIBS"
2861     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2862   fi
2863   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2864   if test $have_krb5=yes; then
2865     KRB5LIB=-lkrb5
2866     LIBS="$KRB5LIB $LIBS"
2867     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2868   fi
2869   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2870   if test "${with_kerberos5}" = no; then
2871     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2872     if test $have_des425 = yes; then
2873       DESLIB=-ldes425
2874       LIBS="$DESLIB $LIBS"
2875       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2876     else
2877       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2878       if test $have_des = yes; then
2879         DESLIB=-ldes
2880         LIBS="$DESLIB $LIBS"
2881         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2882       fi
2883     fi
2884     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2885     if test $have_krb4 = yes; then
2886       KRB4LIB=-lkrb4
2887       LIBS="$KRB4LIB $LIBS"
2888       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2889     else
2890       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2891       if test $have_krb = yes; then
2892         KRB4LIB=-lkrb
2893         LIBS="$KRB4LIB $LIBS"
2894         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2895       fi
2896     fi
2897   fi
2898
2899   if test "${with_kerberos5}" != no; then
2900     AC_CHECK_HEADERS(krb5.h,
2901       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2902                         [#include <krb5.h>])])
2903   else
2904     AC_CHECK_HEADERS(des.h,,
2905                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2906                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2907     AC_CHECK_HEADERS(krb.h,,
2908                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2909                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2910   fi
2911   AC_CHECK_HEADERS(com_err.h)
2912 fi
2913
2914 AC_SUBST(COM_ERRLIB)
2915 AC_SUBST(CRYPTOLIB)
2916 AC_SUBST(KRB5LIB)
2917 AC_SUBST(DESLIB)
2918 AC_SUBST(KRB4LIB)
2919
2920 # Solaris requires -lintl if you want strerror (which calls dgettext)
2921 # to return localized messages.
2922 AC_CHECK_LIB(intl, dgettext)
2923
2924 AC_MSG_CHECKING(whether localtime caches TZ)
2925 AC_CACHE_VAL(emacs_cv_localtime_cache,
2926 [if test x$ac_cv_func_tzset = xyes; then
2927 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2928 char TZ_GMT0[] = "TZ=GMT0";
2929 char TZ_PST8[] = "TZ=PST8";
2930 main()
2931 {
2932   time_t now = time ((time_t *) 0);
2933   int hour_GMT0, hour_unset;
2934   if (putenv (TZ_GMT0) != 0)
2935     exit (1);
2936   hour_GMT0 = localtime (&now)->tm_hour;
2937   unsetenv("TZ");
2938   hour_unset = localtime (&now)->tm_hour;
2939   if (putenv (TZ_PST8) != 0)
2940     exit (1);
2941   if (localtime (&now)->tm_hour == hour_GMT0)
2942     exit (1);
2943   unsetenv("TZ");
2944   if (localtime (&now)->tm_hour != hour_unset)
2945     exit (1);
2946   exit (0);
2947 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2948 [# If we have tzset, assume the worst when cross-compiling.
2949 emacs_cv_localtime_cache=yes])
2950 else
2951         # If we lack tzset, report that localtime does not cache TZ,
2952         # since we can't invalidate the cache if we don't have tzset.
2953         emacs_cv_localtime_cache=no
2954 fi])dnl
2955 AC_MSG_RESULT($emacs_cv_localtime_cache)
2956 if test $emacs_cv_localtime_cache = yes; then
2957   AC_DEFINE(LOCALTIME_CACHE, 1,
2958             [Define to 1 if localtime caches TZ.])
2959 fi
2960
2961 if test "x$HAVE_TIMEVAL" = xyes; then
2962   AC_CHECK_FUNCS(gettimeofday)
2963   if test $ac_cv_func_gettimeofday = yes; then
2964     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2965                    emacs_cv_gettimeofday_two_arguments,
2966     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2967 #ifdef TIME_WITH_SYS_TIME
2968 #include <sys/time.h>
2969 #include <time.h>
2970 #else
2971 #ifdef HAVE_SYS_TIME_H
2972 #include <sys/time.h>
2973 #else
2974 #include <time.h>
2975 #endif
2976 #endif]],
2977       [[struct timeval time;
2978        gettimeofday (&time, 0);]])],
2979       emacs_cv_gettimeofday_two_arguments=yes,
2980       emacs_cv_gettimeofday_two_arguments=no)])
2981     if test $emacs_cv_gettimeofday_two_arguments = no; then
2982       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2983                 [Define to 1 if gettimeofday accepts only one argument.])
2984     fi
2985   fi
2986 fi
2987
2988 ok_so_far=yes
2989 AC_CHECK_FUNC(socket, , ok_so_far=no)
2990 if test $ok_so_far = yes; then
2991   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2992 fi
2993 if test $ok_so_far = yes; then
2994   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2995 fi
2996 if test $ok_so_far = yes; then
2997 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2998   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2999             [Define to 1 if you have inet sockets.])
3000 fi
3001
3002 if test -f /usr/lpp/X11/bin/smt.exp; then
3003   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3004             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3005 fi
3006
3007 AC_MSG_CHECKING(whether system supports dynamic ptys)
3008 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3009   AC_MSG_RESULT(yes)
3010   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3011 else
3012   AC_MSG_RESULT(no)
3013 fi
3014
3015 AC_FUNC_FORK
3016
3017 dnl Adapted from Haible's version.
3018 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3019   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3020     [[char* cs = nl_langinfo(CODESET);]])],
3021     emacs_cv_langinfo_codeset=yes,
3022     emacs_cv_langinfo_codeset=no)
3023   ])
3024 if test $emacs_cv_langinfo_codeset = yes; then
3025   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3026     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3027 fi
3028
3029 AC_CHECK_TYPES(size_t)
3030
3031 AC_TYPE_MBSTATE_T
3032
3033 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3034   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3035                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3036 if test "$emacs_cv_c_restrict_arr" = yes; then
3037   AC_DEFINE(__restrict_arr, __restrict,
3038     [Define to compiler's equivalent of C99 restrict keyword in array
3039      declarations.  Define as empty for no equivalent.])
3040 fi
3041
3042 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3043 dnl how the tty code is related to POSIX and/or other versions of termios.
3044 dnl The following looks like a useful start.
3045 dnl
3046 dnl AC_SYS_POSIX_TERMIOS
3047 dnl if test $ac_cv_sys_posix_termios = yes; then
3048 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3049 dnl                                and macros for terminal control.])
3050 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3051 dnl fi
3052
3053 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3054
3055 # Set up the CFLAGS for real compilation, so we can substitute it.
3056 CFLAGS="$REAL_CFLAGS"
3057 CPPFLAGS="$REAL_CPPFLAGS"
3058
3059 ## Hack to detect a buggy GCC version.
3060 if test "x$GCC" = xyes \
3061    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3062    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3063    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3064    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3065 fi
3066
3067 version=$PACKAGE_VERSION
3068
3069 ### Specify what sort of things we'll be editing into Makefile and config.h.
3070 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3071 AC_SUBST(version)
3072 AC_SUBST(configuration)
3073 ## Unused?
3074 AC_SUBST(canonical)
3075 AC_SUBST(srcdir)
3076 AC_SUBST(prefix)
3077 AC_SUBST(exec_prefix)
3078 AC_SUBST(bindir)
3079 AC_SUBST(datadir)
3080 AC_SUBST(sharedstatedir)
3081 AC_SUBST(libexecdir)
3082 AC_SUBST(mandir)
3083 AC_SUBST(infodir)
3084 AC_SUBST(lispdir)
3085 AC_SUBST(locallisppath)
3086 AC_SUBST(lisppath)
3087 AC_SUBST(x_default_search_path)
3088 AC_SUBST(etcdir)
3089 AC_SUBST(archlibdir)
3090 AC_SUBST(docdir)
3091 AC_SUBST(bitmapdir)
3092 AC_SUBST(gamedir)
3093 AC_SUBST(gameuser)
3094 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3095 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3096 ## end of LIBX_BASE, but nothing ever set it.
3097 AC_SUBST(LD_SWITCH_X_SITE)
3098 AC_SUBST(C_SWITCH_X_SITE)
3099 AC_SUBST(C_SWITCH_X_SYSTEM)
3100 AC_SUBST(CFLAGS)
3101 ## Used in lwlib/Makefile.in.
3102 AC_SUBST(X_TOOLKIT_TYPE)
3103 if test -n "${machfile}"; then
3104   M_FILE="\$(srcdir)/${machfile}"
3105 else
3106   M_FILE=
3107 fi
3108 S_FILE="\$(srcdir)/${opsysfile}"
3109 AC_SUBST(M_FILE)
3110 AC_SUBST(S_FILE)
3111 AC_SUBST(ns_appdir)
3112 AC_SUBST(ns_appbindir)
3113 AC_SUBST(ns_appresdir)
3114 AC_SUBST(ns_appsrc)
3115 AC_SUBST(GNU_OBJC_CFLAGS)
3116 AC_SUBST(OTHER_FILES)
3117
3118 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3119                    [Define to the canonical Emacs configuration name.])
3120 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3121                    [Define to the options passed to configure.])
3122 if test -n "$machfile"; then
3123   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3124                      [Define to the used machine dependent file.])
3125 fi
3126 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3127                    [Define to the used os dependent file.])
3128
3129 XMENU_OBJ=
3130 XOBJ=
3131 FONT_OBJ=
3132 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3133   AC_DEFINE(HAVE_X_WINDOWS, 1,
3134             [Define to 1 if you want to use the X window system.])
3135   XMENU_OBJ=xmenu.o
3136   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3137   FONT_OBJ=xfont.o
3138   if test "$HAVE_XFT" = "yes"; then
3139     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3140   elif test "$HAVE_FREETYPE" = "yes"; then
3141     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3142   fi
3143   AC_SUBST(FONT_OBJ)
3144 fi
3145 AC_SUBST(XMENU_OBJ)
3146 AC_SUBST(XOBJ)
3147 AC_SUBST(FONT_OBJ)
3148
3149 WIDGET_OBJ=
3150 MOTIF_LIBW=
3151 if test "${USE_X_TOOLKIT}" != "none" ; then
3152   WIDGET_OBJ=widget.o
3153   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3154   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3155     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3156   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3157     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3158     MOTIF_LIBW=-lXm
3159     case "$opsys" in
3160       gnu-linux)
3161         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3162         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3163         ;;
3164
3165       unixware)
3166         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3167         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3168         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3169         ;;
3170
3171       aix4-2)
3172         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3173         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3174         ;;
3175     esac
3176     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3177   fi
3178 fi
3179 AC_SUBST(WIDGET_OBJ)
3180
3181 TOOLKIT_LIBW=
3182 case "$USE_X_TOOLKIT" in
3183   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3184   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3185   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3186 esac
3187 AC_SUBST(TOOLKIT_LIBW)
3188
3189 if test "$USE_X_TOOLKIT" = "none"; then
3190   LIBXT_OTHER="\$(LIBXSM)"
3191   OLDXMENU_TARGET="really-oldXMenu"
3192 else
3193   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3194   OLDXMENU_TARGET="really-lwlib"
3195 fi
3196 AC_SUBST(LIBXT_OTHER)
3197
3198 ## The X Menu stuff is present in the X10 distribution, but missing
3199 ## from X11.  If we have X10, just use the installed library;
3200 ## otherwise, use our own copy.
3201 if test "${HAVE_X11}" = "yes" ; then
3202   AC_DEFINE(HAVE_X11, 1,
3203             [Define to 1 if you want to use version 11 of X windows.
3204              Otherwise, Emacs expects to use version 10.])
3205
3206   if test "$USE_X_TOOLKIT" = "none"; then
3207     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3208   else
3209     OLDXMENU="\${lwlibdir}/liblw.a"
3210   fi
3211   LIBXMENU="\$(OLDXMENU)"
3212   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3213   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3214 else
3215   ## For a syntactically valid Makefile; not actually used for anything.
3216   ## See comments in src/Makefile.in.
3217   OLDXMENU=nothing
3218   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3219   if test "${HAVE_X_WINDOWS}" = "yes"; then
3220     LIBXMENU="-lXMenu"
3221   else
3222     LIBXMENU=
3223   fi
3224   LIBX_OTHER=
3225   OLDXMENU_DEPS=
3226 fi
3227
3228 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3229   OLDXMENU_TARGET=
3230   OLDXMENU=nothing
3231   LIBXMENU=
3232   OLDXMENU_DEPS=
3233 fi
3234
3235 AC_SUBST(OLDXMENU_TARGET)
3236 AC_SUBST(OLDXMENU)
3237 AC_SUBST(LIBXMENU)
3238 AC_SUBST(LIBX_OTHER)
3239 AC_SUBST(OLDXMENU_DEPS)
3240
3241 if test "${HAVE_MENUS}" = "yes" ; then
3242   AC_DEFINE(HAVE_MENUS, 1,
3243             [Define to 1 if you have mouse menus.
3244              (This is automatic if you use X, but the option to specify it remains.)
3245              It is also defined with other window systems that support xmenu.c.])
3246 fi
3247
3248 if test "${GNU_MALLOC}" = "yes" ; then
3249   AC_DEFINE(GNU_MALLOC, 1,
3250             [Define to 1 if you want to use the GNU memory allocator.])
3251 fi
3252
3253 RALLOC_OBJ=
3254 if test "${REL_ALLOC}" = "yes" ; then
3255   AC_DEFINE(REL_ALLOC, 1,
3256             [Define REL_ALLOC if you want to use the relocating allocator for
3257              buffer space.])
3258
3259   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3260 fi
3261 AC_SUBST(RALLOC_OBJ)
3262
3263 if test "$opsys" = "cygwin"; then
3264   CYGWIN_OBJ="sheap.o"
3265   ## Cygwin differs because of its unexec().
3266   PRE_ALLOC_OBJ=
3267   POST_ALLOC_OBJ=lastfile.o
3268 else
3269   CYGWIN_OBJ=
3270   PRE_ALLOC_OBJ=lastfile.o
3271   POST_ALLOC_OBJ=
3272 fi
3273 AC_SUBST(CYGWIN_OBJ)
3274 AC_SUBST(PRE_ALLOC_OBJ)
3275 AC_SUBST(POST_ALLOC_OBJ)
3276
3277
3278 case "$opsys" in
3279   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3280
3281   darwin)
3282    ## The -headerpad option tells ld (see man page) to leave room at the
3283    ## end of the header for adding load commands.  Needed for dumping.
3284    ## 0x690 is the total size of 30 segment load commands (at 56
3285    ## each); under Cocoa 31 commands are required.
3286    if test "$HAVE_NS" = "yes"; then
3287      libs_nsgui="-framework AppKit"
3288      headerpad_extra=6C8
3289    else
3290      libs_nsgui=
3291      headerpad_extra=690
3292    fi
3293    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3294
3295    ## This is here because src/Makefile.in did some extra fiddling around
3296    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3297    ##   #ifndef LD_SWITCH_SYSTEM
3298    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3299    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3300    ## not using gcc, darwin system not on an alpha (ie darwin, since
3301    ## darwin + alpha does not occur).
3302    ## Because this was done in src/Makefile.in, the resulting part of
3303    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3304    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3305    ## rather than LD_SWITCH_SYSTEM.
3306    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3307      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3308    ;;
3309
3310   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3311   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3312   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3313   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3314   ## had different values in configure (in ac_link) and src/Makefile.in.
3315   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3316   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3317
3318   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3319 esac
3320
3321 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3322   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3323 fi
3324
3325 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3326
3327
3328 LD_FIRSTFLAG=
3329 ORDINARY_LINK=
3330 case "$opsys" in
3331   ## gnu: GNU needs its own crt0.
3332   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3333
3334   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3335   ## library search parth, i.e. it won't search /usr/lib for libc and
3336   ## friends.  Using -nostartfiles instead avoids this problem, and
3337   ## will also work on earlier NetBSD releases.
3338   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3339
3340   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3341   ##   MkLinux/LinuxPPC needs this.
3342   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3343   gnu-*)
3344     case "$machine" in
3345       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3346     esac
3347     ;;
3348 esac
3349
3350
3351 if test "x$ORDINARY_LINK" = "xyes"; then
3352
3353   LD_FIRSTFLAG=""
3354   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3355
3356 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3357 ## freebsd, gnu-* not on macppc|ibms390x.
3358 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3359
3360   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3361   ## places that are difficult to figure out at make time.  Fortunately,
3362   ## these same versions allow you to pass arbitrary flags on to the
3363   ## linker, so there is no reason not to use it as a linker.
3364   ##
3365   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3366   ## searching for libraries in its internal directories, so we have to
3367   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3368   LD_FIRSTFLAG="-nostdlib"
3369 fi
3370
3371 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3372 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3373
3374 AC_SUBST(LD_FIRSTFLAG)
3375
3376
3377 ## FIXME? The logic here is not precisely the same as that above.
3378 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3379 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3380 LIB_GCC=
3381 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3382
3383   case "$opsys" in
3384     freebsd|netbsd|openbsd) LIB_GCC= ;;
3385
3386     gnu-*)
3387       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3388       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3389       case $host_cpu in
3390       arm*)
3391         LIB_GCC="-lgcc_s"
3392         ;;
3393       *)
3394         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3395         ## immediately undefine it again and redefine it to empty.
3396         ## Was the C_SWITCH_X_SITE part really necessary?
3397 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3398         LIB_GCC=
3399         ;;
3400       esac
3401       ;;
3402
3403     ## Ask GCC where to find libgcc.a.
3404     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3405   esac
3406 fi                              dnl if $GCC
3407 AC_SUBST(LIB_GCC)
3408
3409
3410 TOOLTIP_SUPPORT=
3411 WINDOW_SUPPORT=
3412 ## If we're using X11/GNUstep, define some consequences.
3413 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3414   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3415   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3416   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3417   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3418
3419   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3420   test "$HAVE_X_WINDOWS" = "yes" && \
3421     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3422
3423 fi
3424 AC_SUBST(MOUSE_SUPPORT)
3425 AC_SUBST(TOOLTIP_SUPPORT)
3426 AC_SUBST(WINDOW_SUPPORT)
3427
3428
3429 AH_TOP([/* GNU Emacs site configuration template file.
3430
3431 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3432   Free Software Foundation, Inc.
3433
3434 This file is part of GNU Emacs.
3435
3436 GNU Emacs is free software: you can redistribute it and/or modify
3437 it under the terms of the GNU General Public License as published by
3438 the Free Software Foundation, either version 3 of the License, or
3439 (at your option) any later version.
3440
3441 GNU Emacs is distributed in the hope that it will be useful,
3442 but WITHOUT ANY WARRANTY; without even the implied warranty of
3443 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3444 GNU General Public License for more details.
3445
3446 You should have received a copy of the GNU General Public License
3447 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3448
3449
3450 /* No code in Emacs #includes config.h twice, but some bits of code
3451    intended to work with other packages as well (like gmalloc.c)
3452    think they can include it as many times as they like.  */
3453 #ifndef EMACS_CONFIG_H
3454 #define EMACS_CONFIG_H
3455 ])dnl
3456
3457 AH_BOTTOM([
3458 /* Define AMPERSAND_FULL_NAME if you use the convention
3459    that & in the full name stands for the login id.  */
3460 /* Turned on June 1996 supposing nobody will mind it.  */
3461 #define AMPERSAND_FULL_NAME
3462
3463 /* If using GNU, then support inline function declarations.  */
3464 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3465    generally, because even if non-gcc compilers accept `inline', they
3466    may reject `extern inline'.  */
3467 #if defined (__GNUC__)
3468 #define INLINE __inline__
3469 #else
3470 #define INLINE
3471 #endif
3472
3473 /* `subprocesses' should be defined if you want to
3474    have code for asynchronous subprocesses
3475    (as used in M-x compile and M-x shell).
3476    Only MSDOS does not support this (it overrides
3477    this in its config_opsysfile below).  */
3478
3479 #define subprocesses
3480
3481 /* Include the os and machine dependent files.  */
3482 #include config_opsysfile
3483 #ifdef config_machfile
3484 # include config_machfile
3485 #endif
3486
3487 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3488    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3489   (There is probably a better place to do this, but right now the
3490    Cocoa side does this in s/darwin.h and we cannot parallel this
3491    exactly since GNUstep is multi-OS.  */
3492 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3493 #  define SYSTEM_PURESIZE_EXTRA 30000
3494 #endif
3495
3496 #ifdef emacs /* Don't do this for lib-src.  */
3497 /* Tell regex.c to use a type compatible with Emacs.  */
3498 #define RE_TRANSLATE_TYPE Lisp_Object
3499 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3500 #ifdef make_number
3501 /* If make_number is a macro, use it.  */
3502 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3503 #else
3504 /* If make_number is a function, avoid it.  */
3505 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3506 #endif
3507 #endif
3508
3509 /* These default definitions are good for almost all machines.
3510    The exceptions override them in m/MACHINE.h.  */
3511
3512 #ifndef BITS_PER_CHAR
3513 #define BITS_PER_CHAR 8
3514 #endif
3515
3516 #ifndef BITS_PER_SHORT
3517 #define BITS_PER_SHORT 16
3518 #endif
3519
3520 /* Note that lisp.h uses this in a preprocessor conditional, so it
3521    would not work to use sizeof.  That being so, we do all of them
3522    without sizeof, for uniformity's sake.  */
3523 #ifndef BITS_PER_INT
3524 #define BITS_PER_INT 32
3525 #endif
3526
3527 #ifndef BITS_PER_LONG
3528 #ifdef _LP64
3529 #define BITS_PER_LONG 64
3530 #else
3531 #define BITS_PER_LONG 32
3532 #endif
3533 #endif
3534
3535 /* Define if the compiler supports function prototypes.  It may do so but
3536    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3537 #undef PROTOTYPES
3538
3539 #include <string.h>
3540 #include <stdlib.h>
3541
3542 #ifdef HAVE_ALLOCA_H
3543 # include <alloca.h>
3544 #elif defined __GNUC__
3545 # define alloca __builtin_alloca
3546 #elif defined _AIX
3547 # define alloca __alloca
3548 #else
3549 # include <stddef.h>
3550 # ifdef  __cplusplus
3551 extern "C"
3552 # endif
3553 void *alloca (size_t);
3554 #endif
3555
3556 #ifndef HAVE_SIZE_T
3557 typedef unsigned size_t;
3558 #endif
3559
3560 #ifndef HAVE_STRCHR
3561 #define strchr(a, b) index (a, b)
3562 #endif
3563
3564 #ifndef HAVE_STRRCHR
3565 #define strrchr(a, b) rindex (a, b)
3566 #endif
3567
3568 #if defined __GNUC__ && (__GNUC__ > 2 \
3569                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3570 #define NO_RETURN       __attribute__ ((__noreturn__))
3571 #else
3572 #define NO_RETURN       /* nothing */
3573 #endif
3574
3575 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3576 #define NO_INLINE __attribute__((noinline))
3577 #else
3578 #define NO_INLINE
3579 #endif
3580
3581 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3582 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3583 #else
3584 #define EXTERNALLY_VISIBLE
3585 #endif
3586
3587 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3588 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3589 #else
3590 # define ATTRIBUTE_FORMAT(spec) /* empty */
3591 #endif
3592
3593 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3594 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3595    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3596 #else
3597 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3598    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3599 #endif
3600
3601 /* Some versions of GNU/Linux define noinline in their headers.  */
3602 #ifdef noinline
3603 #undef noinline
3604 #endif
3605
3606 /* These won't be used automatically yet.  We also need to know, at least,
3607    that the stack is continuous.  */
3608 #ifdef __GNUC__
3609 #  ifndef GC_SETJMP_WORKS
3610   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3611 #    define GC_SETJMP_WORKS 1
3612 #  endif
3613 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3614 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3615 #  endif
3616 #endif
3617
3618 #endif /* EMACS_CONFIG_H */
3619
3620 /*
3621 Local Variables:
3622 mode: c
3623 End:
3624 */
3625 ])dnl
3626
3627 #### Report on what we decided to do.
3628 #### Report GTK as a toolkit, even if it doesn't use Xt.
3629 #### It makes printing result more understandable as using GTK sets
3630 #### toolkit_scroll_bars to yes by default.
3631 if test "${HAVE_GTK}" = "yes"; then
3632   USE_X_TOOLKIT=GTK
3633 fi
3634
3635 and_machfile=
3636 if test -n "$machfile"; then
3637   and_machfile=" and \`${machfile}'"
3638 fi
3639
3640 echo "
3641 Configured for \`${canonical}'.
3642
3643   Where should the build process find the source code?    ${srcdir}
3644   What operating system and machine description files should Emacs use?
3645         \`${opsysfile}'${and_machfile}
3646   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3647   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3648   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3649   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3650   What window system should Emacs use?                    ${window_system}
3651   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3652
3653 if test -n "${x_includes}"; then
3654 echo "  Where do we find X Windows header files?                ${x_includes}"
3655 else
3656 echo "  Where do we find X Windows header files?                Standard dirs"
3657 fi
3658 if test -n "${x_libraries}"; then
3659 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3660 else
3661 echo "  Where do we find X Windows libraries?                   Standard dirs"
3662 fi
3663
3664 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3665 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3666 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3667 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3668 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3669 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3670 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3671 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3672
3673 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3674 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3675 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3676 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3677 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3678 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3679
3680 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3681 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3682 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3683 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3684
3685 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3686 echo
3687
3688 if test $USE_XASSERTS = yes; then
3689    echo "  Compiling with asserts turned on."
3690    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3691 fi
3692
3693 echo
3694
3695 if test "$HAVE_NS" = "yes"; then
3696    echo
3697    echo "You must run \"make install\" in order to test the built application.
3698 The installed application will go to nextstep/Emacs.app and can be
3699 run or moved from there."
3700    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3701       echo "The application will be fully self-contained."
3702     else
3703       echo "The lisp resources for the application will be installed under ${prefix}.
3704 You may need to run \"make install\" with sudo.  The application will fail
3705 to run if these resources are not installed."
3706    fi
3707    echo
3708 fi
3709
3710
3711 # Remove any trailing slashes in these variables.
3712 [test "${prefix}" != NONE &&
3713   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3714 test "${exec_prefix}" != NONE &&
3715   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3716
3717 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3718         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3719         doc/lispref/Makefile src/Makefile \
3720         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile])
3721
3722 dnl Make the necessary directories, if they don't exist.
3723 AC_CONFIG_COMMANDS([mkdirs], [
3724 for dir in etc lisp ; do
3725   test -d ${dir} || mkdir ${dir}
3726 done
3727 ])
3728
3729 dnl You might wonder (I did) why epaths.h is generated by running make,
3730 dnl rather than just letting configure generate it from epaths.in.
3731 dnl One reason is that the various paths are not fully expanded (see above);
3732 dnl eg gamedir=${prefix}/var/games/emacs.
3733 dnl Secondly, the GNU Coding standards require that one should be able
3734 dnl to run `make prefix=/some/where/else' and override the values set
3735 dnl by configure.  This also explains the `move-if-change' test and
3736 dnl the use of force in the `epaths-force' rule in Makefile.in.
3737 AC_CONFIG_COMMANDS([epaths], [
3738 echo creating src/epaths.h
3739 ${MAKE-make} epaths-force
3740 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3741
3742 AC_CONFIG_COMMANDS([gdbinit], [
3743 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3744   echo creating src/.gdbinit
3745   echo source $srcdir/src/.gdbinit > src/.gdbinit
3746 fi
3747 ])
3748
3749 AC_OUTPUT
3750
3751 dnl configure.in ends here