lisp/calc/calc-misc.el

   1 ;;; calc-misc.el --- miscellaneous functions for Calc
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 2001, 2002, 2003, 2004
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: David Gillespie <daveg@synaptics.com>
   7 ;; Maintainer: Jay Belanger <jay.p.belanger@gmail.com>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 ;; This file is autoloaded from calc.el.
  29
  30 (require 'calc)
  31 (require 'calc-macs)
  32
  33 ;; Declare functions which are defined elsewhere.
  34 (declare-function calc-do-keypad "calc-keypd" (&optional full-display interactive))
  35 (declare-function calc-inv-hyp-prefix-help "calc-help" ())
  36 (declare-function calc-inverse-prefix-help "calc-help" ())
  37 (declare-function calc-hyperbolic-prefix-help "calc-help" ())
  38 (declare-function calc-explain-why "calc-stuff" (why &optional more))
  39 (declare-function calc-clear-command-flag "calc-ext" (f))
  40 (declare-function calc-roll-down-with-selections "calc-sel" (n m))
  41 (declare-function calc-roll-up-with-selections "calc-sel" (n m))
  42 (declare-function calc-last-args "calc-undo" (n))
  43 (declare-function calc-is-inverse "calc-ext" ())
  44 (declare-function calc-do-prefix-help "calc-ext" (msgs group key))
  45 (declare-function math-objvecp "calc-ext" (a))
  46 (declare-function math-known-scalarp "calc-arith" (a &optional assume-scalar))
  47 (declare-function math-vectorp "calc-ext" (a))
  48 (declare-function math-matrixp "calc-ext" (a))
  49 (declare-function math-trunc-special "calc-arith" (a prec))
  50 (declare-function math-trunc-fancy "calc-arith" (a))
  51 (declare-function math-floor-special "calc-arith" (a prec))
  52 (declare-function math-floor-fancy "calc-arith" (a))
  53 (declare-function math-square-matrixp "calc-ext" (a))
  54 (declare-function math-matrix-inv-raw "calc-mtx" (m))
  55 (declare-function math-known-matrixp "calc-arith" (a))
  56 (declare-function math-mod-fancy "calc-arith" (a b))
  57 (declare-function math-pow-of-zero "calc-arith" (a b))
  58 (declare-function math-pow-zero "calc-arith" (a b))
  59 (declare-function math-pow-fancy "calc-arith" (a b))
  60
  61
  62 ;;;###autoload
  63 (defun calc-dispatch-help (arg)
  64   "C-x* is a prefix key sequence; follow it with one of these letters:
  65
  66 For turning Calc on and off:
  67   C  calc.  Start the Calculator in a window at the bottom of the screen.
  68   O  calc-other-window.  Start the Calculator but don't select its window.
  69   B  calc-big-or-small.  Control whether to use the full Emacs screen for Calc.
  70   Q  quick-calc.  Use the Calculator in the minibuffer.
  71   K  calc-keypad.  Start the Calculator in keypad mode (X window system only).
  72   E  calc-embedded.  Use the Calculator on a formula in this editing buffer.
  73   J  calc-embedded-select.  Like E, but select appropriate half of => or :=.
  74   W  calc-embedded-word.  Like E, but activate a single word, i.e., a number.
  75   Z  calc-user-invocation.  Invoke Calc in the way you defined with `Z I' cmd.
  76   X  calc-quit.  Turn Calc off.
  77
  78 For moving data into and out of Calc:
  79   G  calc-grab-region.  Grab the region defined by mark and point into Calc.
  80   R  calc-grab-rectangle.  Grab the rectangle defined by mark, point into Calc.
  81   :  calc-grab-sum-down.  Grab a rectangle and sum the columns.
  82   _  calc-grab-sum-across.  Grab a rectangle and sum the rows.
  83   Y  calc-copy-to-buffer.  Copy a value from the stack into the editing buffer.
  84
  85 For use with Embedded mode:
  86   A  calc-embedded-activate.  Find and activate all :='s and =>'s in buffer.
  87   D  calc-embedded-duplicate.  Make a copy of this formula and select it.
  88   F  calc-embedded-new-formula.  Insert a new formula at current point.
  89   N  calc-embedded-next.  Advance cursor to next known formula in buffer.
  90   P  calc-embedded-previous.  Advance cursor to previous known formula.
  91   U  calc-embedded-update-formula.  Re-evaluate formula at point.
  92   `  calc-embedded-edit.  Use calc-edit to edit formula at point.
  93
  94 Documentation:
  95   I  calc-info.  Read the Calculator manual in the Emacs Info system.
  96   T  calc-tutorial.  Run the Calculator Tutorial using the Emacs Info system.
  97   S  calc-summary.  Read the Summary from the Calculator manual in Info.
  98
  99 Miscellaneous:
 100   L  calc-load-everything.  Load all parts of the Calculator into memory.
 101   M  read-kbd-macro.  Read a region of keystroke names as a keyboard macro.
 102   0  (zero) calc-reset.  Reset Calc stack and modes to default state.
 103
 104 Press `*' twice (`C-x * *') to turn Calc on or off using the same
 105 Calc user interface as before (either C-x * C or C-x * K; initially C-x * C).
 106 "
 107   (interactive "P")
 108   (calc-check-defines)
 109   (if calc-dispatch-help
 110       (progn
 111         (save-window-excursion
 112           (describe-function 'calc-dispatch-help)
 113           (let ((win (get-buffer-window "*Help*")))
 114             (if win
 115                 (let (key)
 116                   (select-window win)
 117                   (while (progn
 118                            (message "Calc options: Calc, Keypad, ...  %s"
 119                                     "press SPC, DEL to scroll, C-g to cancel")
 120                            (memq (car (setq key (calc-read-key t)))
 121                                  '(?  ?\C-h ?\C-? ?\C-v ?\M-v)))
 122                     (condition-case err
 123                         (if (memq (car key) '(?  ?\C-v))
 124                             (scroll-up)
 125                           (scroll-down))
 126                       (error (beep))))
 127                       (calc-unread-command (cdr key))))))
 128         (calc-do-dispatch nil))
 129     (let ((calc-dispatch-help t))
 130       (calc-do-dispatch arg))))
 131
 132
 133 ;;;###autoload
 134 (defun calc-big-or-small (arg)
 135   "Toggle Calc between full-screen and regular mode."
 136   (interactive "P")
 137   (let ((cwin (get-buffer-window "*Calculator*"))
 138         (twin (get-buffer-window "*Calc Trail*"))
 139         (kwin (get-buffer-window "*Calc Keypad*")))
 140     (if cwin
 141         (setq calc-full-mode
 142               (if kwin
 143                   (and twin (eq (window-width twin) (frame-width)))
 144                 (eq (window-height cwin) (1- (frame-height))))))
 145     (setq calc-full-mode (if arg
 146                              (> (prefix-numeric-value arg) 0)
 147                            (not calc-full-mode)))
 148     (if kwin
 149         (progn
 150           (calc-quit)
 151           (calc-do-keypad calc-full-mode nil))
 152       (if cwin
 153           (progn
 154             (calc-quit)
 155             (calc nil calc-full-mode nil))))
 156     (message (if calc-full-mode
 157                  "Now using full screen for Calc"
 158                "Now using partial screen for Calc"))))
 159
 160 ;;;###autoload
 161 (defun calc-other-window (&optional interactive)
 162   "Invoke the Calculator in another window."
 163   (interactive "p")
 164   (if (memq major-mode '(calc-mode calc-trail-mode))
 165       (progn
 166         (other-window 1)
 167         (if (memq major-mode '(calc-mode calc-trail-mode))
 168             (other-window 1)))
 169     (if (get-buffer-window "*Calculator*")
 170         (calc-quit)
 171       (let ((win (selected-window)))
 172         (calc nil win interactive)))))
 173
 174 ;;;###autoload
 175 (defun another-calc ()
 176   "Create another, independent Calculator buffer."
 177   (interactive)
 178   (if (eq major-mode 'calc-mode)
 179       (mapc (function
 180              (lambda (v)
 181               (set-default v (symbol-value v)))) calc-local-var-list))
 182   (set-buffer (generate-new-buffer "*Calculator*"))
 183   (pop-to-buffer (current-buffer))
 184   (calc-mode))
 185
 186 ;;;###autoload
 187 (defun calc-info ()
 188   "Run the Emacs Info system on the Calculator documentation."
 189   (interactive)
 190   (select-window (get-largest-window))
 191   (info "Calc"))
 192
 193 ;;;###autoload
 194 (defun calc-info-goto-node (node)
 195   "Go to a node in the Calculator info documentation."
 196   (interactive)
 197   (select-window (get-largest-window))
 198   (info (concat "(Calc)" node)))
 199
 200 ;;;###autoload
 201 (defun calc-tutorial ()
 202   "Run the Emacs Info system on the Calculator Tutorial."
 203   (interactive)
 204   (if (get-buffer-window "*Calculator*")
 205       (calc-quit))
 206   (calc-info-goto-node "Interactive Tutorial")
 207   (calc-other-window)
 208   (message "Welcome to the Calc Tutorial!"))
 209
 210 ;;;###autoload
 211 (defun calc-info-summary ()
 212   "Run the Emacs Info system on the Calculator Summary."
 213   (interactive)
 214   (calc-info-goto-node "Summary"))
 215
 216 ;;;###autoload
 217 (defun calc-help ()
 218   (interactive)
 219   (let ((msgs
 220          '("Press `h' for complete help; press `?' repeatedly for a summary"
 221            "Letter keys: Negate; Precision; Yank; Why; Xtended cmd; Quit"
 222            "Letter keys: SHIFT + Undo, reDo; Keep-args; Inverse, Hyperbolic"
 223            "Letter keys: SHIFT + sQrt; Sin, Cos, Tan; Exp, Ln, logB"
 224            "Letter keys: SHIFT + Floor, Round; Abs, conJ, arG; Pi"
 225            "Letter keys: SHIFT + Num-eval; More-recn; eXec-kbd-macro"
 226            "Other keys: +, -, *, /, ^, \\ (int div), : (frac div)"
 227            "Other keys: & (1/x), | (concat), % (modulo), ! (factorial)"
 228            "Other keys: ' (alg-entry), = (eval), ` (edit); M-RET (last-args)"
 229            "Other keys: SPC/RET (enter/dup), LFD (over); < > (scroll horiz)"
 230            "Other keys: DEL (drop), M-DEL (drop-above); { } (scroll vert)"
 231            "Other keys: TAB (swap/roll-dn), M-TAB (roll-up)"
 232            "Other keys: [ , ; ] (vector), ( , ) (complex), ( ; ) (polar)"
 233            "Prefix keys: Algebra, Binary/business, Convert, Display"
 234            "Prefix keys: Functions, Graphics, Help, J (select)"
 235            "Prefix keys: Kombinatorics/statistics, Modes, Store/recall"
 236            "Prefix keys: Trail/time, Units/statistics, Vector/matrix"
 237            "Prefix keys: Z (user), SHIFT + Z (define)"
 238            "Prefix keys: prefix + ? gives further help for that prefix"
 239            "  Calc by Dave Gillespie, daveg@synaptics.com")))
 240     (if calc-full-help-flag
 241         msgs
 242       (if (or calc-inverse-flag calc-hyperbolic-flag)
 243           (if calc-inverse-flag
 244               (if calc-hyperbolic-flag
 245                   (calc-inv-hyp-prefix-help)
 246                 (calc-inverse-prefix-help))
 247             (calc-hyperbolic-prefix-help))
 248         (setq calc-help-phase
 249               (if (eq this-command last-command)
 250                   (% (1+ calc-help-phase) (1+ (length msgs)))
 251                 0))
 252         (let ((msg (nth calc-help-phase msgs)))
 253           (message "%s" (if msg
 254                             (concat msg ":"
 255                                     (make-string (- (apply 'max
 256                                                            (mapcar 'length
 257                                                                    msgs))
 258                                                     (length msg)) 32)
 259                                     "  [?=MORE]")
 260                           "")))))))
 261
 262
 263
 264
 265 ;;;; Stack and buffer management.
 266
 267 ;; The variable calc-last-why-command is set in calc-do-handly-whys
 268 ;; and used in calc-why (in calc-stuff.el).
 269 (defvar calc-last-why-command)
 270
 271 ;;;###autoload
 272 (defun calc-do-handle-whys ()
 273   (setq calc-why (sort calc-next-why
 274                        (function
 275                         (lambda (x y)
 276                           (and (eq (car x) '*) (not (eq (car y) '*))))))
 277         calc-next-why nil)
 278   (if (and calc-why (or (eq calc-auto-why t)
 279                         (and (eq (car (car calc-why)) '*)
 280                              calc-auto-why)))
 281       (progn
 282         (require 'calc-ext)
 283         (calc-explain-why (car calc-why)
 284                           (if (eq calc-auto-why t)
 285                               (cdr calc-why)
 286                             (if calc-auto-why
 287                                 (eq (car (nth 1 calc-why)) '*))))
 288         (setq calc-last-why-command this-command)
 289         (calc-clear-command-flag 'clear-message))))
 290
 291 ;;;###autoload
 292 (defun calc-record-why (&rest stuff)
 293   (if (eq (car stuff) 'quiet)
 294       (setq stuff (cdr stuff))
 295     (if (and (symbolp (car stuff))
 296              (cdr stuff)
 297              (or (Math-objectp (nth 1 stuff))
 298                  (and (Math-vectorp (nth 1 stuff))
 299                       (math-constp (nth 1 stuff)))
 300                  (math-infinitep (nth 1 stuff))))
 301         (setq stuff (cons '* stuff))
 302       (if (and (stringp (car stuff))
 303                (string-match "\\`\\*" (car stuff)))
 304           (setq stuff (cons '* (cons (substring (car stuff) 1)
 305                                      (cdr stuff)))))))
 306   (setq calc-next-why (cons stuff calc-next-why))
 307   nil)
 308
 309 ;; True if A is a constant or vector of constants.  [P x] [Public]
 310 ;;;###autoload
 311 (defun math-constp (a)
 312   (or (Math-scalarp a)
 313       (and (memq (car a) '(sdev intv mod vec))
 314            (progn
 315              (while (and (setq a (cdr a))
 316                          (or (Math-scalarp (car a))  ; optimization
 317                              (math-constp (car a)))))
 318              (null a)))))
 319
 320
 321 ;;;###autoload
 322 (defun calc-roll-down-stack (n &optional m)
 323   (if (< n 0)
 324       (calc-roll-up-stack (- n) m)
 325     (if (or (= n 0) (> n (calc-stack-size))) (setq n (calc-stack-size)))
 326     (or m (setq m 1))
 327     (and (> n 1)
 328          (< m n)
 329          (if (and calc-any-selections
 330                   (not calc-use-selections))
 331              (calc-roll-down-with-selections n m)
 332            (calc-pop-push-list n
 333                                (append (calc-top-list m 1)
 334                                        (calc-top-list (- n m) (1+ m))))))))
 335
 336 ;;;###autoload
 337 (defun calc-roll-up-stack (n &optional m)
 338   (if (< n 0)
 339       (calc-roll-down-stack (- n) m)
 340     (if (or (= n 0) (> n (calc-stack-size))) (setq n (calc-stack-size)))
 341     (or m (setq m 1))
 342     (and (> n 1)
 343          (< m n)
 344          (if (and calc-any-selections
 345                   (not calc-use-selections))
 346              (calc-roll-up-with-selections n m)
 347            (calc-pop-push-list n
 348                                (append (calc-top-list (- n m) 1)
 349                                        (calc-top-list m (- n m -1))))))))
 350
 351
 352 ;;;###autoload
 353 (defun calc-do-refresh ()
 354   (if calc-hyperbolic-flag
 355       (progn
 356         (setq calc-display-dirty t)
 357         nil)
 358     (calc-refresh)
 359     t))
 360
 361
 362 ;;;###autoload
 363 (defun calc-record-list (vals &optional prefix)
 364   (while vals
 365     (or (eq (car vals) 'top-of-stack)
 366         (progn
 367           (calc-record (car vals) prefix)
 368           (setq prefix "...")))
 369     (setq vals (cdr vals))))
 370
 371
 372 ;;;###autoload
 373 (defun calc-last-args-stub (arg)
 374   (interactive "p")
 375   (require 'calc-ext)
 376   (calc-last-args arg))
 377
 378
 379 ;;;###autoload
 380 (defun calc-power (arg)
 381   (interactive "P")
 382   (calc-slow-wrapper
 383    (if (and (featurep 'calc-ext)
 384             (calc-is-inverse))
 385        (calc-binary-op "root" 'calcFunc-nroot arg nil nil)
 386      (calc-binary-op "^" 'calcFunc-pow arg nil nil '^))))
 387
 388 ;;;###autoload
 389 (defun calc-mod (arg)
 390   (interactive "P")
 391   (calc-slow-wrapper
 392    (calc-binary-op "%" 'calcFunc-mod arg nil nil '%)))
 393
 394 ;;;###autoload
 395 (defun calc-inv (arg)
 396   (interactive "P")
 397   (calc-slow-wrapper
 398    (calc-unary-op "inv" 'calcFunc-inv arg)))
 399
 400 ;;;###autoload
 401 (defun calc-percent ()
 402   (interactive)
 403   (calc-slow-wrapper
 404    (calc-pop-push-record-list
 405     1 "%" (list (list 'calcFunc-percent (calc-top-n 1))))))
 406
 407
 408 ;;;###autoload
 409 (defun calc-over (n)
 410   (interactive "P")
 411   (if n
 412       (calc-enter (- (prefix-numeric-value n)))
 413     (calc-enter -2)))
 414
 415
 416 ;;;###autoload
 417 (defun calc-pop-above (n)
 418   (interactive "P")
 419   (if n
 420       (calc-pop (- (prefix-numeric-value n)))
 421     (calc-pop -2)))
 422
 423 ;;;###autoload
 424 (defun calc-roll-down (n)
 425   (interactive "P")
 426   (calc-wrapper
 427    (let ((nn (prefix-numeric-value n)))
 428      (cond ((null n)
 429             (calc-roll-down-stack 2))
 430            ((> nn 0)
 431             (calc-roll-down-stack nn))
 432            ((= nn 0)
 433             (calc-pop-push-list (calc-stack-size)
 434                                 (reverse
 435                                  (calc-top-list (calc-stack-size)))))
 436            (t
 437             (calc-roll-down-stack (calc-stack-size) (- nn)))))))
 438
 439 ;;;###autoload
 440 (defun calc-roll-up (n)
 441   (interactive "P")
 442   (calc-wrapper
 443    (let ((nn (prefix-numeric-value n)))
 444      (cond ((null n)
 445             (calc-roll-up-stack 3))
 446            ((> nn 0)
 447             (calc-roll-up-stack nn))
 448            ((= nn 0)
 449             (calc-pop-push-list (calc-stack-size)
 450                                 (reverse
 451                                  (calc-top-list (calc-stack-size)))))
 452            (t
 453             (calc-roll-up-stack (calc-stack-size) (- nn)))))))
 454
 455
 456
 457
 458 ;;; Other commands.
 459
 460 ;;;###autoload
 461 (defun calc-num-prefix-name (n)
 462   (cond ((eq n '-) "- ")
 463         ((equal n '(4)) "C-u ")
 464         ((consp n) (format "%d " (car n)))
 465         ((integerp n) (format "%d " n))
 466         (t "")))
 467
 468 ;;;###autoload
 469 (defun calc-missing-key (n)
 470   "This is a placeholder for a command which needs to be loaded from calc-ext.
 471 When this key is used, calc-ext (the Calculator extensions module) will be
 472 loaded and the keystroke automatically re-typed."
 473   (interactive "P")
 474   (require 'calc-ext)
 475   (if (keymapp (key-binding (char-to-string last-command-event)))
 476       (message "%s%c-" (calc-num-prefix-name n) last-command-event))
 477   (calc-unread-command)
 478   (setq prefix-arg n))
 479
 480 ;;;###autoload
 481 (defun calc-shift-Y-prefix-help ()
 482   (interactive)
 483   (require 'calc-ext)
 484   (calc-do-prefix-help calc-Y-help-msgs "other" ?Y))
 485
 486
 487
 488
 489 ;;;###autoload
 490 (defun calcDigit-letter ()
 491   (interactive)
 492   (if (calc-minibuffer-contains "[-+]?\\(1[1-9]\\|[2-9][0-9]\\)#.*")
 493       (progn
 494         (setq last-command-event (upcase last-command-event))
 495         (calcDigit-key))
 496     (calcDigit-nondigit)))
 497
 498
 499 ;; A Lisp version of temp_minibuffer_message from minibuf.c.
 500 ;;;###autoload
 501 (defun calc-temp-minibuffer-message (m)
 502   (let ((savemax (point-max)))
 503     (save-excursion
 504       (goto-char (point-max))
 505       (insert m))
 506     (let ((okay nil))
 507       (unwind-protect
 508           (progn
 509             (sit-for 2)
 510             (identity 1)   ; this forces a call to QUIT; in bytecode.c.
 511             (setq okay t))
 512         (progn
 513           (delete-region savemax (point-max))
 514           (or okay (abort-recursive-edit)))))))
 515
 516
 517 (put 'math-with-extra-prec 'lisp-indent-hook 1)
 518
 519
 520 ;; Concatenate two vectors, or a vector and an object.  [V O O] [Public]
 521 ;;;###autoload
 522 (defun math-concat (v1 v2)
 523   (if (stringp v1)
 524       (concat v1 v2)
 525     (require 'calc-ext)
 526     (if (and (or (math-objvecp v1) (math-known-scalarp v1))
 527              (or (math-objvecp v2) (math-known-scalarp v2)))
 528         (append (if (and (math-vectorp v1)
 529                          (or (math-matrixp v1)
 530                              (not (math-matrixp v2))))
 531                     v1
 532                   (list 'vec v1))
 533                 (if (and (math-vectorp v2)
 534                          (or (math-matrixp v2)
 535                              (not (math-matrixp v1))))
 536                     (cdr v2)
 537                   (list v2)))
 538       (list '| v1 v2))))
 539
 540
 541 ;; True if A is zero.  Works for un-normalized values.  [P n] [Public]
 542 ;;;###autoload
 543 (defun math-zerop (a)
 544   (if (consp a)
 545       (cond ((memq (car a) '(bigpos bigneg))
 546              (while (eq (car (setq a (cdr a))) 0))
 547              (null a))
 548             ((memq (car a) '(frac float polar mod))
 549              (math-zerop (nth 1 a)))
 550             ((eq (car a) 'cplx)
 551              (and (math-zerop (nth 1 a)) (math-zerop (nth 2 a))))
 552             ((eq (car a) 'hms)
 553              (and (math-zerop (nth 1 a))
 554                   (math-zerop (nth 2 a))
 555                   (math-zerop (nth 3 a)))))
 556     (eq a 0)))
 557
 558
 559 ;; True if A is real and negative.  [P n] [Public]
 560
 561 ;;;###autoload
 562 (defun math-negp (a)
 563   (if (consp a)
 564       (cond ((eq (car a) 'bigpos) nil)
 565             ((eq (car a) 'bigneg) (cdr a))
 566             ((memq (car a) '(float frac))
 567              (Math-integer-negp (nth 1 a)))
 568             ((eq (car a) 'hms)
 569              (if (math-zerop (nth 1 a))
 570                  (if (math-zerop (nth 2 a))
 571                      (math-negp (nth 3 a))
 572                    (math-negp (nth 2 a)))
 573                (math-negp (nth 1 a))))
 574             ((eq (car a) 'date)
 575              (math-negp (nth 1 a)))
 576             ((eq (car a) 'intv)
 577              (or (math-negp (nth 3 a))
 578                  (and (math-zerop (nth 3 a))
 579                       (memq (nth 1 a) '(0 2)))))
 580             ((equal a '(neg (var inf var-inf))) t))
 581     (< a 0)))
 582
 583 ;; True if A is a negative number or an expression the starts with '-'.
 584 ;;;###autoload
 585 (defun math-looks-negp (a)   ; [P x] [Public]
 586   (or (Math-negp a)
 587       (eq (car-safe a) 'neg)
 588       (and (memq (car-safe a) '(* /))
 589            (or (math-looks-negp (nth 1 a))
 590                (math-looks-negp (nth 2 a))))
 591       (and (eq (car-safe a) '-)
 592            (math-looks-negp (nth 1 a)))))
 593
 594
 595 ;; True if A is real and positive.  [P n] [Public]
 596 ;;;###autoload
 597 (defun math-posp (a)
 598   (if (consp a)
 599       (cond ((eq (car a) 'bigpos) (cdr a))
 600             ((eq (car a) 'bigneg) nil)
 601             ((memq (car a) '(float frac))
 602              (Math-integer-posp (nth 1 a)))
 603             ((eq (car a) 'hms)
 604              (if (math-zerop (nth 1 a))
 605                  (if (math-zerop (nth 2 a))
 606                      (math-posp (nth 3 a))
 607                    (math-posp (nth 2 a)))
 608                (math-posp (nth 1 a))))
 609             ((eq (car a) 'date)
 610              (math-posp (nth 1 a)))
 611             ((eq (car a) 'mod)
 612              (not (math-zerop (nth 1 a))))
 613             ((eq (car a) 'intv)
 614              (or (math-posp (nth 2 a))
 615                  (and (math-zerop (nth 2 a))
 616                       (memq (nth 1 a) '(0 1)))))
 617             ((equal a '(var inf var-inf)) t))
 618     (> a 0)))
 619
 620 ;;;###autoload
 621 (defalias 'math-fixnump 'integerp)
 622 ;;;###autoload
 623 (defalias 'math-fixnatnump 'natnump)
 624
 625
 626 ;; True if A is an even integer.  [P R R] [Public]
 627 ;;;###autoload
 628 (defun math-evenp (a)
 629   (if (consp a)
 630       (and (memq (car a) '(bigpos bigneg))
 631            (= (% (nth 1 a) 2) 0))
 632     (= (% a 2) 0)))
 633
 634 ;; Compute A / 2, for small or big integer A.  [I i]
 635 ;; If A is negative, type of truncation is undefined.
 636 ;;;###autoload
 637 (defun math-div2 (a)
 638   (if (consp a)
 639       (if (cdr a)
 640           (math-normalize (cons (car a) (math-div2-bignum (cdr a))))
 641         0)
 642     (/ a 2)))
 643
 644 ;;;###autoload
 645 (defun math-div2-bignum (a)   ; [l l]
 646   (if (cdr a)
 647       (cons (+ (/ (car a) 2) (* (% (nth 1 a) 2) (/ math-bignum-digit-size 2)))
 648             (math-div2-bignum (cdr a)))
 649     (list (/ (car a) 2))))
 650
 651
 652 ;; Reject an argument to a calculator function.  [Public]
 653 ;;;###autoload
 654 (defun math-reject-arg (&optional a p option)
 655   (if option
 656       (calc-record-why option p a)
 657     (if p
 658         (calc-record-why p a)))
 659   (signal 'wrong-type-argument (and a (if p (list p a) (list a)))))
 660
 661
 662 ;; Coerce A to be an integer (by truncation toward zero).  [I N] [Public]
 663
 664 ;; The variable math-trunc-prec is local to math-trunc, but used by
 665 ;; math-trunc-fancy in calc-arith.el, which is called by math-trunc.
 666
 667 ;;;###autoload
 668 (defun math-trunc (a &optional math-trunc-prec)
 669   (cond (math-trunc-prec
 670          (require 'calc-ext)
 671          (math-trunc-special a math-trunc-prec))
 672         ((Math-integerp a) a)
 673         ((Math-looks-negp a)
 674          (math-neg (math-trunc (math-neg a))))
 675         ((eq (car a) 'float)
 676          (math-scale-int (nth 1 a) (nth 2 a)))
 677         (t (require 'calc-ext)
 678            (math-trunc-fancy a))))
 679 ;;;###autoload
 680 (defalias 'calcFunc-trunc 'math-trunc)
 681
 682 ;; Coerce A to be an integer (by truncation toward minus infinity).  [I N]
 683
 684 ;; The variable math-floor-prec is local to math-floor, but used by
 685 ;; math-floor-fancy in calc-arith.el, which is called by math-floor.
 686
 687 ;;;###autoload
 688 (defun math-floor (a &optional math-floor-prec)    ;  [Public]
 689   (cond (math-floor-prec
 690          (require 'calc-ext)
 691          (math-floor-special a math-floor-prec))
 692         ((Math-integerp a) a)
 693         ((Math-messy-integerp a) (math-trunc a))
 694         ((Math-realp a)
 695          (if (Math-negp a)
 696              (math-add (math-trunc a) -1)
 697            (math-trunc a)))
 698         (t (require 'calc-ext)
 699            (math-floor-fancy a))))
 700 ;;;###autoload
 701 (defalias 'calcFunc-floor 'math-floor)
 702
 703
 704 ;;;###autoload
 705 (defun math-imod (a b)   ; [I I I] [Public]
 706   (if (and (not (consp a)) (not (consp b)))
 707       (if (= b 0)
 708           (math-reject-arg a "*Division by zero")
 709         (% a b))
 710     (cdr (math-idivmod a b))))
 711
 712
 713 ;;;###autoload
 714 (defun calcFunc-inv (m)
 715   (if (Math-vectorp m)
 716       (progn
 717         (require 'calc-ext)
 718         (if (math-square-matrixp m)
 719             (or (math-with-extra-prec 2 (math-matrix-inv-raw m))
 720                 (math-reject-arg m "*Singular matrix"))
 721           (math-reject-arg m 'square-matrixp)))
 722     (if (and
 723          (require 'calc-arith)
 724          (math-known-matrixp m))
 725         (math-pow m -1)
 726       (math-div 1 m))))
 727
 728 ;;;###autoload
 729 (defun math-do-working (msg arg)
 730   (or executing-kbd-macro
 731       (progn
 732         (calc-set-command-flag 'clear-message)
 733         (if math-working-step
 734             (if math-working-step-2
 735                 (setq msg (format "[%d/%d] %s"
 736                                   math-working-step math-working-step-2 msg))
 737               (setq msg (format "[%d] %s" math-working-step msg))))
 738         (message "Working... %s = %s" msg
 739                  (math-showing-full-precision (math-format-number arg))))))
 740
 741
 742 ;; Compute A modulo B, defined in terms of truncation toward minus infinity.
 743 ;;;###autoload
 744 (defun math-mod (a b)   ; [R R R] [Public]
 745   (cond ((and (Math-zerop a) (not (eq (car-safe a) 'mod))) a)
 746         ((Math-zerop b)
 747          (math-reject-arg a "*Division by zero"))
 748         ((and (Math-natnump a) (Math-natnump b))
 749          (math-imod a b))
 750         ((and (Math-anglep a) (Math-anglep b))
 751          (math-sub a (math-mul (math-floor (math-div a b)) b)))
 752         (t (require 'calc-ext)
 753            (math-mod-fancy a b))))
 754
 755
 756
 757 ;;; General exponentiation.
 758
 759 ;;;###autoload
 760 (defun math-pow (a b)   ; [O O N] [Public]
 761   (cond ((equal b '(var nan var-nan))
 762          b)
 763         ((Math-zerop a)
 764          (if (and (Math-scalarp b) (Math-posp b))
 765              (if (math-floatp b) (math-float a) a)
 766            (require 'calc-ext)
 767            (math-pow-of-zero a b)))
 768         ((or (eq a 1) (eq b 1)) a)
 769         ((or (equal a '(float 1 0)) (equal b '(float 1 0))) a)
 770         ((Math-zerop b)
 771          (if (Math-scalarp a)
 772              (if (or (math-floatp a) (math-floatp b))
 773                  '(float 1 0) 1)
 774            (require 'calc-ext)
 775            (math-pow-zero a b)))
 776         ((and (Math-integerp b) (or (Math-numberp a) (Math-vectorp a)))
 777          (if (and (equal a '(float 1 1)) (integerp b))
 778              (math-make-float 1 b)
 779            (math-with-extra-prec 2
 780              (math-ipow a b))))
 781         (t
 782          (require 'calc-ext)
 783          (math-pow-fancy a b))))
 784
 785 ;;;###autoload
 786 (defun math-ipow (a n)   ; [O O I] [Public]
 787   (cond ((Math-integer-negp n)
 788          (math-ipow (math-div 1 a) (Math-integer-neg n)))
 789         ((not (consp n))
 790          (if (and (Math-ratp a) (> n 20))
 791              (math-iipow-show a n)
 792            (math-iipow a n)))
 793         ((math-evenp n)
 794          (math-ipow (math-mul a a) (math-div2 n)))
 795         (t
 796          (math-mul a (math-ipow (math-mul a a)
 797                                 (math-div2 (math-add n -1)))))))
 798
 799 (defun math-iipow (a n)   ; [O O S]
 800   (cond ((= n 0) 1)
 801         ((= n 1) a)
 802         ((= (% n 2) 0) (math-iipow (math-mul a a) (/ n 2)))
 803         (t (math-mul a (math-iipow (math-mul a a) (/ n 2))))))
 804
 805 (defun math-iipow-show (a n)   ; [O O S]
 806   (math-working "pow" a)
 807   (let ((val (cond
 808               ((= n 0) 1)
 809               ((= n 1) a)
 810               ((= (% n 2) 0) (math-iipow-show (math-mul a a) (/ n 2)))
 811               (t (math-mul a (math-iipow-show (math-mul a a) (/ n 2)))))))
 812     (math-working "pow" val)
 813     val))
 814
 815
 816 ;;;###autoload
 817 (defun math-read-radix-digit (dig)   ; [D S; Z S]
 818   (if (> dig ?9)
 819       (if (< dig ?A)
 820           nil
 821         (- dig 55))
 822     (if (>= dig ?0)
 823         (- dig ?0)
 824       nil)))
 825
 826
 827 ;;; Bug reporting
 828
 829 ;;;###autoload
 830 (defun report-calc-bug ()
 831   "Report a bug in Calc, the GNU Emacs calculator.
 832 Prompts for bug subject.  Leaves you in a mail buffer."
 833   (interactive)
 834   (let ((reporter-prompt-for-summary-p t))
 835     (reporter-submit-bug-report calc-bug-address "Calc"
 836                                 nil nil nil
 837                                 "Please describe exactly what actions triggered the bug and the
 838 precise symptoms of the bug.  If possible, include a backtrace by
 839 doing 'M-x toggle-debug-on-error', then reproducing the bug.
 840 " )))
 841 ;;;###autoload
 842 (defalias 'calc-report-bug 'report-calc-bug)
 843
 844 (provide 'calc-misc)
 845
 846 ;; Local variables:
 847 ;; generated-autoload-file: "calc-loaddefs.el"
 848 ;; End:
 849
 850 ;; arch-tag: 7984d9d0-62e5-41dc-afb8-e904b975f250
 851 ;;; calc-misc.el ends here