configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 159 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 160
 161 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 162 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 163 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 164
 165 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 166 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 167 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 168 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 169
 170 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 171 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 172 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 173 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 174 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 175
 176 ## For the times when you want to build Emacs but don't have
 177 ## a suitable makeinfo, and can live without the manuals.
 178 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 179 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 180
 181 ## This is an option because I do not know if all info/man support
 182 ## compressed files, nor how to test if they do so.
 183 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 184 if test $with_compress_info = yes; then
 185    GZIP_INFO=yes
 186 else
 187    GZIP_INFO=
 188 fi
 189 AC_SUBST(GZIP_INFO)
 190
 191 AC_ARG_WITH([pkg-config-prog],dnl
 192 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 193                   [path to pkg-config for finding GTK and librsvg])])
 194 if test "X${with_pkg_config_prog}" != X; then
 195    if test "${with_pkg_config_prog}" != yes; then
 196       PKG_CONFIG="${with_pkg_config_prog}"
 197    fi
 198 fi
 199
 200 CRT_DIR=
 201 AC_ARG_WITH([crt-dir],dnl
 202 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 203 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 204 CRT_DIR="${with_crt_dir}"
 205
 206 AC_ARG_WITH([gnustep-conf],dnl
 207 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 208 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 209   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 210 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 211      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 212
 213 AC_ARG_ENABLE(ns-self-contained,
 214 [AS_HELP_STRING([--disable-ns-self-contained],
 215                 [disable self contained build under NeXTstep])],
 216    EN_NS_SELF_CONTAINED=$enableval,
 217    EN_NS_SELF_CONTAINED=yes)
 218
 219 AC_ARG_ENABLE(asserts,
 220 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 221       USE_XASSERTS=$enableval,
 222       USE_XASSERTS=no)
 223
 224 AC_ARG_ENABLE(maintainer-mode,
 225 [AS_HELP_STRING([--enable-maintainer-mode],
 226                 [enable make rules and dependencies not useful (and sometimes
 227                  confusing) to the casual installer])],
 228       USE_MAINTAINER_MODE=$enableval,
 229       USE_MAINTAINER_MODE=no)
 230 if test $USE_MAINTAINER_MODE = yes; then
 231   MAINT=
 232 else
 233   MAINT=#
 234 fi
 235 AC_SUBST(MAINT)
 236
 237 AC_ARG_ENABLE(locallisppath,
 238 [AS_HELP_STRING([--enable-locallisppath=PATH],
 239                 [directories Emacs should search for lisp files specific
 240                  to this site])],
 241 if test "${enableval}" = "no"; then
 242   locallisppath=
 243 elif test "${enableval}" != "yes"; then
 244   locallisppath=${enableval}
 245 fi)
 246
 247 AC_ARG_ENABLE(checking,
 248 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 249                 [enable expensive run-time checks.  With LIST,
 250                  enable only specific categories of checks.
 251                  Categories are: all,yes,no.
 252                  Flags are: stringbytes, stringoverrun, stringfreelist,
 253                  xmallocoverrun, conslist])],
 254 [ac_checking_flags="${enableval}"],[])
 255 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 256 for check in $ac_checking_flags
 257 do
 258         case $check in
 259         # these set all the flags to specific states
 260         yes)            ac_enable_checking=1 ;;
 261         no)             ac_enable_checking= ;
 262                         ac_gc_check_stringbytes= ;
 263                         ac_gc_check_string_overrun= ;
 264                         ac_gc_check_string_free_list= ;
 265                         ac_xmalloc_overrun= ;
 266                         ac_gc_check_cons_list= ;;
 267         all)            ac_enable_checking=1 ;
 268                         ac_gc_check_stringbytes=1 ;
 269                         ac_gc_check_string_overrun=1 ;
 270                         ac_gc_check_string_free_list=1 ;
 271                         ac_xmalloc_overrun=1 ;
 272                         ac_gc_check_cons_list=1 ;;
 273         # these enable particular checks
 274         stringbytes)    ac_gc_check_stringbytes=1 ;;
 275         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 276         stringfreelist) ac_gc_check_string_free_list=1 ;;
 277         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 278         conslist)       ac_gc_check_cons_list=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Enable expensive run-time checking of data types?])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_stringoverrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310
 311 AC_ARG_ENABLE(use-lisp-union-type,
 312 [AS_HELP_STRING([--enable-use-lisp-union-type],
 313                 [use a union for the Lisp_Object data type.
 314                 This is only useful for development for catching certain types of bugs.])],
 315 if test "${enableval}" != "no"; then
 316    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 317    [Define this to use a lisp union for the Lisp_Object data type.])
 318 fi)
 319
 320
 321 AC_ARG_ENABLE(profiling,
 322 [AS_HELP_STRING([--enable-profiling],
 323                 [build emacs with profiling support.
 324                  This might not work on all platforms])],
 325 [ac_enable_profiling="${enableval}"],[])
 326 if test x$ac_enable_profiling != x ; then
 327    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 328    PROFILING_LDFLAGS="-pg"
 329 else
 330    PROFILING_CFLAGS=
 331    PROFILING_LDFLAGS=
 332 fi
 333 AC_SUBST(PROFILING_CFLAGS)
 334 AC_SUBST(PROFILING_LDFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Check if the source directory already has a configured system in it.
 368 if test `pwd` != `(cd ${srcdir} && pwd)` \
 369    && test -f "${srcdir}/src/config.h" ; then
 370   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 371    as a build directory right now; it has been configured in its own
 372    right.  To configure in another directory as well, you MUST
 373    use GNU make.  If you do not have GNU make, then you must
 374    now do `make distclean' in ${srcdir},
 375    and then run $0 again.]])
 376 fi
 377
 378 #### Given the configuration name, set machfile and opsysfile to the
 379 #### names of the m/*.h and s/*.h files we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system and machine description files.
 400
 401 ### You would hope that you could choose an m/*.h file pretty much
 402 ### based on the machine portion of the configuration name, and an s/*.h
 403 ### file based on the operating system portion.  However, it turns out
 404 ### that each m/*.h file is pretty manufacturer-specific - for
 405 ### example mips.h is MIPS
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 machine='' opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## FreeBSD ports
 419   *-*-freebsd* )
 420     opsys=freebsd
 421     case "${canonical}" in
 422       alpha*)           machine=alpha ;;
 423       amd64-*|x86_64-*) machine=amdx86-64 ;;
 424       arm*)             machine=arm ;;
 425       ia64-*)           machine=ia64 ;;
 426       i[3456]86-*)      machine=intel386 ;;
 427       powerpc-*)        machine=macppc ;;
 428       sparc-*)          machine=sparc ;;
 429       sparc64-*)        machine=sparc ;;
 430     esac
 431   ;;
 432
 433   ## FreeBSD kernel + glibc based userland
 434   *-*-kfreebsd*gnu* )
 435     opsys=gnu-kfreebsd
 436     case "${canonical}" in
 437       alpha*)           machine=alpha ;;
 438       amd64-*|x86_64-*) machine=amdx86-64 ;;
 439       ia64-*)           machine=ia64 ;;
 440       i[3456]86-*)      machine=intel386 ;;
 441       powerpc-*)        machine=macppc ;;
 442       sparc-*)          machine=sparc ;;
 443       sparc64-*)        machine=sparc ;;
 444     esac
 445   ;;
 446
 447   ## NetBSD ports
 448   *-*-netbsd* )
 449     opsys=netbsd
 450     case "${canonical}" in
 451       alpha*)      machine=alpha ;;
 452       x86_64-*)    machine=amdx86-64 ;;
 453       arm-*)       machine=arm ;;
 454       hppa-*)      machine=hp800 ;;
 455       i[3456]86-*) machine=intel386 ;;
 456       m68k-*)      machine=m68k ;;
 457       powerpc-*)   machine=macppc ;;
 458       mips-*)      machine=mips ;;
 459       mipse[bl]-*) machine=mips ;;
 460       sparc*-)     machine=sparc ;;
 461       vax-*)       machine=vax ;;
 462     esac
 463   ;;
 464
 465   ## OpenBSD ports
 466   *-*-openbsd* )
 467     opsys=openbsd
 468     case "${canonical}" in
 469       alpha*)    machine=alpha ;;
 470       x86_64-*)  machine=amdx86-64 ;;
 471       arm-*)     machine=arm ;;
 472       hppa-*)    machine=hp800 ;;
 473       i386-*)    machine=intel386 ;;
 474       powerpc-*) machine=macppc ;;
 475       sparc*)    machine=sparc ;;
 476       vax-*)     machine=vax ;;
 477     esac
 478   ;;
 479
 480   alpha*-*-linux-gnu* )
 481     machine=alpha opsys=gnu-linux
 482   ;;
 483
 484   arm*-*-linux-gnu* )
 485     machine=arm opsys=gnu-linux
 486   ;;
 487
 488   ## Apple Darwin / Mac OS X
 489   *-apple-darwin* )
 490     case "${canonical}" in
 491       i[3456]86-* )  machine=intel386 ;;
 492       powerpc-* )    machine=macppc ;;
 493       x86_64-* )     machine=amdx86-64 ;;
 494       * )            unported=yes ;;
 495     esac
 496     opsys=darwin
 497     # Define CPP as follows to make autoconf work correctly.
 498     CPP="${CC-cc} -E -no-cpp-precomp"
 499     # Use fink packages if available.
 500     if test -d /sw/include && test -d /sw/lib; then
 501       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 502       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 503       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 504     fi
 505   ;;
 506
 507   ## HP 9000 series 700 and 800, running HP/UX
 508   hppa*-hp-hpux10.2* )
 509     machine=hp800 opsys=hpux10-20
 510   ;;
 511   hppa*-hp-hpux1[1-9]* )
 512     machine=hp800 opsys=hpux11
 513     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 514   ;;
 515
 516   hppa*-*-linux-gnu* )
 517     machine=hp800 opsys=gnu-linux
 518   ;;
 519
 520   ## IBM machines
 521   s390-*-linux-gnu* )
 522     machine=ibms390 opsys=gnu-linux
 523   ;;
 524   s390x-*-linux-gnu* )
 525     machine=ibms390x opsys=gnu-linux
 526   ;;
 527   rs6000-ibm-aix4.[23]* )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530   powerpc-ibm-aix4.[23]*  )
 531     machine=ibmrs6000 opsys=aix4-2
 532   ;;
 533   rs6000-ibm-aix[56]* )
 534     machine=ibmrs6000 opsys=aix4-2
 535   ;;
 536   powerpc-ibm-aix[56]*  )
 537     machine=ibmrs6000 opsys=aix4-2
 538   ;;
 539
 540   ## Macintosh PowerPC
 541   powerpc*-*-linux-gnu* )
 542     machine=macppc opsys=gnu-linux
 543   ;;
 544
 545   ## Silicon Graphics machines
 546   ## Iris 4D
 547   mips-sgi-irix6.5 )
 548     machine=iris4d opsys=irix6-5
 549     # Without defining _LANGUAGE_C, things get masked out in the headers
 550     # so that, for instance, grepping for `free' in stdlib.h fails and
 551     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 552     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 553     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 554   ;;
 555
 556   ## Suns
 557   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 558     machine=sparc opsys=gnu-linux
 559   ;;
 560
 561   *-sun-solaris* \
 562     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 563     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 564     case "${canonical}" in
 565       i[3456]86-*-* )     machine=intel386 ;;
 566       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 567       sparc* )          machine=sparc ;;
 568       * )               unported=yes ;;
 569     esac
 570     case "${canonical}" in
 571       *-sunos5.6* | *-solaris2.6* )
 572                 opsys=sol2-6
 573                 NON_GNU_CPP=/usr/ccs/lib/cpp
 574                 RANLIB="ar -ts"
 575                 ;;
 576       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 577                 opsys=sol2-6
 578                 emacs_check_sunpro_c=yes
 579                 NON_GNU_CPP=/usr/ccs/lib/cpp
 580                 ;;
 581       *-sunos5* | *-solaris* )
 582                 opsys=sol2-10
 583                 emacs_check_sunpro_c=yes
 584                 NON_GNU_CPP=/usr/ccs/lib/cpp
 585                 ;;
 586     esac
 587     ## Watch out for a compiler that we know will not work.
 588     case "${canonical}" in
 589      *-solaris* | *-sunos5* )
 590                 if [ "x$CC" = x/usr/ucb/cc ]; then
 591                   ## /usr/ucb/cc doesn't work;
 592                   ## we should find some other compiler that does work.
 593                   unset CC
 594                 fi
 595                 ;;
 596       *) ;;
 597     esac
 598   ;;
 599
 600   ## IA-64
 601   ia64*-*-linux* )
 602     machine=ia64 opsys=gnu-linux
 603   ;;
 604
 605   ## Intel 386 machines where we don't care about the manufacturer.
 606   i[3456]86-*-* )
 607     machine=intel386
 608     case "${canonical}" in
 609       *-cygwin )                opsys=cygwin ;;
 610       *-darwin* )               opsys=darwin
 611                                 CPP="${CC-cc} -E -no-cpp-precomp"
 612                                 ;;
 613       *-linux-gnu* )            opsys=gnu-linux ;;
 614       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 615       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 616       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 617       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 618     esac
 619   ;;
 620
 621   ## m68k Linux-based GNU system
 622   m68k-*-linux-gnu* )
 623     machine=m68k opsys=gnu-linux
 624   ;;
 625
 626   ## Mips Linux-based GNU system
 627   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 628     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 629     machine=mips opsys=gnu-linux
 630   ;;
 631
 632   ## AMD x86-64 Linux-based GNU system
 633   x86_64-*-linux-gnu* )
 634     machine=amdx86-64 opsys=gnu-linux
 635   ;;
 636
 637   ## Tensilica Xtensa Linux-based GNU system
 638   xtensa*-*-linux-gnu* )
 639     machine=xtensa opsys=gnu-linux
 640     ;;
 641
 642   ## SuperH Linux-based GNU system
 643   sh[34]*-*-linux-gnu* )
 644     machine=sh3 opsys=gnu-linux
 645   ;;
 646
 647   * )
 648     unported=yes
 649   ;;
 650 esac
 651
 652 ### If the code above didn't choose an operating system, just choose
 653 ### an operating system based on the configuration name.  You really
 654 ### only want to use this when you have no idea what the right
 655 ### operating system is; if you know what operating systems a machine
 656 ### runs, it's cleaner to make it explicit in the case statement
 657 ### above.
 658 if test x"${opsys}" = x; then
 659   case "${canonical}" in
 660     *-gnu* )                            opsys=gnu ;;
 661     * )
 662       unported=yes
 663     ;;
 664   esac
 665 fi
 666
 667 ]
 668 dnl quotation ends
 669
 670 if test $unported = yes; then
 671   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 672 Check `etc/MACHINES' for recognized configuration names.])
 673 fi
 674
 675 machfile="m/${machine}.h"
 676 opsysfile="s/${opsys}.h"
 677
 678
 679 #### Choose a compiler.
 680 test -n "$CC" && cc_specified=yes
 681
 682 # Save the value of CFLAGS that the user specified.
 683 SPECIFIED_CFLAGS="$CFLAGS"
 684
 685 dnl Sets GCC=yes if using gcc.
 686 AC_PROG_CC
 687
 688 # On Suns, sometimes $CPP names a directory.
 689 if test -n "$CPP" && test -d "$CPP"; then
 690   CPP=
 691 fi
 692
 693 ## If not using gcc, and on Solaris, and no CPP specified, see if
 694 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 695 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 696  test x"$CPP" = x; then
 697   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 698   AC_CACHE_VAL(emacs_cv_sunpro_c,
 699   [AC_TRY_LINK([],
 700 [#ifndef __SUNPRO_C
 701 fail;
 702 #endif
 703 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 704   AC_MSG_RESULT($emacs_cv_sunpro_c)
 705
 706   if test x"$emacs_cv_sunpro_c" = xyes; then
 707     NON_GNU_CPP="$CC -E -Xs"
 708   fi
 709 fi
 710
 711 #### Some systems specify a CPP to use unless we are using GCC.
 712 #### Now that we know whether we are using GCC, we can decide whether
 713 #### to use that one.
 714 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 715 then
 716   CPP="$NON_GNU_CPP"
 717 fi
 718
 719 #### Some systems specify a CC to use unless we are using GCC.
 720 #### Now that we know whether we are using GCC, we can decide whether
 721 #### to use that one.
 722 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 723   test x$cc_specified != xyes
 724 then
 725   CC="$NON_GNU_CC"
 726 fi
 727
 728 if test x$GCC = xyes; then
 729   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 730 else
 731   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 732 fi
 733
 734 dnl checks for Unix variants
 735 AC_USE_SYSTEM_EXTENSIONS
 736
 737 ### Use -Wno-pointer-sign if the compiler supports it
 738 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 739 SAVE_CFLAGS="$CFLAGS"
 740 CFLAGS="$CFLAGS -Wno-pointer-sign"
 741 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 742 if test $has_option = yes; then
 743    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 744 fi
 745 AC_MSG_RESULT($has_option)
 746 CFLAGS="$SAVE_CFLAGS"
 747 unset has_option
 748 unset SAVE_CFLAGS
 749
 750 ### Use -Wdeclaration-after-statement if the compiler supports it
 751 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 752 SAVE_CFLAGS="$CFLAGS"
 753 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 754 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 755 if test $has_option = yes; then
 756    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 757 fi
 758 AC_MSG_RESULT($has_option)
 759 CFLAGS="$SAVE_CFLAGS"
 760 unset has_option
 761 unset SAVE_CFLAGS
 762
 763 ### Use -Wold-style-definition if the compiler supports it
 764 # This can be removed when conversion to standard C is finished.
 765 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 766 SAVE_CFLAGS="$CFLAGS"
 767 CFLAGS="$CFLAGS -Wold-style-definition"
 768 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 769 if test $has_option = yes; then
 770    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 771 fi
 772 AC_MSG_RESULT($has_option)
 773 CFLAGS="$SAVE_CFLAGS"
 774 unset has_option
 775 unset SAVE_CFLAGS
 776
 777 ### Use -Wimplicit-function-declaration if the compiler supports it
 778 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 779 SAVE_CFLAGS="$CFLAGS"
 780 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 781 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 782 if test $has_option = yes; then
 783    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 784 fi
 785 AC_MSG_RESULT($has_option)
 786 CFLAGS="$SAVE_CFLAGS"
 787 unset has_option
 788 unset SAVE_CFLAGS
 789
 790 AC_SUBST(C_WARNINGS_SWITCH)
 791
 792
 793 #### Some other nice autoconf tests.
 794
 795 dnl checks for programs
 796 AC_PROG_CPP
 797 AC_PROG_INSTALL
 798 if test "x$RANLIB" = x; then
 799   AC_PROG_RANLIB
 800 fi
 801
 802 ## Although we're running on an amd64 kernel, we're actually compiling for
 803 ## the x86 architecture.  The user should probably have provided an
 804 ## explicit --build to `configure', but if everything else than the kernel
 805 ## is running in i386 mode, we can help them out.
 806 if test "$machine" = "amdx86-64"; then
 807   AC_CHECK_DECL([i386])
 808   if test "$ac_cv_have_decl_i386" = "yes"; then
 809     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 810     machine=intel386
 811     machfile="m/${machine}.h"
 812   fi
 813 fi
 814
 815 AC_PATH_PROG(INSTALL_INFO, install-info)
 816 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 817 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 818 dnl Don't use GZIP, which is used by gzip for additional parameters.
 819 AC_PATH_PROG(GZIP_PROG, gzip)
 820
 821
 822 ## Need makeinfo >= 4.6 (?) to build the manuals.
 823 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 824 dnl By this stage, configure has already checked for egrep and set EGREP,
 825 dnl or exited with an error if no egrep was found.
 826 if test "$MAKEINFO" != "no" && \
 827   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 828    MAKEINFO=no
 829 fi
 830
 831 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 832 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 833 ## therefore in the category of "special tools" not normally required, which
 834 ## configure does not have to check for (eg autoconf itself).
 835 ## In a Bazaar checkout on the other hand, the manuals are not included.
 836 ## So makeinfo is a requirement to build from Bazaar, and configure
 837 ## should test for it as it does for any other build requirement.
 838 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 839 ## with pre-built manuals, from a Bazaar checkout.
 840 if test "$MAKEINFO" = "no"; then
 841   if test "x${with_makeinfo}" = "xno"; then
 842     MAKEINFO=off
 843   elif test ! -e $srcdir/info/emacs; then
 844     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 845 source tree does not seem to have pre-built manuals in the `info' directory.
 846 Either install a suitable version of makeinfo, or re-run configure
 847 with the `--without-makeinfo' option to build without the manuals.] )
 848   fi
 849 fi
 850
 851 dnl Add our options to ac_link now, after it is set up.
 852
 853 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 854 then
 855   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 856 fi
 857
 858 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 859 then
 860   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 861 fi
 862
 863 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 864 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 865 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 866 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 867 dnl if not built to support GNU ld.
 868
 869 late_LDFLAGS=$LDFLAGS
 870 if test "$GCC" = yes; then
 871   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 872 else
 873   LDFLAGS="$LDFLAGS -znocombreloc"
 874 fi
 875
 876 AC_MSG_CHECKING([for -znocombreloc])
 877 AC_LINK_IFELSE([main(){return 0;}],
 878   [AC_MSG_RESULT(yes)],
 879   LDFLAGS=$late_LDFLAGS
 880   [AC_MSG_RESULT(no)])
 881
 882
 883 # The value of CPP is a quoted variable reference, so we need to do this
 884 # to get its actual value...
 885 CPP=`eval "echo $CPP"`
 886
 887
 888 dnl Not used by any currently supported platform.
 889 dnl The function dump-emacs will not be defined and temacs will do
 890 dnl (load "loadup") automatically unless told otherwise.
 891 CANNOT_DUMP=no
 892 case "$opsys" in
 893   your-opsys-here)
 894    CANNOT_DUMP=yes
 895    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 896   ;;
 897 esac
 898 AC_SUBST(CANNOT_DUMP)
 899
 900
 901 UNEXEC_OBJ=unexelf.o
 902 case "$opsys" in
 903   # MSDOS uses unexcoff.o
 904   # MSWindows uses unexw32.o
 905   aix4-2)
 906    UNEXEC_OBJ=unexaix.o
 907    ;;
 908   cygwin)
 909    UNEXEC_OBJ=unexcw.o
 910    ;;
 911   darwin)
 912    UNEXEC_OBJ=unexmacosx.o
 913    ;;
 914   hpux10-20 | hpux11)
 915    UNEXEC_OBJ=unexhp9k800.o
 916    ;;
 917   sol2-10)
 918    # Use the Solaris dldump() function, called from unexsol.c, to dump
 919    # emacs, instead of the generic ELF dump code found in unexelf.c.
 920    # The resulting binary has a complete symbol table, and is better
 921    # for debugging and other observability tools (debuggers, pstack, etc).
 922    #
 923    # If you encounter a problem using dldump(), please consider sending
 924    # a message to the OpenSolaris tools-linking mailing list:
 925    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 926    #
 927    # It is likely that dldump() works with older Solaris too, but this has
 928    # not been tested, so for now this change is for Solaris 10 or newer.
 929    UNEXEC_OBJ=unexsol.o
 930    ;;
 931 esac
 932
 933 LD_SWITCH_SYSTEM=
 934 case "$opsys" in
 935   freebsd)
 936    ## Let `ld' find image libs and similar things in /usr/local/lib.
 937    ## The system compiler, GCC, has apparently been modified to not
 938    ## look there, contrary to what a stock GCC would do.
 939    LD_SWITCH_SYSTEM=-L/usr/local/lib
 940    ;;
 941
 942   gnu-linux)
 943    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 944    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 945    ;;
 946
 947   netbsd)
 948    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 949    ;;
 950
 951   openbsd)
 952    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 953    ## otherwise Emacs dumps core on elf systems.
 954    LD_SWITCH_SYSTEM="-Z"
 955    ;;
 956 esac
 957 AC_SUBST(LD_SWITCH_SYSTEM)
 958
 959 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 960
 961 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 962 ## which has not been defined yet.  When this was handled with cpp,
 963 ## it was expanded to null when configure sourced the s/*.h file.
 964 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 965 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 966 ## (or somesuch), but because it is supposed to go at the _front_
 967 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 968 ## Compare with the gnu-linux case below, which added to the end
 969 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 970 ## LD_SWITCH_SYSTEM_TEMACS.
 971 case "$opsys" in
 972   netbsd|openbsd)
 973    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 974    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 975 esac
 976
 977
 978 C_SWITCH_MACHINE=
 979 if test "$machine" = "alpha"; then
 980   AC_CHECK_DECL([__ELF__])
 981   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 982     ## With ELF, make sure that all common symbols get allocated to in the
 983     ## data section.  Otherwise, the dump of temacs may miss variables in
 984     ## the shared library that have been initialized.  For example, with
 985     ## GNU libc, __malloc_initialized would normally be resolved to the
 986     ## shared library's .bss section, which is fatal.
 987     if test "x$GCC" = "xyes"; then
 988       C_SWITCH_MACHINE="-fno-common"
 989     else
 990       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 991     fi
 992   else
 993     UNEXEC_OBJ=unexalpha.o
 994   fi
 995 fi
 996 AC_SUBST(C_SWITCH_MACHINE)
 997
 998 AC_SUBST(UNEXEC_OBJ)
 999
