lisp/tar-mode.el

   1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
   2
   3 ;; Copyright (C) 1990,91,93,94,95,96,97,98,99,2000,2001
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 04 Apr 1990
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package attempts to make dealing with Unix 'tar' archives easier.
  31 ;; When this code is loaded, visiting a file whose name ends in '.tar' will
  32 ;; cause the contents of that archive file to be displayed in a Dired-like
  33 ;; listing.  It is then possible to use the customary Dired keybindings to
  34 ;; extract sub-files from that archive, either by reading them into their own
  35 ;; editor buffers, or by copying them directly to arbitrary files on disk.
  36 ;; It is also possible to delete sub-files from within the tar file and write
  37 ;; the modified archive back to disk, or to edit sub-files within the archive
  38 ;; and re-insert the modified files into the archive.  See the documentation
  39 ;; string of tar-mode for more info.
  40
  41 ;; This code now understands the extra fields that GNU tar adds to tar files.
  42
  43 ;; This interacts correctly with "uncompress.el" in the Emacs library,
  44 ;; which you get with
  45 ;;
  46 ;;  (autoload 'uncompress-while-visiting "uncompress")
  47 ;;  (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
  48 ;;                         auto-mode-alist))
  49 ;;
  50 ;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
  51
  52 ;;    ***************   TO DO   ***************
  53 ;;
  54 ;; o  chmod should understand "a+x,og-w".
  55 ;;
  56 ;; o  It's not possible to add a NEW file to a tar archive; not that
  57 ;;    important, but still...
  58 ;;
  59 ;; o  The code is less efficient that it could be - in a lot of places, I
  60 ;;    pull a 512-character string out of the buffer and parse it, when I could
  61 ;;    be parsing it in place, not garbaging a string.  Should redo that.
  62 ;;
  63 ;; o  I'd like a command that searches for a string/regexp in every subfile
  64 ;;    of an archive, where <esc> would leave you in a subfile-edit buffer.
  65 ;;    (Like the Meta-R command of the Zmacs mail reader.)
  66 ;;
  67 ;; o  Sometimes (but not always) reverting the tar-file buffer does not
  68 ;;    re-grind the listing, and you are staring at the binary tar data.
  69 ;;    Typing 'g' again immediately after that will always revert and re-grind
  70 ;;    it, though.  I have no idea why this happens.
  71 ;;
  72 ;; o  Tar-mode interacts poorly with crypt.el and zcat.el because the tar
  73 ;;    write-file-hook actually writes the file.  Instead it should remove the
  74 ;;    header (and conspire to put it back afterwards) so that other write-file
  75 ;;    hooks which frob the buffer have a chance to do their dirty work.  There
  76 ;;    might be a problem if the tar write-file-hook does not come *first* on
  77 ;;    the list.
  78 ;;
  79 ;; o  Block files, sparse files, continuation files, and the various header
  80 ;;    types aren't editable.  Actually I don't know that they work at all.
  81
  82 ;; Rationale:
  83
  84 ;; Why does tar-mode edit the file itself instead of using tar?
  85
  86 ;; That means that you can edit tar files which you don't have room for
  87 ;; on your local disk.
  88
  89 ;; I don't know about recent features in gnu tar, but old versions of tar
  90 ;; can't replace a file in the middle of a tar file with a new version.
  91 ;; Tar-mode can.  I don't think tar can do things like chmod the subfiles.
  92 ;; An implementation which involved unpacking and repacking the file into
  93 ;; some scratch directory would be very wasteful, and wouldn't be able to
  94 ;; preserve the file owners.
  95
  96 ;;; Code:
  97
  98 (defgroup tar nil
  99   "Simple editing of tar files."
 100   :prefix "tar-"
 101   :group 'data)
 102
 103 (defcustom tar-anal-blocksize 20
 104   "*The blocksize of tar files written by Emacs, or nil, meaning don't care.
 105 The blocksize of a tar file is not really the size of the blocks; rather, it is
 106 the number of blocks written with one system call.  When tarring to a tape,
 107 this is the size of the *tape* blocks, but when writing to a file, it doesn't
 108 matter much.  The only noticeable difference is that if a tar file does not
 109 have a blocksize of 20, tar will tell you that; all this really controls is
 110 how many null padding bytes go on the end of the tar file."
 111   :type '(choice integer (const nil))
 112   :group 'tar)
 113
 114 (defcustom tar-update-datestamp nil
 115   "*Non-nil means Tar mode should play fast and loose with sub-file datestamps.
 116 If this is true, then editing and saving a tar file entry back into its
 117 tar file will update its datestamp.  If false, the datestamp is unchanged.
 118 You may or may not want this - it is good in that you can tell when a file
 119 in a tar archive has been changed, but it is bad for the same reason that
 120 editing a file in the tar archive at all is bad - the changed version of
 121 the file never exists on disk."
 122   :type 'boolean
 123   :group 'tar)
 124
 125 (defcustom tar-mode-show-date nil
 126   "*Non-nil means Tar mode should show the date/time of each subfile.
 127 This information is useful, but it takes screen space away from file names."
 128   :type 'boolean
 129   :group 'tar)
 130
 131 (defvar tar-parse-info nil)
 132 ;; Be sure that this variable holds byte position, not char position.
 133 (defvar tar-header-offset nil)
 134 (defvar tar-superior-buffer nil)
 135 (defvar tar-superior-descriptor nil)
 136 (defvar tar-subfile-mode nil)
 137
 138 (put 'tar-parse-info 'permanent-local t)
 139 (put 'tar-header-offset 'permanent-local t)
 140 (put 'tar-superior-buffer 'permanent-local t)
 141 (put 'tar-superior-descriptor 'permanent-local t)
 142 \f
 143 (defmacro tar-setf (form val)
 144   "A mind-numbingly simple implementation of setf."
 145   (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
 146                                       byte-compile-macro-environment))))
 147     (cond ((symbolp mform) (list 'setq mform val))
 148           ((not (consp mform)) (error "can't setf %s" form))
 149           ((eq (car mform) 'aref)
 150            (list 'aset (nth 1 mform) (nth 2 mform) val))
 151           ((eq (car mform) 'car)
 152            (list 'setcar (nth 1 mform) val))
 153           ((eq (car mform) 'cdr)
 154            (list 'setcdr (nth 1 mform) val))
 155           (t (error "don't know how to setf %s" form)))))
 156 \f
 157 ;;; down to business.
 158
 159 (defmacro make-tar-header (name mode uid git size date ck lt ln
 160                            magic uname gname devmaj devmin)
 161   (list 'vector name mode uid git size date ck lt ln
 162         magic uname gname devmaj devmin))
 163
 164 (defmacro tar-header-name (x) (list 'aref x 0))
 165 (defmacro tar-header-mode (x) (list 'aref x 1))
 166 (defmacro tar-header-uid  (x) (list 'aref x 2))
 167 (defmacro tar-header-gid  (x) (list 'aref x 3))
 168 (defmacro tar-header-size (x) (list 'aref x 4))
 169 (defmacro tar-header-date (x) (list 'aref x 5))
 170 (defmacro tar-header-checksum  (x) (list 'aref x 6))
 171 (defmacro tar-header-link-type (x) (list 'aref x 7))
 172 (defmacro tar-header-link-name (x) (list 'aref x 8))
 173 (defmacro tar-header-magic (x) (list 'aref x 9))
 174 (defmacro tar-header-uname (x) (list 'aref x 10))
 175 (defmacro tar-header-gname (x) (list 'aref x 11))
 176 (defmacro tar-header-dmaj (x) (list 'aref x 12))
 177 (defmacro tar-header-dmin (x) (list 'aref x 13))
 178
 179 (defmacro make-tar-desc (data-start tokens)
 180   (list 'cons data-start tokens))
 181
 182 (defmacro tar-desc-data-start (x) (list 'car x))
 183 (defmacro tar-desc-tokens     (x) (list 'cdr x))
 184
 185 (defconst tar-name-offset 0)
 186 (defconst tar-mode-offset (+ tar-name-offset 100))
 187 (defconst tar-uid-offset  (+ tar-mode-offset 8))
 188 (defconst tar-gid-offset  (+ tar-uid-offset 8))
 189 (defconst tar-size-offset (+ tar-gid-offset 8))
 190 (defconst tar-time-offset (+ tar-size-offset 12))
 191 (defconst tar-chk-offset  (+ tar-time-offset 12))
 192 (defconst tar-linkp-offset (+ tar-chk-offset 8))
 193 (defconst tar-link-offset (+ tar-linkp-offset 1))
 194 ;;; GNU-tar specific slots.
 195 (defconst tar-magic-offset (+ tar-link-offset 100))
 196 (defconst tar-uname-offset (+ tar-magic-offset 8))
 197 (defconst tar-gname-offset (+ tar-uname-offset 32))
 198 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
 199 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
 200 (defconst tar-end-offset (+ tar-dmin-offset 8))
 201
 202 (defun tar-header-block-tokenize (string)
 203   "Return a `tar-header' structure.
 204 This is a list of name, mode, uid, gid, size,
 205 write-date, checksum, link-type, and link-name."
 206   (cond ((< (length string) 512) nil)
 207         (;(some 'plusp string)           ; <-- oops, massive cycle hog!
 208          (or (not (= 0 (aref string 0))) ; This will do.
 209              (not (= 0 (aref string 101))))
 210          (let* ((name-end (1- tar-mode-offset))
 211                 (link-end (1- tar-magic-offset))
 212                 (uname-end (1- tar-gname-offset))
 213                 (gname-end (1- tar-dmaj-offset))
 214                 (link-p (aref string tar-linkp-offset))
 215                 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
 216                 (uname-valid-p (or (string= "ustar  " magic-str) (string= "GNUtar " magic-str)))
 217                 name linkname
 218                 (nulsexp   "[^\000]*\000"))
 219            (when (string-match nulsexp string tar-name-offset)
 220              (setq name-end (min name-end (1- (match-end 0)))))
 221            (when (string-match nulsexp string tar-link-offset)
 222              (setq link-end (min link-end (1- (match-end 0)))))
 223            (when (string-match nulsexp string tar-uname-offset)
 224              (setq uname-end (min uname-end (1- (match-end 0)))))
 225            (when (string-match nulsexp string tar-gname-offset)
 226              (setq gname-end (min gname-end (1- (match-end 0)))))
 227            (setq name (substring string tar-name-offset name-end)
 228                  link-p (if (or (= link-p 0) (= link-p ?0))
 229                             nil
 230                           (- link-p ?0)))
 231            (setq linkname (substring string tar-link-offset link-end))
 232            (if default-enable-multibyte-characters
 233                (setq name
 234                      (decode-coding-string name (or file-name-coding-system
 235                                                     'undecided))
 236                      linkname
 237                      (decode-coding-string linkname (or file-name-coding-system
 238                                                         'undecided))))
 239            (if (and (null link-p) (string-match "/$" name)) (setq link-p 5)) ; directory
 240            (make-tar-header
 241              name
 242              (tar-parse-octal-integer string tar-mode-offset tar-uid-offset)
 243              (tar-parse-octal-integer string tar-uid-offset tar-gid-offset)
 244              (tar-parse-octal-integer string tar-gid-offset tar-size-offset)
 245              (tar-parse-octal-integer string tar-size-offset tar-time-offset)
 246              (tar-parse-octal-long-integer string tar-time-offset tar-chk-offset)
 247              (tar-parse-octal-integer string tar-chk-offset tar-linkp-offset)
 248              link-p
 249              linkname
 250              uname-valid-p
 251              (and uname-valid-p (substring string tar-uname-offset uname-end))
 252              (and uname-valid-p (substring string tar-gname-offset gname-end))
 253              (tar-parse-octal-integer string tar-dmaj-offset tar-dmin-offset)
 254              (tar-parse-octal-integer string tar-dmin-offset tar-end-offset)
 255              )))
 256         (t 'empty-tar-block)))
 257
 258
 259 (defun tar-parse-octal-integer (string &optional start end)
 260   (if (null start) (setq start 0))
 261   (if (null end) (setq end (length string)))
 262   (if (= (aref string start) 0)
 263       0
 264     (let ((n 0))
 265       (while (< start end)
 266         (setq n (if (< (aref string start) ?0) n
 267                   (+ (* n 8) (- (aref string start) ?0)))
 268               start (1+ start)))
 269       n)))
 270
 271 (defun tar-parse-octal-long-integer (string &optional start end)
 272   (if (null start) (setq start 0))
 273   (if (null end) (setq end (length string)))
 274   (if (= (aref string start) 0)
 275       (list 0 0)
 276     (let ((lo 0)
 277           (hi 0))
 278       (while (< start end)
 279         (if (>= (aref string start) ?0)
 280             (setq lo (+ (* lo 8) (- (aref string start) ?0))
 281                   hi (+ (* hi 8) (ash lo -16))
 282                   lo (logand lo 65535)))
 283         (setq start (1+ start)))
 284       (list hi lo))))
 285
 286 (defun tar-parse-octal-integer-safe (string)
 287   (let ((L (length string)))
 288     (if (= L 0) (error "empty string"))
 289     (dotimes (i L)
 290        (if (or (< (aref string i) ?0)
 291                (> (aref string i) ?7))
 292            (error "`%c' is not an octal digit"))))
 293   (tar-parse-octal-integer string))
 294
 295
 296 (defun tar-header-block-checksum (string)
 297   "Compute and return a tar-acceptable checksum for this block."
 298   (let* ((chk-field-start tar-chk-offset)
 299          (chk-field-end (+ chk-field-start 8))
 300          (sum 0)
 301          (i 0))
 302     ;; Add up all of the characters except the ones in the checksum field.
 303     ;; Add that field as if it were filled with spaces.
 304     (while (< i chk-field-start)
 305       (setq sum (+ sum (aref string i))
 306             i (1+ i)))
 307     (setq i chk-field-end)
 308     (while (< i 512)
 309       (setq sum (+ sum (aref string i))
 310             i (1+ i)))
 311     (+ sum (* 32 8))))
 312
 313 (defun tar-header-block-check-checksum (hblock desired-checksum file-name)
 314   "Beep and print a warning if the checksum doesn't match."
 315   (if (not (= desired-checksum (tar-header-block-checksum hblock)))
 316       (progn (beep) (message "Invalid checksum for file %s!" file-name))))
 317
 318 (defun tar-clip-time-string (time)
 319   (let ((str (current-time-string time)))
 320     (concat " " (substring str 4 16) (substring str 19 24))))
 321
 322 (defun tar-grind-file-mode (mode)
 323   "Construct a `-rw--r--r--' string indicating MODE.
 324 MODE should be an integer which is a file mode value."
 325   (string
 326    (if (zerop (logand 256 mode)) ?- ?r)
 327    (if (zerop (logand 128 mode)) ?- ?w)
 328    (if (zerop (logand 1024 mode)) (if (zerop (logand  64 mode)) ?- ?x) ?s)
 329    (if (zerop (logand  32 mode)) ?- ?r)
 330    (if (zerop (logand  16 mode)) ?- ?w)
 331    (if (zerop (logand 2048 mode)) (if (zerop (logand   8 mode)) ?- ?x) ?s)
 332    (if (zerop (logand   4 mode)) ?- ?r)
 333    (if (zerop (logand   2 mode)) ?- ?w)
 334    (if (zerop (logand   1 mode)) ?- ?x)))
 335
 336 (defun tar-header-block-summarize (tar-hblock &optional mod-p)
 337   "Return a line similar to the output of `tar -vtf'."
 338   (let ((name (tar-header-name tar-hblock))
 339         (mode (tar-header-mode tar-hblock))
 340         (uid (tar-header-uid tar-hblock))
 341         (gid (tar-header-gid tar-hblock))
 342         (uname (tar-header-uname tar-hblock))
 343         (gname (tar-header-gname tar-hblock))
 344         (size (tar-header-size tar-hblock))
 345         (time (tar-header-date tar-hblock))
 346         (ck (tar-header-checksum tar-hblock))
 347         (type (tar-header-link-type tar-hblock))
 348         (link-name (tar-header-link-name tar-hblock)))
 349     (format "%c%c%s%8s/%-8s%7s%s %s%s"
 350             (if mod-p ?* ? )
 351             (cond ((or (eq type nil) (eq type 0)) ?-)
 352                   ((eq type 1) ?l)      ; link
 353                   ((eq type 2) ?s)      ; symlink
 354                   ((eq type 3) ?c)      ; char special
 355                   ((eq type 4) ?b)      ; block special
 356                   ((eq type 5) ?d)      ; directory
 357                   ((eq type 6) ?p)      ; FIFO/pipe
 358                   ((eq type 20) ?*)     ; directory listing
 359                   ((eq type 29) ?M)     ; multivolume continuation
 360                   ((eq type 35) ?S)     ; sparse
 361                   ((eq type 38) ?V)     ; volume header
 362                   (t ?\ )
 363                   )
 364             (tar-grind-file-mode mode)
 365             (if (= 0 (length uname)) uid uname)
 366             (if (= 0 (length gname)) gid gname)
 367             size
 368             (if tar-mode-show-date (tar-clip-time-string time) "")
 369             (propertize name
 370                         'mouse-face 'highlight
 371                         'help-echo "mouse-2: extract this file into a buffer")
 372             (if (or (eq type 1) (eq type 2))
 373                 (concat (if (= type 1) " ==> " " --> ") link-name)
 374               ""))))
 375
 376 (defun tar-summarize-buffer ()
 377   "Parse the contents of the tar file in the current buffer.
 378 Place a dired-like listing on the front;
 379 then narrow to it, so that only that listing
 380 is visible (and the real data of the buffer is hidden)."
 381   (set-buffer-multibyte nil)
 382   (message "Parsing tar file...")
 383   (let* ((result '())
 384          (pos 1)
 385          (bs (max 1 (- (buffer-size) 1024))) ; always 2+ empty blocks at end.
 386          (bs100 (max 1 (/ bs 100)))
 387          tokens)
 388     (while (and (<= (+ pos 512) (point-max))
 389                 (not (eq 'empty-tar-block
 390                          (setq tokens
 391                                (tar-header-block-tokenize
 392                                 (buffer-substring pos (+ pos 512)))))))
 393       (setq pos (+ pos 512))
 394       (message "Parsing tar file...%d%%"
 395                ;(/ (* pos 100) bs)   ; this gets round-off lossage
 396                (/ pos bs100)         ; this doesn't
 397                )
 398       (if (eq (tar-header-link-type tokens) 20)
 399           ;; Foo.  There's an extra empty block after these.
 400           (setq pos (+ pos 512)))
 401       (let ((size (tar-header-size tokens)))
 402         (if (< size 0)
 403             (error "%s has size %s - corrupted"
 404                    (tar-header-name tokens) size))
 405         ;
 406         ; This is just too slow.  Don't really need it anyway....
 407         ;(tar-header-block-check-checksum
 408         ;  hblock (tar-header-block-checksum hblock)
 409         ;  (tar-header-name tokens))
 410
 411         (setq result (cons (make-tar-desc pos tokens) result))
 412
 413         (and (null (tar-header-link-type tokens))
 414              (> size 0)
 415              (setq pos
 416                    (+ pos 512 (ash (ash (1- size) -9) 9))        ; this works
 417                    ;(+ pos (+ size (- 512 (rem (1- size) 512)))) ; this doesn't
 418                    ))))
 419     (make-local-variable 'tar-parse-info)
 420     (setq tar-parse-info (nreverse result))
 421     ;; A tar file should end with a block or two of nulls,
 422     ;; but let's not get a fatal error if it doesn't.
 423     (if (eq tokens 'empty-tar-block)
 424         (message "Parsing tar file...done")
 425       (message "Warning: premature EOF parsing tar file")))
 426   (save-excursion
 427     (goto-char (point-min))
 428     (let ((buffer-read-only nil)
 429           (summaries nil))
 430       ;; Collect summary lines and insert them all at once since tar files
 431       ;; can be pretty big.
 432       (dolist (tar-desc (reverse tar-parse-info))
 433         (setq summaries
 434               (cons (tar-header-block-summarize (tar-desc-tokens tar-desc))
 435                     (cons "\n"
 436                           summaries))))
 437       (let ((total-summaries (apply 'concat summaries)))
 438         (if (multibyte-string-p total-summaries)
 439             (set-buffer-multibyte t))
 440         (insert total-summaries))
 441       (make-local-variable 'tar-header-offset)
 442       (setq tar-header-offset (point))
 443       (narrow-to-region 1 tar-header-offset)
 444       (if enable-multibyte-characters
 445           (setq tar-header-offset (position-bytes tar-header-offset)))
 446       (set-buffer-modified-p nil))))
 447 \f
 448 (defvar tar-mode-map nil "*Local keymap for Tar mode listings.")
 449
 450 (if tar-mode-map
 451     nil
 452   (setq tar-mode-map (make-keymap))
 453   (suppress-keymap tar-mode-map)
 454   (define-key tar-mode-map " " 'tar-next-line)
 455   (define-key tar-mode-map "C" 'tar-copy)
 456   (define-key tar-mode-map "d" 'tar-flag-deleted)
 457   (define-key tar-mode-map "\^D" 'tar-flag-deleted)
 458   (define-key tar-mode-map "e" 'tar-extract)
 459   (define-key tar-mode-map "f" 'tar-extract)
 460   (define-key tar-mode-map "\C-m" 'tar-extract)
 461   (define-key tar-mode-map [mouse-2] 'tar-mouse-extract)
 462   (define-key tar-mode-map "g" 'revert-buffer)
 463   (define-key tar-mode-map "h" 'describe-mode)
 464   (define-key tar-mode-map "n" 'tar-next-line)
 465   (define-key tar-mode-map "\^N" 'tar-next-line)
 466   (define-key tar-mode-map [down] 'tar-next-line)
 467   (define-key tar-mode-map "o" 'tar-extract-other-window)
 468   (define-key tar-mode-map "p" 'tar-previous-line)
 469   (define-key tar-mode-map "q" 'quit-window)
 470   (define-key tar-mode-map "\^P" 'tar-previous-line)
 471   (define-key tar-mode-map [up] 'tar-previous-line)
 472   (define-key tar-mode-map "R" 'tar-rename-entry)
 473   (define-key tar-mode-map "u" 'tar-unflag)
 474   (define-key tar-mode-map "v" 'tar-view)
 475   (define-key tar-mode-map "x" 'tar-expunge)
 476   (define-key tar-mode-map "\177" 'tar-unflag-backwards)
 477   (define-key tar-mode-map "E" 'tar-extract-other-window)
 478   (define-key tar-mode-map "M" 'tar-chmod-entry)
 479   (define-key tar-mode-map "G" 'tar-chgrp-entry)
 480   (define-key tar-mode-map "O" 'tar-chown-entry)
 481   )
 482 \f
 483 ;; Make menu bar items.
 484
 485 ;; Get rid of the Edit menu bar item to save space.
 486 (define-key tar-mode-map [menu-bar edit] 'undefined)
 487
 488 (define-key tar-mode-map [menu-bar immediate]
 489   (cons "Immediate" (make-sparse-keymap "Immediate")))
 490
 491 (define-key tar-mode-map [menu-bar immediate view]
 492   '("View This File" . tar-view))
 493 (define-key tar-mode-map [menu-bar immediate display]
 494   '("Display in Other Window" . tar-display-other-window))
 495 (define-key tar-mode-map [menu-bar immediate find-file-other-window]
 496   '("Find in Other Window" . tar-extract-other-window))
 497 (define-key tar-mode-map [menu-bar immediate find-file]
 498   '("Find This File" . tar-extract))
 499
 500 (define-key tar-mode-map [menu-bar mark]
 501   (cons "Mark" (make-sparse-keymap "Mark")))
 502
 503 (define-key tar-mode-map [menu-bar mark unmark-all]
 504   '("Unmark All" . tar-clear-modification-flags))
 505 (define-key tar-mode-map [menu-bar mark deletion]
 506   '("Flag" . tar-flag-deleted))
 507 (define-key tar-mode-map [menu-bar mark unmark]
 508   '("Unflag" . tar-unflag))
 509
 510 (define-key tar-mode-map [menu-bar operate]
 511   (cons "Operate" (make-sparse-keymap "Operate")))
 512
 513 (define-key tar-mode-map [menu-bar operate chown]
 514   '("Change Owner..." . tar-chown-entry))
 515 (define-key tar-mode-map [menu-bar operate chgrp]
 516   '("Change Group..." . tar-chgrp-entry))
 517 (define-key tar-mode-map [menu-bar operate chmod]
 518   '("Change Mode..." . tar-chmod-entry))
 519 (define-key tar-mode-map [menu-bar operate rename]
 520   '("Rename to..." . tar-rename-entry))
 521 (define-key tar-mode-map [menu-bar operate copy]
 522   '("Copy to..." . tar-copy))
 523 (define-key tar-mode-map [menu-bar operate expunge]
 524   '("Expunge Marked Files" . tar-expunge))
 525 \f
 526 ;; tar mode is suitable only for specially formatted data.
 527 (put 'tar-mode 'mode-class 'special)
 528 (put 'tar-subfile-mode 'mode-class 'special)
 529
 530 ;;;###autoload
 531 (defun tar-mode ()
 532   "Major mode for viewing a tar file as a dired-like listing of its contents.
 533 You can move around using the usual cursor motion commands.
 534 Letters no longer insert themselves.
 535 Type `e' to pull a file out of the tar file and into its own buffer;
 536 or click mouse-2 on the file's line in the Tar mode buffer.
 537 Type `c' to copy an entry from the tar file into another file on disk.
 538
 539 If you edit a sub-file of this archive (as with the `e' command) and
 540 save it with Control-x Control-s, the contents of that buffer will be
 541 saved back into the tar-file buffer; in this way you can edit a file
 542 inside of a tar archive without extracting it and re-archiving it.
 543
 544 See also: variables `tar-update-datestamp' and `tar-anal-blocksize'.
 545 \\{tar-mode-map}"
 546   ;; this is not interactive because you shouldn't be turning this
 547   ;; mode on and off.  You can corrupt things that way.
 548   ;; rms: with permanent locals, it should now be possible to make this work
 549   ;; interactively in some reasonable fashion.
 550   (kill-all-local-variables)
 551   (make-local-variable 'tar-header-offset)
 552   (make-local-variable 'tar-parse-info)
 553   (make-local-variable 'require-final-newline)
 554   (setq require-final-newline nil) ; binary data, dude...
 555   (make-local-variable 'revert-buffer-function)
 556   (setq revert-buffer-function 'tar-mode-revert)
 557   (make-local-variable 'local-enable-local-variables)
 558   (setq local-enable-local-variables nil)
 559   (make-local-variable 'next-line-add-newlines)
 560   (setq next-line-add-newlines nil)
 561   ;; Prevent loss of data when saving the file.
 562   (make-local-variable 'file-precious-flag)
 563   (setq file-precious-flag t)
 564   (setq major-mode 'tar-mode)
 565   (setq mode-name "Tar")
 566   (use-local-map tar-mode-map)
 567   (auto-save-mode 0)
 568   (make-local-variable 'write-contents-hooks)
 569   (setq write-contents-hooks '(tar-mode-write-file))
 570   (widen)
 571   (if (and (boundp 'tar-header-offset) tar-header-offset)
 572       (narrow-to-region 1 (byte-to-position tar-header-offset))
 573       (tar-summarize-buffer)
 574       (tar-next-line 0))
 575   (run-hooks 'tar-mode-hook)
 576   )
 577
 578
 579 (defun tar-subfile-mode (p)
 580   "Minor mode for editing an element of a tar-file.
 581 This mode arranges for \"saving\" this buffer to write the data
 582 into the tar-file buffer that it came from.  The changes will actually
 583 appear on disk when you save the tar-file's buffer."
 584   (interactive "P")
 585   (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
 586       (error "This buffer is not an element of a tar file"))
 587 ;;; Don't do this, because it is redundant and wastes mode line space.
 588 ;;;  (or (assq 'tar-subfile-mode minor-mode-alist)
 589 ;;;      (setq minor-mode-alist (append minor-mode-alist
 590 ;;;                                  (list '(tar-subfile-mode " TarFile")))))
 591   (make-local-variable 'tar-subfile-mode)
 592   (setq tar-subfile-mode
 593         (if (null p)
 594             (not tar-subfile-mode)
 595             (> (prefix-numeric-value p) 0)))
 596   (cond (tar-subfile-mode
 597          (make-local-variable 'local-write-file-hooks)
 598          (setq local-write-file-hooks '(tar-subfile-save-buffer))
 599          ;; turn off auto-save.
 600          (auto-save-mode -1)
 601          (setq buffer-auto-save-file-name nil)
 602          (run-hooks 'tar-subfile-mode-hook))
 603         (t
 604          (kill-local-variable 'local-write-file-hooks))))
 605
 606
 607 ;; Revert the buffer and recompute the dired-like listing.
 608 (defun tar-mode-revert (&optional no-auto-save no-confirm)
 609   (let ((revert-buffer-function nil)
 610         (old-offset tar-header-offset)
 611         success)
 612     (setq tar-header-offset nil)
 613     (unwind-protect
 614         (and (revert-buffer t no-confirm)
 615              (progn (widen)
 616                     (setq success t)
 617                     (tar-mode)))
 618       ;; If the revert was canceled,
 619       ;; put back the old value of tar-header-offset.
 620       (or success
 621           (setq tar-header-offset old-offset)))))
 622
 623
 624 (defun tar-next-line (p)
 625   (interactive "p")
 626   (forward-line p)
 627   (if (eobp) nil (forward-char (if tar-mode-show-date 54 36))))
 628
 629 (defun tar-previous-line (p)
 630   (interactive "p")
 631   (tar-next-line (- p)))
 632
 633 (defun tar-current-descriptor (&optional noerror)
 634   "Return the tar-descriptor of the current line, or signals an error."
 635   ;; I wish lines had plists, like in ZMACS...
 636   (or (nth (count-lines (point-min)
 637                         (save-excursion (beginning-of-line) (point)))
 638            tar-parse-info)
 639       (if noerror
 640           nil
 641           (error "This line does not describe a tar-file entry"))))
 642
 643 (defun tar-get-descriptor ()
 644   (let* ((descriptor (tar-current-descriptor))
 645          (tokens (tar-desc-tokens descriptor))
 646          (size (tar-header-size tokens))
 647          (link-p (tar-header-link-type tokens)))
 648     (if link-p
 649         (error "This is a %s, not a real file"
 650                (cond ((eq link-p 5) "directory")
 651                      ((eq link-p 20) "tar directory header")
 652                      ((eq link-p 29) "multivolume-continuation")
 653                      ((eq link-p 35) "sparse entry")
 654                      ((eq link-p 38) "volume header")
 655                      (t "link"))))
 656     (if (zerop size) (error "This is a zero-length file"))
 657     descriptor))
 658
 659 (defun tar-mouse-extract (event)
 660   "Extract a file whose tar directory line you click on."
 661   (interactive "e")
 662   (save-excursion
 663     (set-buffer (window-buffer (posn-window (event-end event))))
 664     (save-excursion
 665       (goto-char (posn-point (event-end event)))
 666       ;; Just make sure this doesn't get an error.
 667       (tar-get-descriptor)))
 668   (select-window (posn-window (event-end event)))
 669   (goto-char (posn-point (event-end event)))
 670   (tar-extract))
 671
 672 (defun tar-extract (&optional other-window-p)
 673   "In Tar mode, extract this entry of the tar file into its own buffer."
 674   (interactive)
 675   (let* ((view-p (eq other-window-p 'view))
 676          (descriptor (tar-get-descriptor))
 677          (tokens (tar-desc-tokens descriptor))
 678          (name (tar-header-name tokens))
 679          (size (tar-header-size tokens))
 680          (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
 681          (end (+ start size)))
 682     (let* ((tar-buffer (current-buffer))
 683            (tar-buffer-multibyte enable-multibyte-characters)
 684            (tarname (buffer-name))
 685            (bufname (concat (file-name-nondirectory name)
 686                             " ("
 687                              tarname
 688                              ")"))
 689            (read-only-p (or buffer-read-only view-p))
 690            (new-buffer-file-name (expand-file-name
 691                                   ;; `:' is not allowed on Windows
 692                                   (concat tarname "!" name)))
 693            (buffer (get-file-buffer new-buffer-file-name))
 694            (just-created nil))
 695       (unless buffer
 696         (setq buffer (generate-new-buffer bufname))
 697         (setq bufname (buffer-name buffer))
 698         (setq just-created t)
 699         (unwind-protect
 700             (progn
 701               (widen)
 702               (set-buffer-multibyte nil)
 703               (save-excursion
 704                 (set-buffer buffer)
 705                 (if enable-multibyte-characters
 706                     (progn
 707                       ;; We must avoid unibyte->multibyte conversion.
 708                       (set-buffer-multibyte nil)
 709                       (insert-buffer-substring tar-buffer start end)
 710                       (set-buffer-multibyte t))
 711                   (insert-buffer-substring tar-buffer start end))
 712                 (goto-char (point-min))
 713                 (setq buffer-file-name new-buffer-file-name)
 714                 (setq buffer-file-truename
 715                       (abbreviate-file-name buffer-file-name))
 716                 ;; We need to mimic the parts of insert-file-contents
 717                 ;; which determine the coding-system and decode the text.
 718                 (let ((coding
 719                        (or coding-system-for-read
 720                            (and set-auto-coding-function
 721                                 (save-excursion
 722                                   (funcall set-auto-coding-function
 723                                            name (- (point-max) (point)))))))
 724                       (multibyte enable-multibyte-characters)
 725                       (detected (detect-coding-region
 726                                  1 (min 16384 (point-max)) t)))
 727                   (if coding
 728                       (or (numberp (coding-system-eol-type coding))
 729                           (setq coding (coding-system-change-eol-conversion
 730                                         coding
 731                                         (coding-system-eol-type detected))))
 732                     (setq coding
 733                           (or (find-new-buffer-file-coding-system detected)
 734                               (let ((file-coding
 735                                      (find-operation-coding-system
 736                                       'insert-file-contents buffer-file-name)))
 737                                 (if (consp file-coding)
 738                                     (setq file-coding (car file-coding))
 739                                   file-coding)))))
 740                   (if (or (eq coding 'no-conversion)
 741                           (eq (coding-system-type coding) 5))
 742                       (setq multibyte (set-buffer-multibyte nil)))
 743                   (or multibyte
 744                       (setq coding
 745                             (coding-system-change-text-conversion
 746                              coding 'raw-text)))
 747                   (decode-coding-region 1 (point-max) coding)
 748                   (set-buffer-file-coding-system coding))
 749                 ;; Set the default-directory to the dir of the
 750                 ;; superior buffer.
 751                 (setq default-directory
 752                       (save-excursion
 753                         (set-buffer tar-buffer)
 754                         default-directory))
 755                 (normal-mode)  ; pick a mode.
 756                 (rename-buffer bufname)
 757                 (make-local-variable 'tar-superior-buffer)
 758                 (make-local-variable 'tar-superior-descriptor)
 759                 (setq tar-superior-buffer tar-buffer)
 760                 (setq tar-superior-descriptor descriptor)
 761                 (setq buffer-read-only read-only-p)
 762                 (set-buffer-modified-p nil)
 763                 (tar-subfile-mode 1))
 764               (set-buffer tar-buffer))
 765           (narrow-to-region 1 tar-header-offset)
 766           (set-buffer-multibyte tar-buffer-multibyte)))
 767       (if view-p
 768           (view-buffer buffer (and just-created 'kill-buffer))
 769         (if (eq other-window-p 'display)
 770             (display-buffer buffer)
 771           (if other-window-p
 772               (switch-to-buffer-other-window buffer)
 773             (switch-to-buffer buffer)))))))
 774
 775
 776 (defun tar-extract-other-window ()
 777   "*In Tar mode, find this entry of the tar file in another window."
 778   (interactive)
 779   (tar-extract t))
 780
 781 (defun tar-display-other-window ()
 782   "*In Tar mode, display this entry of the tar file in another window."
 783   (interactive)
 784   (tar-extract 'display))
 785
 786 (defun tar-view ()
 787   "*In Tar mode, view the tar file entry on this line."
 788   (interactive)
 789   (tar-extract 'view))
 790
 791
 792 (defun tar-read-file-name (&optional prompt)
 793   "Read a file name with this line's entry as the default."
 794   (or prompt (setq prompt "Copy to: "))
 795   (let* ((default-file (expand-file-name
 796                         (tar-header-name (tar-desc-tokens
 797                                           (tar-current-descriptor)))))
 798          (target (expand-file-name
 799                   (read-file-name prompt
 800                                   (file-name-directory default-file)
 801                                   default-file nil))))
 802     (if (or (string= "" (file-name-nondirectory target))
 803             (file-directory-p target))
 804         (setq target (concat (if (string-match "/$" target)
 805                                  (substring target 0 (1- (match-end 0)))
 806                                  target)
 807                              "/"
 808                              (file-name-nondirectory default-file))))
 809     target))
 810
 811
 812 (defun tar-copy (&optional to-file)
 813   "*In Tar mode, extract this entry of the tar file into a file on disk.
 814 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
 815 the current tar-entry."
 816   (interactive (list (tar-read-file-name)))
 817   (let* ((descriptor (tar-get-descriptor))
 818          (tokens (tar-desc-tokens descriptor))
 819          (name (tar-header-name tokens))
 820          (size (tar-header-size tokens))
 821          (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
 822          (end (+ start size))
 823          (multibyte enable-multibyte-characters)
 824          (inhibit-file-name-handlers inhibit-file-name-handlers)
 825          (inhibit-file-name-operation inhibit-file-name-operation))
 826     (save-restriction
 827       (widen)
 828       ;; Inhibit compressing a subfile again if *both* name and
 829       ;; to-file are handled by jka-compr
 830       (if (and (eq (find-file-name-handler name 'write-region) 'jka-compr-handler)
 831                (eq (find-file-name-handler to-file 'write-region) 'jka-compr-handler))
 832           (setq inhibit-file-name-handlers
 833                 (cons 'jka-compr-handler
 834                       (and (eq inhibit-file-name-operation 'write-region)
 835                            inhibit-file-name-handlers))
 836                 inhibit-file-name-operation 'write-region))
 837       (unwind-protect
 838           (let ((coding-system-for-write 'no-conversion))
 839             (set-buffer-multibyte nil)
 840             (write-region start end to-file nil nil nil t))
 841         (set-buffer-multibyte multibyte)))
 842     (message "Copied tar entry %s to %s" name to-file)))
 843
 844 (defun tar-flag-deleted (p &optional unflag)
 845   "*In Tar mode, mark this sub-file to be deleted from the tar file.
 846 With a prefix argument, mark that many files."
 847   (interactive "p")
 848   (beginning-of-line)
 849   (dotimes (i (if (< p 0) (- p) p))
 850     (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
 851         (progn
 852           (delete-char 1)
 853           (insert (if unflag " " "D"))))
 854     (forward-line (if (< p 0) -1 1)))
 855   (if (eobp) nil (forward-char 36)))
 856
 857 (defun tar-unflag (p)
 858   "*In Tar mode, un-mark this sub-file if it is marked to be deleted.
 859 With a prefix argument, un-mark that many files forward."
 860   (interactive "p")
 861   (tar-flag-deleted p t))
 862
 863 (defun tar-unflag-backwards (p)
 864   "*In Tar mode, un-mark this sub-file if it is marked to be deleted.
 865 With a prefix argument, un-mark that many files backward."
 866   (interactive "p")
 867   (tar-flag-deleted (- p) t))
 868
 869
 870 ;; When this function is called, it is sure that the buffer is unibyte.
 871 (defun tar-expunge-internal ()
 872   "Expunge the tar-entry specified by the current line."
 873   (let* ((descriptor (tar-current-descriptor))
 874          (tokens (tar-desc-tokens descriptor))
 875          (line (tar-desc-data-start descriptor))
 876          (name (tar-header-name tokens))
 877          (size (tar-header-size tokens))
 878          (link-p (tar-header-link-type tokens))
 879          (start (tar-desc-data-start descriptor))
 880          (following-descs (cdr (memq descriptor tar-parse-info))))
 881     (if link-p (setq size 0)) ; size lies for hard-links.
 882     ;;
 883     ;; delete the current line...
 884     (beginning-of-line)
 885     (let ((line-start (point)))
 886       (end-of-line) (forward-char)
 887       (let ((line-len (- (point) line-start)))
 888         (delete-region line-start (point))
 889         ;;
 890         ;; decrement the header-pointer to be in sync...
 891         (setq tar-header-offset (- tar-header-offset line-len))))
 892     ;;
 893     ;; delete the data pointer...
 894     (setq tar-parse-info (delq descriptor tar-parse-info))
 895     ;;
 896     ;; delete the data from inside the file...
 897     (widen)
 898     (let* ((data-start (+ start tar-header-offset -513))
 899            (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
 900       (delete-region data-start data-end)
 901       ;;
 902       ;; and finally, decrement the start-pointers of all following
 903       ;; entries in the archive.  This is a pig when deleting a bunch
 904       ;; of files at once - we could optimize this to only do the
 905       ;; iteration over the files that remain, or only iterate up to
 906       ;; the next file to be deleted.
 907       (let ((data-length (- data-end data-start)))
 908         (dolist (desc following-descs)
 909           (tar-setf (tar-desc-data-start desc)
 910                     (- (tar-desc-data-start desc) data-length))))
 911       ))
 912   (narrow-to-region 1 tar-header-offset))
 913
 914
 915 (defun tar-expunge (&optional noconfirm)
 916   "*In Tar mode, delete all the archived files flagged for deletion.
 917 This does not modify the disk image; you must save the tar file itself
 918 for this to be permanent."
 919   (interactive)
 920   (if (or noconfirm
 921           (y-or-n-p "Expunge files marked for deletion? "))
 922       (let ((n 0)
 923             (multibyte enable-multibyte-characters))
 924         (set-buffer-multibyte nil)
 925         (save-excursion
 926           (goto-char (point-min))
 927           (while (not (eobp))
 928             (if (looking-at "D")
 929                 (progn (tar-expunge-internal)
 930                        (setq n (1+ n)))
 931                 (forward-line 1)))
 932           ;; after doing the deletions, add any padding that may be necessary.
 933           (tar-pad-to-blocksize)
 934           (narrow-to-region 1 tar-header-offset))
 935         (set-buffer-multibyte multibyte)
 936         (if (zerop n)
 937             (message "Nothing to expunge.")
 938             (message "%s files expunged.  Be sure to save this buffer." n)))))
 939
 940
 941 (defun tar-clear-modification-flags ()
 942   "Remove the stars at the beginning of each line."
 943   (interactive)
 944   (save-excursion
 945     (goto-char (point-min))
 946     (while (< (position-bytes (point)) tar-header-offset)
 947       (if (not (eq (following-char) ?\ ))
 948           (progn (delete-char 1) (insert " ")))
 949       (forward-line 1))))
 950
 951
 952 (defun tar-chown-entry (new-uid)
 953   "*Change the user-id associated with this entry in the tar file.
 954 If this tar file was written by GNU tar, then you will be able to edit
 955 the user id as a string; otherwise, you must edit it as a number.
 956 You can force editing as a number by calling this with a prefix arg.
 957 This does not modify the disk image; you must save the tar file itself
 958 for this to be permanent."
 959   (interactive (list
 960                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 961                    (if (or current-prefix-arg
 962                            (not (tar-header-magic tokens)))
 963                        (let (n)
 964                          (while (not (numberp (setq n (read-minibuffer
 965                                                         "New UID number: "
 966                                                         (format "%s" (tar-header-uid tokens)))))))
 967                          n)
 968                        (read-string "New UID string: " (tar-header-uname tokens))))))
 969   (cond ((stringp new-uid)
 970          (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
 971                    new-uid)
 972          (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
 973         (t
 974          (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
 975                    new-uid)
 976          (tar-alter-one-field tar-uid-offset
 977            (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
 978
 979
 980 (defun tar-chgrp-entry (new-gid)
 981   "*Change the group-id associated with this entry in the tar file.
 982 If this tar file was written by GNU tar, then you will be able to edit
 983 the group id as a string; otherwise, you must edit it as a number.
 984 You can force editing as a number by calling this with a prefix arg.
 985 This does not modify the disk image; you must save the tar file itself
 986 for this to be permanent."
 987   (interactive (list
 988                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 989                    (if (or current-prefix-arg
 990                            (not (tar-header-magic tokens)))
 991                        (let (n)
 992                          (while (not (numberp (setq n (read-minibuffer
 993                                                         "New GID number: "
 994                                                         (format "%s" (tar-header-gid tokens)))))))
 995                          n)
 996                        (read-string "New GID string: " (tar-header-gname tokens))))))
 997   (cond ((stringp new-gid)
 998          (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
 999                    new-gid)
1000          (tar-alter-one-field tar-gname-offset
1001            (concat new-gid "\000")))
1002         (t
1003          (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
1004                    new-gid)
1005          (tar-alter-one-field tar-gid-offset
1006            (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
1007
1008 (defun tar-rename-entry (new-name)
1009   "*Change the name associated with this entry in the tar file.
1010 This does not modify the disk image; you must save the tar file itself
1011 for this to be permanent."
1012   (interactive
1013     (list (read-string "New name: "
1014             (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
1015   (if (string= "" new-name) (error "zero length name"))
1016   (if (> (length new-name) 98) (error "name too long"))
1017   (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
1018             new-name)
1019   (tar-alter-one-field 0
1020     (substring (concat new-name (make-string 99 0)) 0 99)))
1021
1022
1023 (defun tar-chmod-entry (new-mode)
1024   "*Change the protection bits associated with this entry in the tar file.
1025 This does not modify the disk image; you must save the tar file itself
1026 for this to be permanent."
1027   (interactive (list (tar-parse-octal-integer-safe
1028                        (read-string "New protection (octal): "))))
1029   (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
1030             new-mode)
1031   (tar-alter-one-field tar-mode-offset
1032     (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
1033
1034
1035 (defun tar-alter-one-field (data-position new-data-string)
1036   (let* ((descriptor (tar-current-descriptor))
1037          (tokens (tar-desc-tokens descriptor))
1038          (multibyte enable-multibyte-characters))
1039     (unwind-protect
1040         (save-excursion
1041           ;;
1042           ;; update the header-line.
1043           (beginning-of-line)
1044           (let ((p (point)))
1045             (forward-line 1)
1046             (delete-region p (point))
1047             (insert (tar-header-block-summarize tokens) "\n")
1048             (setq tar-header-offset (position-bytes (point-max))))
1049
1050           (widen)
1051           (set-buffer-multibyte nil)
1052           (let* ((start (+ (tar-desc-data-start descriptor) tar-header-offset -513)))
1053             ;;
1054             ;; delete the old field and insert a new one.
1055             (goto-char (+ start data-position))
1056             (delete-region (point) (+ (point) (length new-data-string))) ; <--
1057             (insert new-data-string) ; <--
1058             ;;
1059             ;; compute a new checksum and insert it.
1060             (let ((chk (tar-header-block-checksum
1061                         (buffer-substring start (+ start 512)))))
1062               (goto-char (+ start tar-chk-offset))
1063               (delete-region (point) (+ (point) 8))
1064               (insert (format "%6o" chk))
1065               (insert 0)
1066               (insert ? )
1067               (tar-setf (tar-header-checksum tokens) chk)
1068               ;;
1069               ;; ok, make sure we didn't botch it.
1070               (tar-header-block-check-checksum
1071                 (buffer-substring start (+ start 512))
1072                 chk (tar-header-name tokens))
1073               )))
1074       (narrow-to-region 1 tar-header-offset)
1075       (set-buffer-multibyte multibyte)
1076       (tar-next-line 0))))
1077
1078
1079 (defun tar-octal-time (timeval)
1080   ;; Format a timestamp as 11 octal digits.  Ghod, I hope this works...
1081   (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
1082     (insert (format "%05o%01o%05o"
1083                     (lsh hibits -2)
1084                     (logior (lsh (logand 3 hibits) 1) (> (logand lobits 32768) 0))
1085                     (logand 32767 lobits)
1086                     ))))
1087
1088 (defun tar-subfile-save-buffer ()
1089   "In tar subfile mode, save this buffer into its parent tar-file buffer.
1090 This doesn't write anything to disk; you must save the parent tar-file buffer
1091 to make your changes permanent."
1092   (interactive)
1093   (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
1094     (error "This buffer has no superior tar file buffer"))
1095   (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
1096     (error "This buffer doesn't have an index into its superior tar file!"))
1097   (save-excursion
1098   (let ((subfile (current-buffer))
1099         (subfile-multibyte enable-multibyte-characters)
1100         (coding buffer-file-coding-system)
1101         (descriptor tar-superior-descriptor)
1102         subfile-size)
1103     ;; We must make the current buffer unibyte temporarily to avoid
1104     ;; multibyte->unibyte conversion in `insert-buffer'.
1105     (set-buffer-multibyte nil)
1106     (setq subfile-size (buffer-size))
1107     (set-buffer tar-superior-buffer)
1108     (let* ((tokens (tar-desc-tokens descriptor))
1109            (start (tar-desc-data-start descriptor))
1110            (name (tar-header-name tokens))
1111            (size (tar-header-size tokens))
1112            (size-pad (ash (ash (+ size 511) -9) 9))
1113            (head (memq descriptor tar-parse-info))
1114            (following-descs (cdr head))
1115            (tar-buffer-multibyte enable-multibyte-characters))
1116       (if (not head)
1117         (error "Can't find this tar file entry in its parent tar file!"))
1118       (unwind-protect
1119        (save-excursion
1120         (widen)
1121         (set-buffer-multibyte nil)
1122         ;; delete the old data...
1123         (let* ((data-start (+ start tar-header-offset -1))
1124                (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
1125           (delete-region data-start data-end)
1126           ;; insert the new data...
1127           (goto-char data-start)
1128           (insert-buffer subfile)
1129           (setq subfile-size
1130                 (encode-coding-region
1131                  data-start (+ data-start subfile-size) coding))
1132           ;;
1133           ;; pad the new data out to a multiple of 512...
1134           (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
1135             (goto-char (+ data-start subfile-size))
1136             (insert (make-string (- subfile-size-pad subfile-size) 0))
1137             ;;
1138             ;; update the data pointer of this and all following files...
1139             (tar-setf (tar-header-size tokens) subfile-size)
1140             (let ((difference (- subfile-size-pad size-pad)))
1141               (dolist (desc following-descs)
1142                 (tar-setf (tar-desc-data-start desc)
1143                           (+ (tar-desc-data-start desc) difference))))
1144             ;;
1145             ;; Update the size field in the header block.
1146             (let ((header-start (- data-start 512)))
1147               (goto-char (+ header-start tar-size-offset))
1148               (delete-region (point) (+ (point) 12))
1149               (insert (format "%11o" subfile-size))
1150               (insert ? )
1151               ;;
1152               ;; Maybe update the datestamp.
1153               (if (not tar-update-datestamp)
1154                   nil
1155                 (goto-char (+ header-start tar-time-offset))
1156                 (delete-region (point) (+ (point) 12))
1157                 (insert (tar-octal-time (current-time)))
1158                 (insert ? ))
1159               ;;
1160               ;; compute a new checksum and insert it.
1161               (let ((chk (tar-header-block-checksum
1162                           (buffer-substring header-start data-start))))
1163                 (goto-char (+ header-start tar-chk-offset))
1164                 (delete-region (point) (+ (point) 8))
1165                 (insert (format "%6o" chk))
1166                 (insert 0)
1167                 (insert ? )
1168                 (tar-setf (tar-header-checksum tokens) chk)))
1169             ;;
1170             ;; alter the descriptor-line...
1171             ;;
1172             (let ((position (- (length tar-parse-info) (length head))))
1173               (goto-char (point-min))
1174               (next-line position)
1175               (beginning-of-line)
1176               (let ((p (point))
1177                     after
1178                     (m (set-marker (make-marker) tar-header-offset)))
1179                 (forward-line 1)
1180                 (setq after (point))
1181                 ;; Insert the new text after the old, before deleting,
1182                 ;; to preserve the window start.
1183                 (let ((line (tar-header-block-summarize tokens t)))
1184                   (if (multibyte-string-p line)
1185                       (insert-before-markers (string-as-unibyte line) "\n")
1186                     (insert-before-markers line "\n")))
1187                 (delete-region p after)
1188                 (setq tar-header-offset (marker-position m)))
1189               )))
1190         ;; after doing the insertion, add any final padding that may be necessary.
1191         (tar-pad-to-blocksize))
1192        (narrow-to-region 1 tar-header-offset)
1193        (set-buffer-multibyte tar-buffer-multibyte)))
1194     (set-buffer-modified-p t)   ; mark the tar file as modified
1195     (tar-next-line 0)
1196     (set-buffer subfile)
1197     ;; Restore the buffer multibyteness.
1198     (set-buffer-multibyte subfile-multibyte)
1199     (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1200     (message "Saved into tar-buffer `%s'.  Be sure to save that buffer!"
1201              (buffer-name tar-superior-buffer))
1202     ;; Prevent basic-save-buffer from changing our coding-system.
1203     (setq last-coding-system-used buffer-file-coding-system)
1204     ;; Prevent ordinary saving from happening.
1205     t)))
1206
1207
1208 ;; When this function is called, it is sure that the buffer is unibyte.
1209 (defun tar-pad-to-blocksize ()
1210   "If we are being anal about tar file blocksizes, fix up the current buffer.
1211 Leaves the region wide."
1212   (if (null tar-anal-blocksize)
1213       nil
1214     (widen)
1215     (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1216            (start (tar-desc-data-start last-desc))
1217            (tokens (tar-desc-tokens last-desc))
1218            (link-p (tar-header-link-type tokens))
1219            (size (if link-p 0 (tar-header-size tokens)))
1220            (data-end (+ start size))
1221            (bbytes (ash tar-anal-blocksize 9))
1222            (pad-to (+ bbytes (* bbytes (/ (1- data-end) bbytes))))
1223            (inhibit-read-only t) ; ##
1224            )
1225       ;; If the padding after the last data is too long, delete some;
1226       ;; else insert some until we are padded out to the right number of blocks.
1227       ;;
1228       (goto-char (+ (or tar-header-offset 0) data-end))
1229       (if (> (1+ (buffer-size)) (+ (or tar-header-offset 0) pad-to))
1230           (delete-region (+ (or tar-header-offset 0) pad-to) (1+ (buffer-size)))
1231           (insert (make-string (- (+ (or tar-header-offset 0) pad-to)
1232                                   (1+ (buffer-size)))
1233                                0)))
1234       )))
1235
1236
1237 ;; Used in write-file-hook to write tar-files out correctly.
1238 (defun tar-mode-write-file ()
1239   (unwind-protect
1240       (save-excursion
1241         (widen)
1242         ;; Doing this here confuses things - the region gets left too wide!
1243         ;; I suppose this is run in a context where changing the buffer is bad.
1244         ;; (tar-pad-to-blocksize)
1245         ;; tar-header-offset turns out to be null for files fetched with W3,
1246         ;; at least.
1247         (let ((coding-system-for-write 'no-conversion))
1248           (write-region (or (byte-to-position tar-header-offset)
1249                             (point-min))
1250                         (point-max)
1251                         buffer-file-name nil t))
1252         (tar-clear-modification-flags)
1253         (set-buffer-modified-p nil))
1254     (narrow-to-region 1 (byte-to-position tar-header-offset)))
1255   ;; Return t because we've written the file.
1256   t)
1257 \f
1258 (provide 'tar-mode)
1259
1260 ;;; tar-mode.el ends here