admin/admin.el

   1 ;;; admin.el --- utilities for Emacs administration
   2
   3 ;; Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; add-release-logs     Add ``Version X released'' change log entries.
  24 ;; set-version          Change Emacs version number in source tree.
  25 ;; set-copyright        Change emacs short copyright string (eg as
  26 ;;                      printed by --version) in source tree.
  27
  28 ;;; Code:
  29
  30 (defun add-release-logs (root version)
  31   "Add \"Version VERSION released.\" change log entries in ROOT.
  32 Root must be the root of an Emacs source tree."
  33   (interactive "DEmacs root directory: \nNVersion number: ")
  34   (setq root (expand-file-name root))
  35   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
  36     (error "%s doesn't seem to be the root of an Emacs source tree" root))
  37   (require 'add-log)
  38   (let* ((logs (process-lines "find" root "-name" "ChangeLog"))
  39          (entry (format "%s  %s  <%s>\n\n\t* Version %s released.\n\n"
  40                         (funcall add-log-time-format)
  41                         (or add-log-full-name (user-full-name))
  42                         (or add-log-mailing-address user-mail-address)
  43                         version)))
  44     (dolist (log logs)
  45       (unless (string-match "/gnus/" log)
  46         (find-file log)
  47         (goto-char (point-min))
  48         (insert entry)))))
  49
  50 (defun set-version-in-file (root file version rx)
  51   (find-file (expand-file-name file root))
  52   (goto-char (point-min))
  53   (unless (re-search-forward rx nil t)
  54     (error "Version not found in %s" file))
  55   (replace-match (format "%s" version) nil nil nil 1))
  56
  57 (defun set-version (root version)
  58   "Set Emacs version to VERSION in relevant files under ROOT.
  59 Root must be the root of an Emacs source tree."
  60   (interactive "DEmacs root directory: \nsVersion number: ")
  61   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
  62     (error "%s doesn't seem to be the root of an Emacs source tree" root))
  63   (set-version-in-file root "lisp/version.el" version
  64                        (rx (and "emacs-version" (0+ space)
  65                                 ?\" (submatch (1+ (not (in ?\")))) ?\")))
  66   (set-version-in-file root "README" version
  67                        (rx (and "version" (1+ space)
  68                                 (submatch (1+ (in "0-9."))))))
  69   (set-version-in-file root "configure.in" version
  70                        (rx (and "AC_INIT" (1+ (not (in ?,)))
  71                                 ?, (0+ space)
  72                                 (submatch (1+ (in "0-9."))))))
  73   (set-version-in-file root "doc/emacs/emacs.texi" version
  74                        (rx (and "EMACSVER" (1+ space)
  75                                 (submatch (1+ (in "0-9."))))))
  76   (set-version-in-file root "doc/lispref/elisp.texi" version
  77                        (rx (and "EMACSVER" (1+ space)
  78                                 (submatch (1+ (in "0-9."))))))
  79   (set-version-in-file root "doc/lispref/vol1.texi" version
  80                        (rx (and "EMACSVER" (1+ space)
  81                                 (submatch (1+ (in "0-9."))))))
  82   (set-version-in-file root "doc/lispref/vol2.texi" version
  83                        (rx (and "EMACSVER" (1+ space)
  84                                 (submatch (1+ (in "0-9."))))))
  85   (set-version-in-file root "doc/man/emacs.1" version
  86                        (rx (and ".TH EMACS" (1+ not-newline)
  87                                 "GNU Emacs" (1+ space)
  88                                 (submatch (1+ (in "0-9."))))))
  89   (set-version-in-file root "doc/misc/faq.texi" version
  90                        (rx (and "VER" (1+ space)
  91                                 (submatch (1+ (in "0-9."))))))
  92   (set-version-in-file root "lib-src/makefile.w32-in" version
  93                        (rx (and "VERSION" (0+ space) "=" (0+ space)
  94                                 (submatch (1+ (in "0-9."))))))
  95   ;; nt/emacs.rc also contains the version number, but in an awkward
  96   ;; format. It must contain four components, separated by commas, and
  97   ;; in two places those commas are followed by space, in two other
  98   ;; places they are not.
  99   (let* ((version-components (append (split-string version "\\.")
 100                                     '("0" "0")))
 101          (comma-version
 102           (concat (car version-components) ","
 103                   (cadr version-components) ","
 104                   (cadr (cdr version-components)) ","
 105                   (cadr (cdr (cdr version-components)))))
 106          (comma-space-version
 107           (concat (car version-components) ", "
 108                   (cadr version-components) ", "
 109                   (cadr (cdr version-components)) ", "
 110                   (cadr (cdr (cdr version-components))))))
 111     (set-version-in-file root "nt/emacs.rc" comma-version
 112                          (rx (and "FILEVERSION" (1+ space)
 113                                   (submatch (1+ (in "0-9,"))))))
 114     (set-version-in-file root "nt/emacs.rc" comma-version
 115                          (rx (and "PRODUCTVERSION" (1+ space)
 116                                   (submatch (1+ (in "0-9,"))))))
 117     (set-version-in-file root "nt/emacs.rc" comma-space-version
 118                          (rx (and "\"FileVersion\"" (0+ space) ?, (0+ space)
 119                                   ?\" (submatch (1+ (in "0-9, "))) "\\0\"")))
 120     (set-version-in-file root "nt/emacs.rc" comma-space-version
 121                          (rx (and "\"ProductVersion\"" (0+ space) ?,
 122                                   (0+ space) ?\" (submatch (1+ (in "0-9, ")))
 123                                   "\\0\"")))
 124     ;; Some files in the "mac" subdirectory also contain the version
 125     ;; number.
 126     (set-version-in-file
 127      root "mac/Emacs.app/Contents/Resources/English.lproj/InfoPlist.strings"
 128      version (rx (and "CFBundleShortVersionString" (0+ space) ?= (0+ space) ?\"
 129                       (submatch (1+ (in "0-9."))))))
 130     (set-version-in-file
 131      root "mac/Emacs.app/Contents/Resources/English.lproj/InfoPlist.strings"
 132      version (rx (and "CFBundleGetInfoString" (0+ space) ?= (0+ space) ?\"
 133                       (submatch (1+ (in "0-9."))))))
 134     (set-version-in-file root "mac/src/Emacs.r" (car version-components)
 135                          (rx (and "GNU Emacs " (submatch (1+ (in "0-9")))
 136                                   " for Mac OS")))
 137     (set-version-in-file root "mac/src/Emacs.r" (car version-components)
 138                          (rx (and (submatch (1+ (in "0-9"))) (0+ space) ?\,
 139                                   (0+ space) "/* Major revision in BCD */")))
 140     (set-version-in-file root "mac/src/Emacs.r" (cadr version-components)
 141                          (rx (and (submatch (1+ (in "0-9"))) (0+ space) ?\,
 142                                   (0+ space) "/* Minor revision in BCD */")))
 143     (set-version-in-file root "mac/src/Emacs.r" (cadr (cdr version-components))
 144                          (rx (and (submatch (1+ (in "0-9"))) (0+ space) ?\,
 145                                   (0+ space) "/* Non-final release # */")))
 146     (set-version-in-file root "mac/src/Emacs.r" version
 147                          (rx (and (submatch (1+ (in "0-9."))) (0+ space) ?\" ?\,
 148                                   (0+ space) "/* Short version number */")))
 149     (set-version-in-file root "mac/src/Emacs.r" version
 150                          (rx (and "/* Short version number */" (0+ space) ?\"
 151                                   (submatch (1+ (in "0-9."))))))
 152     (let* ((third-component (string-to-number (cadr (cdr version-components))))
 153            (release (cond ((>= third-component 90) "alpha")
 154                           ((>= third-component 50) "development")
 155                           (t "final"))))
 156       (set-version-in-file
 157        root "mac/src/Emacs.r" release
 158        (rx (and (submatch (1+ (in "a-z"))) (0+ space) ?\, (0+ space)
 159                 "/* development, alpha, beta, or final (release) */"))))))
 160
 161 ;; Note this makes some assumptions about form of short copyright.
 162 ;; FIXME add the \year in the refcards/*.tex files.
 163 (defun set-copyright (root copyright)
 164   "Set Emacs short copyright to COPYRIGHT in relevant files under ROOT.
 165 Root must be the root of an Emacs source tree."
 166   (interactive (list
 167                 (read-directory-name "Emacs root directory: " nil nil t)
 168                 (read-string
 169                  "Short copyright string: "
 170                  (format "Copyright (C) %s Free Software Foundation, Inc."
 171                          (format-time-string "%Y")))))
 172   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
 173     (error "%s doesn't seem to be the root of an Emacs source tree" root))
 174   (set-version-in-file root "lisp/version.el" copyright
 175                        (rx (and "emacs-copyright" (0+ space)
 176                                 ?\" (submatch (1+ (not (in ?\")))) ?\")))
 177   (set-version-in-file root "lib-src/ebrowse.c" copyright
 178                        (rx (and "emacs_copyright" (0+ (not (in ?\")))
 179                                 ?\" (submatch (1+ (not (in ?\")))) ?\")))
 180   (set-version-in-file root "lib-src/etags.c" copyright
 181                        (rx (and "emacs_copyright" (0+ (not (in ?\")))
 182                                 ?\" (submatch (1+ (not (in ?\")))) ?\")))
 183   (set-version-in-file root "lib-src/rcs2log" copyright
 184                        (rx (and "Copyright" (0+ space) ?= (0+ space)
 185                                 ?\' (submatch (1+ nonl)))))
 186   (set-version-in-file
 187    root "mac/Emacs.app/Contents/Resources/English.lproj/InfoPlist.strings"
 188    copyright (rx (and "CFBundleGetInfoString" (0+ space) ?= (0+ space) ?\"
 189                       (1+ anything)
 190                       (submatch "Copyright" (1+ (not (in ?\")))))))
 191   ;; This one is a nuisance, as it needs to be split over two lines.
 192   (string-match "\\(.*[0-9]\\{4\\} *\\)\\(.*\\)" copyright)
 193   (let ((csign "\\0xa9")
 194         (cyear (match-string 1 copyright))  ; "Copyright (C) 2007 "
 195         (owner (match-string 2 copyright))) ; "Free Software Foundation, Inc."
 196     (set-version-in-file root "mac/src/Emacs.r"
 197                          (regexp-quote
 198                           (replace-regexp-in-string "(C)"
 199                                                     (regexp-quote csign) cyear))
 200                          (rx (and
 201                               (submatch "Copyright" (0+ space) (eval csign)
 202                                         (0+ space) (= 4 num)
 203                                         (0+ (not (in ?\")))) ?\")))
 204     (set-version-in-file root "mac/src/Emacs.r" owner
 205                          (rx (and ?\"
 206                               (submatch (1+ (not (in ?\"))))
 207                               ?\" (0+ space)
 208                               "/* Long version number */")))))
 209
 210 (provide 'admin)
 211
 212 ;;; arch-tag: 4ea83636-2293-408b-884e-ad64f22a3bf5
 213 ;; admin.el ends here.