config.bat

   1 @echo off
   2 rem   ----------------------------------------------------------------------
   3 rem   Configuration script for MSDOS
   4 rem   Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003
   5 rem   2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   6
   7 rem   This file is part of GNU Emacs.
   8
   9 rem   GNU Emacs is free software: you can redistribute it and/or modify
  10 rem   it under the terms of the GNU General Public License as published by
  11 rem   the Free Software Foundation, either version 3 of the License, or
  12 rem   (at your option) any later version.
  13
  14 rem   GNU Emacs is distributed in the hope that it will be useful,
  15 rem   but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 rem   GNU General Public License for more details.
  18
  19 rem   You should have received a copy of the GNU General Public License
  20 rem   along with GNU Emacs.  If not, see http://www.gnu.org/licenses/.
  21
  22 rem   ----------------------------------------------------------------------
  23 rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:
  24 rem
  25 rem   + msdos version 3 or better.
  26 rem   + DJGPP version 1.12maint1 or later (version 2.03 or later recommended).
  27 rem   + make utility that allows breaking of the 128 chars limit on
  28 rem     command lines.  ndmake (as of version 4.5) won't work due to a
  29 rem     line length limit.  The make that comes with DJGPP does work.
  30 rem   + rm and mv (from GNU file utilities).
  31 rem   + sed (you can use the port that comes with DJGPP).
  32 rem
  33 rem   You should be able to get all the above utilities from the DJGPP FTP
  34 rem   site, ftp.delorie.com, in the directory "pub/djgpp/current/v2gnu".
  35 rem   ----------------------------------------------------------------------
  36 set X11=
  37 set nodebug=
  38 set djgpp_ver=
  39 if "%1" == "" goto usage
  40 rem   ----------------------------------------------------------------------
  41 rem   See if their environment is large enough.  We need 28 bytes.
  42 set $foo$=789012345678901234567
  43 if not "%$foo$%" == "789012345678901234567" goto SmallEnv
  44 set $foo$=
  45 :again
  46 if "%1" == "" goto usage
  47 if "%1" == "--with-x" goto withx
  48 if "%1" == "--no-debug" goto nodebug
  49 if "%1" == "msdos" goto msdos
  50 :usage
  51 echo Usage: config [--with-x] [--no-debug] msdos
  52 echo [Read the script before you run it.]
  53 goto end
  54 rem   ----------------------------------------------------------------------
  55 :withx
  56 set X11=Y
  57 shift
  58 goto again
  59 rem   ----------------------------------------------------------------------
  60 :nodebug
  61 set nodebug=Y
  62 shift
  63 goto again
  64 rem   ----------------------------------------------------------------------
  65 :msdos
  66 Echo Checking whether 'sed' is available...
  67 sed -e "w junk.$$$" <Nul
  68 If Exist junk.$$$ Goto sedOk
  69 Echo To configure 'Emacs' you need to have 'sed'!
  70 Goto End
  71 :sedOk
  72 Echo Checking whether 'rm' is available...
  73 rm -f junk.$$$
  74 If Not Exist junk.$$$ Goto rmOk
  75 Echo To configure 'Emacs' you need to have 'rm'!
  76 Goto End
  77 :rmOk
  78 Echo Checking whether 'mv' is available...
  79 rm -f junk.1 junk.2
  80 echo foo >junk.1
  81 mv junk.1 ./junk.2
  82 If Exist junk.2 Goto mvOk
  83 Echo To configure 'Emacs' you need to have 'mv'!
  84 rm -f junk.1
  85 Goto End
  86 :mvOk
  87 rm -f junk.2
  88 Echo Checking whether 'gcc' is available...
  89 echo main(){} >junk.c
  90 gcc -c junk.c
  91 if exist junk.o goto gccOk
  92 Echo To configure 'Emacs' you need to have 'gcc'!
  93 rm -f junk.c
  94 Goto End
  95 :gccOk
  96 rm -f junk.c junk.o junk junk.exe
  97 Echo Checking what version of DJGPP is installed...
  98 If Not "%DJGPP%" == "" goto djgppOk
  99 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 100 Goto End
 101 :djgppOk
 102 echo int main()           >junk.c
 103 echo #ifdef __DJGPP__    >>junk.c
 104 echo {return (__DJGPP__)*10;} >>junk.c
 105 echo #else               >>junk.c
 106 echo #ifdef __GO32__     >>junk.c
 107 echo {return 10;}         >>junk.c
 108 echo #else               >>junk.c
 109 echo {return 0;}         >>junk.c
 110 echo #endif              >>junk.c
 111 echo #endif              >>junk.c
 112 gcc -o junk junk.c
 113 if not exist junk.exe coff2exe junk
 114 junk
 115 If ErrorLevel 10 Goto go32Ok
 116 rm -f junk.c junk junk.exe
 117 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 118 Goto End
 119 :go32Ok
 120 set djgpp_ver=1
 121 If ErrorLevel 20 set djgpp_ver=2
 122 rm -f junk.c junk junk.exe
 123 rem The v1.x build does not need djecho
 124 if "%DJGPP_VER%" == "1" Goto djechoOk
 125 rem DJECHO is used by the top-level Makefile in the v2.x build
 126 Echo Checking whether 'djecho' is available...
 127 redir -o Nul -eo djecho -o junk.$$$ foo
 128 If Exist junk.$$$ Goto djechoOk
 129 Echo To build 'Emacs' you need the 'djecho.exe' program!
 130 Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.
 131 Echo Versions of DJGPP before 2.02 called this program 'echo.exe'.
 132 Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,
 133 Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.
 134 Echo Then run CONFIG.BAT again with the same arguments you did now.
 135 Goto End
 136 :djechoOk
 137 rm -f junk.$$$
 138 Echo Configuring for DJGPP Version %DJGPP_VER% ...
 139 Rem   ----------------------------------------------------------------------
 140 Echo Configuring the source directory...
 141 cd src
 142
 143 rem   Create "epaths.h"
 144 sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp
 145 update epaths.tmp epaths.h >nul
 146 rm -f epaths.tmp
 147
 148 rem   Create "config.h"
 149 rm -f config.h2 config.tmp
 150 sed -e '' config.in > config.tmp
 151 if "%X11%" == "" goto src4
 152 sed -f ../msdos/sed2x.inp <config.in >config.tmp
 153 :src4
 154 if "%DJGPP_VER%" == "2" Goto src41
 155 sed -f ../msdos/sed2.inp <config.tmp >config.h2
 156 goto src42
 157 :src41
 158 sed -f ../msdos/sed2v2.inp <config.tmp >config.h2
 159 :src42
 160 Rem See if DECL_ALIGN can be supported with this GCC
 161 rm -f junk.c junk.o junk junk.exe
 162 echo struct { int i; char *p; } __attribute__((__aligned__(8))) foo;  >junk.c
 163 rem Two percent signs because it is a special character for COMMAND.COM/CMD
 164 rem Filter thru Sed because "&" is special for CMD.EXE
 165 echo int main(void) { return (unsigned long)"&"foo %% 8; } | sed "s/.&./\&/"         >>junk.c
 166 gcc -o junk junk.c
 167 if not exist junk.exe coff2exe junk
 168 junk
 169 If Not ErrorLevel 1 Goto alignOk
 170 Echo WARNING: Your GCC does not support 8-byte aligned variables.
 171 Echo WARNING: Therefore Emacs cannot support buffers larger than 128MB.
 172 rem The following line disables DECL_ALIGN which in turn disables USE_LSB_TAG
 173 rem For details see lisp.h where it defines USE_LSB_TAG
 174 echo #define NO_DECL_ALIGN >>config.h2
 175 :alignOk
 176 rm -f junk.c junk junk.exe
 177 update config.h2 config.h >nul
 178 rm -f config.tmp config.h2
 179
 180 rem   On my system dir.h gets in the way.  It's a VMS file so who cares.
 181 if exist dir.h ren dir.h vmsdir.h
 182
 183 rem   Create "makefile" from "makefile.in".
 184 rm -f Makefile junk.c
 185 sed -e "1,/== start of cpp stuff ==/s@^# .*$@@" <Makefile.in >junk.c
 186 If "%DJGPP_VER%" == "1" Goto mfV1
 187 gcc -E -traditional junk.c | sed -f ../msdos/sed1v2.inp >Makefile
 188 goto mfDone
 189 :mfV1
 190 gcc -E -traditional junk.c | sed -f ../msdos/sed1.inp >Makefile
 191 :mfDone
 192 rm -f junk.c
 193
 194 if "%X11%" == "" goto src5
 195 mv Makefile makefile.tmp
 196 sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile
 197 rm -f makefile.tmp
 198 :src5
 199
 200 if "%nodebug%" == "" goto src6
 201 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 202 sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile
 203 rm -f makefile.tmp
 204 :src6
 205 cd ..
 206 rem   ----------------------------------------------------------------------
 207 Echo Configuring the library source directory...
 208 cd lib-src
 209 rem   Create "makefile" from "makefile.in".
 210 sed -e "1,/== start of cpp stuff ==/s@^#[       ].*$@@" <Makefile.in >junk.c
 211 gcc -E -traditional -I. -I../src junk.c | sed -e "s/^ / /" -e "/^#/d" -e "/^[   \f]*$/d" >makefile.new
 212 If "%DJGPP_VER%" == "2" goto libsrc-v2
 213 sed -f ../msdos/sed3.inp <makefile.new >Makefile
 214 Goto libsrc2
 215 :libsrc-v2
 216 sed -f ../msdos/sed3v2.inp <makefile.new >Makefile
 217 :libsrc2
 218 rm -f makefile.new junk.c
 219 if "%nodebug%" == "" goto libsrc3
 220 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 221 sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile
 222 rm -f makefile.tmp
 223 :libsrc3
 224 cd ..
 225 rem   ----------------------------------------------------------------------
 226 if "%X11%" == "" goto oldx1
 227 Echo Configuring the oldxmenu directory...
 228 cd oldxmenu
 229 sed -f ../msdos/sed5x.inp <Makefile.in >Makefile
 230 if "%nodebug%" == "" goto oldx2
 231 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 232 mv -f makefile.tmp Makefile
 233 :oldx2
 234 cd ..
 235 :oldx1
 236 rem   ----------------------------------------------------------------------
 237 Echo Configuring the doc directory...
 238 cd doc
 239 Rem The two variants for lispintro below is for when the shell
 240 Rem supports long file names but DJGPP does not
 241 for %%d in (emacs lispref lispintro lispintr misc) do sed -f ../msdos/sed6.inp < %%d\Makefile.in > %%d\Makefile
 242 cd ..
 243 rem   ----------------------------------------------------------------------
 244 Echo Configuring the lisp directory...
 245 cd lisp
 246 sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile
 247 cd ..
 248 rem   ----------------------------------------------------------------------
 249 If not Exist leim\quail\latin-pre.el goto maindir
 250 Echo Configuring the leim directory...
 251 cd leim
 252 sed -f ../msdos/sedleim.inp < Makefile.in > Makefile
 253 cd ..
 254 rem   ----------------------------------------------------------------------
 255 :maindir
 256 Echo Configuring the main directory...
 257 If "%DJGPP_VER%" == "1" goto mainv1
 258 Echo Looking for the GDB init file...
 259 If Exist src\.gdbinit update src/.gdbinit src/_gdbinit
 260 If Exist src\_gdbinit goto gdbinitOk
 261 Echo ERROR:
 262 Echo I cannot find the GDB init file.  It was called ".gdbinit" in
 263 Echo the Emacs distribution, but was probably renamed to some other
 264 Echo name without the leading dot when you untarred the archive.
 265 Echo It should be in the "src/" subdirectory.  Please make sure this
 266 Echo file exists and is called "_gdbinit" with a leading underscore.
 267 Echo Then run CONFIG.BAT again with the same arguments you did now.
 268 goto End
 269 :gdbinitOk
 270 Echo Looking for the GDB init file...found
 271 copy msdos\mainmake.v2 Makefile >nul
 272 :mainv1
 273 If "%DJGPP_VER%" == "1" copy msdos\mainmake Makefile >nul
 274 rem   ----------------------------------------------------------------------
 275 goto End
 276 :SmallEnv
 277 echo Your environment size is too small.  Please enlarge it and run me again.
 278 echo For example, type "command.com /e:2048" to have 2048 bytes available.
 279 set $foo$=
 280 :end
 281 set X11=
 282 set nodebug=
 283 set djgpp_ver=
 284
 285 goto skipArchTag
 286    arch-tag: 2d2fed23-4dc6-4006-a2e4-49daf0031f33
 287 :skipArchTag