configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" = yes; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" = yes; then
  88   if test "${with_kerberos}" != yes; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 if test "$with_hesiod" = yes; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 101
 102 dnl FIXME currently it is not the last.
 103 dnl This should be the last --with option, because --with-x is
 104 dnl added later on when we find the path of X, and it's best to
 105 dnl keep them together visually.
 106 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 107  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 108 [         case "${withval}" in
 109             y | ye | yes )      val=gtk ;;
 110             n | no )            val=no  ;;
 111             l | lu | luc | luci | lucid )       val=lucid ;;
 112             a | at | ath | athe | athen | athena )      val=athena ;;
 113             m | mo | mot | moti | motif )       val=motif ;;
 114             g | gt | gtk  )     val=gtk ;;
 115             * )
 116 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 117 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 118 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 119             ;;
 120           esac
 121           with_x_toolkit=$val
 122 ])
 123
 124 dnl _ON results in a '--without' option in the --help output, so
 125 dnl the help text should refer to "don't compile", etc.
 126 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 127 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 128 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 129 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 130 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 131 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 132
 133 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 134 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 135 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 136 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 137
 138 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 139 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 140 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 141 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 142
 143 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 144 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 145
 146 dnl Can remove these in Emacs 24.
 147 AC_ARG_WITH([gtk],,
 148   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 149 specify a toolkit.]),,)
 150
 151 AC_ARG_WITH([gcc],,
 152   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 153   variable to specify a compiler.]),,)
 154
 155 AC_ARG_WITH([pkg-config-prog],dnl
 156 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 157                   [Path to pkg-config for finding GTK and librsvg])])
 158 if test "X${with_pkg_config_prog}" != X; then
 159    if test "${with_pkg_config_prog}" != yes; then
 160       PKG_CONFIG="${with_pkg_config_prog}"
 161    fi
 162 fi
 163
 164 AC_ARG_ENABLE(carbon-app,
 165 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 166                 [specify install directory for Emacs.app on Mac OS X
 167                  [DIR=/Application]])],
 168 [ carbon_appdir_x=${enableval}])
 169
 170 AC_ARG_ENABLE(font-backend,
 171 [  --enable-font-backend   compile code of font-backend support],
 172       USE_FONT_BACKEND=$enableval,
 173       USE_FONT_BACKEND=no)
 174
 175 AC_ARG_ENABLE(asserts,
 176 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 177       USE_XASSERTS=$enableval,
 178       USE_XASSERTS=no)
 179
 180 AC_ARG_ENABLE(maintainer-mode,
 181 [AS_HELP_STRING([--enable-maintainer-mode],
 182                 [enable make rules and dependencies not useful (and sometimes
 183                  confusing) to the casual installer])],
 184       USE_MAINTAINER_MODE=$enableval,
 185       USE_MAINTAINER_MODE=no)
 186 if test $USE_MAINTAINER_MODE = yes; then
 187   MAINT=
 188 else
 189   MAINT=#
 190 fi
 191 AC_SUBST(MAINT)
 192
 193 AC_ARG_ENABLE(locallisppath,
 194 [AS_HELP_STRING([--enable-locallisppath=PATH],
 195                 [directories Emacs should search for lisp files specific
 196                  to this site])],
 197 if test "${enableval}" = "no"; then
 198   locallisppath=
 199 elif test "${enableval}" != "yes"; then
 200   locallisppath=${enableval}
 201 fi)
 202
 203 #### Make srcdir absolute, if it isn't already.  It's important to
 204 #### avoid running the path through pwd unnecessarily, since pwd can
 205 #### give you automounter prefixes, which can go away.  We do all this
 206 #### so Emacs can find its files when run uninstalled.
 207 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 208 unset CDPATH
 209 case "${srcdir}" in
 210   /* ) ;;
 211   . )
 212     ## We may be able to use the $PWD environment variable to make this
 213     ## absolute.  But sometimes PWD is inaccurate.
 214     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 215     ## but that tested only for a well-formed and valid PWD,
 216     ## it did not object when PWD was well-formed and valid but just wrong.
 217     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 218     then
 219       srcdir="$PWD"
 220     else
 221       srcdir="`(cd ${srcdir}; pwd)`"
 222     fi
 223   ;;
 224   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 225 esac
 226
 227 #### Check if the source directory already has a configured system in it.
 228 if test `pwd` != `(cd ${srcdir} && pwd)` \
 229    && test -f "${srcdir}/src/config.h" ; then
 230   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 231    as a build directory right now; it has been configured in its own
 232    right.  To configure in another directory as well, you MUST
 233    use GNU make.  If you do not have GNU make, then you must
 234    now do `make distclean' in ${srcdir},
 235    and then run $0 again.]])
 236 fi
 237
 238 #### Given the configuration name, set machfile and opsysfile to the
 239 #### names of the m/*.h and s/*.h files we should use.
 240
 241 ### Canonicalize the configuration name.
 242
 243 AC_CANONICAL_HOST
 244 canonical=$host
 245 configuration=${host_alias-${build_alias-$host}}
 246
 247 dnl This used to use changequote, but, apart from `changequote is evil'
 248 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 249 dnl the great gob of text.  Thus it's not processed for possible expansion.
 250 dnl Just make sure the brackets remain balanced.
 251 dnl
 252 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 253 dnl indicated by comments.
 254 dnl quotation begins
 255 [
 256
 257 ### If you add support for a new configuration, add code to this
 258 ### switch statement to recognize your configuration name and select
 259 ### the appropriate operating system and machine description files.
 260
 261 ### You would hope that you could choose an m/*.h file pretty much
 262 ### based on the machine portion of the configuration name, and an s-
 263 ### file based on the operating system portion.  However, it turns out
 264 ### that each m/*.h file is pretty manufacturer-specific - for
 265 ### example hp9000s300.h is a 68000 machine;
 266 ### mips.h, pmax.h are all MIPS
 267 ### machines.  So we basically have to have a special case for each
 268 ### configuration name.
 269 ###
 270 ### As far as handling version numbers on operating systems is
 271 ### concerned, make sure things will fail in a fixable way.  If
 272 ### /etc/MACHINES doesn't say anything about version numbers, be
 273 ### prepared to handle anything reasonably.  If version numbers
 274 ### matter, be sure /etc/MACHINES says something about it.
 275 ###
 276 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 277 ### "System V Release 4"; he writes, "The old convention encouraged
 278 ### confusion between `system' and `release' levels'."
 279
 280 machine='' opsys='' unported=no
 281 case "${canonical}" in
 282
 283   ## FreeBSD ports
 284   *-*-freebsd* )
 285     opsys=freebsd
 286     case "${canonical}" in
 287       alpha*-*-freebsd*)        machine=alpha ;;
 288       ia64-*-freebsd*)          machine=ia64 ;;
 289       sparc64-*-freebsd*)       machine=sparc ;;
 290       powerpc-*-freebsd*)       machine=macppc ;;
 291       i[3456]86-*-freebsd*)     machine=intel386 ;;
 292       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 293     esac
 294   ;;
 295
 296   ## FreeBSD kernel + glibc based userland
 297   *-*-kfreebsd*gnu* )
 298     opsys=gnu-kfreebsd
 299     case "${canonical}" in
 300       alpha*-*-kfreebsd*)       machine=alpha ;;
 301       ia64-*-kfreebsd*)         machine=ia64 ;;
 302       sparc64-*-kfreebsd*)      machine=sparc ;;
 303       powerpc-*-kfreebsd*)      machine=macppc ;;
 304       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 305       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 306     esac
 307   ;;
 308
 309   ## NetBSD ports
 310   *-*-netbsd* )
 311     opsys=netbsd
 312     if test -f /usr/lib/crti.o; then]
 313 dnl The close and open brackets here are because this section is quoted --
 314 dnl see the `changequote' comment above.
 315       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 316 [   fi
 317
 318     case "${canonical}" in
 319       alpha*-*-netbsd*) machine=alpha ;;
 320       i[3456]86-*-netbsd*) machine=intel386 ;;
 321       m68k-*-netbsd*)
 322                         # This is somewhat bogus.
 323                         machine=hp9000s300 ;;
 324       mips-*-netbsd*)   machine=pmax ;;
 325       mipsel-*-netbsd*) machine=pmax ;;
 326       mipseb-*-netbsd*) machine=pmax ;;
 327       powerpc-*-netbsd*) machine=macppc ;;
 328       sparc*-*-netbsd*) machine=sparc ;;
 329       vax-*-netbsd*)    machine=vax ;;
 330       arm-*-netbsd*)    machine=arm ;;
 331       x86_64-*-netbsd*) machine=amdx86-64 ;;
 332       hppa-*-netbsd*)   machine=hp800 ;;
 333     esac
 334   ;;
 335
 336   ## OpenBSD ports
 337   *-*-openbsd* )
 338     opsys=openbsd
 339     case "${canonical}" in
 340       alpha*-*-openbsd*)        machine=alpha ;;
 341       arm-*-openbsd*)          machine=arm ;;
 342       hppa-*-openbsd*)         machine=hp9000s300 ;;
 343       i386-*-openbsd*)         machine=intel386 ;;
 344       m68k-*-openbsd*)         machine=hp9000s300 ;;
 345       mips64-*-openbsd*)       machine=mips64 ;;
 346       powerpc-*-openbsd*)      machine=macppc ;;
 347       sparc*-*-openbsd*)       machine=sparc ;;
 348       vax-*-openbsd*)          machine=vax ;;
 349       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 350     esac
 351   ;;
 352
 353   ## LynxOS ports
 354   *-*-lynxos* )
 355     opsys=lynxos
 356     case "${canonical}" in
 357       i[3456]86-*-lynxos*) machine=intel386 ;;
 358       powerpc-*-lynxos*) machine=powerpc ;;
 359     esac
 360   ;;
 361
 362   ## BSDI ports
 363   *-*-bsdi* )
 364     opsys=bsdi
 365     case "${canonical}" in
 366       i[345]86-*-bsdi*) machine=intel386 ;;
 367       sparc-*-bsdi*)  machine=sparc ;;
 368       powerpc-*-bsdi*)  machine=macppc ;;
 369     esac
 370     case "${canonical}" in
 371       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 372       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 373       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 374       *-*-bsdi3* )              opsys=bsdos3 ;;
 375       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 376     esac
 377   ;;
 378
 379   ## Alpha (DEC) machines.
 380   alpha*-dec-osf* )
 381     machine=alpha opsys=osf1
 382     # This is needed to find X11R6.1 libraries for certain tests.
 383     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 384     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 385     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 386     # due to non-traditional preprocessing with the current compiler
 387     # defaults.  OSF 4 can also have that compiler version, and there
 388     # seems always to have been a usable /usr/bin/cpp.
 389     NON_GNU_CPP=/usr/bin/cpp
 390     case "${canonical}" in
 391     alpha*-dec-osf[5-9]*)
 392       opsys=osf5-0 ;;
 393     esac
 394   ;;
 395
 396   alpha*-*-linux-gnu* )
 397     machine=alpha opsys=gnu-linux
 398   ;;
 399
 400   arm*-*-linux-gnu* )
 401     machine=arm opsys=gnu-linux
 402   ;;
 403
 404   ## Apple Darwin / Mac OS X
 405   *-apple-darwin* )
 406     case "${canonical}" in
 407       i[3456]86-* )  machine=intel386 ;;
 408       powerpc-* )    machine=powermac ;;
 409       * )            unported=yes ;;
 410     esac
 411     opsys=darwin
 412     # Define CPP as follows to make autoconf work correctly.
 413     CPP="${CC-cc} -E -no-cpp-precomp"
 414     # Use fink packages if available.
 415     if test -d /sw/include && test -d /sw/lib; then
 416       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 417       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 418       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 419     fi
 420   ;;
 421
 422   ## Compaq Nonstop
 423   mips-compaq-nonstopux* )
 424     machine=nonstopux opsys=nonstopux
 425     ;;
 426
 427   ## Cubix QBx/386
 428   i[3456]86-cubix-sysv* )
 429     machine=intel386 opsys=usg5-3
 430   ;;
 431
 432   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 433     machine=pmax opsys=bsd4-2
 434   ;;
 435   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 436     machine=pmax opsys=bsd4-3
 437   ;;
 438   mips-dec-ultrix* )
 439     machine=pmax opsys=ultrix4-3
 440   ;;
 441   mips-dec-osf* )
 442     machine=pmax opsys=osf1
 443   ;;
 444   mips-dec-mach_bsd4.3* )
 445     machine=pmax opsys=mach-bsd4-3
 446   ;;
 447
 448   ## HP 9000 series 200 or 300
 449   m68*-hp-bsd* )
 450     machine=hp9000s300 opsys=bsd4-3
 451   ;;
 452   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 453   m68*-hp-hpux* )
 454     case "`uname -r`" in
 455       ## Someone's system reports A.B8.05 for this.
 456       ## I wonder what other possibilities there are.
 457       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 458       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 459       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 460       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 461       *) machine=hp9000s300 opsys=hpux ;;
 462     esac
 463   ;;
 464
 465   ## HP 9000 series 700 and 800, running HP/UX
 466   hppa*-hp-hpux7* )
 467     machine=hp800 opsys=hpux
 468   ;;
 469   hppa*-hp-hpux8* )
 470     machine=hp800 opsys=hpux8
 471   ;;
 472   hppa*-hp-hpux9shr* )
 473     machine=hp800 opsys=hpux9shr
 474   ;;
 475   hppa*-hp-hpux9* )
 476     machine=hp800 opsys=hpux9
 477   ;;
 478   hppa*-hp-hpux10.2* )
 479     machine=hp800 opsys=hpux10-20
 480   ;;
 481   hppa*-hp-hpux10* )
 482     machine=hp800 opsys=hpux10
 483   ;;
 484   hppa*-hp-hpux1[1-9]* )
 485     machine=hp800 opsys=hpux11
 486     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 487   ;;
 488
 489   hppa*-*-linux-gnu* )
 490     machine=hp800 opsys=gnu-linux
 491   ;;
 492
 493   ## HP 9000 series 700 and 800, running HP/UX
 494   hppa*-hp-hpux* )
 495     ## Cross-compilation?  Nah!
 496     case "`uname -r`" in
 497       ## Someone's system reports A.B8.05 for this.
 498       ## I wonder what other possibilities there are.
 499       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 500       *.08.* ) machine=hp800 opsys=hpux8 ;;
 501       *.09.* ) machine=hp800 opsys=hpux9 ;;
 502       *) machine=hp800 opsys=hpux10 ;;
 503     esac
 504   ;;
 505   hppa*-*-nextstep* )
 506     machine=hp800 opsys=nextstep
 507   ;;
 508
 509   ## IBM machines
 510   i370-ibm-aix*)
 511     machine=ibm370aix opsys=usg5-3
 512   ;;
 513   s390-*-linux-gnu* )
 514     machine=ibms390 opsys=gnu-linux
 515   ;;
 516   s390x-*-linux-gnu* )
 517     machine=ibms390x opsys=gnu-linux
 518   ;;
 519   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 520     machine=ibmrs6000 opsys=aix3-1
 521   ;;
 522   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 523     machine=ibmrs6000 opsys=aix3-2-5
 524   ;;
 525   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 526     machine=ibmrs6000 opsys=aix4-1
 527   ;;
 528   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 535     machine=ibmrs6000 opsys=aix4-2
 536   ;;
 537   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 538     machine=ibmrs6000 opsys=aix4
 539   ;;
 540   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 541     machine=ibmrs6000 opsys=aix4-1
 542   ;;
 543   rs6000-ibm-aix* | powerpc-ibm-aix* )
 544     machine=ibmrs6000 opsys=aix3-2
 545   ;;
 546
 547   ## Prime EXL
 548   i[3456]86-prime-sysv* )
 549     machine=i386 opsys=usg5-3
 550   ;;
 551
 552   ## ncr machine running svr4.3.
 553   i[3456]86-ncr-sysv4.3 )
 554     machine=ncr386 opsys=usg5-4-3
 555   ;;
 556
 557   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 558   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 559   i[3456]86-ncr-sysv* )
 560     machine=ncr386 opsys=usg5-4-2
 561   ;;
 562
 563   ## Macintosh PowerPC
 564   powerpc*-*-linux-gnu* )
 565     machine=macppc opsys=gnu-linux
 566   ;;
 567
 568   ## Workstations sold by MIPS
 569   ## This is not necessarily all workstations using the MIPS processor -
 570   ## Irises are produced by SGI, and DECstations by DEC.
 571
 572   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 573   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 574   ## it gives for choosing between the alternatives seems to be "Use
 575   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 576   ## the BSD world."  I'll assume that these are instructions for
 577   ## handling two odd situations, and that every other situation
 578   ## should use mips.h and usg5-2-2, they being listed first.
 579   mips-mips-usg* )
 580     machine=mips4
 581     ## Fall through to the general code at the bottom to decide on the OS.
 582   ;;
 583   mips-mips-riscos4* )
 584     machine=mips4 opsys=bsd4-3
 585     NON_GNU_CC="cc -systype bsd43"
 586     NON_GNU_CPP="cc -systype bsd43 -E"
 587   ;;
 588   mips-mips-riscos5* )
 589     machine=mips4 opsys=riscos5
 590     NON_GNU_CC="cc -systype bsd43"
 591     NON_GNU_CPP="cc -systype bsd43 -E"
 592   ;;
 593   mips-mips-bsd* )
 594     machine=mips opsys=bsd4-3
 595   ;;
 596   mips-mips-* )
 597     machine=mips opsys=usg5-2-2
 598   ;;
 599
 600   ## NeXT
 601   m68*-next-* | m68k-*-nextstep* )
 602     machine=m68k opsys=nextstep
 603   ;;
 604
 605   ## NEC EWS4800
 606   mips-nec-sysv4*)
 607   machine=ews4800 opsys=ux4800
 608   ;;
 609
 610   ## Siemens Nixdorf
 611   mips-siemens-sysv* | mips-sni-sysv*)
 612     machine=mips-siemens opsys=usg5-4
 613     NON_GNU_CC=/usr/ccs/bin/cc
 614     NON_GNU_CPP=/usr/ccs/lib/cpp
 615   ;;
 616
 617   ## Silicon Graphics machines
 618   ## Iris 4D
 619   mips-sgi-irix6.5 )
 620     machine=iris4d opsys=irix6-5
 621     # Without defining _LANGUAGE_C, things get masked out in the headers
 622     # so that, for instance, grepping for `free' in stdlib.h fails and
 623     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 624     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 625     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 626   ;;
 627   mips-sgi-irix6* )
 628     machine=iris4d opsys=irix6-0
 629     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 630     # but presumably it does no harm.
 631     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 632     # -32 probably isn't necessary in later v.6s -- anyone know which?
 633     NON_GCC_TEST_OPTIONS=-32
 634   ;;
 635   mips-sgi-irix5.[01]* )
 636     machine=iris4d opsys=irix5-0
 637   ;;
 638   mips-sgi-irix5* | mips-sgi-irix* )
 639     machine=iris4d opsys=irix5-2
 640   ;;
 641
 642   ## Suns
 643   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 644     machine=sparc opsys=gnu-linux
 645   ;;
 646
 647   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 648     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 649     | rs6000-*-solaris2*)
 650     case "${canonical}" in
 651       i[3456]86-*-* )     machine=intel386 ;;
 652       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 653       powerpcle* )      machine=powerpcle ;;
 654       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 655       sparc* )          machine=sparc ;;
 656       * )               unported=yes ;;
 657     esac
 658     case "${canonical}" in
 659       *-sunos5.3* | *-solaris2.3* )
 660                 opsys=sol2-3
 661                 NON_GNU_CPP=/usr/ccs/lib/cpp
 662                 ;;
 663       *-sunos5.4* | *-solaris2.4* )
 664                 opsys=sol2-4
 665                 NON_GNU_CPP=/usr/ccs/lib/cpp
 666                 RANLIB="ar -ts"
 667                 ;;
 668       *-sunos5.5* | *-solaris2.5* )
 669                 opsys=sol2-5
 670                 NON_GNU_CPP=/usr/ccs/lib/cpp
 671                 RANLIB="ar -ts"
 672                 ;;
 673       *-sunos5.6* | *-solaris2.6* )
 674                 opsys=sol2-6
 675                 NON_GNU_CPP=/usr/ccs/lib/cpp
 676                 RANLIB="ar -ts"
 677                 ;;
 678       *-sunos5* | *-solaris* )
 679                 opsys=sol2-6
 680                 emacs_check_sunpro_c=yes
 681                 NON_GNU_CPP=/usr/ccs/lib/cpp
 682                 ;;
 683       *                   ) opsys=bsd4-2   ;;
 684     esac
 685     ## Watch out for a compiler that we know will not work.
 686     case "${canonical}" in
 687      *-solaris* | *-sunos5* )
 688                 if [ "x$CC" = x/usr/ucb/cc ]; then
 689                   ## /usr/ucb/cc doesn't work;
 690                   ## we should find some other compiler that does work.
 691                   unset CC
 692                 fi
 693                 ;;
 694       *) ;;
 695     esac
 696   ;;
 697   sparc-*-nextstep* )
 698     machine=sparc opsys=nextstep
 699   ;;
 700
 701   ## Tandem Integrity S2
 702   mips-tandem-sysv* )
 703     machine=tandem-s2 opsys=usg5-3
 704   ;;
 705
 706   ## Vaxen.
 707   vax-dec-* )
 708     machine=vax
 709     case "${canonical}" in
 710       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 711       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 712       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 713       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 714       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 715       *-vms* )                                          opsys=vms ;;
 716       * )                                               unported=yes
 717     esac
 718   ;;
 719
 720   ## IA-64
 721   ia64*-*-linux* )
 722     machine=ia64 opsys=gnu-linux
 723   ;;
 724
 725   ## Intel 386 machines where we don't care about the manufacturer
 726   i[3456]86-*-* )
 727     machine=intel386
 728     case "${canonical}" in
 729       *-cygwin )                opsys=cygwin ;;
 730       *-darwin* )               opsys=darwin
 731                                 CPP="${CC-cc} -E -no-cpp-precomp"
 732                                 ;;
 733       *-xenix* )                opsys=xenix ;;
 734       *-linux-gnu* )            opsys=gnu-linux ;;
 735       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 736       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 737       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 738       *-386bsd* )               opsys=386bsd ;;
 739       *-nextstep* )             opsys=nextstep ;;
 740       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 741     esac
 742   ;;
 743
 744   ## m68k Linux-based GNU system
 745   m68k-*-linux-gnu* )
 746     machine=m68k opsys=gnu-linux
 747   ;;
 748
 749   ## Mips Linux-based GNU system
 750   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 751     machine=mips opsys=gnu-linux
 752   ;;
 753
 754   ## UXP/DS
 755   sparc-fujitsu-sysv4* )
 756     machine=sparc opsys=uxpds
 757     NON_GNU_CPP=/usr/ccs/lib/cpp
 758     RANLIB="ar -ts"
 759   ;;
 760
 761   ## AMD x86-64 Linux-based GNU system
 762   x86_64-*-linux-gnu* )
 763     machine=amdx86-64 opsys=gnu-linux
 764   ;;
 765
 766   ## Tensilica Xtensa Linux-based GNU system
 767   xtensa*-*-linux-gnu* )
 768     machine=xtensa opsys=gnu-linux
 769     ;;
 770
 771   * )
 772     unported=yes
 773   ;;
 774 esac
 775
 776 ### If the code above didn't choose an operating system, just choose
 777 ### an operating system based on the configuration name.  You really
 778 ### only want to use this when you have no idea what the right
 779 ### operating system is; if you know what operating systems a machine
 780 ### runs, it's cleaner to make it explicit in the case statement
 781 ### above.
 782 if test x"${opsys}" = x; then
 783   case "${canonical}" in
 784     *-gnu* )                            opsys=gnu ;;
 785     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 786     *-bsd4.2 )                          opsys=bsd4-2 ;;
 787     *-bsd4.3 )                          opsys=bsd4-3 ;;
 788     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 789     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 790     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 791     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 792     *-sysv4.2uw* )                      opsys=unixware ;;
 793     *-sysv5uw* )                        opsys=unixware ;;
 794     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 795     *-sysv4.1* | *-sysvr4.1* )
 796         NON_GNU_CPP=/usr/lib/cpp
 797         opsys=usg5-4 ;;
 798     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 799         if [ x$NON_GNU_CPP = x ]; then
 800           if [ -f /usr/ccs/lib/cpp ]; then
 801             NON_GNU_CPP=/usr/ccs/lib/cpp
 802           else
 803             NON_GNU_CPP=/lib/cpp
 804           fi
 805         fi
 806         opsys=usg5-4-2 ;;
 807     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 808     * )
 809       unported=yes
 810     ;;
 811   esac
 812 fi
 813
 814 ]
 815 dnl quotation ends
 816
 817 if test $unported = yes; then
 818   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 819 Check `etc/MACHINES' for recognized configuration names.])
 820 fi
 821
 822 machfile="m/${machine}.h"
 823 opsysfile="s/${opsys}.h"
 824
 825
 826 #### Choose a compiler.
 827 test -n "$CC" && cc_specified=yes
 828
 829 # Save the value of CFLAGS that the user specified.
 830 SPECIFIED_CFLAGS="$CFLAGS"
 831
 832 dnl Sets GCC=yes if using gcc.
 833 AC_PROG_CC
 834
 835 # On Suns, sometimes $CPP names a directory.
 836 if test -n "$CPP" && test -d "$CPP"; then
 837   CPP=
 838 fi
 839
 840 ## If not using gcc, and on Solaris, and no CPP specified, see if
 841 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 842 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 843  test x"$CPP" = x; then
 844   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 845   AC_CACHE_VAL(emacs_cv_sunpro_c,
 846   [AC_TRY_LINK([],
 847 [#ifndef __SUNPRO_C
 848 fail;
 849 #endif
 850 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 851   AC_MSG_RESULT($emacs_cv_sunpro_c)
 852
 853   if test x"$emacs_cv_sunpro_c" = xyes; then
 854     NON_GNU_CPP="$CC -E -Xs"
 855   fi
 856 fi
 857
 858 #### Some systems specify a CPP to use unless we are using GCC.
 859 #### Now that we know whether we are using GCC, we can decide whether
 860 #### to use that one.
 861 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 862 then
 863   CPP="$NON_GNU_CPP"
 864 fi
 865
 866 #### Some systems specify a CC to use unless we are using GCC.
 867 #### Now that we know whether we are using GCC, we can decide whether
 868 #### to use that one.
 869 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 870   test x$cc_specified != xyes
 871 then
 872   CC="$NON_GNU_CC"
 873 fi
 874
 875 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 876 then
 877   CC="$CC $GCC_TEST_OPTIONS"
 878 fi
 879
 880 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 881 then
 882   CC="$CC $NON_GCC_TEST_OPTIONS"
 883 fi
 884
 885 dnl checks for Unix variants
 886 AC_AIX
 887 AC_GNU_SOURCE
 888
 889 ### Use -Wno-pointer-sign if the compiler supports it
 890 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 891 SAVE_CFLAGS="$CFLAGS"
 892 CFLAGS="$CFLAGS -Wno-pointer-sign"
 893 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 894 if test $has_option = yes; then
 895    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 896 fi
 897 AC_MSG_RESULT($has_option)
 898 CFLAGS="$SAVE_CFLAGS"
 899 unset has_option
 900 unset SAVE_CFLAGS
 901
 902 #### Some other nice autoconf tests.
 903
 904 dnl checks for programs
 905 AC_PROG_LN_S
 906 AC_PROG_CPP
 907 AC_PROG_INSTALL
 908 if test "x$RANLIB" = x; then
 909   AC_PROG_RANLIB
 910 fi
 911 AC_PATH_PROG(INSTALL_INFO, install-info)
 912 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 913 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 914 dnl Don't use GZIP, which is used by gzip for additional parameters.
 915 AC_PATH_PROG(GZIP_PROG, gzip)
 916
 917
 918 ## Need makeinfo >= 4.6 (?) to build the manuals.
 919 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 920 dnl By this stage, configure has already checked for egrep and set EGREP,
 921 dnl or exited with an error if no egrep was found.
 922 if test "$MAKEINFO" != "no" && \
 923   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 924    MAKEINFO=no
 925 fi
 926
 927 if test "$MAKEINFO" = "no"; then
 928   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 929 fi
 930
 931
 932 dnl Add our options to ac_link now, after it is set up.
 933
 934 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 935 then
 936   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 937 fi
 938
 939 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 940 then
 941   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 942 fi
 943
 944 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 945 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 946 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 947 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 948 dnl if not built to support GNU ld.
 949
 950 late_LDFLAGS=$LDFLAGS
 951 if test "$GCC" = yes; then
 952   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 953 else
 954   LDFLAGS="$LDFLAGS -znocombreloc"
 955 fi
 956
 957 AC_MSG_CHECKING([for -znocombreloc])
 958 AC_LINK_IFELSE([main(){return 0;}],
 959   [AC_MSG_RESULT(yes)],
 960   LDFLAGS=$late_LDFLAGS
 961   [AC_MSG_RESULT(no)])
 962
 963 #### Extract some information from the operating system and machine files.
 964
 965 AC_CHECKING([the machine- and system-dependent files to find out
 966  - which libraries the lib-src programs will want, and
 967  - whether the GNU malloc routines are usable])
 968
 969 ### First figure out CFLAGS (which we use for running the compiler here)
 970 ### and REAL_CFLAGS (which we use for real compilation).
 971 ### The two are the same except on a few systems, where they are made
 972 ### different to work around various lossages.  For example,
 973 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 974 ### as implying static linking.
 975
 976 ### If the CFLAGS env var is specified, we use that value
 977 ### instead of the default.
 978
 979 ### It's not important that this name contain the PID; you can't run
 980 ### two configures in the same directory and have anything work
 981 ### anyway.
 982 tempcname="conftest.c"
 983
 984 echo '
 985 #include "'${srcdir}'/src/'${opsysfile}'"
 986 #include "'${srcdir}'/src/'${machfile}'"
 987 #ifndef LIBS_MACHINE
 988 #define LIBS_MACHINE
 989 #endif
 990 #ifndef LIBS_SYSTEM
 991 #define LIBS_SYSTEM
 992 #endif
 993 #ifndef C_SWITCH_SYSTEM
 994 #define C_SWITCH_SYSTEM
 995 #endif
 996 #ifndef C_SWITCH_MACHINE
 997 #define C_SWITCH_MACHINE
 998 #endif
 999 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1000 configure___ c_switch_system=C_SWITCH_SYSTEM
1001 configure___ c_switch_machine=C_SWITCH_MACHINE
1002
1003 #ifndef LIB_X11_LIB
1004 #define LIB_X11_LIB -lX11
1005 #endif
1006
1007 #ifndef LIBX11_SYSTEM
1008 #define LIBX11_SYSTEM
1009 #endif
1010 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
1011
1012 #ifdef UNEXEC
1013 configure___ unexec=UNEXEC
1014 #else
1015 configure___ unexec=unexec.o
1016 #endif
1017
1018 #ifdef SYSTEM_MALLOC
1019 configure___ system_malloc=yes
1020 #else
1021 configure___ system_malloc=no
1022 #endif
1023
1024 #ifdef USE_MMAP_FOR_BUFFERS
1025 configure___ use_mmap_for_buffers=yes
1026 #else
1027 configure___ use_mmap_for_buffers=no
1028 #endif
1029
1030 #ifndef C_DEBUG_SWITCH
1031 #define C_DEBUG_SWITCH -g
1032 #endif
1033
1034 #ifndef C_OPTIMIZE_SWITCH
1035 #ifdef __GNUC__
1036 #define C_OPTIMIZE_SWITCH -O2
1037 #else
1038 #define C_OPTIMIZE_SWITCH -O
1039 #endif
1040 #endif
1041
1042 #ifndef C_WARNINGS_SWITCH
1043 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1044 #endif
1045
1046 #ifndef LD_SWITCH_MACHINE
1047 #define LD_SWITCH_MACHINE
1048 #endif
1049
1050 #ifndef LD_SWITCH_SYSTEM
1051 #define LD_SWITCH_SYSTEM
1052 #endif
1053
1054 #ifndef LD_SWITCH_X_SITE_AUX
1055 #define LD_SWITCH_X_SITE_AUX
1056 #endif
1057
1058 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1059 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1060
1061 #ifdef THIS_IS_CONFIGURE
1062
1063 /* Get the CFLAGS for tests in configure.  */
1064 #ifdef __GNUC__
1065 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1066 #else
1067 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1068 #endif
1069
1070 #else /* not THIS_IS_CONFIGURE */
1071
1072 /* Get the CFLAGS for real compilation.  */
1073 #ifdef __GNUC__
1074 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1075 #else
1076 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1077 #endif
1078
1079 #endif /* not THIS_IS_CONFIGURE */
1080 ' > ${tempcname}
1081
1082 # The value of CPP is a quoted variable reference, so we need to do this
1083 # to get its actual value...
1084 CPP=`eval "echo $CPP"`
1085 [eval `${CPP} -Isrc ${tempcname} \
1086        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1087 if test "x$SPECIFIED_CFLAGS" = x; then
1088   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1089          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1090 else
1091   REAL_CFLAGS="$CFLAGS"
1092 fi]
1093 rm ${tempcname}
1094
1095 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1096
1097 ### Make sure subsequent tests use flags consistent with the build flags.
1098
1099 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1100   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1101 else
1102   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1103 fi
1104
1105 dnl For AC_FUNC_GETLOADAVG, at least:
1106 AC_CONFIG_LIBOBJ_DIR(src)
1107
1108 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1109 AC_SYS_LARGEFILE
1110
1111
1112 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1113 ### be located in either /usr/lib64 or /usr/lib.
1114 case "${canonical}" in
1115   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1116     if test -d /usr/lib64; then
1117       AC_DEFINE(HAVE_LIB64_DIR, 1,
1118         [Define to 1 if the directory /usr/lib64 exists.])
1119 fi
1120 esac
1121
1122 dnl This function defintion taken from Gnome 2.0
1123 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1124 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1125 dnl also defines GSTUFF_PKG_ERRORS on error
1126 AC_DEFUN([PKG_CHECK_MODULES], [
1127   succeeded=no
1128
1129   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1130
1131   if test "$PKG_CONFIG" = "no" ; then
1132      ifelse([$4], , [AC_MSG_ERROR([
1133       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1134   else
1135      PKG_CONFIG_MIN_VERSION=0.9.0
1136      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1137         AC_MSG_CHECKING(for $2)
1138
1139         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1140             AC_MSG_RESULT(yes)
1141             succeeded=yes
1142
1143             AC_MSG_CHECKING($1_CFLAGS)
1144             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1145             AC_MSG_RESULT($$1_CFLAGS)
1146
1147             AC_MSG_CHECKING($1_LIBS)
1148             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1149             AC_MSG_RESULT($$1_LIBS)
1150         else
1151             AC_MSG_RESULT(no)
1152             $1_CFLAGS=""
1153             $1_LIBS=""
1154             ## If we have a custom action on failure, don't print errors, but
1155             ## do set a variable so people can do so.
1156             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1157             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1158         fi
1159
1160         AC_SUBST($1_CFLAGS)
1161         AC_SUBST($1_LIBS)
1162      else
1163         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1164         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1165      fi
1166   fi
1167
1168   if test $succeeded = yes; then
1169      ifelse([$3], , :, [$3])
1170   else
1171      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1172   fi
1173 ])
1174
1175
1176 if test "${with_sound}" != "no"; then
1177   # Sound support for GNU/Linux and the free BSDs.
1178   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1179   # Emulation library used on NetBSD.
1180   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1181   AC_SUBST(LIBSOUND)
1182
1183   ALSA_REQUIRED=1.0.0
1184   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1185   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1186   if test $HAVE_ALSA = yes; then
1187     SAVE_CFLAGS="$CFLAGS"
1188     SAVE_LDFLAGS="$LDFLAGS"
1189     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1190     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1191     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1192                     emacs_alsa_normal=yes,
1193                     emacs_alsa_normal=no)
1194     if test "$emacs_alsa_normal" != yes; then
1195       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1196                      [snd_lib_error_set_handler (0);],
1197                      emacs_alsa_subdir=yes,
1198                      emacs_alsa_subdir=no)
1199       if test "$emacs_alsa_subdir" != yes; then
1200         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1201       fi
1202       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1203     fi
1204
1205     CFLAGS="$SAVE_CFLAGS"
1206     LDFLAGS="$SAVE_LDFLAGS"
1207     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1208     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1209     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1210   fi
1211   AC_SUBST(CFLAGS_SOUND)
1212 fi
1213
1214 dnl checks for header files
1215 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1216   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1217   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1218   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1219   sys/utsname.h pwd.h)
1220
1221 AC_MSG_CHECKING(if personality LINUX32 can be set)
1222 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1223                emacs_cv_personality_linux32=yes,
1224                emacs_cv_personality_linux32=no)
1225 AC_MSG_RESULT($emacs_cv_personality_linux32)
1226
1227 if test $emacs_cv_personality_linux32 = yes; then
1228   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1229             [Define to 1 if personality LINUX32 can be set.])
1230 fi
1231
1232 dnl On Solaris 8 there's a compilation warning for term.h because
1233 dnl it doesn't define `bool'.
1234 AC_CHECK_HEADERS(term.h, , , -)
1235 AC_HEADER_STDC
1236 AC_HEADER_TIME
1237 AC_CHECK_DECLS([sys_siglist])
1238 if test $ac_cv_have_decl_sys_siglist != yes; then
1239   # For Tru64, at least:
1240   AC_CHECK_DECLS([__sys_siglist])
1241   if test $ac_cv_have_decl___sys_siglist = yes; then
1242     AC_DEFINE(sys_siglist, __sys_siglist,
1243               [Define to any substitute for sys_siglist.])
1244   fi
1245 fi
1246 AC_HEADER_SYS_WAIT
1247
1248 dnl Some systems have utime.h but don't declare the struct anyplace.
1249 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1250 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1251 #include <sys/time.h>
1252 #include <time.h>
1253 #else
1254 #ifdef HAVE_SYS_TIME_H
1255 #include <sys/time.h>
1256 #else
1257 #include <time.h>
1258 #endif
1259 #endif
1260 #ifdef HAVE_UTIME_H
1261 #include <utime.h>
1262 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1263   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1264 if test $emacs_cv_struct_utimbuf = yes; then
1265   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1266 fi
1267
1268 dnl checks for typedefs
1269 AC_TYPE_SIGNAL
1270
1271 dnl Check for speed_t typedef.
1272 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1273   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1274     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1275 if test $emacs_cv_speed_t = yes; then
1276   AC_DEFINE(HAVE_SPEED_T, 1,
1277            [Define to 1 if `speed_t' is declared by <termios.h>.])
1278 fi
1279
1280 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1281 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1282 #include <sys/time.h>
1283 #include <time.h>
1284 #else
1285 #ifdef HAVE_SYS_TIME_H
1286 #include <sys/time.h>
1287 #else
1288 #include <time.h>
1289 #endif
1290 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1291   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1292 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1293 if test $emacs_cv_struct_timeval = yes; then
1294   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1295 fi
1296
1297 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1298 AC_TRY_COMPILE([#include <math.h>],
1299 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1300   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1301 HAVE_EXCEPTION=$emacs_cv_struct_exception
1302 if test $emacs_cv_struct_exception != yes; then
1303   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1304 fi
1305
1306 AC_CHECK_HEADERS(sys/socket.h)
1307 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1308 #if HAVE_SYS_SOCKET_H
1309 #include <sys/socket.h>
1310 #endif])
1311
1312 dnl checks for structure members
1313 AC_STRUCT_TM
1314 AC_STRUCT_TIMEZONE
1315 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1316                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1317                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1318                 [#include <time.h>])
1319 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1320                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1321                   struct ifreq.ifr_addr], , ,
1322                  [AC_INCLUDES_DEFAULT
1323 #if HAVE_SYS_SOCKET_H
1324 #include <sys/socket.h>
1325 #endif
1326 #if HAVE_NET_IF_H
1327 #include <net/if.h>
1328 #endif])
1329
1330 dnl checks for compiler characteristics
1331
1332 dnl Testing __STDC__ to determine prototype support isn't good enough.
1333 dnl DEC C, for instance, doesn't define it with default options, and
1334 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1335 dnl and void *.
1336 AC_C_PROTOTYPES
1337 AC_C_VOLATILE
1338 AC_C_CONST
1339 dnl This isn't useful because we can't turn on use of `inline' unless
1340 dnl the compiler groks `extern inline'.
1341 dnl AC_C_INLINE
1342 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1343   [AC_TRY_COMPILE(, [void * foo;],
1344                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1345 if test $emacs_cv_void_star = yes; then
1346   AC_DEFINE(POINTER_TYPE, void)
1347 else
1348   AC_DEFINE(POINTER_TYPE, char)
1349 fi
1350 AH_TEMPLATE(POINTER_TYPE,
1351             [Define as `void' if your compiler accepts `void *'; otherwise
1352              define as `char'.])dnl
1353
1354
1355
1356 dnl This could be used for targets which can have both byte sexes.
1357 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1358 dnl AC_C_BIGENDIAN
1359
1360 dnl check for Make feature
1361 AC_PROG_MAKE_SET
1362
1363 dnl checks for operating system services
1364 AC_SYS_LONG_FILE_NAMES
1365
1366 #### Choose a window system.
1367
1368 AC_PATH_X
1369 if test "$no_x" = yes; then
1370   window_system=none
1371 else
1372   window_system=x11
1373 fi
1374
1375 if test "${x_libraries}" != NONE; then
1376   if test -n "${x_libraries}"; then
1377     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1378     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1379   fi
1380   x_default_search_path=""
1381   x_search_path=${x_libraries}
1382   if test -z "${x_search_path}"; then
1383     x_search_path=/usr/lib
1384   fi
1385   for x_library in `echo ${x_search_path}: | \
1386                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1387     x_search_path="\
1388 ${x_library}/X11/%L/%T/%N%C%S:\
1389 ${x_library}/X11/%l/%T/%N%C%S:\
1390 ${x_library}/X11/%T/%N%C%S:\
1391 ${x_library}/X11/%L/%T/%N%S:\
1392 ${x_library}/X11/%l/%T/%N%S:\
1393 ${x_library}/X11/%T/%N%S"
1394     if test x"${x_default_search_path}" = x; then
1395       x_default_search_path=${x_search_path}
1396     else
1397       x_default_search_path="${x_search_path}:${x_default_search_path}"
1398     fi
1399   done
1400 fi
1401 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1402   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1403 fi
1404
1405 if test x"${x_includes}" = x; then
1406   bitmapdir=/usr/include/X11/bitmaps
1407 else
1408   # accumulate include directories that have X11 bitmap subdirectories
1409   bmd_acc="dummyval"
1410   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1411     if test -d "${bmd}/X11/bitmaps"; then
1412       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1413     fi
1414     if test -d "${bmd}/bitmaps"; then
1415       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1416     fi
1417   done
1418   if test ${bmd_acc} != "dummyval"; then
1419     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1420   fi
1421 fi
1422
1423 HAVE_CARBON=no
1424 if test "${with_carbon}" != no; then
1425   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1426 fi
1427 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1428   if test "${with_carbon+set}" != set \
1429      && test "${carbon_appdir_x+set}" != set; then
1430     for var in with_x with_x_toolkit with_xim \
1431                with_xpm with_jpeg with_tiff with_gif with_png; do
1432       if eval test \"\${$var+set}\" = set; then
1433         HAVE_CARBON=no
1434         break
1435       fi
1436     done
1437   fi
1438 fi
1439 if test "${HAVE_CARBON}" = yes; then
1440   window_system=mac
1441 fi
1442
1443 case "${window_system}" in
1444   x11 )
1445     HAVE_X_WINDOWS=yes
1446     HAVE_X11=yes
1447     case "${with_x_toolkit}" in
1448       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1449       motif ) USE_X_TOOLKIT=MOTIF ;;
1450       gtk ) with_gtk=yes
1451 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1452 dnl USE_X_TOOLKIT is set.
1453             USE_X_TOOLKIT=none ;;
1454       no ) USE_X_TOOLKIT=none ;;
1455 dnl If user did not say whether to use a toolkit, make this decision later:
1456 dnl use the toolkit if we have gtk, or X11R5 or newer.
1457       * ) USE_X_TOOLKIT=maybe ;;
1458     esac
1459   ;;
1460   mac | none )
1461     HAVE_X_WINDOWS=no
1462     HAVE_X11=no
1463     USE_X_TOOLKIT=none
1464   ;;
1465 esac
1466
1467 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1468    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1469    if test "$HAVE_XSERVER" = true ||
1470       test -n "$DISPLAY" ||
1471       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1472         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1473 were found.  You should install the relevant development files for X
1474 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1475 sure you have development files for image handling, i.e.
1476 tiff, gif, jpeg, png and xpm.
1477 If you are sure you want Emacs compiled without X window support, pass
1478   --without-x
1479 to configure.])
1480    fi
1481 fi
1482
1483 ### If we're using X11, we should use the X menu package.
1484 HAVE_MENUS=no
1485 case ${HAVE_X11} in
1486   yes ) HAVE_MENUS=yes ;;
1487 esac
1488
1489 ### Compute the unexec source name from the object name.
1490 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1491
1492 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1493 # Assume not, until told otherwise.
1494 GNU_MALLOC=yes
1495 doug_lea_malloc=yes
1496 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1497 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1498 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1499                emacs_cv_var___after_morecore_hook,
1500 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1501   emacs_cv_var___after_morecore_hook=yes,
1502   emacs_cv_var___after_morecore_hook=no)])
1503 if test $emacs_cv_var___after_morecore_hook = no; then
1504   doug_lea_malloc=no
1505 fi
1506 if test "${system_malloc}" = "yes"; then
1507   GNU_MALLOC=no
1508   GNU_MALLOC_reason="
1509     (The GNU allocators don't work with this system configuration.)"
1510 fi
1511 if test "$doug_lea_malloc" = "yes" ; then
1512   if test "$GNU_MALLOC" = yes ; then
1513     GNU_MALLOC_reason="
1514       (Using Doug Lea's new malloc from the GNU C Library.)"
1515   fi
1516   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1517             [Define to 1 if you are using the GNU C Library.])
1518 fi
1519
1520 if test x"${REL_ALLOC}" = x; then
1521   REL_ALLOC=${GNU_MALLOC}
1522 fi
1523
1524 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1525 dnl the system configuration file (s/*.h) to turn the use of mmap
1526 dnl in the relocating allocator on.
1527
1528 AC_FUNC_MMAP
1529 if test $use_mmap_for_buffers = yes; then
1530   REL_ALLOC=no
1531 fi
1532
1533 LIBS="$libsrc_libs $LIBS"
1534
1535 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1536 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1537 AC_CHECK_LIB(dnet, dnet_ntoa)
1538 dnl This causes -lresolv to get used in subsequent tests,
1539 dnl which causes failures on some systems such as HPUX 9.
1540 dnl AC_CHECK_LIB(resolv, gethostbyname)
1541
1542 dnl FIXME replace main with a function we actually want from this library.
1543 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1544
1545 AC_CHECK_LIB(pthreads, cma_open)
1546
1547 dnl Check for need for bigtoc support on IBM AIX
1548
1549 case ${host_os} in
1550 aix*)
1551   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1552     case $GCC in
1553     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1554     *) gdb_cv_bigtoc=-bbigtoc ;;
1555     esac
1556
1557     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1558     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1559   ])
1560   ;;
1561 esac
1562
1563 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1564 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1565 # REAL_CPPFLAGS later on.
1566
1567 REAL_CPPFLAGS="$CPPFLAGS"
1568
1569 if test "${HAVE_X11}" = "yes"; then
1570   DEFS="$C_SWITCH_X_SITE $DEFS"
1571   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1572   LIBS="$LIBX $LIBS"
1573   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1574   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1575
1576   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1577   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1578   # but it's more convenient here to set LD_RUN_PATH
1579   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1580   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1581     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1582     export LD_RUN_PATH
1583   fi
1584
1585   if test "${opsys}" = "gnu-linux"; then
1586     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1587     AC_TRY_LINK([],
1588      [XOpenDisplay ("foo");],
1589      [xlinux_first_failure=no],
1590      [xlinux_first_failure=yes])
1591     if test "${xlinux_first_failure}" = "yes"; then
1592       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1593       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1594       OLD_CPPFLAGS="$CPPFLAGS"
1595       OLD_LIBS="$LIBS"
1596       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1597       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1598       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1599       LIBS="$LIBS -b i486-linuxaout"
1600       AC_TRY_LINK([],
1601        [XOpenDisplay ("foo");],
1602        [xlinux_second_failure=no],
1603        [xlinux_second_failure=yes])
1604       if test "${xlinux_second_failure}" = "yes"; then
1605         # If we get the same failure with -b, there is no use adding -b.
1606         # So take it out.  This plays safe.
1607         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1608         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1609         CPPFLAGS="$OLD_CPPFLAGS"
1610         LIBS="$OLD_LIBS"
1611         AC_MSG_RESULT(no)
1612       else
1613         AC_MSG_RESULT(yes)
1614       fi
1615     else
1616       AC_MSG_RESULT(no)
1617     fi
1618   fi
1619
1620   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1621   # header files included from there.
1622   AC_MSG_CHECKING(for Xkb)
1623   AC_TRY_LINK([#include <X11/Xlib.h>
1624 #include <X11/XKBlib.h>],
1625         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1626         emacs_xkb=yes, emacs_xkb=no)
1627   AC_MSG_RESULT($emacs_xkb)
1628   if test $emacs_xkb = yes; then
1629     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1630   fi
1631
1632   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1633 XScreenNumberOfScreen XSetWMProtocols)
1634 fi
1635
1636 if test "${window_system}" = "x11"; then
1637   AC_MSG_CHECKING(X11 version 6)
1638   AC_CACHE_VAL(emacs_cv_x11_version_6,
1639   [AC_TRY_LINK([#include <X11/Xlib.h>],
1640 [#if XlibSpecificationRelease < 6
1641 fail;
1642 #endif
1643 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1644   if test $emacs_cv_x11_version_6 = yes; then
1645     AC_MSG_RESULT(6 or newer)
1646     AC_DEFINE(HAVE_X11R6, 1,
1647               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1648   else
1649     AC_MSG_RESULT(before 6)
1650   fi
1651 fi
1652
1653
1654 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1655 HAVE_RSVG=no
1656 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1657   if test "${with_rsvg}" != "no"; then
1658     RSVG_REQUIRED=2.0.0
1659     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1660
1661     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1662     AC_SUBST(RSVG_CFLAGS)
1663     AC_SUBST(RSVG_LIBS)
1664
1665     if test ".${RSVG_CFLAGS}" != "."; then
1666       HAVE_RSVG=yes
1667       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1668       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1669       LIBS="$RSVG_LIBS $LIBS"
1670     fi
1671   fi
1672 fi
1673
1674
1675 HAVE_GTK=no
1676 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1677   GLIB_REQUIRED=2.6
1678   GTK_REQUIRED=2.6
1679   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1680
1681   dnl Checks for libraries.
1682   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1683   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1684      AC_MSG_ERROR($GTK_PKG_ERRORS)
1685   fi
1686 fi
1687
1688
1689 if test x"$pkg_check_gtk" = xyes; then
1690
1691   AC_SUBST(GTK_CFLAGS)
1692   AC_SUBST(GTK_LIBS)
1693   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1694   CFLAGS="$CFLAGS $GTK_CFLAGS"
1695   LIBS="$GTK_LIBS $LIBS"
1696   dnl Try to compile a simple GTK program.
1697   GTK_COMPILES=no
1698   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1699   if test "${GTK_COMPILES}" != "yes"; then
1700     if test "$USE_X_TOOLKIT" != "maybe"; then
1701       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1702     fi
1703   else
1704     HAVE_GTK=yes
1705     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1706     USE_X_TOOLKIT=none
1707   fi
1708
1709 fi
1710
1711
1712 if test "${HAVE_GTK}" = "yes"; then
1713
1714   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1715   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1716   if test "$with_toolkit_scroll_bars" != no; then
1717     with_toolkit_scroll_bars=yes
1718   fi
1719
1720   dnl  Check if we can use multiple displays with this GTK version.
1721   dnl  If gdk_display_open exists, assume all others are there also.
1722   HAVE_GTK_MULTIDISPLAY=no
1723   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1724   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1725     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1726               [Define to 1 if GTK can handle more than one display.])
1727   fi
1728
1729   dnl  Check if we have the old file selection dialog.
1730   dnl  If gdk_display_open exists, assume all others are there also.
1731   HAVE_GTK_FILE_SELECTION=no
1732   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1733
1734   dnl  Check if we have the new file chooser dialog
1735   dnl  If gdk_display_open exists, assume all others are there also.
1736   HAVE_GTK_FILE_CHOOSER=no
1737   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1738
1739   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1740      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1741     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1742               [Define to 1 if GTK has both file selection and chooser dialog.])
1743   fi
1744
1745   dnl Check if pthreads are available.  Emacs only needs this when using
1746   dnl gtk_file_chooser under Gnome.
1747   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1748     HAVE_GTK_AND_PTHREAD=no
1749     AC_CHECK_HEADERS(pthread.h)
1750     if test "$ac_cv_header_pthread_h"; then
1751       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1752     fi
1753     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1754       case "${canonical}" in
1755         *-hpux*) ;;
1756         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1757       esac
1758       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1759                [Define to 1 if you have GTK and pthread (-lpthread).])
1760     fi
1761   fi
1762 fi
1763
1764 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1765 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1766 dnl also not configured.
1767 HAVE_DBUS=no
1768 if test "${with_dbus}" = "yes"; then
1769    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1770    if test "$HAVE_DBUS" = yes; then
1771       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1772    fi
1773 fi
1774
1775 dnl Do not put whitespace before the #include statements below.
1776 dnl Older compilers (eg sunos4 cc) choke on it.
1777 HAVE_XAW3D=no
1778 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1779   if test "$with_xaw3d" != no; then
1780     AC_MSG_CHECKING(for xaw3d)
1781     AC_CACHE_VAL(emacs_cv_xaw3d,
1782     [AC_TRY_LINK([
1783 #include <X11/Intrinsic.h>
1784 #include <X11/Xaw3d/Simple.h>],
1785       [],
1786       emacs_cv_xaw3d=yes,
1787       emacs_cv_xaw3d=no)])
1788   else
1789     emacs_cv_xaw3d=no
1790   fi
1791   if test $emacs_cv_xaw3d = yes; then
1792     AC_MSG_RESULT([yes; using Lucid toolkit])
1793     USE_X_TOOLKIT=LUCID
1794     HAVE_XAW3D=yes
1795     AC_DEFINE(HAVE_XAW3D, 1,
1796               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1797   else
1798     AC_MSG_RESULT(no)
1799     AC_MSG_CHECKING(for libXaw)
1800     AC_CACHE_VAL(emacs_cv_xaw,
1801     [AC_TRY_LINK([
1802 #include <X11/Intrinsic.h>
1803 #include <X11/Xaw/Simple.h>],
1804       [],
1805       emacs_cv_xaw=yes,
1806       emacs_cv_xaw=no)])
1807     if test $emacs_cv_xaw = yes; then
1808       AC_MSG_RESULT([yes; using Lucid toolkit])
1809       USE_X_TOOLKIT=LUCID
1810     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1811       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1812     else
1813       AC_MSG_RESULT([no; do not use toolkit by default])
1814       USE_X_TOOLKIT=none
1815     fi
1816   fi
1817 fi
1818
1819 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1820
1821 if test "${USE_X_TOOLKIT}" != "none"; then
1822   AC_MSG_CHECKING(X11 toolkit version)
1823   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1824   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1825 [#if XtSpecificationRelease < 6
1826 fail;
1827 #endif
1828 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1829   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1830   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1831     AC_MSG_RESULT(6 or newer)
1832     AC_DEFINE(HAVE_X11XTR6, 1,
1833               [Define to 1 if you have the X11R6 or newer version of Xt.])
1834   else
1835     AC_MSG_RESULT(before 6)
1836   fi
1837
1838 dnl If using toolkit, check whether libXmu.a exists.
1839 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1840   OLDLIBS="$LIBS"
1841   if test x$HAVE_X11XTR6 = xyes; then
1842     LIBS="-lXt -lSM -lICE $LIBS"
1843   else
1844     LIBS="-lXt $LIBS"
1845   fi
1846   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1847   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1848 fi
1849
1850 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1851 if test "${HAVE_X11}" = "yes"; then
1852   if test "${USE_X_TOOLKIT}" != "none"; then
1853     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1854   fi
1855 fi
1856
1857 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1858   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1859   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1860     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1861 int x = 5;
1862 #else
1863 Motif version prior to 2.1.
1864 #endif],
1865     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1866   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1867   if test $emacs_cv_motif_version_2_1 = yes; then
1868     HAVE_LIBXP=no
1869     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1870               [Define to 1 if you have Motif 2.1 or newer.])
1871     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1872     if test ${HAVE_LIBXP} = yes; then
1873       AC_DEFINE(HAVE_LIBXP, 1,
1874                 [Define to 1 if you have the Xp library (-lXp).])
1875     fi
1876   else
1877     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1878     # We put this in CFLAGS temporarily to precede other -I options
1879     # that might be in CFLAGS temporarily.
1880     # We put this in CPPFLAGS where it precedes the other -I options.
1881     OLD_CPPFLAGS=$CPPFLAGS
1882     OLD_CFLAGS=$CFLAGS
1883     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1884     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1885     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1886       [int x = 5;],
1887       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1888     if test $emacs_cv_lesstif = yes; then
1889       # Make sure this -I option remains in CPPFLAGS after it is set
1890       # back to REAL_CPPFLAGS.
1891       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1892       # have those other -I options anyway.  Ultimately, having this
1893       # directory ultimately in CPPFLAGS will be enough.
1894       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1895       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1896     else
1897       CFLAGS=$OLD_CFLAGS
1898       CPPFLAGS=$OLD_CPPFLAGS
1899     fi
1900   fi
1901 fi
1902
1903 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1904 dnl using Motif or Xaw3d is available, and unless
1905 dnl --with-toolkit-scroll-bars=no was specified.
1906
1907 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1908             [Define to 1 if we should use toolkit scroll bars.])dnl
1909 USE_TOOLKIT_SCROLL_BARS=no
1910 if test "${with_toolkit_scroll_bars}" != "no"; then
1911   if test "${USE_X_TOOLKIT}" != "none"; then
1912     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1913       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1914       HAVE_XAW3D=no
1915       USE_TOOLKIT_SCROLL_BARS=yes
1916     elif test "${HAVE_XAW3D}" = "yes"; then
1917       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1918       USE_TOOLKIT_SCROLL_BARS=yes
1919     fi
1920   elif test "${HAVE_GTK}" = "yes"; then
1921     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1922     USE_TOOLKIT_SCROLL_BARS=yes
1923   elif test "${HAVE_CARBON}" = "yes"; then
1924     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1925     USE_TOOLKIT_SCROLL_BARS=yes
1926   fi
1927 fi
1928
1929 dnl See if XIM is available.
1930 AC_TRY_COMPILE([
1931           #include <X11/Xlib.h>
1932           #include <X11/Xresource.h>],
1933          [XIMProc  callback;],
1934          [HAVE_XIM=yes
1935          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1936          HAVE_XIM=no)
1937
1938 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1939
1940 if test "${with_xim}" != "no"; then
1941   AC_DEFINE(USE_XIM, 1,
1942             [Define to 1 if we should use XIM, if it is available.])
1943 fi
1944
1945
1946 if test "${HAVE_XIM}" != "no"; then
1947   late_CFLAGS=$CFLAGS
1948   if test "$GCC" = yes; then
1949     CFLAGS="$CFLAGS --pedantic-errors"
1950   fi
1951   AC_TRY_COMPILE([
1952 #include <X11/Xlib.h>
1953 #include <X11/Xresource.h>],
1954 [Display *display;
1955 XrmDatabase db;
1956 char *res_name;
1957 char *res_class;
1958 XIMProc  callback;
1959 XPointer *client_data;
1960 #ifndef __GNUC__
1961 /* If we're not using GCC, it's probably not XFree86, and this is
1962    probably right, but we can't use something like --pedantic-errors.  */
1963 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1964                                            char*, XIMProc, XPointer*);
1965 #endif
1966 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1967    client_data);],
1968     [emacs_cv_arg6_star=yes])
1969   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1970          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1971 either XPointer or XPointer*.])dnl
1972   if test "$emacs_cv_arg6_star" = yes; then
1973     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1974   else
1975     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1976   fi
1977   CFLAGS=$late_CFLAGS
1978 fi
1979
1980 #### For font-backend
1981 if test "${USE_FONT_BACKEND}" = "yes"; then
1982
1983 AC_DEFINE(USE_FONT_BACKEND, 1,
1984           [Define to 1 if we should use font-backend.])
1985
1986 ### Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1987 HAVE_XFT=maybe
1988 if test "${HAVE_X11}" = "yes"; then
1989   if test "x${with_freetype}" = "xno"; then
1990     with_xft="no";
1991   fi
1992   if test "x${with_xft}" != "xno"; then
1993
1994     dnl Check if --with-pkg-config-prog has been given.
1995     if test "X${with_pkg_config_prog}" != X; then
1996       PKG_CONFIG="${with_pkg_config_prog}"
1997     fi
1998
1999     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2000     if test "$HAVE_XFT" != no; then
2001       OLD_CPPFLAGS="$CPPFLAGS"
2002       OLD_CFLAGS="$CFLAGS"
2003       OLD_LIBS="$LIBS"
2004       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2005       CFLAGS="$CFLAGS $XFT_CFLAGS"
2006       LIBS="$XFT_LIBS $LIBS"
2007       AC_CHECK_HEADER(X11/Xft/Xft.h,
2008         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2009
2010       if test "${HAVE_XFT}" = "yes"; then
2011         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2012         AC_SUBST(XFT_LIBS)
2013         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2014       else
2015         CPPFLAGS="$OLD_CPPFLAGS"
2016         CFLAGS="$OLD_CFLAGS"
2017         LIBS="$OLD_LIBS"
2018       fi
2019     fi
2020   fi
2021 fi
2022 dnl For the "Does Emacs use" message at the end.
2023 if test "$HAVE_XFT" != "yes"; then
2024    HAVE_XFT=no
2025 fi
2026
2027
2028 HAVE_FREETYPE=no
2029 ### Use -lfreetype if available, unless `--with-freetype=no'.
2030 if test "${HAVE_XFT}" = "yes"; then
2031   dnl As we use Xft, we anyway use freetype.
2032   dnl In this case, there's no need of additional CFLAGS and LIBS.
2033   HAVE_FREETYPE=yes
2034 elif test "x${with_freetype}" != "xno"; then
2035   dnl Check if --with-pkg-config-prog has been given.
2036   if test "X${with_pkg_config_prog}" != X; then
2037     PKG_CONFIG="${with_pkg_config_prog}"
2038   fi
2039
2040   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2041   if test "${HAVE_FREETYPE}" = "yes"; then
2042     PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2043     if test "${HAVE_FC}" = "no"; then
2044       dnl Witout fontconfig, we can't use freetype at the moment.
2045       HAVE_FREETYPE=no
2046     fi
2047   fi
2048 fi
2049
2050 HAVE_LIBOTF=no
2051 if test "${HAVE_FREETYPE}" = "yes"; then
2052   AC_DEFINE(HAVE_FREETYPE, 1,
2053             [Define to 1 if you have freetype and fontconfig libraries.])
2054   if test "${with_libotf}" != "no"; then
2055     dnl Check if --with-pkg-config-prog has been given.
2056     if test "X${with_pkg_config_prog}" != X; then
2057       PKG_CONFIG="${with_pkg_config_prog}"
2058     fi
2059     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2060                       HAVE_LIBOTF=no)
2061     if test "$HAVE_LIBOTF" = "yes"; then
2062       AC_DEFINE(HAVE_LIBOTF, 1,
2063                 [Define to 1 if you have libotf library.])
2064     fi
2065   fi
2066 fi
2067
2068 HAVE_M17N_FLT=no
2069 if test "${with_m17n_flt}" != "no"; then
2070   dnl Check if --with-pkg-config-prog has been given.
2071   if test "X${with_pkg_config_prog}" != X; then
2072     PKG_CONFIG="${with_pkg_config_prog}"
2073   fi
2074   dnl Checks for libraries.
2075   PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes,
2076                     HAVE_M17N_FLT=no)
2077   if test "$HAVE_M17N_FLT" = "yes"; then
2078     AC_DEFINE(HAVE_M17N_FLT, 1,
2079               [Define to 1 if you have m17n-flt library.])
2080   fi
2081 fi
2082
2083 AC_SUBST(FREETYPE_CFLAGS)
2084 AC_SUBST(FREETYPE_LIBS)
2085 AC_SUBST(FONTCONFIG_CFLAGS)
2086 AC_SUBST(FONTCONFIG_LIBS)
2087 AC_SUBST(LIBOTF_CFLAGS)
2088 AC_SUBST(LIBOTF_LIBS)
2089 AC_SUBST(M17N_FLT_CFLAGS)
2090 AC_SUBST(M17N_FLT_LIBS)
2091
2092 fi
2093 #### End for font-backend
2094
2095 ### Use -lXpm if available, unless `--with-xpm=no'.
2096 HAVE_XPM=no
2097 if test "${HAVE_X11}" = "yes"; then
2098   if test "${with_xpm}" != "no"; then
2099     AC_CHECK_HEADER(X11/xpm.h,
2100       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2101     if test "${HAVE_XPM}" = "yes"; then
2102       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2103       AC_EGREP_CPP(no_return_alloc_pixels,
2104       [#include "X11/xpm.h"
2105 #ifndef XpmReturnAllocPixels
2106 no_return_alloc_pixels
2107 #endif
2108       ], HAVE_XPM=no, HAVE_XPM=yes)
2109
2110       if test "${HAVE_XPM}" = "yes"; then
2111         AC_MSG_RESULT(yes)
2112       else
2113         AC_MSG_RESULT(no)
2114       fi
2115     fi
2116   fi
2117
2118   if test "${HAVE_XPM}" = "yes"; then
2119     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2120   fi
2121 fi
2122
2123 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2124 HAVE_JPEG=no
2125 if test "${HAVE_X11}" = "yes"; then
2126   if test "${with_jpeg}" != "no"; then
2127     dnl Checking for jpeglib.h can lose because of a redefinition of
2128     dnl  HAVE_STDLIB_H.
2129     AC_CHECK_HEADER(jerror.h,
2130       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2131   fi
2132
2133   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2134   if test "${HAVE_JPEG}" = "yes"; then
2135     AC_DEFINE(HAVE_JPEG)
2136     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2137         [#include <jpeglib.h>
2138          version=JPEG_LIB_VERSION
2139 ],
2140         [AC_DEFINE(HAVE_JPEG)],
2141         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2142         HAVE_JPEG=no])
2143   fi
2144 fi
2145
2146 ### Use -lpng if available, unless `--with-png=no'.
2147 HAVE_PNG=no
2148 if test "${HAVE_X11}" = "yes"; then
2149   if test "${with_png}" != "no"; then
2150     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2151     # in /usr/include/libpng.
2152     AC_CHECK_HEADERS(png.h libpng/png.h)
2153     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2154       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2155     fi
2156   fi
2157
2158   if test "${HAVE_PNG}" = "yes"; then
2159     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2160   fi
2161 fi
2162
2163 ### Use -ltiff if available, unless `--with-tiff=no'.
2164 HAVE_TIFF=no
2165 if test "${HAVE_X11}" = "yes"; then
2166   if test "${with_tiff}" != "no"; then
2167     AC_CHECK_HEADER(tiffio.h,
2168       [tifflibs="-lz -lm"
2169       # At least one tiff package requires the jpeg library.
2170       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2171       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2172   fi
2173
2174   if test "${HAVE_TIFF}" = "yes"; then
2175     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2176   fi
2177 fi
2178
2179 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2180 HAVE_GIF=no
2181 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2182   AC_CHECK_HEADER(gif_lib.h,
2183 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2184 # Earlier versions can crash Emacs.
2185     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2186
2187   if test "$HAVE_GIF" = yes; then
2188       ac_gif_lib_name="-lgif"
2189   fi
2190
2191 # If gif_lib.h but no libgif, try libungif.
2192   if test x"$try_libungif" = xyes; then
2193     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2194
2195     if test "$HAVE_GIF" = yes; then
2196       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2197       ac_gif_lib_name="-lungif"
2198     fi
2199   fi
2200
2201   if test "${HAVE_GIF}" = "yes"; then
2202     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2203   fi
2204 fi
2205
2206 dnl Check for required libraries.
2207 if test "${HAVE_X11}" = "yes"; then
2208   MISSING=""
2209   WITH_NO=""
2210   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2211     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2212   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2213     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2214   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2215     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2216   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2217     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2218   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2219     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2220
2221   if test "X${MISSING}" != X; then
2222     AC_MSG_ERROR([The following required libraries were not found:
2223     $MISSING
2224 Maybe some development libraries/packages are missing?
2225 If you don't want to link with them give
2226     $WITH_NO
2227 as options to configure])
2228   fi
2229 fi
2230
2231 ### Use -lgpm if available, unless `--with-gpm=no'.
2232 HAVE_GPM=no
2233 if test "${with_gpm}" != "no"; then
2234   AC_CHECK_HEADER(gpm.h,
2235     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2236 fi
2237
2238 if test "${HAVE_GPM}" = "yes"; then
2239   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2240 fi
2241
2242 dnl Check for malloc/malloc.h on darwin
2243 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2244
2245 ### Use Mac OS X Carbon API to implement GUI.
2246 if test "${HAVE_CARBON}" = "yes"; then
2247   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2248   ## Specify the install directory
2249   carbon_appdir=
2250   if test "${carbon_appdir_x}" != ""; then
2251     case ${carbon_appdir_x} in
2252       y | ye | yes)  carbon_appdir=/Applications ;;
2253       * ) carbon_appdir=${carbon_appdir_x} ;;
2254     esac
2255   fi
2256   # We also have mouse menus.
2257   HAVE_MENUS=yes
2258 fi
2259
2260 ### Use session management (-lSM -lICE) if available
2261 HAVE_X_SM=no
2262 if test "${HAVE_X11}" = "yes"; then
2263   AC_CHECK_HEADER(X11/SM/SMlib.h,
2264     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2265
2266   if test "${HAVE_X_SM}" = "yes"; then
2267     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2268     case "$LIBS" in
2269       *-lSM*) ;;
2270       *)      LIBS="-lSM -lICE $LIBS" ;;
2271     esac
2272   fi
2273 fi
2274
2275 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2276 AC_CACHE_CHECK(whether netdb declares h_errno,
2277                emacs_cv_netdb_declares_h_errno,
2278 [AC_TRY_LINK([#include <netdb.h>],
2279   [return h_errno;],
2280   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2281 if test $emacs_cv_netdb_declares_h_errno = yes; then
2282   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2283 fi
2284
2285 AC_FUNC_ALLOCA
2286
2287 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2288 dnl FIXME is there an autoconf test that does the right thing, without
2289 dnl needing to call A_M_E afterwards?
2290 if test x"$ac_cv_func_alloca_works" != xyes; then
2291    AC_MSG_ERROR( [a system implementation of alloca is required] )
2292 fi
2293
2294 # fmod, logb, and frexp are found in -lm on most systems.
2295 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2296 AC_CHECK_LIB(m, sqrt)
2297
2298 # Check for mail-locking functions in a "mail" library.  Probably this should
2299 # have the same check as for liblockfile below.
2300 AC_CHECK_LIB(mail, maillock)
2301 dnl Debian, at least:
2302 AC_CHECK_LIB(lockfile, maillock)
2303 # If we have the shared liblockfile, assume we must use it for mail
2304 # locking (e.g. Debian).  If we couldn't link against liblockfile
2305 # (no liblockfile.a installed), ensure that we don't need to.
2306 if test "$ac_cv_lib_lockfile_maillock" = no; then
2307   dnl This works for files generally, not just executables.
2308   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2309   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2310                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2311   if test $ac_cv_prog_liblockfile = yes; then
2312     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2313 This probably means that movemail could lose mail.
2314 There may be a `development' package to install containing liblockfile.])
2315   else :
2316   fi
2317 fi
2318 AC_CHECK_FUNCS(touchlock)
2319 AC_CHECK_HEADERS(maillock.h)
2320
2321 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2322 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2323 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2324 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2325 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2326 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2327 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2328 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2329 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2330
2331 AC_CHECK_HEADERS(sys/un.h)
2332
2333 AC_FUNC_MKTIME
2334 if test "$ac_cv_func_working_mktime" = no; then
2335   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2336 fi
2337
2338 AC_FUNC_GETLOADAVG
2339
2340 AC_FUNC_FSEEKO
2341
2342 # Configure getopt.
2343 m4_include([m4/getopt.m4])
2344 gl_GETOPT_IFELSE([
2345   gl_GETOPT_SUBSTITUTE_HEADER
2346   gl_PREREQ_GETOPT
2347   GETOPTOBJS='getopt.o getopt1.o'
2348 ])
2349 AC_SUBST(GETOPTOBJS)
2350
2351 AC_FUNC_GETPGRP
2352
2353 AC_FUNC_STRFTIME
2354
2355 # UNIX98 PTYs.
2356 AC_CHECK_FUNCS(grantpt)
2357
2358 # PTY-related GNU extensions.
2359 AC_CHECK_FUNCS(getpt)
2360
2361 # Check this now, so that we will NOT find the above functions in ncurses.
2362 # That is because we have not set up to link ncurses in lib-src.
2363 # It's better to believe a function is not available
2364 # than to expect to find it in ncurses.
2365 AC_CHECK_LIB(ncurses, tparm)
2366
2367 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2368
2369 resolv=no
2370 AC_TRY_LINK([#include <netinet/in.h>
2371 #include <arpa/nameser.h>
2372 #include <resolv.h>],
2373     [return res_init();],
2374     have_res_init=yes, have_res_init=no)
2375 if test "$have_res_init" = no; then
2376   OLIBS="$LIBS"
2377   LIBS="$LIBS -lresolv"
2378   AC_MSG_CHECKING(for res_init with -lresolv)
2379   AC_TRY_LINK([#include <netinet/in.h>
2380 #include <arpa/nameser.h>
2381 #include <resolv.h>],
2382     [return res_init();],
2383     have_res_init=yes, have_res_init=no)
2384   AC_MSG_RESULT($have_res_init)
2385   if test "$have_res_init" = yes ; then
2386     resolv=yes
2387   fi
2388   LIBS="$OLIBS"
2389 fi
2390
2391 if test "$have_res_init" = yes; then
2392   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2393 fi
2394
2395 # Do we need the Hesiod library to provide the support routines?
2396 if test "$with_hesiod" = yes ; then
2397   # Don't set $LIBS here -- see comments above.
2398   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2399      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2400                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2401   if test "$resolv" = yes ; then
2402     RESOLVLIB=-lresolv
2403   else
2404     RESOLVLIB=
2405   fi
2406   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2407         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2408                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2409         :, $RESOLVLIB)])
2410 fi
2411
2412 # Do we need libresolv (due to res_init or Hesiod)?
2413 if test "$resolv" = yes ; then
2414   AC_DEFINE(HAVE_LIBRESOLV, 1,
2415             [Define to 1 if you have the resolv library (-lresolv).])
2416 fi
2417
2418 # These tell us which Kerberos-related libraries to use.
2419 if test "${with_kerberos+set}" = set; then
2420   AC_CHECK_LIB(com_err, com_err)
2421   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2422   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2423   AC_CHECK_LIB(krb5, krb5_init_context)
2424   if test "${with_kerberos5+set}" != set; then
2425     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2426                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2427     AC_CHECK_LIB(krb4, krb_get_cred,,
2428                  [AC_CHECK_LIB(krb, krb_get_cred)])
2429   fi
2430
2431   if test "${with_kerberos5+set}" = set; then
2432     AC_CHECK_HEADERS(krb5.h)
2433   else
2434     AC_CHECK_HEADERS(des.h,,
2435                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2436                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2437     AC_CHECK_HEADERS(krb.h,,
2438                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2439                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2440   fi
2441   AC_CHECK_HEADERS(com_err.h)
2442 fi
2443
2444 # Solaris requires -lintl if you want strerror (which calls dgettext)
2445 # to return localized messages.
2446 AC_CHECK_LIB(intl, dgettext)
2447
2448 AC_MSG_CHECKING(whether localtime caches TZ)
2449 AC_CACHE_VAL(emacs_cv_localtime_cache,
2450 [if test x$ac_cv_func_tzset = xyes; then
2451 AC_TRY_RUN([#include <time.h>
2452 extern char **environ;
2453 unset_TZ ()
2454 {
2455   char **from, **to;
2456   for (to = from = environ; (*to = *from); from++)
2457     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2458       to++;
2459 }
2460 char TZ_GMT0[] = "TZ=GMT0";
2461 char TZ_PST8[] = "TZ=PST8";
2462 main()
2463 {
2464   time_t now = time ((time_t *) 0);
2465   int hour_GMT0, hour_unset;
2466   if (putenv (TZ_GMT0) != 0)
2467     exit (1);
2468   hour_GMT0 = localtime (&now)->tm_hour;
2469   unset_TZ ();
2470   hour_unset = localtime (&now)->tm_hour;
2471   if (putenv (TZ_PST8) != 0)
2472     exit (1);
2473   if (localtime (&now)->tm_hour == hour_GMT0)
2474     exit (1);
2475   unset_TZ ();
2476   if (localtime (&now)->tm_hour != hour_unset)
2477     exit (1);
2478   exit (0);
2479 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2480 [# If we have tzset, assume the worst when cross-compiling.
2481 emacs_cv_localtime_cache=yes])
2482 else
2483         # If we lack tzset, report that localtime does not cache TZ,
2484         # since we can't invalidate the cache if we don't have tzset.
2485         emacs_cv_localtime_cache=no
2486 fi])dnl
2487 AC_MSG_RESULT($emacs_cv_localtime_cache)
2488 if test $emacs_cv_localtime_cache = yes; then
2489   AC_DEFINE(LOCALTIME_CACHE, 1,
2490             [Define to 1 if localtime caches TZ.])
2491 fi
2492
2493 if test "x$HAVE_TIMEVAL" = xyes; then
2494   AC_CHECK_FUNCS(gettimeofday)
2495   if test $ac_cv_func_gettimeofday = yes; then
2496     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2497                    emacs_cv_gettimeofday_two_arguments,
2498     [AC_TRY_COMPILE([
2499 #ifdef TIME_WITH_SYS_TIME
2500 #include <sys/time.h>
2501 #include <time.h>
2502 #else
2503 #ifdef HAVE_SYS_TIME_H
2504 #include <sys/time.h>
2505 #else
2506 #include <time.h>
2507 #endif
2508 #endif],
2509       [struct timeval time;
2510        gettimeofday (&time, 0);],
2511       emacs_cv_gettimeofday_two_arguments=yes,
2512       emacs_cv_gettimeofday_two_arguments=no)])
2513     if test $emacs_cv_gettimeofday_two_arguments = no; then
2514       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2515                 [Define to 1 if gettimeofday accepts only one argument.])
2516     fi
2517   fi
2518 fi
2519
2520 ok_so_far=yes
2521 AC_CHECK_FUNC(socket, , ok_so_far=no)
2522 if test $ok_so_far = yes; then
2523   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2524 fi
2525 if test $ok_so_far = yes; then
2526   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2527 fi
2528 if test $ok_so_far = yes; then
2529 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2530   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2531             [Define to 1 if you have inet sockets.])
2532 fi
2533
2534 AC_CHECK_HEADERS(sys/ioctl.h)
2535
2536 if test -f /usr/lpp/X11/bin/smt.exp; then
2537   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2538             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2539 fi
2540
2541 AC_MSG_CHECKING(whether system supports dynamic ptys)
2542 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2543   AC_MSG_RESULT(yes)
2544   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2545 else
2546   AC_MSG_RESULT(no)
2547 fi
2548
2549 AC_FUNC_FORK
2550
2551 dnl Adapted from Haible's version.
2552 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2553   [AC_TRY_LINK([#include <langinfo.h>],
2554     [char* cs = nl_langinfo(CODESET);],
2555     emacs_cv_langinfo_codeset=yes,
2556     emacs_cv_langinfo_codeset=no)
2557   ])
2558 if test $emacs_cv_langinfo_codeset = yes; then
2559   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2560     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2561 fi
2562
2563 AC_CHECK_TYPES(size_t)
2564
2565 AC_TYPE_MBSTATE_T
2566
2567 dnl Restrict could probably be used effectively other than in regex.c.
2568 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2569   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2570                   emacs_cv_c_restrict=yes,
2571                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2572                                   emacs_cv_c_restrict=__restrict,
2573                                   emacs_cv_c_restrict=no)])])
2574 case "$emacs_cv_c_restrict" in
2575   yes) emacs_restrict=restrict;;
2576   no) emacs_restrict="";;
2577   *) emacs_restrict="$emacs_cv_c_restrict";;
2578 esac
2579 if test "$emacs_restrict" != __restrict; then
2580   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2581     [Define to compiler's equivalent of C99 restrict keyword.
2582      Don't define if equivalent is `__restrict'.])
2583 fi
2584
2585 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2586   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2587                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2588 if test "$emacs_cv_c_restrict_arr" = yes; then
2589   AC_DEFINE(__restrict_arr, __restrict,
2590     [Define to compiler's equivalent of C99 restrict keyword in array
2591      declarations.  Define as empty for no equivalent.])
2592 fi
2593
2594 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2595 dnl how the tty code is related to POSIX and/or other versions of termios.
2596 dnl The following looks like a useful start.
2597 dnl
2598 dnl AC_SYS_POSIX_TERMIOS
2599 dnl if test $ac_cv_sys_posix_termios = yes; then
2600 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2601 dnl                                and macros for terminal control.])
2602 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2603 dnl fi
2604
2605 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2606
2607 # Set up the CFLAGS for real compilation, so we can substitute it.
2608 CFLAGS="$REAL_CFLAGS"
2609 CPPFLAGS="$REAL_CPPFLAGS"
2610
2611 #### Find out which version of Emacs this is.
2612 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2613          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2614 if test x"${version}" = x; then
2615   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2616 fi
2617
2618 ### Specify what sort of things we'll be editing into Makefile and config.h.
2619 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2620 AC_SUBST(version)
2621 AC_SUBST(configuration)
2622 AC_SUBST(canonical)
2623 AC_SUBST(srcdir)
2624 AC_SUBST(prefix)
2625 AC_SUBST(exec_prefix)
2626 AC_SUBST(bindir)
2627 AC_SUBST(datadir)
2628 AC_SUBST(sharedstatedir)
2629 AC_SUBST(libexecdir)
2630 AC_SUBST(mandir)
2631 AC_SUBST(infodir)
2632 AC_SUBST(lispdir)
2633 AC_SUBST(locallisppath)
2634 AC_SUBST(lisppath)
2635 AC_SUBST(x_default_search_path)
2636 AC_SUBST(etcdir)
2637 AC_SUBST(archlibdir)
2638 AC_SUBST(docdir)
2639 AC_SUBST(bitmapdir)
2640 AC_SUBST(gamedir)
2641 AC_SUBST(gameuser)
2642 AC_SUBST(c_switch_system)
2643 AC_SUBST(c_switch_machine)
2644 AC_SUBST(LD_SWITCH_X_SITE)
2645 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2646 AC_SUBST(C_SWITCH_X_SITE)
2647 AC_SUBST(CFLAGS)
2648 AC_SUBST(X_TOOLKIT_TYPE)
2649 AC_SUBST(machfile)
2650 AC_SUBST(opsysfile)
2651 AC_SUBST(GETLOADAVG_LIBS)
2652 AC_SUBST(carbon_appdir)
2653
2654 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2655                    [Define to the canonical Emacs configuration name.])
2656 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2657                    [Define to the options passed to configure.])
2658 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2659                    [Define to the used machine dependent file.])
2660 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2661                    [Define to the used os dependent file.])
2662 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2663 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2664  may need to deal with X Windows.  For instance, if you've defined
2665  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2666  your loader can find on its own, you might want to add "-L/..." or
2667  something similar.])
2668 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2669                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2670                     in case it's needed (for Solaris, for example).])
2671 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2672 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2673  may need to deal with X Windows.  For instance, if you've defined
2674  HAVE_X_WINDOWS above and your X include files aren't in a place
2675  that your compiler can find on its own, you might want to add
2676  "-I/..." or something similar.])
2677 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2678                    [Define to the unexec source file name.])
2679
2680 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2681   AC_DEFINE(HAVE_X_WINDOWS, 1,
2682             [Define to 1 if you want to use the X window system.])
2683 fi
2684 if test "${USE_X_TOOLKIT}" != "none" ; then
2685   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2686 fi
2687 if test "${HAVE_X11}" = "yes" ; then
2688   AC_DEFINE(HAVE_X11, 1,
2689             [Define to 1 if you want to use version 11 of X windows.
2690              Otherwise, Emacs expects to use version 10.])
2691 fi
2692 if test "${HAVE_MENUS}" = "yes" ; then
2693   AC_DEFINE(HAVE_MENUS, 1,
2694             [Define to 1 if you have mouse menus.
2695              (This is automatic if you use X, but the option to specify it remains.)
2696              It is also defined with other window systems that support xmenu.c.])
2697 fi
2698 if test "${GNU_MALLOC}" = "yes" ; then
2699   AC_DEFINE(GNU_MALLOC, 1,
2700             [Define to 1 if you want to use the GNU memory allocator.])
2701 fi
2702 if test "${REL_ALLOC}" = "yes" ; then
2703   AC_DEFINE(REL_ALLOC, 1,
2704             [Define REL_ALLOC if you want to use the relocating allocator for
2705              buffer space.])
2706 fi
2707
2708
2709 AH_TOP([/* GNU Emacs site configuration template file.
2710    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2711      2006, 2007, 2008  Free Software Foundation, Inc.
2712
2713 This file is part of GNU Emacs.
2714
2715 GNU Emacs is free software; you can redistribute it and/or modify
2716 it under the terms of the GNU General Public License as published by
2717 the Free Software Foundation; either version 3, or (at your option)
2718 any later version.
2719
2720 GNU Emacs is distributed in the hope that it will be useful,
2721 but WITHOUT ANY WARRANTY; without even the implied warranty of
2722 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2723 GNU General Public License for more details.
2724
2725 You should have received a copy of the GNU General Public License
2726 along with GNU Emacs; see the file COPYING.  If not, write to the
2727 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2728 Boston, MA 02110-1301, USA.  */
2729
2730
2731 /* No code in Emacs #includes config.h twice, but some bits of code
2732    intended to work with other packages as well (like gmalloc.c)
2733    think they can include it as many times as they like.  */
2734 #ifndef EMACS_CONFIG_H
2735 #define EMACS_CONFIG_H
2736 ])dnl
2737
2738 AH_BOTTOM([
2739 /* If we're using any sort of window system, define some consequences.  */
2740 #ifdef HAVE_X_WINDOWS
2741 #define HAVE_WINDOW_SYSTEM
2742 #define MULTI_KBOARD
2743 #define HAVE_MOUSE
2744 #endif
2745
2746 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2747    on unconditionally. */
2748 #ifndef MULTI_KBOARD
2749 #define MULTI_KBOARD
2750 #endif
2751
2752 /* If we're using the Carbon API on Mac OS X, define a few more
2753    variables as well.  */
2754 #ifdef HAVE_CARBON
2755 #define HAVE_WINDOW_SYSTEM
2756 #define HAVE_MOUSE
2757 #endif
2758
2759 /* Define USER_FULL_NAME to return a string
2760    that is the user's full name.
2761    It can assume that the variable `pw'
2762    points to the password file entry for this user.
2763
2764    At some sites, the pw_gecos field contains
2765    the user's full name.  If neither this nor any other
2766    field contains the right thing, use pw_name,
2767    giving the user's login name, since that is better than nothing.  */
2768 #define USER_FULL_NAME pw->pw_gecos
2769
2770 /* Define AMPERSAND_FULL_NAME if you use the convention
2771    that & in the full name stands for the login id.  */
2772 /* Turned on June 1996 supposing nobody will mind it.  */
2773 #define AMPERSAND_FULL_NAME
2774
2775 /* We have blockinput.h.  */
2776 #define DO_BLOCK_INPUT
2777
2778 /* Define HAVE_SOUND if we have sound support.  We know it works
2779    and compiles only on the specified platforms.   For others,
2780    it probably doesn't make sense to try.  */
2781
2782 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2783 #ifdef HAVE_MACHINE_SOUNDCARD_H
2784 #define HAVE_SOUND 1
2785 #endif
2786 #ifdef HAVE_SYS_SOUNDCARD_H
2787 #define HAVE_SOUND 1
2788 #endif
2789 #ifdef HAVE_SOUNDCARD_H
2790 #define HAVE_SOUND 1
2791 #endif
2792 #ifdef HAVE_ALSA
2793 #define HAVE_SOUND 1
2794 #endif
2795 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2796
2797 /* If using GNU, then support inline function declarations. */
2798 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2799    generally, because even if non-gcc compilers accept `inline', they
2800    may reject `extern inline'.  */
2801 #if defined (__GNUC__) && defined (OPTIMIZE)
2802 #define INLINE __inline__
2803 #else
2804 #define INLINE
2805 #endif
2806
2807 /* Include the os and machine dependent files.  */
2808 #include config_opsysfile
2809 #include config_machfile
2810
2811 /* Load in the conversion definitions if this system
2812    needs them and the source file being compiled has not
2813    said to inhibit this.  There should be no need for you
2814    to alter these lines.  */
2815
2816 #ifdef SHORTNAMES
2817 #ifndef NO_SHORTNAMES
2818 #include "../shortnames/remap.h"
2819 #endif /* not NO_SHORTNAMES */
2820 #endif /* SHORTNAMES */
2821
2822 /* If no remapping takes place, static variables cannot be dumped as
2823    pure, so don't worry about the `static' keyword. */
2824 #ifdef NO_REMAP
2825 #undef static
2826 #endif
2827
2828 /* Define `subprocesses' should be defined if you want to
2829    have code for asynchronous subprocesses
2830    (as used in M-x compile and M-x shell).
2831    These do not work for some USG systems yet;
2832    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2833
2834 #ifndef VMS
2835 #ifndef USG
2836 /* #define subprocesses */
2837 #endif
2838 #endif
2839
2840 /* SIGTYPE is the macro we actually use.  */
2841 #ifndef SIGTYPE
2842 #define SIGTYPE RETSIGTYPE
2843 #endif
2844
2845 #ifdef emacs /* Don't do this for lib-src.  */
2846 /* Tell regex.c to use a type compatible with Emacs.  */
2847 #define RE_TRANSLATE_TYPE Lisp_Object
2848 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2849 #ifdef make_number
2850 /* If make_number is a macro, use it.  */
2851 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2852 #else
2853 /* If make_number is a function, avoid it.  */
2854 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2855 #endif
2856 #endif
2857
2858 /* Avoid link-time collision with system mktime if we will use our own.  */
2859 #if ! HAVE_MKTIME || BROKEN_MKTIME
2860 #define mktime emacs_mktime
2861 #endif
2862
2863 #define my_strftime nstrftime   /* for strftime.c */
2864
2865 /* The rest of the code currently tests the CPP symbol BSTRING.
2866    Override any claims made by the system-description files.
2867    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2868 #undef BSTRING
2869 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2870 #define BSTRING
2871 #endif
2872
2873 /* Some of the files of Emacs which are intended for use with other
2874    programs assume that if you have a config.h file, you must declare
2875    the type of getenv.
2876
2877    This declaration shouldn't appear when alloca.s or Makefile.in
2878    includes config.h.  */
2879 #ifndef NOT_C_CODE
2880 extern char *getenv ();
2881 #endif
2882
2883 /* These default definitions are good for almost all machines.
2884    The exceptions override them in m/MACHINE.h.  */
2885
2886 #ifndef BITS_PER_CHAR
2887 #define BITS_PER_CHAR 8
2888 #endif
2889
2890 #ifndef BITS_PER_SHORT
2891 #define BITS_PER_SHORT 16
2892 #endif
2893
2894 /* Note that lisp.h uses this in a preprocessor conditional, so it
2895    would not work to use sizeof.  That being so, we do all of them
2896    without sizeof, for uniformity's sake.  */
2897 #ifndef BITS_PER_INT
2898 #define BITS_PER_INT 32
2899 #endif
2900
2901 #ifndef BITS_PER_LONG
2902 #ifdef _LP64
2903 #define BITS_PER_LONG 64
2904 #else
2905 #define BITS_PER_LONG 32
2906 #endif
2907 #endif
2908
2909 /* Define if the compiler supports function prototypes.  It may do so
2910    but not define __STDC__ (e.g. DEC C by default) or may define it as
2911    zero.  */
2912 #undef PROTOTYPES
2913 /* For mktime.c:  */
2914 #ifndef __P
2915 # if defined PROTOTYPES
2916 #  define __P(args) args
2917 # else
2918 #  define __P(args) ()
2919 # endif  /* GCC.  */
2920 #endif /* __P */
2921
2922 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2923 #ifndef NOT_C_CODE
2924 #ifdef HAVE_STRING_H
2925 #include "string.h"
2926 #endif
2927 #ifdef HAVE_STRINGS_H
2928 #include "strings.h"  /* May be needed for bcopy & al. */
2929 #endif
2930 #ifdef HAVE_STDLIB_H
2931 #include <stdlib.h>
2932 #endif
2933 #ifndef __GNUC__
2934 # ifdef HAVE_ALLOCA_H
2935 #  include <alloca.h>
2936 # else /* AIX files deal with #pragma.  */
2937 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2938 char *alloca ();
2939 #  endif
2940 # endif /* HAVE_ALLOCA_H */
2941 #endif /* __GNUC__ */
2942 #ifndef HAVE_SIZE_T
2943 typedef unsigned size_t;
2944 #endif
2945 #endif /* NOT_C_CODE */
2946
2947 /* Define HAVE_X_I18N if we have usable i18n support.  */
2948
2949 #ifdef HAVE_X11R6
2950 #define HAVE_X_I18N
2951 #elif !defined X11R5_INHIBIT_I18N
2952 #define HAVE_X_I18N
2953 #endif
2954
2955 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2956
2957 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2958 #define HAVE_X11R6_XIM
2959 #endif
2960
2961 /* Should we enable expensive run-time checking of data types?  */
2962 #undef ENABLE_CHECKING
2963
2964 #if defined __GNUC__ && (__GNUC__ > 2 \
2965                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2966 #define NO_RETURN       __attribute__ ((__noreturn__))
2967 #else
2968 #define NO_RETURN       /* nothing */
2969 #endif
2970
2971 /* These won't be used automatically yet.  We also need to know, at least,
2972    that the stack is continuous.  */
2973 #ifdef __GNUC__
2974 #  ifndef GC_SETJMP_WORKS
2975   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2976      see NON_SAVING_SETJMP in the target descriptions.  */
2977   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2978      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2979      Fixme: Deal with SVR3.  */
2980 #    define GC_SETJMP_WORKS 1
2981 #  endif
2982 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2983 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2984 #  endif
2985 #endif
2986
2987 #ifndef HAVE_BCOPY
2988 #define bcopy(a,b,s) memcpy (b,a,s)
2989 #endif
2990 #ifndef HAVE_BZERO
2991 #define bzero(a,s) memset (a,0,s)
2992 #endif
2993 #ifndef HAVE_BCMP
2994 #define BCMP memcmp
2995 #endif
2996
2997 #endif /* EMACS_CONFIG_H */
2998
2999 /*
3000 Local Variables:
3001 mode: c
3002 End:
3003 */
3004 ])dnl
3005
3006 #### Report on what we decided to do.
3007 #### Report GTK as a toolkit, even if it doesn't use Xt.
3008 #### It makes printing result more understandable as using GTK sets
3009 #### toolkit_scroll_bars to yes by default.
3010 if test "${HAVE_GTK}" = "yes"; then
3011   USE_X_TOOLKIT=GTK
3012 fi
3013
3014 echo "
3015 Configured for \`${canonical}'.
3016
3017   Where should the build process find the source code?    ${srcdir}
3018   What operating system and machine description files should Emacs use?
3019         \`${opsysfile}' and \`${machfile}'
3020   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3021   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3022   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3023   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3024   What window system should Emacs use?                    ${window_system}
3025   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3026
3027 if test -n "${x_includes}"; then
3028 echo "  Where do we find X Windows header files?                ${x_includes}"
3029 else
3030 echo "  Where do we find X Windows header files?                Standard dirs"
3031 fi
3032 if test -n "${x_libraries}"; then
3033 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3034 else
3035 echo "  Where do we find X Windows libraries?                   Standard dirs"
3036 fi
3037
3038 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3039 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3040 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3041 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3042 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3043 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3044 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3045 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3046 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3047 echo "  Does Emacs use a font backend?                          ${USE_FONT_BACKEND}"
3048
3049 if test "${USE_FONT_BACKEND}" = "yes"; then
3050   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3051   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3052   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3053   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3054 fi
3055 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3056 echo
3057
3058 if test $USE_XASSERTS = yes; then
3059    echo "  Compiling with asserts turned on."
3060    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3061    echo
3062 fi
3063
3064 if test "$USE_X_TOOLKIT" = GTK; then
3065   case "$canonical" in
3066   *cygwin*)
3067     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3068   will probably get a crash on startup.  If this happens, please use another
3069   toolkit for Emacs.  See etc/PROBLEMS for more information."
3070   ;;
3071   esac
3072 fi
3073
3074
3075 if test "$HAVE_CARBON" = "yes"; then
3076    echo
3077    echo "Warning: The Mac Carbon port is currently unsupported and has
3078 known problems.  It is not recommended for use by non-developers.
3079 Read the emacs-devel archives for more information."
3080    echo
3081 fi
3082
3083 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3084   echo "D-Bus integration has been tested for GNU/Linux only."
3085   echo
3086 fi
3087
3088
3089 # Remove any trailing slashes in these variables.
3090 [test "${prefix}" != NONE &&
3091   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3092 test "${exec_prefix}" != NONE &&
3093   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3094
3095 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3096 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3097 ## from Makefile.c can correctly provide the arg `-traditional' to the
3098 ## C preprocessor.
3099
3100 AC_EGREP_CPP(yes..yes,
3101         [yes..yes],
3102         CPP_NEED_TRADITIONAL=no,
3103         CPP_NEED_TRADITIONAL=yes)
3104
3105 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3106         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3107         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3108         lwlib/Makefile lisp/Makefile leim/Makefile, [
3109
3110 ### Make the necessary directories, if they don't exist.
3111 for dir in etc lisp ; do
3112   test -d ${dir} || mkdir ${dir}
3113 done
3114
3115 # Build src/Makefile from ${srcdir}/src/Makefile.c
3116 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3117 # This must be done after src/config.h is built, since we rely on that file.
3118
3119 # Now get this: Some word that is part of the ${srcdir} directory name
3120 # or the ${configuration} value might, just might, happen to be an
3121 # identifier like `sun4' or `i386' or something, and be predefined by
3122 # the C preprocessor to some helpful value like 1, or maybe the empty
3123 # string.  Needless to say consequent macro substitutions are less
3124 # than conducive to the makefile finding the correct directory.
3125 [undefs="`echo $top_srcdir $configuration $canonical |
3126 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3127     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3128 `"]
3129
3130 echo creating src/epaths.h
3131 ${MAKE-make} epaths-force
3132
3133 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3134 # `..' to `. .'  unless invoked with -traditional
3135
3136 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3137   CPPFLAGS="$CPPFLAGS -traditional"
3138 fi
3139
3140 echo creating lib-src/Makefile
3141 ( cd lib-src
3142   rm -f junk.c junk1.c junk2.c
3143   sed -e '/start of cpp stuff/q' \
3144       < Makefile.c > junk1.c
3145   sed -e '1,/start of cpp stuff/d'\
3146       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3147       < Makefile.c > junk.c
3148   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3149       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3150   cat junk1.c junk2.c > Makefile.new
3151   rm -f junk.c junk1.c junk2.c
3152   chmod 444 Makefile.new
3153   mv -f Makefile.new Makefile
3154 )
3155
3156 echo creating src/Makefile
3157 ( cd src
3158   rm -f junk.c junk1.c junk2.c
3159   sed -e '/start of cpp stuff/q' \
3160       < Makefile.c > junk1.c
3161   sed -e '1,/start of cpp stuff/d'\
3162       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3163       < Makefile.c > junk.c
3164   if test -f ${srcdir}/admin/unidata/UnicodeData.txt; then
3165     echo creating ${srcdir}/admin/unidata/Makefile
3166     cp ${srcdir}/admin/unidata/Makefile.in ${srcdir}/admin/unidata/Makefile
3167     CPPFLAGS="$CPPFLAGS -DHAVE_UNIDATA"
3168   fi
3169   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3170       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3171   cat junk1.c junk2.c > Makefile.new
3172   rm -f junk.c junk1.c junk2.c
3173   chmod 444 Makefile.new
3174   mv -f Makefile.new Makefile
3175 )
3176
3177 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3178   echo creating src/.gdbinit
3179   echo source $srcdir/src/.gdbinit > src/.gdbinit
3180 fi
3181
3182 # This is how we know whether to re-run configure in certain cases.
3183 touch src/config.stamp
3184
3185 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3186
3187 m4_if(dnl       Do not change this comment
3188    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3189 )dnl