lisp/vc/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2006-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: vc tools
   8 ;; Package: vc
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a mercurial version control backend
  28
  29 ;;; Thanks:
  30
  31 ;;; Bugs:
  32
  33 ;;; Installation:
  34
  35 ;;; Todo:
  36
  37 ;; 1) Implement the rest of the vc interface. See the comment at the
  38 ;; beginning of vc.el. The current status is:
  39
  40 ;; FUNCTION NAME                               STATUS
  41 ;; BACKEND PROPERTIES
  42 ;; * revision-granularity                      OK
  43 ;; STATE-QUERYING FUNCTIONS
  44 ;; * registered (file)                         OK
  45 ;; * state (file)                              OK
  46 ;; - state-heuristic (file)                    NOT NEEDED
  47 ;; - dir-status (dir update-function)          OK
  48 ;; - dir-status-files (dir files ds uf)        OK
  49 ;; - dir-extra-headers (dir)                   OK
  50 ;; - dir-printer (fileinfo)                    OK
  51 ;; * working-revision (file)                   OK
  52 ;; - latest-on-branch-p (file)                 ??
  53 ;; * checkout-model (files)                    OK
  54 ;; - workfile-unchanged-p (file)               OK
  55 ;; - mode-line-string (file)                   NOT NEEDED
  56 ;; STATE-CHANGING FUNCTIONS
  57 ;; * register (files &optional rev comment)    OK
  58 ;; * create-repo ()                            OK
  59 ;; - init-revision ()                          NOT NEEDED
  60 ;; - responsible-p (file)                      OK
  61 ;; - could-register (file)                     OK
  62 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  63 ;; - unregister (file)                         OK
  64 ;; * checkin (files rev comment)               OK
  65 ;; * find-revision (file rev buffer)           OK
  66 ;; * checkout (file &optional editable rev)    OK
  67 ;; * revert (file &optional contents-done)     OK
  68 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  69 ;; - merge (file rev1 rev2)                    NEEDED
  70 ;; - merge-news (file)                         NEEDED
  71 ;; - steal-lock (file &optional revision)      NOT NEEDED
  72 ;; HISTORY FUNCTIONS
  73 ;; * print-log (files buffer &optional shortlog start-revision limit) OK
  74 ;; - log-view-mode ()                          OK
  75 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  76 ;; - comment-history (file)                    NOT NEEDED
  77 ;; - update-changelog (files)                  NOT NEEDED
  78 ;; * diff (files &optional rev1 rev2 buffer)   OK
  79 ;; - revision-completion-table (files)         OK?
  80 ;; - annotate-command (file buf &optional rev) OK
  81 ;; - annotate-time ()                          OK
  82 ;; - annotate-current-time ()                  NOT NEEDED
  83 ;; - annotate-extract-revision-at-line ()      OK
  84 ;; TAG SYSTEM
  85 ;; - create-tag (dir name branchp)             NEEDED
  86 ;; - retrieve-tag (dir name update)            NEEDED
  87 ;; MISCELLANEOUS
  88 ;; - make-version-backups-p (file)             ??
  89 ;; - repository-hostname (dirname)             ??
  90 ;; - previous-revision (file rev)              OK
  91 ;; - next-revision (file rev)                  OK
  92 ;; - check-headers ()                          ??
  93 ;; - clear-headers ()                          ??
  94 ;; - delete-file (file)                        TEST IT
  95 ;; - rename-file (old new)                     OK
  96 ;; - find-file-hook ()                         added for bug#10709
  97
  98 ;; 2) Implement Stefan Monnier's advice:
  99 ;; vc-hg-registered and vc-hg-state
 100 ;; Both of those functions should be super extra careful to fail gracefully in
 101 ;; unexpected circumstances. The reason this is important is that any error
 102 ;; there will prevent the user from even looking at the file :-(
 103 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
 104 ;; mercurial's control and extracting the current revision should be done
 105 ;; without even using `hg' (this way even if you don't have `hg' installed,
 106 ;; Emacs is able to tell you this file is under mercurial's control).
 107
 108 ;;; History:
 109 ;;
 110
 111 ;;; Code:
 112
 113 (eval-when-compile
 114   (require 'cl-lib)
 115   (require 'vc)
 116   (require 'vc-dir))
 117
 118 ;;; Customization options
 119
 120 (defgroup vc-hg nil
 121   "VC Mercurial (hg) backend."
 122   :version "24.1"
 123   :group 'vc)
 124
 125 (defcustom vc-hg-global-switches nil
 126   "Global switches to pass to any Hg command."
 127   :type '(choice (const :tag "None" nil)
 128          (string :tag "Argument String")
 129          (repeat :tag "Argument List" :value ("") string))
 130   :version "22.2"
 131   :group 'vc-hg)
 132
 133 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 134   "String or list of strings specifying switches for Hg diff under VC.
 135 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 136   :type '(choice (const :tag "Unspecified" nil)
 137                  (const :tag "None" t)
 138                  (string :tag "Argument String")
 139                  (repeat :tag "Argument List" :value ("") string))
 140   :version "23.1"
 141   :group 'vc-hg)
 142
 143 (defcustom vc-hg-program "hg"
 144   "Name of the Mercurial executable (excluding any arguments)."
 145   :type 'string
 146   :group 'vc-hg)
 147
 148 (defcustom vc-hg-root-log-format
 149   '("{rev}:{tags}: {author|person} {date|shortdate} {desc|firstline}\\n"
 150     "^\\([0-9]+\\):\\([^:]*\\): \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)"
 151     ((1 'log-view-message-face)
 152      (2 'change-log-list)
 153      (3 'change-log-name)
 154      (4 'change-log-date)))
 155   "Mercurial log template for `vc-hg-print-log' short format.
 156 This should be a list (TEMPLATE REGEXP KEYWORDS), where TEMPLATE
 157 is the \"--template\" argument string to pass to Mercurial,
 158 REGEXP is a regular expression matching the resulting Mercurial
 159 output, and KEYWORDS is a list of `font-lock-keywords' for
 160 highlighting the Log View buffer."
 161   :type '(list string string (repeat sexp))
 162   :group 'vc-hg
 163   :version "24.1")
 164
 165 \f
 166 ;;; Properties of the backend
 167
 168 (defvar vc-hg-history nil)
 169
 170 (defun vc-hg-revision-granularity () 'repository)
 171 (defun vc-hg-checkout-model (_files) 'implicit)
 172
 173 ;;; State querying functions
 174
 175 ;;;###autoload (defun vc-hg-registered (file)
 176 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 177 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 178 ;;;###autoload       (progn
 179 ;;;###autoload         (load "vc-hg" nil t)
 180 ;;;###autoload         (vc-hg-registered file))))
 181
 182 ;; Modeled after the similar function in vc-bzr.el
 183 (defun vc-hg-registered (file)
 184   "Return non-nil if FILE is registered with hg."
 185   (when (vc-hg-root file)           ; short cut
 186     (let ((state (vc-hg-state file)))  ; expensive
 187       (and state (not (memq state '(ignored unregistered)))))))
 188
 189 (defun vc-hg-state (file)
 190   "Hg-specific version of `vc-state'."
 191   (let*
 192       ((status nil)
 193        (default-directory (file-name-directory file))
 194        (out
 195         (with-output-to-string
 196           (with-current-buffer
 197               standard-output
 198             (setq status
 199                   (condition-case nil
 200                       ;; Ignore all errors.
 201                       (let ((process-environment
 202                              ;; Avoid localization of messages so we
 203                              ;; can parse the output.
 204                              (append (list "TERM=dumb" "LANGUAGE=C")
 205                                      process-environment)))
 206                         (process-file
 207                          vc-hg-program nil t nil
 208                          "--config" "alias.status=status"
 209                          "--config" "defaults.status="
 210                          "status" "-A" (file-relative-name file)))
 211                     ;; Some problem happened.  E.g. We can't find an `hg'
 212                     ;; executable.
 213                     (error nil)))))))
 214     (when (eq 0 status)
 215         (when (null (string-match ".*: No such file or directory$" out))
 216           (let ((state (aref out 0)))
 217             (cond
 218              ((eq state ?=) 'up-to-date)
 219              ((eq state ?A) 'added)
 220              ((eq state ?M) 'edited)
 221              ((eq state ?I) 'ignored)
 222              ((eq state ?R) 'removed)
 223              ((eq state ?!) 'missing)
 224              ((eq state ??) 'unregistered)
 225              ((eq state ?C) 'up-to-date) ;; Older mercurial versions use this.
 226              (t 'up-to-date)))))))
 227
 228 (defun vc-hg-working-revision (file)
 229   "Hg-specific version of `vc-working-revision'."
 230   (or (ignore-errors
 231         (with-output-to-string
 232           (vc-hg-command standard-output 0 file
 233                          "parent" "--template" "{rev}")))
 234       "0"))
 235
 236 ;;; History functions
 237
 238 (defcustom vc-hg-log-switches nil
 239   "String or list of strings specifying switches for hg log under VC."
 240   :type '(choice (const :tag "None" nil)
 241                  (string :tag "Argument String")
 242                  (repeat :tag "Argument List" :value ("") string))
 243   :group 'vc-hg)
 244
 245 (autoload 'vc-setup-buffer "vc-dispatcher")
 246
 247 (defun vc-hg-print-log (files buffer &optional shortlog start-revision limit)
 248   "Print commit log associated with FILES into specified BUFFER.
 249 If SHORTLOG is non-nil, use a short format based on `vc-hg-root-log-format'.
 250 If START-REVISION is non-nil, it is the newest revision to show.
 251 If LIMIT is non-nil, show no more than this many entries."
 252   ;; `vc-do-command' creates the buffer, but we need it before running
 253   ;; the command.
 254   (vc-setup-buffer buffer)
 255   ;; If the buffer exists from a previous invocation it might be
 256   ;; read-only.
 257   (let ((inhibit-read-only t))
 258     (with-current-buffer
 259         buffer
 260       (apply 'vc-hg-command buffer 0 files "log"
 261              (nconc
 262               (when start-revision (list (format "-r%s:0" start-revision)))
 263               (when limit (list "-l" (format "%s" limit)))
 264               (when shortlog (list "--template" (car vc-hg-root-log-format)))
 265               vc-hg-log-switches)))))
 266
 267 (defvar log-view-message-re)
 268 (defvar log-view-file-re)
 269 (defvar log-view-font-lock-keywords)
 270 (defvar log-view-per-file-logs)
 271 (defvar log-view-expanded-log-entry-function)
 272
 273 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 274   (require 'add-log) ;; we need the add-log faces
 275   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 276   (set (make-local-variable 'log-view-per-file-logs) nil)
 277   (set (make-local-variable 'log-view-message-re)
 278        (if (eq vc-log-view-type 'short)
 279            (cadr vc-hg-root-log-format)
 280          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 281   ;; Allow expanding short log entries
 282   (when (eq vc-log-view-type 'short)
 283     (setq truncate-lines t)
 284     (set (make-local-variable 'log-view-expanded-log-entry-function)
 285          'vc-hg-expanded-log-entry))
 286   (set (make-local-variable 'log-view-font-lock-keywords)
 287        (if (eq vc-log-view-type 'short)
 288            (list (cons (nth 1 vc-hg-root-log-format)
 289                        (nth 2 vc-hg-root-log-format)))
 290          (append
 291           log-view-font-lock-keywords
 292           '(
 293             ;; Handle the case:
 294             ;; user: FirstName LastName <foo@bar>
 295             ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 296              (1 'change-log-name)
 297              (2 'change-log-email))
 298             ;; Handle the cases:
 299             ;; user: foo@bar
 300             ;; and
 301             ;; user: foo
 302             ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 303              (1 'change-log-email))
 304             ("^date: \\(.+\\)" (1 'change-log-date))
 305             ("^tag: +\\([^ ]+\\)$" (1 'highlight))
 306             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 307
 308 (autoload 'vc-switches "vc")
 309
 310 (defun vc-hg-diff (files &optional oldvers newvers buffer)
 311   "Get a difference report using hg between two revisions of FILES."
 312   (let* ((firstfile (car files))
 313          (working (and firstfile (vc-working-revision firstfile))))
 314     (when (and (equal oldvers working) (not newvers))
 315       (setq oldvers nil))
 316     (when (and (not oldvers) newvers)
 317       (setq oldvers working))
 318     (apply #'vc-hg-command (or buffer "*vc-diff*") nil files "diff"
 319            (append
 320             (vc-switches 'hg 'diff)
 321             (when oldvers
 322               (if newvers
 323                   (list "-r" oldvers "-r" newvers)
 324                 (list "-r" oldvers)))))))
 325
 326 (defun vc-hg-expanded-log-entry (revision)
 327   (with-temp-buffer
 328     (vc-hg-command t nil nil "log" "-r" revision)
 329     (goto-char (point-min))
 330     (unless (eobp)
 331       ;; Indent the expanded log entry.
 332       (indent-region (point-min) (point-max) 2)
 333       (goto-char (point-max))
 334       (buffer-string))))
 335
 336 (defun vc-hg-revision-table (files)
 337   (let ((default-directory (file-name-directory (car files))))
 338     (with-temp-buffer
 339       (vc-hg-command t nil files "log" "--template" "{rev} ")
 340       (split-string
 341        (buffer-substring-no-properties (point-min) (point-max))))))
 342
 343 ;; Modeled after the similar function in vc-cvs.el
 344 (defun vc-hg-revision-completion-table (files)
 345   (letrec ((table (lazy-completion-table
 346                    table (lambda () (vc-hg-revision-table files)))))
 347     table))
 348
 349 (defun vc-hg-annotate-command (file buffer &optional revision)
 350   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 351 Optional arg REVISION is a revision to annotate from."
 352   (vc-hg-command buffer 0 file "annotate" "-d" "-n" "--follow"
 353                  (when revision (concat "-r" revision))))
 354
 355 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 356
 357 ;; The format for one line output by "hg annotate -d -n" looks like this:
 358 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 359 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 360 ;; If the user has set the "--follow" option, the output looks like:
 361 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 362 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 363 (defconst vc-hg-annotate-re
 364   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)\\(?:\\(: \\)\\|\\(?: +\\([^:\n]+\\(?::\\(?:[^: \n][^:\n]*\\)?\\)*\\): \\)\\)")
 365
 366 (defun vc-hg-annotate-time ()
 367   (when (looking-at vc-hg-annotate-re)
 368     (goto-char (match-end 0))
 369     (vc-annotate-convert-time
 370      (date-to-time (match-string-no-properties 2)))))
 371
 372 (defun vc-hg-annotate-extract-revision-at-line ()
 373   (save-excursion
 374     (beginning-of-line)
 375     (when (looking-at vc-hg-annotate-re)
 376       (if (match-beginning 3)
 377           (match-string-no-properties 1)
 378         (cons (match-string-no-properties 1)
 379               (expand-file-name (match-string-no-properties 4)
 380                                 (vc-hg-root default-directory)))))))
 381
 382 (defun vc-hg-previous-revision (_file rev)
 383   (let ((newrev (1- (string-to-number rev))))
 384     (when (>= newrev 0)
 385       (number-to-string newrev))))
 386
 387 (defun vc-hg-next-revision (_file rev)
 388   (let ((newrev (1+ (string-to-number rev)))
 389         (tip-revision
 390          (with-temp-buffer
 391            (vc-hg-command t 0 nil "tip" "--style=default")
 392            (goto-char (point-min))
 393            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 394            (string-to-number (match-string-no-properties 1)))))
 395     ;; We don't want to exceed the maximum possible revision number, ie
 396     ;; the tip revision.
 397     (when (<= newrev tip-revision)
 398       (number-to-string newrev))))
 399
 400 ;; Modeled after the similar function in vc-bzr.el
 401 (defun vc-hg-delete-file (file)
 402   "Delete FILE and delete it in the hg repository."
 403   (condition-case ()
 404       (delete-file file)
 405     (file-error nil))
 406   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 407
 408 ;; Modeled after the similar function in vc-bzr.el
 409 (defun vc-hg-rename-file (old new)
 410   "Rename file from OLD to NEW using `hg mv'."
 411   (vc-hg-command nil 0 new "mv" old))
 412
 413 (defun vc-hg-register (files &optional _rev _comment)
 414   "Register FILES under hg.
 415 REV is ignored.
 416 COMMENT is ignored."
 417   (vc-hg-command nil 0 files "add"))
 418
 419 (defun vc-hg-create-repo ()
 420   "Create a new Mercurial repository."
 421   (vc-hg-command nil 0 nil "init"))
 422
 423 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 424
 425 ;; Modeled after the similar function in vc-bzr.el
 426 (defun vc-hg-could-register (file)
 427   "Return non-nil if FILE could be registered under hg."
 428   (and (vc-hg-responsible-p file)      ; shortcut
 429        (condition-case ()
 430            (with-temp-buffer
 431              (vc-hg-command t nil file "add" "--dry-run"))
 432              ;; The command succeeds with no output if file is
 433              ;; registered.
 434          (error))))
 435
 436 (defun vc-hg-unregister (file)
 437   "Unregister FILE from hg."
 438   (vc-hg-command nil 0 file "forget"))
 439
 440 (declare-function log-edit-extract-headers "log-edit" (headers string))
 441
 442 (defun vc-hg-checkin (files _rev comment)
 443   "Hg-specific version of `vc-backend-checkin'.
 444 REV is ignored."
 445   (apply 'vc-hg-command nil 0 files
 446          (nconc (list "commit" "-m")
 447                 (log-edit-extract-headers '(("Author" . "--user")
 448                                             ("Date" . "--date"))
 449                                           comment))))
 450
 451 (defun vc-hg-find-revision (file rev buffer)
 452   (let ((coding-system-for-read 'binary)
 453         (coding-system-for-write 'binary))
 454     (if rev
 455         (vc-hg-command buffer 0 file "cat" "-r" rev)
 456       (vc-hg-command buffer 0 file "cat"))))
 457
 458 (defun vc-hg-find-ignore-file (file)
 459   "Return the root directory of the repository of FILE."
 460   (expand-file-name ".hgignore"
 461                     (vc-hg-root file)))
 462
 463 ;; Modeled after the similar function in vc-bzr.el
 464 (defun vc-hg-checkout (file &optional _editable rev)
 465   "Retrieve a revision of FILE.
 466 EDITABLE is ignored.
 467 REV is the revision to check out into WORKFILE."
 468   (let ((coding-system-for-read 'binary)
 469         (coding-system-for-write 'binary))
 470   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 471     (if rev
 472         (vc-hg-command t 0 file "cat" "-r" rev)
 473       (vc-hg-command t 0 file "cat")))))
 474
 475 (defun vc-hg-resolve-when-done ()
 476   "Call \"hg resolve -m\" if the conflict markers have been removed."
 477   (save-excursion
 478     (goto-char (point-min))
 479     (unless (re-search-forward "^<<<<<<< " nil t)
 480       (vc-hg-command nil 0 buffer-file-name "resolve" "-m")
 481       ;; Remove the hook so that it is not called multiple times.
 482       (remove-hook 'after-save-hook 'vc-hg-resolve-when-done t))))
 483
 484 (defun vc-hg-find-file-hook ()
 485   (when (and buffer-file-name
 486              (file-exists-p (concat buffer-file-name ".orig"))
 487              ;; Hg does not seem to have a "conflict" status, eg
 488              ;; hg http://bz.selenic.com/show_bug.cgi?id=2724
 489              (memq (vc-file-getprop buffer-file-name 'vc-state)
 490                    '(edited conflict))
 491              ;; Maybe go on to check that "hg resolve -l" says "U"?
 492              ;; If "hg resolve -l" says there's a conflict but there are no
 493              ;; conflict markers, it's not clear what we should do.
 494              (save-excursion
 495                (goto-char (point-min))
 496                (re-search-forward "^<<<<<<< " nil t)))
 497     ;; Hg may not recognize "conflict" as a state, but we can do better.
 498     (vc-file-setprop buffer-file-name 'vc-state 'conflict)
 499     (smerge-start-session)
 500     (add-hook 'after-save-hook 'vc-hg-resolve-when-done nil t)
 501     (message "There are unresolved conflicts in this file")))
 502
 503
 504 ;; Modeled after the similar function in vc-bzr.el
 505 (defun vc-hg-workfile-unchanged-p (file)
 506   (eq 'up-to-date (vc-hg-state file)))
 507
 508 ;; Modeled after the similar function in vc-bzr.el
 509 (defun vc-hg-revert (file &optional contents-done)
 510   (unless contents-done
 511     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 512
 513 ;;; Hg specific functionality.
 514
 515 (defvar vc-hg-extra-menu-map
 516   (let ((map (make-sparse-keymap)))
 517     map))
 518
 519 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 520
 521 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 522
 523 (defvar log-view-vc-backend)
 524
 525 (cl-defstruct (vc-hg-extra-fileinfo
 526             (:copier nil)
 527             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 528             (:conc-name vc-hg-extra-fileinfo->))
 529   rename-state        ;; rename or copy state
 530   extra-name)         ;; original name for copies and rename targets, new name for
 531
 532 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 533
 534 (defun vc-hg-dir-printer (info)
 535   "Pretty-printer for the vc-dir-fileinfo structure."
 536   (let ((extra (vc-dir-fileinfo->extra info)))
 537     (vc-default-dir-printer 'Hg info)
 538     (when extra
 539       (insert (propertize
 540                (format "   (%s %s)"
 541                        (pcase (vc-hg-extra-fileinfo->rename-state extra)
 542                          (`copied "copied from")
 543                          (`renamed-from "renamed from")
 544                          (`renamed-to "renamed to"))
 545                        (vc-hg-extra-fileinfo->extra-name extra))
 546                'face 'font-lock-comment-face)))))
 547
 548 (defun vc-hg-after-dir-status (update-function)
 549   (let ((file nil)
 550         (translation '((?= . up-to-date)
 551                        (?C . up-to-date)
 552                        (?A . added)
 553                        (?R . removed)
 554                        (?M . edited)
 555                        (?I . ignored)
 556                        (?! . missing)
 557                        (?  . copy-rename-line)
 558                        (?? . unregistered)))
 559         (translated nil)
 560         (result nil)
 561         (last-added nil)
 562         (last-line-copy nil))
 563       (goto-char (point-min))
 564       (while (not (eobp))
 565         (setq translated (cdr (assoc (char-after) translation)))
 566         (setq file
 567               (buffer-substring-no-properties (+ (point) 2)
 568                                               (line-end-position)))
 569         (cond ((not translated)
 570                (setq last-line-copy nil))
 571               ((eq translated 'up-to-date)
 572                (setq last-line-copy nil))
 573               ((eq translated 'copy-rename-line)
 574                ;; For copied files the output looks like this:
 575                ;; A COPIED_FILE_NAME
 576                ;;   ORIGINAL_FILE_NAME
 577                (setf (nth 2 last-added)
 578                      (vc-hg-create-extra-fileinfo 'copied file))
 579                (setq last-line-copy t))
 580               ((and last-line-copy (eq translated 'removed))
 581                ;; For renamed files the output looks like this:
 582                ;; A NEW_FILE_NAME
 583                ;;   ORIGINAL_FILE_NAME
 584                ;; R ORIGINAL_FILE_NAME
 585                ;; We need to adjust the previous entry to not think it is a copy.
 586                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 587                      'renamed-from)
 588                (push (list file translated
 589                            (vc-hg-create-extra-fileinfo
 590                             'renamed-to (nth 0 last-added))) result)
 591                (setq last-line-copy nil))
 592               (t
 593                (setq last-added (list file translated nil))
 594                (push last-added result)
 595                (setq last-line-copy nil)))
 596         (forward-line))
 597       (funcall update-function result)))
 598
 599 ;; Follows vc-hg-command (or vc-do-async-command), which uses vc-do-command
 600 ;; from vc-dispatcher.
 601 (declare-function vc-exec-after "vc-dispatcher" (code))
 602 ;; Follows vc-exec-after.
 603 (declare-function vc-set-async-update "vc-dispatcher" (process-buffer))
 604
 605 (defun vc-hg-dir-status (dir update-function)
 606   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 607   (vc-run-delayed
 608    (vc-hg-after-dir-status update-function)))
 609
 610 (defun vc-hg-dir-status-files (dir files _default-state update-function)
 611   (apply 'vc-hg-command (current-buffer) 'async dir "status" "-C" files)
 612   (vc-run-delayed
 613    (vc-hg-after-dir-status update-function)))
 614
 615 (defun vc-hg-dir-extra-header (name &rest commands)
 616   (concat (propertize name 'face 'font-lock-type-face)
 617           (propertize
 618            (with-temp-buffer
 619              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 620              (buffer-substring-no-properties (point-min) (1- (point-max))))
 621            'face 'font-lock-variable-name-face)))
 622
 623 (defun vc-hg-dir-extra-headers (dir)
 624   "Generate extra status headers for a Mercurial tree."
 625   (let ((default-directory dir))
 626     (concat
 627      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 628      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 629      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 630      ;; these change after each commit
 631      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 632      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 633      )))
 634
 635 (defun vc-hg-log-incoming (buffer remote-location)
 636   (vc-hg-command buffer 1 nil "incoming" "-n" (unless (string= remote-location "")
 637                                                 remote-location)))
 638
 639 (defun vc-hg-log-outgoing (buffer remote-location)
 640   (vc-hg-command buffer 1 nil "outgoing" "-n" (unless (string= remote-location "")
 641                                                 remote-location)))
 642
 643 (declare-function log-view-get-marked "log-view" ())
 644
 645 ;; XXX maybe also add key bindings for these functions.
 646 (defun vc-hg-push ()
 647   (interactive)
 648   (let ((marked-list (log-view-get-marked)))
 649     (if marked-list
 650         (apply #'vc-hg-command
 651                nil 0 nil
 652                "push"
 653                (apply 'nconc
 654                       (mapcar (lambda (arg) (list "-r" arg)) marked-list)))
 655       (error "No log entries selected for push"))))
 656
 657 (defvar vc-hg-error-regexp-alist nil
 658   ;; 'hg pull' does not list modified files, so, for now, the only
 659   ;; benefit of `vc-compilation-mode' is that one can get rid of
 660   ;; *vc-hg* buffer with 'q' or 'z'.
 661   ;; TODO: call 'hg incoming' before pull/merge to get the list of
 662   ;;       modified files
 663   "Value of `compilation-error-regexp-alist' in *vc-hg* buffers.")
 664
 665 (autoload 'vc-do-async-command "vc-dispatcher")
 666
 667 (defun vc-hg-pull (prompt)
 668   "Issue a Mercurial pull command.
 669 If called interactively with a set of marked Log View buffers,
 670 call \"hg pull -r REVS\" to pull in the specified revisions REVS.
 671
 672 With a prefix argument or if PROMPT is non-nil, prompt for a
 673 specific Mercurial pull command.  The default is \"hg pull -u\",
 674 which fetches changesets from the default remote repository and
 675 then attempts to update the working directory."
 676   (interactive "P")
 677   (let (marked-list)
 678     ;; The `vc-hg-pull' command existed before the `pull' VC action
 679     ;; was implemented.  Keep it for backward compatibility.
 680     (if (and (called-interactively-p 'interactive)
 681              (setq marked-list (log-view-get-marked)))
 682         (apply #'vc-hg-command
 683                nil 0 nil
 684                "pull"
 685                (apply 'nconc
 686                       (mapcar (lambda (arg) (list "-r" arg))
 687                               marked-list)))
 688       (let* ((root (vc-hg-root default-directory))
 689              (buffer (format "*vc-hg : %s*" (expand-file-name root)))
 690              (command "pull")
 691              (hg-program vc-hg-program)
 692              ;; Fixme: before updating the working copy to the latest
 693              ;; state, should check if it's visiting an old revision.
 694              (args '("-u")))
 695         ;; If necessary, prompt for the exact command.
 696         (when prompt
 697           (setq args (split-string
 698                       (read-shell-command "Run Hg (like this): "
 699                                           (format "%s pull -u" hg-program)
 700                                           'vc-hg-history)
 701                       " " t))
 702           (setq hg-program (car  args)
 703                 command    (cadr args)
 704                 args       (cddr args)))
 705         (apply 'vc-do-async-command buffer root hg-program
 706                command args)
 707         (with-current-buffer buffer
 708           (vc-run-delayed (vc-compilation-mode 'hg)))
 709         (vc-set-async-update buffer)))))
 710
 711 (defun vc-hg-merge-branch ()
 712   "Merge incoming changes into the current working directory.
 713 This runs the command \"hg merge\"."
 714   (let* ((root (vc-hg-root default-directory))
 715          (buffer (format "*vc-hg : %s*" (expand-file-name root))))
 716     (apply 'vc-do-async-command buffer root vc-hg-program '("merge"))
 717     (with-current-buffer buffer (vc-run-delayed (vc-compilation-mode 'hg)))
 718     (vc-set-async-update buffer)))
 719
 720 ;;; Internal functions
 721
 722 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 723   "A wrapper around `vc-do-command' for use in vc-hg.el.
 724 This function differs from vc-do-command in that it invokes
 725 `vc-hg-program', and passes `vc-hg-global-switches' to it before FLAGS."
 726   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-hg-program file-or-list
 727          (if (stringp vc-hg-global-switches)
 728              (cons vc-hg-global-switches flags)
 729            (append vc-hg-global-switches
 730                    flags))))
 731
 732 (defun vc-hg-root (file)
 733   (vc-find-root file ".hg"))
 734
 735 (provide 'vc-hg)
 736
 737 ;;; vc-hg.el ends here