configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 24.4.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133
 134 dnl Fairly arbitrary, older versions might work too.
 135 AM_INIT_AUTOMAKE(1.11)
 136
 137 dnl Canonicalize the configuration name.
 138 AC_CANONICAL_HOST
 139 canonical=$host
 140 configuration=${host_alias-${build_alias-$host}}
 141
 142 dnl We get MINGW64 with MSYS2.
 143 case $canonical in
 144  *-mingw*)
 145   . $srcdir/nt/mingw-cfg.site
 146
 147   case $srcdir in
 148     /* | ?:*)
 149       # srcdir is an absolute path.  In this case, force the format
 150       # "/c/foo/bar", to simplify later conversions to native Windows
 151       # format ("c:/foo/bar").
 152       srcdir=`cd "${srcdir}" && pwd -W`
 153       srcdir="/${srcdir:0:1}${srcdir:2}"
 154       ;;
 155   esac;;
 156 esac
 157
 158 dnl Support for --program-prefix, --program-suffix and
 159 dnl --program-transform-name options
 160 AC_ARG_PROGRAM
 161
 162 dnl It is important that variables on the RHS not be expanded here,
 163 dnl hence the single quotes.  This is per the GNU coding standards, see
 164 dnl (autoconf) Installation Directory Variables
 165 dnl See also epaths.h below.
 166 lispdir='${datadir}/emacs/${version}/lisp'
 167 standardlisppath='${lispdir}'
 168 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 169 '${datadir}/emacs/site-lisp'
 170 lisppath='${locallisppath}:${standardlisppath}'
 171 etcdir='${datadir}/emacs/${version}/etc'
 172 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 173 etcdocdir='${datadir}/emacs/${version}/etc'
 174 gamedir='${localstatedir}/games/emacs'
 175
 176 dnl Special option to disable the most of other options.
 177 AC_ARG_WITH(all,
 178 [AS_HELP_STRING([--without-all],
 179                 [omit almost all features and build
 180                 small executable with minimal dependencies])],
 181   [with_features=$withval],
 182   [with_features=yes])
 183
 184 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 185 dnl Create a new --with option that defaults to being disabled.
 186 dnl NAME is the base name of the option.  The shell variable with_NAME
 187 dnl   will be set to either the user's value (if the option is
 188 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 189 dnl   option is not specified).  Note that the shell variable name is
 190 dnl   constructed as autoconf does, by replacing non-alphanumeric
 191 dnl   characters with "_".
 192 dnl HELP-STRING is the help text for the option.
 193 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 194   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 195     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 196 ])dnl
 197
 198 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 199 dnl Create a new --with option that defaults to $with_features.
 200 dnl NAME is the base name of the option.  The shell variable with_NAME
 201 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 202 dnl   'yes' (if the option is not specified).  Note that the shell
 203 dnl   variable name is constructed as autoconf does, by replacing
 204 dnl   non-alphanumeric characters with "_".
 205 dnl HELP-STRING is the help text for the option.
 206 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 207   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 208    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 209 ])dnl
 210
 211 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 212 if test "$with_pop" = yes; then
 213    AC_DEFINE(MAIL_USE_POP)
 214 fi
 215 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 216
 217 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 218 if test "$with_kerberos" != no; then
 219    AC_DEFINE(KERBEROS)
 220 fi
 221 AH_TEMPLATE(KERBEROS,
 222             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 223
 224 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 225 if test "${with_kerberos5}" != no; then
 226   if test "${with_kerberos}" = no; then
 227     with_kerberos=yes
 228     AC_DEFINE(KERBEROS)
 229   fi
 230   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 231 fi
 232
 233 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 234 dnl FIXME hesiod support may not be present, so it seems like an error
 235 dnl to define, or at least use, this unconditionally.
 236 if test "$with_hesiod" != no; then
 237   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 238 fi
 239
 240 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 241 if test "$with_mmdf" != no; then
 242    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 243 fi
 244
 245 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 246 if test "$with_mail_unlink" != no; then
 247    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 248 fi
 249
 250 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 251     [string giving default POP mail host])],
 252     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 253
 254 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 255   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 256 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 257   [ case "${withval}" in
 258       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 259       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 260 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 261       ;;
 262     esac
 263     with_sound=$val
 264   ],
 265   [with_sound=$with_features])
 266
 267 dnl FIXME currently it is not the last.
 268 dnl This should be the last --with option, because --with-x is
 269 dnl added later on when we find the file name of X, and it's best to
 270 dnl keep them together visually.
 271 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 272  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 273 [         case "${withval}" in
 274             y | ye | yes )      val=gtk ;;
 275             n | no )            val=no  ;;
 276             l | lu | luc | luci | lucid )       val=lucid ;;
 277             a | at | ath | athe | athen | athena )      val=athena ;;
 278             m | mo | mot | moti | motif )       val=motif ;;
 279             g | gt | gtk  )     val=gtk ;;
 280             gtk2  )     val=gtk2 ;;
 281             gtk3  )     val=gtk3 ;;
 282             * )
 283 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 284 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 285 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 286 `athena' and `lucid' are synonyms.])
 287             ;;
 288           esac
 289           with_x_toolkit=$val
 290 ])
 291
 292 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 293 if test "$with_wide_int" = yes; then
 294   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 295 fi
 296
 297 dnl _ON results in a '--without' option in the --help output, so
 298 dnl the help text should refer to "don't compile", etc.
 299 with_xpm_set=${with_xpm+set}
 300 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 301 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 302 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 303 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 304 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 305 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 306 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 307 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 308
 309 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 310 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 311 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 312
 313 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 314 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 315 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 316 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 317 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 318
 319 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 320 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 321 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 322 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 323 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 324 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 325 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 326
 327 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 328  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 329  [ case "${withval}" in
 330     y | ye | yes )      val=yes ;;
 331     n | no )            val=no  ;;
 332     g | gf | gfi | gfil | gfile )       val=gfile ;;
 333     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 334     w | w3 | w32 )      val=w32 ;;
 335     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 336 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 337 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 338 otherwise for the first of `gfile' or `inotify' that is usable.])
 339     ;;
 340    esac
 341    with_file_notification=$val
 342  ],
 343  [with_file_notification=$with_features])
 344
 345 ## For the times when you want to build Emacs but don't have
 346 ## a suitable makeinfo, and can live without the manuals.
 347 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 348 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 349
 350 ## This might be a 'configure' arg.
 351 AC_SUBST([ACLOCAL_PATH])
 352
 353 ## Makefile.in needs the cache file name.
 354 AC_SUBST(cache_file)
 355
 356 ## This is an option because I do not know if all info/man support
 357 ## compressed files, nor how to test if they do so.
 358 OPTION_DEFAULT_ON([compress-install],
 359   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 360 make GZIP_PROG= install])
 361
 362 AC_ARG_WITH(gameuser,dnl
 363 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 364 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 365   && gameuser="${with_gameuser}"
 366 test "X$gameuser" = X && gameuser=games
 367
 368 AC_ARG_WITH([gnustep-conf],dnl
 369 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 370    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 371 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 372   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 373 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 374      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 375
 376 AC_ARG_ENABLE(ns-self-contained,
 377 [AS_HELP_STRING([--disable-ns-self-contained],
 378                 [disable self contained build under NeXTstep])],
 379    EN_NS_SELF_CONTAINED=$enableval,
 380    EN_NS_SELF_CONTAINED=yes)
 381
 382 AC_ARG_ENABLE(locallisppath,
 383 [AS_HELP_STRING([--enable-locallisppath=PATH],
 384                 [directories Emacs should search for lisp files specific
 385                  to this site])],
 386 if test "${enableval}" = "no"; then
 387   locallisppath=
 388 elif test "${enableval}" != "yes"; then
 389   locallisppath=${enableval}
 390 fi)
 391
 392 AC_ARG_ENABLE(checking,
 393 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 394                 [enable expensive run-time checks.  With LIST,
 395                  enable only specific categories of checks.
 396                  Categories are: all,yes,no.
 397                  Flags are: stringbytes, stringoverrun, stringfreelist,
 398                  xmallocoverrun, conslist, glyphs])],
 399 [ac_checking_flags="${enableval}"],[])
 400 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 401 for check in $ac_checking_flags
 402 do
 403         case $check in
 404         # these set all the flags to specific states
 405         yes)            ac_enable_checking=1 ;;
 406         no)             ac_enable_checking= ;
 407                         ac_gc_check_stringbytes= ;
 408                         ac_gc_check_string_overrun= ;
 409                         ac_gc_check_string_free_list= ;
 410                         ac_xmalloc_overrun= ;
 411                         ac_gc_check_cons_list= ;
 412                         ac_glyphs_debug= ;;
 413         all)            ac_enable_checking=1 ;
 414                         ac_gc_check_stringbytes=1 ;
 415                         ac_gc_check_string_overrun=1 ;
 416                         ac_gc_check_string_free_list=1 ;
 417                         ac_xmalloc_overrun=1 ;
 418                         ac_gc_check_cons_list=1 ;
 419                         ac_glyphs_debug=1 ;;
 420         # these enable particular checks
 421         stringbytes)    ac_gc_check_stringbytes=1 ;;
 422         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 423         stringfreelist) ac_gc_check_string_free_list=1 ;;
 424         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 425         conslist)       ac_gc_check_cons_list=1 ;;
 426         glyphs)         ac_glyphs_debug=1 ;;
 427         *)      AC_MSG_ERROR(unknown check category $check) ;;
 428         esac
 429 done
 430 IFS="$ac_save_IFS"
 431
 432 if test x$ac_enable_checking != x ; then
 433   AC_DEFINE(ENABLE_CHECKING, 1,
 434 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 435 fi
 436 if test x$ac_gc_check_stringbytes != x ; then
 437   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 438 [Define this temporarily to hunt a bug.  If defined, the size of
 439    strings is redundantly recorded in sdata structures so that it can
 440    be compared to the sizes recorded in Lisp strings.])
 441 fi
 442 if test x$ac_gc_check_string_overrun != x ; then
 443   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 444 [Define this to check for short string overrun.])
 445 fi
 446 if test x$ac_gc_check_string_free_list != x ; then
 447   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 448 [Define this to check the string free list.])
 449 fi
 450 if test x$ac_xmalloc_overrun != x ; then
 451   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 452 [Define this to check for malloc buffer overrun.])
 453 fi
 454 if test x$ac_gc_check_cons_list != x ; then
 455   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 456 [Define this to check for errors in cons list.])
 457 fi
 458 if test x$ac_glyphs_debug != x ; then
 459   AC_DEFINE(GLYPH_DEBUG, 1,
 460 [Define this to enable glyphs debugging code.])
 461 fi
 462
 463 AC_ARG_ENABLE(check-lisp-object-type,
 464 [AS_HELP_STRING([--enable-check-lisp-object-type],
 465                 [enable compile time checks for the Lisp_Object data type.
 466                 This is useful for development for catching certain types of bugs.])],
 467 if test "${enableval}" != "no"; then
 468    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 469    [Define this to enable compile time checks for the Lisp_Object data type.])
 470 fi)
 471
 472
 473 dnl The name of this option is unfortunate.  It predates, and has no
 474 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 475 dnl Actually, it stops it working.
 476 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 477 AC_ARG_ENABLE(profiling,
 478 [AS_HELP_STRING([--enable-profiling],
 479                 [build emacs with low-level, gprof profiling support.
 480                 Mainly useful for debugging Emacs itself.  May not work on
 481                 all platforms.  Stops profiler.el working.])],
 482 [ac_enable_profiling="${enableval}"],[])
 483 if test x$ac_enable_profiling != x ; then
 484    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 485 else
 486    PROFILING_CFLAGS=
 487 fi
 488 AC_SUBST(PROFILING_CFLAGS)
 489
 490 AC_ARG_ENABLE(autodepend,
 491 [AS_HELP_STRING([--enable-autodepend],
 492                 [automatically generate dependencies to .h-files.
 493                  Requires gcc, enabled if found.])],
 494 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 495
 496 AC_ARG_ENABLE(gtk-deprecation-warnings,
 497 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 498                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 499 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 500
 501 dnl This used to use changequote, but, apart from `changequote is evil'
 502 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 503 dnl the great gob of text.  Thus it's not processed for possible expansion.
 504 dnl Just make sure the brackets remain balanced.
 505 dnl
 506 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 507 dnl indicated by comments.
 508 dnl quotation begins
 509 [
 510
 511 ### If you add support for a new configuration, add code to this
 512 ### switch statement to recognize your configuration name and select
 513 ### the appropriate opsys.
 514
 515 ### As far as handling version numbers on operating systems is
 516 ### concerned, make sure things will fail in a fixable way.  If
 517 ### /etc/MACHINES doesn't say anything about version numbers, be
 518 ### prepared to handle anything reasonably.  If version numbers
 519 ### matter, be sure /etc/MACHINES says something about it.
 520
 521 opsys='' unported=no
 522 case "${canonical}" in
 523
 524   ## GNU/Linux and similar ports
 525   *-*-linux* )
 526     opsys=gnu-linux
 527   ;;
 528
 529   ## FreeBSD ports
 530   *-*-freebsd* )
 531     opsys=freebsd
 532   ;;
 533
 534   ## DragonFly ports
 535   *-*-dragonfly* )
 536     opsys=dragonfly
 537   ;;
 538
 539   ## FreeBSD kernel + glibc based userland
 540   *-*-kfreebsd*gnu* )
 541     opsys=gnu-kfreebsd
 542   ;;
 543
 544   ## NetBSD ports
 545   *-*-netbsd* )
 546     opsys=netbsd
 547   ;;
 548
 549   ## OpenBSD ports
 550   *-*-openbsd* | *-*-mirbsd* )
 551     opsys=openbsd
 552   ;;
 553
 554   ## Apple Darwin / Mac OS X
 555   *-apple-darwin* )
 556     case "${canonical}" in
 557       i[3456]86-* )  ;;
 558       powerpc-* )    ;;
 559       x86_64-* )     ;;
 560       * )            unported=yes ;;
 561     esac
 562     opsys=darwin
 563     ## Use fink packages if available.
 564     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 565 ##    if test -d /sw/include && test -d /sw/lib; then
 566 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 567 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 568 ##    fi
 569   ;;
 570
 571   ## Cygwin ports
 572   *-*-cygwin )
 573     opsys=cygwin
 574   ;;
 575
 576   ## HP 9000 series 700 and 800, running HP/UX
 577   hppa*-hp-hpux10.2* )
 578     opsys=hpux10-20
 579   ;;
 580   hppa*-hp-hpux1[1-9]* )
 581     opsys=hpux11
 582     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 583   ;;
 584
 585   ## IBM machines
 586   rs6000-ibm-aix4.[23]* )
 587     opsys=aix4-2
 588   ;;
 589   powerpc-ibm-aix4.[23]*  )
 590     opsys=aix4-2
 591   ;;
 592   rs6000-ibm-aix[56]* )
 593     opsys=aix4-2
 594   ;;
 595   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 596     opsys=aix4-2
 597   ;;
 598
 599   ## Silicon Graphics machines
 600   ## Iris 4D
 601   mips-sgi-irix6.5 )
 602     opsys=irix6-5
 603     # Without defining _LANGUAGE_C, things get masked out in the headers
 604     # so that, for instance, grepping for `free' in stdlib.h fails and
 605     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 606     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 607   ;;
 608
 609   ## Suns
 610   *-sun-solaris* \
 611     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 612     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 613     case "${canonical}" in
 614       i[3456]86-*-* )   ;;
 615       amd64-*-*|x86_64-*-*) ;;
 616       sparc* )          ;;
 617       * )               unported=yes ;;
 618     esac
 619     case "${canonical}" in
 620       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 621                 opsys=sol2-10
 622                 emacs_check_sunpro_c=yes
 623                 ;;
 624       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 625       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 626       *-sunos5.6* | *-solaris2.6* )
 627                 opsys=sol2-6
 628                 RANLIB="ar -ts"
 629                 ;;
 630       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 631       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 632                 opsys=sol2-6
 633                 emacs_check_sunpro_c=yes
 634                 ;;
 635     esac
 636     ## Watch out for a compiler that we know will not work.
 637     case "${canonical}" in
 638      *-solaris* | *-sunos5* )
 639                 if [ "x$CC" = x/usr/ucb/cc ]; then
 640                   ## /usr/ucb/cc doesn't work;
 641                   ## we should find some other compiler that does work.
 642                   unset CC
 643                 fi
 644                 ;;
 645       *) ;;
 646     esac
 647   ;;
 648
 649   ## Intel 386 machines where we don't care about the manufacturer.
 650   i[3456]86-*-* )
 651     case "${canonical}" in
 652       *-darwin* )               opsys=darwin ;;
 653       *-mingw32 )
 654                 opsys=mingw32
 655                 # MinGW overrides and adds some system headers in nt/inc.
 656                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 657                 ;;
 658       *-sysv4.2uw* )            opsys=unixware ;;
 659       *-sysv5uw* )              opsys=unixware ;;
 660       *-sysv5OpenUNIX* )        opsys=unixware ;;
 661       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 662     esac
 663   ;;
 664
 665   # MinGW64
 666   x86_64-*-* )
 667     case "${canonical}" in
 668       *-mingw32 )
 669                 opsys=mingw32
 670                 # MinGW overrides and adds some system headers in nt/inc.
 671                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 672                 ;;
 673       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 674     esac
 675   ;;
 676
 677   * )
 678     unported=yes
 679   ;;
 680 esac
 681
 682 ### If the code above didn't choose an operating system, just choose
 683 ### an operating system based on the configuration name.  You really
 684 ### only want to use this when you have no idea what the right
 685 ### operating system is; if you know what operating systems a machine
 686 ### runs, it's cleaner to make it explicit in the case statement
 687 ### above.
 688 if test x"${opsys}" = x; then
 689   case "${canonical}" in
 690     *-gnu* )                            opsys=gnu ;;
 691     * )
 692       unported=yes
 693     ;;
 694   esac
 695 fi
 696
 697 ]
 698 dnl quotation ends
 699
 700 if test $unported = yes; then
 701   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 702 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 703 Check `etc/MACHINES' for recognized configuration names.])
 704 fi
 705
 706
 707 #### Choose a compiler.
 708
 709 dnl Don't bother to test for C89.
 710 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 711
 712 dnl Sets GCC=yes if using gcc.
 713 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 714 if test -n "$XCRUN"; then
 715   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 716   test -n "$AR" && export AR
 717 fi
 718
 719 dnl Emacs needs C99 or later.
 720 gl_PROG_CC_C99
 721
 722 AM_PROG_CC_C_O
 723
 724 if test x$GCC = xyes; then
 725   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 726 else
 727   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 728 fi
 729
 730 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 731 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 732 dnl that clash with MinGW.
 733 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 734
 735 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 736 AC_DEFUN([gl_CRYPTO_CHECK])
 737 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 738 # as we don't use them.
 739 AC_DEFUN([gl_FCNTL_O_FLAGS])
 740
 741 # Initialize gnulib right after choosing the compiler.
 742 dnl Amongst other things, this sets AR and ARFLAGS.
 743 gl_EARLY
 744
 745 if test "$ac_test_CFLAGS" != set; then
 746   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 747   # if -g3 works and the user does not specify CFLAGS.
 748   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 749   case $CFLAGS in
 750     '-g')
 751       emacs_g3_CFLAGS='-g3';;
 752     '-g -O2')
 753       emacs_g3_CFLAGS='-g3 -O2';;
 754     *)
 755       emacs_g3_CFLAGS='';;
 756   esac
 757   if test -n "$emacs_g3_CFLAGS"; then
 758     emacs_save_CFLAGS=$CFLAGS
 759     CFLAGS=$emacs_g3_CFLAGS
 760     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 761       [emacs_cv_prog_cc_g3],
 762       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 763          [emacs_cv_prog_cc_g3=yes],
 764          [emacs_cv_prog_cc_g3=no])])
 765     if test $emacs_cv_prog_cc_g3 != yes; then
 766       CFLAGS=$emacs_save_CFLAGS
 767     fi
 768     if test $opsys = mingw32; then
 769       CFLAGS="$CFLAGS -gdwarf-2"
 770     fi
 771   fi
 772
 773   case $CFLAGS in
 774     *-O*) ;;
 775     *)
 776       # No optimization flag was inferred for this non-GCC compiler.
 777       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 778       emacs_save_CFLAGS=$CFLAGS
 779       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 780       CFLAGS=${CFLAGS}-O
 781       AC_CACHE_CHECK([whether $CC accepts -O],
 782         [emacs_cv_prog_cc_o],
 783         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 784            [emacs_cv_prog_cc_o=yes],
 785            [emacs_cv_prog_cc_o=no])])
 786       if test $emacs_cv_prog_cc_o != yes; then
 787         CFLAGS=$emacs_save_CFLAGS
 788       fi ;;
 789   esac
 790 fi
 791
 792 AC_ARG_ENABLE([gcc-warnings],
 793   [AS_HELP_STRING([--enable-gcc-warnings],
 794                   [turn on lots of GCC warnings/errors. This is intended for
 795                    developers, and may generate false alarms when used
 796                    with older or non-GNU development tools.])],
 797   [case $enableval in
 798      yes|no) ;;
 799      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 800    esac
 801    gl_gcc_warnings=$enableval],
 802   [gl_gcc_warnings=no]
 803 )
 804
 805 # clang is unduly picky about some things.
 806 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 807   [AC_COMPILE_IFELSE(
 808      [AC_LANG_PROGRAM([[
 809           #ifndef __clang__
 810             error "not clang";
 811           #endif
 812         ]])],
 813      [emacs_cv_clang=yes],
 814      [emacs_cv_clang=no])])
 815
 816 # When compiling with GCC, prefer -isystem to -I when including system
 817 # include files, to avoid generating useless diagnostics for the files.
 818 if test "$gl_gcc_warnings" != yes; then
 819   isystem='-I'
 820   if test "$emacs_cv_clang" = yes
 821   then
 822      # Turn off some warnings if supported.
 823      gl_WARN_ADD([-Wno-switch])
 824      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 825      gl_WARN_ADD([-Wno-pointer-sign])
 826   fi
 827 else
 828   isystem='-isystem '
 829
 830   # This, $nw, is the list of warnings we disable.
 831   nw=
 832
 833   case $with_x_toolkit in
 834     lucid | athena | motif)
 835        # Old toolkits mishandle 'const'.
 836        nw="$nw -Wwrite-strings"
 837        ;;
 838     *)
 839        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 840        ;;
 841   esac
 842   AC_SUBST([WERROR_CFLAGS])
 843
 844   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 845   nw="$nw -Woverlength-strings"     # Not a problem these days
 846   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 847   nw="$nw -Wformat-nonliteral"      # we do this a lot
 848   nw="$nw -Wvla"                    # warnings in gettext.h
 849   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 850   nw="$nw -Wswitch-default"         # Too many warnings for now
 851   nw="$nw -Winline"                 # OK to ignore 'inline'
 852   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 853   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 854                                     # signed overflow has undefined behavior
 855   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 856   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 857   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 858
 859   # Emacs doesn't care about shadowing; see
 860   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 861   nw="$nw -Wshadow"
 862
 863   # Emacs's use of alloca inhibits protecting the stack.
 864   nw="$nw -Wstack-protector"
 865
 866   # The following line should be removable at some point.
 867   nw="$nw -Wsuggest-attribute=pure"
 868
 869   # This part is merely for shortening the command line,
 870   # since -Wno-FOO needs to be added below regardless.
 871   nw="$nw -Wmissing-field-initializers"
 872   nw="$nw -Wswitch"
 873   nw="$nw -Wtype-limits"
 874   nw="$nw -Wunused-parameter"
 875
 876   if test $emacs_cv_clang = yes; then
 877     nw="$nw -Wcast-align"
 878   fi
 879
 880   gl_MANYWARN_ALL_GCC([ws])
 881   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 882   for w in $ws; do
 883     gl_WARN_ADD([$w])
 884   done
 885   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 886   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 887   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 888   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 889   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 890   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 891   gl_WARN_ADD([-Wno-format-nonliteral])
 892
 893   # In spite of excluding -Wlogical-op above, it is enabled, as of
 894   # gcc 4.5.0 20090517.
 895   gl_WARN_ADD([-Wno-logical-op])
 896
 897   # More things that clang is unduly picky about.
 898   if test $emacs_cv_clang = yes; then
 899     gl_WARN_ADD([-Wno-format-extra-args])
 900     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 901     gl_WARN_ADD([-Wno-unused-command-line-argument])
 902     gl_WARN_ADD([-Wno-unused-value])
 903   fi
 904
 905   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 906   AH_VERBATIM([FORTIFY_SOURCE],
 907   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 908       without upsetting glibc 2.15+. */
 909    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 910    # define _FORTIFY_SOURCE 2
 911    #endif
 912   ])
 913   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 914
 915   # We use a slightly smaller set of warning options for lib/.
 916   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 917   nw=
 918   nw="$nw -Wunused-macros"
 919
 920   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 921   AC_SUBST([GNULIB_WARN_CFLAGS])
 922 fi
 923
 924 edit_cflags="
 925   s,///*,/,g
 926   s/^/ /
 927   s/ -I/ $isystem/g
 928   s/^ //
 929 "
 930
 931 AC_ARG_ENABLE(link-time-optimization,
 932 [AS_HELP_STRING([--enable-link-time-optimization],
 933                 [build emacs with link-time optimization.
 934                  This requires GCC 4.5.0 or later, or clang.
 935                  (Note that clang support is experimental - see INSTALL.)
 936                  It also makes Emacs harder to debug, and when we tried it
 937                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 938                  recommended for typical use.])],
 939 if test "${enableval}" != "no"; then
 940    ac_lto_supported=no
 941    if test $emacs_cv_clang = yes; then
 942       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
 943       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
 944       if test -x "$GOLD_PLUGIN"; then
 945          LTO="-flto"
 946       fi
 947    elif test x$GCC = xyes; then
 948       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
 949       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 950       if test x$CPUS != x; then
 951          LTO="-flto=$CPUS"
 952       else
 953          LTO="-flto"
 954       fi
 955    else
 956       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
 957    fi
 958    if test -z "$LTO"; then
 959       ac_lto_supported=no
 960    else
 961       old_CFLAGS=$CFLAGS
 962       CFLAGS="$CFLAGS $LTO"
 963       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 964          [ac_lto_supported=yes], [ac_lto_supported=no])
 965          CFLAGS="$old_CFLAGS"
 966    fi
 967    AC_MSG_RESULT([$ac_lto_supported])
 968    if test "$ac_lto_supported" = "yes"; then
 969       CFLAGS="$CFLAGS $LTO"
 970       if test x$emacs_cv_clang = xyes; then
 971          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
 972          # WARNING: 'ar --plugin ...' doesn't work without
 973          # command, so plugin name is appended to ARFLAGS.
 974          ARFLAGS="cru --plugin $GOLD_PLUGIN"
 975          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
 976       else
 977         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
 978         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
 979         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
 980         dnl dump core on Fedora 20, so play it safe for now.
 981         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
 982           [CFLAGS="$CFLAGS -ffat-lto-objects"])
 983       fi
 984    fi
 985 fi)
 986
 987 dnl Some other nice autoconf tests.
 988 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 989 dnl AC_PROG_INSTALL
 990 dnl AC_PROG_MKDIR_P
 991 dnl if test "x$RANLIB" = x; then
 992 dnl   AC_PROG_RANLIB
 993 dnl fi
 994
 995
 996 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 997 dnl can be made to directories.  This is not relevant for our usage, and
 998 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 999 dnl hosted on AFS, both examples where simple links work, but links to
