lisp/gnus/gnus-gravatar.el

   1 ;;; gnus-gravatar.el --- Gnus Gravatar support
   2
   3 ;; Copyright (C) 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Julien Danjou <julien@danjou.info>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gravatar)
  28
  29 (defgroup gnus-gravatar nil
  30   "Gnus Gravatar."
  31   :group 'gnus-visual)
  32
  33 (defcustom gnus-gravatar-size 32
  34   "How big should gravatars be displayed."
  35   :type 'integer
  36   :version "24.1"
  37   :group 'gnus-gravatar)
  38
  39 (defcustom gnus-gravatar-properties '(:ascent center :relief 1)
  40   "List of image properties applied to Gravatar images."
  41   :type 'list
  42   :version "24.1"
  43   :group 'gnus-gravatar)
  44
  45 (defcustom gnus-gravatar-too-ugly (if (boundp 'gnus-article-x-face-too-ugly)
  46                                       gnus-article-x-face-too-ugly)
  47   "Regexp matching posters whose avatar shouldn't be shown automatically."
  48   :type '(choice regexp (const nil))
  49   :version "24.1"
  50   :group 'gnus-gravatar)
  51
  52 (defun gnus-gravatar-transform-address (header category)
  53   (gnus-with-article-headers
  54     (let ((addresses
  55            (mail-header-parse-addresses
  56             ;; mail-header-parse-addresses does not work (reliably) on
  57             ;; decoded headers.
  58             (or
  59              (ignore-errors
  60                (mail-encode-encoded-word-string
  61                 (or (mail-fetch-field header) "")))
  62              (mail-fetch-field header)))))
  63       (let ((gravatar-size gnus-gravatar-size))
  64         (dolist (address addresses)
  65           (unless (and gnus-gravatar-too-ugly
  66                        (or (string-match gnus-gravatar-too-ugly
  67                                          (car address))
  68                            (and (cdr address)
  69                                 (string-match gnus-gravatar-too-ugly
  70                                               (cdr address)))))
  71             (gravatar-retrieve
  72              (car address)
  73              'gnus-gravatar-insert
  74              (list header address category))))))))
  75
  76 (defun gnus-gravatar-insert (gravatar header address category)
  77   "Insert GRAVATAR for ADDRESS in HEADER in current article buffer.
  78 Set image category to CATEGORY."
  79   (unless (eq gravatar 'error)
  80     (gnus-with-article-headers
  81       (gnus-article-goto-header header)
  82       (mail-header-narrow-to-field)
  83       (let ((real-name (cdr address))
  84             (mail-address (car address)))
  85         (when (if real-name             ; have a realname, go for it!
  86                   (and (search-forward real-name nil t)
  87                        (search-backward real-name nil t))
  88                 (and (search-forward mail-address nil t)
  89                      (search-backward mail-address nil t)))
  90           (goto-char (1- (point)))
  91           ;; If we're on the " quoting the name, go backward
  92           (when (looking-at "[\"<]")
  93             (goto-char (1- (point))))
  94           ;; Do not do anything if there's already a gravatar. This can
  95           ;; happens if the buffer has been regenerated in the mean time, for
  96           ;; example we were fetching someaddress, and then we change to
  97           ;; another mail with the same someaddress.
  98           (unless (memq 'gnus-gravatar (text-properties-at (point)))
  99             (let ((inhibit-read-only t)
 100                   (point (point)))
 101               (unless (featurep 'xemacs)
 102                 (setq gravatar (append gravatar gnus-gravatar-properties)))
 103               (gnus-put-image gravatar nil category)
 104               (put-text-property point (point) 'gnus-gravatar address)
 105               (gnus-add-wash-type category)
 106               (gnus-add-image category gravatar))))))))
 107
 108 ;;;###autoload
 109 (defun gnus-treat-from-gravatar ()
 110   "Display gravatar in the From header.
 111 If gravatar is already displayed, remove it."
 112   (interactive)
 113   (gnus-with-article-buffer
 114     (if (memq 'from-gravatar gnus-article-wash-types)
 115         (gnus-delete-images 'from-gravatar)
 116       (gnus-gravatar-transform-address "from" 'from-gravatar))))
 117
 118 ;;;###autoload
 119 (defun gnus-treat-mail-gravatar ()
 120   "Display gravatars in the Cc and To headers.
 121 If gravatars are already displayed, remove them."
 122   (interactive)
 123     (gnus-with-article-buffer
 124       (if (memq 'mail-gravatar gnus-article-wash-types)
 125           (gnus-delete-images 'mail-gravatar)
 126         (gnus-gravatar-transform-address "cc" 'mail-gravatar)
 127         (gnus-gravatar-transform-address "to" 'mail-gravatar))))
 128
 129 (provide 'gnus-gravatar)
 130
 131 ;;; gnus-gravatar.el ends here