lisp/progmodes/which-func.el

   1 ;;; which-func.el --- print current function in mode line
   2
   3 ;; Copyright (C) 1994, 1997, 1998, 2001, 2002, 2003, 2004, 2005, 2006, 2007
   4 ;;           Free Software Foundation, Inc.
   5
   6 ;; Author:   Alex Rezinsky <alexr@msil.sps.mot.com>
   7 ;;           (doesn't seem to be responsive any more)
   8 ;; Keywords: mode-line, imenu, tools
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This package prints name of function where your current point is
  30 ;; located in mode line. It assumes that you work with imenu package
  31 ;; and imenu--index-alist is up to date.
  32
  33 ;; KNOWN BUGS
  34 ;; ----------
  35 ;; Really this package shows not "function where the current point is
  36 ;; located now", but "nearest function which defined above the current
  37 ;; point". So if your current point is located after end of function
  38 ;; FOO but before begin of function BAR, FOO will be displayed in mode
  39 ;; line.
  40 ;; - if two windows display the same buffer, both windows
  41 ;;   show the same `which-func' information.
  42
  43 ;; TODO LIST
  44 ;; ---------
  45 ;;     1. Dependence on imenu package should be removed.  Separate
  46 ;; function determination mechanism should be used to determine the end
  47 ;; of a function as well as the beginning of a function.
  48 ;;     2. This package should be realized with the help of overlay
  49 ;; properties instead of imenu--index-alist variable.
  50
  51 ;;; History:
  52
  53 ;; THANKS TO
  54 ;; ---------
  55 ;; Per Abrahamsen   <abraham@iesd.auc.dk>
  56 ;;     Some ideas (inserting  in mode-line,  using of post-command  hook
  57 ;;     and toggling this  mode) have  been   borrowed from  his  package
  58 ;;     column.el
  59 ;; Peter Eisenhauer <pipe@fzi.de>
  60 ;;     Bug fixing in case nested indexes.
  61 ;; Terry Tateyama   <ttt@ursa0.cs.utah.edu>
  62 ;;     Suggestion to use find-file-hook for first imenu
  63 ;;     index building.
  64
  65 ;;; Code:
  66
  67 ;; Variables for customization
  68 ;; ---------------------------
  69 ;;
  70 (defvar which-func-unknown "???"
  71   "String to display in the mode line when current function is unknown.")
  72
  73 (defgroup which-func nil
  74   "Mode to display the current function name in the modeline."
  75   :group 'tools
  76   :version "20.3")
  77
  78 (defcustom which-func-modes
  79   '(emacs-lisp-mode c-mode c++-mode perl-mode cperl-mode makefile-mode
  80                     sh-mode fortran-mode f90-mode ada-mode)
  81   "List of major modes for which Which Function mode should be used.
  82 For other modes it is disabled.  If this is equal to t,
  83 then Which Function mode is enabled in any major mode that supports it."
  84   :group 'which-func
  85   :type '(choice (const :tag "All modes" t)
  86                  (repeat (symbol :tag "Major mode"))))
  87
  88 (defcustom which-func-non-auto-modes nil
  89   "List of major modes where Which Function mode is inactive till Imenu is used.
  90 This means that Which Function mode won't really do anything
  91 until you use Imenu, in these modes.  Note that files
  92 larger than `which-func-maxout' behave in this way too;
  93 Which Function mode doesn't do anything until you use Imenu."
  94   :group 'which-func
  95   :type '(repeat (symbol :tag "Major mode")))
  96
  97 (defcustom which-func-maxout 500000
  98   "Don't automatically compute the Imenu menu if buffer is this big or bigger.
  99 Zero means compute the Imenu menu regardless of size."
 100   :group 'which-func
 101   :type 'integer)
 102
 103 (defvar which-func-keymap
 104   (let ((map (make-sparse-keymap)))
 105     (define-key map [mode-line mouse-1] 'beginning-of-defun)
 106     (define-key map [mode-line mouse-2]
 107       (lambda ()
 108         (interactive)
 109         (if (eq (point-min) 1)
 110             (narrow-to-defun)
 111           (widen))))
 112     (define-key map [mode-line mouse-3] 'end-of-defun)
 113     map)
 114   "Keymap to display on mode line which-func.")
 115
 116 (defface which-func
 117   ;; Whether `font-lock-function-name-face' is an appropriate face to
 118   ;; inherit depends on the mode-line face; define several variants based
 119   ;; on the default mode-line face.
 120   '(;; The default mode-line face on a high-color display is a relatively
 121     ;; light color ("grey75"), and only the light-background variant of
 122     ;; `font-lock-function-name-face' is visible against it.
 123     (((class color) (min-colors 88) (background light))
 124      :inherit font-lock-function-name-face)
 125     ;; The default mode-line face on other display types is inverse-video;
 126     ;; it seems that only in the dark-background case is
 127     ;; `font-lock-function-name-face' visible against it.
 128     (((class grayscale mono) (background dark))
 129      :inherit font-lock-function-name-face)
 130     (((class color) (background light))
 131      :inherit font-lock-function-name-face)
 132     ;; If none of the above cases, use an explicit color chosen to contrast
 133     ;; well with the default mode-line face.
 134     (((class color) (min-colors 88) (background dark))
 135      :foreground "Blue1")
 136     (((background dark))
 137      :foreground "Blue1")
 138     (t
 139      :foreground "LightSkyBlue"))
 140   "Face used to highlight mode line function names."
 141   :group 'which-func)
 142
 143 (defcustom which-func-format
 144   `("["
 145     (:propertize which-func-current
 146                  local-map ,which-func-keymap
 147                  face which-func
 148                  ;;mouse-face highlight ; currently not evaluated :-(
 149                  help-echo "mouse-1: go to beginning, mouse-2: toggle rest visibility, mouse-3: go to end")
 150     "]")
 151   "Format for displaying the function in the mode line."
 152   :group 'which-func
 153   :type 'sexp)
 154 ;;;###autoload (put 'which-func-format 'risky-local-variable t)
 155
 156 (defvar which-func-cleanup-function nil
 157   "Function to transform a string before displaying it in the mode line.
 158 The function is called with one argument, the string to display.
 159 Its return value is displayed in the modeline.
 160 If nil, no function is called.  The default value is nil.
 161
 162 This feature can be useful if Imenu is set up to make more
 163 detailed entries (e.g., containing the argument list of a function),
 164 and you want to simplify them for the mode line
 165 \(e.g., removing the parameter list to just have the function name.)")
 166
 167 ;;; Code, nothing to customize below here
 168 ;;; -------------------------------------
 169 ;;;
 170 (require 'imenu)
 171
 172 (defvar which-func-table (make-hash-table :test 'eq :weakness 'key))
 173
 174 (defconst which-func-current
 175   '(:eval (gethash (selected-window) which-func-table which-func-unknown)))
 176 ;;;###autoload (put 'which-func-current 'risky-local-variable t)
 177
 178 (defvar which-func-mode nil
 179   "Non-nil means display current function name in mode line.
 180 This makes a difference only if `which-function-mode' is non-nil.")
 181 (make-variable-buffer-local 'which-func-mode)
 182 ;;(put 'which-func-mode 'permanent-local t)
 183
 184 (add-hook 'find-file-hook 'which-func-ff-hook t)
 185
 186 (defun which-func-ff-hook ()
 187   "File find hook for Which Function mode.
 188 It creates the Imenu index for the buffer, if necessary."
 189   (setq which-func-mode
 190         (and which-function-mode
 191              (or (eq which-func-modes t)
 192                  (member major-mode which-func-modes))))
 193
 194   (condition-case nil
 195       (if (and which-func-mode
 196                (not (member major-mode which-func-non-auto-modes))
 197                (or (null which-func-maxout)
 198                    (< buffer-saved-size which-func-maxout)
 199                    (= which-func-maxout 0)))
 200           (setq imenu--index-alist
 201                 (save-excursion (funcall imenu-create-index-function))))
 202     (error
 203      (setq which-func-mode nil))))
 204
 205 (defun which-func-update ()
 206   ;; "Update the Which-Function mode display for all windows."
 207   ;; (walk-windows 'which-func-update-1 nil 'visible))
 208   (which-func-update-1 (selected-window)))
 209
 210 (defun which-func-update-1 (window)
 211   "Update the Which Function mode display for window WINDOW."
 212   (with-selected-window window
 213     (when which-func-mode
 214       (condition-case info
 215           (let ((current (which-function)))
 216             (unless (equal current (gethash window which-func-table))
 217               (puthash window current which-func-table)
 218               (force-mode-line-update)))
 219         (error
 220          (setq which-func-mode nil)
 221          (error "Error in which-func-update: %s" info))))))
 222
 223 ;;;###autoload
 224 (defalias 'which-func-mode 'which-function-mode)
 225
 226 (defvar which-func-update-timer nil)
 227
 228 ;; This is the name people would normally expect.
 229 ;;;###autoload
 230 (define-minor-mode which-function-mode
 231   "Toggle Which Function mode, globally.
 232 When Which Function mode is enabled, the current function name is
 233 continuously displayed in the mode line, in certain major modes.
 234
 235 With prefix ARG, turn Which Function mode on if arg is positive,
 236 and off otherwise."
 237   :global t :group 'which-func
 238   (if which-function-mode
 239       ;;Turn it on
 240       (progn
 241         (setq which-func-update-timer
 242               (run-with-idle-timer idle-update-delay t 'which-func-update))
 243         (dolist (buf (buffer-list))
 244           (with-current-buffer buf
 245             (setq which-func-mode
 246                   (or (eq which-func-modes t)
 247                       (member major-mode which-func-modes))))))
 248     ;; Turn it off
 249     (when (timerp which-func-update-timer)
 250       (cancel-timer which-func-update-timer))
 251     (setq which-func-update-timer nil)
 252     (dolist (buf (buffer-list))
 253       (with-current-buffer buf (setq which-func-mode nil)))))
 254
 255 (defvar which-function-imenu-failed nil
 256   "Locally t in a buffer if `imenu--make-index-alist' found nothing there.")
 257
 258 (defvar which-func-functions nil
 259   "List of functions for `which-function' to call with no arguments.
 260 It calls them sequentially, and if any returns non-nil,
 261 `which-function' uses that name and stops looking for the name.")
 262
 263 (defun which-function ()
 264   "Return current function name based on point.
 265 Uses `which-func-functions', `imenu--index-alist'
 266 or `add-log-current-defun-function'.
 267 If no function name is found, return nil."
 268   (let ((name
 269          ;; Try the `which-func-functions' functions first.
 270          (run-hook-with-args-until-success 'which-func-functions)))
 271
 272     ;; If Imenu is loaded, try to make an index alist with it.
 273     (when (and (null name)
 274                (boundp 'imenu--index-alist) (null imenu--index-alist)
 275                (null which-function-imenu-failed))
 276       (imenu--make-index-alist t)
 277       (unless imenu--index-alist
 278         (make-local-variable 'which-function-imenu-failed)
 279         (setq which-function-imenu-failed t)))
 280     ;; If we have an index alist, use it.
 281     (when (and (null name)
 282                (boundp 'imenu--index-alist) imenu--index-alist)
 283       (let ((alist imenu--index-alist)
 284             (minoffset (point-max))
 285             offset elem pair mark)
 286         (while alist
 287           (setq elem  (car-safe alist)
 288                 alist (cdr-safe alist))
 289           ;; Elements of alist are either ("name" . marker), or
 290           ;; ("submenu" ("name" . marker) ... ).
 291           (unless (listp (cdr elem))
 292               (setq elem (list elem)))
 293           (while elem
 294             (setq pair (car elem)
 295                   elem (cdr elem))
 296             (and (consp pair)
 297                  (number-or-marker-p (setq mark (cdr pair)))
 298                  (if (>= (setq offset (- (point) mark)) 0)
 299                      (if (< offset minoffset) ; find the closest item
 300                          (setq minoffset offset
 301                                name (car pair)))
 302                    ;; Entries in order, so can skip all those after point.
 303                    (setq elem nil)))))))
 304     ;; Try using add-log support.
 305     (when (and (null name) (boundp 'add-log-current-defun-function)
 306                add-log-current-defun-function)
 307       (setq name (funcall add-log-current-defun-function)))
 308     ;; Filter the name if requested.
 309     (when name
 310       (if which-func-cleanup-function
 311           (funcall which-func-cleanup-function name)
 312         name))))
 313
 314 (provide 'which-func)
 315
 316 ;; arch-tag: fa8a55c7-bfe3-4ffc-95ab-01bf21796827
 317 ;;; which-func.el ends here