lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions files
   9
  10 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
  11 ;;   2005 Free Software Foundation, Inc.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  33 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  34 ;; been removed or renamed in order to work properly with dired of GNU
  35 ;; Emacs.  All suggestions or comments are most welcomed.
  36
  37 ;;
  38 ;; Please, PLEASE, *PLEASE* see the info pages.
  39 ;;
  40
  41 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  42
  43 ;; INSTALLATION: In your ~/.emacs,
  44 ;;
  45 ;; (add-hook 'dired-load-hook
  46 ;;           (function (lambda ()
  47 ;;                       (load "dired-x")
  48 ;;                       ;; Set global variables here.  For example:
  49 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  50 ;;                       )))
  51 ;; (add-hook 'dired-mode-hook
  52 ;;           (function (lambda ()
  53 ;;                       ;; Set buffer-local variables here.  For example:
  54 ;;                       ;; (dired-omit-mode 1)
  55 ;;                       )))
  56 ;;
  57 ;; At load time dired-x.el will install itself, redefine some functions, and
  58 ;; bind some dired keys.  *Please* see the info pages for more details.
  59
  60 ;; *Please* see the info pages for more details.
  61
  62 ;; User defined variables:
  63 ;;
  64 ;;      dired-bind-vm
  65 ;;      dired-vm-read-only-folders
  66 ;;      dired-bind-jump
  67 ;;      dired-bind-info
  68 ;;      dired-bind-man
  69 ;;      dired-x-hands-off-my-keys
  70 ;;      dired-find-subdir
  71 ;;      dired-enable-local-variables
  72 ;;      dired-local-variables-file
  73 ;;      dired-guess-shell-gnutar
  74 ;;      dired-guess-shell-gzip-quiet
  75 ;;      dired-guess-shell-znew-switches
  76 ;;      dired-guess-shell-alist-user
  77 ;;      dired-clean-up-buffers-too
  78 ;;      dired-omit-mode
  79 ;;      dired-omit-files
  80 ;;      dired-omit-extensions
  81 ;;      dired-omit-size-limit
  82 ;;
  83 ;; To find out more about these variables, load this file, put your cursor at
  84 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  85 ;; the info pages for more details.
  86
  87 ;; When loaded this code redefines the following functions of GNU Emacs
  88 ;;
  89 ;;   Function                         Found in this file of GNU Emacs
  90 ;;   --------                         -------------------------------
  91 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  92 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  93 ;;   dired-initial-position           ../lisp/dired.el
  94 ;;
  95 ;;   dired-add-entry                  ../lisp/dired-aux.el
  96 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  97
  98 \f
  99 ;;; Code:
 100
 101 ;; LOAD.
 102
 103 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 104 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 105 ;; (instead of autoloading to dired as is suggested in the info-pages).
 106
 107 (require 'dired)
 108
 109 ;; We will redefine some functions and also need some macros so we need to
 110 ;; load dired stuff of GNU Emacs.
 111
 112 (require 'dired-aux)
 113
 114 (defvar vm-folder-directory)
 115
 116 ;;; User-defined variables.
 117
 118 (defgroup dired-x nil
 119   "Extended directory editing (dired-x)."
 120   :group 'dired)
 121
 122 (defgroup dired-keys nil
 123   "Dired keys customizations."
 124   :prefix "dired-"
 125   :group 'dired-x)
 126
 127 (defcustom dired-bind-vm nil
 128   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 129 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 130 `dired-advertised-find-file', will run rmail."
 131   :type 'boolean
 132   :group 'dired-keys)
 133
 134 (defcustom dired-bind-jump t
 135   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 136   :type 'boolean
 137   :group 'dired-keys)
 138
 139 (defcustom dired-bind-man t
 140   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 141   :type 'boolean
 142   :group 'dired-keys)
 143
 144 (defcustom dired-bind-info t
 145   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 146   :type 'boolean
 147   :group 'dired-keys)
 148
 149 (defcustom dired-vm-read-only-folders nil
 150   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 151 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 152 files not writable by you are visited read-only.
 153
 154 Read-only folders only work in VM 5, not in VM 4."
 155   :type '(choice (const :tag "off" nil)
 156                  (const :tag "on" t)
 157                  (other :tag "non-writable only" if-file-read-only))
 158   :group 'dired-x)
 159
 160 (define-minor-mode dired-omit-mode
 161   "Toggle Dired-Omit mode.
 162 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 163 otherwise.  Enabling and disabling is buffer-local.
 164 If enabled, \"uninteresting\" files are not listed.
 165 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 166 plus those ending with extensions in `dired-omit-extensions'."
 167   :group 'dired-x
 168   (if dired-omit-mode
 169       ;; This will mention how many lines were omitted:
 170       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 171     (revert-buffer)))
 172
 173 ;; For backward compatibility
 174 (defvaralias 'dired-omit-files-p 'dired-omit-mode)
 175 (make-obsolete-variable 'dired-omit-files-p 'dired-omit-mode)
 176
 177 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 178   "*Filenames matching this regexp will not be displayed.
 179 This only has effect when `dired-omit-mode' is t.  See interactive function
 180 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 181 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 182 files and lock files."
 183   :type 'regexp
 184   :group 'dired-x)
 185
 186 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 187   "*If non-nil, Dired always finds a directory in a buffer of its own.
 188 If nil, Dired finds the directory as a subdirectory in some other buffer
 189 if it is present as one.
 190
 191 If there are several dired buffers for a directory, the most recently
 192 used is chosen.
 193
 194 Dired avoids switching to the current buffer, so that if you have
 195 a normal and a wildcard buffer for the same directory, \\[dired] will
 196 toggle between those two."
 197   :type 'boolean
 198   :group 'dired-x)
 199
 200 (defcustom dired-omit-size-limit 30000
 201   "*Maximum size for the \"omitting\" feature.
 202 If nil, there is no maximum size."
 203   :type '(choice (const :tag "no maximum" nil) integer)
 204   :group 'dired-x)
 205
 206 (defcustom dired-enable-local-variables t
 207   "*Control use of local-variables lists in Dired.
 208 The value can be t, nil or something else.
 209 A value of t means local-variables lists are obeyed;
 210 nil means they are ignored; anything else means query.
 211
 212 This temporarily overrides the value of `enable-local-variables' when listing
 213 a directory.  See also `dired-local-variables-file'."
 214   :type 'boolean
 215   :group 'dired-x)
 216
 217 (defcustom dired-guess-shell-gnutar nil
 218   "*If non-nil, name of GNU tar executable.
 219 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 220 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 221 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 222   :type '(choice (const :tag "Not GNU tar" nil)
 223                  (string :tag "Command name"))
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-gzip-quiet t
 227   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 228   :type 'boolean
 229   :group 'dired-x)
 230
 231 (defcustom dired-guess-shell-znew-switches nil
 232   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 233   :type '(choice (const :tag "None" nil)
 234                  (string :tag "Switches"))
 235   :group 'dired-x)
 236
 237 (defcustom dired-clean-up-buffers-too t
 238   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 239   :type 'boolean
 240   :group 'dired-x)
 241
 242 ;;; KEY BINDINGS.
 243
 244 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 245 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 246 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 247 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 248 (define-key dired-mode-map "*." 'dired-mark-extension)
 249 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 250 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 251 (define-key dired-mode-map "\M-g" 'dired-goto-file)
 252 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 253 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 254 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 255 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 256 (define-key dired-mode-map "V" 'dired-do-run-mail)
 257
 258 (if dired-bind-man
 259     (define-key dired-mode-map "N" 'dired-man))
 260
 261 (if dired-bind-info
 262     (define-key dired-mode-map "I" 'dired-info))
 263
 264 ;;; MENU BINDINGS
 265
 266 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 267   (let ((menu (lookup-key menu-bar [operate])))
 268     (define-key-after
 269       menu
 270       [find-files]
 271       '(menu-item
 272         "Find files"
 273         dired-do-find-marked-files
 274         :help "Find current or marked files")
 275       'delete)
 276     (define-key-after
 277       menu
 278       [relsymlink]
 279       '(menu-item
 280         "Relative symlink to..."
 281         dired-do-relsymlink
 282         :visible (fboundp 'make-symbolic-link)
 283         :help "Make relative symbolic links for current or marked files")
 284       'symlink))
 285   (let ((menu (lookup-key menu-bar [mark])))
 286     (define-key-after
 287       menu
 288       [flag-extension]
 289       '(menu-item
 290         "Flag extension..."
 291         dired-flag-extension
 292         :help "Flag files with a certain extension for deletion")
 293       'garbage-files)
 294     (define-key-after
 295       menu
 296       [mark-extension]
 297       '(menu-item
 298         "Mark extension..."
 299         dired-mark-extension
 300         :help "Mark files with a certain extension")
 301       'symlinks)
 302     (define-key-after
 303       menu
 304       [mark-omitted]
 305       '(menu-item
 306         "Mark omitted"
 307         dired-mark-omitted
 308         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 309       'mark-extension))
 310   (let ((menu (lookup-key menu-bar [regexp])))
 311     (define-key-after
 312       menu
 313       [relsymlink-regexp]
 314       '(menu-item
 315         "Relative symlink..."
 316         dired-do-relsymlink-regexp
 317         :visible (fboundp 'make-symbolic-link)
 318         :help "Make relative symbolic links for files matching regexp")
 319       'symlink))
 320   (let ((menu (lookup-key menu-bar [immediate])))
 321     (define-key-after
 322       menu
 323       [omit-mode]
 324       '(menu-item
 325         "Omit mode" dired-omit-mode
 326         :button (:toggle . dired-omit-mode)
 327         :help "Enable or disable omitting \"uninteresting\" files")
 328       'dashes)))
 329
 330 ;;; GLOBAL BINDING.
 331 (if dired-bind-jump
 332     (progn
 333       (define-key global-map "\C-x\C-j" 'dired-jump)
 334       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 335
 336 \f
 337 ;;; Install into appropriate hooks.
 338
 339 (add-hook 'dired-mode-hook 'dired-extra-startup)
 340 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 341
 342 (defun dired-extra-startup ()
 343   "Automatically put on `dired-mode-hook' to get extra Dired features:
 344 \\<dired-mode-map>
 345   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 346   \\[dired-info]\t-- run info on file
 347   \\[dired-man]\t-- run man on file
 348   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 349   \\[dired-omit-mode]\t-- toggle omitting of files
 350   \\[dired-mark-sexp]\t-- mark by Lisp expression
 351   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 352   \t   you can feed it to other commands using \\[yank]
 353
 354 For more features, see variables
 355
 356   `dired-bind-vm'
 357   `dired-bind-jump'
 358   `dired-bind-info'
 359   `dired-bind-man'
 360   `dired-vm-read-only-folders'
 361   `dired-omit-mode'
 362   `dired-omit-files'
 363   `dired-omit-extensions'
 364   `dired-omit-size-limit'
 365   `dired-find-subdir'
 366   `dired-enable-local-variables'
 367   `dired-local-variables-file'
 368   `dired-guess-shell-gnutar'
 369   `dired-guess-shell-gzip-quiet'
 370   `dired-guess-shell-znew-switches'
 371   `dired-guess-shell-alist-user'
 372   `dired-clean-up-buffers-too'
 373
 374 See also functions
 375
 376   `dired-flag-extension'
 377   `dired-virtual'
 378   `dired-jump'
 379   `dired-man'
 380   `dired-vm'
 381   `dired-rmail'
 382   `dired-info'
 383   `dired-do-find-marked-files'"
 384   (interactive)
 385
 386   ;; These must be done in each new dired buffer.
 387   (dired-hack-local-variables)
 388   (dired-omit-startup))
 389
 390 \f
 391 ;;; BUFFER CLEANING.
 392
 393 ;; REDEFINE.
 394 (defun dired-clean-up-after-deletion (fn)
 395   "Clean up after a deleted file or directory FN.
 396 Remove expanded subdir of deleted dir, if any."
 397   (save-excursion (and (cdr dired-subdir-alist)
 398                        (dired-goto-subdir fn)
 399                        (dired-kill-subdir)))
 400
 401   ;; Offer to kill buffer of deleted file FN.
 402   (if dired-clean-up-buffers-too
 403       (progn
 404         (let ((buf (get-file-buffer fn)))
 405           (and buf
 406                (funcall (function y-or-n-p)
 407                         (format "Kill buffer of %s, too? "
 408                                 (file-name-nondirectory fn)))
 409                (save-excursion ; you never know where kill-buffer leaves you
 410                  (kill-buffer buf))))
 411         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 412               (buf nil))
 413           (and buf-list
 414                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 415                                  (dired-plural-s (length buf-list))
 416                                  (file-name-nondirectory fn)))
 417                (while buf-list
 418                  (save-excursion (kill-buffer (car buf-list)))
 419                  (setq buf-list (cdr buf-list)))))))
 420   ;; Anything else?
 421   )
 422
 423 \f
 424 ;;; EXTENSION MARKING FUNCTIONS.
 425
 426 ;;; Mark files with some extension.
 427 (defun dired-mark-extension (extension &optional marker-char)
 428   "Mark all files with a certain EXTENSION for use in later commands.
 429 A `.' is *not* automatically prepended to the string entered."
 430   ;; EXTENSION may also be a list of extensions instead of a single one.
 431   ;; Optional MARKER-CHAR is marker to use.
 432   (interactive "sMarking extension: \nP")
 433   (or (listp extension)
 434       (setq extension (list extension)))
 435   (dired-mark-files-regexp
 436    (concat ".";; don't match names with nothing but an extension
 437            "\\("
 438            (mapconcat 'regexp-quote extension "\\|")
 439            "\\)$")
 440    marker-char))
 441
 442 (defun dired-flag-extension (extension)
 443   "In dired, flag all files with a certain EXTENSION for deletion.
 444 A `.' is *not* automatically prepended to the string entered."
 445   (interactive "sFlagging extension: ")
 446   (dired-mark-extension extension dired-del-marker))
 447
 448 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 449
 450 (defvar dired-patch-unclean-extensions
 451   '(".rej" ".orig")
 452   "List of extensions of dispensable files created by the `patch' program.")
 453
 454 (defvar dired-tex-unclean-extensions
 455   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 456   "List of extensions of dispensable files created by TeX.")
 457
 458 (defvar dired-latex-unclean-extensions
 459   '(".idx" ".lof" ".lot" ".glo")
 460   "List of extensions of dispensable files created by LaTeX.")
 461
 462 (defvar dired-bibtex-unclean-extensions
 463   '(".blg" ".bbl")
 464   "List of extensions of dispensable files created by BibTeX.")
 465
 466 (defvar dired-texinfo-unclean-extensions
 467   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 468     ".tp" ".tps" ".vr" ".vrs")
 469   "List of extensions of dispensable files created by texinfo.")
 470
 471 (defun dired-clean-patch ()
 472   "Flag dispensable files created by patch for deletion.
 473 See variable `dired-patch-unclean-extensions'."
 474   (interactive)
 475   (dired-flag-extension dired-patch-unclean-extensions))
 476
 477 (defun dired-clean-tex ()
 478   "Flag dispensable files created by [La]TeX etc. for deletion.
 479 See variables `dired-tex-unclean-extensions',
 480 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 481 `dired-texinfo-unclean-extensions'."
 482   (interactive)
 483   (dired-flag-extension (append dired-texinfo-unclean-extensions
 484                                 dired-latex-unclean-extensions
 485                                 dired-bibtex-unclean-extensions
 486                                 dired-tex-unclean-extensions)))
 487
 488 (defun dired-very-clean-tex ()
 489   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 490 See variables `dired-texinfo-unclean-extensions',
 491 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 492 `dired-texinfo-unclean-extensions'."
 493   (interactive)
 494   (dired-flag-extension (append dired-texinfo-unclean-extensions
 495                                 dired-latex-unclean-extensions
 496                                 dired-bibtex-unclean-extensions
 497                                 dired-tex-unclean-extensions
 498                                 (list ".dvi"))))
 499 \f
 500 ;;; JUMP.
 501
 502 ;;;###autoload
 503 (defun dired-jump (&optional other-window)
 504   "Jump to dired buffer corresponding to current buffer.
 505 If in a file, dired the current directory and move to file's line.
 506 If in Dired already, pop up a level and goto old directory's line.
 507 In case the proper dired file line cannot be found, refresh the dired
 508 buffer and try again."
 509   (interactive "P")
 510   (let* ((file buffer-file-name)
 511          (dir (if file (file-name-directory file) default-directory)))
 512     (if (eq major-mode 'dired-mode)
 513         (progn
 514           (setq dir (dired-current-directory))
 515           (dired-up-directory other-window)
 516           (or (dired-goto-file dir)
 517               ;; refresh and try again
 518               (progn
 519                 (dired-insert-subdir (file-name-directory dir))
 520                 (dired-goto-file dir))))
 521       (if other-window
 522           (dired-other-window dir)
 523         (dired dir))
 524       (if file
 525           (or (dired-goto-file file)
 526               ;; refresh and try again
 527               (progn
 528                 (dired-insert-subdir (file-name-directory file))
 529                 (dired-goto-file file))
 530               ;; Toggle omitting, if it is on, and try again.
 531               (if dired-omit-mode
 532                   (progn
 533                     (dired-omit-mode)
 534                     (dired-goto-file file))))))))
 535
 536 (defun dired-jump-other-window ()
 537   "Like \\[dired-jump] (`dired-jump') but in other window."
 538   (interactive)
 539   (dired-jump t))
 540 \f
 541 ;;; OMITTING.
 542
 543 ;;; Enhanced omitting of lines from directory listings.
 544 ;;; Marked files are never omitted.
 545
 546 ;; should probably get rid of this and always use 'no-dir.
 547 ;; sk 28-Aug-1991 09:37
 548 (defvar dired-omit-localp 'no-dir
 549   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 550 If it is `no-dir', omitting is much faster, but you can only match
 551 against the non-directory part of the file name.  Set it to nil if you
 552 need to match the entire file name.")
 553
 554 ;; \017=^O for Omit - other packages can chose other control characters.
 555 (defvar dired-omit-marker-char ?\017
 556   "Temporary marker used by dired-omit.
 557 Should never be used as marker by the user or other packages.")
 558
 559 (defun dired-omit-startup ()
 560   (or (assq 'dired-omit-mode minor-mode-alist)
 561       (setq minor-mode-alist
 562             (append '((dired-omit-mode
 563                        (:eval (if (eq major-mode 'dired-mode)
 564                                   " Omit" ""))))
 565                     minor-mode-alist))))
 566
 567 (defun dired-mark-omitted ()
 568   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 569   (interactive)
 570   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 571   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 572
 573 (defvar dired-omit-extensions
 574   (append completion-ignored-extensions
 575           dired-latex-unclean-extensions
 576           dired-bibtex-unclean-extensions
 577           dired-texinfo-unclean-extensions)
 578   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 579 Defaults to elements of `completion-ignored-extensions',
 580 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 581 `dired-texinfo-unclean-extensions'.
 582
 583 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 584 variables `dired-omit-mode' and `dired-omit-files'.")
 585
 586 (defun dired-omit-expunge (&optional regexp)
 587   "Erases all unmarked files matching REGEXP.
 588 Does nothing if global variable `dired-omit-mode' is nil, or if called
 589   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 590 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 591   filenames ending in `dired-omit-extensions'.
 592 If REGEXP is the empty string, this function is a no-op.
 593
 594 This functions works by temporarily binding `dired-marker-char' to
 595 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 596   (interactive "sOmit files (regexp): ")
 597   (if (and dired-omit-mode
 598            (or (interactive-p)
 599                (not dired-omit-size-limit)
 600                (< (buffer-size) dired-omit-size-limit)
 601                (progn
 602                  (message "Not omitting: directory larger than %d characters."
 603                           dired-omit-size-limit)
 604                  (setq dired-omit-mode nil)
 605                  nil)))
 606       (let ((omit-re (or regexp (dired-omit-regexp)))
 607             (old-modified-p (buffer-modified-p))
 608             count)
 609         (or (string= omit-re "")
 610             (let ((dired-marker-char dired-omit-marker-char))
 611               (message "Omitting...")
 612               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 613                   (progn
 614                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 615                     (force-mode-line-update))
 616                 (message "(Nothing to omit)"))))
 617         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 618         ;; in mode-line of omitted buffers.
 619         (set-buffer-modified-p (and old-modified-p
 620                                     (save-excursion
 621                                       (goto-char (point-min))
 622                                       (re-search-forward dired-re-mark nil t))))
 623         count)))
 624
 625 (defun dired-omit-regexp ()
 626   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 627           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 628           (if dired-omit-extensions
 629               (concat ".";; a non-extension part should exist
 630                       "\\("
 631                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 632                       "\\)$")
 633             "")))
 634
 635 ;; Returns t if any work was done, nil otherwise.
 636 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 637   "Mark unmarked files matching REGEXP, displaying MSG.
 638 REGEXP is matched against the entire file name.
 639 Does not re-mark files which already have a mark.
 640 With prefix argument, unflag all those files.
 641 Optional fourth argument LOCALP is as in `dired-get-filename'."
 642   (interactive "P")
 643   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 644     (dired-mark-if
 645      (and
 646       ;; not already marked
 647       (looking-at " ")
 648       ;; uninteresting
 649       (let ((fn (dired-get-filename localp t)))
 650         (and fn (string-match regexp fn))))
 651      msg)))
 652
 653 ;;; REDEFINE.
 654 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 655   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 656   ;; files that are going to be omitted anyway.
 657   (if dired-omit-mode
 658       ;; perhaps return t without calling ls
 659       (let ((omit-re (dired-omit-regexp)))
 660         (if (or (string= omit-re "")
 661                 (not
 662                  (string-match omit-re
 663                                (cond
 664                                 ((eq 'no-dir dired-omit-localp)
 665                                  filename)
 666                                 ((eq t dired-omit-localp)
 667                                  (dired-make-relative filename))
 668                                 (t
 669                                  (dired-make-absolute
 670                                   filename
 671                                   (file-name-directory filename)))))))
 672             ;; if it didn't match, go ahead and add the entry
 673             (dired-omit-old-add-entry filename marker-char relative)
 674           ;; dired-add-entry returns t for success, perhaps we should
 675           ;; return file-exists-p
 676           t))
 677     ;; omitting is not turned on at all
 678     (dired-omit-old-add-entry filename marker-char relative)))
 679
 680 ;;; REDEFINE.
 681 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 682 ;;; Save old defun if not already done:
 683 (or (fboundp 'dired-omit-old-add-entry)
 684     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 685 ;; Redefine it.
 686 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 687
 688 \f
 689 ;;; VIRTUAL DIRED MODE.
 690
 691 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 692
 693 (defalias 'virtual-dired 'dired-virtual)
 694 (defun dired-virtual (dirname &optional switches)
 695   "Put this buffer into Virtual Dired mode.
 696
 697 In Virtual Dired mode, all commands that do not actually consult the
 698 filesystem will work.
 699
 700 This is useful if you want to peruse and move around in an ls -lR
 701 output file, for example one you got from an ftp server.  With
 702 ange-ftp, you can even dired a directory containing an ls-lR file,
 703 visit that file and turn on virtual dired mode.  But don't try to save
 704 this file, as dired-virtual indents the listing and thus changes the
 705 buffer.
 706
 707 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 708 resume it in a later session.
 709
 710 Type \\<dired-mode-map>\\[revert-buffer] \
 711 in the Virtual Dired buffer and answer `y' to convert
 712 the virtual to a real dired buffer again.  You don't have to do this, though:
 713 you can relist single subdirs using \\[dired-do-redisplay]."
 714
 715   ;; DIRNAME is the top level directory of the buffer.  It will become
 716   ;; its `default-directory'.  If nil, the old value of
 717   ;; default-directory is used.
 718
 719   ;; Optional SWITCHES are the ls switches to use.
 720
 721   ;; Shell wildcards will be used if there already is a `wildcard'
 722   ;; line in the buffer (thus it is a saved Dired buffer), but there
 723   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 724   ;; hand if you want them.
 725
 726   (interactive
 727    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 728   (goto-char (point-min))
 729   (or (looking-at "  ")
 730       ;; if not already indented, do it now:
 731       (indent-region (point-min) (point-max) 2))
 732   (or dirname (setq dirname default-directory))
 733   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 734   (setq default-directory dirname)      ; contains no wildcards
 735   (let ((wildcard (save-excursion
 736                     (goto-char (point-min))
 737                     (forward-line 1)
 738                     (and (looking-at "^  wildcard ")
 739                          (buffer-substring (match-end 0)
 740                                            (progn (end-of-line) (point)))))))
 741   (if wildcard
 742         (setq dirname (expand-file-name wildcard default-directory))))
 743   ;; If raw ls listing (not a saved old dired buffer), give it a
 744   ;; decent subdir headerline:
 745   (goto-char (point-min))
 746   (or (looking-at dired-subdir-regexp)
 747       (insert "  "
 748               (directory-file-name (file-name-directory default-directory))
 749               ":\n"))
 750   (dired-mode dirname (or switches dired-listing-switches))
 751   (setq mode-name "Virtual Dired"
 752         revert-buffer-function 'dired-virtual-revert)
 753   (set (make-local-variable 'dired-subdir-alist) nil)
 754   (dired-build-subdir-alist)
 755   (goto-char (point-min))
 756   (dired-initial-position dirname))
 757
 758 (defun dired-virtual-guess-dir ()
 759   "Guess and return appropriate working directory of this buffer.
 760 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 761 based upon buffer contents.  If nothing could be guessed, returns
 762 nil."
 763
 764   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 765         (subexpr 2))
 766     (goto-char (point-min))
 767     (cond ((looking-at regexp)
 768            ;; If a saved dired buffer, look to which dir and
 769            ;; perhaps wildcard it belongs:
 770            (let ((dir (buffer-substring (match-beginning subexpr)
 771                                         (match-end subexpr))))
 772              (file-name-as-directory dir)))
 773           ;; Else no match for headerline found.  It's a raw ls listing.
 774           ;; In raw ls listings the directory does not have a headerline
 775           ;; try parent of first subdir, if any
 776           ((re-search-forward regexp nil t)
 777            (file-name-directory
 778             (directory-file-name
 779              (file-name-as-directory
 780               (buffer-substring (match-beginning subexpr)
 781                                 (match-end subexpr))))))
 782           (t                            ; if all else fails
 783            nil))))
 784
 785
 786 (defun dired-virtual-revert (&optional arg noconfirm)
 787   (if (not
 788        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 789       (error "Cannot revert a Virtual Dired buffer")
 790     (setq mode-name "Dired"
 791           revert-buffer-function 'dired-revert)
 792     (revert-buffer)))
 793
 794 ;; A zero-arg version of dired-virtual.
 795 ;; You need my modified version of set-auto-mode for the
 796 ;; `buffer-contents-mode-alist'.
 797 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 798 (defun dired-virtual-mode ()
 799   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 800 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 801
 802     \"^  \\(/[^ /]+\\)/?+:$\"
 803
 804 to put saved dired buffers automatically into Virtual Dired mode.
 805
 806 Also useful for `auto-mode-alist' (which see) like this:
 807
 808   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 809                               auto-mode-alist)\)"
 810   (interactive)
 811   (dired-virtual (dired-virtual-guess-dir)))
 812
 813 \f
 814 ;;; SMART SHELL.
 815
 816 ;;; An Emacs buffer can have but one working directory, stored in the
 817 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 818 ;;; several subdirectories inserted, but still has but one working directory:
 819 ;;; that of the top level Dired directory in that buffer.  For some commands
 820 ;;; it is appropriate that they use the current Dired directory instead of
 821 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 822 ;;; mechanism is provided for special handling of the working directory in
 823 ;;; special major modes.
 824
 825 ;; It's easier to add to this alist than redefine function
 826 ;; default-directory while keeping the old information.
 827 (defconst default-directory-alist
 828   '((dired-mode . (if (fboundp 'dired-current-directory)
 829                       (dired-current-directory)
 830                     default-directory)))
 831   "Alist of major modes and their opinion on `default-directory'.
 832 This is given as a Lisp expression to evaluate.  A resulting value of
 833 nil is ignored in favor of `default-directory'.")
 834
 835 (defun dired-default-directory ()
 836   "Usage like variable `default-directory'.
 837 Knows about the special cases in variable `default-directory-alist'."
 838   (or (eval (cdr (assq major-mode default-directory-alist)))
 839       default-directory))
 840
 841 (defun dired-smart-shell-command (cmd &optional insert)
 842   "Like function `shell-command', but in the current Virtual Dired directory."
 843   (interactive (list (read-from-minibuffer "Shell command: "
 844                                            nil nil nil 'shell-command-history)
 845                      current-prefix-arg))
 846   (let ((default-directory (dired-default-directory)))
 847     (shell-command cmd insert)))
 848
 849 \f
 850 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 851
 852 ;;; Brief Description:
 853 ;;;
 854 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 855 ;;;
 856 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 857 ;;;
 858 ;;; * `dired-hack-local-variables' checks the value of
 859 ;;;   `dired-local-variables-file'
 860 ;;;
 861 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 862 ;;;   filename found in the directory of the Dired Buffer being created.
 863 ;;;
 864 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 865 ;;;   include it in the Dired Buffer at the bottom.
 866 ;;;
 867 ;;; * Set `enable-local-variables' temporarily to the user variable
 868 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 869 ;;;   Dired Buffer.
 870
 871 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 872   "Filename, as string, containing local dired buffer variables to be hacked.
 873 If this file found in current directory, then it will be inserted into dired
 874 buffer and `hack-local-variables' will be run.  See Info node
 875 `(emacs)File Variables' for more information on local variables.
 876 See also `dired-enable-local-variables'.")
 877
 878 (defun dired-hack-local-variables ()
 879   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 880   (if (and dired-local-variables-file
 881            (stringp dired-local-variables-file)
 882            (file-exists-p dired-local-variables-file))
 883       (let ((opoint (point-max))
 884             buffer-read-only
 885             ;; In case user has `enable-local-variables' set to nil we
 886             ;; override it locally with dired's variable.
 887             (enable-local-variables dired-enable-local-variables))
 888         ;; Insert 'em.
 889         (save-excursion
 890           (goto-char opoint)
 891           (insert "\^L\n")
 892           (insert-file-contents dired-local-variables-file))
 893         ;; Hack 'em.
 894         (let ((buffer-file-name dired-local-variables-file))
 895           (hack-local-variables))
 896         ;; Make sure that the modeline shows the proper information.
 897         (dired-sort-set-modeline)
 898         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 899         (delete-region opoint (point-max)))))
 900
 901 (defun dired-omit-here-always ()
 902   "Create `dired-local-variables-file' for omitting and reverts directory.
 903 Sets `dired-omit-mode' to t in a local variables file that is readable by
 904 dired."
 905   (interactive)
 906   (if (file-exists-p dired-local-variables-file)
 907       (message "File `./%s' already exists." dired-local-variables-file)
 908
 909     ;; Create `dired-local-variables-file'.
 910     (save-excursion
 911       (set-buffer (get-buffer-create " *dot-dired*"))
 912       (erase-buffer)
 913       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 914       (write-file dired-local-variables-file)
 915       (kill-buffer (current-buffer)))
 916
 917     ;; Run extra-hooks and revert directory.
 918     (dired-extra-startup)
 919     (dired-revert)))
 920
 921 \f
 922 ;;; GUESS SHELL COMMAND.
 923
 924 ;;; Brief Description:
 925 ;;;
 926 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 927 ;;;
 928 ;;; * Redefine `dired-do-shell-command' so it calls
 929 ;;;   `dired-guess-shell-command'.
 930 ;;;
 931 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 932 ;;;    marked files.
 933 ;;;
 934 ;;; * Parse `dired-guess-shell-alist-user' and
 935 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 936 ;;;   that matches the first file in the file list.
 937 ;;;
 938 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 939 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 940 ;;;   string.  COMMAND may be a list of commands.
 941 ;;;
 942 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 943 ;;;   with it.  The list of commands is temporarily put into the history list.
 944 ;;;   If a command is used successfully then it is stored permanently in
 945 ;;;   `dired-shell-command-history'.
 946
 947 ;;; Guess what shell command to apply to a file.
 948 (defvar dired-shell-command-history nil
 949   "History list for commands that read dired-shell commands.")
 950
 951 ;;; Default list of shell commands.
 952
 953 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 954 ;;; install GNU zip's version of zcat.
 955
 956 (defvar dired-guess-shell-alist-default
 957   (list
 958    (list "\\.tar$"
 959          '(if dired-guess-shell-gnutar
 960               (concat dired-guess-shell-gnutar " xvf")
 961             "tar xvf")
 962          ;; Extract files into a separate subdirectory
 963          '(if dired-guess-shell-gnutar
 964               (concat "mkdir " (file-name-sans-extension file)
 965                       "; " dired-guess-shell-gnutar " -C "
 966                       (file-name-sans-extension file) " -xvf")
 967             (concat "mkdir " (file-name-sans-extension file)
 968                     "; tar -C " (file-name-sans-extension file) " -xvf")))
 969
 970    ;; REGEXPS for compressed archives must come before the .Z rule to
 971    ;; be recognized:
 972    (list "\\.tar\\.Z$"
 973          ;; Untar it.
 974          '(if dired-guess-shell-gnutar
 975               (concat dired-guess-shell-gnutar " zxvf")
 976             (concat "zcat * | tar xvf -"))
 977          ;; Optional conversion to gzip format.
 978          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 979                   " " dired-guess-shell-znew-switches))
 980
 981    ;; gzip'ed archives
 982    (list "\\.t\\(ar\\.\\)?gz$"
 983          '(if dired-guess-shell-gnutar
 984               (concat dired-guess-shell-gnutar " zxvf")
 985             (concat "gunzip -qc * | tar xvf -"))
 986          ;; Extract files into a separate subdirectory
 987          '(if dired-guess-shell-gnutar
 988               (concat "mkdir " (file-name-sans-extension file)
 989                       "; " dired-guess-shell-gnutar " -C "
 990                       (file-name-sans-extension file) " -zxvf")
 991             (concat "mkdir " (file-name-sans-extension file)
 992                     "; gunzip -qc * | tar -C "
 993                     (file-name-sans-extension file) " -xvf -"))
 994          ;; Optional decompression.
 995          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")))
 996
 997    ;; bzip2'ed archives
 998    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
 999          "bunzip2 -c * | tar xvf -"
1000          ;; Extract files into a separate subdirectory
1001          '(concat "mkdir " (file-name-sans-extension file)
1002                   "; bunzip2 -c * | tar -C "
1003                   (file-name-sans-extension file) " -xvf -")
1004          ;; Optional decompression.
1005          "bunzip2")
1006
1007    '("\\.shar\\.Z$" "zcat * | unshar")
1008    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1009
1010    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1011    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1012          ;; Optional decompression.
1013          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1014    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1015          ;; Optional conversion to gzip format.
1016          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1017                   " " dired-guess-shell-znew-switches))
1018
1019    '("\\.patch$" "cat * | patch")
1020    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1021          ;; Optional decompression.
1022          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1023    (list "\\.patch\\.Z$" "zcat * | patch"
1024          ;; Optional conversion to gzip format.
1025          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1026                   " " dired-guess-shell-znew-switches))
1027
1028    ;; The following four extensions are useful with dired-man ("N" key)
1029    (list "\\.[0-9]$" '(progn (require 'man)
1030                              (if (Man-support-local-filenames)
1031                                  "man -l"
1032                                "cat * | tbl | nroff -man -h")))
1033    (list "\\.[0-9]\\.g?z$" '(progn (require 'man)
1034                                    (if (Man-support-local-filenames)
1035                                        "man -l"
1036                                      "gunzip -qc * | tbl | nroff -man -h"))
1037          ;; Optional decompression.
1038          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1039    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1040                                  (if (Man-support-local-filenames)
1041                                      "man -l"
1042                                    "zcat * | tbl | nroff -man -h"))
1043          ;; Optional conversion to gzip format.
1044          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1045                   " " dired-guess-shell-znew-switches))
1046    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1047
1048    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1049    '("\\.au$" "play")                   ; play Sun audiofiles
1050    '("\\.mpg$" "mpeg_play")
1051    '("\\.uu$" "uudecode")               ; for uudecoded files
1052    '("\\.hqx$" "mcvert")
1053    '("\\.sh$" "sh")                     ; execute shell scripts
1054    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1055    '("\\.gp$" "gnuplot")
1056    '("\\.p[bgpn]m$" "xloadimage")
1057    '("\\.gif$" "xloadimage")                    ; view gif pictures
1058    '("\\.tif$" "xloadimage")
1059    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1060    '("\\.jpe?g$" "xloadimage")
1061    '("\\.fig$" "xfig")                  ; edit fig pictures
1062    '("\\.out$" "xgraph")                ; for plotting purposes.
1063    '("\\.tex$" "latex" "tex")
1064    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1065    '("\\.pdf$" "xpdf")              ; edit PDF files
1066
1067    ;; Some other popular archivers.
1068    (list "\\.zip$" "unzip"
1069          ;; Extract files into a separate subdirectory
1070          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1071                   " -d " (file-name-sans-extension file)))
1072    '("\\.zoo$" "zoo x//")
1073    '("\\.lzh$" "lharc x")
1074    '("\\.arc$" "arc x")
1075    '("\\.shar$" "unshar")
1076
1077    ;; Compression.
1078    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1079    (list "\\.dz$" "dictunzip")
1080    (list "\\.bz2$" "bunzip2")
1081    (list "\\.Z$" "uncompress"
1082          ;; Optional conversion to gzip format.
1083          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1084                   " " dired-guess-shell-znew-switches))
1085    )
1086
1087   "Default alist used for shell command guessing.
1088 See `dired-guess-shell-alist-user'.")
1089
1090 (defcustom dired-guess-shell-alist-user nil
1091   "User-defined alist of rules for suggested commands.
1092 These rules take precedence over the predefined rules in the variable
1093 `dired-guess-shell-alist-default' (to which they are prepended).
1094
1095 Each element of this list looks like
1096
1097     \(REGEXP COMMAND...\)
1098
1099 where each COMMAND can either be a string or a Lisp expression that evaluates
1100 to a string.  If several COMMANDs are given, the first one will be the default
1101 and the rest will be added temporarily to the history and can be retrieved
1102 with \\[previous-history-element] (M-p) .
1103
1104 You can set this variable in your ~/.emacs.  For example, to add rules for
1105 `.foo' and `.bar' files, write
1106
1107  \(setq dired-guess-shell-alist-user
1108        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1109               ;; possibly more rules ...
1110               (list \"\\\\.bar\\\'\";; rule with condition test
1111                     '(if condition
1112                           \"BAR-COMMAND-1\"
1113                         \"BAR-COMMAND-2\")))\)"
1114   :group 'dired-x
1115   :type '(alist :key-type regexp :value-type (repeat sexp)))
1116
1117 (defcustom dired-guess-shell-case-fold-search t
1118   "If non-nil, `dired-guess-shell-alist-default' and
1119 `dired-guess-shell-alist-user' are matched case-insensitively."
1120   :group 'dired-x
1121   :type 'boolean)
1122
1123 (defun dired-guess-default (files)
1124   "Guess a shell commands for FILES.  Return command or list of commands.
1125 See `dired-guess-shell-alist-user'."
1126
1127   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1128          ;; Prepend the user's alist to the default alist.
1129          (alist (append dired-guess-shell-alist-user
1130                         dired-guess-shell-alist-default))
1131          (file (car files))
1132          (flist (cdr files))
1133          elt regexp cmds)
1134
1135     ;; Find the first match in the alist for first file in FILES.
1136     (while alist
1137       (setq elt (car alist)
1138             regexp (car elt)
1139             alist (cdr alist))
1140       (if (string-match regexp file)
1141           (setq cmds (cdr elt)
1142                 alist nil)))
1143
1144     ;; If more than one file, see if all of FILES match regular expression.
1145     (while (and flist
1146                 (string-match regexp (car flist)))
1147       (setq flist (cdr flist)))
1148
1149     ;; If flist is still non-nil, then do not guess since this means that not
1150     ;; all the files in FILES were matched by the regexp.
1151     (setq cmds (and (not flist) cmds))
1152
1153     ;; Return commands or nil if flist is still non-nil.
1154     ;; Evaluate the commands in order that any logical testing will be done.
1155     (cond ((not (cdr cmds))
1156            (eval (car cmds))) ; single command
1157           (t
1158            (mapcar (function eval) cmds)))))
1159
1160 (defun dired-guess-shell-command (prompt files)
1161   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1162
1163   (let ((default (dired-guess-default files))
1164         default-list old-history val (failed t))
1165
1166     (if (null default)
1167         ;; Nothing to guess
1168         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1169
1170       ;; Save current history list
1171       (setq old-history dired-shell-command-history)
1172
1173       (if (listp default)
1174
1175           ;; More than one guess
1176           (setq default-list default
1177                 default (car default)
1178                 prompt (concat
1179                         prompt
1180                         (format "{%d guesses} " (length default-list))))
1181
1182         ;; Just one guess
1183         (setq default-list (list default)))
1184
1185       ;; Push all guesses onto history so that they can be retrieved with M-p
1186       ;; and put the first guess in the prompt but not in the initial value.
1187       (setq dired-shell-command-history
1188             (append default-list dired-shell-command-history)
1189             prompt (concat prompt (format "[%s] " default)))
1190
1191       ;; The unwind-protect returns VAL, and we too.
1192       (unwind-protect
1193           ;; BODYFORM
1194           (progn
1195             (setq val (read-from-minibuffer prompt nil nil nil
1196                                             'dired-shell-command-history)
1197                   failed nil)
1198             ;; If we got a return, then use default.
1199             (if (equal val "")
1200                 (setq val default))
1201             val)
1202
1203         ;; UNWINDFORMS
1204         ;; Undo pushing onto the history list so that an aborted
1205         ;; command doesn't get the default in the next command.
1206         (setq dired-shell-command-history old-history)
1207         (if (not failed)
1208             (or (equal val (car-safe dired-shell-command-history))
1209                 (setq dired-shell-command-history
1210                       (cons val dired-shell-command-history))))))))
1211
1212
1213 ;;; REDEFINE.
1214 ;;; Redefine dired-aux.el's version:
1215 (defun dired-read-shell-command (prompt arg files)
1216   "Read a dired shell command prompting with PROMPT (using read-string).
1217 ARG is the prefix arg and may be used to indicate in the prompt which
1218   files are affected.
1219 This is an extra function so that you can redefine it."
1220   (dired-mark-pop-up
1221    nil 'shell files
1222    'dired-guess-shell-command
1223    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1224    files))                                       ; FILES
1225
1226 \f
1227 ;;; RELATIVE SYMBOLIC LINKS.
1228
1229 (defvar dired-keep-marker-relsymlink ?S
1230   "See variable `dired-keep-marker-move'.")
1231
1232 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1233   "Make a symbolic link (pointing to FILE1) in FILE2.
1234 The link is relative (if possible), for example
1235
1236     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1237
1238 results in
1239
1240     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1241   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1242   (let (name1 name2 len1 len2 (index 0) sub)
1243     (setq file1 (expand-file-name file1)
1244           file2 (expand-file-name file2)
1245           len1 (length file1)
1246           len2 (length file2))
1247     ;; Find common initial file name components:
1248     (let (next)
1249       (while (and (setq next (string-match "/" file1 index))
1250                   (setq next (1+ next))
1251                   (< next (min len1 len2))
1252                   ;; For the comparison, both substrings must end in
1253                   ;; `/', so NEXT is *one plus* the result of the
1254                   ;; string-match.
1255                   ;; E.g., consider the case of linking "/tmp/a/abc"
1256                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1257                   ;; of "/tmp/" as common initial component
1258                   (string-equal (substring file1 0 next)
1259                                 (substring file2 0 next)))
1260         (setq index next))
1261       (setq name2 file2
1262             sub (substring file1 0 index)
1263             name1 (substring file1 index)))
1264     (if (string-equal sub "/")
1265         ;; No common initial file name found
1266         (setq name1 file1)
1267       ;; Else they have a common parent directory
1268       (let ((tem (substring file2 index))
1269             (start 0)
1270             (count 0))
1271         ;; Count number of slashes we must compensate for ...
1272         (while (setq start (string-match "/" tem start))
1273           (setq count (1+ count)
1274                 start (1+ start)))
1275         ;; ... and prepend a "../" for each slash found:
1276         (while (> count 0)
1277           (setq count (1- count)
1278                 name1 (concat "../" name1)))))
1279     (make-symbolic-link
1280      (directory-file-name name1)        ; must not link to foo/
1281                                         ; (trailing slash!)
1282      name2 ok-if-already-exists)))
1283
1284 (defun dired-do-relsymlink (&optional arg)
1285    "Relative symlink all marked (or next ARG) files into a directory.
1286 Otherwise make a relative symbolic link to the current file.
1287 This creates relative symbolic links like
1288
1289     foo -> ../bar/foo
1290
1291 not absolute ones like
1292
1293     foo -> /ugly/file/name/that/may/change/any/day/bar/foo"
1294   (interactive "P")
1295   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1296                            "RelSymLink" arg dired-keep-marker-relsymlink))
1297
1298 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1299   "RelSymlink all marked files containing REGEXP to NEWNAME.
1300 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1301 for more info."
1302   (interactive (dired-mark-read-regexp "RelSymLink"))
1303   (dired-do-create-files-regexp
1304    (function dired-make-relative-symlink)
1305    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1306
1307 \f
1308 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1309
1310 ;;; Brief Description:
1311 ;;;
1312 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1313 ;;;
1314 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1315 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1316 ;;;
1317 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1318 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1319 ;;;
1320 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1321 ;;;   list each time.
1322 ;;;
1323 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1324 ;;;   element of FILE-LIST.
1325 ;;;
1326 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1327 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1328 ;;;   cognizant of the window-configuration.
1329 ;;;
1330 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1331 ;;;   of FILE-LIST giving each a window of height `size'.
1332
1333 (defun dired-do-find-marked-files (&optional noselect)
1334   "Find all marked files displaying all of them simultaneously.
1335 With optional NOSELECT just find files but do not select them.
1336
1337 The current window is split across all files marked, as evenly as possible.
1338 Remaining lines go to bottom-most window.  The number of files that can be
1339 displayed this way is restricted by the height of the current window and
1340 `window-min-height'.
1341
1342 To keep dired buffer displayed, type \\[split-window-vertically] first.
1343 To display just marked files, type \\[delete-other-windows] first."
1344
1345   (interactive "P")
1346   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1347
1348 (defun dired-simultaneous-find-file (file-list noselect)
1349
1350   "Visit all files in FILE-LIST and display them simultaneously.
1351 The current window is split across all files in FILE-LIST, as evenly as
1352 possible.  Remaining lines go to the bottom-most window.  The number of
1353 files that can be displayed this way is restricted by the height of the
1354 current window and the variable `window-min-height'.  With non-nil
1355 NOSELECT the files are merely found but not selected."
1356
1357   ;; We don't make this function interactive because it is usually too clumsy
1358   ;; to specify FILE-LIST interactively unless via dired.
1359
1360   (let (size)
1361
1362     (if noselect
1363         ;; Do not select the buffer.
1364         (find-file-noselect (car file-list))
1365
1366       ;; We will have to select the buffer.  Calculate and check window size.
1367       (setq size (/ (window-height) (length file-list)))
1368       (or (<= window-min-height size)
1369           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1370       (find-file (car file-list)))
1371
1372     ;; Decrement.
1373     (setq file-list (cdr file-list))
1374
1375     (while file-list
1376
1377       (if noselect
1378           ;; Do not select the buffer.
1379           (find-file-noselect (car file-list))
1380
1381         ;; Vertically split off a window of desired size.  Upper window will
1382         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1383         (select-window (split-window nil size))
1384         (find-file (car file-list)))
1385
1386       ;; Decrement.
1387       (setq file-list (cdr file-list)))))
1388
1389 \f
1390 ;;; MISCELLANEOUS COMMANDS.
1391
1392 ;;; Run man on files.
1393
1394 (defun dired-man ()
1395   "Run man on this file.  Display old buffer if buffer name matches filename.
1396 Uses `man.el' of \\[manual-entry] fame."
1397   (interactive)
1398   (require 'man)
1399   (let* ((file (dired-get-filename))
1400          (manual-program (replace-regexp-in-string "\\*" "%s"
1401                           (dired-guess-shell-command
1402                            "Man command: " (list file)))))
1403     (Man-getpage-in-background file)))
1404
1405 ;;; Run Info on files.
1406
1407 (defun dired-info ()
1408   "Run info on this file."
1409   (interactive)
1410   (info (dired-get-filename)))
1411
1412 ;;; Run mail on mail folders.
1413
1414 ;;; (and (not (fboundp 'vm-visit-folder))
1415 ;;;      (defun vm-visit-folder (file &optional arg)
1416 ;;;        nil))
1417
1418 (defun dired-vm (&optional read-only)
1419   "Run VM on this file.
1420 With prefix arg, visit folder read-only (this requires at least VM 5).
1421 See also variable `dired-vm-read-only-folders'."
1422   (interactive "P")
1423   (let ((dir (dired-current-directory))
1424         (fil (dired-get-filename)))
1425     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1426     (cond (read-only (vm-visit-folder fil t))
1427           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1428           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1429           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1430     ;; so that pressing `v' inside VM does prompt within current directory:
1431     (set (make-local-variable 'vm-folder-directory) dir)))
1432
1433 (defun dired-rmail ()
1434   "Run RMAIL on this file."
1435   (interactive)
1436   (rmail (dired-get-filename)))
1437
1438 (defun dired-do-run-mail ()
1439   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1440   (interactive)
1441   (if dired-bind-vm
1442       ;; Read mail folder using vm.
1443       (dired-vm)
1444     ;; Read mail folder using rmail.
1445     (dired-rmail)))
1446
1447 \f
1448 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1449
1450 (or (fboundp 'dired-old-find-buffer-nocreate)
1451     (fset 'dired-old-find-buffer-nocreate
1452           (symbol-function 'dired-find-buffer-nocreate)))
1453
1454 ;;; REDEFINE.
1455 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1456 (defun dired-find-buffer-nocreate (dirname &optional mode)
1457   (if (and dired-find-subdir
1458            ;; don't try to find a wildcard as a subdirectory
1459            (string-equal dirname (file-name-directory dirname)))
1460       (let* ((cur-buf (current-buffer))
1461              (buffers (nreverse
1462                        (dired-buffers-for-dir (expand-file-name dirname))))
1463              (cur-buf-matches (and (memq cur-buf buffers)
1464                                    ;; wildcards must match, too:
1465                                    (equal dired-directory dirname))))
1466         ;; We don't want to switch to the same buffer---
1467         (setq buffers (delq cur-buf buffers));;need setq with delq
1468         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1469             ;; ---unless it's the only possibility:
1470             (and cur-buf-matches cur-buf)))
1471     (dired-old-find-buffer-nocreate dirname mode)))
1472
1473 ;; This should be a builtin
1474 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1475   "Return t if BUFFER1 is more recently used than BUFFER2."
1476   (if (equal buffer1 buffer2)
1477       nil
1478     (let ((more-recent nil)
1479           (list (buffer-list)))
1480       (while (and list
1481                   (not (setq more-recent (equal buffer1 (car list))))
1482                   (not (equal buffer2 (car list))))
1483         (setq list (cdr list)))
1484       more-recent)))
1485
1486 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1487 ;;; (defun dired-buffers-for-dir-exact (dir)
1488 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1489 ;;; ;; at top level, or as subdirectory.
1490 ;;; ;; Top level matches must match the wildcard part too, if any.
1491 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1492 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1493 ;;; ;; dired-buffers.
1494 ;;;   (let ((alist dired-buffers) result elt)
1495 ;;;     (while alist
1496 ;;;       (setq elt (car alist)
1497 ;;;             alist (cdr alist))
1498 ;;;       (let ((buf (cdr elt)))
1499 ;;;         (if (buffer-name buf)
1500 ;;;             ;; Top level must match exactly against dired-directory in
1501 ;;;             ;; case one of them is a wildcard.
1502 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1503 ;;;                                                dired-directory))
1504 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1505 ;;;                                                dired-subdir-alist)))
1506 ;;;                 (setq result (cons buf result)))
1507 ;;;           ;; else buffer is killed - clean up:
1508 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1509 ;;;     result))
1510
1511 ;;; REDEFINE.
1512 ;;; Redefines dired.el's version of `dired-initial-position'
1513 (defun dired-initial-position (dirname)
1514   "Where point should go in a new listing of DIRNAME.
1515 Point assumed at beginning of new subdir line.
1516 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1517   (end-of-line)
1518   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1519   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1520
1521 \f
1522 ;; Does anyone use this? - lrd 6/29/93.
1523 ;; Apparently people do use it. - lrd 12/22/97.
1524 (defun dired-mark-sexp (predicate &optional unflag-p)
1525   "Mark files for which PREDICATE returns non-nil.
1526 With a prefix arg, unflag those files instead.
1527
1528 PREDICATE is a lisp expression that can refer to the following symbols:
1529
1530     inode  [integer] the inode of the file (only for ls -i output)
1531     s      [integer] the size of the file for ls -s output
1532                      (usually in blocks or, with -k, in KByte)
1533     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1534     nlink  [integer] number of links to file
1535     uid    [string]  owner
1536     gid    [string]  group  (If the gid is not displayed by ls,
1537                      this will still be set (to the same as uid))
1538     size   [integer] file size in bytes
1539     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1540     name   [string]  the name of the file
1541     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1542
1543 For example, use
1544
1545         (equal 0 size)
1546
1547 to mark all zero length files."
1548   ;; Using sym="" instead of nil avoids the trap of
1549   ;; (string-match "foo" sym) into which a user would soon fall.
1550   ;; Give `equal' instead of `=' in the example, as this works on
1551   ;; integers and strings.
1552   (interactive "xMark if (lisp expr): \nP")
1553   (message "%s" predicate)
1554   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1555         inode s mode nlink uid gid size time name sym)
1556     (dired-mark-if
1557      (save-excursion
1558        (and
1559         ;; Sets vars
1560         ;;                inode s mode nlink uid gid size time name sym
1561
1562         ;; according to current file line.  Returns t for success, nil if
1563         ;; there is no file line.  Upon success, all variables are set, either
1564         ;; to nil or the appropriate value, so they need not be initialized.
1565         ;; Moves point within the current line.
1566         (if (dired-move-to-filename)
1567             (let (pos
1568                   (mode-len 10) ; length of mode string
1569                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1570                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1571               (beginning-of-line)
1572               (forward-char 2)
1573               (if (looking-at dired-re-inode-size)
1574                   (progn
1575                     (goto-char (match-end 0))
1576                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1577                                                                     (match-end 1)))
1578                           s (string-to-number (buffer-substring (match-beginning 2)
1579                                                                 (match-end 2)))))
1580                 (setq inode nil
1581                       s nil))
1582               (setq mode (buffer-substring (point) (+ mode-len (point))))
1583               (forward-char mode-len)
1584               (setq nlink (read (current-buffer)))
1585               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1586               (setq uid (buffer-substring (+ (point) 1)
1587                                           (progn (forward-word 1) (point))))
1588               (re-search-forward directory-listing-before-filename-regexp)
1589               (goto-char (match-beginning 1))
1590               (forward-char -1)
1591               (setq size (string-to-number (buffer-substring (save-excursion
1592                                                                (backward-word 1)
1593                                                                (setq pos (point)))
1594                                                              (point))))
1595               (goto-char pos)
1596               (backward-word 1)
1597               ;; if no gid is displayed, gid will be set to uid
1598               ;; but user will then not reference it anyway in PREDICATE.
1599               (setq gid (buffer-substring (save-excursion
1600                                             (forward-word 1) (point))
1601                                           (point))
1602                     time (buffer-substring (match-beginning 1)
1603                                            (1- (dired-move-to-filename)))
1604                     name (buffer-substring (point)
1605                                            (or
1606                                             (dired-move-to-end-of-filename t)
1607                                             (point)))
1608                     sym  (progn
1609                            (if (looking-at " -> ")
1610                                (buffer-substring
1611                                 (progn (forward-char 4) (point))
1612                                 (progn (end-of-line) (point)))
1613                              "")))
1614               t)
1615           nil)
1616                       (eval predicate)))
1617      (format "'%s file" predicate))))
1618
1619 \f
1620 ;;; FIND FILE AT POINT.
1621
1622 (defvar dired-x-hands-off-my-keys t
1623   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1624 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1625 If you change this variable after `dired-x.el' is loaded then do
1626 \\[dired-x-bind-find-file].")
1627
1628 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1629 ;;; `find-file{-other-window}' is bound?
1630 (defun dired-x-bind-find-file ()
1631   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1632 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1633 Binding direction based on `dired-x-hands-off-my-keys'.
1634 This function is part of `after-init-hook'."
1635   (interactive)
1636   (if (interactive-p)
1637       (setq dired-x-hands-off-my-keys
1638             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1639   (cond ((not dired-x-hands-off-my-keys)
1640          (substitute-key-definition 'find-file
1641                                     'dired-x-find-file
1642                                     (current-global-map))
1643          (substitute-key-definition 'find-file-other-window
1644                                     'dired-x-find-file-other-window
1645                                     (current-global-map)))
1646         (t
1647          (substitute-key-definition 'dired-x-find-file
1648                                     'find-file
1649                                     (current-global-map))
1650          (substitute-key-definition 'dired-x-find-file-other-window
1651                                     'find-file-other-window
1652                                     (current-global-map))))
1653   ;; Clear mini-buffer.
1654   (message nil))
1655
1656 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1657 ;;; user changes binding.
1658 (dired-x-bind-find-file)
1659 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1660
1661 (defun dired-x-find-file (filename)
1662   "Edit file FILENAME.
1663 May create a new window, or reuse an existing one.
1664 See the function `display-buffer'.
1665
1666 Identical to `find-file' except when called interactively, with a prefix arg
1667 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1668 Useful for editing file mentioned in buffer you are viewing,
1669 or to test if that file exists.  Use minibuffer after snatching filename."
1670   (interactive (list (read-filename-at-point "Find file: ")))
1671   (find-file (expand-file-name filename)))
1672
1673 (defun dired-x-find-file-other-window (filename)
1674   "Edit file FILENAME, in another window.
1675 May create a new window, or reuse an existing one.
1676 See the function `display-buffer'.
1677
1678 Identical to `find-file-other-window' except when called interactively, with a
1679 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1680 Useful for editing file mentioned in buffer you are viewing,
1681 or to test if that file exists.  Use minibuffer after snatching filename."
1682   (interactive (list (read-filename-at-point "Find file: ")))
1683   (find-file-other-window (expand-file-name filename)))
1684
1685 ;;; Internal functions.
1686
1687 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1688 (defun dired-filename-at-point ()
1689   "Get the filename closest to point, but do not change position.
1690 Has a preference for looking backward when not directly on a symbol.  Not
1691 perfect - point must be in middle of or end of filename."
1692
1693   (let ((filename-chars "-.[:alnum:]_/:$+@")
1694         start end filename prefix)
1695
1696     (save-excursion
1697       ;; First see if just past a filename.
1698       (if (not (eobp))
1699           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1700               (progn
1701                 (skip-chars-backward " \n\t\r({[]})")
1702                 (if (not (bobp))
1703                     (backward-char 1)))))
1704
1705       (if (string-match (concat "[" filename-chars "]")
1706                         (char-to-string (following-char)))
1707           (progn
1708             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1709                 (forward-char)
1710               (goto-char (point-min)))
1711             (setq start (point))
1712             (setq prefix
1713                   (and (string-match
1714                         "^\\w+@"
1715                         (buffer-substring start (line-beginning-position)))
1716                        "/"))
1717             (goto-char start)
1718             (if (string-match "[/~]" (char-to-string (preceding-char)))
1719                 (setq start (1- start)))
1720             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1721
1722         (error "No file found around point!"))
1723
1724       ;; Return string.
1725       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1726
1727 (defun read-filename-at-point (prompt)
1728   "Return filename prompting with PROMPT with completion.
1729 If `current-prefix-arg' is non-nil, uses name at point as guess."
1730   (if current-prefix-arg
1731       (let ((guess (dired-filename-at-point)))
1732         (read-file-name prompt
1733                         (file-name-directory guess)
1734                         guess
1735                         nil (file-name-nondirectory guess)))
1736     (read-file-name prompt default-directory)))
1737 \f
1738 ;;; BUG REPORTS
1739
1740 ;; Fixme: get rid of this later.
1741
1742 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1743 ;;; reporter.el which is bundled with GNU Emacs v19.
1744
1745 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1746   "Address(es) accepting submission of reports on dired-x.el.")
1747
1748 (defconst dired-x-variable-list
1749   (list
1750    'dired-bind-vm
1751    'dired-vm-read-only-folders
1752    'dired-bind-jump
1753    'dired-bind-info
1754    'dired-bind-man
1755    'dired-find-subdir
1756    'dired-enable-local-variables
1757    'dired-local-variables-file
1758    'dired-guess-shell-gnutar
1759    'dired-guess-shell-gzip-quiet
1760    'dired-guess-shell-znew-switches
1761    'dired-guess-shell-alist-user
1762    'dired-clean-up-buffers-too
1763    'dired-omit-mode
1764    'dired-omit-files
1765    'dired-omit-extensions
1766    )
1767   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1768
1769 (defun dired-x-submit-report ()
1770   "Submit via `reporter.el' a bug report on program.
1771 Send report on `dired-x-file' version `dired-x-version,' to
1772 `dired-x-maintainer' at address `dired-x-help-address' listing
1773 variables `dired-x-variable-list' in the message."
1774   (interactive)
1775
1776   (reporter-submit-bug-report
1777    dired-x-help-address                 ; address
1778    "dired-x"                            ; pkgname
1779    dired-x-variable-list                ; varlist
1780    nil nil                              ; pre-/post-hooks
1781    ""))
1782
1783 \f
1784 ;; As Barry Warsaw would say: "This might be useful..."
1785 (provide 'dired-x)
1786
1787 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1788 ;;; dired-x.el ends here