1000 dnl directories fail.  We use a cut-down version instead.
1001 dnl AC_PROG_LN_S
1002
1003 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1004 rm -f conf$$ conf$$.file
1005
1006 LN_S_FILEONLY='cp -p'
1007
1008 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1009 dnl random program in the current directory.
1010 if (echo >conf$$.file) 2>/dev/null; then
1011   if ln -s conf$$.file conf$$ 2>/dev/null; then
1012     if test "$opsys" = "mingw32"; then
1013       LN_S_FILEONLY='/bin/ln -s'
1014     else
1015       LN_S_FILEONLY='ln -s'
1016     fi
1017   elif ln conf$$.file conf$$ 2>/dev/null; then
1018     if test "$opsys" = "mingw32"; then
1019       LN_S_FILEONLY=/bin/ln
1020     else
1021       LN_S_FILEONLY=ln
1022     fi
1023   fi
1024 fi
1025
1026 rm -f conf$$ conf$$.file
1027
1028 if test "$LN_S_FILEONLY" = "ln -s"; then
1029    AC_MSG_RESULT([yes])
1030 else
1031    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1032 fi
1033
1034 AC_SUBST(LN_S_FILEONLY)
1035
1036
1037 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1038 dnl doesn't support links to directories, as in "ln file dir".  But that
1039 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1040 dnl executables at "make install" time.
1041 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1042 dnl for more details.
1043 if test "$opsys" = "mingw32"; then
1044   LN_S="/bin/ln"
1045 fi
1046
1047 dnl On some Debian versions, "install-info" prints irritating messages
1048 dnl "This is not dpkg install-info anymore, but GNU install-info"
1049 dnl if called via an absolute file name.
1050 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1051 dnl Sadly some people may have an old ginstall-info installed on
1052 dnl non-Debian systems, so we can't use this.
1053 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1054 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1055
1056 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1057   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1058 dnl Don't use GZIP, which is used by gzip for additional parameters.
1059 AC_PATH_PROG(GZIP_PROG, gzip)
1060
1061 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1062    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1063
1064 if test $opsys = gnu-linux; then
1065   AC_PATH_PROG(PAXCTL, paxctl,,
1066     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1067   if test "X$PAXCTL" != X; then
1068     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1069     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1070       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1071       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1072   fi
1073
1074   if test "${SETFATTR+set}" != set; then
1075     AC_CACHE_CHECK([for setfattr],
1076       [emacs_cv_prog_setfattr],
1077       [touch conftest.tmp
1078        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1079          emacs_cv_prog_setfattr=yes
1080        else
1081          emacs_cv_prog_setfattr=no
1082        fi])
1083     if test "$emacs_cv_prog_setfattr" = yes; then
1084       SETFATTR=setfattr
1085     else
1086       SETFATTR=
1087     fi
1088     rm -f conftest.tmp
1089     AC_SUBST([SETFATTR])
1090   fi
1091 fi
1092
1093 ## Need makeinfo >= 4.7 (?) to build the manuals.
1094 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1095 dnl By this stage, configure has already checked for egrep and set EGREP,
1096 dnl or exited with an error if no egrep was found.
1097 if test "$MAKEINFO" != "no"; then
1098   case `
1099     $MAKEINFO --version 2> /dev/null |
1100     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1101   ` in
1102     '') MAKEINFO=no;;
1103   esac
1104 fi
1105
1106 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1107 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1108 ## therefore in the category of "special tools" not normally required, which
1109 ## configure does not have to check for (eg autoconf itself).
1110 ## In a repository checkout on the other hand, the manuals are not included.
1111 ## So makeinfo is a requirement to build from the repository, and configure
1112 ## should test for it as it does for any other build requirement.
1113 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1114 ## with pre-built manuals, from a repository checkout.
1115 HAVE_MAKEINFO=yes
1116
1117 if test "$MAKEINFO" = "no"; then
1118   MAKEINFO=makeinfo
1119   if test "x${with_makeinfo}" = "xno"; then
1120     HAVE_MAKEINFO=no
1121   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1122     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1123 source tree does not seem to have pre-built manuals in the `info' directory.
1124 Either install a suitable version of makeinfo, or re-run configure
1125 with the `--without-makeinfo' option to build without the manuals.] )
1126   fi
1127 fi
1128 AC_SUBST(HAVE_MAKEINFO)
1129
1130 if test $opsys = mingw32; then
1131    DOCMISC_W32=efaq-w32
1132 else
1133    DOCMISC_W32=
1134 fi
1135 AC_SUBST(DOCMISC_W32)
1136
1137 dnl Add our options to ac_link now, after it is set up.
1138
1139 if test x$GCC = xyes; then
1140   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1141     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1142 else
1143   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1144     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1145 fi
1146
1147 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1148 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1149 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1150 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1151 dnl if not built to support GNU ld.
1152
1153 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1154 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1155 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1156 dnl   Eg "make LDFLAGS=... all" could run into problems,
1157 dnl   http://bugs.debian.org/684788
1158 dnl * unnecessary, since temacs is the only thing that actually needs it.
1159 dnl   Indeed this is where it was originally, prior to:
1160 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1161 late_LDFLAGS="$LDFLAGS"
1162 if test x$GCC = xyes; then
1163   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1164 else
1165   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1166 fi
1167
1168 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1169
1170 AC_MSG_CHECKING([for -znocombreloc])
1171 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1172   [AC_MSG_RESULT(yes)],
1173   LDFLAGS_NOCOMBRELOC=
1174   [AC_MSG_RESULT(no)])
1175
1176 LDFLAGS="$late_LDFLAGS"
1177
1178 AC_CACHE_CHECK([whether addresses are sanitized],
1179   [emacs_cv_sanitize_address],
1180   [AC_COMPILE_IFELSE(
1181      [AC_LANG_PROGRAM(
1182         [[#ifndef __has_feature
1183           #define __has_feature(f) 0
1184           #endif
1185           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1186           #else
1187            error "Addresses are not sanitized.";
1188           #endif
1189         ]])],
1190      [emacs_cv_sanitize_address=yes],
1191      [emacs_cv_sanitize_address=no])])
1192
1193 dnl The function dump-emacs will not be defined and temacs will do
1194 dnl (load "loadup") automatically unless told otherwise.
1195 AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1196 AC_SUBST(CANNOT_DUMP, yes)
1197
1198 UNEXEC_OBJ=unexelf.o
1199 case "$opsys" in
1200   # MSDOS uses unexcoff.o
1201   aix4-2)
1202    UNEXEC_OBJ=unexaix.o
1203    ;;
1204   cygwin)
1205    UNEXEC_OBJ=unexcw.o
1206    ;;
1207   darwin)
1208    UNEXEC_OBJ=unexmacosx.o
1209    ;;
1210   hpux10-20 | hpux11)
1211    UNEXEC_OBJ=unexhp9k800.o
1212    ;;
1213   mingw32)
1214    UNEXEC_OBJ=unexw32.o
1215    ;;
1216   sol2-10)
1217    # Use the Solaris dldump() function, called from unexsol.c, to dump
1218    # emacs, instead of the generic ELF dump code found in unexelf.c.
1219    # The resulting binary has a complete symbol table, and is better
1220    # for debugging and other observability tools (debuggers, pstack, etc).
1221    #
1222    # If you encounter a problem using dldump(), please consider sending
1223    # a message to the OpenSolaris tools-linking mailing list:
1224    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1225    #
1226    # It is likely that dldump() works with older Solaris too, but this has
1227    # not been tested, so for now this change is for Solaris 10 or newer.
1228    UNEXEC_OBJ=unexsol.o
1229    ;;
1230 esac
1231
1232 LD_SWITCH_SYSTEM=
1233 case "$opsys" in
1234   freebsd|dragonfly)
1235    ## Let `ld' find image libs and similar things in /usr/local/lib.
1236    ## The system compiler, GCC, has apparently been modified to not
1237    ## look there, contrary to what a stock GCC would do.
1238 ### It's not our place to do this.  See bug#10313#17.
1239 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1240       :
1241    ;;
1242
1243   gnu-linux)
1244    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1245    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1246    ;;
1247
1248   netbsd)
1249 ### It's not our place to do this.  See bug#10313#17.
1250 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1251       :
1252    ;;
1253
1254   openbsd)
1255    ## Han Boetes <han@boetes.org> says this is necessary,
1256    ## otherwise Emacs dumps core on elf systems.
1257    LD_SWITCH_SYSTEM="-Z"
1258    ;;
1259 esac
1260 AC_SUBST(LD_SWITCH_SYSTEM)
1261
1262 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1263
1264 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1265 ## which has not been defined yet.  When this was handled with cpp,
1266 ## it was expanded to null when configure sourced the s/*.h file.
1267 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1268 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1269 ## (or somesuch), but because it is supposed to go at the _front_
1270 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1271 ## Compare with the gnu-linux case below, which added to the end
1272 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1273 ## LD_SWITCH_SYSTEM_TEMACS.
1274 case "$opsys" in
1275   netbsd|openbsd)
1276    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1277 esac
1278
1279
1280 C_SWITCH_MACHINE=
1281 case $canonical in
1282  alpha*)
1283   AC_CHECK_DECL([__ELF__])
1284   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1285     ## With ELF, make sure that all common symbols get allocated to in the
1286     ## data section.  Otherwise, the dump of temacs may miss variables in
1287     ## the shared library that have been initialized.  For example, with
1288     ## GNU libc, __malloc_initialized would normally be resolved to the
1289     ## shared library's .bss section, which is fatal.
1290     if test "x$GCC" = "xyes"; then
1291       C_SWITCH_MACHINE="-fno-common"
1292     else
1293       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1294     fi
1295   else
1296       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1297       dnl albeit under the mistaken assumption that said file
1298       dnl was no longer used.
1299       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1300   fi
1301   ;;
1302 esac
1303 AC_SUBST(C_SWITCH_MACHINE)
1304
1305 AC_SUBST(UNEXEC_OBJ)
1306
1307 C_SWITCH_SYSTEM=
1308 ## Some programs in src produce warnings saying certain subprograms
1309 ## are too complex and need a MAXMEM value greater than 2000 for
1310 ## additional optimization.  --nils@exp-math.uni-essen.de
1311 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1312   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1313 if test "$opsys" = "mingw32"; then
1314   case "$canonical" in
1315     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1316     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1317   esac
1318 fi
1319 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1320 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1321 AC_SUBST(C_SWITCH_SYSTEM)
1322
1323
1324 LIBS_SYSTEM=
1325 case "$opsys" in
1326   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1327   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1328
1329   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1330
1331   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1332
1333   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1334
1335   ## Motif needs -lgen.
1336   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1337 esac
1338
1339 AC_SUBST(LIBS_SYSTEM)
1340
1341 ### Make sure subsequent tests use flags consistent with the build flags.
1342
1343 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1344   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1345 else
1346   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1347 fi
1348
1349 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1350 AC_DEFUN([AC_TYPE_SIZE_T])
1351 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1352 AC_DEFUN([AC_TYPE_UID_T])
1353
1354 # sqrt and other floating-point functions such as fmod and frexp
1355 # are found in -lm on many systems.
1356 OLD_LIBS=$LIBS
1357 AC_SEARCH_LIBS([sqrt], [m])
1358 if test "X$LIBS" = "X$OLD_LIBS"; then
1359   LIB_MATH=
1360 else
1361   LIB_MATH=$ac_cv_search_sqrt
1362 fi
1363 LIBS=$OLD_LIBS
1364
1365 dnl Current possibilities handled by sed (aix4-2 -> aix,
1366 dnl gnu-linux -> gnu/linux, etc.):
1367 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1368 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1369 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1370
1371 case $opsys in
1372   cygwin )
1373     LIB_MATH=
1374     ;;
1375   darwin )
1376     ## Adding -lm confuses the dynamic linker, so omit it.
1377     LIB_MATH=
1378     ;;
1379   freebsd | dragonfly )
1380     SYSTEM_TYPE=berkeley-unix
1381     ;;
1382   gnu-linux | gnu-kfreebsd )
1383     ;;
1384   hpux10-20 | hpux11 )
1385     ;;
1386   mingw32 )
1387     LIB_MATH=
1388     SYSTEM_TYPE=windows-nt
1389     ;;
1390   dnl NB this may be adjusted below.
1391   netbsd | openbsd )
1392     SYSTEM_TYPE=berkeley-unix
1393     ;;
1394
1395   sol2* | unixware )
1396     SYSTEM_TYPE=usg-unix-v
1397     ;;
1398
1399 esac
1400
1401 AC_SUBST(LIB_MATH)
1402 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1403   [The type of system you are compiling for; sets `system-type'.])
1404
1405
1406 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1407 pre_PKG_CONFIG_LIBS=$LIBS
1408
1409 PKG_PROG_PKG_CONFIG(0.9.0)
1410
1411 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1412 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1413 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1414 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1415 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1416 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1417 dnl actions.
1418 AC_DEFUN([EMACS_CHECK_MODULES],
1419   [PKG_CHECK_MODULES([$1], [$2],
1420      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1421       m4_default([$3], [HAVE_$1=yes])],
1422      [m4_default([$4], [HAVE_$1=no])])])
1423
1424 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1425 AC_SUBST(BDW_GC_CFLAGS)
1426 AC_SUBST(BDW_GC_LIBS)
1427 CFLAGS="$CFLAGS $BDW_GC_CFLAGS"
1428 LIBS="$BDW_GC_LIBS $LIBS"
1429
1430 HAVE_SOUND=no
1431
1432 if test "${with_sound}" != "no"; then
1433   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1434   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1435     have_sound_header=yes, [], [
1436     #ifdef __MINGW32__
1437     #define WIN32_LEAN_AND_MEAN
1438     #include <windows.h>
1439     #endif
1440     ])
1441   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1442     AC_MSG_ERROR([OSS sound support requested but not found.])
1443
1444   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1445     # Emulation library used on NetBSD.
1446     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1447     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1448       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1449     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1450     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1451   fi
1452   AC_SUBST(LIBSOUND)
1453
1454   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1455     ALSA_REQUIRED=1.0.0
1456     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1457     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1458     if test $HAVE_ALSA = yes; then
1459       SAVE_CFLAGS="$CFLAGS"
1460       SAVE_LIBS="$LIBS"
1461       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1462       LIBS="$ALSA_LIBS $LIBS"
1463       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1464                       emacs_alsa_normal=yes,
1465                     emacs_alsa_normal=no)
1466       if test "$emacs_alsa_normal" != yes; then
1467         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1468                        [[snd_lib_error_set_handler (0);]])],
1469                        emacs_alsa_subdir=yes,
1470                      emacs_alsa_subdir=no)
1471         if test "$emacs_alsa_subdir" != yes; then
1472           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1473         fi
1474         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1475       fi
1476
1477       CFLAGS="$SAVE_CFLAGS"
1478       LIBS="$SAVE_LIBS"
1479       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1480       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1481       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1482     elif test "${with_sound}" = "alsa"; then
1483       AC_MSG_ERROR([ALSA sound support requested but not found.])
1484     fi
1485   fi                            dnl with_sound = alsa|yes
1486
1487   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1488   dnl compiles only on the specified platforms.  For others, it
1489   dnl probably doesn't make sense to try.
1490   dnl FIXME So surely we should bypass this whole section if not using
1491   dnl one of these platforms?
1492   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1493      case "$opsys" in
1494        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1495        dnl Adjust the --with-sound help text if you change this.
1496        gnu-linux|freebsd|netbsd|mingw32)
1497          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1498          HAVE_SOUND=yes
1499          ;;
1500      esac
1501   fi
1502
1503   AC_SUBST(CFLAGS_SOUND)
1504 fi
1505
1506 dnl checks for header files
1507 AC_CHECK_HEADERS_ONCE(
1508   sys/systeminfo.h
1509   coff.h pty.h
1510   sys/resource.h
1511   sys/utsname.h pwd.h utmp.h util.h)
1512
1513 AC_MSG_CHECKING(if personality LINUX32 can be set)
1514 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1515                emacs_cv_personality_linux32=yes,
1516                emacs_cv_personality_linux32=no)
1517 AC_MSG_RESULT($emacs_cv_personality_linux32)
1518
1519 if test $emacs_cv_personality_linux32 = yes; then
1520   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1521             [Define to 1 if personality LINUX32 can be set.])
1522 fi
1523
1524 dnl On Solaris 8 there's a compilation warning for term.h because
1525 dnl it doesn't define `bool'.
1526 AC_CHECK_HEADERS(term.h, , , -)
1527 AC_HEADER_TIME
1528 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1529                                       ]])
1530 if test $ac_cv_have_decl_sys_siglist != yes; then
1531   # For Tru64, at least:
1532   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1533                                           ]])
1534 fi
1535 AC_HEADER_SYS_WAIT
1536
1537 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1538 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1539 #if HAVE_SYS_SOCKET_H
1540 #include <sys/socket.h>
1541 #endif])
1542 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1543 #if HAVE_SYS_SOCKET_H
1544 #include <sys/socket.h>
1545 #endif])
1546 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1547 #if HAVE_SYS_SOCKET_H
1548 #include <sys/socket.h>
1549 #endif])
1550
1551 dnl checks for structure members
1552 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1553                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1554                   struct ifreq.ifr_addr,
1555                   struct ifreq.ifr_addr.sa_len], , ,
1556                  [AC_INCLUDES_DEFAULT
1557 #if HAVE_SYS_SOCKET_H
1558 #include <sys/socket.h>
1559 #endif
1560 #if HAVE_NET_IF_H
1561 #include <net/if.h>
1562 #endif])
1563
1564 dnl Check for endianness.
1565 dnl AC_C_BIGENDIAN is done by gnulib.
1566
1567 dnl check for Make feature
1568
1569 DEPFLAGS=
1570 MKDEPDIR=":"
1571 deps_frag=deps.mk
1572 dnl check if we have GCC and autodepend is on.
1573 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1574    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1575    SAVE_CFLAGS="$CFLAGS"
1576    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1577    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1578    CFLAGS="$SAVE_CFLAGS"
1579    test -f deps.d || ac_enable_autodepend=no
1580    rm -rf deps.d
1581    AC_MSG_RESULT([$ac_enable_autodepend])
1582    if test $ac_enable_autodepend = yes; then
1583       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1584       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1585       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1586       deps_frag=autodeps.mk
1587    fi
1588 fi
1589 lwlib_deps_frag=$srcdir/lwlib/$deps_frag
1590 oldxmenu_deps_frag=$srcdir/oldXMenu/$deps_frag
1591 deps_frag=$srcdir/src/$deps_frag
1592 AC_SUBST(MKDEPDIR)
1593 AC_SUBST(DEPFLAGS)
1594 AC_SUBST_FILE(deps_frag)
1595 AC_SUBST_FILE(lwlib_deps_frag)
1596 AC_SUBST_FILE(oldxmenu_deps_frag)
1597
1598 lisp_frag=$srcdir/src/lisp.mk
1599 AC_SUBST_FILE(lisp_frag)
1600
1601
1602 dnl checks for operating system services
1603 AC_SYS_LONG_FILE_NAMES
1604
1605 #### Choose a window system.
1606
1607 ## We leave window_system equal to none if
1608 ## we end up building without one.  Any new window system should
1609 ## set window_system to an appropriate value and add objects to
1610 ## window-system-specific substs.
1611
1612 window_system=none
1613 AC_PATH_X
1614 if test "$no_x" != yes; then
1615   window_system=x11
1616 fi
1617
1618 LD_SWITCH_X_SITE_RPATH=
1619 if test "${x_libraries}" != NONE; then
1620   if test -n "${x_libraries}"; then
1621     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1622     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1623   fi
1624   x_default_search_path=""
1625   x_search_path=${x_libraries}
1626   if test -z "${x_search_path}"; then
1627     x_search_path=/usr/lib
1628   fi
1629   for x_library in `echo ${x_search_path}: | \
1630                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1631     x_search_path="\
1632 ${x_library}/X11/%L/%T/%N%C%S:\
1633 ${x_library}/X11/%l/%T/%N%C%S:\
1634 ${x_library}/X11/%T/%N%C%S:\
1635 ${x_library}/X11/%L/%T/%N%S:\
1636 ${x_library}/X11/%l/%T/%N%S:\
1637 ${x_library}/X11/%T/%N%S"
1638     if test x"${x_default_search_path}" = x; then
1639       x_default_search_path=${x_search_path}
1640     else
1641       x_default_search_path="${x_search_path}:${x_default_search_path}"
1642     fi
1643   done
1644 fi
1645 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1646
1647 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1648   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1649 fi
1650
1651 if test x"${x_includes}" = x; then
1652   bitmapdir=/usr/include/X11/bitmaps
1653 else
1654   # accumulate include directories that have X11 bitmap subdirectories
1655   bmd_acc="dummyval"
1656   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1657     if test -d "${bmd}/X11/bitmaps"; then
1658       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1659     fi
1660     if test -d "${bmd}/bitmaps"; then
1661       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1662     fi
1663   done
1664   if test ${bmd_acc} != "dummyval"; then
1665     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1666   fi
1667 fi
1668
1669 HAVE_NS=no
1670 NS_IMPL_COCOA=no
1671 NS_IMPL_GNUSTEP=no
1672 tmp_CPPFLAGS="$CPPFLAGS"
1673 tmp_CFLAGS="$CFLAGS"
1674 CPPFLAGS="$CPPFLAGS -x objective-c"
1675 CFLAGS="$CFLAGS -x objective-c"
1676 GNU_OBJC_CFLAGS=
1677 LIBS_GNUSTEP=
1678 if test "${with_ns}" != no; then
1679   if test "${opsys}" = darwin; then
1680      NS_IMPL_COCOA=yes
1681      ns_appdir=`pwd`/nextstep/Emacs.app
1682      ns_appbindir=${ns_appdir}/Contents/MacOS
1683      ns_appresdir=${ns_appdir}/Contents/Resources
1684      ns_appsrc=Cocoa/Emacs.base
1685   elif test -f $GNUSTEP_CONFIG_FILE; then
1686      NS_IMPL_GNUSTEP=yes
1687      ns_appdir=`pwd`/nextstep/Emacs.app
1688      ns_appbindir=${ns_appdir}
1689      ns_appresdir=${ns_appdir}/Resources
1690      ns_appsrc=GNUstep/Emacs.base
1691      dnl FIXME sourcing this several times in subshells seems inefficient.
1692      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1693      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1694      dnl I seemed to need these as well with GNUstep-startup 0.25.
1695      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1696      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1697      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1698        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1699      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1700        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1701      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1702      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1703      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1704      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1705      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1706      dnl If they had chosen to either define it or not, we could have
1707      dnl just used AC_CHECK_DECL here.
1708      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1709        emacs_cv_objc_exceptions,
1710 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1711 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1712 1;
1713 #else
1714 fail;
1715 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1716      if test $emacs_cv_objc_exceptions = yes; then
1717        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1718        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1719          [Define if GNUstep uses ObjC exceptions.])
1720        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1721      fi
1722   fi
1723
1724   dnl This is only used while we test the NS headers, it gets reset below.
1725   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1726
1727   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1728                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1729   files are missing or cannot be compiled.])])
1730
1731   macfont_file=""
1732   if test "${NS_IMPL_COCOA}" = "yes"; then
1733     AC_MSG_CHECKING([for OSX 10.4 or newer])
1734     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1735                                      [
1736 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1737 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1738  ; /* OK */
1739 #else
1740  error "OSX 10.4 or newer required";
1741 #endif
1742 #endif
1743                     ])],
1744                     ns_osx_have_104=yes,
1745                     ns_osx_have_104=no)
1746     AC_MSG_RESULT([$ns_osx_have_104])
1747
1748     if test $ns_osx_have_104 = no; then
1749        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1750     fi
1751     AC_MSG_CHECKING([for OSX 10.5 or newer])
1752     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1753                                      [
1754 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1755 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1756  ; /* OK */
1757 #else
1758  error "OSX 10.5 not found";
1759 #endif
1760 #endif
1761                     ])],
1762                     ns_osx_have_105=yes,
1763                     ns_osx_have_105=no)
1764     AC_MSG_RESULT([$ns_osx_have_105])
1765     if test $ns_osx_have_105 = yes; then
1766       macfont_file="macfont.o"
1767     fi
1768   fi
1769   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1770                                      [NSInteger i;])],
1771                     ns_have_nsinteger=yes,
1772                     ns_have_nsinteger=no)
1773   if test $ns_have_nsinteger = yes; then
1774     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1775   fi
1776 fi
1777
1778 AC_SUBST(LIBS_GNUSTEP)
1779
1780 INSTALL_ARCH_INDEP_EXTRA=install-etc
1781 ns_self_contained=no
1782 NS_OBJ=
1783 NS_OBJC_OBJ=
1784 if test "${HAVE_NS}" = yes; then
1785   if test "$with_toolkit_scroll_bars" = "no"; then
1786     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1787   fi
1788
1789   window_system=nextstep
1790   # set up packaging dirs
1791   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1792      ns_self_contained=yes
1793      prefix=${ns_appresdir}
1794      exec_prefix=${ns_appbindir}
1795      dnl This one isn't really used, only archlibdir is.
1796      libexecdir="\${ns_appbindir}/libexec"
1797      archlibdir="\${ns_appbindir}/libexec"
1798      etcdocdir="\${ns_appresdir}/etc"
1799      etcdir="\${ns_appresdir}/etc"
1800      dnl FIXME maybe set datarootdir instead.
1801      dnl That would also get applications, icons, man.
1802      infodir="\${ns_appresdir}/info"
1803      mandir="\${ns_appresdir}/man"
1804      lispdir="\${ns_appresdir}/lisp"
1805      INSTALL_ARCH_INDEP_EXTRA=
1806   fi
1807
1808   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1809 fi
1810 CFLAGS="$tmp_CFLAGS"
1811 CPPFLAGS="$tmp_CPPFLAGS"
1812 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1813 AC_SUBST(ns_self_contained)
1814 AC_SUBST(NS_OBJ)
1815 AC_SUBST(NS_OBJC_OBJ)
1816
1817 HAVE_W32=no
1818 W32_OBJ=
1819 W32_LIBS=
1820 EMACSRES=
1821 CLIENTRES=
1822 CLIENTW=
1823 W32_RES_LINK=
1824 EMACS_MANIFEST=
1825 UPDATE_MANIFEST=
1826 if test "${with_w32}" != no; then
1827   case "${opsys}" in
1828     cygwin)
1829       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1830              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1831                    cannot be found.])])
1832     ;;
1833     mingw32)
1834     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1835     ;;
1836     *)
1837       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1838     ;;
1839   esac
1840 fi
1841
1842 if test "${opsys}" = "mingw32"; then
1843   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1844   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1845      #include <windows.h>
1846      #include <usp10.h>]],
1847    [[PIMAGE_NT_HEADERS pHeader;
1848      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1849    [emacs_cv_w32api=yes
1850     HAVE_W32=yes],
1851    emacs_cv_w32api=no)
1852   AC_MSG_RESULT($emacs_cv_w32api)
1853   if test "${emacs_cv_w32api}" = "no"; then
1854     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1855   fi
1856 fi
1857
1858 FIRSTFILE_OBJ=
1859 NTDIR=
1860 LIBS_ECLIENT=
1861 LIB_WSOCK32=
1862 NTLIB=
1863 CM_OBJ="cm.o"
1864 XARGS_LIMIT=
1865 if test "${HAVE_W32}" = "yes"; then
1866   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1867   AC_CHECK_TOOL(WINDRES, [windres],
1868                 [AC_MSG_ERROR([No resource compiler found.])])
1869   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1870   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1871   EMACSRES="emacs.res"
1872   case "$canonical" in
1873     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1874     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1875   esac
1876   if test "${opsys}" = "cygwin"; then
1877     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1878     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1879     # Tell the linker that emacs.res is an object (which we compile from
1880     # the rc file), not a linker script.
1881     W32_RES_LINK="-Wl,emacs.res"
1882   else
1883     UPDATE_MANIFEST=update-game-score.exe.manifest
1884     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1885     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1886     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1887     W32_RES_LINK="\$(EMACSRES)"
1888     CLIENTRES="emacsclient.res"
1889     CLIENTW="emacsclientw\$(EXEEXT)"
1890     FIRSTFILE_OBJ=firstfile.o
1891     NTDIR=nt
1892     CM_OBJ=
1893     LIBS_ECLIENT="-lcomctl32"
1894     LIB_WSOCK32="-lwsock32"
1895     NTLIB="ntlib.$ac_objext"
1896     XARGS_LIMIT="-s 10000"
1897   fi
1898 fi
1899 AC_SUBST(W32_OBJ)
1900 AC_SUBST(W32_LIBS)
1901 AC_SUBST(EMACSRES)
1902 AC_SUBST(EMACS_MANIFEST)
1903 AC_SUBST(UPDATE_MANIFEST)
1904 AC_SUBST(CLIENTRES)
1905 AC_SUBST(CLIENTW)
1906 AC_SUBST(W32_RES_LINK)
1907 AC_SUBST(FIRSTFILE_OBJ)
1908 AC_SUBST(NTDIR)
1909 AC_SUBST(CM_OBJ)
1910 AC_SUBST(LIBS_ECLIENT)
1911 AC_SUBST(LIB_WSOCK32)
1912 AC_SUBST(NTLIB)
1913 AC_SUBST(XARGS_LIMIT)
1914
1915 if test "${HAVE_W32}" = "yes"; then
1916   window_system=w32
1917   with_xft=no
1918 fi
1919
1920 ## $window_system is now set to the window system we will
1921 ## ultimately use.
1922
1923 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1924    # Too many warnings for now.
1925    nw=
1926    nw="$nw -Wsuggest-attribute=const"
1927    nw="$nw -Wsuggest-attribute=noreturn"
1928    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1929
1930    gl_WARN_ADD([-Wno-unused-variable])
1931    gl_WARN_ADD([-Wno-unused-but-set-variable])
1932    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1933 fi
1934
1935 term_header=
1936 HAVE_X_WINDOWS=no
1937 HAVE_X11=no
1938 USE_X_TOOLKIT=none
1939
1940 case "${window_system}" in
1941   x11 )
1942     HAVE_X_WINDOWS=yes
1943     HAVE_X11=yes
1944     term_header=xterm.h
1945     case "${with_x_toolkit}" in
1946       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1947       motif ) USE_X_TOOLKIT=MOTIF ;;
1948       gtk ) with_gtk=yes
1949             term_header=gtkutil.h
1950 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1951 dnl USE_X_TOOLKIT is set.
1952             USE_X_TOOLKIT=none ;;
1953       gtk2 ) with_gtk2=yes
1954              term_header=gtkutil.h
1955              USE_X_TOOLKIT=none ;;
1956       gtk3 ) with_gtk3=yes
1957              term_header=gtkutil.h
1958              USE_X_TOOLKIT=none ;;
1959       no ) USE_X_TOOLKIT=none ;;
1960 dnl If user did not say whether to use a toolkit, make this decision later:
1961 dnl use the toolkit if we have gtk, or X11R5 or newer.
1962       * ) USE_X_TOOLKIT=maybe ;;
1963     esac
1964   ;;
1965   nextstep )
1966     term_header=nsterm.h
1967   ;;
1968   w32 )
1969     term_header=w32term.h
1970   ;;
1971 esac
1972
1973 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1974    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1975    if test "$HAVE_XSERVER" = true ||
1976       test -n "$DISPLAY" ||
1977       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1978         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1979 were found.  You should install the relevant development files for X
1980 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1981 sure you have development files for image handling, i.e.
1982 tiff, gif, jpeg, png and xpm.
1983 If you are sure you want Emacs compiled without X window support, pass
1984   --without-x
1985 to configure.])
1986    fi
1987 fi
1988
1989 # Does the opsystem file prohibit the use of the GNU malloc?
1990 # Assume not, until told otherwise.
1991 GNU_MALLOC=yes
1992
1993 AC_CACHE_CHECK(
1994   [whether malloc is Doug Lea style],
1995   [emacs_cv_var_doug_lea_malloc],
1996   [emacs_cv_var_doug_lea_malloc=no
1997    dnl Hooks do not work with address sanitization.
1998    if test "$emacs_cv_sanitize_address" != yes; then
1999      AC_LINK_IFELSE(
2000        [AC_LANG_PROGRAM(
2001           [[#include <malloc.h>
2002             static void hook (void) {}]],
2003           [[malloc_set_state (malloc_get_state ());
2004             __after_morecore_hook = hook;
2005             __malloc_initialize_hook = hook;]])],
2006        [emacs_cv_var_doug_lea_malloc=yes])])
2007    fi
2008 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2009
2010 system_malloc=$emacs_cv_sanitize_address
2011 case "$opsys" in
2012   ## darwin ld insists on the use of malloc routines in the System framework.
2013   darwin|mingw32|sol2-10) system_malloc=yes ;;
2014 esac
2015
2016 GMALLOC_OBJ=
2017 if test "${system_malloc}" = "yes"; then
2018   AC_DEFINE([SYSTEM_MALLOC], 1,
2019     [Define to 1 to use the system memory allocator, even if it is not
2020      Doug Lea style.])
2021   GNU_MALLOC=no
2022   GNU_MALLOC_reason="
2023     (The GNU allocators don't work with this system configuration.)"
2024   VMLIMIT_OBJ=
2025 else
2026   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2027   VMLIMIT_OBJ=vm-limit.o
2028
2029   AC_CHECK_HEADERS([sys/vlimit.h])
2030   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2031     [AC_LINK_IFELSE(
2032        [AC_LANG_PROGRAM(
2033          [[extern char data_start[]; char ch;]],
2034          [[return data_start < &ch;]])],
2035        [emacs_cv_data_start=yes],
2036        [emacs_cv_data_start=no])])
2037   if test $emacs_cv_data_start = yes; then
2038     AC_DEFINE([HAVE_DATA_START], 1,
2039       [Define to 1 if data_start is the address of the start
2040        of the main data segment.])
2041   fi
2042 fi
2043 AC_SUBST(GMALLOC_OBJ)
2044 AC_SUBST(VMLIMIT_OBJ)
2045
2046 if test "$doug_lea_malloc" = "yes" ; then
2047   if test "$GNU_MALLOC" = yes ; then
2048     GNU_MALLOC_reason="
2049       (Using Doug Lea's new malloc from the GNU C Library.)"
2050   fi
2051   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2052     [Define to 1 if the system memory allocator is Doug Lea style,
2053      with malloc hooks and malloc_set_state.])
2054
2055   ## Use mmap directly for allocating larger buffers.
2056   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2057   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2058   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2059   case "$opsys" in
2060     mingw32|gnu*) REL_ALLOC=no ;;
2061   esac
2062 fi
2063
2064 if test x"${REL_ALLOC}" = x; then
2065   REL_ALLOC=${GNU_MALLOC}
2066 fi
2067
2068 use_mmap_for_buffers=no
2069 case "$opsys" in
2070   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2071 esac
2072
2073 AC_FUNC_MMAP
2074 if test $use_mmap_for_buffers = yes; then
2075   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2076   REL_ALLOC=no
2077 fi
2078
2079 LIBS="$LIBS_SYSTEM $LIBS"
2080
2081 dnl FIXME replace main with a function we actually want from this library.
2082 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2083
2084 dnl Check for the POSIX thread library.
2085 LIB_PTHREAD=
2086 if test "$opsys" != "mingw32"; then
2087 AC_CHECK_HEADERS_ONCE(pthread.h)
2088 if test "$ac_cv_header_pthread_h"; then
2089   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2090   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2091   dnl testing for pthread_kill if Emacs uses gmalloc.c.
2092   if test "$GMALLOC_OBJ" = gmalloc.o; then
2093     emacs_pthread_function=pthread_atfork
2094   else
2095     emacs_pthread_function=pthread_kill
2096   fi
2097   OLD_LIBS=$LIBS
2098   AC_SEARCH_LIBS([$emacs_pthread_function], [pthread],
2099     [AC_DEFINE([HAVE_PTHREAD], [1],
2100        [Define to 1 if you have pthread (-lpthread).])
2101      # Some systems optimize for single-threaded programs by default, and
2102      # need special flags to disable these optimizations. For example, the
2103      # definition of 'errno' in <errno.h>.
2104      case $opsys in
2105        sol*)
2106          AC_DEFINE([_REENTRANT], 1,
2107         [Define to 1 if your system requires this in multithreaded code.]);;
2108        aix4-2)
2109          AC_DEFINE([_THREAD_SAFE], 1,
2110         [Define to 1 if your system requires this in multithreaded code.]);;
2111      esac])
2112  if test "X$LIBS" != "X$OLD_LIBS"; then
2113     eval LIB_PTHREAD=\$ac_cv_search_$emacs_pthread_function
2114   fi
2115   LIBS=$OLD_LIBS
2116 fi
2117 AC_SUBST([LIB_PTHREAD])
2118 fi
2119
2120 dnl Check for need for bigtoc support on IBM AIX
2121
2122 case ${host_os} in
2123 aix*)
2124   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2125     case $GCC in
2126     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2127     *) gdb_cv_bigtoc=-bbigtoc ;;
2128     esac
2129
2130     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2131     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2132   ])
2133   ;;
2134 esac
2135
2136 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2137 # is for the tests that follow.  We set them back later on.
2138
2139 REAL_CFLAGS="$CFLAGS"
2140 REAL_CPPFLAGS="$CPPFLAGS"
2141 REAL_LIBS="$LIBS"
2142
2143 if test "${HAVE_X11}" = "yes"; then
2144   DEFS="$C_SWITCH_X_SITE $DEFS"
2145   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2146   LIBS="-lX11 $LIBS"
2147   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2148   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2149
2150   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2151   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2152   # but it's more convenient here to set LD_RUN_PATH since this
2153   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2154   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2155     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2156     export LD_RUN_PATH
2157   fi
2158
2159   if test "${opsys}" = "gnu-linux"; then
2160     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2161     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2162      [[XOpenDisplay ("foo");]])],
2163      [xgnu_linux_first_failure=no],
2164      [xgnu_linux_first_failure=yes])
2165     if test "${xgnu_linux_first_failure}" = "yes"; then
2166       OLD_CPPFLAGS="$CPPFLAGS"
2167       OLD_LIBS="$LIBS"
2168       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2169       LIBS="$LIBS -b i486-linuxaout"
2170       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2171        [[XOpenDisplay ("foo");]])],
2172        [xgnu_linux_second_failure=no],
2173        [xgnu_linux_second_failure=yes])
2174       if test "${xgnu_linux_second_failure}" = "yes"; then
2175         # If we get the same failure with -b, there is no use adding -b.
2176         # So leave it out.  This plays safe.
2177         AC_MSG_RESULT(no)
2178       else
2179         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2180         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2181         AC_MSG_RESULT(yes)
2182       fi
2183       CPPFLAGS=$OLD_CPPFLAGS
2184       LIBS=$OLD_LIBS
2185     else
2186       AC_MSG_RESULT(no)
2187     fi
2188   fi
2189
2190   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2191   # header files included from there.
2192   AC_MSG_CHECKING(for Xkb)
2193   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2194 #include <X11/XKBlib.h>]],
2195         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2196         emacs_xkb=yes, emacs_xkb=no)
2197   AC_MSG_RESULT($emacs_xkb)
2198   if test $emacs_xkb = yes; then
2199     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2200   fi
2201
2202   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2203 XScreenNumberOfScreen)
2204 fi
2205
2206 if test "${window_system}" = "x11"; then
2207   AC_MSG_CHECKING(X11 version 6)
2208   AC_CACHE_VAL(emacs_cv_x11_version_6,
2209   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2210 [[#if XlibSpecificationRelease < 6
2211 fail;
2212 #endif
2213 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2214   if test $emacs_cv_x11_version_6 = yes; then
2215     AC_MSG_RESULT(6 or newer)
2216     AC_DEFINE(HAVE_X11R6, 1,
2217               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2218     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2219     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2220     ## XIM support.
2221     case "$opsys" in
2222       sol2-*) : ;;
2223       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2224            [Define if you have usable X11R6-style XIM support.])
2225          ;;
2226     esac
2227   else
2228     AC_MSG_RESULT(before 6)
2229   fi
2230 fi
2231
2232
2233 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2234 HAVE_RSVG=no
2235 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2236   if test "${with_rsvg}" != "no"; then
2237     RSVG_REQUIRED=2.11.0
2238     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2239
2240     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2241     AC_SUBST(RSVG_CFLAGS)
2242     AC_SUBST(RSVG_LIBS)
2243
2244     if test $HAVE_RSVG = yes; then
2245       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2246       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2247       # Windows loads librsvg dynamically
2248       if test "${opsys}" = "mingw32"; then
2249         RSVG_LIBS=
2250       fi
2251     fi
2252   fi
2253 fi
2254
2255 HAVE_IMAGEMAGICK=no
2256 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2257   if test "${with_imagemagick}" != "no"; then
2258     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2259     ## 6.8.2 makes Emacs crash; see Bug#13867.
2260     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2261     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2262     AC_SUBST(IMAGEMAGICK_CFLAGS)
2263     AC_SUBST(IMAGEMAGICK_LIBS)
2264
2265     if test $HAVE_IMAGEMAGICK = yes; then
2266       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2267       OLD_CFLAGS=$CFLAGS
2268       OLD_LIBS=$LIBS
2269       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2270       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2271       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2272       CFLAGS=$OLD_CFLAGS
2273       LIBS=$OLD_LIBS
2274     fi
2275   fi
2276 fi
2277
2278
2279 HAVE_GTK=no
2280 GTK_OBJ=
2281 gtk_term_header=$term_header
2282 check_gtk2=no
2283 gtk3_pkg_errors=
2284 if test "${opsys}" != "mingw32"; then
2285   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2286     GLIB_REQUIRED=2.28
2287     GTK_REQUIRED=3.0
2288     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2289
2290     dnl Checks for libraries.
2291     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2292       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2293     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2294        AC_MSG_ERROR($GTK_PKG_ERRORS)
2295     fi
2296     if test "$pkg_check_gtk" = "yes"; then
2297        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2298        GTK_OBJ=emacsgtkfixed.o
2299        gtk_term_header=gtkutil.h
2300        USE_GTK_TOOLKIT="GTK3"
2301        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2302          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2303            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2304          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2305            [Define to 1 to disable Glib deprecation warnings.])
2306        fi
2307     else
2308        check_gtk2=yes
2309        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2310     fi
2311   fi
2312
2313   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2314     GLIB_REQUIRED=2.10
2315     GTK_REQUIRED=2.10
2316     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2317
2318     dnl Checks for libraries.
2319     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2320       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2321     if test "$pkg_check_gtk" = "no" &&
2322        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2323     then
2324       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2325     fi
2326     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2327   fi
2328 fi
2329
2330 OLD_CFLAGS=$CFLAGS
2331 OLD_LIBS=$LIBS
2332
2333 if test x"$pkg_check_gtk" = xyes; then
2334
2335   AC_SUBST(GTK_LIBS)
2336   CFLAGS="$CFLAGS $GTK_CFLAGS"
2337   LIBS="$GTK_LIBS $LIBS"
2338   dnl Try to compile a simple GTK program.
2339   AC_MSG_CHECKING([whether GTK compiles])
2340   GTK_COMPILES=no
2341   AC_LINK_IFELSE(
2342     [AC_LANG_PROGRAM(
2343        [[/* Check the Gtk and Glib APIs.  */
2344          #include <gtk/gtk.h>
2345          #include <glib-object.h>
2346          static void
2347          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2348          {}
2349        ]],
2350        [[
2351          GtkSettings *gs = 0;
2352          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2353             strict C prohibits this.  Use gtk_main_iteration to test that the
2354             libraries are there.  */
2355          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2356                                     0, 0, 0, G_CALLBACK (callback), 0))
2357            gtk_main_iteration ();
2358        ]])],
2359     [GTK_COMPILES=yes])
2360   AC_MSG_RESULT([$GTK_COMPILES])
2361   if test "${GTK_COMPILES}" != "yes"; then
2362     GTK_OBJ=
2363     if test "$USE_X_TOOLKIT" != "maybe"; then
2364       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2365     fi
2366   else
2367     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2368     HAVE_GTK=yes
2369     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2370     GTK_OBJ="gtkutil.o $GTK_OBJ"
2371     term_header=$gtk_term_header
2372     USE_X_TOOLKIT=none
2373     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2374       :
2375     else
2376       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2377        closing open displays.  This is no problem if you just use
2378        one display, but if you use more than one and close one of them
2379        Emacs may crash.]])
2380       sleep 3
2381     fi
2382   fi
2383
2384 fi
2385 AC_SUBST(GTK_OBJ)
2386
2387
2388 if test "${HAVE_GTK}" = "yes"; then
2389
2390   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2391   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2392   if test "$with_toolkit_scroll_bars" != no; then
2393     with_toolkit_scroll_bars=yes
2394   fi
2395
2396   dnl  Check if we have the old file selection dialog declared and
2397   dnl  in the link library.  In 2.x it may be in the library,
2398   dnl  but not declared if deprecated featured has been selected out.
2399   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2400   HAVE_GTK_FILE_SELECTION=no
2401   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2402                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2403 #include <gtk/gtk.h>])
2404   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2405     AC_CHECK_FUNCS(gtk_file_selection_new)
2406   fi
2407
2408   dnl Same as above for gtk_handle_box.
2409   HAVE_GTK_HANDLE_BOX=no
2410   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2411                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2412 #include <gtk/gtk.h>])
2413   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2414     AC_CHECK_FUNCS(gtk_handle_box_new)
2415   fi
2416
2417   dnl Same as above for gtk_tearoff_menu_item.
2418   HAVE_GTK_TEAROFF_MENU_ITEM=no
2419   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2420                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2421 #include <gtk/gtk.h>])
2422   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2423     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2424   fi
2425
2426   dnl Check for functions introduced in 2.14 and later.
2427   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2428                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2429                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2430                  gtk_orientable_set_orientation \
2431                  gtk_window_set_has_resize_grip)
2432
2433  term_header=gtkutil.h
2434 fi
2435
2436 CFLAGS=$OLD_CFLAGS
2437 LIBS=$OLD_LIBS
2438
2439 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2440 dnl other platforms.
2441 HAVE_DBUS=no
2442 DBUS_OBJ=
2443 if test "${with_dbus}" = "yes"; then
2444    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2445    if test "$HAVE_DBUS" = yes; then
2446      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2447      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2448      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2449      dnl D-Bus 1.5.12.
2450      OLD_LIBS=$LIBS
2451      LIBS="$LIBS $DBUS_LIBS"
2452      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2453                     dbus_type_is_valid \
2454                     dbus_validate_bus_name \
2455                     dbus_validate_path \
2456                     dbus_validate_interface \
2457                     dbus_validate_member)
2458      LIBS=$OLD_LIBS
2459      DBUS_OBJ=dbusbind.o
2460    fi
2461 fi
2462 AC_SUBST(DBUS_CFLAGS)
2463 AC_SUBST(DBUS_LIBS)
2464 AC_SUBST(DBUS_OBJ)
2465
2466 dnl GSettings has been tested under GNU/Linux only.
2467 HAVE_GSETTINGS=no
2468 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2469    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2470    if test "$HAVE_GSETTINGS" = "yes"; then
2471       old_CFLAGS=$CFLAGS
2472       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2473       old_LIBS=$LIBS
2474       LIBS="$LIBS $GSETTINGS_LIBS"
2475       AC_MSG_CHECKING([whether GSettings is in gio])
2476       AC_LINK_IFELSE(
2477          [AC_LANG_PROGRAM(
2478              [[/* Check that gsettings really is present.  */
2479              #include <glib-object.h>
2480              #include <gio/gio.h>
2481              ]],
2482              [[
2483                GSettings *settings;
2484                GVariant *val = g_settings_get_value (settings, "");
2485              ]])],
2486          [], HAVE_GSETTINGS=no)
2487       AC_MSG_RESULT([$HAVE_GSETTINGS])
2488
2489       if test "$HAVE_GSETTINGS" = "yes"; then
2490         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2491         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2492         SETTINGS_LIBS="$GSETTINGS_LIBS"
2493       fi
2494       CFLAGS=$old_CFLAGS
2495       LIBS=$old_LIBS
2496    fi
2497 fi
2498
2499 dnl GConf has been tested under GNU/Linux only.
2500 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2501 HAVE_GCONF=no
2502 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2503    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2504    if test "$HAVE_GCONF" = yes; then
2505       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2506       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2507       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2508       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2509    fi
2510 fi
2511
2512 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2513     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2514     if test "$HAVE_GOBJECT" = "yes"; then
2515        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2516        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2517     fi
2518     SAVE_CFLAGS="$CFLAGS"
2519     SAVE_LIBS="$LIBS"
2520     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2521     LIBS="$SETTINGS_LIBS $LIBS"
2522     CFLAGS="$SAVE_CFLAGS"
2523     LIBS="$SAVE_LIBS"
2524 fi
2525 AC_SUBST(SETTINGS_CFLAGS)
2526 AC_SUBST(SETTINGS_LIBS)
2527
2528
2529 dnl SELinux is available for GNU/Linux only.
2530 HAVE_LIBSELINUX=no
2531 LIBSELINUX_LIBS=
2532 if test "${with_selinux}" = "yes"; then
2533    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2534    if test "$HAVE_LIBSELINUX" = yes; then
2535       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2536       LIBSELINUX_LIBS=-lselinux
2537    fi
2538 fi
2539 AC_SUBST(LIBSELINUX_LIBS)
2540
2541 HAVE_GNUTLS=no
2542 HAVE_GNUTLS3=no
2543 if test "${with_gnutls}" = "yes" ; then
2544   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0],
2545     [HAVE_GNUTLS3=yes], [HAVE_GNUTLS3=no])
2546   if test "${HAVE_GNUTLS3}" = "yes"; then
2547     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2548     HAVE_GNUTLS="yes"
2549   else
2550     EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2551       [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2552   fi
2553   if test "${HAVE_GNUTLS}" = "yes"; then
2554     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2555   fi
2556
2557   # Windows loads GnuTLS dynamically
2558   if test "${opsys}" = "mingw32"; then
2559     LIBGNUTLS_LIBS=
2560   fi
2561 fi
2562
2563 AC_SUBST(LIBGNUTLS_LIBS)
2564 AC_SUBST(LIBGNUTLS_CFLAGS)
2565
2566 NOTIFY_OBJ=
2567 NOTIFY_SUMMARY=no
2568
2569 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2570 dnl a particular library.  This doesn't make much sense?
2571 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2572   with_file_notification=no
2573 fi
2574
2575 dnl MS Windows native file monitor is available for mingw32 only.
2576 case $with_file_notification,$opsys in
2577   w32,* | yes,mingw32)
2578     AC_CHECK_HEADER(windows.h)
2579     if test "$ac_cv_header_windows_h" = yes ; then
2580        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2581        NOTIFY_OBJ=w32notify.o
2582        NOTIFY_SUMMARY="yes (w32)"
2583     fi ;;
2584 esac
2585
2586 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2587 dnl has been added in glib 2.24.  It has been tested under
2588 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2589 dnl only sense when glib has been compiled with inotify support.  How
2590 dnl to check?
2591 case $with_file_notification,$NOTIFY_OBJ in
2592   gfile, | yes,)
2593     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2594     if test "$HAVE_GFILENOTIFY" = "yes"; then
2595        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2596        NOTIFY_OBJ=gfilenotify.o
2597        NOTIFY_SUMMARY="yes -lgio (gfile)"
2598     fi ;;
2599 esac
2600
2601 dnl inotify is only available on GNU/Linux.
2602 case $with_file_notification,$NOTIFY_OBJ in
2603   inotify, | yes,)
2604     AC_CHECK_HEADER(sys/inotify.h)
2605     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2606         AC_CHECK_FUNC(inotify_init1)
2607         if test "$ac_cv_func_inotify_init1" = yes; then
2608           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2609           NOTIFY_OBJ=inotify.o
2610           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2611        fi
2612     fi ;;
2613 esac
2614
2615 case $with_file_notification,$NOTIFY_OBJ in
2616   yes,* | no,* | *,?*) ;;
2617   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2618 esac
2619
2620 if test -n "$NOTIFY_OBJ"; then
2621    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2622 fi
2623 AC_SUBST(NOTIFY_OBJ)
2624 AC_SUBST(GFILENOTIFY_CFLAGS)
2625 AC_SUBST(GFILENOTIFY_LIBS)
2626
2627 dnl Do not put whitespace before the #include statements below.
2628 dnl Older compilers (eg sunos4 cc) choke on it.
2629 HAVE_XAW3D=no
2630 LUCID_LIBW=
2631 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2632   if test "$with_xaw3d" != no; then
2633     AC_CACHE_VAL(emacs_cv_xaw3d,
2634     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2635 #include <X11/Intrinsic.h>
2636 #include <X11/Xaw3d/Simple.h>]],
2637       [[]])],
2638       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2639                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2640       emacs_cv_xaw3d=no)])
2641   else
2642     emacs_cv_xaw3d=no
2643   fi
2644   if test $emacs_cv_xaw3d = yes; then
2645     AC_MSG_CHECKING(for xaw3d)
2646     AC_MSG_RESULT([yes; using Lucid toolkit])
2647     USE_X_TOOLKIT=LUCID
2648     HAVE_XAW3D=yes
2649     LUCID_LIBW=-lXaw3d
2650     AC_DEFINE(HAVE_XAW3D, 1,
2651               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2652   else
2653     AC_MSG_CHECKING(for xaw3d)
2654     AC_MSG_RESULT(no)
2655     AC_MSG_CHECKING(for libXaw)
2656     AC_CACHE_VAL(emacs_cv_xaw,
2657     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2658 #include <X11/Intrinsic.h>
2659 #include <X11/Xaw/Simple.h>]],
2660       [[]])],
2661       emacs_cv_xaw=yes,
2662       emacs_cv_xaw=no)])
2663     if test $emacs_cv_xaw = yes; then
2664       AC_MSG_RESULT([yes; using Lucid toolkit])
2665       USE_X_TOOLKIT=LUCID
2666       LUCID_LIBW=-lXaw
2667     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2668       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2669     else
2670       AC_MSG_ERROR([No X toolkit could be found.
2671 If you are sure you want Emacs compiled without an X toolkit, pass
2672   --with-x-toolkit=no
2673 to configure.  Otherwise, install the development libraries for the toolkit
2674 that you want to use (e.g. Gtk+) and re-run configure.])
2675     fi
2676   fi
2677 fi
2678
2679 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2680
2681 LIBXTR6=
2682 LIBXMU=
2683 if test "${USE_X_TOOLKIT}" != "none"; then
2684   AC_MSG_CHECKING(X11 toolkit version)
2685   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2686   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2687 [[#if XtSpecificationRelease < 6
2688 fail;
2689 #endif
2690 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2691   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2692   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2693     AC_MSG_RESULT(6 or newer)
2694     AC_DEFINE(HAVE_X11XTR6, 1,
2695               [Define to 1 if you have the X11R6 or newer version of Xt.])
2696     LIBXTR6="-lSM -lICE"
2697     case "$opsys" in
2698       ## Use libw.a along with X11R6 Xt.
2699       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2700     esac
2701   else
2702     AC_MSG_RESULT(before 6)
2703   fi
2704
2705 dnl If using toolkit, check whether libXmu.a exists.
2706 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2707   OLDLIBS="$LIBS"
2708   if test x$HAVE_X11XTR6 = xyes; then
2709     OTHERLIBS='-lXt -lSM -lICE'
2710   else
2711     OTHERLIBS='-lXt'
2712   fi
2713   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2714   if test "X$LIBS" != "X$OLDLIBS"; then
2715     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2716   fi
2717   LIBS=$OLDLIBS
2718   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2719 fi
2720 AC_SUBST(LIBXTR6)
2721 AC_SUBST(LIBXMU)
2722
2723 LIBXP=
2724 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2725   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2726   if test -d /usr/include/openmotif; then
2727     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2728     emacs_cv_openmotif=yes
2729     case "$canonical" in
2730       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2731       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2732       ;;
2733       *)
2734       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2735     esac
2736   else
2737     emacs_cv_openmotif=no
2738   fi
2739   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2740   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2741     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2742 int x = 5;
2743 #else
2744 Motif version prior to 2.1.
2745 #endif]])],
2746     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2747   if test $emacs_cv_motif_version_2_1 = yes; then
2748     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2749     if test x$emacs_cv_openmotif = xyes; then
2750       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2751     fi
2752   else
2753     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2754     # We put this in CFLAGS temporarily to precede other -I options
2755     # that might be in CFLAGS temporarily.
2756     # We put this in CPPFLAGS where it precedes the other -I options.
2757     OLD_CPPFLAGS=$CPPFLAGS
2758     OLD_CFLAGS=$CFLAGS
2759     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2760     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2761     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2762       [[int x = 5;]])],
2763       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2764     if test $emacs_cv_lesstif = yes; then
2765       # Make sure this -I option remains in CPPFLAGS after it is set
2766       # back to REAL_CPPFLAGS.
2767       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2768       # have those other -I options anyway.  Ultimately, having this
2769       # directory ultimately in CPPFLAGS will be enough.
2770       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2771       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2772     else
2773       CFLAGS=$OLD_CFLAGS
2774       CPPFLAGS=$OLD_CPPFLAGS
2775     fi
2776   fi
2777   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2778     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2779 fi
2780
2781 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2782 dnl using Motif or Xaw3d is available, and unless
2783 dnl --with-toolkit-scroll-bars=no was specified.
2784
2785 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2786             [Define to 1 if we should use toolkit scroll bars.])dnl
2787 USE_TOOLKIT_SCROLL_BARS=no
2788 if test "${with_toolkit_scroll_bars}" != "no"; then
2789   if test "${USE_X_TOOLKIT}" != "none"; then
2790     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2791       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2792       HAVE_XAW3D=no
2793       USE_TOOLKIT_SCROLL_BARS=yes
2794     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2795       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2796       USE_TOOLKIT_SCROLL_BARS=yes
2797     fi
2798   elif test "${HAVE_GTK}" = "yes"; then
2799     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2800     USE_TOOLKIT_SCROLL_BARS=yes
2801   elif test "${HAVE_NS}" = "yes"; then
2802     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2803     USE_TOOLKIT_SCROLL_BARS=yes
2804   elif test "${HAVE_W32}" = "yes"; then
2805     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2806     USE_TOOLKIT_SCROLL_BARS=yes
2807   fi
2808 fi
2809
2810 dnl See if XIM is available.
2811 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2812           #include <X11/Xlib.h>
2813           #include <X11/Xresource.h>]],
2814          [[XIMProc  callback;]])],
2815          [HAVE_XIM=yes
2816          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2817          HAVE_XIM=no)
2818
2819 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2820
2821 if test "${with_xim}" != "no"; then
2822   AC_DEFINE(USE_XIM, 1,
2823             [Define to 1 if we should use XIM, if it is available.])
2824 fi
2825
2826
2827 if test "${HAVE_XIM}" != "no"; then
2828   late_CFLAGS=$CFLAGS
2829   if test "$GCC" = yes; then
2830     CFLAGS="$CFLAGS --pedantic-errors"
2831   fi
2832   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2833 #include <X11/Xlib.h>
2834 #include <X11/Xresource.h>]],
2835 [[Display *display;
2836 XrmDatabase db;
2837 char *res_name;
2838 char *res_class;
2839 XIMProc  callback;
2840 XPointer *client_data;
2841 #ifndef __GNUC__
2842 /* If we're not using GCC, it's probably not XFree86, and this is
2843    probably right, but we can't use something like --pedantic-errors.  */
2844 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2845                                            char*, XIMProc, XPointer*);
2846 #endif
2847 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2848    client_data);]])],
2849     [emacs_cv_arg6_star=yes])
2850   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2851          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2852 either XPointer or XPointer*.])dnl
2853   if test "$emacs_cv_arg6_star" = yes; then
2854     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2855   else
2856     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2857   fi
2858   CFLAGS=$late_CFLAGS
2859 fi
2860
2861 ### Start of font-backend (under any platform) section.
2862 # (nothing here yet -- this is a placeholder)
2863 ### End of font-backend (under any platform) section.
2864
2865 ### Start of font-backend (under X11) section.
2866 if test "${HAVE_X11}" = "yes"; then
2867     ## Use -lXft if available, unless `--with-xft=no'.
2868     HAVE_XFT=maybe
2869     if test "x${with_x}" = "xno"; then
2870       with_xft="no";
2871     fi
2872
2873     if test "$with_xft" != no; then
2874       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
2875       with_xft=$HAVE_FONTCONFIG
2876     fi
2877
2878     if test "x${with_xft}" != "xno"; then
2879
2880       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
2881       ## Because xftfont.c uses XRenderQueryExtension, we also
2882       ## need to link to -lXrender.
2883       HAVE_XRENDER=no
2884       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2885       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2886         OLD_CPPFLAGS="$CPPFLAGS"
2887         OLD_CFLAGS="$CFLAGS"
2888         OLD_LIBS="$LIBS"
2889         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2890         CFLAGS="$CFLAGS $XFT_CFLAGS"
2891         XFT_LIBS="-lXrender $XFT_LIBS"
2892         LIBS="$XFT_LIBS $LIBS"
2893         AC_CHECK_HEADER(X11/Xft/Xft.h,
2894           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2895           [[#include <X11/X.h>]])
2896
2897         if test "${HAVE_XFT}" = "yes"; then
2898           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2899             AC_SUBST(XFT_LIBS)
2900           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2901         fi                        # "${HAVE_XFT}" = "yes"
2902         CPPFLAGS=$OLD_CPPFLAGS
2903         CFLAGS=$OLD_CFLAGS
2904         LIBS=$OLD_LIBS
2905       fi                          # "$HAVE_XFT" != no
2906     fi                            # "x${with_xft}" != "xno"
2907
2908     ## We used to allow building with FreeType and without Xft.
2909     ## However, the ftx font backend driver is not in good shape.
2910     if test "$HAVE_XFT" != "yes"; then
2911        dnl For the "Does Emacs use" message at the end.
2912        HAVE_XFT=no
2913        HAVE_FREETYPE=no
2914     else
2915        dnl Strict linkers fail with
2916        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2917        dnl if -lfreetype is not specified.
2918        dnl The following is needed to set FREETYPE_LIBS.
2919        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
2920
2921        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2922     fi
2923
2924     HAVE_LIBOTF=no
2925     if test "${HAVE_FREETYPE}" = "yes"; then
2926       AC_DEFINE(HAVE_FREETYPE, 1,
2927                 [Define to 1 if using the freetype and fontconfig libraries.])
2928       if test "${with_libotf}" != "no"; then
2929         EMACS_CHECK_MODULES([LIBOTF], [libotf])
2930         if test "$HAVE_LIBOTF" = "yes"; then
2931           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2932           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2933                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2934                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2935           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2936             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2937                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2938           fi
2939         fi
2940       fi
2941     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2942     dnl Does the new font backend require it, or can it work without it?
2943     fi
2944
2945     HAVE_M17N_FLT=no
2946     if test "${HAVE_LIBOTF}" = yes; then
2947       if test "${with_m17n_flt}" != "no"; then
2948         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
2949         if test "$HAVE_M17N_FLT" = "yes"; then
2950           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2951         fi
2952       fi
2953     fi
2954 else
2955     HAVE_XFT=no
2956     HAVE_FREETYPE=no
2957     HAVE_LIBOTF=no
2958     HAVE_M17N_FLT=no
2959 fi
2960
2961 ### End of font-backend (under X11) section.
2962
2963 AC_SUBST(FREETYPE_CFLAGS)
2964 AC_SUBST(FREETYPE_LIBS)
2965 AC_SUBST(FONTCONFIG_CFLAGS)
2966 AC_SUBST(FONTCONFIG_LIBS)
2967 AC_SUBST(LIBOTF_CFLAGS)
2968 AC_SUBST(LIBOTF_LIBS)
2969 AC_SUBST(M17N_FLT_CFLAGS)
2970 AC_SUBST(M17N_FLT_LIBS)
2971
2972 ### Use -lXpm if available, unless `--with-xpm=no'.
2973 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2974 HAVE_XPM=no
2975 LIBXPM=
2976 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2977   if test "${with_xpm}" != "no"; then
2978     SAVE_CPPFLAGS="$CPPFLAGS"
2979     SAVE_LDFLAGS="$LDFLAGS"
2980     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2981     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2982     AC_CHECK_HEADER(X11/xpm.h,
2983       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2984     if test "${HAVE_XPM}" = "yes"; then
2985       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2986       AC_EGREP_CPP(no_return_alloc_pixels,
2987       [#include "X11/xpm.h"
2988 #ifndef XpmReturnAllocPixels
2989 no_return_alloc_pixels
2990 #endif
2991       ], HAVE_XPM=no, HAVE_XPM=yes)
2992
2993       if test "${HAVE_XPM}" = "yes"; then
2994         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2995         AC_MSG_RESULT(yes)
2996       else
2997         AC_MSG_RESULT(no)
2998         CPPFLAGS="$SAVE_CPPFLAGS"
2999         LDFLAGS="$SAVE_LDFLAGS"
3000       fi
3001     fi
3002   fi
3003
3004   if test "${HAVE_XPM}" = "yes"; then
3005     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3006     LIBXPM=-lXpm
3007   fi
3008 fi
3009
3010 if test "${HAVE_X11}" = "yes"; then
3011   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3012   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3013
3014   if test "${with_xpm}" != "no"; then
3015     AC_CHECK_HEADER(X11/xpm.h,
3016       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3017     if test "${HAVE_XPM}" = "yes"; then
3018       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3019       AC_EGREP_CPP(no_return_alloc_pixels,
3020       [#include "X11/xpm.h"
3021 #ifndef XpmReturnAllocPixels
3022 no_return_alloc_pixels
3023 #endif
3024       ], HAVE_XPM=no, HAVE_XPM=yes)
3025
3026       if test "${HAVE_XPM}" = "yes"; then
3027         AC_MSG_RESULT(yes)
3028       else
3029         AC_MSG_RESULT(no)
3030       fi
3031     fi
3032   fi
3033
3034   if test "${HAVE_XPM}" = "yes"; then
3035     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3036     LIBXPM=-lXpm
3037   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3038     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3039     LIBXPM=-lXpm
3040   fi
3041 fi
3042
3043 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3044 ### slightly different requirements wrt image libraries (it doesn't
3045 ### use -lXpm because it loads the xpm shared library dynamically at
3046 ### run time).
3047 if test "${opsys}" = "mingw32"; then
3048   if test "${with_xpm}" != "no"; then
3049     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3050 #define FOR_MSW 1])
3051   fi
3052
3053   if test "${HAVE_XPM}" = "yes"; then
3054     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3055   fi
3056 fi
3057
3058 AC_SUBST(LIBXPM)
3059
3060 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3061 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3062 HAVE_JPEG=no
3063 LIBJPEG=
3064 if test "${opsys}" = "mingw32"; then
3065   if test "${with_jpeg}" != "no"; then
3066     dnl Checking for jpeglib.h can lose because of a redefinition of
3067     dnl HAVE_STDLIB_H.
3068     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3069   fi
3070   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3071   if test "${HAVE_JPEG}" = "yes"; then
3072     AC_DEFINE(HAVE_JPEG)
3073     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3074         [#include <jpeglib.h>
3075          version=JPEG_LIB_VERSION
3076 ],
3077         [AC_DEFINE(HAVE_JPEG)],
3078         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3079         HAVE_JPEG=no])
3080   fi
3081 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3082   if test "${with_jpeg}" != "no"; then
3083     dnl Checking for jpeglib.h can lose because of a redefinition of
3084     dnl  HAVE_STDLIB_H.
3085     AC_CHECK_HEADER(jerror.h,
3086       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3087   fi
3088
3089   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3090   if test "${HAVE_JPEG}" = "yes"; then
3091     AC_DEFINE(HAVE_JPEG)
3092     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3093         [#include <jpeglib.h>
3094          version=JPEG_LIB_VERSION
3095 ],
3096         [AC_DEFINE(HAVE_JPEG)],
3097         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3098         HAVE_JPEG=no])
3099   fi
3100   if test "${HAVE_JPEG}" = "yes"; then
3101     LIBJPEG=-ljpeg
3102   fi
3103 fi
3104 AC_SUBST(LIBJPEG)
3105
3106 HAVE_ZLIB=no
3107 LIBZ=
3108 if test "${with_zlib}" != "no"; then
3109   OLIBS=$LIBS
3110   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3111   LIBS=$OLIBS
3112   case $ac_cv_search_inflateEnd in
3113     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3114   esac
3115 fi
3116 if test "${HAVE_ZLIB}" = "yes"; then
3117   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3118   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3119   if test "${opsys}" = "mingw32"; then
3120      LIBZ=
3121   fi
3122 fi
3123 AC_SUBST(LIBZ)
3124
3125 ### Use -lpng if available, unless `--with-png=no'.
3126 HAVE_PNG=no
3127 LIBPNG=
3128 PNG_CFLAGS=
3129 if test "${NS_IMPL_COCOA}" = yes; then
3130   : # Nothing to do
3131 elif test "${with_png}" != no; then
3132   # mingw32 loads the library dynamically.
3133   if test "$opsys" = mingw32; then
3134     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3135   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3136     AC_MSG_CHECKING([for png])
3137     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3138     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3139       # libpng-config does not work; configure by hand.
3140       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3141       # in /usr/include/libpng.
3142       if test -r /usr/include/libpng/png.h &&
3143          test ! -r /usr/include/png.h; then
3144         png_cflags=-I/usr/include/libpng
3145       else
3146         png_cflags=
3147       fi
3148       png_libs='-lpng'
3149     }
3150     SAVE_CFLAGS=$CFLAGS
3151     SAVE_LIBS=$LIBS
3152     CFLAGS="$CFLAGS $png_cflags"
3153     LIBS="$png_libs -lz -lm $LIBS"
3154     AC_LINK_IFELSE(
3155       [AC_LANG_PROGRAM([[#include <png.h>]],
3156          [[return !png_get_channels (0, 0);]])],
3157       [HAVE_PNG=yes
3158        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3159        LIBPNG=$png_libs
3160        # $LIBPNG requires explicit -lz in some cases.
3161        # We don't know what those cases are, exactly, so play it safe and
3162        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3163        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3164          LIBPNG="$LIBPNG -lz"
3165        fi])
3166     CFLAGS=$SAVE_CFLAGS
3167     LIBS=$SAVE_LIBS
3168     AC_MSG_RESULT([$HAVE_PNG])
3169   fi
3170 fi
3171 if test $HAVE_PNG = yes; then
3172   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3173
3174   SAVE_CFLAGS=$CFLAGS
3175   CFLAGS="$CFLAGS $PNG_CFLAGS"
3176   AC_CHECK_DECL([png_longjmp],
3177     [],
3178     [AC_DEFINE([PNG_DEPSTRUCT], [],
3179        [Define to empty to suppress deprecation warnings when building
3180         with --enable-gcc-warnings and with libpng versions before 1.5,
3181         which lack png_longjmp.])],
3182     [[#include <png.h>
3183     ]])
3184   CFLAGS=$SAVE_CFLAGS
3185 fi
3186 AC_SUBST(LIBPNG)
3187 AC_SUBST(PNG_CFLAGS)
3188
3189 ### Use -ltiff if available, unless `--with-tiff=no'.
3190 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3191 HAVE_TIFF=no
3192 LIBTIFF=
3193 if test "${opsys}" = "mingw32"; then
3194   if test "${with_tiff}" != "no"; then
3195     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3196   fi
3197   if test "${HAVE_TIFF}" = "yes"; then
3198     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3199   fi
3200 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3201   if test "${with_tiff}" != "no"; then
3202     AC_CHECK_HEADER(tiffio.h,
3203       [tifflibs="-lz -lm"
3204       # At least one tiff package requires the jpeg library.
3205       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3206       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3207   fi
3208
3209   if test "${HAVE_TIFF}" = "yes"; then
3210     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3211     dnl FIXME -lz -lm, as per libpng?
3212     LIBTIFF=-ltiff
3213   fi
3214 fi
3215 AC_SUBST(LIBTIFF)
3216
3217 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3218 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3219 HAVE_GIF=no
3220 LIBGIF=
3221 if test "${opsys}" = "mingw32"; then
3222   if test "${with_gif}" != "no"; then
3223     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3224   fi
3225   if test "${HAVE_GIF}" = "yes"; then
3226     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3227   fi
3228 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3229         || test "${HAVE_W32}" = "yes"; then
3230   AC_CHECK_HEADER(gif_lib.h,
3231 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3232 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3233     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3234         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3235
3236   if test "$HAVE_GIF" = yes; then
3237     LIBGIF=-lgif
3238   elif test "$HAVE_GIF" = maybe; then
3239 # If gif_lib.h but no libgif, try libungif.
3240     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3241     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3242   fi
3243
3244   if test "${HAVE_GIF}" = "yes"; then
3245     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3246   fi
3247 fi
3248 AC_SUBST(LIBGIF)
3249
3250 dnl Check for required libraries.
3251 if test "${HAVE_X11}" = "yes"; then
3252   MISSING=""
3253   WITH_NO=""
3254   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3255     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3256   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3257     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3258   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3259     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3260   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3261     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3262   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3263     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3264
3265   if test "X${MISSING}" != X; then
3266     AC_MSG_ERROR([The following required libraries were not found:
3267     $MISSING
3268 Maybe some development libraries/packages are missing?
3269 If you don't want to link with them give
3270     $WITH_NO
3271 as options to configure])
3272   fi
3273 fi
3274
3275 ### Use -lgpm if available, unless `--with-gpm=no'.
3276 HAVE_GPM=no
3277 LIBGPM=
3278 if test "${with_gpm}" != "no"; then
3279   AC_CHECK_HEADER(gpm.h,
3280     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3281
3282   if test "${HAVE_GPM}" = "yes"; then
3283     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3284     LIBGPM=-lgpm
3285   fi
3286 fi
3287 AC_SUBST(LIBGPM)
3288
3289 dnl Check for malloc/malloc.h on darwin
3290 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3291
3292 GNUSTEP_CFLAGS=
3293 ### Use NeXTstep API to implement GUI.
3294 if test "${HAVE_NS}" = "yes"; then
3295   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3296   if test "${NS_IMPL_COCOA}" = "yes"; then
3297     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3298   fi
3299   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3300     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3301     # See also .m.o rule in Makefile.in */
3302     # FIXME: are all these flags really needed?  Document here why.  */
3303     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3304     ## Extra CFLAGS applied to src/*.m files.
3305     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3306   fi
3307   OTHER_FILES=ns-app
3308 fi
3309
3310 ### Use session management (-lSM -lICE) if available
3311 HAVE_X_SM=no
3312 LIBXSM=
3313 if test "${HAVE_X11}" = "yes"; then
3314   AC_CHECK_HEADER(X11/SM/SMlib.h,
3315     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3316
3317   if test "${HAVE_X_SM}" = "yes"; then
3318     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3319     LIBXSM="-lSM -lICE"
3320   fi
3321 fi
3322 AC_SUBST(LIBXSM)
3323
3324 ### Use XRandr (-lXrandr) if available
3325 HAVE_XRANDR=no
3326 if test "${HAVE_X11}" = "yes"; then
3327   XRANDR_REQUIRED=1.2.2
3328   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3329   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3330   if test $HAVE_XRANDR = no; then
3331     # Test old way in case pkg-config doesn't have it (older machines).
3332     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3333       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3334     if test $HAVE_XRANDR = yes; then
3335       XRANDR_LIBS=-lXrandr
3336     fi
3337   fi
3338   if test $HAVE_XRANDR = yes; then
3339     SAVE_CFLAGS="$CFLAGS"
3340     SAVE_LIBS="$LIBS"
3341     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3342     LIBS="$XRANDR_LIBS $LIBS"
3343     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3344     CFLAGS="$SAVE_CFLAGS"
3345     LIBS="$SAVE_LIBS"
3346
3347     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3348   fi
3349 fi
3350 AC_SUBST(XRANDR_CFLAGS)
3351 AC_SUBST(XRANDR_LIBS)
3352
3353 ### Use Xinerama (-lXinerama) if available
3354 HAVE_XINERAMA=no
3355 if test "${HAVE_X11}" = "yes"; then
3356   XINERAMA_REQUIRED=1.0.2
3357   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3358   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3359   if test $HAVE_XINERAMA = no; then
3360     # Test old way in case pkg-config doesn't have it (older machines).
3361     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3362       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3363     if test $HAVE_XINERAMA = yes; then
3364       XINERAMA_LIBS=-lXinerama
3365     fi
3366   fi
3367   if test $HAVE_XINERAMA = yes; then
3368     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3369   fi
3370 fi
3371 AC_SUBST(XINERAMA_CFLAGS)
3372 AC_SUBST(XINERAMA_LIBS)
3373
3374 ### Use Xfixes (-lXfixes) if available
3375 HAVE_XFIXES=no
3376 if test "${HAVE_X11}" = "yes"; then
3377   XFIXES_REQUIRED=4.0.0
3378   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3379   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3380   if test $HAVE_XFIXES = no; then
3381     # Test old way in case pkg-config doesn't have it (older machines).
3382     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3383       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3384     if test $HAVE_XFIXES = yes; then
3385       XFIXES_LIBS=-lXfixes
3386     fi
3387   fi
3388   if test $HAVE_XFIXES = yes; then
3389     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3390   fi
3391 fi
3392 AC_SUBST(XFIXES_CFLAGS)
3393 AC_SUBST(XFIXES_LIBS)
3394
3395 ### Use libxml (-lxml2) if available
3396 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3397 HAVE_LIBXML2=no
3398 if test "${with_xml2}" != "no"; then
3399   ### I'm not sure what the version number should be, so I just guessed.
3400   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3401   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3402   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3403     SAVE_CPPFLAGS="$CPPFLAGS"
3404     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3405     AC_CHECK_HEADER(libxml/HTMLparser.h,
3406       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3407                      [#include <libxml/HTMLparser.h>])])
3408     CPPFLAGS="$SAVE_CPPFLAGS"
3409     if test "${HAVE_LIBXML2}" = "yes"; then
3410       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3411       LIBXML2_LIBS="-lxml2"
3412     fi
3413   fi
3414   if test "${HAVE_LIBXML2}" = "yes"; then
3415     if test "${opsys}" != "mingw32"; then
3416       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no
3417         [$LIBXML2_LIBS])
3418     else
3419       LIBXML2_LIBS=""
3420     fi
3421     if test "${HAVE_LIBXML2}" = "yes"; then
3422       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3423     else
3424       LIBXML2_LIBS=""
3425       LIBXML2_CFLAGS=""
3426     fi
3427   fi
3428 fi
3429 AC_SUBST(LIBXML2_LIBS)
3430 AC_SUBST(LIBXML2_CFLAGS)
3431
3432 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3433 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3434 if test "${opsys}" = "mingw32"; then
3435   emacs_cv_netdb_declares_h_errno=yes
3436 fi
3437 AC_CACHE_CHECK(whether netdb declares h_errno,
3438                emacs_cv_netdb_declares_h_errno,
3439 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3440   [[return h_errno;]])],
3441   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3442 if test $emacs_cv_netdb_declares_h_errno = yes; then
3443   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3444 fi
3445
3446 # Check for mail-locking functions in a "mail" library.  Probably this should
3447 # have the same check as for liblockfile below.
3448 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3449 if test $have_mail = yes; then
3450   LIBS_MAIL=-lmail
3451   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3452
3453   OLD_LIBS=$LIBS
3454   LIBS="$LIBS_MAIL $LIBS"
3455   AC_CHECK_FUNCS(touchlock)
3456   LIBS=$OLD_LIBS
3457 else
3458   LIBS_MAIL=
3459 fi
3460 dnl Debian, at least:
3461 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3462 if test $have_lockfile = yes; then
3463    LIBS_MAIL=-llockfile
3464    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3465 else
3466 # If we have the shared liblockfile, assume we must use it for mail
3467 # locking (e.g. Debian).  If we couldn't link against liblockfile
3468 # (no liblockfile.a installed), ensure that we don't need to.
3469   dnl This works for files generally, not just executables.
3470   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3471   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3472                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3473   if test $ac_cv_prog_liblockfile = yes; then
3474     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3475 This probably means that movemail could lose mail.
3476 There may be a `development' package to install containing liblockfile.])
3477   fi
3478 fi
3479 AC_CHECK_HEADERS_ONCE(maillock.h)
3480 AC_SUBST(LIBS_MAIL)
3481
3482 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3483 ## interlock access to the mail spool.  The alternative is a lock file named
3484 ## /usr/spool/mail/$USER.lock.
3485 mail_lock=no
3486 case "$opsys" in
3487   aix4-2) mail_lock="lockf" ;;
3488
3489   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3490
3491   ## On GNU/Linux systems, both methods are used by various mail programs.
3492   ## I assume most people are using newer mailers that have heard of flock.
3493   ## Change this if you need to.
3494   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3495   ## configure gets the right answers, and that means *NOT* using flock.
3496   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3497   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3498   ## Debian maintainer hasn't provided a clean fix for Emacs.
3499   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3500   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3501   ## correct logic.  -- fx
3502   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3503   ## liblockfile is a Free Software replacement for libmail, used on
3504   ## Debian systems and elsewhere. -rfr.
3505   gnu-*)
3506     mail_lock="flock"
3507     if test $have_mail = yes || test $have_lockfile = yes; then
3508       test $ac_cv_header_maillock_h = yes && mail_lock=no
3509     fi
3510     ;;
3511
3512   mingw32)
3513     mail_lock="none-needed" ;;
3514 esac
3515
3516 BLESSMAIL_TARGET=
3517 case "$mail_lock" in
3518   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3519
3520   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3521
3522   none-needed) ;;
3523
3524   *) BLESSMAIL_TARGET="need-blessmail" ;;
3525 esac
3526 AC_SUBST(BLESSMAIL_TARGET)
3527
3528 OLD_LIBS=$LIBS
3529 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3530 AC_CHECK_FUNCS(accept4 gethostname \
3531 getrusage get_current_dir_name \
3532 lrand48 random rint \
3533 select getpagesize setlocale \
3534 getrlimit setrlimit shutdown getaddrinfo \
3535 pthread_sigmask strsignal setitimer \
3536 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3537 gai_strerror sync \
3538 getpwent endpwent getgrent endgrent \
3539 cfmakeraw cfsetspeed copysign __executable_start log2)
3540 LIBS=$OLD_LIBS
3541
3542 dnl No need to check for aligned_alloc and posix_memalign if using
3543 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3544 dnl Darwin as they are incompatible with unexmacosx.c.
3545 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3546   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3547 fi
3548
3549 dnl Cannot use AC_CHECK_FUNCS
3550 AC_CACHE_CHECK([for __builtin_unwind_init],
3551                emacs_cv_func___builtin_unwind_init,
3552 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3553                 emacs_cv_func___builtin_unwind_init=yes,
3554                 emacs_cv_func___builtin_unwind_init=no)])
3555 if test $emacs_cv_func___builtin_unwind_init = yes; then
3556   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3557             [Define to 1 if you have the `__builtin_unwind_init' function.])
3558 fi
3559
3560 AC_CHECK_HEADERS_ONCE(sys/un.h)
3561
3562 AC_FUNC_FSEEKO
3563
3564 # UNIX98 PTYs.
3565 AC_CHECK_FUNCS(grantpt)
3566
3567 # PTY-related GNU extensions.
3568 AC_CHECK_FUNCS(getpt posix_openpt)
3569
3570 # Check this now, so that we will NOT find the above functions in ncurses.
3571 # That is because we have not set up to link ncurses in lib-src.
3572 # It's better to believe a function is not available
3573 # than to expect to find it in ncurses.
3574 # Also we need tputs and friends to be able to build at all.
3575 AC_MSG_CHECKING([for library containing tputs])
3576 # Run a test program that contains a call to tputs, a call that is
3577 # never executed.  This tests whether a pre-'main' dynamic linker
3578 # works with the library.  It's too much trouble to actually call
3579 # tputs in the test program, due to portability hassles.  When
3580 # cross-compiling, assume the test program will run if it links.
3581 AC_DEFUN([tputs_link_source], [
3582   AC_LANG_SOURCE(
3583      [[extern void tputs (const char *, int, int (*)(int));
3584        int main (int argc, char **argv)
3585        {
3586           if (argc == 10000)
3587             tputs (argv[0], 0, 0);
3588           return 0;
3589        }]])
3590 ])
3591 if test "${opsys}" = "mingw32"; then
3592   msg='none required'
3593 else
3594   # Maybe curses should be tried earlier?
3595   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3596   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3597     OLIBS=$LIBS
3598     if test -z "$tputs_library"; then
3599       LIBS_TERMCAP=
3600       msg='none required'
3601     else
3602       LIBS_TERMCAP=-l$tputs_library
3603       msg=$LIBS_TERMCAP
3604       LIBS="$LIBS_TERMCAP $LIBS"
3605     fi
3606     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3607       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3608     LIBS=$OLIBS
3609     if test "X$msg" != Xno; then
3610       break
3611     fi
3612   done
3613 fi
3614 AC_MSG_RESULT([$msg])
3615 if test "X$msg" = Xno; then
3616   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3617 The following libraries were tried (in order):
3618   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3619 Please try installing whichever of these libraries is most appropriate
3620 for your system, together with its header files.
3621 For example, a libncurses-dev(el) or similar package.])
3622 fi
3623
3624 ## Use termcap instead of terminfo?
3625 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3626 TERMINFO=yes
3627 ## FIXME?  In the cases below where we unconditionally set
3628 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3629 ## if that was found above to have tputs.
3630 ## Should we use the gnu* logic everywhere?
3631 case "$opsys" in
3632   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3633   ##  The ncurses library has been moved out of the System framework in
3634   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3635   ##  option to use it.
3636   darwin) LIBS_TERMCAP="-lncurses" ;;
3637
3638   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3639
3640   freebsd)
3641     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3642     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3643     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3644 [[#if __FreeBSD_version < 400000
3645 fail;
3646 #endif
3647 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3648
3649     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3650
3651     if test $emacs_cv_freebsd_terminfo = yes; then
3652       LIBS_TERMCAP="-lncurses"
3653     else
3654       TERMINFO=no
3655       LIBS_TERMCAP="-ltermcap"
3656     fi
3657     ;;
3658
3659   mingw32)
3660     TERMINFO=no
3661     LIBS_TERMCAP=
3662     ;;
3663
3664   netbsd)
3665     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3666       TERMINFO=no
3667       LIBS_TERMCAP="-ltermcap"
3668     fi
3669     ;;
3670
3671   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3672
3673   ## hpux: Make sure we get select from libc rather than from libcurses
3674   ##  because libcurses on HPUX 10.10 has a broken version of select.
3675   ##  We used to use -lc -lcurses, but this may be cleaner.
3676   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3677   # set that way, now it uses the default).  Isn't this a contradiction?
3678   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3679
3680 esac
3681
3682 TERMCAP_OBJ=tparam.o
3683 if test $TERMINFO = yes; then
3684   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3685   TERMCAP_OBJ=terminfo.o
3686 fi
3687 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3688   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3689 fi
3690 AC_SUBST(LIBS_TERMCAP)
3691 AC_SUBST(TERMCAP_OBJ)
3692
3693
3694 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3695 # On Darwin, res_init appears not to be useful: see bug#562 and
3696 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3697 resolv=no
3698
3699 if test $opsys != darwin; then
3700
3701   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3702 #include <arpa/nameser.h>
3703 #include <resolv.h>]],
3704     [[return res_init();]])],
3705     have_res_init=yes, have_res_init=no)
3706   if test "$have_res_init" = no; then
3707     OLIBS="$LIBS"
3708     LIBS="$LIBS -lresolv"
3709     AC_MSG_CHECKING(for res_init with -lresolv)
3710     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3711 #include <arpa/nameser.h>
3712 #include <resolv.h>]],
3713       [[return res_init();]])],
3714       have_res_init=yes, have_res_init=no)
3715     AC_MSG_RESULT($have_res_init)
3716     if test "$have_res_init" = yes ; then
3717       resolv=yes
3718     fi
3719     LIBS="$OLIBS"
3720   fi
3721
3722   if test "$have_res_init" = yes; then
3723     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3724   fi
3725 fi                              dnl !darwin
3726
3727 # Do we need the Hesiod library to provide the support routines?
3728 dnl FIXME?  Should we be skipping this on Darwin too?
3729 LIBHESIOD=
3730 if test "$with_hesiod" != no ; then
3731   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3732   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3733      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3734                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3735   if test "$resolv" = yes ; then
3736     RESOLVLIB=-lresolv
3737   else
3738     RESOLVLIB=
3739   fi
3740   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3741         hesiod=yes, :, $RESOLVLIB)])
3742
3743   if test x"$hesiod" = xyes; then
3744     LIBHESIOD=-lhesiod
3745   fi
3746 fi
3747 AC_SUBST(LIBHESIOD)
3748
3749 # Do we need libresolv (due to res_init or Hesiod)?
3750 if test "$resolv" = yes && test $opsys != darwin; then
3751   LIBRESOLV=-lresolv
3752 else
3753   LIBRESOLV=
3754 fi
3755 AC_SUBST(LIBRESOLV)
3756
3757 # These tell us which Kerberos-related libraries to use.
3758 COM_ERRLIB=
3759 CRYPTOLIB=
3760 KRB5LIB=
3761 DESLIB=
3762 KRB4LIB=
3763
3764 if test "${with_kerberos}" != no; then
3765   OLD_LIBS=$LIBS
3766   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3767   if test $have_com_err = yes; then
3768     COM_ERRLIB=-lcom_err
3769     LIBS="$COM_ERRLIB $LIBS"
3770   fi
3771   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3772   if test $have_crypto = yes; then
3773     CRYPTOLIB=-lcrypto
3774     LIBS="$CRYPTOLIB $LIBS"
3775   fi
3776   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3777   if test $have_k5crypto = yes; then
3778     CRYPTOLIB=-lk5crypto
3779     LIBS="$CRYPTOLIB $LIBS"
3780   fi
3781   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3782   if test $have_krb5=yes; then
3783     KRB5LIB=-lkrb5
3784     LIBS="$KRB5LIB $LIBS"
3785   fi
3786   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3787   if test "${with_kerberos5}" = no; then
3788     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3789     if test $have_des425 = yes; then
3790       DESLIB=-ldes425
3791       LIBS="$DESLIB $LIBS"
3792     else
3793       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3794       if test $have_des = yes; then
3795         DESLIB=-ldes
3796         LIBS="$DESLIB $LIBS"
3797       fi
3798     fi
3799     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3800     if test $have_krb4 = yes; then
3801       KRB4LIB=-lkrb4
3802       LIBS="$KRB4LIB $LIBS"
3803     else
3804       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3805       if test $have_krb = yes; then
3806         KRB4LIB=-lkrb
3807         LIBS="$KRB4LIB $LIBS"
3808       fi
3809     fi
3810   fi
3811
3812   if test "${with_kerberos5}" != no; then
3813     AC_CHECK_HEADERS(krb5.h,
3814       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3815                         [#include <krb5.h>])])
3816   else
3817     AC_CHECK_HEADERS(krb.h,,
3818                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3819                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3820   fi
3821   AC_CHECK_HEADERS(com_err.h)
3822   LIBS=$OLD_LIBS
3823 fi
3824
3825 AC_SUBST(COM_ERRLIB)
3826 AC_SUBST(CRYPTOLIB)
3827 AC_SUBST(KRB5LIB)
3828 AC_SUBST(DESLIB)
3829 AC_SUBST(KRB4LIB)
3830
3831 AC_CHECK_HEADERS(valgrind/valgrind.h)
3832
3833 AC_CHECK_FUNCS_ONCE(tzset)
3834 AC_MSG_CHECKING(whether localtime caches TZ)
3835 AC_CACHE_VAL(emacs_cv_localtime_cache,
3836 [if test x$ac_cv_func_tzset = xyes; then
3837 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3838 char TZ_GMT0[] = "TZ=GMT0";
3839 char TZ_PST8[] = "TZ=PST8";
3840 main()
3841 {
3842   time_t now = time ((time_t *) 0);
3843   int hour_GMT0, hour_unset;
3844   if (putenv (TZ_GMT0) != 0)
3845     exit (1);
3846   hour_GMT0 = localtime (&now)->tm_hour;
3847   unsetenv("TZ");
3848   hour_unset = localtime (&now)->tm_hour;
3849   if (putenv (TZ_PST8) != 0)
3850     exit (1);
3851   if (localtime (&now)->tm_hour == hour_GMT0)
3852     exit (1);
3853   unsetenv("TZ");
3854   if (localtime (&now)->tm_hour != hour_unset)
3855     exit (1);
3856   exit (0);
3857 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3858 [# If we have tzset, assume the worst when cross-compiling.
3859 emacs_cv_localtime_cache=yes])
3860 else
3861         # If we lack tzset, report that localtime does not cache TZ,
3862         # since we can't invalidate the cache if we don't have tzset.
3863         emacs_cv_localtime_cache=no
3864 fi])dnl
3865 AC_MSG_RESULT($emacs_cv_localtime_cache)
3866 if test $emacs_cv_localtime_cache = yes; then
3867   AC_DEFINE(LOCALTIME_CACHE, 1,
3868             [Define to 1 if localtime caches TZ.])
3869 fi
3870
3871 ok_so_far=yes
3872 AC_CHECK_FUNC(socket, , ok_so_far=no)
3873 if test $ok_so_far = yes; then
3874   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3875 fi
3876 if test $ok_so_far = yes; then
3877   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3878 fi
3879 if test $ok_so_far = yes; then
3880 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3881   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3882             [Define to 1 if you have inet sockets.])
3883 fi
3884
3885 AC_FUNC_FORK
3886
3887 AC_CHECK_FUNCS(snprintf)
3888
3889 dnl Check for glib.  This differs from other library checks in that
3890 dnl Emacs need not link to glib unless some other library is already
3891 dnl linking to glib.  Although glib provides no facilities that Emacs
3892 dnl needs for its own purposes, when glib is present Emacs needs to
3893 dnl use primitives like g_main_context_query to avoid clashing with
3894 dnl glib at a low level.
3895 dnl
3896 dnl Check this late, since it depends on $GTK_CFLAGS etc.
3897 XGSELOBJ=
3898 OLDCFLAGS="$CFLAGS"
3899 OLDLIBS="$LIBS"
3900 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
3901 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
3902 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3903 LIBS="$LIBS $GFILENOTIFY_LIBS"
3904 AC_MSG_CHECKING([whether GLib is linked in])
3905 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3906         [[#include <glib.h>
3907         ]],
3908         [[g_print ("Hello world");]])],
3909      [links_glib=yes],
3910      [links_glib=no])
3911 AC_MSG_RESULT([$links_glib])
3912 if test "${links_glib}" = "yes"; then
3913   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3914   if test "$HAVE_NS" = no;then
3915     XGSELOBJ=xgselect.o
3916   fi
3917 fi
3918 CFLAGS="$OLDCFLAGS"
3919 LIBS="$OLDLIBS"
3920 AC_SUBST(XGSELOBJ)
3921
3922 dnl Adapted from Haible's version.
3923 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3924   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3925     [[char* cs = nl_langinfo(CODESET);]])],
3926     emacs_cv_langinfo_codeset=yes,
3927     emacs_cv_langinfo_codeset=no)
3928   ])
3929 if test $emacs_cv_langinfo_codeset = yes; then
3930   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3931     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3932 fi
3933
3934 AC_TYPE_MBSTATE_T
3935
3936 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3937   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3938                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3939 if test "$emacs_cv_c_restrict_arr" = yes; then
3940   AC_DEFINE(__restrict_arr, __restrict,
3941     [Define to compiler's equivalent of C99 restrict keyword in array
3942      declarations.  Define as empty for no equivalent.])
3943 fi
3944
3945 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3946 dnl how the tty code is related to POSIX and/or other versions of termios.
3947 dnl The following looks like a useful start.
3948 dnl
3949 dnl AC_SYS_POSIX_TERMIOS
3950 dnl if test $ac_cv_sys_posix_termios = yes; then
3951 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3952 dnl                                and macros for terminal control.])
3953 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3954 dnl fi
3955
3956 dnl Turned on June 1996 supposing nobody will mind it.
3957 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3958 if test "${opsys}" != "mingw32"; then
3959    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3960      in the full name stands for the login id.])
3961 fi
3962
3963 dnl Everybody supports this, except MS.
3964 dnl Seems like the kind of thing we should be testing for, though.
3965 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3966 if test "${opsys}" != "mingw32"; then
3967   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3968 fi
3969
3970 dnl Everybody supports this, except MS-DOS.
3971 dnl Seems like the kind of thing we should be testing for, though.
3972 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3973 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3974   4.2-compatible sockets.])
3975
3976 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3977
3978 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3979   a null file, or a data sink.])
3980 if test "${opsys}" = "mingw32"; then
3981   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3982 else
3983   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3984 fi
3985
3986 if test "${opsys}" = "mingw32"; then
3987   SEPCHAR=';'
3988 else
3989   SEPCHAR=':'
3990 fi
3991 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
3992 dnl This is for MinGW, and is used in test/automated/Makefile.in.
3993 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
3994 dnl decides that a command-line argument to be passed to a MinGW program
3995 dnl is a PATH-style list of directories.  But that heuristics plays it
3996 dnl safe, and only does the replacement when it is _absolutely_ sure it
3997 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
3998 dnl which breaks in-tree builds.  So we do this manually instead.
3999 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4000 dnl be computed as ':' in MSYS Bash.
4001 AC_SUBST(SEPCHAR)
4002
4003 dnl Everybody supports this, except MS-DOS.
4004 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4005
4006 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4007
4008
4009 AC_DEFINE(DIRECTORY_SEP, ['/'],
4010   [Character that separates directories in a file name.])
4011
4012 if test "${opsys}" = "mingw32"; then
4013   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4014     [Returns true if character is a device separator.])
4015
4016   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4017     [Returns true if character is a directory separator.])
4018
4019   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4020     [Returns true if character is any form of separator.])
4021 else
4022   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4023     [Returns true if character is a device separator.])
4024
4025   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4026     [Returns true if character is a directory separator.])
4027
4028   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4029     [Returns true if character is any form of separator.])
4030 fi
4031
4032 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4033
4034 case $opsys in
4035   aix4-2)
4036     dnl Unfortunately without libXmu we cannot support EditRes.
4037     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4038       AC_DEFINE(NO_EDITRES, 1)
4039     fi
4040     ;;
4041
4042   hpux*)
4043     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4044     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4045     AC_DEFINE(NO_EDITRES, 1)
4046     ;;
4047 esac
4048
4049
4050 case $opsys in
4051   irix6-5 | sol2* | unixware )
4052     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4053     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4054     dnl need the constant to dimension an array.  So wire in the appropriate
4055     dnl value here.
4056     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4057     ;;
4058 esac
4059
4060 emacs_broken_SIGIO=no
4061
4062 case $opsys in
4063   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4064   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4065   hpux* | irix6-5 | openbsd | sol2* | unixware )
4066     emacs_broken_SIGIO=yes
4067     ;;
4068
4069   aix4-2)
4070     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4071     dnl the way this system works, libc functions that return malloced
4072     dnl memory use the libc malloc implementation. Calling xfree or
4073     dnl xrealloc on the results of such functions results in a crash.
4074     dnl
4075     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4076     dnl but that does not currently work on this system.
4077     dnl
4078     dnl It is possible to completely override the malloc implementation on
4079     dnl AIX, but that involves putting the malloc functions in a shared
4080     dnl library and setting the MALLOCTYPE environment variable to point to
4081     dnl that shared library.
4082     dnl
4083     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4084     dnl to avoid a crash just use the Emacs implementation for that function.
4085     dnl
4086     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4087     dnl of this file, so that we do not check for get_current_dir_name
4088     dnl on AIX.  But that might be fragile if something else ends
4089     dnl up testing for get_current_dir_name as a dependency.
4090     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4091       get_current_dir_name should not be used.])
4092     ;;
4093
4094   freebsd)
4095     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4096     dnl writes/reads on a PTY, read(2) returns bogus data:
4097     dnl
4098     dnl write(2)  1022 bytes
4099     dnl write(2)   954 bytes, get EAGAIN
4100     dnl read(2)   1024 bytes in process_read_output
4101     dnl read(2)     11 bytes in process_read_output
4102     dnl
4103     dnl That is, read(2) returns more bytes than have ever been written
4104     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4105     dnl successfully after processing (for example with CRs added if the
4106     dnl terminal is set up that way which it is here).  The same bytes will
4107     dnl be seen again in a later read(2), without the CRs.
4108     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4109       work around an issue when reading from a PTY.])
4110     ;;
4111 esac
4112
4113 case $opsys in
4114   gnu-* | sol2-10 )
4115     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4116     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4117   ;;
4118 esac
4119
4120 case $opsys in
4121   darwin | dragonfly | freebsd | netbsd | openbsd )
4122     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4123       close a pty to make it a controlling terminal (it is already a
4124       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4125   ;;
4126 esac
4127
4128 dnl FIXME Surely we can test for this rather than hard-code it.
4129 case $opsys in
4130   netbsd | openbsd) sound_device="/dev/audio" ;;
4131   *) sound_device="/dev/dsp" ;;
4132 esac
4133
4134 dnl Used in sound.c
4135 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4136   [Name of the default sound device.])
4137
4138
4139 dnl Emacs can read input using SIGIO and buffering characters itself,
4140 dnl or using CBREAK mode and making C-g cause SIGINT.
4141 dnl The choice is controlled by the variable interrupt_input.
4142 dnl
4143 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4144 dnl
4145 dnl Emacs uses the presence of the USABLE_SIGIO macro
4146 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4147 dnl INTERRUPT_INPUT to decide whether to use it by default.
4148 dnl
4149 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4150 dnl CBREAK mode has two disadvantages
4151 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4152 dnl I hear that in system V this problem does not exist.
4153 dnl 2) Control-G causes output to be discarded.
4154 dnl I do not know whether this can be fixed in system V.
4155 dnl
4156 dnl Another method of doing input is planned but not implemented.
4157 dnl It would have Emacs fork off a separate process
4158 dnl to read the input and send it to the true Emacs process
4159 dnl through a pipe.
4160 case $opsys in
4161   darwin | gnu-linux | gnu-kfreebsd )
4162     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4163   ;;
4164 esac
4165
4166
4167 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4168 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4169 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4170 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4171 dnl taking float or double parameters.
4172 case $opsys in
4173   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4174     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4175       file defines `NeedWidePrototypes' as `NO'.])
4176   ;;
4177 esac
4178
4179
4180 dnl Used in process.c, this must be a loop, even if it only runs once.
4181 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4182 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4183 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4184 dnl trying suffixes 0-16.
4185 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4186   first PTY, if PTYs are supported.])
4187 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4188 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4189   end of a PTY, if non-standard.])
4190 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4191   end of a PTY, if non-standard.])
4192
4193 case $opsys in
4194   aix4-2 )
4195     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4196     dnl You allocate a pty by opening /dev/ptc to get the master side.
4197     dnl To get the name of the slave side, you just ttyname() the master side.
4198     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4199     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4200     ;;
4201
4202   cygwin )
4203     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4204     dnl multi-line AC_DEFINEs are hard. :(
4205     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4206     AC_DEFINE(PTY_NAME_SPRINTF, [])
4207     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4208     ;;
4209
4210   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4211   darwin )
4212     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4213     dnl Not used, because PTY_ITERATION is defined.
4214     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4215     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4216     dnl But we don't have to block SIGCHLD because it is blocked in the
4217     dnl implementation of grantpt.
4218     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4219     AC_DEFINE(PTY_NAME_SPRINTF, [])
4220     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4221     ;;
4222
4223   gnu | openbsd )
4224     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4225     ;;
4226
4227   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4228     dnl if HAVE_GRANTPT
4229     if test "x$ac_cv_func_grantpt" = xyes; then
4230       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4231       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4232       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4233       dnl to prevent sigchld_handler from intercepting the child's death.
4234       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4235       dnl if HAVE_POSIX_OPENPT
4236       if test "x$ac_cv_func_posix_openpt" = xyes; then
4237         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4238         AC_DEFINE(PTY_NAME_SPRINTF, [])
4239       dnl if HAVE_GETPT
4240       elif test "x$ac_cv_func_getpt" = xyes; then
4241         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4242         AC_DEFINE(PTY_NAME_SPRINTF, [])
4243       else
4244         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4245       fi
4246     else
4247       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4248     fi
4249     ;;
4250
4251   hpux*)
4252     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4253     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4254     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4255     ;;
4256
4257   irix6-5 )
4258     dnl It looks like this cannot be right, because it is not a loop.
4259     dnl However, process.c actually does this:
4260     dnl # ifndef __sgi
4261     dnl   continue;
4262     dnl # else
4263     dnl   return -1;
4264     dnl # endif
4265     dnl which presumably makes it OK, since irix == sgi (?).
4266     dnl FIXME it seems like this special treatment is unnecessary?
4267     dnl Why can't irix use a single-trip loop like eg cygwin?
4268     AC_DEFINE(PTY_ITERATION, [])
4269     dnl Not used, because PTY_ITERATION is defined.
4270     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4271     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4272     dnl No need to get the pty name at all.
4273     AC_DEFINE(PTY_NAME_SPRINTF, [])
4274     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4275     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4276     ;;
4277
4278   sol2* )
4279     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4280     dnl from intercepting that death.  If any child but grantpt's should die
4281     dnl within, it should be caught after sigrelse(2).
4282     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4283     ;;
4284
4285   unixware )
4286     dnl Comments are as per sol2*.
4287     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4288     ;;
4289 esac
4290
4291
4292 case $opsys in
4293   sol2* | unixware )
4294     dnl This change means that we don't loop through allocate_pty too
4295     dnl many times in the (rare) event of a failure.
4296     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4297     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4298     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4299     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4300     ;;
4301 esac
4302
4303
4304 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4305 "typing" a signal character on the pty.])
4306
4307 case $opsys in
4308   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4309   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4310   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4311     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4312     ;;
4313
4314   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4315   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4316   gnu-linux | gnu-kfreebsd )
4317
4318     AC_MSG_CHECKING([for signals via characters])
4319     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4320 #include <linux/version.h>
4321 #if LINUX_VERSION_CODE < 0x20400
4322 # error "Linux version too old"
4323 #endif
4324       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4325
4326     AC_MSG_RESULT([$emacs_signals_via_chars])
4327     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4328     ;;
4329 esac
4330
4331
4332 AH_TEMPLATE(TAB3, [Undocumented.])
4333
4334 case $opsys in
4335   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4336
4337   gnu | dragonfly | freebsd | netbsd | openbsd )
4338     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4339     AC_DEFINE(TAB3, OXTABS)
4340     ;;
4341
4342   gnu-linux | gnu-kfreebsd )
4343     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4344 #ifndef __ia64__
4345 # error "not ia64"
4346 #endif
4347       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4348         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4349         [Mark a secondary stack, like the register stack on the ia64.]), [])
4350     ;;
4351
4352   hpux*)
4353     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4354       run_time_remap; for HPUX.])
4355     ;;
4356 esac
4357
4358
4359 dnl This won't be used automatically yet.  We also need to know, at least,
4360 dnl that the stack is continuous.
4361 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4362   registers relevant for conservative garbage collection in the jmp_buf.])
4363
4364
4365 case $opsys in
4366   dnl Not all the architectures are tested, but there are Debian packages
4367   dnl for SCM and/or Guile on them, so the technique must work.  See also
4368   dnl comments in alloc.c concerning setjmp and gcc.
4369   dnl Fixme: it's probably safe to just use the GCC conditional below.
4370   gnu-linux | gnu-kfreebsd )
4371     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4372 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4373   || defined __alpha__ || defined __mips__ || defined __s390__ \
4374   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4375   || defined __ia64__ || defined __sh__
4376 /* ok */
4377 #else
4378 # error "setjmp not known to work on this arch"
4379 #endif
4380     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4381     ;;
4382 esac
4383
4384
4385 if test x$GCC = xyes; then
4386    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4387    AC_DEFINE(GC_SETJMP_WORKS, 1)
4388 else
4389   case $opsys in
4390     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4391     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4392       AC_DEFINE(GC_SETJMP_WORKS, 1)
4393       ;;
4394   esac
4395 fi                              dnl GCC?
4396
4397 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4398 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4399   [AC_LINK_IFELSE(
4400      [AC_LANG_PROGRAM(
4401        [[#include <setjmp.h>
4402          #ifdef __MINGW32__
4403          # define _longjmp longjmp
4404          #endif
4405        ]],
4406        [[jmp_buf j;
4407          if (! _setjmp (j))
4408            _longjmp (j, 1);]])],
4409      [emacs_cv_func__setjmp=yes],
4410      [emacs_cv_func__setjmp=no])])
4411 if test $emacs_cv_func__setjmp = yes; then
4412   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4413 else
4414   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4415     [AC_LINK_IFELSE(
4416        [AC_LANG_PROGRAM(
4417          [[#include <setjmp.h>
4418          ]],
4419          [[sigjmp_buf j;
4420            if (! sigsetjmp (j, 1))
4421              siglongjmp (j, 1);]])],
4422        [emacs_cv_func_sigsetjmp=yes],
4423        [emacs_cv_func_sigsetjmp=no])])
4424   if test $emacs_cv_func_sigsetjmp = yes; then
4425     AC_DEFINE([HAVE_SIGSETJMP], 1,
4426       [Define to 1 if sigsetjmp and siglongjmp work.
4427        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4428   fi
4429 fi
4430
4431 case $opsys in
4432   sol2* | unixware )
4433     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4434     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4435     dnl and this is all we need.
4436     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4437     ;;
4438 esac
4439
4440
4441 case $opsys in
4442   hpux* | sol2* )
4443     dnl Used in xfaces.c.
4444     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4445       some systems, where it requires time.h.])
4446     ;;
4447 esac
4448
4449
4450 dnl Define symbols to identify the version of Unix this is.
4451 dnl Define all the symbols that apply correctly.
4452 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4453 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4454 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4455 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4456
4457 case $opsys in
4458   aix4-2)
4459     AC_DEFINE(USG, [])
4460     dnl This symbol should be defined on AIX Version 3  ???????
4461     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4462 #ifndef _AIX
4463 # error "_AIX not defined"
4464 #endif
4465     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4466     ;;
4467
4468   cygwin)
4469     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4470     ;;
4471
4472   darwin)
4473     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4474     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4475     dnl distinguish OS X from pure Darwin.
4476     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4477     ;;
4478
4479   gnu-linux | gnu-kfreebsd )
4480     AC_DEFINE(USG, [])
4481     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4482     ;;
4483
4484   hpux*)
4485     AC_DEFINE(USG, [])
4486     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4487     ;;
4488
4489   irix6-5)
4490     AC_DEFINE(USG, [])
4491     AC_DEFINE(USG5_4, [])
4492     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4493     ;;
4494
4495   mingw32)
4496     AC_DEFINE(DOS_NT, [])
4497     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4498     if test "x$ac_enable_checking" != "x" ; then
4499       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4500     fi
4501     ;;
4502
4503   sol2*)
4504     AC_DEFINE(USG, [])
4505     AC_DEFINE(USG5_4, [])
4506     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4507     ;;
4508
4509   unixware)
4510     AC_DEFINE(USG, [])
4511     AC_DEFINE(USG5_4, [])
4512     ;;
4513 esac
4514
4515 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4516   [case $opsys in
4517      aix4-2)
4518        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4519        emacs_cv_usable_FIONREAD=no
4520        ;;
4521
4522      mingw32)
4523        emacs_cv_usable_FIONREAD=yes
4524        ;;
4525
4526      *)
4527        AC_COMPILE_IFELSE(
4528          [AC_LANG_PROGRAM([[#include <sys/types.h>
4529                             #include <sys/ioctl.h>
4530                             #ifdef USG5_4
4531                             # include <sys/filio.h>
4532                             #endif
4533                           ]],
4534                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4535          [emacs_cv_usable_FIONREAD=yes],
4536          [emacs_cv_usable_FIONREAD=no])
4537        ;;
4538    esac])
4539 if test $emacs_cv_usable_FIONREAD = yes; then
4540   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4541
4542   if test $emacs_broken_SIGIO = no; then
4543     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4544       [AC_COMPILE_IFELSE(
4545          [AC_LANG_PROGRAM([[#include <fcntl.h>
4546                             #include <signal.h>
4547                           ]],
4548                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4549          [emacs_cv_usable_SIGIO=yes],
4550          [emacs_cv_usable_SIGIO=no])],
4551       [emacs_cv_usable_SIGIO=yes],
4552       [emacs_cv_usable_SIGIO=no])
4553     if test $emacs_cv_usable_SIGIO = yes; then
4554       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4555     fi
4556   fi
4557 fi
4558
4559
4560 case $opsys in
4561   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4562   dnl and on Cygwin prior to version 1.7.24 that becomes the
4563   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4564   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4565   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4566   dnl needed starting with cygwin-1.7.24, and it is no longer
4567   dnl effective starting with glib-2.36. */
4568   cygwin)
4569     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4570       G_SLICE environment variable to "always-malloc" at startup.])
4571     ;;
4572
4573   hpux11)
4574     dnl It works to open the pty's tty in the parent (Emacs), then
4575     dnl close and reopen it in the child.
4576     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4577       works to open a pty's tty in the parent process, then close and
4578       reopen it in the child.])
4579     ;;
4580
4581   irix6-5)
4582     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4583       use VSUSP instead of VSWTCH.])
4584     ;;
4585
4586   sol2-10)
4587     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4588       on Solaris.])
4589     ;;
4590 esac
4591
4592 # Set up the CFLAGS for real compilation, so we can substitute it.
4593 CFLAGS="$REAL_CFLAGS"
4594 CPPFLAGS="$REAL_CPPFLAGS"
4595 LIBS="$REAL_LIBS"
4596
4597 ## Hack to detect a buggy GCC version.
4598 if test "x$GCC" = xyes \
4599    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4600    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4601    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4602    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4603 fi
4604
4605 version=$PACKAGE_VERSION
4606
4607 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4608 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4609   [Short copyright string for this version of Emacs.])
4610 AC_SUBST(copyright)
4611
4612 ### Specify what sort of things we'll be editing into Makefile and config.h.
4613 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4614 AC_SUBST(version)
4615 AC_SUBST(configuration)
4616 ## Unused?
4617 AC_SUBST(canonical)
4618 AC_SUBST(srcdir)
4619 AC_SUBST(prefix)
4620 AC_SUBST(exec_prefix)
4621 AC_SUBST(bindir)
4622 AC_SUBST(datadir)
4623 AC_SUBST(sharedstatedir)
4624 AC_SUBST(libexecdir)
4625 AC_SUBST(mandir)
4626 AC_SUBST(infodir)
4627 AC_SUBST(lispdir)
4628 AC_SUBST(standardlisppath)
4629 AC_SUBST(locallisppath)
4630 AC_SUBST(lisppath)
4631 AC_SUBST(x_default_search_path)
4632 AC_SUBST(etcdir)
4633 AC_SUBST(archlibdir)
4634 AC_SUBST(etcdocdir)
4635 AC_SUBST(bitmapdir)
4636 AC_SUBST(gamedir)
4637 AC_SUBST(gameuser)
4638 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4639 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4640 ## end of LIBX_BASE, but nothing ever set it.
4641 AC_SUBST(LD_SWITCH_X_SITE)
4642 AC_SUBST(C_SWITCH_X_SITE)
4643 AC_SUBST(GNUSTEP_CFLAGS)
4644 AC_SUBST(CFLAGS)
4645 ## Used in lwlib/Makefile.in.
4646 AC_SUBST(X_TOOLKIT_TYPE)
4647 AC_SUBST(ns_appdir)
4648 AC_SUBST(ns_appbindir)
4649 AC_SUBST(ns_appresdir)
4650 AC_SUBST(ns_appsrc)
4651 AC_SUBST(GNU_OBJC_CFLAGS)
4652 AC_SUBST(OTHER_FILES)
4653
4654 if test -n "${term_header}"; then
4655     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4656         [Define to the header for the built-in window system.])
4657 fi
4658
4659 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4660                    [Define to the canonical Emacs configuration name.])
4661 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4662                    [Define to the options passed to configure.])
4663 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4664   define this to include extra configuration information.])
4665
4666 case $opsys in
4667   mingw32)
4668     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4669     ;;
4670 esac
4671
4672 XMENU_OBJ=
4673 XOBJ=
4674 FONT_OBJ=
4675 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4676   AC_DEFINE(HAVE_X_WINDOWS, 1,
4677             [Define to 1 if you want to use the X window system.])
4678   XMENU_OBJ=xmenu.o
4679   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4680   FONT_OBJ=xfont.o
4681   if test "$HAVE_XFT" = "yes"; then
4682     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4683   elif test "$HAVE_FREETYPE" = "yes"; then
4684     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4685   fi
4686   AC_SUBST(FONT_OBJ)
4687 fi
4688 AC_SUBST(XMENU_OBJ)
4689 AC_SUBST(XOBJ)
4690 AC_SUBST(FONT_OBJ)
4691
4692 WIDGET_OBJ=
4693 MOTIF_LIBW=
4694 if test "${USE_X_TOOLKIT}" != "none" ; then
4695   WIDGET_OBJ=widget.o
4696   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4697   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4698     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4699   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4700     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4701     MOTIF_LIBW=-lXm
4702     case "$opsys" in
4703       gnu-linux)
4704         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4705         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4706         ;;
4707
4708       unixware)
4709         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4710         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4711         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4712         ;;
4713
4714       aix4-2)
4715         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4716         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4717         ;;
4718     esac
4719     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4720   fi
4721 fi
4722 AC_SUBST(WIDGET_OBJ)
4723
4724 TOOLKIT_LIBW=
4725 case "$USE_X_TOOLKIT" in
4726   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4727   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4728   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4729 esac
4730 AC_SUBST(TOOLKIT_LIBW)
4731
4732 if test "${opsys}" != "mingw32"; then
4733   if test "$USE_X_TOOLKIT" = "none"; then
4734     LIBXT_OTHER="\$(LIBXSM)"
4735   else
4736     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4737   fi
4738 fi
4739 AC_SUBST(LIBXT_OTHER)
4740
4741 if test "${HAVE_X11}" = "yes" ; then
4742   AC_DEFINE(HAVE_X11, 1,
4743             [Define to 1 if you want to use version 11 of X windows.])
4744   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4745 else
4746   LIBX_OTHER=
4747 fi
4748 AC_SUBST(LIBX_OTHER)
4749
4750 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4751   LIBXMENU=
4752 elif test "$USE_X_TOOLKIT" = none; then
4753   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4754 else
4755   LIBXMENU='$(lwlibdir)/liblw.a'
4756 fi
4757 AC_SUBST(LIBXMENU)
4758
4759 if test "${GNU_MALLOC}" = "yes" ; then
4760   AC_DEFINE(GNU_MALLOC, 1,
4761             [Define to 1 if you want to use the GNU memory allocator.])
4762 fi
4763
4764 RALLOC_OBJ=
4765 if test "${REL_ALLOC}" = "yes" ; then
4766   AC_DEFINE(REL_ALLOC, 1,
4767             [Define REL_ALLOC if you want to use the relocating allocator for
4768              buffer space.])
4769
4770   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4771 fi
4772 AC_SUBST(RALLOC_OBJ)
4773
4774 if test "$opsys" = "cygwin"; then
4775   CYGWIN_OBJ="sheap.o cygw32.o"
4776   ## Cygwin differs because of its unexec().
4777   PRE_ALLOC_OBJ=
4778   POST_ALLOC_OBJ=lastfile.o
4779 elif test "$opsys" = "mingw32"; then
4780   CYGWIN_OBJ=
4781   PRE_ALLOC_OBJ=
4782   POST_ALLOC_OBJ=lastfile.o
4783 else
4784   CYGWIN_OBJ=
4785   PRE_ALLOC_OBJ=lastfile.o
4786   POST_ALLOC_OBJ=
4787 fi
4788 AC_SUBST(CYGWIN_OBJ)
4789 AC_SUBST(PRE_ALLOC_OBJ)
4790 AC_SUBST(POST_ALLOC_OBJ)
4791
4792 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4793 dnl verbatim defined above.  The tricky name is apropos, as this hack
4794 dnl makes Fortify go sour!
4795 AH_VERBATIM([FORTIFY_SOUR],
4796 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4797    The workaround disables some useful run-time checking, so it
4798    should be conditional to the platforms with the performance bug.
4799    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4800 #if defined __APPLE__ && defined __GNUC__
4801 # ifndef _DONT_USE_CTYPE_INLINE_
4802 #  define _DONT_USE_CTYPE_INLINE_
4803 # endif
4804 # ifndef _FORTIFY_SOURCE
4805 #  define _FORTIFY_SOURCE 0
4806 # endif
4807 #endif
4808 ])
4809
4810 # If user asks to omit features, disable optional features that gnulib
4811 # might otherwise enable.
4812 if test "$with_features" = no && test "$enable_acl" != yes; then
4813   enable_acl=no
4814 fi
4815
4816 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4817 # it temporarily reverts them to their pre-pkg-config values,
4818 # because gnulib needs to work with both src (which uses the
4819 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4820 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4821 # and it therefore needs to run in an environment where LIBS does not
4822 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4823 # for some package unrelated to lib-src.
4824 SAVE_CFLAGS=$CFLAGS
4825 SAVE_LIBS=$LIBS
4826 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4827 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4828 gl_ASSERT_NO_GNULIB_POSIXCHECK
4829 gl_ASSERT_NO_GNULIB_TESTS
4830 gl_INIT
4831 CFLAGS=$SAVE_CFLAGS
4832 LIBS=$SAVE_LIBS
4833
4834 if test "${opsys}" = "mingw32"; then
4835   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4836   # Remove unneeded switches from the value of CC that goes to Makefiles
4837   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4838 fi
4839
4840 case "$opsys" in
4841   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4842
4843   darwin)
4844    ## The -headerpad option tells ld (see man page) to leave room at the
4845    ## end of the header for adding load commands.  Needed for dumping.
4846    ## 0x690 is the total size of 30 segment load commands (at 56
4847    ## each); under Cocoa 31 commands are required.
4848    if test "$HAVE_NS" = "yes"; then
4849      libs_nsgui="-framework AppKit"
4850      if test "$NS_IMPL_COCOA" = "yes"; then
4851         libs_nsgui="$libs_nsgui -framework IOKit"
4852      fi
4853      headerpad_extra=6C8
4854    else
4855      libs_nsgui=
4856      headerpad_extra=690
4857    fi
4858    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4859
4860    ## This is here because src/Makefile.in did some extra fiddling around
4861    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4862    ## LD_SWITCH_SYSTEM_TEMACS instead,
4863    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4864      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4865    ;;
4866
4867   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4868   ## find X at run-time.
4869   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4870   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4871   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4872   ## had different values in configure (in ac_link) and src/Makefile.in.
4873   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4874   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4875
4876   mingw32)
4877    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
4878    case "$canonical" in
4879      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4880      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4881    esac
4882    ;;
4883
4884   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4885
4886   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4887 esac
4888
4889 if test x$ac_enable_profiling != x ; then
4890   case $opsys in
4891     *freebsd | gnu-linux) ;;
4892     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4893   esac
4894 fi
4895
4896 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4897
4898 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4899
4900 ## Common for all window systems
4901 if test "$window_system" != "none"; then
4902   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4903   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
4904   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4905 fi
4906
4907 AC_SUBST(WINDOW_SYSTEM_OBJ)
4908
4909 AH_TOP([/* GNU Emacs site configuration template file.
4910
4911 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4912   Free Software Foundation, Inc.
4913
4914 This file is part of GNU Emacs.
4915
4916 GNU Emacs is free software: you can redistribute it and/or modify
4917 it under the terms of the GNU General Public License as published by
4918 the Free Software Foundation, either version 3 of the License, or
4919 (at your option) any later version.
4920
4921 GNU Emacs is distributed in the hope that it will be useful,
4922 but WITHOUT ANY WARRANTY; without even the implied warranty of
4923 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4924 GNU General Public License for more details.
4925
4926 You should have received a copy of the GNU General Public License
4927 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4928
4929
4930 /* No code in Emacs #includes config.h twice, but some bits of code
4931    intended to work with other packages as well (like gmalloc.c)
4932    think they can include it as many times as they like.  */
4933 #ifndef EMACS_CONFIG_H
4934 #define EMACS_CONFIG_H
4935 ])dnl
4936
4937 AH_BOTTOM([#include <conf_post.h>
4938
4939 #endif /* EMACS_CONFIG_H */
4940
4941 /*
4942 Local Variables:
4943 mode: c
4944 End:
4945 */
4946 ])dnl
4947
4948 #### Report on what we decided to do.
4949 #### Report GTK as a toolkit, even if it doesn't use Xt.
4950 #### It makes printing result more understandable as using GTK sets
4951 #### toolkit_scroll_bars to yes by default.
4952 if test "${HAVE_GTK}" = "yes"; then
4953   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4954 fi
4955
4956 if test $USE_ACL -ne 0; then
4957   ACL_SUMMARY="yes $LIB_ACL"
4958 else
4959   ACL_SUMMARY=no
4960 fi
4961
4962 echo "
4963 Configured for \`${canonical}'.
4964
4965   Where should the build process find the source code?    ${srcdir}
4966   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4967   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4968   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4969   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4970   What window system should Emacs use?                    ${window_system}
4971   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4972
4973 if test -n "${x_includes}"; then
4974 echo "  Where do we find X Windows header files?                ${x_includes}"
4975 else
4976 echo "  Where do we find X Windows header files?                Standard dirs"
4977 fi
4978 if test -n "${x_libraries}"; then
4979 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4980 else
4981 echo "  Where do we find X Windows libraries?                   Standard dirs"
4982 fi
4983
4984 optsep=
4985 emacs_config_features=
4986 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG IMAGEMAGICK SOUND GPM DBUS \
4987   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
4988   LIBOTF XFT ZLIB; do
4989
4990     case $opt in
4991       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
4992       *) eval val=\${HAVE_$opt} ;;
4993     esac
4994     test x"$val" = xno && continue
4995     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
4996     optsep=' '
4997 done
4998 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
4999   [Summary of some of the main features enabled by configure.])
5000
5001 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
5002 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
5003 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
5004 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
5005 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5006 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
5007 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5008 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5009
5010 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5011
5012 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5013 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5014 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5015 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5016 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5017 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
5018 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5019 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5020 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5021
5022 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5023 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5024 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5025 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5026 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5027
5028 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5029 echo
5030
5031 if test -n "${EMACSDATA}"; then
5032    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5033 fi
5034 if test -n "${EMACSDOC}"; then
5035    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5036 fi
5037
5038 echo
5039
5040 if test "$HAVE_NS" = "yes"; then
5041    echo
5042    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5043 The installed application will go to nextstep/Emacs.app and can be
5044 run or moved from there."
5045    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5046       echo "The application will be fully self-contained."
5047     else
5048       echo "The lisp resources for the application will be installed under ${prefix}.
5049 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5050 to run if these resources are not installed."
5051    fi
5052    echo
5053 fi
5054
5055 if test "${opsys}" = "cygwin"; then
5056   case `uname -r` in
5057     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5058            echo
5059            ;;
5060   esac
5061 fi
5062
5063 # Remove any trailing slashes in these variables.
5064 [test "${prefix}" != NONE &&
5065   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5066 test "${exec_prefix}" != NONE &&
5067   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5068
5069 if test "$HAVE_NS" = "yes"; then
5070   if test "$NS_IMPL_GNUSTEP" = yes; then
5071     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5072       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5073     ns_check_file=Resources/Info-gnustep.plist
5074   else
5075     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5076       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5077     ns_check_file=Contents/Info.plist
5078   fi
5079   AC_SUBST(ns_check_file)
5080 fi
5081
5082 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5083 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5084 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5085 dnl (else you get "no `Makefile.am' found for any configure output").
5086 dnl This will work, but you get a config.status that is not quite right
5087 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5088 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5089 dnl it seems better to just live with the duplication.
5090 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5091
5092 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5093        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5094        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5095        leim/Makefile nextstep/Makefile nt/Makefile])
5096
5097 dnl test/ is not present in release tarfiles.
5098 opt_makefile=test/automated/Makefile
5099
5100 if test -f "$srcdir/$opt_makefile.in"; then
5101   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5102   dnl Again, it's best not to use a variable.  Though you can add
5103   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5104   AC_CONFIG_FILES([test/automated/Makefile])
5105 fi
5106
5107
5108 dnl The admin/ directory used to be excluded from tarfiles.
5109 if test -d $srcdir/admin; then
5110   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5111   AC_CONFIG_FILES([admin/unidata/Makefile])
5112   AC_CONFIG_FILES([admin/grammars/Makefile])
5113 fi                              dnl -d admin
5114
5115
5116 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5117
5118 AC_SUBST(SUBDIR_MAKEFILES_IN)
5119
5120 dnl You might wonder (I did) why epaths.h is generated by running make,
5121 dnl rather than just letting configure generate it from epaths.in.
5122 dnl One reason is that the various paths are not fully expanded (see above);
5123 dnl eg gamedir=${prefix}/var/games/emacs.
5124 dnl Secondly, the GNU Coding standards require that one should be able
5125 dnl to run `make prefix=/some/where/else' and override the values set
5126 dnl by configure.  This also explains the `move-if-change' test and
5127 dnl the use of force in the `epaths-force' rule in Makefile.in.
5128 AC_CONFIG_COMMANDS([src/epaths.h], [
5129 if test "${opsys}" = "mingw32"; then
5130   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5131 else
5132   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5133 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5134 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5135
5136 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5137 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5138 dnl or a symlink?
5139 AC_CONFIG_COMMANDS([src/.gdbinit], [
5140 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5141   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5142 fi
5143 ])
5144
5145 AC_OUTPUT
5146
5147 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])