lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a valid Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defvar PC-old-read-file-name-internal nil)
 145
 146 (defun PC-bindings (bind)
 147   (let ((completion-map minibuffer-local-completion-map)
 148         (must-match-map minibuffer-local-must-match-map))
 149     (cond ((not bind)
 150            ;; These bindings are the default bindings.  It would be better to
 151            ;; restore the previous bindings.
 152            (define-key completion-map "\t"      'minibuffer-complete)
 153            (define-key completion-map " "       'minibuffer-complete-word)
 154            (define-key completion-map "?"       'minibuffer-completion-help)
 155
 156            (define-key must-match-map "\t"      'minibuffer-complete)
 157            (define-key must-match-map " "       'minibuffer-complete-word)
 158            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 159            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 160            (define-key must-match-map "?"       'minibuffer-completion-help)
 161
 162            (define-key global-map "\e\t"        'complete-symbol))
 163           (PC-default-bindings
 164            (define-key completion-map "\t"      'PC-complete)
 165            (define-key completion-map " "       'PC-complete-word)
 166            (define-key completion-map "?"       'PC-completion-help)
 167
 168            (define-key completion-map "\e\t"    'PC-complete)
 169            (define-key completion-map "\e "     'PC-complete-word)
 170            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 171            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 172            (define-key completion-map "\e?"     'PC-completion-help)
 173
 174            (define-key must-match-map "\t"      'PC-complete)
 175            (define-key must-match-map " "       'PC-complete-word)
 176            (define-key must-match-map "\r"      'PC-complete-and-exit)
 177            (define-key must-match-map "\n"      'PC-complete-and-exit)
 178            (define-key must-match-map "?"       'PC-completion-help)
 179
 180            (define-key must-match-map "\e\t"    'PC-complete)
 181            (define-key must-match-map "\e "     'PC-complete-word)
 182            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 183            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 184            (define-key must-match-map "\e?"     'PC-completion-help)
 185
 186            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 187
 188 ;;;###autoload
 189 (define-minor-mode partial-completion-mode
 190   "Toggle Partial Completion mode.
 191 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 192
 193 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 194 nil) is enhanced so that if some string is divided into words and each word is
 195 delimited by a character in `PC-word-delimiters', partial words are completed
 196 as much as possible and `*' characters are treated likewise in file names.
 197
 198 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 199 command begins with that sequence of characters, and
 200 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 201 other file in that directory begin with that sequence of characters.
 202
 203 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 204 specially in \\[find-file].  For example,
 205 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 206 See also the variable `PC-include-file-path'.
 207
 208 Partial Completion mode extends the meaning of `completion-auto-help' (which
 209 see), so that if it is neither nil nor t, Emacs shows the `*Completions*'
 210 buffer only on the second attempt to complete.  That is, if TAB finds nothing
 211 to complete, the first TAB just says \"Next char not unique\" and the
 212 second TAB brings up the `*Completions*' buffer."
 213   :global t :group 'partial-completion
 214   ;; Deal with key bindings...
 215   (PC-bindings partial-completion-mode)
 216   ;; Deal with include file feature...
 217   (cond ((not partial-completion-mode)
 218          (remove-hook 'find-file-not-found-functions 'PC-look-for-include-file))
 219         ((not PC-disable-includes)
 220          (add-hook 'find-file-not-found-functions 'PC-look-for-include-file)))
 221   ;; ... with some underhand redefining.
 222   (cond ((and (not partial-completion-mode)
 223               (functionp PC-old-read-file-name-internal))
 224          (fset 'read-file-name-internal PC-old-read-file-name-internal))
 225         ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 226          (setq PC-old-read-file-name-internal
 227                (symbol-function 'read-file-name-internal))
 228          (fset 'read-file-name-internal
 229                'PC-read-include-file-name-internal)))
 230     (when (and partial-completion-mode (null PC-env-vars-alist))
 231       (setq PC-env-vars-alist
 232             (mapcar (lambda (string)
 233                       (let ((d (string-match "=" string)))
 234                         (cons (concat "$" (substring string 0 d))
 235                               (and d (substring string (1+ d))))))
 236                     process-environment))))
 237
 238 \f
 239 (defun PC-complete ()
 240   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 241 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 242 name which consists of three or more words, the first beginning with \"b\"
 243 and the third beginning with \"di\".
 244
 245 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 246 `beginning-of-defun', so this would produce a list of completions
 247 just like when normal Emacs completions are ambiguous.
 248
 249 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 250 \".\", and SPC."
 251   (interactive)
 252   (if (PC-was-meta-key)
 253       (minibuffer-complete)
 254     ;; If the previous command was not this one,
 255     ;; never scroll, always retry completion.
 256     (or (eq last-command this-command)
 257         (setq minibuffer-scroll-window nil))
 258     (let ((window minibuffer-scroll-window))
 259       ;; If there's a fresh completion window with a live buffer,
 260       ;; and this command is repeated, scroll that window.
 261       (if (and window (window-buffer window)
 262                (buffer-name (window-buffer window)))
 263           (with-current-buffer (window-buffer window)
 264             (if (pos-visible-in-window-p (point-max) window)
 265                 (set-window-start window (point-min) nil)
 266               (scroll-other-window)))
 267         (PC-do-completion nil)))))
 268
 269
 270 (defun PC-complete-word ()
 271   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 272 See `PC-complete' for details.
 273 This can be bound to other keys, like `-' and `.', if you wish."
 274   (interactive)
 275   (if (eq (PC-was-meta-key) PC-meta-flag)
 276       (if (eq last-command-char ? )
 277           (minibuffer-complete-word)
 278         (self-insert-command 1))
 279     (self-insert-command 1)
 280     (if (eobp)
 281         (PC-do-completion 'word))))
 282
 283
 284 (defun PC-complete-space ()
 285   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 286 See `PC-complete' for details.
 287 This is suitable for binding to other keys which should act just like SPC."
 288   (interactive)
 289   (if (eq (PC-was-meta-key) PC-meta-flag)
 290       (minibuffer-complete-word)
 291     (insert " ")
 292     (if (eobp)
 293         (PC-do-completion 'word))))
 294
 295
 296 (defun PC-complete-and-exit ()
 297   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 298 See `PC-complete' for details."
 299   (interactive)
 300   (if (eq (PC-was-meta-key) PC-meta-flag)
 301       (minibuffer-complete-and-exit)
 302     (PC-do-complete-and-exit)))
 303
 304 (defun PC-force-complete-and-exit ()
 305   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 306 See `PC-complete' for details."
 307   (interactive)
 308   (let ((minibuffer-completion-confirm nil))
 309     (PC-do-complete-and-exit)))
 310
 311 (defun PC-do-complete-and-exit ()
 312   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 313       (exit-minibuffer)
 314     (let ((flag (PC-do-completion 'exit)))
 315       (and flag
 316            (if (or (eq flag 'complete)
 317                    (not minibuffer-completion-confirm))
 318                (exit-minibuffer)
 319              (PC-temp-minibuffer-message " [Confirm]"))))))
 320
 321
 322 (defun PC-completion-help ()
 323   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 324 See `PC-complete' for details."
 325   (interactive)
 326   (if (eq (PC-was-meta-key) PC-meta-flag)
 327       (minibuffer-completion-help)
 328     (PC-do-completion 'help)))
 329
 330 (defun PC-was-meta-key ()
 331   (or (/= (length (this-command-keys)) 1)
 332       (let ((key (aref (this-command-keys) 0)))
 333         (if (integerp key)
 334             (>= key 128)
 335           (not (null (memq 'meta (event-modifiers key))))))))
 336
 337
 338 (defvar PC-ignored-extensions 'empty-cache)
 339 (defvar PC-delims 'empty-cache)
 340 (defvar PC-ignored-regexp nil)
 341 (defvar PC-word-failed-flag nil)
 342 (defvar PC-delim-regex nil)
 343 (defvar PC-ndelims-regex nil)
 344 (defvar PC-delims-list nil)
 345
 346 (defvar PC-completion-as-file-name-predicate
 347   (lambda () minibuffer-completing-file-name)
 348   "A function testing whether a minibuffer completion now will work filename-style.
 349 The function takes no arguments, and typically looks at the value
 350 of `minibuffer-completion-table' and the minibuffer contents.")
 351
 352 (defun PC-do-completion (&optional mode beg end)
 353   (or beg (setq beg (minibuffer-prompt-end)))
 354   (or end (setq end (point-max)))
 355   (let* ((table minibuffer-completion-table)
 356          (pred minibuffer-completion-predicate)
 357          (filename (funcall PC-completion-as-file-name-predicate))
 358          (dirname nil)
 359          (dirlength 0)
 360          (str (buffer-substring beg end))
 361          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 362          (ambig nil)
 363          basestr
 364          env-on
 365          regex
 366          p offset
 367          (poss nil)
 368          helpposs
 369          (case-fold-search completion-ignore-case))
 370
 371     ;; Check if buffer contents can already be considered complete
 372     (if (and (eq mode 'exit)
 373              (test-completion str table pred))
 374         'complete
 375
 376       ;; Do substitutions in directory names
 377       (and filename
 378            (setq basestr (or (file-name-directory str) ""))
 379            (setq dirlength (length basestr))
 380            ;; Do substitutions in directory names
 381            (setq p (substitute-in-file-name basestr))
 382            (not (string-equal basestr p))
 383            (setq str (concat p (file-name-nondirectory str)))
 384            (progn
 385              (delete-region beg end)
 386              (insert str)
 387              (setq end (+ beg (length str)))))
 388
 389       ;; Prepare various delimiter strings
 390       (or (equal PC-word-delimiters PC-delims)
 391           (setq PC-delims PC-word-delimiters
 392                 PC-delim-regex (concat "[" PC-delims "]")
 393                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 394                 PC-delims-list (append PC-delims nil)))
 395
 396       ;; Add wildcards if necessary
 397       (and filename
 398            (let ((dir (file-name-directory str))
 399                  (file (file-name-nondirectory str))
 400                  ;; The base dir for file-completion is passed in `predicate'.
 401                  (default-directory (expand-file-name pred)))
 402              (while (and (stringp dir) (not (file-directory-p dir)))
 403                (setq dir (directory-file-name dir))
 404                (setq file (concat (replace-regexp-in-string
 405                                    PC-delim-regex "*\\&"
 406                                    (file-name-nondirectory dir))
 407                                   "*/" file))
 408                (setq dir (file-name-directory dir)))
 409              (setq str (concat dir file))))
 410
 411       ;; Look for wildcard expansions in directory name
 412       (and filename
 413            (string-match "\\*.*/" str)
 414            (let ((pat str)
 415                  ;; The base dir for file-completion is passed in `predicate'.
 416                  (default-directory (expand-file-name pred))
 417                  files)
 418              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 419              (while (setq p (string-match PC-delim-regex pat p))
 420                (setq pat (concat (substring pat 0 p)
 421                                  "*"
 422                                  (substring pat p))
 423                      p (+ p 2)))
 424              (setq files (PC-expand-many-files (concat pat "*")))
 425              (if files
 426                  (let ((dir (file-name-directory (car files)))
 427                        (p files))
 428                    (while (and (setq p (cdr p))
 429                                (equal dir (file-name-directory (car p)))))
 430                    (if p
 431                        (setq filename nil table nil pred nil
 432                              ambig t)
 433                      (delete-region beg end)
 434                      (setq str (concat dir (file-name-nondirectory str)))
 435                      (insert str)
 436                      (setq end (+ beg (length str)))))
 437                (setq filename nil table nil pred nil))))
 438
 439       ;; Strip directory name if appropriate
 440       (if filename
 441           (if incname
 442               (setq basestr (substring str incname)
 443                     dirname (substring str 0 incname))
 444             (setq basestr (file-name-nondirectory str)
 445                   dirname (file-name-directory str))
 446             ;; Make sure str is consistent with its directory and basename
 447             ;; parts.  This is important on DOZe'NT systems when str only
 448             ;; includes a drive letter, like in "d:".
 449             (setq str (concat dirname basestr)))
 450         (setq basestr str))
 451
 452       ;; Convert search pattern to a standard regular expression
 453       (setq regex (regexp-quote basestr)
 454             offset (if (and (> (length regex) 0)
 455                             (not (eq (aref basestr 0) ?\*))
 456                             (or (eq PC-first-char t)
 457                                 (and PC-first-char filename))) 1 0)
 458             p offset)
 459       (while (setq p (string-match PC-delim-regex regex p))
 460         (if (eq (aref regex p) ? )
 461             (setq regex (concat (substring regex 0 p)
 462                                 PC-ndelims-regex
 463                                 PC-delim-regex
 464                                 (substring regex (1+ p)))
 465                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 466           (let ((bump (if (memq (aref regex p)
 467                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 468                           -1 0)))
 469             (setq regex (concat (substring regex 0 (+ p bump))
 470                                 PC-ndelims-regex
 471                                 (substring regex (+ p bump)))
 472                   p (+ p (length PC-ndelims-regex) 1)))))
 473       (setq p 0)
 474       (if filename
 475           (while (setq p (string-match "\\\\\\*" regex p))
 476             (setq regex (concat (substring regex 0 p)
 477                                 "[^/]*"
 478                                 (substring regex (+ p 2))))))
 479       ;;(setq the-regex regex)
 480       (setq regex (concat "\\`" regex))
 481
 482       (and (> (length basestr) 0)
 483            (= (aref basestr 0) ?$)
 484            (setq env-on t
 485                  table PC-env-vars-alist
 486                  pred nil))
 487
 488       ;; Find an initial list of possible completions
 489       (if (not (setq p (string-match (concat PC-delim-regex
 490                                              (if filename "\\|\\*" ""))
 491                                      str
 492                                      (+ (length dirname) offset))))
 493
 494           ;; Minibuffer contains no hyphens -- simple case!
 495           (setq poss (all-completions (if env-on
 496                                           basestr str)
 497                                       table
 498                                       pred))
 499
 500         ;; Use all-completions to do an initial cull.  This is a big win,
 501         ;; since all-completions is written in C!
 502         (let ((compl (all-completions (if env-on
 503                                           (file-name-nondirectory (substring str 0 p))
 504                                         (substring str 0 p))
 505                                         table
 506                                         pred)))
 507           (setq p compl)
 508           (while p
 509             (and (string-match regex (car p))
 510                  (progn
 511                    (set-text-properties 0 (length (car p)) '() (car p))
 512                    (setq poss (cons (car p) poss))))
 513             (setq p (cdr p)))))
 514
 515       ;; Now we have a list of possible completions
 516       (cond
 517
 518        ;; No valid completions found
 519        ((null poss)
 520         (if (and (eq mode 'word)
 521                  (not PC-word-failed-flag))
 522             (let ((PC-word-failed-flag t))
 523               (delete-backward-char 1)
 524               (PC-do-completion 'word))
 525           (beep)
 526           (PC-temp-minibuffer-message (if ambig
 527                                           " [Ambiguous dir name]"
 528                                         (if (eq mode 'help)
 529                                             " [No completions]"
 530                                           " [No match]")))
 531           nil))
 532
 533        ;; More than one valid completion found
 534        ((or (cdr (setq helpposs poss))
 535             (memq mode '(help word)))
 536
 537         ;; Handle completion-ignored-extensions
 538         (and filename
 539              (not (eq mode 'help))
 540              (let ((p2 poss))
 541
 542                ;; Build a regular expression representing the extensions list
 543                (or (equal completion-ignored-extensions PC-ignored-extensions)
 544                    (setq PC-ignored-regexp
 545                          (concat "\\("
 546                                  (mapconcat
 547                                   'regexp-quote
 548                                   (setq PC-ignored-extensions
 549                                         completion-ignored-extensions)
 550                                   "\\|")
 551                                  "\\)\\'")))
 552
 553                ;; Check if there are any without an ignored extension.
 554                ;; Also ignore `.' and `..'.
 555                (setq p nil)
 556                (while p2
 557                  (or (string-match PC-ignored-regexp (car p2))
 558                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 559                      (setq p (cons (car p2) p)))
 560                  (setq p2 (cdr p2)))
 561
 562                ;; If there are "good" names, use them
 563                (and p (setq poss p))))
 564
 565         ;; Is the actual string one of the possible completions?
 566         (setq p (and (not (eq mode 'help)) poss))
 567         (while (and p
 568                     (not (string-equal (car p) basestr)))
 569           (setq p (cdr p)))
 570         (and p (null mode)
 571              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 572         (if (and p
 573                  (not (and (null mode)
 574                            (eq this-command last-command))))
 575             t
 576
 577           ;; If ambiguous, try for a partial completion
 578           (let ((improved nil)
 579                 prefix
 580                 (pt nil)
 581                 (skip "\\`"))
 582
 583             ;; Check if next few letters are the same in all cases
 584             (if (and (not (eq mode 'help))
 585                      (setq prefix (try-completion "" (mapcar 'list poss))))
 586                 (let ((first t) i)
 587                   (if (eq mode 'word)
 588                       (setq prefix (PC-chop-word prefix basestr)))
 589                   (goto-char (+ beg (length dirname)))
 590                   (while (and (progn
 591                                 (setq i 0)
 592                                 (while (< i (length prefix))
 593                                   (if (and (< (point) end)
 594                                            (eq (aref prefix i)
 595                                                (following-char)))
 596                                       (forward-char 1)
 597                                     (if (and (< (point) end)
 598                                              (or (and (looking-at " ")
 599                                                       (memq (aref prefix i)
 600                                                             PC-delims-list))
 601                                                  (eq (downcase (aref prefix i))
 602                                                      (downcase
 603                                                       (following-char)))))
 604                                         (progn
 605                                           (delete-char 1)
 606                                           (setq end (1- end)))
 607                                       (and filename (looking-at "\\*")
 608                                            (progn
 609                                              (delete-char 1)
 610                                              (setq end (1- end))))
 611                                       (setq improved t))
 612                                     (insert (substring prefix i (1+ i)))
 613                                     (setq end (1+ end)))
 614                                   (setq i (1+ i)))
 615                                 (or pt (setq pt (point)))
 616                                 (looking-at PC-delim-regex))
 617                               (setq skip (concat skip
 618                                                  (regexp-quote prefix)
 619                                                  PC-ndelims-regex)
 620                                     prefix (try-completion
 621                                             ""
 622                                             (mapcar
 623                                              (function
 624                                               (lambda (x)
 625                                                 (list
 626                                                  (and (string-match skip x)
 627                                                       (substring
 628                                                        x
 629                                                        (match-end 0))))))
 630                                              poss)))
 631                               (or (> i 0) (> (length prefix) 0))
 632                               (or (not (eq mode 'word))
 633                                   (and first (> (length prefix) 0)
 634                                        (setq first nil
 635                                              prefix (substring prefix 0 1))))))
 636                   (goto-char (if (eq mode 'word) end
 637                                (or pt beg)))))
 638
 639             (if (and (eq mode 'word)
 640                      (not PC-word-failed-flag))
 641
 642                 (if improved
 643
 644                     ;; We changed it... would it be complete without the space?
 645                     (if (test-completion (buffer-substring 1 (1- end))
 646                                           table pred)
 647                         (delete-region (1- end) end)))
 648
 649               (if improved
 650
 651                   ;; We changed it... enough to be complete?
 652                   (and (eq mode 'exit)
 653                        (test-completion (field-string) table pred))
 654
 655                 ;; If totally ambiguous, display a list of completions
 656                 (if (or (eq completion-auto-help t)
 657                         (and completion-auto-help
 658                              (eq last-command this-command))
 659                         (eq mode 'help))
 660                     (with-output-to-temp-buffer "*Completions*"
 661                       (display-completion-list (sort helpposs 'string-lessp))
 662                       (with-current-buffer standard-output
 663                         ;; Record which part of the buffer we are completing
 664                         ;; so that choosing a completion from the list
 665                         ;; knows how much old text to replace.
 666                         (setq completion-base-size dirlength)))
 667                   (PC-temp-minibuffer-message " [Next char not unique]"))
 668                 nil)))))
 669
 670        ;; Only one possible completion
 671        (t
 672         (if (and (equal basestr (car poss))
 673                  (not (and env-on filename)))
 674             (if (null mode)
 675                 (PC-temp-minibuffer-message " [Sole completion]"))
 676           (delete-region beg end)
 677           (insert (format "%s"
 678                           (if filename
 679                               (substitute-in-file-name (concat dirname (car poss)))
 680                             (car poss)))))
 681         t)))))
 682
 683 (defun PC-chop-word (new old)
 684   (let ((i -1)
 685         (j -1))
 686     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 687                 (setq j (string-match PC-delim-regex new (1+ j)))))
 688     (if (and j
 689              (or (not PC-word-failed-flag)
 690                  (setq j (string-match PC-delim-regex new (1+ j)))))
 691         (substring new 0 (1+ j))
 692       new)))
 693
 694 (defvar PC-not-minibuffer nil)
 695
 696 (defun PC-temp-minibuffer-message (message)
 697   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 698   (cond (PC-not-minibuffer
 699          (message message)
 700          (sit-for 2)
 701          (message ""))
 702         ((fboundp 'temp-minibuffer-message)
 703          (temp-minibuffer-message message))
 704         (t
 705          (let ((point-max (point-max)))
 706            (save-excursion
 707              (goto-char point-max)
 708              (insert message))
 709            (let ((inhibit-quit t))
 710              (sit-for 2)
 711              (delete-region point-max (point-max))
 712              (when quit-flag
 713                (setq quit-flag nil
 714                      unread-command-events '(7))))))))
 715
 716
 717 (defun PC-lisp-complete-symbol ()
 718   "Perform completion on Lisp symbol preceding point.
 719 That symbol is compared against the symbols that exist
 720 and any additional characters determined by what is there
 721 are inserted.
 722 If the symbol starts just after an open-parenthesis,
 723 only symbols with function definitions are considered.
 724 Otherwise, all symbols with function definitions, values
 725 or properties are considered."
 726   (interactive)
 727   (let* ((end (point))
 728          (beg (save-excursion
 729                 (with-syntax-table lisp-mode-syntax-table
 730                   (backward-sexp 1)
 731                   (while (= (char-syntax (following-char)) ?\')
 732                     (forward-char 1))
 733                   (point))))
 734          (minibuffer-completion-table obarray)
 735          (minibuffer-completion-predicate
 736           (if (eq (char-after (1- beg)) ?\()
 737               'fboundp
 738             (function (lambda (sym)
 739                         (or (boundp sym) (fboundp sym)
 740                             (symbol-plist sym))))))
 741          (PC-not-minibuffer t))
 742     (PC-do-completion nil beg end)))
 743
 744 (defun PC-complete-as-file-name ()
 745    "Perform completion on file names preceding point.
 746  Environment vars are converted to their values."
 747    (interactive)
 748    (let* ((end (point))
 749           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 750                                        (point-min) t)
 751                    (+ (point) 2)
 752                    (point-min)))
 753           (minibuffer-completion-table 'read-file-name-internal)
 754           (minibuffer-completion-predicate "")
 755           (PC-not-minibuffer t))
 756      (goto-char end)
 757      (PC-do-completion nil beg end)))
 758
 759 ;; Use the shell to do globbing.
 760 ;; This could now use file-expand-wildcards instead.
 761
 762 (defun PC-expand-many-files (name)
 763   (with-current-buffer (generate-new-buffer " *Glob Output*")
 764     (erase-buffer)
 765     (shell-command (concat "echo " name) t)
 766     (goto-char (point-min))
 767     ;; CSH-style shells were known to output "No match", whereas
 768     ;; SH-style shells tend to simply output `name' when no match is found.
 769     (if (looking-at (concat ".*No match\\|\\(^\\| \\)\\("
 770                             (regexp-quote name)
 771                             "\\|"
 772                             (regexp-quote (expand-file-name name))
 773                             "\\)\\( \\|$\\)"))
 774         nil
 775       (insert "(\"")
 776       (while (search-forward " " nil t)
 777         (delete-backward-char 1)
 778         (insert "\" \""))
 779       (goto-char (point-max))
 780       (delete-backward-char 1)
 781       (insert "\")")
 782       (goto-char (point-min))
 783       (let ((files (read (current-buffer))) (p nil))
 784         (kill-buffer (current-buffer))
 785         (or (equal completion-ignored-extensions PC-ignored-extensions)
 786             (setq PC-ignored-regexp
 787                   (concat "\\("
 788                           (mapconcat
 789                            'regexp-quote
 790                            (setq PC-ignored-extensions
 791                                  completion-ignored-extensions)
 792                            "\\|")
 793                           "\\)\\'")))
 794         (setq p nil)
 795         (while files
 796           ;; This whole process of going through to shell, to echo, and
 797           ;; finally parsing the output is a hack.  It breaks as soon as
 798           ;; there are spaces in the file names or when the no-match
 799           ;; message changes.  To make up for it, we check that what we read
 800           ;; indeed exists, so we may miss some files, but we at least won't
 801           ;; list non-existent ones.
 802           (or (not (file-exists-p (car files)))
 803               (string-match PC-ignored-regexp (car files))
 804               (setq p (cons (car files) p)))
 805           (setq files (cdr files)))
 806         p))))
 807
 808 ;; Facilities for loading C header files.  This is independent from the
 809 ;; main completion code.  See also the variable `PC-include-file-path'
 810 ;; at top of this file.
 811
 812 (defun PC-look-for-include-file ()
 813   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 814       (let ((name (substring (buffer-file-name)
 815                              (match-beginning 1) (match-end 1)))
 816             (punc (aref (buffer-file-name) (match-beginning 0)))
 817             (path nil)
 818             new-buf)
 819         (kill-buffer (current-buffer))
 820         (if (equal name "")
 821             (with-current-buffer (car (buffer-list))
 822               (save-excursion
 823                 (beginning-of-line)
 824                 (if (looking-at
 825                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 826                     (setq name (buffer-substring (match-beginning 1)
 827                                                  (match-end 1))
 828                           punc (char-after (1- (match-beginning 1))))
 829                   ;; Suggested by Frank Siebenlist:
 830                   (if (or (looking-at
 831                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 832                           (looking-at
 833                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 834                           (looking-at
 835                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 836                       (progn
 837                         (setq name (buffer-substring (match-beginning 1)
 838                                                      (match-end 1))
 839                               punc ?\<
 840                               path load-path)
 841                         (if (string-match "\\.elc$" name)
 842                             (setq name (substring name 0 -1))
 843                           (or (string-match "\\.el$" name)
 844                               (setq name (concat name ".el")))))
 845                     (error "Not on an #include line"))))))
 846         (or (string-match "\\.[[:alnum:]]+$" name)
 847             (setq name (concat name ".h")))
 848         (if (eq punc ?\<)
 849             (let ((path (or path (PC-include-file-path))))
 850               (while (and path
 851                           (not (file-exists-p
 852                                 (concat (file-name-as-directory (car path))
 853                                         name))))
 854                 (setq path (cdr path)))
 855               (if path
 856                   (setq name (concat (file-name-as-directory (car path)) name))
 857                 (error "No such include file: <%s>" name)))
 858           (let ((dir (with-current-buffer (car (buffer-list))
 859                        default-directory)))
 860             (if (file-exists-p (concat dir name))
 861                 (setq name (concat dir name))
 862               (error "No such include file: `%s'" name))))
 863         (setq new-buf (get-file-buffer name))
 864         (if new-buf
 865             ;; no need to verify last-modified time for this!
 866             (set-buffer new-buf)
 867           (set-buffer (create-file-buffer name))
 868           (erase-buffer)
 869           (insert-file-contents name t))
 870         ;; Returning non-nil with the new buffer current
 871         ;; is sufficient to tell find-file to use it.
 872         t)
 873     nil))
 874
 875 (defun PC-include-file-path ()
 876   (or PC-include-file-path
 877       (let ((env (getenv "INCPATH"))
 878             (path nil)
 879             pos)
 880         (or env (error "No include file path specified"))
 881         (while (setq pos (string-match ":[^:]+$" env))
 882           (setq path (cons (substring env (1+ pos)) path)
 883                 env (substring env 0 pos)))
 884         path)))
 885
 886 ;; This is adapted from lib-complete.el, by Mike Williams.
 887 (defun PC-include-file-all-completions (file search-path &optional full)
 888   "Return all completions for FILE in any directory on SEARCH-PATH.
 889 If optional third argument FULL is non-nil, returned pathnames should be
 890 absolute rather than relative to some directory on the SEARCH-PATH."
 891   (setq search-path
 892         (mapcar (lambda (dir)
 893                   (if dir (file-name-as-directory dir) default-directory))
 894                 search-path))
 895   (if (file-name-absolute-p file)
 896       ;; It's an absolute file name, so don't need search-path
 897       (progn
 898         (setq file (expand-file-name file))
 899         (file-name-all-completions
 900          (file-name-nondirectory file) (file-name-directory file)))
 901     (let ((subdir (file-name-directory file))
 902           (ndfile (file-name-nondirectory file))
 903           file-lists)
 904       ;; Append subdirectory part to each element of search-path
 905       (if subdir
 906           (setq search-path
 907                 (mapcar (lambda (dir) (concat dir subdir))
 908                         search-path)
 909                 file ))
 910       ;; Make list of completions in each directory on search-path
 911       (while search-path
 912         (let* ((dir (car search-path))
 913                (subdir (if full dir subdir)))
 914           (if (file-directory-p dir)
 915               (progn
 916                 (setq file-lists
 917                       (cons
 918                        (mapcar (lambda (file) (concat subdir file))
 919                                (file-name-all-completions ndfile
 920                                                           (car search-path)))
 921                        file-lists))))
 922           (setq search-path (cdr search-path))))
 923       ;; Compress out duplicates while building complete list (slloooow!)
 924       (let ((sorted (sort (apply 'nconc file-lists)
 925                           (lambda (x y) (not (string-lessp x y)))))
 926             compressed)
 927         (while sorted
 928           (if (equal (car sorted) (car compressed)) nil
 929             (setq compressed (cons (car sorted) compressed)))
 930           (setq sorted (cdr sorted)))
 931         compressed))))
 932
 933 (defun PC-read-include-file-name-internal (string dir action)
 934   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 935       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 936              (str2 (substring string (match-beginning 0)))
 937              (completion-table
 938               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 939                       (PC-include-file-all-completions
 940                        name (PC-include-file-path)))))
 941         (cond
 942          ((not completion-table) nil)
 943          ((eq action nil) (try-completion str2 completion-table nil))
 944          ((eq action t) (all-completions str2 completion-table nil))
 945          ((eq action 'lambda) (test-completion str2 completion-table nil))))
 946     (funcall PC-old-read-file-name-internal string dir action)))
 947 \f
 948
 949 (provide 'complete)
 950
 951 ;; arch-tag: fc7e2768-ff44-4e22-b579-4d825b968458
 952 ;;; complete.el ends here