lisp/eshell/em-cmpl.el

   1 ;;; em-cmpl.el --- completion using the TAB key
   2
   3 ;; Copyright (C) 1999-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: John Wiegley <johnw@gnu.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; Eshell, by using the pcomplete package, provides a full
  25 ;; programmable completion facility that is comparable to shells like
  26 ;; tcsh or zsh.
  27 ;;
  28 ;; Completions are context-sensitive, which means that pressing <TAB>
  29 ;; after the command 'rmdir' will result in a list of directories,
  30 ;; while doing so after 'rm' will result in a list of all file
  31 ;; entries.
  32 ;;
  33 ;; Many builtin completion rules are provided, for commands such as
  34 ;; `cvs', or RedHat's `rpm' utility.  Adding new completion rules is
  35 ;; no more difficult than writing a plain Lisp functions, and they can
  36 ;; be debugged, profiled, and compiled using exactly the same
  37 ;; facilities (since in fact, they *are* just Lisp functions).  See
  38 ;; the definition of the function `pcomplete/make' for an example of
  39 ;; how to write a completion function.
  40 ;;
  41 ;; The completion facility is very easy to use.  Just press TAB.  If
  42 ;; there are a large number of possible completions, a buffer will
  43 ;; appear showing a list of them.  Completions may be selected from
  44 ;; that buffer using the mouse.  If no completion is selected, and the
  45 ;; user starts doing something else, the display buffer will
  46 ;; automatically disappear.
  47 ;;
  48 ;; If the list of possible completions is very small, Eshell will
  49 ;; "cycle" through them, selecting a different entry each time <TAB>
  50 ;; is pressed.  <S-TAB> may be used to cycle in the opposite
  51 ;; direction.
  52 ;;
  53 ;; Glob patterns can also be cycled.  For example, entering 'echo
  54 ;; x*<tab>' will cycle through all the filenames beginning with 'x'.
  55 ;; This is done because the glob list is treated as though it were a
  56 ;; list of possible completions.  Pressing <C-c SPC> will insert all
  57 ;; of the matching glob patterns at point.
  58 ;;
  59 ;; If a Lisp form is being entered, <TAB> will complete the Lisp
  60 ;; symbol name, in exactly the same way that <M-TAB> does in Emacs
  61 ;; Lisp mode.
  62 ;;
  63 ;; The list of possible completions can be viewed at any point by
  64 ;; pressing <M-?>.
  65 ;;
  66 ;; Finally, context-related help can be accessed by pressing <C-c M-h>.
  67 ;; This only works well if the completion function has provided Eshell
  68 ;; with sufficient pointers to locate the relevant help text.
  69
  70 ;;; Code:
  71 (require 'pcomplete)
  72
  73 (eval-when-compile
  74   (require 'cl-lib)
  75   (require 'eshell))
  76 (require 'esh-util)
  77
  78 ;;;###autoload
  79 (progn
  80 (defgroup eshell-cmpl nil
  81   "This module provides a programmable completion function bound to
  82 the TAB key, which allows for completing command names, file names,
  83 variable names, arguments, etc."
  84   :tag "Argument completion"
  85   :group 'eshell-module))
  86
  87 ;;; User Variables:
  88
  89 (defcustom eshell-cmpl-load-hook nil
  90   "A list of functions to run when `eshell-cmpl' is loaded."
  91   :version "24.1"                       ; removed eshell-cmpl-initialize
  92   :type 'hook
  93   :group 'eshell-cmpl)
  94
  95 (defcustom eshell-show-lisp-completions nil
  96   "If non-nil, include Lisp functions in the command completion list.
  97 If this variable is nil, Lisp completion can still be done in command
  98 position by using M-TAB instead of TAB."
  99   :type 'boolean
 100   :group 'eshell-cmpl)
 101
 102 (defcustom eshell-show-lisp-alternatives t
 103   "If non-nil, and no other completions found, show Lisp functions.
 104 Setting this variable means nothing if `eshell-show-lisp-completions'
 105 is non-nil."
 106   :type 'boolean
 107   :group 'eshell-cmpl)
 108
 109 (defcustom eshell-no-completion-during-jobs t
 110   "If non-nil, don't allow completion while a process is running."
 111   :type 'boolean
 112   :group 'eshell-cmpl)
 113
 114 (defcustom eshell-command-completions-alist
 115   '(("acroread" . "\\.pdf\\'")
 116     ("xpdf"     . "\\.pdf\\'")
 117     ("ar"       . "\\.[ao]\\'")
 118     ("gcc"      . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 119     ("g++"      . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 120     ("cc"       . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 121     ("CC"       . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 122     ("acc"      . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 123     ("bcc"      . "\\.[Cc]\\([Cc]\\|[Pp][Pp]\\)?\\'")
 124     ("readelf"  . "\\(\\`[^.]*\\|\\.\\([ao]\\|so\\)\\)\\'")
 125     ("objdump"  . "\\(\\`[^.]*\\|\\.\\([ao]\\|so\\)\\)\\'")
 126     ("nm"       . "\\(\\`[^.]*\\|\\.\\([ao]\\|so\\)\\)\\'")
 127     ("gdb"      . "\\`\\([^.]*\\|a\\.out\\)\\'")
 128     ("dbx"      . "\\`\\([^.]*\\|a\\.out\\)\\'")
 129     ("sdb"      . "\\`\\([^.]*\\|a\\.out\\)\\'")
 130     ("adb"      . "\\`\\([^.]*\\|a\\.out\\)\\'"))
 131   "An alist that defines simple argument type correlations.
 132 This is provided for common commands, as a simplistic alternative
 133 to writing a completion function."
 134   :type '(repeat (cons string regexp))
 135   :group 'eshell-cmpl)
 136
 137 (defcustom eshell-cmpl-file-ignore "~\\'"
 138   (documentation-property 'pcomplete-file-ignore
 139                           'variable-documentation)
 140   :type (get 'pcomplete-file-ignore 'custom-type)
 141   :group 'eshell-cmpl)
 142
 143 (defcustom eshell-cmpl-dir-ignore "\\`\\(\\.\\.?\\|CVS\\)/\\'"
 144   (documentation-property 'pcomplete-dir-ignore
 145                           'variable-documentation)
 146   :type (get 'pcomplete-dir-ignore 'custom-type)
 147   :group 'eshell-cmpl)
 148
 149 (defcustom eshell-cmpl-ignore-case (eshell-under-windows-p)
 150   (documentation-property 'pcomplete-ignore-case
 151                           'variable-documentation)
 152   :type (get 'pcomplete-ignore-case 'custom-type)
 153   :group 'eshell-cmpl)
 154
 155 (defcustom eshell-cmpl-autolist nil
 156   (documentation-property 'pcomplete-autolist
 157                           'variable-documentation)
 158   :type (get 'pcomplete-autolist 'custom-type)
 159   :group 'eshell-cmpl)
 160
 161 (defcustom eshell-cmpl-suffix-list (list ?/ ?:)
 162   (documentation-property 'pcomplete-suffix-list
 163                           'variable-documentation)
 164   :type (get 'pcomplete-suffix-list 'custom-type)
 165   :group 'pcomplete)
 166
 167 (defcustom eshell-cmpl-recexact nil
 168   (documentation-property 'pcomplete-recexact
 169                           'variable-documentation)
 170   :type (get 'pcomplete-recexact 'custom-type)
 171   :group 'eshell-cmpl)
 172
 173 (defcustom eshell-cmpl-man-function 'man
 174   (documentation-property 'pcomplete-man-function
 175                           'variable-documentation)
 176   :type (get 'pcomplete-man-function 'custom-type)
 177   :group 'eshell-cmpl)
 178
 179 (defcustom eshell-cmpl-compare-entry-function 'file-newer-than-file-p
 180   (documentation-property 'pcomplete-compare-entry-function
 181                           'variable-documentation)
 182   :type (get 'pcomplete-compare-entry-function 'custom-type)
 183   :group 'eshell-cmpl)
 184
 185 (defcustom eshell-cmpl-expand-before-complete nil
 186   (documentation-property 'pcomplete-expand-before-complete
 187                           'variable-documentation)
 188   :type (get 'pcomplete-expand-before-complete 'custom-type)
 189   :group 'eshell-cmpl)
 190
 191 (defcustom eshell-cmpl-cycle-completions t
 192   (documentation-property 'pcomplete-cycle-completions
 193                           'variable-documentation)
 194   :type (get 'pcomplete-cycle-completions 'custom-type)
 195   :group 'eshell-cmpl)
 196
 197 (defcustom eshell-cmpl-cycle-cutoff-length 5
 198   (documentation-property 'pcomplete-cycle-cutoff-length
 199                           'variable-documentation)
 200   :type (get 'pcomplete-cycle-cutoff-length 'custom-type)
 201   :group 'eshell-cmpl)
 202
 203 (defcustom eshell-cmpl-restore-window-delay 1
 204   (documentation-property 'pcomplete-restore-window-delay
 205                           'variable-documentation)
 206   :type (get 'pcomplete-restore-window-delay 'custom-type)
 207   :group 'eshell-cmpl)
 208
 209 (defcustom eshell-command-completion-function
 210   (function
 211    (lambda ()
 212      (pcomplete-here (eshell-complete-commands-list))))
 213   (documentation-property 'pcomplete-command-completion-function
 214                           'variable-documentation)
 215   :type (get 'pcomplete-command-completion-function 'custom-type)
 216   :group 'eshell-cmpl)
 217
 218 (defcustom eshell-cmpl-command-name-function
 219   'eshell-completion-command-name
 220   (documentation-property 'pcomplete-command-name-function
 221                           'variable-documentation)
 222   :type (get 'pcomplete-command-name-function 'custom-type)
 223   :group 'eshell-cmpl)
 224
 225 (defcustom eshell-default-completion-function
 226   (function
 227    (lambda ()
 228      (while (pcomplete-here
 229              (pcomplete-dirs-or-entries
 230               (cdr (assoc (funcall eshell-cmpl-command-name-function)
 231                           eshell-command-completions-alist)))))))
 232   (documentation-property 'pcomplete-default-completion-function
 233                           'variable-documentation)
 234   :type (get 'pcomplete-default-completion-function 'custom-type)
 235   :group 'eshell-cmpl)
 236
 237 (defcustom eshell-cmpl-use-paring t
 238   (documentation-property 'pcomplete-use-paring 'variable-documentation)
 239   :type (get 'pcomplete-use-paring 'custom-type)
 240   :group 'eshell-cmpl)
 241
 242 ;;; Functions:
 243
 244 (defun eshell-cmpl-initialize ()
 245   "Initialize the completions module."
 246   (set (make-local-variable 'pcomplete-command-completion-function)
 247        eshell-command-completion-function)
 248   (set (make-local-variable 'pcomplete-command-name-function)
 249        eshell-cmpl-command-name-function)
 250   (set (make-local-variable 'pcomplete-default-completion-function)
 251        eshell-default-completion-function)
 252   (set (make-local-variable 'pcomplete-parse-arguments-function)
 253        'eshell-complete-parse-arguments)
 254   (set (make-local-variable 'pcomplete-file-ignore)
 255        eshell-cmpl-file-ignore)
 256   (set (make-local-variable 'pcomplete-dir-ignore)
 257        eshell-cmpl-dir-ignore)
 258   (set (make-local-variable 'pcomplete-ignore-case)
 259        eshell-cmpl-ignore-case)
 260   (set (make-local-variable 'pcomplete-autolist)
 261        eshell-cmpl-autolist)
 262   (set (make-local-variable 'pcomplete-suffix-list)
 263        eshell-cmpl-suffix-list)
 264   (set (make-local-variable 'pcomplete-recexact)
 265        eshell-cmpl-recexact)
 266   (set (make-local-variable 'pcomplete-man-function)
 267        eshell-cmpl-man-function)
 268   (set (make-local-variable 'pcomplete-compare-entry-function)
 269        eshell-cmpl-compare-entry-function)
 270   (set (make-local-variable 'pcomplete-expand-before-complete)
 271        eshell-cmpl-expand-before-complete)
 272   (set (make-local-variable 'pcomplete-cycle-completions)
 273        eshell-cmpl-cycle-completions)
 274   (set (make-local-variable 'pcomplete-cycle-cutoff-length)
 275        eshell-cmpl-cycle-cutoff-length)
 276   (set (make-local-variable 'pcomplete-restore-window-delay)
 277        eshell-cmpl-restore-window-delay)
 278   (set (make-local-variable 'pcomplete-use-paring)
 279        eshell-cmpl-use-paring)
 280   ;; `pcomplete-arg-quote-list' should only be set after all the
 281   ;; load-hooks for any other extension modules have been run, which
 282   ;; is true at the time `eshell-mode-hook' is run
 283   (add-hook 'eshell-mode-hook
 284             (function
 285              (lambda ()
 286                (set (make-local-variable 'pcomplete-arg-quote-list)
 287                     eshell-special-chars-outside-quoting))) nil t)
 288   (add-hook 'pcomplete-quote-arg-hook 'eshell-quote-backslash nil t)
 289   (define-key eshell-mode-map [(meta tab)] 'lisp-complete-symbol)
 290   (define-key eshell-mode-map [(meta control ?i)] 'lisp-complete-symbol)
 291   (define-key eshell-command-map [(meta ?h)] 'eshell-completion-help)
 292   (define-key eshell-command-map [tab] 'pcomplete-expand-and-complete)
 293   (define-key eshell-command-map [(control ?i)]
 294     'pcomplete-expand-and-complete)
 295   (define-key eshell-command-map [space] 'pcomplete-expand)
 296   (define-key eshell-command-map [? ] 'pcomplete-expand)
 297   (define-key eshell-mode-map [tab] 'eshell-pcomplete)
 298   (define-key eshell-mode-map [(control ?i)] 'eshell-pcomplete)
 299   (add-hook 'completion-at-point-functions
 300             #'pcomplete-completions-at-point nil t)
 301   ;; jww (1999-10-19): Will this work on anything but X?
 302   (if (featurep 'xemacs)
 303       (define-key eshell-mode-map [iso-left-tab] 'pcomplete-reverse)
 304     (define-key eshell-mode-map [backtab] 'pcomplete-reverse))
 305   (define-key eshell-mode-map [(meta ??)] 'pcomplete-list))
 306
 307 (defun eshell-completion-command-name ()
 308   "Return the command name, possibly sans globbing."
 309   (let ((cmd (file-name-nondirectory (pcomplete-arg 'first))))
 310     (setq cmd (if (and (> (length cmd) 0)
 311                        (eq (aref cmd 0) eshell-explicit-command-char))
 312                   (substring cmd 1)
 313                 cmd))
 314     (if (eshell-under-windows-p)
 315         (file-name-sans-extension cmd)
 316       cmd)))
 317
 318 (defun eshell-completion-help ()
 319   (interactive)
 320   (if (= (point) eshell-last-output-end)
 321       (describe-prefix-bindings)
 322     (call-interactively 'pcomplete-help)))
 323
 324 (defun eshell-complete-parse-arguments ()
 325   "Parse the command line arguments for `pcomplete-argument'."
 326   (when (and eshell-no-completion-during-jobs
 327              (eshell-interactive-process))
 328     (insert-and-inherit "\t")
 329     (throw 'pcompleted t))
 330   (let ((end (point-marker))
 331         (begin (save-excursion (eshell-bol) (point)))
 332         (posns (list t))
 333         args delim)
 334     (when (memq this-command '(pcomplete-expand
 335                                pcomplete-expand-and-complete))
 336       (run-hook-with-args 'eshell-expand-input-functions begin end)
 337       (if (= begin end)
 338           (end-of-line))
 339       (setq end (point-marker)))
 340     (if (setq delim
 341               (catch 'eshell-incomplete
 342                 (ignore
 343                  (setq args (eshell-parse-arguments begin end)))))
 344         (cond ((memq (car delim) '(?\{ ?\<))
 345                (setq begin (1+ (cadr delim))
 346                      args (eshell-parse-arguments begin end)))
 347               ((eq (car delim) ?\()
 348                (lisp-complete-symbol)
 349                (throw 'pcompleted t))
 350               (t
 351                (insert-and-inherit "\t")
 352                (throw 'pcompleted t))))
 353     (when (get-text-property (1- end) 'comment)
 354       (insert-and-inherit "\t")
 355       (throw 'pcompleted t))
 356     (let ((pos begin))
 357       (while (< pos end)
 358         (if (get-text-property pos 'arg-begin)
 359             (nconc posns (list pos)))
 360         (setq pos (1+ pos))))
 361     (setq posns (cdr posns))
 362     (cl-assert (= (length args) (length posns)))
 363     (let ((a args)
 364           (i 0)
 365           l final)
 366       (while a
 367         (if (and (consp (car a))
 368                  (eq (caar a) 'eshell-operator))
 369             (setq l i))
 370         (setq a (cdr a) i (1+ i)))
 371       (and l
 372            (setq args (nthcdr (1+ l) args)
 373                  posns (nthcdr (1+ l) posns))))
 374     (cl-assert (= (length args) (length posns)))
 375     (when (and args (eq (char-syntax (char-before end)) ? )
 376                (not (eq (char-before (1- end)) ?\\)))
 377       (nconc args (list ""))
 378       (nconc posns (list (point))))
 379     (cons (mapcar
 380            (function
 381             (lambda (arg)
 382               (let ((val
 383                      (if (listp arg)
 384                          (let ((result
 385                                 (eshell-do-eval
 386                                  (list 'eshell-commands arg) t)))
 387                            (cl-assert (eq (car result) 'quote))
 388                            (cadr result))
 389                        arg)))
 390                 (if (numberp val)
 391                     (setq val (number-to-string val)))
 392                 (or val ""))))
 393            args)
 394           posns)))
 395
 396 (defun eshell-complete-commands-list ()
 397   "Generate list of applicable, visible commands."
 398   (let ((filename (pcomplete-arg)) glob-name)
 399     (if (file-name-directory filename)
 400         (pcomplete-executables)
 401       (if (and (> (length filename) 0)
 402                (eq (aref filename 0) eshell-explicit-command-char))
 403           (setq filename (substring filename 1)
 404                 pcomplete-stub filename
 405                 glob-name t))
 406       (let* ((paths (eshell-parse-colon-path eshell-path-env))
 407              (cwd (file-name-as-directory
 408                    (expand-file-name default-directory)))
 409              (path "") (comps-in-path ())
 410              (file "") (filepath "") (completions ()))
 411         ;; Go thru each path in the search path, finding completions.
 412         (while paths
 413           (setq path (file-name-as-directory
 414                       (expand-file-name (or (car paths) ".")))
 415                 comps-in-path
 416                 (and (file-accessible-directory-p path)
 417                      (file-name-all-completions filename path)))
 418           ;; Go thru each completion found, to see whether it should
 419           ;; be used.
 420           (while comps-in-path
 421             (setq file (car comps-in-path)
 422                   filepath (concat path file))
 423             (if (and (not (member file completions)) ;
 424                      (or (string-equal path cwd)
 425                          (not (file-directory-p filepath)))
 426                      (file-executable-p filepath))
 427                 (setq completions (cons file completions)))
 428             (setq comps-in-path (cdr comps-in-path)))
 429           (setq paths (cdr paths)))
 430         ;; Add aliases which are currently visible, and Lisp functions.
 431         (pcomplete-uniqify-list
 432          (if glob-name
 433              completions
 434            (setq completions
 435                  (append (and (eshell-using-module 'eshell-alias)
 436                               (funcall (symbol-function 'eshell-alias-completions)
 437                                        filename))
 438                          (eshell-winnow-list
 439                           (mapcar
 440                            (function
 441                             (lambda (name)
 442                               (substring name 7)))
 443                            (all-completions (concat "eshell/" filename)
 444                                             obarray 'functionp))
 445                           nil '(eshell-find-alias-function))
 446                          completions))
 447            (append (and (or eshell-show-lisp-completions
 448                             (and eshell-show-lisp-alternatives
 449                                  (null completions)))
 450                         (all-completions filename obarray 'functionp))
 451                    completions)))))))
 452
 453 (defun eshell-pcomplete (&optional interactively)
 454   "Eshell wrapper for `pcomplete'."
 455   (interactive "p")
 456   ;; Pretend to be pcomplete so that cycling works (bug#13293).
 457   (setq this-command 'pcomplete)
 458   (condition-case nil
 459       (if interactively
 460           (call-interactively 'pcomplete)
 461         (pcomplete))
 462     (text-read-only (completion-at-point)))) ; Workaround for bug#12838.
 463
 464 (provide 'em-cmpl)
 465
 466 ;; Local Variables:
 467 ;; generated-autoload-file: "esh-groups.el"
 468 ;; End:
 469
 470 ;;; em-cmpl.el ends here