configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 standardlisppath='${lispdir}:${leimdir}'
  42 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  43 '${datadir}/emacs/site-lisp'
  44 lisppath='${locallisppath}:${standardlisppath}'
  45 etcdir='${datadir}/emacs/${version}/etc'
  46 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  47 docdir='${datadir}/emacs/${version}/etc'
  48 gamedir='${localstatedir}/games/emacs'
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 151 if test "$with_wide_int" = yes; then
 152   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 153 fi
 154
 155 dnl _ON results in a '--without' option in the --help output, so
 156 dnl the help text should refer to "don't compile", etc.
 157 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 158 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 159 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 160 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 161 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 162 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 163 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 164 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 165
 166 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 167 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 168 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 169
 170 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 171 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 172 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 173 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 174
 175 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 176 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 177 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 178 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 179 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 180 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 181
 182 ## For the times when you want to build Emacs but don't have
 183 ## a suitable makeinfo, and can live without the manuals.
 184 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 185 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 186
 187 ## Makefile.in needs the cache file name.
 188 AC_SUBST(cache_file)
 189
 190 ## This is an option because I do not know if all info/man support
 191 ## compressed files, nor how to test if they do so.
 192 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 193 if test $with_compress_info = yes; then
 194    GZIP_INFO=yes
 195 else
 196    GZIP_INFO=
 197 fi
 198 AC_SUBST(GZIP_INFO)
 199
 200 AC_ARG_WITH([pkg-config-prog],dnl
 201 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 202                   [path to pkg-config for finding GTK and librsvg])])
 203 if test "X${with_pkg_config_prog}" != X; then
 204    if test "${with_pkg_config_prog}" != yes; then
 205       PKG_CONFIG="${with_pkg_config_prog}"
 206    fi
 207 fi
 208
 209 CRT_DIR=
 210 AC_ARG_WITH([crt-dir],dnl
 211 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 212 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 213 CRT_DIR="${with_crt_dir}"
 214
 215 AC_ARG_WITH(gameuser,dnl
 216 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 217 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 218   && gameuser="${with_gameuser}"
 219 test "X$gameuser" = X && gameuser=games
 220
 221 AC_ARG_WITH([gnustep-conf],dnl
 222 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 223 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 224   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 225 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 226      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 227
 228 AC_ARG_ENABLE(ns-self-contained,
 229 [AS_HELP_STRING([--disable-ns-self-contained],
 230                 [disable self contained build under NeXTstep])],
 231    EN_NS_SELF_CONTAINED=$enableval,
 232    EN_NS_SELF_CONTAINED=yes)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist, glyphs])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;
 264                         ac_glyphs_debug= ;;
 265         all)            ac_enable_checking=1 ;
 266                         ac_gc_check_stringbytes=1 ;
 267                         ac_gc_check_string_overrun=1 ;
 268                         ac_gc_check_string_free_list=1 ;
 269                         ac_xmalloc_overrun=1 ;
 270                         ac_gc_check_cons_list=1 ;
 271                         ac_glyphs_debug=1 ;;
 272         # these enable particular checks
 273         stringbytes)    ac_gc_check_stringbytes=1 ;;
 274         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 275         stringfreelist) ac_gc_check_string_free_list=1 ;;
 276         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 277         conslist)       ac_gc_check_cons_list=1 ;;
 278         glyphs)         ac_glyphs_debug=1 ;;
 279         *)      AC_MSG_ERROR(unknown check category $check) ;;
 280         esac
 281 done
 282 IFS="$ac_save_IFS"
 283
 284 if test x$ac_enable_checking != x ; then
 285   AC_DEFINE(ENABLE_CHECKING, 1,
 286 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 287 fi
 288 if test x$ac_gc_check_stringbytes != x ; then
 289   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 290 [Define this temporarily to hunt a bug.  If defined, the size of
 291    strings is redundantly recorded in sdata structures so that it can
 292    be compared to the sizes recorded in Lisp strings.])
 293 fi
 294 if test x$ac_gc_check_string_overrun != x ; then
 295   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 296 [Define this to check for short string overrun.])
 297 fi
 298 if test x$ac_gc_check_string_free_list != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 300 [Define this to check the string free list.])
 301 fi
 302 if test x$ac_xmalloc_overrun != x ; then
 303   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 304 [Define this to check for malloc buffer overrun.])
 305 fi
 306 if test x$ac_gc_check_cons_list != x ; then
 307   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 308 [Define this to check for errors in cons list.])
 309 fi
 310 if test x$ac_glyphs_debug != x ; then
 311   AC_DEFINE(GLYPH_DEBUG, 1,
 312 [Define this to enable glyphs debugging code.])
 313 fi
 314
 315 AC_ARG_ENABLE(check-lisp-object-type,
 316 [AS_HELP_STRING([--enable-check-lisp-object-type],
 317                 [enable compile time checks for the Lisp_Object data type.
 318                 This is useful for development for catching certain types of bugs.])],
 319 if test "${enableval}" != "no"; then
 320    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 321    [Define this to enable compile time checks for the Lisp_Object data type.])
 322 fi)
 323
 324
 325 AC_ARG_ENABLE(profiling,
 326 [AS_HELP_STRING([--enable-profiling],
 327                 [build emacs with profiling support.
 328                  This might not work on all platforms])],
 329 [ac_enable_profiling="${enableval}"],[])
 330 if test x$ac_enable_profiling != x ; then
 331    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 332 else
 333    PROFILING_CFLAGS=
 334 fi
 335 AC_SUBST(PROFILING_CFLAGS)
 336
 337 AC_ARG_ENABLE(autodepend,
 338 [AS_HELP_STRING([--enable-autodepend],
 339                 [automatically generate dependencies to .h-files.
 340                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 341                  found])],
 342 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 343
 344 #### Make srcdir absolute, if it isn't already.  It's important to
 345 #### avoid running the path through pwd unnecessarily, since pwd can
 346 #### give you automounter prefixes, which can go away.  We do all this
 347 #### so Emacs can find its files when run uninstalled.
 348 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 349 unset CDPATH
 350 case "${srcdir}" in
 351   /* ) ;;
 352   . )
 353     ## We may be able to use the $PWD environment variable to make this
 354     ## absolute.  But sometimes PWD is inaccurate.
 355     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 356     ## but that tested only for a well-formed and valid PWD,
 357     ## it did not object when PWD was well-formed and valid but just wrong.
 358     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 359     then
 360       srcdir="$PWD"
 361     else
 362       srcdir="`(cd ${srcdir}; pwd)`"
 363     fi
 364   ;;
 365   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 366 esac
 367
 368 #### Given the configuration name, set opsysfile to the
 369 #### name of s/*.h file we should use.
 370
 371 ### Canonicalize the configuration name.
 372
 373 AC_CANONICAL_HOST
 374 canonical=$host
 375 configuration=${host_alias-${build_alias-$host}}
 376
 377 dnl This used to use changequote, but, apart from `changequote is evil'
 378 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 379 dnl the great gob of text.  Thus it's not processed for possible expansion.
 380 dnl Just make sure the brackets remain balanced.
 381 dnl
 382 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 383 dnl indicated by comments.
 384 dnl quotation begins
 385 [
 386
 387 ### If you add support for a new configuration, add code to this
 388 ### switch statement to recognize your configuration name and select
 389 ### the appropriate operating system file.
 390
 391 ### You would hope that you could choose an s/*.h
 392 ### file based on the operating system portion.  However, it turns out
 393 ### that each s/*.h file is pretty manufacturer-specific.
 394 ### So we basically have to have a special case for each
 395 ### configuration name.
 396 ###
 397 ### As far as handling version numbers on operating systems is
 398 ### concerned, make sure things will fail in a fixable way.  If
 399 ### /etc/MACHINES doesn't say anything about version numbers, be
 400 ### prepared to handle anything reasonably.  If version numbers
 401 ### matter, be sure /etc/MACHINES says something about it.
 402
 403 opsys='' unported=no
 404 case "${canonical}" in
 405
 406   ## GNU/Linux and similar ports
 407   *-*-linux* )
 408     opsys=gnu-linux
 409   ;;
 410
 411   ## FreeBSD ports
 412   *-*-freebsd* )
 413     opsys=freebsd
 414   ;;
 415
 416   ## FreeBSD kernel + glibc based userland
 417   *-*-kfreebsd*gnu* )
 418     opsys=gnu-kfreebsd
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424   ;;
 425
 426   ## OpenBSD ports
 427   *-*-openbsd* )
 428     opsys=openbsd
 429   ;;
 430
 431   ## Apple Darwin / Mac OS X
 432   *-apple-darwin* )
 433     case "${canonical}" in
 434       i[3456]86-* )  ;;
 435       powerpc-* )    ;;
 436       x86_64-* )     ;;
 437       * )            unported=yes ;;
 438     esac
 439     opsys=darwin
 440     ## Use fink packages if available.
 441     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 442 ##    if test -d /sw/include && test -d /sw/lib; then
 443 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 444 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 445 ##    fi
 446   ;;
 447
 448   ## HP 9000 series 700 and 800, running HP/UX
 449   hppa*-hp-hpux10.2* )
 450     opsys=hpux10-20
 451   ;;
 452   hppa*-hp-hpux1[1-9]* )
 453     opsys=hpux11
 454     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 455   ;;
 456
 457   ## IBM machines
 458   rs6000-ibm-aix4.[23]* )
 459     opsys=aix4-2
 460   ;;
 461   powerpc-ibm-aix4.[23]*  )
 462     opsys=aix4-2
 463   ;;
 464   rs6000-ibm-aix[56]* )
 465     opsys=aix4-2
 466   ;;
 467   powerpc-ibm-aix[56]*  )
 468     opsys=aix4-2
 469   ;;
 470
 471   ## Silicon Graphics machines
 472   ## Iris 4D
 473   mips-sgi-irix6.5 )
 474     opsys=irix6-5
 475     # Without defining _LANGUAGE_C, things get masked out in the headers
 476     # so that, for instance, grepping for `free' in stdlib.h fails and
 477     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 478     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 479   ;;
 480
 481   ## Suns
 482   *-sun-solaris* \
 483     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 484     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 485     case "${canonical}" in
 486       i[3456]86-*-* )   ;;
 487       amd64-*-*|x86_64-*-*) ;;
 488       sparc* )          ;;
 489       * )               unported=yes ;;
 490     esac
 491     case "${canonical}" in
 492       *-sunos5.6* | *-solaris2.6* )
 493                 opsys=sol2-6
 494                 RANLIB="ar -ts"
 495                 ;;
 496       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 497                 opsys=sol2-6
 498                 emacs_check_sunpro_c=yes
 499                 ;;
 500       *-sunos5* | *-solaris* )
 501                 opsys=sol2-10
 502                 emacs_check_sunpro_c=yes
 503                 ;;
 504     esac
 505     ## Watch out for a compiler that we know will not work.
 506     case "${canonical}" in
 507      *-solaris* | *-sunos5* )
 508                 if [ "x$CC" = x/usr/ucb/cc ]; then
 509                   ## /usr/ucb/cc doesn't work;
 510                   ## we should find some other compiler that does work.
 511                   unset CC
 512                 fi
 513                 ;;
 514       *) ;;
 515     esac
 516   ;;
 517
 518   ## Intel 386 machines where we don't care about the manufacturer.
 519   i[3456]86-*-* )
 520     case "${canonical}" in
 521       *-cygwin )                opsys=cygwin ;;
 522       *-darwin* )               opsys=darwin ;;
 523       *-sysv4.2uw* )            opsys=unixware ;;
 524       *-sysv5uw* )              opsys=unixware ;;
 525       *-sysv5OpenUNIX* )        opsys=unixware ;;
 526       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 527     esac
 528   ;;
 529
 530   * )
 531     unported=yes
 532   ;;
 533 esac
 534
 535 ### If the code above didn't choose an operating system, just choose
 536 ### an operating system based on the configuration name.  You really
 537 ### only want to use this when you have no idea what the right
 538 ### operating system is; if you know what operating systems a machine
 539 ### runs, it's cleaner to make it explicit in the case statement
 540 ### above.
 541 if test x"${opsys}" = x; then
 542   case "${canonical}" in
 543     *-gnu* )                            opsys=gnu ;;
 544     * )
 545       unported=yes
 546     ;;
 547   esac
 548 fi
 549
 550 ]
 551 dnl quotation ends
 552
 553 if test $unported = yes; then
 554   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 555 Check `etc/MACHINES' for recognized configuration names.])
 556 fi
 557
 558 opsysfile="s/${opsys}.h"
 559
 560
 561 #### Choose a compiler.
 562
 563 dnl Sets GCC=yes if using gcc.
 564 AC_PROG_CC
 565 AM_PROG_CC_C_O
 566
 567 if test x$GCC = xyes; then
 568   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 569 else
 570   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 571 fi
 572
 573 # Initialize gnulib right after choosing the compiler.
 574 gl_EARLY
 575
 576 AC_ARG_ENABLE([gcc-warnings],
 577   [AS_HELP_STRING([--enable-gcc-warnings],
 578                   [turn on lots of GCC warnings. This is intended for
 579                    developers, and may generate false alarms when used
 580                    with older or non-GNU development tools.])],
 581   [case $enableval in
 582      yes|no) ;;
 583      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 584    esac
 585    gl_gcc_warnings=$enableval],
 586   [gl_gcc_warnings=no]
 587 )
 588
 589 AC_ARG_ENABLE(link-time-optimization,
 590 [AS_HELP_STRING([--enable-link-time-optimization],
 591                 [build emacs with link-time optimization.
 592                  This is supported only for GCC since 4.5.0.])],
 593 if test "${enableval}" != "no"; then
 594    AC_MSG_CHECKING([whether link-time optimization is supported])
 595    ac_lto_supported=no
 596    if test x$GCC = xyes; then
 597       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 598       if test x$CPUS != x; then
 599          LTO="-flto=$CPUS"
 600       else
 601          LTO="-flto"
 602       fi
 603       old_CFLAGS=$CFLAGS
 604       CFLAGS="$CFLAGS $LTO"
 605       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 606         [ac_lto_supported=yes], [ac_lto_supported=no])
 607       CFLAGS="$old_CFLAGS"
 608    fi
 609    AC_MSG_RESULT([$ac_lto_supported])
 610    if test "$ac_lto_supported" = "yes"; then
 611       CFLAGS="$CFLAGS $LTO"
 612    fi
 613 fi)
 614
 615 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 616 # ------------------------------------------------
 617 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 618 # Otherwise, run RUN-IF-NOT-FOUND.
 619 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 620   [AC_PREPROC_IFELSE(
 621     [AC_LANG_PROGRAM(
 622       [[
 623 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 624 /* ok */
 625 #else
 626 # error "your version of gcc is older than $1.$2"
 627 #endif
 628       ]]),
 629     ], [$3], [$4])
 630   ]
 631 )
 632
 633 # When compiling with GCC, prefer -isystem to -I when including system
 634 # include files, to avoid generating useless diagnostics for the files.
 635 if test "$gl_gcc_warnings" != yes; then
 636   isystem='-I'
 637 else
 638   isystem='-isystem '
 639
 640   # This, $nw, is the list of warnings we disable.
 641   nw=
 642
 643   case $with_x_toolkit in
 644     lucid | athena | motif)
 645        # Old toolkits mishandle 'const'.
 646        nw="$nw -Wwrite-strings"
 647        ;;
 648     *)
 649        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 650        ;;
 651   esac
 652   AC_SUBST([WERROR_CFLAGS])
 653
 654   nw="$nw -Waggregate-return"       # anachronistic
 655   nw="$nw -Wlong-long"              # C90 is anachronistic
 656   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 657   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 658   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 659   nw="$nw -Wcast-qual"              # Too many warnings for now
 660   nw="$nw -Wconversion"             # Too many warnings for now
 661   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 662   nw="$nw -Wsign-conversion"        # Too many warnings for now
 663   nw="$nw -Woverlength-strings"     # Not a problem these days
 664   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 665   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 666   nw="$nw -Wpadded"                 # Our structs are not padded
 667   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 668   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 669   nw="$nw -Wformat-nonliteral"      # we do this a lot
 670   nw="$nw -Wvla"                    # warnings in gettext.h
 671   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 672   nw="$nw -Wswitch-enum"            # Too many warnings for now
 673   nw="$nw -Wswitch-default"         # Too many warnings for now
 674   nw="$nw -Wfloat-equal"            # warns about high-quality code
 675   nw="$nw -Winline"                 # OK to ignore 'inline'
 676   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 677   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 678
 679   # Emacs doesn't care about shadowing; see
 680   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 681   nw="$nw -Wshadow"
 682
 683   # The following lines should be removable at some point.
 684   nw="$nw -Wstack-protector"
 685   nw="$nw -Wstrict-overflow"
 686   nw="$nw -Wsuggest-attribute=pure"
 687
 688   gl_MANYWARN_ALL_GCC([ws])
 689   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 690   for w in $ws; do
 691     gl_WARN_ADD([$w])
 692   done
 693   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 694   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 695   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 696   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 697   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 698   gl_WARN_ADD([-Wno-format-nonliteral])
 699
 700   # In spite of excluding -Wlogical-op above, it is enabled, as of
 701   # gcc 4.5.0 20090517.
 702   gl_WARN_ADD([-Wno-logical-op])
 703
 704   gl_WARN_ADD([-fdiagnostics-show-option])
 705   gl_WARN_ADD([-funit-at-a-time])
 706
 707   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 708   AC_DEFINE([_FORTIFY_SOURCE], [2],
 709     [enable compile-time and run-time bounds-checking, and some warnings])
 710   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 711
 712   # We use a slightly smaller set of warning options for lib/.
 713   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 714   nw=
 715   nw="$nw -Wunused-macros"
 716
 717   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 718   AC_SUBST([GNULIB_WARN_CFLAGS])
 719 fi
 720
 721
 722
 723 dnl Some other nice autoconf tests.
 724 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 725 dnl AC_PROG_INSTALL
 726 dnl AC_PROG_MKDIR_P
 727 dnl if test "x$RANLIB" = x; then
 728 dnl   AC_PROG_RANLIB
 729 dnl fi
 730
 731 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 732   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 733 dnl Don't use GZIP, which is used by gzip for additional parameters.
 734 AC_PATH_PROG(GZIP_PROG, gzip)
 735
 736 if test $opsys = gnu-linux; then
 737   AC_PATH_PROG(PAXCTL, paxctl,,
 738     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 739 fi
 740
 741 ## Need makeinfo >= 4.7 (?) to build the manuals.
 742 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 743 dnl By this stage, configure has already checked for egrep and set EGREP,
 744 dnl or exited with an error if no egrep was found.
 745 if test "$MAKEINFO" != "no" && \
 746   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 747    MAKEINFO=no
 748 fi
 749
 750 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 751 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 752 ## therefore in the category of "special tools" not normally required, which
 753 ## configure does not have to check for (eg autoconf itself).
 754 ## In a Bazaar checkout on the other hand, the manuals are not included.
 755 ## So makeinfo is a requirement to build from Bazaar, and configure
 756 ## should test for it as it does for any other build requirement.
 757 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 758 ## with pre-built manuals, from a Bazaar checkout.
 759 HAVE_MAKEINFO=yes
 760
 761 if test "$MAKEINFO" = "no"; then
 762   MAKEINFO=makeinfo
 763   if test "x${with_makeinfo}" = "xno"; then
 764     HAVE_MAKEINFO=no
 765   elif test ! -e $srcdir/info/emacs; then
 766     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 767 source tree does not seem to have pre-built manuals in the `info' directory.
 768 Either install a suitable version of makeinfo, or re-run configure
 769 with the `--without-makeinfo' option to build without the manuals.] )
 770   fi
 771 fi
 772 AC_SUBST(HAVE_MAKEINFO)
 773
 774 dnl Just so that there is only a single place we need to edit.
 775 INFO_EXT=.info
 776 INFO_OPTS=--no-split
 777 AC_SUBST(INFO_EXT)
 778 AC_SUBST(INFO_OPTS)
 779
 780 dnl Add our options to ac_link now, after it is set up.
 781
 782 if test x$GCC = xyes; then
 783   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 784     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 785 else
 786   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 787     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 788 fi
 789
 790 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 791 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 792 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 793 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 794 dnl if not built to support GNU ld.
 795
 796 late_LDFLAGS=$LDFLAGS
 797 if test x$GCC = xyes; then
 798   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 799 else
 800   LDFLAGS="$LDFLAGS -znocombreloc"
 801 fi
 802
 803 AC_MSG_CHECKING([for -znocombreloc])
 804 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 805   [AC_MSG_RESULT(yes)],
 806   LDFLAGS=$late_LDFLAGS
 807   [AC_MSG_RESULT(no)])
 808
 809
 810 dnl The function dump-emacs will not be defined and temacs will do
 811 dnl (load "loadup") automatically unless told otherwise.
 812 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 813 case "$opsys" in
 814   your-opsys-here) CANNOT_DUMP=yes ;;
 815 esac
 816
 817 test "$CANNOT_DUMP" = "yes" && \
 818   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 819
 820 AC_SUBST(CANNOT_DUMP)
 821
 822
 823 UNEXEC_OBJ=unexelf.o
 824 case "$opsys" in
 825   # MSDOS uses unexcoff.o
 826   # MSWindows uses unexw32.o
 827   aix4-2)
 828    UNEXEC_OBJ=unexaix.o
 829    ;;
 830   cygwin)
 831    UNEXEC_OBJ=unexcw.o
 832    ;;
 833   darwin)
 834    UNEXEC_OBJ=unexmacosx.o
 835    ;;
 836   hpux10-20 | hpux11)
 837    UNEXEC_OBJ=unexhp9k800.o
 838    ;;
 839   sol2-10)
 840    # Use the Solaris dldump() function, called from unexsol.c, to dump
 841    # emacs, instead of the generic ELF dump code found in unexelf.c.
 842    # The resulting binary has a complete symbol table, and is better
 843    # for debugging and other observability tools (debuggers, pstack, etc).
 844    #
 845    # If you encounter a problem using dldump(), please consider sending
 846    # a message to the OpenSolaris tools-linking mailing list:
 847    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 848    #
 849    # It is likely that dldump() works with older Solaris too, but this has
 850    # not been tested, so for now this change is for Solaris 10 or newer.
 851    UNEXEC_OBJ=unexsol.o
 852    ;;
 853 esac
 854
 855 LD_SWITCH_SYSTEM=
 856 case "$opsys" in
 857   freebsd)
 858    ## Let `ld' find image libs and similar things in /usr/local/lib.
 859    ## The system compiler, GCC, has apparently been modified to not
 860    ## look there, contrary to what a stock GCC would do.
 861 ### It's not our place to do this.  See bug#10313#17.
 862 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 863       :
 864    ;;
 865
 866   gnu-linux)
 867    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 868    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 869    ;;
 870
 871   netbsd)
 872 ### It's not our place to do this.  See bug#10313#17.
 873 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 874       :
 875    ;;
 876
 877   openbsd)
 878    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 879    ## otherwise Emacs dumps core on elf systems.
 880    LD_SWITCH_SYSTEM="-Z"
 881    ;;
 882 esac
 883 AC_SUBST(LD_SWITCH_SYSTEM)
 884
 885 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 886
 887 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 888 ## which has not been defined yet.  When this was handled with cpp,
 889 ## it was expanded to null when configure sourced the s/*.h file.
 890 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 891 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 892 ## (or somesuch), but because it is supposed to go at the _front_
 893 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 894 ## Compare with the gnu-linux case below, which added to the end
 895 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 896 ## LD_SWITCH_SYSTEM_TEMACS.
 897 case "$opsys" in
 898   netbsd|openbsd)
 899    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 900 esac
 901
 902
 903 C_SWITCH_MACHINE=
 904 case $canonical in
 905  alpha*)
 906   AC_CHECK_DECL([__ELF__])
 907   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 908     ## With ELF, make sure that all common symbols get allocated to in the
 909     ## data section.  Otherwise, the dump of temacs may miss variables in
 910     ## the shared library that have been initialized.  For example, with
 911     ## GNU libc, __malloc_initialized would normally be resolved to the
 912     ## shared library's .bss section, which is fatal.
 913     if test "x$GCC" = "xyes"; then
 914       C_SWITCH_MACHINE="-fno-common"
 915     else
 916       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 917     fi
 918   else
 919     UNEXEC_OBJ=unexalpha.o
 920   fi
 921   ;;
 922 esac
 923 AC_SUBST(C_SWITCH_MACHINE)
 924
 925 AC_SUBST(UNEXEC_OBJ)
 926
 927 C_SWITCH_SYSTEM=
 928 ## Some programs in src produce warnings saying certain subprograms
 929 ## are too complex and need a MAXMEM value greater than 2000 for
 930 ## additional optimization.  --nils@exp-math.uni-essen.de
 931 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 932   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 933 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 934 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 935 AC_SUBST(C_SWITCH_SYSTEM)
 936
 937
 938 LIBS_SYSTEM=
 939 case "$opsys" in
 940   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 941   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 942
 943   freebsd) LIBS_SYSTEM="-lutil" ;;
 944
 945   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 946
 947   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 948
 949   ## Motif needs -lgen.
 950   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 951 esac
 952 AC_SUBST(LIBS_SYSTEM)
 953
 954
 955 ### Make sure subsequent tests use flags consistent with the build flags.
 956
 957 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 958   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 959 else
 960   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 961 fi
 962
 963 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 964 AC_DEFUN([AC_TYPE_SIZE_T])
 965 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 966 AC_DEFUN([AC_TYPE_UID_T])
 967
 968
 969 LIB_MATH=-lm
 970 LIB_STANDARD=
 971 START_FILES=
 972 dnl Current possibilities handled by sed (aix4-2 -> aix,
 973 dnl gnu-linux -> gnu/linux, etc.):
 974 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 975 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 976 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 977
 978 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 979 case $opsys in
 980   cygwin )
 981     LIB_MATH=
 982     START_FILES='pre-crt0.o'
 983     ;;
 984   darwin )
 985     ## Adding -lm confuses the dynamic linker, so omit it.
 986     LIB_MATH=
 987     START_FILES='pre-crt0.o'
 988     ;;
 989   freebsd )
 990     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 991     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 992     SYSTEM_TYPE=berkeley-unix
 993     ;;
 994   gnu-linux | gnu-kfreebsd )
 995     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 996     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 997     ;;
 998   hpux10-20 | hpux11 )
 999     LIB_STANDARD=-lc
