lisp/iswitchb.el

   1 ;;; iswitchb.el --- switch between buffers using substrings
   2
   3 ;; Copyright (C) 1996, 1997  Free Software Foundation, Inc.
   4
   5 ;; Author: Stephen Eglen <stephen@anc.ed.ac.uk>
   6 ;; Maintainer: Stephen Eglen <stephen@anc.ed.ac.uk>
   7 ;; Keywords: extensions convenience
   8 ;; location: http://www.anc.ed.ac.uk/~stephen/emacs/
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Installation:
  30 ;; To get the functions in this package bound to keys, do
  31 ;; (iswitchb-default-keybindings)
  32
  33 ;; As you type in a substring, the list of buffers currently matching
  34 ;; the substring are displayed as you type.  The list is ordered so
  35 ;; that the most recent buffers visited come at the start of the list.
  36 ;; The buffer at the start of the list will be the one visited when
  37 ;; you press return.  By typing more of the substring, the list is
  38 ;; narrowed down so that gradually the buffer you want will be at the
  39 ;; top of the list.  Alternatively, you can use C-s an C-r to rotate
  40 ;; buffer names in the list until the one you want is at the top of
  41 ;; the list.  Completion is also available so that you can see what is
  42 ;; common to all of the matching buffers as you type.
  43
  44 ;; This code is similar to a couple of other packages.  Michael R Cook
  45 ;; <mcook@cognex.com> wrote a similar buffer switching package, but
  46 ;; does exact matching rather than substring matching on buffer names.
  47 ;; I also modified a couple of functions from icomplete.el to provide
  48 ;; the completion feedback in the minibuffer.
  49
  50 ;;; Example
  51
  52 ;;If I have two buffers called "123456" and "123", with "123456" the
  53 ;;most recent, when I use iswitchb, I first of all get presented with
  54 ;;the list of all the buffers
  55 ;;
  56 ;;       iswitch  {123456,123}
  57 ;;
  58 ;; If I then press 2:
  59 ;;       iswitch 2[3]{123456,123}
  60 ;;
  61 ;; The list in {} are the matching buffers, most recent first (buffers
  62 ;; visible in the current frame are put at the end of the list by
  63 ;; default).  At any time I can select the item at the head of the
  64 ;; list by pressing RET.  I can also bring the put the first element
  65 ;; at the end of the list by pressing C-s, or put the last element at
  66 ;; the head of the list by pressing C-r.  The item in [] indicates
  67 ;; what can be added to my input by pressing TAB.  In this case, I
  68 ;; will get "3" added to my input.  So, press TAB:
  69 ;;       iswitch 23{123456,123}
  70 ;;
  71 ;; At this point, I still have two matching buffers.
  72 ;; If I want the first buffer in the list, I simply press RET.  If I
  73 ;; wanted the second in the list, I could press C-s to move it to the
  74 ;; top of the list and then RET to select it.
  75 ;;
  76 ;;However, If I type 4, I only have one match left:
  77 ;;       iswitch 234[123456] [Matched]
  78 ;;
  79 ;;Since there is only one matching buffer left, it is given in [] and we
  80 ;;see the text [Matched] afterwards.  I can now press TAB or RET to go
  81 ;;to that buffer.
  82 ;;
  83 ;; If however, I now type "a":
  84 ;;       iswitch 234a [No match]
  85 ;; There are no matching buffers.  If I press RET or TAB, I can be
  86 ;; prompted to create a new buffer called "234a".
  87 ;;
  88 ;; Of course, where this function comes in really useful is when you
  89 ;; can specify the buffer using only a few keystrokes.  In the above
  90 ;; example, the quickest way to get to the "123456" buffer would be
  91 ;; just to type 4 and then RET (assuming there isn't any newer buffer
  92 ;; with 4 in its name).
  93
  94 ;; To see a full list of all matching buffers in a separate buffer,
  95 ;; hit ? or press TAB when there are no further completions to the
  96 ;; substring.  Repeated TAB presses will scroll you through this
  97 ;; separate buffer.
  98
  99 ;; The buffer at the head of the list can be killed by pressing C-k.
 100 ;; If the buffer needs saving, you will be queried before the buffer
 101 ;; is killed.
 102
 103 ;; If you find that the file you are after is not in a buffer, you can
 104 ;; press C-x C-f to immediately drop into find-file.
 105
 106 ;;
 107 ;;  See the doc string of iswitchb for full keybindings and features.
 108 ;;  (describe-function 'iswitchb)
 109
 110 ;;; Customisation
 111
 112 ;; See the User Variables section below for easy ways to change the
 113 ;; functionality of the program.  These are accessible using the
 114 ;; custom package.
 115 ;; To modify the keybindings, use the hook provided.  For example:
 116 ;;(add-hook 'iswitchb-define-mode-map-hook
 117 ;;        'iswitchb-my-keys)
 118 ;;
 119 ;;(defun iswitchb-my-keys ()
 120 ;;  "Add my keybindings for iswitchb."
 121 ;;  (define-key iswitchb-mode-map " " 'iswitchb-next-match)
 122 ;;  )
 123 ;;
 124 ;; Seeing all the matching buffers
 125 ;;
 126 ;; If you have many matching buffers, they may not all fit onto one
 127 ;; line of the minibuffer.  In this case, you should use rsz-mini
 128 ;; (resize-minibuffer-mode).  You can also limit iswitchb so that it
 129 ;; only shows a certain number of lines -- see the documentation for
 130 ;; `iswitchb-minibuffer-setup-hook'.
 131
 132 ;; Changing the list of buffers
 133
 134 ;; By default, the list of current buffers is most recent first,
 135 ;; oldest last, with the exception that the buffers visible in the
 136 ;; current frame are put at the end of the list.  A hook exists to
 137 ;; allow other functions to order the list.  For example, if you add:
 138 ;;
 139 ;; (add-hook 'iswitchb-make-buflist-hook 'iswitchb-summaries-to-end)
 140 ;;
 141 ;; then all buffers matching "Summary" are moved to the end of the
 142 ;; list.  (I find this handy for keeping the INBOX Summary and so on
 143 ;; out of the way.)  It also moves buffers matching "output\*$" to the
 144 ;; end of the list (these are created by AUC TeX when compiling.)
 145 ;; Other functions could be made available which alter the list of
 146 ;; matching buffers (either deleting or rearranging elements.)
 147
 148 ;; Font-Lock
 149
 150 ;; If you have font-lock loaded, the first matching buffer is
 151 ;; highlighted.  To switch this off, set (setq iswitchb-use-fonts nil)
 152 ;; I don't use font-lock that much, so I've hardcoded the faces.  If
 153 ;; this is too harsh, let me know.  Colouring of the matching buffer
 154 ;; name was suggested by Carsten Dominik (dominik@strw.leidenuniv.nl)
 155
 156 ;; Replacement for read-buffer
 157
 158 ;; iswitchb-read-buffer has been written to be a drop in replacement
 159 ;; for the normal buffer selection routine `read-buffer'.  To use
 160 ;; iswitch for all buffer selections in Emacs, add:
 161 ;; (setq read-buffer-function 'iswitchb-read-buffer)
 162 ;; (This variable should be present in Emacs 20.3+)
 163 ;; XEmacs users can get the same behaviour by doing:
 164 ;; (defalias 'read-buffer 'iswitchb-read-buffer)
 165 ;; since `read-buffer' is defined in lisp.
 166
 167 ;; Regexp matching
 168
 169 ;; There is limited provision for regexp matching within iswitchb,
 170 ;; enabled through `iswitchb-regexp'.  This allows you to type `c$'
 171 ;; for example and see all buffer names ending in `c'.  This facility
 172 ;; is quite limited though in two respects.  First, you can't
 173 ;; currently type in expressions like `[0-9]' directly -- you have to
 174 ;; type them in when iswitchb-regexp is nil and then toggle on the
 175 ;; regexp functionality.  Likewise, don't enter an expression
 176 ;; containing `\' in regexp mode.  If you try, iswitchb gets confused,
 177 ;; so just hit C-g and try again.  Secondly, no completion mechanism
 178 ;; is currently offered when regexp searching.
 179
 180 ;;; TODO
 181
 182 ;;; Acknowledgements
 183
 184 ;; Thanks to Jari Aalto <jari.aalto@poboxes.com> for help with the
 185 ;; first version of this package, iswitch-buffer.  Thanks also to many
 186 ;; others for testing earlier versions.
 187
 188 ;;; Code:
 189
 190 ;; CL needed for cadr and last
 191 (if (not (and (fboundp 'cadr)
 192               (fboundp 'last)))
 193     (require 'cl))
 194
 195 ;; Set up the custom library.
 196 ;; taken from http://www.dina.kvl.dk/~abraham/custom/
 197 (eval-and-compile
 198   (condition-case ()
 199       (require 'custom)
 200     (error nil))
 201   (if (and (featurep 'custom) (fboundp 'custom-declare-variable))
 202       nil ;; We've got what we needed
 203     ;; We have the old custom-library, hack around it!
 204     (defmacro defgroup (&rest args)
 205       nil)
 206     (defmacro defcustom (var value doc &rest args)
 207       (` (defvar (, var) (, value) (, doc))))))
 208
 209 ;;; User Variables
 210 ;;
 211 ;; These are some things you might want to change.
 212
 213 (defgroup iswitchb nil
 214   "Switch between buffers using substrings."
 215   :group 'extensions
 216   :group 'convenience
 217   ;; These links are to be added in later versions of custom and
 218   ;; so are currently commented out.
 219   :link '(emacs-commentary-link :tag "Commentary" "iswitchb.el")
 220   :link '(emacs-library-link :tag "Lisp File" "iswitchb.el"))
 221
 222 (defcustom iswitchb-case case-fold-search
 223   "*Non-nil if searching of buffer names should ignore case."
 224   :type 'boolean
 225   :group 'iswitchb)
 226
 227 (defcustom iswitchb-buffer-ignore
 228   '("^ ")
 229   "*List of regexps or functions matching buffer names to ignore.
 230 For example, traditional behavior is not to list buffers whose names begin
 231 with a space, for which the regexp is `^ '.  See the source file for
 232 example functions that filter buffernames."
 233   :type '(repeat regexp)
 234   :group 'iswitchb)
 235
 236 ;;; Examples for setting the value of iswitchb-buffer-ignore
 237 ;(defun iswitchb-ignore-c-mode (name)
 238 ;  "Ignore all c mode buffers -- example function for iswitchb."
 239 ;  (save-excursion
 240 ;    (set-buffer name)
 241 ;    (string-match "^C$" mode-name)))
 242
 243 ;(setq iswitchb-buffer-ignore '("^ " iswitchb-ignore-c-mode))
 244 ;(setq iswitchb-buffer-ignore '("^ " "\\.c$" "\\.h$"))
 245
 246 (defcustom iswitchb-default-method  'always-frame
 247     "*How to switch to new buffer when using `iswitchb-buffer'.
 248 Possible values:
 249 `samewindow'    Show new buffer in same window
 250 `otherwindow'   Show new buffer in another window (same frame)
 251 `display'       Display buffer in another window without switching to it
 252 `otherframe'    Show new buffer in another frame
 253 `maybe-frame'   If a buffer is visible in another frame, prompt to ask if you
 254                 you want to see the buffer in the same window of the current
 255                 frame or in the other frame.
 256 `always-frame'  If a buffer is visible in another frame, raise that
 257                 frame.  Otherwise, visit the buffer in the same window."
 258     :type '(choice (const samewindow)
 259                    (const otherwindow)
 260                    (const display)
 261                    (const otherframe)
 262                    (const maybe-frame)
 263                    (const always-frame))
 264     :group 'iswitchb)
 265
 266 (defcustom iswitchb-regexp nil
 267   "*Non-nil means that `iswitchb' will do regexp matching.
 268 Value can be toggled within `iswitchb' using `iswitchb-toggle-regexp'."
 269   :type 'boolean
 270   :group 'iswitchb)
 271
 272 (defcustom iswitchb-newbuffer t
 273   "*Non-nil means create new buffer if no buffer matches substring.
 274 See also `iswitchb-prompt-newbuffer'."
 275   :type 'boolean
 276   :group 'iswitchb)
 277
 278 (defcustom iswitchb-prompt-newbuffer t
 279   "*Non-nil means prompt user to confirm before creating new buffer.
 280 See also `iswitchb-newbuffer'."
 281   :type 'boolean
 282   :group 'iswitchb)
 283
 284 (defcustom iswitchb-define-mode-map-hook  nil
 285   "*Hook to define keys in `iswitchb-mode-map' for extra keybindings."
 286   :type 'hook
 287   :group 'iswitchb)
 288
 289 (defcustom iswitchb-use-fonts t
 290   "*Non-nil means use font-lock fonts for showing first match."
 291   :type 'boolean
 292   :group 'iswitchb)
 293
 294 (defcustom iswitchb-make-buflist-hook  nil
 295   "*Hook to run when list of matching buffers is created."
 296   :type 'hook
 297   :group 'iswitchb)
 298
 299 (defvar iswitchb-all-frames 'visible
 300   "*Argument to pass to `walk-windows' when finding visible buffers.
 301 See documentation of `walk-windows' for useful values.")
 302
 303 (defcustom iswitchb-minibuffer-setup-hook nil
 304   "*Iswitchb-specific customization of minibuffer setup.
 305
 306 This hook is run during minibuffer setup iff `iswitchb' will be active.
 307 It is intended for use in customizing iswitchb for interoperation
 308 with other packages.  For instance:
 309
 310   \(add-hook 'iswitchb-minibuffer-setup-hook
 311             \(function
 312              \(lambda ()
 313                \(make-local-variable 'resize-minibuffer-window-max-height)
 314                \(setq resize-minibuffer-window-max-height 3))))
 315
 316 will constrain rsz-mini to a maximum minibuffer height of 3 lines when
 317 iswitchb is running.  Copied from `icomplete-minibuffer-setup-hook'."
 318   :type 'hook
 319   :group 'iswitchb)
 320
 321 ;; Do we need the variable iswitchb-use-mycompletion?
 322
 323 ;;; Internal Variables
 324
 325 (defvar iswitchb-method nil
 326   "Stores the method for viewing the selected buffer.
 327 Its value is one of `samewindow', `otherwindow', `display', `otherframe',
 328 `maybe-frame' or `always-frame'.  See `iswitchb-default-method' for
 329 details of values.")
 330
 331 (defvar iswitchb-eoinput 1
 332   "Point where minibuffer input ends and completion info begins.
 333 Copied from `icomplete-eoinput'.")
 334 (make-variable-buffer-local 'iswitchb-eoinput)
 335
 336 (defvar iswitchb-buflist nil
 337   "Stores the current list of buffers that will be searched through.
 338 The list is ordered, so that the most recent buffers come first,
 339 although by default, the buffers visible in the current frame are put
 340 at the end of the list.  Created by `iswitchb-make-buflist'.")
 341
 342 ;; todo -- is this necessary?
 343
 344 (defvar iswitchb-use-mycompletion nil
 345   "Non-nil means use `iswitchb-buffer' completion feedback.
 346 Should only be set to t by iswitchb functions, so that it doesn't
 347 interfere with other minibuffer usage.")
 348
 349 (defvar iswitchb-change-word-sub nil
 350   "Private variable used by `iswitchb-word-matching-substring'.")
 351
 352 (defvar iswitchb-common-match-string  nil
 353   "Stores the string that is common to all matching buffers.")
 354
 355 (defvar iswitchb-rescan nil
 356   "Non-nil means we need to regenerate the list of matching buffers.")
 357
 358 (defvar iswitchb-text nil
 359   "Stores the users string as it is typed in.")
 360
 361 (defvar iswitchb-matches nil
 362   "List of buffers currently matching `iswitchb-text'.")
 363
 364 (defvar iswitchb-mode-map nil
 365   "Keymap for `iswitchb-buffer'.")
 366
 367 (defvar  iswitchb-history nil
 368   "History of buffers selected using `iswitchb-buffer'.")
 369
 370 (defvar iswitchb-exit nil
 371   "Flag to monitor how `iswitchb-buffer' exits.
 372 If equal to `takeprompt', we use the prompt as the buffer name to be
 373 selected.")
 374
 375 (defvar iswitchb-buffer-ignore-orig nil
 376   "Stores original value of `iswitchb-buffer-ignore'.")
 377
 378 (defvar iswitchb-xemacs  (string-match "XEmacs" (emacs-version))
 379   "Non-nil if we are running XEmacs.  Otherwise, assume we are running Emacs.")
 380
 381 (defvar iswitchb-default nil
 382   "Default buffer for iswitchb.")
 383
 384 ;; The following variables are needed to keep the byte compiler quiet.
 385 (defvar iswitchb-require-match nil
 386   "Non-nil if matching buffer must be selected.")
 387
 388 (defvar iswitchb-temp-buflist nil
 389   "Stores a temporary version of the buffer list being created.")
 390
 391 (defvar iswitchb-bufs-in-frame nil
 392   "List of the buffers visible in the current frame.")
 393
 394 ;;; FUNCTIONS
 395
 396 ;;; ISWITCHB KEYMAP
 397 (defun iswitchb-define-mode-map ()
 398   "Set up the keymap for `iswitchb-buffer'."
 399   (interactive)
 400   (let (map)
 401     ;; generated every time so that it can inherit new functions.
 402     ;;(or iswitchb-mode-map
 403
 404     (setq map (copy-keymap minibuffer-local-map))
 405     (define-key map "?" 'iswitchb-completion-help)
 406     (define-key map "\C-s" 'iswitchb-next-match)
 407     (define-key map "\C-r" 'iswitchb-prev-match)
 408     (define-key map "\t" 'iswitchb-complete)
 409     (define-key map "\C-j" 'iswitchb-select-buffer-text)
 410     (define-key map "\C-t" 'iswitchb-toggle-regexp)
 411     (define-key map "\C-x\C-f" 'iswitchb-find-file)
 412     ;;(define-key map "\C-a" 'iswitchb-toggle-ignore)
 413     (define-key map "\C-c" 'iswitchb-toggle-case)
 414     (define-key map "\C-k" 'iswitchb-kill-buffer)
 415     (define-key map "\C-m" 'iswitchb-exit-minibuffer)
 416     (setq iswitchb-mode-map map)
 417     (run-hooks 'iswitchb-define-mode-map-hook)))
 418
 419 ;;; MAIN FUNCTION
 420 (defun iswitchb ()
 421   "Switch to buffer matching a substring.
 422 As you type in a string, all of the buffers matching the string are
 423 displayed.  When you have found the buffer you want, it can then be
 424 selected.  As you type, most keys have their normal keybindings,
 425 except for the following:
 426 \\<iswitchb-mode-map>
 427
 428 RET Select the buffer at the front of the list of matches.  If the
 429 list is empty, possibly prompt to create new buffer.
 430
 431 \\[iswitchb-select-buffer-text] Select the current prompt as the buffer.
 432 If no buffer is found, prompt for a new one.
 433
 434 \\[iswitchb-next-match] Put the first element at the end of the list.
 435 \\[iswitchb-prev-match] Put the last element at the start of the list.
 436 \\[iswitchb-complete] Complete a common suffix to the current string that
 437 matches all buffers.  If there is only one match, select that buffer.
 438 If there is no common suffix, show a list of all matching buffers
 439 in a separate window.
 440 \\[iswitchb-toggle-regexp] Toggle regexp searching.
 441 \\[iswitchb-toggle-case] Toggle case-sensitive searching of buffer names.
 442 \\[iswitchb-completion-help] Show list of matching buffers in separate window.
 443 \\[iswitchb-find-file] Exit iswitchb and drop into find-file.
 444 \\[iswitchb-kill-buffer] Kill buffer at head of buffer list."
 445   ;;\\[iswitchb-toggle-ignore] Toggle ignoring certain buffers (see \
 446   ;;`iswitchb-buffer-ignore')
 447
 448   (let
 449       (prompt buf)
 450
 451     (setq prompt (format "iswitch "))
 452
 453     (setq buf (iswitchb-read-buffer prompt))
 454
 455     ;;(message "chosen text %s" iswitchb-final-text)
 456     ;; Choose the buffer name: either the text typed in, or the head
 457     ;; of the list of matches
 458
 459     (cond ( (eq iswitchb-exit 'findfile)
 460             (call-interactively 'find-file))
 461
 462           (t
 463            ;; View the buffer
 464            ;;(message "go to buf %s" buf)
 465            ;; Check buf is non-nil.
 466            (if buf
 467                (if (get-buffer buf)
 468                    ;; buffer exists, so view it and then exit
 469                    (iswitchb-visit-buffer buf)
 470                  ;; else buffer doesn't exist
 471                  (iswitchb-possible-new-buffer buf)))
 472            ))))
 473
 474 ;;;###autoload
 475 (defun iswitchb-read-buffer (prompt &optional default require-match)
 476   "Replacement for the built-in `read-buffer'.
 477 Return the name of a buffer selected.
 478 PROMPT is the prompt to give to the user.  DEFAULT if given is the default
 479 buffer to be selected, which will go to the front of the list.
 480 If REQUIRE-MATCH is non-nil, an existing-buffer must be selected."
 481   (let
 482       (
 483        buf-sel
 484        iswitchb-final-text
 485        (icomplete-mode nil) ;; prevent icomplete starting up
 486        ;; can only use fonts if they have been bound.
 487        (iswitchb-use-fonts (and iswitchb-use-fonts
 488                                 (boundp 'font-lock-comment-face)
 489                                 (boundp 'font-lock-function-name-face))))
 490
 491     (iswitchb-define-mode-map)
 492     (setq iswitchb-exit nil)
 493     (setq iswitchb-rescan t)
 494     (setq iswitchb-text "")
 495     (setq iswitchb-default
 496           (if (bufferp default)
 497               (buffer-name default)
 498             default))
 499     (iswitchb-make-buflist iswitchb-default)
 500     (iswitchb-set-matches)
 501     (let
 502         ((minibuffer-local-completion-map iswitchb-mode-map)
 503          (iswitchb-prepost-hooks t)
 504          (iswitchb-require-match require-match))
 505       ;; prompt the user for the buffer name
 506       (setq iswitchb-final-text (completing-read
 507                                  prompt ;the prompt
 508                                  '(("dummy".1)) ;table
 509                                  nil    ;predicate
 510                                  nil    ;require-match [handled elsewhere]
 511                                  nil    ;initial-contents
 512                                  'iswitchb-history)))
 513     ;; Handling the require-match must be done in a better way.
 514     (if (and require-match (not (iswitchb-existing-buffer-p)))
 515         (error "must specify valid buffer"))
 516
 517     (if (or
 518          (eq iswitchb-exit 'takeprompt)
 519          (null iswitchb-matches))
 520         (setq buf-sel iswitchb-final-text)
 521       ;; else take head of list
 522       (setq buf-sel (car iswitchb-matches)))
 523
 524     ;; Or possibly choose the default buffer
 525     (if  (equal iswitchb-final-text "")
 526         (setq buf-sel
 527               (car iswitchb-matches)))
 528
 529     buf-sel))
 530
 531 (defun iswitchb-existing-buffer-p ()
 532   "Return non-nil if there is a matching buffer."
 533   (not (null iswitchb-matches)))
 534
 535 ;;; COMPLETION CODE
 536
 537 (defun iswitchb-set-common-completion  ()
 538   "Find common completion of `iswitchb-text' in `iswitchb-matches'.
 539 The result is stored in `iswitchb-common-match-string'."
 540
 541   (let* (val)
 542     (setq  iswitchb-common-match-string nil)
 543     (if (and iswitchb-matches
 544              (not iswitchb-regexp) ;; testing
 545              (stringp iswitchb-text)
 546              (> (length iswitchb-text) 0))
 547         (if (setq val (iswitchb-find-common-substring
 548                        iswitchb-matches iswitchb-text))
 549             (setq iswitchb-common-match-string val)))
 550     val))
 551
 552 (defun iswitchb-complete ()
 553   "Try and complete the current pattern amongst the buffer names."
 554   (interactive)
 555   (let (res)
 556     (cond ((not  iswitchb-matches)
 557            (iswitchb-completion-help))
 558
 559           ((= 1 (length iswitchb-matches))
 560            ;; only one choice, so select it.
 561            (exit-minibuffer))
 562
 563           (t
 564            ;; else there could be some completions
 565            (setq res iswitchb-common-match-string)
 566            (if (and (not (memq res '(t nil)))
 567                     (not (equal res iswitchb-text)))
 568                ;; found something to complete, so put it in the minibuffer.
 569                (progn
 570                  (setq iswitchb-rescan nil)
 571                  (delete-region (point-min) (point))
 572                  (insert  res))
 573              ;; else nothing to complete
 574              (iswitchb-completion-help)
 575              )))))
 576
 577 ;;; TOGGLE FUNCTIONS
 578
 579 (defun iswitchb-toggle-case ()
 580   "Toggle the value of `iswitchb-case'."
 581   (interactive)
 582   (setq iswitchb-case (not iswitchb-case))
 583   ;; ask for list to be regenerated.
 584   (setq iswitchb-rescan t))
 585
 586 (defun iswitchb-toggle-regexp ()
 587   "Toggle the value of `iswitchb-regexp'."
 588   (interactive)
 589   (setq iswitchb-regexp (not iswitchb-regexp))
 590   ;; ask for list to be regenerated.
 591   (setq iswitchb-rescan t))
 592
 593 (defun iswitchb-toggle-ignore ()
 594   "Toggle ignoring buffers specified with `iswitchb-buffer-ignore'."
 595   (interactive)
 596   (if iswitchb-buffer-ignore
 597       (progn
 598         (setq iswitchb-buffer-ignore-orig iswitchb-buffer-ignore)
 599         (setq iswitchb-buffer-ignore nil))
 600     ;; else
 601     (setq iswitchb-buffer-ignore iswitchb-buffer-ignore-orig))
 602   (iswitchb-make-buflist iswitchb-default)
 603   ;; ask for list to be regenerated.
 604   (setq iswitchb-rescan t))
 605
 606 (defun iswitchb-exit-minibuffer ()
 607   "Exit minibuffer, but make sure we have a match if one is needed."
 608   (interactive)
 609   (if (or (not iswitchb-require-match)
 610            (iswitchb-existing-buffer-p))
 611       (throw 'exit nil)))
 612
 613 (defun iswitchb-select-buffer-text ()
 614   "Select the buffer named by the prompt.
 615 If no buffer exactly matching the prompt exists, maybe create a new one."
 616   (interactive)
 617   (setq iswitchb-exit 'takeprompt)
 618   (exit-minibuffer))
 619
 620 (defun iswitchb-find-file ()
 621   "Drop into find-file from buffer switching."
 622   (interactive)
 623   (setq iswitchb-exit 'findfile)
 624   (exit-minibuffer))
 625
 626 (defun iswitchb-next-match ()
 627   "Put first element of `iswitchb-matches' at the end of the list."
 628   (interactive)
 629   (let ((next  (cadr iswitchb-matches)))
 630     (setq iswitchb-buflist (iswitchb-chop iswitchb-buflist next))
 631     (setq iswitchb-rescan t)))
 632
 633 (defun iswitchb-prev-match ()
 634   "Put last element of `iswitchb-matches' at the front of the list."
 635   (interactive)
 636   (let ((prev  (car (last iswitchb-matches))))
 637     (setq iswitchb-buflist (iswitchb-chop iswitchb-buflist prev))
 638     (setq iswitchb-rescan t)))
 639
 640 (defun iswitchb-chop (list elem)
 641   "Remove all elements before ELEM and put them at the end of LIST."
 642   (let ((ret nil)
 643         (next nil)
 644         (sofar nil))
 645     (while (not ret)
 646       (setq next (car list))
 647       (if (equal next elem)
 648           (setq ret (append list (nreverse sofar)))
 649         ;; else
 650         (progn
 651           (setq list (cdr list))
 652           (setq sofar (cons next sofar)))))
 653     ret))
 654
 655 ;;; CREATE LIST OF ALL CURRENT BUFFERS
 656
 657 (defun iswitchb-make-buflist (default)
 658   "Set `iswitchb-buflist' to the current list of buffers.
 659 Currently visible buffers are put at the end of the list.
 660 The hook `iswitchb-make-buflist-hook' is run after the list has been
 661 created to allow the user to further modify the order of the buffer names
 662 in this list.  If DEFAULT is non-nil, and corresponds to an existing buffer,
 663 it is put to the start of the list."
 664   (setq iswitchb-buflist
 665         (let* ((iswitchb-current-buffers (iswitchb-get-buffers-in-frames))
 666               (iswitchb-temp-buflist
 667                (delq nil
 668                      (mapcar
 669                       (lambda (x)
 670                         (let ((b-name (buffer-name x)))
 671                           (if (not
 672                                (or
 673                                 (iswitchb-ignore-buffername-p b-name)
 674                                 (memq b-name iswitchb-current-buffers)))
 675                               b-name)))
 676                       (buffer-list)))))
 677           (nconc iswitchb-temp-buflist iswitchb-current-buffers)
 678           (run-hooks 'iswitchb-make-buflist-hook)
 679           ;; Should this be after the hooks, or should the hooks be the
 680           ;; final thing to be run?
 681           (if default
 682               (progn
 683                 (setq iswitchb-temp-buflist
 684                       (delete default iswitchb-temp-buflist))
 685                 (setq iswitchb-temp-buflist
 686                       (cons default iswitchb-temp-buflist))))
 687           iswitchb-temp-buflist)))
 688
 689 (defun iswitchb-to-end (lst)
 690   "Move the elements from LST to the end of `iswitchb-temp-buflist'."
 691   (mapcar
 692    (lambda (elem)
 693      (setq iswitchb-temp-buflist (delq elem iswitchb-temp-buflist)))
 694    lst)
 695   (nconc iswitchb-temp-buflist lst))
 696
 697 (defun iswitchb-get-buffers-in-frames (&optional current)
 698   "Return the list of buffers that are visible in the current frame.
 699 If optional argument `current' is given, restrict searching to the
 700 current frame, rather than all frames, regardless of value of
 701 `iswitchb-all-frames'."
 702   (let ((iswitchb-bufs-in-frame nil))
 703     (walk-windows 'iswitchb-get-bufname nil
 704                   (if current
 705                       nil
 706                     iswitchb-all-frames))
 707     iswitchb-bufs-in-frame))
 708
 709 (defun iswitchb-get-bufname (win)
 710   "Used by `iswitchb-get-buffers-in-frames' to walk through all windows."
 711   (let ((buf (buffer-name (window-buffer win))))
 712         (if (not (member buf iswitchb-bufs-in-frame))
 713             ;; Only add buf if it is not already in list.
 714             ;; This prevents same buf in two different windows being
 715             ;; put into the list twice.
 716             (setq iswitchb-bufs-in-frame
 717                   (cons buf iswitchb-bufs-in-frame)))))
 718
 719 ;;; FIND MATCHING BUFFERS
 720
 721 (defun iswitchb-set-matches ()
 722   "Set `iswitchb-matches' to the list of buffers matching prompt."
 723   (if iswitchb-rescan
 724       (setq iswitchb-matches
 725             (let* ((buflist iswitchb-buflist))
 726               (iswitchb-get-matched-buffers iswitchb-text iswitchb-regexp
 727                                             buflist)))))
 728
 729 (defun iswitchb-get-matched-buffers (regexp
 730                                      &optional string-format buffer-list)
 731   "Return buffers matching REGEXP.
 732 If STRING-FORMAT is nil, consider REGEXP as just a string.
 733 BUFFER-LIST can be list of buffers or list of strings."
 734   (let* ((case-fold-search  iswitchb-case)
 735          ;; need reverse since we are building up list backwards
 736          (list              (reverse buffer-list))
 737          (do-string         (stringp (car list)))
 738          name
 739          ret)
 740     (mapcar
 741      (lambda (x)
 742
 743        (if do-string
 744            (setq name x)               ;We already have the name
 745          (setq name (buffer-name x)))
 746
 747        (cond
 748         ((and (or (and string-format (string-match regexp name))
 749                   (and (null string-format)
 750                        (string-match (regexp-quote regexp) name)))
 751
 752               (not (iswitchb-ignore-buffername-p name)))
 753          (setq ret (cons name ret))
 754           )))
 755      list)
 756     ret))
 757
 758 (defun iswitchb-ignore-buffername-p (bufname)
 759   "Return t if the buffer BUFNAME should be ignored."
 760   (let ((data       (match-data))
 761         (re-list    iswitchb-buffer-ignore)
 762         ignorep
 763         nextstr)
 764     (while re-list
 765       (setq nextstr (car re-list))
 766       (cond
 767        ((stringp nextstr)
 768         (if (string-match nextstr bufname)
 769             (progn
 770               (setq ignorep t)
 771               (setq re-list nil))))
 772        ((fboundp nextstr)
 773         (if (funcall nextstr bufname)
 774             (progn
 775               (setq ignorep t)
 776               (setq re-list nil)))))
 777       (setq re-list (cdr re-list)))
 778     (set-match-data data)
 779
 780     ;; return the result
 781     ignorep))
 782
 783 (defun iswitchb-word-matching-substring (word)
 784   "Return part of WORD before 1st match to `iswitchb-change-word-sub'.
 785 If `iswitchb-change-word-sub' cannot be found in WORD, return nil."
 786   (let ((case-fold-search iswitchb-case))
 787     (let ((m (string-match iswitchb-change-word-sub word)))
 788       (if m
 789           (substring word m)
 790         ;; else no match
 791         nil))))
 792
 793 (defun iswitchb-find-common-substring (lis subs)
 794   "Return common string following SUBS in each element of LIS."
 795   (let (res
 796         alist
 797         iswitchb-change-word-sub)
 798     (setq iswitchb-change-word-sub
 799           (if iswitchb-regexp
 800               subs
 801             (regexp-quote subs)))
 802     (setq res (mapcar 'iswitchb-word-matching-substring lis))
 803     (setq res (delq nil res)) ;; remove any nil elements (shouldn't happen)
 804     (setq alist (mapcar 'iswitchb-makealist res)) ;; could use an  OBARRAY
 805
 806     ;; try-completion returns t if there is an exact match.
 807     (let ((completion-ignore-case iswitchb-case))
 808
 809     (try-completion subs alist))))
 810
 811 (defun iswitchb-makealist (res)
 812   "Return dotted pair (RES . 1)."
 813   (cons res 1))
 814
 815 ;; from Wayne Mesard <wmesard@esd.sgi.com>
 816 (defun iswitchb-rotate-list (lis)
 817   "Destructively removes the last element from LIS.
 818 Return the modified list with the last element prepended to it."
 819   (if (<= (length lis) 1)
 820       lis
 821     (let ((las lis)
 822           (prev lis))
 823       (while (consp (cdr las))
 824         (setq prev las
 825               las (cdr las)))
 826       (setcdr prev nil)
 827       (cons (car las) lis))))
 828
 829 (defun iswitchb-completion-help ()
 830   "Show possible completions in a *Buffer Completions* buffer."
 831   ;; we could allow this buffer to be used to select match, but I think
 832   ;; choose-completion-string will need redefining, so it just inserts
 833   ;; choice with out any previous input.
 834   (interactive)
 835   (setq iswitchb-rescan nil)
 836   (let ((completion-setup-hook nil)     ;disable fancy highlight/selection.
 837         (buf (current-buffer))
 838         (temp-buf "*Buffer Completions*")
 839         (win)
 840         (again (eq last-command this-command)))
 841
 842     (if again
 843         ;; scroll buffer
 844         (progn
 845           (set-buffer temp-buf)
 846           (setq win (get-buffer-window temp-buf))
 847           (if (pos-visible-in-window-p (point-max) win)
 848               (set-window-start win (point-min))
 849             (scroll-other-window))
 850           (set-buffer buf))
 851
 852       (with-output-to-temp-buffer temp-buf
 853         (if iswitchb-xemacs
 854
 855             ;; XEmacs extents are put on by default, doesn't seem to be
 856             ;; any way of switching them off.
 857             (display-completion-list (if iswitchb-matches
 858                                          iswitchb-matches
 859                                        iswitchb-buflist)
 860                                      :help-string "iswitchb "
 861                                    :activate-callback
 862                                    '(lambda (x y z)
 863                                       (message "doesn't work yet, sorry!")))
 864           ;; else running Emacs
 865           (display-completion-list (if iswitchb-matches
 866                                      iswitchb-matches
 867                                      iswitchb-buflist))
 868           )))))
 869
 870 ;;; KILL CURRENT BUFFER
 871
 872 (defun iswitchb-kill-buffer ()
 873   "Kill the buffer at the head of `iswitchb-matches'."
 874   (interactive)
 875   (let ( (enable-recursive-minibuffers t)
 876          buf)
 877
 878     (setq buf (car iswitchb-matches))
 879     ;; check to see if buf is non-nil.
 880     (if buf
 881         (progn
 882           (kill-buffer buf)
 883
 884           ;; Check if buffer exists.  XEmacs gnuserv.el makes alias
 885           ;; for kill-buffer which does not return t if buffer is
 886           ;; killed, so we can't rely on kill-buffer return value.
 887           (if (get-buffer buf)
 888               ;; buffer couldn't be killed.
 889               (setq iswitchb-rescan t)
 890             ;; else buffer was killed so remove name from list.
 891             (setq iswitchb-buflist  (delq buf iswitchb-buflist)))))))
 892
 893 ;;; VISIT CHOSEN BUFFER
 894 (defun iswitchb-visit-buffer (buffer)
 895   "Visit buffer named BUFFER according to `iswitchb-method'."
 896   (let* (win  newframe)
 897     (cond
 898      ((eq iswitchb-method 'samewindow)
 899       (switch-to-buffer buffer))
 900
 901      ((memq iswitchb-method '(always-frame maybe-frame))
 902       (cond
 903        ((and (setq win (iswitchb-window-buffer-p buffer))
 904              (or (eq iswitchb-method 'always-frame)
 905                  (y-or-n-p "Jump to frame? ")))
 906         (setq newframe (window-frame win))
 907         (raise-frame newframe)
 908         (select-frame newframe)
 909         (select-window win)
 910         (if (not iswitchb-xemacs)
 911             ;; reposition mouse to make frame active.  not needed in XEmacs
 912             ;; This line came from the other-frame defun in Emacs.
 913             (set-mouse-position (selected-frame) (1- (frame-width)) 0)))
 914        (t
 915         ;;  No buffer in other frames...
 916         (switch-to-buffer buffer)
 917         )))
 918
 919      ((eq iswitchb-method 'otherwindow)
 920       (switch-to-buffer-other-window buffer))
 921
 922      ((eq iswitchb-method 'display)
 923       (display-buffer buffer))
 924
 925      ((eq iswitchb-method 'otherframe)
 926       (progn
 927         (switch-to-buffer-other-frame buffer)
 928         (if (not iswitchb-xemacs)
 929             (set-mouse-position (selected-frame) (1- (frame-width)) 0))
 930         )))))
 931
 932 (defun iswitchb-possible-new-buffer (buf)
 933   "Possibly create and visit a new buffer called BUF."
 934
 935   (let ((newbufcreated))
 936     (if (and iswitchb-newbuffer
 937              (or
 938               (not iswitchb-prompt-newbuffer)
 939
 940               (and iswitchb-prompt-newbuffer
 941                    (y-or-n-p
 942                     (format
 943                      "No buffer matching `%s', create one? "
 944                      buf)))))
 945         ;; then create a new buffer
 946         (progn
 947           (setq newbufcreated (get-buffer-create buf))
 948           (if (fboundp 'set-buffer-major-mode)
 949               (set-buffer-major-mode newbufcreated))
 950           (iswitchb-visit-buffer newbufcreated))
 951       ;; else wont create new buffer
 952       (message (format "no buffer matching `%s'" buf)))))
 953
 954 (defun iswitchb-window-buffer-p  (buffer)
 955   "Return window pointer if BUFFER is visible in another frame.
 956 If BUFFER is visible in the current frame, return nil."
 957   (interactive)
 958   (let ((blist (iswitchb-get-buffers-in-frames 'current)))
 959     ;;If the buffer is visible in current frame, return nil
 960     (if (memq buffer blist)
 961         nil
 962       ;;  maybe in other frame or icon
 963       (get-buffer-window buffer 0) ; better than 'visible
 964       )))
 965
 966 ;;;###autoload
 967 (defun iswitchb-default-keybindings ()
 968   "Set up default keybindings for `iswitchb-buffer'.
 969 Call this function to override the normal bindings.  This function also
 970 adds a hook to the minibuffer."
 971   (interactive)
 972   (add-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)
 973   (global-set-key (read-kbd-macro "C-x b")  'iswitchb-buffer)
 974   (global-set-key (read-kbd-macro "C-x 4 b")  'iswitchb-buffer-other-window)
 975   (global-set-key (read-kbd-macro "C-x 4 C-o")  'iswitchb-display-buffer)
 976   (global-set-key (read-kbd-macro "C-x 5 b")  'iswitchb-buffer-other-frame))
 977
 978 ;;;###autoload
 979 (defun iswitchb-buffer ()
 980   "Switch to another buffer.
 981
 982 The buffer name is selected interactively by typing a substring.  The
 983 buffer is displayed according to `iswitchb-default-method' -- the
 984 default is to show it in the same window, unless it is already visible
 985 in another frame.
 986 For details of keybindings, do `\\[describe-function] iswitchb'."
 987   (interactive)
 988   (setq iswitchb-method iswitchb-default-method)
 989   (iswitchb))
 990
 991 ;;;###autoload
 992 (defun iswitchb-buffer-other-window ()
 993   "Switch to another buffer and show it in another window.
 994 The buffer name is selected interactively by typing a substring.
 995 For details of keybindings, do `\\[describe-function] iswitchb'."
 996   (interactive)
 997   (setq iswitchb-method 'otherwindow)
 998   (iswitchb))
 999
1000 ;;;###autoload
1001 (defun iswitchb-display-buffer ()
1002   "Display a buffer in another window but don't select it.
1003 The buffer name is selected interactively by typing a substring.
1004 For details of keybindings, do `\\[describe-function] iswitchb'."
1005   (interactive)
1006   (setq iswitchb-method 'display)
1007   (iswitchb))
1008
1009 ;;;###autoload
1010 (defun iswitchb-buffer-other-frame ()
1011   "Switch to another buffer and show it in another frame.
1012 The buffer name is selected interactively by typing a substring.
1013 For details of keybindings, do `\\[describe-function] iswitchb'."
1014   (interactive)
1015   (setq iswitchb-method 'otherframe)
1016   (iswitchb))
1017
1018 ;;; XEmacs hack for showing default buffer
1019
1020 ;; The first time we enter the minibuffer, Emacs puts up the default
1021 ;; buffer to switch to, but XEmacs doesn't -- presumably there is a
1022 ;; subtle difference in the two versions of post-command-hook.  The
1023 ;; default is shown for both whenever we delete all of our text
1024 ;; though, indicating its just a problem the first time we enter the
1025 ;; function.  To solve this, we use another entry hook for emacs to
1026 ;; show the default the first time we enter the minibuffer.
1027
1028 (defun iswitchb-init-XEmacs-trick ()
1029   "Display default buffer when first entering minibuffer.
1030 This is a hack for XEmacs, and should really be handled by `iswitchb-exhibit'."
1031   (if (iswitchb-entryfn-p)
1032       (progn
1033         (iswitchb-exhibit)
1034         (goto-char (point-min)))))
1035
1036 ;; add this hook for XEmacs only.
1037 (if iswitchb-xemacs
1038     (add-hook 'iswitchb-minibuffer-setup-hook
1039               'iswitchb-init-XEmacs-trick))
1040
1041 ;;; XEmacs / backspace key
1042 ;; For some reason, if the backspace key is pressed in XEmacs, the
1043 ;; line gets confused, so I've added a simple key definition to make
1044 ;; backspace act like the normal delete key.
1045
1046 (defun iswitchb-xemacs-backspacekey ()
1047   "Bind backspace to `backward-delete-char'."
1048   (define-key iswitchb-mode-map '[backspace] 'backward-delete-char)
1049   (define-key iswitchb-mode-map '[(meta backspace)] 'backward-kill-word))
1050
1051 (if iswitchb-xemacs
1052     (add-hook 'iswitchb-define-mode-map-hook
1053               'iswitchb-xemacs-backspacekey))
1054
1055 ;;; ICOMPLETE TYPE CODE
1056
1057 (defun iswitchb-exhibit ()
1058   "Find matching buffers and display a list in the minibuffer.
1059 Copied from `icomplete-exhibit' with two changes:
1060 1. It prints a default buffer name when there is no text yet entered.
1061 2. It calls my completion routine rather than the standard completion."
1062
1063   (if iswitchb-use-mycompletion
1064       (let ((contents (buffer-substring (point-min)(point-max)))
1065             (buffer-undo-list t))
1066         (save-excursion
1067           (goto-char (point-max))
1068                                         ; Register the end of input, so we
1069                                         ; know where the extra stuff
1070                                         ; (match-status info) begins:
1071           (if (not (boundp 'iswitchb-eoinput))
1072               ;; In case it got wiped out by major mode business:
1073               (make-local-variable 'iswitchb-eoinput))
1074           (setq iswitchb-eoinput (point))
1075           ;; Update the list of matches
1076           (setq iswitchb-text contents)
1077           (iswitchb-set-matches)
1078           (setq iswitchb-rescan t)
1079           (iswitchb-set-common-completion)
1080
1081           ;; Insert the match-status information:
1082           (insert-string
1083            (iswitchb-completions
1084             contents
1085             minibuffer-completion-table
1086             minibuffer-completion-predicate
1087             (not minibuffer-completion-confirm)))
1088           ))))
1089
1090 (defun iswitchb-completions
1091   (name candidates predicate require-match)
1092   "Return the string that is displayed after the user's text.
1093 Modified from `icomplete-completions'."
1094
1095   (let ((comps iswitchb-matches)
1096                                         ; "-determined" - only one candidate
1097         (open-bracket-determined (if require-match "(" "["))
1098         (close-bracket-determined (if require-match ")" "]"))
1099                                         ;"-prospects" - more than one candidate
1100         (open-bracket-prospects "{")
1101         (close-bracket-prospects "}")
1102         first)
1103
1104     (if (and iswitchb-use-fonts  comps)
1105         (progn
1106           (setq first (car comps))
1107           (setq first (format "%s" first))
1108           (put-text-property 0 (length first) 'face
1109                              (if (= (length comps) 1)
1110                                  'font-lock-comment-face
1111                                'font-lock-function-name-face)
1112                              first)
1113           (setq comps  (cons first (cdr comps)))))
1114
1115     (cond ((null comps) (format " %sNo match%s"
1116                                 open-bracket-determined
1117                                 close-bracket-determined))
1118
1119           ((null (cdr comps))           ;one match
1120            (concat (if (and (> (length (car comps))
1121                                (length name)))
1122                        (concat open-bracket-determined
1123                                ;; when there is one match, show the
1124                                ;; matching buffer name in full
1125                                (car comps)
1126                                close-bracket-determined)
1127                      "")
1128                    (if (not iswitchb-use-fonts) " [Matched]")))
1129           (t                            ;multiple matches
1130            (let* (
1131                   ;;(most (try-completion name candidates predicate))
1132                   (most nil)
1133                   (most-len (length most))
1134                   most-is-exact
1135                   first
1136                   (alternatives
1137                    (apply
1138                     (function concat)
1139                     (cdr (apply
1140                           (function nconc)
1141                           (mapcar '(lambda (com)
1142                                      (if (= (length com) most-len)
1143                                          ;; Most is one exact match,
1144                                          ;; note that and leave out
1145                                          ;; for later indication:
1146                                          (progn
1147                                            (setq most-is-exact t)
1148                                            ())
1149                                        (list ","
1150                                              (substring com
1151                                                         most-len))))
1152                                   comps))))))
1153
1154              (concat
1155
1156               ;; put in common completion item -- what you get by
1157               ;; pressing tab
1158               (if (> (length iswitchb-common-match-string) (length name))
1159                   (concat open-bracket-determined
1160                           (substring iswitchb-common-match-string
1161                                      (length name))
1162                           close-bracket-determined))
1163               ;; end of partial matches...
1164
1165               ;; think this bit can be ignored.
1166               (and (> most-len (length name))
1167                    (concat open-bracket-determined
1168                            (substring most (length name))
1169                            close-bracket-determined))
1170
1171               ;; list all alternatives
1172               open-bracket-prospects
1173               (if most-is-exact
1174                   (concat "," alternatives)
1175                 alternatives)
1176               close-bracket-prospects))))))
1177
1178 (defun iswitchb-minibuffer-setup ()
1179   "Set up minibuffer for `iswitchb-buffer'.
1180 Copied from `icomplete-minibuffer-setup-hook'."
1181   (if (iswitchb-entryfn-p)
1182       (progn
1183
1184         (make-local-variable 'iswitchb-use-mycompletion)
1185         (setq iswitchb-use-mycompletion t)
1186         (make-local-hook 'pre-command-hook)
1187         (add-hook 'pre-command-hook
1188                   'iswitchb-pre-command
1189                   nil t)
1190         (make-local-hook 'post-command-hook)
1191         (add-hook 'post-command-hook
1192                   'iswitchb-post-command
1193                   nil t)
1194
1195         (run-hooks 'iswitchb-minibuffer-setup-hook))))
1196
1197 (defun iswitchb-pre-command ()
1198   "Run before command in `iswitchb-buffer'."
1199   (iswitchb-tidy))
1200
1201 (defun iswitchb-post-command ()
1202   "Run after command in `iswitchb-buffer'."
1203   (iswitchb-exhibit))
1204
1205 (defun iswitchb-tidy ()
1206   "Remove completions display, if any, prior to new user input.
1207 Copied from `icomplete-tidy'."
1208
1209   (if (and (boundp 'iswitchb-eoinput)
1210            iswitchb-eoinput)
1211
1212       (if (> iswitchb-eoinput (point-max))
1213           ;; Oops, got rug pulled out from under us - reinit:
1214           (setq iswitchb-eoinput (point-max))
1215         (let ((buffer-undo-list buffer-undo-list )) ; prevent entry
1216           (delete-region iswitchb-eoinput (point-max))))
1217
1218     ;; Reestablish the local variable 'cause minibuffer-setup is weird:
1219     (make-local-variable 'iswitchb-eoinput)
1220     (setq iswitchb-eoinput 1)))
1221
1222 (defun iswitchb-entryfn-p ()
1223   "Return non-nil if `this-command' shows we are using `iswitchb-buffer'."
1224   (or (boundp 'iswitchb-prepost-hooks)
1225       ;; I think the of this may be redundant, since the prepost hooks
1226       ;; will always be set in the iswitchb defuns.
1227       ;;(and (symbolp this-command)             ; ignore lambda functions
1228       ;;(memq this-command
1229       ;;         '(iswitchb-buffer
1230       ;;           iswitchb-buffer-other-frame
1231       ;;       iswitchb-display-buffer
1232       ;;       iswitchb-buffer-other-window))))
1233   ))
1234
1235 (defun iswitchb-summaries-to-end ()
1236   "Move the summaries to the end of the list.
1237 This is an example function which can be hooked on to
1238 `iswitchb-make-buflist-hook'.  Any buffer matching the regexps
1239 `Summary' or `output\*$'are put to the end of the list."
1240   (let ((summaries (delq nil (mapcar
1241                               (lambda (x)
1242                                  (if (or
1243                                       (string-match "Summary" x)
1244                                       (string-match "output\\*$" x))
1245                                      x))
1246                               iswitchb-temp-buflist))))
1247     (iswitchb-to-end summaries)))
1248
1249 (provide 'iswitchb)
1250
1251 ;;; iswitchb.el ends here