lisp/gud.el

   1 ;;; gud.el --- Grand Unified Debugger mode for gdb, sdb, dbx, or xdb
   2 ;;;            under Emacs
   3
   4 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   5 ;; Maintainer: FSF
   6 ;; Keywords: unix, tools
   7
   8 ;; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The ancestral gdb.el was by W. Schelter <wfs@rascal.ics.utexas.edu>
  29 ;; It was later rewritten by rms.  Some ideas were due to Masanobu.
  30 ;; Grand Unification (sdb/dbx support) by Eric S. Raymond <esr@thyrsus.com>
  31 ;; The overloading code was then rewritten by Barry Warsaw <bwarsaw@cen.com>,
  32 ;; who also hacked the mode to use comint.el.  Shane Hartman <shane@spr.com>
  33 ;; added support for xdb (HPUX debugger).  Rick Sladkey <jrs@world.std.com>
  34 ;; wrote the GDB command completion code.  Dave Love <d.love@dl.ac.uk>
  35 ;; added the IRIX kluge, re-implemented the Mips-ish variant and added
  36 ;; a menu.
  37
  38 ;;; Code:
  39
  40 (require 'comint)
  41 (require 'etags)
  42
  43 ;; ======================================================================
  44 ;; GUD commands must be visible in C buffers visited by GUD
  45
  46 (defvar gud-key-prefix "\C-x\C-a"
  47   "Prefix of all GUD commands valid in C buffers.")
  48
  49 (global-set-key (concat gud-key-prefix "\C-l") 'gud-refresh)
  50 (define-key ctl-x-map " " 'gud-break)   ;; backward compatibility hack
  51
  52 (defvar gud-massage-args nil)
  53 (put 'gud-massage-args 'permanent-local t)
  54 (defvar gud-marker-filter nil)
  55 (put 'gud-marker-filter 'permanent-local t)
  56 (defvar gud-find-file nil)
  57 (put 'gud-find-file 'permanent-local t)
  58
  59 (defun gud-massage-args (&rest args)
  60   (apply gud-massage-args args))
  61
  62 (defun gud-marker-filter (&rest args)
  63   (apply gud-marker-filter args))
  64
  65 (defun gud-find-file (file)
  66   ;; Don't get confused by double slashes in the name that comes from GDB.
  67   (while (string-match "//+" file)
  68     (setq file (replace-match "/" t t file)))
  69   (funcall gud-find-file file))
  70
  71 ;; Keymap definitions for menu bar entries common to all debuggers and
  72 ;; slots for debugger-dependent ones in sensible places.  (Defined here
  73 ;; before use.)
  74 (defvar gud-menu-map (make-sparse-keymap "Gud") nil)
  75 (define-key gud-menu-map [refresh] '("Refresh" . gud-refresh))
  76 (define-key gud-menu-map [remove] '("Remove breakpoint" . gud-remove))
  77 (define-key gud-menu-map [tbreak] nil)  ; gdb, sdb and xdb
  78 (define-key gud-menu-map [break] '("Set breakpoint" . gud-break))
  79 (define-key gud-menu-map [up] nil)      ; gdb, dbx, and xdb
  80 (define-key gud-menu-map [down] nil)    ; gdb, dbx, and xdb
  81 (define-key gud-menu-map [print] '("Print expression" . gud-print))
  82 (define-key gud-menu-map [finish] nil)  ; gdb or xdb
  83 (define-key gud-menu-map [stepi] '("Step instruction" . gud-stepi))
  84 (define-key gud-menu-map [step] '("Step line" . gud-step))
  85 (define-key gud-menu-map [next] '("Next line" . gud-next))
  86 (define-key gud-menu-map [cont] '("Continue" . gud-cont))
  87 \f
  88 ;; ======================================================================
  89 ;; command definition
  90
  91 ;; This macro is used below to define some basic debugger interface commands.
  92 ;; Of course you may use `gud-def' with any other debugger command, including
  93 ;; user defined ones.
  94
  95 ;; A macro call like (gud-def FUNC NAME KEY DOC) expands to a form
  96 ;; which defines FUNC to send the command NAME to the debugger, gives
  97 ;; it the docstring DOC, and binds that function to KEY in the GUD
  98 ;; major mode.  The function is also bound in the global keymap with the
  99 ;; GUD prefix.
 100
 101 (defmacro gud-def (func cmd key &optional doc)
 102   "Define FUNC to be a command sending STR and bound to KEY, with
 103 optional doc string DOC.  Certain %-escapes in the string arguments
 104 are interpreted specially if present.  These are:
 105
 106   %f    name (without directory) of current source file.
 107   %d    directory of current source file.
 108   %l    number of current source line
 109   %e    text of the C lvalue or function-call expression surrounding point.
 110   %a    text of the hexadecimal address surrounding point
 111   %p    prefix argument to the command (if any) as a number
 112
 113   The `current' source file is the file of the current buffer (if
 114 we're in a C file) or the source file current at the last break or
 115 step (if we're in the GUD buffer).
 116   The `current' line is that of the current buffer (if we're in a
 117 source file) or the source line number at the last break or step (if
 118 we're in the GUD buffer)."
 119   (list 'progn
 120         (list 'defun func '(arg)
 121               (or doc "")
 122               '(interactive "p")
 123               (list 'gud-call cmd 'arg))
 124         (if key
 125             (list 'define-key
 126                   '(current-local-map)
 127                   (concat "\C-c" key)
 128                   (list 'quote func)))
 129         (if key
 130             (list 'global-set-key
 131                   (list 'concat 'gud-key-prefix key)
 132                   (list 'quote func)))))
 133
 134 ;; Where gud-display-frame should put the debugging arrow.  This is
 135 ;; set by the marker-filter, which scans the debugger's output for
 136 ;; indications of the current program counter.
 137 (defvar gud-last-frame nil)
 138
 139 ;; Used by gud-refresh, which should cause gud-display-frame to redisplay
 140 ;; the last frame, even if it's been called before and gud-last-frame has
 141 ;; been set to nil.
 142 (defvar gud-last-last-frame nil)
 143
 144 ;; All debugger-specific information is collected here.
 145 ;; Here's how it works, in case you ever need to add a debugger to the mode.
 146 ;;
 147 ;; Each entry must define the following at startup:
 148 ;;
 149 ;;<name>
 150 ;; comint-prompt-regexp
 151 ;; gud-<name>-massage-args
 152 ;; gud-<name>-marker-filter
 153 ;; gud-<name>-find-file
 154 ;;
 155 ;; The job of the massage-args method is to modify the given list of
 156 ;; debugger arguments before running the debugger.
 157 ;;
 158 ;; The job of the marker-filter method is to detect file/line markers in
 159 ;; strings and set the global gud-last-frame to indicate what display
 160 ;; action (if any) should be triggered by the marker.  Note that only
 161 ;; whatever the method *returns* is displayed in the buffer; thus, you
 162 ;; can filter the debugger's output, interpreting some and passing on
 163 ;; the rest.
 164 ;;
 165 ;; The job of the find-file method is to visit and return the buffer indicated
 166 ;; by the car of gud-tag-frame.  This may be a file name, a tag name, or
 167 ;; something else.  It would be good if it also copied the Gud menubar entry.
 168 \f
 169 ;; ======================================================================
 170 ;; gdb functions
 171
 172 ;;; History of argument lists passed to gdb.
 173 (defvar gud-gdb-history nil)
 174
 175 (defun gud-gdb-massage-args (file args)
 176   (cons "-fullname" args))
 177
 178 ;; There's no guarantee that Emacs will hand the filter the entire
 179 ;; marker at once; it could be broken up across several strings.  We
 180 ;; might even receive a big chunk with several markers in it.  If we
 181 ;; receive a chunk of text which looks like it might contain the
 182 ;; beginning of a marker, we save it here between calls to the
 183 ;; filter.
 184 (defvar gud-marker-acc "")
 185 (make-variable-buffer-local 'gud-marker-acc)
 186
 187 (defun gud-gdb-marker-filter (string)
 188   (setq gud-marker-acc (concat gud-marker-acc string))
 189   (let ((output ""))
 190
 191     ;; Process all the complete markers in this chunk.
 192     (while (string-match "\032\032\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 193                          gud-marker-acc)
 194       (setq
 195
 196        ;; Extract the frame position from the marker.
 197        gud-last-frame
 198        (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
 199              (string-to-int (substring gud-marker-acc
 200                                        (match-beginning 2)
 201                                        (match-end 2))))
 202
 203        ;; Append any text before the marker to the output we're going
 204        ;; to return - we don't include the marker in this text.
 205        output (concat output
 206                       (substring gud-marker-acc 0 (match-beginning 0)))
 207
 208        ;; Set the accumulator to the remaining text.
 209        gud-marker-acc (substring gud-marker-acc (match-end 0))))
 210
 211     ;; Does the remaining text look like it might end with the
 212     ;; beginning of another marker?  If it does, then keep it in
 213     ;; gud-marker-acc until we receive the rest of it.  Since we
 214     ;; know the full marker regexp above failed, it's pretty simple to
 215     ;; test for marker starts.
 216     (if (string-match "\032.*\\'" gud-marker-acc)
 217         (progn
 218           ;; Everything before the potential marker start can be output.
 219           (setq output (concat output (substring gud-marker-acc
 220                                                  0 (match-beginning 0))))
 221
 222           ;; Everything after, we save, to combine with later input.
 223           (setq gud-marker-acc
 224                 (substring gud-marker-acc (match-beginning 0))))
 225
 226       (setq output (concat output gud-marker-acc)
 227             gud-marker-acc ""))
 228
 229     output))
 230
 231 (defun gud-new-keymap (map)
 232   "Return a new keymap which inherits from MAP and has name `Gud'."
 233   (nconc (make-sparse-keymap "Gud") map))
 234
 235 (defun gud-gdb-find-file (f)
 236   (save-excursion
 237     (let ((buf (find-file-noselect f)))
 238       (set-buffer buf)
 239       (use-local-map (gud-new-keymap (current-local-map)))
 240       (define-key (current-local-map) [menu-bar debug]
 241         (cons "Gud" (gud-new-keymap gud-menu-map)))
 242       (local-set-key [menu-bar debug tbreak]
 243                      '("Temporary breakpoint" . gud-tbreak))
 244       (local-set-key [menu-bar debug finish] '("Finish function" . gud-finish))
 245       (local-set-key [menu-bar debug up] '("Up stack" . gud-up))
 246       (local-set-key [menu-bar debug down] '("Down stack" . gud-down))
 247       buf)))
 248
 249 (defvar gdb-minibuffer-local-map nil
 250   "Keymap for minibuffer prompting of gdb startup command.")
 251 (if gdb-minibuffer-local-map
 252     ()
 253   (setq gdb-minibuffer-local-map (copy-keymap minibuffer-local-map))
 254   (define-key
 255     gdb-minibuffer-local-map "\C-i" 'comint-dynamic-complete-filename))
 256
 257 ;;;###autoload
 258 (defun gdb (command-line)
 259   "Run gdb on program FILE in buffer *gud-FILE*.
 260 The directory containing FILE becomes the initial working directory
 261 and source-file directory for your debugger."
 262   (interactive
 263    (list (read-from-minibuffer "Run gdb (like this): "
 264                                (if (consp gud-gdb-history)
 265                                    (car gud-gdb-history)
 266                                  "gdb ")
 267                                gdb-minibuffer-local-map nil
 268                                '(gud-gdb-history . 1))))
 269
 270   (gud-common-init command-line 'gud-gdb-massage-args
 271                    'gud-gdb-marker-filter 'gud-gdb-find-file)
 272
 273   (gud-def gud-break  "break %f:%l"  "\C-b" "Set breakpoint at current line.")
 274   (gud-def gud-tbreak "tbreak %f:%l" "\C-t" "Set temporary breakpoint at current line.")
 275   (gud-def gud-remove "clear %f:%l"  "\C-d" "Remove breakpoint at current line")
 276   (gud-def gud-step   "step %p"      "\C-s" "Step one source line with display.")
 277   (gud-def gud-stepi  "stepi %p"     "\C-i" "Step one instruction with display.")
 278   (gud-def gud-next   "next %p"      "\C-n" "Step one line (skip functions).")
 279   (gud-def gud-cont   "cont"         "\C-r" "Continue with display.")
 280   (gud-def gud-finish "finish"       "\C-f" "Finish executing current function.")
 281   (gud-def gud-up     "up %p"        "<" "Up N stack frames (numeric arg).")
 282   (gud-def gud-down   "down %p"      ">" "Down N stack frames (numeric arg).")
 283   (gud-def gud-print  "print %e"     "\C-p" "Evaluate C expression at point.")
 284
 285   (local-set-key "\C-i" 'gud-gdb-complete-command)
 286   (local-set-key [menu-bar debug tbreak] '("Temporary breakpoint" . gud-tbreak))
 287   (local-set-key [menu-bar debug finish] '("Finish function" . gud-finish))
 288   (local-set-key [menu-bar debug up] '("Up stack" . gud-up))
 289   (local-set-key [menu-bar debug down] '("Down stack" . gud-down))
 290   (setq comint-prompt-regexp "^(.*gdb[+]?) *")
 291   (setq paragraph-start comint-prompt-regexp)
 292   (run-hooks 'gdb-mode-hook)
 293   )
 294
 295 ;; One of the nice features of GDB is its impressive support for
 296 ;; context-sensitive command completion.  We preserve that feature
 297 ;; in the GUD buffer by using a GDB command designed just for Emacs.
 298
 299 ;; The completion process filter indicates when it is finished.
 300 (defvar gud-gdb-complete-in-progress)
 301
 302 ;; Since output may arrive in fragments we accumulate partials strings here.
 303 (defvar gud-gdb-complete-string)
 304
 305 ;; We need to know how much of the completion to chop off.
 306 (defvar gud-gdb-complete-break)
 307
 308 ;; The completion list is constructed by the process filter.
 309 (defvar gud-gdb-complete-list)
 310
 311 (defvar gud-comint-buffer nil)
 312
 313 (defun gud-gdb-complete-command ()
 314   "Perform completion on the GDB command preceding point.
 315 This is implemented using the GDB `complete' command which isn't
 316 available with older versions of GDB."
 317   (interactive)
 318   (let* ((end (point))
 319          (command (save-excursion
 320                     (beginning-of-line)
 321                     (and (looking-at comint-prompt-regexp)
 322                          (goto-char (match-end 0)))
 323                     (buffer-substring (point) end)))
 324          command-word)
 325     ;; Find the word break.  This match will always succeed.
 326     (string-match "\\(\\`\\| \\)\\([^ ]*\\)\\'" command)
 327     (setq gud-gdb-complete-break (match-beginning 2)
 328           command-word (substring command gud-gdb-complete-break))
 329     ;; Temporarily install our filter function.
 330     (let ((gud-marker-filter 'gud-gdb-complete-filter))
 331       ;; Issue the command to GDB.
 332       (gud-basic-call (concat "complete " command))
 333       (setq gud-gdb-complete-in-progress t
 334             gud-gdb-complete-string nil
 335             gud-gdb-complete-list nil)
 336       ;; Slurp the output.
 337       (while gud-gdb-complete-in-progress
 338         (accept-process-output (get-buffer-process gud-comint-buffer))))
 339     ;; Protect against old versions of GDB.
 340     (and gud-gdb-complete-list
 341          (string-match "^Undefined command: \"complete\""
 342                        (car gud-gdb-complete-list))
 343          (error "This version of GDB doesn't support the `complete' command."))
 344     ;; Sort the list like readline.
 345     (setq gud-gdb-complete-list
 346           (sort gud-gdb-complete-list (function string-lessp)))
 347     ;; Remove duplicates.
 348     (let ((first gud-gdb-complete-list)
 349           (second (cdr gud-gdb-complete-list)))
 350       (while second
 351         (if (string-equal (car first) (car second))
 352             (setcdr first (setq second (cdr second)))
 353           (setq first second
 354                 second (cdr second)))))
 355     ;; Add a trailing single quote if there is a unique completion
 356     ;; and it contains an odd number of unquoted single quotes.
 357     (and (= (length gud-gdb-complete-list) 1)
 358          (let ((str (car gud-gdb-complete-list))
 359                (pos 0)
 360                (count 0))
 361            (while (string-match "\\([^'\\]\\|\\\\'\\)*'" str pos)
 362              (setq count (1+ count)
 363                    pos (match-end 0)))
 364            (and (= (mod count 2) 1)
 365                 (setq gud-gdb-complete-list (list (concat str "'"))))))
 366     ;; Let comint handle the rest.
 367     (comint-dynamic-simple-complete command-word gud-gdb-complete-list)))
 368
 369 ;; The completion process filter is installed temporarily to slurp the
 370 ;; output of GDB up to the next prompt and build the completion list.
 371 (defun gud-gdb-complete-filter (string)
 372   (setq string (concat gud-gdb-complete-string string))
 373   (while (string-match "\n" string)
 374     (setq gud-gdb-complete-list
 375           (cons (substring string gud-gdb-complete-break (match-beginning 0))
 376                 gud-gdb-complete-list))
 377     (setq string (substring string (match-end 0))))
 378   (if (string-match comint-prompt-regexp string)
 379       (progn
 380         (setq gud-gdb-complete-in-progress nil)
 381         string)
 382     (progn
 383       (setq gud-gdb-complete-string string)
 384       "")))
 385
 386 \f
 387 ;; ======================================================================
 388 ;; sdb functions
 389
 390 ;;; History of argument lists passed to sdb.
 391 (defvar gud-sdb-history nil)
 392
 393 (defvar gud-sdb-needs-tags (not (file-exists-p "/var"))
 394   "If nil, we're on a System V Release 4 and don't need the tags hack.")
 395
 396 (defvar gud-sdb-lastfile nil)
 397
 398 (defun gud-sdb-massage-args (file args) args)
 399
 400 (defun gud-sdb-marker-filter (string)
 401   (setq gud-marker-acc
 402         (if gud-marker-acc (concat gud-marker-acc string) string))
 403   (let (start)
 404     ;; Process all complete markers in this chunk
 405     (while
 406         (cond
 407          ;; System V Release 3.2 uses this format
 408          ((string-match "\\(^0x\\w* in \\|^\\|\n\\)\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 409                         gud-marker-acc start)
 410           (setq gud-last-frame
 411                 (cons
 412                  (substring gud-marker-acc (match-beginning 2) (match-end 2))
 413                  (string-to-int
 414                   (substring gud-marker-acc (match-beginning 3) (match-end 3))))))
 415          ;; System V Release 4.0 quite often clumps two lines together
 416          ((string-match "^\\(BREAKPOINT\\|STEPPED\\) process [0-9]+ function [^ ]+ in \\(.+\\)\n\\([0-9]+\\):"
 417                         gud-marker-acc start)
 418           (setq gud-sdb-lastfile
 419                 (substring gud-marker-acc (match-beginning 2) (match-end 2)))
 420           (setq gud-last-frame
 421                 (cons
 422                  gud-sdb-lastfile
 423                  (string-to-int
 424                   (substring gud-marker-acc (match-beginning 3) (match-end 3))))))
 425          ;; System V Release 4.0
 426          ((string-match "^\\(BREAKPOINT\\|STEPPED\\) process [0-9]+ function [^ ]+ in \\(.+\\)\n"
 427                         gud-marker-acc start)
 428           (setq gud-sdb-lastfile
 429                 (substring gud-marker-acc (match-beginning 2) (match-end 2))))
 430          ((and gud-sdb-lastfile (string-match "^\\([0-9]+\\):"
 431                                               gud-marker-acc start))
 432                (setq gud-last-frame
 433                      (cons
 434                       gud-sdb-lastfile
 435                       (string-to-int
 436                        (substring gud-marker-acc (match-beginning 1) (match-end 1))))))
 437          (t
 438           (setq gud-sdb-lastfile nil)))
 439       (setq start (match-end 0)))
 440
 441     ;; Search for the last incomplete line in this chunk
 442     (while (string-match "\n" gud-marker-acc start)
 443       (setq start (match-end 0)))
 444
 445     ;; If we have an incomplete line, store it in gud-marker-acc.
 446     ;; Otherwise clear gud-marker-acc. to avoid an
 447     ;; unnecessary concat when this function runs next.
 448     (setq gud-marker-acc
 449           (if (= start (length gud-marker-acc))
 450               (substring gud-marker-acc start)
 451             nil)))
 452   string)
 453
 454 (defun gud-sdb-find-file (f)
 455   (save-excursion
 456     (let ((buf (if gud-sdb-needs-tags
 457                    (find-tag-noselect f)
 458                  (find-file-noselect f))))
 459       (set-buffer buf)
 460       (use-local-map (gud-new-keymap (current-local-map)))
 461       (define-key (current-local-map) [menu-bar debug]
 462         (cons "Gud" (gud-new-keymap gud-menu-map)))
 463       (local-set-key [menu-bar debug tbreak] '("Temporary breakpoint" . gud-tbreak))
 464       buf)))
 465
 466 ;;;###autoload
 467 (defun sdb (command-line)
 468   "Run sdb on program FILE in buffer *gud-FILE*.
 469 The directory containing FILE becomes the initial working directory
 470 and source-file directory for your debugger."
 471   (interactive
 472    (list (read-from-minibuffer "Run sdb (like this): "
 473                                (if (consp gud-sdb-history)
 474                                    (car gud-sdb-history)
 475                                  "sdb ")
 476                                nil nil
 477                                '(gud-sdb-history . 1))))
 478   (if (and gud-sdb-needs-tags
 479            (not (and (boundp 'tags-file-name)
 480                      (stringp tags-file-name)
 481                      (file-exists-p tags-file-name))))
 482       (error "The sdb support requires a valid tags table to work."))
 483
 484   (gud-common-init command-line 'gud-sdb-massage-args
 485                    'gud-sdb-marker-filter 'gud-sdb-find-file)
 486
 487   (gud-def gud-break  "%l b" "\C-b"   "Set breakpoint at current line.")
 488   (gud-def gud-tbreak "%l c" "\C-t"   "Set temporary breakpoint at current line.")
 489   (gud-def gud-remove "%l d" "\C-d"   "Remove breakpoint at current line")
 490   (gud-def gud-step   "s %p" "\C-s"   "Step one source line with display.")
 491   (gud-def gud-stepi  "i %p" "\C-i"   "Step one instruction with display.")
 492   (gud-def gud-next   "S %p" "\C-n"   "Step one line (skip functions).")
 493   (gud-def gud-cont   "c"    "\C-r"   "Continue with display.")
 494   (gud-def gud-print  "%e/"  "\C-p"   "Evaluate C expression at point.")
 495
 496   (setq comint-prompt-regexp  "\\(^\\|\n\\)\\*")
 497   (setq paragraph-start comint-prompt-regexp)
 498   (local-set-key [menu-bar debug tbreak]
 499     '("Temporary breakpoint" . gud-tbreak))
 500   (run-hooks 'sdb-mode-hook)
 501   )
 502 \f
 503 ;; ======================================================================
 504 ;; dbx functions
 505
 506 ;;; History of argument lists passed to dbx.
 507 (defvar gud-dbx-history nil)
 508
 509 (defun gud-dbx-massage-args (file args) args)
 510
 511 (defun gud-dbx-marker-filter (string)
 512   (setq gud-marker-acc (if gud-marker-acc (concat gud-marker-acc string) string))
 513
 514   (let (start)
 515     ;; Process all complete markers in this chunk.
 516     (while (or (string-match
 517                 "stopped in .* at line \\([0-9]*\\) in file \"\\([^\"]*\\)\""
 518                 gud-marker-acc start)
 519                (string-match
 520                 "signal .* in .* at line \\([0-9]*\\) in file \"\\([^\"]*\\)\""
 521                 gud-marker-acc start))
 522       (setq gud-last-frame
 523             (cons
 524              (substring gud-marker-acc (match-beginning 2) (match-end 2))
 525              (string-to-int
 526               (substring gud-marker-acc (match-beginning 1) (match-end 1))))
 527             start (match-end 0)))
 528
 529     ;; Search for the last incomplete line in this chunk
 530     (while (string-match "\n" gud-marker-acc start)
 531       (setq start (match-end 0)))
 532
 533     ;; If the incomplete line APPEARS to begin with another marker, keep it
 534     ;; in the accumulator.  Otherwise, clear the accumulator to avoid an
 535     ;; unnecessary concat during the next call.
 536     (setq gud-marker-acc
 537           (if (string-match "\\(stopped\\|signal\\)" gud-marker-acc start)
 538               (substring gud-marker-acc (match-beginning 0))
 539             nil)))
 540   string)
 541
 542 ;; Functions for Mips-style dbx.  Given the option `-emacs', documented in
 543 ;; OSF1, not necessarily elsewhere, it produces markers similar to gdb's.
 544 (defvar gud-mips-p
 545   (or (string-match "^mips-[^-]*-ultrix" system-configuration)
 546       ;; We haven't tested gud on this system:
 547       (string-match "^mips-[^-]*-riscos" system-configuration)
 548       ;; It's documented on OSF/1.3
 549       (string-match "^mips-[^-]*-osf1" system-configuration)
 550       (string-match "^alpha-[^-]*-osf" system-configuration))
 551   "Non-nil to assume the MIPS/OSF dbx conventions (argument `-emacs').")
 552
 553 (defun gud-mipsdbx-massage-args (file args)
 554   (cons "-emacs" args))
 555
 556 ;; This is just like the gdb one except for the regexps since we need to cope
 557 ;; with an optional breakpoint number in [] before the ^Z^Z
 558 (defun gud-mipsdbx-marker-filter (string)
 559   (setq gud-marker-acc (concat gud-marker-acc string))
 560   (let ((output ""))
 561
 562     ;; Process all the complete markers in this chunk.
 563     (while (string-match
 564             ;; This is like th gdb marker but with an optional
 565             ;; leading break point number like `[1] '
 566             "[][ 0-9]*\032\032\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 567             gud-marker-acc)
 568       (setq
 569
 570        ;; Extract the frame position from the marker.
 571        gud-last-frame
 572        (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
 573              (string-to-int (substring gud-marker-acc
 574                                        (match-beginning 2)
 575                                        (match-end 2))))
 576
 577        ;; Append any text before the marker to the output we're going
 578        ;; to return - we don't include the marker in this text.
 579        output (concat output
 580                       (substring gud-marker-acc 0 (match-beginning 0)))
 581
 582        ;; Set the accumulator to the remaining text.
 583        gud-marker-acc (substring gud-marker-acc (match-end 0))))
 584
 585     ;; Does the remaining text look like it might end with the
 586     ;; beginning of another marker?  If it does, then keep it in
 587     ;; gud-marker-acc until we receive the rest of it.  Since we
 588     ;; know the full marker regexp above failed, it's pretty simple to
 589     ;; test for marker starts.
 590     (if (string-match "[][ 0-9]*\032.*\\'" gud-marker-acc)
 591         (progn
 592           ;; Everything before the potential marker start can be output.
 593           (setq output (concat output (substring gud-marker-acc
 594                                                  0 (match-beginning 0))))
 595
 596           ;; Everything after, we save, to combine with later input.
 597           (setq gud-marker-acc
 598                 (substring gud-marker-acc (match-beginning 0))))
 599
 600       (setq output (concat output gud-marker-acc)
 601             gud-marker-acc ""))
 602
 603     output))
 604
 605 ;; The dbx in IRIX is a pain.  It doesn't print the file name when
 606 ;; stopping at a breakpoint (but you do get it from the `up' and
 607 ;; `down' commands...).  The only way to extract the information seems
 608 ;; to be with a `file' command, although the current line number is
 609 ;; available in $curline.  Thus we have to look for output which
 610 ;; appears to indicate a breakpoint.  Then we prod the dbx sub-process
 611 ;; to output the information we want with a combination of the
 612 ;; `printf' and `file' commands as a pseudo marker which we can
 613 ;; recognise next time through the marker-filter.  This would be like
 614 ;; the gdb marker but you can't get the file name without a newline...
 615 ;; Note that gud-remove won't work since Irix dbx expects a breakpoint
 616 ;; number rather than a line number etc.  Maybe this could be made to
 617 ;; work by listing all the breakpoints and picking the one(s) with the
 618 ;; correct line number, but life's too short.
 619 ;;   d.love@dl.ac.uk (Dave Love) can be blamed for this
 620
 621 (defvar gud-irix-p (string-match "^mips-[^-]*-irix" system-configuration)
 622   "Non-nil to assume the interface appropriate for IRIX dbx.
 623 This works in IRIX 4, 5 and 6.")
 624 ;; [Irix dbx seems to be a moving target.  The dbx output changed
 625 ;; subtly sometime between OS v4.0.5 and v5.2 so that, for instance,
 626 ;; the output from `up' is no longer spotted by gud (and it's probably
 627 ;; not distinctive enough to try to match it -- use C-<, C->
 628 ;; exclusively) .  For 5.3 and 6.0, the $curline variable changed to
 629 ;; `long long'(why?!), so the printf stuff needed changing.  The line
 630 ;; number is cast to `long' as a compromise between the new `long
 631 ;; long' and the original `int'.  The process filter is also somewhat
 632 ;; unreliable, sometimes not spotting the markers; I don't know
 633 ;; whether there's anything that can be done about that.  It would be
 634 ;; much better if SGI could be persuaded to (re?)instate the MIPS
 635 ;; -emacs flag for gdb-like output (which ought to be possible as most
 636 ;; of the communication I've had over it has been from sgi.com).]
 637
 638 ;; this filter is influenced by the xdb one rather than the gdb one
 639 (defun gud-irixdbx-marker-filter (string)
 640   (let (result (case-fold-search nil))
 641     (if (or (string-match comint-prompt-regexp string)
 642             (string-match ".*\012" string))
 643         (setq result (concat gud-marker-acc string)
 644               gud-marker-acc "")
 645       (setq gud-marker-acc (concat gud-marker-acc string)))
 646     (if result
 647         (cond
 648          ;; look for breakpoint or signal indication e.g.:
 649          ;; [2] Process  1267 (pplot) stopped at [params:338 ,0x400ec0]
 650          ;; Process  1281 (pplot) stopped at [params:339 ,0x400ec8]
 651          ;; Process  1270 (pplot) Floating point exception [._read._read:16 ,0x452188]
 652          ((string-match
 653            "^\\(\\[[0-9]+] \\)?Process +[0-9]+ ([^)]*) [^[]+\\[[^]\n]*]\n"
 654            result)
 655           ;; prod dbx into printing out the line number and file
 656           ;; name in a form we can grok as below
 657           (process-send-string (get-buffer-process gud-comint-buffer)
 658                                "printf \"\032\032%1d:\",(long)$curline;file\n"))
 659          ;; look for result of, say, "up" e.g.:
 660          ;; .pplot.pplot(0x800) ["src/pplot.f":261, 0x400c7c]
 661          ;; (this will also catch one of the lines printed by "where")
 662          ((string-match
 663            "^[^ ][^[]*\\[\"\\([^\"]+\\)\":\\([0-9]+\\), [^]]+]\n"
 664            result)
 665           (let ((file (substring result (match-beginning 1)
 666                                  (match-end 1))))
 667             (if (file-exists-p file)
 668                 (setq gud-last-frame
 669                       (cons
 670                        (substring
 671                         result (match-beginning 1) (match-end 1))
 672                        (string-to-int
 673                         (substring
 674                          result (match-beginning 2) (match-end 2)))))))
 675           result)
 676          ((string-match                 ; kluged-up marker as above
 677            "\032\032\\([0-9]*\\):\\(.*\\)\n" result)
 678           (let ((file (substring result (match-beginning 2) (match-end 2))))
 679             (if (file-exists-p file)
 680                 (setq gud-last-frame
 681                       (cons
 682                        file
 683                        (string-to-int
 684                         (substring
 685                          result (match-beginning 1) (match-end 1)))))))
 686           (setq result (substring result 0 (match-beginning 0))))))
 687     (or result "")))
 688
 689 (defun gud-dbx-find-file (f)
 690   (save-excursion
 691     (let ((buf (find-file-noselect f)))
 692       (set-buffer buf)
 693       (use-local-map (gud-new-keymap (current-local-map)))
 694       (define-key (current-local-map) [menu-bar debug]
 695         (cons "Gud" (gud-new-keymap gud-menu-map)))
 696       (local-set-key [menu-bar debug up] '("Up stack" . gud-up))
 697       (local-set-key [menu-bar debug down] '("Down stack" . gud-down))
 698       buf)))
 699
 700 ;;;###autoload
 701 (defun dbx (command-line)
 702   "Run dbx on program FILE in buffer *gud-FILE*.
 703 The directory containing FILE becomes the initial working directory
 704 and source-file directory for your debugger."
 705   (interactive
 706    (list (read-from-minibuffer "Run dbx (like this): "
 707                                (if (consp gud-dbx-history)
 708                                    (car gud-dbx-history)
 709                                  "dbx ")
 710                                nil nil
 711                                '(gud-dbx-history . 1))))
 712
 713   (cond
 714    (gud-mips-p
 715     (gud-common-init command-line 'gud-mipsdbx-massage-args
 716                      'gud-mipsdbx-marker-filter 'gud-dbx-find-file))
 717    (gud-irix-p
 718     (gud-common-init command-line 'gud-dbx-massage-args
 719                      'gud-irixdbx-marker-filter 'gud-dbx-find-file))
 720    (t
 721     (gud-common-init command-line 'gud-dbx-massage-args
 722                      'gud-dbx-marker-filter 'gud-dbx-find-file)))
 723
 724   (cond
 725    (gud-mips-p
 726     (gud-def gud-up     "up %p"         "<" "Up (numeric arg) stack frames.")
 727     (gud-def gud-down   "down %p" ">" "Down (numeric arg) stack frames.")
 728     (gud-def gud-break "stop at \"%f\":%l"
 729                                   "\C-b" "Set breakpoint at current line.")
 730     (gud-def gud-finish "return"  "\C-f" "Finish executing current function."))
 731    (gud-irix-p
 732     (gud-def gud-break "stop at \"%d%f\":%l"
 733                                   "\C-b" "Set breakpoint at current line.")
 734     (gud-def gud-finish "return"  "\C-f" "Finish executing current function.")
 735     (gud-def gud-up     "up %p; printf \"\032\032%1ld:\",(long)$curline;file\n"
 736              "<" "Up (numeric arg) stack frames.")
 737     (gud-def gud-down "down %p; printf \"\032\032%1ld:\",(long)$curline;file\n"
 738              ">" "Down (numeric arg) stack frames.")
 739     ;; Make dbx give out the source location info that we need.
 740     (process-send-string (get-buffer-process gud-comint-buffer)
 741                          "printf \"\032\032%1d:\",(long)$curline;file\n"))
 742    (t
 743     (gud-def gud-up     "up %p"         "<" "Up (numeric arg) stack frames.")
 744     (gud-def gud-down   "down %p" ">" "Down (numeric arg) stack frames.")
 745     (gud-def gud-break "file \"%d%f\"\nstop at %l"
 746                                   "\C-b" "Set breakpoint at current line.")))
 747
 748   (gud-def gud-remove "clear %l"  "\C-d" "Remove breakpoint at current line")
 749   (gud-def gud-step   "step %p"   "\C-s" "Step one line with display.")
 750   (gud-def gud-stepi  "stepi %p"  "\C-i" "Step one instruction with display.")
 751   (gud-def gud-next   "next %p"   "\C-n" "Step one line (skip functions).")
 752   (gud-def gud-cont   "cont"      "\C-r" "Continue with display.")
 753   (gud-def gud-print  "print %e"  "\C-p" "Evaluate C expression at point.")
 754
 755   (setq comint-prompt-regexp  "^[^)\n]*dbx) *")
 756   (setq paragraph-start comint-prompt-regexp)
 757   (local-set-key [menu-bar debug up] '("Up stack" . gud-up))
 758   (local-set-key [menu-bar debug down] '("Down stack" . gud-down))
 759   (run-hooks 'dbx-mode-hook)
 760   )
 761 \f
 762 ;; ======================================================================
 763 ;; xdb (HP PARISC debugger) functions
 764
 765 ;;; History of argument lists passed to xdb.
 766 (defvar gud-xdb-history nil)
 767
 768 (defvar gud-xdb-directories nil
 769   "*A list of directories that xdb should search for source code.
 770 If nil, only source files in the program directory
 771 will be known to xdb.
 772
 773 The file names should be absolute, or relative to the directory
 774 containing the executable being debugged.")
 775
 776 (defun gud-xdb-massage-args (file args)
 777   (nconc (let ((directories gud-xdb-directories)
 778                (result nil))
 779            (while directories
 780              (setq result (cons (car directories) (cons "-d" result)))
 781              (setq directories (cdr directories)))
 782            (nreverse result))
 783          args))
 784
 785 (defun gud-xdb-file-name (f)
 786   "Transform a relative pathname to a full pathname in xdb mode"
 787   (let ((result nil))
 788     (if (file-exists-p f)
 789         (setq result (expand-file-name f))
 790       (let ((directories gud-xdb-directories))
 791         (while directories
 792           (let ((path (concat (car directories) "/" f)))
 793             (if (file-exists-p path)
 794                 (setq result (expand-file-name path)
 795                       directories nil)))
 796           (setq directories (cdr directories)))))
 797     result))
 798
 799 ;; xdb does not print the lines all at once, so we have to accumulate them
 800 (defun gud-xdb-marker-filter (string)
 801   (let (result)
 802     (if (or (string-match comint-prompt-regexp string)
 803             (string-match ".*\012" string))
 804         (setq result (concat gud-marker-acc string)
 805               gud-marker-acc "")
 806       (setq gud-marker-acc (concat gud-marker-acc string)))
 807     (if result
 808         (if (or (string-match "\\([^\n \t:]+\\): [^:]+: \\([0-9]+\\):" result)
 809                 (string-match "[^: \t]+:[ \t]+\\([^:]+\\): [^:]+: \\([0-9]+\\):"
 810                               result))
 811             (let ((line (string-to-int
 812                          (substring result (match-beginning 2) (match-end 2))))
 813                   (file (gud-xdb-file-name
 814                          (substring result (match-beginning 1) (match-end 1)))))
 815               (if file
 816                   (setq gud-last-frame (cons file line))))))
 817     (or result "")))
 818
 819 (defun gud-xdb-find-file (f)
 820   (save-excursion
 821     (let ((realf (gud-xdb-file-name f)))
 822       (if realf
 823           (let ((buf (find-file-noselect realf)))
 824             (set-buffer buf)
 825             (use-local-map (gud-new-keymap (current-local-map)))
 826             (define-key (current-local-map) [menu-bar debug]
 827               (cons "Gud" (gud-new-keymap gud-menu-map)))
 828             (local-set-key [menu-bar debug tbreak]
 829                            '("Temporary breakpoint" . gud-tbreak))
 830             (local-set-key [menu-bar debug finish]
 831                            '("Finish function" . gud-finish))
 832             (local-set-key [menu-bar debug up] '("Up stack" . gud-up))
 833             (local-set-key [menu-bar debug up] '("Up stack" . gud-up))
 834             (local-set-key [menu-bar debug down] '("Down stack" . gud-down))
 835             buf)
 836         nil))))
 837
 838 ;;;###autoload
 839 (defun xdb (command-line)
 840   "Run xdb on program FILE in buffer *gud-FILE*.
 841 The directory containing FILE becomes the initial working directory
 842 and source-file directory for your debugger.
 843
 844 You can set the variable 'gud-xdb-directories' to a list of program source
 845 directories if your program contains sources from more than one directory."
 846   (interactive
 847    (list (read-from-minibuffer "Run xdb (like this): "
 848                                (if (consp gud-xdb-history)
 849                                    (car gud-xdb-history)
 850                                  "xdb ")
 851                                nil nil
 852                                '(gud-xdb-history . 1))))
 853
 854   (gud-common-init command-line 'gud-xdb-massage-args
 855                    'gud-xdb-marker-filter 'gud-xdb-find-file)
 856
 857   (gud-def gud-break  "b %f:%l"    "\C-b" "Set breakpoint at current line.")
 858   (gud-def gud-tbreak "b %f:%l\\t" "\C-t"
 859            "Set temporary breakpoint at current line.")
 860   (gud-def gud-remove "db"         "\C-d" "Remove breakpoint at current line")
 861   (gud-def gud-step   "s %p"       "\C-s" "Step one line with display.")
 862   (gud-def gud-next   "S %p"       "\C-n" "Step one line (skip functions).")
 863   (gud-def gud-cont   "c"          "\C-r" "Continue with display.")
 864   (gud-def gud-up     "up %p"      "<"    "Up (numeric arg) stack frames.")
 865   (gud-def gud-down   "down %p"    ">"    "Down (numeric arg) stack frames.")
 866   (gud-def gud-finish "bu\\t"      "\C-f" "Finish executing current function.")
 867   (gud-def gud-print  "p %e"       "\C-p" "Evaluate C expression at point.")
 868
 869   (setq comint-prompt-regexp  "^>")
 870   (setq paragraph-start comint-prompt-regexp)
 871   (local-set-key [menu-bar debug tbreak] '("Temporary breakpoint" . gud-tbreak))
 872   (local-set-key [menu-bar debug finish] '("Finish function" . gud-finish))
 873   (local-set-key [menu-bar debug up] '("Up stack" . gud-up))
 874   (local-set-key [menu-bar debug down] '("Down stack" . gud-down))
 875   (run-hooks 'xdb-mode-hook))
 876 \f
 877 ;; ======================================================================
 878 ;; perldb functions
 879
 880 ;;; History of argument lists passed to perldb.
 881 (defvar gud-perldb-history nil)
 882
 883 (defun gud-perldb-massage-args (file args)
 884   (cons "-d" (cons "-emacs" args)))
 885
 886 ;; There's no guarantee that Emacs will hand the filter the entire
 887 ;; marker at once; it could be broken up across several strings.  We
 888 ;; might even receive a big chunk with several markers in it.  If we
 889 ;; receive a chunk of text which looks like it might contain the
 890 ;; beginning of a marker, we save it here between calls to the
 891 ;; filter.
 892 (defvar gud-perldb-marker-acc "")
 893
 894 (defun gud-perldb-marker-filter (string)
 895   (setq gud-marker-acc (concat gud-marker-acc string))
 896   (let ((output ""))
 897
 898     ;; Process all the complete markers in this chunk.
 899     (while (string-match "\032\032\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 900                          gud-marker-acc)
 901       (setq
 902
 903        ;; Extract the frame position from the marker.
 904        gud-last-frame
 905        (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
 906              (string-to-int (substring gud-marker-acc
 907                                        (match-beginning 2)
 908                                        (match-end 2))))
 909
 910        ;; Append any text before the marker to the output we're going
 911        ;; to return - we don't include the marker in this text.
 912        output (concat output
 913                       (substring gud-marker-acc 0 (match-beginning 0)))
 914
 915        ;; Set the accumulator to the remaining text.
 916        gud-marker-acc (substring gud-marker-acc (match-end 0))))
 917
 918     ;; Does the remaining text look like it might end with the
 919     ;; beginning of another marker?  If it does, then keep it in
 920     ;; gud-marker-acc until we receive the rest of it.  Since we
 921     ;; know the full marker regexp above failed, it's pretty simple to
 922     ;; test for marker starts.
 923     (if (string-match "\032.*\\'" gud-marker-acc)
 924         (progn
 925           ;; Everything before the potential marker start can be output.
 926           (setq output (concat output (substring gud-marker-acc
 927                                                  0 (match-beginning 0))))
 928
 929           ;; Everything after, we save, to combine with later input.
 930           (setq gud-marker-acc
 931                 (substring gud-marker-acc (match-beginning 0))))
 932
 933       (setq output (concat output gud-marker-acc)
 934             gud-marker-acc ""))
 935
 936     output))
 937
 938 (defun gud-perldb-find-file (f)
 939   (save-excursion
 940     (let ((buf (find-file-noselect f)))
 941       (set-buffer buf)
 942       (define-key (current-local-map) [menu-bar debug] (cons "Gud" (copy-keymap gud-menu-map)))
 943       buf)))
 944
 945 ;;;###autoload
 946 (defun perldb (command-line)
 947   "Run perldb on program FILE in buffer *gud-FILE*.
 948 The directory containing FILE becomes the initial working directory
 949 and source-file directory for your debugger."
 950   (interactive
 951    (list (read-from-minibuffer "Run perldb (like this): "
 952                                (if (consp gud-perldb-history)
 953                                    (car gud-perldb-history)
 954                                  "perl ")
 955                                nil nil
 956                                '(gud-perldb-history . 1))))
 957
 958   (gud-common-init command-line 'gud-perldb-massage-args
 959                    'gud-perldb-marker-filter 'gud-perldb-find-file)
 960
 961   (gud-def gud-break  "b %l"         "\C-b" "Set breakpoint at current line.")
 962   (gud-def gud-remove "d %l"         "\C-d" "Remove breakpoint at current line")
 963   (gud-def gud-step   "s"            "\C-s" "Step one source line with display.")
 964   (gud-def gud-next   "n"            "\C-n" "Step one line (skip functions).")
 965   (gud-def gud-cont   "c"            "\C-r" "Continue with display.")
 966 ;  (gud-def gud-finish "finish"       "\C-f" "Finish executing current function.")
 967 ;  (gud-def gud-up     "up %p"        "<" "Up N stack frames (numeric arg).")
 968 ;  (gud-def gud-down   "down %p"      ">" "Down N stack frames (numeric arg).")
 969   (gud-def gud-print  "%e"           "\C-p" "Evaluate perl expression at point.")
 970
 971   (setq comint-prompt-regexp "^  DB<[0-9]+> ")
 972   (setq paragraph-start comint-prompt-regexp)
 973   (run-hooks 'perldb-mode-hook)
 974   )
 975
 976 ;;
 977 ;; End of debugger-specific information
 978 ;;
 979
 980 \f
 981 ;;; When we send a command to the debugger via gud-call, it's annoying
 982 ;;; to see the command and the new prompt inserted into the debugger's
 983 ;;; buffer; we have other ways of knowing the command has completed.
 984 ;;;
 985 ;;; If the buffer looks like this:
 986 ;;; --------------------
 987 ;;; (gdb) set args foo bar
 988 ;;; (gdb) -!-
 989 ;;; --------------------
 990 ;;; (the -!- marks the location of point), and we type `C-x SPC' in a
 991 ;;; source file to set a breakpoint, we want the buffer to end up like
 992 ;;; this:
 993 ;;; --------------------
 994 ;;; (gdb) set args foo bar
 995 ;;; Breakpoint 1 at 0x92: file make-docfile.c, line 49.
 996 ;;; (gdb) -!-
 997 ;;; --------------------
 998 ;;; Essentially, the old prompt is deleted, and the command's output
 999 ;;; and the new prompt take its place.
1000 ;;;
1001 ;;; Not echoing the command is easy enough; you send it directly using
1002 ;;; process-send-string, and it never enters the buffer.  However,
1003 ;;; getting rid of the old prompt is trickier; you don't want to do it
1004 ;;; when you send the command, since that will result in an annoying
1005 ;;; flicker as the prompt is deleted, redisplay occurs while Emacs
1006 ;;; waits for a response from the debugger, and the new prompt is
1007 ;;; inserted.  Instead, we'll wait until we actually get some output
1008 ;;; from the subprocess before we delete the prompt.  If the command
1009 ;;; produced no output other than a new prompt, that prompt will most
1010 ;;; likely be in the first chunk of output received, so we will delete
1011 ;;; the prompt and then replace it with an identical one.  If the
1012 ;;; command produces output, the prompt is moving anyway, so the
1013 ;;; flicker won't be annoying.
1014 ;;;
1015 ;;; So - when we want to delete the prompt upon receipt of the next
1016 ;;; chunk of debugger output, we position gud-delete-prompt-marker at
1017 ;;; the start of the prompt; the process filter will notice this, and
1018 ;;; delete all text between it and the process output marker.  If
1019 ;;; gud-delete-prompt-marker points nowhere, we leave the current
1020 ;;; prompt alone.
1021 (defvar gud-delete-prompt-marker nil)
1022
1023 \f
1024 (defun gud-mode ()
1025   "Major mode for interacting with an inferior debugger process.
1026
1027    You start it up with one of the commands M-x gdb, M-x sdb, M-x dbx,
1028 or M-x xdb.  Each entry point finishes by executing a hook; `gdb-mode-hook',
1029 `sdb-mode-hook', `dbx-mode-hook' or `xdb-mode-hook' respectively.
1030
1031 After startup, the following commands are available in both the GUD
1032 interaction buffer and any source buffer GUD visits due to a breakpoint stop
1033 or step operation:
1034
1035 \\[gud-break] sets a breakpoint at the current file and line.  In the
1036 GUD buffer, the current file and line are those of the last breakpoint or
1037 step.  In a source buffer, they are the buffer's file and current line.
1038
1039 \\[gud-remove] removes breakpoints on the current file and line.
1040
1041 \\[gud-refresh] displays in the source window the last line referred to
1042 in the gud buffer.
1043
1044 \\[gud-step], \\[gud-next], and \\[gud-stepi] do a step-one-line,
1045 step-one-line (not entering function calls), and step-one-instruction
1046 and then update the source window with the current file and position.
1047 \\[gud-cont] continues execution.
1048
1049 \\[gud-print] tries to find the largest C lvalue or function-call expression
1050 around point, and sends it to the debugger for value display.
1051
1052 The above commands are common to all supported debuggers except xdb which
1053 does not support stepping instructions.
1054
1055 Under gdb, sdb and xdb, \\[gud-tbreak] behaves exactly like \\[gud-break],
1056 except that the breakpoint is temporary; that is, it is removed when
1057 execution stops on it.
1058
1059 Under gdb, dbx, and xdb, \\[gud-up] pops up through an enclosing stack
1060 frame.  \\[gud-down] drops back down through one.
1061
1062 If you are using gdb or xdb, \\[gud-finish] runs execution to the return from
1063 the current function and stops.
1064
1065 All the keystrokes above are accessible in the GUD buffer
1066 with the prefix C-c, and in all buffers through the prefix C-x C-a.
1067
1068 All pre-defined functions for which the concept make sense repeat
1069 themselves the appropriate number of times if you give a prefix
1070 argument.
1071
1072 You may use the `gud-def' macro in the initialization hook to define other
1073 commands.
1074
1075 Other commands for interacting with the debugger process are inherited from
1076 comint mode, which see."
1077   (interactive)
1078   (comint-mode)
1079   (setq major-mode 'gud-mode)
1080   (setq mode-name "Debugger")
1081   (setq mode-line-process '(":%s"))
1082   (use-local-map (gud-new-keymap comint-mode-map))
1083   (define-key (current-local-map) "\C-c\C-l" 'gud-refresh)
1084   (define-key (current-local-map) [menu-bar debug]
1085     (cons "Gud" (gud-new-keymap gud-menu-map)))
1086   (make-local-variable 'gud-last-frame)
1087   (setq gud-last-frame nil)
1088   (make-local-variable 'comint-prompt-regexp)
1089   (make-local-variable 'paragraph-start)
1090   (make-local-variable 'gud-delete-prompt-marker)
1091   (setq gud-delete-prompt-marker (make-marker))
1092   (run-hooks 'gud-mode-hook))
1093
1094 ;; Chop STRING into words separated by SPC or TAB and return a list of them.
1095 (defun gud-chop-words (string)
1096   (let ((i 0) (beg 0)
1097         (len (length string))
1098         (words nil))
1099     (while (< i len)
1100       (if (memq (aref string i) '(?\t ? ))
1101           (progn
1102             (setq words (cons (substring string beg i) words)
1103                   beg (1+ i))
1104             (while (and (< beg len) (memq (aref string beg) '(?\t ? )))
1105               (setq beg (1+ beg)))
1106             (setq i (1+ beg)))
1107         (setq i (1+ i))))
1108     (if (< beg len)
1109         (setq words (cons (substring string beg) words)))
1110     (nreverse words)))
1111
1112 ;; Perform initializations common to all debuggers.
1113 ;; The first arg is the specified command line,
1114 ;; which starts with the program to debug.
1115 ;; The other three args specify the values to use
1116 ;; for local variables in the debugger buffer.
1117 (defun gud-common-init (command-line massage-args marker-filter find-file)
1118   (let* ((words (gud-chop-words command-line))
1119          (program (car words))
1120          ;; Extract the file name from WORDS
1121          ;; and put t in its place.
1122          ;; Later on we will put the modified file name arg back there.
1123          (file-word (let ((w (cdr words)))
1124                       (while (and w (= ?- (aref (car w) 0)))
1125                         (setq w (cdr w)))
1126                       (prog1 (car w)
1127                         (setcar w t))))
1128          (file-subst
1129           (and file-word (substitute-in-file-name file-word)))
1130          (args (cdr words))
1131          ;; If a directory was specified, expand the file name.
1132          ;; Otherwise, don't expand it, so GDB can use the PATH.
1133          ;; A file name without directory is literally valid
1134          ;; only if the file exists in ., and in that case,
1135          ;; omitting the expansion here has no visible effect.
1136          (file (and file-word
1137                     (if (file-name-directory file-subst)
1138                         (expand-file-name file-subst)
1139                       file-subst)))
1140          (filepart (and file-word (file-name-nondirectory file))))
1141     (switch-to-buffer (concat "*gud-" filepart "*"))
1142     ;; Set default-directory to the file's directory.
1143     (and file-word
1144          ;; Don't set default-directory if no directory was specified.
1145          ;; In that case, either the file is found in the current directory,
1146          ;; in which case this setq is a no-op,
1147          ;; or it is found by searching PATH,
1148          ;; in which case we don't know what directory it was found in.
1149          (file-name-directory file)
1150          (setq default-directory (file-name-directory file)))
1151     (or (bolp) (newline))
1152     (insert "Current directory is " default-directory "\n")
1153     ;; Put the substituted and expanded file name back in its place.
1154     (let ((w args))
1155       (while (and w (not (eq (car w) t)))
1156         (setq w (cdr w)))
1157       (setcar w file))
1158     (apply 'make-comint (concat "gud-" filepart) program nil
1159            (if file-word (funcall massage-args file args) args)))
1160   ;; Since comint clobbered the mode, we don't set it until now.
1161   (gud-mode)
1162   (make-local-variable 'gud-massage-args)
1163   (setq gud-massage-args massage-args)
1164   (make-local-variable 'gud-marker-filter)
1165   (setq gud-marker-filter marker-filter)
1166   (make-local-variable 'gud-find-file)
1167   (setq gud-find-file find-file)
1168
1169   (set-process-filter (get-buffer-process (current-buffer)) 'gud-filter)
1170   (set-process-sentinel (get-buffer-process (current-buffer)) 'gud-sentinel)
1171   (gud-set-buffer)
1172   )
1173
1174 (defun gud-set-buffer ()
1175   (cond ((eq major-mode 'gud-mode)
1176         (setq gud-comint-buffer (current-buffer)))))
1177
1178 ;; These functions are responsible for inserting output from your debugger
1179 ;; into the buffer.  The hard work is done by the method that is
1180 ;; the value of gud-marker-filter.
1181
1182 (defun gud-filter (proc string)
1183   ;; Here's where the actual buffer insertion is done
1184   (let (output)
1185     (if (buffer-name (process-buffer proc))
1186         (save-excursion
1187           (set-buffer (process-buffer proc))
1188           ;; If we have been so requested, delete the debugger prompt.
1189           (if (marker-buffer gud-delete-prompt-marker)
1190               (progn
1191                 (delete-region (process-mark proc) gud-delete-prompt-marker)
1192                 (set-marker gud-delete-prompt-marker nil)))
1193           ;; Save the process output, checking for source file markers.
1194           (setq output (gud-marker-filter string))
1195           ;; Check for a filename-and-line number.
1196           ;; Don't display the specified file
1197           ;; unless (1) point is at or after the position where output appears
1198           ;; and (2) this buffer is on the screen.
1199           (if (and gud-last-frame
1200                    (>= (point) (process-mark proc))
1201                    (get-buffer-window (current-buffer)))
1202               (gud-display-frame))
1203           ;; Let the comint filter do the actual insertion.
1204           ;; That lets us inherit various comint features.
1205           (comint-output-filter proc output)))))
1206
1207 (defun gud-sentinel (proc msg)
1208   (cond ((null (buffer-name (process-buffer proc)))
1209          ;; buffer killed
1210          ;; Stop displaying an arrow in a source file.
1211          (setq overlay-arrow-position nil)
1212          (set-process-buffer proc nil))
1213         ((memq (process-status proc) '(signal exit))
1214          ;; Stop displaying an arrow in a source file.
1215          (setq overlay-arrow-position nil)
1216          ;; Fix the mode line.
1217          (setq mode-line-process
1218                (concat ":"
1219                        (symbol-name (process-status proc))))
1220          (let* ((obuf (current-buffer)))
1221            ;; save-excursion isn't the right thing if
1222            ;;  process-buffer is current-buffer
1223            (unwind-protect
1224                (progn
1225                  ;; Write something in *compilation* and hack its mode line,
1226                  (set-buffer (process-buffer proc))
1227                  ;; Force mode line redisplay soon
1228                  (set-buffer-modified-p (buffer-modified-p))
1229                  (if (eobp)
1230                      (insert ?\n mode-name " " msg)
1231                    (save-excursion
1232                      (goto-char (point-max))
1233                      (insert ?\n mode-name " " msg)))
1234                  ;; If buffer and mode line will show that the process
1235                  ;; is dead, we can delete it now.  Otherwise it
1236                  ;; will stay around until M-x list-processes.
1237                  (delete-process proc))
1238              ;; Restore old buffer, but don't restore old point
1239              ;; if obuf is the gud buffer.
1240              (set-buffer obuf))))))
1241
1242 (defun gud-display-frame ()
1243   "Find and obey the last filename-and-line marker from the debugger.
1244 Obeying it means displaying in another window the specified file and line."
1245   (interactive)
1246   (if gud-last-frame
1247    (progn
1248      (gud-set-buffer)
1249      (gud-display-line (car gud-last-frame) (cdr gud-last-frame))
1250      (setq gud-last-last-frame gud-last-frame
1251            gud-last-frame nil))))
1252
1253 ;; Make sure the file named TRUE-FILE is in a buffer that appears on the screen
1254 ;; and that its line LINE is visible.
1255 ;; Put the overlay-arrow on the line LINE in that buffer.
1256 ;; Most of the trickiness in here comes from wanting to preserve the current
1257 ;; region-restriction if that's possible.  We use an explicit display-buffer
1258 ;; to get around the fact that this is called inside a save-excursion.
1259
1260 (defun gud-display-line (true-file line)
1261   (let* ((last-nonmenu-event t)  ; Prevent use of dialog box for questions.
1262          (buffer (gud-find-file true-file))
1263          (window (display-buffer buffer))
1264          (pos))
1265 ;;;    (if (equal buffer (current-buffer))
1266 ;;;     nil
1267 ;;;      (setq buffer-read-only nil))
1268     (save-excursion
1269 ;;;      (setq buffer-read-only t)
1270       (set-buffer buffer)
1271       (save-restriction
1272         (widen)
1273         (goto-line line)
1274         (setq pos (point))
1275         (setq overlay-arrow-string "=>")
1276         (or overlay-arrow-position
1277             (setq overlay-arrow-position (make-marker)))
1278         (set-marker overlay-arrow-position (point) (current-buffer)))
1279       (cond ((or (< pos (point-min)) (> pos (point-max)))
1280              (widen)
1281              (goto-char pos))))
1282     (set-window-point window overlay-arrow-position)))
1283
1284 ;;; The gud-call function must do the right thing whether its invoking
1285 ;;; keystroke is from the GUD buffer itself (via major-mode binding)
1286 ;;; or a C buffer.  In the former case, we want to supply data from
1287 ;;; gud-last-frame.  Here's how we do it:
1288
1289 (defun gud-format-command (str arg)
1290   (let ((insource (not (eq (current-buffer) gud-comint-buffer)))
1291         (frame (or gud-last-frame gud-last-last-frame))
1292         result)
1293     (while (and str (string-match "\\([^%]*\\)%\\([adeflp]\\)" str))
1294       (let ((key (string-to-char (substring str (match-beginning 2))))
1295             subst)
1296         (cond
1297          ((eq key ?f)
1298           (setq subst (file-name-nondirectory (if insource
1299                                                   (buffer-file-name)
1300                                                 (car frame)))))
1301          ((eq key ?d)
1302           (setq subst (file-name-directory (if insource
1303                                                (buffer-file-name)
1304                                              (car frame)))))
1305          ((eq key ?l)
1306           (setq subst (if insource
1307                           (save-excursion
1308                             (beginning-of-line)
1309                             (save-restriction (widen)
1310                                               (1+ (count-lines 1 (point)))))
1311                         (cdr frame))))
1312          ((eq key ?e)
1313           (setq subst (find-c-expr)))
1314          ((eq key ?a)
1315           (setq subst (gud-read-address)))
1316          ((eq key ?p)
1317           (setq subst (if arg (int-to-string arg) ""))))
1318         (setq result (concat result
1319                              (substring str (match-beginning 1) (match-end 1))
1320                              subst)))
1321       (setq str (substring str (match-end 2))))
1322     ;; There might be text left in STR when the loop ends.
1323     (concat result str)))
1324
1325 (defun gud-read-address ()
1326   "Return a string containing the core-address found in the buffer at point."
1327   (save-excursion
1328     (let ((pt (point)) found begin)
1329       (setq found (if (search-backward "0x" (- pt 7) t) (point)))
1330       (cond
1331        (found (forward-char 2)
1332               (buffer-substring found
1333                                 (progn (re-search-forward "[^0-9a-f]")
1334                                        (forward-char -1)
1335                                        (point))))
1336        (t (setq begin (progn (re-search-backward "[^0-9]")
1337                              (forward-char 1)
1338                              (point)))
1339           (forward-char 1)
1340           (re-search-forward "[^0-9]")
1341           (forward-char -1)
1342           (buffer-substring begin (point)))))))
1343
1344 (defun gud-call (fmt &optional arg)
1345   (let ((msg (gud-format-command fmt arg)))
1346     (message "Command: %s" msg)
1347     (sit-for 0)
1348     (gud-basic-call msg)))
1349
1350 (defun gud-basic-call (command)
1351   "Invoke the debugger COMMAND displaying source in other window."
1352   (interactive)
1353   (gud-set-buffer)
1354   (let ((command (concat command "\n"))
1355         (proc (get-buffer-process gud-comint-buffer)))
1356     (or proc (error "Current buffer has no process"))
1357     ;; Arrange for the current prompt to get deleted.
1358     (save-excursion
1359       (set-buffer gud-comint-buffer)
1360       (goto-char (process-mark proc))
1361       (beginning-of-line)
1362       (if (looking-at comint-prompt-regexp)
1363           (set-marker gud-delete-prompt-marker (point))))
1364     (process-send-string proc command)))
1365
1366 (defun gud-refresh (&optional arg)
1367   "Fix up a possibly garbled display, and redraw the arrow."
1368   (interactive "P")
1369   (recenter arg)
1370   (or gud-last-frame (setq gud-last-frame gud-last-last-frame))
1371   (gud-display-frame))
1372 \f
1373 ;;; Code for parsing expressions out of C code.  The single entry point is
1374 ;;; find-c-expr, which tries to return an lvalue expression from around point.
1375 ;;;
1376 ;;; The rest of this file is a hacked version of gdbsrc.el by
1377 ;;; Debby Ayers <ayers@asc.slb.com>,
1378 ;;; Rich Schaefer <schaefer@asc.slb.com> Schlumberger, Austin, Tx.
1379
1380 (defun find-c-expr ()
1381   "Returns the C expr that surrounds point."
1382   (interactive)
1383   (save-excursion
1384     (let ((p) (expr) (test-expr))
1385       (setq p (point))
1386       (setq expr (expr-cur))
1387       (setq test-expr (expr-prev))
1388       (while (expr-compound test-expr expr)
1389         (setq expr (cons (car test-expr) (cdr expr)))
1390         (goto-char (car expr))
1391         (setq test-expr (expr-prev)))
1392       (goto-char p)
1393       (setq test-expr (expr-next))
1394       (while (expr-compound expr test-expr)
1395         (setq expr (cons (car expr) (cdr test-expr)))
1396         (setq test-expr (expr-next))
1397         )
1398       (buffer-substring (car expr) (cdr expr)))))
1399
1400 (defun expr-cur ()
1401   "Returns the expr that point is in; point is set to beginning of expr.
1402 The expr is represented as a cons cell, where the car specifies the point in
1403 the current buffer that marks the beginning of the expr and the cdr specifies
1404 the character after the end of the expr."
1405   (let ((p (point)) (begin) (end))
1406     (expr-backward-sexp)
1407     (setq begin (point))
1408     (expr-forward-sexp)
1409     (setq end (point))
1410     (if (>= p end)
1411         (progn
1412          (setq begin p)
1413          (goto-char p)
1414          (expr-forward-sexp)
1415          (setq end (point))
1416          )
1417       )
1418     (goto-char begin)
1419     (cons begin end)))
1420
1421 (defun expr-backward-sexp ()
1422   "Version of `backward-sexp' that catches errors."
1423   (condition-case nil
1424       (backward-sexp)
1425     (error t)))
1426
1427 (defun expr-forward-sexp ()
1428   "Version of `forward-sexp' that catches errors."
1429   (condition-case nil
1430      (forward-sexp)
1431     (error t)))
1432
1433 (defun expr-prev ()
1434   "Returns the previous expr, point is set to beginning of that expr.
1435 The expr is represented as a cons cell, where the car specifies the point in
1436 the current buffer that marks the beginning of the expr and the cdr specifies
1437 the character after the end of the expr"
1438   (let ((begin) (end))
1439     (expr-backward-sexp)
1440     (setq begin (point))
1441     (expr-forward-sexp)
1442     (setq end (point))
1443     (goto-char begin)
1444     (cons begin end)))
1445
1446 (defun expr-next ()
1447   "Returns the following expr, point is set to beginning of that expr.
1448 The expr is represented as a cons cell, where the car specifies the point in
1449 the current buffer that marks the beginning of the expr and the cdr specifies
1450 the character after the end of the expr."
1451   (let ((begin) (end))
1452     (expr-forward-sexp)
1453     (expr-forward-sexp)
1454     (setq end (point))
1455     (expr-backward-sexp)
1456     (setq begin (point))
1457     (cons begin end)))
1458
1459 (defun expr-compound-sep (span-start span-end)
1460   "Returns '.' for '->' & '.', returns ' ' for white space,
1461 returns '?' for other punctuation."
1462   (let ((result ? )
1463         (syntax))
1464     (while (< span-start span-end)
1465       (setq syntax (char-syntax (char-after span-start)))
1466       (cond
1467        ((= syntax ? ) t)
1468        ((= syntax ?.) (setq syntax (char-after span-start))
1469         (cond
1470          ((= syntax ?.) (setq result ?.))
1471          ((and (= syntax ?-) (= (char-after (+ span-start 1)) ?>))
1472           (setq result ?.)
1473           (setq span-start (+ span-start 1)))
1474          (t (setq span-start span-end)
1475             (setq result ??)))))
1476       (setq span-start (+ span-start 1)))
1477     result))
1478
1479 (defun expr-compound (first second)
1480   "Non-nil if concatenating FIRST and SECOND makes a single C token.
1481 The two exprs are represented as a cons cells, where the car
1482 specifies the point in the current buffer that marks the beginning of the
1483 expr and the cdr specifies the character after the end of the expr.
1484 Link exprs of the form:
1485       Expr -> Expr
1486       Expr . Expr
1487       Expr (Expr)
1488       Expr [Expr]
1489       (Expr) Expr
1490       [Expr] Expr"
1491   (let ((span-start (cdr first))
1492         (span-end (car second))
1493         (syntax))
1494     (setq syntax (expr-compound-sep span-start span-end))
1495     (cond
1496      ((= (car first) (car second)) nil)
1497      ((= (cdr first) (cdr second)) nil)
1498      ((= syntax ?.) t)
1499      ((= syntax ? )
1500          (setq span-start (char-after (- span-start 1)))
1501          (setq span-end (char-after span-end))
1502          (cond
1503           ((= span-start ?) ) t )
1504           ((= span-start ?] ) t )
1505           ((= span-end ?( ) t )
1506           ((= span-end ?[ ) t )
1507           (t nil))
1508          )
1509      (t nil))))
1510
1511 (provide 'gud)
1512
1513 ;;; gud.el ends here