lisp/emacs-lisp/cl-seq.el

   1 ;;; cl-seq.el --- Common Lisp features, part 3  -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Copyright (C) 1993 Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Gillespie <daveg@synaptics.com>
   6 ;; Version: 2.02
   7 ;; Keywords: extensions
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; These are extensions to Emacs Lisp that provide a degree of
  29 ;; Common Lisp compatibility, beyond what is already built-in
  30 ;; in Emacs Lisp.
  31 ;;
  32 ;; This package was written by Dave Gillespie; it is a complete
  33 ;; rewrite of Cesar Quiroz's original cl.el package of December 1986.
  34 ;;
  35 ;; This package works with Emacs 18, Emacs 19, and Lucid Emacs 19.
  36 ;;
  37 ;; Bug reports, comments, and suggestions are welcome!
  38
  39 ;; This file contains the Common Lisp sequence and list functions
  40 ;; which take keyword arguments.
  41
  42 ;; See cl.el for Change Log.
  43
  44
  45 ;;; Code:
  46
  47 (or (memq 'cl-19 features)
  48     (error "Tried to load `cl-seq' before `cl'!"))
  49
  50
  51 ;;; We define these here so that this file can compile without having
  52 ;;; loaded the cl.el file already.
  53
  54 (defmacro cl-push (x place) (list 'setq place (list 'cons x place)))
  55 (defmacro cl-pop (place)
  56   (list 'car (list 'prog1 place (list 'setq place (list 'cdr place)))))
  57
  58
  59 ;;; Keyword parsing.  This is special-cased here so that we can compile
  60 ;;; this file independent from cl-macs.
  61
  62 (defmacro cl-parsing-keywords (kwords other-keys &rest body)
  63   (cons
  64    'let*
  65    (cons (mapcar
  66           (function
  67            (lambda (x)
  68              (let* ((var (if (consp x) (car x) x))
  69                     (mem (list 'car (list 'cdr (list 'memq (list 'quote var)
  70                                                      'cl-keys)))))
  71                (if (eq var :test-not)
  72                    (setq mem (list 'and mem (list 'setq 'cl-test mem) t)))
  73                (if (eq var :if-not)
  74                    (setq mem (list 'and mem (list 'setq 'cl-if mem) t)))
  75                (list (intern
  76                       (format "cl-%s" (substring (symbol-name var) 1)))
  77                      (if (consp x) (list 'or mem (car (cdr x))) mem)))))
  78           kwords)
  79          (append
  80           (and (not (eq other-keys t))
  81                (list
  82                 (list 'let '((cl-keys-temp cl-keys))
  83                       (list 'while 'cl-keys-temp
  84                             (list 'or (list 'memq '(car cl-keys-temp)
  85                                             (list 'quote
  86                                                   (mapcar
  87                                                    (function
  88                                                     (lambda (x)
  89                                                       (if (consp x)
  90                                                           (car x) x)))
  91                                                    (append kwords
  92                                                            other-keys))))
  93                                   '(car (cdr (memq (quote :allow-other-keys)
  94                                                    cl-keys)))
  95                                   '(error "Bad keyword argument %s"
  96                                           (car cl-keys-temp)))
  97                             '(setq cl-keys-temp (cdr (cdr cl-keys-temp)))))))
  98           body))))
  99 (put 'cl-parsing-keywords 'lisp-indent-function 2)
 100 (put 'cl-parsing-keywords 'edebug-form-spec '(sexp sexp &rest form))
 101
 102 (defmacro cl-check-key (x)
 103   (list 'if 'cl-key (list 'funcall 'cl-key x) x))
 104
 105 (defmacro cl-check-test-nokey (item x)
 106   (list 'cond
 107         (list 'cl-test
 108               (list 'eq (list 'not (list 'funcall 'cl-test item x))
 109                     'cl-test-not))
 110         (list 'cl-if
 111               (list 'eq (list 'not (list 'funcall 'cl-if x)) 'cl-if-not))
 112         (list 't (list 'if (list 'numberp item)
 113                        (list 'equal item x) (list 'eq item x)))))
 114
 115 (defmacro cl-check-test (item x)
 116   (list 'cl-check-test-nokey item (list 'cl-check-key x)))
 117
 118 (defmacro cl-check-match (x y)
 119   (setq x (list 'cl-check-key x) y (list 'cl-check-key y))
 120   (list 'if 'cl-test
 121         (list 'eq (list 'not (list 'funcall 'cl-test x y)) 'cl-test-not)
 122         (list 'if (list 'numberp x)
 123               (list 'equal x y) (list 'eq x y))))
 124
 125 (put 'cl-check-key 'edebug-form-spec 'edebug-forms)
 126 (put 'cl-check-test 'edebug-form-spec 'edebug-forms)
 127 (put 'cl-check-test-nokey 'edebug-form-spec 'edebug-forms)
 128 (put 'cl-check-match 'edebug-form-spec 'edebug-forms)
 129
 130 (defvar cl-test) (defvar cl-test-not)
 131 (defvar cl-if) (defvar cl-if-not)
 132 (defvar cl-key)
 133
 134
 135 (defun reduce (cl-func cl-seq &rest cl-keys)
 136   "Reduce two-argument FUNCTION across SEQUENCE.
 137 Keywords supported:  :start :end :from-end :initial-value :key"
 138   (cl-parsing-keywords (:from-end (:start 0) :end :initial-value :key) ()
 139     (or (listp cl-seq) (setq cl-seq (append cl-seq nil)))
 140     (setq cl-seq (subseq cl-seq cl-start cl-end))
 141     (if cl-from-end (setq cl-seq (nreverse cl-seq)))
 142     (let ((cl-accum (cond ((memq :initial-value cl-keys) cl-initial-value)
 143                           (cl-seq (cl-check-key (cl-pop cl-seq)))
 144                           (t (funcall cl-func)))))
 145       (if cl-from-end
 146           (while cl-seq
 147             (setq cl-accum (funcall cl-func (cl-check-key (cl-pop cl-seq))
 148                                     cl-accum)))
 149         (while cl-seq
 150           (setq cl-accum (funcall cl-func cl-accum
 151                                   (cl-check-key (cl-pop cl-seq))))))
 152       cl-accum)))
 153
 154 (defun fill (seq item &rest cl-keys)
 155   "Fill the elements of SEQ with ITEM.
 156 Keywords supported:  :start :end"
 157   (cl-parsing-keywords ((:start 0) :end) ()
 158     (if (listp seq)
 159         (let ((p (nthcdr cl-start seq))
 160               (n (if cl-end (- cl-end cl-start) 8000000)))
 161           (while (and p (>= (setq n (1- n)) 0))
 162             (setcar p item)
 163             (setq p (cdr p))))
 164       (or cl-end (setq cl-end (length seq)))
 165       (if (and (= cl-start 0) (= cl-end (length seq)))
 166           (fillarray seq item)
 167         (while (< cl-start cl-end)
 168           (aset seq cl-start item)
 169           (setq cl-start (1+ cl-start)))))
 170     seq))
 171
 172 (defun replace (cl-seq1 cl-seq2 &rest cl-keys)
 173   "Replace the elements of SEQ1 with the elements of SEQ2.
 174 SEQ1 is destructively modified, then returned.
 175 Keywords supported:  :start1 :end1 :start2 :end2"
 176   (cl-parsing-keywords ((:start1 0) :end1 (:start2 0) :end2) ()
 177     (if (and (eq cl-seq1 cl-seq2) (<= cl-start2 cl-start1))
 178         (or (= cl-start1 cl-start2)
 179             (let* ((cl-len (length cl-seq1))
 180                    (cl-n (min (- (or cl-end1 cl-len) cl-start1)
 181                               (- (or cl-end2 cl-len) cl-start2))))
 182               (while (>= (setq cl-n (1- cl-n)) 0)
 183                 (cl-set-elt cl-seq1 (+ cl-start1 cl-n)
 184                             (elt cl-seq2 (+ cl-start2 cl-n))))))
 185       (if (listp cl-seq1)
 186           (let ((cl-p1 (nthcdr cl-start1 cl-seq1))
 187                 (cl-n1 (if cl-end1 (- cl-end1 cl-start1) 4000000)))
 188             (if (listp cl-seq2)
 189                 (let ((cl-p2 (nthcdr cl-start2 cl-seq2))
 190                       (cl-n (min cl-n1
 191                                  (if cl-end2 (- cl-end2 cl-start2) 4000000))))
 192                   (while (and cl-p1 cl-p2 (>= (setq cl-n (1- cl-n)) 0))
 193                     (setcar cl-p1 (car cl-p2))
 194                     (setq cl-p1 (cdr cl-p1) cl-p2 (cdr cl-p2))))
 195               (setq cl-end2 (min (or cl-end2 (length cl-seq2))
 196                                  (+ cl-start2 cl-n1)))
 197               (while (and cl-p1 (< cl-start2 cl-end2))
 198                 (setcar cl-p1 (aref cl-seq2 cl-start2))
 199                 (setq cl-p1 (cdr cl-p1) cl-start2 (1+ cl-start2)))))
 200         (setq cl-end1 (min (or cl-end1 (length cl-seq1))
 201                            (+ cl-start1 (- (or cl-end2 (length cl-seq2))
 202                                            cl-start2))))
 203         (if (listp cl-seq2)
 204             (let ((cl-p2 (nthcdr cl-start2 cl-seq2)))
 205               (while (< cl-start1 cl-end1)
 206                 (aset cl-seq1 cl-start1 (car cl-p2))
 207                 (setq cl-p2 (cdr cl-p2) cl-start1 (1+ cl-start1))))
 208           (while (< cl-start1 cl-end1)
 209             (aset cl-seq1 cl-start1 (aref cl-seq2 cl-start2))
 210             (setq cl-start2 (1+ cl-start2) cl-start1 (1+ cl-start1))))))
 211     cl-seq1))
 212
 213 (defun remove* (cl-item cl-seq &rest cl-keys)
 214   "Remove all occurrences of ITEM in SEQ.
 215 This is a non-destructive function; it makes a copy of SEQ if necessary
 216 to avoid corrupting the original SEQ.
 217 Keywords supported:  :test :test-not :key :count :start :end :from-end"
 218   (cl-parsing-keywords (:test :test-not :key :if :if-not :count :from-end
 219                         (:start 0) :end) ()
 220     (if (<= (or cl-count (setq cl-count 8000000)) 0)
 221         cl-seq
 222       (if (or (nlistp cl-seq) (and cl-from-end (< cl-count 4000000)))
 223           (let ((cl-i (cl-position cl-item cl-seq cl-start cl-end
 224                                    cl-from-end)))
 225             (if cl-i
 226                 (let ((cl-res (apply 'delete* cl-item (append cl-seq nil)
 227                                      (append (if cl-from-end
 228                                                  (list :end (1+ cl-i))
 229                                                (list :start cl-i))
 230                                              cl-keys))))
 231                   (if (listp cl-seq) cl-res
 232                     (if (stringp cl-seq) (concat cl-res) (vconcat cl-res))))
 233               cl-seq))
 234         (setq cl-end (- (or cl-end 8000000) cl-start))
 235         (if (= cl-start 0)
 236             (while (and cl-seq (> cl-end 0)
 237                         (cl-check-test cl-item (car cl-seq))
 238                         (setq cl-end (1- cl-end) cl-seq (cdr cl-seq))
 239                         (> (setq cl-count (1- cl-count)) 0))))
 240         (if (and (> cl-count 0) (> cl-end 0))
 241             (let ((cl-p (if (> cl-start 0) (nthcdr cl-start cl-seq)
 242                           (setq cl-end (1- cl-end)) (cdr cl-seq))))
 243               (while (and cl-p (> cl-end 0)
 244                           (not (cl-check-test cl-item (car cl-p))))
 245                 (setq cl-p (cdr cl-p) cl-end (1- cl-end)))
 246               (if (and cl-p (> cl-end 0))
 247                   (nconc (ldiff cl-seq cl-p)
 248                          (if (= cl-count 1) (cdr cl-p)
 249                            (and (cdr cl-p)
 250                                 (apply 'delete* cl-item
 251                                        (copy-sequence (cdr cl-p))
 252                                        :start 0 :end (1- cl-end)
 253                                        :count (1- cl-count) cl-keys))))
 254                 cl-seq))
 255           cl-seq)))))
 256
 257 (defun remove-if (cl-pred cl-list &rest cl-keys)
 258   "Remove all items satisfying PREDICATE in SEQ.
 259 This is a non-destructive function; it makes a copy of SEQ if necessary
 260 to avoid corrupting the original SEQ.
 261 Keywords supported:  :key :count :start :end :from-end"
 262   (apply 'remove* nil cl-list :if cl-pred cl-keys))
 263
 264 (defun remove-if-not (cl-pred cl-list &rest cl-keys)
 265   "Remove all items not satisfying PREDICATE in SEQ.
 266 This is a non-destructive function; it makes a copy of SEQ if necessary
 267 to avoid corrupting the original SEQ.
 268 Keywords supported:  :key :count :start :end :from-end"
 269   (apply 'remove* nil cl-list :if-not cl-pred cl-keys))
 270
 271 (defun delete* (cl-item cl-seq &rest cl-keys)
 272   "Remove all occurrences of ITEM in SEQ.
 273 This is a destructive function; it reuses the storage of SEQ whenever possible.
 274 Keywords supported:  :test :test-not :key :count :start :end :from-end"
 275   (cl-parsing-keywords (:test :test-not :key :if :if-not :count :from-end
 276                         (:start 0) :end) ()
 277     (if (<= (or cl-count (setq cl-count 8000000)) 0)
 278         cl-seq
 279       (if (listp cl-seq)
 280           (if (and cl-from-end (< cl-count 4000000))
 281               (let (cl-i)
 282                 (while (and (>= (setq cl-count (1- cl-count)) 0)
 283                             (setq cl-i (cl-position cl-item cl-seq cl-start
 284                                                     cl-end cl-from-end)))
 285                   (if (= cl-i 0) (setq cl-seq (cdr cl-seq))
 286                     (let ((cl-tail (nthcdr (1- cl-i) cl-seq)))
 287                       (setcdr cl-tail (cdr (cdr cl-tail)))))
 288                   (setq cl-end cl-i))
 289                 cl-seq)
 290             (setq cl-end (- (or cl-end 8000000) cl-start))
 291             (if (= cl-start 0)
 292                 (progn
 293                   (while (and cl-seq
 294                               (> cl-end 0)
 295                               (cl-check-test cl-item (car cl-seq))
 296                               (setq cl-end (1- cl-end) cl-seq (cdr cl-seq))
 297                               (> (setq cl-count (1- cl-count)) 0)))
 298                   (setq cl-end (1- cl-end)))
 299               (setq cl-start (1- cl-start)))
 300             (if (and (> cl-count 0) (> cl-end 0))
 301                 (let ((cl-p (nthcdr cl-start cl-seq)))
 302                   (while (and (cdr cl-p) (> cl-end 0))
 303                     (if (cl-check-test cl-item (car (cdr cl-p)))
 304                         (progn
 305                           (setcdr cl-p (cdr (cdr cl-p)))
 306                           (if (= (setq cl-count (1- cl-count)) 0)
 307                               (setq cl-end 1)))
 308                       (setq cl-p (cdr cl-p)))
 309                     (setq cl-end (1- cl-end)))))
 310             cl-seq)
 311         (apply 'remove* cl-item cl-seq cl-keys)))))
 312
 313 (defun delete-if (cl-pred cl-list &rest cl-keys)
 314   "Remove all items satisfying PREDICATE in SEQ.
 315 This is a destructive function; it reuses the storage of SEQ whenever possible.
 316 Keywords supported:  :key :count :start :end :from-end"
 317   (apply 'delete* nil cl-list :if cl-pred cl-keys))
 318
 319 (defun delete-if-not (cl-pred cl-list &rest cl-keys)
 320   "Remove all items not satisfying PREDICATE in SEQ.
 321 This is a destructive function; it reuses the storage of SEQ whenever possible.
 322 Keywords supported:  :key :count :start :end :from-end"
 323   (apply 'delete* nil cl-list :if-not cl-pred cl-keys))
 324
 325 (defun remove-duplicates (cl-seq &rest cl-keys)
 326   "Return a copy of SEQ with all duplicate elements removed.
 327 Keywords supported:  :test :test-not :key :start :end :from-end"
 328   (cl-delete-duplicates cl-seq cl-keys t))
 329
 330 (defun delete-duplicates (cl-seq &rest cl-keys)
 331   "Remove all duplicate elements from SEQ (destructively).
 332 Keywords supported:  :test :test-not :key :start :end :from-end"
 333   (cl-delete-duplicates cl-seq cl-keys nil))
 334
 335 (defun cl-delete-duplicates (cl-seq cl-keys cl-copy)
 336   (if (listp cl-seq)
 337       (cl-parsing-keywords (:test :test-not :key (:start 0) :end :from-end :if)
 338           ()
 339         (if cl-from-end
 340             (let ((cl-p (nthcdr cl-start cl-seq)) cl-i)
 341               (setq cl-end (- (or cl-end (length cl-seq)) cl-start))
 342               (while (> cl-end 1)
 343                 (setq cl-i 0)
 344                 (while (setq cl-i (cl-position (cl-check-key (car cl-p))
 345                                                (cdr cl-p) cl-i (1- cl-end)))
 346                   (if cl-copy (setq cl-seq (copy-sequence cl-seq)
 347                                     cl-p (nthcdr cl-start cl-seq) cl-copy nil))
 348                   (let ((cl-tail (nthcdr cl-i cl-p)))
 349                     (setcdr cl-tail (cdr (cdr cl-tail))))
 350                   (setq cl-end (1- cl-end)))
 351                 (setq cl-p (cdr cl-p) cl-end (1- cl-end)
 352                       cl-start (1+ cl-start)))
 353               cl-seq)
 354           (setq cl-end (- (or cl-end (length cl-seq)) cl-start))
 355           (while (and (cdr cl-seq) (= cl-start 0) (> cl-end 1)
 356                       (cl-position (cl-check-key (car cl-seq))
 357                                    (cdr cl-seq) 0 (1- cl-end)))
 358             (setq cl-seq (cdr cl-seq) cl-end (1- cl-end)))
 359           (let ((cl-p (if (> cl-start 0) (nthcdr (1- cl-start) cl-seq)
 360                         (setq cl-end (1- cl-end) cl-start 1) cl-seq)))
 361             (while (and (cdr (cdr cl-p)) (> cl-end 1))
 362               (if (cl-position (cl-check-key (car (cdr cl-p)))
 363                                (cdr (cdr cl-p)) 0 (1- cl-end))
 364                   (progn
 365                     (if cl-copy (setq cl-seq (copy-sequence cl-seq)
 366                                       cl-p (nthcdr (1- cl-start) cl-seq)
 367                                       cl-copy nil))
 368                     (setcdr cl-p (cdr (cdr cl-p))))
 369                 (setq cl-p (cdr cl-p)))
 370               (setq cl-end (1- cl-end) cl-start (1+ cl-start)))
 371             cl-seq)))
 372     (let ((cl-res (cl-delete-duplicates (append cl-seq nil) cl-keys nil)))
 373       (if (stringp cl-seq) (concat cl-res) (vconcat cl-res)))))
 374
 375 (defun substitute (cl-new cl-old cl-seq &rest cl-keys)
 376   "Substitute NEW for OLD in SEQ.
 377 This is a non-destructive function; it makes a copy of SEQ if necessary
 378 to avoid corrupting the original SEQ.
 379 Keywords supported:  :test :test-not :key :count :start :end :from-end"
 380   (cl-parsing-keywords (:test :test-not :key :if :if-not :count
 381                         (:start 0) :end :from-end) ()
 382     (if (or (eq cl-old cl-new)
 383             (<= (or cl-count (setq cl-from-end nil cl-count 8000000)) 0))
 384         cl-seq
 385       (let ((cl-i (cl-position cl-old cl-seq cl-start cl-end)))
 386         (if (not cl-i)
 387             cl-seq
 388           (setq cl-seq (copy-sequence cl-seq))
 389           (or cl-from-end
 390               (progn (cl-set-elt cl-seq cl-i cl-new)
 391                      (setq cl-i (1+ cl-i) cl-count (1- cl-count))))
 392           (apply 'nsubstitute cl-new cl-old cl-seq :count cl-count
 393                  :start cl-i cl-keys))))))
 394
 395 (defun substitute-if (cl-new cl-pred cl-list &rest cl-keys)
 396   "Substitute NEW for all items satisfying PREDICATE in SEQ.
 397 This is a non-destructive function; it makes a copy of SEQ if necessary
 398 to avoid corrupting the original SEQ.
 399 Keywords supported:  :key :count :start :end :from-end"
 400   (apply 'substitute cl-new nil cl-list :if cl-pred cl-keys))
 401
 402 (defun substitute-if-not (cl-new cl-pred cl-list &rest cl-keys)
 403   "Substitute NEW for all items not satisfying PREDICATE in SEQ.
 404 This is a non-destructive function; it makes a copy of SEQ if necessary
 405 to avoid corrupting the original SEQ.
 406 Keywords supported:  :key :count :start :end :from-end"
 407   (apply 'substitute cl-new nil cl-list :if-not cl-pred cl-keys))
 408
 409 (defun nsubstitute (cl-new cl-old cl-seq &rest cl-keys)
 410   "Substitute NEW for OLD in SEQ.
 411 This is a destructive function; it reuses the storage of SEQ whenever possible.
 412 Keywords supported:  :test :test-not :key :count :start :end :from-end"
 413   (cl-parsing-keywords (:test :test-not :key :if :if-not :count
 414                         (:start 0) :end :from-end) ()
 415     (or (eq cl-old cl-new) (<= (or cl-count (setq cl-count 8000000)) 0)
 416         (if (and (listp cl-seq) (or (not cl-from-end) (> cl-count 4000000)))
 417             (let ((cl-p (nthcdr cl-start cl-seq)))
 418               (setq cl-end (- (or cl-end 8000000) cl-start))
 419               (while (and cl-p (> cl-end 0) (> cl-count 0))
 420                 (if (cl-check-test cl-old (car cl-p))
 421                     (progn
 422                       (setcar cl-p cl-new)
 423                       (setq cl-count (1- cl-count))))
 424                 (setq cl-p (cdr cl-p) cl-end (1- cl-end))))
 425           (or cl-end (setq cl-end (length cl-seq)))
 426           (if cl-from-end
 427               (while (and (< cl-start cl-end) (> cl-count 0))
 428                 (setq cl-end (1- cl-end))
 429                 (if (cl-check-test cl-old (elt cl-seq cl-end))
 430                     (progn
 431                       (cl-set-elt cl-seq cl-end cl-new)
 432                       (setq cl-count (1- cl-count)))))
 433             (while (and (< cl-start cl-end) (> cl-count 0))
 434               (if (cl-check-test cl-old (aref cl-seq cl-start))
 435                   (progn
 436                     (aset cl-seq cl-start cl-new)
 437                     (setq cl-count (1- cl-count))))
 438               (setq cl-start (1+ cl-start))))))
 439     cl-seq))
 440
 441 (defun nsubstitute-if (cl-new cl-pred cl-list &rest cl-keys)
 442   "Substitute NEW for all items satisfying PREDICATE in SEQ.
 443 This is a destructive function; it reuses the storage of SEQ whenever possible.
 444 Keywords supported:  :key :count :start :end :from-end"
 445   (apply 'nsubstitute cl-new nil cl-list :if cl-pred cl-keys))
 446
 447 (defun nsubstitute-if-not (cl-new cl-pred cl-list &rest cl-keys)
 448   "Substitute NEW for all items not satisfying PREDICATE in SEQ.
 449 This is a destructive function; it reuses the storage of SEQ whenever possible.
 450 Keywords supported:  :key :count :start :end :from-end"
 451   (apply 'nsubstitute cl-new nil cl-list :if-not cl-pred cl-keys))
 452
 453 (defun find (cl-item cl-seq &rest cl-keys)
 454   "Find the first occurrence of ITEM in LIST.
 455 Return the matching ITEM, or nil if not found.
 456 Keywords supported:  :test :test-not :key :start :end :from-end"
 457   (let ((cl-pos (apply 'position cl-item cl-seq cl-keys)))
 458     (and cl-pos (elt cl-seq cl-pos))))
 459
 460 (defun find-if (cl-pred cl-list &rest cl-keys)
 461   "Find the first item satisfying PREDICATE in LIST.
 462 Return the matching ITEM, or nil if not found.
 463 Keywords supported:  :key :start :end :from-end"
 464   (apply 'find nil cl-list :if cl-pred cl-keys))
 465
 466 (defun find-if-not (cl-pred cl-list &rest cl-keys)
 467   "Find the first item not satisfying PREDICATE in LIST.
 468 Return the matching ITEM, or nil if not found.
 469 Keywords supported:  :key :start :end :from-end"
 470   (apply 'find nil cl-list :if-not cl-pred cl-keys))
 471
 472 (defun position (cl-item cl-seq &rest cl-keys)
 473   "Find the first occurrence of ITEM in LIST.
 474 Return the index of the matching item, or nil if not found.
 475 Keywords supported:  :test :test-not :key :start :end :from-end"
 476   (cl-parsing-keywords (:test :test-not :key :if :if-not
 477                         (:start 0) :end :from-end) ()
 478     (cl-position cl-item cl-seq cl-start cl-end cl-from-end)))
 479
 480 (defun cl-position (cl-item cl-seq cl-start &optional cl-end cl-from-end)
 481   (if (listp cl-seq)
 482       (let ((cl-p (nthcdr cl-start cl-seq)))
 483         (or cl-end (setq cl-end 8000000))
 484         (let ((cl-res nil))
 485           (while (and cl-p (< cl-start cl-end) (or (not cl-res) cl-from-end))
 486             (if (cl-check-test cl-item (car cl-p))
 487                 (setq cl-res cl-start))
 488             (setq cl-p (cdr cl-p) cl-start (1+ cl-start)))
 489           cl-res))
 490     (or cl-end (setq cl-end (length cl-seq)))
 491     (if cl-from-end
 492         (progn
 493           (while (and (>= (setq cl-end (1- cl-end)) cl-start)
 494                       (not (cl-check-test cl-item (aref cl-seq cl-end)))))
 495           (and (>= cl-end cl-start) cl-end))
 496       (while (and (< cl-start cl-end)
 497                   (not (cl-check-test cl-item (aref cl-seq cl-start))))
 498         (setq cl-start (1+ cl-start)))
 499       (and (< cl-start cl-end) cl-start))))
 500
 501 (defun position-if (cl-pred cl-list &rest cl-keys)
 502   "Find the first item satisfying PREDICATE in LIST.
 503 Return the index of the matching item, or nil if not found.
 504 Keywords supported:  :key :start :end :from-end"
 505   (apply 'position nil cl-list :if cl-pred cl-keys))
 506
 507 (defun position-if-not (cl-pred cl-list &rest cl-keys)
 508   "Find the first item not satisfying PREDICATE in LIST.
 509 Return the index of the matching item, or nil if not found.
 510 Keywords supported:  :key :start :end :from-end"
 511   (apply 'position nil cl-list :if-not cl-pred cl-keys))
 512
 513 (defun count (cl-item cl-seq &rest cl-keys)
 514   "Count the number of occurrences of ITEM in LIST.
 515 Keywords supported:  :test :test-not :key :start :end"
 516   (cl-parsing-keywords (:test :test-not :key :if :if-not (:start 0) :end) ()
 517     (let ((cl-count 0) cl-x)
 518       (or cl-end (setq cl-end (length cl-seq)))
 519       (if (consp cl-seq) (setq cl-seq (nthcdr cl-start cl-seq)))
 520       (while (< cl-start cl-end)
 521         (setq cl-x (if (consp cl-seq) (cl-pop cl-seq) (aref cl-seq cl-start)))
 522         (if (cl-check-test cl-item cl-x) (setq cl-count (1+ cl-count)))
 523         (setq cl-start (1+ cl-start)))
 524       cl-count)))
 525
 526 (defun count-if (cl-pred cl-list &rest cl-keys)
 527   "Count the number of items satisfying PREDICATE in LIST.
 528 Keywords supported:  :key :start :end"
 529   (apply 'count nil cl-list :if cl-pred cl-keys))
 530
 531 (defun count-if-not (cl-pred cl-list &rest cl-keys)
 532   "Count the number of items not satisfying PREDICATE in LIST.
 533 Keywords supported:  :key :start :end"
 534   (apply 'count nil cl-list :if-not cl-pred cl-keys))
 535
 536 (defun mismatch (cl-seq1 cl-seq2 &rest cl-keys)
 537   "Compare SEQ1 with SEQ2, return index of first mismatching element.
 538 Return nil if the sequences match.  If one sequence is a prefix of the
 539 other, the return value indicates the end of the shorter sequence.
 540 Keywords supported:  :test :test-not :key :start1 :end1 :start2 :end2 :from-end"
 541   (cl-parsing-keywords (:test :test-not :key :from-end
 542                         (:start1 0) :end1 (:start2 0) :end2) ()
 543     (or cl-end1 (setq cl-end1 (length cl-seq1)))
 544     (or cl-end2 (setq cl-end2 (length cl-seq2)))
 545     (if cl-from-end
 546         (progn
 547           (while (and (< cl-start1 cl-end1) (< cl-start2 cl-end2)
 548                       (cl-check-match (elt cl-seq1 (1- cl-end1))
 549                                       (elt cl-seq2 (1- cl-end2))))
 550             (setq cl-end1 (1- cl-end1) cl-end2 (1- cl-end2)))
 551           (and (or (< cl-start1 cl-end1) (< cl-start2 cl-end2))
 552                (1- cl-end1)))
 553       (let ((cl-p1 (and (listp cl-seq1) (nthcdr cl-start1 cl-seq1)))
 554             (cl-p2 (and (listp cl-seq2) (nthcdr cl-start2 cl-seq2))))
 555         (while (and (< cl-start1 cl-end1) (< cl-start2 cl-end2)
 556                     (cl-check-match (if cl-p1 (car cl-p1)
 557                                       (aref cl-seq1 cl-start1))
 558                                     (if cl-p2 (car cl-p2)
 559                                       (aref cl-seq2 cl-start2))))
 560           (setq cl-p1 (cdr cl-p1) cl-p2 (cdr cl-p2)
 561                 cl-start1 (1+ cl-start1) cl-start2 (1+ cl-start2)))
 562         (and (or (< cl-start1 cl-end1) (< cl-start2 cl-end2))
 563              cl-start1)))))
 564
 565 (defun search (cl-seq1 cl-seq2 &rest cl-keys)
 566   "Search for SEQ1 as a subsequence of SEQ2.
 567 Return the index of the leftmost element of the first match found;
 568 return nil if there are no matches.
 569 Keywords supported:  :test :test-not :key :start1 :end1 :start2 :end2 :from-end"
 570   (cl-parsing-keywords (:test :test-not :key :from-end
 571                         (:start1 0) :end1 (:start2 0) :end2) ()
 572     (or cl-end1 (setq cl-end1 (length cl-seq1)))
 573     (or cl-end2 (setq cl-end2 (length cl-seq2)))
 574     (if (>= cl-start1 cl-end1)
 575         (if cl-from-end cl-end2 cl-start2)
 576       (let* ((cl-len (- cl-end1 cl-start1))
 577              (cl-first (cl-check-key (elt cl-seq1 cl-start1)))
 578              (cl-if nil) cl-pos)
 579         (setq cl-end2 (- cl-end2 (1- cl-len)))
 580         (while (and (< cl-start2 cl-end2)
 581                     (setq cl-pos (cl-position cl-first cl-seq2
 582                                               cl-start2 cl-end2 cl-from-end))
 583                     (apply 'mismatch cl-seq1 cl-seq2
 584                            :start1 (1+ cl-start1) :end1 cl-end1
 585                            :start2 (1+ cl-pos) :end2 (+ cl-pos cl-len)
 586                            :from-end nil cl-keys))
 587           (if cl-from-end (setq cl-end2 cl-pos) (setq cl-start2 (1+ cl-pos))))
 588         (and (< cl-start2 cl-end2) cl-pos)))))
 589
 590 (defun sort* (cl-seq cl-pred &rest cl-keys)
 591   "Sort the argument SEQUENCE according to PREDICATE.
 592 This is a destructive function; it reuses the storage of SEQUENCE if possible.
 593 Keywords supported:  :key"
 594   (if (nlistp cl-seq)
 595       (replace cl-seq (apply 'sort* (append cl-seq nil) cl-pred cl-keys))
 596     (cl-parsing-keywords (:key) ()
 597       (if (memq cl-key '(nil identity))
 598           (sort cl-seq cl-pred)
 599         (sort cl-seq (function (lambda (cl-x cl-y)
 600                                  (funcall cl-pred (funcall cl-key cl-x)
 601                                           (funcall cl-key cl-y)))))))))
 602
 603 (defun stable-sort (cl-seq cl-pred &rest cl-keys)
 604   "Sort the argument SEQUENCE stably according to PREDICATE.
 605 This is a destructive function; it reuses the storage of SEQUENCE if possible.
 606 Keywords supported:  :key"
 607   (apply 'sort* cl-seq cl-pred cl-keys))
 608
 609 (defun merge (cl-type cl-seq1 cl-seq2 cl-pred &rest cl-keys)
 610   "Destructively merge the two sequences to produce a new sequence.
 611 TYPE is the sequence type to return, SEQ1 and SEQ2 are the two
 612 argument sequences, and PRED is a `less-than' predicate on the elements.
 613 Keywords supported:  :key"
 614   (or (listp cl-seq1) (setq cl-seq1 (append cl-seq1 nil)))
 615   (or (listp cl-seq2) (setq cl-seq2 (append cl-seq2 nil)))
 616   (cl-parsing-keywords (:key) ()
 617     (let ((cl-res nil))
 618       (while (and cl-seq1 cl-seq2)
 619         (if (funcall cl-pred (cl-check-key (car cl-seq2))
 620                      (cl-check-key (car cl-seq1)))
 621             (cl-push (cl-pop cl-seq2) cl-res)
 622           (cl-push (cl-pop cl-seq1) cl-res)))
 623       (coerce (nconc (nreverse cl-res) cl-seq1 cl-seq2) cl-type))))
 624
 625 ;;; See compiler macro in cl-macs.el
 626 (defun member* (cl-item cl-list &rest cl-keys)
 627   "Find the first occurrence of ITEM in LIST.
 628 Return the sublist of LIST whose car is ITEM.
 629 Keywords supported:  :test :test-not :key"
 630   (if cl-keys
 631       (cl-parsing-keywords (:test :test-not :key :if :if-not) ()
 632         (while (and cl-list (not (cl-check-test cl-item (car cl-list))))
 633           (setq cl-list (cdr cl-list)))
 634         cl-list)
 635     (if (and (numberp cl-item) (not (integerp cl-item)))
 636         (member cl-item cl-list)
 637       (memq cl-item cl-list))))
 638
 639 (defun member-if (cl-pred cl-list &rest cl-keys)
 640   "Find the first item satisfying PREDICATE in LIST.
 641 Return the sublist of LIST whose car matches.
 642 Keywords supported:  :key"
 643   (apply 'member* nil cl-list :if cl-pred cl-keys))
 644
 645 (defun member-if-not (cl-pred cl-list &rest cl-keys)
 646   "Find the first item not satisfying PREDICATE in LIST.
 647 Return the sublist of LIST whose car matches.
 648 Keywords supported:  :key"
 649   (apply 'member* nil cl-list :if-not cl-pred cl-keys))
 650
 651 (defun cl-adjoin (cl-item cl-list &rest cl-keys)
 652   (if (cl-parsing-keywords (:key) t
 653         (apply 'member* (cl-check-key cl-item) cl-list cl-keys))
 654       cl-list
 655     (cons cl-item cl-list)))
 656
 657 ;;; See compiler macro in cl-macs.el
 658 (defun assoc* (cl-item cl-alist &rest cl-keys)
 659   "Find the first item whose car matches ITEM in LIST.
 660 Keywords supported:  :test :test-not :key"
 661   (if cl-keys
 662       (cl-parsing-keywords (:test :test-not :key :if :if-not) ()
 663         (while (and cl-alist
 664                     (or (not (consp (car cl-alist)))
 665                         (not (cl-check-test cl-item (car (car cl-alist))))))
 666           (setq cl-alist (cdr cl-alist)))
 667         (and cl-alist (car cl-alist)))
 668     (if (and (numberp cl-item) (not (integerp cl-item)))
 669         (assoc cl-item cl-alist)
 670       (assq cl-item cl-alist))))
 671
 672 (defun assoc-if (cl-pred cl-list &rest cl-keys)
 673   "Find the first item whose car satisfies PREDICATE in LIST.
 674 Keywords supported:  :key"
 675   (apply 'assoc* nil cl-list :if cl-pred cl-keys))
 676
 677 (defun assoc-if-not (cl-pred cl-list &rest cl-keys)
 678   "Find the first item whose car does not satisfy PREDICATE in LIST.
 679 Keywords supported:  :key"
 680   (apply 'assoc* nil cl-list :if-not cl-pred cl-keys))
 681
 682 (defun rassoc* (cl-item cl-alist &rest cl-keys)
 683   "Find the first item whose cdr matches ITEM in LIST.
 684 Keywords supported:  :test :test-not :key"
 685   (if (or cl-keys (numberp cl-item))
 686       (cl-parsing-keywords (:test :test-not :key :if :if-not) ()
 687         (while (and cl-alist
 688                     (or (not (consp (car cl-alist)))
 689                         (not (cl-check-test cl-item (cdr (car cl-alist))))))
 690           (setq cl-alist (cdr cl-alist)))
 691         (and cl-alist (car cl-alist)))
 692     (rassq cl-item cl-alist)))
 693
 694 (defun rassoc-if (cl-pred cl-list &rest cl-keys)
 695   "Find the first item whose cdr satisfies PREDICATE in LIST.
 696 Keywords supported:  :key"
 697   (apply 'rassoc* nil cl-list :if cl-pred cl-keys))
 698
 699 (defun rassoc-if-not (cl-pred cl-list &rest cl-keys)
 700   "Find the first item whose cdr does not satisfy PREDICATE in LIST.
 701 Keywords supported:  :key"
 702   (apply 'rassoc* nil cl-list :if-not cl-pred cl-keys))
 703
 704 (defun union (cl-list1 cl-list2 &rest cl-keys)
 705   "Combine LIST1 and LIST2 using a set-union operation.
 706 The result list contains all items that appear in either LIST1 or LIST2.
 707 This is a non-destructive function; it makes a copy of the data if necessary
 708 to avoid corrupting the original LIST1 and LIST2.
 709 Keywords supported:  :test :test-not :key"
 710   (cond ((null cl-list1) cl-list2) ((null cl-list2) cl-list1)
 711         ((equal cl-list1 cl-list2) cl-list1)
 712         (t
 713          (or (>= (length cl-list1) (length cl-list2))
 714              (setq cl-list1 (prog1 cl-list2 (setq cl-list2 cl-list1))))
 715          (while cl-list2
 716            (if (or cl-keys (numberp (car cl-list2)))
 717                (setq cl-list1 (apply 'adjoin (car cl-list2) cl-list1 cl-keys))
 718              (or (memq (car cl-list2) cl-list1)
 719                  (cl-push (car cl-list2) cl-list1)))
 720            (cl-pop cl-list2))
 721          cl-list1)))
 722
 723 (defun nunion (cl-list1 cl-list2 &rest cl-keys)
 724   "Combine LIST1 and LIST2 using a set-union operation.
 725 The result list contains all items that appear in either LIST1 or LIST2.
 726 This is a destructive function; it reuses the storage of LIST1 and LIST2
 727 whenever possible.
 728 Keywords supported:  :test :test-not :key"
 729   (cond ((null cl-list1) cl-list2) ((null cl-list2) cl-list1)
 730         (t (apply 'union cl-list1 cl-list2 cl-keys))))
 731
 732 (defun intersection (cl-list1 cl-list2 &rest cl-keys)
 733   "Combine LIST1 and LIST2 using a set-intersection operation.
 734 The result list contains all items that appear in both LIST1 and LIST2.
 735 This is a non-destructive function; it makes a copy of the data if necessary
 736 to avoid corrupting the original LIST1 and LIST2.
 737 Keywords supported:  :test :test-not :key"
 738   (and cl-list1 cl-list2
 739        (if (equal cl-list1 cl-list2) cl-list1
 740          (cl-parsing-keywords (:key) (:test :test-not)
 741            (let ((cl-res nil))
 742              (or (>= (length cl-list1) (length cl-list2))
 743                  (setq cl-list1 (prog1 cl-list2 (setq cl-list2 cl-list1))))
 744              (while cl-list2
 745                (if (if (or cl-keys (numberp (car cl-list2)))
 746                        (apply 'member* (cl-check-key (car cl-list2))
 747                               cl-list1 cl-keys)
 748                      (memq (car cl-list2) cl-list1))
 749                    (cl-push (car cl-list2) cl-res))
 750                (cl-pop cl-list2))
 751              cl-res)))))
 752
 753 (defun nintersection (cl-list1 cl-list2 &rest cl-keys)
 754   "Combine LIST1 and LIST2 using a set-intersection operation.
 755 The result list contains all items that appear in both LIST1 and LIST2.
 756 This is a destructive function; it reuses the storage of LIST1 and LIST2
 757 whenever possible.
 758 Keywords supported:  :test :test-not :key"
 759   (and cl-list1 cl-list2 (apply 'intersection cl-list1 cl-list2 cl-keys)))
 760
 761 (defun set-difference (cl-list1 cl-list2 &rest cl-keys)
 762   "Combine LIST1 and LIST2 using a set-difference operation.
 763 The result list contains all items that appear in LIST1 but not LIST2.
 764 This is a non-destructive function; it makes a copy of the data if necessary
 765 to avoid corrupting the original LIST1 and LIST2.
 766 Keywords supported:  :test :test-not :key"
 767   (if (or (null cl-list1) (null cl-list2)) cl-list1
 768     (cl-parsing-keywords (:key) (:test :test-not)
 769       (let ((cl-res nil))
 770         (while cl-list1
 771           (or (if (or cl-keys (numberp (car cl-list1)))
 772                   (apply 'member* (cl-check-key (car cl-list1))
 773                          cl-list2 cl-keys)
 774                 (memq (car cl-list1) cl-list2))
 775               (cl-push (car cl-list1) cl-res))
 776           (cl-pop cl-list1))
 777         cl-res))))
 778
 779 (defun nset-difference (cl-list1 cl-list2 &rest cl-keys)
 780   "Combine LIST1 and LIST2 using a set-difference operation.
 781 The result list contains all items that appear in LIST1 but not LIST2.
 782 This is a destructive function; it reuses the storage of LIST1 and LIST2
 783 whenever possible.
 784 Keywords supported:  :test :test-not :key"
 785   (if (or (null cl-list1) (null cl-list2)) cl-list1
 786     (apply 'set-difference cl-list1 cl-list2 cl-keys)))
 787
 788 (defun set-exclusive-or (cl-list1 cl-list2 &rest cl-keys)
 789   "Combine LIST1 and LIST2 using a set-exclusive-or operation.
 790 The result list contains all items that appear in exactly one of LIST1, LIST2.
 791 This is a non-destructive function; it makes a copy of the data if necessary
 792 to avoid corrupting the original LIST1 and LIST2.
 793 Keywords supported:  :test :test-not :key"
 794   (cond ((null cl-list1) cl-list2) ((null cl-list2) cl-list1)
 795         ((equal cl-list1 cl-list2) nil)
 796         (t (append (apply 'set-difference cl-list1 cl-list2 cl-keys)
 797                    (apply 'set-difference cl-list2 cl-list1 cl-keys)))))
 798
 799 (defun nset-exclusive-or (cl-list1 cl-list2 &rest cl-keys)
 800   "Combine LIST1 and LIST2 using a set-exclusive-or operation.
 801 The result list contains all items that appear in exactly one of LIST1, LIST2.
 802 This is a destructive function; it reuses the storage of LIST1 and LIST2
 803 whenever possible.
 804 Keywords supported:  :test :test-not :key"
 805   (cond ((null cl-list1) cl-list2) ((null cl-list2) cl-list1)
 806         ((equal cl-list1 cl-list2) nil)
 807         (t (nconc (apply 'nset-difference cl-list1 cl-list2 cl-keys)
 808                   (apply 'nset-difference cl-list2 cl-list1 cl-keys)))))
 809
 810 (defun subsetp (cl-list1 cl-list2 &rest cl-keys)
 811   "True if LIST1 is a subset of LIST2.
 812 I.e., if every element of LIST1 also appears in LIST2.
 813 Keywords supported:  :test :test-not :key"
 814   (cond ((null cl-list1) t) ((null cl-list2) nil)
 815         ((equal cl-list1 cl-list2) t)
 816         (t (cl-parsing-keywords (:key) (:test :test-not)
 817              (while (and cl-list1
 818                          (apply 'member* (cl-check-key (car cl-list1))
 819                                 cl-list2 cl-keys))
 820                (cl-pop cl-list1))
 821              (null cl-list1)))))
 822
 823 (defun subst-if (cl-new cl-pred cl-tree &rest cl-keys)
 824   "Substitute NEW for elements matching PREDICATE in TREE (non-destructively).
 825 Return a copy of TREE with all matching elements replaced by NEW.
 826 Keywords supported:  :key"
 827   (apply 'sublis (list (cons nil cl-new)) cl-tree :if cl-pred cl-keys))
 828
 829 (defun subst-if-not (cl-new cl-pred cl-tree &rest cl-keys)
 830   "Substitute NEW for elts not matching PREDICATE in TREE (non-destructively).
 831 Return a copy of TREE with all non-matching elements replaced by NEW.
 832 Keywords supported:  :key"
 833   (apply 'sublis (list (cons nil cl-new)) cl-tree :if-not cl-pred cl-keys))
 834
 835 (defun nsubst (cl-new cl-old cl-tree &rest cl-keys)
 836   "Substitute NEW for OLD everywhere in TREE (destructively).
 837 Any element of TREE which is `eql' to OLD is changed to NEW (via a call
 838 to `setcar').
 839 Keywords supported:  :test :test-not :key"
 840   (apply 'nsublis (list (cons cl-old cl-new)) cl-tree cl-keys))
 841
 842 (defun nsubst-if (cl-new cl-pred cl-tree &rest cl-keys)
 843   "Substitute NEW for elements matching PREDICATE in TREE (destructively).
 844 Any element of TREE which matches is changed to NEW (via a call to `setcar').
 845 Keywords supported:  :key"
 846   (apply 'nsublis (list (cons nil cl-new)) cl-tree :if cl-pred cl-keys))
 847
 848 (defun nsubst-if-not (cl-new cl-pred cl-tree &rest cl-keys)
 849   "Substitute NEW for elements not matching PREDICATE in TREE (destructively).
 850 Any element of TREE which matches is changed to NEW (via a call to `setcar').
 851 Keywords supported:  :key"
 852   (apply 'nsublis (list (cons nil cl-new)) cl-tree :if-not cl-pred cl-keys))
 853
 854 (defun sublis (cl-alist cl-tree &rest cl-keys)
 855   "Perform substitutions indicated by ALIST in TREE (non-destructively).
 856 Return a copy of TREE with all matching elements replaced.
 857 Keywords supported:  :test :test-not :key"
 858   (cl-parsing-keywords (:test :test-not :key :if :if-not) ()
 859     (cl-sublis-rec cl-tree)))
 860
 861 (defvar cl-alist)
 862 (defun cl-sublis-rec (cl-tree)   ; uses cl-alist/key/test*/if*
 863   (let ((cl-temp (cl-check-key cl-tree)) (cl-p cl-alist))
 864     (while (and cl-p (not (cl-check-test-nokey (car (car cl-p)) cl-temp)))
 865       (setq cl-p (cdr cl-p)))
 866     (if cl-p (cdr (car cl-p))
 867       (if (consp cl-tree)
 868           (let ((cl-a (cl-sublis-rec (car cl-tree)))
 869                 (cl-d (cl-sublis-rec (cdr cl-tree))))
 870             (if (and (eq cl-a (car cl-tree)) (eq cl-d (cdr cl-tree)))
 871                 cl-tree
 872               (cons cl-a cl-d)))
 873         cl-tree))))
 874
 875 (defun nsublis (cl-alist cl-tree &rest cl-keys)
 876   "Perform substitutions indicated by ALIST in TREE (destructively).
 877 Any matching element of TREE is changed via a call to `setcar'.
 878 Keywords supported:  :test :test-not :key"
 879   (cl-parsing-keywords (:test :test-not :key :if :if-not) ()
 880     (let ((cl-hold (list cl-tree)))
 881       (cl-nsublis-rec cl-hold)
 882       (car cl-hold))))
 883
 884 (defun cl-nsublis-rec (cl-tree)   ; uses cl-alist/temp/p/key/test*/if*
 885   (while (consp cl-tree)
 886     (let ((cl-temp (cl-check-key (car cl-tree))) (cl-p cl-alist))
 887       (while (and cl-p (not (cl-check-test-nokey (car (car cl-p)) cl-temp)))
 888         (setq cl-p (cdr cl-p)))
 889       (if cl-p (setcar cl-tree (cdr (car cl-p)))
 890         (if (consp (car cl-tree)) (cl-nsublis-rec (car cl-tree))))
 891       (setq cl-temp (cl-check-key (cdr cl-tree)) cl-p cl-alist)
 892       (while (and cl-p (not (cl-check-test-nokey (car (car cl-p)) cl-temp)))
 893         (setq cl-p (cdr cl-p)))
 894       (if cl-p
 895           (progn (setcdr cl-tree (cdr (car cl-p))) (setq cl-tree nil))
 896         (setq cl-tree (cdr cl-tree))))))
 897
 898 (defun tree-equal (cl-x cl-y &rest cl-keys)
 899   "T if trees X and Y have `eql' leaves.
 900 Atoms are compared by `eql'; cons cells are compared recursively.
 901 Keywords supported:  :test :test-not :key"
 902   (cl-parsing-keywords (:test :test-not :key) ()
 903     (cl-tree-equal-rec cl-x cl-y)))
 904
 905 (defun cl-tree-equal-rec (cl-x cl-y)
 906   (while (and (consp cl-x) (consp cl-y)
 907               (cl-tree-equal-rec (car cl-x) (car cl-y)))
 908     (setq cl-x (cdr cl-x) cl-y (cdr cl-y)))
 909   (and (not (consp cl-x)) (not (consp cl-y)) (cl-check-match cl-x cl-y)))
 910
 911
 912 (run-hooks 'cl-seq-load-hook)
 913
 914 ;;; cl-seq.el ends here