lisp/indent.el

   1 ;;; indent.el --- indentation commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Commands for making and changing indentation in text.  These are
  27 ;; described in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (defgroup indent nil
  32   "Indentation commands"
  33   :group 'editing)
  34
  35 (defcustom standard-indent 4
  36   "*Default number of columns for margin-changing functions to indent."
  37   :group 'indent
  38   :type 'integer)
  39
  40 (defvar indent-line-function 'indent-to-left-margin
  41   "Function to indent current line.")
  42
  43 (defun indent-according-to-mode ()
  44   "Indent line in proper way for current major mode."
  45   (interactive)
  46   (funcall indent-line-function))
  47
  48 (defun indent-for-tab-command (&optional prefix-arg)
  49   "Indent line in proper way for current major mode."
  50   (interactive "P")
  51   (if (eq indent-line-function 'indent-to-left-margin)
  52       (insert-tab prefix-arg)
  53     (if prefix-arg
  54         (funcall indent-line-function prefix-arg)
  55       (funcall indent-line-function))))
  56
  57 (defun insert-tab (&optional prefix-arg)
  58   (let ((count (prefix-numeric-value prefix-arg)))
  59     (if (and abbrev-mode
  60              (eq (char-syntax (preceding-char)) ?w))
  61         (expand-abbrev))
  62     (if indent-tabs-mode
  63         (insert-char ?\t count)
  64       (indent-to (* tab-width (+ count (/ (current-column) tab-width)))))))
  65
  66 (defun indent-rigidly (start end arg)
  67   "Indent all lines starting in the region sideways by ARG columns.
  68 Called from a program, takes three arguments, START, END and ARG."
  69   (interactive "r\np")
  70   (save-excursion
  71     (goto-char end)
  72     (setq end (point-marker))
  73     (goto-char start)
  74     (or (bolp) (forward-line 1))
  75     (while (< (point) end)
  76       (let ((indent (current-indentation))
  77             eol-flag)
  78         (save-excursion
  79           (skip-chars-forward " \t")
  80           (setq eol-flag (eolp)))
  81         (or eol-flag
  82             (indent-to (max 0 (+ indent arg)) 0))
  83         (delete-region (point) (progn (skip-chars-forward " \t") (point))))
  84       (forward-line 1))
  85     (move-marker end nil)))
  86
  87 (defun indent-line-to (column)
  88   "Indent current line to COLUMN.
  89 This function removes or adds spaces and tabs at beginning of line
  90 only if necessary.  It leaves point at end of indentation."
  91   (back-to-indentation)
  92   (let ((cur-col (current-column)))
  93     (cond ((< cur-col column)
  94            (if (>= (- column (* (/ cur-col tab-width) tab-width)) tab-width)
  95                (delete-region (point)
  96                               (progn (skip-chars-backward " ") (point))))
  97            (indent-to column))
  98           ((> cur-col column) ; too far right (after tab?)
  99            (delete-region (progn (move-to-column column t) (point))
 100                           (progn (back-to-indentation) (point)))))))
 101
 102 (defun current-left-margin ()
 103   "Return the left margin to use for this line.
 104 This is the value of the buffer-local variable `left-margin' plus the value
 105 of the `left-margin' text-property at the start of the line."
 106   (save-excursion
 107     (back-to-indentation)
 108     (max 0
 109          (+ left-margin (or (get-text-property
 110                              (if (and (eobp) (not (bobp)))
 111                                  (1- (point)) (point))
 112                              'left-margin) 0)))))
 113
 114 (defun move-to-left-margin (&optional n force)
 115   "Move to the left margin of the current line.
 116 With optional argument, move forward N-1 lines first.
 117 The column moved to is the one given by the `current-left-margin' function.
 118 If the line's indentation appears to be wrong, and this command is called
 119 interactively or with optional argument FORCE, it will be fixed."
 120   (interactive (list (prefix-numeric-value current-prefix-arg) t))
 121   (beginning-of-line n)
 122   (skip-chars-forward " \t")
 123   (let ((lm (current-left-margin))
 124         (cc (current-column)))
 125     (cond ((> cc lm)
 126            (if (> (move-to-column lm force) lm)
 127                ;; If lm is in a tab and we are not forcing, move before tab
 128                (backward-char 1)))
 129           ((and force (< cc lm))
 130            (indent-to-left-margin)))))
 131
 132 ;; This is the default indent-line-function,
 133 ;; used in Fundamental Mode, Text Mode, etc.
 134 (defun indent-to-left-margin ()
 135   "Indent current line to the column given by `current-left-margin'."
 136   (indent-line-to (current-left-margin)))
 137
 138 (defun delete-to-left-margin (&optional from to)
 139   "Remove left margin indentation from a region.
 140 This deletes to the column given by `current-left-margin'.
 141 In no case will it delete non-whitespace.
 142 Args FROM and TO are optional; default is the whole buffer."
 143   (save-excursion
 144     (goto-char (or to (point-max)))
 145     (setq to (point-marker))
 146     (goto-char (or from (point-min)))
 147     (or (bolp) (forward-line 1))
 148     (while (< (point) to)
 149       (delete-region (point) (progn (move-to-left-margin nil t) (point)))
 150       (forward-line 1))
 151     (move-marker to nil)))
 152
 153 (defun set-left-margin (from to lm)
 154   "Set the left margin of the region to WIDTH.
 155 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 156   (interactive "r\nNSet left margin to column: ")
 157   (if (interactive-p) (setq lm (prefix-numeric-value lm)))
 158   (save-excursion
 159     ;; If inside indentation, start from BOL.
 160     (goto-char from)
 161     (skip-chars-backward " \t")
 162     (if (bolp) (setq from (point)))
 163     ;; Place end after whitespace
 164     (goto-char to)
 165     (skip-chars-forward " \t")
 166     (setq to (point-marker)))
 167   ;; Delete margin indentation first, but keep paragraph indentation.
 168   (delete-to-left-margin from to)
 169   (put-text-property from to 'left-margin lm)
 170   (indent-rigidly from to lm)
 171   (if auto-fill-function (save-excursion (fill-region from to nil t t)))
 172   (move-marker to nil))
 173
 174 (defun set-right-margin (from to lm)
 175   "Set the right margin of the region to WIDTH.
 176 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 177   (interactive "r\nNSet right margin to width: ")
 178   (if (interactive-p) (setq lm (prefix-numeric-value lm)))
 179   (save-excursion
 180     (goto-char from)
 181     (skip-chars-backward " \t")
 182     (if (bolp) (setq from (point))))
 183   (put-text-property from to 'right-margin lm)
 184   (if auto-fill-function (save-excursion (fill-region from to nil t t))))
 185
 186 (defun alter-text-property (from to prop func &optional object)
 187   "Programmatically change value of a text-property.
 188 For each region between FROM and TO that has a single value for PROPERTY,
 189 apply FUNCTION to that value and sets the property to the function's result.
 190 Optional fifth argument OBJECT specifies the string or buffer to operate on."
 191   (let ((begin from)
 192         end val)
 193     (while (setq val (get-text-property begin prop object)
 194                  end (text-property-not-all begin to prop val object))
 195       (put-text-property begin end prop (funcall func val) object)
 196       (setq begin end))
 197     (if (< begin to)
 198         (put-text-property begin to prop (funcall func val) object))))
 199
 200 (defun increase-left-margin (from to inc)
 201   "Increase or decrease the left-margin of the region.
 202 With no prefix argument, this adds `standard-indent' of indentation.
 203 A prefix arg (optional third arg INC noninteractively) specifies the amount
 204 to change the margin by, in characters.
 205 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 206   (interactive "*r\nP")
 207   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 208   (save-excursion
 209     (goto-char from)
 210     (skip-chars-backward " \t")
 211     (if (bolp) (setq from (point)))
 212     (goto-char to)
 213     (setq to (point-marker)))
 214   (alter-text-property from to 'left-margin
 215                        (lambda (v) (max (- left-margin) (+ inc (or v 0)))))
 216   (indent-rigidly from to inc)
 217   (if auto-fill-function (save-excursion (fill-region from to nil t t)))
 218   (move-marker to nil))
 219
 220 (defun decrease-left-margin (from to inc)
 221   "Make the left margin of the region smaller.
 222 With no prefix argument, decrease the indentation by `standard-indent'.
 223 A prefix arg (optional third arg INC noninteractively) specifies the amount
 224 to change the margin by, in characters.
 225 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 226   (interactive "*r\nP")
 227   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 228   (increase-left-margin from to (- inc)))
 229
 230 (defun increase-right-margin (from to inc)
 231   "Increase the right-margin of the region.
 232 With no prefix argument, increase the right margin by `standard-indent'.
 233 A prefix arg (optional third arg INC noninteractively) specifies the amount
 234 to change the margin by, in characters.  A negative argument decreases
 235 the right margin width.
 236 If `auto-fill-mode' is active, re-fill the region to fit the new margin."
 237   (interactive "r\nP")
 238   (if (interactive-p)
 239       (setq inc (if inc (prefix-numeric-value current-prefix-arg)
 240                   standard-indent)))
 241   (save-excursion
 242     (alter-text-property from to 'right-margin
 243        (lambda (v) (+ inc (or v 0))))
 244     (if auto-fill-function
 245         (fill-region from to nil t t))))
 246
 247 (defun decrease-right-margin (from to inc)
 248   "Make the right margin of the region smaller.
 249 With no prefix argument, decrease the right margin by `standard-indent'.
 250 A prefix arg (optional third arg INC noninteractively) specifies the amount
 251 of width to remove, in characters.  A negative argument increases
 252 the right margin width.
 253 If `auto-fill-mode' is active, re-fills region to fit in new margin."
 254   (interactive "*r\nP")
 255   (setq inc (if inc (prefix-numeric-value inc) standard-indent))
 256   (increase-right-margin from to (- inc)))
 257
 258 (defun beginning-of-line-text (&optional n)
 259   "Move to the beginning of the text on this line.
 260 With optional argument, move forward N-1 lines first.
 261 From the beginning of the line, moves past the left-margin indentation, the
 262 fill-prefix, and any indentation used for centering or right-justifying the
 263 line, but does not move past any whitespace that was explicitly inserted
 264 \(such as a tab used to indent the first line of a paragraph)."
 265   (interactive "p")
 266   (beginning-of-line n)
 267   (skip-chars-forward " \t")
 268   ;; Skip over fill-prefix.
 269   (if (and fill-prefix
 270            (not (string-equal fill-prefix "")))
 271       (if (equal fill-prefix
 272                  (buffer-substring
 273                   (point) (min (point-max) (+ (length fill-prefix) (point)))))
 274           (forward-char (length fill-prefix)))
 275     (if (and adaptive-fill-mode adaptive-fill-regexp
 276              (looking-at adaptive-fill-regexp))
 277         (goto-char (match-end 0))))
 278   ;; Skip centering or flushright indentation
 279   (if (memq (current-justification) '(center right))
 280       (skip-chars-forward " \t")))
 281
 282 (defvar indent-region-function nil
 283   "Short cut function to indent region using `indent-according-to-mode'.
 284 A value of nil means really run `indent-according-to-mode' on each line.")
 285
 286 (defun indent-region (start end column)
 287   "Indent each nonblank line in the region.
 288 With no argument, indent each line using `indent-according-to-mode',
 289 or use `indent-region-function' to do the whole region if that's non-nil.
 290 If there is a fill prefix, make each line start with the fill prefix.
 291 With argument COLUMN, indent each line to that column.
 292 Called from a program, takes three args: START, END and COLUMN."
 293   (interactive "r\nP")
 294   (if (null column)
 295       (if fill-prefix
 296           (save-excursion
 297             (goto-char end)
 298             (setq end (point-marker))
 299             (goto-char start)
 300             (let ((regexp (regexp-quote fill-prefix)))
 301               (while (< (point) end)
 302                 (or (looking-at regexp)
 303                     (and (bolp) (eolp))
 304                     (insert fill-prefix))
 305                 (forward-line 1))))
 306         (if indent-region-function
 307             (funcall indent-region-function start end)
 308           (save-excursion
 309             (goto-char end)
 310             (setq end (point-marker))
 311             (goto-char start)
 312             (or (bolp) (forward-line 1))
 313             (while (< (point) end)
 314               (or (and (bolp) (eolp))
 315                   (funcall indent-line-function))
 316               (forward-line 1))
 317             (move-marker end nil))))
 318     (setq column (prefix-numeric-value column))
 319     (save-excursion
 320       (goto-char end)
 321       (setq end (point-marker))
 322       (goto-char start)
 323       (or (bolp) (forward-line 1))
 324       (while (< (point) end)
 325         (delete-region (point) (progn (skip-chars-forward " \t") (point)))
 326         (or (eolp)
 327             (indent-to column 0))
 328         (forward-line 1))
 329       (move-marker end nil))))
 330
 331 (defun indent-relative-maybe ()
 332   "Indent a new line like previous nonblank line."
 333   (interactive)
 334   (indent-relative t))
 335
 336 (defun indent-relative (&optional unindented-ok)
 337   "Space out to under next indent point in previous nonblank line.
 338 An indent point is a non-whitespace character following whitespace.
 339 If the previous nonblank line has no indent points beyond the
 340 column point starts at, `tab-to-tab-stop' is done instead."
 341   (interactive "P")
 342   (if (and abbrev-mode
 343            (eq (char-syntax (preceding-char)) ?w))
 344       (expand-abbrev))
 345   (let ((start-column (current-column))
 346         indent)
 347     (save-excursion
 348       (beginning-of-line)
 349       (if (re-search-backward "^[^\n]" nil t)
 350           (let ((end (save-excursion (forward-line 1) (point))))
 351             (move-to-column start-column)
 352             ;; Is start-column inside a tab on this line?
 353             (if (> (current-column) start-column)
 354                 (backward-char 1))
 355             (or (looking-at "[ \t]")
 356                 unindented-ok
 357                 (skip-chars-forward "^ \t" end))
 358             (skip-chars-forward " \t" end)
 359             (or (= (point) end) (setq indent (current-column))))))
 360     (if indent
 361         (let ((opoint (point-marker)))
 362           (delete-region (point) (progn (skip-chars-backward " \t") (point)))
 363           (indent-to indent 0)
 364           (if (> opoint (point))
 365               (goto-char opoint))
 366           (move-marker opoint nil))
 367       (tab-to-tab-stop))))
 368
 369 (defcustom tab-stop-list
 370   '(8 16 24 32 40 48 56 64 72 80 88 96 104 112 120)
 371   "*List of tab stop positions used by `tab-to-tab-stop'.
 372 This should be a list of integers, ordered from smallest to largest."
 373   :group 'indent
 374   :type '(repeat integer))
 375
 376 (defvar edit-tab-stops-map nil "Keymap used in `edit-tab-stops'.")
 377 (if edit-tab-stops-map
 378     nil
 379   (setq edit-tab-stops-map (make-sparse-keymap))
 380   (define-key edit-tab-stops-map "\C-x\C-s" 'edit-tab-stops-note-changes)
 381   (define-key edit-tab-stops-map "\C-c\C-c" 'edit-tab-stops-note-changes))
 382
 383 (defvar edit-tab-stops-buffer nil
 384   "Buffer whose tab stops are being edited--in case
 385 the variable `tab-stop-list' is local in that buffer.")
 386
 387 (defun edit-tab-stops ()
 388   "Edit the tab stops used by `tab-to-tab-stop'.
 389 Creates a buffer *Tab Stops* containing text describing the tab stops.
 390 A colon indicates a column where there is a tab stop.
 391 You can add or remove colons and then do \\<edit-tab-stops-map>\\[edit-tab-stops-note-changes] to make changes take effect."
 392   (interactive)
 393   (setq edit-tab-stops-buffer (current-buffer))
 394   (switch-to-buffer (get-buffer-create "*Tab Stops*"))
 395   (use-local-map edit-tab-stops-map)
 396   (make-local-variable 'indent-tabs-mode)
 397   (setq indent-tabs-mode nil)
 398   (overwrite-mode 1)
 399   (setq truncate-lines t)
 400   (erase-buffer)
 401   (let ((tabs tab-stop-list))
 402     (while tabs
 403       (indent-to (car tabs) 0)
 404       (insert ?:)
 405       (setq tabs (cdr tabs))))
 406   (let ((count 0))
 407     (insert ?\n)
 408     (while (< count 8)
 409       (insert (+ count ?0))
 410     (insert "         ")
 411       (setq count (1+ count)))
 412     (insert ?\n)
 413     (while (> count 0)
 414       (insert "0123456789")
 415       (setq count (1- count))))
 416   (insert "\nTo install changes, type C-c C-c")
 417   (goto-char (point-min)))
 418
 419 (defun edit-tab-stops-note-changes ()
 420   "Put edited tab stops into effect."
 421   (interactive)
 422     (let (tabs)
 423       (save-excursion
 424         (goto-char 1)
 425         (end-of-line)
 426         (while (search-backward ":" nil t)
 427           (setq tabs (cons (current-column) tabs))))
 428       (bury-buffer (prog1 (current-buffer)
 429                           (switch-to-buffer edit-tab-stops-buffer)))
 430       (setq tab-stop-list tabs))
 431   (message "Tab stops installed"))
 432
 433 (defun tab-to-tab-stop ()
 434   "Insert spaces or tabs to next defined tab-stop column.
 435 The variable `tab-stop-list' is a list of columns at which there are tab stops.
 436 Use \\[edit-tab-stops] to edit them interactively."
 437   (interactive)
 438   (and abbrev-mode (= (char-syntax (preceding-char)) ?w)
 439        (expand-abbrev))
 440   (let ((tabs tab-stop-list))
 441     (while (and tabs (>= (current-column) (car tabs)))
 442       (setq tabs (cdr tabs)))
 443     (if tabs
 444         (let ((opoint (point)))
 445           (skip-chars-backward " \t")
 446           (delete-region (point) opoint)
 447           (indent-to (car tabs)))
 448       (insert ?\ ))))
 449
 450 (defun move-to-tab-stop ()
 451   "Move point to next defined tab-stop column.
 452 The variable `tab-stop-list' is a list of columns at which there are tab stops.
 453 Use \\[edit-tab-stops] to edit them interactively."
 454   (interactive)
 455   (let ((tabs tab-stop-list))
 456     (while (and tabs (>= (current-column) (car tabs)))
 457       (setq tabs (cdr tabs)))
 458     (if tabs
 459         (let ((before (point)))
 460           (move-to-column (car tabs) t)
 461           (save-excursion
 462             (goto-char before)
 463             ;; If we just added a tab, or moved over one,
 464             ;; delete any superfluous spaces before the old point.
 465             (if (and (eq (preceding-char) ?\ )
 466                      (eq (following-char) ?\t))
 467                 (let ((tabend (* (/ (current-column) tab-width) tab-width)))
 468                   (while (and (> (current-column) tabend)
 469                               (eq (preceding-char) ?\ ))
 470                     (forward-char -1))
 471                   (delete-region (point) before))))))))
 472
 473 (define-key global-map "\t" 'indent-for-tab-command)
 474 (define-key esc-map "\034" 'indent-region)
 475 (define-key ctl-x-map "\t" 'indent-rigidly)
 476 (define-key esc-map "i" 'tab-to-tab-stop)
 477
 478 ;;; indent.el ends here