configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 165
 166 ## For the times when you want to build Emacs but don't have
 167 ## a suitable makeinfo, and can live without the manuals.
 168 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 169 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 170
 171 dnl Can remove these in Emacs 24.
 172 AC_ARG_WITH([gtk],,
 173   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 174 specify a toolkit.])],,)
 175
 176 AC_ARG_WITH([gcc],,
 177   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 178 variable to specify a compiler.])],,)
 179
 180 AC_ARG_WITH([pkg-config-prog],dnl
 181 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 182                   [path to pkg-config for finding GTK and librsvg])])
 183 if test "X${with_pkg_config_prog}" != X; then
 184    if test "${with_pkg_config_prog}" != yes; then
 185       PKG_CONFIG="${with_pkg_config_prog}"
 186    fi
 187 fi
 188
 189 CRT_DIR=
 190 AC_ARG_WITH([crt-dir],dnl
 191 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 192 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 193 CRT_DIR="${with_crt_dir}"
 194
 195 AC_ARG_WITH([gnustep-conf],dnl
 196 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 197 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 198   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 199 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 200      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 201
 202 AC_ARG_ENABLE(ns-self-contained,
 203 [AS_HELP_STRING([--disable-ns-self-contained],
 204                 [disable self contained build under NeXTstep])],
 205    EN_NS_SELF_CONTAINED=$enableval,
 206    EN_NS_SELF_CONTAINED=yes)
 207
 208 AC_ARG_ENABLE(asserts,
 209 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 210       USE_XASSERTS=$enableval,
 211       USE_XASSERTS=no)
 212
 213 AC_ARG_ENABLE(maintainer-mode,
 214 [AS_HELP_STRING([--enable-maintainer-mode],
 215                 [enable make rules and dependencies not useful (and sometimes
 216                  confusing) to the casual installer])],
 217       USE_MAINTAINER_MODE=$enableval,
 218       USE_MAINTAINER_MODE=no)
 219 if test $USE_MAINTAINER_MODE = yes; then
 220   MAINT=
 221 else
 222   MAINT=#
 223 fi
 224 AC_SUBST(MAINT)
 225
 226 AC_ARG_ENABLE(locallisppath,
 227 [AS_HELP_STRING([--enable-locallisppath=PATH],
 228                 [directories Emacs should search for lisp files specific
 229                  to this site])],
 230 if test "${enableval}" = "no"; then
 231   locallisppath=
 232 elif test "${enableval}" != "yes"; then
 233   locallisppath=${enableval}
 234 fi)
 235
 236 AC_ARG_ENABLE(checking,
 237 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 238                 [enable expensive run-time checks.  With LIST,
 239                  enable only specific categories of checks.
 240                  Categories are: all,yes,no.
 241                  Flags are: stringbytes, stringoverrun, stringfreelist,
 242                  xmallocoverrun, conslist])],
 243 [ac_checking_flags="${enableval}"],[])
 244 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 245 for check in $ac_checking_flags
 246 do
 247         case $check in
 248         # these set all the flags to specific states
 249         yes)            ac_enable_checking=1 ;;
 250         no)             ac_enable_checking= ;
 251                         ac_gc_check_stringbytes= ;
 252                         ac_gc_check_string_overrun= ;
 253                         ac_gc_check_string_free_list= ;
 254                         ac_xmalloc_overrun= ;
 255                         ac_gc_check_cons_list= ;;
 256         all)            ac_enable_checking=1 ;
 257                         ac_gc_check_stringbytes=1 ;
 258                         ac_gc_check_string_overrun=1 ;
 259                         ac_gc_check_string_free_list=1 ;
 260                         ac_xmalloc_overrun=1 ;
 261                         ac_gc_check_cons_list=1 ;;
 262         # these enable particular checks
 263         stringbytes)    ac_gc_check_stringbytes=1 ;;
 264         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 265         stringfreelist) ac_gc_check_string_free_list=1 ;;
 266         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 267         conslist)       ac_gc_check_cons_list=1 ;;
 268         *)      AC_MSG_ERROR(unknown check category $check) ;;
 269         esac
 270 done
 271 IFS="$ac_save_IFS"
 272
 273 if test x$ac_enable_checking != x ; then
 274   AC_DEFINE(ENABLE_CHECKING, 1,
 275 [Enable expensive run-time checking of data types?])
 276 fi
 277 if test x$ac_gc_check_stringbytes != x ; then
 278   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 279 [Define this temporarily to hunt a bug.  If defined, the size of
 280    strings is redundantly recorded in sdata structures so that it can
 281    be compared to the sizes recorded in Lisp strings.])
 282 fi
 283 if test x$ac_gc_check_stringoverrun != x ; then
 284   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 285 [Define this to check for short string overrun.])
 286 fi
 287 if test x$ac_gc_check_string_free_list != x ; then
 288   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 289 [Define this to check the string free list.])
 290 fi
 291 if test x$ac_xmalloc_overrun != x ; then
 292   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 293 [Define this to check for malloc buffer overrun.])
 294 fi
 295 if test x$ac_gc_check_cons_list != x ; then
 296   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 297 [Define this to check for errors in cons list.])
 298 fi
 299
 300 AC_ARG_ENABLE(profiling,
 301 [AS_HELP_STRING([--enable-profiling],
 302                 [build emacs with profiling support.
 303                  This might not work on all platforms])],
 304 [ac_enable_profiling="${enableval}"],[])
 305 if test x$ac_enable_profiling != x ; then
 306    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 307    PROFILING_LDFLAGS="-pg"
 308 else
 309    PROFILING_CFLAGS=
 310    PROFILING_LDFLAGS=
 311 fi
 312
 313 AC_ARG_ENABLE(autodepend,
 314 [AS_HELP_STRING([--enable-autodepend],
 315                 [automatically generate dependencies to .h-files.
 316                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 317                  found])],
 318 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 319
 320 #### Make srcdir absolute, if it isn't already.  It's important to
 321 #### avoid running the path through pwd unnecessarily, since pwd can
 322 #### give you automounter prefixes, which can go away.  We do all this
 323 #### so Emacs can find its files when run uninstalled.
 324 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 325 unset CDPATH
 326 case "${srcdir}" in
 327   /* ) ;;
 328   . )
 329     ## We may be able to use the $PWD environment variable to make this
 330     ## absolute.  But sometimes PWD is inaccurate.
 331     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 332     ## but that tested only for a well-formed and valid PWD,
 333     ## it did not object when PWD was well-formed and valid but just wrong.
 334     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 335     then
 336       srcdir="$PWD"
 337     else
 338       srcdir="`(cd ${srcdir}; pwd)`"
 339     fi
 340   ;;
 341   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 342 esac
 343
 344 #### Check if the source directory already has a configured system in it.
 345 if test `pwd` != `(cd ${srcdir} && pwd)` \
 346    && test -f "${srcdir}/src/config.h" ; then
 347   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 348    as a build directory right now; it has been configured in its own
 349    right.  To configure in another directory as well, you MUST
 350    use GNU make.  If you do not have GNU make, then you must
 351    now do `make distclean' in ${srcdir},
 352    and then run $0 again.]])
 353 fi
 354
 355 #### Given the configuration name, set machfile and opsysfile to the
 356 #### names of the m/*.h and s/*.h files we should use.
 357
 358 ### Canonicalize the configuration name.
 359
 360 AC_CANONICAL_HOST
 361 canonical=$host
 362 configuration=${host_alias-${build_alias-$host}}
 363
 364 dnl This used to use changequote, but, apart from `changequote is evil'
 365 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 366 dnl the great gob of text.  Thus it's not processed for possible expansion.
 367 dnl Just make sure the brackets remain balanced.
 368 dnl
 369 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 370 dnl indicated by comments.
 371 dnl quotation begins
 372 [
 373
 374 ### If you add support for a new configuration, add code to this
 375 ### switch statement to recognize your configuration name and select
 376 ### the appropriate operating system and machine description files.
 377
 378 ### You would hope that you could choose an m/*.h file pretty much
 379 ### based on the machine portion of the configuration name, and an s-
 380 ### file based on the operating system portion.  However, it turns out
 381 ### that each m/*.h file is pretty manufacturer-specific - for
 382 ### example mips.h is MIPS
 383 ### So we basically have to have a special case for each
 384 ### configuration name.
 385 ###
 386 ### As far as handling version numbers on operating systems is
 387 ### concerned, make sure things will fail in a fixable way.  If
 388 ### /etc/MACHINES doesn't say anything about version numbers, be
 389 ### prepared to handle anything reasonably.  If version numbers
 390 ### matter, be sure /etc/MACHINES says something about it.
 391 ###
 392 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 393 ### "System V Release 4"; he writes, "The old convention encouraged
 394 ### confusion between `system' and `release' levels'."
 395
 396 machine='' opsys='' unported=no
 397 case "${canonical}" in
 398
 399   ## FreeBSD ports
 400   *-*-freebsd* )
 401     opsys=freebsd
 402     case "${canonical}" in
 403       alpha*-*-freebsd*)        machine=alpha ;;
 404       arm*-*-freebsd*)          machine=arm ;;
 405       ia64-*-freebsd*)          machine=ia64 ;;
 406       sparc-*-freebsd*)         machine=sparc ;;
 407       sparc64-*-freebsd*)       machine=sparc ;;
 408       powerpc-*-freebsd*)       machine=macppc ;;
 409       i[3456]86-*-freebsd*)     machine=intel386 ;;
 410       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 411     esac
 412   ;;
 413
 414   ## FreeBSD kernel + glibc based userland
 415   *-*-kfreebsd*gnu* )
 416     opsys=gnu-kfreebsd
 417     case "${canonical}" in
 418       alpha*-*-kfreebsd*)       machine=alpha ;;
 419       ia64-*-kfreebsd*)         machine=ia64 ;;
 420       sparc-*-kfreebsd*)        machine=sparc ;;
 421       sparc64-*-kfreebsd*)      machine=sparc ;;
 422       powerpc-*-kfreebsd*)      machine=macppc ;;
 423       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 424       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## NetBSD ports
 429   *-*-netbsd* )
 430     opsys=netbsd
 431     if test -f /usr/lib/crti.o; then]
 432 dnl The close and open brackets here are because this section is quoted --
 433 dnl see the `changequote' comment above.
 434       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 435 [   fi
 436
 437     case "${canonical}" in
 438       alpha*-*-netbsd*) machine=alpha ;;
 439       i[3456]86-*-netbsd*) machine=intel386 ;;
 440       mips-*-netbsd*)   machine=mips ;;
 441       mipsel-*-netbsd*) machine=mips ;;
 442       mipseb-*-netbsd*) machine=mips ;;
 443       powerpc-*-netbsd*) machine=macppc ;;
 444       sparc*-*-netbsd*) machine=sparc ;;
 445       vax-*-netbsd*)    machine=vax ;;
 446       arm-*-netbsd*)    machine=arm ;;
 447       x86_64-*-netbsd*) machine=amdx86-64 ;;
 448       hppa-*-netbsd*)   machine=hp800 ;;
 449       m68k-*-netbsd*)   machine=m68k ;;
 450     esac
 451   ;;
 452
 453   ## OpenBSD ports
 454   *-*-openbsd* )
 455     opsys=openbsd
 456     case "${canonical}" in
 457       alpha*-*-openbsd*)        machine=alpha ;;
 458       arm-*-openbsd*)          machine=arm ;;
 459       i386-*-openbsd*)         machine=intel386 ;;
 460       powerpc-*-openbsd*)      machine=macppc ;;
 461       sparc*-*-openbsd*)       machine=sparc ;;
 462       vax-*-openbsd*)          machine=vax ;;
 463       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 464       hppa-*-openbsd*)         machine=hp800 ;;
 465     esac
 466   ;;
 467
 468   alpha*-*-linux-gnu* )
 469     machine=alpha opsys=gnu-linux
 470   ;;
 471
 472   arm*-*-linux-gnu* )
 473     machine=arm opsys=gnu-linux
 474   ;;
 475
 476   ## Apple Darwin / Mac OS X
 477   *-apple-darwin* )
 478     case "${canonical}" in
 479       i[3456]86-* )  machine=intel386 ;;
 480       powerpc-* )    machine=macppc ;;
 481       x86_64-* )     machine=amdx86-64 ;;
 482       * )            unported=yes ;;
 483     esac
 484     opsys=darwin
 485     # Define CPP as follows to make autoconf work correctly.
 486     CPP="${CC-cc} -E -no-cpp-precomp"
 487     # Use fink packages if available.
 488     if test -d /sw/include && test -d /sw/lib; then
 489       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 490       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 491       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 492     fi
 493   ;;
 494
 495   ## HP 9000 series 700 and 800, running HP/UX
 496   hppa*-hp-hpux10.2* )
 497     machine=hp800 opsys=hpux10-20
 498   ;;
 499   hppa*-hp-hpux1[1-9]* )
 500     machine=hp800 opsys=hpux11
 501     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 502   ;;
 503
 504   hppa*-*-linux-gnu* )
 505     machine=hp800 opsys=gnu-linux
 506   ;;
 507
 508   ## IBM machines
 509   s390-*-linux-gnu* )
 510     machine=ibms390 opsys=gnu-linux
 511   ;;
 512   s390x-*-linux-gnu* )
 513     machine=ibms390x opsys=gnu-linux
 514   ;;
 515   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527
 528   ## Macintosh PowerPC
 529   powerpc*-*-linux-gnu* )
 530     machine=macppc opsys=gnu-linux
 531   ;;
 532
 533   ## Silicon Graphics machines
 534   ## Iris 4D
 535   mips-sgi-irix6.5 )
 536     machine=iris4d opsys=irix6-5
 537     # Without defining _LANGUAGE_C, things get masked out in the headers
 538     # so that, for instance, grepping for `free' in stdlib.h fails and
 539     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 540     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 541     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 542   ;;
 543
 544   ## Suns
 545   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 546     machine=sparc opsys=gnu-linux
 547   ;;
 548
 549   *-sun-solaris* \
 550     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 551     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 552     case "${canonical}" in
 553       i[3456]86-*-* )     machine=intel386 ;;
 554       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 555       sparc* )          machine=sparc ;;
 556       * )               unported=yes ;;
 557     esac
 558     case "${canonical}" in
 559       *-sunos5.6* | *-solaris2.6* )
 560                 opsys=sol2-6
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 RANLIB="ar -ts"
 563                 ;;
 564       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 565                 opsys=sol2-6
 566                 emacs_check_sunpro_c=yes
 567                 NON_GNU_CPP=/usr/ccs/lib/cpp
 568                 ;;
 569       *-sunos5* | *-solaris* )
 570                 opsys=sol2-10
 571                 emacs_check_sunpro_c=yes
 572                 NON_GNU_CPP=/usr/ccs/lib/cpp
 573                 ;;
 574     esac
 575     ## Watch out for a compiler that we know will not work.
 576     case "${canonical}" in
 577      *-solaris* | *-sunos5* )
 578                 if [ "x$CC" = x/usr/ucb/cc ]; then
 579                   ## /usr/ucb/cc doesn't work;
 580                   ## we should find some other compiler that does work.
 581                   unset CC
 582                 fi
 583                 ;;
 584       *) ;;
 585     esac
 586   ;;
 587
 588   ## IA-64
 589   ia64*-*-linux* )
 590     machine=ia64 opsys=gnu-linux
 591   ;;
 592
 593   ## Intel 386 machines where we don't care about the manufacturer
 594   i[3456]86-*-* )
 595     machine=intel386
 596     case "${canonical}" in
 597       *-cygwin )                opsys=cygwin ;;
 598       *-darwin* )               opsys=darwin
 599                                 CPP="${CC-cc} -E -no-cpp-precomp"
 600                                 ;;
 601       *-linux-gnu* )            opsys=gnu-linux ;;
 602       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 603       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 604       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 605       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 606     esac
 607   ;;
 608
 609   ## m68k Linux-based GNU system
 610   m68k-*-linux-gnu* )
 611     machine=m68k opsys=gnu-linux
 612   ;;
 613
 614   ## Mips Linux-based GNU system
 615   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 616     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 617     machine=mips opsys=gnu-linux
 618   ;;
 619
 620   ## AMD x86-64 Linux-based GNU system
 621   x86_64-*-linux-gnu* )
 622     machine=amdx86-64 opsys=gnu-linux
 623   ;;
 624
 625   ## Tensilica Xtensa Linux-based GNU system
 626   xtensa*-*-linux-gnu* )
 627     machine=xtensa opsys=gnu-linux
 628     ;;
 629
 630   ## SuperH Linux-based GNU system
 631   sh[34]*-*-linux-gnu* )
 632     machine=sh3 opsys=gnu-linux
 633   ;;
 634
 635   * )
 636     unported=yes
 637   ;;
 638 esac
 639
 640 ### If the code above didn't choose an operating system, just choose
 641 ### an operating system based on the configuration name.  You really
 642 ### only want to use this when you have no idea what the right
 643 ### operating system is; if you know what operating systems a machine
 644 ### runs, it's cleaner to make it explicit in the case statement
 645 ### above.
 646 if test x"${opsys}" = x; then
 647   case "${canonical}" in
 648     *-gnu* )                            opsys=gnu ;;
 649     * )
 650       unported=yes
 651     ;;
 652   esac
 653 fi
 654
 655 ]
 656 dnl quotation ends
 657
 658 if test $unported = yes; then
 659   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 660 Check `etc/MACHINES' for recognized configuration names.])
 661 fi
 662
 663 machfile="m/${machine}.h"
 664 opsysfile="s/${opsys}.h"
 665
 666
 667 #### Choose a compiler.
 668 test -n "$CC" && cc_specified=yes
 669
 670 # Save the value of CFLAGS that the user specified.
 671 SPECIFIED_CFLAGS="$CFLAGS"
 672
 673 dnl Sets GCC=yes if using gcc.
 674 AC_PROG_CC
 675
 676 # On Suns, sometimes $CPP names a directory.
 677 if test -n "$CPP" && test -d "$CPP"; then
 678   CPP=
 679 fi
 680
 681 ## If not using gcc, and on Solaris, and no CPP specified, see if
 682 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 683 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 684  test x"$CPP" = x; then
 685   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 686   AC_CACHE_VAL(emacs_cv_sunpro_c,
 687   [AC_TRY_LINK([],
 688 [#ifndef __SUNPRO_C
 689 fail;
 690 #endif
 691 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 692   AC_MSG_RESULT($emacs_cv_sunpro_c)
 693
 694   if test x"$emacs_cv_sunpro_c" = xyes; then
 695     NON_GNU_CPP="$CC -E -Xs"
 696   fi
 697 fi
 698
 699 #### Some systems specify a CPP to use unless we are using GCC.
 700 #### Now that we know whether we are using GCC, we can decide whether
 701 #### to use that one.
 702 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 703 then
 704   CPP="$NON_GNU_CPP"
 705 fi
 706
 707 #### Some systems specify a CC to use unless we are using GCC.
 708 #### Now that we know whether we are using GCC, we can decide whether
 709 #### to use that one.
 710 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 711   test x$cc_specified != xyes
 712 then
 713   CC="$NON_GNU_CC"
 714 fi
 715
 716 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 717 then
 718   CC="$CC $GCC_TEST_OPTIONS"
 719 fi
 720
 721 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 722 then
 723   CC="$CC $NON_GCC_TEST_OPTIONS"
 724 fi
 725
 726 dnl checks for Unix variants
 727 AC_USE_SYSTEM_EXTENSIONS
 728
 729 ### Use -Wno-pointer-sign if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wno-pointer-sign"
 733 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 ### Use -Wdeclaration-after-statement if the compiler supports it
 743 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 744 SAVE_CFLAGS="$CFLAGS"
 745 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 746 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 747 if test $has_option = yes; then
 748    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 749 fi
 750 AC_MSG_RESULT($has_option)
 751 CFLAGS="$SAVE_CFLAGS"
 752 unset has_option
 753 unset SAVE_CFLAGS
 754
 755 #### Some other nice autoconf tests.
 756
 757 dnl checks for programs
 758 AC_PROG_LN_S
 759 AC_PROG_CPP
 760 AC_PROG_INSTALL
 761 if test "x$RANLIB" = x; then
 762   AC_PROG_RANLIB
 763 fi
 764
 765 ## Although we're running on an amd64 kernel, we're actually compiling for
 766 ## the x86 architecture.  The user should probably have provided an
 767 ## explicit --build to `configure', but if everything else than the kernel
 768 ## is running in i386 mode, we can help them out.
 769 if test "$machine" = "amdx86-64"; then
 770   AC_CHECK_DECL([i386])
 771   if test "$ac_cv_have_decl_i386" = "yes"; then
 772     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 773     machine=intel386
 774     machfile="m/${machine}.h"
 775   fi
 776 fi
 777
 778 AC_PATH_PROG(INSTALL_INFO, install-info)
 779 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 780 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 781 dnl Don't use GZIP, which is used by gzip for additional parameters.
 782 AC_PATH_PROG(GZIP_PROG, gzip)
 783
 784
 785 ## Need makeinfo >= 4.6 (?) to build the manuals.
 786 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 787 dnl By this stage, configure has already checked for egrep and set EGREP,
 788 dnl or exited with an error if no egrep was found.
 789 if test "$MAKEINFO" != "no" && \
 790   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 791    MAKEINFO=no
 792 fi
 793
 794 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 795 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 796 ## therefore in the category of "special tools" not normally required, which
 797 ## configure does not have to check for (eg autoconf itself).
 798 ## In a Bazaar checkout on the other hand, the manuals are not included.
 799 ## So makeinfo is a requirement to build from Bazaar, and configure
 800 ## should test for it as it does for any other build requirement.
 801 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 802 ## with pre-built manuals, from a Bazaar checkout.
 803 if test "$MAKEINFO" = "no"; then
 804   if test "x${with_makeinfo}" = "xno"; then
 805     MAKEINFO=off
 806   elif test ! -e $srcdir/info/emacs; then
 807     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 808 source tree does not seem to have pre-built manuals in the `info' directory.
 809 Either install a suitable version of makeinfo, or re-run configure
 810 with the `--without-makeinfo' option to build without the manuals.] )
 811   fi
 812 fi
 813
 814 dnl Add our options to ac_link now, after it is set up.
 815
 816 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 817 then
 818   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 819 fi
 820
 821 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 822 then
 823   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 824 fi
 825
 826 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 827 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 828 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 829 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 830 dnl if not built to support GNU ld.
 831
 832 late_LDFLAGS=$LDFLAGS
 833 if test "$GCC" = yes; then
 834   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 835 else
 836   LDFLAGS="$LDFLAGS -znocombreloc"
 837 fi
 838
 839 AC_MSG_CHECKING([for -znocombreloc])
 840 AC_LINK_IFELSE([main(){return 0;}],
 841   [AC_MSG_RESULT(yes)],
 842   LDFLAGS=$late_LDFLAGS
 843   [AC_MSG_RESULT(no)])
 844
 845 LIB_MATH=-lm
 846
 847 case $opsys in
 848   cygwin )
 849     LIB_MATH=
 850     ;;
 851   darwin )
 852     ## Adding -lm confuses the dynamic linker, so omit it.
 853     LIB_MATH=
 854     ;;
 855 esac
 856
 857 AC_SUBST(LIB_MATH)
 858
 859 #### Extract some information from the operating system and machine files.
 860
 861 AC_CHECKING([the machine- and system-dependent files to find out
 862  - which libraries the lib-src programs will want, and
 863  - whether the GNU malloc routines are usable])
 864
 865 ### First figure out CFLAGS (which we use for running the compiler here)
 866 ### and REAL_CFLAGS (which we use for real compilation).
 867 ### The two are the same except on a few systems, where they are made
 868 ### different to work around various lossages.  For example,
 869 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 870 ### as implying static linking.
 871
 872 ### If the CFLAGS env var is specified, we use that value
 873 ### instead of the default.
 874
 875 ### It's not important that this name contain the PID; you can't run
 876 ### two configures in the same directory and have anything work
 877 ### anyway.
 878 tempcname="conftest.c"
 879
 880 echo '
 881 #include "'${srcdir}'/src/'${opsysfile}'"
 882 #include "'${srcdir}'/src/'${machfile}'"
 883 #ifndef LIBS_SYSTEM
 884 #define LIBS_SYSTEM
 885 #endif
 886 #ifndef C_SWITCH_SYSTEM
 887 #define C_SWITCH_SYSTEM
 888 #endif
 889 #ifndef C_SWITCH_MACHINE
 890 #define C_SWITCH_MACHINE
 891 #endif
 892 configure___ libsrc_libs=LIBS_SYSTEM
 893 configure___ c_switch_system=C_SWITCH_SYSTEM
 894 configure___ c_switch_machine=C_SWITCH_MACHINE
 895
 896 configure___ LIBX=-lX11
 897
 898 configure___ unexec=UNEXEC
 899
 900 #ifdef SYSTEM_MALLOC
 901 configure___ system_malloc=yes
 902 #else
 903 configure___ system_malloc=no
 904 #endif
 905
 906 #ifdef USE_MMAP_FOR_BUFFERS
 907 configure___ use_mmap_for_buffers=yes
 908 #else
 909 configure___ use_mmap_for_buffers=no
 910 #endif
 911
 912 #ifndef C_OPTIMIZE_SWITCH
 913 #ifdef __GNUC__
 914 #define C_OPTIMIZE_SWITCH -O2
 915 #else
 916 #define C_OPTIMIZE_SWITCH -O
 917 #endif
 918 #endif
 919
 920 #ifndef C_WARNINGS_SWITCH
 921 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 922 #endif
 923
 924 #ifndef LD_SWITCH_MACHINE
 925 #define LD_SWITCH_MACHINE
 926 #endif
 927
 928 #ifndef LD_SWITCH_SYSTEM
 929 #define LD_SWITCH_SYSTEM
 930 #endif
 931
 932 #ifndef LD_SWITCH_X_SITE_AUX
 933 #define LD_SWITCH_X_SITE_AUX
 934 #endif
 935
 936 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 937 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 938
 939 #ifdef THIS_IS_CONFIGURE
 940
 941 /* Get the CFLAGS for tests in configure.  */
 942 #ifdef __GNUC__
 943 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 944 #else
 945 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 946 #endif
 947
 948 #else /* not THIS_IS_CONFIGURE */
 949
 950 /* Get the CFLAGS for real compilation.  */
 951 #ifdef __GNUC__
 952 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 953 #else
 954 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 955 #endif
 956
 957 #endif /* not THIS_IS_CONFIGURE */
 958 ' > ${tempcname}
 959
 960 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 961
 962 # The value of CPP is a quoted variable reference, so we need to do this
 963 # to get its actual value...
 964 CPP=`eval "echo $CPP"`
 965 [eval `${CPP} -Isrc ${tempcname} \
 966        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 967 if test "x$SPECIFIED_CFLAGS" = x; then
 968   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 969          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 970 else
 971   REAL_CFLAGS="$CFLAGS"
 972 fi]
 973 rm ${tempcname}
 974
 975 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 976
 977 ### Make sure subsequent tests use flags consistent with the build flags.
 978
 979 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 980   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 981 else
 982   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 983 fi
 984
 985 dnl For AC_FUNC_GETLOADAVG, at least:
 986 AC_CONFIG_LIBOBJ_DIR(src)
 987
 988 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 989 AC_SYS_LARGEFILE
 990
 991
 992 ## If user specified a crt-dir, use that unconditionally.
 993 if test "X$CRT_DIR" = "X"; then
 994
 995   case "$canonical" in
 996     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
 997     ## On x86-64 and s390x GNU/Linux distributions, the standard library
 998     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
 999     ## For anything else (eg /usr/lib32), it is up the user to specify
1000     ## the location (bug#5655).
1001     ## Test for crtn.o, not just the directory, because sometimes the
1002     ## directory exists but does not have the relevant files (bug#1287).
1003     ## FIXME better to test for binary compatibility somehow.
1004     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1005     ;;
1006
1007     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1008   esac
1009
1010   case "$opsys" in
1011     hpux10-20) CRT_DIR=/lib ;;
1012   esac
1013
1014   ## Default is /usr/lib.
1015   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1016
1017 else
1018
1019   ## Some platforms don't use any of these files, so it is not
1020   ## appropriate to put this test outside the if block.
1021   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1022     AC_MSG_ERROR([crt*.o not found in specified location.])
1023
1024 fi
1025
1026 AC_SUBST(CRT_DIR)
1027
1028
1029 dnl This function defintion taken from Gnome 2.0
1030 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1031 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1032 dnl also defines GSTUFF_PKG_ERRORS on error
1033 AC_DEFUN([PKG_CHECK_MODULES], [
1034   succeeded=no
1035
1036   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1037
1038   if test "$PKG_CONFIG" = "no" ; then
1039      ifelse([$4], , [AC_MSG_ERROR([
1040       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1041   else
1042      PKG_CONFIG_MIN_VERSION=0.9.0
1043      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1044         AC_MSG_CHECKING(for $2)
1045
1046         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1047             AC_MSG_RESULT(yes)
1048             succeeded=yes
1049
1050             AC_MSG_CHECKING($1_CFLAGS)
1051             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1052             AC_MSG_RESULT($$1_CFLAGS)
1053
1054             AC_MSG_CHECKING($1_LIBS)
1055             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1056             AC_MSG_RESULT($$1_LIBS)
1057         else
1058             AC_MSG_RESULT(no)
1059             $1_CFLAGS=""
1060             $1_LIBS=""
1061             ## If we have a custom action on failure, don't print errors, but
1062             ## do set a variable so people can do so.
1063             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1064             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1065         fi
1066
1067         AC_SUBST($1_CFLAGS)
1068         AC_SUBST($1_LIBS)
1069      else
1070         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1071         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1072      fi
1073   fi
1074
1075   if test $succeeded = yes; then
1076      ifelse([$3], , :, [$3])
1077   else
1078      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1079   fi
1080 ])
1081
1082
1083 if test "${with_sound}" != "no"; then
1084   # Sound support for GNU/Linux and the free BSDs.
1085   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1086   # Emulation library used on NetBSD.
1087   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1088   AC_SUBST(LIBSOUND)
1089
1090   ALSA_REQUIRED=1.0.0
1091   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1092   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1093   if test $HAVE_ALSA = yes; then
1094     SAVE_CFLAGS="$CFLAGS"
1095     SAVE_LDFLAGS="$LDFLAGS"
1096     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1097     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1098     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1099                     emacs_alsa_normal=yes,
1100                     emacs_alsa_normal=no)
1101     if test "$emacs_alsa_normal" != yes; then
1102       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1103                      [snd_lib_error_set_handler (0);],
1104                      emacs_alsa_subdir=yes,
1105                      emacs_alsa_subdir=no)
1106       if test "$emacs_alsa_subdir" != yes; then
1107         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1108       fi
1109       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1110     fi
1111
1112     CFLAGS="$SAVE_CFLAGS"
1113     LDFLAGS="$SAVE_LDFLAGS"
1114     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1115     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1116     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1117   fi
1118   AC_SUBST(CFLAGS_SOUND)
1119 fi
1120
1121 dnl checks for header files
1122 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1123   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1124   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1125   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1126   sys/utsname.h pwd.h utmp.h)
1127
1128 AC_MSG_CHECKING(if personality LINUX32 can be set)
1129 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1130                emacs_cv_personality_linux32=yes,
1131                emacs_cv_personality_linux32=no)
1132 AC_MSG_RESULT($emacs_cv_personality_linux32)
1133
1134 if test $emacs_cv_personality_linux32 = yes; then
1135   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1136             [Define to 1 if personality LINUX32 can be set.])
1137 fi
1138
1139 dnl On Solaris 8 there's a compilation warning for term.h because
1140 dnl it doesn't define `bool'.
1141 AC_CHECK_HEADERS(term.h, , , -)
1142 AC_HEADER_STDC
1143 AC_HEADER_TIME
1144 AC_CHECK_DECLS([sys_siglist])
1145 if test $ac_cv_have_decl_sys_siglist != yes; then
1146   # For Tru64, at least:
1147   AC_CHECK_DECLS([__sys_siglist])
1148   if test $ac_cv_have_decl___sys_siglist = yes; then
1149     AC_DEFINE(sys_siglist, __sys_siglist,
1150               [Define to any substitute for sys_siglist.])
1151   fi
1152 fi
1153 AC_HEADER_SYS_WAIT
1154
1155 dnl Some systems have utime.h but don't declare the struct anyplace.
1156 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1157 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1158 #include <sys/time.h>
1159 #include <time.h>
1160 #else
1161 #ifdef HAVE_SYS_TIME_H
1162 #include <sys/time.h>
1163 #else
1164 #include <time.h>
1165 #endif
1166 #endif
1167 #ifdef HAVE_UTIME_H
1168 #include <utime.h>
1169 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1170   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1171 if test $emacs_cv_struct_utimbuf = yes; then
1172   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1173 fi
1174
1175 dnl checks for typedefs
1176 AC_TYPE_SIGNAL
1177
1178 dnl Check for speed_t typedef.
1179 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1180   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1181     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1182 if test $emacs_cv_speed_t = yes; then
1183   AC_DEFINE(HAVE_SPEED_T, 1,
1184            [Define to 1 if `speed_t' is declared by <termios.h>.])
1185 fi
1186
1187 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1188 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1189 #include <sys/time.h>
1190 #include <time.h>
1191 #else
1192 #ifdef HAVE_SYS_TIME_H
1193 #include <sys/time.h>
1194 #else
1195 #include <time.h>
1196 #endif
1197 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1198   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1199 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1200 if test $emacs_cv_struct_timeval = yes; then
1201   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1202 fi
1203
1204 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1205 AC_TRY_COMPILE([#include <math.h>],
1206 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1207   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1208 HAVE_EXCEPTION=$emacs_cv_struct_exception
1209 if test $emacs_cv_struct_exception != yes; then
1210   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1211 fi
1212
1213 AC_CHECK_HEADERS(sys/socket.h)
1214 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1215 #if HAVE_SYS_SOCKET_H
1216 #include <sys/socket.h>
1217 #endif])
1218
1219 dnl checks for structure members
1220 AC_STRUCT_TM
1221 AC_STRUCT_TIMEZONE
1222 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1223                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1224                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1225                 [#include <time.h>])
1226 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1227                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1228                   struct ifreq.ifr_addr], , ,
1229                  [AC_INCLUDES_DEFAULT
1230 #if HAVE_SYS_SOCKET_H
1231 #include <sys/socket.h>
1232 #endif
1233 #if HAVE_NET_IF_H
1234 #include <net/if.h>
1235 #endif])
1236
1237 dnl checks for compiler characteristics
1238
1239 dnl Testing __STDC__ to determine prototype support isn't good enough.
1240 dnl DEC C, for instance, doesn't define it with default options, and
1241 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1242 dnl and void *.
1243 AC_C_PROTOTYPES
1244 AC_C_VOLATILE
1245 AC_C_CONST
1246 dnl This isn't useful because we can't turn on use of `inline' unless
1247 dnl the compiler groks `extern inline'.
1248 dnl AC_C_INLINE
1249 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1250   [AC_TRY_COMPILE(, [void * foo;],
1251                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1252 if test $emacs_cv_void_star = yes; then
1253   AC_DEFINE(POINTER_TYPE, void)
1254 else
1255   AC_DEFINE(POINTER_TYPE, char)
1256 fi
1257 AH_TEMPLATE(POINTER_TYPE,
1258             [Define as `void' if your compiler accepts `void *'; otherwise
1259              define as `char'.])dnl
1260
1261
1262
1263 dnl This could be used for targets which can have both byte sexes.
1264 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1265 dnl AC_C_BIGENDIAN
1266
1267 dnl check for Make feature
1268 AC_PROG_MAKE_SET
1269
1270 dnl check for GNU Make if we have GCC and autodepend is on.
1271 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1272    AC_MSG_CHECKING([whether we are using GNU Make])
1273    HAVE_GNU_MAKE=no
1274    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1275    if test "x$testval" != x; then
1276       HAVE_GNU_MAKE=yes
1277    else
1278       ac_enable_autodepend=no
1279    fi
1280    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1281    if test $HAVE_GNU_MAKE = yes; then
1282       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1283       SAVE_CFLAGS="$CFLAGS"
1284       CFLAGS="$CFLAGS -MMD -MF deps.d"
1285       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1286       CFLAGS="$SAVE_CFLAGS"
1287       test -f deps.d || ac_enable_autodepend=no
1288       rm -rf deps.d
1289       AC_MSG_RESULT([$ac_enable_autodepend])
1290    fi
1291    if test $ac_enable_autodepend = yes; then
1292       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1293    fi
1294 fi
1295
1296 dnl checks for operating system services
1297 AC_SYS_LONG_FILE_NAMES
1298
1299 #### Choose a window system.
1300
1301 AC_PATH_X
1302 if test "$no_x" = yes; then
1303   window_system=none
1304 else
1305   window_system=x11
1306 fi
1307
1308 ## Workaround for bug in autoconf <= 2.62.
1309 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1310 ## No need to do anything special for these standard directories.
1311 ## This is an experiment, take it out if it causes problems.
1312 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1313
1314    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1315
1316 fi
1317
1318 if test "${x_libraries}" != NONE; then
1319   if test -n "${x_libraries}"; then
1320     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1321     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1322   fi
1323   x_default_search_path=""
1324   x_search_path=${x_libraries}
1325   if test -z "${x_search_path}"; then
1326     x_search_path=/usr/lib
1327   fi
1328   for x_library in `echo ${x_search_path}: | \
1329                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1330     x_search_path="\
1331 ${x_library}/X11/%L/%T/%N%C%S:\
1332 ${x_library}/X11/%l/%T/%N%C%S:\
1333 ${x_library}/X11/%T/%N%C%S:\
1334 ${x_library}/X11/%L/%T/%N%S:\
1335 ${x_library}/X11/%l/%T/%N%S:\
1336 ${x_library}/X11/%T/%N%S"
1337     if test x"${x_default_search_path}" = x; then
1338       x_default_search_path=${x_search_path}
1339     else
1340       x_default_search_path="${x_search_path}:${x_default_search_path}"
1341     fi
1342   done
1343 fi
1344 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1345   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1346 fi
1347
1348 if test x"${x_includes}" = x; then
1349   bitmapdir=/usr/include/X11/bitmaps
1350 else
1351   # accumulate include directories that have X11 bitmap subdirectories
1352   bmd_acc="dummyval"
1353   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1354     if test -d "${bmd}/X11/bitmaps"; then
1355       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1356     fi
1357     if test -d "${bmd}/bitmaps"; then
1358       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1359     fi
1360   done
1361   if test ${bmd_acc} != "dummyval"; then
1362     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1363   fi
1364 fi
1365
1366 HAVE_NS=no
1367 NS_IMPL_COCOA=no
1368 NS_IMPL_GNUSTEP=no
1369 tmp_CPPFLAGS="$CPPFLAGS"
1370 tmp_CFLAGS="$CFLAGS"
1371 CPPFLAGS="$CPPFLAGS -x objective-c"
1372 CFLAGS="$CFLAGS -x objective-c"
1373 if test "${with_ns}" != no; then
1374   if test "${opsys}" = darwin; then
1375      NS_IMPL_COCOA=yes
1376      ns_appdir=`pwd`/nextstep/Emacs.app
1377      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1378      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1379      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1380   elif test -f $GNUSTEP_CONFIG_FILE; then
1381      NS_IMPL_GNUSTEP=yes
1382      ns_appdir=`pwd`/nextstep/Emacs.app
1383      ns_appbindir=`pwd`/nextstep/Emacs.app
1384      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1385      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1386      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1387      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1388      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1389      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1390      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1391      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1392      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1393      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1394   fi
1395   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1396                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1397   files are missing or cannot be compiled.])])
1398   NS_HAVE_NSINTEGER=yes
1399   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1400                                      [NSInteger i;])],
1401                     ns_have_nsinteger=yes,
1402                     ns_have_nsinteger=no)
1403   if test $ns_have_nsinteger = no; then
1404     NS_HAVE_NSINTEGER=no
1405   fi
1406 fi
1407
1408 NS_OBJ=
1409 NS_SUPPORT=
1410 if test "${HAVE_NS}" = yes; then
1411   window_system=nextstep
1412   with_xft=no
1413   # set up packaging dirs
1414   exec_prefix=${ns_appbindir}
1415   libexecdir=${ns_appbindir}/libexec
1416   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1417      prefix=${ns_appresdir}
1418   fi
1419   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1420   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1421 fi
1422 CFLAGS="$tmp_CFLAGS"
1423 CPPFLAGS="$tmp_CPPFLAGS"
1424 AC_SUBST(NS_OBJ)
1425 AC_SUBST(NS_SUPPORT)
1426
1427 case "${window_system}" in
1428   x11 )
1429     HAVE_X_WINDOWS=yes
1430     HAVE_X11=yes
1431     case "${with_x_toolkit}" in
1432       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1433       motif ) USE_X_TOOLKIT=MOTIF ;;
1434       gtk ) with_gtk=yes
1435 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1436 dnl USE_X_TOOLKIT is set.
1437             USE_X_TOOLKIT=none ;;
1438       no ) USE_X_TOOLKIT=none ;;
1439 dnl If user did not say whether to use a toolkit, make this decision later:
1440 dnl use the toolkit if we have gtk, or X11R5 or newer.
1441       * ) USE_X_TOOLKIT=maybe ;;
1442     esac
1443   ;;
1444   nextstep | none )
1445     HAVE_X_WINDOWS=no
1446     HAVE_X11=no
1447     USE_X_TOOLKIT=none
1448   ;;
1449 esac
1450
1451 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1452    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1453    if test "$HAVE_XSERVER" = true ||
1454       test -n "$DISPLAY" ||
1455       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1456         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1457 were found.  You should install the relevant development files for X
1458 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1459 sure you have development files for image handling, i.e.
1460 tiff, gif, jpeg, png and xpm.
1461 If you are sure you want Emacs compiled without X window support, pass
1462   --without-x
1463 to configure.])
1464    fi
1465 fi
1466
1467 ### If we're using X11, we should use the X menu package.
1468 HAVE_MENUS=no
1469 case ${HAVE_X11} in
1470   yes ) HAVE_MENUS=yes ;;
1471 esac
1472
1473 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1474 # Assume not, until told otherwise.
1475 GNU_MALLOC=yes
1476 doug_lea_malloc=yes
1477 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1478 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1479 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1480                emacs_cv_var___after_morecore_hook,
1481 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1482   emacs_cv_var___after_morecore_hook=yes,
1483   emacs_cv_var___after_morecore_hook=no)])
1484 if test $emacs_cv_var___after_morecore_hook = no; then
1485   doug_lea_malloc=no
1486 fi
1487 if test "${system_malloc}" = "yes"; then
1488   GNU_MALLOC=no
1489   GNU_MALLOC_reason="
1490     (The GNU allocators don't work with this system configuration.)"
1491 fi
1492 if test "$doug_lea_malloc" = "yes" ; then
1493   if test "$GNU_MALLOC" = yes ; then
1494     GNU_MALLOC_reason="
1495       (Using Doug Lea's new malloc from the GNU C Library.)"
1496   fi
1497   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1498             [Define to 1 if you are using the GNU C Library.])
1499 fi
1500
1501 if test x"${REL_ALLOC}" = x; then
1502   REL_ALLOC=${GNU_MALLOC}
1503 fi
1504
1505 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1506 dnl the system configuration file (s/*.h) to turn the use of mmap
1507 dnl in the relocating allocator on.
1508
1509 AC_FUNC_MMAP
1510 if test $use_mmap_for_buffers = yes; then
1511   REL_ALLOC=no
1512 fi
1513
1514 LIBS="$libsrc_libs $LIBS"
1515
1516 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1517 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1518 AC_CHECK_LIB(dnet, dnet_ntoa)
1519 dnl This causes -lresolv to get used in subsequent tests,
1520 dnl which causes failures on some systems such as HPUX 9.
1521 dnl AC_CHECK_LIB(resolv, gethostbyname)
1522
1523 dnl FIXME replace main with a function we actually want from this library.
1524 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1525
1526 AC_CHECK_LIB(pthreads, cma_open)
1527
1528 dnl Check for need for bigtoc support on IBM AIX
1529
1530 case ${host_os} in
1531 aix*)
1532   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1533     case $GCC in
1534     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1535     *) gdb_cv_bigtoc=-bbigtoc ;;
1536     esac
1537
1538     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1539     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1540   ])
1541   ;;
1542 esac
1543
1544 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1545 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1546 # REAL_CPPFLAGS later on.
1547
1548 REAL_CPPFLAGS="$CPPFLAGS"
1549
1550 if test "${HAVE_X11}" = "yes"; then
1551   DEFS="$C_SWITCH_X_SITE $DEFS"
1552   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1553   LIBS="$LIBX $LIBS"
1554   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1555   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1556
1557   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1558   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1559   # but it's more convenient here to set LD_RUN_PATH
1560   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1561   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1562     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1563     export LD_RUN_PATH
1564   fi
1565
1566   if test "${opsys}" = "gnu-linux"; then
1567     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1568     AC_TRY_LINK([],
1569      [XOpenDisplay ("foo");],
1570      [xlinux_first_failure=no],
1571      [xlinux_first_failure=yes])
1572     if test "${xlinux_first_failure}" = "yes"; then
1573       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1574       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1575       OLD_CPPFLAGS="$CPPFLAGS"
1576       OLD_LIBS="$LIBS"
1577       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1578       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1579       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1580       LIBS="$LIBS -b i486-linuxaout"
1581       AC_TRY_LINK([],
1582        [XOpenDisplay ("foo");],
1583        [xlinux_second_failure=no],
1584        [xlinux_second_failure=yes])
1585       if test "${xlinux_second_failure}" = "yes"; then
1586         # If we get the same failure with -b, there is no use adding -b.
1587         # So take it out.  This plays safe.
1588         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1589         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1590         CPPFLAGS="$OLD_CPPFLAGS"
1591         LIBS="$OLD_LIBS"
1592         AC_MSG_RESULT(no)
1593       else
1594         AC_MSG_RESULT(yes)
1595       fi
1596     else
1597       AC_MSG_RESULT(no)
1598     fi
1599   fi
1600
1601   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1602   # header files included from there.
1603   AC_MSG_CHECKING(for Xkb)
1604   AC_TRY_LINK([#include <X11/Xlib.h>
1605 #include <X11/XKBlib.h>],
1606         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1607         emacs_xkb=yes, emacs_xkb=no)
1608   AC_MSG_RESULT($emacs_xkb)
1609   if test $emacs_xkb = yes; then
1610     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1611   fi
1612
1613   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1614 XScreenNumberOfScreen XSetWMProtocols)
1615 fi
1616
1617 if test "${window_system}" = "x11"; then
1618   AC_MSG_CHECKING(X11 version 6)
1619   AC_CACHE_VAL(emacs_cv_x11_version_6,
1620   [AC_TRY_LINK([#include <X11/Xlib.h>],
1621 [#if XlibSpecificationRelease < 6
1622 fail;
1623 #endif
1624 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1625   if test $emacs_cv_x11_version_6 = yes; then
1626     AC_MSG_RESULT(6 or newer)
1627     AC_DEFINE(HAVE_X11R6, 1,
1628               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1629   else
1630     AC_MSG_RESULT(before 6)
1631   fi
1632 fi
1633
1634
1635 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1636 HAVE_RSVG=no
1637 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1638   if test "${with_rsvg}" != "no"; then
1639     RSVG_REQUIRED=2.11.0
1640     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1641
1642     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1643     AC_SUBST(RSVG_CFLAGS)
1644     AC_SUBST(RSVG_LIBS)
1645
1646     if test ".${RSVG_CFLAGS}" != "."; then
1647       HAVE_RSVG=yes
1648       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1649       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1650       LIBS="$RSVG_LIBS $LIBS"
1651     fi
1652   fi
1653 fi
1654
1655
1656 HAVE_GTK=no
1657 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1658   GLIB_REQUIRED=2.6
1659   GTK_REQUIRED=2.6
1660   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1661
1662   dnl Checks for libraries.
1663   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1664   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1665      AC_MSG_ERROR($GTK_PKG_ERRORS)
1666   fi
1667 fi
1668
1669
1670 GTK_OBJ=
1671 if test x"$pkg_check_gtk" = xyes; then
1672
1673   AC_SUBST(GTK_CFLAGS)
1674   AC_SUBST(GTK_LIBS)
1675   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1676   CFLAGS="$CFLAGS $GTK_CFLAGS"
1677   LIBS="$GTK_LIBS $LIBS"
1678   dnl Try to compile a simple GTK program.
1679   GTK_COMPILES=no
1680   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1681   if test "${GTK_COMPILES}" != "yes"; then
1682     if test "$USE_X_TOOLKIT" != "maybe"; then
1683       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1684     fi
1685   else
1686     HAVE_GTK=yes
1687     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1688     GTK_OBJ=gtkutil.o
1689     USE_X_TOOLKIT=none
1690     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1691       :
1692     else
1693       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1694        closing open displays.  This is no problem if you just use
1695        one display, but if you use more than one and close one of them
1696        Emacs may crash.]])
1697       sleep 3
1698     fi
1699   fi
1700
1701 fi
1702 AC_SUBST(GTK_OBJ)
1703
1704
1705 if test "${HAVE_GTK}" = "yes"; then
1706
1707   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1708   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1709   if test "$with_toolkit_scroll_bars" != no; then
1710     with_toolkit_scroll_bars=yes
1711   fi
1712
1713   dnl  Check if we can use multiple displays with this GTK version.
1714   dnl  If gdk_display_open exists, assume all others are there also.
1715   HAVE_GTK_MULTIDISPLAY=no
1716   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1717   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1718     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1719               [Define to 1 if GTK can handle more than one display.])
1720   fi
1721
1722   dnl  Check if we have the old file selection dialog declared and
1723   dnl  in the link library.  In 2.x it may be in the library,
1724   dnl  but not declared if deprecated featured has been selected out.
1725   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1726   HAVE_GTK_FILE_SELECTION=no
1727   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1728                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1729 #include <gtk/gtk.h>])
1730   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1731     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1732                    HAVE_GTK_FILE_SELECTION=no)
1733   fi
1734
1735   dnl  Check if we have the new file chooser dialog
1736   HAVE_GTK_FILE_CHOOSER=no
1737   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1738                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1739 #include <gtk/gtk.h>])
1740   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1741     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1742                    HAVE_GTK_FILE_CHOOSER=no)
1743   fi
1744
1745   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1746      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1747     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1748               [Define to 1 if GTK has both file selection and chooser dialog.])
1749   fi
1750
1751   dnl Check if pthreads are available.  Emacs only needs this when using
1752   dnl gtk_file_chooser under Gnome.
1753   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1754     HAVE_GTK_AND_PTHREAD=no
1755     AC_CHECK_HEADERS(pthread.h)
1756     if test "$ac_cv_header_pthread_h"; then
1757       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1758     fi
1759     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1760       case "${canonical}" in
1761         *-hpux*) ;;
1762         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1763       esac
1764       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1765                [Define to 1 if you have GTK and pthread (-lpthread).])
1766     fi
1767   fi
1768 fi
1769
1770 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1771 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1772 dnl also not configured.
1773 HAVE_DBUS=no
1774 DBUS_OBJ=
1775 if test "${with_dbus}" = "yes"; then
1776    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1777    if test "$HAVE_DBUS" = yes; then
1778      LIBS="$LIBS $DBUS_LIBS"
1779      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1780      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1781      DBUS_OBJ=dbusbind.o
1782    fi
1783 fi
1784 AC_SUBST(DBUS_OBJ)
1785
1786 dnl GConf has been tested under GNU/Linux only.
1787 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1788 HAVE_GCONF=no
1789 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1790    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1791    if test "$HAVE_GCONF" = yes; then
1792       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1793    fi
1794 fi
1795
1796 dnl SELinux is available for GNU/Linux only.
1797 HAVE_LIBSELINUX=no
1798 LIBSELINUX_LIBS=
1799 if test "${with_selinux}" = "yes"; then
1800    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1801    if test "$HAVE_LIBSELINUX" = yes; then
1802       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1803       LIBSELINUX_LIBS=-lselinux
1804    fi
1805 fi
1806 AC_SUBST(LIBSELINUX_LIBS)
1807
1808 dnl Do not put whitespace before the #include statements below.
1809 dnl Older compilers (eg sunos4 cc) choke on it.
1810 HAVE_XAW3D=no
1811 LUCID_LIBW=
1812 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1813   if test "$with_xaw3d" != no; then
1814     AC_MSG_CHECKING(for xaw3d)
1815     AC_CACHE_VAL(emacs_cv_xaw3d,
1816     [AC_TRY_LINK([
1817 #include <X11/Intrinsic.h>
1818 #include <X11/Xaw3d/Simple.h>],
1819       [],
1820       emacs_cv_xaw3d=yes,
1821       emacs_cv_xaw3d=no)])
1822   else
1823     emacs_cv_xaw3d=no
1824   fi
1825   if test $emacs_cv_xaw3d = yes; then
1826     AC_MSG_RESULT([yes; using Lucid toolkit])
1827     USE_X_TOOLKIT=LUCID
1828     HAVE_XAW3D=yes
1829     LUCID_LIBW=-lXaw3d
1830     AC_DEFINE(HAVE_XAW3D, 1,
1831               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1832   else
1833     AC_MSG_RESULT(no)
1834     AC_MSG_CHECKING(for libXaw)
1835     AC_CACHE_VAL(emacs_cv_xaw,
1836     [AC_TRY_LINK([
1837 #include <X11/Intrinsic.h>
1838 #include <X11/Xaw/Simple.h>],
1839       [],
1840       emacs_cv_xaw=yes,
1841       emacs_cv_xaw=no)])
1842     if test $emacs_cv_xaw = yes; then
1843       AC_MSG_RESULT([yes; using Lucid toolkit])
1844       USE_X_TOOLKIT=LUCID
1845       LUCID_LIBW=-lXaw
1846     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1847       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1848     else
1849       AC_MSG_RESULT([no; do not use toolkit by default])
1850       USE_X_TOOLKIT=none
1851     fi
1852   fi
1853 fi
1854
1855 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1856
1857 LIBXTR6=
1858 if test "${USE_X_TOOLKIT}" != "none"; then
1859   AC_MSG_CHECKING(X11 toolkit version)
1860   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1861   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1862 [#if XtSpecificationRelease < 6
1863 fail;
1864 #endif
1865 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1866   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1867   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1868     AC_MSG_RESULT(6 or newer)
1869     AC_DEFINE(HAVE_X11XTR6, 1,
1870               [Define to 1 if you have the X11R6 or newer version of Xt.])
1871     LIBXTR6="-lSM -lICE"
1872     case "$opsys" in
1873       ## Use libw.a along with X11R6 Xt.
1874       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
1875     esac
1876   else
1877     AC_MSG_RESULT(before 6)
1878   fi
1879
1880 dnl If using toolkit, check whether libXmu.a exists.
1881 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1882   OLDLIBS="$LIBS"
1883   if test x$HAVE_X11XTR6 = xyes; then
1884     LIBS="-lXt -lSM -lICE $LIBS"
1885   else
1886     LIBS="-lXt $LIBS"
1887   fi
1888   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1889   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1890 fi
1891 AC_SUBST(LIBXTR6)
1892
1893 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1894 if test "${HAVE_X11}" = "yes"; then
1895   if test "${USE_X_TOOLKIT}" != "none"; then
1896     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1897   fi
1898 fi
1899
1900 LIBXP=
1901 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1902   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1903   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1904     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1905 int x = 5;
1906 #else
1907 Motif version prior to 2.1.
1908 #endif],
1909     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1910   if test $emacs_cv_motif_version_2_1 = yes; then
1911     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
1912   else
1913     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1914     # We put this in CFLAGS temporarily to precede other -I options
1915     # that might be in CFLAGS temporarily.
1916     # We put this in CPPFLAGS where it precedes the other -I options.
1917     OLD_CPPFLAGS=$CPPFLAGS
1918     OLD_CFLAGS=$CFLAGS
1919     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1920     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1921     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1922       [int x = 5;],
1923       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1924     if test $emacs_cv_lesstif = yes; then
1925       # Make sure this -I option remains in CPPFLAGS after it is set
1926       # back to REAL_CPPFLAGS.
1927       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1928       # have those other -I options anyway.  Ultimately, having this
1929       # directory ultimately in CPPFLAGS will be enough.
1930       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1931       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1932     else
1933       CFLAGS=$OLD_CFLAGS
1934       CPPFLAGS=$OLD_CPPFLAGS
1935     fi
1936   fi
1937 fi
1938
1939 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1940 dnl using Motif or Xaw3d is available, and unless
1941 dnl --with-toolkit-scroll-bars=no was specified.
1942
1943 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1944             [Define to 1 if we should use toolkit scroll bars.])dnl
1945 USE_TOOLKIT_SCROLL_BARS=no
1946 if test "${with_toolkit_scroll_bars}" != "no"; then
1947   if test "${USE_X_TOOLKIT}" != "none"; then
1948     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1949       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1950       HAVE_XAW3D=no
1951       USE_TOOLKIT_SCROLL_BARS=yes
1952     elif test "${HAVE_XAW3D}" = "yes"; then
1953       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1954       USE_TOOLKIT_SCROLL_BARS=yes
1955     fi
1956   elif test "${HAVE_GTK}" = "yes"; then
1957     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1958     USE_TOOLKIT_SCROLL_BARS=yes
1959   elif test "${HAVE_NS}" = "yes"; then
1960     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1961     USE_TOOLKIT_SCROLL_BARS=yes
1962   fi
1963 fi
1964
1965 dnl See if XIM is available.
1966 AC_TRY_COMPILE([
1967           #include <X11/Xlib.h>
1968           #include <X11/Xresource.h>],
1969          [XIMProc  callback;],
1970          [HAVE_XIM=yes
1971          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1972          HAVE_XIM=no)
1973
1974 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1975
1976 if test "${with_xim}" != "no"; then
1977   AC_DEFINE(USE_XIM, 1,
1978             [Define to 1 if we should use XIM, if it is available.])
1979 fi
1980
1981
1982 if test "${HAVE_XIM}" != "no"; then
1983   late_CFLAGS=$CFLAGS
1984   if test "$GCC" = yes; then
1985     CFLAGS="$CFLAGS --pedantic-errors"
1986   fi
1987   AC_TRY_COMPILE([
1988 #include <X11/Xlib.h>
1989 #include <X11/Xresource.h>],
1990 [Display *display;
1991 XrmDatabase db;
1992 char *res_name;
1993 char *res_class;
1994 XIMProc  callback;
1995 XPointer *client_data;
1996 #ifndef __GNUC__
1997 /* If we're not using GCC, it's probably not XFree86, and this is
1998    probably right, but we can't use something like --pedantic-errors.  */
1999 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2000                                            char*, XIMProc, XPointer*);
2001 #endif
2002 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2003    client_data);],
2004     [emacs_cv_arg6_star=yes])
2005   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2006          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2007 either XPointer or XPointer*.])dnl
2008   if test "$emacs_cv_arg6_star" = yes; then
2009     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2010   else
2011     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2012   fi
2013   CFLAGS=$late_CFLAGS
2014 fi
2015
2016 ### Start of font-backend (under any platform) section.
2017 # (nothing here yet -- this is a placeholder)
2018 ### End of font-backend (under any platform) section.
2019
2020 ### Start of font-backend (under X11) section.
2021 if test "${HAVE_X11}" = "yes"; then
2022    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2023
2024    ## Use -lXft if available, unless `--with-xft=no'.
2025    HAVE_XFT=maybe
2026     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2027       with_xft="no";
2028     fi
2029     if test "x${with_xft}" != "xno"; then
2030
2031       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2032       ## Because xftfont.c uses XRenderQueryExtension, we also
2033       ## need to link to -lXrender.
2034       HAVE_XRENDER=no
2035       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2036       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2037         OLD_CPPFLAGS="$CPPFLAGS"
2038         OLD_CFLAGS="$CFLAGS"
2039         OLD_LIBS="$LIBS"
2040         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2041         CFLAGS="$CFLAGS $XFT_CFLAGS"
2042         XFT_LIBS="-lXrender $XFT_LIBS"
2043         LIBS="$XFT_LIBS $LIBS"
2044         AC_CHECK_HEADER(X11/Xft/Xft.h,
2045           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2046
2047         if test "${HAVE_XFT}" = "yes"; then
2048           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2049             AC_SUBST(XFT_LIBS)
2050           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2051         else
2052           CPPFLAGS="$OLD_CPPFLAGS"
2053           CFLAGS="$OLD_CFLAGS"
2054           LIBS="$OLD_LIBS"
2055         fi                        # "${HAVE_XFT}" = "yes"
2056       fi                          # "$HAVE_XFT" != no
2057     fi                            # "x${with_xft}" != "xno"
2058
2059     dnl For the "Does Emacs use" message at the end.
2060     if test "$HAVE_XFT" != "yes"; then
2061        HAVE_XFT=no
2062     fi
2063
2064
2065     HAVE_FREETYPE=no
2066     ## We used to allow building with FreeType and without Xft.
2067     ## However, the ftx font backend driver is not in good shape.
2068     if test "${HAVE_XFT}" = "yes"; then
2069       dnl As we use Xft, we anyway use freetype.
2070       dnl There's no need for additional CFLAGS and LIBS.
2071       HAVE_FREETYPE=yes
2072       FONTCONFIG_CFLAGS=
2073       FONTCONFIG_LIBS=
2074     fi
2075
2076     HAVE_LIBOTF=no
2077     if test "${HAVE_FREETYPE}" = "yes"; then
2078       AC_DEFINE(HAVE_FREETYPE, 1,
2079                 [Define to 1 if using the freetype and fontconfig libraries.])
2080       if test "${with_libotf}" != "no"; then
2081         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2082                           HAVE_LIBOTF=no)
2083         if test "$HAVE_LIBOTF" = "yes"; then
2084           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2085           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2086                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2087                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2088           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2089             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2090                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2091           fi
2092         fi
2093       fi
2094     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2095     dnl Does the new font backend require it, or can it work without it?
2096     fi
2097
2098     HAVE_M17N_FLT=no
2099     if test "${HAVE_LIBOTF}" = yes; then
2100       if test "${with_m17n_flt}" != "no"; then
2101         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2102         if test "$HAVE_M17N_FLT" = "yes"; then
2103           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2104         fi
2105       fi
2106     fi
2107 else
2108     HAVE_XFT=no
2109     HAVE_FREETYPE=no
2110     HAVE_LIBOTF=no
2111     HAVE_M17N_FLT=no
2112 fi
2113 ### End of font-backend (under X11) section.
2114
2115 AC_SUBST(FREETYPE_CFLAGS)
2116 AC_SUBST(FREETYPE_LIBS)
2117 AC_SUBST(FONTCONFIG_CFLAGS)
2118 AC_SUBST(FONTCONFIG_LIBS)
2119 AC_SUBST(LIBOTF_CFLAGS)
2120 AC_SUBST(LIBOTF_LIBS)
2121 AC_SUBST(M17N_FLT_CFLAGS)
2122 AC_SUBST(M17N_FLT_LIBS)
2123
2124 ### Use -lXpm if available, unless `--with-xpm=no'.
2125 HAVE_XPM=no
2126 LIBXPM=
2127 if test "${HAVE_X11}" = "yes"; then
2128   if test "${with_xpm}" != "no"; then
2129     AC_CHECK_HEADER(X11/xpm.h,
2130       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2131     if test "${HAVE_XPM}" = "yes"; then
2132       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2133       AC_EGREP_CPP(no_return_alloc_pixels,
2134       [#include "X11/xpm.h"
2135 #ifndef XpmReturnAllocPixels
2136 no_return_alloc_pixels
2137 #endif
2138       ], HAVE_XPM=no, HAVE_XPM=yes)
2139
2140       if test "${HAVE_XPM}" = "yes"; then
2141         AC_MSG_RESULT(yes)
2142       else
2143         AC_MSG_RESULT(no)
2144       fi
2145     fi
2146   fi
2147
2148   if test "${HAVE_XPM}" = "yes"; then
2149     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2150     LIBXPM=-lXpm
2151   fi
2152 fi
2153 AC_SUBST(LIBXPM)
2154
2155 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2156 HAVE_JPEG=no
2157 LIBJPEG=
2158 if test "${HAVE_X11}" = "yes"; then
2159   if test "${with_jpeg}" != "no"; then
2160     dnl Checking for jpeglib.h can lose because of a redefinition of
2161     dnl  HAVE_STDLIB_H.
2162     AC_CHECK_HEADER(jerror.h,
2163       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2164   fi
2165
2166   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2167   if test "${HAVE_JPEG}" = "yes"; then
2168     AC_DEFINE(HAVE_JPEG)
2169     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2170         [#include <jpeglib.h>
2171          version=JPEG_LIB_VERSION
2172 ],
2173         [AC_DEFINE(HAVE_JPEG)],
2174         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2175         HAVE_JPEG=no])
2176   fi
2177   if test "${HAVE_JPEG}" = "yes"; then
2178     LIBJPEG=-ljpeg
2179   fi
2180 fi
2181 AC_SUBST(LIBJPEG)
2182
2183 ### Use -lpng if available, unless `--with-png=no'.
2184 HAVE_PNG=no
2185 LIBPNG=
2186 if test "${HAVE_X11}" = "yes"; then
2187   if test "${with_png}" != "no"; then
2188     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2189     # in /usr/include/libpng.
2190     AC_CHECK_HEADERS(png.h libpng/png.h)
2191     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2192       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2193     fi
2194   fi
2195
2196   if test "${HAVE_PNG}" = "yes"; then
2197     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2198     LIBPNG="-lpng -lz -lm"
2199   fi
2200 fi
2201 AC_SUBST(LIBPNG)
2202
2203 ### Use -ltiff if available, unless `--with-tiff=no'.
2204 HAVE_TIFF=no
2205 LIBTIFF=
2206 if test "${HAVE_X11}" = "yes"; then
2207   if test "${with_tiff}" != "no"; then
2208     AC_CHECK_HEADER(tiffio.h,
2209       [tifflibs="-lz -lm"
2210       # At least one tiff package requires the jpeg library.
2211       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2212       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2213   fi
2214
2215   if test "${HAVE_TIFF}" = "yes"; then
2216     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2217     dnl FIXME -lz -lm, as per libpng?
2218     LIBTIFF=-ltiff
2219   fi
2220 fi
2221 AC_SUBST(LIBTIFF)
2222
2223 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2224 HAVE_GIF=no
2225 LIBGIF=
2226 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2227   AC_CHECK_HEADER(gif_lib.h,
2228 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2229 # Earlier versions can crash Emacs.
2230     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2231
2232   if test "$HAVE_GIF" = yes; then
2233     LIBGIF=-lgif
2234   elif test "$HAVE_GIF" = maybe; then
2235 # If gif_lib.h but no libgif, try libungif.
2236     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2237     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2238   fi
2239
2240   if test "${HAVE_GIF}" = "yes"; then
2241     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2242   fi
2243 fi
2244 AC_SUBST(LIBGIF)
2245
2246 dnl Check for required libraries.
2247 if test "${HAVE_X11}" = "yes"; then
2248   MISSING=""
2249   WITH_NO=""
2250   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2251     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2252   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2253     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2254   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2255     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2256   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2257     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2258   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2259     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2260
2261   if test "X${MISSING}" != X; then
2262     AC_MSG_ERROR([The following required libraries were not found:
2263     $MISSING
2264 Maybe some development libraries/packages are missing?
2265 If you don't want to link with them give
2266     $WITH_NO
2267 as options to configure])
2268   fi
2269 fi
2270
2271 ### Use -lgpm if available, unless `--with-gpm=no'.
2272 HAVE_GPM=no
2273 LIBGPM=
2274 if test "${with_gpm}" != "no"; then
2275   AC_CHECK_HEADER(gpm.h,
2276     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2277
2278   if test "${HAVE_GPM}" = "yes"; then
2279     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2280     LIBGPM=-lgpm
2281   fi
2282 fi
2283 AC_SUBST(LIBGPM)
2284
2285 dnl Check for malloc/malloc.h on darwin
2286 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2287
2288 C_SWITCH_X_SYSTEM=
2289 ### Use NeXTstep API to implement GUI.
2290 if test "${HAVE_NS}" = "yes"; then
2291   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2292   if test "${NS_IMPL_COCOA}" = "yes"; then
2293     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2294     GNU_OBJC_CFLAGS=
2295   fi
2296   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2297     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2298     # See also .m.o rule in Makefile.in */
2299     # FIXME: are all these flags really needed?  Document here why.  */
2300     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2301     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2302   fi
2303   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2304     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2305   fi
2306   # We also have mouse menus.
2307   HAVE_MENUS=yes
2308   OTHER_FILES=ns-app
2309 fi
2310
2311
2312 ### Use session management (-lSM -lICE) if available
2313 HAVE_X_SM=no
2314 LIBXSM=
2315 if test "${HAVE_X11}" = "yes"; then
2316   AC_CHECK_HEADER(X11/SM/SMlib.h,
2317     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2318
2319   if test "${HAVE_X_SM}" = "yes"; then
2320     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2321     LIBXSM="-lSM -lICE"
2322     case "$LIBS" in
2323       *-lSM*) ;;
2324       *)      LIBS="$LIBXSM $LIBS" ;;
2325     esac
2326   fi
2327 fi
2328 AC_SUBST(LIBXSM)
2329
2330 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2331 AC_CACHE_CHECK(whether netdb declares h_errno,
2332                emacs_cv_netdb_declares_h_errno,
2333 [AC_TRY_LINK([#include <netdb.h>],
2334   [return h_errno;],
2335   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2336 if test $emacs_cv_netdb_declares_h_errno = yes; then
2337   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2338 fi
2339
2340 AC_FUNC_ALLOCA
2341
2342 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2343 dnl FIXME is there an autoconf test that does the right thing, without
2344 dnl needing to call A_M_E afterwards?
2345 if test x"$ac_cv_func_alloca_works" != xyes; then
2346    AC_MSG_ERROR( [a system implementation of alloca is required] )
2347 fi
2348
2349 # fmod, logb, and frexp are found in -lm on most systems.
2350 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2351 AC_CHECK_LIB(m, sqrt)
2352
2353 # Check for mail-locking functions in a "mail" library.  Probably this should
2354 # have the same check as for liblockfile below.
2355 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2356 if test $have_mail = yes; then
2357   LIBS_MAIL=-lmail
2358   LIBS="$LIBS_MAIL $LIBS"
2359   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2360 else
2361   LIBS_MAIL=
2362 fi
2363 dnl Debian, at least:
2364 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2365 if test $have_lockfile = yes; then
2366    LIBS_MAIL=-llockfile
2367    LIBS="$LIBS_MAIL $LIBS"
2368    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2369 else
2370 # If we have the shared liblockfile, assume we must use it for mail
2371 # locking (e.g. Debian).  If we couldn't link against liblockfile
2372 # (no liblockfile.a installed), ensure that we don't need to.
2373   dnl This works for files generally, not just executables.
2374   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2375   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2376                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2377   if test $ac_cv_prog_liblockfile = yes; then
2378     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2379 This probably means that movemail could lose mail.
2380 There may be a `development' package to install containing liblockfile.])
2381   fi
2382 fi
2383 AC_CHECK_FUNCS(touchlock)
2384 AC_CHECK_HEADERS(maillock.h)
2385 AC_SUBST(LIBS_MAIL)
2386
2387 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2388 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2389 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2390 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2391 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2392 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2393 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2394 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2395 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2396 cfmakeraw cfsetspeed)
2397
2398 AC_CHECK_HEADERS(sys/un.h)
2399
2400 AC_FUNC_MKTIME
2401 if test "$ac_cv_func_working_mktime" = no; then
2402   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2403 fi
2404
2405 AC_FUNC_GETLOADAVG
2406
2407 AC_FUNC_FSEEKO
2408
2409 # Configure getopt.
2410 m4_include([m4/getopt.m4])
2411 gl_GETOPT_IFELSE([
2412   gl_GETOPT_SUBSTITUTE_HEADER
2413   gl_PREREQ_GETOPT
2414   GETOPTOBJS='getopt.o getopt1.o'
2415 ])
2416 AC_SUBST(GETOPTOBJS)
2417
2418 AC_FUNC_GETPGRP
2419
2420 AC_FUNC_STRFTIME
2421
2422 # UNIX98 PTYs.
2423 AC_CHECK_FUNCS(grantpt)
2424
2425 # PTY-related GNU extensions.
2426 AC_CHECK_FUNCS(getpt)
2427
2428 # Check this now, so that we will NOT find the above functions in ncurses.
2429 # That is because we have not set up to link ncurses in lib-src.
2430 # It's better to believe a function is not available
2431 # than to expect to find it in ncurses.
2432 # Also we need tputs and frieds to be able to build at all.
2433 have_tputs_et_al=true
2434 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2435 if test "$have_tputs_et_al" != true; then
2436   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2437 Maybe some development libraries/packages are missing?  Try installing
2438 libncurses-dev(el), libterminfo-dev(el) or similar.])
2439 fi
2440 # Must define this when any termcap library is found.
2441 AC_DEFINE(HAVE_LIBNCURSES, 1,
2442           [Define to 1 if you have the `ncurses' library (-lncurses).])
2443
2444 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2445
2446 resolv=no
2447 AC_TRY_LINK([#include <netinet/in.h>
2448 #include <arpa/nameser.h>
2449 #include <resolv.h>],
2450     [return res_init();],
2451     have_res_init=yes, have_res_init=no)
2452 if test "$have_res_init" = no; then
2453   OLIBS="$LIBS"
2454   LIBS="$LIBS -lresolv"
2455   AC_MSG_CHECKING(for res_init with -lresolv)
2456   AC_TRY_LINK([#include <netinet/in.h>
2457 #include <arpa/nameser.h>
2458 #include <resolv.h>],
2459     [return res_init();],
2460     have_res_init=yes, have_res_init=no)
2461   AC_MSG_RESULT($have_res_init)
2462   if test "$have_res_init" = yes ; then
2463     resolv=yes
2464   fi
2465   LIBS="$OLIBS"
2466 fi
2467
2468 if test "$have_res_init" = yes; then
2469   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2470 fi
2471
2472 # Do we need the Hesiod library to provide the support routines?
2473 LIBHESIOD=
2474 if test "$with_hesiod" != no ; then
2475   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2476   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2477      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2478                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2479   if test "$resolv" = yes ; then
2480     RESOLVLIB=-lresolv
2481   else
2482     RESOLVLIB=
2483   fi
2484   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2485         hesiod=yes, :, $RESOLVLIB)])
2486
2487   if test x"$hesiod" = xyes; then
2488     AC_DEFINE(HAVE_LIBHESIOD, 1,
2489               [Define to 1 if you have the hesiod library (-lhesiod).])
2490     LIBHESIOD=-lhesiod
2491   fi
2492 fi
2493 AC_SUBST(LIBHESIOD)
2494
2495 # Do we need libresolv (due to res_init or Hesiod)?
2496 if test "$resolv" = yes ; then
2497   AC_DEFINE(HAVE_LIBRESOLV, 1,
2498             [Define to 1 if you have the resolv library (-lresolv).])
2499   LIBRESOLV=-lresolv
2500 else
2501   LIBRESOLV=
2502 fi
2503 AC_SUBST(LIBRESOLV)
2504
2505 # These tell us which Kerberos-related libraries to use.
2506 COM_ERRLIB=
2507 CRYPTOLIB=
2508 KRB5LIB=
2509 DESLIB=
2510 KRB4LIB=
2511
2512 if test "${with_kerberos}" != no; then
2513   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2514   if test $have_com_err = yes; then
2515     COM_ERRLIB=-lcom_err
2516     LIBS="$COM_ERRLIB $LIBS"
2517     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2518   fi
2519   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2520   if test $have_crypto = yes; then
2521     CRYPTOLIB=-lcrypto
2522     LIBS="$CRYPTOLIB $LIBS"
2523     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2524   fi
2525   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2526   if test $have_k5crypto = yes; then
2527     CRYPTOLIB=-lk5crypto
2528     LIBS="$CRYPTOLIB $LIBS"
2529     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2530   fi
2531   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2532   if test $have_krb5=yes; then
2533     KRB5LIB=-lkrb5
2534     LIBS="$KRB5LIB $LIBS"
2535     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2536   fi
2537   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2538   if test "${with_kerberos5}" = no; then
2539     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2540     if test $have_des425 = yes; then
2541       DESLIB=-ldes425
2542       LIBS="$DESLIB $LIBS"
2543       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2544     else
2545       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2546       if test $have_des = yes; then
2547         DESLIB=-ldes
2548         LIBS="$DESLIB $LIBS"
2549         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2550       fi
2551     fi
2552     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2553     if test $have_krb4 = yes; then
2554       KRB4LIB=-lkrb4
2555       LIBS="$KRB4LIB $LIBS"
2556       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2557     else
2558       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2559       if test $have_krb = yes; then
2560         KRB4LIB=-lkrb
2561         LIBS="$KRB4LIB $LIBS"
2562         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2563       fi
2564     fi
2565   fi
2566
2567   if test "${with_kerberos5}" != no; then
2568     AC_CHECK_HEADERS(krb5.h,
2569       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2570                         [#include <krb5.h>])])
2571   else
2572     AC_CHECK_HEADERS(des.h,,
2573                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2574                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2575     AC_CHECK_HEADERS(krb.h,,
2576                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2577                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2578   fi
2579   AC_CHECK_HEADERS(com_err.h)
2580 fi
2581
2582 AC_SUBST(COM_ERRLIB)
2583 AC_SUBST(CRYPTOLIB)
2584 AC_SUBST(KRB5LIB)
2585 AC_SUBST(DESLIB)
2586 AC_SUBST(KRB4LIB)
2587
2588 # Solaris requires -lintl if you want strerror (which calls dgettext)
2589 # to return localized messages.
2590 AC_CHECK_LIB(intl, dgettext)
2591
2592 AC_MSG_CHECKING(whether localtime caches TZ)
2593 AC_CACHE_VAL(emacs_cv_localtime_cache,
2594 [if test x$ac_cv_func_tzset = xyes; then
2595 AC_TRY_RUN([#include <time.h>
2596 extern char **environ;
2597 unset_TZ ()
2598 {
2599   char **from, **to;
2600   for (to = from = environ; (*to = *from); from++)
2601     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2602       to++;
2603 }
2604 char TZ_GMT0[] = "TZ=GMT0";
2605 char TZ_PST8[] = "TZ=PST8";
2606 main()
2607 {
2608   time_t now = time ((time_t *) 0);
2609   int hour_GMT0, hour_unset;
2610   if (putenv (TZ_GMT0) != 0)
2611     exit (1);
2612   hour_GMT0 = localtime (&now)->tm_hour;
2613   unset_TZ ();
2614   hour_unset = localtime (&now)->tm_hour;
2615   if (putenv (TZ_PST8) != 0)
2616     exit (1);
2617   if (localtime (&now)->tm_hour == hour_GMT0)
2618     exit (1);
2619   unset_TZ ();
2620   if (localtime (&now)->tm_hour != hour_unset)
2621     exit (1);
2622   exit (0);
2623 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2624 [# If we have tzset, assume the worst when cross-compiling.
2625 emacs_cv_localtime_cache=yes])
2626 else
2627         # If we lack tzset, report that localtime does not cache TZ,
2628         # since we can't invalidate the cache if we don't have tzset.
2629         emacs_cv_localtime_cache=no
2630 fi])dnl
2631 AC_MSG_RESULT($emacs_cv_localtime_cache)
2632 if test $emacs_cv_localtime_cache = yes; then
2633   AC_DEFINE(LOCALTIME_CACHE, 1,
2634             [Define to 1 if localtime caches TZ.])
2635 fi
2636
2637 if test "x$HAVE_TIMEVAL" = xyes; then
2638   AC_CHECK_FUNCS(gettimeofday)
2639   if test $ac_cv_func_gettimeofday = yes; then
2640     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2641                    emacs_cv_gettimeofday_two_arguments,
2642     [AC_TRY_COMPILE([
2643 #ifdef TIME_WITH_SYS_TIME
2644 #include <sys/time.h>
2645 #include <time.h>
2646 #else
2647 #ifdef HAVE_SYS_TIME_H
2648 #include <sys/time.h>
2649 #else
2650 #include <time.h>
2651 #endif
2652 #endif],
2653       [struct timeval time;
2654        gettimeofday (&time, 0);],
2655       emacs_cv_gettimeofday_two_arguments=yes,
2656       emacs_cv_gettimeofday_two_arguments=no)])
2657     if test $emacs_cv_gettimeofday_two_arguments = no; then
2658       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2659                 [Define to 1 if gettimeofday accepts only one argument.])
2660     fi
2661   fi
2662 fi
2663
2664 ok_so_far=yes
2665 AC_CHECK_FUNC(socket, , ok_so_far=no)
2666 if test $ok_so_far = yes; then
2667   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2668 fi
2669 if test $ok_so_far = yes; then
2670   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2671 fi
2672 if test $ok_so_far = yes; then
2673 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2674   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2675             [Define to 1 if you have inet sockets.])
2676 fi
2677
2678 AC_CHECK_HEADERS(sys/ioctl.h)
2679
2680 if test -f /usr/lpp/X11/bin/smt.exp; then
2681   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2682             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2683 fi
2684
2685 AC_MSG_CHECKING(whether system supports dynamic ptys)
2686 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2687   AC_MSG_RESULT(yes)
2688   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2689 else
2690   AC_MSG_RESULT(no)
2691 fi
2692
2693 AC_FUNC_FORK
2694
2695 dnl Adapted from Haible's version.
2696 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2697   [AC_TRY_LINK([#include <langinfo.h>],
2698     [char* cs = nl_langinfo(CODESET);],
2699     emacs_cv_langinfo_codeset=yes,
2700     emacs_cv_langinfo_codeset=no)
2701   ])
2702 if test $emacs_cv_langinfo_codeset = yes; then
2703   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2704     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2705 fi
2706
2707 AC_CHECK_TYPES(size_t)
2708
2709 AC_TYPE_MBSTATE_T
2710
2711 dnl Restrict could probably be used effectively other than in regex.c.
2712 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2713   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2714                   emacs_cv_c_restrict=yes,
2715                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2716                                   emacs_cv_c_restrict=__restrict,
2717                                   emacs_cv_c_restrict=no)])])
2718 case "$emacs_cv_c_restrict" in
2719   yes) emacs_restrict=restrict;;
2720   no) emacs_restrict="";;
2721   *) emacs_restrict="$emacs_cv_c_restrict";;
2722 esac
2723 if test "$emacs_restrict" != __restrict; then
2724   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2725     [Define to compiler's equivalent of C99 restrict keyword.
2726      Don't define if equivalent is `__restrict'.])
2727 fi
2728
2729 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2730   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2731                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2732 if test "$emacs_cv_c_restrict_arr" = yes; then
2733   AC_DEFINE(__restrict_arr, __restrict,
2734     [Define to compiler's equivalent of C99 restrict keyword in array
2735      declarations.  Define as empty for no equivalent.])
2736 fi
2737
2738 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2739 dnl how the tty code is related to POSIX and/or other versions of termios.
2740 dnl The following looks like a useful start.
2741 dnl
2742 dnl AC_SYS_POSIX_TERMIOS
2743 dnl if test $ac_cv_sys_posix_termios = yes; then
2744 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2745 dnl                                and macros for terminal control.])
2746 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2747 dnl fi
2748
2749 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2750
2751 # Set up the CFLAGS for real compilation, so we can substitute it.
2752 CFLAGS="$REAL_CFLAGS"
2753 CPPFLAGS="$REAL_CPPFLAGS"
2754
2755 #### Find out which version of Emacs this is.
2756 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2757          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2758 if test x"${version}" = x; then
2759   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2760 fi
2761 if test x"${version}" != x"$PACKAGE_VERSION"; then
2762   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2763 fi
2764
2765 ### Specify what sort of things we'll be editing into Makefile and config.h.
2766 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2767 AC_SUBST(version)
2768 AC_SUBST(configuration)
2769 AC_SUBST(canonical)
2770 AC_SUBST(srcdir)
2771 AC_SUBST(prefix)
2772 AC_SUBST(exec_prefix)
2773 AC_SUBST(bindir)
2774 AC_SUBST(datadir)
2775 AC_SUBST(sharedstatedir)
2776 AC_SUBST(libexecdir)
2777 AC_SUBST(mandir)
2778 AC_SUBST(infodir)
2779 AC_SUBST(lispdir)
2780 AC_SUBST(locallisppath)
2781 AC_SUBST(lisppath)
2782 AC_SUBST(x_default_search_path)
2783 AC_SUBST(etcdir)
2784 AC_SUBST(archlibdir)
2785 AC_SUBST(docdir)
2786 AC_SUBST(bitmapdir)
2787 AC_SUBST(gamedir)
2788 AC_SUBST(gameuser)
2789 AC_SUBST(c_switch_system)
2790 AC_SUBST(c_switch_machine)
2791 AC_SUBST(unexec)
2792 AC_SUBST(LD_SWITCH_X_SITE)
2793 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2794 AC_SUBST(C_SWITCH_X_SITE)
2795 AC_SUBST(C_SWITCH_X_SYSTEM)
2796 AC_SUBST(CFLAGS)
2797 ## Used in lwlib/Makefile.in.
2798 AC_SUBST(X_TOOLKIT_TYPE)
2799 AC_SUBST(machfile)
2800 AC_SUBST(opsysfile)
2801 AC_SUBST(GETLOADAVG_LIBS)
2802 AC_SUBST(ns_appdir)
2803 AC_SUBST(ns_appbindir)
2804 AC_SUBST(ns_appresdir)
2805 AC_SUBST(ns_appsrc)
2806 AC_SUBST(GNUSTEP_MAKEFILES)
2807 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2808 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2809 AC_SUBST(GNU_OBJC_CFLAGS)
2810 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2811 AC_SUBST(OTHER_FILES)
2812
2813 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2814                    [Define to the canonical Emacs configuration name.])
2815 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2816                    [Define to the options passed to configure.])
2817 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2818                    [Define to the used machine dependent file.])
2819 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2820                    [Define to the used os dependent file.])
2821 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2822 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2823  may need to deal with X Windows.  For instance, if you've defined
2824  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2825  your loader can find on its own, you might want to add "-L/..." or
2826  something similar.])
2827 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2828                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2829                     in case it's needed (for Solaris, for example).])
2830 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2831 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2832  may need to deal with X Windows.  For instance, if you've defined
2833  HAVE_X_WINDOWS above and your X include files aren't in a place
2834  that your compiler can find on its own, you might want to add
2835  "-I/..." or something similar.])
2836
2837 XMENU_OBJ=
2838 XOBJ=
2839 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2840   AC_DEFINE(HAVE_X_WINDOWS, 1,
2841             [Define to 1 if you want to use the X window system.])
2842   XMENU_OBJ=xmenu.o
2843   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
2844 fi
2845 AC_SUBST(XMENU_OBJ)
2846 AC_SUBST(XOBJ)
2847
2848 WIDGET_OBJ=
2849 MOTIF_LIBW=
2850 if test "${USE_X_TOOLKIT}" != "none" ; then
2851   WIDGET_OBJ=widget.o
2852   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2853   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2854     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2855   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2856     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2857     MOTIF_LIBW=-lXm
2858     case "$opsys" in
2859       gnu-linux)
2860         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
2861         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
2862         ;;
2863
2864       unixware)
2865         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
2866         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
2867         MOTIF_LIBW="MOTIF_LIBW -lXimp"
2868         ;;
2869
2870       aix4-2)
2871         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
2872         MOTIF_LIBW="$MOTIF_LIBW -li18n"
2873         ;;
2874     esac
2875     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
2876   fi
2877 fi
2878 AC_SUBST(WIDGET_OBJ)
2879
2880 case "$USE_X_TOOLKIT" in
2881   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
2882   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
2883   *) TOOLKIT_LIBW= ;;
2884 esac
2885 AC_SUBST(TOOLKIT_LIBW)
2886
2887 if test "${HAVE_X11}" = "yes" ; then
2888   AC_DEFINE(HAVE_X11, 1,
2889             [Define to 1 if you want to use version 11 of X windows.
2890              Otherwise, Emacs expects to use version 10.])
2891 fi
2892 if test "${HAVE_MENUS}" = "yes" ; then
2893   AC_DEFINE(HAVE_MENUS, 1,
2894             [Define to 1 if you have mouse menus.
2895              (This is automatic if you use X, but the option to specify it remains.)
2896              It is also defined with other window systems that support xmenu.c.])
2897 fi
2898 if test "${GNU_MALLOC}" = "yes" ; then
2899   AC_DEFINE(GNU_MALLOC, 1,
2900             [Define to 1 if you want to use the GNU memory allocator.])
2901 fi
2902 if test "${REL_ALLOC}" = "yes" ; then
2903   AC_DEFINE(REL_ALLOC, 1,
2904             [Define REL_ALLOC if you want to use the relocating allocator for
2905              buffer space.])
2906 fi
2907
2908
2909 AH_TOP([/* GNU Emacs site configuration template file.
2910    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2911      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2912
2913 This file is part of GNU Emacs.
2914
2915 GNU Emacs is free software: you can redistribute it and/or modify
2916 it under the terms of the GNU General Public License as published by
2917 the Free Software Foundation, either version 3 of the License, or
2918 (at your option) any later version.
2919
2920 GNU Emacs is distributed in the hope that it will be useful,
2921 but WITHOUT ANY WARRANTY; without even the implied warranty of
2922 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2923 GNU General Public License for more details.
2924
2925 You should have received a copy of the GNU General Public License
2926 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2927
2928
2929 /* No code in Emacs #includes config.h twice, but some bits of code
2930    intended to work with other packages as well (like gmalloc.c)
2931    think they can include it as many times as they like.  */
2932 #ifndef EMACS_CONFIG_H
2933 #define EMACS_CONFIG_H
2934 ])dnl
2935
2936 AH_BOTTOM([
2937 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2938 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2939 #define HAVE_WINDOW_SYSTEM
2940 #define HAVE_MOUSE
2941 #endif
2942
2943 /* Define AMPERSAND_FULL_NAME if you use the convention
2944    that & in the full name stands for the login id.  */
2945 /* Turned on June 1996 supposing nobody will mind it.  */
2946 #define AMPERSAND_FULL_NAME
2947
2948 /* Define HAVE_SOUND if we have sound support.  We know it works
2949    and compiles only on the specified platforms.   For others,
2950    it probably doesn't make sense to try.  */
2951
2952 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2953 #ifdef HAVE_MACHINE_SOUNDCARD_H
2954 #define HAVE_SOUND 1
2955 #endif
2956 #ifdef HAVE_SYS_SOUNDCARD_H
2957 #define HAVE_SOUND 1
2958 #endif
2959 #ifdef HAVE_SOUNDCARD_H
2960 #define HAVE_SOUND 1
2961 #endif
2962 #ifdef HAVE_ALSA
2963 #define HAVE_SOUND 1
2964 #endif
2965 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2966
2967 /* If using GNU, then support inline function declarations. */
2968 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2969    generally, because even if non-gcc compilers accept `inline', they
2970    may reject `extern inline'.  */
2971 #if defined (__GNUC__) && defined (OPTIMIZE)
2972 #define INLINE __inline__
2973 #else
2974 #define INLINE
2975 #endif
2976
2977 /* `subprocesses' should be defined if you want to
2978    have code for asynchronous subprocesses
2979    (as used in M-x compile and M-x shell).
2980    Only MSDOS does not support this (it overrides
2981    this in its config_opsysfile below).  */
2982
2983 #define subprocesses
2984
2985 /* Include the os and machine dependent files.  */
2986 #include config_opsysfile
2987 #include config_machfile
2988
2989 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2990   (There is probably a better place to do this, but right now the Cocoa
2991    side does this in s/darwin.h and we cannot
2992    parallel this exactly since GNUstep is multi-OS. */
2993 #ifdef HAVE_NS
2994 # ifdef NS_IMPL_GNUSTEP
2995 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2996 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2997 #  define SYSTEM_PURESIZE_EXTRA 30000
2998 # endif /* NS_IMPL_GNUSTEP */
2999 #endif /* HAVE_NS */
3000
3001 /* SIGTYPE is the macro we actually use.  */
3002 #ifndef SIGTYPE
3003 #define SIGTYPE RETSIGTYPE
3004 #endif
3005
3006 #ifdef emacs /* Don't do this for lib-src.  */
3007 /* Tell regex.c to use a type compatible with Emacs.  */
3008 #define RE_TRANSLATE_TYPE Lisp_Object
3009 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3010 #ifdef make_number
3011 /* If make_number is a macro, use it.  */
3012 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3013 #else
3014 /* If make_number is a function, avoid it.  */
3015 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3016 #endif
3017 #endif
3018
3019 /* Avoid link-time collision with system mktime if we will use our own.  */
3020 #if ! HAVE_MKTIME || BROKEN_MKTIME
3021 #define mktime emacs_mktime
3022 #endif
3023
3024 #define my_strftime nstrftime   /* for strftime.c */
3025
3026 /* The rest of the code currently tests the CPP symbol BSTRING.
3027    Override any claims made by the system-description files.
3028    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3029 #undef BSTRING
3030 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3031 #define BSTRING
3032 #endif
3033
3034 /* Some of the files of Emacs which are intended for use with other
3035    programs assume that if you have a config.h file, you must declare
3036    the type of getenv.
3037
3038    This declaration shouldn't appear when alloca.s or Makefile.in
3039    includes config.h.  */
3040 #ifndef NOT_C_CODE
3041 extern char *getenv ();
3042 #endif
3043
3044 /* These default definitions are good for almost all machines.
3045    The exceptions override them in m/MACHINE.h.  */
3046
3047 #ifndef BITS_PER_CHAR
3048 #define BITS_PER_CHAR 8
3049 #endif
3050
3051 #ifndef BITS_PER_SHORT
3052 #define BITS_PER_SHORT 16
3053 #endif
3054
3055 /* Note that lisp.h uses this in a preprocessor conditional, so it
3056    would not work to use sizeof.  That being so, we do all of them
3057    without sizeof, for uniformity's sake.  */
3058 #ifndef BITS_PER_INT
3059 #define BITS_PER_INT 32
3060 #endif
3061
3062 #ifndef BITS_PER_LONG
3063 #ifdef _LP64
3064 #define BITS_PER_LONG 64
3065 #else
3066 #define BITS_PER_LONG 32
3067 #endif
3068 #endif
3069
3070 /* Define if the compiler supports function prototypes.  It may do so
3071    but not define __STDC__ (e.g. DEC C by default) or may define it as
3072    zero.  */
3073 #undef PROTOTYPES
3074 /* For mktime.c:  */
3075 #ifndef __P
3076 # if defined PROTOTYPES
3077 #  define __P(args) args
3078 # else
3079 #  define __P(args) ()
3080 # endif  /* GCC.  */
3081 #endif /* __P */
3082
3083 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3084 #ifndef NOT_C_CODE
3085 #ifdef HAVE_STRING_H
3086 #include "string.h"
3087 #endif
3088 #ifdef HAVE_STRINGS_H
3089 #include "strings.h"  /* May be needed for bcopy & al. */
3090 #endif
3091 #ifdef HAVE_STDLIB_H
3092 #include <stdlib.h>
3093 #endif
3094 #ifndef __GNUC__
3095 # ifdef HAVE_ALLOCA_H
3096 #  include <alloca.h>
3097 # else /* AIX files deal with #pragma.  */
3098 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3099 char *alloca ();
3100 #  endif
3101 # endif /* HAVE_ALLOCA_H */
3102 #endif /* __GNUC__ */
3103 #ifndef HAVE_SIZE_T
3104 typedef unsigned size_t;
3105 #endif
3106 #endif /* NOT_C_CODE */
3107
3108 /* Define HAVE_X_I18N if we have usable i18n support.  */
3109
3110 #ifdef HAVE_X11R6
3111 #define HAVE_X_I18N
3112 #elif !defined X11R5_INHIBIT_I18N
3113 #define HAVE_X_I18N
3114 #endif
3115
3116 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3117
3118 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3119 #define HAVE_X11R6_XIM
3120 #endif
3121
3122 #if defined __GNUC__ && (__GNUC__ > 2 \
3123                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3124 #define NO_RETURN       __attribute__ ((__noreturn__))
3125 #else
3126 #define NO_RETURN       /* nothing */
3127 #endif
3128
3129 /* These won't be used automatically yet.  We also need to know, at least,
3130    that the stack is continuous.  */
3131 #ifdef __GNUC__
3132 #  ifndef GC_SETJMP_WORKS
3133   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3134      see NON_SAVING_SETJMP in the target descriptions.  */
3135   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3136      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3137      Fixme: Deal with SVR3.  */
3138 #    define GC_SETJMP_WORKS 1
3139 #  endif
3140 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3141 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3142 #  endif
3143 #endif
3144
3145 #ifndef HAVE_BCOPY
3146 #define bcopy(a,b,s) memcpy (b,a,s)
3147 #endif
3148 #ifndef HAVE_BZERO
3149 #define bzero(a,s) memset (a,0,s)
3150 #endif
3151 #ifndef HAVE_BCMP
3152 #define BCMP memcmp
3153 #endif
3154
3155 #endif /* EMACS_CONFIG_H */
3156
3157 /*
3158 Local Variables:
3159 mode: c
3160 End:
3161 */
3162 ])dnl
3163
3164 #### Report on what we decided to do.
3165 #### Report GTK as a toolkit, even if it doesn't use Xt.
3166 #### It makes printing result more understandable as using GTK sets
3167 #### toolkit_scroll_bars to yes by default.
3168 if test "${HAVE_GTK}" = "yes"; then
3169   USE_X_TOOLKIT=GTK
3170 fi
3171
3172 echo "
3173 Configured for \`${canonical}'.
3174
3175   Where should the build process find the source code?    ${srcdir}
3176   What operating system and machine description files should Emacs use?
3177         \`${opsysfile}' and \`${machfile}'
3178   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3179   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3180   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3181   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3182   What window system should Emacs use?                    ${window_system}
3183   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3184
3185 if test -n "${x_includes}"; then
3186 echo "  Where do we find X Windows header files?                ${x_includes}"
3187 else
3188 echo "  Where do we find X Windows header files?                Standard dirs"
3189 fi
3190 if test -n "${x_libraries}"; then
3191 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3192 else
3193 echo "  Where do we find X Windows libraries?                   Standard dirs"
3194 fi
3195
3196 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3197 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3198 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3199 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3200 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3201 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3202 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3203 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3204 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3205 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3206 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3207
3208 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3209 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3210 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3211 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3212
3213 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3214 echo
3215
3216 if test $USE_XASSERTS = yes; then
3217    echo "  Compiling with asserts turned on."
3218    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3219 fi
3220
3221 echo
3222
3223 if test "$HAVE_NS" = "yes"; then
3224    echo
3225    echo "You must run \"make install\" in order to test the built application.
3226 The installed application will go to nextstep/Emacs.app and can be
3227 run or moved from there."
3228    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3229       echo "The application will be fully self-contained."
3230     else
3231       echo "The lisp resources for the application will be installed under ${prefix}.
3232 You may need to run \"make install\" with sudo.  The application will fail
3233 to run if these resources are not installed."
3234    fi
3235    echo
3236 fi
3237
3238 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3239   echo "D-Bus integration has been tested for GNU/Linux only."
3240   echo
3241 fi
3242
3243
3244 # Remove any trailing slashes in these variables.
3245 [test "${prefix}" != NONE &&
3246   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3247 test "${exec_prefix}" != NONE &&
3248   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3249
3250 # Now get this: Some word that is part of the ${srcdir} directory name
3251 # or the ${configuration} value might, just might, happen to be an
3252 # identifier like `sun4' or `i386' or something, and be predefined by
3253 # the C preprocessor to some helpful value like 1, or maybe the empty
3254 # string.  Needless to say consequent macro substitutions are less
3255 # than conducive to the makefile finding the correct directory.
3256 [cpp_undefs="`echo $srcdir $configuration $canonical unix |
3257   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3258   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3259
3260 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3261 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3262 ## from Makefile.c can correctly provide the arg `-traditional' to the
3263 ## C preprocessor.
3264
3265 AC_EGREP_CPP(yes..yes,
3266         [yes..yes],
3267         CPP_NEED_TRADITIONAL=no,
3268         CPP_NEED_TRADITIONAL=yes)
3269
3270 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3271         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3272         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3273         lwlib/Makefile lisp/Makefile leim/Makefile, [
3274
3275 ### Make the necessary directories, if they don't exist.
3276 for dir in etc lisp ; do
3277   test -d ${dir} || mkdir ${dir}
3278 done
3279
3280 # Build src/Makefile from ${srcdir}/src/Makefile.c
3281 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3282 # This must be done after src/config.h is built, since we rely on that file.
3283
3284 echo creating src/epaths.h
3285 ${MAKE-make} epaths-force
3286
3287 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3288 # `..' to `. .'  unless invoked with -traditional
3289
3290 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3291   CPPFLAGS="$CPPFLAGS -traditional"
3292 fi
3293
3294 echo creating lib-src/Makefile
3295 ( cd lib-src
3296   rm -f junk.c junk1.c junk2.c
3297   sed -e '/start of cpp stuff/q' \
3298       < Makefile.c > junk1.c
3299   sed -e '1,/start of cpp stuff/d'\
3300       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3301       < Makefile.c > junk.c
3302   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3303       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3304   cat junk1.c junk2.c > Makefile.new
3305   rm -f junk.c junk1.c junk2.c
3306   chmod 444 Makefile.new
3307   mv -f Makefile.new Makefile
3308 )
3309
3310 echo creating src/Makefile
3311 ( cd src
3312   rm -f junk.c junk1.c junk2.c
3313   sed -e '/start of cpp stuff/q' \
3314       < Makefile.c > junk1.c
3315   sed -e '1,/start of cpp stuff/d'\
3316       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3317       < Makefile.c > junk.c
3318   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3319       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3320   cat junk1.c junk2.c > Makefile.new
3321   rm -f junk.c junk1.c junk2.c
3322   chmod 444 Makefile.new
3323   mv -f Makefile.new Makefile
3324 )
3325
3326 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3327   echo creating src/.gdbinit
3328   echo source $srcdir/src/.gdbinit > src/.gdbinit
3329 fi
3330
3331 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3332
3333 m4_if(dnl       Do not change this comment
3334    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3335 )dnl