lisp/map-ynp.el

   1 ;;; map-ynp.el --- General-purpose boolean question-asker.
   2
   3 ;;; Copyright (C) 1991, 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Roland McGrath <roland@gnu.ai.mit.edu>
   6 ;; Keywords: lisp, extensions
   7
   8 ;;; This program is free software; you can redistribute it and/or modify
   9 ;;; it under the terms of the GNU General Public License as published by
  10 ;;; the Free Software Foundation; either version 2, or (at your option)
  11 ;;; any later version.
  12 ;;;
  13 ;;; This program is distributed in the hope that it will be useful,
  14 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;;; GNU General Public License for more details.
  17 ;;;
  18 ;;; A copy of the GNU General Public License can be obtained from this
  19 ;;; program's author (send electronic mail to roland@ai.mit.edu) or from
  20 ;;; the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA
  21 ;;; 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; map-y-or-n-p is a general-purpose question-asking function.
  26 ;;; It asks a series of y/n questions (a la y-or-n-p), and decides to
  27 ;;; applies an action to each element of a list based on the answer.
  28 ;;; The nice thing is that you also get some other possible answers
  29 ;;; to use, reminiscent of query-replace: ! to answer y to all remaining
  30 ;;; questions; ESC or q to answer n to all remaining questions; . to answer
  31 ;;; y once and then n for the remainder; and you can get help with C-h.
  32
  33 ;;; Code:
  34
  35 ;;;###autoload
  36 (defun map-y-or-n-p (prompter actor list &optional help action-alist)
  37   "Ask a series of boolean questions.
  38 Takes args PROMPTER ACTOR LIST, and optional args HELP and ACTION-ALIST.
  39
  40 LIST is a list of objects, or a function of no arguments to return the next
  41 object or nil.
  42
  43 If PROMPTER is a string, the prompt is \(format PROMPTER OBJECT\).  If not
  44 a string, PROMPTER is a function of one arg (an object from LIST), which
  45 returns a string to be used as the prompt for that object.  If the return
  46 value is not a string, it is eval'd to get the answer; it may be nil to
  47 ignore the object, t to act on the object without asking the user, or a
  48 form to do a more complex prompt.
  49
  50 ACTOR is a function of one arg (an object from LIST),
  51 which gets called with each object that the user answers `yes' for.
  52
  53 If HELP is given, it is a list (OBJECT OBJECTS ACTION),
  54 where OBJECT is a string giving the singular noun for an elt of LIST;
  55 OBJECTS is the plural noun for elts of LIST, and ACTION is a transitive
  56 verb describing ACTOR.  The default is \(\"object\" \"objects\" \"act on\"\).
  57
  58 At the prompts, the user may enter y, Y, or SPC to act on that object;
  59 n, N, or DEL to skip that object; ! to act on all following objects;
  60 ESC or q to exit (skip all following objects); . (period) to act on the
  61 current object and then exit; or \\[help-command] to get help.
  62
  63 If ACTION-ALIST is given, it is an alist (KEY FUNCTION HELP) of extra keys
  64 that will be accepted.  KEY is a character; FUNCTION is a function of one
  65 arg (an object from LIST); HELP is a string.  When the user hits KEY,
  66 FUNCTION is called.  If it returns non-nil, the object is considered
  67 \"acted upon\", and the next object from LIST is processed.  If it returns
  68 nil, the prompt is repeated for the same object.
  69
  70 Returns the number of actions taken."
  71   (let* ((old-help-form help-form)
  72          (help-form (let ((object (if help (nth 0 help) "object"))
  73                           (objects (if help (nth 1 help) "objects"))
  74                           (action (if help (nth 2 help) "act on")))
  75                       (concat (format "Type SPC or `y' to %s the current %s;
  76 DEL or `n' to skip the current %s;
  77 ! to %s all remaining %s;
  78 ESC or `q' to exit;\n"
  79                                       action object object action objects)
  80                               (mapconcat (function
  81                                           (lambda (elt)
  82                                             (format "%c to %s"
  83                                                     (nth 0 elt)
  84                                                     (nth 2 elt))))
  85                                          action-alist
  86                                          ";\n")
  87                               (if action-alist ";\n")
  88                               (format "or . (period) to %s \
  89 the current %s and exit."
  90                                       action object))))
  91          (user-keys (if action-alist
  92                         (concat (mapconcat (function
  93                                             (lambda (elt)
  94                                               (key-description
  95                                                (char-to-string (car elt)))))
  96                                            action-alist ", ")
  97                                 " ")
  98                       ""))
  99          (actions 0)
 100          prompt char elt tail
 101          (next (if (or (symbolp list)
 102                        (subrp list)
 103                        (byte-code-function-p list)
 104                        (and (consp list)
 105                             (eq (car list) 'lambda)))
 106                    (function (lambda ()
 107                                (setq elt (funcall list))))
 108                  (function (lambda ()
 109                              (if list
 110                                  (progn
 111                                    (setq elt (car list)
 112                                          list (cdr list))
 113                                    t)
 114                                nil))))))
 115     (if (stringp prompter)
 116         (setq prompter (` (lambda (object)
 117                             (format (, prompter) object)))))
 118     (while (funcall next)
 119       (setq prompt (funcall prompter elt))
 120       (if (stringp prompt)
 121           (progn
 122             ;; Prompt the user about this object.
 123             (let ((cursor-in-echo-area t))
 124               (message "%s(y, n, !, ., q, %sor %s) "
 125                        prompt user-keys
 126                        (key-description (char-to-string help-char)))
 127               (setq char (read-char)))
 128             (cond ((or (= ?q char)
 129                        (= ?\e char))
 130                    (setq next (function (lambda () nil))))
 131                   ((or (= ?y char)
 132                        (= ?Y char)
 133                        (= ?  char))
 134                    ;; Act on the object.
 135                    (let ((help-form old-help-form))
 136                      (funcall actor elt))
 137                    (setq actions (1+ actions)))
 138                   ((or (= ?n char)
 139                        (= ?N char)
 140                        (= ?\^? char))
 141                    ;; Skip the object.
 142                    )
 143                   ((= ?. char)
 144                    ;; Act on the object and then exit.
 145                    (funcall actor elt)
 146                    (setq actions (1+ actions)
 147                          next (function (lambda () nil))))
 148                   ((= ?! char)
 149                    ;; Act on this and all following objects.
 150                    (if (eval (funcall prompter elt))
 151                        (progn
 152                          (funcall actor elt)
 153                          (setq actions (1+ actions))))
 154                    (while (funcall next)
 155                      (if (eval (funcall prompter elt))
 156                          (progn
 157                            (funcall actor elt)
 158                            (setq actions (1+ actions))))))
 159                   ((= ?? char)
 160                    (setq unread-command-events (list help-char))
 161                    (setq next (` (lambda ()
 162                                    (setq next '(, next))
 163                                    '(, elt)))))
 164                   ((setq tail (assq char action-alist))
 165                    ;; A user-defined key.
 166                    (if (funcall (nth 1 tail) elt) ;Call its function.
 167                        ;; The function has eaten this object.
 168                        (setq actions (1+ actions))
 169                      ;; Regurgitated; try again.
 170                      (setq next (` (lambda ()
 171                                    (setq next '(, next))
 172                                    '(, elt))))))
 173                   (t
 174                    ;; Random char.
 175                    (message "Type %s for help."
 176                             (key-description (char-to-string help-char)))
 177                    (beep)
 178                    (sit-for 1)
 179                    (setq next (` (lambda ()
 180                                    (setq next '(, next))
 181                                    '(, elt)))))))
 182         (if (eval prompt)
 183             (progn
 184               (funcall actor elt)
 185               (setq actions (1+ actions))))))
 186     ;; Clear the last prompt from the minibuffer.
 187     (message "")
 188     ;; Return the number of actions that were taken.
 189     actions))
 190
 191 ;;; map-ynp.el ends here