lisp/font-lock.el

   1 ;;; font-lock.el --- Electric font lock mode
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
   5 ;;   2010, 2011  Free Software Foundation, Inc.
   6
   7 ;; Author: Jamie Zawinski
   8 ;;      Richard Stallman
   9 ;;      Stefan Monnier
  10 ;; Maintainer: FSF
  11 ;; Keywords: languages, faces
  12 ;; Package: emacs
  13
  14 ;; This file is part of GNU Emacs.
  15
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 ;;; Commentary:
  30
  31 ;; Font Lock mode is a minor mode that causes your comments to be displayed in
  32 ;; one face, strings in another, reserved words in another, and so on.
  33 ;;
  34 ;; Comments will be displayed in `font-lock-comment-face'.
  35 ;; Strings will be displayed in `font-lock-string-face'.
  36 ;; Regexps are used to display selected patterns in other faces.
  37 ;;
  38 ;; To make the text you type be fontified, use M-x font-lock-mode RET.
  39 ;; When this minor mode is on, the faces of the current line are updated with
  40 ;; every insertion or deletion.
  41 ;;
  42 ;; To turn Font Lock mode on automatically, add this to your ~/.emacs file:
  43 ;;
  44 ;;  (add-hook 'emacs-lisp-mode-hook 'turn-on-font-lock)
  45 ;;
  46 ;; Or if you want to turn Font Lock mode on in many modes:
  47 ;;
  48 ;;  (global-font-lock-mode t)
  49 ;;
  50 ;; Fontification for a particular mode may be available in a number of levels
  51 ;; of decoration.  The higher the level, the more decoration, but the more time
  52 ;; it takes to fontify.  See the variable `font-lock-maximum-decoration', and
  53 ;; also the variable `font-lock-maximum-size'.  Support modes for Font Lock
  54 ;; mode can be used to speed up Font Lock mode.  See `font-lock-support-mode'.
  55 \f
  56 ;;; How Font Lock mode fontifies:
  57
  58 ;; When Font Lock mode is turned on in a buffer, it (a) fontifies the entire
  59 ;; buffer and (b) installs one of its fontification functions on one of the
  60 ;; hook variables that are run by Emacs after every buffer change (i.e., an
  61 ;; insertion or deletion).  Fontification means the replacement of `face' text
  62 ;; properties in a given region; Emacs displays text with these `face' text
  63 ;; properties appropriately.
  64 ;;
  65 ;; Fontification normally involves syntactic (i.e., strings and comments) and
  66 ;; regexp (i.e., keywords and everything else) passes.  There are actually
  67 ;; three passes; (a) the syntactic keyword pass, (b) the syntactic pass and (c)
  68 ;; the keyword pass.  Confused?
  69 ;;
  70 ;; The syntactic keyword pass places `syntax-table' text properties in the
  71 ;; buffer according to the variable `font-lock-syntactic-keywords'.  It is
  72 ;; necessary because Emacs' syntax table is not powerful enough to describe all
  73 ;; the different syntactic constructs required by the sort of people who decide
  74 ;; that a single quote can be syntactic or not depending on the time of day.
  75 ;; (What sort of person could decide to overload the meaning of a quote?)
  76 ;; Obviously the syntactic keyword pass must occur before the syntactic pass.
  77 ;;
  78 ;; The syntactic pass places `face' text properties in the buffer according to
  79 ;; syntactic context, i.e., according to the buffer's syntax table and buffer
  80 ;; text's `syntax-table' text properties.  It involves using a syntax parsing
  81 ;; function to determine the context of different parts of a region of text.  A
  82 ;; syntax parsing function is necessary because generally strings and/or
  83 ;; comments can span lines, and so the context of a given region is not
  84 ;; necessarily apparent from the content of that region.  Because the keyword
  85 ;; pass only works within a given region, it is not generally appropriate for
  86 ;; syntactic fontification.  This is the first fontification pass that makes
  87 ;; changes visible to the user; it fontifies strings and comments.
  88 ;;
  89 ;; The keyword pass places `face' text properties in the buffer according to
  90 ;; the variable `font-lock-keywords'.  It involves searching for given regexps
  91 ;; (or calling given search functions) within the given region.  This is the
  92 ;; second fontification pass that makes changes visible to the user; it
  93 ;; fontifies language reserved words, etc.
  94 ;;
  95 ;; Oh, and the answer is, "Yes, obviously just about everything should be done
  96 ;; in a single syntactic pass, but the only syntactic parser available
  97 ;; understands only strings and comments."  Perhaps one day someone will write
  98 ;; some syntactic parsers for common languages and a son-of-font-lock.el could
  99 ;; use them rather then relying so heavily on the keyword (regexp) pass.
 100
 101 ;;; How Font Lock mode supports modes or is supported by modes:
 102
 103 ;; Modes that support Font Lock mode do so by defining one or more variables
 104 ;; whose values specify the fontification.  Font Lock mode knows of these
 105 ;; variable names from the buffer local variable `font-lock-defaults'.
 106 ;; (Font Lock mode is set up via (a) where a mode's patterns are
 107 ;; distributed with the mode's package library, and (b) where a mode's
 108 ;; patterns are distributed with font-lock.el itself.  An example of (a)
 109 ;; is Pascal mode, an example of (b) is Lisp mode.  Normally, the mechanism is
 110 ;; (a); (b) is used where it is not clear which package library should contain
 111 ;; the pattern definitions.)  Font Lock mode chooses which variable to use for
 112 ;; fontification based on `font-lock-maximum-decoration'.
 113 ;;
 114 ;; Font Lock mode fontification behavior can be modified in a number of ways.
 115 ;; See the below comments and the comments distributed throughout this file.
 116
 117 ;;; Constructing patterns:
 118
 119 ;; See the documentation for the variable `font-lock-keywords'.
 120 ;;
 121 ;; Efficient regexps for use as MATCHERs for `font-lock-keywords' and
 122 ;; `font-lock-syntactic-keywords' can be generated via the function
 123 ;; `regexp-opt'.
 124
 125 ;;; Adding patterns for modes that already support Font Lock:
 126
 127 ;; Though Font Lock highlighting patterns already exist for many modes, it's
 128 ;; likely there's something that you want fontified that currently isn't, even
 129 ;; at the maximum fontification level.  You can add highlighting patterns via
 130 ;; `font-lock-add-keywords'.  For example, say in some C
 131 ;; header file you #define the token `and' to expand to `&&', etc., to make
 132 ;; your C code almost readable.  In your ~/.emacs there could be:
 133 ;;
 134 ;;  (font-lock-add-keywords 'c-mode '("\\<\\(and\\|or\\|not\\)\\>"))
 135 ;;
 136 ;; Some modes provide specific ways to modify patterns based on the values of
 137 ;; other variables.  For example, additional C types can be specified via the
 138 ;; variable `c-font-lock-extra-types'.
 139
 140 ;;; Adding patterns for modes that do not support Font Lock:
 141
 142 ;; Not all modes support Font Lock mode.  If you (as a user of the mode) add
 143 ;; patterns for a new mode, you must define in your ~/.emacs a variable or
 144 ;; variables that specify regexp fontification.  Then, you should indicate to
 145 ;; Font Lock mode, via the mode hook setting `font-lock-defaults', exactly what
 146 ;; support is required.  For example, say Foo mode should have the following
 147 ;; regexps fontified case-sensitively, and comments and strings should not be
 148 ;; fontified automagically.  In your ~/.emacs there could be:
 149 ;;
 150 ;;  (defvar foo-font-lock-keywords
 151 ;;    '(("\\<\\(one\\|two\\|three\\)\\>" . font-lock-keyword-face)
 152 ;;      ("\\<\\(four\\|five\\|six\\)\\>" . font-lock-type-face))
 153 ;;    "Default expressions to highlight in Foo mode.")
 154 ;;
 155 ;;  (add-hook 'foo-mode-hook
 156 ;;   (lambda ()
 157 ;;     (set (make-local-variable 'font-lock-defaults)
 158 ;;          '(foo-font-lock-keywords t))))
 159
 160 ;;; Adding Font Lock support for modes:
 161
 162 ;; Of course, it would be better that the mode already supports Font Lock mode.
 163 ;; The package author would do something similar to above.  The mode must
 164 ;; define at the top-level a variable or variables that specify regexp
 165 ;; fontification.  Then, the mode command should indicate to Font Lock mode,
 166 ;; via `font-lock-defaults', exactly what support is required.  For example,
 167 ;; say Bar mode should have the following regexps fontified case-insensitively,
 168 ;; and comments and strings should be fontified automagically.  In bar.el there
 169 ;; could be:
 170 ;;
 171 ;;  (defvar bar-font-lock-keywords
 172 ;;    '(("\\<\\(uno\\|due\\|tre\\)\\>" . font-lock-keyword-face)
 173 ;;      ("\\<\\(quattro\\|cinque\\|sei\\)\\>" . font-lock-type-face))
 174 ;;    "Default expressions to highlight in Bar mode.")
 175 ;;
 176 ;; and within `bar-mode' there could be:
 177 ;;
 178 ;;  (set (make-local-variable 'font-lock-defaults)
 179 ;;       '(bar-font-lock-keywords nil t))
 180 \f
 181 ;; What is fontification for?  You might say, "It's to make my code look nice."
 182 ;; I think it should be for adding information in the form of cues.  These cues
 183 ;; should provide you with enough information to both (a) distinguish between
 184 ;; different items, and (b) identify the item meanings, without having to read
 185 ;; the items and think about it.  Therefore, fontification allows you to think
 186 ;; less about, say, the structure of code, and more about, say, why the code
 187 ;; doesn't work.  Or maybe it allows you to think less and drift off to sleep.
 188 ;;
 189 ;; So, here are my opinions/advice/guidelines:
 190 ;;
 191 ;; - Highlight conceptual objects, such as function and variable names, and
 192 ;;   different objects types differently, i.e., (a) and (b) above, highlight
 193 ;;   function names differently to variable names.
 194 ;; - Keep the faces distinct from each other as far as possible.
 195 ;;   i.e., (a) above.
 196 ;; - Use the same face for the same conceptual object, across all modes.
 197 ;;   i.e., (b) above, all modes that have items that can be thought of as, say,
 198 ;;   keywords, should be highlighted with the same face, etc.
 199 ;; - Make the face attributes fit the concept as far as possible.
 200 ;;   i.e., function names might be a bold color such as blue, comments might
 201 ;;   be a bright color such as red, character strings might be brown, because,
 202 ;;   err, strings are brown (that was not the reason, please believe me).
 203 ;; - Don't use a non-nil OVERRIDE unless you have a good reason.
 204 ;;   Only use OVERRIDE for special things that are easy to define, such as the
 205 ;;   way `...' quotes are treated in strings and comments in Emacs Lisp mode.
 206 ;;   Don't use it to, say, highlight keywords in commented out code or strings.
 207 ;; - Err, that's it.
 208 \f
 209 ;;; Code:
 210
 211 (require 'syntax)
 212 (eval-when-compile (require 'cl))
 213
 214 ;; Define core `font-lock' group.
 215 (defgroup font-lock '((jit-lock custom-group))
 216   "Font Lock mode text highlighting package."
 217   :link '(custom-manual :tag "Emacs Manual" "(emacs)Font Lock")
 218   :link '(custom-manual :tag "Elisp Manual" "(elisp)Font Lock Mode")
 219   :group 'faces)
 220
 221 (defgroup font-lock-faces nil
 222   "Faces for highlighting text."
 223   :prefix "font-lock-"
 224   :group 'font-lock)
 225
 226 (defgroup font-lock-extra-types nil
 227   "Extra mode-specific type names for highlighting declarations."
 228   :group 'font-lock)
 229 \f
 230 ;; User variables.
 231
 232 (defcustom font-lock-maximum-size 256000
 233   "Maximum size of a buffer for buffer fontification.
 234 Only buffers less than this can be fontified when Font Lock mode is turned on.
 235 If nil, means size is irrelevant.
 236 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 237 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 238  ((c-mode . 256000) (c++-mode . 256000) (rmail-mode . 1048576))
 239 means that the maximum size is 250K for buffers in C or C++ modes, one megabyte
 240 for buffers in Rmail mode, and size is irrelevant otherwise."
 241   :type '(choice (const :tag "none" nil)
 242                  (integer :tag "size")
 243                  (repeat :menu-tag "mode specific" :tag "mode specific"
 244                          :value ((t . nil))
 245                          (cons :tag "Instance"
 246                                (radio :tag "Mode"
 247                                       (const :tag "all" t)
 248                                       (symbol :tag "name"))
 249                                (radio :tag "Size"
 250                                       (const :tag "none" nil)
 251                                       (integer :tag "size")))))
 252   :group 'font-lock)
 253
 254 (defcustom font-lock-maximum-decoration t
 255   "Maximum decoration level for fontification.
 256 If nil, use the default decoration (typically the minimum available).
 257 If t, use the maximum decoration available.
 258 If a number, use that level of decoration (or if not available the maximum).
 259 If a list, each element should be a cons pair of the form (MAJOR-MODE . LEVEL),
 260 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 261  ((c-mode . t) (c++-mode . 2) (t . 1))
 262 means use the maximum decoration available for buffers in C mode, level 2
 263 decoration for buffers in C++ mode, and level 1 decoration otherwise."
 264   :type '(choice (const :tag "default" nil)
 265                  (const :tag "maximum" t)
 266                  (integer :tag "level" 1)
 267                  (repeat :menu-tag "mode specific" :tag "mode specific"
 268                          :value ((t . t))
 269                          (cons :tag "Instance"
 270                                (radio :tag "Mode"
 271                                       (const :tag "all" t)
 272                                       (symbol :tag "name"))
 273                                (radio :tag "Decoration"
 274                                       (const :tag "default" nil)
 275                                       (const :tag "maximum" t)
 276                                       (integer :tag "level" 1)))))
 277   :group 'font-lock)
 278
 279 (defcustom font-lock-verbose nil
 280   "If non-nil, means show status messages for buffer fontification.
 281 If a number, only buffers greater than this size have fontification messages."
 282   :type '(choice (const :tag "never" nil)
 283                  (other :tag "always" t)
 284                  (integer :tag "size"))
 285   :group 'font-lock
 286   :version "24.1")
 287 \f
 288
 289 ;; Originally these variable values were face names such as `bold' etc.
 290 ;; Now we create our own faces, but we keep these variables for compatibility
 291 ;; and they give users another mechanism for changing face appearance.
 292 ;; We now allow a FACENAME in `font-lock-keywords' to be any expression that
 293 ;; returns a face.  So the easiest thing is to continue using these variables,
 294 ;; rather than sometimes evaling FACENAME and sometimes not.  sm.
 295
 296 ;; Note that in new code, in the vast majority of cases there is no
 297 ;; need to create variables that specify face names.  Simply using
 298 ;; faces directly is enough.  Font-lock is not a template to be
 299 ;; followed in this area.
 300 (defvar font-lock-comment-face          'font-lock-comment-face
 301   "Face name to use for comments.")
 302
 303 (defvar font-lock-comment-delimiter-face 'font-lock-comment-delimiter-face
 304   "Face name to use for comment delimiters.")
 305
 306 (defvar font-lock-string-face           'font-lock-string-face
 307   "Face name to use for strings.")
 308
 309 (defvar font-lock-doc-face              'font-lock-doc-face
 310   "Face name to use for documentation.")
 311
 312 (defvar font-lock-keyword-face          'font-lock-keyword-face
 313   "Face name to use for keywords.")
 314
 315 (defvar font-lock-builtin-face          'font-lock-builtin-face
 316   "Face name to use for builtins.")
 317
 318 (defvar font-lock-function-name-face    'font-lock-function-name-face
 319   "Face name to use for function names.")
 320
 321 (defvar font-lock-variable-name-face    'font-lock-variable-name-face
 322   "Face name to use for variable names.")
 323
 324 (defvar font-lock-type-face             'font-lock-type-face
 325   "Face name to use for type and class names.")
 326
 327 (defvar font-lock-constant-face         'font-lock-constant-face
 328   "Face name to use for constant and label names.")
 329
 330 (defvar font-lock-warning-face          'font-lock-warning-face
 331   "Face name to use for things that should stand out.")
 332
 333 (defvar font-lock-negation-char-face    'font-lock-negation-char-face
 334   "Face name to use for easy to overlook negation.
 335 This can be an \"!\" or the \"n\" in \"ifndef\".")
 336
 337 (defvar font-lock-preprocessor-face     'font-lock-preprocessor-face
 338   "Face name to use for preprocessor directives.")
 339
 340 (defvar font-lock-reference-face        'font-lock-constant-face)
 341 (make-obsolete-variable 'font-lock-reference-face 'font-lock-constant-face "20.3")
 342
 343 ;; Fontification variables:
 344
 345 (defvar font-lock-keywords nil
 346   "A list of the keywords to highlight.
 347 There are two kinds of values: user-level, and compiled.
 348
 349 A user-level keywords list is what a major mode or the user would
 350 set up.  Normally the list would come from `font-lock-defaults'.
 351 through selection of a fontification level and evaluation of any
 352 contained expressions.  You can also alter it by calling
 353 `font-lock-add-keywords' or `font-lock-remove-keywords' with MODE = nil.
 354
 355 Each element in a user-level keywords list should have one of these forms:
 356
 357  MATCHER
 358  (MATCHER . SUBEXP)
 359  (MATCHER . FACENAME)
 360  (MATCHER . HIGHLIGHT)
 361  (MATCHER HIGHLIGHT ...)
 362  (eval . FORM)
 363
 364 where MATCHER can be either the regexp to search for, or the function name to
 365 call to make the search (called with one argument, the limit of the search;
 366 it should return non-nil, move point, and set `match-data' appropriately if
 367 it succeeds; like `re-search-forward' would).
 368 MATCHER regexps can be generated via the function `regexp-opt'.
 369
 370 FORM is an expression, whose value should be a keyword element, evaluated when
 371 the keyword is (first) used in a buffer.  This feature can be used to provide a
 372 keyword that can only be generated when Font Lock mode is actually turned on.
 373
 374 HIGHLIGHT should be either MATCH-HIGHLIGHT or MATCH-ANCHORED.
 375
 376 For highlighting single items, for example each instance of the word \"foo\",
 377 typically only MATCH-HIGHLIGHT is required.
 378 However, if an item or (typically) items are to be highlighted following the
 379 instance of another item (the anchor), for example each instance of the
 380 word \"bar\" following the word \"anchor\" then MATCH-ANCHORED may be required.
 381
 382 MATCH-HIGHLIGHT should be of the form:
 383
 384  (SUBEXP FACENAME [OVERRIDE [LAXMATCH]])
 385
 386 SUBEXP is the number of the subexpression of MATCHER to be highlighted.
 387
 388 FACENAME is an expression whose value is the face name to use.
 389 Instead of a face, FACENAME can evaluate to a property list
 390 of the form (face FACE PROP1 VAL1 PROP2 VAL2 ...)
 391 in which case all the listed text-properties will be set rather than
 392 just FACE.  In such a case, you will most likely want to put those
 393 properties in `font-lock-extra-managed-props' or to override
 394 `font-lock-unfontify-region-function'.
 395
 396 OVERRIDE and LAXMATCH are flags.  If OVERRIDE is t, existing fontification can
 397 be overwritten.  If `keep', only parts not already fontified are highlighted.
 398 If `prepend' or `append', existing fontification is merged with the new, in
 399 which the new or existing fontification, respectively, takes precedence.
 400 If LAXMATCH is non-nil, that means don't signal an error if there is
 401 no match for SUBEXP in MATCHER.
 402
 403 For example, an element of the form highlights (if not already highlighted):
 404
 405  \"\\\\\\=<foo\\\\\\=>\"                discrete occurrences of \"foo\" in the value of the
 406                         variable `font-lock-keyword-face'.
 407  (\"fu\\\\(bar\\\\)\" . 1)      substring \"bar\" within all occurrences of \"fubar\" in
 408                         the value of `font-lock-keyword-face'.
 409  (\"fubar\" . fubar-face)       Occurrences of \"fubar\" in the value of `fubar-face'.
 410  (\"foo\\\\|bar\" 0 foo-bar-face t)
 411                         occurrences of either \"foo\" or \"bar\" in the value
 412                         of `foo-bar-face', even if already highlighted.
 413  (fubar-match 1 fubar-face)
 414                         the first subexpression within all occurrences of
 415                         whatever the function `fubar-match' finds and matches
 416                         in the value of `fubar-face'.
 417
 418 MATCH-ANCHORED should be of the form:
 419
 420  (MATCHER PRE-MATCH-FORM POST-MATCH-FORM MATCH-HIGHLIGHT ...)
 421
 422 where MATCHER is a regexp to search for or the function name to call to make
 423 the search, as for MATCH-HIGHLIGHT above, but with one exception; see below.
 424 PRE-MATCH-FORM and POST-MATCH-FORM are evaluated before the first, and after
 425 the last, instance MATCH-ANCHORED's MATCHER is used.  Therefore they can be
 426 used to initialize before, and cleanup after, MATCHER is used.  Typically,
 427 PRE-MATCH-FORM is used to move to some position relative to the original
 428 MATCHER, before starting with MATCH-ANCHORED's MATCHER.  POST-MATCH-FORM might
 429 be used to move back, before resuming with MATCH-ANCHORED's parent's MATCHER.
 430
 431 For example, an element of the form highlights (if not already highlighted):
 432
 433  (\"\\\\\\=<anchor\\\\\\=>\" (0 anchor-face) (\"\\\\\\=<item\\\\\\=>\" nil nil (0 item-face)))
 434
 435  discrete occurrences of \"anchor\" in the value of `anchor-face', and subsequent
 436  discrete occurrences of \"item\" (on the same line) in the value of `item-face'.
 437  (Here PRE-MATCH-FORM and POST-MATCH-FORM are nil.  Therefore \"item\" is
 438  initially searched for starting from the end of the match of \"anchor\", and
 439  searching for subsequent instances of \"anchor\" resumes from where searching
 440  for \"item\" concluded.)
 441
 442 The above-mentioned exception is as follows.  The limit of the MATCHER search
 443 defaults to the end of the line after PRE-MATCH-FORM is evaluated.
 444 However, if PRE-MATCH-FORM returns a position greater than the position after
 445 PRE-MATCH-FORM is evaluated, that position is used as the limit of the search.
 446 It is generally a bad idea to return a position greater than the end of the
 447 line, i.e., cause the MATCHER search to span lines.
 448
 449 These regular expressions can match text which spans lines, although
 450 it is better to avoid it if possible since updating them while editing
 451 text is slower, and it is not guaranteed to be always correct when using
 452 support modes like jit-lock or lazy-lock.
 453
 454 This variable is set by major modes via the variable `font-lock-defaults'.
 455 Be careful when composing regexps for this list; a poorly written pattern can
 456 dramatically slow things down!
 457
 458 A compiled keywords list starts with t.  It is produced internal
 459 by `font-lock-compile-keywords' from a user-level keywords list.
 460 Its second element is the user-level keywords list that was
 461 compiled.  The remaining elements have the same form as
 462 user-level keywords, but normally their values have been
 463 optimized.")
 464
 465 (defvar font-lock-keywords-alist nil
 466   "Alist of additional `font-lock-keywords' elements for major modes.
 467
 468 Each element has the form (MODE KEYWORDS . HOW).
 469 `font-lock-set-defaults' adds the elements in the list KEYWORDS to
 470 `font-lock-keywords' when Font Lock is turned on in major mode MODE.
 471
 472 If HOW is nil, KEYWORDS are added at the beginning of
 473 `font-lock-keywords'.  If it is `set', they are used to replace the
 474 value of `font-lock-keywords'.  If HOW is any other non-nil value,
 475 they are added at the end.
 476
 477 This is normally set via `font-lock-add-keywords' and
 478 `font-lock-remove-keywords'.")
 479 (put 'font-lock-keywords-alist 'risky-local-variable t)
 480
 481 (defvar font-lock-removed-keywords-alist nil
 482   "Alist of `font-lock-keywords' elements to be removed for major modes.
 483
 484 Each element has the form (MODE . KEYWORDS).  `font-lock-set-defaults'
 485 removes the elements in the list KEYWORDS from `font-lock-keywords'
 486 when Font Lock is turned on in major mode MODE.
 487
 488 This is normally set via `font-lock-add-keywords' and
 489 `font-lock-remove-keywords'.")
 490
 491 (defvar font-lock-keywords-only nil
 492   "*Non-nil means Font Lock should not fontify comments or strings.
 493 This is normally set via `font-lock-defaults'.")
 494
 495 (defvar font-lock-keywords-case-fold-search nil
 496   "*Non-nil means the patterns in `font-lock-keywords' are case-insensitive.
 497 This is set via the function `font-lock-set-defaults', based on
 498 the CASE-FOLD argument of `font-lock-defaults'.")
 499 (make-variable-buffer-local 'font-lock-keywords-case-fold-search)
 500
 501 (defvar font-lock-syntactically-fontified 0
 502   "Point up to which `font-lock-syntactic-keywords' has been applied.
 503 If nil, this is ignored, in which case the syntactic fontification may
 504 sometimes be slightly incorrect.")
 505 (make-variable-buffer-local 'font-lock-syntactically-fontified)
 506
 507 (defvar font-lock-syntactic-face-function
 508   (lambda (state)
 509     (if (nth 3 state) font-lock-string-face font-lock-comment-face))
 510   "Function to determine which face to use when fontifying syntactically.
 511 The function is called with a single parameter (the state as returned by
 512 `parse-partial-sexp' at the beginning of the region to highlight) and
 513 should return a face.  This is normally set via `font-lock-defaults'.")
 514
 515 (defvar font-lock-syntactic-keywords nil
 516   "A list of the syntactic keywords to put syntax properties on.
 517 The value can be the list itself, or the name of a function or variable
 518 whose value is the list.
 519
 520 See `font-lock-keywords' for a description of the form of this list;
 521 only the differences are stated here.  MATCH-HIGHLIGHT should be of the form:
 522
 523  (SUBEXP SYNTAX OVERRIDE LAXMATCH)
 524
 525 where SYNTAX can be a string (as taken by `modify-syntax-entry'), a syntax
 526 table, a cons cell (as returned by `string-to-syntax') or an expression whose
 527 value is such a form.  OVERRIDE cannot be `prepend' or `append'.
 528
 529 Here are two examples of elements of `font-lock-syntactic-keywords'
 530 and what they do:
 531
 532  (\"\\\\$\\\\(#\\\\)\" 1 \".\")
 533
 534  gives a hash character punctuation syntax (\".\") when following a
 535  dollar-sign character.  Hash characters in other contexts will still
 536  follow whatever the syntax table says about the hash character.
 537
 538  (\"\\\\('\\\\).\\\\('\\\\)\"
 539   (1 \"\\\"\")
 540   (2 \"\\\"\"))
 541
 542  gives a pair single-quotes, which surround a single character, a SYNTAX of
 543  \"\\\"\" (meaning string quote syntax).  Single-quote characters in other
 544  contexts will not be affected.
 545
 546 This is normally set via `font-lock-defaults'.")
 547 (make-obsolete-variable 'font-lock-syntactic-keywords
 548                         'syntax-propertize-function "24.1")
 549
 550 (defvar font-lock-syntax-table nil
 551   "Non-nil means use this syntax table for fontifying.
 552 If this is nil, the major mode's syntax table is used.
 553 This is normally set via `font-lock-defaults'.")
 554
 555 (defvar font-lock-beginning-of-syntax-function nil
 556   "*Non-nil means use this function to move back outside all constructs.
 557 When called with no args it should move point backward to a place which
 558 is not in a string or comment and not within any bracket-pairs (or else,
 559 a place such that any bracket-pairs outside it can be ignored for Emacs
 560 syntax analysis and fontification).
 561
 562 If this is nil, Font Lock uses `syntax-begin-function' to move back
 563 outside of any comment, string, or sexp.  This variable is semi-obsolete;
 564 we recommend setting `syntax-begin-function' instead.
 565
 566 This is normally set via `font-lock-defaults'.")
 567 (make-obsolete-variable 'font-lock-beginning-of-syntax-function
 568                         'syntax-begin-function "23.3")
 569
 570 (defvar font-lock-mark-block-function nil
 571   "*Non-nil means use this function to mark a block of text.
 572 When called with no args it should leave point at the beginning of any
 573 enclosing textual block and mark at the end.
 574 This is normally set via `font-lock-defaults'.")
 575
 576 (defvar font-lock-fontify-buffer-function 'font-lock-default-fontify-buffer
 577   "Function to use for fontifying the buffer.
 578 This is normally set via `font-lock-defaults'.")
 579
 580 (defvar font-lock-unfontify-buffer-function 'font-lock-default-unfontify-buffer
 581   "Function to use for unfontifying the buffer.
 582 This is used when turning off Font Lock mode.
 583 This is normally set via `font-lock-defaults'.")
 584
 585 (defvar font-lock-fontify-region-function 'font-lock-default-fontify-region
 586   "Function to use for fontifying a region.
 587 It should take two args, the beginning and end of the region, and an optional
 588 third arg VERBOSE.  If VERBOSE is non-nil, the function should print status
 589 messages.  This is normally set via `font-lock-defaults'.")
 590
 591 (defvar font-lock-unfontify-region-function 'font-lock-default-unfontify-region
 592   "Function to use for unfontifying a region.
 593 It should take two args, the beginning and end of the region.
 594 This is normally set via `font-lock-defaults'.")
 595
 596 (defvar font-lock-inhibit-thing-lock nil
 597   "List of Font Lock mode related modes that should not be turned on.
 598 Currently, valid mode names are `fast-lock-mode', `jit-lock-mode' and
 599 `lazy-lock-mode'.  This is normally set via `font-lock-defaults'.")
 600
 601 (defvar font-lock-multiline nil
 602   "Whether font-lock should cater to multiline keywords.
 603 If nil, don't try to handle multiline patterns.
 604 If t, always handle multiline patterns.
 605 If `undecided', don't try to handle multiline patterns until you see one.
 606 Major/minor modes can set this variable if they know which option applies.")
 607
 608 (defvar font-lock-fontified nil)        ; Whether we have fontified the buffer.
 609 \f
 610 ;; Font Lock mode.
 611
 612 (eval-when-compile
 613   ;;
 614   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 615   (require 'cl)
 616   ;;
 617   ;; Borrowed from lazy-lock.el.
 618   ;; We use this to preserve or protect things when modifying text properties.
 619   (defmacro save-buffer-state (&rest body)
 620     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 621     (declare (indent 0) (debug t))
 622     `(let ((inhibit-point-motion-hooks t))
 623        (with-silent-modifications
 624          ,@body)))
 625   ;;
 626   ;; Shut up the byte compiler.
 627   (defvar font-lock-face-attributes))   ; Obsolete but respected if set.
 628
 629 (defun font-lock-mode-internal (arg)
 630   ;; Turn on Font Lock mode.
 631   (when arg
 632     (add-hook 'after-change-functions 'font-lock-after-change-function t t)
 633     (font-lock-set-defaults)
 634     (font-lock-turn-on-thing-lock)
 635     ;; Fontify the buffer if we have to.
 636     (let ((max-size (font-lock-value-in-major-mode font-lock-maximum-size)))
 637       (cond (font-lock-fontified
 638              nil)
 639             ((or (null max-size) (> max-size (buffer-size)))
 640              (font-lock-fontify-buffer))
 641             (font-lock-verbose
 642              (message "Fontifying %s...buffer size greater than font-lock-maximum-size"
 643                       (buffer-name))))))
 644   ;; Turn off Font Lock mode.
 645   (unless font-lock-mode
 646     (remove-hook 'after-change-functions 'font-lock-after-change-function t)
 647     (font-lock-unfontify-buffer)
 648     (font-lock-turn-off-thing-lock)))
 649
 650 (defun font-lock-add-keywords (mode keywords &optional how)
 651   "Add highlighting KEYWORDS for MODE.
 652
 653 MODE should be a symbol, the major mode command name, such as `c-mode'
 654 or nil.  If nil, highlighting keywords are added for the current buffer.
 655 KEYWORDS should be a list; see the variable `font-lock-keywords'.
 656 By default they are added at the beginning of the current highlighting list.
 657 If optional argument HOW is `set', they are used to replace the current
 658 highlighting list.  If HOW is any other non-nil value, they are added at the
 659 end of the current highlighting list.
 660
 661 For example:
 662
 663  (font-lock-add-keywords 'c-mode
 664   '((\"\\\\\\=<\\\\(FIXME\\\\):\" 1 font-lock-warning-face prepend)
 665     (\"\\\\\\=<\\\\(and\\\\|or\\\\|not\\\\)\\\\\\=>\" . font-lock-keyword-face)))
 666
 667 adds two fontification patterns for C mode, to fontify `FIXME:' words, even in
 668 comments, and to fontify `and', `or' and `not' words as keywords.
 669
 670 The above procedure will only add the keywords for C mode, not
 671 for modes derived from C mode.  To add them for derived modes too,
 672 pass nil for MODE and add the call to c-mode-hook.
 673
 674 For example:
 675
 676  (add-hook 'c-mode-hook
 677   (lambda ()
 678    (font-lock-add-keywords nil
 679     '((\"\\\\\\=<\\\\(FIXME\\\\):\" 1 font-lock-warning-face prepend)
 680       (\"\\\\\\=<\\\\(and\\\\|or\\\\|not\\\\)\\\\\\=>\" .
 681        font-lock-keyword-face)))))
 682
 683 The above procedure may fail to add keywords to derived modes if
 684 some involved major mode does not follow the standard conventions.
 685 File a bug report if this happens, so the major mode can be corrected.
 686
 687 Note that some modes have specialized support for additional patterns, e.g.,
 688 see the variables `c-font-lock-extra-types', `c++-font-lock-extra-types',
 689 `objc-font-lock-extra-types' and `java-font-lock-extra-types'."
 690   (cond (mode
 691          ;; If MODE is non-nil, add the KEYWORDS and HOW spec to
 692          ;; `font-lock-keywords-alist' so `font-lock-set-defaults' uses them.
 693          (let ((spec (cons keywords how)) cell)
 694            (if (setq cell (assq mode font-lock-keywords-alist))
 695                (if (eq how 'set)
 696                    (setcdr cell (list spec))
 697                  (setcdr cell (append (cdr cell) (list spec))))
 698              (push (list mode spec) font-lock-keywords-alist)))
 699          ;; Make sure that `font-lock-removed-keywords-alist' does not
 700          ;; contain the new keywords.
 701          (font-lock-update-removed-keyword-alist mode keywords how))
 702         (t
 703          (when (and font-lock-mode
 704                     (not (or font-lock-keywords font-lock-defaults)))
 705            ;; The major mode has not set any keywords, so when we enabled
 706            ;; font-lock-mode it only enabled the font-core.el part, not the
 707            ;; font-lock-mode-internal.  Try again.
 708            (font-lock-mode -1)
 709            (set (make-local-variable 'font-lock-defaults) '(nil t))
 710            (font-lock-mode 1))
 711          ;; Otherwise set or add the keywords now.
 712          ;; This is a no-op if it has been done already in this buffer
 713          ;; for the correct major mode.
 714          (font-lock-set-defaults)
 715          (let ((was-compiled (eq (car font-lock-keywords) t)))
 716            ;; Bring back the user-level (uncompiled) keywords.
 717            (if was-compiled
 718                (setq font-lock-keywords (cadr font-lock-keywords)))
 719            ;; Now modify or replace them.
 720            (if (eq how 'set)
 721                (setq font-lock-keywords keywords)
 722              (font-lock-remove-keywords nil keywords) ;to avoid duplicates
 723              (let ((old (if (eq (car-safe font-lock-keywords) t)
 724                             (cdr font-lock-keywords)
 725                           font-lock-keywords)))
 726                (setq font-lock-keywords (if how
 727                                             (append old keywords)
 728                                           (append keywords old)))))
 729            ;; If the keywords were compiled before, compile them again.
 730            (if was-compiled
 731                (setq font-lock-keywords
 732                      (font-lock-compile-keywords font-lock-keywords)))))))
 733
 734 (defun font-lock-update-removed-keyword-alist (mode keywords how)
 735   "Update `font-lock-removed-keywords-alist' when adding new KEYWORDS to MODE."
 736   ;; When font-lock is enabled first all keywords in the list
 737   ;; `font-lock-keywords-alist' are added, then all keywords in the
 738   ;; list `font-lock-removed-keywords-alist' are removed.  If a
 739   ;; keyword was once added, removed, and then added again it must be
 740   ;; removed from the removed-keywords list.  Otherwise the second add
 741   ;; will not take effect.
 742   (let ((cell (assq mode font-lock-removed-keywords-alist)))
 743     (if cell
 744         (if (eq how 'set)
 745             ;; A new set of keywords is defined.  Forget all about
 746             ;; our old keywords that should be removed.
 747             (setq font-lock-removed-keywords-alist
 748                   (delq cell font-lock-removed-keywords-alist))
 749           ;; Delete all previously removed keywords.
 750           (dolist (kword keywords)
 751             (setcdr cell (delete kword (cdr cell))))
 752           ;; Delete the mode cell if empty.
 753           (if (null (cdr cell))
 754               (setq font-lock-removed-keywords-alist
 755                     (delq cell font-lock-removed-keywords-alist)))))))
 756
 757 ;; Written by Anders Lindgren <andersl@andersl.com>.
 758 ;;
 759 ;; Case study:
 760 ;; (I)  The keywords are removed from a major mode.
 761 ;;      In this case the keyword could be local (i.e. added earlier by
 762 ;;      `font-lock-add-keywords'), global, or both.
 763 ;;
 764 ;;      (a) In the local case we remove the keywords from the variable
 765 ;;          `font-lock-keywords-alist'.
 766 ;;
 767 ;;      (b) The actual global keywords are not known at this time.
 768 ;;          All keywords are added to `font-lock-removed-keywords-alist',
 769 ;;          when font-lock is enabled those keywords are removed.
 770 ;;
 771 ;;      Note that added keywords are taken out of the list of removed
 772 ;;      keywords.  This ensure correct operation when the same keyword
 773 ;;      is added and removed several times.
 774 ;;
 775 ;; (II) The keywords are removed from the current buffer.
 776 (defun font-lock-remove-keywords (mode keywords)
 777   "Remove highlighting KEYWORDS for MODE.
 778
 779 MODE should be a symbol, the major mode command name, such as `c-mode'
 780 or nil.  If nil, highlighting keywords are removed for the current buffer.
 781
 782 To make the removal apply to modes derived from MODE as well,
 783 pass nil for MODE and add the call to MODE-hook.  This may fail
 784 for some derived modes if some involved major mode does not
 785 follow the standard conventions.  File a bug report if this
 786 happens, so the major mode can be corrected."
 787   (cond (mode
 788          ;; Remove one keyword at the time.
 789          (dolist (keyword keywords)
 790            (let ((top-cell (assq mode font-lock-keywords-alist)))
 791              ;; If MODE is non-nil, remove the KEYWORD from
 792              ;; `font-lock-keywords-alist'.
 793              (when top-cell
 794                (dolist (keyword-list-how-pair (cdr top-cell))
 795                  ;; `keywords-list-how-pair' is a cons with a list of
 796                  ;; keywords in the car top-cell and the original how
 797                  ;; argument in the cdr top-cell.
 798                  (setcar keyword-list-how-pair
 799                          (delete keyword (car keyword-list-how-pair))))
 800                ;; Remove keyword list/how pair when the keyword list
 801                ;; is empty and how doesn't specify `set'.  (If it
 802                ;; should be deleted then previously deleted keywords
 803                ;; would appear again.)
 804                (let ((cell top-cell))
 805                  (while (cdr cell)
 806                    (if (and (null (car (car (cdr cell))))
 807                             (not (eq (cdr (car (cdr cell))) 'set)))
 808                        (setcdr cell (cdr (cdr cell)))
 809                      (setq cell (cdr cell)))))
 810                ;; Final cleanup, remove major mode cell if last keyword
 811                ;; was deleted.
 812                (if (null (cdr top-cell))
 813                    (setq font-lock-keywords-alist
 814                          (delq top-cell font-lock-keywords-alist))))
 815              ;; Remember the keyword in case it is not local.
 816              (let ((cell (assq mode font-lock-removed-keywords-alist)))
 817                (if cell
 818                    (unless (member keyword (cdr cell))
 819                      (nconc cell (list keyword)))
 820                  (push (cons mode (list keyword))
 821                        font-lock-removed-keywords-alist))))))
 822         (t
 823          ;; Otherwise remove it immediately.
 824          (font-lock-set-defaults)
 825          (let ((was-compiled (eq (car font-lock-keywords) t)))
 826            ;; Bring back the user-level (uncompiled) keywords.
 827            (if was-compiled
 828                (setq font-lock-keywords (cadr font-lock-keywords)))
 829
 830            ;; Edit them.
 831            (setq font-lock-keywords (copy-sequence font-lock-keywords))
 832            (dolist (keyword keywords)
 833              (setq font-lock-keywords
 834                    (delete keyword font-lock-keywords)))
 835
 836            ;; If the keywords were compiled before, compile them again.
 837            (if was-compiled
 838                (setq font-lock-keywords
 839                      (font-lock-compile-keywords font-lock-keywords)))))))
 840 \f
 841 ;;; Font Lock Support mode.
 842
 843 ;; This is the code used to interface font-lock.el with any of its add-on
 844 ;; packages, and provide the user interface.  Packages that have their own
 845 ;; local buffer fontification functions (see below) may have to call
 846 ;; `font-lock-after-fontify-buffer' and/or `font-lock-after-unfontify-buffer'
 847 ;; themselves.
 848
 849 (defcustom font-lock-support-mode 'jit-lock-mode
 850   "Support mode for Font Lock mode.
 851 Support modes speed up Font Lock mode by being choosy about when fontification
 852 occurs.  The default support mode, Just-in-time Lock mode (symbol
 853 `jit-lock-mode'), is recommended.
 854
 855 Other, older support modes are Fast Lock mode (symbol `fast-lock-mode') and
 856 Lazy Lock mode (symbol `lazy-lock-mode').  See those modes for more info.
 857 However, they are no longer recommended, as Just-in-time Lock mode is better.
 858
 859 If nil, means support for Font Lock mode is never performed.
 860 If a symbol, use that support mode.
 861 If a list, each element should be of the form (MAJOR-MODE . SUPPORT-MODE),
 862 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 863  ((c-mode . fast-lock-mode) (c++-mode . fast-lock-mode) (t . lazy-lock-mode))
 864 means that Fast Lock mode is used to support Font Lock mode for buffers in C or
 865 C++ modes, and Lazy Lock mode is used to support Font Lock mode otherwise.
 866
 867 The value of this variable is used when Font Lock mode is turned on."
 868   :type '(choice (const :tag "none" nil)
 869                  (const :tag "fast lock" fast-lock-mode)
 870                  (const :tag "lazy lock" lazy-lock-mode)
 871                  (const :tag "jit lock" jit-lock-mode)
 872                  (repeat :menu-tag "mode specific" :tag "mode specific"
 873                          :value ((t . jit-lock-mode))
 874                          (cons :tag "Instance"
 875                                (radio :tag "Mode"
 876                                       (const :tag "all" t)
 877                                       (symbol :tag "name"))
 878                                (radio :tag "Support"
 879                                       (const :tag "none" nil)
 880                                       (const :tag "fast lock" fast-lock-mode)
 881                                       (const :tag "lazy lock" lazy-lock-mode)
 882                                       (const :tag "JIT lock" jit-lock-mode)))
 883                          ))
 884   :version "21.1"
 885   :group 'font-lock)
 886
 887 (defvar fast-lock-mode)
 888 (defvar lazy-lock-mode)
 889 (defvar jit-lock-mode)
 890
 891 (declare-function fast-lock-after-fontify-buffer "fast-lock")
 892 (declare-function fast-lock-after-unfontify-buffer "fast-lock")
 893 (declare-function fast-lock-mode "fast-lock")
 894 (declare-function lazy-lock-after-fontify-buffer "lazy-lock")
 895 (declare-function lazy-lock-after-unfontify-buffer "lazy-lock")
 896 (declare-function lazy-lock-mode "lazy-lock")
 897
 898 (defun font-lock-turn-on-thing-lock ()
 899   (case (font-lock-value-in-major-mode font-lock-support-mode)
 900     (fast-lock-mode (fast-lock-mode t))
 901     (lazy-lock-mode (lazy-lock-mode t))
 902     (jit-lock-mode
 903      ;; Prepare for jit-lock
 904      (remove-hook 'after-change-functions
 905                   'font-lock-after-change-function t)
 906      (set (make-local-variable 'font-lock-fontify-buffer-function)
 907           'jit-lock-refontify)
 908      ;; Don't fontify eagerly (and don't abort if the buffer is large).
 909      (set (make-local-variable 'font-lock-fontified) t)
 910      ;; Use jit-lock.
 911      (jit-lock-register 'font-lock-fontify-region
 912                         (not font-lock-keywords-only))
 913      ;; Tell jit-lock how we extend the region to refontify.
 914      (add-hook 'jit-lock-after-change-extend-region-functions
 915                'font-lock-extend-jit-lock-region-after-change
 916                nil t))))
 917
 918 (defun font-lock-turn-off-thing-lock ()
 919   (cond ((bound-and-true-p fast-lock-mode)
 920          (fast-lock-mode -1))
 921         ((bound-and-true-p jit-lock-mode)
 922          (jit-lock-unregister 'font-lock-fontify-region)
 923          ;; Reset local vars to the non-jit-lock case.
 924          (kill-local-variable 'font-lock-fontify-buffer-function))
 925         ((bound-and-true-p lazy-lock-mode)
 926          (lazy-lock-mode -1))))
 927
 928 (defun font-lock-after-fontify-buffer ()
 929   (cond ((bound-and-true-p fast-lock-mode)
 930          (fast-lock-after-fontify-buffer))
 931         ;; Useless now that jit-lock intercepts font-lock-fontify-buffer.  -sm
 932         ;; (jit-lock-mode
 933         ;;  (jit-lock-after-fontify-buffer))
 934         ((bound-and-true-p lazy-lock-mode)
 935          (lazy-lock-after-fontify-buffer))))
 936
 937 (defun font-lock-after-unfontify-buffer ()
 938   (cond ((bound-and-true-p fast-lock-mode)
 939          (fast-lock-after-unfontify-buffer))
 940         ;; Useless as well.  It's only called when:
 941         ;; - turning off font-lock: it does not matter if we leave spurious
 942         ;;   `fontified' text props around since jit-lock-mode is also off.
 943         ;; - font-lock-default-fontify-buffer fails: this is not run
 944         ;;   any more anyway.   -sm
 945         ;;
 946         ;; (jit-lock-mode
 947         ;;  (jit-lock-after-unfontify-buffer))
 948         ((bound-and-true-p lazy-lock-mode)
 949          (lazy-lock-after-unfontify-buffer))))
 950
 951 ;;; End of Font Lock Support mode.
 952 \f
 953 ;;; Fontification functions.
 954
 955 ;; Rather than the function, e.g., `font-lock-fontify-region' containing the
 956 ;; code to fontify a region, the function runs the function whose name is the
 957 ;; value of the variable, e.g., `font-lock-fontify-region-function'.  Normally,
 958 ;; the value of this variable is, e.g., `font-lock-default-fontify-region'
 959 ;; which does contain the code to fontify a region.  However, the value of the
 960 ;; variable could be anything and thus, e.g., `font-lock-fontify-region' could
 961 ;; do anything.  The indirection of the fontification functions gives major
 962 ;; modes the capability of modifying the way font-lock.el fontifies.  Major
 963 ;; modes can modify the values of, e.g., `font-lock-fontify-region-function',
 964 ;; via the variable `font-lock-defaults'.
 965 ;;
 966 ;; For example, Rmail mode sets the variable `font-lock-defaults' so that
 967 ;; font-lock.el uses its own function for buffer fontification.  This function
 968 ;; makes fontification be on a message-by-message basis and so visiting an
 969 ;; RMAIL file is much faster.  A clever implementation of the function might
 970 ;; fontify the headers differently than the message body.  (It should, and
 971 ;; correspondingly for Mail mode, but I can't be bothered to do the work.  Can
 972 ;; you?)  This hints at a more interesting use...
 973 ;;
 974 ;; Languages that contain text normally contained in different major modes
 975 ;; could define their own fontification functions that treat text differently
 976 ;; depending on its context.  For example, Perl mode could arrange that here
 977 ;; docs are fontified differently than Perl code.  Or Yacc mode could fontify
 978 ;; rules one way and C code another.  Neat!
 979 ;;
 980 ;; A further reason to use the fontification indirection feature is when the
 981 ;; default syntactual fontification, or the default fontification in general,
 982 ;; is not flexible enough for a particular major mode.  For example, perhaps
 983 ;; comments are just too hairy for `font-lock-fontify-syntactically-region' to
 984 ;; cope with.  You need to write your own version of that function, e.g.,
 985 ;; `hairy-fontify-syntactically-region', and make your own version of
 986 ;; `hairy-fontify-region' call that function before calling
 987 ;; `font-lock-fontify-keywords-region' for the normal regexp fontification
 988 ;; pass.  And Hairy mode would set `font-lock-defaults' so that font-lock.el
 989 ;; would call your region fontification function instead of its own.  For
 990 ;; example, TeX modes could fontify {\foo ...} and \bar{...}  etc. multi-line
 991 ;; directives correctly and cleanly.  (It is the same problem as fontifying
 992 ;; multi-line strings and comments; regexps are not appropriate for the job.)
 993
 994 (defvar font-lock-extend-after-change-region-function nil
 995   "A function that determines the region to refontify after a change.
 996
 997 This variable is either nil, or is a function that determines the
 998 region to refontify after a change.
 999 It is usually set by the major mode via `font-lock-defaults'.
1000 Font-lock calls this function after each buffer change.
1001
1002 The function is given three parameters, the standard BEG, END, and OLD-LEN
1003 from `after-change-functions'.  It should return either a cons of the beginning
1004 and end buffer positions \(in that order) of the region to refontify, or nil
1005 \(which directs the caller to fontify a default region).
1006 This function should preserve the match-data.
1007 The region it returns may start or end in the middle of a line.")
1008 (make-variable-buffer-local 'font-lock-extend-after-change-region-function)
1009
1010 (defun font-lock-fontify-buffer ()
1011   "Fontify the current buffer the way the function `font-lock-mode' would."
1012   (interactive)
1013   (font-lock-set-defaults)
1014   (let ((font-lock-verbose (or font-lock-verbose
1015                                (called-interactively-p 'interactive))))
1016     (funcall font-lock-fontify-buffer-function)))
1017
1018 (defun font-lock-unfontify-buffer ()
1019   (funcall font-lock-unfontify-buffer-function))
1020
1021 (defun font-lock-fontify-region (beg end &optional loudly)
1022   (font-lock-set-defaults)
1023   (funcall font-lock-fontify-region-function beg end loudly))
1024
1025 (defun font-lock-unfontify-region (beg end)
1026   (save-buffer-state
1027     (funcall font-lock-unfontify-region-function beg end)))
1028
1029 (defun font-lock-default-fontify-buffer ()
1030   (let ((verbose (if (numberp font-lock-verbose)
1031                      (> (buffer-size) font-lock-verbose)
1032                    font-lock-verbose)))
1033     (with-temp-message
1034         (when verbose
1035           (format "Fontifying %s..." (buffer-name)))
1036       ;; Make sure we fontify etc. in the whole buffer.
1037       (save-restriction
1038         (widen)
1039         (condition-case nil
1040             (save-excursion
1041               (save-match-data
1042                 (font-lock-fontify-region (point-min) (point-max) verbose)
1043                 (font-lock-after-fontify-buffer)
1044                 (setq font-lock-fontified t)))
1045           ;; We don't restore the old fontification, so it's best to unfontify.
1046           (quit (font-lock-unfontify-buffer)))))))
1047
1048 (defun font-lock-default-unfontify-buffer ()
1049   ;; Make sure we unfontify etc. in the whole buffer.
1050   (save-restriction
1051     (widen)
1052     (font-lock-unfontify-region (point-min) (point-max))
1053     (font-lock-after-unfontify-buffer)
1054     (setq font-lock-fontified nil)))
1055
1056 (defvar font-lock-dont-widen nil
1057   "If non-nil, font-lock will work on the non-widened buffer.
1058 Useful for things like RMAIL and Info where the whole buffer is not
1059 a very meaningful entity to highlight.")
1060
1061
1062 (defvar font-lock-beg) (defvar font-lock-end)
1063 (defvar font-lock-extend-region-functions
1064   '(font-lock-extend-region-wholelines
1065     ;; This use of font-lock-multiline property is unreliable but is just
1066     ;; a handy heuristic: in case you don't have a function that does
1067     ;; /identification/ of multiline elements, you may still occasionally
1068     ;; discover them by accident (or you may /identify/ them but not in all
1069     ;; cases), in which case the font-lock-multiline property can help make
1070     ;; sure you will properly *re*identify them during refontification.
1071     font-lock-extend-region-multiline)
1072   "Special hook run just before proceeding to fontify a region.
1073 This is used to allow major modes to help font-lock find safe buffer positions
1074 as beginning and end of the fontified region.  Its most common use is to solve
1075 the problem of /identification/ of multiline elements by providing a function
1076 that tries to find such elements and move the boundaries such that they do
1077 not fall in the middle of one.
1078 Each function is called with no argument; it is expected to adjust the
1079 dynamically bound variables `font-lock-beg' and `font-lock-end'; and return
1080 non-nil if it did make such an adjustment.
1081 These functions are run in turn repeatedly until they all return nil.
1082 Put first the functions more likely to cause a change and cheaper to compute.")
1083 ;; Mark it as a special hook which doesn't use any global setting
1084 ;; (i.e. doesn't obey the element t in the buffer-local value).
1085 (make-variable-buffer-local 'font-lock-extend-region-functions)
1086
1087 (defun font-lock-extend-region-multiline ()
1088   "Move fontification boundaries away from any `font-lock-multiline' property."
1089   (let ((changed nil))
1090     (when (and (> font-lock-beg (point-min))
1091                (get-text-property (1- font-lock-beg) 'font-lock-multiline))
1092       (setq changed t)
1093       (setq font-lock-beg (or (previous-single-property-change
1094                                font-lock-beg 'font-lock-multiline)
1095                               (point-min))))
1096     ;;
1097     (when (get-text-property font-lock-end 'font-lock-multiline)
1098       (setq changed t)
1099       (setq font-lock-end (or (text-property-any font-lock-end (point-max)
1100                                                  'font-lock-multiline nil)
1101                               (point-max))))
1102     changed))
1103
1104 (defun font-lock-extend-region-wholelines ()
1105   "Move fontification boundaries to beginning of lines."
1106   (let ((changed nil))
1107     (goto-char font-lock-beg)
1108     (unless (bolp)
1109       (setq changed t font-lock-beg (line-beginning-position)))
1110     (goto-char font-lock-end)
1111     (unless (bolp)
1112       (unless (eq font-lock-end
1113                   (setq font-lock-end (line-beginning-position 2)))
1114         (setq changed t)))
1115     changed))
1116
1117 (defun font-lock-default-fontify-region (beg end loudly)
1118   (save-buffer-state
1119     ;; Use the fontification syntax table, if any.
1120     (with-syntax-table (or font-lock-syntax-table (syntax-table))
1121       (save-restriction
1122         (unless font-lock-dont-widen (widen))
1123         ;; Extend the region to fontify so that it starts and ends at
1124         ;; safe places.
1125         (let ((funs font-lock-extend-region-functions)
1126               (font-lock-beg beg)
1127               (font-lock-end end))
1128           (while funs
1129             (setq funs (if (or (not (funcall (car funs)))
1130                                (eq funs font-lock-extend-region-functions))
1131                            (cdr funs)
1132                          ;; If there's been a change, we should go through
1133                          ;; the list again since this new position may
1134                          ;; warrant a different answer from one of the fun
1135                          ;; we've already seen.
1136                          font-lock-extend-region-functions)))
1137           (setq beg font-lock-beg end font-lock-end))
1138         ;; Now do the fontification.
1139         (font-lock-unfontify-region beg end)
1140         (when (and font-lock-syntactic-keywords
1141                    (null syntax-propertize-function))
1142           ;; Ensure the beginning of the file is properly syntactic-fontified.
1143           (let ((start beg))
1144             (when (< font-lock-syntactically-fontified start)
1145               (setq start (max font-lock-syntactically-fontified (point-min)))
1146               (setq font-lock-syntactically-fontified end))
1147             (font-lock-fontify-syntactic-keywords-region start end)))
1148         (unless font-lock-keywords-only
1149           (font-lock-fontify-syntactically-region beg end loudly))
1150         (font-lock-fontify-keywords-region beg end loudly)))))
1151
1152 ;; The following must be rethought, since keywords can override fontification.
1153 ;;    ;; Now scan for keywords, but not if we are inside a comment now.
1154 ;;    (or (and (not font-lock-keywords-only)
1155 ;;             (let ((state (parse-partial-sexp beg end nil nil
1156 ;;                                              font-lock-cache-state)))
1157 ;;               (or (nth 4 state) (nth 7 state))))
1158 ;;        (font-lock-fontify-keywords-region beg end))
1159
1160 (defvar font-lock-extra-managed-props nil
1161   "Additional text properties managed by font-lock.
1162 This is used by `font-lock-default-unfontify-region' to decide
1163 what properties to clear before refontifying a region.")
1164
1165 (defun font-lock-default-unfontify-region (beg end)
1166   (remove-list-of-text-properties
1167    beg end (append
1168             font-lock-extra-managed-props
1169             (if font-lock-syntactic-keywords
1170                 '(syntax-table face font-lock-multiline)
1171               '(face font-lock-multiline)))))
1172
1173 ;; Called when any modification is made to buffer text.
1174 (defun font-lock-after-change-function (beg end old-len)
1175   (save-excursion
1176     (let ((inhibit-point-motion-hooks t)
1177           (inhibit-quit t)
1178           (region (if font-lock-extend-after-change-region-function
1179                       (funcall font-lock-extend-after-change-region-function
1180                                beg end old-len))))
1181       (save-match-data
1182         (if region
1183             ;; Fontify the region the major mode has specified.
1184             (setq beg (car region) end (cdr region))
1185           ;; Fontify the whole lines which enclose the region.
1186           ;; Actually, this is not needed because
1187           ;; font-lock-default-fontify-region already rounds up to a whole
1188           ;; number of lines.
1189           ;; (setq beg (progn (goto-char beg) (line-beginning-position))
1190           ;;       end (progn (goto-char end) (line-beginning-position 2)))
1191           (unless (eq end (point-max))
1192             ;; Rounding up to a whole number of lines should include the
1193             ;; line right after `end'.  Typical case: the first char of
1194             ;; the line was deleted.  Or a \n was inserted in the middle
1195             ;; of a line.
1196             (setq end (1+ end))))
1197         (font-lock-fontify-region beg end)))))
1198
1199 (defvar jit-lock-start) (defvar jit-lock-end)
1200 (defun font-lock-extend-jit-lock-region-after-change (beg end old-len)
1201   "Function meant for `jit-lock-after-change-extend-region-functions'.
1202 This function does 2 things:
1203 - extend the region so that it not only includes the part that was modified
1204   but also the surrounding text whose highlighting may change as a consequence.
1205 - anticipate (part of) the region extension that will happen later in
1206   `font-lock-default-fontify-region', in order to avoid the need for
1207   double-redisplay in `jit-lock-fontify-now'."
1208   (save-excursion
1209     ;; First extend the region as font-lock-after-change-function would.
1210     (let ((region (if font-lock-extend-after-change-region-function
1211                       (funcall font-lock-extend-after-change-region-function
1212                                beg end old-len))))
1213       (if region
1214           (setq beg (min jit-lock-start (car region))
1215                 end (max jit-lock-end (cdr region))))
1216       ;; Then extend the region obeying font-lock-multiline properties,
1217       ;; indicating which part of the buffer needs to be refontified.
1218       ;; !!! This is the *main* user of font-lock-multiline property !!!
1219       ;; font-lock-after-change-function could/should also do that, but it
1220       ;; doesn't need to because font-lock-default-fontify-region does
1221       ;; it anyway.  Here OTOH we have no guarantee that
1222       ;; font-lock-default-fontify-region will be executed on this region
1223       ;; any time soon.
1224       ;; Note: contrary to font-lock-default-fontify-region, we do not do
1225       ;; any loop here because we are not looking for a safe spot: we just
1226       ;; mark the text whose appearance may need to change as a result of
1227       ;; the buffer modification.
1228       (when (and (> beg (point-min))
1229                  (get-text-property (1- beg) 'font-lock-multiline))
1230         (setq beg (or (previous-single-property-change
1231                        beg 'font-lock-multiline)
1232                       (point-min))))
1233       (when (< end (point-max))
1234         (setq end
1235               (if (get-text-property end 'font-lock-multiline)
1236                   (or (text-property-any end (point-max)
1237                                          'font-lock-multiline nil)
1238                       (point-max))
1239                 ;; Rounding up to a whole number of lines should include the
1240                 ;; line right after `end'.  Typical case: the first char of
1241                 ;; the line was deleted.  Or a \n was inserted in the middle
1242                 ;; of a line.
1243                 (1+ end))))
1244       ;; Finally, pre-enlarge the region to a whole number of lines, to try
1245       ;; and anticipate what font-lock-default-fontify-region will do, so as to
1246       ;; avoid double-redisplay.
1247       ;; We could just run `font-lock-extend-region-functions', but since
1248       ;; the only purpose is to avoid the double-redisplay, we prefer to
1249       ;; do here only the part that is cheap and most likely to be useful.
1250       (when (memq 'font-lock-extend-region-wholelines
1251                   font-lock-extend-region-functions)
1252         (goto-char beg)
1253         (setq jit-lock-start (min jit-lock-start (line-beginning-position)))
1254         (goto-char end)
1255         (setq jit-lock-end
1256               (max jit-lock-end
1257                    (if (bolp) (point) (line-beginning-position 2))))))))
1258
1259 (defun font-lock-fontify-block (&optional arg)
1260   "Fontify some lines the way `font-lock-fontify-buffer' would.
1261 The lines could be a function or paragraph, or a specified number of lines.
1262 If ARG is given, fontify that many lines before and after point, or 16 lines if
1263 no ARG is given and `font-lock-mark-block-function' is nil.
1264 If `font-lock-mark-block-function' non-nil and no ARG is given, it is used to
1265 delimit the region to fontify."
1266   (interactive "P")
1267   (let ((inhibit-point-motion-hooks t) font-lock-beginning-of-syntax-function
1268         deactivate-mark)
1269     ;; Make sure we have the right `font-lock-keywords' etc.
1270     (if (not font-lock-mode) (font-lock-set-defaults))
1271     (save-excursion
1272       (save-match-data
1273         (condition-case error-data
1274             (if (or arg (not font-lock-mark-block-function))
1275                 (let ((lines (if arg (prefix-numeric-value arg) 16)))
1276                   (font-lock-fontify-region
1277                    (save-excursion (forward-line (- lines)) (point))
1278                    (save-excursion (forward-line lines) (point))))
1279               (funcall font-lock-mark-block-function)
1280               (font-lock-fontify-region (point) (mark)))
1281           ((error quit) (message "Fontifying block...%s" error-data)))))))
1282
1283 ;;; End of Fontification functions.
1284 \f
1285 ;;; Additional text property functions.
1286
1287 ;; The following text property functions should be builtins.  This means they
1288 ;; should be written in C and put with all the other text property functions.
1289 ;; In the meantime, those that are used by font-lock.el are defined in Lisp
1290 ;; below and given a `font-lock-' prefix.  Those that are not used are defined
1291 ;; in Lisp below and commented out.  sm.
1292
1293 (defun font-lock-prepend-text-property (start end prop value &optional object)
1294   "Prepend to one property of the text from START to END.
1295 Arguments PROP and VALUE specify the property and value to prepend to the value
1296 already in place.  The resulting property values are always lists.
1297 Optional argument OBJECT is the string or buffer containing the text."
1298   (let ((val (if (listp value) value (list value))) next prev)
1299     (while (/= start end)
1300       (setq next (next-single-property-change start prop object end)
1301             prev (get-text-property start prop object))
1302       ;; Canonicalize old forms of face property.
1303       (and (memq prop '(face font-lock-face))
1304            (listp prev)
1305            (or (keywordp (car prev))
1306                (memq (car prev) '(foreground-color background-color)))
1307            (setq prev (list prev)))
1308       (put-text-property start next prop
1309                          (append val (if (listp prev) prev (list prev)))
1310                          object)
1311       (setq start next))))
1312
1313 (defun font-lock-append-text-property (start end prop value &optional object)
1314   "Append to one property of the text from START to END.
1315 Arguments PROP and VALUE specify the property and value to append to the value
1316 already in place.  The resulting property values are always lists.
1317 Optional argument OBJECT is the string or buffer containing the text."
1318   (let ((val (if (listp value) value (list value))) next prev)
1319     (while (/= start end)
1320       (setq next (next-single-property-change start prop object end)
1321             prev (get-text-property start prop object))
1322       ;; Canonicalize old forms of face property.
1323       (and (memq prop '(face font-lock-face))
1324            (listp prev)
1325            (or (keywordp (car prev))
1326                (memq (car prev) '(foreground-color background-color)))
1327            (setq prev (list prev)))
1328       (put-text-property start next prop
1329                          (append (if (listp prev) prev (list prev)) val)
1330                          object)
1331       (setq start next))))
1332
1333 (defun font-lock-fillin-text-property (start end prop value &optional object)
1334   "Fill in one property of the text from START to END.
1335 Arguments PROP and VALUE specify the property and value to put where none are
1336 already in place.  Therefore existing property values are not overwritten.
1337 Optional argument OBJECT is the string or buffer containing the text."
1338   (let ((start (text-property-any start end prop nil object)) next)
1339     (while start
1340       (setq next (next-single-property-change start prop object end))
1341       (put-text-property start next prop value object)
1342       (setq start (text-property-any next end prop nil object)))))
1343
1344 ;; For completeness: this is to `remove-text-properties' as `put-text-property'
1345 ;; is to `add-text-properties', etc.
1346 ;;(defun remove-text-property (start end property &optional object)
1347 ;;  "Remove a property from text from START to END.
1348 ;;Argument PROPERTY is the property to remove.
1349 ;;Optional argument OBJECT is the string or buffer containing the text.
1350 ;;Return t if the property was actually removed, nil otherwise."
1351 ;;  (remove-text-properties start end (list property) object))
1352
1353 ;; For consistency: maybe this should be called `remove-single-property' like
1354 ;; `next-single-property-change' (not `next-single-text-property-change'), etc.
1355 ;;(defun remove-single-text-property (start end prop value &optional object)
1356 ;;  "Remove a specific property value from text from START to END.
1357 ;;Arguments PROP and VALUE specify the property and value to remove.  The
1358 ;;resulting property values are not equal to VALUE nor lists containing VALUE.
1359 ;;Optional argument OBJECT is the string or buffer containing the text."
1360 ;;  (let ((start (text-property-not-all start end prop nil object)) next prev)
1361 ;;    (while start
1362 ;;      (setq next (next-single-property-change start prop object end)
1363 ;;          prev (get-text-property start prop object))
1364 ;;      (cond ((and (symbolp prev) (eq value prev))
1365 ;;           (remove-text-property start next prop object))
1366 ;;          ((and (listp prev) (memq value prev))
1367 ;;           (let ((new (delq value prev)))
1368 ;;             (cond ((null new)
1369 ;;                    (remove-text-property start next prop object))
1370 ;;                   ((= (length new) 1)
1371 ;;                    (put-text-property start next prop (car new) object))
1372 ;;                   (t
1373 ;;                    (put-text-property start next prop new object))))))
1374 ;;      (setq start (text-property-not-all next end prop nil object)))))
1375
1376 ;;; End of Additional text property functions.
1377 \f
1378 ;;; Syntactic regexp fontification functions.
1379
1380 ;; These syntactic keyword pass functions are identical to those keyword pass
1381 ;; functions below, with the following exceptions; (a) they operate on
1382 ;; `font-lock-syntactic-keywords' of course, (b) they are all `defun' as speed
1383 ;; is less of an issue, (c) eval of property value does not occur JIT as speed
1384 ;; is less of an issue, (d) OVERRIDE cannot be `prepend' or `append' as it
1385 ;; makes no sense for `syntax-table' property values, (e) they do not do it
1386 ;; LOUDLY as it is not likely to be intensive.
1387
1388 (defun font-lock-apply-syntactic-highlight (highlight)
1389   "Apply HIGHLIGHT following a match.
1390 HIGHLIGHT should be of the form MATCH-HIGHLIGHT,
1391 see `font-lock-syntactic-keywords'."
1392   (let* ((match (nth 0 highlight))
1393          (start (match-beginning match)) (end (match-end match))
1394          (value (nth 1 highlight))
1395          (override (nth 2 highlight)))
1396     (if (not start)
1397         ;; No match but we might not signal an error.
1398         (or (nth 3 highlight)
1399             (error "No match %d in highlight %S" match highlight))
1400       (when (and (consp value) (not (numberp (car value))))
1401         (setq value (eval value)))
1402       (when (stringp value) (setq value (string-to-syntax value)))
1403       ;; Flush the syntax-cache.  I believe this is not necessary for
1404       ;; font-lock's use of syntax-ppss, but I'm not 100% sure and it can
1405       ;; still be necessary for other users of syntax-ppss anyway.
1406       (syntax-ppss-after-change-function start)
1407       (cond
1408        ((not override)
1409         ;; Cannot override existing fontification.
1410         (or (text-property-not-all start end 'syntax-table nil)
1411             (put-text-property start end 'syntax-table value)))
1412        ((eq override t)
1413         ;; Override existing fontification.
1414         (put-text-property start end 'syntax-table value))
1415        ((eq override 'keep)
1416         ;; Keep existing fontification.
1417         (font-lock-fillin-text-property start end 'syntax-table value))))))
1418
1419 (defun font-lock-fontify-syntactic-anchored-keywords (keywords limit)
1420   "Fontify according to KEYWORDS until LIMIT.
1421 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1422 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1423   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1424         ;; Evaluate PRE-MATCH-FORM.
1425         (pre-match-value (eval (nth 1 keywords))))
1426     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1427     (if (and (numberp pre-match-value) (> pre-match-value (point)))
1428         (setq limit pre-match-value)
1429       (setq limit (line-end-position)))
1430     (save-match-data
1431       ;; Find an occurrence of `matcher' before `limit'.
1432       (while (if (stringp matcher)
1433                  (re-search-forward matcher limit t)
1434                (funcall matcher limit))
1435         ;; Apply each highlight to this instance of `matcher'.
1436         (setq highlights lowdarks)
1437         (while highlights
1438           (font-lock-apply-syntactic-highlight (car highlights))
1439           (setq highlights (cdr highlights)))))
1440     ;; Evaluate POST-MATCH-FORM.
1441     (eval (nth 2 keywords))))
1442
1443 (defun font-lock-fontify-syntactic-keywords-region (start end)
1444   "Fontify according to `font-lock-syntactic-keywords' between START and END.
1445 START should be at the beginning of a line."
1446   (unless parse-sexp-lookup-properties
1447     ;; We wouldn't go through so much trouble if we didn't intend to use those
1448     ;; properties, would we?
1449     (set (make-local-variable 'parse-sexp-lookup-properties) t))
1450   ;; If `font-lock-syntactic-keywords' is a symbol, get the real keywords.
1451   (when (symbolp font-lock-syntactic-keywords)
1452     (setq font-lock-syntactic-keywords (font-lock-eval-keywords
1453                                         font-lock-syntactic-keywords)))
1454   ;; If `font-lock-syntactic-keywords' is not compiled, compile it.
1455   (unless (eq (car font-lock-syntactic-keywords) t)
1456     (setq font-lock-syntactic-keywords (font-lock-compile-keywords
1457                                         font-lock-syntactic-keywords
1458                                         t)))
1459   ;; Get down to business.
1460   (let ((case-fold-search font-lock-keywords-case-fold-search)
1461         (keywords (cddr font-lock-syntactic-keywords))
1462         keyword matcher highlights)
1463     (while keywords
1464       ;; Find an occurrence of `matcher' from `start' to `end'.
1465       (setq keyword (car keywords) matcher (car keyword))
1466       (goto-char start)
1467       (while (and (< (point) end)
1468                   (if (stringp matcher)
1469                       (re-search-forward matcher end t)
1470                     (funcall matcher end)))
1471         ;; Apply each highlight to this instance of `matcher', which may be
1472         ;; specific highlights or more keywords anchored to `matcher'.
1473         (setq highlights (cdr keyword))
1474         (while highlights
1475           (if (numberp (car (car highlights)))
1476               (font-lock-apply-syntactic-highlight (car highlights))
1477             (font-lock-fontify-syntactic-anchored-keywords (car highlights)
1478                                                            end))
1479           (setq highlights (cdr highlights))))
1480       (setq keywords (cdr keywords)))))
1481
1482 ;;; End of Syntactic regexp fontification functions.
1483 \f
1484 ;;; Syntactic fontification functions.
1485
1486 (defvar font-lock-comment-start-skip nil
1487   "If non-nil, Font Lock mode uses this instead of `comment-start-skip'.")
1488
1489 (defvar font-lock-comment-end-skip nil
1490   "If non-nil, Font Lock mode uses this instead of `comment-end'.")
1491
1492 (defun font-lock-fontify-syntactically-region (start end &optional loudly)
1493   "Put proper face on each string and comment between START and END.
1494 START should be at the beginning of a line."
1495   (syntax-propertize end)  ; Apply any needed syntax-table properties.
1496   (let ((comment-end-regexp
1497          (or font-lock-comment-end-skip
1498              (regexp-quote
1499               (replace-regexp-in-string "^ *" "" comment-end))))
1500         ;; Find the `start' state.
1501         (state (syntax-ppss start))
1502         face beg)
1503     (if loudly (message "Fontifying %s... (syntactically...)" (buffer-name)))
1504     ;;
1505     ;; Find each interesting place between here and `end'.
1506     (while
1507         (progn
1508           (when (or (nth 3 state) (nth 4 state))
1509             (setq face (funcall font-lock-syntactic-face-function state))
1510             (setq beg (max (nth 8 state) start))
1511             (setq state (parse-partial-sexp (point) end nil nil state
1512                                             'syntax-table))
1513             (when face (put-text-property beg (point) 'face face))
1514             (when (and (eq face 'font-lock-comment-face)
1515                        (or font-lock-comment-start-skip
1516                            comment-start-skip))
1517               ;; Find the comment delimiters
1518               ;; and use font-lock-comment-delimiter-face for them.
1519               (save-excursion
1520                 (goto-char beg)
1521                 (if (looking-at (or font-lock-comment-start-skip
1522                                     comment-start-skip))
1523                     (put-text-property beg (match-end 0) 'face
1524                                        font-lock-comment-delimiter-face)))
1525               (if (looking-back comment-end-regexp (point-at-bol) t)
1526                   (put-text-property (match-beginning 0) (point) 'face
1527                                      font-lock-comment-delimiter-face))))
1528           (< (point) end))
1529       (setq state (parse-partial-sexp (point) end nil nil state
1530                                       'syntax-table)))))
1531
1532 ;;; End of Syntactic fontification functions.
1533 \f
1534 ;;; Keyword regexp fontification functions.
1535
1536 (defsubst font-lock-apply-highlight (highlight)
1537   "Apply HIGHLIGHT following a match.
1538 HIGHLIGHT should be of the form MATCH-HIGHLIGHT, see `font-lock-keywords'."
1539   (let* ((match (nth 0 highlight))
1540          (start (match-beginning match)) (end (match-end match))
1541          (override (nth 2 highlight)))
1542     (if (not start)
1543         ;; No match but we might not signal an error.
1544         (or (nth 3 highlight)
1545             (error "No match %d in highlight %S" match highlight))
1546       (let ((val (eval (nth 1 highlight))))
1547         (when (eq (car-safe val) 'face)
1548           (add-text-properties start end (cddr val))
1549           (setq val (cadr val)))
1550         (cond
1551          ((not (or val (eq override t)))
1552           ;; If `val' is nil, don't do anything.  It is important to do it
1553           ;; explicitly, because when adding nil via things like
1554           ;; font-lock-append-text-property, the property is actually
1555           ;; changed from <face> to (<face>) which is undesirable.  --Stef
1556           nil)
1557          ((not override)
1558           ;; Cannot override existing fontification.
1559           (or (text-property-not-all start end 'face nil)
1560               (put-text-property start end 'face val)))
1561          ((eq override t)
1562           ;; Override existing fontification.
1563           (put-text-property start end 'face val))
1564          ((eq override 'prepend)
1565           ;; Prepend to existing fontification.
1566           (font-lock-prepend-text-property start end 'face val))
1567          ((eq override 'append)
1568           ;; Append to existing fontification.
1569           (font-lock-append-text-property start end 'face val))
1570          ((eq override 'keep)
1571           ;; Keep existing fontification.
1572           (font-lock-fillin-text-property start end 'face val)))))))
1573
1574 (defsubst font-lock-fontify-anchored-keywords (keywords limit)
1575   "Fontify according to KEYWORDS until LIMIT.
1576 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1577 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1578   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1579         (lead-start (match-beginning 0))
1580         ;; Evaluate PRE-MATCH-FORM.
1581         (pre-match-value (eval (nth 1 keywords))))
1582     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1583     (if (not (and (numberp pre-match-value) (> pre-match-value (point))))
1584         (setq limit (line-end-position))
1585       (setq limit pre-match-value)
1586       (when (and font-lock-multiline (>= limit (line-beginning-position 2)))
1587         ;; this is a multiline anchored match
1588         ;; (setq font-lock-multiline t)
1589         (put-text-property (if (= limit (line-beginning-position 2))
1590                                (1- limit)
1591                              (min lead-start (point)))
1592                            limit
1593                            'font-lock-multiline t)))
1594     (save-match-data
1595       ;; Find an occurrence of `matcher' before `limit'.
1596       (while (and (< (point) limit)
1597                   (if (stringp matcher)
1598                       (re-search-forward matcher limit t)
1599                     (funcall matcher limit)))
1600         ;; Apply each highlight to this instance of `matcher'.
1601         (setq highlights lowdarks)
1602         (while highlights
1603           (font-lock-apply-highlight (car highlights))
1604           (setq highlights (cdr highlights)))))
1605     ;; Evaluate POST-MATCH-FORM.
1606     (eval (nth 2 keywords))))
1607
1608 (defun font-lock-fontify-keywords-region (start end &optional loudly)
1609   "Fontify according to `font-lock-keywords' between START and END.
1610 START should be at the beginning of a line.
1611 LOUDLY, if non-nil, allows progress-meter bar."
1612   (unless (eq (car font-lock-keywords) t)
1613     (setq font-lock-keywords
1614           (font-lock-compile-keywords font-lock-keywords)))
1615   (let ((case-fold-search font-lock-keywords-case-fold-search)
1616         (keywords (cddr font-lock-keywords))
1617         (bufname (buffer-name)) (count 0)
1618         (pos (make-marker))
1619         keyword matcher highlights)
1620     ;;
1621     ;; Fontify each item in `font-lock-keywords' from `start' to `end'.
1622     (while keywords
1623       (if loudly (message "Fontifying %s... (regexps..%s)" bufname
1624                           (make-string (incf count) ?.)))
1625       ;;
1626       ;; Find an occurrence of `matcher' from `start' to `end'.
1627       (setq keyword (car keywords) matcher (car keyword))
1628       (goto-char start)
1629       (while (and (< (point) end)
1630                   (if (stringp matcher)
1631                       (re-search-forward matcher end t)
1632                     (funcall matcher end))
1633                   ;; Beware empty string matches since they will
1634                   ;; loop indefinitely.
1635                   (or (> (point) (match-beginning 0))
1636                       (progn (forward-char 1) t)))
1637         (when (and font-lock-multiline
1638                    (>= (point)
1639                        (save-excursion (goto-char (match-beginning 0))
1640                                        (forward-line 1) (point))))
1641           ;; this is a multiline regexp match
1642           ;; (setq font-lock-multiline t)
1643           (put-text-property (if (= (point)
1644                                     (save-excursion
1645                                       (goto-char (match-beginning 0))
1646                                       (forward-line 1) (point)))
1647                                  (1- (point))
1648                                (match-beginning 0))
1649                              (point)
1650                              'font-lock-multiline t))
1651         ;; Apply each highlight to this instance of `matcher', which may be
1652         ;; specific highlights or more keywords anchored to `matcher'.
1653         (setq highlights (cdr keyword))
1654         (while highlights
1655           (if (numberp (car (car highlights)))
1656               (font-lock-apply-highlight (car highlights))
1657             (set-marker pos (point))
1658             (font-lock-fontify-anchored-keywords (car highlights) end)
1659             ;; Ensure forward progress.  `pos' is a marker because anchored
1660             ;; keyword may add/delete text (this happens e.g. in grep.el).
1661             (if (< (point) pos) (goto-char pos)))
1662           (setq highlights (cdr highlights))))
1663       (setq keywords (cdr keywords)))
1664     (set-marker pos nil)))
1665
1666 ;;; End of Keyword regexp fontification functions.
1667 \f
1668 ;; Various functions.
1669
1670 (defun font-lock-compile-keywords (keywords &optional syntactic-keywords)
1671   "Compile KEYWORDS into the form (t KEYWORDS COMPILED...)
1672 Here each COMPILED is of the form (MATCHER HIGHLIGHT ...) as shown in the
1673 `font-lock-keywords' doc string.
1674 If SYNTACTIC-KEYWORDS is non-nil, it means these keywords are used for
1675 `font-lock-syntactic-keywords' rather than for `font-lock-keywords'."
1676   (if (not font-lock-set-defaults)
1677       ;; This should never happen.  But some external packages sometimes
1678       ;; call font-lock in unexpected and incorrect ways.  It's important to
1679       ;; stop processing at this point, otherwise we may end up changing the
1680       ;; global value of font-lock-keywords and break highlighting in many
1681       ;; other buffers.
1682       (error "Font-lock trying to use keywords before setting them up"))
1683   (if (eq (car-safe keywords) t)
1684       keywords
1685     (setq keywords
1686           (cons t (cons keywords
1687                         (mapcar 'font-lock-compile-keyword keywords))))
1688     (if (and (not syntactic-keywords)
1689              (let ((beg-function
1690                     (or font-lock-beginning-of-syntax-function
1691                         syntax-begin-function)))
1692                (or (eq beg-function 'beginning-of-defun)
1693                    (get beg-function 'font-lock-syntax-paren-check)))
1694              (not beginning-of-defun-function))
1695         ;; Try to detect when a string or comment contains something that
1696         ;; looks like a defun and would thus confuse font-lock.
1697         (nconc keywords
1698                `((,(if defun-prompt-regexp
1699                        (concat "^\\(?:" defun-prompt-regexp "\\)?\\s(")
1700                      "^\\s(")
1701                   (0
1702                    (if (memq (get-text-property (match-beginning 0) 'face)
1703                              '(font-lock-string-face font-lock-doc-face
1704                                font-lock-comment-face))
1705                        (list 'face font-lock-warning-face
1706                              'help-echo "Looks like a toplevel defun: escape the parenthesis"))
1707                    prepend)))))
1708     keywords))
1709
1710 (defun font-lock-compile-keyword (keyword)
1711   (cond ((nlistp keyword)                       ; MATCHER
1712          (list keyword '(0 font-lock-keyword-face)))
1713         ((eq (car keyword) 'eval)               ; (eval . FORM)
1714          (font-lock-compile-keyword (eval (cdr keyword))))
1715         ((eq (car-safe (cdr keyword)) 'quote)   ; (MATCHER . 'FORM)
1716          ;; If FORM is a FACENAME then quote it.  Otherwise ignore the quote.
1717          (if (symbolp (nth 2 keyword))
1718              (list (car keyword) (list 0 (cdr keyword)))
1719            (font-lock-compile-keyword (cons (car keyword) (nth 2 keyword)))))
1720         ((numberp (cdr keyword))                ; (MATCHER . MATCH)
1721          (list (car keyword) (list (cdr keyword) 'font-lock-keyword-face)))
1722         ((symbolp (cdr keyword))                ; (MATCHER . FACENAME)
1723          (list (car keyword) (list 0 (cdr keyword))))
1724         ((nlistp (nth 1 keyword))               ; (MATCHER . HIGHLIGHT)
1725          (list (car keyword) (cdr keyword)))
1726         (t                                      ; (MATCHER HIGHLIGHT ...)
1727          keyword)))
1728
1729 (defun font-lock-eval-keywords (keywords)
1730   "Evalulate KEYWORDS if a function (funcall) or variable (eval) name."
1731   (if (listp keywords)
1732       keywords
1733     (font-lock-eval-keywords (if (fboundp keywords)
1734                                  (funcall keywords)
1735                                (eval keywords)))))
1736
1737 (defun font-lock-value-in-major-mode (alist)
1738   "Return value in ALIST for `major-mode', or ALIST if it is not an alist.
1739 Structure is ((MAJOR-MODE . VALUE) ...) where MAJOR-MODE may be t."
1740   (if (consp alist)
1741       (cdr (or (assq major-mode alist) (assq t alist)))
1742     alist))
1743
1744 (defun font-lock-choose-keywords (keywords level)
1745   "Return LEVELth element of KEYWORDS.
1746 A LEVEL of nil is equal to a LEVEL of 0, a LEVEL of t is equal to
1747 \(1- (length KEYWORDS))."
1748   (cond ((not (and (listp keywords) (symbolp (car keywords))))
1749          keywords)
1750         ((numberp level)
1751          (or (nth level keywords) (car (last keywords))))
1752         ((eq level t)
1753          (car (last keywords)))
1754         (t
1755          (car keywords))))
1756
1757 (defvar font-lock-set-defaults nil)     ; Whether we have set up defaults.
1758
1759 (defun font-lock-refresh-defaults ()
1760   "Restart fontification in current buffer after recomputing from defaults.
1761 Recompute fontification variables using `font-lock-defaults' and
1762 `font-lock-maximum-decoration'.  Then restart fontification.
1763
1764 Use this function when you have changed any of the above
1765 variables directly.
1766
1767 Note: This function will erase modifications done by
1768 `font-lock-add-keywords' or `font-lock-remove-keywords', but will
1769 preserve `hi-lock-mode' highlighting patterns."
1770   (let ((hi-lock--inhibit-font-lock-hook t))
1771     (font-lock-mode -1))
1772   (kill-local-variable 'font-lock-set-defaults)
1773   (font-lock-mode 1))
1774
1775 (defvar font-lock-major-mode nil
1776   "Major mode for which the font-lock settings have been setup.")
1777 (make-variable-buffer-local 'font-lock-major-mode)
1778
1779 (defun font-lock-set-defaults ()
1780   "Set fontification defaults appropriately for this mode.
1781 Sets various variables using `font-lock-defaults' and
1782 `font-lock-maximum-decoration'."
1783   ;; Set fontification defaults if not previously set for correct major mode.
1784   (unless (and font-lock-set-defaults
1785                (eq font-lock-major-mode major-mode))
1786     (setq font-lock-major-mode major-mode)
1787     (set (make-local-variable 'font-lock-set-defaults) t)
1788     (make-local-variable 'font-lock-fontified)
1789     (make-local-variable 'font-lock-multiline)
1790     (let* ((defaults font-lock-defaults)
1791            (keywords
1792             (font-lock-choose-keywords (nth 0 defaults)
1793                                        (font-lock-value-in-major-mode font-lock-maximum-decoration)))
1794            (local (cdr (assq major-mode font-lock-keywords-alist)))
1795            (removed-keywords
1796             (cdr-safe (assq major-mode font-lock-removed-keywords-alist))))
1797       (set (make-local-variable 'font-lock-defaults) defaults)
1798       ;; Syntactic fontification?
1799       (if (nth 1 defaults)
1800           (set (make-local-variable 'font-lock-keywords-only) t)
1801         (kill-local-variable 'font-lock-keywords-only))
1802       ;; Case fold during regexp fontification?
1803       (if (nth 2 defaults)
1804           (set (make-local-variable 'font-lock-keywords-case-fold-search) t)
1805         (kill-local-variable 'font-lock-keywords-case-fold-search))
1806       ;; Syntax table for regexp and syntactic fontification?
1807       (if (null (nth 3 defaults))
1808           (kill-local-variable 'font-lock-syntax-table)
1809         (set (make-local-variable 'font-lock-syntax-table)
1810              (copy-syntax-table (syntax-table)))
1811         (dolist (selem (nth 3 defaults))
1812           ;; The character to modify may be a single CHAR or a STRING.
1813           (let ((syntax (cdr selem)))
1814             (dolist (char (if (numberp (car selem))
1815                               (list (car selem))
1816                             (mapcar 'identity (car selem))))
1817               (modify-syntax-entry char syntax font-lock-syntax-table)))))
1818       ;; Syntax function for syntactic fontification?
1819       (if (nth 4 defaults)
1820         (set (make-local-variable 'font-lock-beginning-of-syntax-function)
1821                (nth 4 defaults))
1822         (kill-local-variable 'font-lock-beginning-of-syntax-function))
1823       ;; Variable alist?
1824       (dolist (x (nthcdr 5 defaults))
1825         (set (make-local-variable (car x)) (cdr x)))
1826       ;; Set up `font-lock-keywords' last because its value might depend
1827       ;; on other settings (e.g. font-lock-compile-keywords uses
1828       ;; font-lock-beginning-of-syntax-function).
1829       (set (make-local-variable 'font-lock-keywords)
1830            (font-lock-eval-keywords keywords))
1831       ;; Local fontification?
1832       (while local
1833         (font-lock-add-keywords nil (car (car local)) (cdr (car local)))
1834         (setq local (cdr local)))
1835       (when removed-keywords
1836         (font-lock-remove-keywords nil removed-keywords))
1837       ;; Now compile the keywords.
1838       (unless (eq (car font-lock-keywords) t)
1839         (setq font-lock-keywords
1840               (font-lock-compile-keywords font-lock-keywords))))))
1841 \f
1842 ;;; Color etc. support.
1843
1844 ;; Note that `defface' will not overwrite any faces declared above via
1845 ;; `custom-declare-face'.
1846 (defface font-lock-comment-face
1847   '((((class grayscale) (background light))
1848      (:foreground "DimGray" :weight bold :slant italic))
1849     (((class grayscale) (background dark))
1850      (:foreground "LightGray" :weight bold :slant italic))
1851     (((class color) (min-colors 88) (background light))
1852      (:foreground "Firebrick"))
1853     (((class color) (min-colors 88) (background dark))
1854      (:foreground "chocolate1"))
1855     (((class color) (min-colors 16) (background light))
1856      (:foreground "red"))
1857     (((class color) (min-colors 16) (background dark))
1858      (:foreground "red1"))
1859     (((class color) (min-colors 8) (background light))
1860      (:foreground "red"))
1861     (((class color) (min-colors 8) (background dark))
1862      )
1863     (t (:weight bold :slant italic)))
1864   "Font Lock mode face used to highlight comments."
1865   :group 'font-lock-faces)
1866
1867 (defface font-lock-comment-delimiter-face
1868   '((default :inherit font-lock-comment-face)
1869     (((class grayscale)))
1870     (((class color) (min-colors 16)))
1871     (((class color) (min-colors 8) (background light))
1872      :foreground "red")
1873     (((class color) (min-colors 8) (background dark))
1874      :foreground "red1"))
1875   "Font Lock mode face used to highlight comment delimiters."
1876   :group 'font-lock-faces)
1877
1878 (defface font-lock-string-face
1879   '((((class grayscale) (background light)) (:foreground "DimGray" :slant italic))
1880     (((class grayscale) (background dark)) (:foreground "LightGray" :slant italic))
1881     (((class color) (min-colors 88) (background light)) (:foreground "VioletRed4"))
1882     (((class color) (min-colors 88) (background dark)) (:foreground "LightSalmon"))
1883     (((class color) (min-colors 16) (background light)) (:foreground "RosyBrown"))
1884     (((class color) (min-colors 16) (background dark)) (:foreground "LightSalmon"))
1885     (((class color) (min-colors 8)) (:foreground "green"))
1886     (t (:slant italic)))
1887   "Font Lock mode face used to highlight strings."
1888   :group 'font-lock-faces)
1889
1890 (defface font-lock-doc-face
1891   '((t :inherit font-lock-string-face))
1892   "Font Lock mode face used to highlight documentation."
1893   :group 'font-lock-faces)
1894
1895 (defface font-lock-keyword-face
1896   '((((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1897     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1898     (((class color) (min-colors 88) (background light)) (:foreground "Purple"))
1899     (((class color) (min-colors 88) (background dark)) (:foreground "Cyan1"))
1900     (((class color) (min-colors 16) (background light)) (:foreground "Purple"))
1901     (((class color) (min-colors 16) (background dark)) (:foreground "Cyan"))
1902     (((class color) (min-colors 8)) (:foreground "cyan" :weight bold))
1903     (t (:weight bold)))
1904   "Font Lock mode face used to highlight keywords."
1905   :group 'font-lock-faces)
1906
1907 (defface font-lock-builtin-face
1908   '((((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1909     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1910     (((class color) (min-colors 88) (background light)) (:foreground "MediumOrchid4"))
1911     (((class color) (min-colors 88) (background dark)) (:foreground "LightSteelBlue"))
1912     (((class color) (min-colors 16) (background light)) (:foreground "Orchid"))
1913     (((class color) (min-colors 16) (background dark)) (:foreground "LightSteelBlue"))
1914     (((class color) (min-colors 8)) (:foreground "blue" :weight bold))
1915     (t (:weight bold)))
1916   "Font Lock mode face used to highlight builtins."
1917   :group 'font-lock-faces)
1918
1919 (defface font-lock-function-name-face
1920   '((((class color) (min-colors 88) (background light)) (:foreground "Blue1"))
1921     (((class color) (min-colors 88) (background dark)) (:foreground "LightSkyBlue"))
1922     (((class color) (min-colors 16) (background light)) (:foreground "Blue"))
1923     (((class color) (min-colors 16) (background dark)) (:foreground "LightSkyBlue"))
1924     (((class color) (min-colors 8)) (:foreground "blue" :weight bold))
1925     (t (:inverse-video t :weight bold)))
1926   "Font Lock mode face used to highlight function names."
1927   :group 'font-lock-faces)
1928
1929 (defface font-lock-variable-name-face
1930   '((((class grayscale) (background light))
1931      (:foreground "Gray90" :weight bold :slant italic))
1932     (((class grayscale) (background dark))
1933      (:foreground "DimGray" :weight bold :slant italic))
1934     (((class color) (min-colors 88) (background light)) (:foreground "sienna"))
1935     (((class color) (min-colors 88) (background dark)) (:foreground "LightGoldenrod"))
1936     (((class color) (min-colors 16) (background light)) (:foreground "DarkGoldenrod"))
1937     (((class color) (min-colors 16) (background dark)) (:foreground "LightGoldenrod"))
1938     (((class color) (min-colors 8)) (:foreground "yellow" :weight light))
1939     (t (:weight bold :slant italic)))
1940   "Font Lock mode face used to highlight variable names."
1941   :group 'font-lock-faces)
1942
1943 (defface font-lock-type-face
1944   '((((class grayscale) (background light)) (:foreground "Gray90" :weight bold))
1945     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1946     (((class color) (min-colors 88) (background light)) (:foreground "ForestGreen"))
1947     (((class color) (min-colors 88) (background dark)) (:foreground "PaleGreen"))
1948     (((class color) (min-colors 16) (background light)) (:foreground "ForestGreen"))
1949     (((class color) (min-colors 16) (background dark)) (:foreground "PaleGreen"))
1950     (((class color) (min-colors 8)) (:foreground "green"))
1951     (t (:weight bold :underline t)))
1952   "Font Lock mode face used to highlight type and classes."
1953   :group 'font-lock-faces)
1954
1955 (defface font-lock-constant-face
1956   '((((class grayscale) (background light))
1957      (:foreground "LightGray" :weight bold :underline t))
1958     (((class grayscale) (background dark))
1959      (:foreground "Gray50" :weight bold :underline t))
1960     (((class color) (min-colors 88) (background light)) (:foreground "dark cyan"))
1961     (((class color) (min-colors 88) (background dark)) (:foreground "Aquamarine"))
1962     (((class color) (min-colors 16) (background light)) (:foreground "CadetBlue"))
1963     (((class color) (min-colors 16) (background dark)) (:foreground "Aquamarine"))
1964     (((class color) (min-colors 8)) (:foreground "magenta"))
1965     (t (:weight bold :underline t)))
1966   "Font Lock mode face used to highlight constants and labels."
1967   :group 'font-lock-faces)
1968
1969 (defface font-lock-warning-face
1970   '((((class color) (min-colors 88) (background light)) (:foreground "Red1" :weight bold))
1971     (((class color) (min-colors 88) (background dark)) (:foreground "Pink" :weight bold))
1972     (((class color) (min-colors 16) (background light)) (:foreground "Red1" :weight bold))
1973     (((class color) (min-colors 16) (background dark)) (:foreground "Pink" :weight bold))
1974     (((class color) (min-colors 8)) (:foreground "red"))
1975     (t (:inverse-video t :weight bold)))
1976   "Font Lock mode face used to highlight warnings."
1977   :group 'font-lock-faces)
1978
1979 (defface font-lock-negation-char-face
1980   '((t nil))
1981   "Font Lock mode face used to highlight easy to overlook negation."
1982   :group 'font-lock-faces)
1983
1984 (defface font-lock-preprocessor-face
1985   '((t :inherit font-lock-builtin-face))
1986   "Font Lock mode face used to highlight preprocessor directives."
1987   :group 'font-lock-faces)
1988
1989 (defface font-lock-regexp-grouping-backslash
1990   '((t :inherit bold))
1991   "Font Lock mode face for backslashes in Lisp regexp grouping constructs."
1992   :group 'font-lock-faces)
1993
1994 (defface font-lock-regexp-grouping-construct
1995   '((t :inherit bold))
1996   "Font Lock mode face used to highlight grouping constructs in Lisp regexps."
1997   :group 'font-lock-faces)
1998
1999 ;;; End of Color etc. support.
2000 \f
2001 ;;; Menu support.
2002
2003 ;; This section of code is commented out because Emacs does not have real menu
2004 ;; buttons.  (We can mimic them by putting "( ) " or "(X) " at the beginning of
2005 ;; the menu entry text, but with Xt it looks both ugly and embarrassingly
2006 ;; amateur.)  If/When Emacs gets real menus buttons, put in menu-bar.el after
2007 ;; the entry for "Text Properties" something like:
2008 ;;
2009 ;; (define-key menu-bar-edit-menu [font-lock]
2010 ;;   (cons "Syntax Highlighting" font-lock-menu))
2011 ;;
2012 ;; and remove a single ";" from the beginning of each line in the rest of this
2013 ;; section.  Probably the mechanism for telling the menu code what are menu
2014 ;; buttons and when they are on or off needs tweaking.  I have assumed that the
2015 ;; mechanism is via `menu-toggle' and `menu-selected' symbol properties.  sm.
2016
2017 ;;;;;###autoload
2018 ;;(progn
2019 ;;  ;; Make the Font Lock menu.
2020 ;;  (defvar font-lock-menu (make-sparse-keymap "Syntax Highlighting"))
2021 ;;  ;; Add the menu items in reverse order.
2022 ;;  (define-key font-lock-menu [fontify-less]
2023 ;;    '("Less In Current Buffer" . font-lock-fontify-less))
2024 ;;  (define-key font-lock-menu [fontify-more]
2025 ;;    '("More In Current Buffer" . font-lock-fontify-more))
2026 ;;  (define-key font-lock-menu [font-lock-sep]
2027 ;;    '("--"))
2028 ;;  (define-key font-lock-menu [font-lock-mode]
2029 ;;    '("In Current Buffer" . font-lock-mode))
2030 ;;  (define-key font-lock-menu [global-font-lock-mode]
2031 ;;    '("In All Buffers" . global-font-lock-mode)))
2032 ;;
2033 ;;;;;###autoload
2034 ;;(progn
2035 ;;  ;; We put the appropriate `menu-enable' etc. symbol property values on when
2036 ;;  ;; font-lock.el is loaded, so we don't need to autoload the three variables.
2037 ;;  (put 'global-font-lock-mode 'menu-toggle t)
2038 ;;  (put 'font-lock-mode 'menu-toggle t)
2039 ;;  (put 'font-lock-fontify-more 'menu-enable '(identity))
2040 ;;  (put 'font-lock-fontify-less 'menu-enable '(identity)))
2041 ;;
2042 ;; ;; Put the appropriate symbol property values on now.  See above.
2043 ;;(put 'global-font-lock-mode 'menu-selected 'global-font-lock-mode)
2044 ;;(put 'font-lock-mode 'menu-selected 'font-lock-mode)
2045 ;;(put 'font-lock-fontify-more 'menu-enable '(nth 2 font-lock-fontify-level))
2046 ;;(put 'font-lock-fontify-less 'menu-enable '(nth 1 font-lock-fontify-level))
2047 ;;
2048 ;;(defvar font-lock-fontify-level nil)  ; For less/more fontification.
2049 ;;
2050 ;;(defun font-lock-fontify-level (level)
2051 ;;  (let ((font-lock-maximum-decoration level))
2052 ;;    (when font-lock-mode
2053 ;;      (font-lock-mode))
2054 ;;    (font-lock-mode)
2055 ;;    (when font-lock-verbose
2056 ;;      (message "Fontifying %s... level %d" (buffer-name) level))))
2057 ;;
2058 ;;(defun font-lock-fontify-less ()
2059 ;;  "Fontify the current buffer with less decoration.
2060 ;;See `font-lock-maximum-decoration'."
2061 ;;  (interactive)
2062 ;;  ;; Check in case we get called interactively.
2063 ;;  (if (nth 1 font-lock-fontify-level)
2064 ;;      (font-lock-fontify-level (1- (car font-lock-fontify-level)))
2065 ;;    (error "No less decoration")))
2066 ;;
2067 ;;(defun font-lock-fontify-more ()
2068 ;;  "Fontify the current buffer with more decoration.
2069 ;;See `font-lock-maximum-decoration'."
2070 ;;  (interactive)
2071 ;;  ;; Check in case we get called interactively.
2072 ;;  (if (nth 2 font-lock-fontify-level)
2073 ;;      (font-lock-fontify-level (1+ (car font-lock-fontify-level)))
2074 ;;    (error "No more decoration")))
2075 ;;
2076 ;; ;; This should be called by `font-lock-set-defaults'.
2077 ;;(defun font-lock-set-menu ()
2078 ;;  ;; Activate less/more fontification entries if there are multiple levels for
2079 ;;  ;; the current buffer.  Sets `font-lock-fontify-level' to be of the form
2080 ;;  ;; (CURRENT-LEVEL IS-LOWER-LEVEL-P IS-HIGHER-LEVEL-P) for menu activation.
2081 ;;  (let ((keywords (nth 0 font-lock-defaults))
2082 ;;      (level (font-lock-value-in-major-mode font-lock-maximum-decoration)))
2083 ;;    (make-local-variable 'font-lock-fontify-level)
2084 ;;    (if (or (symbolp keywords) (= (length keywords) 1))
2085 ;;      (font-lock-unset-menu)
2086 ;;      (cond ((eq level t)
2087 ;;           (setq level (1- (length keywords))))
2088 ;;          ((or (null level) (zerop level))
2089 ;;           ;; The default level is usually, but not necessarily, level 1.
2090 ;;           (setq level (- (length keywords)
2091 ;;                          (length (member (eval (car keywords))
2092 ;;                                          (mapcar 'eval (cdr keywords))))))))
2093 ;;      (setq font-lock-fontify-level (list level (> level 1)
2094 ;;                                        (< level (1- (length keywords))))))))
2095 ;;
2096 ;; ;; This should be called by `font-lock-unset-defaults'.
2097 ;;(defun font-lock-unset-menu ()
2098 ;;  ;; Deactivate less/more fontification entries.
2099 ;;  (setq font-lock-fontify-level nil))
2100
2101 ;;; End of Menu support.
2102 \f
2103 ;;; Various regexp information shared by several modes.
2104 ;; ;; Information specific to a single mode should go in its load library.
2105
2106 ;; Font Lock support for C, C++, Objective-C and Java modes is now in
2107 ;; cc-fonts.el (and required by cc-mode.el).  However, the below function
2108 ;; should stay in font-lock.el, since it is used by other libraries.  sm.
2109
2110 (defun font-lock-match-c-style-declaration-item-and-skip-to-next (limit)
2111   "Match, and move over, any declaration/definition item after point.
2112 Matches after point, but ignores leading whitespace and `*' characters.
2113 Does not move further than LIMIT.
2114
2115 The expected syntax of a declaration/definition item is `word' (preceded by
2116 optional whitespace and `*' characters and proceeded by optional whitespace)
2117 optionally followed by a `('.  Everything following the item (but belonging to
2118 it) is expected to be skip-able by `scan-sexps', and items are expected to be
2119 separated with a `,' and to be terminated with a `;'.
2120
2121 Thus the regexp matches after point:    word (
2122                                         ^^^^ ^
2123 Where the match subexpressions are:       1  2
2124
2125 The item is delimited by (match-beginning 1) and (match-end 1).
2126 If (match-beginning 2) is non-nil, the item is followed by a `('.
2127
2128 This function could be MATCHER in a MATCH-ANCHORED `font-lock-keywords' item."
2129   (when (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?")
2130     (when (and (match-end 2) (> (- (match-end 2) (match-beginning 2)) 1))
2131       ;; If `word' is followed by a double open-paren, it's probably
2132       ;; a macro used for "int myfun P_ ((int arg1))".  Let's go back one
2133       ;; word to try and match `myfun' rather than `P_'.
2134       (let ((pos (point)))
2135         (skip-chars-backward " \t\n")
2136         (skip-syntax-backward "w")
2137         (unless (looking-at "\\(\\sw+\\)[ \t\n]*\\sw+[ \t\n]*\\(((?\\)?")
2138           ;; Looks like it was something else, so go back to where we
2139           ;; were and reset the match data by rematching.
2140           (goto-char pos)
2141           (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?"))))
2142     (save-match-data
2143       (condition-case nil
2144           (save-restriction
2145             ;; Restrict to the LIMIT.
2146             (narrow-to-region (point-min) limit)
2147             (goto-char (match-end 1))
2148             ;; Move over any item value, etc., to the next item.
2149             (while (not (looking-at "[ \t\n]*\\(\\(,\\)\\|;\\|\\'\\)"))
2150               (goto-char (or (scan-sexps (point) 1) (point-max))))
2151             (if (match-end 2)
2152                 (goto-char (match-end 2))))
2153         (error t)))))
2154
2155 ;; C preprocessor(cpp) is used outside of C, C++ and Objective-C source file.
2156 ;; e.g. assembler code and GNU linker script in Linux kernel.
2157 ;; `cpp-font-lock-keywords' is handy for modes for the files.
2158 ;;
2159 ;; Here we cannot use `regexp-opt' because because regex-opt is not preloaded
2160 ;; while font-lock.el is preloaded to emacs. So values pre-calculated with
2161 ;; regexp-opt are used here.
2162
2163 ;; `cpp-font-lock-keywords-source-directives' is calculated from:
2164 ;;
2165 ;;          (regexp-opt
2166 ;;           '("define"  "elif" "else" "endif" "error" "file" "if" "ifdef"
2167 ;;             "ifndef" "import" "include" "line" "pragma" "undef" "warning"))
2168 ;;
2169 (defconst cpp-font-lock-keywords-source-directives
2170   "define\\|e\\(?:l\\(?:if\\|se\\)\\|ndif\\|rror\\)\\|file\\|i\\(?:f\\(?:n?def\\)?\\|mport\\|nclude\\)\\|line\\|pragma\\|undef\\|warning"
2171   "Regular expression used in `cpp-font-lock-keywords'.")
2172
2173 ;; `cpp-font-lock-keywords-source-depth' is calculated from:
2174 ;;
2175 ;;          (regexp-opt-depth (regexp-opt
2176 ;;                     '("define"  "elif" "else" "endif" "error" "file" "if" "ifdef"
2177 ;;                       "ifndef" "import" "include" "line" "pragma" "undef" "warning")))
2178 ;;
2179 (defconst cpp-font-lock-keywords-source-depth 0
2180   "An integer representing regular expression depth of `cpp-font-lock-keywords-source-directives'.
2181 Used in `cpp-font-lock-keywords'.")
2182
2183 (defconst cpp-font-lock-keywords
2184   (let* ((directives cpp-font-lock-keywords-source-directives)
2185          (directives-depth cpp-font-lock-keywords-source-depth))
2186     (list
2187      ;;
2188      ;; Fontify error directives.
2189      '("^#[ \t]*\\(?:error\\|warning\\)[ \t]+\\(.+\\)" 1 font-lock-warning-face prepend)
2190      ;;
2191      ;; Fontify filenames in #include <...> preprocessor directives as strings.
2192      '("^#[ \t]*\\(?:import\\|include\\)[ \t]*\\(<[^>\"\n]*>?\\)"
2193        1 font-lock-string-face prepend)
2194      ;;
2195      ;; Fontify function macro names.
2196      '("^#[ \t]*define[ \t]+\\([[:alpha:]_][[:alnum:]_$]*\\)("
2197        (1 font-lock-function-name-face prepend)
2198        ;;
2199        ;; Macro arguments.
2200        ((lambda (limit)
2201           (re-search-forward
2202            "\\(?:\\([[:alpha:]_][[:alnum:]_]*\\)[,]?\\)"
2203            (or (save-excursion (re-search-forward ")" limit t))
2204                limit)
2205            t))
2206         nil nil (1 font-lock-variable-name-face prepend)))
2207      ;;
2208      ;; Fontify symbol names in #elif or #if ... defined preprocessor directives.
2209      '("^#[ \t]*\\(?:elif\\|if\\)\\>"
2210        ("\\<\\(defined\\)\\>[ \t]*(?\\([[:alpha:]_][[:alnum:]_]*\\)?" nil nil
2211         (1 font-lock-builtin-face prepend) (2 font-lock-variable-name-face prepend t)))
2212      ;;
2213      ;; Fontify otherwise as symbol names, and the preprocessor directive names.
2214      (list
2215       (concat "^\\(#[ \t]*\\(?:" directives
2216               "\\)\\)\\>[ \t!]*\\([[:alpha:]_][[:alnum:]_]*\\)?")
2217       '(1 font-lock-preprocessor-face prepend)
2218       (list (+ 2 directives-depth)
2219             'font-lock-variable-name-face nil t))))
2220   "Font lock keywords for C preprocessor directives.
2221 `c-mode', `c++-mode' and `objc-mode' have their own font lock keywords
2222 for C preprocessor directives.  This definition is for the other modes
2223 in which C preprocessor directives are used. e.g. `asm-mode' and
2224 `ld-script-mode'.")
2225
2226 \f
2227 ;; Lisp.
2228
2229 (defconst lisp-font-lock-keywords-1
2230   (eval-when-compile
2231     `(;; Definitions.
2232       (,(concat "(\\(def\\("
2233                 ;; Function declarations.
2234                 "\\(advice\\|alias\\|generic\\|macro\\*?\\|method\\|"
2235                 "setf\\|subst\\*?\\|un\\*?\\|"
2236                 "ine-\\(condition\\|"
2237                 "\\(?:derived\\|\\(?:global\\(?:ized\\)?-\\)?minor\\|generic\\)-mode\\|"
2238                 "method-combination\\|setf-expander\\|skeleton\\|widget\\|"
2239                 "function\\|\\(compiler\\|modify\\|symbol\\)-macro\\)\\)\\|"
2240                 ;; Variable declarations.
2241                 "\\(const\\(ant\\)?\\|custom\\|varalias\\|face\\|parameter\\|var\\)\\|"
2242                 ;; Structure declarations.
2243                 "\\(class\\|group\\|theme\\|package\\|struct\\|type\\)"
2244                 "\\)\\)\\>"
2245                 ;; Any whitespace and defined object.
2246                 "[ \t'\(]*"
2247                 "\\(setf[ \t]+\\sw+)\\|\\sw+\\)?")
2248        (1 font-lock-keyword-face)
2249        (9 (cond ((match-beginning 3) font-lock-function-name-face)
2250                 ((match-beginning 6) font-lock-variable-name-face)
2251                 (t font-lock-type-face))
2252           nil t))
2253       ;; Emacs Lisp autoload cookies.  Supports the slightly different
2254       ;; forms used by mh-e, calendar, etc.
2255       ("^;;;###\\([-a-z]*autoload\\)" 1 font-lock-warning-face prepend)
2256       ;; Regexp negated char group.
2257       ("\\[\\(\\^\\)" 1 font-lock-negation-char-face prepend)))
2258   "Subdued level highlighting for Lisp modes.")
2259
2260 (defconst lisp-font-lock-keywords-2
2261   (append lisp-font-lock-keywords-1
2262    (eval-when-compile
2263      `(;; Control structures.  Emacs Lisp forms.
2264        (,(concat
2265           "(" (regexp-opt
2266                '("cond" "if" "while" "while-no-input" "let" "let*"
2267                  "prog" "progn" "progv" "prog1" "prog2" "prog*"
2268                  "inline" "lambda" "save-restriction" "save-excursion"
2269                  "save-selected-window" "save-window-excursion"
2270                  "save-match-data" "save-current-buffer"
2271                  "combine-after-change-calls" "unwind-protect"
2272                  "condition-case" "condition-case-no-debug"
2273                  "track-mouse" "eval-after-load" "eval-and-compile"
2274                  "eval-when-compile" "eval-when" "eval-next-after-load"
2275                  "with-case-table" "with-category-table"
2276                  "with-current-buffer" "with-demoted-errors"
2277                  "with-electric-help"
2278                  "with-local-quit" "with-no-warnings"
2279                  "with-output-to-string" "with-output-to-temp-buffer"
2280                  "with-selected-window" "with-selected-frame"
2281                  "with-silent-modifications" "with-syntax-table"
2282                  "with-temp-buffer" "with-temp-file" "with-temp-message"
2283                  "with-timeout" "with-timeout-handler") t)
2284           "\\>")
2285           .  1)
2286        ;; Control structures.  Common Lisp forms.
2287        (,(concat
2288           "(" (regexp-opt
2289                '("when" "unless" "case" "ecase" "typecase" "etypecase"
2290                  "ccase" "ctypecase" "handler-case" "handler-bind"
2291                  "restart-bind" "restart-case" "in-package"
2292                  "break" "ignore-errors"
2293                  "loop" "do" "do*" "dotimes" "dolist" "the" "locally"
2294                  "proclaim" "declaim" "declare" "symbol-macrolet" "letf"
2295                  "lexical-let" "lexical-let*" "flet" "labels" "compiler-let"
2296                  "destructuring-bind" "macrolet" "tagbody" "block" "go"
2297                  "multiple-value-bind" "multiple-value-prog1"
2298                  "return" "return-from"
2299                  "with-accessors" "with-compilation-unit"
2300                  "with-condition-restarts" "with-hash-table-iterator"
2301                  "with-input-from-string" "with-open-file"
2302                  "with-open-stream" "with-output-to-string"
2303                  "with-package-iterator" "with-simple-restart"
2304                  "with-slots" "with-standard-io-syntax") t)
2305           "\\>")
2306           . 1)
2307        ;; Exit/Feature symbols as constants.
2308        (,(concat "(\\(catch\\|throw\\|featurep\\|provide\\|require\\)\\>"
2309                  "[ \t']*\\(\\sw+\\)?")
2310         (1 font-lock-keyword-face)
2311         (2 font-lock-constant-face nil t))
2312        ;; Erroneous structures.
2313        ("(\\(abort\\|assert\\|warn\\|check-type\\|cerror\\|error\\|signal\\)\\>" 1 font-lock-warning-face)
2314        ;; Words inside \\[] tend to be for `substitute-command-keys'.
2315        ("\\\\\\\\\\[\\(\\sw+\\)\\]" 1 font-lock-constant-face prepend)
2316        ;; Words inside `' tend to be symbol names.
2317        ("`\\(\\sw\\sw+\\)'" 1 font-lock-constant-face prepend)
2318        ;; Constant values.
2319        ("\\<:\\sw+\\>" 0 font-lock-builtin-face)
2320        ;; ELisp and CLisp `&' keywords as types.
2321        ("\\<\\&\\sw+\\>" . font-lock-type-face)
2322        ;; ELisp regexp grouping constructs
2323        ((lambda (bound)
2324           (catch 'found
2325             ;; The following loop is needed to continue searching after matches
2326             ;; that do not occur in strings.  The associated regexp matches one
2327             ;; of `\\\\' `\\(' `\\(?:' `\\|' `\\)'.  `\\\\' has been included to
2328             ;; avoid highlighting, for example, `\\(' in `\\\\('.
2329             (while (re-search-forward "\\(\\\\\\\\\\)\\(?:\\(\\\\\\\\\\)\\|\\((\\(?:\\?[0-9]*:\\)?\\|[|)]\\)\\)" bound t)
2330               (unless (match-beginning 2)
2331                 (let ((face (get-text-property (1- (point)) 'face)))
2332                   (when (or (and (listp face)
2333                                  (memq 'font-lock-string-face face))
2334                             (eq 'font-lock-string-face face))
2335                     (throw 'found t)))))))
2336         (1 'font-lock-regexp-grouping-backslash prepend)
2337         (3 'font-lock-regexp-grouping-construct prepend))
2338 ;;;  This is too general -- rms.
2339 ;;;  A user complained that he has functions whose names start with `do'
2340 ;;;  and that they get the wrong color.
2341 ;;;      ;; CL `with-' and `do-' constructs
2342 ;;;      ("(\\(\\(do-\\|with-\\)\\(\\s_\\|\\w\\)*\\)" 1 font-lock-keyword-face)
2343       )))
2344   "Gaudy level highlighting for Lisp modes.")
2345
2346 (defvar lisp-font-lock-keywords lisp-font-lock-keywords-1
2347   "Default expressions to highlight in Lisp modes.")
2348 \f
2349 (provide 'font-lock)
2350
2351 ;;; font-lock.el ends here