lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; This package supplies the string and regular-expression replace functions
  25 ;; documented in the Emacs user's manual.
  26
  27 ;;; Code:
  28
  29 (defcustom case-replace t
  30   "*Non-nil means query-replace should preserve case in replacements."
  31   :type 'boolean
  32   :group 'matching)
  33
  34 (defvar query-replace-history nil)
  35
  36 (defvar query-replace-interactive nil
  37   "Non-nil means `query-replace' uses the last search string.
  38 That becomes the \"string to replace\".")
  39
  40 (defun query-replace-read-args (string regexp-flag)
  41   (let (from to)
  42     (if query-replace-interactive
  43         (setq from (car (if regexp-flag regexp-search-ring search-ring)))
  44       (setq from (read-from-minibuffer (format "%s: " string)
  45                                        nil nil nil
  46                                        'query-replace-history nil t)))
  47     (setq to (read-from-minibuffer (format "%s %s with: " string from)
  48                                    nil nil nil
  49                                    'query-replace-history nil t))
  50     (list from to current-prefix-arg)))
  51
  52 (defun query-replace (from-string to-string &optional arg)
  53   "Replace some occurrences of FROM-STRING with TO-STRING.
  54 As each match is found, the user must type a character saying
  55 what to do with it.  For directions, type \\[help-command] at that time.
  56
  57 If `query-replace-interactive' is non-nil, the last incremental search
  58 string is used as FROM-STRING--you don't have to specify it with the
  59 minibuffer.
  60
  61 Preserves case in each replacement if `case-replace' and `case-fold-search'
  62 are non-nil and FROM-STRING has no uppercase letters.
  63 \(Preserving case means that if the string matched is all caps, or capitalized,
  64 then its replacement is upcased or capitalized.)
  65
  66 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
  67 only matches surrounded by word boundaries.
  68
  69 To customize possible responses, change the \"bindings\" in `query-replace-map'."
  70   (interactive (query-replace-read-args "Query replace" nil))
  71   (perform-replace from-string to-string t nil arg))
  72 (define-key esc-map "%" 'query-replace)
  73
  74 (defun query-replace-regexp (regexp to-string &optional arg)
  75   "Replace some things after point matching REGEXP with TO-STRING.
  76 As each match is found, the user must type a character saying
  77 what to do with it.  For directions, type \\[help-command] at that time.
  78
  79 If `query-replace-interactive' is non-nil, the last incremental search
  80 regexp is used as REGEXP--you don't have to specify it with the
  81 minibuffer.
  82
  83 Preserves case in each replacement if `case-replace' and `case-fold-search'
  84 are non-nil and REGEXP has no uppercase letters.
  85 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
  86 only matches surrounded by word boundaries.
  87 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
  88 and `\\=\\N' (where N is a digit) stands for
  89  whatever what matched the Nth `\\(...\\)' in REGEXP."
  90   (interactive (query-replace-read-args "Query replace regexp" t))
  91   (perform-replace regexp to-string t t arg))
  92
  93 (defun map-query-replace-regexp (regexp to-strings &optional arg)
  94   "Replace some matches for REGEXP with various strings, in rotation.
  95 The second argument TO-STRINGS contains the replacement strings, separated
  96 by spaces.  This command works like `query-replace-regexp' except
  97 that each successive replacement uses the next successive replacement string,
  98 wrapping around from the last such string to the first.
  99
 100 Non-interactively, TO-STRINGS may be a list of replacement strings.
 101
 102 If `query-replace-interactive' is non-nil, the last incremental search
 103 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 104
 105 A prefix argument N says to use each replacement string N times
 106 before rotating to the next."
 107   (interactive
 108    (let (from to)
 109      (setq from (if query-replace-interactive
 110                     (car regexp-search-ring)
 111                   (read-from-minibuffer "Map query replace (regexp): "
 112                                         nil nil nil
 113                                         'query-replace-history nil t)))
 114      (setq to (read-from-minibuffer
 115                (format "Query replace %s with (space-separated strings): "
 116                        from)
 117                nil nil nil
 118                'query-replace-history nil t))
 119      (list from to current-prefix-arg)))
 120   (let (replacements)
 121     (if (listp to-strings)
 122         (setq replacements to-strings)
 123       (while (/= (length to-strings) 0)
 124         (if (string-match " " to-strings)
 125             (setq replacements
 126                   (append replacements
 127                           (list (substring to-strings 0
 128                                            (string-match " " to-strings))))
 129                   to-strings (substring to-strings
 130                                        (1+ (string-match " " to-strings))))
 131           (setq replacements (append replacements (list to-strings))
 132                 to-strings ""))))
 133     (perform-replace regexp replacements t t nil arg)))
 134
 135 (defun replace-string (from-string to-string &optional delimited)
 136   "Replace occurrences of FROM-STRING with TO-STRING.
 137 Preserve case in each match if `case-replace' and `case-fold-search'
 138 are non-nil and FROM-STRING has no uppercase letters.
 139 \(Preserving case means that if the string matched is all caps, or capitalized,
 140 then its replacement is upcased or capitalized.)
 141
 142 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 143 only matches surrounded by word boundaries.
 144
 145 If `query-replace-interactive' is non-nil, the last incremental search
 146 string is used as FROM-STRING--you don't have to specify it with the
 147 minibuffer.
 148
 149 This function is usually the wrong thing to use in a Lisp program.
 150 What you probably want is a loop like this:
 151   (while (search-forward FROM-STRING nil t)
 152     (replace-match TO-STRING nil t))
 153 which will run faster and will not set the mark or print anything.
 154 \(You may need a more complex loop if FROM-STRING can match the null string
 155 and TO-STRING is also null.)"
 156   (interactive (query-replace-read-args "Replace string" nil))
 157   (perform-replace from-string to-string nil nil delimited))
 158
 159 (defun replace-regexp (regexp to-string &optional delimited)
 160   "Replace things after point matching REGEXP with TO-STRING.
 161 Preserve case in each match if `case-replace' and `case-fold-search'
 162 are non-nil and REGEXP has no uppercase letters.
 163 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 164 only matches surrounded by word boundaries.
 165 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 166 and `\\=\\N' (where N is a digit) stands for
 167  whatever what matched the Nth `\\(...\\)' in REGEXP.
 168
 169 If `query-replace-interactive' is non-nil, the last incremental search
 170 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 171
 172 This function is usually the wrong thing to use in a Lisp program.
 173 What you probably want is a loop like this:
 174   (while (re-search-forward REGEXP nil t)
 175     (replace-match TO-STRING nil nil))
 176 which will run faster and will not set the mark or print anything."
 177   (interactive (query-replace-read-args "Replace regexp" t))
 178   (perform-replace regexp to-string nil t delimited))
 179 \f
 180 (defvar regexp-history nil
 181   "History list for some commands that read regular expressions.")
 182
 183 (defalias 'delete-non-matching-lines 'keep-lines)
 184 (defun keep-lines (regexp)
 185   "Delete all lines except those containing matches for REGEXP.
 186 A match split across lines preserves all the lines it lies in.
 187 Applies to all lines after point."
 188   (interactive (list (read-from-minibuffer
 189                       "Keep lines (containing match for regexp): "
 190                       nil nil nil 'regexp-history nil t)))
 191   (save-excursion
 192     (or (bolp) (forward-line 1))
 193     (let ((start (point)))
 194       (while (not (eobp))
 195         ;; Start is first char not preserved by previous match.
 196         (if (not (re-search-forward regexp nil 'move))
 197             (delete-region start (point-max))
 198           (let ((end (save-excursion (goto-char (match-beginning 0))
 199                                      (beginning-of-line)
 200                                      (point))))
 201             ;; Now end is first char preserved by the new match.
 202             (if (< start end)
 203                 (delete-region start end))))
 204         (setq start (save-excursion (forward-line 1)
 205                                     (point)))
 206         ;; If the match was empty, avoid matching again at same place.
 207         (and (not (eobp)) (= (match-beginning 0) (match-end 0))
 208              (forward-char 1))))))
 209
 210 (defalias 'delete-matching-lines 'flush-lines)
 211 (defun flush-lines (regexp)
 212   "Delete lines containing matches for REGEXP.
 213 If a match is split across lines, all the lines it lies in are deleted.
 214 Applies to lines after point."
 215   (interactive (list (read-from-minibuffer
 216                       "Flush lines (containing match for regexp): "
 217                       nil nil nil 'regexp-history nil t)))
 218   (save-excursion
 219     (while (and (not (eobp))
 220                 (re-search-forward regexp nil t))
 221       (delete-region (save-excursion (goto-char (match-beginning 0))
 222                                      (beginning-of-line)
 223                                      (point))
 224                      (progn (forward-line 1) (point))))))
 225
 226 (defalias 'count-matches 'how-many)
 227 (defun how-many (regexp)
 228   "Print number of matches for REGEXP following point."
 229   (interactive (list(read-from-minibuffer
 230                      "How many matches for (regexp): "
 231                      nil nil nil 'regexp-history nil t)))
 232   (let ((count 0) opoint)
 233     (save-excursion
 234      (while (and (not (eobp))
 235                  (progn (setq opoint (point))
 236                         (re-search-forward regexp nil t)))
 237        (if (= opoint (point))
 238            (forward-char 1)
 239          (setq count (1+ count))))
 240      (message "%d occurrences" count))))
 241 \f
 242 (defvar occur-mode-map ())
 243 (if occur-mode-map
 244     ()
 245   (setq occur-mode-map (make-sparse-keymap))
 246   (define-key occur-mode-map [mouse-2] 'occur-mode-mouse-goto)
 247   (define-key occur-mode-map "\C-c\C-c" 'occur-mode-goto-occurrence)
 248   (define-key occur-mode-map "\C-m" 'occur-mode-goto-occurrence)
 249   (define-key occur-mode-map "\M-n" 'occur-next)
 250   (define-key occur-mode-map "\M-p" 'occur-prev)
 251   (define-key occur-mode-map "g" 'revert-buffer))
 252
 253
 254 (defvar occur-buffer nil
 255   "Name of buffer for last occur.")
 256
 257
 258 (defvar occur-nlines nil
 259   "Number of lines of context to show around matching line.")
 260
 261 (defvar occur-command-arguments nil
 262   "Arguments that were given to `occur' when it made this buffer.")
 263
 264 (put 'occur-mode 'mode-class 'special)
 265
 266 (defun occur-mode ()
 267   "Major mode for output from \\[occur].
 268 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 269 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 270 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 271
 272 \\{occur-mode-map}"
 273   (kill-all-local-variables)
 274   (use-local-map occur-mode-map)
 275   (setq major-mode 'occur-mode)
 276   (setq mode-name "Occur")
 277   (make-local-variable 'revert-buffer-function)
 278   (setq revert-buffer-function 'occur-revert-function)
 279   (make-local-variable 'occur-buffer)
 280   (make-local-variable 'occur-nlines)
 281   (make-local-variable 'occur-command-arguments)
 282   (run-hooks 'occur-mode-hook))
 283
 284 ;; Handle revert-buffer for *Occur* buffers.
 285 (defun occur-revert-function (ignore1 ignore2)
 286   (let ((args occur-command-arguments ))
 287     (save-excursion
 288       (set-buffer occur-buffer)
 289       (apply 'occur args))))
 290
 291 (defun occur-mode-mouse-goto (event)
 292   "In Occur mode, go to the occurrence whose line you click on."
 293   (interactive "e")
 294   (let (buffer pos)
 295     (save-excursion
 296       (set-buffer (window-buffer (posn-window (event-end event))))
 297       (save-excursion
 298         (goto-char (posn-point (event-end event)))
 299         (setq pos (occur-mode-find-occurrence))
 300         (setq buffer occur-buffer)))
 301     (pop-to-buffer buffer)
 302     (goto-char (marker-position pos))))
 303
 304 (defun occur-mode-find-occurrence ()
 305   (if (or (null occur-buffer)
 306           (null (buffer-name occur-buffer)))
 307       (progn
 308         (setq occur-buffer nil)
 309         (error "Buffer in which occurrences were found is deleted")))
 310   (let ((pos (get-text-property (point) 'occur)))
 311     (if (null pos)
 312         (error "No occurrence on this line")
 313       pos)))
 314
 315 (defun occur-mode-goto-occurrence ()
 316   "Go to the occurrence the current line describes."
 317   (interactive)
 318   (let ((pos (occur-mode-find-occurrence)))
 319     (pop-to-buffer occur-buffer)
 320     (goto-char (marker-position pos))))
 321
 322 (defun occur-next (&optional n)
 323   "Move to the Nth (default 1) next match in the *Occur* buffer."
 324   (interactive "p")
 325   (if (not n) (setq n 1))
 326   (let ((r))
 327     (while (> n 0)
 328       (if (get-text-property (point) 'occur-point)
 329           (forward-char 1))
 330       (setq r (next-single-property-change (point) 'occur-point))
 331       (if r
 332           (goto-char r)
 333         (error "no more matches"))
 334       (setq n (1- n)))))
 335
 336
 337
 338 (defun occur-prev (&optional n)
 339   "Move to the Nth (default 1) previous match in the *Occur* buffer."
 340   (interactive "p")
 341   (if (not n) (setq n 1))
 342   (let ((r))
 343     (while (> n 0)
 344
 345       (setq r (get-text-property (point) 'occur-point))
 346       (if r (forward-char -1))
 347
 348       (setq r (previous-single-property-change (point) 'occur-point))
 349       (if r
 350           (goto-char (- r 1))
 351         (error "no earlier matches"))
 352
 353       (setq n (1- n)))))
 354 \f
 355 (defcustom list-matching-lines-default-context-lines 0
 356   "*Default number of context lines to include around a `list-matching-lines'
 357 match.  A negative number means to include that many lines before the match.
 358 A positive number means to include that many lines both before and after."
 359   :type 'integer
 360   :group 'matching)
 361
 362 (defalias 'list-matching-lines 'occur)
 363
 364 (defvar list-matching-lines-face 'bold
 365   "*Face used by M-x list-matching-lines to show the text that matches.
 366 If the value is nil, don't highlight the matching portions specially.")
 367
 368 (defun occur (regexp &optional nlines)
 369   "Show all lines in the current buffer containing a match for REGEXP.
 370
 371 If a match spreads across multiple lines, all those lines are shown.
 372
 373 Each line is displayed with NLINES lines before and after, or -NLINES
 374 before if NLINES is negative.
 375 NLINES defaults to `list-matching-lines-default-context-lines'.
 376 Interactively it is the prefix arg.
 377
 378 The lines are shown in a buffer named `*Occur*'.
 379 It serves as a menu to find any of the occurrences in this buffer.
 380 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 381
 382 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 383 the matching is case-sensitive."
 384   (interactive
 385    (list (let* ((default (car regexp-history))
 386                 (input
 387                  (read-from-minibuffer
 388                   (if default
 389                       (format "List lines matching regexp (default `%s'): "
 390                               default)
 391                     "List lines matching regexp: ")
 392                   nil nil nil 'regexp-history nil t)))
 393            (if (string-equal input "")
 394                default
 395              (set-text-properties 0 (length input) nil input)
 396              input))
 397          current-prefix-arg))
 398   (let ((nlines (if nlines
 399                     (prefix-numeric-value nlines)
 400                   list-matching-lines-default-context-lines))
 401         (first t)
 402         ;;flag to prevent printing separator for first match
 403         (occur-num-matches 0)
 404         (buffer (current-buffer))
 405         (dir default-directory)
 406         (linenum 1)
 407         (prevpos
 408          ;;position of most recent match
 409          (point-min))
 410         (case-fold-search  (and case-fold-search
 411                                 (isearch-no-upper-case-p regexp t)))
 412         (final-context-start
 413          ;; Marker to the start of context immediately following
 414          ;; the matched text in *Occur*.
 415          (make-marker)))
 416 ;;;     (save-excursion
 417 ;;;       (beginning-of-line)
 418 ;;;       (setq linenum (1+ (count-lines (point-min) (point))))
 419 ;;;       (setq prevpos (point)))
 420     (save-excursion
 421       (goto-char (point-min))
 422       ;; Check first whether there are any matches at all.
 423       (if (not (re-search-forward regexp nil t))
 424           (message "No matches for `%s'" regexp)
 425         ;; Back up, so the search loop below will find the first match.
 426         (goto-char (match-beginning 0))
 427         (with-output-to-temp-buffer "*Occur*"
 428           (save-excursion
 429             (set-buffer standard-output)
 430             (setq default-directory dir)
 431             ;; We will insert the number of lines, and "lines", later.
 432             (insert " matching ")
 433             (let ((print-escape-newlines t))
 434               (prin1 regexp))
 435             (insert " in buffer " (buffer-name buffer) ?. ?\n)
 436             (occur-mode)
 437             (setq occur-buffer buffer)
 438             (setq occur-nlines nlines)
 439             (setq occur-command-arguments
 440                   (list regexp nlines)))
 441           (if (eq buffer standard-output)
 442               (goto-char (point-max)))
 443           (save-excursion
 444             ;; Find next match, but give up if prev match was at end of buffer.
 445             (while (and (not (= prevpos (point-max)))
 446                         (re-search-forward regexp nil t))
 447               (goto-char (match-beginning 0))
 448               (beginning-of-line)
 449               (save-match-data
 450                 (setq linenum (+ linenum (count-lines prevpos (point)))))
 451               (setq prevpos (point))
 452               (goto-char (match-end 0))
 453               (let* ((start
 454                       ;;start point of text in source buffer to be put
 455                       ;;into *Occur*
 456                       (save-excursion
 457                               (goto-char (match-beginning 0))
 458                               (forward-line (if (< nlines 0)
 459                                                 nlines
 460                                               (- nlines)))
 461                               (point)))
 462                      (end
 463                       ;; end point of text in source buffer to be put
 464                       ;; into *Occur*
 465                       (save-excursion
 466                         (goto-char (match-end 0))
 467                         (if (> nlines 0)
 468                             (forward-line (1+ nlines))
 469                           (forward-line 1))
 470                         (point)))
 471                      (match-beg
 472                       ;; Amount of context before matching text
 473                       (- (match-beginning 0) start))
 474                      (match-len
 475                       ;; Length of matching text
 476                       (- (match-end 0) (match-beginning 0)))
 477                      (tag (format "%5d" linenum))
 478                      (empty (make-string (length tag) ?\ ))
 479                      tem
 480                      ;; Number of lines of context to show for current match.
 481                      occur-marker
 482                      ;; Marker pointing to end of match in source buffer.
 483                      (text-beg
 484                       ;; Marker pointing to start of text for one
 485                       ;; match in *Occur*.
 486                       (make-marker))
 487                      (text-end
 488                       ;; Marker pointing to end of text for one match
 489                       ;; in *Occur*.
 490                       (make-marker))
 491                      )
 492                 (save-excursion
 493                   (setq occur-marker (make-marker))
 494                   (set-marker occur-marker (point))
 495                   (set-buffer standard-output)
 496                   (setq occur-num-matches (1+ occur-num-matches))
 497                   (or first (zerop nlines)
 498                       (insert "--------\n"))
 499                   (setq first nil)
 500
 501                   ;; Insert matching text including context lines from
 502                   ;; source buffer into *Occur*
 503                   (set-marker text-beg (point))
 504                   (insert-buffer-substring buffer start end)
 505                   (set-marker text-end (point))
 506
 507                   ;; Highlight text that was matched.
 508                   (if list-matching-lines-face
 509                       (put-text-property
 510                        (+ (marker-position text-beg) match-beg)
 511                        (+ (marker-position text-beg) match-beg match-len)
 512                        'face list-matching-lines-face))
 513
 514                   ;; `occur-point' property is used by occur-next and
 515                   ;; occur-prev to move between matching lines.
 516                   (put-text-property
 517                    (+ (marker-position text-beg) match-beg match-len)
 518                    (+ (marker-position text-beg) match-beg match-len 1)
 519                    'occur-point t)
 520                   (set-marker final-context-start
 521                               (- (point) (- end (match-end 0))))
 522
 523                   ;; Now go back to the start of the matching text
 524                   ;; adding the space and colon to the start of each line.
 525                   (goto-char (- (point) (- end start)))
 526                   ;; Insert space and colon for lines of context before match.
 527                   (setq tem (if (< linenum nlines)
 528                                 (- nlines linenum)
 529                               nlines))
 530                   (while (> tem 0)
 531                     (insert empty ?:)
 532                     (forward-line 1)
 533                     (setq tem (1- tem)))
 534
 535                   ;; Insert line number and colon for the lines of
 536                   ;; matching text.
 537                   (let ((this-linenum linenum))
 538                     (while (< (point) final-context-start)
 539                       (if (null tag)
 540                           (setq tag (format "%5d" this-linenum)))
 541                       (insert tag ?:)
 542                       (forward-line 1)
 543                       (setq tag nil)
 544                       (setq this-linenum (1+ this-linenum)))
 545                     (while (<= (point) final-context-start)
 546                       (insert empty ?:)
 547                       (forward-line 1)
 548                       (setq this-linenum (1+ this-linenum))))
 549
 550                   ;; Insert space and colon for lines of context after match.
 551                   (while (and (< (point) (point-max)) (< tem nlines))
 552                     (insert empty ?:)
 553                     (forward-line 1)
 554                     (setq tem (1+ tem)))
 555
 556                   ;; Add text properties.  The `occur' prop is used to
 557                   ;; store the marker of the matching text in the
 558                   ;; source buffer.
 559                   (put-text-property (marker-position text-beg)
 560                                      (- (marker-position text-end) 1)
 561                                      'mouse-face 'highlight)
 562                   (put-text-property (marker-position text-beg)
 563                                      (marker-position text-end)
 564                                      'occur occur-marker)
 565                   (goto-char (point-max)))
 566                 (forward-line 1)))
 567             (set-buffer standard-output)
 568             ;; Go back to top of *Occur* and finish off by printing the
 569             ;; number of matching lines.
 570             (goto-char (point-min))
 571             (let ((message-string
 572                    (if (= occur-num-matches 1)
 573                        "1 line"
 574                      (format "%d lines" occur-num-matches))))
 575               (insert message-string)
 576               (if (interactive-p)
 577                   (message "%s matched" message-string)))))))))
 578 \f
 579 ;; It would be nice to use \\[...], but there is no reasonable way
 580 ;; to make that display both SPC and Y.
 581 (defconst query-replace-help
 582   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
 583 RET or `q' to exit, Period to replace one match and exit,
 584 Comma to replace but not move point immediately,
 585 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
 586 C-w to delete match and recursive edit,
 587 C-l to clear the screen, redisplay, and offer same replacement again,
 588 ! to replace all remaining matches with no more questions,
 589 ^ to move point back to previous match."
 590   "Help message while in query-replace")
 591
 592 (defvar query-replace-map (make-sparse-keymap)
 593   "Keymap that defines the responses to questions in `query-replace'.
 594 The \"bindings\" in this map are not commands; they are answers.
 595 The valid answers include `act', `skip', `act-and-show',
 596 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
 597 `automatic', `backup', `exit-prefix', and `help'.")
 598
 599 (define-key query-replace-map " " 'act)
 600 (define-key query-replace-map "\d" 'skip)
 601 (define-key query-replace-map [delete] 'skip)
 602 (define-key query-replace-map [backspace] 'skip)
 603 (define-key query-replace-map "y" 'act)
 604 (define-key query-replace-map "n" 'skip)
 605 (define-key query-replace-map "Y" 'act)
 606 (define-key query-replace-map "N" 'skip)
 607 (define-key query-replace-map "," 'act-and-show)
 608 (define-key query-replace-map "q" 'exit)
 609 (define-key query-replace-map "\r" 'exit)
 610 (define-key query-replace-map [return] 'exit)
 611 (define-key query-replace-map "." 'act-and-exit)
 612 (define-key query-replace-map "\C-r" 'edit)
 613 (define-key query-replace-map "\C-w" 'delete-and-edit)
 614 (define-key query-replace-map "\C-l" 'recenter)
 615 (define-key query-replace-map "!" 'automatic)
 616 (define-key query-replace-map "^" 'backup)
 617 (define-key query-replace-map "\C-h" 'help)
 618 (define-key query-replace-map [f1] 'help)
 619 (define-key query-replace-map [help] 'help)
 620 (define-key query-replace-map "?" 'help)
 621 (define-key query-replace-map "\C-g" 'quit)
 622 (define-key query-replace-map "\C-]" 'quit)
 623 (define-key query-replace-map "\e" 'exit-prefix)
 624 (define-key query-replace-map [escape] 'exit-prefix)
 625
 626 (defun perform-replace (from-string replacements
 627                         query-flag regexp-flag delimited-flag
 628                         &optional repeat-count map)
 629   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
 630 Don't use this in your own program unless you want to query and set the mark
 631 just as `query-replace' does.  Instead, write a simple loop like this:
 632   (while (re-search-forward \"foo[ \t]+bar\" nil t)
 633     (replace-match \"foobar\" nil nil))
 634 which will run faster and probably do exactly what you want."
 635   (or map (setq map query-replace-map))
 636   (and query-flag minibuffer-auto-raise
 637        (raise-frame (window-frame (minibuffer-window))))
 638   (let ((nocasify (not (and case-fold-search case-replace
 639                             (string-equal from-string
 640                                           (downcase from-string)))))
 641         (literal (not regexp-flag))
 642         (search-function (if regexp-flag 're-search-forward 'search-forward))
 643         (search-string from-string)
 644         (real-match-data nil)           ; the match data for the current match
 645         (next-replacement nil)
 646         (replacement-index 0)
 647         (keep-going t)
 648         (stack nil)
 649         (next-rotate-count 0)
 650         (replace-count 0)
 651         (nonempty-match nil)
 652
 653         ;; Data for the next match.  If a cons, it has the same format as
 654         ;; (match-data); otherwise it is t if a match is possible at point.
 655         (match-again t)
 656
 657         (message
 658          (if query-flag
 659              (substitute-command-keys
 660               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
 661     (if (stringp replacements)
 662         (setq next-replacement replacements)
 663       (or repeat-count (setq repeat-count 1)))
 664     (if delimited-flag
 665         (setq search-function 're-search-forward
 666               search-string (concat "\\b"
 667                                     (if regexp-flag from-string
 668                                       (regexp-quote from-string))
 669                                     "\\b")))
 670     (push-mark)
 671     (undo-boundary)
 672     (unwind-protect
 673         ;; Loop finding occurrences that perhaps should be replaced.
 674         (while (and keep-going
 675                     (not (eobp))
 676                     ;; Use the next match if it is already known;
 677                     ;; otherwise, search for a match after moving forward
 678                     ;; one char if progress is required.
 679                     (setq real-match-data
 680                           (if (consp match-again)
 681                               (progn (goto-char (nth 1 match-again))
 682                                      match-again)
 683                             (and (or match-again
 684                                      (progn
 685                                        (forward-char 1)
 686                                        (not (eobp))))
 687                                  (funcall search-function search-string nil t)
 688                                  ;; For speed, use only integers and
 689                                  ;; reuse the list used last time.
 690                                  (match-data t real-match-data)))))
 691
 692           ;; Record whether the match is nonempty, to avoid an infinite loop
 693           ;; repeatedly matching the same empty string.
 694           (setq nonempty-match
 695                 (/= (nth 0 real-match-data) (nth 1 real-match-data)))
 696
 697           ;; If the match is empty, record that the next one can't be adjacent.
 698           ;; Otherwise, if matching a regular expression, do the next
 699           ;; match now, since the replacement for this match may
 700           ;; affect whether the next match is adjacent to this one.
 701           (setq match-again
 702                 (and nonempty-match
 703                      (or (not regexp-flag)
 704                          (and (looking-at search-string)
 705                               (match-data)))))
 706
 707           ;; If time for a change, advance to next replacement string.
 708           (if (and (listp replacements)
 709                    (= next-rotate-count replace-count))
 710               (progn
 711                 (setq next-rotate-count
 712                       (+ next-rotate-count repeat-count))
 713                 (setq next-replacement (nth replacement-index replacements))
 714                 (setq replacement-index (% (1+ replacement-index) (length replacements)))))
 715           (if (not query-flag)
 716               (progn
 717                 (store-match-data real-match-data)
 718                 (replace-match next-replacement nocasify literal)
 719                 (setq replace-count (1+ replace-count)))
 720             (undo-boundary)
 721             (let (done replaced key def)
 722               ;; Loop reading commands until one of them sets done,
 723               ;; which means it has finished handling this occurrence.
 724               (while (not done)
 725                 (store-match-data real-match-data)
 726                 (replace-highlight (match-beginning 0) (match-end 0))
 727                 ;; Bind message-log-max so we don't fill up the message log
 728                 ;; with a bunch of identical messages.
 729                 (let ((message-log-max nil))
 730                   (message message from-string next-replacement))
 731                 (setq key (read-event))
 732                 ;; Necessary in case something happens during read-event
 733                 ;; that clobbers the match data.
 734                 (store-match-data real-match-data)
 735                 (setq key (vector key))
 736                 (setq def (lookup-key map key))
 737                 ;; Restore the match data while we process the command.
 738                 (cond ((eq def 'help)
 739                        (with-output-to-temp-buffer "*Help*"
 740                          (princ
 741                           (concat "Query replacing "
 742                                   (if regexp-flag "regexp " "")
 743                                   from-string " with "
 744                                   next-replacement ".\n\n"
 745                                   (substitute-command-keys
 746                                    query-replace-help)))
 747                          (save-excursion
 748                            (set-buffer standard-output)
 749                            (help-mode))))
 750                       ((eq def 'exit)
 751                        (setq keep-going nil)
 752                        (setq done t))
 753                       ((eq def 'backup)
 754                        (if stack
 755                            (let ((elt (car stack)))
 756                              (goto-char (car elt))
 757                              (setq replaced (eq t (cdr elt)))
 758                              (or replaced
 759                                  (store-match-data (cdr elt)))
 760                              (setq stack (cdr stack)))
 761                          (message "No previous match")
 762                          (ding 'no-terminate)
 763                          (sit-for 1)))
 764                       ((eq def 'act)
 765                        (or replaced
 766                            (progn
 767                              (replace-match next-replacement nocasify literal)
 768                              (setq replace-count (1+ replace-count))))
 769                        (setq done t replaced t))
 770                       ((eq def 'act-and-exit)
 771                        (or replaced
 772                            (progn
 773                              (replace-match next-replacement nocasify literal)
 774                              (setq replace-count (1+ replace-count))))
 775                        (setq keep-going nil)
 776                        (setq done t replaced t))
 777                       ((eq def 'act-and-show)
 778                        (if (not replaced)
 779                            (progn
 780                              (replace-match next-replacement nocasify literal)
 781                              (setq replace-count (1+ replace-count))
 782                              (setq replaced t))))
 783                       ((eq def 'automatic)
 784                        (or replaced
 785                            (progn
 786                              (replace-match next-replacement nocasify literal)
 787                              (setq replace-count (1+ replace-count))))
 788                        (setq done t query-flag nil replaced t))
 789                       ((eq def 'skip)
 790                        (setq done t))
 791                       ((eq def 'recenter)
 792                        (recenter nil))
 793                       ((eq def 'edit)
 794                        (store-match-data
 795                         (prog1 (match-data)
 796                           (save-excursion (recursive-edit))))
 797                        ;; Before we make the replacement,
 798                        ;; decide whether the search string
 799                        ;; can match again just after this match.
 800                        (if (and regexp-flag nonempty-match)
 801                            (setq match-again (and (looking-at search-string)
 802                                                   (match-data)))))
 803                       ((eq def 'delete-and-edit)
 804                        (delete-region (match-beginning 0) (match-end 0))
 805                        (store-match-data
 806                         (prog1 (match-data)
 807                           (save-excursion (recursive-edit))))
 808                        (setq replaced t))
 809                       ;; Note: we do not need to treat `exit-prefix'
 810                       ;; specially here, since we reread
 811                       ;; any unrecognized character.
 812                       (t
 813                        (setq this-command 'mode-exited)
 814                        (setq keep-going nil)
 815                        (setq unread-command-events
 816                              (append (listify-key-sequence key)
 817                                      unread-command-events))
 818                        (setq done t))))
 819               ;; Record previous position for ^ when we move on.
 820               ;; Change markers to numbers in the match data
 821               ;; since lots of markers slow down editing.
 822               (setq stack
 823                     (cons (cons (point)
 824                                 (or replaced (match-data t)))
 825                           stack)))))
 826       (replace-dehighlight))
 827     (or unread-command-events
 828         (message "Replaced %d occurrence%s"
 829                  replace-count
 830                  (if (= replace-count 1) "" "s")))
 831     (and keep-going stack)))
 832
 833 (defcustom query-replace-highlight nil
 834   "*Non-nil means to highlight words during query replacement."
 835   :type 'boolean
 836   :group 'matching)
 837
 838 (defvar replace-overlay nil)
 839
 840 (defun replace-dehighlight ()
 841   (and replace-overlay
 842        (progn
 843          (delete-overlay replace-overlay)
 844          (setq replace-overlay nil))))
 845
 846 (defun replace-highlight (start end)
 847   (and query-replace-highlight
 848        (progn
 849          (or replace-overlay
 850              (progn
 851                (setq replace-overlay (make-overlay start end))
 852                (overlay-put replace-overlay 'face
 853                             (if (internal-find-face 'query-replace)
 854                                 'query-replace 'region))))
 855          (move-overlay replace-overlay start end (current-buffer)))))
 856
 857 ;;; replace.el ends here