lisp/calendar/timeclock.el

   1 ;;; timeclock.el --- mode for keeping track of how much you work
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008  Free Software Foundation, Inc.
   5
   6 ;; Author: John Wiegley <johnw@gnu.org>
   7 ;; Created: 25 Mar 1999
   8 ;; Version: 2.6.1
   9 ;; Keywords: calendar data
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This mode is for keeping track of time intervals.  You can use it
  31 ;; for whatever purpose you like, but the typical scenario is to keep
  32 ;; track of how much time you spend working on certain projects.
  33 ;;
  34 ;; Use `timeclock-in' when you start on a project, and `timeclock-out'
  35 ;; when you're done.  Once you've collected some data, you can use
  36 ;; `timeclock-workday-remaining' to see how much time is left to be
  37 ;; worked today (where `timeclock-workday' specifies the length of the
  38 ;; working day), and `timeclock-when-to-leave' to calculate when you're free.
  39
  40 ;; You'll probably want to bind the timeclock commands to some handy
  41 ;; keystrokes.  At the moment, C-x t is unused:
  42 ;;
  43 ;;   (require 'timeclock)
  44 ;;
  45 ;;   (define-key ctl-x-map "ti" 'timeclock-in)
  46 ;;   (define-key ctl-x-map "to" 'timeclock-out)
  47 ;;   (define-key ctl-x-map "tc" 'timeclock-change)
  48 ;;   (define-key ctl-x-map "tr" 'timeclock-reread-log)
  49 ;;   (define-key ctl-x-map "tu" 'timeclock-update-modeline)
  50 ;;   (define-key ctl-x-map "tw" 'timeclock-when-to-leave-string)
  51
  52 ;; If you want Emacs to display the amount of time "left" to your
  53 ;; workday in the modeline, you can either set the value of
  54 ;; `timeclock-modeline-display' to t using M-x customize, or you
  55 ;; can add this code to your .emacs file:
  56 ;;
  57 ;;   (require 'timeclock)
  58 ;;   (timeclock-modeline-display)
  59 ;;
  60 ;; To cancel this modeline display at any time, just call
  61 ;; `timeclock-modeline-display' again.
  62
  63 ;; You may also want Emacs to ask you before exiting, if you are
  64 ;; currently working on a project.  This can be done either by setting
  65 ;; `timeclock-ask-before-exiting' to t using M-x customize (this is
  66 ;; the default), or by adding the following to your .emacs file:
  67 ;;
  68 ;;   (add-hook 'kill-emacs-query-functions 'timeclock-query-out)
  69
  70 ;; NOTE: If you change your .timelog file without using timeclock's
  71 ;; functions, or if you change the value of any of timeclock's
  72 ;; customizable variables, you should run the command
  73 ;; `timeclock-reread-log'.  This will recompute any discrepancies in
  74 ;; your average working time, and will make sure that the various
  75 ;; display functions return the correct value.
  76
  77 ;;; History:
  78
  79 ;;; Code:
  80
  81 (defgroup timeclock nil
  82   "Keeping track of the time that gets spent."
  83   :group 'data)
  84
  85 ;;; User Variables:
  86
  87 (defcustom timeclock-file (convert-standard-filename "~/.timelog")
  88   "The file used to store timeclock data in."
  89   :type 'file
  90   :group 'timeclock)
  91
  92 (defcustom timeclock-workday (* 8 60 60)
  93   "The length of a work period in seconds."
  94   :type 'integer
  95   :group 'timeclock)
  96
  97 (defcustom timeclock-relative t
  98   "Whether to make reported time relative to `timeclock-workday'.
  99 For example, if the length of a normal workday is eight hours, and you
 100 work four hours on Monday, then the amount of time \"remaining\" on
 101 Tuesday is twelve hours -- relative to an averaged work period of
 102 eight hours -- or eight hours, non-relative.  So relative time takes
 103 into account any discrepancy of time under-worked or over-worked on
 104 previous days.  This only affects the timeclock modeline display."
 105   :type 'boolean
 106   :group 'timeclock)
 107
 108 (defcustom timeclock-get-project-function 'timeclock-ask-for-project
 109   "The function used to determine the name of the current project.
 110 When clocking in, and no project is specified, this function will be
 111 called to determine what is the current project to be worked on.
 112 If this variable is nil, no questions will be asked."
 113   :type 'function
 114   :group 'timeclock)
 115
 116 (defcustom timeclock-get-reason-function 'timeclock-ask-for-reason
 117   "A function used to determine the reason for clocking out.
 118 When clocking out, and no reason is specified, this function will be
 119 called to determine what is the reason.
 120 If this variable is nil, no questions will be asked."
 121   :type 'function
 122   :group 'timeclock)
 123
 124 (defcustom timeclock-get-workday-function nil
 125   "A function used to determine the length of today's workday.
 126 The first time that a user clocks in each day, this function will be
 127 called to determine what is the length of the current workday.  If
 128 the return value is nil, or equal to `timeclock-workday', nothing special
 129 will be done.  If it is a quantity different from `timeclock-workday',
 130 however, a record will be output to the timelog file to note the fact that
 131 that day has a length that is different from the norm."
 132   :type '(choice (const nil) function)
 133   :group 'timeclock)
 134
 135 (defcustom timeclock-ask-before-exiting t
 136   "If non-nil, ask if the user wants to clock out before exiting Emacs.
 137 This variable only has effect if set with \\[customize]."
 138   :set (lambda (symbol value)
 139          (if value
 140              (add-hook 'kill-emacs-query-functions 'timeclock-query-out)
 141            (remove-hook 'kill-emacs-query-functions 'timeclock-query-out))
 142          (setq timeclock-ask-before-exiting value))
 143   :type 'boolean
 144   :group 'timeclock)
 145
 146 (defvar timeclock-update-timer nil
 147   "The timer used to update `timeclock-mode-string'.")
 148
 149 ;; For byte-compiler.
 150 (defvar display-time-hook)
 151 (defvar timeclock-modeline-display)
 152
 153 (defcustom timeclock-use-display-time t
 154   "If non-nil, use `display-time-hook' for doing modeline updates.
 155 The advantage of this is that one less timer has to be set running
 156 amok in Emacs' process space.  The disadvantage is that it requires
 157 you to have `display-time' running.  If you don't want to use
 158 `display-time', but still want the modeline to show how much time is
 159 left, set this variable to nil.  Changing the value of this variable
 160 while timeclock information is being displayed in the modeline has no
 161 effect.  You should call the function `timeclock-modeline-display' with
 162 a positive argument to force an update."
 163   :set (lambda (symbol value)
 164          (let ((currently-displaying
 165                 (and (boundp 'timeclock-modeline-display)
 166                      timeclock-modeline-display)))
 167            ;; if we're changing to the state that
 168            ;; `timeclock-modeline-display' is already using, don't
 169            ;; bother toggling it.  This happens on the initial loading
 170            ;; of timeclock.el.
 171            (if (and currently-displaying
 172                     (or (and value
 173                              (boundp 'display-time-hook)
 174                              (memq 'timeclock-update-modeline
 175                                    display-time-hook))
 176                         (and (not value)
 177                              timeclock-update-timer)))
 178                (setq currently-displaying nil))
 179            (and currently-displaying
 180                 (set-variable 'timeclock-modeline-display nil))
 181            (setq timeclock-use-display-time value)
 182            (and currently-displaying
 183                 (set-variable 'timeclock-modeline-display t))
 184            timeclock-use-display-time))
 185   :type 'boolean
 186   :group 'timeclock
 187   :require 'time)
 188
 189 (defcustom timeclock-first-in-hook nil
 190   "A hook run for the first \"in\" event each day.
 191 Note that this hook is run before recording any events.  Thus the
 192 value of `timeclock-hours-today', `timeclock-last-event' and the
 193 return value of function `timeclock-last-period' are relative previous
 194 to today."
 195   :type 'hook
 196   :group 'timeclock)
 197
 198 (defcustom timeclock-load-hook nil
 199   "Hook that gets run after timeclock has been loaded."
 200   :type 'hook
 201   :group 'timeclock)
 202
 203 (defcustom timeclock-in-hook nil
 204   "A hook run every time an \"in\" event is recorded."
 205   :type 'hook
 206   :group 'timeclock)
 207
 208 (defcustom timeclock-day-over-hook nil
 209   "A hook that is run when the workday has been completed.
 210 This hook is only run if the current time remaining is being displayed
 211 in the modeline.  See the variable `timeclock-modeline-display'."
 212   :type 'hook
 213   :group 'timeclock)
 214
 215 (defcustom timeclock-out-hook nil
 216   "A hook run every time an \"out\" event is recorded."
 217   :type 'hook
 218   :group 'timeclock)
 219
 220 (defcustom timeclock-done-hook nil
 221   "A hook run every time a project is marked as completed."
 222   :type 'hook
 223   :group 'timeclock)
 224
 225 (defcustom timeclock-event-hook nil
 226   "A hook run every time any event is recorded."
 227   :type 'hook
 228   :group 'timeclock)
 229
 230 (defvar timeclock-last-event nil
 231   "A list containing the last event that was recorded.
 232 The format of this list is (CODE TIME PROJECT).")
 233
 234 (defvar timeclock-last-event-workday nil
 235   "The number of seconds in the workday of `timeclock-last-event'.")
 236
 237 ;;; Internal Variables:
 238
 239 (defvar timeclock-discrepancy nil
 240   "A variable containing the time discrepancy before the last event.
 241 Normally, timeclock assumes that you intend to work for
 242 `timeclock-workday' seconds every day.  Any days in which you work
 243 more or less than this amount is considered either a positive or
 244 a negative discrepancy.  If you work in such a manner that the
 245 discrepancy is always brought back to zero, then you will by
 246 definition have worked an average amount equal to `timeclock-workday'
 247 each day.")
 248
 249 (defvar timeclock-elapsed nil
 250   "A variable containing the time elapsed for complete periods today.
 251 This value is not accurate enough to be useful by itself.  Rather,
 252 call `timeclock-workday-elapsed', to determine how much time has been
 253 worked so far today.  Also, if `timeclock-relative' is nil, this value
 254 will be the same as `timeclock-discrepancy'.")
 255
 256 (defvar timeclock-use-elapsed nil
 257   "Non-nil if the modeline should display time elapsed, not remaining.")
 258
 259 (defvar timeclock-last-period nil
 260   "Integer representing the number of seconds in the last period.
 261 Note that you shouldn't access this value, but instead should use the
 262 function `timeclock-last-period'.")
 263
 264 (defvar timeclock-mode-string nil
 265   "The timeclock string (optionally) displayed in the modeline.
 266 The time is bracketed by <> if you are clocked in, otherwise by [].")
 267
 268 (defvar timeclock-day-over nil
 269   "The date of the last day when notified \"day over\" for.")
 270
 271 ;;; User Functions:
 272
 273 ;;;###autoload
 274 (defun timeclock-modeline-display (&optional arg)
 275   "Toggle display of the amount of time left today in the modeline.
 276 If `timeclock-use-display-time' is non-nil (the default), then
 277 the function `display-time-mode' must be active, and the modeline
 278 will be updated whenever the time display is updated.  Otherwise,
 279 the timeclock will use its own sixty second timer to do its
 280 updating.  With prefix ARG, turn modeline display on if and only
 281 if ARG is positive.  Returns the new status of timeclock modeline
 282 display (non-nil means on)."
 283   (interactive "P")
 284   ;; cf display-time-mode.
 285   (setq timeclock-mode-string "")
 286   (or global-mode-string (setq global-mode-string '("")))
 287   (let ((on-p (if arg
 288                   (> (prefix-numeric-value arg) 0)
 289                 (not timeclock-modeline-display))))
 290     (if on-p
 291         (progn
 292           (or (memq 'timeclock-mode-string global-mode-string)
 293               (setq global-mode-string
 294                     (append global-mode-string '(timeclock-mode-string))))
 295           (unless (memq 'timeclock-update-modeline timeclock-event-hook)
 296             (add-hook 'timeclock-event-hook 'timeclock-update-modeline))
 297           (when timeclock-update-timer
 298             (cancel-timer timeclock-update-timer)
 299             (setq timeclock-update-timer nil))
 300           (if (boundp 'display-time-hook)
 301               (remove-hook 'display-time-hook 'timeclock-update-modeline))
 302           (if timeclock-use-display-time
 303               (progn
 304                 ;; Update immediately so there is a visible change
 305                 ;; on calling this function.
 306                 (if display-time-mode (timeclock-update-modeline)
 307                   (message "Activate `display-time-mode' or turn off \
 308 `timeclock-use-display-time' to see timeclock information"))
 309                 (add-hook 'display-time-hook 'timeclock-update-modeline))
 310             (setq timeclock-update-timer
 311                   (run-at-time nil 60 'timeclock-update-modeline))))
 312       (setq global-mode-string
 313             (delq 'timeclock-mode-string global-mode-string))
 314       (remove-hook 'timeclock-event-hook 'timeclock-update-modeline)
 315       (if (boundp 'display-time-hook)
 316           (remove-hook 'display-time-hook
 317                        'timeclock-update-modeline))
 318       (when timeclock-update-timer
 319         (cancel-timer timeclock-update-timer)
 320         (setq timeclock-update-timer nil)))
 321     (force-mode-line-update)
 322     (setq timeclock-modeline-display on-p)))
 323
 324 ;; This has to be here so that the function definition of
 325 ;; `timeclock-modeline-display' is known to the "set" function.
 326 (defcustom timeclock-modeline-display nil
 327   "Toggle modeline display of time remaining.
 328 You must modify via \\[customize] for this variable to have an effect."
 329   :set (lambda (symbol value)
 330          (setq timeclock-modeline-display
 331                (timeclock-modeline-display (or value 0))))
 332   :type 'boolean
 333   :group 'timeclock
 334   :require 'timeclock)
 335
 336 (defsubst timeclock-time-to-date (time)
 337   "Convert the TIME value to a textual date string."
 338   (format-time-string "%Y/%m/%d" time))
 339
 340 ;;;###autoload
 341 (defun timeclock-in (&optional arg project find-project)
 342   "Clock in, recording the current time moment in the timelog.
 343 With a numeric prefix ARG, record the fact that today has only that
 344 many hours in it to be worked.  If ARG is a non-numeric prefix argument
 345 \(non-nil, but not a number), 0 is assumed (working on a holiday or
 346 weekend).  *If not called interactively, ARG should be the number of
 347 _seconds_ worked today*.  This feature only has effect the first time
 348 this function is called within a day.
 349
 350 PROJECT is the project being clocked into.  If PROJECT is nil, and
 351 FIND-PROJECT is non-nil -- or the user calls `timeclock-in'
 352 interactively -- call the function `timeclock-get-project-function' to
 353 discover the name of the project."
 354   (interactive
 355    (list (and current-prefix-arg
 356               (if (numberp current-prefix-arg)
 357                   (* current-prefix-arg 60 60)
 358                 0))))
 359   (if (equal (car timeclock-last-event) "i")
 360       (error "You've already clocked in!")
 361     (unless timeclock-last-event
 362       (timeclock-reread-log))
 363     ;; Either no log file, or day has rolled over.
 364     (unless (and timeclock-last-event
 365                  (equal (timeclock-time-to-date
 366                          (cadr timeclock-last-event))
 367                         (timeclock-time-to-date (current-time))))
 368       (let ((workday (or (and (numberp arg) arg)
 369                          (and arg 0)
 370                          (and timeclock-get-workday-function
 371                               (funcall timeclock-get-workday-function))
 372                          timeclock-workday)))
 373         (run-hooks 'timeclock-first-in-hook)
 374         ;; settle the discrepancy for the new day
 375         (setq timeclock-discrepancy
 376               (- (or timeclock-discrepancy 0) workday))
 377         (if (not (= workday timeclock-workday))
 378             (timeclock-log "h" (number-to-string
 379                                 (/ workday (if (zerop (% workday (* 60 60)))
 380                                                60 60.0) 60))))))
 381     (timeclock-log "i" (or project
 382                            (and timeclock-get-project-function
 383                                 (or find-project (interactive-p))
 384                                 (funcall timeclock-get-project-function))))
 385     (run-hooks 'timeclock-in-hook)))
 386
 387 ;;;###autoload
 388 (defun timeclock-out (&optional arg reason find-reason)
 389   "Clock out, recording the current time moment in the timelog.
 390 If a prefix ARG is given, the user has completed the project that was
 391 begun during the last time segment.
 392
 393 REASON is the user's reason for clocking out.  If REASON is nil, and
 394 FIND-REASON is non-nil -- or the user calls `timeclock-out'
 395 interactively -- call the function `timeclock-get-reason-function' to
 396 discover the reason."
 397   (interactive "P")
 398   (or timeclock-last-event
 399       (error "You haven't clocked in!"))
 400   (if (equal (downcase (car timeclock-last-event)) "o")
 401       (error "You've already clocked out!")
 402     (timeclock-log
 403      (if arg "O" "o")
 404      (or reason
 405          (and timeclock-get-reason-function
 406               (or find-reason (interactive-p))
 407               (funcall timeclock-get-reason-function))))
 408     (run-hooks 'timeclock-out-hook)
 409     (if arg
 410         (run-hooks 'timeclock-done-hook))))
 411
 412 ;; Should today-only be removed in favour of timeclock-relative? - gm
 413 (defsubst timeclock-workday-remaining (&optional today-only)
 414   "Return the number of seconds until the workday is complete.
 415 The amount returned is relative to the value of `timeclock-workday'.
 416 If TODAY-ONLY is non-nil, the value returned will be relative only to
 417 the time worked today, and not to past time."
 418   (let ((discrep (timeclock-find-discrep)))
 419     (if discrep
 420         (- (if today-only (cadr discrep)
 421              (car discrep)))
 422       0.0)))
 423
 424 ;;;###autoload
 425 (defun timeclock-status-string (&optional show-seconds today-only)
 426   "Report the overall timeclock status at the present moment.
 427 If SHOW-SECONDS is non-nil, display second resolution.
 428 If TODAY-ONLY is non-nil, the display will be relative only to time
 429 worked today, ignoring the time worked on previous days."
 430   (interactive "P")
 431   (let ((remainder (timeclock-workday-remaining
 432                     (or today-only
 433                         (not timeclock-relative))))
 434         (last-in (equal (car timeclock-last-event) "i"))
 435         status)
 436     (setq status
 437           (format "Currently %s since %s (%s), %s %s, leave at %s"
 438                   (if last-in "IN" "OUT")
 439                   (if show-seconds
 440                       (format-time-string "%-I:%M:%S %p"
 441                                           (nth 1 timeclock-last-event))
 442                     (format-time-string "%-I:%M %p"
 443                                         (nth 1 timeclock-last-event)))
 444                   (or (nth 2 timeclock-last-event)
 445                       (if last-in "**UNKNOWN**" "workday over"))
 446                   (timeclock-seconds-to-string remainder show-seconds t)
 447                   (if (> remainder 0)
 448                       "remaining" "over")
 449                   (timeclock-when-to-leave-string show-seconds today-only)))
 450     (if (interactive-p)
 451         (message "%s" status)
 452       status)))
 453
 454 ;;;###autoload
 455 (defun timeclock-change (&optional arg project)
 456   "Change to working on a different project.
 457 This clocks out of the current project, then clocks in on a new one.
 458 With a prefix ARG, consider the previous project as finished at the
 459 time of changeover.  PROJECT is the name of the last project you were
 460 working on."
 461   (interactive "P")
 462   (timeclock-out arg)
 463   (timeclock-in nil project (interactive-p)))
 464
 465 ;;;###autoload
 466 (defun timeclock-query-out ()
 467   "Ask the user whether to clock out.
 468 This is a useful function for adding to `kill-emacs-query-functions'."
 469   (and (equal (car timeclock-last-event) "i")
 470        (y-or-n-p "You're currently clocking time, clock out? ")
 471        (timeclock-out))
 472   ;; Unconditionally return t for `kill-emacs-query-functions'.
 473   t)
 474
 475 ;;;###autoload
 476 (defun timeclock-reread-log ()
 477   "Re-read the timeclock, to account for external changes.
 478 Returns the new value of `timeclock-discrepancy'."
 479   (interactive)
 480   (setq timeclock-discrepancy nil)
 481   (timeclock-find-discrep)
 482   (if (and timeclock-discrepancy timeclock-modeline-display)
 483       (timeclock-update-modeline))
 484   timeclock-discrepancy)
 485
 486 (defun timeclock-seconds-to-string (seconds &optional show-seconds
 487                                             reverse-leader)
 488   "Convert SECONDS into a compact time string.
 489 If SHOW-SECONDS is non-nil, make the resolution of the return string
 490 include the second count.  If REVERSE-LEADER is non-nil, it means to
 491 output a \"+\" if the time value is negative, rather than a \"-\".
 492 This is used when negative time values have an inverted meaning (such
 493 as with time remaining, where negative time really means overtime)."
 494   (if show-seconds
 495       (format "%s%d:%02d:%02d"
 496               (if (< seconds 0) (if reverse-leader "+" "-") "")
 497               (truncate (/ (abs seconds) 60 60))
 498               (% (truncate (/ (abs seconds) 60)) 60)
 499               (% (truncate (abs seconds)) 60))
 500     (format "%s%d:%02d"
 501             (if (< seconds 0) (if reverse-leader "+" "-") "")
 502             (truncate (/ (abs seconds) 60 60))
 503             (% (truncate (/ (abs seconds) 60)) 60))))
 504
 505 (defsubst timeclock-currently-in-p ()
 506   "Return non-nil if the user is currently clocked in."
 507   (equal (car timeclock-last-event) "i"))
 508
 509 ;;;###autoload
 510 (defun timeclock-workday-remaining-string (&optional show-seconds
 511                                                      today-only)
 512   "Return a string representing the amount of time left today.
 513 Display second resolution if SHOW-SECONDS is non-nil.  If TODAY-ONLY
 514 is non-nil, the display will be relative only to time worked today.
 515 See `timeclock-relative' for more information about the meaning of
 516 \"relative to today\"."
 517   (interactive)
 518   (let ((string (timeclock-seconds-to-string
 519                  (timeclock-workday-remaining today-only)
 520                  show-seconds t)))
 521     (if (interactive-p)
 522         (message "%s" string)
 523       string)))
 524
 525 (defsubst timeclock-workday-elapsed ()
 526   "Return the number of seconds worked so far today.
 527 If RELATIVE is non-nil, the amount returned will be relative to past
 528 time worked.  The default is to return only the time that has elapsed
 529 so far today."
 530   (let ((discrep (timeclock-find-discrep)))
 531     (if discrep
 532         (nth 2 discrep)
 533       0.0)))
 534
 535 ;;;###autoload
 536 (defun timeclock-workday-elapsed-string (&optional show-seconds)
 537   "Return a string representing the amount of time worked today.
 538 Display seconds resolution if SHOW-SECONDS is non-nil.  If RELATIVE is
 539 non-nil, the amount returned will be relative to past time worked."
 540   (interactive)
 541   (let ((string (timeclock-seconds-to-string (timeclock-workday-elapsed)
 542                                              show-seconds)))
 543     (if (interactive-p)
 544         (message "%s" string)
 545       string)))
 546
 547 (defsubst timeclock-time-to-seconds (time)
 548   "Convert TIME to a floating point number."
 549   (+ (* (car time) 65536.0)
 550      (cadr time)
 551      (/ (or (nth 2 time) 0) 1000000.0)))
 552
 553 (defsubst timeclock-seconds-to-time (seconds)
 554   "Convert SECONDS (a floating point number) to an Emacs time structure."
 555   (list (floor seconds 65536)
 556         (floor (mod seconds 65536))
 557         (floor (* (- seconds (ffloor seconds)) 1000000))))
 558
 559 ;; Should today-only be removed in favour of timeclock-relative? - gm
 560 (defsubst timeclock-when-to-leave (&optional today-only)
 561   "Return a time value representing the end of today's workday.
 562 If TODAY-ONLY is non-nil, the value returned will be relative only to
 563 the time worked today, and not to past time."
 564   (timeclock-seconds-to-time
 565    (- (timeclock-time-to-seconds (current-time))
 566       (let ((discrep (timeclock-find-discrep)))
 567         (if discrep
 568             (if today-only
 569                 (cadr discrep)
 570               (car discrep))
 571           0.0)))))
 572
 573 ;;;###autoload
 574 (defun timeclock-when-to-leave-string (&optional show-seconds
 575                                                  today-only)
 576   "Return a string representing the end of today's workday.
 577 This string is relative to the value of `timeclock-workday'.  If
 578 SHOW-SECONDS is non-nil, the value printed/returned will include
 579 seconds.  If TODAY-ONLY is non-nil, the value returned will be
 580 relative only to the time worked today, and not to past time."
 581   ;; Should today-only be removed in favour of timeclock-relative? - gm
 582   (interactive)
 583   (let* ((then (timeclock-when-to-leave today-only))
 584          (string
 585           (if show-seconds
 586               (format-time-string "%-I:%M:%S %p" then)
 587             (format-time-string "%-I:%M %p" then))))
 588     (if (interactive-p)
 589         (message "%s" string)
 590       string)))
 591
 592 (defun timeclock-make-hours-explicit (old-default)
 593   "Specify all workday lengths in `timeclock-file'.
 594 OLD-DEFAULT hours are set for every day that has no number indicated."
 595   (interactive "P")
 596   (if old-default (setq old-default (prefix-numeric-value old-default))
 597     (error "`timelog-make-hours-explicit' requires an explicit argument"))
 598   (let ((extant-timelog (find-buffer-visiting timeclock-file))
 599         current-date)
 600     (with-current-buffer (find-file-noselect timeclock-file t)
 601       (unwind-protect
 602           (save-excursion
 603             (save-restriction
 604               (widen)
 605               (goto-char (point-min))
 606               (while (progn (skip-chars-forward "\n") (not (eobp)))
 607                 ;; This is just a variant of `timeclock-moment-regexp'.
 608                 (unless (looking-at
 609                          (concat "^\\([bhioO]\\) \\([0-9]+/[0-9]+/[0-9]+\\) "
 610                                  "\\([0-9]+:[0-9]+:[0-9]+\\)"))
 611                   (error "Can't parse `%s'" timeclock-file))
 612                 (let ((this-date (match-string 2)))
 613                   (unless (or (and current-date
 614                                    (string= this-date current-date))
 615                               (string= (match-string 1) "h"))
 616                     (insert (format "h %s %s %s\n" (match-string 2)
 617                                     (match-string 3) old-default)))
 618                   (if (string-match "^[ih]" (match-string 1)) ; ignore logouts
 619                       (setq current-date this-date)))
 620                 (forward-line))
 621               (save-buffer)))
 622         (unless extant-timelog (kill-buffer (current-buffer)))))))
 623
 624 ;;; Internal Functions:
 625
 626 (defvar timeclock-project-list nil)
 627 (defvar timeclock-last-project nil)
 628
 629 (defun timeclock-completing-read (prompt alist &optional default)
 630   "A version of `completing-read' that works on both Emacs and XEmacs.
 631 PROMPT, ALIST and DEFAULT are used for the PROMPT, COLLECTION and DEF
 632 arguments of `completing-read'."
 633   (if (featurep 'xemacs)
 634       (let ((str (completing-read prompt alist)))
 635         (if (or (null str) (zerop (length str)))
 636             default
 637           str))
 638     (completing-read prompt alist nil nil nil nil default)))
 639
 640 (defun timeclock-ask-for-project ()
 641   "Ask the user for the project they are clocking into."
 642   (timeclock-completing-read
 643    (format "Clock into which project (default %s): "
 644            (or timeclock-last-project
 645                (car timeclock-project-list)))
 646    (mapcar 'list timeclock-project-list)
 647    (or timeclock-last-project
 648        (car timeclock-project-list))))
 649
 650 (defvar timeclock-reason-list nil)
 651
 652 (defun timeclock-ask-for-reason ()
 653   "Ask the user for the reason they are clocking out."
 654   (timeclock-completing-read "Reason for clocking out: "
 655                              (mapcar 'list timeclock-reason-list)))
 656
 657 (defun timeclock-update-modeline ()
 658   "Update the `timeclock-mode-string' displayed in the modeline.
 659 The value of `timeclock-relative' affects the display as described in
 660 that variable's documentation."
 661   (interactive)
 662   (let ((remainder
 663          (if timeclock-use-elapsed
 664              (timeclock-workday-elapsed)
 665            (timeclock-workday-remaining (not timeclock-relative))))
 666         (last-in (equal (car timeclock-last-event) "i")))
 667     (when (and (< remainder 0)
 668                (not (and timeclock-day-over
 669                          (equal timeclock-day-over
 670                                 (timeclock-time-to-date
 671                                  (current-time))))))
 672       (setq timeclock-day-over
 673             (timeclock-time-to-date (current-time)))
 674       (run-hooks 'timeclock-day-over-hook))
 675     (setq timeclock-mode-string
 676           (propertize
 677            (format " %c%s%c "
 678                    (if last-in ?< ?[)
 679                    (timeclock-seconds-to-string remainder nil t)
 680                    (if last-in ?> ?]))
 681            'help-echo "timeclock: time remaining"))))
 682
 683 (put 'timeclock-mode-string 'risky-local-variable t)
 684
 685 (defun timeclock-log (code &optional project)
 686   "Log the event CODE to the timeclock log, at the time of call.
 687 If PROJECT is a string, it represents the project which the event is
 688 being logged for.  Normally only \"in\" events specify a project."
 689   (let ((extant-timelog (find-buffer-visiting timeclock-file)))
 690     (with-current-buffer (find-file-noselect timeclock-file t)
 691       (save-excursion
 692         (save-restriction
 693           (widen)
 694           (goto-char (point-max))
 695           (if (not (bolp))
 696               (insert "\n"))
 697           (let ((now (current-time)))
 698             (insert code " "
 699                     (format-time-string "%Y/%m/%d %H:%M:%S" now)
 700                     (or (and (stringp project)
 701                              (> (length project) 0)
 702                              (concat " " project))
 703                         "")
 704                     "\n")
 705             (if (equal (downcase code) "o")
 706                 (setq timeclock-last-period
 707                       (- (timeclock-time-to-seconds now)
 708                          (timeclock-time-to-seconds
 709                           (cadr timeclock-last-event)))
 710                       timeclock-discrepancy
 711                       (+ timeclock-discrepancy
 712                          timeclock-last-period)))
 713             (setq timeclock-last-event (list code now project)))))
 714       (save-buffer)
 715       (unless extant-timelog (kill-buffer (current-buffer)))))
 716   (run-hooks 'timeclock-event-hook))
 717
 718 (defvar timeclock-moment-regexp
 719   (concat "\\([bhioO]\\)\\s-+"
 720           "\\([0-9]+\\)/\\([0-9]+\\)/\\([0-9]+\\)\\s-+"
 721           "\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)[ \t]*" "\\([^\n]*\\)"))
 722
 723 (defsubst timeclock-read-moment ()
 724   "Read the moment under point from the timelog."
 725   (if (looking-at timeclock-moment-regexp)
 726       (let ((code (match-string 1))
 727             (year (string-to-number (match-string 2)))
 728             (mon  (string-to-number (match-string 3)))
 729             (mday (string-to-number (match-string 4)))
 730             (hour (string-to-number (match-string 5)))
 731             (min  (string-to-number (match-string 6)))
 732             (sec  (string-to-number (match-string 7)))
 733             (project (match-string 8)))
 734         (list code (encode-time sec min hour mday mon year) project))))
 735
 736 (defun timeclock-last-period (&optional moment)
 737   "Return the value of the last event period.
 738 If the last event was a clock-in, the period will be open ended, and
 739 growing every second.  Otherwise, it is a fixed amount which has been
 740 recorded to disk.  If MOMENT is non-nil, use that as the current time.
 741 This is only provided for coherency when used by
 742 `timeclock-discrepancy'."
 743   (if (equal (car timeclock-last-event) "i")
 744       (- (timeclock-time-to-seconds (or moment (current-time)))
 745          (timeclock-time-to-seconds
 746           (cadr timeclock-last-event)))
 747     timeclock-last-period))
 748
 749 (defsubst timeclock-entry-length (entry)
 750   "Return the length of ENTRY in seconds."
 751   (- (timeclock-time-to-seconds (cadr entry))
 752      (timeclock-time-to-seconds (car entry))))
 753
 754 (defsubst timeclock-entry-begin (entry)
 755   "Return the start time of ENTRY."
 756   (car entry))
 757
 758 (defsubst timeclock-entry-end (entry)
 759   "Return the end time of ENTRY."
 760   (cadr entry))
 761
 762 (defsubst timeclock-entry-project (entry)
 763   "Return the project of ENTRY."
 764   (nth 2 entry))
 765
 766 (defsubst timeclock-entry-comment (entry)
 767   "Return the comment of ENTRY."
 768   (nth 3 entry))
 769
 770 (defsubst timeclock-entry-list-length (entry-list)
 771   "Return the total length of ENTRY-LIST in seconds."
 772   (let ((length 0))
 773     (dolist (entry entry-list)
 774       (setq length (+ length (timeclock-entry-length entry))))
 775     length))
 776
 777 (defsubst timeclock-entry-list-begin (entry-list)
 778   "Return the start time of the first element of ENTRY-LIST."
 779   (timeclock-entry-begin (car entry-list)))
 780
 781 (defsubst timeclock-entry-list-end (entry-list)
 782   "Return the end time of the last element of ENTRY-LIST."
 783   (timeclock-entry-end (car (last entry-list))))
 784
 785 (defsubst timeclock-entry-list-span (entry-list)
 786   "Return the total time in seconds spanned by ENTRY-LIST."
 787   (- (timeclock-time-to-seconds (timeclock-entry-list-end entry-list))
 788      (timeclock-time-to-seconds (timeclock-entry-list-begin entry-list))))
 789
 790 (defsubst timeclock-entry-list-break (entry-list)
 791   "Return the total break time (span - length) in ENTRY-LIST."
 792   (- (timeclock-entry-list-span entry-list)
 793      (timeclock-entry-list-length entry-list)))
 794
 795 (defsubst timeclock-entry-list-projects (entry-list)
 796   "Return a list of all the projects in ENTRY-LIST."
 797   (let (projects proj)
 798     (dolist (entry entry-list)
 799       (setq proj (timeclock-entry-project entry))
 800       (if projects
 801           (add-to-list 'projects proj)
 802         (setq projects (list proj))))
 803     projects))
 804
 805 (defsubst timeclock-day-required (day)
 806   "Return the required length of DAY in seconds, default `timeclock-workday'."
 807   (or (car day) timeclock-workday))
 808
 809 (defsubst timeclock-day-length (day)
 810   "Return the actual length of DAY in seconds."
 811   (timeclock-entry-list-length (cdr day)))
 812
 813 (defsubst timeclock-day-debt (day)
 814   "Return the debt (required - actual) associated with DAY, in seconds."
 815   (- (timeclock-day-required day)
 816      (timeclock-day-length day)))
 817
 818 (defsubst timeclock-day-begin (day)
 819   "Return the start time of DAY."
 820   (timeclock-entry-list-begin (cdr day)))
 821
 822 (defsubst timeclock-day-end (day)
 823   "Return the end time of DAY."
 824   (timeclock-entry-list-end (cdr day)))
 825
 826 (defsubst timeclock-day-span (day)
 827   "Return the span of DAY."
 828   (timeclock-entry-list-span (cdr day)))
 829
 830 (defsubst timeclock-day-break (day)
 831   "Return the total break time of DAY."
 832   (timeclock-entry-list-break (cdr day)))
 833
 834 (defsubst timeclock-day-projects (day)
 835   "Return a list of all the projects in DAY."
 836   (timeclock-entry-list-projects (cdr day)))
 837
 838 (defmacro timeclock-day-list-template (func)
 839   "Template for summing the result of FUNC on each element of DAY-LIST."
 840   `(let ((length 0))
 841      (while day-list
 842        (setq length (+ length (,(eval func) (car day-list)))
 843              day-list (cdr day-list)))
 844      length))
 845
 846 (defun timeclock-day-list-required (day-list)
 847   "Return total required length of DAY-LIST, in seconds."
 848   (timeclock-day-list-template 'timeclock-day-required))
 849
 850 (defun timeclock-day-list-length (day-list)
 851   "Return actual length of DAY-LIST, in seconds."
 852   (timeclock-day-list-template 'timeclock-day-length))
 853
 854 (defun timeclock-day-list-debt (day-list)
 855   "Return total debt (required - actual) of DAY-LIST."
 856   (timeclock-day-list-template 'timeclock-day-debt))
 857
 858 (defsubst timeclock-day-list-begin (day-list)
 859   "Return the start time of DAY-LIST."
 860   (timeclock-day-begin (car day-list)))
 861
 862 (defsubst timeclock-day-list-end (day-list)
 863   "Return the end time of DAY-LIST."
 864   (timeclock-day-end (car (last day-list))))
 865
 866 (defun timeclock-day-list-span (day-list)
 867   "Return the span of DAY-LIST."
 868   (timeclock-day-list-template 'timeclock-day-span))
 869
 870 (defun timeclock-day-list-break (day-list)
 871   "Return the total break of DAY-LIST."
 872   (timeclock-day-list-template 'timeclock-day-break))
 873
 874 (defun timeclock-day-list-projects (day-list)
 875   "Return a list of all the projects in DAY-LIST."
 876   (let (projects)
 877     (dolist (day day-list)
 878       (dolist (proj (timeclock-day-projects day))
 879         (if projects
 880             (add-to-list 'projects proj)
 881           (setq projects (list proj)))))
 882     projects))
 883
 884 (defsubst timeclock-current-debt (&optional log-data)
 885   "Return the seconds debt from LOG-DATA, default `timeclock-log-data'."
 886   (nth 0 (or log-data (timeclock-log-data))))
 887
 888 (defsubst timeclock-day-alist (&optional log-data)
 889   "Return the date alist from LOG-DATA, default `timeclock-log-data'."
 890   (nth 1 (or log-data (timeclock-log-data))))
 891
 892 (defun timeclock-day-list (&optional log-data)
 893   "Return a list of the cdrs of the date alist from LOG-DATA."
 894   (let (day-list)
 895     (dolist (date-list (timeclock-day-alist log-data))
 896       (setq day-list (cons (cdr date-list) day-list)))
 897     day-list))
 898
 899 (defsubst timeclock-project-alist (&optional log-data)
 900   "Return the project alist from LOG-DATA, default `timeclock-log-data'."
 901   (nth 2 (or log-data (timeclock-log-data))))
 902
 903 (defun timeclock-log-data (&optional recent-only filename)
 904   "Return the contents of the timelog file, in a useful format.
 905 If the optional argument RECENT-ONLY is non-nil, only show the contents
 906 from the last point where the time debt (see below) was set.
 907 If the optional argument FILENAME is non-nil, it is used instead of
 908 the file specified by `timeclock-file.'
 909
 910 A timelog contains data in the form of a single entry per line.
 911 Each entry has the form:
 912
 913   CODE YYYY/MM/DD HH:MM:SS [COMMENT]
 914
 915 CODE is one of: b, h, i, o or O.  COMMENT is optional when the code is
 916 i, o or O.  The meanings of the codes are:
 917
 918   b  Set the current time balance, or \"time debt\".  Useful when
 919      archiving old log data, when a debt must be carried forward.
 920      The COMMENT here is the number of seconds of debt.
 921
 922   h  Set the required working time for the given day.  This must
 923      be the first entry for that day.  The COMMENT in this case is
 924      the number of hours in this workday.  Floating point amounts
 925      are allowed.
 926
 927   i  Clock in.  The COMMENT in this case should be the name of the
 928      project worked on.
 929
 930   o  Clock out.  COMMENT is unnecessary, but can be used to provide
 931      a description of how the period went, for example.
 932
 933   O  Final clock out.  Whatever project was being worked on, it is
 934      now finished.  Useful for creating summary reports.
 935
 936 When this function is called, it will return a data structure with the
 937 following format:
 938
 939   (DEBT ENTRIES-BY-DAY ENTRIES-BY-PROJECT)
 940
 941 DEBT is a floating point number representing the number of seconds
 942 \"owed\" before any work was done.  For a new file (one without a 'b'
 943 entry), this is always zero.
 944
 945 The two entries lists have similar formats.  They are both alists,
 946 where the CAR is the index, and the CDR is a list of time entries.
 947 For ENTRIES-BY-DAY, the CAR is a textual date string, of the form
 948 YYYY/MM/DD.  For ENTRIES-BY-PROJECT, it is the name of the project
 949 worked on, or t for the default project.
 950
 951 The CDR for ENTRIES-BY-DAY is slightly different than for
 952 ENTRIES-BY-PROJECT.  It has the following form:
 953
 954   (DAY-LENGTH TIME-ENTRIES...)
 955
 956 For ENTRIES-BY-PROJECT, there is no DAY-LENGTH member.  It is simply a
 957 list of TIME-ENTRIES.  Note that if DAY-LENGTH is nil, it means
 958 whatever is the default should be used.
 959
 960 A TIME-ENTRY is a recorded time interval.  It has the following format
 961 \(although generally one does not have to manipulate these entries
 962 directly; see below):
 963
 964   (BEGIN-TIME END-TIME PROJECT [COMMENT] [FINAL-P])
 965
 966 Anyway, suffice it to say there are a lot of structures.  Typically
 967 the user is expected to manipulate to the day(s) or project(s) that he
 968 or she wants, at which point the following helper functions may be
 969 used:
 970
 971   timeclock-day-required
 972   timeclock-day-length
 973   timeclock-day-debt
 974   timeclock-day-begin
 975   timeclock-day-end
 976   timeclock-day-span
 977   timeclock-day-break
 978   timeclock-day-projects
 979
 980   timeclock-day-list-required
 981   timeclock-day-list-length
 982   timeclock-day-list-debt
 983   timeclock-day-list-begin
 984   timeclock-day-list-end
 985   timeclock-day-list-span
 986   timeclock-day-list-break
 987   timeclock-day-list-projects
 988
 989   timeclock-entry-length
 990   timeclock-entry-begin
 991   timeclock-entry-end
 992   timeclock-entry-project
 993   timeclock-entry-comment
 994
 995   timeclock-entry-list-length
 996   timeclock-entry-list-begin
 997   timeclock-entry-list-end
 998   timeclock-entry-list-span
 999   timeclock-entry-list-break
1000   timeclock-entry-list-projects
1001
1002 A few comments should make the use of the above functions obvious:
1003
1004   `required' is the amount of time that must be spent during a day, or
1005   sequence of days, in order to have no debt.
1006
1007   `length' is the actual amount of time that was spent.
1008
1009   `debt' is the difference between required time and length.  A
1010   negative debt signifies overtime.
1011
1012   `begin' is the earliest moment at which work began.
1013
1014   `end' is the final moment work was done.
1015
1016   `span' is the difference between begin and end.
1017
1018   `break' is the difference between span and length.
1019
1020   `project' is the project that was worked on, and `projects' is a
1021   list of all the projects that were worked on during a given period.
1022
1023   `comment', where it applies, could mean anything.
1024
1025 There are a few more functions available, for locating day and entry
1026 lists:
1027
1028   timeclock-day-alist LOG-DATA
1029   timeclock-project-alist LOG-DATA
1030   timeclock-current-debt LOG-DATA
1031
1032 See the documentation for the given function if more info is needed."
1033   (let* ((log-data (list 0.0 nil nil))
1034          (now (current-time))
1035          (todays-date (timeclock-time-to-date now))
1036          last-date-limited last-date-seconds last-date
1037          (line 0) last beg day entry event)
1038     (with-temp-buffer
1039       (insert-file-contents (or filename timeclock-file))
1040       (when recent-only
1041         (goto-char (point-max))
1042         (unless (re-search-backward "^b\\s-+" nil t)
1043           (goto-char (point-min))))
1044       (while (or (setq event (timeclock-read-moment))
1045                  (and beg (not last)
1046                       (setq last t event (list "o" now))))
1047         (setq line (1+ line))
1048         (cond ((equal (car event) "b")
1049                (setcar log-data (string-to-number (nth 2 event))))
1050               ((equal (car event) "h")
1051                (setq last-date-limited (timeclock-time-to-date (cadr event))
1052                      last-date-seconds (* (string-to-number (nth 2 event))
1053                                           3600.0)))
1054               ((equal (car event) "i")
1055                (if beg
1056                    (error "Error in format of timelog file, line %d" line)
1057                  (setq beg t))
1058                (setq entry (list (cadr event) nil
1059                                  (and (> (length (nth 2 event)) 0)
1060                                       (nth 2 event))))
1061                (let ((date (timeclock-time-to-date (cadr event))))
1062                  (if (and last-date
1063                           (not (equal date last-date)))
1064                      (progn
1065                        (setcar (cdr log-data)
1066                                (cons (cons last-date day)
1067                                      (cadr log-data)))
1068                        (setq day (list (and last-date-limited
1069                                             last-date-seconds))))
1070                    (unless day
1071                      (setq day (list (and last-date-limited
1072                                           last-date-seconds)))))
1073                  (setq last-date date
1074                        last-date-limited nil)))
1075               ((equal (downcase (car event)) "o")
1076                (if (not beg)
1077                    (error "Error in format of timelog file, line %d" line)
1078                  (setq beg nil))
1079                (setcar (cdr entry) (cadr event))
1080                (let ((desc (and (> (length (nth 2 event)) 0)
1081                                 (nth 2 event))))
1082                  (if desc
1083                      (nconc entry (list (nth 2 event))))
1084                  (if (equal (car event) "O")
1085                      (nconc entry (if desc
1086                                       (list t)
1087                                     (list nil t))))
1088                  (nconc day (list entry))
1089                  (setq desc (nth 2 entry))
1090                  (let ((proj (assoc desc (nth 2 log-data))))
1091                    (if (null proj)
1092                        (setcar (cddr log-data)
1093                                (cons (cons desc (list entry))
1094                                      (nth 2 log-data)))
1095                      (nconc (cdr proj) (list entry)))))))
1096         (forward-line))
1097       (if day
1098           (setcar (cdr log-data)
1099                   (cons (cons last-date day)
1100                         (cadr log-data))))
1101       log-data)))
1102
1103 (defun timeclock-find-discrep ()
1104   "Calculate time discrepancies, in seconds.
1105 The result is a three element list, containing the total time
1106 discrepancy, today's discrepancy, and the time worked today."
1107   ;; This is not implemented in terms of the functions above, because
1108   ;; it's a bit wasteful to read all of that data in, just to throw
1109   ;; away more than 90% of the information afterwards.
1110   ;;
1111   ;; If it were implemented using those functions, it would look
1112   ;; something like this:
1113   ;;  (let ((days (timeclock-day-alist (timeclock-log-data)))
1114   ;;        (total 0.0))
1115   ;;    (while days
1116   ;;      (setq total (+ total (- (timeclock-day-length (cdar days))
1117   ;;                              (timeclock-day-required (cdar days))))
1118   ;;            days (cdr days)))
1119   ;;    total)
1120   (let* ((now (current-time))
1121          (todays-date (timeclock-time-to-date now))
1122          (first t) (accum 0) (elapsed 0)
1123          event beg last-date avg
1124          last-date-limited last-date-seconds)
1125     (unless timeclock-discrepancy
1126       (when (file-readable-p timeclock-file)
1127         (setq timeclock-project-list nil
1128               timeclock-last-project nil
1129               timeclock-reason-list nil
1130               timeclock-elapsed 0)
1131         (with-temp-buffer
1132           (insert-file-contents timeclock-file)
1133           (goto-char (point-max))
1134           (unless (re-search-backward "^b\\s-+" nil t)
1135             (goto-char (point-min)))
1136           (while (setq event (timeclock-read-moment))
1137             (cond ((equal (car event) "b")
1138                    (setq accum (string-to-number (nth 2 event))))
1139                   ((equal (car event) "h")
1140                    (setq last-date-limited
1141                          (timeclock-time-to-date (cadr event))
1142                          last-date-seconds
1143                          (* (string-to-number (nth 2 event)) 3600.0)))
1144                   ((equal (car event) "i")
1145                    (when (and (nth 2 event)
1146                               (> (length (nth 2 event)) 0))
1147                      (add-to-list 'timeclock-project-list (nth 2 event))
1148                      (setq timeclock-last-project (nth 2 event)))
1149                    (let ((date (timeclock-time-to-date (cadr event))))
1150                      (if (if last-date
1151                              (not (equal date last-date))
1152                            first)
1153                          (setq first nil
1154                                accum (- accum (if last-date-limited
1155                                                   last-date-seconds
1156                                                 timeclock-workday))))
1157                      (setq last-date date
1158                            last-date-limited nil)
1159                      (if beg
1160                          (error "Error in format of timelog file!")
1161                        (setq beg (timeclock-time-to-seconds (cadr event))))))
1162                   ((equal (downcase (car event)) "o")
1163                    (if (and (nth 2 event)
1164                             (> (length (nth 2 event)) 0))
1165                        (add-to-list 'timeclock-reason-list (nth 2 event)))
1166                    (if (not beg)
1167                        (error "Error in format of timelog file!")
1168                      (setq timeclock-last-period
1169                            (- (timeclock-time-to-seconds (cadr event)) beg)
1170                            accum (+ timeclock-last-period accum)
1171                            beg nil))
1172                    (if (equal last-date todays-date)
1173                        (setq timeclock-elapsed
1174                              (+ timeclock-last-period timeclock-elapsed)))))
1175             (setq timeclock-last-event event
1176                   timeclock-last-event-workday
1177                   (if (equal (timeclock-time-to-date now) last-date-limited)
1178                       last-date-seconds
1179                     timeclock-workday))
1180             (forward-line))
1181           (setq timeclock-discrepancy accum))))
1182     (unless timeclock-last-event-workday
1183       (setq timeclock-last-event-workday timeclock-workday))
1184     (setq accum (or timeclock-discrepancy 0)
1185           elapsed (or timeclock-elapsed elapsed))
1186     (if timeclock-last-event
1187         (if (equal (car timeclock-last-event) "i")
1188             (let ((last-period (timeclock-last-period now)))
1189               (setq accum (+ accum last-period)
1190                     elapsed (+ elapsed last-period)))
1191           (if (not (equal (timeclock-time-to-date
1192                            (cadr timeclock-last-event))
1193                           (timeclock-time-to-date now)))
1194               (setq accum (- accum timeclock-last-event-workday)))))
1195     (list accum (- elapsed timeclock-last-event-workday)
1196           elapsed)))
1197
1198 ;;; A reporting function that uses timeclock-log-data
1199
1200 (defun timeclock-day-base (&optional time)
1201   "Given a time within a day, return 0:0:0 within that day.
1202 If optional argument TIME is non-nil, use that instead of the current time."
1203   (let ((decoded (decode-time (or time (current-time)))))
1204     (setcar (nthcdr 0 decoded) 0)
1205     (setcar (nthcdr 1 decoded) 0)
1206     (setcar (nthcdr 2 decoded) 0)
1207     (apply 'encode-time decoded)))
1208
1209 (defun timeclock-mean (l)
1210   "Compute the arithmetic mean of the values in the list L."
1211   (let ((total 0)
1212         (count 0))
1213     (dolist (thisl l)
1214       (setq total (+ total thisl)
1215             count (1+ count)))
1216     (if (zerop count)
1217         0
1218       (/ total count))))
1219
1220 (defun timeclock-generate-report (&optional html-p)
1221   "Generate a summary report based on the current timelog file.
1222 By default, the report is in plain text, but if the optional argument
1223 HTML-P is non-nil, HTML markup is added."
1224   (interactive "P")
1225   (let ((log (timeclock-log-data))
1226         (today (timeclock-day-base)))
1227     (if html-p (insert "<p>"))
1228     (insert "Currently ")
1229     (let ((project (nth 2 timeclock-last-event))
1230           (begin (nth 1 timeclock-last-event))
1231           done)
1232       (if (timeclock-currently-in-p)
1233           (insert "IN")
1234         (if (zerop (length project))
1235             (progn (insert "Done Working Today")
1236                    (setq done t))
1237           (insert "OUT")))
1238       (unless done
1239         (insert " since " (format-time-string "%Y/%m/%d %-I:%M %p" begin))
1240         (if html-p
1241             (insert "<br>\n<b>")
1242           (insert "\n*"))
1243         (if (timeclock-currently-in-p)
1244             (insert "Working on "))
1245         (if html-p
1246             (insert project "</b><br>\n")
1247           (insert project "*\n"))
1248         (let ((proj-data (cdr (assoc project (timeclock-project-alist log))))
1249               (two-weeks-ago (timeclock-seconds-to-time
1250                               (- (timeclock-time-to-seconds today)
1251                                  (* 2 7 24 60 60))))
1252               two-week-len today-len)
1253           (while proj-data
1254             (if (not (time-less-p
1255                       (timeclock-entry-begin (car proj-data)) today))
1256                 (setq today-len (timeclock-entry-list-length proj-data)
1257                       proj-data nil)
1258               (if (and (null two-week-len)
1259                        (not (time-less-p
1260                              (timeclock-entry-begin (car proj-data))
1261                              two-weeks-ago)))
1262                   (setq two-week-len (timeclock-entry-list-length proj-data)))
1263               (setq proj-data (cdr proj-data))))
1264           (if (null two-week-len)
1265               (setq two-week-len today-len))
1266           (if html-p (insert "<p>"))
1267           (if today-len
1268               (insert "\nTime spent on this task today: "
1269                       (timeclock-seconds-to-string today-len)
1270                       ".  In the last two weeks: "
1271                       (timeclock-seconds-to-string two-week-len))
1272             (if two-week-len
1273                 (insert "\nTime spent on this task in the last two weeks: "
1274                         (timeclock-seconds-to-string two-week-len))))
1275           (if html-p (insert "<br>"))
1276           (insert "\n"
1277                   (timeclock-seconds-to-string (timeclock-workday-elapsed))
1278                   " worked today, "
1279                   (timeclock-seconds-to-string (timeclock-workday-remaining))
1280                   " remaining, done at "
1281                   (timeclock-when-to-leave-string) "\n")))
1282       (if html-p (insert "<p>"))
1283       (insert "\nThere have been "
1284               (number-to-string
1285                (length (timeclock-day-alist log)))
1286               " days of activity, starting "
1287               (caar (last (timeclock-day-alist log))))
1288       (if html-p (insert "</p>"))
1289       (when html-p
1290         (insert "<p>
1291 <table>
1292 <td width=\"25\"><br></td><td>
1293 <table border=1 cellpadding=3>
1294 <tr><th><i>Statistics</i></th>
1295     <th>Entire</th>
1296     <th>-30 days</th>
1297     <th>-3 mons</th>
1298     <th>-6 mons</th>
1299     <th>-1 year</th>
1300 </tr>")
1301         (let* ((day-list (timeclock-day-list))
1302                (thirty-days-ago (timeclock-seconds-to-time
1303                                  (- (timeclock-time-to-seconds today)
1304                                     (* 30 24 60 60))))
1305                (three-months-ago (timeclock-seconds-to-time
1306                                   (- (timeclock-time-to-seconds today)
1307                                      (* 90 24 60 60))))
1308                (six-months-ago (timeclock-seconds-to-time
1309                                 (- (timeclock-time-to-seconds today)
1310                                    (* 180 24 60 60))))
1311                (one-year-ago (timeclock-seconds-to-time
1312                               (- (timeclock-time-to-seconds today)
1313                                  (* 365 24 60 60))))
1314                (time-in  (vector (list t) (list t) (list t) (list t) (list t)))
1315                (time-out (vector (list t) (list t) (list t) (list t) (list t)))
1316                (breaks   (vector (list t) (list t) (list t) (list t) (list t)))
1317                (workday  (vector (list t) (list t) (list t) (list t) (list t)))
1318                (lengths  (vector '(0 0) thirty-days-ago three-months-ago
1319                                  six-months-ago one-year-ago)))
1320           ;; collect statistics from complete timelog
1321           (dolist (day day-list)
1322             (let ((i 0) (l 5))
1323               (while (< i l)
1324                 (unless (time-less-p
1325                          (timeclock-day-begin day)
1326                          (aref lengths i))
1327                   (let ((base (timeclock-time-to-seconds
1328                                (timeclock-day-base
1329                                 (timeclock-day-begin day)))))
1330                     (nconc (aref time-in i)
1331                            (list (- (timeclock-time-to-seconds
1332                                      (timeclock-day-begin day))
1333                                     base)))
1334                     (let ((span (timeclock-day-span day))
1335                           (len (timeclock-day-length day))
1336                           (req (timeclock-day-required day)))
1337                       ;; If the day's actual work length is less than
1338                       ;; 70% of its span, then likely the exit time
1339                       ;; and break amount are not worthwhile adding to
1340                       ;; the statistic
1341                       (when (and (> span 0)
1342                                  (> (/ (float len) (float span)) 0.70))
1343                         (nconc (aref time-out i)
1344                                (list (- (timeclock-time-to-seconds
1345                                          (timeclock-day-end day))
1346                                         base)))
1347                         (nconc (aref breaks i) (list (- span len))))
1348                       (if req
1349                           (setq len (+ len (- timeclock-workday req))))
1350                       (nconc (aref workday i) (list len)))))
1351                 (setq i (1+ i)))))
1352           ;; average statistics
1353           (let ((i 0) (l 5))
1354             (while (< i l)
1355               (aset time-in i (timeclock-mean (cdr (aref time-in i))))
1356               (aset time-out i (timeclock-mean (cdr (aref time-out i))))
1357               (aset breaks i (timeclock-mean (cdr (aref breaks i))))
1358               (aset workday i (timeclock-mean (cdr (aref workday i))))
1359               (setq i (1+ i))))
1360           ;; Output the HTML table
1361           (insert "<tr>\n")
1362           (insert "<td align=\"center\">Time in</td>\n")
1363           (let ((i 0) (l 5))
1364             (while (< i l)
1365               (insert "<td align=\"right\">"
1366                       (timeclock-seconds-to-string (aref time-in i))
1367                       "</td>\n")
1368               (setq i (1+ i))))
1369           (insert "</tr>\n")
1370
1371           (insert "<tr>\n")
1372           (insert "<td align=\"center\">Time out</td>\n")
1373           (let ((i 0) (l 5))
1374             (while (< i l)
1375               (insert "<td align=\"right\">"
1376                       (timeclock-seconds-to-string (aref time-out i))
1377                       "</td>\n")
1378               (setq i (1+ i))))
1379           (insert "</tr>\n")
1380
1381           (insert "<tr>\n")
1382           (insert "<td align=\"center\">Break</td>\n")
1383           (let ((i 0) (l 5))
1384             (while (< i l)
1385               (insert "<td align=\"right\">"
1386                       (timeclock-seconds-to-string (aref breaks i))
1387                       "</td>\n")
1388               (setq i (1+ i))))
1389           (insert "</tr>\n")
1390
1391           (insert "<tr>\n")
1392           (insert "<td align=\"center\">Workday</td>\n")
1393           (let ((i 0) (l 5))
1394             (while (< i l)
1395               (insert "<td align=\"right\">"
1396                       (timeclock-seconds-to-string (aref workday i))
1397                       "</td>\n")
1398               (setq i (1+ i))))
1399           (insert "</tr>\n"))
1400         (insert "<tfoot>
1401 <td colspan=\"6\" align=\"center\">
1402   <i>These are approximate figures</i></td>
1403 </tfoot>
1404 </table>
1405 </td></table>")))))
1406
1407 ;;; A helpful little function
1408
1409 (defun timeclock-visit-timelog ()
1410   "Open the file named by `timeclock-file' in another window."
1411   (interactive)
1412   (find-file-other-window timeclock-file))
1413
1414 (provide 'timeclock)
1415
1416 (run-hooks 'timeclock-load-hook)
1417
1418 ;; make sure we know the list of reasons, projects, and have computed
1419 ;; the last event and current discrepancy.
1420 (if (file-readable-p timeclock-file)
1421     (timeclock-reread-log))
1422
1423 ;; arch-tag: a0be3377-deb6-44ec-b9a2-a7be28436a40
1424 ;;; timeclock.el ends here