1000 C_SWITCH_SYSTEM=
1001 ## Some programs in src produce warnings saying certain subprograms
1002 ## are too complex and need a MAXMEM value greater than 2000 for
1003 ## additional optimization.  --nils@exp-math.uni-essen.de
1004 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1005   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1006 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1007 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1008 AC_SUBST(C_SWITCH_SYSTEM)
1009
1010
1011 LIBS_SYSTEM=
1012 case "$opsys" in
1013   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1014   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1015
1016   freebsd) LIBS_SYSTEM="-lutil" ;;
1017
1018   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1019
1020   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1021
1022   ## Motif needs -lgen.
1023   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1024 esac
1025 AC_SUBST(LIBS_SYSTEM)
1026
1027
1028 ### Make sure subsequent tests use flags consistent with the build flags.
1029
1030 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1031   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1032 else
1033   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1034 fi
1035
1036 dnl For AC_FUNC_GETLOADAVG, at least:
1037 AC_CONFIG_LIBOBJ_DIR(src)
1038
1039 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1040 AC_SYS_LARGEFILE
1041
1042
1043 ## If user specified a crt-dir, use that unconditionally.
1044 if test "X$CRT_DIR" = "X"; then
1045
1046   case "$canonical" in
1047     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1048     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1049     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1050     ## For anything else (eg /usr/lib32), it is up the user to specify
1051     ## the location (bug#5655).
1052     ## Test for crtn.o, not just the directory, because sometimes the
1053     ## directory exists but does not have the relevant files (bug#1287).
1054     ## FIXME better to test for binary compatibility somehow.
1055     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1056     ;;
1057
1058     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1059   esac
1060
1061   case "$opsys" in
1062     hpux10-20) CRT_DIR=/lib ;;
1063   esac
1064
1065   ## Default is /usr/lib.
1066   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1067
1068 else
1069
1070   ## Some platforms don't use any of these files, so it is not
1071   ## appropriate to put this test outside the if block.
1072   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1073     AC_MSG_ERROR([crt*.o not found in specified location.])
1074
1075 fi
1076
1077 AC_SUBST(CRT_DIR)
1078
1079 LIB_MATH=-lm
1080 LIB_STANDARD=
1081 START_FILES=
1082
1083 case $opsys in
1084   cygwin )
1085     LIB_MATH=
1086     START_FILES='pre-crt0.o'
1087     ;;
1088   darwin )
1089     ## Adding -lm confuses the dynamic linker, so omit it.
1090     LIB_MATH=
1091     START_FILES='pre-crt0.o'
1092     ;;
1093   freebsd )
1094     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1095     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1096     ;;
1097   gnu-linux | gnu-kfreebsd )
1098     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1099     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1100     ;;
1101   hpux10-20 | hpux11 )
1102     LIB_STANDARD=-lc
1103     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1104     ;;
1105   netbsd | openbsd )
1106     if test -f $CRT_DIR/crti.o; then
1107         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1108         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1109     else
1110         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1111         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1112     fi
1113     ;;
1114 esac
1115
1116 AC_SUBST(LIB_MATH)
1117 AC_SUBST(START_FILES)
1118
1119 dnl This function definition taken from Gnome 2.0
1120 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1121 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1122 dnl also defines GSTUFF_PKG_ERRORS on error
1123 AC_DEFUN([PKG_CHECK_MODULES], [
1124   succeeded=no
1125
1126   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1127
1128   if test "$PKG_CONFIG" = "no" ; then
1129      ifelse([$4], , [AC_MSG_ERROR([
1130       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1131   else
1132      PKG_CONFIG_MIN_VERSION=0.9.0
1133      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1134         AC_MSG_CHECKING(for $2)
1135
1136         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1137             AC_MSG_RESULT(yes)
1138             succeeded=yes
1139
1140             AC_MSG_CHECKING($1_CFLAGS)
1141             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1142             AC_MSG_RESULT($$1_CFLAGS)
1143
1144             AC_MSG_CHECKING($1_LIBS)
1145             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1146             AC_MSG_RESULT($$1_LIBS)
1147         else
1148             AC_MSG_RESULT(no)
1149             $1_CFLAGS=""
1150             $1_LIBS=""
1151             ## If we have a custom action on failure, don't print errors, but
1152             ## do set a variable so people can do so.
1153             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1154             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1155         fi
1156
1157         AC_SUBST($1_CFLAGS)
1158         AC_SUBST($1_LIBS)
1159      else
1160         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1161         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1162      fi
1163   fi
1164
1165   if test $succeeded = yes; then
1166      ifelse([$3], , :, [$3])
1167   else
1168      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1169   fi
1170 ])
1171
1172
1173 if test "${with_sound}" != "no"; then
1174   # Sound support for GNU/Linux and the free BSDs.
1175   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1176     have_sound_header=yes)
1177   # Emulation library used on NetBSD.
1178   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1179   AC_SUBST(LIBSOUND)
1180
1181   ALSA_REQUIRED=1.0.0
1182   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1183   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1184   if test $HAVE_ALSA = yes; then
1185     SAVE_CFLAGS="$CFLAGS"
1186     SAVE_LDFLAGS="$LDFLAGS"
1187     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1188     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1189     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1190                     emacs_alsa_normal=yes,
1191                     emacs_alsa_normal=no)
1192     if test "$emacs_alsa_normal" != yes; then
1193       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1194                      [snd_lib_error_set_handler (0);],
1195                      emacs_alsa_subdir=yes,
1196                      emacs_alsa_subdir=no)
1197       if test "$emacs_alsa_subdir" != yes; then
1198         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1199       fi
1200       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1201     fi
1202
1203     CFLAGS="$SAVE_CFLAGS"
1204     LDFLAGS="$SAVE_LDFLAGS"
1205     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1206     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1207     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1208   fi
1209
1210   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1211   dnl compiles only on the specified platforms.  For others, it
1212   dnl probably doesn't make sense to try.
1213   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1214      case "$opsys" in
1215        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1216        gnu-linux|freebsd|netbsd)
1217          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1218          ;;
1219      esac
1220   fi
1221
1222   AC_SUBST(CFLAGS_SOUND)
1223 fi
1224
1225 dnl checks for header files
1226 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1227   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1228   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1229   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1230   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1231
1232 AC_MSG_CHECKING(if personality LINUX32 can be set)
1233 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1234                emacs_cv_personality_linux32=yes,
1235                emacs_cv_personality_linux32=no)
1236 AC_MSG_RESULT($emacs_cv_personality_linux32)
1237
1238 if test $emacs_cv_personality_linux32 = yes; then
1239   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1240             [Define to 1 if personality LINUX32 can be set.])
1241 fi
1242
1243 dnl On Solaris 8 there's a compilation warning for term.h because
1244 dnl it doesn't define `bool'.
1245 AC_CHECK_HEADERS(term.h, , , -)
1246 AC_HEADER_STDC
1247 AC_HEADER_TIME
1248 AC_CHECK_DECLS([sys_siglist])
1249 if test $ac_cv_have_decl_sys_siglist != yes; then
1250   # For Tru64, at least:
1251   AC_CHECK_DECLS([__sys_siglist])
1252   if test $ac_cv_have_decl___sys_siglist = yes; then
1253     AC_DEFINE(sys_siglist, __sys_siglist,
1254               [Define to any substitute for sys_siglist.])
1255   fi
1256 fi
1257 AC_HEADER_SYS_WAIT
1258
1259 dnl Some systems have utime.h but don't declare the struct anyplace.
1260 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1261 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1262 #include <sys/time.h>
1263 #include <time.h>
1264 #else
1265 #ifdef HAVE_SYS_TIME_H
1266 #include <sys/time.h>
1267 #else
1268 #include <time.h>
1269 #endif
1270 #endif
1271 #ifdef HAVE_UTIME_H
1272 #include <utime.h>
1273 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1274   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1275 if test $emacs_cv_struct_utimbuf = yes; then
1276   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1277 fi
1278
1279 dnl checks for typedefs
1280 AC_TYPE_SIGNAL
1281
1282 dnl Check for speed_t typedef.
1283 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1284   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1285     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1286 if test $emacs_cv_speed_t = yes; then
1287   AC_DEFINE(HAVE_SPEED_T, 1,
1288            [Define to 1 if `speed_t' is declared by <termios.h>.])
1289 fi
1290
1291 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1292 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1293 #include <sys/time.h>
1294 #include <time.h>
1295 #else
1296 #ifdef HAVE_SYS_TIME_H
1297 #include <sys/time.h>
1298 #else
1299 #include <time.h>
1300 #endif
1301 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1302   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1303 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1304 if test $emacs_cv_struct_timeval = yes; then
1305   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1306 fi
1307
1308 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1309 AC_TRY_COMPILE([#include <math.h>],
1310 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1311   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1312 HAVE_EXCEPTION=$emacs_cv_struct_exception
1313 if test $emacs_cv_struct_exception != yes; then
1314   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1315 fi
1316
1317 AC_CHECK_HEADERS(sys/socket.h)
1318 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1319 #if HAVE_SYS_SOCKET_H
1320 #include <sys/socket.h>
1321 #endif])
1322
1323 dnl checks for structure members
1324 AC_STRUCT_TM
1325 AC_STRUCT_TIMEZONE
1326 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1327                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1328                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1329                 [#include <time.h>])
1330 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1331                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1332                   struct ifreq.ifr_addr], , ,
1333                  [AC_INCLUDES_DEFAULT
1334 #if HAVE_SYS_SOCKET_H
1335 #include <sys/socket.h>
1336 #endif
1337 #if HAVE_NET_IF_H
1338 #include <net/if.h>
1339 #endif])
1340
1341 dnl checks for compiler characteristics
1342
1343 dnl Testing __STDC__ to determine prototype support isn't good enough.
1344 dnl DEC C, for instance, doesn't define it with default options, and
1345 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1346 dnl and void *.
1347 AC_C_PROTOTYPES
1348 AC_C_VOLATILE
1349 AC_C_CONST
1350 dnl This isn't useful because we can't turn on use of `inline' unless
1351 dnl the compiler groks `extern inline'.
1352 dnl AC_C_INLINE
1353 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1354   [AC_TRY_COMPILE(, [void * foo;],
1355                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1356 if test $emacs_cv_void_star = yes; then
1357   AC_DEFINE(POINTER_TYPE, void)
1358 else
1359   AC_DEFINE(POINTER_TYPE, char)
1360 fi
1361 AH_TEMPLATE(POINTER_TYPE,
1362             [Define as `void' if your compiler accepts `void *'; otherwise
1363              define as `char'.])dnl
1364
1365 dnl Check for endianess
1366 AC_C_BIGENDIAN
1367
1368 dnl check for Make feature
1369 AC_PROG_MAKE_SET
1370
1371 DEPFLAGS=
1372 MKDEPDIR=":"
1373 deps_frag=deps.mk
1374 dnl check for GNU Make if we have GCC and autodepend is on.
1375 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1376    AC_MSG_CHECKING([whether we are using GNU Make])
1377    HAVE_GNU_MAKE=no
1378    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1379    if test "x$testval" != x; then
1380       HAVE_GNU_MAKE=yes
1381    else
1382       ac_enable_autodepend=no
1383    fi
1384    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1385    if test $HAVE_GNU_MAKE = yes; then
1386       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1387       SAVE_CFLAGS="$CFLAGS"
1388       CFLAGS="$CFLAGS -MMD -MF deps.d"
1389       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1390       CFLAGS="$SAVE_CFLAGS"
1391       test -f deps.d || ac_enable_autodepend=no
1392       rm -rf deps.d
1393       AC_MSG_RESULT([$ac_enable_autodepend])
1394    fi
1395    if test $ac_enable_autodepend = yes; then
1396       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1397       ## In parallel builds, another make might create depdir between
1398       ## the first test and mkdir, so stick another test on the end.
1399       ## Or use mkinstalldirs?  mkdir -p is not portable.
1400       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1401       deps_frag=autodeps.mk
1402    fi
1403 fi
1404 deps_frag=$srcdir/src/$deps_frag
1405 AC_SUBST(MKDEPDIR)
1406 AC_SUBST(DEPFLAGS)
1407 AC_SUBST_FILE(deps_frag)
1408
1409
1410 dnl checks for operating system services
1411 AC_SYS_LONG_FILE_NAMES
1412
1413 #### Choose a window system.
1414
1415 AC_PATH_X
1416 if test "$no_x" = yes; then
1417   window_system=none
1418 else
1419   window_system=x11
1420 fi
1421
1422 ## Workaround for bug in autoconf <= 2.62.
1423 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1424 ## No need to do anything special for these standard directories.
1425 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1426
1427    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1428
1429 fi
1430
1431 LD_SWITCH_X_SITE_AUX=
1432 LD_SWITCH_X_SITE_AUX_RPATH=
1433 if test "${x_libraries}" != NONE; then
1434   if test -n "${x_libraries}"; then
1435     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1436     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1437     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1438   fi
1439   x_default_search_path=""
1440   x_search_path=${x_libraries}
1441   if test -z "${x_search_path}"; then
1442     x_search_path=/usr/lib
1443   fi
1444   for x_library in `echo ${x_search_path}: | \
1445                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1446     x_search_path="\
1447 ${x_library}/X11/%L/%T/%N%C%S:\
1448 ${x_library}/X11/%l/%T/%N%C%S:\
1449 ${x_library}/X11/%T/%N%C%S:\
1450 ${x_library}/X11/%L/%T/%N%S:\
1451 ${x_library}/X11/%l/%T/%N%S:\
1452 ${x_library}/X11/%T/%N%S"
1453     if test x"${x_default_search_path}" = x; then
1454       x_default_search_path=${x_search_path}
1455     else
1456       x_default_search_path="${x_search_path}:${x_default_search_path}"
1457     fi
1458   done
1459 fi
1460 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1461 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1462
1463 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1464   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1465 fi
1466
1467 if test x"${x_includes}" = x; then
1468   bitmapdir=/usr/include/X11/bitmaps
1469 else
1470   # accumulate include directories that have X11 bitmap subdirectories
1471   bmd_acc="dummyval"
1472   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1473     if test -d "${bmd}/X11/bitmaps"; then
1474       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1475     fi
1476     if test -d "${bmd}/bitmaps"; then
1477       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1478     fi
1479   done
1480   if test ${bmd_acc} != "dummyval"; then
1481     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1482   fi
1483 fi
1484
1485 HAVE_NS=no
1486 NS_IMPL_COCOA=no
1487 NS_IMPL_GNUSTEP=no
1488 tmp_CPPFLAGS="$CPPFLAGS"
1489 tmp_CFLAGS="$CFLAGS"
1490 CPPFLAGS="$CPPFLAGS -x objective-c"
1491 CFLAGS="$CFLAGS -x objective-c"
1492 TEMACS_LDFLAGS2="\${LDFLAGS} \${PROFILING_LDFLAGS}"
1493 dnl I don't think it's especially important, but src/Makefile.in
1494 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1495 dnl trailing "/" to it, so now we do it here.
1496 if test "${with_ns}" != no; then
1497   if test "${opsys}" = darwin; then
1498      NS_IMPL_COCOA=yes
1499      ns_appdir=`pwd`/nextstep/Emacs.app/
1500      ns_appbindir=${ns_appdir}Contents/MacOS/
1501      ns_appresdir=${ns_appdir}Contents/Resources
1502      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1503   elif test -f $GNUSTEP_CONFIG_FILE; then
1504      NS_IMPL_GNUSTEP=yes
1505      ns_appdir=`pwd`/nextstep/Emacs.app/
1506      ns_appbindir=${ns_appdir}
1507      ns_appresdir=${ns_appdir}Resources
1508      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1509      dnl FIXME sourcing this several times in subshells seems inefficient.
1510      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1511      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1512      dnl I seemed to need these as well with GNUstep-startup 0.25.
1513      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1514      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1515      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1516        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1517      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1518        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1519      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1520      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1521      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1522      LIB_STANDARD=
1523      START_FILES=
1524      TEMACS_LDFLAGS2=
1525   fi
1526   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1527                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1528   files are missing or cannot be compiled.])])
1529   NS_HAVE_NSINTEGER=yes
1530   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1531                                      [NSInteger i;])],
1532                     ns_have_nsinteger=yes,
1533                     ns_have_nsinteger=no)
1534   if test $ns_have_nsinteger = no; then
1535     NS_HAVE_NSINTEGER=no
1536   fi
1537 fi
1538 AC_SUBST(TEMACS_LDFLAGS2)
1539
1540 ns_frag=/dev/null
1541 NS_OBJ=
1542 NS_SUPPORT=
1543 if test "${HAVE_NS}" = yes; then
1544   window_system=nextstep
1545   with_xft=no
1546   # set up packaging dirs
1547   exec_prefix=${ns_appbindir}
1548   libexecdir=${ns_appbindir}/libexec
1549   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1550      prefix=${ns_appresdir}
1551   fi
1552   ns_frag=$srcdir/src/ns.mk
1553   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1554   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1555 fi
1556 CFLAGS="$tmp_CFLAGS"
1557 CPPFLAGS="$tmp_CPPFLAGS"
1558 AC_SUBST(NS_OBJ)
1559 AC_SUBST(NS_SUPPORT)
1560 AC_SUBST(LIB_STANDARD)
1561 AC_SUBST_FILE(ns_frag)
1562
1563 case "${window_system}" in
1564   x11 )
1565     HAVE_X_WINDOWS=yes
1566     HAVE_X11=yes
1567     case "${with_x_toolkit}" in
1568       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1569       motif ) USE_X_TOOLKIT=MOTIF ;;
1570       gtk ) with_gtk=yes
1571 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1572 dnl USE_X_TOOLKIT is set.
1573             USE_X_TOOLKIT=none ;;
1574       gtk3 ) with_gtk3=yes
1575              USE_X_TOOLKIT=none ;;
1576       no ) USE_X_TOOLKIT=none ;;
1577 dnl If user did not say whether to use a toolkit, make this decision later:
1578 dnl use the toolkit if we have gtk, or X11R5 or newer.
1579       * ) USE_X_TOOLKIT=maybe ;;
1580     esac
1581   ;;
1582   nextstep | none )
1583     HAVE_X_WINDOWS=no
1584     HAVE_X11=no
1585     USE_X_TOOLKIT=none
1586   ;;
1587 esac
1588
1589 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1590    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1591    if test "$HAVE_XSERVER" = true ||
1592       test -n "$DISPLAY" ||
1593       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1594         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1595 were found.  You should install the relevant development files for X
1596 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1597 sure you have development files for image handling, i.e.
1598 tiff, gif, jpeg, png and xpm.
1599 If you are sure you want Emacs compiled without X window support, pass
1600   --without-x
1601 to configure.])
1602    fi
1603 fi
1604
1605 ### If we're using X11, we should use the X menu package.
1606 HAVE_MENUS=no
1607 case ${HAVE_X11} in
1608   yes ) HAVE_MENUS=yes ;;
1609 esac
1610
1611 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1612 # Assume not, until told otherwise.
1613 GNU_MALLOC=yes
1614 doug_lea_malloc=yes
1615 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1616 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1617 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1618                emacs_cv_var___after_morecore_hook,
1619 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1620   emacs_cv_var___after_morecore_hook=yes,
1621   emacs_cv_var___after_morecore_hook=no)])
1622 if test $emacs_cv_var___after_morecore_hook = no; then
1623   doug_lea_malloc=no
1624 fi
1625
1626
1627 dnl See comments in aix4-2.h about maybe using system malloc there.
1628 system_malloc=no
1629 case "$opsys" in
1630   ## darwin ld insists on the use of malloc routines in the System framework.
1631   darwin|sol2-10) system_malloc=yes ;;
1632 esac
1633
1634 if test "${system_malloc}" = "yes"; then
1635   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1636   GNU_MALLOC=no
1637   GNU_MALLOC_reason="
1638     (The GNU allocators don't work with this system configuration.)"
1639   GMALLOC_OBJ=
1640   VMLIMIT_OBJ=
1641 else
1642   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1643   VMLIMIT_OBJ=vm-limit.o
1644 fi
1645 AC_SUBST(GMALLOC_OBJ)
1646 AC_SUBST(VMLIMIT_OBJ)
1647
1648 if test "$doug_lea_malloc" = "yes" ; then
1649   if test "$GNU_MALLOC" = yes ; then
1650     GNU_MALLOC_reason="
1651       (Using Doug Lea's new malloc from the GNU C Library.)"
1652   fi
1653   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1654             [Define to 1 if you are using the GNU C Library.])
1655
1656   ## Use mmap directly for allocating larger buffers.
1657   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1658   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1659   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1660   case "$opsys" in
1661     gnu*) REL_ALLOC=no ;;
1662   esac
1663 fi
1664
1665 if test x"${REL_ALLOC}" = x; then
1666   REL_ALLOC=${GNU_MALLOC}
1667 fi
1668
1669 use_mmap_for_buffers=no
1670 case "$opsys" in
1671   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1672 esac
1673
1674 AC_FUNC_MMAP
1675 if test $use_mmap_for_buffers = yes; then
1676   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1677   REL_ALLOC=no
1678 fi
1679
1680 LIBS="$LIBS_SYSTEM $LIBS"
1681
1682 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1683 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1684 AC_CHECK_LIB(dnet, dnet_ntoa)
1685 dnl This causes -lresolv to get used in subsequent tests,
1686 dnl which causes failures on some systems such as HPUX 9.
1687 dnl AC_CHECK_LIB(resolv, gethostbyname)
1688
1689 dnl FIXME replace main with a function we actually want from this library.
1690 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1691
1692 AC_CHECK_LIB(pthreads, cma_open)
1693
1694 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1695 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1696 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1697 ## added to LIBS in configure would never contain the pthreads part,
1698 ## but the value used in Makefiles might.  FIXME?
1699 ##
1700 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1701 ## be harmless on older versions of X where it happens to exist.
1702 test "$opsys" = "aix4-2" && \
1703   test $ac_cv_lib_pthreads_cma_open = yes && \
1704   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1705
1706 dnl Check for need for bigtoc support on IBM AIX
1707
1708 case ${host_os} in
1709 aix*)
1710   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1711     case $GCC in
1712     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1713     *) gdb_cv_bigtoc=-bbigtoc ;;
1714     esac
1715
1716     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1717     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1718   ])
1719   ;;
1720 esac
1721
1722 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1723 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1724 # REAL_CPPFLAGS later on.
1725
1726 REAL_CFLAGS="$CFLAGS"
1727 REAL_CPPFLAGS="$CPPFLAGS"
1728
1729 if test "${HAVE_X11}" = "yes"; then
1730   DEFS="$C_SWITCH_X_SITE $DEFS"
1731   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1732   LIBS="-lX11 $LIBS"
1733   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1734   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1735
1736   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1737   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1738   # but it's more convenient here to set LD_RUN_PATH
1739   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1740   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1741     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1742     export LD_RUN_PATH
1743   fi
1744
1745   if test "${opsys}" = "gnu-linux"; then
1746     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1747     AC_TRY_LINK([],
1748      [XOpenDisplay ("foo");],
1749      [xlinux_first_failure=no],
1750      [xlinux_first_failure=yes])
1751     if test "${xlinux_first_failure}" = "yes"; then
1752       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1753       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1754       OLD_CPPFLAGS="$CPPFLAGS"
1755       OLD_LIBS="$LIBS"
1756       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1757       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1758       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1759       LIBS="$LIBS -b i486-linuxaout"
1760       AC_TRY_LINK([],
1761        [XOpenDisplay ("foo");],
1762        [xlinux_second_failure=no],
1763        [xlinux_second_failure=yes])
1764       if test "${xlinux_second_failure}" = "yes"; then
1765         # If we get the same failure with -b, there is no use adding -b.
1766         # So take it out.  This plays safe.
1767         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1768         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1769         CPPFLAGS="$OLD_CPPFLAGS"
1770         LIBS="$OLD_LIBS"
1771         AC_MSG_RESULT(no)
1772       else
1773         AC_MSG_RESULT(yes)
1774       fi
1775     else
1776       AC_MSG_RESULT(no)
1777     fi
1778   fi
1779
1780   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1781   # header files included from there.
1782   AC_MSG_CHECKING(for Xkb)
1783   AC_TRY_LINK([#include <X11/Xlib.h>
1784 #include <X11/XKBlib.h>],
1785         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1786         emacs_xkb=yes, emacs_xkb=no)
1787   AC_MSG_RESULT($emacs_xkb)
1788   if test $emacs_xkb = yes; then
1789     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1790   fi
1791
1792   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1793 XScreenNumberOfScreen XSetWMProtocols)
1794 fi
1795
1796 if test "${window_system}" = "x11"; then
1797   AC_MSG_CHECKING(X11 version 6)
1798   AC_CACHE_VAL(emacs_cv_x11_version_6,
1799   [AC_TRY_LINK([#include <X11/Xlib.h>],
1800 [#if XlibSpecificationRelease < 6
1801 fail;
1802 #endif
1803 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1804   if test $emacs_cv_x11_version_6 = yes; then
1805     AC_MSG_RESULT(6 or newer)
1806     AC_DEFINE(HAVE_X11R6, 1,
1807               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1808     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1809     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1810     ## XIM support.
1811     case "$opsys" in
1812       sol2-*) : ;;
1813       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1814            [Define if you have usable X11R6-style XIM support.])
1815          ;;
1816     esac
1817   else
1818     AC_MSG_RESULT(before 6)
1819   fi
1820 fi
1821
1822
1823 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1824 HAVE_RSVG=no
1825 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1826   if test "${with_rsvg}" != "no"; then
1827     RSVG_REQUIRED=2.11.0
1828     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1829
1830     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1831     AC_SUBST(RSVG_CFLAGS)
1832     AC_SUBST(RSVG_LIBS)
1833
1834     if test $HAVE_RSVG = yes; then
1835       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1836       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1837       LIBS="$RSVG_LIBS $LIBS"
1838     fi
1839   fi
1840 fi
1841
1842 HAVE_IMAGEMAGICK=no
1843 if test "${HAVE_X11}" = "yes"; then
1844   if test "${with_imagemagick}" != "no"; then
1845     IMAGEMAGICK_MODULE="Wand"
1846     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1847     AC_SUBST(IMAGEMAGICK_CFLAGS)
1848     AC_SUBST(IMAGEMAGICK_LIBS)
1849
1850     if test $HAVE_IMAGEMAGICK = yes; then
1851       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1852       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1853       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1854       AC_CHECK_FUNCS(MagickExportImagePixels)
1855     fi
1856   fi
1857 fi
1858
1859
1860 HAVE_GTK=no
1861 if test "${with_gtk3}" = "yes"; then
1862   GLIB_REQUIRED=2.6
1863   GTK_REQUIRED=2.90
1864   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1865
1866   dnl Checks for libraries.
1867   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1868   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1869      AC_MSG_ERROR($GTK_PKG_ERRORS)
1870   fi
1871 fi
1872
1873 if test "$pkg_check_gtk" != "yes"; then
1874   HAVE_GTK=no
1875 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1876   GLIB_REQUIRED=2.6
1877   GTK_REQUIRED=2.6
1878   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1879
1880   dnl Checks for libraries.
1881   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1882   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1883      AC_MSG_ERROR($GTK_PKG_ERRORS)
1884   fi
1885 fi
1886 fi
1887
1888 GTK_OBJ=
1889 if test x"$pkg_check_gtk" = xyes; then
1890
1891   AC_SUBST(GTK_CFLAGS)
1892   AC_SUBST(GTK_LIBS)
1893   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1894   CFLAGS="$CFLAGS $GTK_CFLAGS"
1895   LIBS="$GTK_LIBS $LIBS"
1896   dnl Try to compile a simple GTK program.
1897   GTK_COMPILES=no
1898   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1899   if test "${GTK_COMPILES}" != "yes"; then
1900     if test "$USE_X_TOOLKIT" != "maybe"; then
1901       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1902     fi
1903   else
1904     HAVE_GTK=yes
1905     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1906     GTK_OBJ=gtkutil.o
1907     USE_X_TOOLKIT=none
1908     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1909       :
1910     else
1911       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1912        closing open displays.  This is no problem if you just use
1913        one display, but if you use more than one and close one of them
1914        Emacs may crash.]])
1915       sleep 3
1916     fi
1917   fi
1918
1919 fi
1920 AC_SUBST(GTK_OBJ)
1921
1922
1923 if test "${HAVE_GTK}" = "yes"; then
1924
1925   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1926   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1927   if test "$with_toolkit_scroll_bars" != no; then
1928     with_toolkit_scroll_bars=yes
1929   fi
1930
1931   dnl  Check if we have the old file selection dialog declared and
1932   dnl  in the link library.  In 2.x it may be in the library,
1933   dnl  but not declared if deprecated featured has been selected out.
1934   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1935   HAVE_GTK_FILE_SELECTION=no
1936   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1937                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1938 #include <gtk/gtk.h>])
1939   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1940     AC_CHECK_FUNCS(gtk_file_selection_new)
1941   fi
1942
1943   dnl Check if pthreads are available.  Emacs only needs this when using
1944   dnl gtk_file_chooser under Gnome.
1945     HAVE_GTK_AND_PTHREAD=no
1946     AC_CHECK_HEADERS(pthread.h)
1947     if test "$ac_cv_header_pthread_h"; then
1948       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1949     fi
1950     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1951       case "${canonical}" in
1952         *-hpux*) ;;
1953         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1954       esac
1955       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1956                [Define to 1 if you have GTK and pthread (-lpthread).])
1957     fi
1958
1959   dnl Check for functions introduced in 2.14 and later.
1960   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1961                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1962                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1963                  gtk_orientable_set_orientation)
1964
1965 fi
1966
1967 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1968 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1969 dnl also not configured.
1970 HAVE_DBUS=no
1971 DBUS_OBJ=
1972 if test "${with_dbus}" = "yes"; then
1973    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1974    if test "$HAVE_DBUS" = yes; then
1975      LIBS="$LIBS $DBUS_LIBS"
1976      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1977      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1978      DBUS_OBJ=dbusbind.o
1979    fi
1980 fi
1981 AC_SUBST(DBUS_OBJ)
1982
1983 dnl GConf has been tested under GNU/Linux only.
1984 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1985 HAVE_GCONF=no
1986 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1987    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1988    if test "$HAVE_GCONF" = yes; then
1989       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1990    fi
1991 fi
1992
1993 dnl SELinux is available for GNU/Linux only.
1994 HAVE_LIBSELINUX=no
1995 LIBSELINUX_LIBS=
1996 if test "${with_selinux}" = "yes"; then
1997    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1998    if test "$HAVE_LIBSELINUX" = yes; then
1999       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2000       LIBSELINUX_LIBS=-lselinux
2001    fi
2002 fi
2003 AC_SUBST(LIBSELINUX_LIBS)
2004
2005 HAVE_GNUTLS=no
2006 if test "${with_gnutls}" = "yes" ; then
2007   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2008   if test "${HAVE_GNUTLS}" = "yes"; then
2009     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2010   fi
2011 fi
2012 AC_SUBST(LIBGNUTLS_LIBS)
2013 AC_SUBST(LIBGNUTLS_CFLAGS)
2014
2015 dnl Do not put whitespace before the #include statements below.
2016 dnl Older compilers (eg sunos4 cc) choke on it.
2017 HAVE_XAW3D=no
2018 LUCID_LIBW=
2019 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2020   if test "$with_xaw3d" != no; then
2021     AC_MSG_CHECKING(for xaw3d)
2022     AC_CACHE_VAL(emacs_cv_xaw3d,
2023     [AC_TRY_LINK([
2024 #include <X11/Intrinsic.h>
2025 #include <X11/Xaw3d/Simple.h>],
2026       [],
2027       emacs_cv_xaw3d=yes,
2028       emacs_cv_xaw3d=no)])
2029   else
2030     emacs_cv_xaw3d=no
2031   fi
2032   if test $emacs_cv_xaw3d = yes; then
2033     AC_MSG_RESULT([yes; using Lucid toolkit])
2034     USE_X_TOOLKIT=LUCID
2035     HAVE_XAW3D=yes
2036     LUCID_LIBW=-lXaw3d
2037     AC_DEFINE(HAVE_XAW3D, 1,
2038               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2039   else
2040     AC_MSG_RESULT(no)
2041     AC_MSG_CHECKING(for libXaw)
2042     AC_CACHE_VAL(emacs_cv_xaw,
2043     [AC_TRY_LINK([
2044 #include <X11/Intrinsic.h>
2045 #include <X11/Xaw/Simple.h>],
2046       [],
2047       emacs_cv_xaw=yes,
2048       emacs_cv_xaw=no)])
2049     if test $emacs_cv_xaw = yes; then
2050       AC_MSG_RESULT([yes; using Lucid toolkit])
2051       USE_X_TOOLKIT=LUCID
2052       LUCID_LIBW=-lXaw
2053     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2054       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2055     else
2056       AC_MSG_RESULT([no; do not use toolkit by default])
2057       USE_X_TOOLKIT=none
2058     fi
2059   fi
2060 fi
2061
2062 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2063
2064 LIBXTR6=
2065 if test "${USE_X_TOOLKIT}" != "none"; then
2066   AC_MSG_CHECKING(X11 toolkit version)
2067   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2068   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2069 [#if XtSpecificationRelease < 6
2070 fail;
2071 #endif
2072 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2073   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2074   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2075     AC_MSG_RESULT(6 or newer)
2076     AC_DEFINE(HAVE_X11XTR6, 1,
2077               [Define to 1 if you have the X11R6 or newer version of Xt.])
2078     LIBXTR6="-lSM -lICE"
2079     case "$opsys" in
2080       ## Use libw.a along with X11R6 Xt.
2081       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2082     esac
2083   else
2084     AC_MSG_RESULT(before 6)
2085   fi
2086
2087 dnl If using toolkit, check whether libXmu.a exists.
2088 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2089   OLDLIBS="$LIBS"
2090   if test x$HAVE_X11XTR6 = xyes; then
2091     LIBS="-lXt -lSM -lICE $LIBS"
2092   else
2093     LIBS="-lXt $LIBS"
2094   fi
2095   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2096   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2097 fi
2098 AC_SUBST(LIBXTR6)
2099
2100 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2101 dnl Why not just test for libxmu in the normal way?
2102 LIBXMU=-lXmu
2103 case "$machine" in
2104   ## These machines don't supply Xmu.
2105   hpux* | aix4-2 )
2106     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2107     ;;
2108 esac
2109 AC_SUBST(LIBXMU)
2110
2111 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2112 if test "${HAVE_X11}" = "yes"; then
2113   if test "${USE_X_TOOLKIT}" != "none"; then
2114     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2115   fi
2116 fi
2117
2118 LIBXP=
2119 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2120   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2121   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2122     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2123 int x = 5;
2124 #else
2125 Motif version prior to 2.1.
2126 #endif],
2127     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2128   if test $emacs_cv_motif_version_2_1 = yes; then
2129     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2130   else
2131     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2132     # We put this in CFLAGS temporarily to precede other -I options
2133     # that might be in CFLAGS temporarily.
2134     # We put this in CPPFLAGS where it precedes the other -I options.
2135     OLD_CPPFLAGS=$CPPFLAGS
2136     OLD_CFLAGS=$CFLAGS
2137     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2138     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2139     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2140       [int x = 5;],
2141       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2142     if test $emacs_cv_lesstif = yes; then
2143       # Make sure this -I option remains in CPPFLAGS after it is set
2144       # back to REAL_CPPFLAGS.
2145       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2146       # have those other -I options anyway.  Ultimately, having this
2147       # directory ultimately in CPPFLAGS will be enough.
2148       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2149       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2150     else
2151       CFLAGS=$OLD_CFLAGS
2152       CPPFLAGS=$OLD_CPPFLAGS
2153     fi
2154   fi
2155 fi
2156
2157 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2158 dnl using Motif or Xaw3d is available, and unless
2159 dnl --with-toolkit-scroll-bars=no was specified.
2160
2161 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2162             [Define to 1 if we should use toolkit scroll bars.])dnl
2163 USE_TOOLKIT_SCROLL_BARS=no
2164 if test "${with_toolkit_scroll_bars}" != "no"; then
2165   if test "${USE_X_TOOLKIT}" != "none"; then
2166     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2167       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2168       HAVE_XAW3D=no
2169       USE_TOOLKIT_SCROLL_BARS=yes
2170     elif test "${HAVE_XAW3D}" = "yes"; then
2171       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2172       USE_TOOLKIT_SCROLL_BARS=yes
2173     fi
2174   elif test "${HAVE_GTK}" = "yes"; then
2175     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2176     USE_TOOLKIT_SCROLL_BARS=yes
2177   elif test "${HAVE_NS}" = "yes"; then
2178     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2179     USE_TOOLKIT_SCROLL_BARS=yes
2180   fi
2181 fi
2182
2183 dnl See if XIM is available.
2184 AC_TRY_COMPILE([
2185           #include <X11/Xlib.h>
2186           #include <X11/Xresource.h>],
2187          [XIMProc  callback;],
2188          [HAVE_XIM=yes
2189          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2190          HAVE_XIM=no)
2191
2192 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2193
2194 if test "${with_xim}" != "no"; then
2195   AC_DEFINE(USE_XIM, 1,
2196             [Define to 1 if we should use XIM, if it is available.])
2197 fi
2198
2199
2200 if test "${HAVE_XIM}" != "no"; then
2201   late_CFLAGS=$CFLAGS
2202   if test "$GCC" = yes; then
2203     CFLAGS="$CFLAGS --pedantic-errors"
2204   fi
2205   AC_TRY_COMPILE([
2206 #include <X11/Xlib.h>
2207 #include <X11/Xresource.h>],
2208 [Display *display;
2209 XrmDatabase db;
2210 char *res_name;
2211 char *res_class;
2212 XIMProc  callback;
2213 XPointer *client_data;
2214 #ifndef __GNUC__
2215 /* If we're not using GCC, it's probably not XFree86, and this is
2216    probably right, but we can't use something like --pedantic-errors.  */
2217 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2218                                            char*, XIMProc, XPointer*);
2219 #endif
2220 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2221    client_data);],
2222     [emacs_cv_arg6_star=yes])
2223   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2224          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2225 either XPointer or XPointer*.])dnl
2226   if test "$emacs_cv_arg6_star" = yes; then
2227     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2228   else
2229     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2230   fi
2231   CFLAGS=$late_CFLAGS
2232 fi
2233
2234 ### Start of font-backend (under any platform) section.
2235 # (nothing here yet -- this is a placeholder)
2236 ### End of font-backend (under any platform) section.
2237
2238 ### Start of font-backend (under X11) section.
2239 if test "${HAVE_X11}" = "yes"; then
2240    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2241
2242    ## Use -lXft if available, unless `--with-xft=no'.
2243    HAVE_XFT=maybe
2244     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2245       with_xft="no";
2246     fi
2247     if test "x${with_xft}" != "xno"; then
2248
2249       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2250       ## Because xftfont.c uses XRenderQueryExtension, we also
2251       ## need to link to -lXrender.
2252       HAVE_XRENDER=no
2253       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2254       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2255         OLD_CPPFLAGS="$CPPFLAGS"
2256         OLD_CFLAGS="$CFLAGS"
2257         OLD_LIBS="$LIBS"
2258         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2259         CFLAGS="$CFLAGS $XFT_CFLAGS"
2260         XFT_LIBS="-lXrender $XFT_LIBS"
2261         LIBS="$XFT_LIBS $LIBS"
2262         AC_CHECK_HEADER(X11/Xft/Xft.h,
2263           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2264
2265         if test "${HAVE_XFT}" = "yes"; then
2266           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2267             AC_SUBST(XFT_LIBS)
2268           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2269         else
2270           CPPFLAGS="$OLD_CPPFLAGS"
2271           CFLAGS="$OLD_CFLAGS"
2272           LIBS="$OLD_LIBS"
2273         fi                        # "${HAVE_XFT}" = "yes"
2274       fi                          # "$HAVE_XFT" != no
2275     fi                            # "x${with_xft}" != "xno"
2276
2277     dnl For the "Does Emacs use" message at the end.
2278     if test "$HAVE_XFT" != "yes"; then
2279        HAVE_XFT=no
2280     fi
2281
2282
2283     HAVE_FREETYPE=no
2284     ## We used to allow building with FreeType and without Xft.
2285     ## However, the ftx font backend driver is not in good shape.
2286     if test "${HAVE_XFT}" = "yes"; then
2287       dnl As we use Xft, we anyway use freetype.
2288       dnl There's no need for additional CFLAGS and LIBS.
2289       HAVE_FREETYPE=yes
2290       FONTCONFIG_CFLAGS=
2291       FONTCONFIG_LIBS=
2292     fi
2293
2294     HAVE_LIBOTF=no
2295     if test "${HAVE_FREETYPE}" = "yes"; then
2296       AC_DEFINE(HAVE_FREETYPE, 1,
2297                 [Define to 1 if using the freetype and fontconfig libraries.])
2298       if test "${with_libotf}" != "no"; then
2299         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2300                           HAVE_LIBOTF=no)
2301         if test "$HAVE_LIBOTF" = "yes"; then
2302           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2303           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2304                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2305                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2306           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2307             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2308                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2309           fi
2310         fi
2311       fi
2312     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2313     dnl Does the new font backend require it, or can it work without it?
2314     fi
2315
2316     HAVE_M17N_FLT=no
2317     if test "${HAVE_LIBOTF}" = yes; then
2318       if test "${with_m17n_flt}" != "no"; then
2319         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2320         if test "$HAVE_M17N_FLT" = "yes"; then
2321           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2322         fi
2323       fi
2324     fi
2325 else
2326     HAVE_XFT=no
2327     HAVE_FREETYPE=no
2328     HAVE_LIBOTF=no
2329     HAVE_M17N_FLT=no
2330 fi
2331
2332 ### End of font-backend (under X11) section.
2333
2334 AC_SUBST(FREETYPE_CFLAGS)
2335 AC_SUBST(FREETYPE_LIBS)
2336 AC_SUBST(FONTCONFIG_CFLAGS)
2337 AC_SUBST(FONTCONFIG_LIBS)
2338 AC_SUBST(LIBOTF_CFLAGS)
2339 AC_SUBST(LIBOTF_LIBS)
2340 AC_SUBST(M17N_FLT_CFLAGS)
2341 AC_SUBST(M17N_FLT_LIBS)
2342
2343 ### Use -lXpm if available, unless `--with-xpm=no'.
2344 HAVE_XPM=no
2345 LIBXPM=
2346 if test "${HAVE_X11}" = "yes"; then
2347   if test "${with_xpm}" != "no"; then
2348     AC_CHECK_HEADER(X11/xpm.h,
2349       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2350     if test "${HAVE_XPM}" = "yes"; then
2351       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2352       AC_EGREP_CPP(no_return_alloc_pixels,
2353       [#include "X11/xpm.h"
2354 #ifndef XpmReturnAllocPixels
2355 no_return_alloc_pixels
2356 #endif
2357       ], HAVE_XPM=no, HAVE_XPM=yes)
2358
2359       if test "${HAVE_XPM}" = "yes"; then
2360         AC_MSG_RESULT(yes)
2361       else
2362         AC_MSG_RESULT(no)
2363       fi
2364     fi
2365   fi
2366
2367   if test "${HAVE_XPM}" = "yes"; then
2368     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2369     LIBXPM=-lXpm
2370   fi
2371 fi
2372 AC_SUBST(LIBXPM)
2373
2374 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2375 HAVE_JPEG=no
2376 LIBJPEG=
2377 if test "${HAVE_X11}" = "yes"; then
2378   if test "${with_jpeg}" != "no"; then
2379     dnl Checking for jpeglib.h can lose because of a redefinition of
2380     dnl  HAVE_STDLIB_H.
2381     AC_CHECK_HEADER(jerror.h,
2382       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2383   fi
2384
2385   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2386   if test "${HAVE_JPEG}" = "yes"; then
2387     AC_DEFINE(HAVE_JPEG)
2388     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2389         [#include <jpeglib.h>
2390          version=JPEG_LIB_VERSION
2391 ],
2392         [AC_DEFINE(HAVE_JPEG)],
2393         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2394         HAVE_JPEG=no])
2395   fi
2396   if test "${HAVE_JPEG}" = "yes"; then
2397     LIBJPEG=-ljpeg
2398   fi
2399 fi
2400 AC_SUBST(LIBJPEG)
2401
2402 ### Use -lpng if available, unless `--with-png=no'.
2403 HAVE_PNG=no
2404 LIBPNG=
2405 if test "${HAVE_X11}" = "yes"; then
2406   if test "${with_png}" != "no"; then
2407     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2408     # in /usr/include/libpng.
2409     AC_CHECK_HEADERS(png.h libpng/png.h)
2410     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2411       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2412     fi
2413   fi
2414
2415   if test "${HAVE_PNG}" = "yes"; then
2416     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2417     LIBPNG="-lpng -lz -lm"
2418   fi
2419 fi
2420 AC_SUBST(LIBPNG)
2421
2422 ### Use -ltiff if available, unless `--with-tiff=no'.
2423 HAVE_TIFF=no
2424 LIBTIFF=
2425 if test "${HAVE_X11}" = "yes"; then
2426   if test "${with_tiff}" != "no"; then
2427     AC_CHECK_HEADER(tiffio.h,
2428       [tifflibs="-lz -lm"
2429       # At least one tiff package requires the jpeg library.
2430       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2431       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2432   fi
2433
2434   if test "${HAVE_TIFF}" = "yes"; then
2435     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2436     dnl FIXME -lz -lm, as per libpng?
2437     LIBTIFF=-ltiff
2438   fi
2439 fi
2440 AC_SUBST(LIBTIFF)
2441
2442 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2443 HAVE_GIF=no
2444 LIBGIF=
2445 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2446   AC_CHECK_HEADER(gif_lib.h,
2447 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2448 # Earlier versions can crash Emacs.
2449     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2450
2451   if test "$HAVE_GIF" = yes; then
2452     LIBGIF=-lgif
2453   elif test "$HAVE_GIF" = maybe; then
2454 # If gif_lib.h but no libgif, try libungif.
2455     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2456     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2457   fi
2458
2459   if test "${HAVE_GIF}" = "yes"; then
2460     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2461   fi
2462 fi
2463 AC_SUBST(LIBGIF)
2464
2465 dnl Check for required libraries.
2466 if test "${HAVE_X11}" = "yes"; then
2467   MISSING=""
2468   WITH_NO=""
2469   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2470     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2471   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2472     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2473   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2474     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2475   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2476     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2477   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2478     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2479
2480   if test "X${MISSING}" != X; then
2481     AC_MSG_ERROR([The following required libraries were not found:
2482     $MISSING
2483 Maybe some development libraries/packages are missing?
2484 If you don't want to link with them give
2485     $WITH_NO
2486 as options to configure])
2487   fi
2488 fi
2489
2490 ### Use -lgpm if available, unless `--with-gpm=no'.
2491 HAVE_GPM=no
2492 LIBGPM=
2493 MOUSE_SUPPORT=
2494 if test "${with_gpm}" != "no"; then
2495   AC_CHECK_HEADER(gpm.h,
2496     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2497
2498   if test "${HAVE_GPM}" = "yes"; then
2499     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2500     LIBGPM=-lgpm
2501     ## May be reset below.
2502     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2503   fi
2504 fi
2505 AC_SUBST(LIBGPM)
2506
2507 dnl Check for malloc/malloc.h on darwin
2508 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2509
2510 C_SWITCH_X_SYSTEM=
2511 ### Use NeXTstep API to implement GUI.
2512 if test "${HAVE_NS}" = "yes"; then
2513   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2514   if test "${NS_IMPL_COCOA}" = "yes"; then
2515     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2516     GNU_OBJC_CFLAGS=
2517   fi
2518   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2519     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2520     # See also .m.o rule in Makefile.in */
2521     # FIXME: are all these flags really needed?  Document here why.  */
2522     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2523     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2524   fi
2525   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2526     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2527   fi
2528   # We also have mouse menus.
2529   HAVE_MENUS=yes
2530   OTHER_FILES=ns-app
2531 fi
2532
2533
2534 ### Use session management (-lSM -lICE) if available
2535 HAVE_X_SM=no
2536 LIBXSM=
2537 if test "${HAVE_X11}" = "yes"; then
2538   AC_CHECK_HEADER(X11/SM/SMlib.h,
2539     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2540
2541   if test "${HAVE_X_SM}" = "yes"; then
2542     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2543     LIBXSM="-lSM -lICE"
2544     case "$LIBS" in
2545       *-lSM*) ;;
2546       *)      LIBS="$LIBXSM $LIBS" ;;
2547     esac
2548   fi
2549 fi
2550 AC_SUBST(LIBXSM)
2551
2552 ### Use libxml (-lxml2) if available
2553 if test "${with_xml2}" != "no"; then
2554   ### I'm not sure what the version number should be, so I just guessed.
2555   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.2.0, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2556   if test "${HAVE_LIBXML2}" = "yes"; then
2557     LIBS="$LIBXML2_LIBS $LIBS"
2558     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2559     if test "${HAVE_LIBXML2}" = "yes"; then
2560       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2561     else
2562       LIBXML2_LIBS=""
2563       LIBXML2_CFLAGS=""
2564     fi
2565   fi
2566 fi
2567 AC_SUBST(LIBXML2_LIBS)
2568 AC_SUBST(LIBXML2_CFLAGS)
2569
2570 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2571 AC_CACHE_CHECK(whether netdb declares h_errno,
2572                emacs_cv_netdb_declares_h_errno,
2573 [AC_TRY_LINK([#include <netdb.h>],
2574   [return h_errno;],
2575   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2576 if test $emacs_cv_netdb_declares_h_errno = yes; then
2577   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2578 fi
2579
2580 AC_FUNC_ALLOCA
2581
2582 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2583 dnl FIXME is there an autoconf test that does the right thing, without
2584 dnl needing to call A_M_E afterwards?
2585 if test x"$ac_cv_func_alloca_works" != xyes; then
2586    AC_MSG_ERROR( [a system implementation of alloca is required] )
2587 fi
2588
2589 # fmod, logb, and frexp are found in -lm on most systems.
2590 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2591 AC_CHECK_LIB(m, sqrt)
2592
2593 # Check for mail-locking functions in a "mail" library.  Probably this should
2594 # have the same check as for liblockfile below.
2595 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2596 if test $have_mail = yes; then
2597   LIBS_MAIL=-lmail
2598   LIBS="$LIBS_MAIL $LIBS"
2599   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2600 else
2601   LIBS_MAIL=
2602 fi
2603 dnl Debian, at least:
2604 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2605 if test $have_lockfile = yes; then
2606    LIBS_MAIL=-llockfile
2607    LIBS="$LIBS_MAIL $LIBS"
2608    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2609 else
2610 # If we have the shared liblockfile, assume we must use it for mail
2611 # locking (e.g. Debian).  If we couldn't link against liblockfile
2612 # (no liblockfile.a installed), ensure that we don't need to.
2613   dnl This works for files generally, not just executables.
2614   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2615   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2616                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2617   if test $ac_cv_prog_liblockfile = yes; then
2618     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2619 This probably means that movemail could lose mail.
2620 There may be a `development' package to install containing liblockfile.])
2621   fi
2622 fi
2623 AC_CHECK_FUNCS(touchlock)
2624 AC_CHECK_HEADERS(maillock.h)
2625 AC_SUBST(LIBS_MAIL)
2626
2627 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2628 ## interlock access to the mail spool.  The alternative is a lock file named
2629 ## /usr/spool/mail/$USER.lock.
2630 mail_lock=no
2631 case "$opsys" in
2632   aix4-2) mail_lock="lockf" ;;
2633
2634   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2635
2636   ## On GNU/Linux systems, both methods are used by various mail programs.
2637   ## I assume most people are using newer mailers that have heard of flock.
2638   ## Change this if you need to.
2639   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2640   ## configure gets the right answers, and that means *NOT* using flock.
2641   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2642   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2643   ## Debian maintainer hasn't provided a clean fix for Emacs.
2644   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2645   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2646   ## correct logic.  -- fx
2647   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2648   ## liblockfile is a Free Software replacement for libmail, used on
2649   ## Debian systems and elsewhere. -rfr.
2650   gnu-*)
2651     mail_lock="flock"
2652     if test $have_mail = yes || test $have_lockfile = yes; then
2653       test $ac_cv_header_maillock_h = yes && mail_lock=no
2654     fi
2655     ;;
2656 esac
2657
2658 BLESSMAIL_TARGET=
2659 case "$mail_lock" in
2660   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2661
2662   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2663
2664   *) BLESSMAIL_TARGET="need-blessmail" ;;
2665 esac
2666 AC_SUBST(BLESSMAIL_TARGET)
2667
2668
2669 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2670 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2671 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2672 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2673 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2674 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2675 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2676 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2677 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2678 cfmakeraw cfsetspeed isnan copysign __executable_start)
2679
2680 AC_CHECK_HEADERS(sys/un.h)
2681
2682 AC_FUNC_MKTIME
2683 if test "$ac_cv_func_working_mktime" = no; then
2684   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2685 fi
2686
2687 AC_FUNC_GETLOADAVG
2688
2689 AC_FUNC_FSEEKO
2690
2691 # Configure getopt.
2692 m4_include([m4/getopt.m4])
2693 gl_GETOPT_IFELSE([
2694   gl_GETOPT_SUBSTITUTE_HEADER
2695   gl_PREREQ_GETOPT
2696   GETOPTOBJS='getopt.o getopt1.o'
2697 ])
2698 AC_SUBST(GETOPTOBJS)
2699
2700 AC_FUNC_GETPGRP
2701
2702 AC_FUNC_STRFTIME
2703
2704 # UNIX98 PTYs.
2705 AC_CHECK_FUNCS(grantpt)
2706
2707 # PTY-related GNU extensions.
2708 AC_CHECK_FUNCS(getpt)
2709
2710 # Check this now, so that we will NOT find the above functions in ncurses.
2711 # That is because we have not set up to link ncurses in lib-src.
2712 # It's better to believe a function is not available
2713 # than to expect to find it in ncurses.
2714 # Also we need tputs and friends to be able to build at all.
2715 have_tputs_et_al=true
2716 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2717 if test "$have_tputs_et_al" != true; then
2718   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2719 Maybe some development libraries/packages are missing?  Try installing
2720 libncurses-dev(el), libterminfo-dev(el) or similar.])
2721 fi
2722 # Must define this when any termcap library is found.
2723 AC_DEFINE(HAVE_LIBNCURSES, 1,
2724           [Define to 1 if you have the `ncurses' library (-lncurses).])
2725 ## FIXME This was the cpp logic, but I am not sure it is right.
2726 ## The above test has not necessarily found libncurses.
2727 HAVE_LIBNCURSES=yes
2728
2729 ## Use terminfo instead of termcap?
2730 ## Note only system files NOT using terminfo are:
2731 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2732 ## darwin|gnu without ncurses.
2733 TERMINFO=no
2734 LIBS_TERMCAP=
2735 case "$opsys" in
2736   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2737   ## hpux10-20: Use the system provided termcap(3) library.
2738   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2739   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2740   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2741
2742   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2743   ##  The ncurses library has been moved out of the System framework in
2744   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2745   ##  option to use it.
2746   darwin|gnu*)
2747     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2748     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2749       TERMINFO=yes
2750       LIBS_TERMCAP="-lncurses"
2751     fi
2752     ;;
2753
2754   freebsd)
2755     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2756     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2757     [AC_TRY_LINK([#include <osreldate.h>],
2758 [#if __FreeBSD_version < 400000
2759 fail;
2760 #endif
2761 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2762
2763     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2764
2765     if test $emacs_cv_freebsd_terminfo = yes; then
2766       TERMINFO=yes
2767       LIBS_TERMCAP="-lncurses"
2768     else
2769       LIBS_TERMCAP="-ltermcap"
2770     fi
2771     ;;
2772
2773   netbsd)
2774     if test $ac_cv_search_tputs = -lterminfo; then
2775       TERMINFO=yes
2776       LIBS_TERMCAP="-lterminfo"
2777     else
2778       LIBS_TERMCAP="-ltermcap"
2779     fi
2780     ;;
2781
2782 esac
2783
2784 case "$opsys" in
2785   ## hpux: Make sure we get select from libc rather than from libcurses
2786   ##  because libcurses on HPUX 10.10 has a broken version of select.
2787   ##  We used to use -lc -lcurses, but this may be cleaner.
2788   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2789
2790   openbsd) LIBS_TERMCAP="-lncurses" ;;
2791
2792   ## Must use system termcap, if we use any termcap.  It does special things.
2793   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2794 esac
2795
2796 TERMCAP_OBJ=tparam.o
2797 if test $TERMINFO = yes; then
2798   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2799
2800   ## Default used to be -ltermcap.  Add a case above if need something else.
2801   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2802
2803   TERMCAP_OBJ=terminfo.o
2804 fi
2805 AC_SUBST(LIBS_TERMCAP)
2806 AC_SUBST(TERMCAP_OBJ)
2807
2808
2809 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2810 resolv=no
2811 AC_TRY_LINK([#include <netinet/in.h>
2812 #include <arpa/nameser.h>
2813 #include <resolv.h>],
2814     [return res_init();],
2815     have_res_init=yes, have_res_init=no)
2816 if test "$have_res_init" = no; then
2817   OLIBS="$LIBS"
2818   LIBS="$LIBS -lresolv"
2819   AC_MSG_CHECKING(for res_init with -lresolv)
2820   AC_TRY_LINK([#include <netinet/in.h>
2821 #include <arpa/nameser.h>
2822 #include <resolv.h>],
2823     [return res_init();],
2824     have_res_init=yes, have_res_init=no)
2825   AC_MSG_RESULT($have_res_init)
2826   if test "$have_res_init" = yes ; then
2827     resolv=yes
2828   fi
2829   LIBS="$OLIBS"
2830 fi
2831
2832 if test "$have_res_init" = yes; then
2833   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2834 fi
2835
2836 # Do we need the Hesiod library to provide the support routines?
2837 LIBHESIOD=
2838 if test "$with_hesiod" != no ; then
2839   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2840   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2841      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2842                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2843   if test "$resolv" = yes ; then
2844     RESOLVLIB=-lresolv
2845   else
2846     RESOLVLIB=
2847   fi
2848   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2849         hesiod=yes, :, $RESOLVLIB)])
2850
2851   if test x"$hesiod" = xyes; then
2852     AC_DEFINE(HAVE_LIBHESIOD, 1,
2853               [Define to 1 if you have the hesiod library (-lhesiod).])
2854     LIBHESIOD=-lhesiod
2855   fi
2856 fi
2857 AC_SUBST(LIBHESIOD)
2858
2859 # Do we need libresolv (due to res_init or Hesiod)?
2860 if test "$resolv" = yes ; then
2861   AC_DEFINE(HAVE_LIBRESOLV, 1,
2862             [Define to 1 if you have the resolv library (-lresolv).])
2863   LIBRESOLV=-lresolv
2864 else
2865   LIBRESOLV=
2866 fi
2867 AC_SUBST(LIBRESOLV)
2868
2869 # These tell us which Kerberos-related libraries to use.
2870 COM_ERRLIB=
2871 CRYPTOLIB=
2872 KRB5LIB=
2873 DESLIB=
2874 KRB4LIB=
2875
2876 if test "${with_kerberos}" != no; then
2877   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2878   if test $have_com_err = yes; then
2879     COM_ERRLIB=-lcom_err
2880     LIBS="$COM_ERRLIB $LIBS"
2881     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2882   fi
2883   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2884   if test $have_crypto = yes; then
2885     CRYPTOLIB=-lcrypto
2886     LIBS="$CRYPTOLIB $LIBS"
2887     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2888   fi
2889   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2890   if test $have_k5crypto = yes; then
2891     CRYPTOLIB=-lk5crypto
2892     LIBS="$CRYPTOLIB $LIBS"
2893     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2894   fi
2895   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2896   if test $have_krb5=yes; then
2897     KRB5LIB=-lkrb5
2898     LIBS="$KRB5LIB $LIBS"
2899     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2900   fi
2901   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2902   if test "${with_kerberos5}" = no; then
2903     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2904     if test $have_des425 = yes; then
2905       DESLIB=-ldes425
2906       LIBS="$DESLIB $LIBS"
2907       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2908     else
2909       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2910       if test $have_des = yes; then
2911         DESLIB=-ldes
2912         LIBS="$DESLIB $LIBS"
2913         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2914       fi
2915     fi
2916     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2917     if test $have_krb4 = yes; then
2918       KRB4LIB=-lkrb4
2919       LIBS="$KRB4LIB $LIBS"
2920       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2921     else
2922       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2923       if test $have_krb = yes; then
2924         KRB4LIB=-lkrb
2925         LIBS="$KRB4LIB $LIBS"
2926         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2927       fi
2928     fi
2929   fi
2930
2931   if test "${with_kerberos5}" != no; then
2932     AC_CHECK_HEADERS(krb5.h,
2933       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2934                         [#include <krb5.h>])])
2935   else
2936     AC_CHECK_HEADERS(des.h,,
2937                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2938                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2939     AC_CHECK_HEADERS(krb.h,,
2940                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2941                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2942   fi
2943   AC_CHECK_HEADERS(com_err.h)
2944 fi
2945
2946 AC_SUBST(COM_ERRLIB)
2947 AC_SUBST(CRYPTOLIB)
2948 AC_SUBST(KRB5LIB)
2949 AC_SUBST(DESLIB)
2950 AC_SUBST(KRB4LIB)
2951
2952 # Solaris requires -lintl if you want strerror (which calls dgettext)
2953 # to return localized messages.
2954 AC_CHECK_LIB(intl, dgettext)
2955
2956 AC_MSG_CHECKING(whether localtime caches TZ)
2957 AC_CACHE_VAL(emacs_cv_localtime_cache,
2958 [if test x$ac_cv_func_tzset = xyes; then
2959 AC_TRY_RUN([#include <time.h>
2960 extern char **environ;
2961 unset_TZ ()
2962 {
2963   char **from, **to;
2964   for (to = from = environ; (*to = *from); from++)
2965     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2966       to++;
2967 }
2968 char TZ_GMT0[] = "TZ=GMT0";
2969 char TZ_PST8[] = "TZ=PST8";
2970 main()
2971 {
2972   time_t now = time ((time_t *) 0);
2973   int hour_GMT0, hour_unset;
2974   if (putenv (TZ_GMT0) != 0)
2975     exit (1);
2976   hour_GMT0 = localtime (&now)->tm_hour;
2977   unset_TZ ();
2978   hour_unset = localtime (&now)->tm_hour;
2979   if (putenv (TZ_PST8) != 0)
2980     exit (1);
2981   if (localtime (&now)->tm_hour == hour_GMT0)
2982     exit (1);
2983   unset_TZ ();
2984   if (localtime (&now)->tm_hour != hour_unset)
2985     exit (1);
2986   exit (0);
2987 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2988 [# If we have tzset, assume the worst when cross-compiling.
2989 emacs_cv_localtime_cache=yes])
2990 else
2991         # If we lack tzset, report that localtime does not cache TZ,
2992         # since we can't invalidate the cache if we don't have tzset.
2993         emacs_cv_localtime_cache=no
2994 fi])dnl
2995 AC_MSG_RESULT($emacs_cv_localtime_cache)
2996 if test $emacs_cv_localtime_cache = yes; then
2997   AC_DEFINE(LOCALTIME_CACHE, 1,
2998             [Define to 1 if localtime caches TZ.])
2999 fi
3000
3001 if test "x$HAVE_TIMEVAL" = xyes; then
3002   AC_CHECK_FUNCS(gettimeofday)
3003   if test $ac_cv_func_gettimeofday = yes; then
3004     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3005                    emacs_cv_gettimeofday_two_arguments,
3006     [AC_TRY_COMPILE([
3007 #ifdef TIME_WITH_SYS_TIME
3008 #include <sys/time.h>
3009 #include <time.h>
3010 #else
3011 #ifdef HAVE_SYS_TIME_H
3012 #include <sys/time.h>
3013 #else
3014 #include <time.h>
3015 #endif
3016 #endif],
3017       [struct timeval time;
3018        gettimeofday (&time, 0);],
3019       emacs_cv_gettimeofday_two_arguments=yes,
3020       emacs_cv_gettimeofday_two_arguments=no)])
3021     if test $emacs_cv_gettimeofday_two_arguments = no; then
3022       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3023                 [Define to 1 if gettimeofday accepts only one argument.])
3024     fi
3025   fi
3026 fi
3027
3028 ok_so_far=yes
3029 AC_CHECK_FUNC(socket, , ok_so_far=no)
3030 if test $ok_so_far = yes; then
3031   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3032 fi
3033 if test $ok_so_far = yes; then
3034   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3035 fi
3036 if test $ok_so_far = yes; then
3037 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3038   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3039             [Define to 1 if you have inet sockets.])
3040 fi
3041
3042 AC_CHECK_HEADERS(sys/ioctl.h)
3043
3044 if test -f /usr/lpp/X11/bin/smt.exp; then
3045   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3046             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3047 fi
3048
3049 AC_MSG_CHECKING(whether system supports dynamic ptys)
3050 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3051   AC_MSG_RESULT(yes)
3052   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3053 else
3054   AC_MSG_RESULT(no)
3055 fi
3056
3057 AC_FUNC_FORK
3058
3059 dnl Adapted from Haible's version.
3060 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3061   [AC_TRY_LINK([#include <langinfo.h>],
3062     [char* cs = nl_langinfo(CODESET);],
3063     emacs_cv_langinfo_codeset=yes,
3064     emacs_cv_langinfo_codeset=no)
3065   ])
3066 if test $emacs_cv_langinfo_codeset = yes; then
3067   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3068     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3069 fi
3070
3071 AC_CHECK_TYPES(size_t)
3072
3073 AC_TYPE_MBSTATE_T
3074
3075 dnl Restrict could probably be used effectively other than in regex.c.
3076 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3077   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3078                   emacs_cv_c_restrict=yes,
3079                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3080                                   emacs_cv_c_restrict=__restrict,
3081                                   emacs_cv_c_restrict=no)])])
3082 case "$emacs_cv_c_restrict" in
3083   yes) emacs_restrict=restrict;;
3084   no) emacs_restrict="";;
3085   *) emacs_restrict="$emacs_cv_c_restrict";;
3086 esac
3087 if test "$emacs_restrict" != __restrict; then
3088   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3089     [Define to compiler's equivalent of C99 restrict keyword.
3090      Don't define if equivalent is `__restrict'.])
3091 fi
3092
3093 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3094   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3095                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3096 if test "$emacs_cv_c_restrict_arr" = yes; then
3097   AC_DEFINE(__restrict_arr, __restrict,
3098     [Define to compiler's equivalent of C99 restrict keyword in array
3099      declarations.  Define as empty for no equivalent.])
3100 fi
3101
3102 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3103 dnl how the tty code is related to POSIX and/or other versions of termios.
3104 dnl The following looks like a useful start.
3105 dnl
3106 dnl AC_SYS_POSIX_TERMIOS
3107 dnl if test $ac_cv_sys_posix_termios = yes; then
3108 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3109 dnl                                and macros for terminal control.])
3110 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3111 dnl fi
3112
3113 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3114
3115 # Set up the CFLAGS for real compilation, so we can substitute it.
3116 CFLAGS="$REAL_CFLAGS"
3117 CPPFLAGS="$REAL_CPPFLAGS"
3118
3119 ## Hack to detect a buggy GCC version.
3120 if test "x$GCC" = xyes \
3121    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3122    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3123    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3124    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3125 fi
3126
3127 #### Find out which version of Emacs this is.
3128 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3129          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3130 if test x"${version}" = x; then
3131   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3132 fi
3133 if test x"${version}" != x"$PACKAGE_VERSION"; then
3134   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3135 fi
3136
3137 ### Specify what sort of things we'll be editing into Makefile and config.h.
3138 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3139 AC_SUBST(version)
3140 AC_SUBST(configuration)
3141 ## Unused?
3142 AC_SUBST(canonical)
3143 AC_SUBST(srcdir)
3144 AC_SUBST(prefix)
3145 AC_SUBST(exec_prefix)
3146 AC_SUBST(bindir)
3147 AC_SUBST(datadir)
3148 AC_SUBST(sharedstatedir)
3149 AC_SUBST(libexecdir)
3150 AC_SUBST(mandir)
3151 AC_SUBST(infodir)
3152 AC_SUBST(lispdir)
3153 AC_SUBST(locallisppath)
3154 AC_SUBST(lisppath)
3155 AC_SUBST(x_default_search_path)
3156 AC_SUBST(etcdir)
3157 AC_SUBST(archlibdir)
3158 AC_SUBST(docdir)
3159 AC_SUBST(bitmapdir)
3160 AC_SUBST(gamedir)
3161 AC_SUBST(gameuser)
3162 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3163 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3164 ## end of LIBX_BASE, but nothing ever set it.
3165 AC_SUBST(LD_SWITCH_X_SITE)
3166 AC_SUBST(C_SWITCH_X_SITE)
3167 AC_SUBST(C_SWITCH_X_SYSTEM)
3168 AC_SUBST(CFLAGS)
3169 ## Used in lwlib/Makefile.in.
3170 AC_SUBST(X_TOOLKIT_TYPE)
3171 AC_SUBST(machfile)
3172 AC_SUBST(opsysfile)
3173 AC_SUBST(GETLOADAVG_LIBS)
3174 AC_SUBST(ns_appdir)
3175 AC_SUBST(ns_appbindir)
3176 AC_SUBST(ns_appresdir)
3177 AC_SUBST(ns_appsrc)
3178 AC_SUBST(GNU_OBJC_CFLAGS)
3179 AC_SUBST(OTHER_FILES)
3180
3181 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3182                    [Define to the canonical Emacs configuration name.])
3183 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3184                    [Define to the options passed to configure.])
3185 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3186                    [Define to the used machine dependent file.])
3187 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3188                    [Define to the used os dependent file.])
3189
3190 XMENU_OBJ=
3191 XOBJ=
3192 FONT_OBJ=
3193 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3194   AC_DEFINE(HAVE_X_WINDOWS, 1,
3195             [Define to 1 if you want to use the X window system.])
3196   XMENU_OBJ=xmenu.o
3197   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3198   FONT_OBJ=xfont.o
3199   if test "$HAVE_XFT" = "yes"; then
3200     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3201   elif test "$HAVE_FREETYPE" = "yes"; then
3202     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3203   fi
3204   AC_SUBST(FONT_OBJ)
3205 fi
3206 AC_SUBST(XMENU_OBJ)
3207 AC_SUBST(XOBJ)
3208 AC_SUBST(FONT_OBJ)
3209
3210 WIDGET_OBJ=
3211 MOTIF_LIBW=
3212 if test "${USE_X_TOOLKIT}" != "none" ; then
3213   WIDGET_OBJ=widget.o
3214   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3215   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3216     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3217   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3218     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3219     MOTIF_LIBW=-lXm
3220     case "$opsys" in
3221       gnu-linux)
3222         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3223         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3224         ;;
3225
3226       unixware)
3227         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3228         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3229         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3230         ;;
3231
3232       aix4-2)
3233         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3234         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3235         ;;
3236     esac
3237     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3238   fi
3239 fi
3240 AC_SUBST(WIDGET_OBJ)
3241
3242 TOOLKIT_LIBW=
3243 case "$USE_X_TOOLKIT" in
3244   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3245   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3246   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3247 esac
3248 AC_SUBST(TOOLKIT_LIBW)
3249
3250 if test "$USE_X_TOOLKIT" = "none"; then
3251   LIBXT_OTHER="\$(LIBXSM)"
3252   OLDXMENU_TARGET="really-oldXMenu"
3253 else
3254   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3255   OLDXMENU_TARGET="really-lwlib"
3256 fi
3257 AC_SUBST(LIBXT_OTHER)
3258
3259 ## The X Menu stuff is present in the X10 distribution, but missing
3260 ## from X11.  If we have X10, just use the installed library;
3261 ## otherwise, use our own copy.
3262 if test "${HAVE_X11}" = "yes" ; then
3263   AC_DEFINE(HAVE_X11, 1,
3264             [Define to 1 if you want to use version 11 of X windows.
3265              Otherwise, Emacs expects to use version 10.])
3266
3267   if test "$USE_X_TOOLKIT" = "none"; then
3268     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3269   else
3270     OLDXMENU="\${lwlibdir}liblw.a"
3271   fi
3272   LIBXMENU="\$(OLDXMENU)"
3273   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3274   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3275 else
3276   ## For a syntactically valid Makefile; not actually used for anything.
3277   ## See comments in src/Makefile.in.
3278   OLDXMENU=nothing
3279   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3280   if test "${HAVE_X_WINDOWS}" = "yes"; then
3281     LIBXMENU="-lXMenu"
3282   else
3283     LIBXMENU=
3284   fi
3285   LIBX_OTHER=
3286   OLDXMENU_DEPS=
3287 fi
3288
3289 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3290   OLDXMENU_TARGET=
3291   OLDXMENU=nothing
3292   LIBXMENU=
3293   OLDXMENU_DEPS=
3294 fi
3295
3296 AC_SUBST(OLDXMENU_TARGET)
3297 AC_SUBST(OLDXMENU)
3298 AC_SUBST(LIBXMENU)
3299 AC_SUBST(LIBX_OTHER)
3300 AC_SUBST(OLDXMENU_DEPS)
3301
3302 if test "${HAVE_MENUS}" = "yes" ; then
3303   AC_DEFINE(HAVE_MENUS, 1,
3304             [Define to 1 if you have mouse menus.
3305              (This is automatic if you use X, but the option to specify it remains.)
3306              It is also defined with other window systems that support xmenu.c.])
3307 fi
3308
3309 if test "${GNU_MALLOC}" = "yes" ; then
3310   AC_DEFINE(GNU_MALLOC, 1,
3311             [Define to 1 if you want to use the GNU memory allocator.])
3312 fi
3313
3314 RALLOC_OBJ=
3315 if test "${REL_ALLOC}" = "yes" ; then
3316   AC_DEFINE(REL_ALLOC, 1,
3317             [Define REL_ALLOC if you want to use the relocating allocator for
3318              buffer space.])
3319
3320   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3321 fi
3322 AC_SUBST(RALLOC_OBJ)
3323
3324 if test "$opsys" = "cygwin"; then
3325   CYGWIN_OBJ="sheap.o"
3326   ## Cygwin differs because of its unexec().
3327   PRE_ALLOC_OBJ=
3328   POST_ALLOC_OBJ=lastfile.o
3329 else
3330   CYGWIN_OBJ=
3331   PRE_ALLOC_OBJ=lastfile.o
3332   POST_ALLOC_OBJ=
3333 fi
3334 AC_SUBST(CYGWIN_OBJ)
3335 AC_SUBST(PRE_ALLOC_OBJ)
3336 AC_SUBST(POST_ALLOC_OBJ)
3337
3338
3339 case "$opsys" in
3340   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3341
3342   darwin)
3343    ## The -headerpad option tells ld (see man page) to leave room at the
3344    ## end of the header for adding load commands.  Needed for dumping.
3345    ## 0x690 is the total size of 30 segment load commands (at 56
3346    ## each); under Cocoa 31 commands are required.
3347    if test "$HAVE_NS" = "yes"; then
3348      libs_nsgui="-framework AppKit"
3349      headerpad_extra=6C8
3350    else
3351      libs_nsgui=
3352      headerpad_extra=690
3353    fi
3354    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3355
3356    ## This is here because src/Makefile.in did some extra fiddling around
3357    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3358    ##   #ifndef LD_SWITCH_SYSTEM
3359    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3360    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3361    ## not using gcc, darwin system not on an alpha (ie darwin, since
3362    ## darwin + alpha does not occur).
3363    ## Because this was done in src/Makefile.in, the resulting part of
3364    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3365    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3366    ## rather than LD_SWITCH_SYSTEM.
3367    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3368      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3369    ;;
3370
3371   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3372   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3373   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3374   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3375   ## had different values in configure (in ac_link) and src/Makefile.in.
3376   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3377   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3378
3379   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3380 esac
3381
3382 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3383   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3384 fi
3385
3386 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3387
3388
3389 LD_FIRSTFLAG=
3390 ORDINARY_LINK=
3391 case "$opsys" in
3392   ## gnu: GNU needs its own crt0.
3393   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3394
3395   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3396   ## library search parth, i.e. it won't search /usr/lib for libc and
3397   ## friends.  Using -nostartfiles instead avoids this problem, and
3398   ## will also work on earlier NetBSD releases.
3399   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3400
3401   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3402   ##   MkLinux/LinuxPPC needs this.
3403   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3404   gnu-*)
3405     case "$machine" in
3406       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3407     esac
3408     ;;
3409 esac
3410
3411
3412 if test "x$ORDINARY_LINK" = "xyes"; then
3413
3414   LD_FIRSTFLAG=""
3415   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3416
3417 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3418 ## freebsd, gnu-* not on macppc|ibms390x.
3419 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3420
3421   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3422   ## places that are difficult to figure out at make time.  Fortunately,
3423   ## these same versions allow you to pass arbitrary flags on to the
3424   ## linker, so there is no reason not to use it as a linker.
3425   ##
3426   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3427   ## searching for libraries in its internal directories, so we have to
3428   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3429   LD_FIRSTFLAG="-nostdlib"
3430 fi
3431
3432 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3433 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3434
3435 AC_SUBST(LD_FIRSTFLAG)
3436
3437
3438 ## FIXME? The logic here is not precisely the same as that above.
3439 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3440 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3441 LIB_GCC=
3442 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3443
3444   case "$opsys" in
3445     freebsd|netbsd|openbsd) LIB_GCC= ;;
3446
3447     gnu-*)
3448       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3449       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3450       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3451       if test "$machine" = "arm"; then
3452         LIB_GCC="-lgcc_s"
3453       else
3454         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3455         ## immediately undefine it again and redefine it to empty.
3456         ## Was the C_SWITCH_X_SITE part really necessary?
3457 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3458         LIB_GCC=
3459       fi
3460       ;;
3461
3462     ## Ask GCC where to find libgcc.a.
3463     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3464   esac
3465 fi                              dnl if $GCC
3466 AC_SUBST(LIB_GCC)
3467
3468
3469 TOOLTIP_SUPPORT=
3470 WINDOW_SUPPORT=
3471 ## If we're using X11/GNUstep, define some consequences.
3472 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3473   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3474   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3475   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3476   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3477
3478   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3479   test "$HAVE_X_WINDOWS" = "yes" && \
3480     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3481
3482 fi
3483 AC_SUBST(MOUSE_SUPPORT)
3484 AC_SUBST(TOOLTIP_SUPPORT)
3485 AC_SUBST(WINDOW_SUPPORT)
3486
3487
3488 AH_TOP([/* GNU Emacs site configuration template file.
3489    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3490      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3491
3492 This file is part of GNU Emacs.
3493
3494 GNU Emacs is free software: you can redistribute it and/or modify
3495 it under the terms of the GNU General Public License as published by
3496 the Free Software Foundation, either version 3 of the License, or
3497 (at your option) any later version.
3498
3499 GNU Emacs is distributed in the hope that it will be useful,
3500 but WITHOUT ANY WARRANTY; without even the implied warranty of
3501 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3502 GNU General Public License for more details.
3503
3504 You should have received a copy of the GNU General Public License
3505 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3506
3507
3508 /* No code in Emacs #includes config.h twice, but some bits of code
3509    intended to work with other packages as well (like gmalloc.c)
3510    think they can include it as many times as they like.  */
3511 #ifndef EMACS_CONFIG_H
3512 #define EMACS_CONFIG_H
3513 ])dnl
3514
3515 AH_BOTTOM([
3516 /* Define AMPERSAND_FULL_NAME if you use the convention
3517    that & in the full name stands for the login id.  */
3518 /* Turned on June 1996 supposing nobody will mind it.  */
3519 #define AMPERSAND_FULL_NAME
3520
3521 /* If using GNU, then support inline function declarations.  */
3522 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3523    generally, because even if non-gcc compilers accept `inline', they
3524    may reject `extern inline'.  */
3525 #if defined (__GNUC__) && defined (OPTIMIZE)
3526 #define INLINE __inline__
3527 #else
3528 #define INLINE
3529 #endif
3530
3531 /* `subprocesses' should be defined if you want to
3532    have code for asynchronous subprocesses
3533    (as used in M-x compile and M-x shell).
3534    Only MSDOS does not support this (it overrides
3535    this in its config_opsysfile below).  */
3536
3537 #define subprocesses
3538
3539 /* Include the os and machine dependent files.  */
3540 #include config_opsysfile
3541 #include config_machfile
3542
3543 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3544   (There is probably a better place to do this, but right now the Cocoa
3545    side does this in s/darwin.h and we cannot
3546    parallel this exactly since GNUstep is multi-OS.  */
3547 #ifdef HAVE_NS
3548 # ifdef NS_IMPL_GNUSTEP
3549 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3550 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3551 #  define SYSTEM_PURESIZE_EXTRA 30000
3552 # endif /* NS_IMPL_GNUSTEP */
3553 #endif /* HAVE_NS */
3554
3555 /* SIGTYPE is the macro we actually use.  */
3556 #ifndef SIGTYPE
3557 #define SIGTYPE RETSIGTYPE
3558 #endif
3559
3560 #ifdef emacs /* Don't do this for lib-src.  */
3561 /* Tell regex.c to use a type compatible with Emacs.  */
3562 #define RE_TRANSLATE_TYPE Lisp_Object
3563 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3564 #ifdef make_number
3565 /* If make_number is a macro, use it.  */
3566 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3567 #else
3568 /* If make_number is a function, avoid it.  */
3569 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3570 #endif
3571 #endif
3572
3573 /* Avoid link-time collision with system mktime if we will use our own.  */
3574 #if ! HAVE_MKTIME || BROKEN_MKTIME
3575 #define mktime emacs_mktime
3576 #endif
3577
3578 #define my_strftime nstrftime   /* for strftime.c */
3579
3580 /* These default definitions are good for almost all machines.
3581    The exceptions override them in m/MACHINE.h.  */
3582
3583 #ifndef BITS_PER_CHAR
3584 #define BITS_PER_CHAR 8
3585 #endif
3586
3587 #ifndef BITS_PER_SHORT
3588 #define BITS_PER_SHORT 16
3589 #endif
3590
3591 /* Note that lisp.h uses this in a preprocessor conditional, so it
3592    would not work to use sizeof.  That being so, we do all of them
3593    without sizeof, for uniformity's sake.  */
3594 #ifndef BITS_PER_INT
3595 #define BITS_PER_INT 32
3596 #endif
3597
3598 #ifndef BITS_PER_LONG
3599 #ifdef _LP64
3600 #define BITS_PER_LONG 64
3601 #else
3602 #define BITS_PER_LONG 32
3603 #endif
3604 #endif
3605
3606 /* Define if the compiler supports function prototypes.  It may do so but
3607    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3608 #undef PROTOTYPES
3609
3610 #include <string.h>
3611 #include <stdlib.h>
3612
3613 #ifdef HAVE_ALLOCA_H
3614 # include <alloca.h>
3615 #elif defined __GNUC__
3616 # define alloca __builtin_alloca
3617 #elif defined _AIX
3618 # define alloca __alloca
3619 #else
3620 # include <stddef.h>
3621 # ifdef  __cplusplus
3622 extern "C"
3623 # endif
3624 void *alloca (size_t);
3625 #endif
3626
3627 #ifndef HAVE_SIZE_T
3628 typedef unsigned size_t;
3629 #endif
3630
3631 #ifndef HAVE_STRCHR
3632 #define strchr(a, b) index (a, b)
3633 #endif
3634
3635 #ifndef HAVE_STRRCHR
3636 #define strrchr(a, b) rindex (a, b)
3637 #endif
3638
3639 #if defined __GNUC__ && (__GNUC__ > 2 \
3640                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3641 #define NO_RETURN       __attribute__ ((__noreturn__))
3642 #else
3643 #define NO_RETURN       /* nothing */
3644 #endif
3645
3646 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3647 #define NO_INLINE __attribute__((noinline))
3648 #else
3649 #define NO_INLINE
3650 #endif
3651
3652 /* Some versions of GNU/Linux define noinline in their headers.  */
3653 #ifdef noinline
3654 #undef noinline
3655 #endif
3656
3657 /* These won't be used automatically yet.  We also need to know, at least,
3658    that the stack is continuous.  */
3659 #ifdef __GNUC__
3660 #  ifndef GC_SETJMP_WORKS
3661   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3662 #    define GC_SETJMP_WORKS 1
3663 #  endif
3664 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3665 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3666 #  endif
3667 #endif
3668
3669 #endif /* EMACS_CONFIG_H */
3670
3671 /*
3672 Local Variables:
3673 mode: c
3674 End:
3675 */
3676 ])dnl
3677
3678 #### Report on what we decided to do.
3679 #### Report GTK as a toolkit, even if it doesn't use Xt.
3680 #### It makes printing result more understandable as using GTK sets
3681 #### toolkit_scroll_bars to yes by default.
3682 if test "${HAVE_GTK}" = "yes"; then
3683   USE_X_TOOLKIT=GTK
3684 fi
3685
3686 echo "
3687 Configured for \`${canonical}'.
3688
3689   Where should the build process find the source code?    ${srcdir}
3690   What operating system and machine description files should Emacs use?
3691         \`${opsysfile}' and \`${machfile}'
3692   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3693   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3694   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3695   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3696   What window system should Emacs use?                    ${window_system}
3697   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3698
3699 if test -n "${x_includes}"; then
3700 echo "  Where do we find X Windows header files?                ${x_includes}"
3701 else
3702 echo "  Where do we find X Windows header files?                Standard dirs"
3703 fi
3704 if test -n "${x_libraries}"; then
3705 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3706 else
3707 echo "  Where do we find X Windows libraries?                   Standard dirs"
3708 fi
3709
3710 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3711 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3712 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3713 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3714 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3715 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3716 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3717 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3718
3719 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3720 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3721 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3722 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3723 echo "  Does Emacs use -lgnutls (BROKEN)?                       ${HAVE_GNUTLS}"
3724 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3725
3726 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3727 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3728 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3729 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3730
3731 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3732 echo
3733
3734 if test $USE_XASSERTS = yes; then
3735    echo "  Compiling with asserts turned on."
3736    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3737 fi
3738
3739 echo
3740
3741 if test "$HAVE_NS" = "yes"; then
3742    echo
3743    echo "You must run \"make install\" in order to test the built application.
3744 The installed application will go to nextstep/Emacs.app and can be
3745 run or moved from there."
3746    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3747       echo "The application will be fully self-contained."
3748     else
3749       echo "The lisp resources for the application will be installed under ${prefix}.
3750 You may need to run \"make install\" with sudo.  The application will fail
3751 to run if these resources are not installed."
3752    fi
3753    echo
3754 fi
3755
3756 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3757   echo "D-Bus integration has been tested for GNU/Linux only."
3758   echo
3759 fi
3760
3761
3762 # Remove any trailing slashes in these variables.
3763 [test "${prefix}" != NONE &&
3764   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3765 test "${exec_prefix}" != NONE &&
3766   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3767
3768 dnl You might wonder (I did) why epaths.h is generated by running make,
3769 dnl rather than just letting configure generate it from epaths.in.
3770 dnl One reason is that the various paths are not fully expanded (see above);
3771 dnl eg gamedir=${prefix}/var/games/emacs.
3772 dnl Secondly, the GNU Coding standards require that one should be able
3773 dnl to run `make prefix=/some/where/else' and override the values set
3774 dnl by configure.  This also explains the `move-if-change' test and
3775 dnl the use of force in the `epaths-force' rule in Makefile.in.
3776 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3777         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3778         doc/lispref/Makefile src/Makefile \
3779         lwlib/Makefile lisp/Makefile leim/Makefile \
3780         doc/emacs/emacsver.texi, [
3781
3782 ### Make the necessary directories, if they don't exist.
3783 for dir in etc lisp ; do
3784   test -d ${dir} || mkdir ${dir}
3785 done
3786
3787 echo creating src/epaths.h
3788 ${MAKE-make} epaths-force
3789
3790 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3791   echo creating src/.gdbinit
3792   echo source $srcdir/src/.gdbinit > src/.gdbinit
3793 fi
3794
3795 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3796