lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989, 1994, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do `M-x describe-mode'.
  33 ;;
  34 ;; This may be useful in your .emacs:
  35 ;;
  36 ;;      (autoload 'hexl-find-file "hexl"
  37 ;;        "Edit file FILENAME in hexl-mode." t)
  38 ;;
  39 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  40 ;;
  41 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  42 ;;
  43 ;; Currently hexl only supports big endian hex output with 16 bit
  44 ;; grouping.
  45 ;;
  46 ;; -iso in `hexl-options' will allow iso characters to display in the
  47 ;; ASCII region of the screen (if your emacs supports this) instead of
  48 ;; changing them to dots.
  49
  50 ;;; Code:
  51
  52 ;;
  53 ;; vars here
  54 ;;
  55
  56 (defgroup hexl nil
  57   "Edit a file in a hex dump format using the hexl filter."
  58   :group 'data)
  59
  60
  61 (defcustom hexl-program "hexl"
  62   "The program that will hexlify and dehexlify its stdin.
  63 `hexl-program' will always be concatenated with `hexl-options'
  64 and \"-de\" when dehexlifying a buffer."
  65   :type 'string
  66   :group 'hexl)
  67
  68 (defcustom hexl-iso ""
  69   "If your emacs can handle ISO characters, this should be set to
  70 \"-iso\" otherwise it should be \"\"."
  71   :type 'string
  72   :group 'hexl)
  73
  74 (defcustom hexl-options (format "-hex %s" hexl-iso)
  75   "Options to hexl-program that suit your needs."
  76   :type 'string
  77   :group 'hexl)
  78
  79 (defcustom hexlify-command
  80   (format "%s%s %s" exec-directory hexl-program hexl-options)
  81   "The command to use to hexlify a buffer."
  82   :type 'string
  83   :group 'hexl)
  84
  85 (defcustom dehexlify-command
  86   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  87   "The command to use to unhexlify a buffer."
  88   :type 'string
  89   :group 'hexl)
  90
  91 (defcustom hexl-follow-ascii t
  92   "If non-nil then highlight the ASCII character corresponding to point."
  93   :type 'boolean
  94   :group 'hexl)
  95
  96 (defvar hexl-max-address 0
  97   "Maximum offset into hexl buffer.")
  98
  99 (defvar hexl-mode-map nil)
 100
 101 (defvar hexl-mode-old-local-map)
 102 (defvar hexl-mode-old-mode-name)
 103 (defvar hexl-mode-old-major-mode)
 104 (defvar hexl-mode-old-write-contents-hooks)
 105 (defvar hexl-mode-old-require-final-newline)
 106 (defvar hexl-mode-old-syntax-table)
 107
 108 (defvar hexl-ascii-overlay nil
 109   "Overlay used to highlight ASCII element corresponding to current point.")
 110 (make-variable-buffer-local 'hexl-ascii-overlay)
 111
 112 ;; routines
 113
 114 (put 'hexl-mode 'mode-class 'special)
 115
 116 ;;;###autoload
 117 (defun hexl-mode (&optional arg)
 118   "\\<hexl-mode-map>
 119 A major mode for editing binary files in hex dump format.
 120
 121 This function automatically converts a buffer into the hexl format
 122 using the function `hexlify-buffer'.
 123
 124 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 125 representing the offset into the file that the characters on this line
 126 are at and 16 characters from the file (displayed as hexadecimal
 127 values grouped every 16 bits) and as their ASCII values.
 128
 129 If any of the characters (displayed as ASCII characters) are
 130 unprintable (control or meta characters) they will be replaced as
 131 periods.
 132
 133 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 134 in hexl format.
 135
 136 A sample format:
 137
 138   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 139   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 140   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 141   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 142   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 143   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 144   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 145   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 146   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 147   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 148   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 149   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 150   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 151   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 152   000000c0: 7265 6769 6f6e 2e0a                      region..
 153
 154 Movement is as simple as movement in a normal emacs text buffer.  Most
 155 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 156 to move the cursor left, right, down, and up).
 157
 158 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 159 also supported.
 160
 161 There are several ways to change text in hexl mode:
 162
 163 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 164 bound to self-insert so you can simply type the character and it will
 165 insert itself (actually overstrike) into the buffer.
 166
 167 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 168 it isn't bound to self-insert.  An octal number can be supplied in place
 169 of another key to insert the octal number's ASCII representation.
 170
 171 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 172 into the buffer at the current point.
 173
 174 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 175 into the buffer at the current point.
 176
 177 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 178 into the buffer at the current point.
 179
 180 \\[hexl-mode-exit] will exit hexl-mode.
 181
 182 Note: saving the file with any of the usual Emacs commands
 183 will actually convert it back to binary format while saving.
 184
 185 You can use \\[hexl-find-file] to visit a file in hexl-mode.
 186
 187 \\[describe-bindings] for advanced commands."
 188   (interactive "p")
 189   (if (eq major-mode 'hexl-mode)
 190       (error "You are already in hexl mode")
 191
 192     (let ((modified (buffer-modified-p))
 193           (inhibit-read-only t)
 194           (original-point (1- (point)))
 195           max-address)
 196       (and (eobp) (not (bobp))
 197            (setq original-point (1- original-point)))
 198       (if (not (or (eq arg 1) (not arg)))
 199           ;; if no argument then we guess at hexl-max-address
 200           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 201         (setq max-address (1- (buffer-size)))
 202         (hexlify-buffer)
 203         (set-buffer-modified-p modified))
 204       (make-local-variable 'hexl-max-address)
 205       (setq hexl-max-address max-address)
 206       (hexl-goto-address original-point))
 207
 208     ;; We do not turn off the old major mode; instead we just
 209     ;; override most of it.  That way, we can restore it perfectly.
 210     (make-local-variable 'hexl-mode-old-local-map)
 211     (setq hexl-mode-old-local-map (current-local-map))
 212     (use-local-map hexl-mode-map)
 213
 214     (make-local-variable 'hexl-mode-old-mode-name)
 215     (setq hexl-mode-old-mode-name mode-name)
 216     (setq mode-name "Hexl")
 217
 218     (make-local-variable 'hexl-mode-old-major-mode)
 219     (setq hexl-mode-old-major-mode major-mode)
 220     (setq major-mode 'hexl-mode)
 221
 222     (make-local-variable 'hexl-mode-old-syntax-table)
 223     (setq hexl-mode-old-syntax-table (syntax-table))
 224     (set-syntax-table (standard-syntax-table))
 225
 226     (make-local-variable 'hexl-mode-old-write-contents-hooks)
 227     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
 228     (make-local-variable 'write-contents-hooks)
 229     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 230
 231     (make-local-variable 'hexl-mode-old-require-final-newline)
 232     (setq hexl-mode-old-require-final-newline require-final-newline)
 233     (make-local-variable 'require-final-newline)
 234     (setq require-final-newline nil)
 235
 236     ;; Add hooks to rehexlify or dehexlify on various events.
 237     (make-local-hook 'after-revert-hook)
 238     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 239
 240     (make-local-hook 'change-major-mode-hook)
 241     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 242
 243     (if hexl-follow-ascii (hexl-follow-ascii 1)))
 244   (run-hooks 'hexl-mode-hook))
 245
 246 (defun hexl-after-revert-hook ()
 247   (hexlify-buffer)
 248   (set-buffer-modified-p nil))
 249
 250 (defvar hexl-in-save-buffer nil)
 251
 252 (defun hexl-save-buffer ()
 253   "Save a hexl format buffer as binary in visited file if modified."
 254   (interactive)
 255   (if hexl-in-save-buffer nil
 256     (set-buffer-modified-p (if (buffer-modified-p)
 257                                (save-excursion
 258                                  (let ((buf (generate-new-buffer " hexl"))
 259                                        (name (buffer-name))
 260                                        (file-name (buffer-file-name))
 261                                        (start (point-min))
 262                                        (end (point-max))
 263                                        modified)
 264                                    (set-buffer buf)
 265                                    (insert-buffer-substring name start end)
 266                                    (set-buffer name)
 267                                    (dehexlify-buffer)
 268                                    ;; Prevent infinite recursion.
 269                                    (let ((hexl-in-save-buffer t))
 270                                      (save-buffer))
 271                                    (setq modified (buffer-modified-p))
 272                                    (delete-region (point-min) (point-max))
 273                                    (insert-buffer-substring buf start end)
 274                                    (kill-buffer buf)
 275                                    modified))
 276                              (message "(No changes need to be saved)")
 277                              nil))
 278     ;; Return t to indicate we have saved t
 279     t))
 280
 281 ;;;###autoload
 282 (defun hexl-find-file (filename)
 283   "Edit file FILENAME in hexl-mode.
 284 Switch to a buffer visiting file FILENAME, creating one in none exists."
 285   (interactive "fFilename: ")
 286   (find-file-literally filename)
 287   (if (not (eq major-mode 'hexl-mode))
 288       (hexl-mode)))
 289
 290 (defun hexl-mode-exit (&optional arg)
 291   "Exit Hexl mode, returning to previous mode.
 292 With arg, don't unhexlify buffer."
 293   (interactive "p")
 294   (if (or (eq arg 1) (not arg))
 295       (let ((modified (buffer-modified-p))
 296             (inhibit-read-only t)
 297             (original-point (1+ (hexl-current-address))))
 298         (dehexlify-buffer)
 299         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 300         (set-buffer-modified-p modified)
 301         (goto-char original-point)))
 302
 303   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 304   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 305   (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 306   (setq hexl-ascii-overlay nil)
 307
 308   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
 309   (setq require-final-newline hexl-mode-old-require-final-newline)
 310   (setq mode-name hexl-mode-old-mode-name)
 311   (use-local-map hexl-mode-old-local-map)
 312   (set-syntax-table hexl-mode-old-syntax-table)
 313   (setq major-mode hexl-mode-old-major-mode)
 314   (force-mode-line-update))
 315
 316 (defun hexl-maybe-dehexlify-buffer ()
 317   "Convert a hexl format buffer to binary.
 318 Ask the user for confirmation."
 319   (if (y-or-n-p "Convert contents back to binary format? ")
 320       (let ((modified (buffer-modified-p))
 321             (inhibit-read-only t)
 322             (original-point (1+ (hexl-current-address))))
 323         (dehexlify-buffer)
 324         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 325         (set-buffer-modified-p modified)
 326         (goto-char original-point))))
 327
 328 (defun hexl-current-address (&optional validate)
 329   "Return current hexl-address."
 330   (interactive)
 331   (let ((current-column (- (% (point) 68) 11))
 332         (hexl-address 0))
 333     (if (< current-column 0)
 334         (if validate
 335             (error "Point is not on a character in the file")
 336           (setq current-column 0)))
 337     (setq hexl-address
 338           (+ (* (/ (point) 68) 16)
 339              (if (>= current-column 41)
 340                  (- current-column 41)
 341                (/ (- current-column  (/ current-column 5)) 2))))
 342     hexl-address))
 343
 344 (defun hexl-address-to-marker (address)
 345   "Return marker for ADDRESS."
 346   (interactive "nAddress: ")
 347   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 348
 349 (defun hexl-goto-address (address)
 350   "Goto hexl-mode (decimal) address ADDRESS.
 351 Signal error if ADDRESS out of range."
 352   (interactive "nAddress: ")
 353   (if (or (< address 0) (> address hexl-max-address))
 354           (error "Out of hexl region"))
 355   (goto-char (hexl-address-to-marker address)))
 356
 357 (defun hexl-goto-hex-address (hex-address)
 358   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 359 Signal error if HEX-ADDRESS is out of range."
 360   (interactive "sHex Address: ")
 361   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 362
 363 (defun hexl-hex-string-to-integer (hex-string)
 364   "Return decimal integer for HEX-STRING."
 365   (interactive "sHex number: ")
 366   (let ((hex-num 0))
 367     (while (not (equal hex-string ""))
 368       (setq hex-num (+ (* hex-num 16)
 369                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 370       (setq hex-string (substring hex-string 1)))
 371     hex-num))
 372
 373 (defun hexl-octal-string-to-integer (octal-string)
 374   "Return decimal integer for OCTAL-STRING."
 375   (interactive "sOctal number: ")
 376   (let ((oct-num 0))
 377     (while (not (equal octal-string ""))
 378       (setq oct-num (+ (* oct-num 8)
 379                        (hexl-oct-char-to-integer
 380                         (string-to-char octal-string))))
 381       (setq octal-string (substring octal-string 1)))
 382     oct-num))
 383
 384 ;; move point functions
 385
 386 (defun hexl-backward-char (arg)
 387   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 388   (interactive "p")
 389   (hexl-goto-address (- (hexl-current-address) arg)))
 390
 391 (defun hexl-forward-char (arg)
 392   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 393   (interactive "p")
 394   (hexl-goto-address (+ (hexl-current-address) arg)))
 395
 396 (defun hexl-backward-short (arg)
 397   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 398   (interactive "p")
 399   (hexl-goto-address (let ((address (hexl-current-address)))
 400                        (if (< arg 0)
 401                            (progn
 402                              (setq arg (- arg))
 403                              (while (> arg 0)
 404                                (if (not (equal address (logior address 3)))
 405                                    (if (> address hexl-max-address)
 406                                        (progn
 407                                          (message "End of buffer.")
 408                                          (setq address hexl-max-address))
 409                                      (setq address (logior address 3)))
 410                                  (if (> address hexl-max-address)
 411                                      (progn
 412                                        (message "End of buffer.")
 413                                        (setq address hexl-max-address))
 414                                    (setq address (+ address 4))))
 415                                (setq arg (1- arg)))
 416                              (if (> address hexl-max-address)
 417                                  (progn
 418                                    (message "End of buffer.")
 419                                    (setq address hexl-max-address))
 420                                (setq address (logior address 3))))
 421                          (while (> arg 0)
 422                            (if (not (equal address (logand address -4)))
 423                                (setq address (logand address -4))
 424                              (if (not (equal address 0))
 425                                  (setq address (- address 4))
 426                                (message "Beginning of buffer.")))
 427                            (setq arg (1- arg))))
 428                        address)))
 429
 430 (defun hexl-forward-short (arg)
 431   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 432   (interactive "p")
 433   (hexl-backward-short (- arg)))
 434
 435 (defun hexl-backward-word (arg)
 436   "Move to left ARG words (right if ARG negative) in hexl-mode."
 437   (interactive "p")
 438   (hexl-goto-address (let ((address (hexl-current-address)))
 439                        (if (< arg 0)
 440                            (progn
 441                              (setq arg (- arg))
 442                              (while (> arg 0)
 443                                (if (not (equal address (logior address 7)))
 444                                    (if (> address hexl-max-address)
 445                                        (progn
 446                                          (message "End of buffer.")
 447                                          (setq address hexl-max-address))
 448                                      (setq address (logior address 7)))
 449                                  (if (> address hexl-max-address)
 450                                      (progn
 451                                        (message "End of buffer.")
 452                                        (setq address hexl-max-address))
 453                                    (setq address (+ address 8))))
 454                                (setq arg (1- arg)))
 455                              (if (> address hexl-max-address)
 456                                  (progn
 457                                    (message "End of buffer.")
 458                                    (setq address hexl-max-address))
 459                                (setq address (logior address 7))))
 460                          (while (> arg 0)
 461                            (if (not (equal address (logand address -8)))
 462                                (setq address (logand address -8))
 463                              (if (not (equal address 0))
 464                                  (setq address (- address 8))
 465                                (message "Beginning of buffer.")))
 466                            (setq arg (1- arg))))
 467                        address)))
 468
 469 (defun hexl-forward-word (arg)
 470   "Move right ARG words (left if ARG negative) in hexl-mode."
 471   (interactive "p")
 472   (hexl-backward-word (- arg)))
 473
 474 (defun hexl-previous-line (arg)
 475   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 476 If there is byte at the target address move to the last byte in that line."
 477   (interactive "p")
 478   (hexl-next-line (- arg)))
 479
 480 (defun hexl-next-line (arg)
 481   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 482 If there is no byte at the target address move to the last byte in that line."
 483   (interactive "p")
 484   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 485                        (if (and (< arg 0) (< address 0))
 486                                 (progn (message "Out of hexl region.")
 487                                        (setq address
 488                                              (% (hexl-current-address) 16)))
 489                          (if (and (> address hexl-max-address)
 490                                   (< (% hexl-max-address 16) (% address 16)))
 491                              (setq address hexl-max-address)
 492                            (if (> address hexl-max-address)
 493                                (progn (message "Out of hexl region.")
 494                                       (setq
 495                                        address
 496                                        (+ (logand hexl-max-address -16)
 497                                           (% (hexl-current-address) 16)))))))
 498                        address)))
 499
 500 (defun hexl-beginning-of-buffer (arg)
 501   "Move to the beginning of the hexl buffer.
 502 Leaves `hexl-mark' at previous position.
 503 With prefix arg N, puts point N bytes of the way from the true beginning."
 504   (interactive "p")
 505   (push-mark (point))
 506   (hexl-goto-address (+ 0 (1- arg))))
 507
 508 (defun hexl-end-of-buffer (arg)
 509   "Go to `hexl-max-address' minus ARG."
 510   (interactive "p")
 511   (push-mark (point))
 512   (hexl-goto-address (- hexl-max-address (1- arg))))
 513
 514 (defun hexl-beginning-of-line ()
 515   "Goto beginning of line in hexl mode."
 516   (interactive)
 517   (goto-char (+ (* (/ (point) 68) 68) 11)))
 518
 519 (defun hexl-end-of-line ()
 520   "Goto end of line in hexl mode."
 521   (interactive)
 522   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 523                        (if (> address hexl-max-address)
 524                            (setq address hexl-max-address))
 525                        address)))
 526
 527 (defun hexl-scroll-down (arg)
 528   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 529   (interactive "P")
 530   (if (null arg)
 531       (setq arg (1- (window-height)))
 532     (setq arg (prefix-numeric-value arg)))
 533   (hexl-scroll-up (- arg)))
 534
 535 (defun hexl-scroll-up (arg)
 536   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 537   (interactive "P")
 538   (if (null arg)
 539       (setq arg (1- (window-height)))
 540     (setq arg (prefix-numeric-value arg)))
 541   (let ((movement (* arg 16))
 542         (address (hexl-current-address)))
 543     (if (or (> (+ address movement) hexl-max-address)
 544             (< (+ address movement) 0))
 545         (message "Out of hexl region.")
 546       (hexl-goto-address (+ address movement))
 547       (recenter 0))))
 548
 549 (defun hexl-beginning-of-1k-page ()
 550   "Go to beginning of 1k boundary."
 551   (interactive)
 552   (hexl-goto-address (logand (hexl-current-address) -1024)))
 553
 554 (defun hexl-end-of-1k-page ()
 555   "Go to end of 1k boundary."
 556   (interactive)
 557   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 558                        (if (> address hexl-max-address)
 559                            (setq address hexl-max-address))
 560                        address)))
 561
 562 (defun hexl-beginning-of-512b-page ()
 563   "Go to beginning of 512 byte boundary."
 564   (interactive)
 565   (hexl-goto-address (logand (hexl-current-address) -512)))
 566
 567 (defun hexl-end-of-512b-page ()
 568   "Go to end of 512 byte boundary."
 569   (interactive)
 570   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 571                        (if (> address hexl-max-address)
 572                            (setq address hexl-max-address))
 573                        address)))
 574
 575 (defun hexl-quoted-insert (arg)
 576   "Read next input character and insert it.
 577 Useful for inserting control characters.
 578 You may also type up to 3 octal digits, to insert a character with that code"
 579   (interactive "p")
 580   (hexl-insert-char (read-quoted-char) arg))
 581
 582 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 583
 584 ;;;###autoload
 585 (defun hexlify-buffer ()
 586   "Convert a binary buffer to hexl format.
 587 This discards the buffer's undo information."
 588   (interactive)
 589   (and buffer-undo-list
 590        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 591            (error "Aborted")))
 592   (setq buffer-undo-list nil)
 593   (let ((binary-process-output nil) ; for Ms-Dos
 594         (binary-process-input buffer-file-type)
 595         ;; If the buffer was read with EOL conversions, be sure to use the
 596         ;; same conversions when passing the region to the `hexl' program.
 597         (coding-system-for-write
 598          (let ((eol-type (coding-system-eol-type buffer-file-coding-system)))
 599            (cond ((eq eol-type 1)
 600                   'raw-text-dos)
 601                  ((eq eol-type 2)
 602                   'raw-text-mac)
 603                  ((eq eol-type 0)
 604                   'raw-text-unix)
 605                  (t 'no-conversion))))
 606         (buffer-undo-list t))
 607     (shell-command-on-region (point-min) (point-max) hexlify-command t)))
 608
 609 (defun dehexlify-buffer ()
 610   "Convert a hexl format buffer to binary.
 611 This discards the buffer's undo information."
 612   (interactive)
 613   (and buffer-undo-list
 614        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 615            (error "Aborted")))
 616   (setq buffer-undo-list nil)
 617   (let ((binary-process-output buffer-file-type) ; for Ms-Dos
 618         (binary-process-input nil)
 619         (coding-system-for-read 'raw-text)
 620         (buffer-undo-list t))
 621     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 622
 623 (defun hexl-char-after-point ()
 624   "Return char for ASCII hex digits at point."
 625   (hexl-htoi (char-after (point))
 626              (char-after (1+ (point)))))
 627
 628 (defun hexl-htoi (lh rh)
 629   "Hex (char) LH (char) RH to integer."
 630     (+ (* (hexl-hex-char-to-integer lh) 16)
 631        (hexl-hex-char-to-integer rh)))
 632
 633 (defun hexl-hex-char-to-integer (character)
 634   "Take a char and return its value as if it was a hex digit."
 635   (if (and (>= character ?0) (<= character ?9))
 636       (- character ?0)
 637     (let ((ch (logior character 32)))
 638       (if (and (>= ch ?a) (<= ch ?f))
 639           (- ch (- ?a 10))
 640         (error "Invalid hex digit `%c'" ch)))))
 641
 642 (defun hexl-oct-char-to-integer (character)
 643   "Take a char and return its value as if it was a octal digit."
 644   (if (and (>= character ?0) (<= character ?7))
 645       (- character ?0)
 646     (error "Invalid octal digit `%c'" character)))
 647
 648 (defun hexl-printable-character (ch)
 649   "Return a displayable string for character CH."
 650   (format "%c" (if hexl-iso
 651                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 652                        46
 653                      ch)
 654                  (if (or (< ch 32) (>= ch 127))
 655                      46
 656                    ch))))
 657
 658 (defun hexl-self-insert-command (arg)
 659   "Insert this character."
 660   (interactive "p")
 661   (hexl-insert-char last-command-char arg))
 662
 663 (defun hexl-insert-char (ch num)
 664   "Insert a character in a hexl buffer."
 665   (let ((address (hexl-current-address t)))
 666     (while (> num 0)
 667       (let ((hex-position
 668              (+ (* (/ address 16) 68)
 669                 11
 670                 (* 2 (% address 16))
 671                 (/ (% address 16) 2)))
 672             (ascii-position
 673              (+ (* (/ address 16) 68) 52 (% address 16)))
 674             at-ascii-position)
 675         (if (= (point) ascii-position)
 676             (setq at-ascii-position t))
 677         (goto-char hex-position)
 678         (delete-char 2)
 679         (insert (format "%02x" ch))
 680         (goto-char ascii-position)
 681         (delete-char 1)
 682         (insert (hexl-printable-character ch))
 683         (or (eq address hexl-max-address)
 684             (setq address (1+ address)))
 685         (hexl-goto-address address)
 686         (if at-ascii-position
 687             (progn
 688               (beginning-of-line)
 689               (forward-char 51)
 690               (forward-char (% address 16)))))
 691       (setq num (1- num)))))
 692
 693 ;; hex conversion
 694
 695 (defun hexl-insert-hex-char (arg)
 696   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 697   (interactive "p")
 698   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 699     (if (or (> num 255) (< num 0))
 700         (error "Hex number out of range")
 701       (hexl-insert-char num arg))))
 702
 703 (defun hexl-insert-decimal-char (arg)
 704   "Insert a ASCII char ARG times at point for a given decimal number."
 705   (interactive "p")
 706   (let ((num (string-to-int (read-string "Decimal Number: "))))
 707     (if (or (> num 255) (< num 0))
 708         (error "Decimal number out of range")
 709       (hexl-insert-char num arg))))
 710
 711 (defun hexl-insert-octal-char (arg)
 712   "Insert a ASCII char ARG times at point for a given octal number."
 713   (interactive "p")
 714   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 715     (if (or (> num 255) (< num 0))
 716         (error "Decimal number out of range")
 717       (hexl-insert-char num arg))))
 718
 719 (defun hexl-follow-ascii (&optional arg)
 720   "Toggle following ASCII in Hexl buffers.
 721 With prefix ARG, turn on following if and only if ARG is positive.
 722 When following is enabled, the ASCII character corresponding to the
 723 element under the point is highlighted.
 724 Customize the variable `hexl-follow-ascii' to disable this feature."
 725   (interactive "P")
 726   (let ((on-p (if arg
 727                   (> (prefix-numeric-value arg) 0)
 728                (not hexl-ascii-overlay))))
 729
 730     (make-local-hook 'post-command-hook)
 731
 732     (if on-p
 733       ;; turn it on
 734       (if (not hexl-ascii-overlay)
 735           (progn
 736             (setq hexl-ascii-overlay (make-overlay 1 1)
 737                   hexl-follow-ascii t)
 738             (overlay-put hexl-ascii-overlay 'face 'highlight)
 739             (add-hook 'post-command-hook 'hexl-follow-ascii-find nil t)))
 740       ;; turn it off
 741       (if hexl-ascii-overlay
 742           (progn
 743             (delete-overlay hexl-ascii-overlay)
 744             (setq hexl-ascii-overlay nil
 745                   hexl-follow-ascii nil)
 746             (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 747             )))))
 748
 749 (defun hexl-follow-ascii-find ()
 750   "Find and highlight the ASCII element corresponding to current point."
 751   (let ((pos (+ 51
 752                 (- (point) (current-column))
 753                 (mod (hexl-current-address) 16))))
 754     (move-overlay hexl-ascii-overlay pos (1+ pos))
 755     ))
 756
 757 ;; startup stuff.
 758
 759 (if hexl-mode-map
 760     nil
 761   (setq hexl-mode-map (make-sparse-keymap))
 762
 763   (define-key hexl-mode-map [left] 'hexl-backward-char)
 764   (define-key hexl-mode-map [right] 'hexl-forward-char)
 765   (define-key hexl-mode-map [up] 'hexl-previous-line)
 766   (define-key hexl-mode-map [down] 'hexl-next-line)
 767   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 768   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 769   (define-key hexl-mode-map [next] 'hexl-scroll-up)
 770   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
 771   (define-key hexl-mode-map [home] 'hexl-beginning-of-buffer)
 772   (define-key hexl-mode-map [deletechar] 'undefined)
 773   (define-key hexl-mode-map [deleteline] 'undefined)
 774   (define-key hexl-mode-map [insertline] 'undefined)
 775   (define-key hexl-mode-map [S-delete] 'undefined)
 776   (define-key hexl-mode-map "\177" 'undefined)
 777
 778   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 779   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 780   (define-key hexl-mode-map "\C-d" 'undefined)
 781   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 782   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 783
 784   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 785       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 786
 787   (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 788   (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 789   (define-key hexl-mode-map "\C-k" 'undefined)
 790   (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 791   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 792   (define-key hexl-mode-map "\C-o" 'undefined)
 793   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 794   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 795   (define-key hexl-mode-map "\C-t" 'undefined)
 796   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 797   (define-key hexl-mode-map "\C-w" 'undefined)
 798   (define-key hexl-mode-map "\C-y" 'undefined)
 799
 800   (let ((ch 32))
 801     (while (< ch 127)
 802       (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 803       (setq ch (1+ ch))))
 804
 805   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 806   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 807   (define-key hexl-mode-map "\e\C-c" 'undefined)
 808   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 809   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 810   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 811   (define-key hexl-mode-map "\e\C-g" 'undefined)
 812   (define-key hexl-mode-map "\e\C-h" 'undefined)
 813   (define-key hexl-mode-map "\e\C-i" 'undefined)
 814   (define-key hexl-mode-map "\e\C-j" 'undefined)
 815   (define-key hexl-mode-map "\e\C-k" 'undefined)
 816   (define-key hexl-mode-map "\e\C-l" 'undefined)
 817   (define-key hexl-mode-map "\e\C-m" 'undefined)
 818   (define-key hexl-mode-map "\e\C-n" 'undefined)
 819   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 820   (define-key hexl-mode-map "\e\C-p" 'undefined)
 821   (define-key hexl-mode-map "\e\C-q" 'undefined)
 822   (define-key hexl-mode-map "\e\C-r" 'undefined)
 823   (define-key hexl-mode-map "\e\C-s" 'undefined)
 824   (define-key hexl-mode-map "\e\C-t" 'undefined)
 825   (define-key hexl-mode-map "\e\C-u" 'undefined)
 826
 827   (define-key hexl-mode-map "\e\C-w" 'undefined)
 828   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 829   (define-key hexl-mode-map "\e\C-y" 'undefined)
 830
 831   (define-key hexl-mode-map "\ea" 'undefined)
 832   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 833   (define-key hexl-mode-map "\ec" 'undefined)
 834   (define-key hexl-mode-map "\ed" 'undefined)
 835   (define-key hexl-mode-map "\ee" 'undefined)
 836   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 837   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 838   (define-key hexl-mode-map "\eh" 'undefined)
 839   (define-key hexl-mode-map "\ei" 'undefined)
 840   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 841   (define-key hexl-mode-map "\ek" 'undefined)
 842   (define-key hexl-mode-map "\el" 'undefined)
 843   (define-key hexl-mode-map "\em" 'undefined)
 844   (define-key hexl-mode-map "\en" 'undefined)
 845   (define-key hexl-mode-map "\eo" 'undefined)
 846   (define-key hexl-mode-map "\ep" 'undefined)
 847   (define-key hexl-mode-map "\eq" 'undefined)
 848   (define-key hexl-mode-map "\er" 'undefined)
 849   (define-key hexl-mode-map "\es" 'undefined)
 850   (define-key hexl-mode-map "\et" 'undefined)
 851   (define-key hexl-mode-map "\eu" 'undefined)
 852   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 853   (define-key hexl-mode-map "\ey" 'undefined)
 854   (define-key hexl-mode-map "\ez" 'undefined)
 855   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 856   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 857
 858   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 859
 860   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 861   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 862   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 863   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 864   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 865
 866 (provide 'hexl)
 867
 868 ;;; hexl.el ends here