configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_WITH([gnustep-conf],dnl
 173 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 174 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 175   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 176 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 177      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 178
 179 AC_ARG_ENABLE(cocoa-experimental-ctrl-g,
 180 [AS_HELP_STRING([--enable-cocoa-experimental-ctrl-g],
 181                 [enable experimental improved ctrl-g recognition])],
 182    EN_COCOA_EXPERIMENTAL_CTRL_G=$enableval,
 183    EN_COCOA_EXPERIMENTAL_CTRL_G=no)
 184
 185 AC_ARG_ENABLE(ns-self-contained,
 186 [AS_HELP_STRING([--disable-ns-self-contained],
 187                 [disable self contained build under NeXTstep])],
 188    EN_NS_SELF_CONTAINED=$enableval,
 189    EN_NS_SELF_CONTAINED=yes)
 190
 191 AC_ARG_ENABLE(asserts,
 192 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 193       USE_XASSERTS=$enableval,
 194       USE_XASSERTS=no)
 195
 196 AC_ARG_ENABLE(maintainer-mode,
 197 [AS_HELP_STRING([--enable-maintainer-mode],
 198                 [enable make rules and dependencies not useful (and sometimes
 199                  confusing) to the casual installer])],
 200       USE_MAINTAINER_MODE=$enableval,
 201       USE_MAINTAINER_MODE=no)
 202 if test $USE_MAINTAINER_MODE = yes; then
 203   MAINT=
 204 else
 205   MAINT=#
 206 fi
 207 AC_SUBST(MAINT)
 208
 209 AC_ARG_ENABLE(locallisppath,
 210 [AS_HELP_STRING([--enable-locallisppath=PATH],
 211                 [directories Emacs should search for lisp files specific
 212                  to this site])],
 213 if test "${enableval}" = "no"; then
 214   locallisppath=
 215 elif test "${enableval}" != "yes"; then
 216   locallisppath=${enableval}
 217 fi)
 218
 219 #### Make srcdir absolute, if it isn't already.  It's important to
 220 #### avoid running the path through pwd unnecessarily, since pwd can
 221 #### give you automounter prefixes, which can go away.  We do all this
 222 #### so Emacs can find its files when run uninstalled.
 223 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 224 unset CDPATH
 225 case "${srcdir}" in
 226   /* ) ;;
 227   . )
 228     ## We may be able to use the $PWD environment variable to make this
 229     ## absolute.  But sometimes PWD is inaccurate.
 230     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 231     ## but that tested only for a well-formed and valid PWD,
 232     ## it did not object when PWD was well-formed and valid but just wrong.
 233     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 234     then
 235       srcdir="$PWD"
 236     else
 237       srcdir="`(cd ${srcdir}; pwd)`"
 238     fi
 239   ;;
 240   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 241 esac
 242
 243 #### Check if the source directory already has a configured system in it.
 244 if test `pwd` != `(cd ${srcdir} && pwd)` \
 245    && test -f "${srcdir}/src/config.h" ; then
 246   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 247    as a build directory right now; it has been configured in its own
 248    right.  To configure in another directory as well, you MUST
 249    use GNU make.  If you do not have GNU make, then you must
 250    now do `make distclean' in ${srcdir},
 251    and then run $0 again.]])
 252 fi
 253
 254 #### Given the configuration name, set machfile and opsysfile to the
 255 #### names of the m/*.h and s/*.h files we should use.
 256
 257 ### Canonicalize the configuration name.
 258
 259 AC_CANONICAL_HOST
 260 canonical=$host
 261 configuration=${host_alias-${build_alias-$host}}
 262
 263 dnl This used to use changequote, but, apart from `changequote is evil'
 264 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 265 dnl the great gob of text.  Thus it's not processed for possible expansion.
 266 dnl Just make sure the brackets remain balanced.
 267 dnl
 268 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 269 dnl indicated by comments.
 270 dnl quotation begins
 271 [
 272
 273 ### If you add support for a new configuration, add code to this
 274 ### switch statement to recognize your configuration name and select
 275 ### the appropriate operating system and machine description files.
 276
 277 ### You would hope that you could choose an m/*.h file pretty much
 278 ### based on the machine portion of the configuration name, and an s-
 279 ### file based on the operating system portion.  However, it turns out
 280 ### that each m/*.h file is pretty manufacturer-specific - for
 281 ### example mips.h is MIPS
 282 ### So we basically have to have a special case for each
 283 ### configuration name.
 284 ###
 285 ### As far as handling version numbers on operating systems is
 286 ### concerned, make sure things will fail in a fixable way.  If
 287 ### /etc/MACHINES doesn't say anything about version numbers, be
 288 ### prepared to handle anything reasonably.  If version numbers
 289 ### matter, be sure /etc/MACHINES says something about it.
 290 ###
 291 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 292 ### "System V Release 4"; he writes, "The old convention encouraged
 293 ### confusion between `system' and `release' levels'."
 294
 295 machine='' opsys='' unported=no
 296 case "${canonical}" in
 297
 298   ## FreeBSD ports
 299   *-*-freebsd* )
 300     opsys=freebsd
 301     case "${canonical}" in
 302       alpha*-*-freebsd*)        machine=alpha ;;
 303       arm*-*-freebsd*)          machine=arm ;;
 304       ia64-*-freebsd*)          machine=ia64 ;;
 305       sparc-*-freebsd*)         machine=sparc ;;
 306       sparc64-*-freebsd*)       machine=sparc ;;
 307       powerpc-*-freebsd*)       machine=macppc ;;
 308       i[3456]86-*-freebsd*)     machine=intel386 ;;
 309       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 310     esac
 311   ;;
 312
 313   ## FreeBSD kernel + glibc based userland
 314   *-*-kfreebsd*gnu* )
 315     opsys=gnu-kfreebsd
 316     case "${canonical}" in
 317       alpha*-*-kfreebsd*)       machine=alpha ;;
 318       ia64-*-kfreebsd*)         machine=ia64 ;;
 319       sparc-*-kfreebsd*)        machine=sparc ;;
 320       sparc64-*-kfreebsd*)      machine=sparc ;;
 321       powerpc-*-kfreebsd*)      machine=macppc ;;
 322       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 323       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 324     esac
 325   ;;
 326
 327   ## NetBSD ports
 328   *-*-netbsd* )
 329     opsys=netbsd
 330     if test -f /usr/lib/crti.o; then]
 331 dnl The close and open brackets here are because this section is quoted --
 332 dnl see the `changequote' comment above.
 333       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 334 [   fi
 335
 336     case "${canonical}" in
 337       alpha*-*-netbsd*) machine=alpha ;;
 338       i[3456]86-*-netbsd*) machine=intel386 ;;
 339       powerpc-*-netbsd*) machine=macppc ;;
 340       sparc*-*-netbsd*) machine=sparc ;;
 341       vax-*-netbsd*)    machine=vax ;;
 342       arm-*-netbsd*)    machine=arm ;;
 343       x86_64-*-netbsd*) machine=amdx86-64 ;;
 344       hppa-*-netbsd*)   machine=hp800 ;;
 345     esac
 346   ;;
 347
 348   ## OpenBSD ports
 349   *-*-openbsd* )
 350     opsys=openbsd
 351     case "${canonical}" in
 352       alpha*-*-openbsd*)        machine=alpha ;;
 353       arm-*-openbsd*)          machine=arm ;;
 354       i386-*-openbsd*)         machine=intel386 ;;
 355       powerpc-*-openbsd*)      machine=macppc ;;
 356       sparc*-*-openbsd*)       machine=sparc ;;
 357       vax-*-openbsd*)          machine=vax ;;
 358       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 359       hppa-*-openbsd*)         machine=hp800 ;;
 360     esac
 361   ;;
 362
 363   ## LynxOS ports
 364   *-*-lynxos* )
 365     opsys=lynxos
 366     case "${canonical}" in
 367       i[3456]86-*-lynxos*) machine=intel386 ;;
 368       powerpc-*-lynxos*) machine=powerpc ;;
 369     esac
 370   ;;
 371
 372   alpha*-*-linux-gnu* )
 373     machine=alpha opsys=gnu-linux
 374   ;;
 375
 376   arm*-*-linux-gnu* )
 377     machine=arm opsys=gnu-linux
 378   ;;
 379
 380   ## Apple Darwin / Mac OS X
 381   *-apple-darwin* )
 382     case "${canonical}" in
 383       i[3456]86-* )  machine=intel386 ;;
 384       powerpc-* )    machine=macppc ;;
 385       * )            unported=yes ;;
 386     esac
 387     opsys=darwin
 388     # Define CPP as follows to make autoconf work correctly.
 389     CPP="${CC-cc} -E -no-cpp-precomp"
 390     # Use fink packages if available.
 391     if test -d /sw/include && test -d /sw/lib; then
 392       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 393       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 394       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 395     fi
 396   ;;
 397
 398   ## HP 9000 series 700 and 800, running HP/UX
 399   hppa*-hp-hpux10.2* )
 400     machine=hp800 opsys=hpux10-20
 401   ;;
 402   hppa*-hp-hpux1[1-9]* )
 403     machine=hp800 opsys=hpux11
 404     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 405   ;;
 406
 407   hppa*-*-linux-gnu* )
 408     machine=hp800 opsys=gnu-linux
 409   ;;
 410
 411   ## IBM machines
 412   s390-*-linux-gnu* )
 413     machine=ibms390 opsys=gnu-linux
 414   ;;
 415   s390x-*-linux-gnu* )
 416     machine=ibms390x opsys=gnu-linux
 417   ;;
 418   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 419     machine=ibmrs6000 opsys=aix4-2
 420   ;;
 421   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 422     machine=ibmrs6000 opsys=aix4-2
 423   ;;
 424   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 425     machine=ibmrs6000 opsys=aix4-2
 426   ;;
 427   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 428     machine=ibmrs6000 opsys=aix4-2
 429   ;;
 430
 431   ## Macintosh PowerPC
 432   powerpc*-*-linux-gnu* )
 433     machine=macppc opsys=gnu-linux
 434   ;;
 435
 436   ## Silicon Graphics machines
 437   ## Iris 4D
 438   mips-sgi-irix6.5 )
 439     machine=iris4d opsys=irix6-5
 440     # Without defining _LANGUAGE_C, things get masked out in the headers
 441     # so that, for instance, grepping for `free' in stdlib.h fails and
 442     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 443     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 444     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 445   ;;
 446
 447   ## Suns
 448   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 449     machine=sparc opsys=gnu-linux
 450   ;;
 451
 452   *-sun-solaris* \
 453     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 454     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 455     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 456     case "${canonical}" in
 457       i[3456]86-*-* )     machine=intel386 ;;
 458       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 459       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 460       sparc* )          machine=sparc ;;
 461       * )               unported=yes ;;
 462     esac
 463     case "${canonical}" in
 464       *-sunos5.3* | *-solaris2.3* )
 465                 opsys=sol2-3
 466                 NON_GNU_CPP=/usr/ccs/lib/cpp
 467                 ;;
 468       *-sunos5.4* | *-solaris2.4* )
 469                 opsys=sol2-4
 470                 NON_GNU_CPP=/usr/ccs/lib/cpp
 471                 RANLIB="ar -ts"
 472                 ;;
 473       *-sunos5.5* | *-solaris2.5* )
 474                 opsys=sol2-5
 475                 NON_GNU_CPP=/usr/ccs/lib/cpp
 476                 RANLIB="ar -ts"
 477                 ;;
 478       *-sunos5.6* | *-solaris2.6* )
 479                 opsys=sol2-6
 480                 NON_GNU_CPP=/usr/ccs/lib/cpp
 481                 RANLIB="ar -ts"
 482                 ;;
 483       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 484                 opsys=sol2-6
 485                 emacs_check_sunpro_c=yes
 486                 NON_GNU_CPP=/usr/ccs/lib/cpp
 487                 ;;
 488       *-sunos5* | *-solaris* )
 489                 opsys=sol2-10
 490                 emacs_check_sunpro_c=yes
 491                 NON_GNU_CPP=/usr/ccs/lib/cpp
 492                 ;;
 493     esac
 494     ## Watch out for a compiler that we know will not work.
 495     case "${canonical}" in
 496      *-solaris* | *-sunos5* )
 497                 if [ "x$CC" = x/usr/ucb/cc ]; then
 498                   ## /usr/ucb/cc doesn't work;
 499                   ## we should find some other compiler that does work.
 500                   unset CC
 501                 fi
 502                 ;;
 503       *) ;;
 504     esac
 505   ;;
 506
 507   ## Vaxen.
 508   vax-dec-* )
 509     machine=vax
 510     case "${canonical}" in
 511       *-vms* )                                          opsys=vms ;;
 512       * )                                               unported=yes
 513     esac
 514   ;;
 515
 516   ## IA-64
 517   ia64*-*-linux* )
 518     machine=ia64 opsys=gnu-linux
 519   ;;
 520
 521   ## Intel 386 machines where we don't care about the manufacturer
 522   i[3456]86-*-* )
 523     machine=intel386
 524     case "${canonical}" in
 525       *-cygwin )                opsys=cygwin ;;
 526       *-darwin* )               opsys=darwin
 527                                 CPP="${CC-cc} -E -no-cpp-precomp"
 528                                 ;;
 529       *-linux-gnu* )            opsys=gnu-linux ;;
 530       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 531       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 532       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 533       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 534     esac
 535   ;;
 536
 537   ## m68k Linux-based GNU system
 538   m68k-*-linux-gnu* )
 539     machine=m68k opsys=gnu-linux
 540   ;;
 541
 542   ## Mips Linux-based GNU system
 543   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 544     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 545     machine=mips opsys=gnu-linux
 546   ;;
 547
 548   ## AMD x86-64 Linux-based GNU system
 549   x86_64-*-linux-gnu* )
 550     machine=amdx86-64 opsys=gnu-linux
 551   ;;
 552
 553   ## Tensilica Xtensa Linux-based GNU system
 554   xtensa*-*-linux-gnu* )
 555     machine=xtensa opsys=gnu-linux
 556     ;;
 557
 558   ## SuperH Linux-based GNU system
 559   sh[34]*-*-linux-gnu* )
 560     machine=sh3 opsys=gnu-linux
 561   ;;
 562
 563   * )
 564     unported=yes
 565   ;;
 566 esac
 567
 568 ### If the code above didn't choose an operating system, just choose
 569 ### an operating system based on the configuration name.  You really
 570 ### only want to use this when you have no idea what the right
 571 ### operating system is; if you know what operating systems a machine
 572 ### runs, it's cleaner to make it explicit in the case statement
 573 ### above.
 574 if test x"${opsys}" = x; then
 575   case "${canonical}" in
 576     *-gnu* )                            opsys=gnu ;;
 577     *-sysv4.2uw* )                      opsys=unixware ;;
 578     *-sysv5uw* )                        opsys=unixware ;;
 579     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 580     *-sysv4.1* | *-sysvr4.1* )
 581         NON_GNU_CPP=/usr/lib/cpp
 582         opsys=usg5-4 ;;
 583     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 584         if [ x$NON_GNU_CPP = x ]; then
 585           if [ -f /usr/ccs/lib/cpp ]; then
 586             NON_GNU_CPP=/usr/ccs/lib/cpp
 587           else
 588             NON_GNU_CPP=/lib/cpp
 589           fi
 590         fi
 591         opsys=usg5-4-2 ;;
 592     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 593     * )
 594       unported=yes
 595     ;;
 596   esac
 597 fi
 598
 599 ]
 600 dnl quotation ends
 601
 602 if test $unported = yes; then
 603   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 604 Check `etc/MACHINES' for recognized configuration names.])
 605 fi
 606
 607 machfile="m/${machine}.h"
 608 opsysfile="s/${opsys}.h"
 609
 610
 611 #### Choose a compiler.
 612 test -n "$CC" && cc_specified=yes
 613
 614 # Save the value of CFLAGS that the user specified.
 615 SPECIFIED_CFLAGS="$CFLAGS"
 616
 617 dnl Sets GCC=yes if using gcc.
 618 AC_PROG_CC
 619
 620 # On Suns, sometimes $CPP names a directory.
 621 if test -n "$CPP" && test -d "$CPP"; then
 622   CPP=
 623 fi
 624
 625 ## If not using gcc, and on Solaris, and no CPP specified, see if
 626 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 627 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 628  test x"$CPP" = x; then
 629   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 630   AC_CACHE_VAL(emacs_cv_sunpro_c,
 631   [AC_TRY_LINK([],
 632 [#ifndef __SUNPRO_C
 633 fail;
 634 #endif
 635 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 636   AC_MSG_RESULT($emacs_cv_sunpro_c)
 637
 638   if test x"$emacs_cv_sunpro_c" = xyes; then
 639     NON_GNU_CPP="$CC -E -Xs"
 640   fi
 641 fi
 642
 643 #### Some systems specify a CPP to use unless we are using GCC.
 644 #### Now that we know whether we are using GCC, we can decide whether
 645 #### to use that one.
 646 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 647 then
 648   CPP="$NON_GNU_CPP"
 649 fi
 650
 651 #### Some systems specify a CC to use unless we are using GCC.
 652 #### Now that we know whether we are using GCC, we can decide whether
 653 #### to use that one.
 654 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 655   test x$cc_specified != xyes
 656 then
 657   CC="$NON_GNU_CC"
 658 fi
 659
 660 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 661 then
 662   CC="$CC $GCC_TEST_OPTIONS"
 663 fi
 664
 665 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 666 then
 667   CC="$CC $NON_GCC_TEST_OPTIONS"
 668 fi
 669
 670 dnl checks for Unix variants
 671 AC_USE_SYSTEM_EXTENSIONS
 672
 673 ### Use -Wno-pointer-sign if the compiler supports it
 674 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 675 SAVE_CFLAGS="$CFLAGS"
 676 CFLAGS="$CFLAGS -Wno-pointer-sign"
 677 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 678 if test $has_option = yes; then
 679    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 680 fi
 681 AC_MSG_RESULT($has_option)
 682 CFLAGS="$SAVE_CFLAGS"
 683 unset has_option
 684 unset SAVE_CFLAGS
 685
 686 #### Some other nice autoconf tests.
 687
 688 dnl checks for programs
 689 AC_PROG_LN_S
 690 AC_PROG_CPP
 691 AC_PROG_INSTALL
 692 if test "x$RANLIB" = x; then
 693   AC_PROG_RANLIB
 694 fi
 695 AC_PATH_PROG(INSTALL_INFO, install-info)
 696 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 697 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 698 dnl Don't use GZIP, which is used by gzip for additional parameters.
 699 AC_PATH_PROG(GZIP_PROG, gzip)
 700
 701
 702 ## Need makeinfo >= 4.6 (?) to build the manuals.
 703 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 704 dnl By this stage, configure has already checked for egrep and set EGREP,
 705 dnl or exited with an error if no egrep was found.
 706 if test "$MAKEINFO" != "no" && \
 707   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 708    MAKEINFO=no
 709 fi
 710
 711 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 712 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 713 ## therefore in the category of "special tools" not normally required, which
 714 ## configure does not have to check for (eg autoconf itself).
 715 ## In a CVS checkout on the other hand, the manuals are not included.
 716 ## So makeinfo is a requirement to build from CVS, and configure
 717 ## should test for it as it does for any other build requirement.
 718 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 719 ## with pre-built manuals, from a CVS checkout.
 720 if test "$MAKEINFO" = "no"; then
 721   if test "x${with_makeinfo}" = "xno"; then
 722     MAKEINFO=off
 723   elif ! test -e $srcdir/info/emacs; then
 724     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 725 source tree does not seem to have pre-built manuals in the `info' directory.
 726 Either install a suitable version of makeinfo, or re-run configure
 727 with the `--without-makeinfo' option to build without the manuals.] )
 728   fi
 729 fi
 730
 731 dnl Add our options to ac_link now, after it is set up.
 732
 733 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 734 then
 735   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 736 fi
 737
 738 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 739 then
 740   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 741 fi
 742
 743 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 744 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 745 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 746 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 747 dnl if not built to support GNU ld.
 748
 749 late_LDFLAGS=$LDFLAGS
 750 if test "$GCC" = yes; then
 751   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 752 else
 753   LDFLAGS="$LDFLAGS -znocombreloc"
 754 fi
 755
 756 AC_MSG_CHECKING([for -znocombreloc])
 757 AC_LINK_IFELSE([main(){return 0;}],
 758   [AC_MSG_RESULT(yes)],
 759   LDFLAGS=$late_LDFLAGS
 760   [AC_MSG_RESULT(no)])
 761
 762 #### Extract some information from the operating system and machine files.
 763
 764 AC_CHECKING([the machine- and system-dependent files to find out
 765  - which libraries the lib-src programs will want, and
 766  - whether the GNU malloc routines are usable])
 767
 768 ### First figure out CFLAGS (which we use for running the compiler here)
 769 ### and REAL_CFLAGS (which we use for real compilation).
 770 ### The two are the same except on a few systems, where they are made
 771 ### different to work around various lossages.  For example,
 772 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 773 ### as implying static linking.
 774
 775 ### If the CFLAGS env var is specified, we use that value
 776 ### instead of the default.
 777
 778 ### It's not important that this name contain the PID; you can't run
 779 ### two configures in the same directory and have anything work
 780 ### anyway.
 781 tempcname="conftest.c"
 782
 783 echo '
 784 #include "'${srcdir}'/src/'${opsysfile}'"
 785 #include "'${srcdir}'/src/'${machfile}'"
 786 #ifndef LIBS_MACHINE
 787 #define LIBS_MACHINE
 788 #endif
 789 #ifndef LIBS_SYSTEM
 790 #define LIBS_SYSTEM
 791 #endif
 792 #ifndef C_SWITCH_SYSTEM
 793 #define C_SWITCH_SYSTEM
 794 #endif
 795 #ifndef C_SWITCH_MACHINE
 796 #define C_SWITCH_MACHINE
 797 #endif
 798 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 799 configure___ c_switch_system=C_SWITCH_SYSTEM
 800 configure___ c_switch_machine=C_SWITCH_MACHINE
 801
 802 #ifndef LIB_X11_LIB
 803 #define LIB_X11_LIB -lX11
 804 #endif
 805
 806 #ifndef LIBX11_SYSTEM
 807 #define LIBX11_SYSTEM
 808 #endif
 809 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 810
 811 #ifdef UNEXEC
 812 configure___ unexec=UNEXEC
 813 #else
 814 configure___ unexec=unexec.o
 815 #endif
 816
 817 #ifdef SYSTEM_MALLOC
 818 configure___ system_malloc=yes
 819 #else
 820 configure___ system_malloc=no
 821 #endif
 822
 823 #ifdef USE_MMAP_FOR_BUFFERS
 824 configure___ use_mmap_for_buffers=yes
 825 #else
 826 configure___ use_mmap_for_buffers=no
 827 #endif
 828
 829 #ifndef C_DEBUG_SWITCH
 830 #define C_DEBUG_SWITCH -g
 831 #endif
 832
 833 #ifndef C_OPTIMIZE_SWITCH
 834 #ifdef __GNUC__
 835 #define C_OPTIMIZE_SWITCH -O2
 836 #else
 837 #define C_OPTIMIZE_SWITCH -O
 838 #endif
 839 #endif
 840
 841 #ifndef C_WARNINGS_SWITCH
 842 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 843 #endif
 844
 845 #ifndef LD_SWITCH_MACHINE
 846 #define LD_SWITCH_MACHINE
 847 #endif
 848
 849 #ifndef LD_SWITCH_SYSTEM
 850 #define LD_SWITCH_SYSTEM
 851 #endif
 852
 853 #ifndef LD_SWITCH_X_SITE_AUX
 854 #define LD_SWITCH_X_SITE_AUX
 855 #endif
 856
 857 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 858 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 859
 860 #ifdef THIS_IS_CONFIGURE
 861
 862 /* Get the CFLAGS for tests in configure.  */
 863 #ifdef __GNUC__
 864 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 865 #else
 866 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 867 #endif
 868
 869 #else /* not THIS_IS_CONFIGURE */
 870
 871 /* Get the CFLAGS for real compilation.  */
 872 #ifdef __GNUC__
 873 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 874 #else
 875 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 876 #endif
 877
 878 #endif /* not THIS_IS_CONFIGURE */
 879 ' > ${tempcname}
 880
 881 # The value of CPP is a quoted variable reference, so we need to do this
 882 # to get its actual value...
 883 CPP=`eval "echo $CPP"`
 884 [eval `${CPP} -Isrc ${tempcname} \
 885        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 886 if test "x$SPECIFIED_CFLAGS" = x; then
 887   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 888          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 889 else
 890   REAL_CFLAGS="$CFLAGS"
 891 fi]
 892 rm ${tempcname}
 893
 894 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 895
 896 ### Make sure subsequent tests use flags consistent with the build flags.
 897
 898 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 899   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 900 else
 901   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 902 fi
 903
 904 dnl For AC_FUNC_GETLOADAVG, at least:
 905 AC_CONFIG_LIBOBJ_DIR(src)
 906
 907 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 908 AC_SYS_LARGEFILE
 909
 910
 911 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 912 ### be located in either /usr/lib64 or /usr/lib.
 913 ### In some rare cases, /usr/lib64 exists but does not contain the
 914 ### relevant files (bug#1287).  Hence test for crtn.o.
 915 case "${canonical}" in
 916   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 917     if test -e /usr/lib64/crtn.o; then
 918       AC_DEFINE(HAVE_LIB64_DIR, 1,
 919         [Define to 1 if the directory /usr/lib64 exists.])
 920 fi
 921 esac
 922
 923 dnl This function defintion taken from Gnome 2.0
 924 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 925 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 926 dnl also defines GSTUFF_PKG_ERRORS on error
 927 AC_DEFUN([PKG_CHECK_MODULES], [
 928   succeeded=no
 929
 930   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 931
 932   if test "$PKG_CONFIG" = "no" ; then
 933      ifelse([$4], , [AC_MSG_ERROR([
 934       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 935   else
 936      PKG_CONFIG_MIN_VERSION=0.9.0
 937      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 938         AC_MSG_CHECKING(for $2)
 939
 940         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 941             AC_MSG_RESULT(yes)
 942             succeeded=yes
 943
 944             AC_MSG_CHECKING($1_CFLAGS)
 945             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 946             AC_MSG_RESULT($$1_CFLAGS)
 947
 948             AC_MSG_CHECKING($1_LIBS)
 949             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 950             AC_MSG_RESULT($$1_LIBS)
 951         else
 952             AC_MSG_RESULT(no)
 953             $1_CFLAGS=""
 954             $1_LIBS=""
 955             ## If we have a custom action on failure, don't print errors, but
 956             ## do set a variable so people can do so.
 957             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 958             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 959         fi
 960
 961         AC_SUBST($1_CFLAGS)
 962         AC_SUBST($1_LIBS)
 963      else
 964         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 965         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 966      fi
 967   fi
 968
 969   if test $succeeded = yes; then
 970      ifelse([$3], , :, [$3])
 971   else
 972      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 973   fi
 974 ])
 975
 976
 977 if test "${with_sound}" != "no"; then
 978   # Sound support for GNU/Linux and the free BSDs.
 979   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 980   # Emulation library used on NetBSD.
 981   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 982   AC_SUBST(LIBSOUND)
 983
 984   ALSA_REQUIRED=1.0.0
 985   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 986   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 987   if test $HAVE_ALSA = yes; then
 988     SAVE_CFLAGS="$CFLAGS"
 989     SAVE_LDFLAGS="$LDFLAGS"
 990     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 991     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 992     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 993                     emacs_alsa_normal=yes,
 994                     emacs_alsa_normal=no)
 995     if test "$emacs_alsa_normal" != yes; then
 996       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 997                      [snd_lib_error_set_handler (0);],
 998                      emacs_alsa_subdir=yes,
 999                      emacs_alsa_subdir=no)
1000       if test "$emacs_alsa_subdir" != yes; then
1001         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1002       fi
1003       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1004     fi
1005
1006     CFLAGS="$SAVE_CFLAGS"
1007     LDFLAGS="$SAVE_LDFLAGS"
1008     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1009     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1010     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1011   fi
1012   AC_SUBST(CFLAGS_SOUND)
1013 fi
1014
1015 dnl checks for header files
1016 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1017   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1018   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1019   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1020   sys/utsname.h pwd.h)
1021
1022 AC_MSG_CHECKING(if personality LINUX32 can be set)
1023 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1024                emacs_cv_personality_linux32=yes,
1025                emacs_cv_personality_linux32=no)
1026 AC_MSG_RESULT($emacs_cv_personality_linux32)
1027
1028 if test $emacs_cv_personality_linux32 = yes; then
1029   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1030             [Define to 1 if personality LINUX32 can be set.])
1031 fi
1032
1033 dnl On Solaris 8 there's a compilation warning for term.h because
1034 dnl it doesn't define `bool'.
1035 AC_CHECK_HEADERS(term.h, , , -)
1036 AC_HEADER_STDC
1037 AC_HEADER_TIME
1038 AC_CHECK_DECLS([sys_siglist])
1039 if test $ac_cv_have_decl_sys_siglist != yes; then
1040   # For Tru64, at least:
1041   AC_CHECK_DECLS([__sys_siglist])
1042   if test $ac_cv_have_decl___sys_siglist = yes; then
1043     AC_DEFINE(sys_siglist, __sys_siglist,
1044               [Define to any substitute for sys_siglist.])
1045   fi
1046 fi
1047 AC_HEADER_SYS_WAIT
1048
1049 dnl Some systems have utime.h but don't declare the struct anyplace.
1050 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1051 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1052 #include <sys/time.h>
1053 #include <time.h>
1054 #else
1055 #ifdef HAVE_SYS_TIME_H
1056 #include <sys/time.h>
1057 #else
1058 #include <time.h>
1059 #endif
1060 #endif
1061 #ifdef HAVE_UTIME_H
1062 #include <utime.h>
1063 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1064   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1065 if test $emacs_cv_struct_utimbuf = yes; then
1066   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1067 fi
1068
1069 dnl checks for typedefs
1070 AC_TYPE_SIGNAL
1071
1072 dnl Check for speed_t typedef.
1073 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1074   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1075     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1076 if test $emacs_cv_speed_t = yes; then
1077   AC_DEFINE(HAVE_SPEED_T, 1,
1078            [Define to 1 if `speed_t' is declared by <termios.h>.])
1079 fi
1080
1081 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1082 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1083 #include <sys/time.h>
1084 #include <time.h>
1085 #else
1086 #ifdef HAVE_SYS_TIME_H
1087 #include <sys/time.h>
1088 #else
1089 #include <time.h>
1090 #endif
1091 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1092   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1093 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1094 if test $emacs_cv_struct_timeval = yes; then
1095   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1096 fi
1097
1098 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1099 AC_TRY_COMPILE([#include <math.h>],
1100 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1101   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1102 HAVE_EXCEPTION=$emacs_cv_struct_exception
1103 if test $emacs_cv_struct_exception != yes; then
1104   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1105 fi
1106
1107 AC_CHECK_HEADERS(sys/socket.h)
1108 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1109 #if HAVE_SYS_SOCKET_H
1110 #include <sys/socket.h>
1111 #endif])
1112
1113 dnl checks for structure members
1114 AC_STRUCT_TM
1115 AC_STRUCT_TIMEZONE
1116 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1117                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1118                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1119                 [#include <time.h>])
1120 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1121                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1122                   struct ifreq.ifr_addr], , ,
1123                  [AC_INCLUDES_DEFAULT
1124 #if HAVE_SYS_SOCKET_H
1125 #include <sys/socket.h>
1126 #endif
1127 #if HAVE_NET_IF_H
1128 #include <net/if.h>
1129 #endif])
1130
1131 dnl checks for compiler characteristics
1132
1133 dnl Testing __STDC__ to determine prototype support isn't good enough.
1134 dnl DEC C, for instance, doesn't define it with default options, and
1135 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1136 dnl and void *.
1137 AC_C_PROTOTYPES
1138 AC_C_VOLATILE
1139 AC_C_CONST
1140 dnl This isn't useful because we can't turn on use of `inline' unless
1141 dnl the compiler groks `extern inline'.
1142 dnl AC_C_INLINE
1143 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1144   [AC_TRY_COMPILE(, [void * foo;],
1145                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1146 if test $emacs_cv_void_star = yes; then
1147   AC_DEFINE(POINTER_TYPE, void)
1148 else
1149   AC_DEFINE(POINTER_TYPE, char)
1150 fi
1151 AH_TEMPLATE(POINTER_TYPE,
1152             [Define as `void' if your compiler accepts `void *'; otherwise
1153              define as `char'.])dnl
1154
1155
1156
1157 dnl This could be used for targets which can have both byte sexes.
1158 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1159 dnl AC_C_BIGENDIAN
1160
1161 dnl check for Make feature
1162 AC_PROG_MAKE_SET
1163
1164 dnl checks for operating system services
1165 AC_SYS_LONG_FILE_NAMES
1166
1167 #### Choose a window system.
1168
1169 AC_PATH_X
1170 if test "$no_x" = yes; then
1171   window_system=none
1172 else
1173   window_system=x11
1174 fi
1175
1176 ## Workaround for bug in autoconf <= 2.62.
1177 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1178 ## No need to do anything special for these standard directories.
1179 ## This is an experiment, take it out if it causes problems.
1180 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1181
1182    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1183
1184 fi
1185
1186 if test "${x_libraries}" != NONE; then
1187   if test -n "${x_libraries}"; then
1188     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1189     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1190   fi
1191   x_default_search_path=""
1192   x_search_path=${x_libraries}
1193   if test -z "${x_search_path}"; then
1194     x_search_path=/usr/lib
1195   fi
1196   for x_library in `echo ${x_search_path}: | \
1197                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1198     x_search_path="\
1199 ${x_library}/X11/%L/%T/%N%C%S:\
1200 ${x_library}/X11/%l/%T/%N%C%S:\
1201 ${x_library}/X11/%T/%N%C%S:\
1202 ${x_library}/X11/%L/%T/%N%S:\
1203 ${x_library}/X11/%l/%T/%N%S:\
1204 ${x_library}/X11/%T/%N%S"
1205     if test x"${x_default_search_path}" = x; then
1206       x_default_search_path=${x_search_path}
1207     else
1208       x_default_search_path="${x_search_path}:${x_default_search_path}"
1209     fi
1210   done
1211 fi
1212 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1213   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1214 fi
1215
1216 if test x"${x_includes}" = x; then
1217   bitmapdir=/usr/include/X11/bitmaps
1218 else
1219   # accumulate include directories that have X11 bitmap subdirectories
1220   bmd_acc="dummyval"
1221   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1222     if test -d "${bmd}/X11/bitmaps"; then
1223       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1224     fi
1225     if test -d "${bmd}/bitmaps"; then
1226       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1227     fi
1228   done
1229   if test ${bmd_acc} != "dummyval"; then
1230     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1231   fi
1232 fi
1233
1234 HAVE_NS=no
1235 NS_IMPL_COCOA=no
1236 NS_IMPL_GNUSTEP=no
1237 tmp_CPPFLAGS="$CPPFLAGS"
1238 tmp_CFLAGS="$CFLAGS"
1239 CPPFLAGS="$CPPFLAGS -x objective-c"
1240 CFLAGS="$CFLAGS -x objective-c"
1241 if test "${with_ns}" != no; then
1242   if test "${opsys}" = darwin; then
1243      NS_IMPL_COCOA=yes
1244      ns_appdir=`pwd`/nextstep/Emacs.app
1245      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1246      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1247      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1248   elif test -f $GNUSTEP_CONFIG_FILE; then
1249      NS_IMPL_GNUSTEP=yes
1250      ns_appdir=`pwd`/nextstep/Emacs.app
1251      ns_appbindir=`pwd`/nextstep/Emacs.app
1252      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1253      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1254      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1255      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1256      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1257      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1258      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1259      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1260      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1261      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1262   fi
1263   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1264                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1265   files are missing or cannot be compiled.])])
1266   NS_HAVE_NSINTEGER=yes
1267   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1268                                      [NSInteger i;])],
1269                     ns_have_nsinteger=yes,
1270                     ns_have_nsinteger=no)
1271   if test $ns_have_nsinteger = no; then
1272     NS_HAVE_NSINTEGER=no
1273   fi
1274 fi
1275 if test "${HAVE_NS}" = yes; then
1276   window_system=nextstep
1277   with_xft=no
1278   with_freetype=no
1279   # set up packaging dirs
1280   exec_prefix=${ns_appbindir}
1281   libexecdir=${ns_appbindir}/libexec
1282   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1283      prefix=${ns_appresdir}
1284   fi
1285 fi
1286 CFLAGS="$tmp_CFLAGS"
1287 CPPFLAGS="$tmp_CPPFLAGS"
1288
1289 case "${window_system}" in
1290   x11 )
1291     HAVE_X_WINDOWS=yes
1292     HAVE_X11=yes
1293     case "${with_x_toolkit}" in
1294       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1295       motif ) USE_X_TOOLKIT=MOTIF ;;
1296       gtk ) with_gtk=yes
1297 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1298 dnl USE_X_TOOLKIT is set.
1299             USE_X_TOOLKIT=none ;;
1300       no ) USE_X_TOOLKIT=none ;;
1301 dnl If user did not say whether to use a toolkit, make this decision later:
1302 dnl use the toolkit if we have gtk, or X11R5 or newer.
1303       * ) USE_X_TOOLKIT=maybe ;;
1304     esac
1305   ;;
1306   nextstep | none )
1307     HAVE_X_WINDOWS=no
1308     HAVE_X11=no
1309     USE_X_TOOLKIT=none
1310   ;;
1311 esac
1312
1313 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1314    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1315    if test "$HAVE_XSERVER" = true ||
1316       test -n "$DISPLAY" ||
1317       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1318         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1319 were found.  You should install the relevant development files for X
1320 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1321 sure you have development files for image handling, i.e.
1322 tiff, gif, jpeg, png and xpm.
1323 If you are sure you want Emacs compiled without X window support, pass
1324   --without-x
1325 to configure.])
1326    fi
1327 fi
1328
1329 ### If we're using X11, we should use the X menu package.
1330 HAVE_MENUS=no
1331 case ${HAVE_X11} in
1332   yes ) HAVE_MENUS=yes ;;
1333 esac
1334
1335 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1336 # Assume not, until told otherwise.
1337 GNU_MALLOC=yes
1338 doug_lea_malloc=yes
1339 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1340 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1341 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1342                emacs_cv_var___after_morecore_hook,
1343 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1344   emacs_cv_var___after_morecore_hook=yes,
1345   emacs_cv_var___after_morecore_hook=no)])
1346 if test $emacs_cv_var___after_morecore_hook = no; then
1347   doug_lea_malloc=no
1348 fi
1349 if test "${system_malloc}" = "yes"; then
1350   GNU_MALLOC=no
1351   GNU_MALLOC_reason="
1352     (The GNU allocators don't work with this system configuration.)"
1353 fi
1354 if test "$doug_lea_malloc" = "yes" ; then
1355   if test "$GNU_MALLOC" = yes ; then
1356     GNU_MALLOC_reason="
1357       (Using Doug Lea's new malloc from the GNU C Library.)"
1358   fi
1359   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1360             [Define to 1 if you are using the GNU C Library.])
1361 fi
1362
1363 if test x"${REL_ALLOC}" = x; then
1364   REL_ALLOC=${GNU_MALLOC}
1365 fi
1366
1367 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1368 dnl the system configuration file (s/*.h) to turn the use of mmap
1369 dnl in the relocating allocator on.
1370
1371 AC_FUNC_MMAP
1372 if test $use_mmap_for_buffers = yes; then
1373   REL_ALLOC=no
1374 fi
1375
1376 LIBS="$libsrc_libs $LIBS"
1377
1378 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1379 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1380 AC_CHECK_LIB(dnet, dnet_ntoa)
1381 dnl This causes -lresolv to get used in subsequent tests,
1382 dnl which causes failures on some systems such as HPUX 9.
1383 dnl AC_CHECK_LIB(resolv, gethostbyname)
1384
1385 dnl FIXME replace main with a function we actually want from this library.
1386 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1387
1388 AC_CHECK_LIB(pthreads, cma_open)
1389
1390 dnl Check for need for bigtoc support on IBM AIX
1391
1392 case ${host_os} in
1393 aix*)
1394   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1395     case $GCC in
1396     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1397     *) gdb_cv_bigtoc=-bbigtoc ;;
1398     esac
1399
1400     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1401     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1402   ])
1403   ;;
1404 esac
1405
1406 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1407 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1408 # REAL_CPPFLAGS later on.
1409
1410 REAL_CPPFLAGS="$CPPFLAGS"
1411
1412 if test "${HAVE_X11}" = "yes"; then
1413   DEFS="$C_SWITCH_X_SITE $DEFS"
1414   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1415   LIBS="$LIBX $LIBS"
1416   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1417   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1418
1419   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1420   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1421   # but it's more convenient here to set LD_RUN_PATH
1422   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1423   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1424     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1425     export LD_RUN_PATH
1426   fi
1427
1428   if test "${opsys}" = "gnu-linux"; then
1429     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1430     AC_TRY_LINK([],
1431      [XOpenDisplay ("foo");],
1432      [xlinux_first_failure=no],
1433      [xlinux_first_failure=yes])
1434     if test "${xlinux_first_failure}" = "yes"; then
1435       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1436       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1437       OLD_CPPFLAGS="$CPPFLAGS"
1438       OLD_LIBS="$LIBS"
1439       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1440       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1441       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1442       LIBS="$LIBS -b i486-linuxaout"
1443       AC_TRY_LINK([],
1444        [XOpenDisplay ("foo");],
1445        [xlinux_second_failure=no],
1446        [xlinux_second_failure=yes])
1447       if test "${xlinux_second_failure}" = "yes"; then
1448         # If we get the same failure with -b, there is no use adding -b.
1449         # So take it out.  This plays safe.
1450         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1451         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1452         CPPFLAGS="$OLD_CPPFLAGS"
1453         LIBS="$OLD_LIBS"
1454         AC_MSG_RESULT(no)
1455       else
1456         AC_MSG_RESULT(yes)
1457       fi
1458     else
1459       AC_MSG_RESULT(no)
1460     fi
1461   fi
1462
1463   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1464   # header files included from there.
1465   AC_MSG_CHECKING(for Xkb)
1466   AC_TRY_LINK([#include <X11/Xlib.h>
1467 #include <X11/XKBlib.h>],
1468         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1469         emacs_xkb=yes, emacs_xkb=no)
1470   AC_MSG_RESULT($emacs_xkb)
1471   if test $emacs_xkb = yes; then
1472     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1473   fi
1474
1475   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1476 XScreenNumberOfScreen XSetWMProtocols)
1477 fi
1478
1479 if test "${window_system}" = "x11"; then
1480   AC_MSG_CHECKING(X11 version 6)
1481   AC_CACHE_VAL(emacs_cv_x11_version_6,
1482   [AC_TRY_LINK([#include <X11/Xlib.h>],
1483 [#if XlibSpecificationRelease < 6
1484 fail;
1485 #endif
1486 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1487   if test $emacs_cv_x11_version_6 = yes; then
1488     AC_MSG_RESULT(6 or newer)
1489     AC_DEFINE(HAVE_X11R6, 1,
1490               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1491   else
1492     AC_MSG_RESULT(before 6)
1493   fi
1494 fi
1495
1496
1497 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1498 HAVE_RSVG=no
1499 if test "${HAVE_X11}" = "yes"; then
1500   if test "${with_rsvg}" != "no"; then
1501     RSVG_REQUIRED=2.0.0
1502     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1503
1504     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1505     AC_SUBST(RSVG_CFLAGS)
1506     AC_SUBST(RSVG_LIBS)
1507
1508     if test ".${RSVG_CFLAGS}" != "."; then
1509       HAVE_RSVG=yes
1510       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1511       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1512       LIBS="$RSVG_LIBS $LIBS"
1513     fi
1514   fi
1515 fi
1516
1517
1518 HAVE_GTK=no
1519 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1520   GLIB_REQUIRED=2.6
1521   GTK_REQUIRED=2.6
1522   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1523
1524   dnl Checks for libraries.
1525   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1526   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1527      AC_MSG_ERROR($GTK_PKG_ERRORS)
1528   fi
1529 fi
1530
1531
1532 if test x"$pkg_check_gtk" = xyes; then
1533
1534   AC_SUBST(GTK_CFLAGS)
1535   AC_SUBST(GTK_LIBS)
1536   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1537   CFLAGS="$CFLAGS $GTK_CFLAGS"
1538   LIBS="$GTK_LIBS $LIBS"
1539   dnl Try to compile a simple GTK program.
1540   GTK_COMPILES=no
1541   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1542   if test "${GTK_COMPILES}" != "yes"; then
1543     if test "$USE_X_TOOLKIT" != "maybe"; then
1544       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1545     fi
1546   else
1547     HAVE_GTK=yes
1548     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1549     USE_X_TOOLKIT=none
1550     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1551       :
1552     else
1553       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1554        closing open displays.  This is no problem if you just use
1555        one display, but if you use more than one and close one of them
1556        Emacs may crash.]])
1557       sleep 3
1558     fi
1559   fi
1560
1561 fi
1562
1563
1564 if test "${HAVE_GTK}" = "yes"; then
1565
1566   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1567   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1568   if test "$with_toolkit_scroll_bars" != no; then
1569     with_toolkit_scroll_bars=yes
1570   fi
1571
1572   dnl  Check if we can use multiple displays with this GTK version.
1573   dnl  If gdk_display_open exists, assume all others are there also.
1574   HAVE_GTK_MULTIDISPLAY=no
1575   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1576   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1577     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1578               [Define to 1 if GTK can handle more than one display.])
1579   fi
1580
1581   dnl  Check if we have the old file selection dialog.
1582   dnl  If gdk_display_open exists, assume all others are there also.
1583   HAVE_GTK_FILE_SELECTION=no
1584   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1585
1586   dnl  Check if we have the new file chooser dialog
1587   dnl  If gdk_display_open exists, assume all others are there also.
1588   HAVE_GTK_FILE_CHOOSER=no
1589   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1590
1591   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1592      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1593     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1594               [Define to 1 if GTK has both file selection and chooser dialog.])
1595   fi
1596
1597   dnl Check if pthreads are available.  Emacs only needs this when using
1598   dnl gtk_file_chooser under Gnome.
1599   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1600     HAVE_GTK_AND_PTHREAD=no
1601     AC_CHECK_HEADERS(pthread.h)
1602     if test "$ac_cv_header_pthread_h"; then
1603       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1604     fi
1605     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1606       case "${canonical}" in
1607         *-hpux*) ;;
1608         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1609       esac
1610       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1611                [Define to 1 if you have GTK and pthread (-lpthread).])
1612     fi
1613   fi
1614 fi
1615
1616 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1617 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1618 dnl also not configured.
1619 HAVE_DBUS=no
1620 if test "${with_dbus}" = "yes"; then
1621    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1622    if test "$HAVE_DBUS" = yes; then
1623       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1624    fi
1625 fi
1626
1627 dnl Do not put whitespace before the #include statements below.
1628 dnl Older compilers (eg sunos4 cc) choke on it.
1629 HAVE_XAW3D=no
1630 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1631   if test "$with_xaw3d" != no; then
1632     AC_MSG_CHECKING(for xaw3d)
1633     AC_CACHE_VAL(emacs_cv_xaw3d,
1634     [AC_TRY_LINK([
1635 #include <X11/Intrinsic.h>
1636 #include <X11/Xaw3d/Simple.h>],
1637       [],
1638       emacs_cv_xaw3d=yes,
1639       emacs_cv_xaw3d=no)])
1640   else
1641     emacs_cv_xaw3d=no
1642   fi
1643   if test $emacs_cv_xaw3d = yes; then
1644     AC_MSG_RESULT([yes; using Lucid toolkit])
1645     USE_X_TOOLKIT=LUCID
1646     HAVE_XAW3D=yes
1647     AC_DEFINE(HAVE_XAW3D, 1,
1648               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1649   else
1650     AC_MSG_RESULT(no)
1651     AC_MSG_CHECKING(for libXaw)
1652     AC_CACHE_VAL(emacs_cv_xaw,
1653     [AC_TRY_LINK([
1654 #include <X11/Intrinsic.h>
1655 #include <X11/Xaw/Simple.h>],
1656       [],
1657       emacs_cv_xaw=yes,
1658       emacs_cv_xaw=no)])
1659     if test $emacs_cv_xaw = yes; then
1660       AC_MSG_RESULT([yes; using Lucid toolkit])
1661       USE_X_TOOLKIT=LUCID
1662     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1663       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1664     else
1665       AC_MSG_RESULT([no; do not use toolkit by default])
1666       USE_X_TOOLKIT=none
1667     fi
1668   fi
1669 fi
1670
1671 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1672
1673 if test "${USE_X_TOOLKIT}" != "none"; then
1674   AC_MSG_CHECKING(X11 toolkit version)
1675   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1676   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1677 [#if XtSpecificationRelease < 6
1678 fail;
1679 #endif
1680 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1681   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1682   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1683     AC_MSG_RESULT(6 or newer)
1684     AC_DEFINE(HAVE_X11XTR6, 1,
1685               [Define to 1 if you have the X11R6 or newer version of Xt.])
1686   else
1687     AC_MSG_RESULT(before 6)
1688   fi
1689
1690 dnl If using toolkit, check whether libXmu.a exists.
1691 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1692   OLDLIBS="$LIBS"
1693   if test x$HAVE_X11XTR6 = xyes; then
1694     LIBS="-lXt -lSM -lICE $LIBS"
1695   else
1696     LIBS="-lXt $LIBS"
1697   fi
1698   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1699   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1700 fi
1701
1702 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1703 if test "${HAVE_X11}" = "yes"; then
1704   if test "${USE_X_TOOLKIT}" != "none"; then
1705     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1706   fi
1707 fi
1708
1709 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1710   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1711   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1712     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1713 int x = 5;
1714 #else
1715 Motif version prior to 2.1.
1716 #endif],
1717     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1718   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1719   if test $emacs_cv_motif_version_2_1 = yes; then
1720     HAVE_LIBXP=no
1721     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1722               [Define to 1 if you have Motif 2.1 or newer.])
1723     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1724     if test ${HAVE_LIBXP} = yes; then
1725       AC_DEFINE(HAVE_LIBXP, 1,
1726                 [Define to 1 if you have the Xp library (-lXp).])
1727     fi
1728   else
1729     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1730     # We put this in CFLAGS temporarily to precede other -I options
1731     # that might be in CFLAGS temporarily.
1732     # We put this in CPPFLAGS where it precedes the other -I options.
1733     OLD_CPPFLAGS=$CPPFLAGS
1734     OLD_CFLAGS=$CFLAGS
1735     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1736     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1737     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1738       [int x = 5;],
1739       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1740     if test $emacs_cv_lesstif = yes; then
1741       # Make sure this -I option remains in CPPFLAGS after it is set
1742       # back to REAL_CPPFLAGS.
1743       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1744       # have those other -I options anyway.  Ultimately, having this
1745       # directory ultimately in CPPFLAGS will be enough.
1746       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1747       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1748     else
1749       CFLAGS=$OLD_CFLAGS
1750       CPPFLAGS=$OLD_CPPFLAGS
1751     fi
1752   fi
1753 fi
1754
1755 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1756 dnl using Motif or Xaw3d is available, and unless
1757 dnl --with-toolkit-scroll-bars=no was specified.
1758
1759 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1760             [Define to 1 if we should use toolkit scroll bars.])dnl
1761 USE_TOOLKIT_SCROLL_BARS=no
1762 if test "${with_toolkit_scroll_bars}" != "no"; then
1763   if test "${USE_X_TOOLKIT}" != "none"; then
1764     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1765       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1766       HAVE_XAW3D=no
1767       USE_TOOLKIT_SCROLL_BARS=yes
1768     elif test "${HAVE_XAW3D}" = "yes"; then
1769       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1770       USE_TOOLKIT_SCROLL_BARS=yes
1771     fi
1772   elif test "${HAVE_GTK}" = "yes"; then
1773     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1774     USE_TOOLKIT_SCROLL_BARS=yes
1775   elif test "${HAVE_NS}" = "yes"; then
1776     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1777     USE_TOOLKIT_SCROLL_BARS=yes
1778   fi
1779 fi
1780
1781 dnl See if XIM is available.
1782 AC_TRY_COMPILE([
1783           #include <X11/Xlib.h>
1784           #include <X11/Xresource.h>],
1785          [XIMProc  callback;],
1786          [HAVE_XIM=yes
1787          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1788          HAVE_XIM=no)
1789
1790 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1791
1792 if test "${with_xim}" != "no"; then
1793   AC_DEFINE(USE_XIM, 1,
1794             [Define to 1 if we should use XIM, if it is available.])
1795 fi
1796
1797
1798 if test "${HAVE_XIM}" != "no"; then
1799   late_CFLAGS=$CFLAGS
1800   if test "$GCC" = yes; then
1801     CFLAGS="$CFLAGS --pedantic-errors"
1802   fi
1803   AC_TRY_COMPILE([
1804 #include <X11/Xlib.h>
1805 #include <X11/Xresource.h>],
1806 [Display *display;
1807 XrmDatabase db;
1808 char *res_name;
1809 char *res_class;
1810 XIMProc  callback;
1811 XPointer *client_data;
1812 #ifndef __GNUC__
1813 /* If we're not using GCC, it's probably not XFree86, and this is
1814    probably right, but we can't use something like --pedantic-errors.  */
1815 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1816                                            char*, XIMProc, XPointer*);
1817 #endif
1818 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1819    client_data);],
1820     [emacs_cv_arg6_star=yes])
1821   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1822          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1823 either XPointer or XPointer*.])dnl
1824   if test "$emacs_cv_arg6_star" = yes; then
1825     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1826   else
1827     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1828   fi
1829   CFLAGS=$late_CFLAGS
1830 fi
1831
1832 ### Start of font-backend section.
1833 PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1834 test "${HAVE_FC}" = "no" && with_freetype=no
1835
1836 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1837 HAVE_XFT=maybe
1838 if test "x${with_freetype}" = "xno" || test "x${with_x}" = "xno"; then
1839   with_xft="no";
1840 fi
1841 if test "x${with_xft}" != "xno"; then
1842
1843   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1844   if test "$HAVE_XFT" != no; then
1845     OLD_CPPFLAGS="$CPPFLAGS"
1846     OLD_CFLAGS="$CFLAGS"
1847     OLD_LIBS="$LIBS"
1848     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1849     CFLAGS="$CFLAGS $XFT_CFLAGS"
1850     LIBS="$XFT_LIBS $LIBS"
1851     AC_CHECK_HEADER(X11/Xft/Xft.h,
1852       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1853
1854     if test "${HAVE_XFT}" = "yes"; then
1855       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1856         AC_SUBST(XFT_LIBS)
1857       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1858     else
1859       CPPFLAGS="$OLD_CPPFLAGS"
1860       CFLAGS="$OLD_CFLAGS"
1861       LIBS="$OLD_LIBS"
1862     fi                        # "${HAVE_XFT}" = "yes"
1863   fi                          # "$HAVE_XFT" != no
1864 fi                            # "x${with_xft}" != "xno"
1865
1866 dnl For the "Does Emacs use" message at the end.
1867 if test "$HAVE_XFT" != "yes"; then
1868    HAVE_XFT=no
1869 fi
1870
1871
1872 HAVE_FREETYPE=no
1873 ### Use -lfreetype if available, unless `--with-freetype=no'.
1874 if test "${HAVE_XFT}" = "yes"; then
1875   dnl As we use Xft, we anyway use freetype.
1876   dnl In this case, there's no need of additional CFLAGS and LIBS.
1877   HAVE_FREETYPE=yes
1878   FONTCONFIG_CFLAGS=
1879   FONTCONFIG_LIBS=
1880 elif test "x${with_freetype}" != "xno" && test "x${with_x}" != "xno"; then
1881
1882   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1883 fi
1884
1885 HAVE_LIBOTF=no
1886 if test "${HAVE_FREETYPE}" = "yes"; then
1887   AC_DEFINE(HAVE_FREETYPE, 1,
1888             [Define to 1 if using the freetype and fontconfig libraries.])
1889   if test "${with_libotf}" != "no"; then
1890     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1891                       HAVE_LIBOTF=no)
1892     if test "$HAVE_LIBOTF" = "yes"; then
1893       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1894     fi
1895   fi
1896 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1897 dnl Does the new font backend require it, or can it work without it?
1898 fi
1899
1900 HAVE_M17N_FLT=no
1901 if test "${HAVE_LIBOTF}" = yes; then
1902   if test "${with_m17n_flt}" != "no"; then
1903     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1904     if test "$HAVE_M17N_FLT" = "yes"; then
1905       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1906     fi
1907   fi
1908 fi
1909
1910 AC_SUBST(FREETYPE_CFLAGS)
1911 AC_SUBST(FREETYPE_LIBS)
1912 AC_SUBST(FONTCONFIG_CFLAGS)
1913 AC_SUBST(FONTCONFIG_LIBS)
1914 AC_SUBST(LIBOTF_CFLAGS)
1915 AC_SUBST(LIBOTF_LIBS)
1916 AC_SUBST(M17N_FLT_CFLAGS)
1917 AC_SUBST(M17N_FLT_LIBS)
1918
1919 ### End of font-backend section.
1920
1921 ### Use -lXpm if available, unless `--with-xpm=no'.
1922 HAVE_XPM=no
1923 if test "${HAVE_X11}" = "yes"; then
1924   if test "${with_xpm}" != "no"; then
1925     AC_CHECK_HEADER(X11/xpm.h,
1926       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1927     if test "${HAVE_XPM}" = "yes"; then
1928       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1929       AC_EGREP_CPP(no_return_alloc_pixels,
1930       [#include "X11/xpm.h"
1931 #ifndef XpmReturnAllocPixels
1932 no_return_alloc_pixels
1933 #endif
1934       ], HAVE_XPM=no, HAVE_XPM=yes)
1935
1936       if test "${HAVE_XPM}" = "yes"; then
1937         AC_MSG_RESULT(yes)
1938       else
1939         AC_MSG_RESULT(no)
1940       fi
1941     fi
1942   fi
1943
1944   if test "${HAVE_XPM}" = "yes"; then
1945     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1946   fi
1947 fi
1948
1949 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1950 HAVE_JPEG=no
1951 if test "${HAVE_X11}" = "yes"; then
1952   if test "${with_jpeg}" != "no"; then
1953     dnl Checking for jpeglib.h can lose because of a redefinition of
1954     dnl  HAVE_STDLIB_H.
1955     AC_CHECK_HEADER(jerror.h,
1956       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1957   fi
1958
1959   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1960   if test "${HAVE_JPEG}" = "yes"; then
1961     AC_DEFINE(HAVE_JPEG)
1962     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1963         [#include <jpeglib.h>
1964          version=JPEG_LIB_VERSION
1965 ],
1966         [AC_DEFINE(HAVE_JPEG)],
1967         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1968         HAVE_JPEG=no])
1969   fi
1970 fi
1971
1972 ### Use -lpng if available, unless `--with-png=no'.
1973 HAVE_PNG=no
1974 if test "${HAVE_X11}" = "yes"; then
1975   if test "${with_png}" != "no"; then
1976     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1977     # in /usr/include/libpng.
1978     AC_CHECK_HEADERS(png.h libpng/png.h)
1979     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1980       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1981     fi
1982   fi
1983
1984   if test "${HAVE_PNG}" = "yes"; then
1985     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1986   fi
1987 fi
1988
1989 ### Use -ltiff if available, unless `--with-tiff=no'.
1990 HAVE_TIFF=no
1991 if test "${HAVE_X11}" = "yes"; then
1992   if test "${with_tiff}" != "no"; then
1993     AC_CHECK_HEADER(tiffio.h,
1994       [tifflibs="-lz -lm"
1995       # At least one tiff package requires the jpeg library.
1996       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1997       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
1998   fi
1999
2000   if test "${HAVE_TIFF}" = "yes"; then
2001     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2002   fi
2003 fi
2004
2005 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2006 HAVE_GIF=no
2007 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2008   AC_CHECK_HEADER(gif_lib.h,
2009 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2010 # Earlier versions can crash Emacs.
2011     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2012
2013   if test "$HAVE_GIF" = yes; then
2014       ac_gif_lib_name="-lgif"
2015   fi
2016
2017 # If gif_lib.h but no libgif, try libungif.
2018   if test x"$try_libungif" = xyes; then
2019     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2020
2021     if test "$HAVE_GIF" = yes; then
2022       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2023       ac_gif_lib_name="-lungif"
2024     fi
2025   fi
2026
2027   if test "${HAVE_GIF}" = "yes"; then
2028     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2029   fi
2030 fi
2031
2032 dnl Check for required libraries.
2033 if test "${HAVE_X11}" = "yes"; then
2034   MISSING=""
2035   WITH_NO=""
2036   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2037     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2038   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2039     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2040   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2041     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2042   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2043     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2044   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2045     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2046
2047   if test "X${MISSING}" != X; then
2048     AC_MSG_ERROR([The following required libraries were not found:
2049     $MISSING
2050 Maybe some development libraries/packages are missing?
2051 If you don't want to link with them give
2052     $WITH_NO
2053 as options to configure])
2054   fi
2055 fi
2056
2057 ### Use -lgpm if available, unless `--with-gpm=no'.
2058 HAVE_GPM=no
2059 if test "${with_gpm}" != "no"; then
2060   AC_CHECK_HEADER(gpm.h,
2061     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2062 fi
2063
2064 if test "${HAVE_GPM}" = "yes"; then
2065   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2066 fi
2067
2068 dnl Check for malloc/malloc.h on darwin
2069 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2070
2071 ### Use NeXTstep API to implement GUI.
2072 if test "${HAVE_NS}" = "yes"; then
2073   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2074   if test "${NS_IMPL_COCOA}" = "yes"; then
2075     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2076     GNU_OBJC_CFLAGS=
2077     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2078   fi
2079   if test "${EN_COCOA_EXPERIMENTAL_CTRL_G}" = "yes"; then
2080     AC_DEFINE(COCOA_EXPERIMENTAL_CTRL_G, 1, [Define to 1 if you are trying experimental enhanced Ctrl-g support using NS windowing under MacOS X.])
2081   fi
2082   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2083     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2084     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2085   fi
2086   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2087     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2088   fi
2089   # We also have mouse menus.
2090   HAVE_MENUS=yes
2091 fi
2092
2093
2094 ### Use session management (-lSM -lICE) if available
2095 HAVE_X_SM=no
2096 if test "${HAVE_X11}" = "yes"; then
2097   AC_CHECK_HEADER(X11/SM/SMlib.h,
2098     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2099
2100   if test "${HAVE_X_SM}" = "yes"; then
2101     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2102     case "$LIBS" in
2103       *-lSM*) ;;
2104       *)      LIBS="-lSM -lICE $LIBS" ;;
2105     esac
2106   fi
2107 fi
2108
2109 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2110 AC_CACHE_CHECK(whether netdb declares h_errno,
2111                emacs_cv_netdb_declares_h_errno,
2112 [AC_TRY_LINK([#include <netdb.h>],
2113   [return h_errno;],
2114   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2115 if test $emacs_cv_netdb_declares_h_errno = yes; then
2116   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2117 fi
2118
2119 AC_FUNC_ALLOCA
2120
2121 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2122 dnl FIXME is there an autoconf test that does the right thing, without
2123 dnl needing to call A_M_E afterwards?
2124 if test x"$ac_cv_func_alloca_works" != xyes; then
2125    AC_MSG_ERROR( [a system implementation of alloca is required] )
2126 fi
2127
2128 # fmod, logb, and frexp are found in -lm on most systems.
2129 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2130 AC_CHECK_LIB(m, sqrt)
2131
2132 # Check for mail-locking functions in a "mail" library.  Probably this should
2133 # have the same check as for liblockfile below.
2134 AC_CHECK_LIB(mail, maillock)
2135 dnl Debian, at least:
2136 AC_CHECK_LIB(lockfile, maillock)
2137 # If we have the shared liblockfile, assume we must use it for mail
2138 # locking (e.g. Debian).  If we couldn't link against liblockfile
2139 # (no liblockfile.a installed), ensure that we don't need to.
2140 if test "$ac_cv_lib_lockfile_maillock" = no; then
2141   dnl This works for files generally, not just executables.
2142   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2143   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2144                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2145   if test $ac_cv_prog_liblockfile = yes; then
2146     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2147 This probably means that movemail could lose mail.
2148 There may be a `development' package to install containing liblockfile.])
2149   else :
2150   fi
2151 fi
2152 AC_CHECK_FUNCS(touchlock)
2153 AC_CHECK_HEADERS(maillock.h)
2154
2155 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2156 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2157 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2158 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2159 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2160 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2161 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2162 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2163 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2164 cfmakeraw cfsetspeed)
2165
2166 AC_CHECK_HEADERS(sys/un.h)
2167
2168 AC_FUNC_MKTIME
2169 if test "$ac_cv_func_working_mktime" = no; then
2170   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2171 fi
2172
2173 AC_FUNC_GETLOADAVG
2174
2175 AC_FUNC_FSEEKO
2176
2177 # Configure getopt.
2178 m4_include([m4/getopt.m4])
2179 gl_GETOPT_IFELSE([
2180   gl_GETOPT_SUBSTITUTE_HEADER
2181   gl_PREREQ_GETOPT
2182   GETOPTOBJS='getopt.o getopt1.o'
2183 ])
2184 AC_SUBST(GETOPTOBJS)
2185
2186 AC_FUNC_GETPGRP
2187
2188 AC_FUNC_STRFTIME
2189
2190 # UNIX98 PTYs.
2191 AC_CHECK_FUNCS(grantpt)
2192
2193 # PTY-related GNU extensions.
2194 AC_CHECK_FUNCS(getpt)
2195
2196 # Check this now, so that we will NOT find the above functions in ncurses.
2197 # That is because we have not set up to link ncurses in lib-src.
2198 # It's better to believe a function is not available
2199 # than to expect to find it in ncurses.
2200 AC_CHECK_LIB(ncurses, tparm)
2201
2202 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2203
2204 resolv=no
2205 AC_TRY_LINK([#include <netinet/in.h>
2206 #include <arpa/nameser.h>
2207 #include <resolv.h>],
2208     [return res_init();],
2209     have_res_init=yes, have_res_init=no)
2210 if test "$have_res_init" = no; then
2211   OLIBS="$LIBS"
2212   LIBS="$LIBS -lresolv"
2213   AC_MSG_CHECKING(for res_init with -lresolv)
2214   AC_TRY_LINK([#include <netinet/in.h>
2215 #include <arpa/nameser.h>
2216 #include <resolv.h>],
2217     [return res_init();],
2218     have_res_init=yes, have_res_init=no)
2219   AC_MSG_RESULT($have_res_init)
2220   if test "$have_res_init" = yes ; then
2221     resolv=yes
2222   fi
2223   LIBS="$OLIBS"
2224 fi
2225
2226 if test "$have_res_init" = yes; then
2227   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2228 fi
2229
2230 # Do we need the Hesiod library to provide the support routines?
2231 if test "$with_hesiod" != no ; then
2232   # Don't set $LIBS here -- see comments above.
2233   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2234      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2235                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2236   if test "$resolv" = yes ; then
2237     RESOLVLIB=-lresolv
2238   else
2239     RESOLVLIB=
2240   fi
2241   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2242         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2243                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2244         :, $RESOLVLIB)])
2245 fi
2246
2247 # Do we need libresolv (due to res_init or Hesiod)?
2248 if test "$resolv" = yes ; then
2249   AC_DEFINE(HAVE_LIBRESOLV, 1,
2250             [Define to 1 if you have the resolv library (-lresolv).])
2251 fi
2252
2253 # These tell us which Kerberos-related libraries to use.
2254 if test "${with_kerberos}" != no; then
2255   AC_CHECK_LIB(com_err, com_err)
2256   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2257   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2258   AC_CHECK_LIB(krb5, krb5_init_context)
2259   if test "${with_kerberos5}" = no; then
2260     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2261                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2262     AC_CHECK_LIB(krb4, krb_get_cred,,
2263                  [AC_CHECK_LIB(krb, krb_get_cred)])
2264   fi
2265
2266   if test "${with_kerberos5}" != no; then
2267     AC_CHECK_HEADERS(krb5.h,
2268       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2269                         [#include <krb5.h>])])
2270   else
2271     AC_CHECK_HEADERS(des.h,,
2272                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2273                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2274     AC_CHECK_HEADERS(krb.h,,
2275                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2276                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2277   fi
2278   AC_CHECK_HEADERS(com_err.h)
2279 fi
2280
2281 # Solaris requires -lintl if you want strerror (which calls dgettext)
2282 # to return localized messages.
2283 AC_CHECK_LIB(intl, dgettext)
2284
2285 AC_MSG_CHECKING(whether localtime caches TZ)
2286 AC_CACHE_VAL(emacs_cv_localtime_cache,
2287 [if test x$ac_cv_func_tzset = xyes; then
2288 AC_TRY_RUN([#include <time.h>
2289 extern char **environ;
2290 unset_TZ ()
2291 {
2292   char **from, **to;
2293   for (to = from = environ; (*to = *from); from++)
2294     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2295       to++;
2296 }
2297 char TZ_GMT0[] = "TZ=GMT0";
2298 char TZ_PST8[] = "TZ=PST8";
2299 main()
2300 {
2301   time_t now = time ((time_t *) 0);
2302   int hour_GMT0, hour_unset;
2303   if (putenv (TZ_GMT0) != 0)
2304     exit (1);
2305   hour_GMT0 = localtime (&now)->tm_hour;
2306   unset_TZ ();
2307   hour_unset = localtime (&now)->tm_hour;
2308   if (putenv (TZ_PST8) != 0)
2309     exit (1);
2310   if (localtime (&now)->tm_hour == hour_GMT0)
2311     exit (1);
2312   unset_TZ ();
2313   if (localtime (&now)->tm_hour != hour_unset)
2314     exit (1);
2315   exit (0);
2316 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2317 [# If we have tzset, assume the worst when cross-compiling.
2318 emacs_cv_localtime_cache=yes])
2319 else
2320         # If we lack tzset, report that localtime does not cache TZ,
2321         # since we can't invalidate the cache if we don't have tzset.
2322         emacs_cv_localtime_cache=no
2323 fi])dnl
2324 AC_MSG_RESULT($emacs_cv_localtime_cache)
2325 if test $emacs_cv_localtime_cache = yes; then
2326   AC_DEFINE(LOCALTIME_CACHE, 1,
2327             [Define to 1 if localtime caches TZ.])
2328 fi
2329
2330 if test "x$HAVE_TIMEVAL" = xyes; then
2331   AC_CHECK_FUNCS(gettimeofday)
2332   if test $ac_cv_func_gettimeofday = yes; then
2333     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2334                    emacs_cv_gettimeofday_two_arguments,
2335     [AC_TRY_COMPILE([
2336 #ifdef TIME_WITH_SYS_TIME
2337 #include <sys/time.h>
2338 #include <time.h>
2339 #else
2340 #ifdef HAVE_SYS_TIME_H
2341 #include <sys/time.h>
2342 #else
2343 #include <time.h>
2344 #endif
2345 #endif],
2346       [struct timeval time;
2347        gettimeofday (&time, 0);],
2348       emacs_cv_gettimeofday_two_arguments=yes,
2349       emacs_cv_gettimeofday_two_arguments=no)])
2350     if test $emacs_cv_gettimeofday_two_arguments = no; then
2351       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2352                 [Define to 1 if gettimeofday accepts only one argument.])
2353     fi
2354   fi
2355 fi
2356
2357 ok_so_far=yes
2358 AC_CHECK_FUNC(socket, , ok_so_far=no)
2359 if test $ok_so_far = yes; then
2360   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2361 fi
2362 if test $ok_so_far = yes; then
2363   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2364 fi
2365 if test $ok_so_far = yes; then
2366 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2367   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2368             [Define to 1 if you have inet sockets.])
2369 fi
2370
2371 AC_CHECK_HEADERS(sys/ioctl.h)
2372
2373 if test -f /usr/lpp/X11/bin/smt.exp; then
2374   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2375             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2376 fi
2377
2378 AC_MSG_CHECKING(whether system supports dynamic ptys)
2379 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2380   AC_MSG_RESULT(yes)
2381   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2382 else
2383   AC_MSG_RESULT(no)
2384 fi
2385
2386 AC_FUNC_FORK
2387
2388 dnl Adapted from Haible's version.
2389 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2390   [AC_TRY_LINK([#include <langinfo.h>],
2391     [char* cs = nl_langinfo(CODESET);],
2392     emacs_cv_langinfo_codeset=yes,
2393     emacs_cv_langinfo_codeset=no)
2394   ])
2395 if test $emacs_cv_langinfo_codeset = yes; then
2396   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2397     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2398 fi
2399
2400 AC_CHECK_TYPES(size_t)
2401
2402 AC_TYPE_MBSTATE_T
2403
2404 dnl Restrict could probably be used effectively other than in regex.c.
2405 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2406   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2407                   emacs_cv_c_restrict=yes,
2408                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2409                                   emacs_cv_c_restrict=__restrict,
2410                                   emacs_cv_c_restrict=no)])])
2411 case "$emacs_cv_c_restrict" in
2412   yes) emacs_restrict=restrict;;
2413   no) emacs_restrict="";;
2414   *) emacs_restrict="$emacs_cv_c_restrict";;
2415 esac
2416 if test "$emacs_restrict" != __restrict; then
2417   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2418     [Define to compiler's equivalent of C99 restrict keyword.
2419      Don't define if equivalent is `__restrict'.])
2420 fi
2421
2422 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2423   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2424                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2425 if test "$emacs_cv_c_restrict_arr" = yes; then
2426   AC_DEFINE(__restrict_arr, __restrict,
2427     [Define to compiler's equivalent of C99 restrict keyword in array
2428      declarations.  Define as empty for no equivalent.])
2429 fi
2430
2431 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2432 dnl how the tty code is related to POSIX and/or other versions of termios.
2433 dnl The following looks like a useful start.
2434 dnl
2435 dnl AC_SYS_POSIX_TERMIOS
2436 dnl if test $ac_cv_sys_posix_termios = yes; then
2437 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2438 dnl                                and macros for terminal control.])
2439 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2440 dnl fi
2441
2442 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2443
2444 # Set up the CFLAGS for real compilation, so we can substitute it.
2445 CFLAGS="$REAL_CFLAGS"
2446 CPPFLAGS="$REAL_CPPFLAGS"
2447
2448 #### Find out which version of Emacs this is.
2449 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2450          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2451 if test x"${version}" = x; then
2452   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2453 fi
2454
2455 ### Specify what sort of things we'll be editing into Makefile and config.h.
2456 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2457 AC_SUBST(version)
2458 AC_SUBST(configuration)
2459 AC_SUBST(canonical)
2460 AC_SUBST(srcdir)
2461 AC_SUBST(prefix)
2462 AC_SUBST(exec_prefix)
2463 AC_SUBST(bindir)
2464 AC_SUBST(datadir)
2465 AC_SUBST(sharedstatedir)
2466 AC_SUBST(libexecdir)
2467 AC_SUBST(mandir)
2468 AC_SUBST(infodir)
2469 AC_SUBST(lispdir)
2470 AC_SUBST(locallisppath)
2471 AC_SUBST(lisppath)
2472 AC_SUBST(x_default_search_path)
2473 AC_SUBST(etcdir)
2474 AC_SUBST(archlibdir)
2475 AC_SUBST(docdir)
2476 AC_SUBST(bitmapdir)
2477 AC_SUBST(gamedir)
2478 AC_SUBST(gameuser)
2479 AC_SUBST(c_switch_system)
2480 AC_SUBST(c_switch_machine)
2481 AC_SUBST(LD_SWITCH_X_SITE)
2482 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2483 AC_SUBST(C_SWITCH_X_SITE)
2484 AC_SUBST(CFLAGS)
2485 AC_SUBST(X_TOOLKIT_TYPE)
2486 AC_SUBST(machfile)
2487 AC_SUBST(opsysfile)
2488 AC_SUBST(GETLOADAVG_LIBS)
2489 AC_SUBST(ns_appdir)
2490 AC_SUBST(ns_appbindir)
2491 AC_SUBST(ns_appresdir)
2492 AC_SUBST(ns_appsrc)
2493 AC_SUBST(GNUSTEP_MAKEFILES)
2494 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2495 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2496 AC_SUBST(GNU_OBJC_CFLAGS)
2497 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2498
2499 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2500                    [Define to the canonical Emacs configuration name.])
2501 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2502                    [Define to the options passed to configure.])
2503 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2504                    [Define to the used machine dependent file.])
2505 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2506                    [Define to the used os dependent file.])
2507 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2508 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2509  may need to deal with X Windows.  For instance, if you've defined
2510  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2511  your loader can find on its own, you might want to add "-L/..." or
2512  something similar.])
2513 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2514                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2515                     in case it's needed (for Solaris, for example).])
2516 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2517 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2518  may need to deal with X Windows.  For instance, if you've defined
2519  HAVE_X_WINDOWS above and your X include files aren't in a place
2520  that your compiler can find on its own, you might want to add
2521  "-I/..." or something similar.])
2522 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2523                    [Define to the unexec source file name.])
2524
2525 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2526   AC_DEFINE(HAVE_X_WINDOWS, 1,
2527             [Define to 1 if you want to use the X window system.])
2528 fi
2529 if test "${USE_X_TOOLKIT}" != "none" ; then
2530   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2531   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2532     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2533   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2534     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2535   fi
2536 fi
2537 if test "${HAVE_X11}" = "yes" ; then
2538   AC_DEFINE(HAVE_X11, 1,
2539             [Define to 1 if you want to use version 11 of X windows.
2540              Otherwise, Emacs expects to use version 10.])
2541 fi
2542 if test "${HAVE_MENUS}" = "yes" ; then
2543   AC_DEFINE(HAVE_MENUS, 1,
2544             [Define to 1 if you have mouse menus.
2545              (This is automatic if you use X, but the option to specify it remains.)
2546              It is also defined with other window systems that support xmenu.c.])
2547 fi
2548 if test "${GNU_MALLOC}" = "yes" ; then
2549   AC_DEFINE(GNU_MALLOC, 1,
2550             [Define to 1 if you want to use the GNU memory allocator.])
2551 fi
2552 if test "${REL_ALLOC}" = "yes" ; then
2553   AC_DEFINE(REL_ALLOC, 1,
2554             [Define REL_ALLOC if you want to use the relocating allocator for
2555              buffer space.])
2556 fi
2557
2558
2559 AH_TOP([/* GNU Emacs site configuration template file.
2560    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2561      2006, 2007, 2008  Free Software Foundation, Inc.
2562
2563 This file is part of GNU Emacs.
2564
2565 GNU Emacs is free software: you can redistribute it and/or modify
2566 it under the terms of the GNU General Public License as published by
2567 the Free Software Foundation, either version 3 of the License, or
2568 (at your option) any later version.
2569
2570 GNU Emacs is distributed in the hope that it will be useful,
2571 but WITHOUT ANY WARRANTY; without even the implied warranty of
2572 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2573 GNU General Public License for more details.
2574
2575 You should have received a copy of the GNU General Public License
2576 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2577
2578
2579 /* No code in Emacs #includes config.h twice, but some bits of code
2580    intended to work with other packages as well (like gmalloc.c)
2581    think they can include it as many times as they like.  */
2582 #ifndef EMACS_CONFIG_H
2583 #define EMACS_CONFIG_H
2584 ])dnl
2585
2586 AH_BOTTOM([
2587 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2588 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2589 #define HAVE_WINDOW_SYSTEM
2590 #define HAVE_MOUSE
2591 #endif
2592
2593 /* Sadly for now, GNUstep dump does not work.  */
2594 #ifdef NS_IMPL_GNUSTEP
2595 #define CANNOT_DUMP
2596 #endif
2597
2598 /* Define AMPERSAND_FULL_NAME if you use the convention
2599    that & in the full name stands for the login id.  */
2600 /* Turned on June 1996 supposing nobody will mind it.  */
2601 #define AMPERSAND_FULL_NAME
2602
2603 /* Define HAVE_SOUND if we have sound support.  We know it works
2604    and compiles only on the specified platforms.   For others,
2605    it probably doesn't make sense to try.  */
2606
2607 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2608 #ifdef HAVE_MACHINE_SOUNDCARD_H
2609 #define HAVE_SOUND 1
2610 #endif
2611 #ifdef HAVE_SYS_SOUNDCARD_H
2612 #define HAVE_SOUND 1
2613 #endif
2614 #ifdef HAVE_SOUNDCARD_H
2615 #define HAVE_SOUND 1
2616 #endif
2617 #ifdef HAVE_ALSA
2618 #define HAVE_SOUND 1
2619 #endif
2620 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2621
2622 /* If using GNU, then support inline function declarations. */
2623 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2624    generally, because even if non-gcc compilers accept `inline', they
2625    may reject `extern inline'.  */
2626 #if defined (__GNUC__) && defined (OPTIMIZE)
2627 #define INLINE __inline__
2628 #else
2629 #define INLINE
2630 #endif
2631
2632 /* `subprocesses' should be defined if you want to
2633    have code for asynchronous subprocesses
2634    (as used in M-x compile and M-x shell).
2635    Only MSDOS does not support this (it overrides
2636    this in its config_opsysfile below).  */
2637
2638 #define subprocesses
2639
2640 /* Include the os and machine dependent files.  */
2641 #include config_opsysfile
2642 #include config_machfile
2643
2644 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2645   (There is probably a better place to do this, but right now the Cocoa
2646    side does this in s/darwin.h and we cannot
2647    parallel this exactly since GNUstep is multi-OS. */
2648 #ifdef HAVE_NS
2649 #define OTHER_FILES ns-app
2650 # ifdef NS_IMPL_GNUSTEP
2651 /* See also .m.o rule in Makefile.in */
2652 /* FIXME: are all these flags really needed?  Document here why.  */
2653 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2654 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2655 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2656 #  define SYSTEM_PURESIZE_EXTRA 30000
2657 # endif /* NS_IMPL_GNUSTEP */
2658 #endif /* HAVE_NS */
2659
2660 /* SIGTYPE is the macro we actually use.  */
2661 #ifndef SIGTYPE
2662 #define SIGTYPE RETSIGTYPE
2663 #endif
2664
2665 #ifdef emacs /* Don't do this for lib-src.  */
2666 /* Tell regex.c to use a type compatible with Emacs.  */
2667 #define RE_TRANSLATE_TYPE Lisp_Object
2668 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2669 #ifdef make_number
2670 /* If make_number is a macro, use it.  */
2671 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2672 #else
2673 /* If make_number is a function, avoid it.  */
2674 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2675 #endif
2676 #endif
2677
2678 /* Avoid link-time collision with system mktime if we will use our own.  */
2679 #if ! HAVE_MKTIME || BROKEN_MKTIME
2680 #define mktime emacs_mktime
2681 #endif
2682
2683 #define my_strftime nstrftime   /* for strftime.c */
2684
2685 /* The rest of the code currently tests the CPP symbol BSTRING.
2686    Override any claims made by the system-description files.
2687    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2688 #undef BSTRING
2689 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2690 #define BSTRING
2691 #endif
2692
2693 /* Some of the files of Emacs which are intended for use with other
2694    programs assume that if you have a config.h file, you must declare
2695    the type of getenv.
2696
2697    This declaration shouldn't appear when alloca.s or Makefile.in
2698    includes config.h.  */
2699 #ifndef NOT_C_CODE
2700 extern char *getenv ();
2701 #endif
2702
2703 /* These default definitions are good for almost all machines.
2704    The exceptions override them in m/MACHINE.h.  */
2705
2706 #ifndef BITS_PER_CHAR
2707 #define BITS_PER_CHAR 8
2708 #endif
2709
2710 #ifndef BITS_PER_SHORT
2711 #define BITS_PER_SHORT 16
2712 #endif
2713
2714 /* Note that lisp.h uses this in a preprocessor conditional, so it
2715    would not work to use sizeof.  That being so, we do all of them
2716    without sizeof, for uniformity's sake.  */
2717 #ifndef BITS_PER_INT
2718 #define BITS_PER_INT 32
2719 #endif
2720
2721 #ifndef BITS_PER_LONG
2722 #ifdef _LP64
2723 #define BITS_PER_LONG 64
2724 #else
2725 #define BITS_PER_LONG 32
2726 #endif
2727 #endif
2728
2729 /* Define if the compiler supports function prototypes.  It may do so
2730    but not define __STDC__ (e.g. DEC C by default) or may define it as
2731    zero.  */
2732 #undef PROTOTYPES
2733 /* For mktime.c:  */
2734 #ifndef __P
2735 # if defined PROTOTYPES
2736 #  define __P(args) args
2737 # else
2738 #  define __P(args) ()
2739 # endif  /* GCC.  */
2740 #endif /* __P */
2741
2742 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2743 #ifndef NOT_C_CODE
2744 #ifdef HAVE_STRING_H
2745 #include "string.h"
2746 #endif
2747 #ifdef HAVE_STRINGS_H
2748 #include "strings.h"  /* May be needed for bcopy & al. */
2749 #endif
2750 #ifdef HAVE_STDLIB_H
2751 #include <stdlib.h>
2752 #endif
2753 #ifndef __GNUC__
2754 # ifdef HAVE_ALLOCA_H
2755 #  include <alloca.h>
2756 # else /* AIX files deal with #pragma.  */
2757 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2758 char *alloca ();
2759 #  endif
2760 # endif /* HAVE_ALLOCA_H */
2761 #endif /* __GNUC__ */
2762 #ifndef HAVE_SIZE_T
2763 typedef unsigned size_t;
2764 #endif
2765 #endif /* NOT_C_CODE */
2766
2767 /* Define HAVE_X_I18N if we have usable i18n support.  */
2768
2769 #ifdef HAVE_X11R6
2770 #define HAVE_X_I18N
2771 #elif !defined X11R5_INHIBIT_I18N
2772 #define HAVE_X_I18N
2773 #endif
2774
2775 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2776
2777 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2778 #define HAVE_X11R6_XIM
2779 #endif
2780
2781 /* Should we enable expensive run-time checking of data types?  */
2782 #undef ENABLE_CHECKING
2783
2784 #if defined __GNUC__ && (__GNUC__ > 2 \
2785                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2786 #define NO_RETURN       __attribute__ ((__noreturn__))
2787 #else
2788 #define NO_RETURN       /* nothing */
2789 #endif
2790
2791 /* These won't be used automatically yet.  We also need to know, at least,
2792    that the stack is continuous.  */
2793 #ifdef __GNUC__
2794 #  ifndef GC_SETJMP_WORKS
2795   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2796      see NON_SAVING_SETJMP in the target descriptions.  */
2797   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2798      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2799      Fixme: Deal with SVR3.  */
2800 #    define GC_SETJMP_WORKS 1
2801 #  endif
2802 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2803 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2804 #  endif
2805 #endif
2806
2807 #ifndef HAVE_BCOPY
2808 #define bcopy(a,b,s) memcpy (b,a,s)
2809 #endif
2810 #ifndef HAVE_BZERO
2811 #define bzero(a,s) memset (a,0,s)
2812 #endif
2813 #ifndef HAVE_BCMP
2814 #define BCMP memcmp
2815 #endif
2816
2817 #endif /* EMACS_CONFIG_H */
2818
2819 /*
2820 Local Variables:
2821 mode: c
2822 End:
2823 */
2824 ])dnl
2825
2826 #### Report on what we decided to do.
2827 #### Report GTK as a toolkit, even if it doesn't use Xt.
2828 #### It makes printing result more understandable as using GTK sets
2829 #### toolkit_scroll_bars to yes by default.
2830 if test "${HAVE_GTK}" = "yes"; then
2831   USE_X_TOOLKIT=GTK
2832 fi
2833
2834 echo "
2835 Configured for \`${canonical}'.
2836
2837   Where should the build process find the source code?    ${srcdir}
2838   What operating system and machine description files should Emacs use?
2839         \`${opsysfile}' and \`${machfile}'
2840   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2841   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2842   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2843   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2844   What window system should Emacs use?                    ${window_system}
2845   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2846
2847 if test -n "${x_includes}"; then
2848 echo "  Where do we find X Windows header files?                ${x_includes}"
2849 else
2850 echo "  Where do we find X Windows header files?                Standard dirs"
2851 fi
2852 if test -n "${x_libraries}"; then
2853 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2854 else
2855 echo "  Where do we find X Windows libraries?                   Standard dirs"
2856 fi
2857
2858 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2859 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2860 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2861 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2862 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2863 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2864 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2865 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2866 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2867
2868 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2869 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2870 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2871 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2872
2873 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2874 echo
2875
2876 if test $USE_XASSERTS = yes; then
2877    echo "  Compiling with asserts turned on."
2878    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2879 fi
2880
2881 echo
2882
2883 if test "$USE_X_TOOLKIT" = GTK; then
2884   case "$canonical" in
2885   *cygwin*)
2886     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2887   will probably get a crash on startup.  If this happens, please use another
2888   toolkit for Emacs.  See etc/PROBLEMS for more information."
2889   ;;
2890   esac
2891 fi
2892
2893 if test "$HAVE_NS" = "yes"; then
2894    echo
2895    echo "You must run \"make install\" in order to test the built application.
2896 The installed application will go to nextstep/Emacs.app and can be
2897 run or moved from there."
2898    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2899       echo "The application will be fully self-contained."
2900     else
2901       echo "The lisp resources for the application will be installed under ${prefix}.
2902 You may need to run \"make install\" with sudo.  The application will fail
2903 to run if these resources are not installed."
2904    fi
2905    echo
2906 fi
2907
2908 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2909   echo "D-Bus integration has been tested for GNU/Linux only."
2910   echo
2911 fi
2912
2913
2914 # Remove any trailing slashes in these variables.
2915 [test "${prefix}" != NONE &&
2916   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2917 test "${exec_prefix}" != NONE &&
2918   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2919
2920 # Now get this: Some word that is part of the ${srcdir} directory name
2921 # or the ${configuration} value might, just might, happen to be an
2922 # identifier like `sun4' or `i386' or something, and be predefined by
2923 # the C preprocessor to some helpful value like 1, or maybe the empty
2924 # string.  Needless to say consequent macro substitutions are less
2925 # than conducive to the makefile finding the correct directory.
2926 [cpp_undefs="`echo $srcdir $configuration $canonical |
2927   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2928   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2929
2930 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2931 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2932 ## from Makefile.c can correctly provide the arg `-traditional' to the
2933 ## C preprocessor.
2934
2935 AC_EGREP_CPP(yes..yes,
2936         [yes..yes],
2937         CPP_NEED_TRADITIONAL=no,
2938         CPP_NEED_TRADITIONAL=yes)
2939
2940 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2941         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2942         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2943         lwlib/Makefile lisp/Makefile leim/Makefile, [
2944
2945 ### Make the necessary directories, if they don't exist.
2946 for dir in etc lisp ; do
2947   test -d ${dir} || mkdir ${dir}
2948 done
2949
2950 # Build src/Makefile from ${srcdir}/src/Makefile.c
2951 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2952 # This must be done after src/config.h is built, since we rely on that file.
2953
2954 echo creating src/epaths.h
2955 ${MAKE-make} epaths-force
2956
2957 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2958 # `..' to `. .'  unless invoked with -traditional
2959
2960 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2961   CPPFLAGS="$CPPFLAGS -traditional"
2962 fi
2963
2964 echo creating lib-src/Makefile
2965 ( cd lib-src
2966   rm -f junk.c junk1.c junk2.c
2967   sed -e '/start of cpp stuff/q' \
2968       < Makefile.c > junk1.c
2969   sed -e '1,/start of cpp stuff/d'\
2970       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2971       < Makefile.c > junk.c
2972   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2973       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2974   cat junk1.c junk2.c > Makefile.new
2975   rm -f junk.c junk1.c junk2.c
2976   chmod 444 Makefile.new
2977   mv -f Makefile.new Makefile
2978 )
2979
2980 echo creating src/Makefile
2981 ( cd src
2982   rm -f junk.c junk1.c junk2.c
2983   sed -e '/start of cpp stuff/q' \
2984       < Makefile.c > junk1.c
2985   sed -e '1,/start of cpp stuff/d'\
2986       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2987       < Makefile.c > junk.c
2988   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2989       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2990   cat junk1.c junk2.c > Makefile.new
2991   rm -f junk.c junk1.c junk2.c
2992   chmod 444 Makefile.new
2993   mv -f Makefile.new Makefile
2994 )
2995
2996 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2997   echo creating src/.gdbinit
2998   echo source $srcdir/src/.gdbinit > src/.gdbinit
2999 fi
3000
3001 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3002
3003 m4_if(dnl       Do not change this comment
3004    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3005 )dnl