lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defvar frame-creation-function-alist
  29   (list (cons nil
  30               (if (fboundp 'tty-create-frame-with-faces)
  31                   'tty-create-frame-with-faces
  32                 (lambda (parameters)
  33                   (error "Can't create multiple frames without a window system")))))
  34   "Alist of window-system dependent functions to call to create a new frame.
  35 The window system startup file should add its frame creation
  36 function to this list, which should take an alist of parameters
  37 as its argument.")
  38
  39 (defvar window-system-default-frame-alist nil
  40   "Alist of window-system dependent default frame parameters.
  41 You can set this in your `.emacs' file; for example,
  42
  43     ;; Disable menubar and toolbar on the console, but enable them under X.
  44     (setq window-system-default-frame-alist
  45           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  46             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  47
  48 Parameters specified here supersede the values given in `default-frame-alist'.")
  49
  50 ;; The initial value given here used to ask for a minibuffer.
  51 ;; But that's not necessary, because the default is to have one.
  52 ;; By not specifying it here, we let an X resource specify it.
  53 (defcustom initial-frame-alist nil
  54   "*Alist of frame parameters for creating the initial X window frame.
  55 You can set this in your `.emacs' file; for example,
  56  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  57 Parameters specified here supersede the values given in `default-frame-alist'.
  58
  59 If the value calls for a frame without a minibuffer, and you have not created
  60 a minibuffer frame on your own, one is created according to
  61 `minibuffer-frame-alist'.
  62
  63 You can specify geometry-related options for just the initial frame
  64 by setting this variable in your `.emacs' file; however, they won't
  65 take effect until Emacs reads `.emacs', which happens after first creating
  66 the frame.  If you want the frame to have the proper geometry as soon
  67 as it appears, you need to use this three-step process:
  68 * Specify X resources to give the geometry you want.
  69 * Set `default-frame-alist' to override these options so that they
  70   don't affect subsequent frames.
  71 * Set `initial-frame-alist' in a way that matches the X resources,
  72   to override what you put in `default-frame-alist'."
  73   :type '(repeat (cons :format "%v"
  74                        (symbol :tag "Parameter")
  75                        (sexp :tag "Value")))
  76   :group 'frames)
  77
  78 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  79   "*Alist of frame parameters for initially creating a minibuffer frame.
  80 You can set this in your `.emacs' file; for example,
  81  (setq minibuffer-frame-alist
  82    '((top . 1) (left . 1) (width . 80) (height . 2)))
  83 Parameters specified here supersede the values given in
  84 `default-frame-alist', for a minibuffer frame."
  85   :type '(repeat (cons :format "%v"
  86                        (symbol :tag "Parameter")
  87                        (sexp :tag "Value")))
  88   :group 'frames)
  89
  90 (defcustom pop-up-frame-alist nil
  91   "*Alist of frame parameters used when creating pop-up frames.
  92 Pop-up frames are used for completions, help, and the like.
  93 This variable can be set in your init file, like this:
  94   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  95 These supersede the values given in `default-frame-alist',
  96 for pop-up frames."
  97   :type '(repeat (cons :format "%v"
  98                        (symbol :tag "Parameter")
  99                        (sexp :tag "Value")))
 100   :group 'frames)
 101
 102 (setq pop-up-frame-function
 103       ;; Using `function' here caused some sort of problem.
 104       '(lambda ()
 105          (make-frame pop-up-frame-alist)))
 106
 107 (defcustom special-display-frame-alist
 108   '((height . 14) (width . 80) (unsplittable . t))
 109   "*Alist of frame parameters used when creating special frames.
 110 Special frames are used for buffers whose names are in
 111 `special-display-buffer-names' and for buffers whose names match
 112 one of the regular expressions in `special-display-regexps'.
 113 This variable can be set in your init file, like this:
 114   (setq special-display-frame-alist '((width . 80) (height . 20)))
 115 These supersede the values given in `default-frame-alist'."
 116   :type '(repeat (cons :format "%v"
 117                          (symbol :tag "Parameter")
 118                          (sexp :tag "Value")))
 119   :group 'frames)
 120
 121 (defun special-display-popup-frame (buffer &optional args)
 122   "Display BUFFER in its own frame, reusing an existing window if any.
 123 Return the window chosen.
 124 Currently we do not insist on selecting the window within its frame.
 125 If ARGS is an alist, use it as a list of frame parameter specs.
 126 If ARGS is a list whose car is a symbol,
 127 use (car ARGS) as a function to do the work.
 128 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 129   (if (and args (symbolp (car args)))
 130       (apply (car args) buffer (cdr args))
 131     (let ((window (get-buffer-window buffer 0)))
 132       (or
 133        ;; If we have a window already, make it visible.
 134        (when window
 135          (let ((frame (window-frame window)))
 136            (make-frame-visible frame)
 137            (raise-frame frame)
 138            window))
 139        ;; Reuse the current window if the user requested it.
 140        (when (cdr (assq 'same-window args))
 141          (condition-case nil
 142              (progn (switch-to-buffer buffer) (selected-window))
 143            (error nil)))
 144        ;; Stay on the same frame if requested.
 145        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 146          (let* ((pop-up-frames nil) (pop-up-windows t)
 147                 special-display-regexps special-display-buffer-names
 148                 (window (display-buffer buffer)))
 149            ;; Only do it if this is a new window:
 150            ;; (set-window-dedicated-p window t)
 151            window))
 152        ;; If no window yet, make one in a new frame.
 153        (let ((frame
 154               (with-current-buffer buffer
 155                 (make-frame (append args special-display-frame-alist)))))
 156          (set-window-buffer (frame-selected-window frame) buffer)
 157          (set-window-dedicated-p (frame-selected-window frame) t)
 158          (frame-selected-window frame))))))
 159
 160 (defun handle-delete-frame (event)
 161   "Handle delete-frame events from the X server."
 162   (interactive "e")
 163   (let ((frame (posn-window (event-start event)))
 164         (i 0)
 165         (tail (frame-list)))
 166     (while tail
 167       (and (frame-visible-p (car tail))
 168            (not (eq (car tail) frame))
 169           (setq i (1+ i)))
 170       (setq tail (cdr tail)))
 171     (if (> i 0)
 172         (delete-frame frame t)
 173       ;; Gildea@x.org says it is ok to ask questions before terminating.
 174       (save-buffers-kill-emacs))))
 175 \f
 176 ;;;; Arrangement of frames at startup
 177
 178 ;; 1) Load the window system startup file from the lisp library and read the
 179 ;; high-priority arguments (-q and the like).  The window system startup
 180 ;; file should create any frames specified in the window system defaults.
 181 ;;
 182 ;; 2) If no frames have been opened, we open an initial text frame.
 183 ;;
 184 ;; 3) Once the init file is done, we apply any newly set parameters
 185 ;; in initial-frame-alist to the frame.
 186
 187 ;; These are now called explicitly at the proper times,
 188 ;; since that is easier to understand.
 189 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 190 ;; (add-hook 'before-init-hook 'frame-initialize)
 191 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 192
 193 ;; If we create the initial frame, this is it.
 194 (defvar frame-initial-frame nil)
 195
 196 ;; Record the parameters used in frame-initialize to make the initial frame.
 197 (defvar frame-initial-frame-alist)
 198
 199 (defvar frame-initial-geometry-arguments nil)
 200
 201 ;; startup.el calls this function before loading the user's init
 202 ;; file - if there is no frame with a minibuffer open now, create
 203 ;; one to display messages while loading the init file.
 204 (defun frame-initialize ()
 205   "Create an initial frame if necessary."
 206   ;; Are we actually running under a window system at all?
 207   (if (and initial-window-system
 208            (not noninteractive)
 209            (not (eq initial-window-system 'pc)))
 210       (progn
 211         ;; Turn on special-display processing only if there's a window system.
 212         (setq special-display-function 'special-display-popup-frame)
 213
 214         ;; If there is no frame with a minibuffer besides the terminal
 215         ;; frame, then we need to create the opening frame.  Make sure
 216         ;; it has a minibuffer, but let initial-frame-alist omit the
 217         ;; minibuffer spec.
 218         (or (delq terminal-frame (minibuffer-frame-list))
 219             (progn
 220               (setq frame-initial-frame-alist
 221                     (append initial-frame-alist default-frame-alist nil))
 222               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 223                   (setq frame-initial-frame-alist
 224                         (cons '(horizontal-scroll-bars . t)
 225                               frame-initial-frame-alist)))
 226               (setq frame-initial-frame-alist
 227                     (cons (cons 'window-system initial-window-system)
 228                           frame-initial-frame-alist))
 229               (setq default-minibuffer-frame
 230                     (setq frame-initial-frame
 231                           (make-frame frame-initial-frame-alist)))
 232               ;; Delete any specifications for window geometry parameters
 233               ;; so that we won't reapply them in frame-notice-user-settings.
 234               ;; It would be wrong to reapply them then,
 235               ;; because that would override explicit user resizing.
 236               (setq initial-frame-alist
 237                     (frame-remove-geometry-params initial-frame-alist))))
 238         ;; Copy the environment of the Emacs process into the new frame.
 239         (set-frame-parameter frame-initial-frame 'environment
 240                              (frame-parameter terminal-frame 'environment))
 241         ;; At this point, we know that we have a frame open, so we
 242         ;; can delete the terminal frame.
 243         (delete-frame terminal-frame)
 244         (setq terminal-frame nil))))
 245
 246 (defvar frame-notice-user-settings t
 247   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 248
 249 (declare-function tool-bar-mode "tool-bar" (&optional arg))
 250
 251 ;; startup.el calls this function after loading the user's init
 252 ;; file.  Now default-frame-alist and initial-frame-alist contain
 253 ;; information to which we must react; do what needs to be done.
 254 (defun frame-notice-user-settings ()
 255   "Act on user's init file settings of frame parameters.
 256 React to settings of `initial-frame-alist',
 257 `window-system-default-frame-alist' and `default-frame-alist'
 258 there (in decreasing order of priority)."
 259   ;; Make menu-bar-mode and default-frame-alist consistent.
 260   (when (boundp 'menu-bar-mode)
 261     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 262       (if default
 263           (setq menu-bar-mode (not (eq (cdr default) 0)))
 264         (setq default-frame-alist
 265               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 266                     default-frame-alist)))))
 267
 268   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 269   ;; it in batch mode since that would leave a tool-bar-lines
 270   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 271   ;; what we want.
 272   (when (and (boundp 'tool-bar-mode)
 273              (not noninteractive))
 274     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 275       (if default
 276           (setq tool-bar-mode (not (eq (cdr default) 0)))
 277         ;; If Emacs was started on a tty, changing default-frame-alist
 278         ;; would disable the toolbar on X frames created later.  We
 279         ;; want to keep the default of showing a toolbar under X even
 280         ;; in this case.
 281         ;;
 282         ;; If the user explicitly called `tool-bar-mode' in .emacs,
 283         ;; then default-frame-alist is already changed anyway.
 284         (when initial-window-system
 285           (setq default-frame-alist
 286                 (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 287                       default-frame-alist))))))
 288
 289   ;; Creating and deleting frames may shift the selected frame around,
 290   ;; and thus the current buffer.  Protect against that.  We don't
 291   ;; want to use save-excursion here, because that may also try to set
 292   ;; the buffer of the selected window, which fails when the selected
 293   ;; window is the minibuffer.
 294   (let ((old-buffer (current-buffer))
 295         (window-system-frame-alist
 296          (cdr (assq initial-window-system
 297                     window-system-default-frame-alist))))
 298
 299     (when (and frame-notice-user-settings
 300                (null frame-initial-frame))
 301       ;; This case happens when we don't have a window system, and
 302       ;; also for MS-DOS frames.
 303       (let ((parms (frame-parameters frame-initial-frame)))
 304         ;; Don't change the frame names.
 305         (setq parms (delq (assq 'name parms) parms))
 306         ;; Can't modify the minibuffer parameter, so don't try.
 307         (setq parms (delq (assq 'minibuffer parms) parms))
 308         (modify-frame-parameters nil
 309                                  (if (null initial-window-system)
 310                                      (append initial-frame-alist
 311                                              window-system-frame-alist
 312                                              default-frame-alist
 313                                              parms
 314                                              nil)
 315                                    ;; initial-frame-alist and
 316                                    ;; default-frame-alist were already
 317                                    ;; applied in pc-win.el.
 318                                    parms))
 319         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 320             (let ((newparms (frame-parameters))
 321                   (frame (selected-frame)))
 322               (tty-handle-reverse-video frame newparms)
 323               ;; If we changed the background color, we need to update
 324               ;; the background-mode parameter, and maybe some faces,
 325               ;; too.
 326               (when (assq 'background-color newparms)
 327                 (unless (or (assq 'background-mode initial-frame-alist)
 328                             (assq 'background-mode default-frame-alist))
 329                   (frame-set-background-mode frame))
 330                 (face-set-after-frame-default frame))))))
 331
 332     ;; If the initial frame is still around, apply initial-frame-alist
 333     ;; and default-frame-alist to it.
 334     (when (frame-live-p frame-initial-frame)
 335
 336       ;; When tool-bar has been switched off, correct the frame size
 337       ;; by the lines added in x-create-frame for the tool-bar and
 338       ;; switch `tool-bar-mode' off.
 339       (when (display-graphic-p)
 340         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 341                                   (assq 'tool-bar-lines window-system-frame-alist)
 342                                   (assq 'tool-bar-lines default-frame-alist))))
 343           (when (and tool-bar-originally-present
 344                      (or (null tool-bar-lines)
 345                          (null (cdr tool-bar-lines))
 346                          (eq 0 (cdr tool-bar-lines))))
 347             (let* ((char-height (frame-char-height frame-initial-frame))
 348                    (image-height tool-bar-images-pixel-height)
 349                    (margin (cond ((and (consp tool-bar-button-margin)
 350                                        (integerp (cdr tool-bar-button-margin))
 351                                        (> tool-bar-button-margin 0))
 352                                   (cdr tool-bar-button-margin))
 353                                  ((and (integerp tool-bar-button-margin)
 354                                        (> tool-bar-button-margin 0))
 355                                   tool-bar-button-margin)
 356                                  (t 0)))
 357                    (relief (if (and (integerp tool-bar-button-relief)
 358                                     (> tool-bar-button-relief 0))
 359                                tool-bar-button-relief 3))
 360                    (lines (/ (+ image-height
 361                                 (* 2 margin)
 362                                 (* 2 relief)
 363                                 (1- char-height))
 364                              char-height))
 365                    (height (frame-parameter frame-initial-frame 'height))
 366                    (newparms (list (cons 'height (- height lines))))
 367                    (initial-top (cdr (assq 'top
 368                                            frame-initial-geometry-arguments)))
 369                    (top (frame-parameter frame-initial-frame 'top)))
 370               (when (and (consp initial-top) (eq '- (car initial-top)))
 371                 (let ((adjusted-top
 372                        (cond ((and (consp top)
 373                                    (eq '+ (car top)))
 374                               (list '+
 375                                     (+ (cadr top)
 376                                        (* lines char-height))))
 377                              ((and (consp top)
 378                                    (eq '- (car top)))
 379                               (list '-
 380                                     (- (cadr top)
 381                                        (* lines char-height))))
 382                              (t (+ top (* lines char-height))))))
 383                   (setq newparms
 384                         (append newparms
 385                                 `((top . ,adjusted-top))
 386                                 nil))))
 387               (modify-frame-parameters frame-initial-frame newparms)
 388               (tool-bar-mode -1)))))
 389
 390       ;; The initial frame we create above always has a minibuffer.
 391       ;; If the user wants to remove it, or make it a minibuffer-only
 392       ;; frame, then we'll have to delete the current frame and make a
 393       ;; new one; you can't remove or add a root window to/from an
 394       ;; existing frame.
 395       ;;
 396       ;; NOTE: default-frame-alist was nil when we created the
 397       ;; existing frame.  We need to explicitly include
 398       ;; default-frame-alist in the parameters of the screen we
 399       ;; create here, so that its new value, gleaned from the user's
 400       ;; .emacs file, will be applied to the existing screen.
 401       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 402                             (assq 'minibuffer window-system-frame-alist)
 403                             (assq 'minibuffer default-frame-alist)
 404                             '(minibuffer . t)))
 405                    t))
 406           ;; Create the new frame.
 407           (let (parms new)
 408             ;; If the frame isn't visible yet, wait till it is.
 409             ;; If the user has to position the window,
 410             ;; Emacs doesn't know its real position until
 411             ;; the frame is seen to be visible.
 412             (while (not (cdr (assq 'visibility
 413                                    (frame-parameters frame-initial-frame))))
 414               (sleep-for 1))
 415             (setq parms (frame-parameters frame-initial-frame))
 416
 417             ;; Get rid of `name' unless it was specified explicitly before.
 418             (or (assq 'name frame-initial-frame-alist)
 419                 (setq parms (delq (assq 'name parms) parms)))
 420             ;; An explicit parent-id is a request to XEmbed the frame.
 421             (or (assq 'parent-id frame-initial-frame-alist)
 422                 (setq parms (delq (assq 'parent-id parms) parms)))
 423
 424             (setq parms (append initial-frame-alist
 425                                 window-system-frame-alist
 426                                 default-frame-alist
 427                                 parms
 428                                 nil))
 429
 430             ;; Get rid of `reverse', because that was handled
 431             ;; when we first made the frame.
 432             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 433
 434             (if (assq 'height frame-initial-geometry-arguments)
 435                 (setq parms (assq-delete-all 'height parms)))
 436             (if (assq 'width frame-initial-geometry-arguments)
 437                 (setq parms (assq-delete-all 'width parms)))
 438             (if (assq 'left frame-initial-geometry-arguments)
 439                 (setq parms (assq-delete-all 'left parms)))
 440             (if (assq 'top frame-initial-geometry-arguments)
 441                 (setq parms (assq-delete-all 'top parms)))
 442             (setq new
 443                   (make-frame
 444                    ;; Use the geometry args that created the existing
 445                    ;; frame, rather than the parms we get for it.
 446                    (append frame-initial-geometry-arguments
 447                            '((user-size . t) (user-position . t))
 448                            parms)))
 449             ;; The initial frame, which we are about to delete, may be
 450             ;; the only frame with a minibuffer.  If it is, create a
 451             ;; new one.
 452             (or (delq frame-initial-frame (minibuffer-frame-list))
 453                 (make-initial-minibuffer-frame nil))
 454
 455             ;; If the initial frame is serving as a surrogate
 456             ;; minibuffer frame for any frames, we need to wean them
 457             ;; onto a new frame.  The default-minibuffer-frame
 458             ;; variable must be handled similarly.
 459             (let ((users-of-initial
 460                    (filtered-frame-list
 461                     (lambda (frame)
 462                       (and (not (eq frame frame-initial-frame))
 463                            (eq (window-frame
 464                                 (minibuffer-window frame))
 465                                frame-initial-frame))))))
 466               (if (or users-of-initial
 467                       (eq default-minibuffer-frame frame-initial-frame))
 468
 469                   ;; Choose an appropriate frame.  Prefer frames which
 470                   ;; are only minibuffers.
 471                   (let* ((new-surrogate
 472                           (car
 473                            (or (filtered-frame-list
 474                                 (lambda (frame)
 475                                   (eq (cdr (assq 'minibuffer
 476                                                  (frame-parameters frame)))
 477                                       'only)))
 478                                (minibuffer-frame-list))))
 479                          (new-minibuffer (minibuffer-window new-surrogate)))
 480
 481                     (if (eq default-minibuffer-frame frame-initial-frame)
 482                         (setq default-minibuffer-frame new-surrogate))
 483
 484                     ;; Wean the frames using frame-initial-frame as
 485                     ;; their minibuffer frame.
 486                     (dolist (frame users-of-initial)
 487                       (modify-frame-parameters
 488                        frame (list (cons 'minibuffer new-minibuffer)))))))
 489
 490             ;; Redirect events enqueued at this frame to the new frame.
 491             ;; Is this a good idea?
 492             (redirect-frame-focus frame-initial-frame new)
 493
 494             ;; Finally, get rid of the old frame.
 495             (delete-frame frame-initial-frame t))
 496
 497         ;; Otherwise, we don't need all that rigamarole; just apply
 498         ;; the new parameters.
 499         (let (newparms allparms tail)
 500           (setq allparms (append initial-frame-alist
 501                                  window-system-frame-alist
 502                                  default-frame-alist nil))
 503           (if (assq 'height frame-initial-geometry-arguments)
 504               (setq allparms (assq-delete-all 'height allparms)))
 505           (if (assq 'width frame-initial-geometry-arguments)
 506               (setq allparms (assq-delete-all 'width allparms)))
 507           (if (assq 'left frame-initial-geometry-arguments)
 508               (setq allparms (assq-delete-all 'left allparms)))
 509           (if (assq 'top frame-initial-geometry-arguments)
 510               (setq allparms (assq-delete-all 'top allparms)))
 511           (setq tail allparms)
 512           ;; Find just the parms that have changed since we first
 513           ;; made this frame.  Those are the ones actually set by
 514           ;; the init file.  For those parms whose values we already knew
 515           ;; (such as those spec'd by command line options)
 516           ;; it is undesirable to specify the parm again
 517           ;; once the user has seen the frame and been able to alter it
 518           ;; manually.
 519           (while tail
 520             (let (newval oldval)
 521               (setq oldval (assq (car (car tail))
 522                                  frame-initial-frame-alist))
 523               (setq newval (cdr (assq (car (car tail)) allparms)))
 524               (or (and oldval (eq (cdr oldval) newval))
 525                   (setq newparms
 526                         (cons (cons (car (car tail)) newval) newparms))))
 527             (setq tail (cdr tail)))
 528           (setq newparms (nreverse newparms))
 529           (modify-frame-parameters frame-initial-frame
 530                                    newparms)
 531           ;; If we changed the background color,
 532           ;; we need to update the background-mode parameter
 533           ;; and maybe some faces too.
 534           (when (assq 'background-color newparms)
 535             (unless (assq 'background-mode newparms)
 536               (frame-set-background-mode frame-initial-frame))
 537             (face-set-after-frame-default frame-initial-frame)))))
 538
 539     ;; Restore the original buffer.
 540     (set-buffer old-buffer)
 541
 542     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 543     ;; Make sure frame-notice-user-settings does nothing if called twice.
 544     (setq frame-notice-user-settings nil)
 545     (setq frame-initial-frame nil)))
 546
 547 (defun make-initial-minibuffer-frame (display)
 548   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 549     (if display
 550         (make-frame-on-display display parms)
 551       (make-frame parms))))
 552
 553 ;;;; Creation of additional frames, and other frame miscellanea
 554
 555 (defun modify-all-frames-parameters (alist)
 556   "Modify all current and future frames' parameters according to ALIST.
 557 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 558 Furthermore, this function removes all parameters in ALIST from
 559 `window-system-default-frame-alist'.
 560 See help of `modify-frame-parameters' for more information."
 561   (dolist (frame (frame-list))
 562     (modify-frame-parameters frame alist))
 563
 564   (dolist (pair alist) ;; conses to add/replace
 565     ;; initial-frame-alist needs setting only when
 566     ;; frame-notice-user-settings is true.
 567     (and frame-notice-user-settings
 568          (setq initial-frame-alist
 569                (assq-delete-all (car pair) initial-frame-alist)))
 570     (setq default-frame-alist
 571           (assq-delete-all (car pair) default-frame-alist))
 572     ;; Remove any similar settings from the window-system specific
 573     ;; parameters---they would override default-frame-alist.
 574     (dolist (w window-system-default-frame-alist)
 575       (setcdr w (assq-delete-all (car pair) (cdr w)))))
 576
 577   (and frame-notice-user-settings
 578        (setq initial-frame-alist (append initial-frame-alist alist)))
 579   (setq default-frame-alist (append default-frame-alist alist)))
 580
 581 (defun get-other-frame ()
 582   "Return some frame other than the current frame.
 583 Create one if necessary.  Note that the minibuffer frame, if separate,
 584 is not considered (see `next-frame')."
 585   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 586                (make-frame)
 587              (next-frame (selected-frame)))))
 588     s))
 589
 590 (defun next-multiframe-window ()
 591   "Select the next window, regardless of which frame it is on."
 592   (interactive)
 593   (select-window (next-window (selected-window)
 594                               (> (minibuffer-depth) 0)
 595                               0))
 596   (select-frame-set-input-focus (selected-frame)))
 597
 598 (defun previous-multiframe-window ()
 599   "Select the previous window, regardless of which frame it is on."
 600   (interactive)
 601   (select-window (previous-window (selected-window)
 602                                   (> (minibuffer-depth) 0)
 603                                   0))
 604   (select-frame-set-input-focus (selected-frame)))
 605
 606 (declare-function x-initialize-window-system "term/x-win" ())
 607 (defvar x-display-name)
 608
 609 (defun make-frame-on-display (display &optional parameters)
 610   "Make a frame on X display DISPLAY.
 611 The optional second argument PARAMETERS specifies additional frame parameters."
 612   (interactive "sMake frame on display: ")
 613   (if (featurep 'ns-windowing)
 614       (progn
 615         (when (and (boundp 'ns-initialized) (not ns-initialized))
 616           (setq ns-display-name display)
 617           (ns-initialize-window-system))
 618         (make-frame `((window-system . ns) (display . ,display) . ,parameters)))
 619     (progn
 620       (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 621           (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 622       (when (and (boundp 'x-initialized) (not x-initialized))
 623         (setq x-display-name display)
 624         (x-initialize-window-system))
 625       (make-frame `((window-system . x) (display . ,display) . ,parameters)))))
 626
 627 (defun make-frame-on-tty (tty type &optional parameters)
 628   "Make a frame on terminal device TTY.
 629 TTY should be the file name of the tty device to use.  TYPE
 630 should be the terminal type string of TTY, for example \"xterm\"
 631 or \"vt100\".  The optional third argument PARAMETERS specifies
 632 additional frame parameters."
 633   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 634   (unless tty
 635     (error "Invalid terminal device"))
 636   (unless type
 637     (error "Invalid terminal type"))
 638   (make-frame `((window-system . nil) (tty . ,tty) (tty-type . ,type) . ,parameters)))
 639
 640 (declare-function x-close-connection "xfns.c" (terminal))
 641
 642 (defun close-display-connection (display)
 643   "Close the connection to a display, deleting all its associated frames.
 644 For DISPLAY, specify either a frame or a display name (a string).
 645 If DISPLAY is nil, that stands for the selected frame's display."
 646   (interactive
 647    (list
 648     (let* ((default (frame-parameter nil 'display))
 649            (display (completing-read
 650                      (format "Close display (default %s): " default)
 651                      (delete-dups
 652                       (mapcar (lambda (frame)
 653                                 (frame-parameter frame 'display))
 654                               (frame-list)))
 655                      nil t nil nil
 656                      default)))
 657       (if (zerop (length display)) default display))))
 658   (let ((frames (delq nil
 659                       (mapcar (lambda (frame)
 660                                 (if (equal display
 661                                            (frame-parameter frame 'display))
 662                                     frame))
 663                               (frame-list)))))
 664     (if (and (consp frames)
 665              (not (y-or-n-p (if (cdr frames)
 666                                 (format "Delete %s frames? " (length frames))
 667                               (format "Delete %s ? " (car frames))))))
 668         (error "Abort!")
 669       (mapc 'delete-frame frames)
 670       (x-close-connection display))))
 671
 672 (defun make-frame-command ()
 673   "Make a new frame, and select it if the terminal displays only one frame."
 674   (interactive)
 675   (if (and window-system (not (eq window-system 'pc)))
 676       (make-frame)
 677     (select-frame (make-frame))))
 678
 679 (defvar before-make-frame-hook nil
 680   "Functions to run before a frame is created.")
 681
 682 (defvar after-make-frame-functions nil
 683   "Functions to run after a frame is created.
 684 The functions are run with one arg, the newly created frame.")
 685
 686 (defvar after-setting-font-hook nil
 687   "Functions to run after a frame's font has been changed.")
 688
 689 ;; Alias, kept temporarily.
 690 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 691
 692 (defvar frame-inherited-parameters '()
 693   ;; FIXME: Shouldn't we add `font' here as well?
 694   "Parameters `make-frame' copies from the `selected-frame' to the new frame.")
 695
 696 (defun make-frame (&optional parameters)
 697   "Return a newly created frame displaying the current buffer.
 698 Optional argument PARAMETERS is an alist of parameters for the new frame.
 699 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 700
 701  (name . STRING)        The frame should be named STRING.
 702
 703  (width . NUMBER)       The frame should be NUMBER characters in width.
 704  (height . NUMBER)      The frame should be NUMBER text lines high.
 705
 706 You cannot specify either `width' or `height', you must use neither or both.
 707
 708  (minibuffer . t)       The frame should have a minibuffer.
 709  (minibuffer . nil)     The frame should have no minibuffer.
 710  (minibuffer . only)    The frame should contain only a minibuffer.
 711  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 712
 713  (window-system . nil)  The frame should be displayed on a terminal device.
 714  (window-system . x)    The frame should be displayed in an X window.
 715
 716  (terminal . ID)          The frame should use the terminal identified by ID.
 717
 718 Before the frame is created (via `frame-creation-function-alist'), functions on the
 719 hook `before-make-frame-hook' are run.  After the frame is created, functions
 720 on `after-make-frame-functions' are run with one arg, the newly created frame.
 721
 722 This function itself does not make the new frame the selected frame.
 723 The previously selected frame remains selected.  However, the
 724 window system may select the new frame for its own reasons, for
 725 instance if the frame appears under the mouse pointer and your
 726 setup is for focus to follow the pointer."
 727   (interactive)
 728   (let* ((w (cond
 729              ((assq 'terminal parameters)
 730               (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
 731                 (cond
 732                  ((eq type t) nil)
 733                  ((eq type nil) (error "Terminal %s does not exist"
 734                                        (cdr (assq 'terminal parameters))))
 735                  (t type))))
 736              ((assq 'window-system parameters)
 737               (cdr (assq 'window-system parameters)))
 738              (t window-system)))
 739          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 740          (oldframe (selected-frame))
 741          frame)
 742     (unless frame-creation-function
 743       (error "Don't know how to create a frame on window system %s" w))
 744     (run-hooks 'before-make-frame-hook)
 745     (setq frame
 746           (funcall frame-creation-function
 747                    (append parameters
 748                            (cdr (assq w window-system-default-frame-alist)))))
 749     (normal-erase-is-backspace-setup-frame frame)
 750     ;; Inherit the original frame's parameters.
 751     (dolist (param frame-inherited-parameters)
 752       (unless (assq param parameters)   ;Overridden by explicit parameters.
 753         (let ((val (frame-parameter oldframe param)))
 754           (when val (set-frame-parameter frame param val)))))
 755     (run-hook-with-args 'after-make-frame-functions frame)
 756     frame))
 757
 758 (defun filtered-frame-list (predicate)
 759   "Return a list of all live frames which satisfy PREDICATE."
 760   (let* ((frames (frame-list))
 761          (list frames))
 762     (while (consp frames)
 763       (unless (funcall predicate (car frames))
 764         (setcar frames nil))
 765       (setq frames (cdr frames)))
 766     (delq nil list)))
 767
 768 (defun minibuffer-frame-list ()
 769   "Return a list of all frames with their own minibuffers."
 770   (filtered-frame-list
 771    (lambda (frame)
 772      (eq frame (window-frame (minibuffer-window frame))))))
 773
 774 ;; Used to be called `terminal-id' in termdev.el.
 775 (defun get-device-terminal (device)
 776   "Return the terminal corresponding to DEVICE.
 777 DEVICE can be a terminal, a frame, nil (meaning the selected frame's terminal),
 778 the name of an X display device (HOST.SERVER.SCREEN) or a tty device file."
 779   (cond
 780    ((or (null device) (framep device))
 781     (frame-terminal device))
 782    ((stringp device)
 783     (let ((f (car (filtered-frame-list
 784                    (lambda (frame)
 785                      (or (equal (frame-parameter frame 'display) device)
 786                          (equal (frame-parameter frame 'tty) device)))))))
 787       (or f (error "Display %s does not exist" device))
 788       (frame-terminal f)))
 789    ((terminal-live-p device) device)
 790    (t
 791     (error "Invalid argument %s in `get-device-terminal'" device))))
 792
 793 (defun frames-on-display-list (&optional device)
 794   "Return a list of all frames on DEVICE.
 795
 796 DEVICE should be a terminal, a frame,
 797 or a name of an X display or tty (a string of the form
 798 HOST:SERVER.SCREEN).
 799
 800 If DEVICE is omitted or nil, it defaults to the selected
 801 frame's terminal device."
 802   (let* ((terminal (get-device-terminal device))
 803          (func #'(lambda (frame)
 804                    (eq (frame-terminal frame) terminal))))
 805     (filtered-frame-list func)))
 806
 807 (defun framep-on-display (&optional terminal)
 808   "Return the type of frames on TERMINAL.
 809 TERMINAL may be a terminal id, a display name or a frame.  If it
 810 is a frame, its type is returned.  If TERMINAL is omitted or nil,
 811 it defaults to the selected frame's terminal device.  All frames
 812 on a given display are of the same type."
 813   (or (terminal-live-p terminal)
 814       (framep terminal)
 815       (framep (car (frames-on-display-list terminal)))))
 816
 817 (defun frame-remove-geometry-params (param-list)
 818   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 819 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 820 `height', `user-size' and `user-position' parameters.
 821 Emacs uses this to avoid overriding explicit moves and resizings from
 822 the user during startup."
 823   (setq param-list (cons nil param-list))
 824   (let ((tail param-list))
 825     (while (consp (cdr tail))
 826       (if (and (consp (car (cdr tail)))
 827                (memq (car (car (cdr tail)))
 828                      '(height width top left user-position user-size)))
 829           (progn
 830             (setq frame-initial-geometry-arguments
 831                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 832             (setcdr tail (cdr (cdr tail))))
 833         (setq tail (cdr tail)))))
 834   (setq frame-initial-geometry-arguments
 835         (nreverse frame-initial-geometry-arguments))
 836   (cdr param-list))
 837
 838 (declare-function x-focus-frame "xfns.c" (frame))
 839
 840 (defun select-frame-set-input-focus (frame)
 841   "Select FRAME, raise it, and set input focus, if possible."
 842     (select-frame frame)
 843     (raise-frame frame)
 844     ;; Ensure, if possible, that frame gets input focus.
 845     (when (memq (window-system frame) '(x mac w32 ns))
 846       (x-focus-frame frame))
 847     (when focus-follows-mouse
 848       (set-mouse-position (selected-frame) (1- (frame-width)) 0)))
 849
 850 (defun other-frame (arg)
 851   "Select the ARGth different visible frame on current display, and raise it.
 852 All frames are arranged in a cyclic order.
 853 This command selects the frame ARG steps away in that order.
 854 A negative ARG moves in the opposite order.
 855
 856 To make this command work properly, you must tell Emacs
 857 how the system (or the window manager) generally handles
 858 focus-switching between windows.  If moving the mouse onto a window
 859 selects it (gives it focus), set `focus-follows-mouse' to t.
 860 Otherwise, that variable should be nil."
 861   (interactive "p")
 862   (let ((frame (selected-frame)))
 863     (while (> arg 0)
 864       (setq frame (next-frame frame))
 865       (while (not (eq (frame-visible-p frame) t))
 866         (setq frame (next-frame frame)))
 867       (setq arg (1- arg)))
 868     (while (< arg 0)
 869       (setq frame (previous-frame frame))
 870       (while (not (eq (frame-visible-p frame) t))
 871         (setq frame (previous-frame frame)))
 872       (setq arg (1+ arg)))
 873     (select-frame-set-input-focus frame)))
 874
 875 (defun iconify-or-deiconify-frame ()
 876   "Iconify the selected frame, or deiconify if it's currently an icon."
 877   (interactive)
 878   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 879       (iconify-frame)
 880     (make-frame-visible)))
 881
 882 (defun suspend-frame ()
 883   "Do whatever is right to suspend the current frame.
 884 Calls `suspend-emacs' if invoked from the controlling tty device,
 885 `suspend-tty' from a secondary tty device, and
 886 `iconify-or-deiconify-frame' from an X frame."
 887   (interactive)
 888   (let ((type (framep (selected-frame))))
 889     (cond
 890      ((memq type '(x ns w32)) (iconify-or-deiconify-frame))
 891      ((eq type t)
 892       (if (controlling-tty-p)
 893           (suspend-emacs)
 894         (suspend-tty)))
 895      (t (suspend-emacs)))))
 896
 897 (defun make-frame-names-alist ()
 898   (let* ((current-frame (selected-frame))
 899          (falist
 900           (cons
 901            (cons (frame-parameter current-frame 'name) current-frame) nil))
 902          (frame (next-frame nil t)))
 903     (while (not (eq frame current-frame))
 904       (progn
 905         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 906         (setq frame (next-frame frame t))))
 907     falist))
 908
 909 (defvar frame-name-history nil)
 910 (defun select-frame-by-name (name)
 911   "Select the frame on the current terminal whose name is NAME and raise it.
 912 If there is no frame by that name, signal an error."
 913   (interactive
 914    (let* ((frame-names-alist (make-frame-names-alist))
 915            (default (car (car frame-names-alist)))
 916            (input (completing-read
 917                    (format "Select Frame (default %s): " default)
 918                    frame-names-alist nil t nil 'frame-name-history)))
 919      (if (= (length input) 0)
 920          (list default)
 921        (list input))))
 922   (let* ((frame-names-alist (make-frame-names-alist))
 923          (frame (cdr (assoc name frame-names-alist))))
 924     (or frame
 925         (error "There is no frame named `%s'" name))
 926     (make-frame-visible frame)
 927     (raise-frame frame)
 928     (select-frame frame)
 929     ;; Ensure, if possible, that frame gets input focus.
 930     (cond ((memq (window-system frame) '(x w32 ns))
 931            (x-focus-frame frame)))
 932     (when focus-follows-mouse
 933       (set-mouse-position frame (1- (frame-width frame)) 0))))
 934 \f
 935 ;;;; Frame configurations
 936
 937 (defun current-frame-configuration ()
 938   "Return a list describing the positions and states of all frames.
 939 Its car is `frame-configuration'.
 940 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 941 where
 942   FRAME is a frame object,
 943   ALIST is an association list specifying some of FRAME's parameters, and
 944   WINDOW-CONFIG is a window configuration object for FRAME."
 945   (cons 'frame-configuration
 946         (mapcar (lambda (frame)
 947                   (list frame
 948                         (frame-parameters frame)
 949                         (current-window-configuration frame)))
 950                 (frame-list))))
 951
 952 (defun set-frame-configuration (configuration &optional nodelete)
 953   "Restore the frames to the state described by CONFIGURATION.
 954 Each frame listed in CONFIGURATION has its position, size, window
 955 configuration, and other parameters set as specified in CONFIGURATION.
 956 However, this function does not restore deleted frames.
 957
 958 Ordinarily, this function deletes all existing frames not
 959 listed in CONFIGURATION.  But if optional second argument NODELETE
 960 is given and non-nil, the unwanted frames are iconified instead."
 961   (or (frame-configuration-p configuration)
 962       (signal 'wrong-type-argument
 963               (list 'frame-configuration-p configuration)))
 964   (let ((config-alist (cdr configuration))
 965         frames-to-delete)
 966     (dolist (frame (frame-list))
 967       (let ((parameters (assq frame config-alist)))
 968         (if parameters
 969             (progn
 970               (modify-frame-parameters
 971                frame
 972                ;; Since we can't set a frame's minibuffer status,
 973                ;; we might as well omit the parameter altogether.
 974                (let* ((parms (nth 1 parameters))
 975                       (mini (assq 'minibuffer parms))
 976                       (name (assq 'name parms))
 977                       (explicit-name (cdr (assq 'explicit-name parms))))
 978                  (when mini (setq parms (delq mini parms)))
 979                  ;; Leave name in iff it was set explicitly.
 980                  ;; This should fix the behavior reported in
 981                  ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg01632.html
 982                  (when (and name (not explicit-name))
 983                    (setq parms (delq name parms)))
 984                  parms))
 985               (set-window-configuration (nth 2 parameters)))
 986           (setq frames-to-delete (cons frame frames-to-delete)))))
 987     (mapc (if nodelete
 988               ;; Note: making frames invisible here was tried
 989               ;; but led to some strange behavior--each time the frame
 990               ;; was made visible again, the window manager asked afresh
 991               ;; for where to put it.
 992               'iconify-frame
 993             'delete-frame)
 994           frames-to-delete)))
 995 \f
 996 ;;;; Convenience functions for accessing and interactively changing
 997 ;;;; frame parameters.
 998
 999 (defun frame-height (&optional frame)
1000   "Return number of lines available for display on FRAME.
1001 If FRAME is omitted, describe the currently selected frame."
1002   (cdr (assq 'height (frame-parameters frame))))
1003
1004 (defun frame-width (&optional frame)
1005   "Return number of columns available for display on FRAME.
1006 If FRAME is omitted, describe the currently selected frame."
1007   (cdr (assq 'width (frame-parameters frame))))
1008
1009 (declare-function x-list-fonts "xfaces.c"
1010                   (pattern &optional face frame maximum width))
1011
1012 (defalias 'set-default-font 'set-frame-font)
1013 (defun set-frame-font (font-name &optional keep-size)
1014   "Set the font of the selected frame to FONT-NAME.
1015 When called interactively, prompt for the name of the font to use.
1016 To get the frame's current default font, use `frame-parameters'.
1017
1018 The default behavior is to keep the numbers of lines and columns in
1019 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
1020 non-nil (interactively, prefix argument) the current frame size (in
1021 pixels) is kept by adjusting the numbers of the lines and columns."
1022   (interactive
1023    (let* ((completion-ignore-case t)
1024           (font (completing-read "Font name: "
1025                                  ;; x-list-fonts will fail with an error
1026                                  ;; if this frame doesn't support fonts.
1027                                  (x-list-fonts "*" nil (selected-frame))
1028                                  nil nil nil nil
1029                                  (frame-parameter nil 'font))))
1030      (list font current-prefix-arg)))
1031   (let (fht fwd)
1032     (if keep-size
1033         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
1034               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
1035     (modify-frame-parameters (selected-frame)
1036                              (list (cons 'font font-name)))
1037     (if keep-size
1038         (modify-frame-parameters
1039          (selected-frame)
1040          (list (cons 'height (round fht (frame-char-height)))
1041                (cons 'width (round fwd (frame-char-width)))))))
1042   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
1043
1044 (defun set-frame-parameter (frame parameter value)
1045   "Set frame parameter PARAMETER to VALUE on FRAME.
1046 If FRAME is nil, it defaults to the selected frame.
1047 See `modify-frame-parameters'."
1048   (modify-frame-parameters frame (list (cons parameter value))))
1049
1050 (defun set-background-color (color-name)
1051   "Set the background color of the selected frame to COLOR-NAME.
1052 When called interactively, prompt for the name of the color to use.
1053 To get the frame's current background color, use `frame-parameters'."
1054   (interactive (list (facemenu-read-color "Background color: ")))
1055   (modify-frame-parameters (selected-frame)
1056                            (list (cons 'background-color color-name)))
1057   (or window-system
1058       (face-set-after-frame-default (selected-frame))))
1059
1060 (defun set-foreground-color (color-name)
1061   "Set the foreground color of the selected frame to COLOR-NAME.
1062 When called interactively, prompt for the name of the color to use.
1063 To get the frame's current foreground color, use `frame-parameters'."
1064   (interactive (list (facemenu-read-color "Foreground color: ")))
1065   (modify-frame-parameters (selected-frame)
1066                            (list (cons 'foreground-color color-name)))
1067   (or window-system
1068       (face-set-after-frame-default (selected-frame))))
1069
1070 (defun set-cursor-color (color-name)
1071   "Set the text cursor color of the selected frame to COLOR-NAME.
1072 When called interactively, prompt for the name of the color to use.
1073 To get the frame's current cursor color, use `frame-parameters'."
1074   (interactive (list (facemenu-read-color "Cursor color: ")))
1075   (modify-frame-parameters (selected-frame)
1076                            (list (cons 'cursor-color color-name))))
1077
1078 (defun set-mouse-color (color-name)
1079   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
1080 When called interactively, prompt for the name of the color to use.
1081 To get the frame's current mouse color, use `frame-parameters'."
1082   (interactive (list (facemenu-read-color "Mouse color: ")))
1083   (modify-frame-parameters (selected-frame)
1084                            (list (cons 'mouse-color
1085                                        (or color-name
1086                                            (cdr (assq 'mouse-color
1087                                                       (frame-parameters))))))))
1088
1089 (defun set-border-color (color-name)
1090   "Set the color of the border of the selected frame to COLOR-NAME.
1091 When called interactively, prompt for the name of the color to use.
1092 To get the frame's current border color, use `frame-parameters'."
1093   (interactive (list (facemenu-read-color "Border color: ")))
1094   (modify-frame-parameters (selected-frame)
1095                            (list (cons 'border-color color-name))))
1096
1097 (defun auto-raise-mode (arg)
1098   "Toggle whether or not the selected frame should auto-raise.
1099 With arg, turn auto-raise mode on if and only if arg is positive.
1100 Note that this controls Emacs's own auto-raise feature.
1101 Some window managers allow you to enable auto-raise for certain windows.
1102 You can use that for Emacs windows if you wish, but if you do,
1103 that is beyond the control of Emacs and this command has no effect on it."
1104   (interactive "P")
1105   (if (null arg)
1106       (setq arg
1107             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1108                 -1 1)))
1109   (if (> arg 0)
1110       (raise-frame (selected-frame)))
1111   (modify-frame-parameters (selected-frame)
1112                            (list (cons 'auto-raise (> arg 0)))))
1113
1114 (defun auto-lower-mode (arg)
1115   "Toggle whether or not the selected frame should auto-lower.
1116 With arg, turn auto-lower mode on if and only if arg is positive.
1117 Note that this controls Emacs's own auto-lower feature.
1118 Some window managers allow you to enable auto-lower for certain windows.
1119 You can use that for Emacs windows if you wish, but if you do,
1120 that is beyond the control of Emacs and this command has no effect on it."
1121   (interactive "P")
1122   (if (null arg)
1123       (setq arg
1124             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1125                 -1 1)))
1126   (modify-frame-parameters (selected-frame)
1127                            (list (cons 'auto-lower (> arg 0)))))
1128 (defun set-frame-name (name)
1129   "Set the name of the selected frame to NAME.
1130 When called interactively, prompt for the name of the frame.
1131 The frame name is displayed on the modeline if the terminal displays only
1132 one frame, otherwise the name is displayed on the frame's caption bar."
1133   (interactive "sFrame name: ")
1134   (modify-frame-parameters (selected-frame)
1135                            (list (cons 'name name))))
1136
1137 (defun frame-current-scroll-bars (&optional frame)
1138   "Return the current scroll-bar settings in frame FRAME.
1139 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1140 current location of the vertical scroll-bars (left, right, or nil),
1141 and HORIZONTAL specifies the current location of the horizontal scroll
1142 bars (top, bottom, or nil)."
1143   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1144         (hor nil))
1145     (unless (memq vert '(left right nil))
1146       (setq vert default-frame-scroll-bars))
1147     (cons vert hor)))
1148 \f
1149 ;;;; Frame/display capabilities.
1150 (defun selected-terminal ()
1151   "Return the terminal that is now selected."
1152   (frame-terminal (selected-frame)))
1153
1154 (declare-function msdos-mouse-p "dosfns.c")
1155
1156 (defun display-mouse-p (&optional display)
1157   "Return non-nil if DISPLAY has a mouse available.
1158 DISPLAY can be a display name, a frame, or nil (meaning the selected
1159 frame's display)."
1160   (let ((frame-type (framep-on-display display)))
1161     (cond
1162      ((eq frame-type 'pc)
1163       (msdos-mouse-p))
1164      ((eq system-type 'windows-nt)
1165       (with-no-warnings
1166        (> w32-num-mouse-buttons 0)))
1167      ((memq frame-type '(x mac ns))
1168       t)    ;; We assume X, Mac, NeXTstep *always* have a pointing device
1169      (t
1170       (or (and (featurep 'xt-mouse)
1171                xterm-mouse-mode)
1172           ;; t-mouse is distributed with the GPM package.  It doesn't have
1173           ;; a toggle.
1174           (featurep 't-mouse))))))
1175
1176 (defun display-popup-menus-p (&optional display)
1177   "Return non-nil if popup menus are supported on DISPLAY.
1178 DISPLAY can be a display name, a frame, or nil (meaning the selected
1179 frame's display).
1180 Support for popup menus requires that the mouse be available."
1181   (and
1182    (let ((frame-type (framep-on-display display)))
1183      (memq frame-type '(x w32 pc mac ns)))
1184    (display-mouse-p display)))
1185
1186 (defun display-graphic-p (&optional display)
1187   "Return non-nil if DISPLAY is a graphic display.
1188 Graphical displays are those which are capable of displaying several
1189 frames and several different fonts at once.  This is true for displays
1190 that use a window system such as X, and false for text-only terminals.
1191 DISPLAY can be a display name, a frame, or nil (meaning the selected
1192 frame's display)."
1193   (not (null (memq (framep-on-display display) '(x w32 mac ns)))))
1194
1195 (defun display-images-p (&optional display)
1196   "Return non-nil if DISPLAY can display images.
1197
1198 DISPLAY can be a display name, a frame, or nil (meaning the selected
1199 frame's display)."
1200   (and (display-graphic-p display)
1201        (fboundp 'image-mask-p)
1202        (fboundp 'image-size)))
1203
1204 (defalias 'display-multi-frame-p 'display-graphic-p)
1205 (defalias 'display-multi-font-p 'display-graphic-p)
1206
1207 (defun display-selections-p (&optional display)
1208   "Return non-nil if DISPLAY supports selections.
1209 A selection is a way to transfer text or other data between programs
1210 via special system buffers called `selection' or `cut buffer' or
1211 `clipboard'.
1212 DISPLAY can be a display name, a frame, or nil (meaning the selected
1213 frame's display)."
1214   (let ((frame-type (framep-on-display display)))
1215     (cond
1216      ((eq frame-type 'pc)
1217       ;; MS-DOG frames support selections when Emacs runs inside
1218       ;; the Windows' DOS Box.
1219       (with-no-warnings
1220        (not (null dos-windows-version))))
1221      ((memq frame-type '(x w32 mac ns))
1222       t)    ;; FIXME?
1223      (t
1224       nil))))
1225
1226 (declare-function x-display-screens "xfns.c" (&optional terminal))
1227
1228 (defun display-screens (&optional display)
1229   "Return the number of screens associated with DISPLAY."
1230   (let ((frame-type (framep-on-display display)))
1231     (cond
1232      ((memq frame-type '(x w32 mac ns))
1233       (x-display-screens display))
1234      (t
1235       1))))
1236
1237 (declare-function x-display-pixel-height "xfns.c" (&optional terminal))
1238
1239 (defun display-pixel-height (&optional display)
1240   "Return the height of DISPLAY's screen in pixels.
1241 For character terminals, each character counts as a single pixel."
1242   (let ((frame-type (framep-on-display display)))
1243     (cond
1244      ((memq frame-type '(x w32 mac ns))
1245       (x-display-pixel-height display))
1246      (t
1247       (frame-height (if (framep display) display (selected-frame)))))))
1248
1249 (declare-function x-display-pixel-width "xfns.c" (&optional terminal))
1250
1251 (defun display-pixel-width (&optional display)
1252   "Return the width of DISPLAY's screen in pixels.
1253 For character terminals, each character counts as a single pixel."
1254   (let ((frame-type (framep-on-display display)))
1255     (cond
1256      ((memq frame-type '(x w32 mac ns))
1257       (x-display-pixel-width display))
1258      (t
1259       (frame-width (if (framep display) display (selected-frame)))))))
1260
1261 (defcustom display-mm-dimensions-alist nil
1262   "Alist for specifying screen dimensions in millimeters.
1263 The dimensions will be used for `display-mm-height' and
1264 `display-mm-width' if defined for the respective display.
1265
1266 Each element of the alist has the form (display . (width . height)),
1267 e.g. (\":0.0\" . (287 . 215)).
1268
1269 If `display' equals t, it specifies dimensions for all graphical
1270 displays not explicitely specified."
1271   :version "22.1"
1272   :type '(alist :key-type (choice (string :tag "Display name")
1273                                   (const :tag "Default" t))
1274                 :value-type (cons :tag "Dimensions"
1275                                   (integer :tag "Width")
1276                                   (integer :tag "Height")))
1277   :group 'frames)
1278
1279 (declare-function x-display-mm-height "xfns.c" (&optional terminal))
1280
1281 (defun display-mm-height (&optional display)
1282   "Return the height of DISPLAY's screen in millimeters.
1283 System values can be overridden by `display-mm-dimensions-alist'.
1284 If the information is unavailable, value is nil."
1285   (and (memq (framep-on-display display) '(x w32 mac ns))
1286        (or (cddr (assoc (or display (frame-parameter nil 'display))
1287                         display-mm-dimensions-alist))
1288            (cddr (assoc t display-mm-dimensions-alist))
1289            (x-display-mm-height display))))
1290
1291 (declare-function x-display-mm-width "xfns.c" (&optional terminal))
1292
1293 (defun display-mm-width (&optional display)
1294   "Return the width of DISPLAY's screen in millimeters.
1295 System values can be overridden by `display-mm-dimensions-alist'.
1296 If the information is unavailable, value is nil."
1297   (and (memq (framep-on-display display) '(x w32 mac ns))
1298        (or (cadr (assoc (or display (frame-parameter nil 'display))
1299                         display-mm-dimensions-alist))
1300            (cadr (assoc t display-mm-dimensions-alist))
1301            (x-display-mm-width display))))
1302
1303 (declare-function x-display-backing-store "xfns.c" (&optional terminal))
1304
1305 (defun display-backing-store (&optional display)
1306   "Return the backing store capability of DISPLAY's screen.
1307 The value may be `always', `when-mapped', `not-useful', or nil if
1308 the question is inapplicable to a certain kind of display."
1309   (let ((frame-type (framep-on-display display)))
1310     (cond
1311      ((memq frame-type '(x w32 mac ns))
1312       (x-display-backing-store display))
1313      (t
1314       'not-useful))))
1315
1316 (declare-function x-display-save-under "xfns.c" (&optional terminal))
1317
1318 (defun display-save-under (&optional display)
1319   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1320   (let ((frame-type (framep-on-display display)))
1321     (cond
1322      ((memq frame-type '(x w32 mac ns))
1323       (x-display-save-under display))
1324      (t
1325       'not-useful))))
1326
1327 (declare-function x-display-planes "xfns.c" (&optional terminal))
1328
1329 (defun display-planes (&optional display)
1330   "Return the number of planes supported by DISPLAY."
1331   (let ((frame-type (framep-on-display display)))
1332     (cond
1333      ((memq frame-type '(x w32 mac ns))
1334       (x-display-planes display))
1335      ((eq frame-type 'pc)
1336       4)
1337      (t
1338       (truncate (log (length (tty-color-alist)) 2))))))
1339
1340 (declare-function x-display-color-cells "xfns.c" (&optional terminal))
1341
1342 (defun display-color-cells (&optional display)
1343   "Return the number of color cells supported by DISPLAY."
1344   (let ((frame-type (framep-on-display display)))
1345     (cond
1346      ((memq frame-type '(x w32 mac ns))
1347       (x-display-color-cells display))
1348      ((eq frame-type 'pc)
1349       16)
1350      (t
1351       (tty-display-color-cells display)))))
1352
1353 (declare-function x-display-visual-class "xfns.c" (&optional terminal))
1354
1355 (defun display-visual-class (&optional display)
1356   "Returns the visual class of DISPLAY.
1357 The value is one of the symbols `static-gray', `gray-scale',
1358 `static-color', `pseudo-color', `true-color', or `direct-color'."
1359   (let ((frame-type (framep-on-display display)))
1360     (cond
1361      ((memq frame-type '(x w32 mac ns))
1362       (x-display-visual-class display))
1363      ((and (memq frame-type '(pc t))
1364            (tty-display-color-p display))
1365       'static-color)
1366      (t
1367       'static-gray))))
1368
1369 \f
1370 ;;;; Frame geometry values
1371
1372 (defun frame-geom-value-cons (type value &optional frame)
1373   "Return equivalent geometry value for FRAME as a cons with car `+'.
1374 A geometry value equivalent to VALUE for FRAME is returned,
1375 where the value is a cons with car `+', not numeric.
1376 TYPE is the car of the original geometry spec (TYPE . VALUE).
1377    It is `top' or `left', depending on which edge VALUE is related to.
1378 VALUE is the cdr of a frame geometry spec: (left/top . VALUE).
1379 If VALUE is a number, then it is converted to a cons value, perhaps
1380    relative to the opposite frame edge from that in the original spec.
1381 FRAME defaults to the selected frame.
1382
1383 Examples (measures in pixels) -
1384  Assuming display height/width=1024, frame height/width=600:
1385  300 inside display edge:                   300  => (+  300)
1386                                         (+  300) => (+  300)
1387  300 inside opposite display edge:      (-  300) => (+  124)
1388                                            -300  => (+  124)
1389  300 beyond display edge
1390   (= 724 inside opposite display edge): (+ -300) => (+ -300)
1391  300 beyond display edge
1392   (= 724 inside opposite display edge): (- -300) => (+  724)
1393
1394 In the 3rd, 4th, and 6th examples, the returned value is relative to
1395 the opposite frame edge from the edge indicated in the input spec."
1396   (cond ((and (consp value) (eq '+ (car value))) ; e.g. (+ 300), (+ -300)
1397          value)
1398         ((natnump value) (list '+ value)) ; e.g. 300 => (+ 300)
1399         (t                              ; e.g. -300, (- 300), (- -300)
1400          (list '+ (- (if (eq 'left type) ; => (+ 124), (+ 124), (+ 724)
1401                          (x-display-pixel-width)
1402                        (x-display-pixel-height))
1403                      (if (integerp value) (- value) (cadr value))
1404                      (if (eq 'left type)
1405                          (frame-pixel-width frame)
1406                        (frame-pixel-height frame)))))))
1407
1408 (defun frame-geom-spec-cons (spec &optional frame)
1409   "Return equivalent geometry spec for FRAME as a cons with car `+'.
1410 A geometry specification equivalent to SPEC for FRAME is returned,
1411 where the value is a cons with car `+', not numeric.
1412 SPEC is a frame geometry spec: (left . VALUE) or (top . VALUE).
1413 If VALUE is a number, then it is converted to a cons value, perhaps
1414    relative to the opposite frame edge from that in the original spec.
1415 FRAME defaults to the selected frame.
1416
1417 Examples (measures in pixels) -
1418  Assuming display height=1024, frame height=600:
1419  top 300 below display top:               (top .  300) => (top +  300)
1420                                           (top +  300) => (top +  300)
1421  bottom 300 above display bottom:         (top -  300) => (top +  124)
1422                                           (top . -300) => (top +  124)
1423  top 300 above display top
1424   (= bottom 724 above display bottom):    (top + -300) => (top + -300)
1425  bottom 300 below display bottom
1426   (= top 724 below display top):          (top - -300) => (top +  724)
1427
1428 In the 3rd, 4th, and 6th examples, the returned value is relative to
1429 the opposite frame edge from the edge indicated in the input spec."
1430   (cons (car spec) (frame-geom-value-cons (car spec) (cdr spec))))
1431 \f
1432 ;;;; Aliases for backward compatibility with Emacs 18.
1433 (define-obsolete-function-alias 'screen-height 'frame-height "19.7")
1434 (define-obsolete-function-alias 'screen-width 'frame-width "19.7")
1435
1436 (defun set-screen-width (cols &optional pretend)
1437   "Change the size of the screen to COLS columns.
1438 Optional second arg non-nil means that redisplay should use COLS columns
1439 but that the idea of the actual width of the frame should not be changed.
1440 This function is provided only for compatibility with Emacs 18."
1441   (set-frame-width (selected-frame) cols pretend))
1442
1443 (defun set-screen-height (lines &optional pretend)
1444   "Change the height of the screen to LINES lines.
1445 Optional second arg non-nil means that redisplay should use LINES lines
1446 but that the idea of the actual height of the screen should not be changed.
1447 This function is provided only for compatibility with Emacs 18."
1448   (set-frame-height (selected-frame) lines pretend))
1449
1450 (defun delete-other-frames (&optional frame)
1451   "Delete all frames except FRAME.
1452 If FRAME uses another frame's minibuffer, the minibuffer frame is
1453 left untouched.  FRAME nil or omitted means use the selected frame."
1454   (interactive)
1455   (unless frame
1456     (setq frame (selected-frame)))
1457   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1458          (frames (delq mini-frame (delq frame (frame-list)))))
1459     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1460     ;; signals an error when trying to delete a mini-frame that's
1461     ;; still in use by another frame.
1462     (dolist (frame frames)
1463       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1464         (delete-frame frame)))
1465     ;; Delete minibuffer-only frames.
1466     (dolist (frame frames)
1467       (when (eq (frame-parameter frame 'minibuffer) 'only)
1468         (delete-frame frame)))))
1469
1470 (make-obsolete 'set-screen-width 'set-frame-width "19.7")
1471 (make-obsolete 'set-screen-height 'set-frame-height "19.7")
1472
1473 ;; miscellaneous obsolescence declarations
1474 (define-obsolete-variable-alias 'delete-frame-hook
1475     'delete-frame-functions "22.1")
1476
1477 \f
1478 ;; Highlighting trailing whitespace.
1479
1480 (make-variable-buffer-local 'show-trailing-whitespace)
1481
1482 (defcustom show-trailing-whitespace nil
1483   "*Non-nil means highlight trailing whitespace.
1484 This is done in the face `trailing-whitespace'."
1485   :type 'boolean
1486   :group 'whitespace-faces)
1487
1488
1489 \f
1490 ;; Scrolling
1491
1492 (defgroup scrolling nil
1493   "Scrolling windows."
1494   :version "21.1"
1495   :group 'frames)
1496
1497 (defcustom auto-hscroll-mode t
1498   "*Allow or disallow automatic scrolling windows horizontally.
1499 If non-nil, windows are automatically scrolled horizontally to make
1500 point visible."
1501   :version "21.1"
1502   :type 'boolean
1503   :group 'scrolling)
1504 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1505
1506 \f
1507 ;; Blinking cursor
1508
1509 (defgroup cursor nil
1510   "Displaying text cursors."
1511   :version "21.1"
1512   :group 'frames)
1513
1514 (defcustom blink-cursor-delay 0.5
1515   "*Seconds of idle time after which cursor starts to blink."
1516   :type 'number
1517   :group 'cursor)
1518
1519 (defcustom blink-cursor-interval 0.5
1520   "*Length of cursor blink interval in seconds."
1521   :type 'number
1522   :group 'cursor)
1523
1524 (defvar blink-cursor-idle-timer nil
1525   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1526 The function `blink-cursor-start' is called when the timer fires.")
1527
1528 (defvar blink-cursor-timer nil
1529   "Timer started from `blink-cursor-start'.
1530 This timer calls `blink-cursor-timer-function' every
1531 `blink-cursor-interval' seconds.")
1532
1533 (defun blink-cursor-start ()
1534   "Timer function called from the timer `blink-cursor-idle-timer'.
1535 This starts the timer `blink-cursor-timer', which makes the cursor blink
1536 if appropriate.  It also arranges to cancel that timer when the next
1537 command starts, by installing a pre-command hook."
1538   (when (null blink-cursor-timer)
1539     ;; Set up the timer first, so that if this signals an error,
1540     ;; blink-cursor-end is not added to pre-command-hook.
1541     (setq blink-cursor-timer
1542           (run-with-timer blink-cursor-interval blink-cursor-interval
1543                           'blink-cursor-timer-function))
1544     (add-hook 'pre-command-hook 'blink-cursor-end)
1545     (internal-show-cursor nil nil)))
1546
1547 (defun blink-cursor-timer-function ()
1548   "Timer function of timer `blink-cursor-timer'."
1549   (internal-show-cursor nil (not (internal-show-cursor-p))))
1550
1551 (defun blink-cursor-end ()
1552   "Stop cursor blinking.
1553 This is installed as a pre-command hook by `blink-cursor-start'.
1554 When run, it cancels the timer `blink-cursor-timer' and removes
1555 itself as a pre-command hook."
1556   (remove-hook 'pre-command-hook 'blink-cursor-end)
1557   (internal-show-cursor nil t)
1558   (when blink-cursor-timer
1559     (cancel-timer blink-cursor-timer)
1560     (setq blink-cursor-timer nil)))
1561
1562 (define-minor-mode blink-cursor-mode
1563   "Toggle blinking cursor mode.
1564 With a numeric argument, turn blinking cursor mode on if ARG is positive,
1565 otherwise turn it off.  When blinking cursor mode is enabled, the
1566 cursor of the selected window blinks.
1567
1568 Note that this command is effective only when Emacs
1569 displays through a window system, because then Emacs does its own
1570 cursor display.  On a text-only terminal, this is not implemented."
1571   :init-value (not (or noninteractive
1572                        no-blinking-cursor
1573                        (eq system-type 'ms-dos)
1574                        (not (memq window-system '(x w32 mac)))))
1575   :initialize 'custom-initialize-safe-default
1576   :group 'cursor
1577   :global t
1578   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1579   (setq blink-cursor-idle-timer nil)
1580   (blink-cursor-end)
1581   (when blink-cursor-mode
1582     ;; Hide the cursor.
1583     ;;(internal-show-cursor nil nil)
1584     (setq blink-cursor-idle-timer
1585           (run-with-idle-timer blink-cursor-delay
1586                                blink-cursor-delay
1587                                'blink-cursor-start))))
1588
1589 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1590 \f
1591 ;; Hourglass pointer
1592
1593 (defcustom display-hourglass t
1594   "*Non-nil means show an hourglass pointer, when Emacs is busy.
1595 This feature only works when on a window system that can change
1596 cursor shapes."
1597   :type 'boolean
1598   :group 'cursor)
1599
1600 (defcustom hourglass-delay 1
1601   "*Seconds to wait before displaying an hourglass pointer when Emacs is busy."
1602   :type 'number
1603   :group 'cursor)
1604
1605 \f
1606 (defcustom cursor-in-non-selected-windows t
1607   "*Non-nil means show a hollow box cursor in non-selected windows.
1608 If nil, don't show a cursor except in the selected window.
1609 If t, display a cursor related to the usual cursor type
1610  \(a solid box becomes hollow, a bar becomes a narrower bar).
1611 You can also specify the cursor type as in the `cursor-type' variable.
1612 Use Custom to set this variable to get the display updated."
1613   :tag "Cursor In Non-selected Windows"
1614   :type 'boolean
1615   :group 'cursor
1616   :set #'(lambda (symbol value)
1617            (set-default symbol value)
1618            (force-mode-line-update t)))
1619
1620 \f
1621 ;;;; Key bindings
1622
1623 (define-key ctl-x-5-map "2" 'make-frame-command)
1624 (define-key ctl-x-5-map "1" 'delete-other-frames)
1625 (define-key ctl-x-5-map "0" 'delete-frame)
1626 (define-key ctl-x-5-map "o" 'other-frame)
1627
1628 (provide 'frame)
1629
1630 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1631 ;;; frame.el ends here