lisp/info.el

   1 ;;; info.el --- info package for Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: help
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Note that nowadays we expect info files to be made using makeinfo.
  27
  28 ;;; Code:
  29
  30 (defvar Info-history nil
  31   "List of info nodes user has visited.
  32 Each element of list is a list (FILENAME NODENAME BUFFERPOS).")
  33
  34 (defvar Info-enable-edit nil
  35   "*Non-nil means the \\<info-mode-map>\\[Info-edit] command in Info can edit the current node.
  36 This is convenient if you want to write info files by hand.
  37 However, we recommend that you not do this.
  38 It is better to write a Texinfo file and generate the Info file from that,
  39 because that gives you a printed manual as well.")
  40
  41 (defvar Info-enable-active-nodes t
  42   "Non-nil allows Info to execute Lisp code associated with nodes.
  43 The Lisp code is executed when the node is selected.")
  44
  45 (defvar Info-default-directory-list nil
  46   "List of default directories to search for Info documentation files.
  47 This value is used as the default for `Info-directory-list'.  It is set
  48 in paths.el.")
  49
  50 (defvar Info-directory-list nil
  51   "List of directories to search for Info documentation files.
  52 nil means not yet initialized.  In this case, Info uses the environment
  53 variable INFODIR to initialize it, or `Info-default-directory-list'
  54 if there is no INFODIR variable in the environment.")
  55
  56 (defvar Info-current-file nil
  57   "Info file that Info is now looking at, or nil.")
  58
  59 (defvar Info-current-subfile nil
  60   "Info subfile that is actually in the *info* buffer now,
  61 or nil if current info file is not split into subfiles.")
  62
  63 (defvar Info-current-node nil
  64   "Name of node that Info is now looking at, or nil.")
  65
  66 (defvar Info-tag-table-marker (make-marker)
  67   "Marker pointing at beginning of current Info file's tag table.
  68 Marker points nowhere if file has no tag table.")
  69
  70 ;;;###autoload
  71 (defun info (&optional file)
  72   "Enter Info, the documentation browser.
  73 Optional argument FILE specifies the file to examine;
  74 the default is the top-level directory of Info.
  75
  76 In interactive use, a prefix argument directs this command
  77 to read a file name from the minibuffer."
  78   (interactive (if current-prefix-arg
  79                    (list (read-file-name "Info file name: " nil nil t))))
  80   (or Info-directory-list
  81       (setq Info-directory-list
  82             (let ((path (getenv "INFOPATH")))
  83               (if path
  84                   (let ((list nil)
  85                         idx)
  86                     (while (> (length path) 0)
  87                       (setq idx (or (string-match ":" path) (length path))
  88                             list (cons (substring path 0 idx) list)
  89                             path (substring path (min (1+ idx)
  90                                                       (length path)))))
  91                     (nreverse list))
  92                 Info-default-directory-list))))
  93   (if file
  94       (Info-goto-node (concat "(" file ")"))
  95     (if (get-buffer "*info*")
  96         (switch-to-buffer "*info*")
  97       (Info-directory))))
  98
  99 ;; Go to an info node specified as separate filename and nodename.
 100 ;; no-going-back is non-nil if recovering from an error in this function;
 101 ;; it says do not attempt further (recursive) error recovery.
 102 (defun Info-find-node (filename nodename &optional no-going-back)
 103   ;; Convert filename to lower case if not found as specified.
 104   ;; Expand it.
 105   (if filename
 106       (let (temp temp-downcase found)
 107         (setq filename (substitute-in-file-name filename))
 108         (let ((dirs (if (string-match "^\\./" filename)
 109                         ;; If specified name starts with `./'
 110                         ;; then just try current directory.
 111                         '("./")
 112                       Info-directory-list)))
 113           ;; Search the directory list for file FILENAME.
 114           (while (and dirs (not found))
 115             (setq temp (expand-file-name filename (car dirs)))
 116             (setq temp-downcase
 117                   (expand-file-name (downcase filename) (car dirs)))
 118             ;; Try several variants of specified name.
 119             ;; Try downcasing, appending `.info', or both.
 120             (cond ((file-exists-p temp)
 121                    (setq found temp))
 122                   ((file-exists-p temp-downcase)
 123                    (setq found temp-downcase))
 124                   ((file-exists-p (concat temp ".info"))
 125                    (setq found (concat temp ".info")))
 126                   ((file-exists-p (concat temp-downcase ".info"))
 127                    (setq found (concat temp-downcase ".info"))))
 128             (setq dirs (cdr dirs))))
 129         (if found
 130             (setq filename found)
 131           (error "Info file %s does not exist" filename))))
 132   ;; Record the node we are leaving.
 133   (if (and Info-current-file (not no-going-back))
 134       (setq Info-history
 135             (cons (list Info-current-file Info-current-node (point))
 136                   Info-history)))
 137   ;; Go into info buffer.
 138   (switch-to-buffer "*info*")
 139   (buffer-disable-undo (current-buffer))
 140   (or (eq major-mode 'Info-mode)
 141       (Info-mode))
 142   (widen)
 143   (setq Info-current-node nil)
 144   (unwind-protect
 145       (progn
 146         ;; Switch files if necessary
 147         (or (null filename)
 148             (equal Info-current-file filename)
 149             (let ((buffer-read-only nil))
 150               (setq Info-current-file nil
 151                     Info-current-subfile nil
 152                     buffer-file-name nil)
 153               (erase-buffer)
 154               (insert-file-contents filename t)
 155               (set-buffer-modified-p nil)
 156               (setq default-directory (file-name-directory filename))
 157               ;; See whether file has a tag table.  Record the location if yes.
 158               (set-marker Info-tag-table-marker nil)
 159               (goto-char (point-max))
 160               (forward-line -8)
 161               (or (equal nodename "*")
 162                   (not (search-forward "\^_\nEnd tag table\n" nil t))
 163                   (let (pos)
 164                     ;; We have a tag table.  Find its beginning.
 165                     ;; Is this an indirect file?
 166                     (search-backward "\nTag table:\n")
 167                     (setq pos (point))
 168                     (if (save-excursion
 169                           (forward-line 2)
 170                           (looking-at "(Indirect)\n"))
 171                         ;; It is indirect.  Copy it to another buffer
 172                         ;; and record that the tag table is in that buffer.
 173                         (save-excursion
 174                           (let ((buf (current-buffer)))
 175                             (set-buffer (get-buffer-create " *info tag table*"))
 176                             (buffer-disable-undo (current-buffer))
 177                             (setq case-fold-search t)
 178                             (erase-buffer)
 179                             (insert-buffer-substring buf)
 180                             (set-marker Info-tag-table-marker
 181                                         (match-end 0))))
 182                       (set-marker Info-tag-table-marker pos))))
 183               (setq Info-current-file
 184                     (file-name-sans-versions buffer-file-name))))
 185         (if (equal nodename "*")
 186             (progn (setq Info-current-node nodename)
 187                    (Info-set-mode-line))
 188           ;; Search file for a suitable node.
 189           (let ((guesspos (point-min))
 190                 (regexp (concat "Node: *" (regexp-quote nodename) " *[,\t\n\177]")))
 191             ;; First get advice from tag table if file has one.
 192             ;; Also, if this is an indirect info file,
 193             ;; read the proper subfile into this buffer.
 194             (if (marker-position Info-tag-table-marker)
 195                 (save-excursion
 196                   (set-buffer (marker-buffer Info-tag-table-marker))
 197                   (goto-char Info-tag-table-marker)
 198                   (if (re-search-forward regexp nil t)
 199                       (progn
 200                         (setq guesspos (read (current-buffer)))
 201                         ;; If this is an indirect file,
 202                         ;; determine which file really holds this node
 203                         ;; and read it in.
 204                         (if (not (eq (current-buffer) (get-buffer "*info*")))
 205                             (setq guesspos
 206                                   (Info-read-subfile guesspos))))
 207                     (error "No such node: \"%s\"" nodename))))
 208             (goto-char (max (point-min) (- guesspos 1000)))
 209             ;; Now search from our advised position (or from beg of buffer)
 210             ;; to find the actual node.
 211             (catch 'foo
 212               (while (search-forward "\n\^_" nil t)
 213                 (forward-line 1)
 214                 (let ((beg (point)))
 215                   (forward-line 1)
 216                   (if (re-search-backward regexp beg t)
 217                       (throw 'foo t))))
 218               (error "No such node: %s" nodename)))
 219           (Info-select-node)))
 220     ;; If we did not finish finding the specified node,
 221     ;; go back to the previous one.
 222     (or Info-current-node no-going-back
 223         (let ((hist (car Info-history)))
 224           (setq Info-history (cdr Info-history))
 225           (Info-find-node (nth 0 hist) (nth 1 hist) t)
 226           (goto-char (nth 2 hist)))))
 227   (goto-char (point-min)))
 228
 229 (defun Info-read-subfile (nodepos)
 230   (set-buffer (marker-buffer Info-tag-table-marker))
 231   (goto-char (point-min))
 232   (search-forward "\n\^_")
 233   (let (lastfilepos
 234         lastfilename)
 235     (forward-line 2)
 236     (catch 'foo
 237       (while (not (looking-at "\^_"))
 238         (if (not (eolp))
 239             (let ((beg (point))
 240                   thisfilepos thisfilename)
 241               (search-forward ": ")
 242               (setq thisfilename  (buffer-substring beg (- (point) 2)))
 243               (setq thisfilepos (read (current-buffer)))
 244               ;; read in version 19 stops at the end of number.
 245               ;; Advance to the next line.
 246               (forward-line 1)
 247               (if (> thisfilepos nodepos)
 248                   (throw 'foo t))
 249               (setq lastfilename thisfilename)
 250               (setq lastfilepos thisfilepos))
 251           (forward-line 1))))
 252     (set-buffer (get-buffer "*info*"))
 253     (or (equal Info-current-subfile lastfilename)
 254         (let ((buffer-read-only nil))
 255           (setq buffer-file-name nil)
 256           (widen)
 257           (erase-buffer)
 258           (insert-file-contents lastfilename)
 259           (set-buffer-modified-p nil)
 260           (setq Info-current-subfile lastfilename)))
 261     (goto-char (point-min))
 262     (search-forward "\n\^_")
 263     (+ (- nodepos lastfilepos) (point))))
 264
 265 ;; Select the info node that point is in.
 266 (defun Info-select-node ()
 267   (save-excursion
 268    ;; Find beginning of node.
 269    (search-backward "\n\^_")
 270    (forward-line 2)
 271    ;; Get nodename spelled as it is in the node.
 272    (re-search-forward "Node:[ \t]*")
 273    (setq Info-current-node
 274          (buffer-substring (point)
 275                            (progn
 276                             (skip-chars-forward "^,\t\n")
 277                             (point))))
 278    (Info-set-mode-line)
 279    ;; Find the end of it, and narrow.
 280    (beginning-of-line)
 281    (let (active-expression)
 282      (narrow-to-region (point)
 283                        (if (re-search-forward "\n[\^_\f]" nil t)
 284                            (prog1
 285                             (1- (point))
 286                             (if (looking-at "[\n\^_\f]*execute: ")
 287                                 (progn
 288                                   (goto-char (match-end 0))
 289                                   (setq active-expression
 290                                         (read (current-buffer))))))
 291                          (point-max)))
 292      (if Info-enable-active-nodes (eval active-expression)))))
 293
 294 (defun Info-set-mode-line ()
 295   (setq mode-line-buffer-identification
 296         (concat
 297          "Info:  ("
 298          (if Info-current-file
 299              (file-name-nondirectory Info-current-file)
 300            "")
 301          ")"
 302          (or Info-current-node ""))))
 303 \f
 304 ;; Go to an info node specified with a filename-and-nodename string
 305 ;; of the sort that is found in pointers in nodes.
 306
 307 (defun Info-goto-node (nodename)
 308   "Go to info node named NAME.  Give just NODENAME or (FILENAME)NODENAME."
 309   (interactive "sGoto node: ")
 310   (let (filename)
 311     (string-match "\\s *\\((\\s *\\([^\t)]*\\)\\s *)\\s *\\|\\)\\(.*\\)"
 312                   nodename)
 313     (setq filename (if (= (match-beginning 1) (match-end 1))
 314                        ""
 315                      (substring nodename (match-beginning 2) (match-end 2)))
 316           nodename (substring nodename (match-beginning 3) (match-end 3)))
 317     (let ((trim (string-match "\\s *\\'" filename)))
 318       (if trim (setq filename (substring filename 0 trim))))
 319     (let ((trim (string-match "\\s *\\'" nodename)))
 320       (if trim (setq nodename (substring nodename 0 trim))))
 321     (Info-find-node (if (equal filename "") nil filename)
 322                     (if (equal nodename "") "Top" nodename))))
 323 \f
 324 (defun Info-restore-point (hl)
 325   "If this node has been visited, restore the point value when we left."
 326   (if hl
 327       (if (and (equal (nth 0 (car hl)) Info-current-file)
 328                (equal (nth 1 (car hl)) Info-current-node))
 329           (goto-char (nth 2 (car hl)))
 330         (Info-restore-point (cdr hl)))))
 331 \f
 332 (defvar Info-last-search nil
 333   "Default regexp for \\<info-mode-map>\\[Info-search] command to search for.")
 334
 335 (defun Info-search (regexp)
 336   "Search for REGEXP, starting from point, and select node it's found in."
 337   (interactive "sSearch (regexp): ")
 338   (if (equal regexp "")
 339       (setq regexp Info-last-search)
 340     (setq Info-last-search regexp))
 341   (let ((found ()) current
 342         (onode Info-current-node)
 343         (ofile Info-current-file)
 344         (opoint (point))
 345         (osubfile Info-current-subfile))
 346     (save-excursion
 347       (save-restriction
 348         (widen)
 349         (if (null Info-current-subfile)
 350             (progn (re-search-forward regexp) (setq found (point)))
 351           (condition-case err
 352               (progn (re-search-forward regexp) (setq found (point)))
 353             (search-failed nil)))))
 354     (if (not found) ;can only happen in subfile case -- else would have erred
 355         (unwind-protect
 356             (let ((list ()))
 357               (set-buffer (marker-buffer Info-tag-table-marker))
 358               (goto-char (point-min))
 359               (search-forward "\n\^_\nIndirect:")
 360               (save-restriction
 361                 (narrow-to-region (point)
 362                                   (progn (search-forward "\n\^_")
 363                                          (1- (point))))
 364                 (goto-char (point-min))
 365                 (search-forward (concat "\n" osubfile ": "))
 366                 (beginning-of-line)
 367                 (while (not (eobp))
 368                   (re-search-forward "\\(^.*\\): [0-9]+$")
 369                   (goto-char (+ (match-end 1) 2))
 370                   (setq list (cons (cons (read (current-buffer))
 371                                          (buffer-substring (match-beginning 1)
 372                                                            (match-end 1)))
 373                                    list))
 374                   (goto-char (1+ (match-end 0))))
 375                 (setq list (nreverse list)
 376                       current (car (car list))
 377                       list (cdr list)))
 378               (while list
 379                 (message "Searching subfile %s..." (cdr (car list)))
 380                 (Info-read-subfile (car (car list)))
 381                 (setq list (cdr list))
 382                 (goto-char (point-min))
 383                 (if (re-search-forward regexp nil t)
 384                     (setq found (point) list ())))
 385               (if found
 386                   (message "")
 387                 (signal 'search-failed (list regexp))))
 388           (if (not found)
 389               (progn (Info-read-subfile opoint)
 390                      (goto-char opoint)
 391                      (Info-select-node)))))
 392     (widen)
 393     (goto-char found)
 394     (Info-select-node)
 395     (or (and (equal onode Info-current-node)
 396              (equal ofile Info-current-file))
 397         (setq Info-history (cons (list ofile onode opoint)
 398                                  Info-history)))))
 399 \f
 400 ;; Extract the value of the node-pointer named NAME.
 401 ;; If there is none, use ERRORNAME in the error message;
 402 ;; if ERRORNAME is nil, just return nil.
 403 (defun Info-extract-pointer (name &optional errorname)
 404   (save-excursion
 405    (goto-char (point-min))
 406    (forward-line 1)
 407    (if (re-search-backward (concat name ":") nil t)
 408        (progn
 409          (goto-char (match-end 0))
 410          (Info-following-node-name))
 411      (if (eq errorname t)
 412          nil
 413        (error (concat "Node has no " (capitalize (or errorname name))))))))
 414
 415 (defun Info-following-node-name (&optional allowedchars)
 416   (skip-chars-forward " \t")
 417   (buffer-substring
 418    (point)
 419    (progn
 420      (while (looking-at (concat "[" (or allowedchars "^,\t\n") "]"))
 421        (skip-chars-forward (concat (or allowedchars "^,\t\n") "("))
 422        (if (looking-at "(")
 423            (skip-chars-forward "^)")))
 424      (skip-chars-backward " ")
 425      (point))))
 426
 427 (defun Info-next ()
 428   "Go to the next node of this node."
 429   (interactive)
 430   (Info-goto-node (Info-extract-pointer "next")))
 431
 432 (defun Info-prev ()
 433   "Go to the previous node of this node."
 434   (interactive)
 435   (Info-goto-node (Info-extract-pointer "prev[ious]*" "previous")))
 436
 437 (defun Info-up ()
 438   "Go to the superior node of this node."
 439   (interactive)
 440   (Info-goto-node (Info-extract-pointer "up"))
 441   (Info-restore-point Info-history))
 442
 443 (defun Info-last ()
 444   "Go back to the last node visited."
 445   (interactive)
 446   (or Info-history
 447       (error "This is the first Info node you looked at"))
 448   (let (filename nodename opoint)
 449     (setq filename (car (car Info-history)))
 450     (setq nodename (car (cdr (car Info-history))))
 451     (setq opoint (car (cdr (cdr (car Info-history)))))
 452     (setq Info-history (cdr Info-history))
 453     (Info-find-node filename nodename)
 454     (setq Info-history (cdr Info-history))
 455     (goto-char opoint)))
 456
 457 (defun Info-directory ()
 458   "Go to the Info directory node."
 459   (interactive)
 460   (Info-find-node "dir" "top"))
 461 \f
 462 (defun Info-follow-reference (footnotename)
 463   "Follow cross reference named NAME to the node it refers to.
 464 NAME may be an abbreviation of the reference name."
 465   (interactive
 466    (let ((completion-ignore-case t)
 467          completions default (start-point (point)) str i)
 468      (save-excursion
 469        (goto-char (point-min))
 470        (while (re-search-forward "\\*note[ \n\t]*\\([^:]*\\):" nil t)
 471          (setq str (buffer-substring
 472                     (match-beginning 1)
 473                     (1- (point))))
 474          ;; See if this one should be the default.
 475          (and (null default)
 476               (< (match-beginning 0) start-point)
 477               (<= start-point (point))
 478               (setq default t))
 479          (setq i 0)
 480          (while (setq i (string-match "[ \n\t]+" str i))
 481            (setq str (concat (substring str 0 i) " "
 482                              (substring str (match-end 0))))
 483            (setq i (1+ i)))
 484          ;; Record as a completion and perhaps as default.
 485          (if (eq default t) (setq default str))
 486          (setq completions
 487                (cons (cons str nil)
 488                      completions))))
 489      (if completions
 490          (list (completing-read (if default
 491                                     (concat "Follow reference named: ("
 492                                             default ") ")
 493                                   "Follow reference named: ")
 494                                 completions default t))
 495        (error "No cross-references in this node"))))
 496   (let (target beg i (str (concat "\\*note " footnotename)))
 497     (while (setq i (string-match " " str i))
 498       (setq str (concat (substring str 0 i) "[ \t\n]+" (substring str (1+ i))))
 499       (setq i (+ i 6)))
 500     (save-excursion
 501       (goto-char (point-min))
 502       (or (re-search-forward str nil t)
 503           (error "No cross-reference named %s" footnotename))
 504       (goto-char (+ (match-beginning 0) 5))
 505       (setq target
 506             (Info-extract-menu-node-name "Bad format cross reference" t)))
 507     (while (setq i (string-match "[ \t\n]+" target i))
 508       (setq target (concat (substring target 0 i) " "
 509                            (substring target (match-end 0))))
 510       (setq i (+ i 1)))
 511     (Info-goto-node target)))
 512
 513 (defun Info-extract-menu-node-name (&optional errmessage multi-line)
 514   (skip-chars-forward " \t\n")
 515   (let ((beg (point))
 516         str i)
 517     (skip-chars-forward "^:")
 518     (forward-char 1)
 519     (setq str
 520           (if (looking-at ":")
 521               (buffer-substring beg (1- (point)))
 522             (skip-chars-forward " \t\n")
 523             (Info-following-node-name (if multi-line "^.,\t" "^.,\t\n"))))
 524     (while (setq i (string-match "\n" str i))
 525       (aset str i ?\ ))
 526     str))
 527
 528 ;; No one calls this and Info-menu-item doesn't exist.
 529 ;;(defun Info-menu-item-sequence (list)
 530 ;;  (while list
 531 ;;    (Info-menu-item (car list))
 532 ;;    (setq list (cdr list))))
 533
 534 (defun Info-menu (menu-item)
 535   "Go to node for menu item named (or abbreviated) NAME.
 536 Completion is allowed, and the menu item point is on is the default."
 537   (interactive
 538    (let ((completions '())
 539          ;; If point is within a menu item, use that item as the default
 540          (default nil)
 541          (p (point))
 542          (last nil))
 543      (save-excursion
 544        (goto-char (point-min))
 545        (if (not (search-forward "\n* menu:" nil t))
 546            (error "No menu in this node"))
 547        (while (re-search-forward
 548                 "\n\\* \\([^:\t\n]*\\):" nil t)
 549          (if (and (null default)
 550                   (prog1 (if last (< last p) nil)
 551                     (setq last (match-beginning 0)))
 552                   (<= p last))
 553              (setq default (car (car completions))))
 554          (setq completions (cons (cons (buffer-substring
 555                                          (match-beginning 1)
 556                                          (match-end 1))
 557                                        (match-beginning 1))
 558                                  completions)))
 559        (if (and (null default) last
 560                 (< last p)
 561                 (<= p (progn (end-of-line) (point))))
 562            (setq default (car (car completions)))))
 563      (let ((item nil))
 564        (while (null item)
 565          (setq item (let ((completion-ignore-case t))
 566                       (completing-read (if default
 567                                            (format "Menu item (default %s): "
 568                                                    default)
 569                                            "Menu item: ")
 570                                        completions nil t)))
 571          ;; we rely on the fact that completing-read accepts an input
 572          ;; of "" even when the require-match argument is true and ""
 573          ;; is not a valid possibility
 574          (if (string= item "")
 575              (if default
 576                  (setq item default)
 577                  ;; ask again
 578                  (setq item nil))))
 579        (list item))))
 580   ;; there is a problem here in that if several menu items have the same
 581   ;; name you can only go to the node of the first with this command.
 582   (Info-goto-node (Info-extract-menu-item menu-item)))
 583
 584 (defun Info-extract-menu-item (menu-item)
 585   (setq menu-item (regexp-quote menu-item))
 586   (save-excursion
 587     (goto-char (point-min))
 588     (or (search-forward "\n* menu:" nil t)
 589         (error "No menu in this node"))
 590     (or (re-search-forward (concat "\n* " menu-item ":") nil t)
 591         (re-search-forward (concat "\n* " menu-item) nil t)
 592         (error "No such item in menu"))
 593     (beginning-of-line)
 594     (forward-char 2)
 595     (Info-extract-menu-node-name)))
 596
 597 ;; If COUNT is nil, use the last item in the menu.
 598 (defun Info-extract-menu-counting (count)
 599   (save-excursion
 600     (goto-char (point-min))
 601     (or (search-forward "\n* menu:" nil t)
 602         (error "No menu in this node"))
 603     (if count
 604         (or (search-forward "\n* " nil t count)
 605             (error "Too few items in menu"))
 606       (while (search-forward "\n* " nil t)
 607         nil))
 608     (Info-extract-menu-node-name)))
 609
 610 (defun Info-nth-menu-item ()
 611   "Go to the node of the Nth menu item.
 612 N is the digit argument used to invoke this command."
 613   (interactive)
 614   (Info-goto-node
 615    (Info-extract-menu-counting
 616     (- (aref (this-command-keys) (1- (length (this-command-keys)))) ?0))))
 617
 618 (defun Info-top-node ()
 619   "Go to the Top node of this file."
 620   (interactive)
 621   (Info-goto-node "Top"))
 622
 623 (defun Info-final-node ()
 624   "Go to the final node in this file."
 625   (interactive)
 626   (Info-goto-node "Top")
 627   (let (Info-history)
 628     ;; Go to the last node in the menu of Top.
 629     (Info-goto-node (Info-extract-menu-counting nil))
 630     ;; If the last node in the menu is not last in pointer structure,
 631     ;; move forward until we can't go any farther.
 632     (while (Info-forward-node t t) nil)
 633     ;; Then keep moving down to last subnode, unless we reach an index.
 634     (while (and (not (string-match "\\<index\\>" Info-current-node))
 635                 (save-excursion (search-forward "\n* Menu:" nil t)))
 636       (Info-goto-node (Info-extract-menu-counting nil)))))
 637
 638 (defun Info-forward-node (&optional not-down no-error)
 639   "Go forward one node, considering all nodes as forming one sequence."
 640   (interactive)
 641   (goto-char (point-min))
 642   (forward-line 1)
 643   ;; three possibilities, in order of priority:
 644   ;;     1. next node is in a menu in this node (but not in an index)
 645   ;;     2. next node is next at same level
 646   ;;     3. next node is up and next
 647   (cond ((and (not not-down)
 648               (save-excursion (search-forward "\n* menu:" nil t))
 649               (not (string-match "\\<index\\>" Info-current-node)))
 650          (Info-first-menu-item)
 651          t)
 652         ((save-excursion (search-backward "next:" nil t))
 653          (Info-next)
 654          t)
 655         ((and (save-excursion (search-backward "up:" nil t))
 656               (not (equal (downcase (Info-extract-pointer "up")) "top")))
 657          (let ((old-node Info-current-node))
 658            (Info-up)
 659            (let (Info-history success)
 660              (unwind-protect
 661                  (setq success (Info-forward-node t no-error))
 662                (or success (Info-goto-node old-node))))))
 663         (no-error nil)
 664         (t (error "No pointer forward from this node"))))
 665
 666 (defun Info-backward-node ()
 667   "Go backward one node, considering all nodes as forming one sequence."
 668   (interactive)
 669   (let ((prevnode (Info-extract-pointer "prev[ious]*" t))
 670         (upnode (Info-extract-pointer "up" t)))
 671     (cond ((and upnode (string-match "(" upnode))
 672            (error "First node in file"))
 673           ((and upnode (or (null prevnode)
 674                            (equal (downcase prevnode) (downcase upnode))))
 675            (Info-up))
 676           (prevnode
 677            ;; If we move back at the same level,
 678            ;; go down to find the last subnode*.
 679            (Info-prev)
 680            (let (Info-history)
 681              (while (and (not (string-match "\\<index\\>" Info-current-node))
 682                          (save-excursion (search-forward "\n* Menu:" nil t)))
 683                (Info-goto-node (Info-extract-menu-counting nil)))))
 684           (t
 685            (error "No pointer backward from this node")))))
 686
 687 (defun Info-exit ()
 688   "Exit Info by selecting some other buffer."
 689   (interactive)
 690   (switch-to-buffer (prog1 (other-buffer (current-buffer))
 691                            (bury-buffer (current-buffer)))))
 692
 693 (defun Info-next-menu-item ()
 694   (interactive)
 695   (save-excursion
 696     (forward-line -1)
 697     (search-forward "\n* menu:" nil t)
 698     (or (search-forward "\n* " nil t)
 699         (error "No more items in menu"))
 700     (Info-goto-node (Info-extract-menu-node-name))))
 701
 702 (defun Info-last-menu-item ()
 703   (interactive)
 704   (save-excursion
 705     (forward-line 1)
 706     (search-backward "\n* menu:" nil t)
 707     (or (search-backward "\n* " nil t)
 708         (error "No previous items in menu"))
 709     (Info-goto-node (Info-extract-menu-node-name))))
 710
 711 (defmacro no-error (&rest body)
 712   (list 'condition-case nil (cons 'progn (append body '(t))) '(error nil)))
 713
 714 (defun Info-next-preorder ()
 715   "Go to the next node, popping up a level if there is none."
 716   (interactive)
 717   (cond ((no-error (Info-next-menu-item))       )
 718         ((no-error (Info-up))                   (forward-line 1))
 719         (t                                      (error "No more nodes"))))
 720
 721 (defun Info-last-preorder ()
 722   "Go to the last node, popping up a level if there is none."
 723   (interactive)
 724   (cond ((no-error (Info-last-menu-item))       )
 725         ((no-error (Info-up))                   (forward-line -1))
 726         (t                                      (error "No previous nodes"))))
 727
 728 (defun Info-scroll-up ()
 729   "Read the next screen.  If end of buffer is visible, go to next entry."
 730   (interactive)
 731   (if (pos-visible-in-window-p (point-max))
 732       (Info-next-preorder)
 733       (scroll-up))
 734   )
 735
 736 (defun Info-scroll-down ()
 737   "Read the previous screen.  If start of buffer is visible, go to last entry."
 738   (interactive)
 739   (if (pos-visible-in-window-p (point-min))
 740       (Info-last-preorder)
 741       (scroll-down))
 742   )
 743
 744 (defun Info-undefined ()
 745   "Make command be undefined in Info."
 746   (interactive)
 747   (ding))
 748
 749 (defun Info-help ()
 750   "Enter the Info tutorial."
 751   (interactive)
 752   (delete-other-windows)
 753   (Info-find-node "info"
 754                   (if (< (window-height) 23)
 755                       "Help-Small-Screen"
 756                     "Help")))
 757
 758 (defun Info-summary ()
 759   "Display a brief summary of all Info commands."
 760   (interactive)
 761   (save-window-excursion
 762     (switch-to-buffer "*Help*")
 763     (erase-buffer)
 764     (insert (documentation 'Info-mode))
 765     (goto-char (point-min))
 766     (let (ch flag)
 767       (while (progn (setq flag (not (pos-visible-in-window-p (point-max))))
 768                     (message (if flag "Type Space to see more"
 769                                "Type Space to return to Info"))
 770                     (if (/= ?\  (setq ch (read-char)))
 771                         (progn (setq unread-command-events (list ch)) nil)
 772                       flag))
 773         (scroll-up)))))
 774 \f
 775 (defun Info-get-token (pos start all &optional errorstring)
 776   "Return the token around POS,
 777 POS must be somewhere inside the token
 778 START is a regular expression which will match the
 779     beginning of the tokens delimited string
 780 ALL is a regular expression with a single
 781     parenthized subpattern which is the token to be
 782     returned. E.g. '{\(.*\)}' would return any string
 783     enclosed in braces around POS.
 784 SIG optional fourth argument, controls action on no match
 785     nil: return nil
 786     t: beep
 787     a string: signal an error, using that string."
 788   (save-excursion
 789     (goto-char pos)
 790     (re-search-backward start (max (point-min) (- pos 200)) 'yes)
 791     (while (and (re-search-forward all (min (point-max) (+ pos 200)) 'yes)
 792                 (not (and (<= (match-beginning 0) pos)
 793                           (> (match-end 0) pos)))))
 794     (if (and (<= (match-beginning 0) pos)
 795              (> (match-end 0) pos))
 796         (buffer-substring (match-beginning 1) (match-end 1))
 797       (cond ((null errorstring)
 798              nil)
 799             ((eq errorstring t)
 800              (beep)
 801              nil)
 802             (t
 803              (error "No %s around position %d" errorstring pos))))))
 804
 805 (defun Info-follow-nearest-node (click)
 806   "\\<Info-mode-map>Follow a node reference near point.
 807 Like \\[Info-menu], \\[Info-follow-reference], \\[Info-next], \\[Info-prev] or \\[Info-up] command, depending on where you click.
 808 At end of the node's text, moves to the next node."
 809   (interactive "e")
 810   (let* ((start (event-start click))
 811          (window (car start))
 812          (pos (car (cdr start))))
 813     (select-window window)
 814     (goto-char pos))
 815   (let (node)
 816     (cond
 817      ((setq node (Info-get-token (point) "\\*note[ \n]" "\\*note[ \n]\\([^:]*\\):" t))
 818       (Info-follow-reference node))
 819      ((setq node (Info-get-token (point) "\\* " "\\* \\([^:]*\\)::" t))
 820       (Info-goto-node node))
 821      ((setq node (Info-get-token (point) "\\* " "\\* \\([^:]*\\):" t))
 822       (Info-menu node))
 823      ((setq node (Info-get-token (point) "Up: " "Up: \\([^,\n\t]*\\)" t))
 824       (Info-goto-node node))
 825      ((setq node (Info-get-token (point) "Next: " "Next: \\([^,\n\t]*\\)" t))
 826       (Info-goto-node node))
 827      ((setq node (Info-get-token (point) "File: " "File: \\([^,\n\t]*\\)" t))
 828       (Info-goto-node "Top"))
 829      ((setq node (Info-get-token (point) "Prev: " "Prev: \\([^,\n\t]*\\)" t))
 830       (Info-goto-node node))
 831      ((save-excursion (forward-line 1) (eobp))
 832       (Info-next)))
 833     ))
 834 \f
 835 (defvar Info-mode-map nil
 836   "Keymap containing Info commands.")
 837 (if Info-mode-map
 838     nil
 839   (setq Info-mode-map (make-keymap))
 840   (suppress-keymap Info-mode-map)
 841   (define-key Info-mode-map "." 'beginning-of-buffer)
 842   (define-key Info-mode-map " " 'Info-scroll-up)
 843   (define-key Info-mode-map "\C-m" 'Info-next-preorder)
 844   (define-key Info-mode-map "1" 'Info-nth-menu-item)
 845   (define-key Info-mode-map "2" 'Info-nth-menu-item)
 846   (define-key Info-mode-map "3" 'Info-nth-menu-item)
 847   (define-key Info-mode-map "4" 'Info-nth-menu-item)
 848   (define-key Info-mode-map "5" 'Info-nth-menu-item)
 849   (define-key Info-mode-map "6" 'Info-nth-menu-item)
 850   (define-key Info-mode-map "7" 'Info-nth-menu-item)
 851   (define-key Info-mode-map "8" 'Info-nth-menu-item)
 852   (define-key Info-mode-map "9" 'Info-nth-menu-item)
 853   (define-key Info-mode-map "0" 'undefined)
 854   (define-key Info-mode-map "?" 'Info-summary)
 855   (define-key Info-mode-map "]" 'Info-forward-node)
 856   (define-key Info-mode-map "[" 'Info-backward-node)
 857   (define-key Info-mode-map "<" 'Info-top-node)
 858   (define-key Info-mode-map ">" 'Info-final-node)
 859   (define-key Info-mode-map "b" 'beginning-of-buffer)
 860   (define-key Info-mode-map "d" 'Info-directory)
 861   (define-key Info-mode-map "e" 'Info-edit)
 862   (define-key Info-mode-map "f" 'Info-follow-reference)
 863   (define-key Info-mode-map "g" 'Info-goto-node)
 864   (define-key Info-mode-map "h" 'Info-help)
 865   (define-key Info-mode-map "l" 'Info-last)
 866   (define-key Info-mode-map "m" 'Info-menu)
 867   (define-key Info-mode-map "n" 'Info-next)
 868   (define-key Info-mode-map "p" 'Info-prev)
 869   (define-key Info-mode-map "q" 'Info-exit)
 870   (define-key Info-mode-map "s" 'Info-search)
 871   (define-key Info-mode-map "u" 'Info-up)
 872   (define-key Info-mode-map "\177" 'Info-scroll-down)
 873   (define-key Info-mode-map [mouse-3] 'Info-follow-nearest-node)
 874   )
 875 \f
 876 ;; Info mode is suitable only for specially formatted data.
 877 (put 'info-mode 'mode-class 'special)
 878
 879 (defun Info-mode ()
 880   "\\<Info-mode-map>
 881 Info mode provides commands for browsing through the Info documentation tree.
 882 Documentation in Info is divided into \"nodes\", each of which discusses
 883 one topic and contains references to other nodes which discuss related
 884 topics.  Info has commands to follow the references and show you other nodes.
 885
 886 \\[Info-help]   Invoke the Info tutorial.
 887
 888 Selecting other nodes:
 889 \\[Info-next]   Move to the \"next\" node of this node.
 890 \\[Info-previous]       Move to the \"previous\" node of this node.
 891 \\[Info-up]     Move \"up\" from this node.
 892 \\[Info-menu]   Pick menu item specified by name (or abbreviation).
 893         Picking a menu item causes another node to be selected.
 894 \\[Info-directory]      Go to the Info directory node.
 895 \\[Info-follow-reference]       Follow a cross reference.  Reads name of reference.
 896 \\[Info-last]   Move to the last node you were at.
 897
 898 Moving within a node:
 899 \\[scroll-up]   Normally, scroll forward a full screen.  If the end of the buffer is
 900 already visible, try to go to the next menu entry, or up if there is none.
 901 \\[scroll-down]  Normally, scroll backward.  If the beginning of the buffer is
 902 already visible, try to go to the previous menu entry, or up if there is none.
 903 \\[beginning-of-buffer] Go to beginning of node.
 904
 905 Advanced commands:
 906 \\[Info-exit]   Quit Info: reselect previously selected buffer.
 907 \\[Info-edit]   Edit contents of selected node.
 908 1       Pick first item in node's menu.
 909 2, 3, 4, 5   Pick second ... fifth item in node's menu.
 910 \\[Info-goto-node]      Move to node specified by name.
 911         You may include a filename as well, as (FILENAME)NODENAME.
 912 \\[Info-search] Search through this Info file for specified regexp,
 913         and select the node in which the next occurrence is found.
 914 \\[Info-next-preorder]  Next-preorder; that is, try to go to the next menu item,
 915         and if that fails try to move up, and if that fails, tell user
 916         he/she is done reading."
 917   (kill-all-local-variables)
 918   (setq major-mode 'Info-mode)
 919   (setq mode-name "Info")
 920   (use-local-map Info-mode-map)
 921   (set-syntax-table text-mode-syntax-table)
 922   (setq local-abbrev-table text-mode-abbrev-table)
 923   (setq case-fold-search t)
 924   (setq buffer-read-only t)
 925   (make-local-variable 'Info-current-file)
 926   (make-local-variable 'Info-current-subfile)
 927   (make-local-variable 'Info-current-node)
 928   (make-local-variable 'Info-tag-table-marker)
 929   (make-local-variable 'Info-history)
 930   (Info-set-mode-line)
 931   (run-hooks 'Info-mode-hook))
 932
 933 (defvar Info-edit-map nil
 934   "Local keymap used within `e' command of Info.")
 935 (if Info-edit-map
 936     nil
 937   (setq Info-edit-map (nconc (make-sparse-keymap) text-mode-map))
 938   (define-key Info-edit-map "\C-c\C-c" 'Info-cease-edit))
 939
 940 ;; Info-edit mode is suitable only for specially formatted data.
 941 (put 'info-edit-mode 'mode-class 'special)
 942
 943 (defun Info-edit-mode ()
 944   "Major mode for editing the contents of an Info node.
 945 Like text mode with the addition of `Info-cease-edit'
 946 which returns to Info mode for browsing.
 947 \\{Info-edit-map}"
 948   )
 949
 950 (defun Info-edit ()
 951   "Edit the contents of this Info node.
 952 Allowed only if variable `Info-enable-edit' is non-nil."
 953   (interactive)
 954   (or Info-enable-edit
 955       (error "Editing info nodes is not enabled"))
 956   (use-local-map Info-edit-map)
 957   (setq major-mode 'Info-edit-mode)
 958   (setq mode-name "Info Edit")
 959   (kill-local-variable 'mode-line-buffer-identification)
 960   (setq buffer-read-only nil)
 961   ;; Make mode line update.
 962   (set-buffer-modified-p (buffer-modified-p))
 963   (message (substitute-command-keys
 964              "Editing: Type \\<info-mode-map>\\[Info-cease-edit] to return to info")))
 965
 966 (defun Info-cease-edit ()
 967   "Finish editing Info node; switch back to Info proper."
 968   (interactive)
 969   ;; Do this first, so nothing has changed if user C-g's at query.
 970   (and (buffer-modified-p)
 971        (y-or-n-p "Save the file? ")
 972        (save-buffer))
 973   (use-local-map Info-mode-map)
 974   (setq major-mode 'Info-mode)
 975   (setq mode-name "Info")
 976   (Info-set-mode-line)
 977   (setq buffer-read-only t)
 978   ;; Make mode line update.
 979   (set-buffer-modified-p (buffer-modified-p))
 980   (and (marker-position Info-tag-table-marker)
 981        (buffer-modified-p)
 982        (message "Tags may have changed.  Use Info-tagify if necessary")))
 983 \f
 984 (defun Info-find-emacs-command-nodes (command)
 985   "Return a list of locations documenting COMMAND in the Emacs Info manual.
 986 The locations are of the format used in Info-history, i.e.
 987 \(FILENAME NODENAME BUFFERPOS\)."
 988   (require 'info)
 989   (let ((where '())
 990         (cmd-desc (concat "^\\* " (regexp-quote (symbol-name command))
 991                           ":\\s *\\(.*\\)\\.$")))
 992     (save-excursion
 993       (Info-find-node "emacs" "Command Index")
 994       ;; Take the index node off the Info history.
 995       (setq Info-history (cdr Info-history))
 996       (goto-char (point-max))
 997       (while (re-search-backward cmd-desc nil t)
 998           (setq where (cons (list Info-current-file
 999                                   (buffer-substring
1000                                    (match-beginning 1)
1001                                    (match-end 1))
1002                                   0)
1003                             where)))
1004       where)))
1005
1006 ;;;###autoload
1007 (defun Info-goto-emacs-command-node (command)
1008   "Go to the Info node in the Emacs manual for command COMMAND."
1009   (interactive "CFind documentation for command: ")
1010   (or (commandp command)
1011       (signal 'wrong-type-argument (list 'commandp command)))
1012   (let ((where (Info-find-emacs-command-nodes command)))
1013     (if where
1014         (let ((num-matches (length where)))
1015           ;; Get Info running, and pop to it in another window.
1016           (save-window-excursion
1017             (info))
1018           (pop-to-buffer "*info*")
1019           (Info-find-node (car (car where))
1020                           (car (cdr (car where))))
1021           (if (> num-matches 1)
1022               (progn
1023                 ;; Info-find-node already pushed (car where) onto
1024                 ;; Info-history.  Put the other nodes that were found on
1025                 ;; the history.
1026                 (setq Info-history (nconc (cdr where) Info-history))
1027                 (message (substitute-command-keys
1028                           "Found %d other entr%.  Use \\[Info-last] to see %s."
1029                         (1- num-matches)
1030                         (if (> num-matches 2) "ies" "y")
1031                         (if (> num-matches 2) "them" "it"))))))
1032       (error "Couldn't find documentation for %s." command))))
1033
1034 ;;;###autoload
1035 (defun Info-goto-emacs-key-command-node (key)
1036   "Go to the Info node in the Emacs manual the command bound to KEY, a string.
1037 Interactively, if the binding is execute-extended-command, a command is read."
1038   (interactive "kFind documentation for key:")
1039   (let ((command (key-binding key)))
1040     (cond ((null command)
1041            (message "%s is undefined" (key-description key)))
1042           ((and (interactive-p)
1043                 (eq command 'execute-extended-command))
1044            (Info-goto-emacs-command-node
1045             (read-command "Find documentation for command: ")))
1046           (t
1047            (Info-goto-emacs-command-node command)))))
1048
1049 (provide 'info)
1050
1051 ;;; info.el ends here