1000     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1001     ;;
1002   dnl NB this may be adjusted below.
1003   netbsd | openbsd )
1004     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1005     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1006     SYSTEM_TYPE=berkeley-unix
1007     ;;
1008
1009   sol2* | unixware )
1010     SYSTEM_TYPE=usg-unix-v
1011     ;;
1012
1013 esac
1014
1015 AC_SUBST(LIB_MATH)
1016 AC_SUBST(START_FILES)
1017 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1018   [The type of system you are compiling for; sets `system-type'.])
1019
1020 dnl Not all platforms use crtn.o files.  Check if the current one does.
1021 crt_files=
1022
1023 for file in x $LIB_STANDARD $START_FILES; do
1024   case "$file" in
1025     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1026   esac
1027 done
1028
1029 if test "x$crt_files" != x; then
1030
1031   ## If user specified a crt-dir, use that unconditionally.
1032   crt_gcc=no
1033
1034   if test "X$CRT_DIR" = "X"; then
1035
1036     CRT_DIR=/usr/lib            # default
1037
1038     case "$canonical" in
1039       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1040       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1041       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1042       ## For anything else (eg /usr/lib32), it is up the user to specify
1043       ## the location (bug#5655).
1044       ## Test for crtn.o, not just the directory, because sometimes the
1045       ## directory exists but does not have the relevant files (bug#1287).
1046       ## FIXME better to test for binary compatibility somehow.
1047       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1048       ;;
1049
1050       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1051     esac
1052
1053     case "$opsys" in
1054       hpux10-20) CRT_DIR=/lib ;;
1055     esac
1056
1057     test "x${GCC}" = xyes && crt_gcc=yes
1058
1059   fi                            # CRT_DIR = ""
1060
1061   crt_missing=
1062
1063   for file in $crt_files; do
1064
1065     ## If we're using gcc, try to determine it automatically by asking
1066     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1067     ## system-dependent default from above.]
1068     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1069
1070        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1071        case "$crt_file" in
1072          */*)
1073            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1074            ;;
1075        esac
1076     fi
1077
1078     dnl We expect all the files to be in a single directory, so after the
1079     dnl first there is no point asking gcc.
1080     crt_gcc=no
1081
1082     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1083   done                          # $crt_files
1084
1085   test "x$crt_missing" = x || \
1086     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1087 Try using the --with-crt-dir option.])
1088
1089 fi                              # crt_files != ""
1090
1091 AC_SUBST(CRT_DIR)
1092
1093 case $opsys in
1094   netbsd | openbsd )
1095     if test -f $CRT_DIR/crti.o; then
1096
1097         test -f $CRT_DIR/crtn.o || \
1098           AC_MSG_ERROR([Required file not found: crtn.o])
1099
1100         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1101         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1102     fi
1103     ;;
1104 esac
1105
1106
1107 # Configure gnulib before invoking PKG_CHECK_MODULES, as the latter might
1108 # for example add -lrt to RSVG_LIBS, which would then cause gnulib to
1109 # incorrectly conclude that -lrt is not needed to link clock_gettime.
1110 gl_ASSERT_NO_GNULIB_POSIXCHECK
1111 gl_ASSERT_NO_GNULIB_TESTS
1112 gl_INIT
1113
1114 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1115
1116 dnl This function definition taken from Gnome 2.0
1117 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1118 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1119 dnl also defines GSTUFF_PKG_ERRORS on error
1120 AC_DEFUN([PKG_CHECK_MODULES], [
1121   succeeded=no
1122
1123   if test "$PKG_CONFIG" = "no" ; then
1124      ifelse([$4], , [AC_MSG_ERROR([
1125       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1126   else
1127      PKG_CONFIG_MIN_VERSION=0.9.0
1128      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1129         AC_MSG_CHECKING(for $2)
1130
1131         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1132            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1133            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1134             edit_cflags="
1135               s,///*,/,g
1136               s/^/ /
1137               s/ -I/ $isystem/g
1138               s/^ //
1139             "
1140             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1141             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1142             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1143             succeeded=yes
1144         else
1145             AC_MSG_RESULT(no)
1146             $1_CFLAGS=""
1147             $1_LIBS=""
1148             ## If we have a custom action on failure, don't print errors, but
1149             ## do set a variable so people can do so.
1150             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1151             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1152         fi
1153
1154         AC_SUBST($1_CFLAGS)
1155         AC_SUBST($1_LIBS)
1156      else
1157         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1158         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1159      fi
1160   fi
1161
1162   if test $succeeded = yes; then
1163      ifelse([$3], , :, [$3])
1164   else
1165      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1166   fi
1167 ])
1168
1169
1170 if test "${with_sound}" != "no"; then
1171   # Sound support for GNU/Linux and the free BSDs.
1172   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1173     have_sound_header=yes)
1174   # Emulation library used on NetBSD.
1175   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1176   AC_SUBST(LIBSOUND)
1177
1178   ALSA_REQUIRED=1.0.0
1179   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1180   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1181   if test $HAVE_ALSA = yes; then
1182     SAVE_CFLAGS="$CFLAGS"
1183     SAVE_LIBS="$LIBS"
1184     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1185     LIBS="$ALSA_LIBS $LIBS"
1186     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1187                     emacs_alsa_normal=yes,
1188                     emacs_alsa_normal=no)
1189     if test "$emacs_alsa_normal" != yes; then
1190       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1191                      [[snd_lib_error_set_handler (0);]])],
1192                      emacs_alsa_subdir=yes,
1193                      emacs_alsa_subdir=no)
1194       if test "$emacs_alsa_subdir" != yes; then
1195         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1196       fi
1197       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1198     fi
1199
1200     CFLAGS="$SAVE_CFLAGS"
1201     LIBS="$SAVE_LIBS"
1202     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1203     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1204     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1205   fi
1206
1207   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1208   dnl compiles only on the specified platforms.  For others, it
1209   dnl probably doesn't make sense to try.
1210   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1211      case "$opsys" in
1212        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1213        gnu-linux|freebsd|netbsd)
1214          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1215          ;;
1216      esac
1217   fi
1218
1219   AC_SUBST(CFLAGS_SOUND)
1220 fi
1221
1222 dnl checks for header files
1223 AC_CHECK_HEADERS_ONCE(
1224   linux/version.h sys/systeminfo.h
1225   stdio_ext.h fcntl.h coff.h pty.h
1226   sys/vlimit.h sys/resource.h
1227   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1228
1229 AC_MSG_CHECKING(if personality LINUX32 can be set)
1230 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1231                emacs_cv_personality_linux32=yes,
1232                emacs_cv_personality_linux32=no)
1233 AC_MSG_RESULT($emacs_cv_personality_linux32)
1234
1235 if test $emacs_cv_personality_linux32 = yes; then
1236   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1237             [Define to 1 if personality LINUX32 can be set.])
1238 fi
1239
1240 dnl On Solaris 8 there's a compilation warning for term.h because
1241 dnl it doesn't define `bool'.
1242 AC_CHECK_HEADERS(term.h, , , -)
1243 AC_HEADER_TIME
1244 AC_CHECK_DECLS([sys_siglist])
1245 if test $ac_cv_have_decl_sys_siglist != yes; then
1246   # For Tru64, at least:
1247   AC_CHECK_DECLS([__sys_siglist])
1248   if test $ac_cv_have_decl___sys_siglist = yes; then
1249     AC_DEFINE(sys_siglist, __sys_siglist,
1250               [Define to any substitute for sys_siglist.])
1251   fi
1252 fi
1253 AC_HEADER_SYS_WAIT
1254
1255 dnl Check for speed_t typedef.
1256 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1257   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1258     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1259 if test $emacs_cv_speed_t = yes; then
1260   AC_DEFINE(HAVE_SPEED_T, 1,
1261            [Define to 1 if `speed_t' is declared by <termios.h>.])
1262 fi
1263
1264 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1265 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1266 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1267   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1268 HAVE_EXCEPTION=$emacs_cv_struct_exception
1269 dnl Define on Darwin so emacs symbols will not conflict with those
1270 dnl in the System framework.  Otherwise -prebind will not work.
1271 if test $emacs_cv_struct_exception != yes || test $opsys = darwin; then
1272   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1273 fi
1274
1275 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1276 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1277 #if HAVE_SYS_SOCKET_H
1278 #include <sys/socket.h>
1279 #endif])
1280 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1281 #if HAVE_SYS_SOCKET_H
1282 #include <sys/socket.h>
1283 #endif])
1284 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1285 #if HAVE_SYS_SOCKET_H
1286 #include <sys/socket.h>
1287 #endif])
1288
1289 dnl checks for structure members
1290 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1291                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1292                   struct ifreq.ifr_addr,
1293                   struct ifreq.ifr_addr.sa_len], , ,
1294                  [AC_INCLUDES_DEFAULT
1295 #if HAVE_SYS_SOCKET_H
1296 #include <sys/socket.h>
1297 #endif
1298 #if HAVE_NET_IF_H
1299 #include <net/if.h>
1300 #endif])
1301
1302 dnl Check for endianness.
1303 dnl AC_C_BIGENDIAN is done by gnulib.
1304
1305 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1306   [emacs_cv_attribute_aligned],
1307   [AC_COMPILE_IFELSE(
1308      [AC_LANG_PROGRAM(
1309         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1310         [[]])],
1311      [emacs_cv_attribute_aligned=yes],
1312      [emacs_cv_attribute_aligned=no])])
1313 if test $emacs_cv_attribute_aligned = yes; then
1314   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1315     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1316 fi
1317
1318 dnl check for Make feature
1319 dnl AC_PROG_MAKE_SET is done by Automake.
1320
1321 DEPFLAGS=
1322 MKDEPDIR=":"
1323 deps_frag=deps.mk
1324 dnl check for GNU Make if we have GCC and autodepend is on.
1325 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1326    AC_MSG_CHECKING([whether we are using GNU Make])
1327    HAVE_GNU_MAKE=no
1328    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1329    if test "x$testval" != x; then
1330       HAVE_GNU_MAKE=yes
1331    else
1332       ac_enable_autodepend=no
1333    fi
1334    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1335    if test $HAVE_GNU_MAKE = yes; then
1336       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1337       SAVE_CFLAGS="$CFLAGS"
1338       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1339       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1340       CFLAGS="$SAVE_CFLAGS"
1341       test -f deps.d || ac_enable_autodepend=no
1342       rm -rf deps.d
1343       AC_MSG_RESULT([$ac_enable_autodepend])
1344    fi
1345    if test $ac_enable_autodepend = yes; then
1346       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1347       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1348       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1349       deps_frag=autodeps.mk
1350    fi
1351 fi
1352 deps_frag=$srcdir/src/$deps_frag
1353 AC_SUBST(MKDEPDIR)
1354 AC_SUBST(DEPFLAGS)
1355 AC_SUBST_FILE(deps_frag)
1356
1357
1358 lisp_frag=$srcdir/src/lisp.mk
1359 AC_SUBST_FILE(lisp_frag)
1360
1361
1362 dnl checks for operating system services
1363 AC_SYS_LONG_FILE_NAMES
1364
1365 #### Choose a window system.
1366
1367 AC_PATH_X
1368 if test "$no_x" = yes; then
1369   window_system=none
1370 else
1371   window_system=x11
1372 fi
1373
1374 LD_SWITCH_X_SITE_RPATH=
1375 if test "${x_libraries}" != NONE; then
1376   if test -n "${x_libraries}"; then
1377     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1378     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1379   fi
1380   x_default_search_path=""
1381   x_search_path=${x_libraries}
1382   if test -z "${x_search_path}"; then
1383     x_search_path=/usr/lib
1384   fi
1385   for x_library in `echo ${x_search_path}: | \
1386                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1387     x_search_path="\
1388 ${x_library}/X11/%L/%T/%N%C%S:\
1389 ${x_library}/X11/%l/%T/%N%C%S:\
1390 ${x_library}/X11/%T/%N%C%S:\
1391 ${x_library}/X11/%L/%T/%N%S:\
1392 ${x_library}/X11/%l/%T/%N%S:\
1393 ${x_library}/X11/%T/%N%S"
1394     if test x"${x_default_search_path}" = x; then
1395       x_default_search_path=${x_search_path}
1396     else
1397       x_default_search_path="${x_search_path}:${x_default_search_path}"
1398     fi
1399   done
1400 fi
1401 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1402
1403 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1404   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1405 fi
1406
1407 if test x"${x_includes}" = x; then
1408   bitmapdir=/usr/include/X11/bitmaps
1409 else
1410   # accumulate include directories that have X11 bitmap subdirectories
1411   bmd_acc="dummyval"
1412   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1413     if test -d "${bmd}/X11/bitmaps"; then
1414       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1415     fi
1416     if test -d "${bmd}/bitmaps"; then
1417       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1418     fi
1419   done
1420   if test ${bmd_acc} != "dummyval"; then
1421     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1422   fi
1423 fi
1424
1425 HAVE_NS=no
1426 NS_IMPL_COCOA=no
1427 NS_IMPL_GNUSTEP=no
1428 tmp_CPPFLAGS="$CPPFLAGS"
1429 tmp_CFLAGS="$CFLAGS"
1430 CPPFLAGS="$CPPFLAGS -x objective-c"
1431 CFLAGS="$CFLAGS -x objective-c"
1432 TEMACS_LDFLAGS2="\${LDFLAGS}"
1433 GNU_OBJC_CFLAGS=
1434 if test "${with_ns}" != no; then
1435   if test "${opsys}" = darwin; then
1436      NS_IMPL_COCOA=yes
1437      ns_appdir=`pwd`/nextstep/Emacs.app
1438      ns_appbindir=${ns_appdir}/Contents/MacOS
1439      ns_appresdir=${ns_appdir}/Contents/Resources
1440      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1441   elif test -f $GNUSTEP_CONFIG_FILE; then
1442      NS_IMPL_GNUSTEP=yes
1443      ns_appdir=`pwd`/nextstep/Emacs.app
1444      ns_appbindir=${ns_appdir}
1445      ns_appresdir=${ns_appdir}/Resources
1446      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1447      dnl FIXME sourcing this several times in subshells seems inefficient.
1448      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1449      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1450      dnl I seemed to need these as well with GNUstep-startup 0.25.
1451      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1452      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1453      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1454        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1455      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1456        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1457      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1458      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1459      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1460      LIB_STANDARD=
1461      START_FILES=
1462      TEMACS_LDFLAGS2=
1463      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1464      dnl If they had chosen to either define it or not, we could have
1465      dnl just used AC_CHECK_DECL here.
1466      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1467        emacs_cv_objc_exceptions,
1468 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1469 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1470 1;
1471 #else
1472 fail;
1473 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1474      if test $emacs_cv_objc_exceptions = yes; then
1475        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1476        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1477          [Define if GNUstep uses ObjC exceptions.])
1478        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1479      fi
1480   fi
1481
1482   dnl This is only used while we test the NS headers, it gets reset below.
1483   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1484
1485   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1486                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1487   files are missing or cannot be compiled.])])
1488   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1489                                      [NSInteger i;])],
1490                     ns_have_nsinteger=yes,
1491                     ns_have_nsinteger=no)
1492   if test $ns_have_nsinteger = yes; then
1493     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1494   fi
1495 fi
1496 AC_SUBST(TEMACS_LDFLAGS2)
1497
1498 INSTALL_ARCH_INDEP_EXTRA=install-etc
1499 ns_self_contained=no
1500 ns_frag=/dev/null
1501 NS_OBJ=
1502 NS_OBJC_OBJ=
1503 if test "${HAVE_NS}" = yes; then
1504   if test "$with_toolkit_scroll_bars" = "no"; then
1505     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1506   fi
1507
1508   window_system=nextstep
1509   with_xft=no
1510   # set up packaging dirs
1511   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1512      ns_self_contained=yes
1513      prefix=${ns_appresdir}
1514      exec_prefix=${ns_appbindir}
1515      dnl This one isn't really used, only archlibdir is.
1516      libexecdir="\${ns_appbindir}/libexec"
1517      archlibdir="\${ns_appbindir}/libexec"
1518      docdir="\${ns_appresdir}/etc"
1519      etcdir="\${ns_appresdir}/etc"
1520      dnl FIXME maybe set datarootdir instead.
1521      dnl That would also get applications, icons, man.
1522      infodir="\${ns_appresdir}/info"
1523      mandir="\${ns_appresdir}/man"
1524      lispdir="\${ns_appresdir}/lisp"
1525      leimdir="\${ns_appresdir}/leim"
1526      INSTALL_ARCH_INDEP_EXTRA=
1527   fi
1528   ns_frag=$srcdir/src/ns.mk
1529   NS_OBJ="fontset.o fringe.o image.o"
1530   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1531 fi
1532 CFLAGS="$tmp_CFLAGS"
1533 CPPFLAGS="$tmp_CPPFLAGS"
1534 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1535 AC_SUBST(ns_self_contained)
1536 AC_SUBST(NS_OBJ)
1537 AC_SUBST(NS_OBJC_OBJ)
1538 AC_SUBST(LIB_STANDARD)
1539 AC_SUBST_FILE(ns_frag)
1540
1541 case "${window_system}" in
1542   x11 )
1543     HAVE_X_WINDOWS=yes
1544     HAVE_X11=yes
1545     case "${with_x_toolkit}" in
1546       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1547       motif ) USE_X_TOOLKIT=MOTIF ;;
1548       gtk ) with_gtk=yes
1549 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1550 dnl USE_X_TOOLKIT is set.
1551             USE_X_TOOLKIT=none ;;
1552       gtk3 ) with_gtk3=yes
1553              USE_X_TOOLKIT=none ;;
1554       no ) USE_X_TOOLKIT=none ;;
1555 dnl If user did not say whether to use a toolkit, make this decision later:
1556 dnl use the toolkit if we have gtk, or X11R5 or newer.
1557       * ) USE_X_TOOLKIT=maybe ;;
1558     esac
1559   ;;
1560   nextstep | none )
1561     HAVE_X_WINDOWS=no
1562     HAVE_X11=no
1563     USE_X_TOOLKIT=none
1564   ;;
1565 esac
1566
1567 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1568    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1569    if test "$HAVE_XSERVER" = true ||
1570       test -n "$DISPLAY" ||
1571       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1572         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1573 were found.  You should install the relevant development files for X
1574 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1575 sure you have development files for image handling, i.e.
1576 tiff, gif, jpeg, png and xpm.
1577 If you are sure you want Emacs compiled without X window support, pass
1578   --without-x
1579 to configure.])
1580    fi
1581 fi
1582
1583 ### If we're using X11, we should use the X menu package.
1584 HAVE_MENUS=no
1585 case ${HAVE_X11} in
1586   yes ) HAVE_MENUS=yes ;;
1587 esac
1588
1589 # Does the opsystem file prohibit the use of the GNU malloc?
1590 # Assume not, until told otherwise.
1591 GNU_MALLOC=yes
1592
1593 AC_CACHE_CHECK(
1594   [whether malloc is Doug Lea style],
1595   [emacs_cv_var_doug_lea_malloc],
1596   [AC_LINK_IFELSE(
1597      [AC_LANG_PROGRAM(
1598         [[#include <malloc.h>
1599           static void hook (void) {}]],
1600         [[malloc_set_state (malloc_get_state ());
1601           __after_morecore_hook = hook;
1602           __malloc_initialize_hook = hook;]])],
1603      [emacs_cv_var_doug_lea_malloc=yes],
1604      [emacs_cv_var_doug_lea_malloc=no])])
1605 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1606
1607
1608 dnl See comments in aix4-2.h about maybe using system malloc there.
1609 system_malloc=no
1610 case "$opsys" in
1611   ## darwin ld insists on the use of malloc routines in the System framework.
1612   darwin|sol2-10) system_malloc=yes ;;
1613 esac
1614
1615 if test "${system_malloc}" = "yes"; then
1616   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1617   GNU_MALLOC=no
1618   GNU_MALLOC_reason="
1619     (The GNU allocators don't work with this system configuration.)"
1620   GMALLOC_OBJ=
1621   VMLIMIT_OBJ=
1622 else
1623   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1624   VMLIMIT_OBJ=vm-limit.o
1625 fi
1626 AC_SUBST(GMALLOC_OBJ)
1627 AC_SUBST(VMLIMIT_OBJ)
1628
1629 if test "$doug_lea_malloc" = "yes" ; then
1630   if test "$GNU_MALLOC" = yes ; then
1631     GNU_MALLOC_reason="
1632       (Using Doug Lea's new malloc from the GNU C Library.)"
1633   fi
1634   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1635             [Define to 1 if you are using the GNU C Library.])
1636
1637   ## Use mmap directly for allocating larger buffers.
1638   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1639   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1640   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1641   case "$opsys" in
1642     gnu*) REL_ALLOC=no ;;
1643   esac
1644 fi
1645
1646 if test x"${REL_ALLOC}" = x; then
1647   REL_ALLOC=${GNU_MALLOC}
1648 fi
1649
1650 use_mmap_for_buffers=no
1651 case "$opsys" in
1652   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1653 esac
1654
1655 AC_FUNC_MMAP
1656 if test $use_mmap_for_buffers = yes; then
1657   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1658   REL_ALLOC=no
1659 fi
1660
1661 LIBS="$LIBS_SYSTEM $LIBS"
1662
1663 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1664 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1665 AC_CHECK_LIB(dnet, dnet_ntoa)
1666 dnl This causes -lresolv to get used in subsequent tests,
1667 dnl which causes failures on some systems such as HPUX 9.
1668 dnl AC_CHECK_LIB(resolv, gethostbyname)
1669
1670 dnl FIXME replace main with a function we actually want from this library.
1671 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1672
1673 dnl Check if pthreads is available.
1674 LIB_PTHREAD=
1675 AC_CHECK_HEADERS_ONCE(pthread.h)
1676 if test "$ac_cv_header_pthread_h"; then
1677   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1678   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1679   dnl testing for pthread_self if Emacs uses gmalloc.c.
1680   if test "$GMALLOC_OBJ" = gmalloc.o; then
1681     emacs_pthread_function=pthread_atfork
1682   else
1683     emacs_pthread_function=pthread_self
1684   fi
1685   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1686 fi
1687 if test "$HAVE_PTHREAD" = yes; then
1688   case "${canonical}" in
1689     *-hpux*) ;;
1690     *) LIB_PTHREAD="-lpthread"
1691        LIBS="$LIB_PTHREAD $LIBS" ;;
1692   esac
1693   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1694 fi
1695 AC_SUBST([LIB_PTHREAD])
1696
1697 AC_CHECK_LIB(pthreads, cma_open)
1698
1699 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1700 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1701 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1702 ## added to LIBS in configure would never contain the pthreads part,
1703 ## but the value used in Makefiles might.  FIXME?
1704 ##
1705 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1706 ## be harmless on older versions of X where it happens to exist.
1707 test "$opsys" = "aix4-2" && \
1708   test $ac_cv_lib_pthreads_cma_open = yes && \
1709   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1710
1711 dnl Check for need for bigtoc support on IBM AIX
1712
1713 case ${host_os} in
1714 aix*)
1715   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1716     case $GCC in
1717     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1718     *) gdb_cv_bigtoc=-bbigtoc ;;
1719     esac
1720
1721     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1722     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1723   ])
1724   ;;
1725 esac
1726
1727 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1728 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1729 # REAL_CPPFLAGS later on.
1730
1731 REAL_CFLAGS="$CFLAGS"
1732 REAL_CPPFLAGS="$CPPFLAGS"
1733
1734 if test "${HAVE_X11}" = "yes"; then
1735   DEFS="$C_SWITCH_X_SITE $DEFS"
1736   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1737   LIBS="-lX11 $LIBS"
1738   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1739   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1740
1741   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1742   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1743   # but it's more convenient here to set LD_RUN_PATH since this
1744   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1745   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1746     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1747     export LD_RUN_PATH
1748   fi
1749
1750   if test "${opsys}" = "gnu-linux"; then
1751     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1752     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1753      [[XOpenDisplay ("foo");]])],
1754      [xgnu_linux_first_failure=no],
1755      [xgnu_linux_first_failure=yes])
1756     if test "${xgnu_linux_first_failure}" = "yes"; then
1757       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1758       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1759       OLD_CPPFLAGS="$CPPFLAGS"
1760       OLD_LIBS="$LIBS"
1761       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1762       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1763       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1764       LIBS="$LIBS -b i486-linuxaout"
1765       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1766        [[XOpenDisplay ("foo");]])],
1767        [xgnu_linux_second_failure=no],
1768        [xgnu_linux_second_failure=yes])
1769       if test "${xgnu_linux_second_failure}" = "yes"; then
1770         # If we get the same failure with -b, there is no use adding -b.
1771         # So take it out.  This plays safe.
1772         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1773         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1774         CPPFLAGS="$OLD_CPPFLAGS"
1775         LIBS="$OLD_LIBS"
1776         AC_MSG_RESULT(no)
1777       else
1778         AC_MSG_RESULT(yes)
1779       fi
1780     else
1781       AC_MSG_RESULT(no)
1782     fi
1783   fi
1784
1785   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1786   # header files included from there.
1787   AC_MSG_CHECKING(for Xkb)
1788   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1789 #include <X11/XKBlib.h>]],
1790         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1791         emacs_xkb=yes, emacs_xkb=no)
1792   AC_MSG_RESULT($emacs_xkb)
1793   if test $emacs_xkb = yes; then
1794     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1795   fi
1796
1797   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1798 XScreenNumberOfScreen)
1799 fi
1800
1801 if test "${window_system}" = "x11"; then
1802   AC_MSG_CHECKING(X11 version 6)
1803   AC_CACHE_VAL(emacs_cv_x11_version_6,
1804   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1805 [[#if XlibSpecificationRelease < 6
1806 fail;
1807 #endif
1808 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1809   if test $emacs_cv_x11_version_6 = yes; then
1810     AC_MSG_RESULT(6 or newer)
1811     AC_DEFINE(HAVE_X11R6, 1,
1812               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1813     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1814     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1815     ## XIM support.
1816     case "$opsys" in
1817       sol2-*) : ;;
1818       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1819            [Define if you have usable X11R6-style XIM support.])
1820          ;;
1821     esac
1822   else
1823     AC_MSG_RESULT(before 6)
1824   fi
1825 fi
1826
1827
1828 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1829 HAVE_RSVG=no
1830 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1831   if test "${with_rsvg}" != "no"; then
1832     RSVG_REQUIRED=2.11.0
1833     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1834
1835     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1836     AC_SUBST(RSVG_CFLAGS)
1837     AC_SUBST(RSVG_LIBS)
1838
1839     if test $HAVE_RSVG = yes; then
1840       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1841       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1842       LIBS="$RSVG_LIBS $LIBS"
1843     fi
1844   fi
1845 fi
1846
1847 HAVE_IMAGEMAGICK=no
1848 if test "${HAVE_X11}" = "yes"; then
1849   if test "${with_imagemagick}" != "no"; then
1850     ## 6.2.8 is the earliest version known to work, but earlier versions
1851     ## might work - let us know if you find one.
1852     ## 6.0.7 does not work.  See bug#7955.
1853     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1854     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1855     AC_SUBST(IMAGEMAGICK_CFLAGS)
1856     AC_SUBST(IMAGEMAGICK_LIBS)
1857
1858     if test $HAVE_IMAGEMAGICK = yes; then
1859       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1860       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1861       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1862       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1863     fi
1864   fi
1865 fi
1866
1867
1868 HAVE_GTK=no
1869 GTK_OBJ=
1870 if test "${with_gtk3}" = "yes"; then
1871   GLIB_REQUIRED=2.28
1872   GTK_REQUIRED=3.0
1873   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1874
1875   dnl Checks for libraries.
1876   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1877   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1878      AC_MSG_ERROR($GTK_PKG_ERRORS)
1879   fi
1880   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1881   GTK_OBJ=emacsgtkfixed.o
1882 fi
1883
1884 if test "$pkg_check_gtk" != "yes"; then
1885   HAVE_GTK=no
1886 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1887   GLIB_REQUIRED=2.10
1888   GTK_REQUIRED=2.10
1889   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1890
1891   dnl Checks for libraries.
1892   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1893   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1894      AC_MSG_ERROR($GTK_PKG_ERRORS)
1895   fi
1896 fi
1897 fi
1898
1899 if test x"$pkg_check_gtk" = xyes; then
1900
1901   AC_SUBST(GTK_CFLAGS)
1902   AC_SUBST(GTK_LIBS)
1903   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1904   CFLAGS="$CFLAGS $GTK_CFLAGS"
1905   LIBS="$GTK_LIBS $LIBS"
1906   dnl Try to compile a simple GTK program.
1907   GTK_COMPILES=no
1908   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1909   if test "${GTK_COMPILES}" != "yes"; then
1910     if test "$USE_X_TOOLKIT" != "maybe"; then
1911       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1912     fi
1913   else
1914     HAVE_GTK=yes
1915     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1916     GTK_OBJ="gtkutil.o $GTK_OBJ"
1917     USE_X_TOOLKIT=none
1918     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1919       :
1920     else
1921       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1922        closing open displays.  This is no problem if you just use
1923        one display, but if you use more than one and close one of them
1924        Emacs may crash.]])
1925       sleep 3
1926     fi
1927   fi
1928
1929 fi
1930 AC_SUBST(GTK_OBJ)
1931
1932
1933 if test "${HAVE_GTK}" = "yes"; then
1934
1935   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1936   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1937   if test "$with_toolkit_scroll_bars" != no; then
1938     with_toolkit_scroll_bars=yes
1939   fi
1940
1941   dnl  Check if we have the old file selection dialog declared and
1942   dnl  in the link library.  In 2.x it may be in the library,
1943   dnl  but not declared if deprecated featured has been selected out.
1944   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1945   HAVE_GTK_FILE_SELECTION=no
1946   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1947                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1948 #include <gtk/gtk.h>])
1949   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1950     AC_CHECK_FUNCS(gtk_file_selection_new)
1951   fi
1952
1953
1954   dnl Check for functions introduced in 2.14 and later.
1955   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1956                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1957                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1958                  gtk_orientable_set_orientation \
1959                  gtk_window_set_has_resize_grip)
1960 fi
1961
1962 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1963 dnl other platforms.
1964 HAVE_DBUS=no
1965 DBUS_OBJ=
1966 if test "${with_dbus}" = "yes"; then
1967    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1968    if test "$HAVE_DBUS" = yes; then
1969      LIBS="$LIBS $DBUS_LIBS"
1970      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1971      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1972      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1973      dnl D-Bus 1.5.12.
1974      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1975                     dbus_type_is_valid \
1976                     dbus_validate_bus_name \
1977                     dbus_validate_path \
1978                     dbus_validate_interface \
1979                     dbus_validate_member)
1980      DBUS_OBJ=dbusbind.o
1981    fi
1982 fi
1983 AC_SUBST(DBUS_OBJ)
1984
1985 dnl GSettings has been tested under GNU/Linux only.
1986 HAVE_GSETTINGS=no
1987 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1988    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1989    if test "$HAVE_GSETTINGS" = "yes"; then
1990       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1991       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1992       SETTINGS_LIBS="$GSETTINGS_LIBS"
1993    fi
1994 fi
1995
1996 dnl GConf has been tested under GNU/Linux only.
1997 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1998 HAVE_GCONF=no
1999 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2000    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2001    if test "$HAVE_GCONF" = yes; then
2002       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2003       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2004       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2005       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2006    fi
2007 fi
2008
2009 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2010     SAVE_CFLAGS="$CFLAGS"
2011     SAVE_LIBS="$LIBS"
2012     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2013     LIBS="$SETTINGS_LIBS $LIBS"
2014     AC_CHECK_FUNCS([g_type_init])
2015     CFLAGS="$SAVE_CFLAGS"
2016     LIBS="$SAVE_LIBS"
2017 fi
2018 AC_SUBST(SETTINGS_CFLAGS)
2019 AC_SUBST(SETTINGS_LIBS)
2020
2021
2022 dnl SELinux is available for GNU/Linux only.
2023 HAVE_LIBSELINUX=no
2024 LIBSELINUX_LIBS=
2025 if test "${with_selinux}" = "yes"; then
2026    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2027    if test "$HAVE_LIBSELINUX" = yes; then
2028       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2029       LIBSELINUX_LIBS=-lselinux
2030    fi
2031 fi
2032 AC_SUBST(LIBSELINUX_LIBS)
2033
2034 HAVE_GNUTLS=no
2035 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2036 if test "${with_gnutls}" = "yes" ; then
2037   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2038   if test "${HAVE_GNUTLS}" = "yes"; then
2039     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2040   fi
2041
2042   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2043   LIBS="$LIBGNUTLS_LIBS $LIBS"
2044   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2045
2046   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2047     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2048   fi
2049 fi
2050
2051 AC_SUBST(LIBGNUTLS_LIBS)
2052 AC_SUBST(LIBGNUTLS_CFLAGS)
2053
2054 dnl Do not put whitespace before the #include statements below.
2055 dnl Older compilers (eg sunos4 cc) choke on it.
2056 HAVE_XAW3D=no
2057 LUCID_LIBW=
2058 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2059   if test "$with_xaw3d" != no; then
2060     AC_MSG_CHECKING(for xaw3d)
2061     AC_CACHE_VAL(emacs_cv_xaw3d,
2062     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2063 #include <X11/Intrinsic.h>
2064 #include <X11/Xaw3d/Simple.h>]],
2065       [[]])],
2066       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2067                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2068       emacs_cv_xaw3d=no)])
2069   else
2070     emacs_cv_xaw3d=no
2071   fi
2072   if test $emacs_cv_xaw3d = yes; then
2073     AC_MSG_RESULT([yes; using Lucid toolkit])
2074     USE_X_TOOLKIT=LUCID
2075     HAVE_XAW3D=yes
2076     LUCID_LIBW=-lXaw3d
2077     AC_DEFINE(HAVE_XAW3D, 1,
2078               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2079   else
2080     AC_MSG_RESULT(no)
2081     AC_MSG_CHECKING(for libXaw)
2082     AC_CACHE_VAL(emacs_cv_xaw,
2083     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2084 #include <X11/Intrinsic.h>
2085 #include <X11/Xaw/Simple.h>]],
2086       [[]])],
2087       emacs_cv_xaw=yes,
2088       emacs_cv_xaw=no)])
2089     if test $emacs_cv_xaw = yes; then
2090       AC_MSG_RESULT([yes; using Lucid toolkit])
2091       USE_X_TOOLKIT=LUCID
2092       LUCID_LIBW=-lXaw
2093     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2094       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2095     else
2096       AC_MSG_ERROR([No X toolkit could be found.
2097 If you are sure you want Emacs compiled without an X toolkit, pass
2098   --with-x-toolkit=no
2099 to configure.  Otherwise, install the development libraries for the toolkit
2100 that you want to use (e.g. Gtk+) and re-run configure.])
2101     fi
2102   fi
2103 fi
2104
2105 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2106
2107 LIBXTR6=
2108 if test "${USE_X_TOOLKIT}" != "none"; then
2109   AC_MSG_CHECKING(X11 toolkit version)
2110   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2111   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2112 [[#if XtSpecificationRelease < 6
2113 fail;
2114 #endif
2115 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2116   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2117   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2118     AC_MSG_RESULT(6 or newer)
2119     AC_DEFINE(HAVE_X11XTR6, 1,
2120               [Define to 1 if you have the X11R6 or newer version of Xt.])
2121     LIBXTR6="-lSM -lICE"
2122     case "$opsys" in
2123       ## Use libw.a along with X11R6 Xt.
2124       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2125     esac
2126   else
2127     AC_MSG_RESULT(before 6)
2128   fi
2129
2130 dnl If using toolkit, check whether libXmu.a exists.
2131 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2132   OLDLIBS="$LIBS"
2133   if test x$HAVE_X11XTR6 = xyes; then
2134     LIBS="-lXt -lSM -lICE $LIBS"
2135   else
2136     LIBS="-lXt $LIBS"
2137   fi
2138   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2139   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2140   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2141 fi
2142 AC_SUBST(LIBXTR6)
2143
2144 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2145 dnl Why not just test for libxmu in the normal way?
2146 LIBXMU=-lXmu
2147 case $opsys in
2148   ## These systems don't supply Xmu.
2149   hpux* | aix4-2 )
2150     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2151     ;;
2152 esac
2153 AC_SUBST(LIBXMU)
2154
2155 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2156 if test "${HAVE_X11}" = "yes"; then
2157   if test "${USE_X_TOOLKIT}" != "none"; then
2158     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2159   fi
2160 fi
2161
2162 LIBXP=
2163 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2164   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2165   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2166     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2167 int x = 5;
2168 #else
2169 Motif version prior to 2.1.
2170 #endif]])],
2171     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2172   if test $emacs_cv_motif_version_2_1 = yes; then
2173     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2174   else
2175     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2176     # We put this in CFLAGS temporarily to precede other -I options
2177     # that might be in CFLAGS temporarily.
2178     # We put this in CPPFLAGS where it precedes the other -I options.
2179     OLD_CPPFLAGS=$CPPFLAGS
2180     OLD_CFLAGS=$CFLAGS
2181     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2182     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2183     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2184       [[int x = 5;]])],
2185       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2186     if test $emacs_cv_lesstif = yes; then
2187       # Make sure this -I option remains in CPPFLAGS after it is set
2188       # back to REAL_CPPFLAGS.
2189       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2190       # have those other -I options anyway.  Ultimately, having this
2191       # directory ultimately in CPPFLAGS will be enough.
2192       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2193       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2194     else
2195       CFLAGS=$OLD_CFLAGS
2196       CPPFLAGS=$OLD_CPPFLAGS
2197     fi
2198   fi
2199   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2200     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2201 fi
2202
2203 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2204 dnl using Motif or Xaw3d is available, and unless
2205 dnl --with-toolkit-scroll-bars=no was specified.
2206
2207 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2208             [Define to 1 if we should use toolkit scroll bars.])dnl
2209 USE_TOOLKIT_SCROLL_BARS=no
2210 if test "${with_toolkit_scroll_bars}" != "no"; then
2211   if test "${USE_X_TOOLKIT}" != "none"; then
2212     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2213       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2214       HAVE_XAW3D=no
2215       USE_TOOLKIT_SCROLL_BARS=yes
2216     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2217       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2218       USE_TOOLKIT_SCROLL_BARS=yes
2219     fi
2220   elif test "${HAVE_GTK}" = "yes"; then
2221     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2222     USE_TOOLKIT_SCROLL_BARS=yes
2223   elif test "${HAVE_NS}" = "yes"; then
2224     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2225     USE_TOOLKIT_SCROLL_BARS=yes
2226   fi
2227 fi
2228
2229 dnl See if XIM is available.
2230 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2231           #include <X11/Xlib.h>
2232           #include <X11/Xresource.h>]],
2233          [[XIMProc  callback;]])],
2234          [HAVE_XIM=yes
2235          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2236          HAVE_XIM=no)
2237
2238 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2239
2240 if test "${with_xim}" != "no"; then
2241   AC_DEFINE(USE_XIM, 1,
2242             [Define to 1 if we should use XIM, if it is available.])
2243 fi
2244
2245
2246 if test "${HAVE_XIM}" != "no"; then
2247   late_CFLAGS=$CFLAGS
2248   if test "$GCC" = yes; then
2249     CFLAGS="$CFLAGS --pedantic-errors"
2250   fi
2251   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2252 #include <X11/Xlib.h>
2253 #include <X11/Xresource.h>]],
2254 [[Display *display;
2255 XrmDatabase db;
2256 char *res_name;
2257 char *res_class;
2258 XIMProc  callback;
2259 XPointer *client_data;
2260 #ifndef __GNUC__
2261 /* If we're not using GCC, it's probably not XFree86, and this is
2262    probably right, but we can't use something like --pedantic-errors.  */
2263 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2264                                            char*, XIMProc, XPointer*);
2265 #endif
2266 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2267    client_data);]])],
2268     [emacs_cv_arg6_star=yes])
2269   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2270          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2271 either XPointer or XPointer*.])dnl
2272   if test "$emacs_cv_arg6_star" = yes; then
2273     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2274   else
2275     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2276   fi
2277   CFLAGS=$late_CFLAGS
2278 fi
2279
2280 ### Start of font-backend (under any platform) section.
2281 # (nothing here yet -- this is a placeholder)
2282 ### End of font-backend (under any platform) section.
2283
2284 ### Start of font-backend (under X11) section.
2285 if test "${HAVE_X11}" = "yes"; then
2286    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2287
2288    ## Use -lXft if available, unless `--with-xft=no'.
2289    HAVE_XFT=maybe
2290     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2291       with_xft="no";
2292     fi
2293     if test "x${with_xft}" != "xno"; then
2294
2295       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2296       ## Because xftfont.c uses XRenderQueryExtension, we also
2297       ## need to link to -lXrender.
2298       HAVE_XRENDER=no
2299       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2300       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2301         OLD_CPPFLAGS="$CPPFLAGS"
2302         OLD_CFLAGS="$CFLAGS"
2303         OLD_LIBS="$LIBS"
2304         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2305         CFLAGS="$CFLAGS $XFT_CFLAGS"
2306         XFT_LIBS="-lXrender $XFT_LIBS"
2307         LIBS="$XFT_LIBS $LIBS"
2308         AC_CHECK_HEADER(X11/Xft/Xft.h,
2309           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2310
2311         if test "${HAVE_XFT}" = "yes"; then
2312           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2313             AC_SUBST(XFT_LIBS)
2314           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2315         else
2316           CPPFLAGS="$OLD_CPPFLAGS"
2317           CFLAGS="$OLD_CFLAGS"
2318           LIBS="$OLD_LIBS"
2319         fi                        # "${HAVE_XFT}" = "yes"
2320       fi                          # "$HAVE_XFT" != no
2321     fi                            # "x${with_xft}" != "xno"
2322
2323     ## We used to allow building with FreeType and without Xft.
2324     ## However, the ftx font backend driver is not in good shape.
2325     if test "$HAVE_XFT" != "yes"; then
2326        dnl For the "Does Emacs use" message at the end.
2327        HAVE_XFT=no
2328        HAVE_FREETYPE=no
2329     else
2330        dnl Strict linkers fail with
2331        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2332        dnl if -lfreetype is not specified.
2333        dnl The following is needed to set FREETYPE_LIBS.
2334        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2335                          HAVE_FREETYPE=no)
2336
2337        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2338     fi
2339
2340     HAVE_LIBOTF=no
2341     if test "${HAVE_FREETYPE}" = "yes"; then
2342       AC_DEFINE(HAVE_FREETYPE, 1,
2343                 [Define to 1 if using the freetype and fontconfig libraries.])
2344       if test "${with_libotf}" != "no"; then
2345         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2346                           HAVE_LIBOTF=no)
2347         if test "$HAVE_LIBOTF" = "yes"; then
2348           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2349           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2350                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2351                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2352           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2353             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2354                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2355           fi
2356         fi
2357       fi
2358     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2359     dnl Does the new font backend require it, or can it work without it?
2360     fi
2361
2362     HAVE_M17N_FLT=no
2363     if test "${HAVE_LIBOTF}" = yes; then
2364       if test "${with_m17n_flt}" != "no"; then
2365         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2366         if test "$HAVE_M17N_FLT" = "yes"; then
2367           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2368         fi
2369       fi
2370     fi
2371 else
2372     HAVE_XFT=no
2373     HAVE_FREETYPE=no
2374     HAVE_LIBOTF=no
2375     HAVE_M17N_FLT=no
2376 fi
2377
2378 ### End of font-backend (under X11) section.
2379
2380 AC_SUBST(FREETYPE_CFLAGS)
2381 AC_SUBST(FREETYPE_LIBS)
2382 AC_SUBST(FONTCONFIG_CFLAGS)
2383 AC_SUBST(FONTCONFIG_LIBS)
2384 AC_SUBST(LIBOTF_CFLAGS)
2385 AC_SUBST(LIBOTF_LIBS)
2386 AC_SUBST(M17N_FLT_CFLAGS)
2387 AC_SUBST(M17N_FLT_LIBS)
2388
2389 ### Use -lXpm if available, unless `--with-xpm=no'.
2390 HAVE_XPM=no
2391 LIBXPM=
2392 if test "${HAVE_X11}" = "yes"; then
2393   if test "${with_xpm}" != "no"; then
2394     AC_CHECK_HEADER(X11/xpm.h,
2395       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2396     if test "${HAVE_XPM}" = "yes"; then
2397       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2398       AC_EGREP_CPP(no_return_alloc_pixels,
2399       [#include "X11/xpm.h"
2400 #ifndef XpmReturnAllocPixels
2401 no_return_alloc_pixels
2402 #endif
2403       ], HAVE_XPM=no, HAVE_XPM=yes)
2404
2405       if test "${HAVE_XPM}" = "yes"; then
2406         AC_MSG_RESULT(yes)
2407       else
2408         AC_MSG_RESULT(no)
2409       fi
2410     fi
2411   fi
2412
2413   if test "${HAVE_XPM}" = "yes"; then
2414     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2415     LIBXPM=-lXpm
2416   fi
2417 fi
2418 AC_SUBST(LIBXPM)
2419
2420 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2421 HAVE_JPEG=no
2422 LIBJPEG=
2423 if test "${HAVE_X11}" = "yes"; then
2424   if test "${with_jpeg}" != "no"; then
2425     dnl Checking for jpeglib.h can lose because of a redefinition of
2426     dnl  HAVE_STDLIB_H.
2427     AC_CHECK_HEADER(jerror.h,
2428       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2429   fi
2430
2431   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2432   if test "${HAVE_JPEG}" = "yes"; then
2433     AC_DEFINE(HAVE_JPEG)
2434     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2435         [#include <jpeglib.h>
2436          version=JPEG_LIB_VERSION
2437 ],
2438         [AC_DEFINE(HAVE_JPEG)],
2439         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2440         HAVE_JPEG=no])
2441   fi
2442   if test "${HAVE_JPEG}" = "yes"; then
2443     LIBJPEG=-ljpeg
2444   fi
2445 fi
2446 AC_SUBST(LIBJPEG)
2447
2448 ### Use -lpng if available, unless `--with-png=no'.
2449 HAVE_PNG=no
2450 LIBPNG=
2451 if test "${HAVE_X11}" = "yes"; then
2452   if test "${with_png}" != "no"; then
2453     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2454     # in /usr/include/libpng.
2455     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2456     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2457       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2458     fi
2459   fi
2460
2461   if test "${HAVE_PNG}" = "yes"; then
2462     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2463     LIBPNG="-lpng -lz -lm"
2464
2465     AC_CHECK_DECL(png_longjmp,
2466       [],
2467       [AC_DEFINE(PNG_DEPSTRUCT, [],
2468          [Define to empty to suppress deprecation warnings when building
2469           with --enable-gcc-warnings and with libpng versions before 1.5,
2470           which lack png_longjmp.])],
2471       [[#ifdef HAVE_LIBPNG_PNG_H
2472         # include <libpng/png.h>
2473         #else
2474         # include <png.h>
2475         #endif
2476       ]])
2477   fi
2478 fi
2479 AC_SUBST(LIBPNG)
2480
2481 ### Use -ltiff if available, unless `--with-tiff=no'.
2482 HAVE_TIFF=no
2483 LIBTIFF=
2484 if test "${HAVE_X11}" = "yes"; then
2485   if test "${with_tiff}" != "no"; then
2486     AC_CHECK_HEADER(tiffio.h,
2487       [tifflibs="-lz -lm"
2488       # At least one tiff package requires the jpeg library.
2489       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2490       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2491   fi
2492
2493   if test "${HAVE_TIFF}" = "yes"; then
2494     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2495     dnl FIXME -lz -lm, as per libpng?
2496     LIBTIFF=-ltiff
2497   fi
2498 fi
2499 AC_SUBST(LIBTIFF)
2500
2501 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2502 HAVE_GIF=no
2503 LIBGIF=
2504 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2505   AC_CHECK_HEADER(gif_lib.h,
2506 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2507 # Earlier versions can crash Emacs.
2508     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2509
2510   if test "$HAVE_GIF" = yes; then
2511     LIBGIF=-lgif
2512   elif test "$HAVE_GIF" = maybe; then
2513 # If gif_lib.h but no libgif, try libungif.
2514     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2515     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2516   fi
2517
2518   if test "${HAVE_GIF}" = "yes"; then
2519     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2520   fi
2521 fi
2522 AC_SUBST(LIBGIF)
2523
2524 dnl Check for required libraries.
2525 if test "${HAVE_X11}" = "yes"; then
2526   MISSING=""
2527   WITH_NO=""
2528   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2529     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2530   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2531     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2532   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2533     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2534   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2535     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2536   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2537     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2538
2539   if test "X${MISSING}" != X; then
2540     AC_MSG_ERROR([The following required libraries were not found:
2541     $MISSING
2542 Maybe some development libraries/packages are missing?
2543 If you don't want to link with them give
2544     $WITH_NO
2545 as options to configure])
2546   fi
2547 fi
2548
2549 ### Use -lgpm if available, unless `--with-gpm=no'.
2550 HAVE_GPM=no
2551 LIBGPM=
2552 if test "${with_gpm}" != "no"; then
2553   AC_CHECK_HEADER(gpm.h,
2554     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2555
2556   if test "${HAVE_GPM}" = "yes"; then
2557     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2558     LIBGPM=-lgpm
2559   fi
2560 fi
2561 AC_SUBST(LIBGPM)
2562
2563 dnl Check for malloc/malloc.h on darwin
2564 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2565
2566 GNUSTEP_CFLAGS=
2567 ### Use NeXTstep API to implement GUI.
2568 if test "${HAVE_NS}" = "yes"; then
2569   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2570   if test "${NS_IMPL_COCOA}" = "yes"; then
2571     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2572   fi
2573   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2574     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2575     # See also .m.o rule in Makefile.in */
2576     # FIXME: are all these flags really needed?  Document here why.  */
2577     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2578     ## Extra CFLAGS applied to src/*.m files.
2579     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2580   fi
2581   # We also have mouse menus.
2582   HAVE_MENUS=yes
2583   OTHER_FILES=ns-app
2584 fi
2585
2586
2587 ### Use session management (-lSM -lICE) if available
2588 HAVE_X_SM=no
2589 LIBXSM=
2590 if test "${HAVE_X11}" = "yes"; then
2591   AC_CHECK_HEADER(X11/SM/SMlib.h,
2592     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2593
2594   if test "${HAVE_X_SM}" = "yes"; then
2595     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2596     LIBXSM="-lSM -lICE"
2597     case "$LIBS" in
2598       *-lSM*) ;;
2599       *)      LIBS="$LIBXSM $LIBS" ;;
2600     esac
2601   fi
2602 fi
2603 AC_SUBST(LIBXSM)
2604
2605 ### Use libxml (-lxml2) if available
2606 HAVE_LIBXML2=no
2607 if test "${with_xml2}" != "no"; then
2608   ### I'm not sure what the version number should be, so I just guessed.
2609   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2610   if test "${HAVE_LIBXML2}" = "yes"; then
2611     LIBS="$LIBXML2_LIBS $LIBS"
2612     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2613     if test "${HAVE_LIBXML2}" = "yes"; then
2614       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2615     else
2616       LIBXML2_LIBS=""
2617       LIBXML2_CFLAGS=""
2618     fi
2619   fi
2620 fi
2621 AC_SUBST(LIBXML2_LIBS)
2622 AC_SUBST(LIBXML2_CFLAGS)
2623
2624 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2625 AC_CACHE_CHECK(whether netdb declares h_errno,
2626                emacs_cv_netdb_declares_h_errno,
2627 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2628   [[return h_errno;]])],
2629   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2630 if test $emacs_cv_netdb_declares_h_errno = yes; then
2631   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2632 fi
2633
2634 # fmod, logb, and frexp are found in -lm on most systems.
2635 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2636 AC_CHECK_LIB(m, sqrt)
2637
2638 # Check for mail-locking functions in a "mail" library.  Probably this should
2639 # have the same check as for liblockfile below.
2640 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2641 if test $have_mail = yes; then
2642   LIBS_MAIL=-lmail
2643   LIBS="$LIBS_MAIL $LIBS"
2644   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2645 else
2646   LIBS_MAIL=
2647 fi
2648 dnl Debian, at least:
2649 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2650 if test $have_lockfile = yes; then
2651    LIBS_MAIL=-llockfile
2652    LIBS="$LIBS_MAIL $LIBS"
2653    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2654 else
2655 # If we have the shared liblockfile, assume we must use it for mail
2656 # locking (e.g. Debian).  If we couldn't link against liblockfile
2657 # (no liblockfile.a installed), ensure that we don't need to.
2658   dnl This works for files generally, not just executables.
2659   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2660   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2661                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2662   if test $ac_cv_prog_liblockfile = yes; then
2663     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2664 This probably means that movemail could lose mail.
2665 There may be a `development' package to install containing liblockfile.])
2666   fi
2667 fi
2668 AC_CHECK_HEADERS_ONCE(maillock.h)
2669 AC_SUBST(LIBS_MAIL)
2670
2671 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2672 ## interlock access to the mail spool.  The alternative is a lock file named
2673 ## /usr/spool/mail/$USER.lock.
2674 mail_lock=no
2675 case "$opsys" in
2676   aix4-2) mail_lock="lockf" ;;
2677
2678   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2679
2680   ## On GNU/Linux systems, both methods are used by various mail programs.
2681   ## I assume most people are using newer mailers that have heard of flock.
2682   ## Change this if you need to.
2683   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2684   ## configure gets the right answers, and that means *NOT* using flock.
2685   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2686   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2687   ## Debian maintainer hasn't provided a clean fix for Emacs.
2688   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2689   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2690   ## correct logic.  -- fx
2691   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2692   ## liblockfile is a Free Software replacement for libmail, used on
2693   ## Debian systems and elsewhere. -rfr.
2694   gnu-*)
2695     mail_lock="flock"
2696     if test $have_mail = yes || test $have_lockfile = yes; then
2697       test $ac_cv_header_maillock_h = yes && mail_lock=no
2698     fi
2699     ;;
2700 esac
2701
2702 BLESSMAIL_TARGET=
2703 case "$mail_lock" in
2704   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2705
2706   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2707
2708   *) BLESSMAIL_TARGET="need-blessmail" ;;
2709 esac
2710 AC_SUBST(BLESSMAIL_TARGET)
2711
2712
2713 AC_CHECK_FUNCS(gethostname \
2714 closedir getrusage get_current_dir_name \
2715 lrand48 logb frexp fmod cbrt setsid \
2716 fpathconf select euidaccess getpagesize setlocale \
2717 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2718 __fpending strsignal setitimer \
2719 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2720 gai_strerror mkstemp getline getdelim fsync sync \
2721 difftime posix_memalign \
2722 getpwent endpwent getgrent endgrent \
2723 touchlock \
2724 cfmakeraw cfsetspeed copysign __executable_start)
2725
2726 dnl FIXME Fragile: something else may test for getwd as a dependency.
2727 dnl Change to defining BROKEN_xxx ?
2728 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2729 if test $opsys != unixware; then
2730   AC_CHECK_FUNCS(getwd)
2731 fi
2732
2733 dnl FIXME Fragile: see above.
2734 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2735 ## has a broken `rint' in some library versions including math library
2736 ## version number A.09.05.
2737 ## You can fix the math library by installing patch number PHSS_4630.
2738 ## But we can fix it more reliably for Emacs by just not using rint.
2739 ## We also skip HAVE_RANDOM - see comments in src/s/hpux10-20.h.
2740 case $opsys in
2741    hpux*) : ;;
2742    *) AC_CHECK_FUNCS(random rint) ;;
2743 esac
2744
2745 dnl Cannot use AC_CHECK_FUNCS
2746 AC_CACHE_CHECK([for __builtin_unwind_init],
2747                emacs_cv_func___builtin_unwind_init,
2748 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2749                 emacs_cv_func___builtin_unwind_init=yes,
2750                 emacs_cv_func___builtin_unwind_init=no)])
2751 if test $emacs_cv_func___builtin_unwind_init = yes; then
2752   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2753             [Define to 1 if you have the `__builtin_unwind_init' function.])
2754 fi
2755
2756 AC_CHECK_HEADERS_ONCE(sys/un.h)
2757
2758 AC_FUNC_FSEEKO
2759
2760 AC_FUNC_GETPGRP
2761
2762 # UNIX98 PTYs.
2763 AC_CHECK_FUNCS(grantpt)
2764
2765 # PTY-related GNU extensions.
2766 AC_CHECK_FUNCS(getpt)
2767
2768 # Check this now, so that we will NOT find the above functions in ncurses.
2769 # That is because we have not set up to link ncurses in lib-src.
2770 # It's better to believe a function is not available
2771 # than to expect to find it in ncurses.
2772 # Also we need tputs and friends to be able to build at all.
2773 AC_MSG_CHECKING([for library containing tputs])
2774 # Run a test program that contains a call to tputs, a call that is
2775 # never executed.  This tests whether a pre-'main' dynamic linker
2776 # works with the library.  It's too much trouble to actually call
2777 # tputs in the test program, due to portability hassles.  When
2778 # cross-compiling, assume the test program will run if it links.
2779 AC_DEFUN([tputs_link_source], [
2780   AC_LANG_SOURCE(
2781      [[extern void tputs (const char *, int, int (*)(int));
2782        int main (int argc, char **argv)
2783        {
2784           if (argc == 10000)
2785             tputs (argv[0], 0, 0);
2786           return 0;
2787        }]])
2788 ])
2789 # Maybe curses should be tried earlier?
2790 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2791 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2792   OLIBS=$LIBS
2793   if test -z "$tputs_library"; then
2794     LIBS_TERMCAP=
2795     msg='none required'
2796   else
2797     LIBS_TERMCAP=-l$tputs_library
2798     msg=$LIBS_TERMCAP
2799     LIBS="$LIBS_TERMCAP $LIBS"
2800   fi
2801   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2802     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2803   LIBS=$OLIBS
2804   if test "X$msg" != Xno; then
2805     break
2806   fi
2807 done
2808 AC_MSG_RESULT([$msg])
2809 if test "X$msg" = Xno; then
2810   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2811 The following libraries were tried (in order):
2812   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2813 Please try installing whichever of these libraries is most appropriate
2814 for your system, together with its header files.
2815 For example, a libncurses-dev(el) or similar package.])
2816 fi
2817
2818 ## Use termcap instead of terminfo?
2819 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2820 TERMINFO=yes
2821 ## FIXME?  In the cases below where we unconditionally set
2822 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2823 ## if that was found above to have tputs.
2824 ## Should we use the gnu* logic everywhere?
2825 case "$opsys" in
2826   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2827   ##  The ncurses library has been moved out of the System framework in
2828   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2829   ##  option to use it.
2830   darwin) LIBS_TERMCAP="-lncurses" ;;
2831
2832   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2833
2834   freebsd)
2835     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2836     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2837     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2838 [[#if __FreeBSD_version < 400000
2839 fail;
2840 #endif
2841 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2842
2843     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2844
2845     if test $emacs_cv_freebsd_terminfo = yes; then
2846       LIBS_TERMCAP="-lncurses"
2847     else
2848       TERMINFO=no
2849       LIBS_TERMCAP="-ltermcap"
2850     fi
2851     ;;
2852
2853   netbsd)
2854     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2855       TERMINFO=no
2856       LIBS_TERMCAP="-ltermcap"
2857     fi
2858     ;;
2859
2860   openbsd) LIBS_TERMCAP="-lncurses" ;;
2861
2862   ## hpux: Make sure we get select from libc rather than from libcurses
2863   ##  because libcurses on HPUX 10.10 has a broken version of select.
2864   ##  We used to use -lc -lcurses, but this may be cleaner.
2865   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2866   # set that way, now it uses the default).  Isn't this a contradiction?
2867   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2868
2869 esac
2870
2871 TERMCAP_OBJ=tparam.o
2872 if test $TERMINFO = yes; then
2873   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2874   TERMCAP_OBJ=terminfo.o
2875 fi
2876 AC_SUBST(LIBS_TERMCAP)
2877 AC_SUBST(TERMCAP_OBJ)
2878
2879
2880 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2881 # On Darwin, res_init appears not to be useful: see bug#562 and
2882 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2883 resolv=no
2884
2885 if test $opsys != darwin; then
2886
2887   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2888 #include <arpa/nameser.h>
2889 #include <resolv.h>]],
2890     [[return res_init();]])],
2891     have_res_init=yes, have_res_init=no)
2892   if test "$have_res_init" = no; then
2893     OLIBS="$LIBS"
2894     LIBS="$LIBS -lresolv"
2895     AC_MSG_CHECKING(for res_init with -lresolv)
2896     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2897 #include <arpa/nameser.h>
2898 #include <resolv.h>]],
2899       [[return res_init();]])],
2900       have_res_init=yes, have_res_init=no)
2901     AC_MSG_RESULT($have_res_init)
2902     if test "$have_res_init" = yes ; then
2903       resolv=yes
2904     fi
2905     LIBS="$OLIBS"
2906   fi
2907
2908   if test "$have_res_init" = yes; then
2909     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2910   fi
2911 fi                              dnl !darwin
2912
2913 # Do we need the Hesiod library to provide the support routines?
2914 dnl FIXME?  Should we be skipping this on Darwin too?
2915 LIBHESIOD=
2916 if test "$with_hesiod" != no ; then
2917   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2918   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2919      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2920                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2921   if test "$resolv" = yes ; then
2922     RESOLVLIB=-lresolv
2923   else
2924     RESOLVLIB=
2925   fi
2926   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2927         hesiod=yes, :, $RESOLVLIB)])
2928
2929   if test x"$hesiod" = xyes; then
2930     AC_DEFINE(HAVE_LIBHESIOD, 1,
2931               [Define to 1 if you have the hesiod library (-lhesiod).])
2932     LIBHESIOD=-lhesiod
2933   fi
2934 fi
2935 AC_SUBST(LIBHESIOD)
2936
2937 # Do we need libresolv (due to res_init or Hesiod)?
2938 if test "$resolv" = yes && test $opsys != darwin; then
2939   AC_DEFINE(HAVE_LIBRESOLV, 1,
2940             [Define to 1 if you have the resolv library (-lresolv).])
2941   LIBRESOLV=-lresolv
2942 else
2943   LIBRESOLV=
2944 fi
2945 AC_SUBST(LIBRESOLV)
2946
2947 # These tell us which Kerberos-related libraries to use.
2948 COM_ERRLIB=
2949 CRYPTOLIB=
2950 KRB5LIB=
2951 DESLIB=
2952 KRB4LIB=
2953
2954 if test "${with_kerberos}" != no; then
2955   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2956   if test $have_com_err = yes; then
2957     COM_ERRLIB=-lcom_err
2958     LIBS="$COM_ERRLIB $LIBS"
2959     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2960   fi
2961   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2962   if test $have_crypto = yes; then
2963     CRYPTOLIB=-lcrypto
2964     LIBS="$CRYPTOLIB $LIBS"
2965     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2966   fi
2967   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2968   if test $have_k5crypto = yes; then
2969     CRYPTOLIB=-lk5crypto
2970     LIBS="$CRYPTOLIB $LIBS"
2971     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2972   fi
2973   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2974   if test $have_krb5=yes; then
2975     KRB5LIB=-lkrb5
2976     LIBS="$KRB5LIB $LIBS"
2977     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2978   fi
2979   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2980   if test "${with_kerberos5}" = no; then
2981     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2982     if test $have_des425 = yes; then
2983       DESLIB=-ldes425
2984       LIBS="$DESLIB $LIBS"
2985       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2986     else
2987       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2988       if test $have_des = yes; then
2989         DESLIB=-ldes
2990         LIBS="$DESLIB $LIBS"
2991         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2992       fi
2993     fi
2994     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2995     if test $have_krb4 = yes; then
2996       KRB4LIB=-lkrb4
2997       LIBS="$KRB4LIB $LIBS"
2998       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2999     else
3000       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3001       if test $have_krb = yes; then
3002         KRB4LIB=-lkrb
3003         LIBS="$KRB4LIB $LIBS"
3004         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3005       fi
3006     fi
3007   fi
3008
3009   if test "${with_kerberos5}" != no; then
3010     AC_CHECK_HEADERS(krb5.h,
3011       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3012                         [#include <krb5.h>])])
3013   else
3014     AC_CHECK_HEADERS(des.h,,
3015                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3016                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3017     AC_CHECK_HEADERS(krb.h,,
3018                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3019                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3020   fi
3021   AC_CHECK_HEADERS(com_err.h)
3022 fi
3023
3024 AC_SUBST(COM_ERRLIB)
3025 AC_SUBST(CRYPTOLIB)
3026 AC_SUBST(KRB5LIB)
3027 AC_SUBST(DESLIB)
3028 AC_SUBST(KRB4LIB)
3029
3030 AC_CHECK_FUNCS_ONCE(tzset)
3031 AC_MSG_CHECKING(whether localtime caches TZ)
3032 AC_CACHE_VAL(emacs_cv_localtime_cache,
3033 [if test x$ac_cv_func_tzset = xyes; then
3034 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3035 char TZ_GMT0[] = "TZ=GMT0";
3036 char TZ_PST8[] = "TZ=PST8";
3037 main()
3038 {
3039   time_t now = time ((time_t *) 0);
3040   int hour_GMT0, hour_unset;
3041   if (putenv (TZ_GMT0) != 0)
3042     exit (1);
3043   hour_GMT0 = localtime (&now)->tm_hour;
3044   unsetenv("TZ");
3045   hour_unset = localtime (&now)->tm_hour;
3046   if (putenv (TZ_PST8) != 0)
3047     exit (1);
3048   if (localtime (&now)->tm_hour == hour_GMT0)
3049     exit (1);
3050   unsetenv("TZ");
3051   if (localtime (&now)->tm_hour != hour_unset)
3052     exit (1);
3053   exit (0);
3054 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3055 [# If we have tzset, assume the worst when cross-compiling.
3056 emacs_cv_localtime_cache=yes])
3057 else
3058         # If we lack tzset, report that localtime does not cache TZ,
3059         # since we can't invalidate the cache if we don't have tzset.
3060         emacs_cv_localtime_cache=no
3061 fi])dnl
3062 AC_MSG_RESULT($emacs_cv_localtime_cache)
3063 if test $emacs_cv_localtime_cache = yes; then
3064   AC_DEFINE(LOCALTIME_CACHE, 1,
3065             [Define to 1 if localtime caches TZ.])
3066 fi
3067
3068 ok_so_far=yes
3069 AC_CHECK_FUNC(socket, , ok_so_far=no)
3070 if test $ok_so_far = yes; then
3071   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3072 fi
3073 if test $ok_so_far = yes; then
3074   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3075 fi
3076 if test $ok_so_far = yes; then
3077 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3078   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3079             [Define to 1 if you have inet sockets.])
3080 fi
3081
3082 if test -f /usr/lpp/X11/bin/smt.exp; then
3083   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3084             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3085 fi
3086
3087 AC_MSG_CHECKING(whether system supports dynamic ptys)
3088 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3089   AC_MSG_RESULT(yes)
3090   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3091 else
3092   AC_MSG_RESULT(no)
3093 fi
3094
3095 AC_FUNC_FORK
3096
3097 AC_CHECK_FUNCS(snprintf)
3098
3099 dnl Adapted from Haible's version.
3100 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3101   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3102     [[char* cs = nl_langinfo(CODESET);]])],
3103     emacs_cv_langinfo_codeset=yes,
3104     emacs_cv_langinfo_codeset=no)
3105   ])
3106 if test $emacs_cv_langinfo_codeset = yes; then
3107   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3108     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3109 fi
3110
3111 AC_TYPE_MBSTATE_T
3112
3113 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3114   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3115                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3116 if test "$emacs_cv_c_restrict_arr" = yes; then
3117   AC_DEFINE(__restrict_arr, __restrict,
3118     [Define to compiler's equivalent of C99 restrict keyword in array
3119      declarations.  Define as empty for no equivalent.])
3120 fi
3121
3122 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3123 dnl how the tty code is related to POSIX and/or other versions of termios.
3124 dnl The following looks like a useful start.
3125 dnl
3126 dnl AC_SYS_POSIX_TERMIOS
3127 dnl if test $ac_cv_sys_posix_termios = yes; then
3128 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3129 dnl                                and macros for terminal control.])
3130 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3131 dnl fi
3132
3133 dnl Every platform that uses configure (ie every non-MS platform)
3134 dnl supports this.  There is a create-lockfiles option you can
3135 dnl customize if you do not want the lock files to be written.
3136 dnl So it is not clear that this #define still needs to exist.
3137 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3138   so that Emacs can tell instantly when you try to modify a file that
3139   someone else has modified in his/her Emacs.])
3140
3141 dnl Everybody supports this, except MS.
3142 dnl Seems like the kind of thing we should be testing for, though.
3143 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3144 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3145
3146 dnl Everybody supports this, except MS-DOS.
3147 dnl Seems like the kind of thing we should be testing for, though.
3148 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3149 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3150   4.2-compatible sockets.])
3151
3152
3153 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3154
3155 case $opsys in
3156   aix4-2)
3157     dnl Unfortunately without libXmu we cannot support EditRes.
3158     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3159       AC_DEFINE(NO_EDITRES, 1)
3160     fi
3161     ;;
3162
3163   hpux*)
3164     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3165     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3166     AC_DEFINE(NO_EDITRES, 1)
3167     ;;
3168 esac
3169
3170
3171 case $opsys in
3172   darwin | gnu | hpux* | *bsd )
3173     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3174   ;;
3175 esac
3176
3177
3178 case $opsys in
3179   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3180   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3181   hpux* | irix6-5 | openbsd | sol2* | unixware )
3182     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3183     ;;
3184
3185   aix4-2)
3186     dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3187     AC_DEFINE(BROKEN_FIONREAD, 1, [Define if FIONREAD should not be used.])
3188     dnl As we define BROKEN_FIONREAD, SIGIO will be undefined in systty.h.
3189     dnl But, on AIX, SIGAIO, SIGPTY, and SIGPOLL are defined as SIGIO,
3190     dnl which causes compilation error at init_signals in sysdep.c.
3191     dnl So, we define these macros so that syssignal.h detects them
3192     dnl and undefine SIGAIO, SIGPTY and SIGPOLL.
3193     AC_DEFINE(BROKEN_SIGAIO, 1, [Define if SIGAIO should not be used.])
3194     AC_DEFINE(BROKEN_SIGPOLL,1, [Define if SIGPOLL should not be used.])
3195     AC_DEFINE(BROKEN_SIGPTY, 1, [Define if SIGPTY should not be used.])
3196
3197     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3198     dnl the way this system works, libc functions that return malloced
3199     dnl memory use the libc malloc implementation. Calling xfree or
3200     dnl xrealloc on the results of such functions results in a crash.
3201     dnl
3202     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3203     dnl but that does not currently work on this system.
3204     dnl
3205     dnl It is possible to completely override the malloc implementation on
3206     dnl AIX, but that involves putting the malloc functions in a shared
3207     dnl library and setting the MALLOCTYPE environment variable to point to
3208     dnl that shared library.
3209     dnl
3210     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3211     dnl to avoid a crash just use the Emacs implementation for that function.
3212     dnl
3213     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3214     dnl of this file, so that we do not check for get_current_dir_name
3215     dnl on AIX.  But that might be fragile if something else ends
3216     dnl up testing for get_current_dir_name as a dependency.
3217     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3218       get_current_dir_name should not be used.])
3219     ;;
3220
3221   freebsd)
3222     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3223     dnl writes/reads on a PTY, read(2) returns bogus data:
3224     dnl
3225     dnl write(2)  1022 bytes
3226     dnl write(2)   954 bytes, get EAGAIN
3227     dnl read(2)   1024 bytes in process_read_output
3228     dnl read(2)     11 bytes in process_read_output
3229     dnl
3230     dnl That is, read(2) returns more bytes than have ever been written
3231     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3232     dnl successfully after processing (for example with CRs added if the
3233     dnl terminal is set up that way which it is here).  The same bytes will
3234     dnl be seen again in a later read(2), without the CRs.
3235     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3236       work around an issue when reading from a PTY.])
3237     ;;
3238
3239   dnl Define the following so emacs symbols will not conflict with those
3240   dnl in the System framework.  Otherwise -prebind will not work.
3241   darwin)
3242     AC_DEFINE(NO_ABORT, 1, [Do not define abort in emacs.c.])
3243     ;;
3244 esac
3245
3246 case $opsys in
3247   gnu-* | sol2-10 )
3248     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3249     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3250   ;;
3251 esac
3252
3253 case $opsys in
3254   darwin | freebsd | netbsd | openbsd )
3255     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3256       close a pty to make it a controlling terminal (it is already a
3257       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3258   ;;
3259 esac
3260
3261 dnl FIXME Surely we can test for this rather than hard-code it.
3262 case $opsys in
3263   netbsd | openbsd) sound_device="/dev/audio" ;;
3264   *) sound_device="/dev/dsp" ;;
3265 esac
3266
3267 dnl Used in sound.c
3268 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3269   [Name of the default sound device.])
3270
3271
3272 dnl Emacs can read input using SIGIO and buffering characters itself,
3273 dnl or using CBREAK mode and making C-g cause SIGINT.
3274 dnl The choice is controlled by the variable interrupt_input.
3275 dnl
3276 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3277 dnl
3278 dnl Emacs uses the presence or absence of the SIGIO and BROKEN_SIGIO macros
3279 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3280 dnl INTERRUPT_INPUT to decide whether to use it by default.
3281 dnl
3282 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3283 dnl CBREAK mode has two disadvantages
3284 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3285 dnl I hear that in system V this problem does not exist.
3286 dnl 2) Control-G causes output to be discarded.
3287 dnl I do not know whether this can be fixed in system V.
3288 dnl
3289 dnl Another method of doing input is planned but not implemented.
3290 dnl It would have Emacs fork off a separate process
3291 dnl to read the input and send it to the true Emacs process
3292 dnl through a pipe.
3293 case $opsys in
3294   darwin | gnu-linux | gnu-kfreebsd )
3295     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3296   ;;
3297 esac
3298
3299
3300 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3301 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3302 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3303 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3304 dnl taking float or double parameters.
3305 case $opsys in
3306   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3307     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3308       file defines `NeedWidePrototypes' as `NO'.])
3309   ;;
3310 esac
3311
3312
3313 dnl Used in process.c, this must be a loop, even if it only runs once.
3314 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3315 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3316 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3317 dnl trying suffixes 0-16.
3318 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3319   first PTY, if PTYs are supported.])
3320 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3321 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3322   end of a PTY, if non-standard.])
3323 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3324   end of a PTY, if non-standard.])
3325
3326 case $opsys in
3327   aix4-2 )
3328     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)] )
3329     dnl You allocate a pty by opening /dev/ptc to get the master side.
3330     dnl To get the name of the slave side, you just ttyname() the master side.
3331     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");] )
3332     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));] )
3333     ;;
3334
3335   cygwin )
3336     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)] )
3337     dnl multi-line AC_DEFINEs are hard. :(
3338     AC_DEFINE(PTY_OPEN, [ do { int dummy; SIGMASKTYPE mask; mask = sigblock (sigmask (SIGCHLD)); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; sigsetmask (mask); if (fd >= 0) emacs_close (dummy); } while (0)] )
3339     AC_DEFINE(PTY_NAME_SPRINTF, [] )
3340     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [] )
3341     ;;
3342
3343   darwin )
3344     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)] )
3345     dnl Not used, because PTY_ITERATION is defined.
3346     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3347     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3348     dnl But we don't have to block SIGCHLD because it is blocked in the
3349     dnl implementation of grantpt.
3350     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)] )
3351     AC_DEFINE(PTY_NAME_SPRINTF, [] )
3352     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [] )
3353     ;;
3354
3355   gnu | freebsd | netbsd | openbsd )
3356     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3357     ;;
3358
3359   gnu-linux | gnu-kfreebsd )
3360     dnl if HAVE_GRANTPT
3361     if test "x$ac_cv_func_grantpt" = xyes; then
3362       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3363       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)] )
3364       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3365       dnl to prevent sigchld_handler from intercepting the child's death.
3366       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname; sigblock (sigmask (SIGCHLD)); if (grantpt (fd) == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname(fd))) { sigunblock (sigmask (SIGCHLD)); close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); sigunblock (sigmask (SIGCHLD)); }] )
3367       dnl if HAVE_GETPT
3368       if test "x$ac_cv_func_getpt" = xyes; then
3369         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3370         AC_DEFINE(PTY_NAME_SPRINTF, [] )
3371       else
3372         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");] )
3373       fi
3374     else
3375       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3376     fi
3377     ;;
3378
3379   hpux*)
3380     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3381     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);] )
3382     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);] )
3383     ;;
3384
3385   irix6-5 )
3386     dnl It looks like this cannot be right, because it is not a loop.
3387     dnl However, process.c actually does this:
3388     dnl # ifndef __sgi
3389     dnl   continue;
3390     dnl # else
3391     dnl   return -1;
3392     dnl # endif
3393     dnl which presumably makes it OK, since irix == sgi (?).
3394     dnl FIXME it seems like this special treatment is unnecessary?
3395     dnl Why can't irix use a single-trip loop like eg cygwin?
3396     AC_DEFINE(PTY_ITERATION, [])
3397     dnl Not used, because PTY_ITERATION is defined.
3398     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3399     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }] )
3400     dnl No need to get the pty name at all.
3401     AC_DEFINE(PTY_NAME_SPRINTF, [] )
3402     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3403     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [] )
3404     ;;
3405
3406   sol2* )
3407     dnl This change means that we don't loop through allocate_pty too
3408     dnl many times in the (rare) event of a failure.
3409     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3410     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");] )
3411     dnl Uses sigblock/sigunblock rather than sighold/sigrelse,
3412     dnl which appear to be BSD4.1 specific.  It may also be appropriate
3413     dnl for SVR4.x (x<2) but I'm not sure.   fnf@cygnus.com
3414     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3415     dnl from intercepting that death.  If any child but grantpt's should die
3416     dnl within, it should be caught after sigrelse(2).
3417     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock (sigmask (SIGCLD)); if (grantpt (fd) == -1) { emacs_close (fd); return -1; } sigunblock (sigmask (SIGCLD)); if (unlockpt (fd) == -1) { emacs_close (fd); return -1; } if (!(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }] )
3418     ;;
3419
3420   dnl Comments are as per sol2*.
3421   unixware )
3422     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3423     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");] )
3424     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock(sigmask(SIGCLD)); if (grantpt(fd) == -1) fatal("could not grant slave pty"); sigunblock(sigmask(SIGCLD)); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }] )
3425     ;;
3426 esac
3427
3428
3429 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3430 "typing" a signal character on the pty.])
3431
3432 case $opsys in
3433   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3434   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3435   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3436     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3437     ;;
3438
3439   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3440   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3441   gnu-linux | gnu-kfreebsd )
3442
3443     AC_MSG_CHECKING([for signals via characters])
3444     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3445 #include <linux/version.h>
3446 #if LINUX_VERSION_CODE < 0x20400
3447 # error "Linux version too old"
3448 #endif
3449       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3450
3451     AC_MSG_RESULT([$emacs_signals_via_chars])
3452     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3453     ;;
3454 esac
3455
3456
3457 dnl Used in dispnew.c
3458 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3459 buffer of a stdio stream.])
3460
3461 dnl FIXME just PENDING_OUTPUT_COUNT should suffice.
3462 AH_TEMPLATE(GNU_LIBRARY_PENDING_OUTPUT_COUNT, [Value of
3463 PENDING_OUTPUT_COUNT if using the GNU C library.])
3464
3465 case $opsys in
3466   cygwin | darwin | freebsd | netbsd | openbsd )
3467     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3468     ;;
3469
3470   unixware)
3471     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3472     ;;
3473
3474   gnu | gnu-linux | gnu-kfreebsd )
3475     AC_MSG_CHECKING([for style of pending output formalism])
3476     dnl In autoconf 2.67 (?) and later, we could use a single test
3477     dnl since the preprocessed output is accessible in "conftest.i".
3478     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3479 #include <stdio.h>
3480 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3481 # error "stdio definitions not found"
3482 #endif
3483       ]], [[]])], emacs_pending_output=new, emacs_pending_output=unknown)
3484
3485       if test $emacs_pending_output = unknown; then
3486         case $opsys in
3487           gnu-linux | gnu-kfreebsd)
3488             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3489 #include <stdio.h>
3490 #ifndef __UCLIBC__
3491 # error "not using uclibc"
3492 #endif
3493             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3494             ;;
3495         esac
3496       fi
3497
3498       AC_MSG_RESULT([$emacs_pending_output])
3499
3500       case $emacs_pending_output in
3501         new)
3502           dnl New C libio names.
3503           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3504             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3505           ;;
3506         uclibc)
3507           dnl Using the uClibc library.
3508           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3509             [((FILE)->__bufpos - (FILE)->__bufstart)])
3510           ;;
3511         old)
3512           dnl Old C++ iostream names.
3513           AC_DEFINE(GNU_LIBRARY_PENDING_OUTPUT_COUNT(FILE),
3514             [((FILE)->_pptr - (FILE)->_pbase)])
3515           ;;
3516       esac
3517     ;;
3518 esac
3519
3520
3521 dnl Used in vm-limit.c
3522 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3523 dnl Used in lisp.h, emacs.c, mem-limits.h
3524 dnl NEWS.18 describes this as "a number which contains
3525 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3526 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3527 stored in a Lisp_Object.])
3528 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3529
3530 case $opsys in
3531   gnu)
3532     dnl libc defines data_start.
3533     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3534     ;;
3535
3536   hpux*)
3537     dnl The data segment on this machine always starts at address 0x40000000.
3538     AC_DEFINE(DATA_START, [0x40000000])
3539     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3540     ;;
3541   irix6-5)
3542     AC_DEFINE(DATA_START, [0x10000000])
3543     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3544     ;;
3545 esac
3546
3547
3548 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3549 AH_TEMPLATE(TAB3, [Undocumented.])
3550
3551 case $opsys in
3552   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3553
3554   gnu | freebsd | netbsd | openbsd )
3555     AC_DEFINE(TABDLY, OXTABS, [Undocumented.] )
3556     AC_DEFINE(TAB3, OXTABS)
3557     ;;
3558
3559   gnu-linux | gnu-kfreebsd )
3560     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3561     dnl library, we cannot get the maximum address for brk.
3562     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3563 #ifndef __i386__
3564 # error "not i386"
3565 #endif
3566       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3567     ;;
3568
3569   hpux*)
3570     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3571       run_time_remap; for HPUX.])
3572     ;;
3573
3574   irix6-5)
3575     dnl Ulimit(UL_GMEMLIM) is busted...
3576     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3577     ;;
3578 esac
3579
3580
3581 dnl Used in xfaces.c.
3582 case $opsys in
3583   hpux* | sol2* )
3584     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3585       some systems, where it requires time.h.])
3586     ;;
3587 esac
3588
3589
3590 case $opsys in
3591   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3592   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3593   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3594   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3595   cygwin)
3596     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3597       G_SLICE environment variable to "always-malloc" at startup, if
3598       using GTK.])
3599     ;;
3600
3601   gnu) opsysfile="s/bsd-common.h" ;;
3602
3603   gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3604
3605   hpux11)
3606     dnl See comments in sysdep.c:sys_signal.
3607     dnl SA_RESTART resets the timeout of `select' on hpux11.
3608     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3609     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3610       be used in batch mode.])
3611     dnl It works to open the pty's tty in the parent (Emacs), then
3612     dnl close and reopen it in the child.
3613     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3614       works to open a pty's tty in the parent process, then close and
3615       reopen it in the child.])
3616
3617     opsysfile="s/hpux10-20.h"
3618     ;;
3619
3620   irix6-5)
3621     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3622       use VSUSP instead of VSWTCH.])
3623     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
3624       should not call setpgrp.])
3625     ;;
3626
3627   openbsd) opsysfile="s/netbsd.h" ;;
3628
3629   sol2-10)
3630     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3631       on Solaris.])
3632     opsysfile="s/sol2-6.h"
3633     ;;
3634 esac
3635
3636 # Set up the CFLAGS for real compilation, so we can substitute it.
3637 CFLAGS="$REAL_CFLAGS"
3638 CPPFLAGS="$REAL_CPPFLAGS"
3639
3640 ## Hack to detect a buggy GCC version.
3641 if test "x$GCC" = xyes \
3642    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3643    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3644    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3645    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3646 fi
3647
3648 version=$PACKAGE_VERSION
3649
3650 ### Specify what sort of things we'll be editing into Makefile and config.h.
3651 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3652 AC_SUBST(version)
3653 AC_SUBST(configuration)
3654 ## Unused?
3655 AC_SUBST(canonical)
3656 AC_SUBST(srcdir)
3657 AC_SUBST(prefix)
3658 AC_SUBST(exec_prefix)
3659 AC_SUBST(bindir)
3660 AC_SUBST(datadir)
3661 AC_SUBST(sharedstatedir)
3662 AC_SUBST(libexecdir)
3663 AC_SUBST(mandir)
3664 AC_SUBST(infodir)
3665 AC_SUBST(lispdir)
3666 AC_SUBST(leimdir)
3667 AC_SUBST(standardlisppath)
3668 AC_SUBST(locallisppath)
3669 AC_SUBST(lisppath)
3670 AC_SUBST(x_default_search_path)
3671 AC_SUBST(etcdir)
3672 AC_SUBST(archlibdir)
3673 AC_SUBST(docdir)
3674 AC_SUBST(bitmapdir)
3675 AC_SUBST(gamedir)
3676 AC_SUBST(gameuser)
3677 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3678 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3679 ## end of LIBX_BASE, but nothing ever set it.
3680 AC_SUBST(LD_SWITCH_X_SITE)
3681 AC_SUBST(C_SWITCH_X_SITE)
3682 AC_SUBST(GNUSTEP_CFLAGS)
3683 AC_SUBST(CFLAGS)
3684 ## Used in lwlib/Makefile.in.
3685 AC_SUBST(X_TOOLKIT_TYPE)
3686 if test -n "${opsysfile}"; then
3687   S_FILE="\$(srcdir)/${opsysfile}"
3688 else
3689   S_FILE=
3690 fi
3691 AC_SUBST(S_FILE)
3692 AC_SUBST(ns_appdir)
3693 AC_SUBST(ns_appbindir)
3694 AC_SUBST(ns_appresdir)
3695 AC_SUBST(ns_appsrc)
3696 AC_SUBST(GNU_OBJC_CFLAGS)
3697 AC_SUBST(OTHER_FILES)
3698
3699 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3700                    [Define to the canonical Emacs configuration name.])
3701 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3702                    [Define to the options passed to configure.])
3703 if test -n "$opsysfile"; then
3704   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3705                      [Define to the used os dependent file.])
3706 fi
3707
3708 XMENU_OBJ=
3709 XOBJ=
3710 FONT_OBJ=
3711 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3712   AC_DEFINE(HAVE_X_WINDOWS, 1,
3713             [Define to 1 if you want to use the X window system.])
3714   XMENU_OBJ=xmenu.o
3715   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3716   FONT_OBJ=xfont.o
3717   if test "$HAVE_XFT" = "yes"; then
3718     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3719   elif test "$HAVE_FREETYPE" = "yes"; then
3720     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3721   fi
3722   AC_SUBST(FONT_OBJ)
3723 fi
3724 AC_SUBST(XMENU_OBJ)
3725 AC_SUBST(XOBJ)
3726 AC_SUBST(FONT_OBJ)
3727
3728 WIDGET_OBJ=
3729 MOTIF_LIBW=
3730 if test "${USE_X_TOOLKIT}" != "none" ; then
3731   WIDGET_OBJ=widget.o
3732   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3733   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3734     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3735   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3736     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3737     MOTIF_LIBW=-lXm
3738     case "$opsys" in
3739       gnu-linux)
3740         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3741         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3742         ;;
3743
3744       unixware)
3745         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3746         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3747         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3748         ;;
3749
3750       aix4-2)
3751         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3752         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3753         ;;
3754     esac
3755     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3756   fi
3757 fi
3758 AC_SUBST(WIDGET_OBJ)
3759
3760 TOOLKIT_LIBW=
3761 case "$USE_X_TOOLKIT" in
3762   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3763   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3764   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3765 esac
3766 AC_SUBST(TOOLKIT_LIBW)
3767
3768 if test "$USE_X_TOOLKIT" = "none"; then
3769   LIBXT_OTHER="\$(LIBXSM)"
3770   OLDXMENU_TARGET="really-oldXMenu"
3771 else
3772   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3773   OLDXMENU_TARGET="really-lwlib"
3774 fi
3775 AC_SUBST(LIBXT_OTHER)
3776
3777 ## The X Menu stuff is present in the X10 distribution, but missing
3778 ## from X11.  If we have X10, just use the installed library;
3779 ## otherwise, use our own copy.
3780 if test "${HAVE_X11}" = "yes" ; then
3781   AC_DEFINE(HAVE_X11, 1,
3782             [Define to 1 if you want to use version 11 of X windows.
3783              Otherwise, Emacs expects to use version 10.])
3784
3785   if test "$USE_X_TOOLKIT" = "none"; then
3786     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3787   else
3788     OLDXMENU="\${lwlibdir}/liblw.a"
3789   fi
3790   LIBXMENU="\$(OLDXMENU)"
3791   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3792   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3793 else
3794   ## For a syntactically valid Makefile; not actually used for anything.
3795   ## See comments in src/Makefile.in.
3796   OLDXMENU=nothing
3797   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3798   if test "${HAVE_X_WINDOWS}" = "yes"; then
3799     LIBXMENU="-lXMenu"
3800   else
3801     LIBXMENU=
3802   fi
3803   LIBX_OTHER=
3804   OLDXMENU_DEPS=
3805 fi
3806
3807 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3808   OLDXMENU_TARGET=
3809   OLDXMENU=nothing
3810   LIBXMENU=
3811   OLDXMENU_DEPS=
3812 fi
3813
3814 AC_SUBST(OLDXMENU_TARGET)
3815 AC_SUBST(OLDXMENU)
3816 AC_SUBST(LIBXMENU)
3817 AC_SUBST(LIBX_OTHER)
3818 AC_SUBST(OLDXMENU_DEPS)
3819
3820 if test "${HAVE_MENUS}" = "yes" ; then
3821   AC_DEFINE(HAVE_MENUS, 1,
3822             [Define to 1 if you have mouse menus.
3823              (This is automatic if you use X, but the option to specify it remains.)
3824              It is also defined with other window systems that support xmenu.c.])
3825 fi
3826
3827 if test "${GNU_MALLOC}" = "yes" ; then
3828   AC_DEFINE(GNU_MALLOC, 1,
3829             [Define to 1 if you want to use the GNU memory allocator.])
3830 fi
3831
3832 RALLOC_OBJ=
3833 if test "${REL_ALLOC}" = "yes" ; then
3834   AC_DEFINE(REL_ALLOC, 1,
3835             [Define REL_ALLOC if you want to use the relocating allocator for
3836              buffer space.])
3837
3838   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3839 fi
3840 AC_SUBST(RALLOC_OBJ)
3841
3842 if test "$opsys" = "cygwin"; then
3843   CYGWIN_OBJ="sheap.o"
3844   ## Cygwin differs because of its unexec().
3845   PRE_ALLOC_OBJ=
3846   POST_ALLOC_OBJ=lastfile.o
3847 else
3848   CYGWIN_OBJ=
3849   PRE_ALLOC_OBJ=lastfile.o
3850   POST_ALLOC_OBJ=
3851 fi
3852 AC_SUBST(CYGWIN_OBJ)
3853 AC_SUBST(PRE_ALLOC_OBJ)
3854 AC_SUBST(POST_ALLOC_OBJ)
3855
3856 case "$opsys" in
3857   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3858
3859   darwin)
3860    ## The -headerpad option tells ld (see man page) to leave room at the
3861    ## end of the header for adding load commands.  Needed for dumping.
3862    ## 0x690 is the total size of 30 segment load commands (at 56
3863    ## each); under Cocoa 31 commands are required.
3864    if test "$HAVE_NS" = "yes"; then
3865      libs_nsgui="-framework AppKit"
3866      headerpad_extra=6C8
3867    else
3868      libs_nsgui=
3869      headerpad_extra=690
3870    fi
3871    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3872
3873    ## This is here because src/Makefile.in did some extra fiddling around
3874    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3875    ##   #ifndef LD_SWITCH_SYSTEM
3876    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3877    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3878    ## not using gcc, darwin.
3879    ## Because this was done in src/Makefile.in, the resulting part of
3880    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3881    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3882    ## rather than LD_SWITCH_SYSTEM.
3883    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3884      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3885    ;;
3886
3887   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3888   ## find X at run-time.
3889   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3890   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3891   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3892   ## had different values in configure (in ac_link) and src/Makefile.in.
3893   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3894   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3895
3896   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3897 esac
3898
3899 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3900   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3901 fi
3902
3903 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3904
3905
3906 LD_FIRSTFLAG=
3907 ORDINARY_LINK=
3908 case "$opsys" in
3909   ## gnu: GNU needs its own crt0.
3910   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3911
3912   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3913   ## library search parth, i.e. it won't search /usr/lib for libc and
3914   ## friends.  Using -nostartfiles instead avoids this problem, and
3915   ## will also work on earlier NetBSD releases.
3916   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3917
3918   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3919   ##   MkLinux/LinuxPPC needs this.
3920   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3921   gnu-*)
3922     case "$canonical" in
3923       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3924     esac
3925     ;;
3926 esac
3927
3928
3929 if test "x$ORDINARY_LINK" = "xyes"; then
3930
3931   LD_FIRSTFLAG=""
3932   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3933
3934 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3935 ## freebsd, gnu-* not on powerpc*|s390x*.
3936 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3937
3938   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3939   ## places that are difficult to figure out at make time.  Fortunately,
3940   ## these same versions allow you to pass arbitrary flags on to the
3941   ## linker, so there is no reason not to use it as a linker.
3942   ##
3943   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3944   ## searching for libraries in its internal directories, so we have to
3945   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3946   LD_FIRSTFLAG="-nostdlib"
3947 fi
3948
3949 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3950 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3951
3952 AC_SUBST(LD_FIRSTFLAG)
3953
3954
3955 ## FIXME? The logic here is not precisely the same as that above.
3956 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3957 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3958 LIB_GCC=
3959 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3960
3961   case "$opsys" in
3962     freebsd|netbsd|openbsd) LIB_GCC= ;;
3963
3964     gnu-*)
3965       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3966       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3967       case $host_cpu in
3968       arm*)
3969         LIB_GCC="-lgcc_s"
3970         ;;
3971       *)
3972         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3973         ## immediately undefine it again and redefine it to empty.
3974         ## Was the C_SWITCH_X_SITE part really necessary?
3975 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3976         LIB_GCC=
3977         ;;
3978       esac
3979       ;;
3980
3981     ## Ask GCC where to find libgcc.a.
3982     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3983   esac
3984 fi                              dnl if $GCC
3985 AC_SUBST(LIB_GCC)
3986
3987
3988 ## If we're using X11/GNUstep, define some consequences.
3989 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3990   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3991   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3992 fi
3993
3994
3995 AH_TOP([/* GNU Emacs site configuration template file.
3996
3997 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3998   Free Software Foundation, Inc.
3999
4000 This file is part of GNU Emacs.
4001
4002 GNU Emacs is free software: you can redistribute it and/or modify
4003 it under the terms of the GNU General Public License as published by
4004 the Free Software Foundation, either version 3 of the License, or
4005 (at your option) any later version.
4006
4007 GNU Emacs is distributed in the hope that it will be useful,
4008 but WITHOUT ANY WARRANTY; without even the implied warranty of
4009 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4010 GNU General Public License for more details.
4011
4012 You should have received a copy of the GNU General Public License
4013 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4014
4015
4016 /* No code in Emacs #includes config.h twice, but some bits of code
4017    intended to work with other packages as well (like gmalloc.c)
4018    think they can include it as many times as they like.  */
4019 #ifndef EMACS_CONFIG_H
4020 #define EMACS_CONFIG_H
4021 ])dnl
4022
4023 AH_BOTTOM([
4024 /* On AIX 3 this must be included before any other include file.  */
4025 #include <alloca.h>
4026 #if ! HAVE_ALLOCA
4027 # error "alloca not available on this machine"
4028 #endif
4029
4030 /* Define AMPERSAND_FULL_NAME if you use the convention
4031    that & in the full name stands for the login id.  */
4032 /* Turned on June 1996 supposing nobody will mind it.  */
4033 #define AMPERSAND_FULL_NAME
4034
4035 /* `subprocesses' should be defined if you want to
4036    have code for asynchronous subprocesses
4037    (as used in M-x compile and M-x shell).
4038    Only MSDOS does not support this (it overrides
4039    this in its config_opsysfile below).  */
4040
4041 #define subprocesses
4042
4043 /* Include the os dependent file.  */
4044 #ifdef config_opsysfile
4045 # include config_opsysfile
4046 #endif
4047
4048 /* Mac OS X / GNUstep need a bit more pure memory.  Of the existing knobs,
4049    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
4050 #ifdef HAVE_NS
4051 #if defined NS_IMPL_GNUSTEP
4052 #  define SYSTEM_PURESIZE_EXTRA 30000
4053 #elif defined DARWIN_OS
4054 #  define SYSTEM_PURESIZE_EXTRA 200000
4055 #endif
4056 #endif
4057
4058 #ifdef emacs /* Don't do this for lib-src.  */
4059 /* Tell regex.c to use a type compatible with Emacs.  */
4060 #define RE_TRANSLATE_TYPE Lisp_Object
4061 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
4062 #ifdef make_number
4063 /* If make_number is a macro, use it.  */
4064 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
4065 #else
4066 /* If make_number is a function, avoid it.  */
4067 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
4068 #endif
4069 #endif
4070
4071 #include <string.h>
4072 #include <stdlib.h>
4073
4074 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
4075 #define NO_INLINE __attribute__((noinline))
4076 #else
4077 #define NO_INLINE
4078 #endif
4079
4080 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
4081 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
4082 #else
4083 #define EXTERNALLY_VISIBLE
4084 #endif
4085
4086 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
4087 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
4088 #else
4089 # define ATTRIBUTE_FORMAT(spec) /* empty */
4090 #endif
4091
4092 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
4093 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
4094    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
4095 #else
4096 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
4097    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
4098 #endif
4099
4100 #define ATTRIBUTE_CONST _GL_ATTRIBUTE_CONST
4101
4102 /* Some versions of GNU/Linux define noinline in their headers.  */
4103 #ifdef noinline
4104 #undef noinline
4105 #endif
4106
4107 /* These won't be used automatically yet.  We also need to know, at least,
4108    that the stack is continuous.  */
4109 #ifdef __GNUC__
4110 #  ifndef GC_SETJMP_WORKS
4111   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
4112 #    define GC_SETJMP_WORKS 1
4113 #  endif
4114 #endif
4115
4116 #endif /* EMACS_CONFIG_H */
4117
4118 /*
4119 Local Variables:
4120 mode: c
4121 End:
4122 */
4123 ])dnl
4124
4125 #### Report on what we decided to do.
4126 #### Report GTK as a toolkit, even if it doesn't use Xt.
4127 #### It makes printing result more understandable as using GTK sets
4128 #### toolkit_scroll_bars to yes by default.
4129 if test "${HAVE_GTK}" = "yes"; then
4130   USE_X_TOOLKIT=GTK
4131 fi
4132
4133 echo "
4134 Configured for \`${canonical}'.
4135
4136   Where should the build process find the source code?    ${srcdir}
4137   What operating system file should Emacs use?            ${opsysfile-none}
4138   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4139   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4140   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4141   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4142   What window system should Emacs use?                    ${window_system}
4143   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4144
4145 if test -n "${x_includes}"; then
4146 echo "  Where do we find X Windows header files?                ${x_includes}"
4147 else
4148 echo "  Where do we find X Windows header files?                Standard dirs"
4149 fi
4150 if test -n "${x_libraries}"; then
4151 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4152 else
4153 echo "  Where do we find X Windows libraries?                   Standard dirs"
4154 fi
4155
4156 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4157 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4158 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4159 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4160 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4161 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4162 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4163 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4164
4165 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4166 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4167 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4168 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4169 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4170 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4171 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4172
4173 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4174 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4175 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4176 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4177
4178 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4179 echo
4180
4181 if test -n "${EMACSDATA}"; then
4182    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4183 fi
4184 if test -n "${EMACSDOC}"; then
4185    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4186 fi
4187
4188 echo
4189
4190 if test "$HAVE_NS" = "yes"; then
4191    echo
4192    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4193 The installed application will go to nextstep/Emacs.app and can be
4194 run or moved from there."
4195    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4196       echo "The application will be fully self-contained."
4197     else
4198       echo "The lisp resources for the application will be installed under ${prefix}.
4199 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4200 to run if these resources are not installed."
4201    fi
4202    echo
4203 fi
4204
4205 if test "${opsys}" = "cygwin"; then
4206   case `uname -r` in
4207     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4208            echo
4209            ;;
4210   esac
4211 fi
4212
4213 # Remove any trailing slashes in these variables.
4214 [test "${prefix}" != NONE &&
4215   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4216 test "${exec_prefix}" != NONE &&
4217   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4218
4219 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4220 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4221 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4222 dnl (else you get "no `Makefile.am' found for any configure output").
4223 dnl This will work, but you get a config.status that is not quite right
4224 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4225 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4226 dnl it seems better to just live with the duplication.
4227 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4228
4229 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4230        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4231        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4232        leim/Makefile])
4233
4234 dnl test/ is not present in release tarfiles.
4235 opt_makefile=test/automated/Makefile
4236
4237 if test -f $srcdir/${opt_makefile}.in; then
4238   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4239   dnl Again, it's best not to use a variable.  Though you can add
4240   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4241   AC_CONFIG_FILES([test/automated/Makefile])
4242 fi
4243
4244
4245 dnl admin/ may or may not be present.
4246 opt_makefile=admin/unidata/Makefile
4247
4248 if test -f $srcdir/${opt_makefile}.in; then
4249   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4250   AC_CONFIG_FILES([admin/unidata/Makefile])
4251 fi
4252
4253
4254 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4255
4256 AC_SUBST(SUBDIR_MAKEFILES_IN)
4257
4258 dnl Make the necessary directories, if they don't exist.
4259 AC_CONFIG_COMMANDS([mkdirs], [
4260 for dir in etc lisp ; do
4261   test -d ${dir} || mkdir ${dir}
4262 done
4263 ])
4264
4265 dnl You might wonder (I did) why epaths.h is generated by running make,
4266 dnl rather than just letting configure generate it from epaths.in.
4267 dnl One reason is that the various paths are not fully expanded (see above);
4268 dnl eg gamedir=${prefix}/var/games/emacs.
4269 dnl Secondly, the GNU Coding standards require that one should be able
4270 dnl to run `make prefix=/some/where/else' and override the values set
4271 dnl by configure.  This also explains the `move-if-change' test and
4272 dnl the use of force in the `epaths-force' rule in Makefile.in.
4273 AC_CONFIG_COMMANDS([epaths], [
4274 echo creating src/epaths.h
4275 ${MAKE-make} epaths-force
4276 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4277
4278 AC_CONFIG_COMMANDS([gdbinit], [
4279 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4280   echo creating src/.gdbinit
4281   echo source $srcdir/src/.gdbinit > src/.gdbinit
4282 fi
4283 ])
4284
4285 AC_OUTPUT