lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;;; Customizable settings
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40
  41 (defcustom tooltip-delay 0.7
  42   "Seconds to wait before displaying a tooltip the first time."
  43   :tag "Delay"
  44   :type 'number
  45   :group 'tooltip)
  46
  47 (defcustom tooltip-short-delay 0.1
  48   "Seconds to wait between subsequent tooltips on different items."
  49   :tag "Short delay"
  50   :type 'number
  51   :group 'tooltip)
  52
  53 (defcustom tooltip-recent-seconds 1
  54   "Display tooltips if changing tip items within this many seconds.
  55 Do so after `tooltip-short-delay'."
  56   :tag "Recent seconds"
  57   :type 'number
  58   :group 'tooltip)
  59
  60 (defcustom tooltip-hide-delay 10
  61   "Hide tooltips automatically after this many seconds."
  62   :tag "Hide delay"
  63   :type 'number
  64   :group 'tooltip)
  65
  66 (defcustom tooltip-x-offset nil
  67   "X offset, in pixels, for the display of tooltips.
  68 The offset is relative to the position of the mouse.  It must
  69 be chosen so that the tooltip window doesn't contain the mouse
  70 when it pops up.  If the value is nil, the default offset is 5
  71 pixels.
  72
  73 If `tooltip-frame-parameters' includes the `left' parameter,
  74 the value of `tooltip-x-offset' is ignored."
  75   :tag "X offset"
  76   :type '(choice (const :tag "Default" nil)
  77                  (integer :tag "Offset" :value 1))
  78   :group 'tooltip)
  79
  80 (defcustom tooltip-y-offset nil
  81   "Y offset, in pixels, for the display of tooltips.
  82 The offset is relative to the position of the mouse.  It must
  83 be chosen so that the tooltip window doesn't contain the mouse
  84 when it pops up.  If the value is nil, the default offset is -10
  85 pixels.
  86
  87 If `tooltip-frame-parameters' includes the `top' parameter,
  88 the value of `tooltip-y-offset' is ignored."
  89   :tag "Y offset"
  90   :type '(choice (const :tag "Default" nil)
  91                  (integer :tag "Offset" :value 1))
  92   :group 'tooltip)
  93
  94 (defcustom tooltip-frame-parameters
  95   '((name . "tooltip")
  96     (internal-border-width . 5)
  97     (border-width . 1))
  98   "Frame parameters used for tooltips.
  99
 100 If `left' or `top' parameters are included, they specify the absolute
 101 position to pop up the tooltip."
 102   :type 'sexp
 103   :tag "Frame Parameters"
 104   :group 'tooltip)
 105
 106 (defface tooltip
 107   '((((class color))
 108      :background "lightyellow"
 109      :foreground "black"
 110      :inherit variable-pitch)
 111     (t
 112      :inherit variable-pitch))
 113   "Face for tooltips."
 114   :group 'tooltip)
 115
 116 \f
 117 ;;; Variables that are not customizable.
 118
 119 (defvar tooltip-hook nil
 120   "Functions to call to display tooltips.
 121 Each function is called with one argument EVENT which is a copy of
 122 the last mouse movement event that occurred.")
 123
 124 (defvar tooltip-timeout-id nil
 125   "The id of the timeout started when Emacs becomes idle.")
 126
 127 (defvar tooltip-last-mouse-motion-event nil
 128   "A copy of the last mouse motion event seen.")
 129
 130 (defvar tooltip-hide-time nil
 131   "Time when the last tooltip was hidden.")
 132
 133 ;;; Event accessors
 134
 135 (defun tooltip-event-buffer (event)
 136   "Return the buffer over which event EVENT occurred.
 137 This might return nil if the event did not occur over a buffer."
 138   (let ((window (posn-window (event-end event))))
 139     (and window (window-buffer window))))
 140
 141 ;;; Switching tooltips on/off
 142
 143 ;; We don't set track-mouse globally because this is a big redisplay
 144 ;; problem in buffers having a pre-command-hook or such installed,
 145 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 146 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 147 ;; would be accompanied by a full redisplay.
 148
 149 ;;;###autoload
 150 (define-minor-mode tooltip-mode
 151   "Toggle Tooltip display.
 152 With ARG, turn tooltip mode on if and only if ARG is positive."
 153   :global t
 154   ;; If you change the :init-value below, you also need to change the
 155   ;; corresponding code in startup.el.
 156   :init-value (not (or noninteractive
 157                        (and (boundp 'emacs-quick-startup) emacs-quick-startup)
 158                        (not (and (fboundp 'display-graphic-p)
 159                                  (display-graphic-p)))
 160                        (not (fboundp 'x-show-tip))))
 161   :group 'tooltip
 162   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
 163     (error "Sorry, tooltips are not yet available on this system"))
 164   (if tooltip-mode
 165       (progn
 166         (add-hook 'pre-command-hook 'tooltip-hide)
 167         (add-hook 'tooltip-hook 'tooltip-help-tips))
 168     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
 169       (remove-hook 'pre-command-hook 'tooltip-hide))
 170     (remove-hook 'tooltip-hook 'tooltip-help-tips))
 171   (setq show-help-function
 172         (if tooltip-mode 'tooltip-show-help-function nil)))
 173
 174 \f
 175 ;;; Timeout for tooltip display
 176
 177 (defun tooltip-delay ()
 178   "Return the delay in seconds for the next tooltip."
 179   (let ((delay tooltip-delay)
 180         (now (float-time)))
 181     (when (and tooltip-hide-time
 182                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 183       (setq delay tooltip-short-delay))
 184     delay))
 185
 186 (defun tooltip-cancel-delayed-tip ()
 187   "Disable the tooltip timeout."
 188   (when tooltip-timeout-id
 189     (disable-timeout tooltip-timeout-id)
 190     (setq tooltip-timeout-id nil)))
 191
 192 (defun tooltip-start-delayed-tip ()
 193   "Add a one-shot timeout to call function tooltip-timeout."
 194   (setq tooltip-timeout-id
 195         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 196
 197 (defun tooltip-timeout (object)
 198   "Function called when timer with id tooltip-timeout-id fires."
 199   (run-hook-with-args-until-success 'tooltip-hook
 200                                     tooltip-last-mouse-motion-event))
 201
 202 \f
 203 ;;; Displaying tips
 204
 205 (defun tooltip-set-param (alist key value)
 206   "Change the value of KEY in alist ALIST to VALUE.
 207 If there's no association for KEY in ALIST, add one, otherwise
 208 change the existing association.  Value is the resulting alist."
 209   (let ((param (assq key alist)))
 210     (if (consp param)
 211         (setcdr param value)
 212       (push (cons key value) alist))
 213     alist))
 214
 215 (defun tooltip-show (text &optional use-echo-area)
 216   "Show a tooltip window displaying TEXT.
 217
 218 Text larger than `x-max-tooltip-size' is clipped.
 219
 220 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 221 parameters, they determine the x and y position where the tooltip
 222 is displayed.  Otherwise, the tooltip pops at offsets specified by
 223 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 224 position.
 225
 226 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 227 in echo area."
 228   (if use-echo-area
 229       (message "%s" text)
 230     (condition-case error
 231         (let ((params (copy-sequence tooltip-frame-parameters))
 232               (fg (face-attribute 'tooltip :foreground))
 233               (bg (face-attribute 'tooltip :background)))
 234           (when (stringp fg)
 235             (setq params (tooltip-set-param params 'foreground-color fg))
 236             (setq params (tooltip-set-param params 'border-color fg)))
 237           (when (stringp bg)
 238             (setq params (tooltip-set-param params 'background-color bg)))
 239           (x-show-tip (propertize text 'face 'tooltip)
 240                       (selected-frame)
 241                       params
 242                       tooltip-hide-delay
 243                       tooltip-x-offset
 244                       tooltip-y-offset))
 245       (error
 246        (message "Error while displaying tooltip: %s" error)
 247        (sit-for 1)
 248        (message "%s" text)))))
 249
 250 (defun tooltip-hide (&optional ignored-arg)
 251   "Hide a tooltip, if one is displayed.
 252 Value is non-nil if tooltip was open."
 253   (tooltip-cancel-delayed-tip)
 254   (when (x-hide-tip)
 255     (setq tooltip-hide-time (float-time))))
 256
 257 \f
 258 ;;; Debugger-related functions
 259
 260 (defun tooltip-identifier-from-point (point)
 261   "Extract the identifier at POINT, if any.
 262 Value is nil if no identifier exists at point.  Identifier extraction
 263 is based on the current syntax table."
 264   (save-excursion
 265     (goto-char point)
 266     (let ((start (progn (skip-syntax-backward "w_") (point))))
 267       (unless (looking-at "[0-9]")
 268         (skip-syntax-forward "w_")
 269         (when (> (point) start)
 270           (buffer-substring start (point)))))))
 271
 272 (defmacro tooltip-region-active-p ()
 273   "Value is non-nil if the region is currently active."
 274   (if (string-match "^GNU" (emacs-version))
 275       `(and transient-mark-mode mark-active)
 276     `(region-active-p)))
 277
 278 (defun tooltip-expr-to-print (event)
 279   "Return an expression that should be printed for EVENT.
 280 If a region is active and the mouse is inside the region, print
 281 the region.  Otherwise, figure out the identifier around the point
 282 where the mouse is."
 283   (save-excursion
 284     (set-buffer (tooltip-event-buffer event))
 285     (let ((point (posn-point (event-end event))))
 286       (if (tooltip-region-active-p)
 287           (when (and (<= (region-beginning) point) (<= point (region-end)))
 288             (buffer-substring (region-beginning) (region-end)))
 289         (tooltip-identifier-from-point point)))))
 290
 291 (defun tooltip-process-prompt-regexp (process)
 292   "Return regexp matching the prompt of PROCESS at the end of a string.
 293 The prompt is taken from the value of COMINT-PROMPT-REGEXP in the buffer
 294 of PROCESS."
 295   (let ((prompt-regexp (save-excursion
 296                          (set-buffer (process-buffer process))
 297                          comint-prompt-regexp)))
 298     ;; Most start with `^' but the one for `sdb' cannot be easily
 299     ;; stripped.  Code the prompt for `sdb' fixed here.
 300     (if (= (aref prompt-regexp 0) ?^)
 301         (setq prompt-regexp (substring prompt-regexp 1))
 302       (setq prompt-regexp "\\*"))
 303     (concat "\n*" prompt-regexp "$")))
 304
 305 (defun tooltip-strip-prompt (process output)
 306   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 307   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 308     (save-match-data
 309       (when (string-match prompt-regexp output)
 310         (setq output (substring output 0 (match-beginning 0)))))
 311     output))
 312
 313 \f
 314 ;;; Tooltip help.
 315
 316 (defvar tooltip-help-message nil
 317   "The last help message received via `tooltip-show-help-function'.")
 318
 319 (defun tooltip-show-help-function (msg)
 320   "Function installed as `show-help-function'.
 321 MSG is either a help string to display, or nil to cancel the display."
 322   (let ((previous-help tooltip-help-message))
 323     (setq tooltip-help-message msg)
 324     (cond ((null msg)
 325            ;; Cancel display.  This also cancels a delayed tip, if
 326            ;; there is one.
 327            (tooltip-hide))
 328           ((equal previous-help msg)
 329            ;; Same help as before (but possibly the mouse has moved).
 330            ;; Keep what we have.
 331            )
 332           (t
 333            ;; A different help.  Remove a previous tooltip, and
 334            ;; display a new one, with some delay.
 335            (tooltip-hide)
 336            (tooltip-start-delayed-tip)))))
 337
 338 (defun tooltip-help-tips (event)
 339   "Hook function to display a help tooltip.
 340 This is installed on the hook `tooltip-hook', which is run when
 341 the timer with ID `tooltip-timeout-id' fires.
 342 Value is non-nil if this function handled the tip."
 343   (when (stringp tooltip-help-message)
 344     (tooltip-show tooltip-help-message)
 345     t))
 346
 347 (provide 'tooltip)
 348
 349 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 350 ;;; tooltip.el ends here