lisp/thumbs.el

   1 ;;; thumbs.el --- Thumbnails previewer for images files
   2
   3 ;; Copyright 2004, 2005 Free Software Foundation, Inc
   4
   5 ;; Author: Jean-Philippe Theberge <jphiltheberge@videotron.ca>
   6 ;; Keywords: Multimedia
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24 ;;
  25 ;; Thanks: Alex Schroeder <alex@gnu.org> for maintaining the package at some time
  26 ;;         The peoples at #emacs@freenode.net for numerous help
  27 ;;         RMS for emacs and the GNU project.
  28 ;;
  29
  30 ;;; Commentary:
  31
  32 ;; This package create two new mode: thumbs-mode and
  33 ;; thumbs-view-image-mode.  It is used for images browsing and viewing
  34 ;; from within Emacs.  Minimal image manipulation functions are also
  35 ;; available via external programs.
  36 ;;
  37 ;; The 'convert' program from 'ImageMagick'
  38 ;; [URL:http://www.imagemagick.org/] is required.
  39 ;;
  40 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  41 ;; CHANGELOG
  42 ;;
  43 ;; This is version 2.0
  44 ;;
  45 ;; USAGE
  46 ;;
  47 ;; Type M-x thumbs RET DIR RET to view the directory DIR in Thumbs mode.
  48 ;; That should be a directory containing image files.
  49 ;; from dired, C-t m enter in thumbs-mode with all marked files
  50 ;;             C-t a enter in thumbs-mode with all files in current-directory
  51 ;; In thumbs-mode, pressing <return> on a image will bring you in image view mode
  52 ;; for that image.  C-h m will give you a list of available keybinding.
  53
  54 ;;; History:
  55 ;;
  56
  57 ;;; Code:
  58
  59 (require 'dired)
  60
  61 ;; CUSTOMIZATIONS
  62
  63 (defgroup thumbs nil
  64   "Thumbnails previewer."
  65   :version "22.1"
  66   :group 'multimedia)
  67
  68 (defcustom thumbs-thumbsdir "~/.emacs-thumbs"
  69   "*Directory to store thumbnails."
  70   :type 'directory
  71   :group 'thumbs)
  72
  73 (defcustom thumbs-geometry "100x100"
  74   "*Size of thumbnails."
  75   :type 'string
  76   :group 'thumbs)
  77
  78 (defcustom thumbs-per-line 5
  79   "*Number of thumbnails per line to show in directory."
  80   :type 'string
  81   :group 'thumbs)
  82
  83 (defcustom thumbs-thumbsdir-max-size 50000000
  84   "Max size for thumbnails directory.
  85 When it reaches that size (in bytes), a warning is sent."
  86   :type 'string
  87   :group 'thumbs)
  88
  89 (defcustom thumbs-conversion-program
  90   (if (eq system-type 'windows-nt)
  91       "convert.exe"
  92     (or (executable-find "convert")
  93         "/usr/X11R6/bin/convert"))
  94   "*Name of conversion program for thumbnails generation.
  95 It must be 'convert'."
  96   :type 'string
  97   :group 'thumbs)
  98
  99 (defcustom thumbs-setroot-command
 100   "xloadimage -onroot -fullscreen *"
 101   "Command to set the root window."
 102   :type 'string
 103   :group 'thumbs)
 104
 105 (defcustom thumbs-relief 5
 106   "*Size of button-like border around thumbnails."
 107   :type 'string
 108   :group 'thumbs)
 109
 110 (defcustom thumbs-margin 2
 111   "*Size of the margin around thumbnails.
 112 This is where you see the cursor."
 113   :type 'string
 114   :group 'thumbs)
 115
 116 (defcustom thumbs-thumbsdir-auto-clean t
 117   "If set, delete older file in the thumbnails directory.
 118 Deletion is done at load time when the directory size is bigger
 119 than `thumbs-thumbsdir-max-size'."
 120   :type 'boolean
 121   :group 'thumbs)
 122
 123 (defcustom thumbs-image-resizing-step 10
 124   "Step by which to resize image."
 125   :type 'string
 126   :group 'thumbs)
 127
 128 (defcustom thumbs-temp-dir temporary-file-directory
 129   "Temporary directory to use.
 130 Defaults to `temporary-file-directory'.  Leaving it to
 131 this value can let another user see some of your images."
 132   :type 'directory
 133   :group 'thumbs)
 134
 135 (defcustom thumbs-temp-prefix "emacsthumbs"
 136   "Prefix to add to temp files."
 137   :type 'string
 138   :group 'thumbs)
 139
 140 ;; Initialize some variable, for later use.
 141 (defvar thumbs-current-tmp-filename
 142   nil
 143   "Temporary filename of current image.")
 144 (defvar thumbs-current-image-filename
 145   nil
 146   "Filename of current image.")
 147 (defvar thumbs-current-image-size
 148   nil
 149   "Size of current image.")
 150 (defvar thumbs-image-num
 151   nil
 152   "Number of current image.")
 153 (defvar thumbs-current-dir
 154   nil
 155   "Current directory.")
 156 (defvar thumbs-markedL
 157   nil
 158   "List of marked files.")
 159
 160 (defalias 'thumbs-gensym
 161     (if (fboundp 'gensym)
 162         'gensym
 163       ;; Copied from cl-macs.el
 164       (defvar thumbs-gensym-counter 0)
 165       (lambda (&optional prefix)
 166         "Generate a new uninterned symbol.
 167 The name is made by appending a number to PREFIX, default \"G\"."
 168         (let ((pfix (if (stringp prefix) prefix "G"))
 169               (num (if (integerp prefix) prefix
 170                      (prog1 thumbs-gensym-counter
 171                        (setq thumbs-gensym-counter
 172                              (1+ thumbs-gensym-counter))))))
 173           (make-symbol (format "%s%d" pfix num))))))
 174
 175 (defsubst thumbs-temp-dir ()
 176   (file-name-as-directory (expand-file-name thumbs-temp-dir)))
 177
 178 (defun thumbs-temp-file ()
 179   "Return a unique temporary filename for an image."
 180   (format "%s%s-%s.jpg"
 181           (thumbs-temp-dir)
 182           thumbs-temp-prefix
 183           (thumbs-gensym "T")))
 184
 185 (defun thumbs-thumbsdir ()
 186   "Return the current thumbnails directory (from `thumbs-thumbsdir').
 187 Create the thumbnails directory if it does not exist."
 188   (let ((thumbs-thumbsdir (file-name-as-directory
 189                            (expand-file-name thumbs-thumbsdir))))
 190     (unless (file-directory-p thumbs-thumbsdir)
 191       (make-directory thumbs-thumbsdir)
 192       (message "Creating thumbnails directory"))
 193     thumbs-thumbsdir))
 194
 195 (defun thumbs-cleanup-thumbsdir ()
 196   "Clean the thumbnails directory.
 197 If the total size of all files in `thumbs-thumbsdir' is bigger than
 198 `thumbs-thumbsdir-max-size', files are deleted until the max size is
 199 reached."
 200   (let* ((filesL
 201           (sort
 202            (mapcar
 203             (lambda (f)
 204               (let ((fattribsL (file-attributes f)))
 205                 `(,(nth 4 fattribsL) ,(nth 7 fattribsL) ,f)))
 206             (directory-files (thumbs-thumbsdir) t (image-file-name-regexp)))
 207            '(lambda (l1 l2) (time-less-p (car l1) (car l2)))))
 208          (dirsize (apply '+ (mapcar (lambda (x) (cadr x)) filesL))))
 209     (while (> dirsize thumbs-thumbsdir-max-size)
 210       (progn
 211         (message "Deleting file %s" (cadr (cdar filesL))))
 212       (delete-file (cadr (cdar filesL)))
 213       (setq dirsize (- dirsize (car (cdar filesL))))
 214       (setq filesL (cdr filesL)))))
 215
 216 ;; Check the thumbsnail directory size and clean it if necessary.
 217 (when thumbs-thumbsdir-auto-clean
 218   (thumbs-cleanup-thumbsdir))
 219
 220 (defun thumbs-call-convert (filein fileout action
 221                                    &optional arg output-format action-prefix)
 222   "Call the convert program.
 223 FILEIN is the input file,
 224 FILEOUT is the output file,
 225 ACTION is the command to send to convert.
 226 Optional arguments are:
 227 ARG any arguments to the ACTION command,
 228 OUTPUT-FORMAT is the file format to output (default is jpeg),
 229 ACTION-PREFIX is the symbol to place before the ACTION command
 230               (defaults to '-' but can sometimes be '+')."
 231   (let ((command (format "%s %s%s %s \"%s\" \"%s:%s\""
 232                          thumbs-conversion-program
 233                          (or action-prefix "-")
 234                          action
 235                          (or arg "")
 236                          filein
 237                          (or output-format "jpeg")
 238                          fileout)))
 239     (shell-command command)))
 240
 241 (defun thumbs-increment-image-size-element (n d)
 242   "Increment number N by D percent."
 243   (round (+ n (/ (* d n) 100))))
 244
 245 (defun thumbs-decrement-image-size-element (n d)
 246   "Decrement number N by D percent."
 247   (round (- n (/ (* d n) 100))))
 248
 249 (defun thumbs-increment-image-size (s)
 250   "Increment S (a cons of width x height)."
 251   (cons
 252    (thumbs-increment-image-size-element (car s)
 253                                         thumbs-image-resizing-step)
 254    (thumbs-increment-image-size-element (cdr s)
 255                                         thumbs-image-resizing-step)))
 256
 257 (defun thumbs-decrement-image-size (s)
 258   "Decrement S (a cons of width x height)."
 259   (cons
 260    (thumbs-decrement-image-size-element (car s)
 261                                         thumbs-image-resizing-step)
 262    (thumbs-decrement-image-size-element (cdr s)
 263                                         thumbs-image-resizing-step)))
 264
 265 (defun thumbs-resize-image (&optional increment size)
 266   "Resize image in current buffer.
 267 If INCREMENT is set, make the image bigger, else smaller.
 268 Or, alternatively, a SIZE may be specified."
 269   (interactive)
 270   ;; cleaning of old temp file
 271   (condition-case nil
 272     (apply 'delete-file
 273            (directory-files
 274             (thumbs-temp-dir) t
 275             thumbs-temp-prefix))
 276     (error nil))
 277   (let ((buffer-read-only nil)
 278         (x (if size
 279                size
 280              (if increment
 281                  (thumbs-increment-image-size
 282                   thumbs-current-image-size)
 283                (thumbs-decrement-image-size
 284                 thumbs-current-image-size))))
 285         (tmp (thumbs-temp-file)))
 286     (erase-buffer)
 287     (thumbs-call-convert thumbs-current-image-filename
 288                          tmp "sample"
 289                          (concat (number-to-string (car x)) "x"
 290                                  (number-to-string (cdr x))))
 291     (thumbs-insert-image tmp 'jpeg 0)
 292     (setq thumbs-current-tmp-filename tmp)))
 293
 294 (defun thumbs-resize-interactive (width height)
 295   "Resize image interactively to specified WIDTH and HEIGHT."
 296   (interactive "nWidth: \nnHeight: ")
 297   (thumbs-resize-image nil (cons width height)))
 298
 299 (defun thumbs-resize-image-size-down ()
 300   "Resize image (smaller)."
 301   (interactive)
 302   (thumbs-resize-image nil))
 303
 304 (defun thumbs-resize-image-size-up ()
 305   "Resize image (bigger)."
 306   (interactive)
 307   (thumbs-resize-image t))
 308
 309 (defun thumbs-thumbname (img)
 310   "Return a thumbnail name for the image IMG."
 311   (convert-standard-filename
 312    (let ((filename (expand-file-name img)))
 313      (format "%s%08x-%s.jpg"
 314              (thumbs-thumbsdir)
 315              (sxhash filename)
 316              (subst-char-in-string
 317               ?\s ?\_
 318               (apply
 319                'concat
 320                (split-string filename "/")))))))
 321
 322 (defun thumbs-make-thumb (img)
 323   "Create the thumbnail for IMG."
 324   (let ((fn (expand-file-name img))
 325         (tn (thumbs-thumbname img)))
 326     (if (or (not (file-exists-p tn))
 327             ;;  This is not the right fix, but I don't understand
 328             ;;  the external program or why it produces a geometry
 329             ;;  unequal to the one requested -- rms.
 330 ;;;         (not (equal (thumbs-file-size tn) thumbs-geometry))
 331             )
 332         (thumbs-call-convert fn tn "sample" thumbs-geometry))
 333     tn))
 334
 335 (defun thumbs-image-type (img)
 336   "Return image type from filename IMG."
 337   (cond ((string-match ".*\\.jpe?g\\'" img) 'jpeg)
 338         ((string-match ".*\\.xpm\\'" img) 'xpm)
 339         ((string-match ".*\\.xbm\\'" img) 'xbm)
 340         ((string-match ".*\\.gif\\'" img) 'gif)
 341         ((string-match ".*\\.bmp\\'" img) 'bmp)
 342         ((string-match ".*\\.png\\'" img) 'png)
 343         ((string-match ".*\\.tiff?\\'" img) 'tiff)))
 344
 345 (defun thumbs-file-size (img)
 346   (let ((i (image-size (find-image `((:type ,(thumbs-image-type img) :file ,img))) t)))
 347     (concat (number-to-string (round (car i)))
 348             "x"
 349             (number-to-string (round (cdr i))))))
 350
 351 ;;;###autoload
 352 (defun thumbs-find-thumb (img)
 353   "Display the thumbnail for IMG."
 354   (interactive "f")
 355   (find-file (thumbs-make-thumb img)))
 356
 357 (defun thumbs-insert-image (img type relief &optional marked)
 358   "Insert image IMG at point.
 359 TYPE and RELIEF will be used in constructing the image; see `image'
 360 in the emacs-lisp manual for further documentation.
 361 If MARKED is non-nil, the image is marked."
 362   (let ((i `(image :type ,type
 363                    :file ,img
 364                    :relief ,relief
 365                    :conversion ,(if marked 'disabled)
 366                    :margin ,thumbs-margin)))
 367     (insert-image i)
 368     (setq thumbs-current-image-size
 369           (image-size i t))))
 370
 371 (defun thumbs-insert-thumb (img &optional marked)
 372   "Insert the thumbnail for IMG at point.
 373 If MARKED is non-nil, the image is marked."
 374   (thumbs-insert-image
 375    (thumbs-make-thumb img) 'jpeg thumbs-relief marked)
 376   (put-text-property (1- (point)) (point)
 377                      'thumb-image-file img))
 378
 379 (defun thumbs-do-thumbs-insertion (L)
 380   "Insert all thumbs in list L."
 381   (let ((i 0))
 382     (dolist (img L)
 383       (thumbs-insert-thumb img
 384                            (member img thumbs-markedL))
 385       (when (= 0 (mod (setq i (1+ i)) thumbs-per-line))
 386         (newline)))
 387     (unless (bobp) (newline))))
 388
 389 (defun thumbs-show-thumbs-list (L &optional buffer-name same-window)
 390   (unless (and (display-images-p)
 391                (image-type-available-p 'jpeg))
 392     (error "Required image type is not supported in this Emacs session"))
 393   (funcall (if same-window 'switch-to-buffer 'pop-to-buffer)
 394            (or buffer-name "*THUMB-View*"))
 395   (let ((inhibit-read-only t))
 396     (erase-buffer)
 397     (thumbs-mode)
 398     (thumbs-do-thumbs-insertion L)
 399     (goto-char (point-min))
 400     (setq thumbs-current-dir default-directory)
 401     (make-variable-buffer-local 'thumbs-current-dir)))
 402
 403 ;;;###autoload
 404 (defun thumbs-show-all-from-dir (dir &optional reg same-window)
 405   "Make a preview buffer for all images in DIR.
 406 Optional argument REG to select file matching a regexp,
 407 and SAME-WINDOW to show thumbs in the same window."
 408   (interactive "DDir: ")
 409   (thumbs-show-thumbs-list
 410    (directory-files dir t
 411                     (or reg (image-file-name-regexp)))
 412    (concat "*Thumbs: " dir) same-window))
 413
 414 ;;;###autoload
 415 (defun thumbs-dired-show-marked ()
 416   "In dired, make a thumbs buffer with all marked files."
 417   (interactive)
 418   (thumbs-show-thumbs-list (dired-get-marked-files) nil t))
 419
 420 ;;;###autoload
 421 (defun thumbs-dired-show-all ()
 422   "In dired, make a thumbs buffer with all files in current directory."
 423   (interactive)
 424   (thumbs-show-all-from-dir default-directory nil t))
 425
 426 ;;;###autoload
 427 (defalias 'thumbs 'thumbs-show-all-from-dir)
 428
 429 (defun thumbs-find-image (img &optional num otherwin)
 430   (funcall
 431    (if otherwin 'switch-to-buffer-other-window 'switch-to-buffer)
 432    (concat "*Image: " (file-name-nondirectory img) " - "
 433            (number-to-string (or num 0)) "*"))
 434   (thumbs-view-image-mode)
 435   (let ((inhibit-read-only t))
 436     (setq thumbs-current-image-filename img
 437           thumbs-current-tmp-filename nil
 438           thumbs-image-num (or num 0))
 439     (make-variable-buffer-local 'thumbs-current-image-filename)
 440     (make-variable-buffer-local 'thumbs-current-tmp-filename)
 441     (make-variable-buffer-local 'thumbs-current-image-size)
 442     (make-variable-buffer-local 'thumbs-image-num)
 443     (delete-region (point-min)(point-max))
 444     (thumbs-insert-image img (thumbs-image-type img) 0)))
 445
 446 (defun thumbs-find-image-at-point (&optional img otherwin)
 447   "Display image IMG for thumbnail at point.
 448 Use another window if OTHERWIN is t."
 449   (interactive)
 450   (let* ((i (or img (thumbs-current-image))))
 451     (thumbs-find-image i (point) otherwin)))
 452
 453 (defun thumbs-find-image-at-point-other-window ()
 454   "Display image for thumbnail at point in the preview buffer.
 455 Open another window."
 456   (interactive)
 457   (thumbs-find-image-at-point nil t))
 458
 459 (defun thumbs-mouse-find-image (event)
 460   "Display image for thumbnail at mouse click EVENT."
 461   (interactive "e")
 462   (mouse-set-point event)
 463   (thumbs-find-image-at-point))
 464
 465 (defun thumbs-call-setroot-command (img)
 466   "Call the setroot program for IMG."
 467   (run-hooks 'thumbs-before-setroot-hook)
 468   (shell-command (replace-regexp-in-string
 469                   "\\*"
 470                   (shell-quote-argument (expand-file-name img))
 471                   thumbs-setroot-command nil t))
 472   (run-hooks 'thumbs-after-setroot-hook))
 473
 474 (defun thumbs-set-image-at-point-to-root-window ()
 475   "Set the image at point as the desktop wallpaper."
 476   (interactive)
 477   (thumbs-call-setroot-command
 478    (thumbs-current-image)))
 479
 480 (defun thumbs-set-root ()
 481   "Set the current image as root."
 482   (interactive)
 483   (thumbs-call-setroot-command
 484    (or thumbs-current-tmp-filename
 485        thumbs-current-image-filename)))
 486
 487 (defun thumbs-file-alist ()
 488   "Make an alist of elements (POS . FILENAME) for all images in thumb buffer."
 489   (save-excursion
 490     (let (list)
 491       (goto-char (point-min))
 492       (while (not (eobp))
 493         (if (thumbs-current-image)
 494             (push (cons (point-marker)
 495                         (thumbs-current-image))
 496                   list))
 497         (forward-char 1))
 498       list)))
 499
 500 (defun thumbs-file-list ()
 501   "Make a list of file names for all images in thumb buffer."
 502   (save-excursion
 503     (let (list)
 504       (goto-char (point-min))
 505       (while (not (eobp))
 506         (if (thumbs-current-image)
 507             (push (thumbs-current-image) list))
 508         (forward-char 1))
 509       (nreverse list))))
 510
 511 (defun thumbs-delete-images ()
 512   "Delete the image at point (and its thumbnail) (or marked files if any)."
 513   (interactive)
 514   (let ((files (or thumbs-markedL (list (thumbs-current-image)))))
 515     (if (yes-or-no-p (format "Really delete %d files? " (length files)))
 516         (let ((thumbs-fileL (thumbs-file-alist))
 517               (inhibit-read-only t))
 518           (dolist (x files)
 519             (let (failure)
 520               (condition-case ()
 521                   (progn
 522                     (delete-file x)
 523                     (delete-file (thumbs-thumbname x)))
 524                 (file-error (setq failure t)))
 525               (unless failure
 526                 (when (rassoc x thumbs-fileL)
 527                   (goto-char (car (rassoc x thumbs-fileL)))
 528                   (delete-region (point) (1+ (point))))
 529                 (setq thumbs-markedL
 530                       (delq x thumbs-markedL)))))))))
 531
 532 (defun thumbs-rename-images (newfile)
 533   "Rename the image at point (and its thumbnail) (or marked files if any)."
 534   (interactive "FRename to file or directory: ")
 535   (let ((files (or thumbs-markedL (list (thumbs-current-image))))
 536         failures)
 537     (if (and (not (file-directory-p newfile))
 538              thumbs-markedL)
 539         (if (file-exists-p newfile)
 540             (error "Renaming marked files to file name `%s'" newfile)
 541           (make-directory newfile t)))
 542     (if (yes-or-no-p (format "Really rename %d files? " (length files)))
 543         (let ((thumbs-fileL (thumbs-file-alist))
 544               (inhibit-read-only t))
 545           (dolist (file files)
 546             (let (failure)
 547               (condition-case ()
 548                   (if (file-directory-p newfile)
 549                       (rename-file file
 550                                    (expand-file-name
 551                                     (file-name-nondirectory file)
 552                                     newfile))
 553                     (rename-file file newfile))
 554                 (file-error (setq failure t)
 555                             (push file failures)))
 556               (unless failure
 557                 (when (rassoc file thumbs-fileL)
 558                   (goto-char (car (rassoc file thumbs-fileL)))
 559                   (delete-region (point) (1+ (point))))
 560                 (setq thumbs-markedL
 561                       (delq file thumbs-markedL)))))))
 562     (if failures
 563         (display-warning 'file-error
 564                          (format "Rename failures for %s into %s"
 565                                  failures newfile)
 566                          :error))))
 567
 568 (defun thumbs-kill-buffer ()
 569   "Kill the current buffer."
 570   (interactive)
 571   (quit-window t (selected-window)))
 572
 573 (defun thumbs-show-image-num (num)
 574   "Show the image with number NUM."
 575   (let ((image-buffer (get-buffer-create "*Image*")))
 576     (let ((i (thumbs-current-image)))
 577       (with-current-buffer image-buffer
 578         (thumbs-insert-image i (thumbs-image-type i) 0))
 579       (setq thumbs-image-num num
 580             thumbs-current-image-filename i))))
 581
 582 (defun thumbs-next-image ()
 583   "Show the next image."
 584   (interactive)
 585   (let* ((i (1+ thumbs-image-num))
 586          (list (thumbs-file-alist))
 587          (l (caar list)))
 588     (while (and (/= i thumbs-image-num) (not (assoc i list)))
 589       (setq i (if (>= i l) 1 (1+ i))))
 590     (thumbs-show-image-num i)))
 591
 592 (defun thumbs-previous-image ()
 593   "Show the previous image."
 594   (interactive)
 595   (let* ((i (- thumbs-image-num 1))
 596          (list (thumbs-file-alist))
 597          (l (caar list)))
 598     (while (and (/= i thumbs-image-num) (not (assoc i list)))
 599       (setq i (if (<= i 1) l (1- i))))
 600     (thumbs-show-image-num i)))
 601
 602 (defun thumbs-redraw-buffer ()
 603   "Redraw the current thumbs buffer."
 604   (let ((p (point))
 605         (inhibit-read-only t)
 606         (files (thumbs-file-list)))
 607     (erase-buffer)
 608     (thumbs-do-thumbs-insertion files)
 609     (goto-char p)))
 610
 611 (defun thumbs-mark ()
 612   "Mark the image at point."
 613   (interactive)
 614   (let ((elt (thumbs-current-image)))
 615     (unless elt
 616       (error "No image here"))
 617     (push elt thumbs-markedL)
 618     (let ((inhibit-read-only t))
 619       (delete-char 1)
 620       (thumbs-insert-thumb elt t)))
 621   (when (eolp) (forward-char)))
 622
 623 (defun thumbs-unmark ()
 624   "Unmark the image at point."
 625   (interactive)
 626   (let ((elt (thumbs-current-image)))
 627     (unless elt
 628       (error "No image here"))
 629     (setq thumbs-markedL (delete elt thumbs-markedL))
 630     (let ((inhibit-read-only t))
 631       (delete-char 1)
 632       (thumbs-insert-thumb elt nil)))
 633   (when (eolp) (forward-char)))
 634
 635 ;; Image modification routines
 636
 637 (defun thumbs-modify-image (action &optional arg)
 638   "Call convert to do ACTION on image with argument ARG.
 639 ACTION and ARG should be a valid convert command."
 640   (interactive "sAction: \nsValue: ")
 641   ;; cleaning of old temp file
 642   (mapc 'delete-file
 643         (directory-files
 644          (thumbs-temp-dir)
 645          t
 646          thumbs-temp-prefix))
 647   (let ((buffer-read-only nil)
 648         (tmp (thumbs-temp-file)))
 649     (erase-buffer)
 650     (thumbs-call-convert thumbs-current-image-filename
 651                          tmp
 652                          action
 653                          (or arg ""))
 654     (thumbs-insert-image tmp 'jpeg 0)
 655     (setq thumbs-current-tmp-filename tmp)))
 656
 657 (defun thumbs-emboss-image (emboss)
 658   "Emboss the image with value EMBOSS."
 659   (interactive "nEmboss value: ")
 660   (if (or (< emboss 3) (> emboss 31) (zerop (% emboss 2)))
 661       (error "Arg must be an odd number between 3 and 31"))
 662   (thumbs-modify-image "emboss" (number-to-string emboss)))
 663
 664 (defun thumbs-monochrome-image ()
 665   "Turn the image to monochrome."
 666   (interactive)
 667   (thumbs-modify-image "monochrome"))
 668
 669 (defun thumbs-negate-image ()
 670   "Negate the image."
 671   (interactive)
 672   (thumbs-modify-image "negate"))
 673
 674 (defun thumbs-rotate-left ()
 675   "Rotate the image 90 degrees counter-clockwise."
 676   (interactive)
 677   (thumbs-modify-image "rotate" "270"))
 678
 679 (defun thumbs-rotate-right ()
 680   "Rotate the image 90 degrees clockwise."
 681   (interactive)
 682   (thumbs-modify-image "rotate" "90"))
 683
 684 (defun thumbs-current-image ()
 685   "Return the name of the image file name at point."
 686   (get-text-property (point) 'thumb-image-file))
 687
 688 (defun thumbs-forward-char ()
 689   "Move forward one image."
 690   (interactive)
 691   (forward-char)
 692   (while (and (not (eobp)) (not (thumbs-current-image)))
 693     (forward-char))
 694   (thumbs-show-name))
 695
 696 (defun thumbs-backward-char ()
 697   "Move backward one image."
 698   (interactive)
 699   (forward-char -1)
 700   (while (and (not (bobp)) (not (thumbs-current-image)))
 701     (forward-char -1))
 702   (thumbs-show-name))
 703
 704 (defun thumbs-forward-line ()
 705   "Move down one line."
 706   (interactive)
 707   (forward-line 1)
 708   (thumbs-show-name))
 709
 710 (defun thumbs-backward-line ()
 711   "Move up one line."
 712   (interactive)
 713   (forward-line -1)
 714   (thumbs-show-name))
 715
 716 (defun thumbs-show-name ()
 717   "Show the name of the current file."
 718   (interactive)
 719   (let ((f (thumbs-current-image)))
 720     (and f (message "%s [%s]" f (thumbs-file-size f)))))
 721
 722 (defun thumbs-save-current-image ()
 723   "Save the current image."
 724   (interactive)
 725   (let ((f (or thumbs-current-tmp-filename
 726                thumbs-current-image-filename))
 727         (sa (read-from-minibuffer "Save image file as: "
 728                                   thumbs-current-image-filename)))
 729     (copy-file f sa)))
 730
 731 (defun thumbs-dired ()
 732   "Use `dired' on the current thumbs directory."
 733   (interactive)
 734   (dired thumbs-current-dir))
 735
 736 ;; thumbs-mode
 737
 738 (defvar thumbs-mode-map
 739   (let ((map (make-sparse-keymap)))
 740     (define-key map [return] 'thumbs-find-image-at-point)
 741     (define-key map [mouse-2] 'thumbs-mouse-find-image)
 742     (define-key map [(meta return)] 'thumbs-find-image-at-point-other-window)
 743     (define-key map [(control return)] 'thumbs-set-image-at-point-to-root-window)
 744     (define-key map [delete] 'thumbs-delete-images)
 745     (define-key map [right] 'thumbs-forward-char)
 746     (define-key map [left] 'thumbs-backward-char)
 747     (define-key map [up] 'thumbs-backward-line)
 748     (define-key map [down] 'thumbs-forward-line)
 749     (define-key map "d" 'thumbs-dired)
 750     (define-key map "m" 'thumbs-mark)
 751     (define-key map "u" 'thumbs-unmark)
 752     (define-key map "R" 'thumbs-rename-images)
 753     (define-key map "x" 'thumbs-delete-images)
 754     (define-key map "s" 'thumbs-show-name)
 755     (define-key map "q" 'thumbs-kill-buffer)
 756     map)
 757   "Keymap for `thumbs-mode'.")
 758
 759 (put 'thumbs-mode 'mode-class 'special)
 760 (define-derived-mode thumbs-mode
 761   fundamental-mode "thumbs"
 762   "Preview images in a thumbnails buffer"
 763   (setq buffer-read-only t)
 764   (set (make-local-variable 'thumbs-markedL) nil))
 765
 766 (defvar thumbs-view-image-mode-map
 767   (let ((map (make-sparse-keymap)))
 768     (define-key map [prior] 'thumbs-previous-image)
 769     (define-key map [next] 'thumbs-next-image)
 770     (define-key map "-" 'thumbs-resize-image-size-down)
 771     (define-key map "+" 'thumbs-resize-image-size-up)
 772     (define-key map "<" 'thumbs-rotate-left)
 773     (define-key map ">" 'thumbs-rotate-right)
 774     (define-key map "e" 'thumbs-emboss-image)
 775     (define-key map "r" 'thumbs-resize-interactive)
 776     (define-key map "s" 'thumbs-save-current-image)
 777     (define-key map "q" 'thumbs-kill-buffer)
 778     (define-key map "w" 'thumbs-set-root)
 779     map)
 780   "Keymap for `thumbs-view-image-mode'.")
 781
 782 ;; thumbs-view-image-mode
 783 (put 'thumbs-view-image-mode 'mode-class 'special)
 784 (define-derived-mode thumbs-view-image-mode
 785   fundamental-mode "image-view-mode"
 786   (setq buffer-read-only t))
 787
 788 ;;;###autoload
 789 (defun thumbs-dired-setroot ()
 790   "In dired, call the setroot program on the image at point."
 791   (interactive)
 792   (thumbs-call-setroot-command (dired-get-filename)))
 793
 794 ;; Modif to dired mode map
 795 (define-key dired-mode-map "\C-ta" 'thumbs-dired-show-all)
 796 (define-key dired-mode-map "\C-tm" 'thumbs-dired-show-marked)
 797 (define-key dired-mode-map "\C-tw" 'thumbs-dired-setroot)
 798
 799 (provide 'thumbs)
 800
 801 ;; arch-tag: f9ac1ef8-83fc-42c0-8069-1fae43fd2e5c
 802 ;;; thumbs.el ends here