lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do `M-x describe-mode'.
  33 ;;
  34 ;; This may be useful in your .emacs:
  35 ;;
  36 ;;      (autoload 'hexl-find-file "hexl"
  37 ;;        "Edit file FILENAME in hexl-mode." t)
  38 ;;
  39 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  40 ;;
  41 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  42 ;;
  43 ;; Currently hexl only supports big endian hex output with 16 bit
  44 ;; grouping.
  45 ;;
  46 ;; -iso in `hexl-options' will allow iso characters to display in the
  47 ;; ASCII region of the screen (if your emacs supports this) instead of
  48 ;; changing them to dots.
  49
  50 ;;; Code:
  51
  52 ;;
  53 ;; vars here
  54 ;;
  55
  56 (defgroup hexl nil
  57   "Edit a file in a hex dump format using the hexl filter."
  58   :group 'data)
  59
  60
  61 (defcustom hexl-program "hexl"
  62   "The program that will hexlify and dehexlify its stdin.
  63 `hexl-program' will always be concatenated with `hexl-options'
  64 and \"-de\" when dehexlifying a buffer."
  65   :type 'string
  66   :group 'hexl)
  67
  68 (defcustom hexl-iso ""
  69   "If your emacs can handle ISO characters, this should be set to
  70 \"-iso\" otherwise it should be \"\"."
  71   :type 'string
  72   :group 'hexl)
  73
  74 (defcustom hexl-options (format "-hex %s" hexl-iso)
  75   "Options to hexl-program that suit your needs."
  76   :type 'string
  77   :group 'hexl)
  78
  79 (defcustom hexlify-command
  80   (format "%s%s %s" exec-directory hexl-program hexl-options)
  81   "The command to use to hexlify a buffer."
  82   :type 'string
  83   :group 'hexl)
  84
  85 (defcustom dehexlify-command
  86   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  87   "The command to use to unhexlify a buffer."
  88   :type 'string
  89   :group 'hexl)
  90
  91 (defvar hexl-max-address 0
  92   "Maximum offset into hexl buffer.")
  93
  94 (defvar hexl-mode-map nil)
  95
  96 (defvar hexl-mode-old-local-map)
  97 (defvar hexl-mode-old-mode-name)
  98 (defvar hexl-mode-old-major-mode)
  99 (defvar hexl-mode-old-write-contents-hooks)
 100 (defvar hexl-mode-old-require-final-newline)
 101 (defvar hexl-mode-old-syntax-table)
 102
 103 ;; routines
 104
 105 (put 'hexl-mode 'mode-class 'special)
 106
 107 ;;;###autoload
 108 (defun hexl-mode (&optional arg)
 109   "\\<hexl-mode-map>
 110 A major mode for editing binary files in hex dump format.
 111
 112 This function automatically converts a buffer into the hexl format
 113 using the function `hexlify-buffer'.
 114
 115 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 116 representing the offset into the file that the characters on this line
 117 are at and 16 characters from the file (displayed as hexadecimal
 118 values grouped every 16 bits) and as their ASCII values.
 119
 120 If any of the characters (displayed as ASCII characters) are
 121 unprintable (control or meta characters) they will be replaced as
 122 periods.
 123
 124 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 125 in hexl format.
 126
 127 A sample format:
 128
 129   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 130   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 131   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 132   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 133   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 134   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 135   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 136   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 137   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 138   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 139   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 140   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 141   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 142   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 143   000000c0: 7265 6769 6f6e 2e0a                      region..
 144
 145 Movement is as simple as movement in a normal emacs text buffer.  Most
 146 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 147 to move the cursor left, right, down, and up).
 148
 149 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 150 also supported.
 151
 152 There are several ways to change text in hexl mode:
 153
 154 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 155 bound to self-insert so you can simply type the character and it will
 156 insert itself (actually overstrike) into the buffer.
 157
 158 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 159 it isn't bound to self-insert.  An octal number can be supplied in place
 160 of another key to insert the octal number's ASCII representation.
 161
 162 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 163 into the buffer at the current point.
 164
 165 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 166 into the buffer at the current point.
 167
 168 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 169 into the buffer at the current point.
 170
 171 \\[hexl-mode-exit] will exit hexl-mode.
 172
 173 Note: saving the file with any of the usual Emacs commands
 174 will actually convert it back to binary format while saving.
 175
 176 You can use \\[hexl-find-file] to visit a file in hexl-mode.
 177
 178 \\[describe-bindings] for advanced commands."
 179   (interactive "p")
 180   (if (eq major-mode 'hexl-mode)
 181       (error "You are already in hexl mode")
 182
 183     (let ((modified (buffer-modified-p))
 184           (inhibit-read-only t)
 185           (original-point (1- (point)))
 186           max-address)
 187       (and (eobp) (not (bobp))
 188            (setq original-point (1- original-point)))
 189       (if (not (or (eq arg 1) (not arg)))
 190           ;; if no argument then we guess at hexl-max-address
 191           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 192         (setq max-address (1- (buffer-size)))
 193         (hexlify-buffer)
 194         (set-buffer-modified-p modified))
 195       (make-local-variable 'hexl-max-address)
 196       (setq hexl-max-address max-address)
 197       (hexl-goto-address original-point))
 198
 199     ;; We do not turn off the old major mode; instead we just
 200     ;; override most of it.  That way, we can restore it perfectly.
 201     (make-local-variable 'hexl-mode-old-local-map)
 202     (setq hexl-mode-old-local-map (current-local-map))
 203     (use-local-map hexl-mode-map)
 204
 205     (make-local-variable 'hexl-mode-old-mode-name)
 206     (setq hexl-mode-old-mode-name mode-name)
 207     (setq mode-name "Hexl")
 208
 209     (make-local-variable 'hexl-mode-old-major-mode)
 210     (setq hexl-mode-old-major-mode major-mode)
 211     (setq major-mode 'hexl-mode)
 212
 213     (make-local-variable 'hexl-mode-old-syntax-table)
 214     (setq hexl-mode-old-syntax-table (syntax-table))
 215     (set-syntax-table (standard-syntax-table))
 216
 217     (make-local-variable 'hexl-mode-old-write-contents-hooks)
 218     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
 219     (make-local-variable 'write-contents-hooks)
 220     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 221
 222     (make-local-variable 'hexl-mode-old-require-final-newline)
 223     (setq hexl-mode-old-require-final-newline require-final-newline)
 224     (make-local-variable 'require-final-newline)
 225     (setq require-final-newline nil)
 226
 227     ;; Add hooks to rehexlify or dehexlify on various events.
 228     (make-local-hook 'after-revert-hook)
 229     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 230
 231     (make-local-hook 'change-major-mode-hook)
 232     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t))
 233   (run-hooks 'hexl-mode-hook))
 234
 235 (defun hexl-after-revert-hook ()
 236   (hexlify-buffer)
 237   (set-buffer-modified-p nil))
 238
 239 (defvar hexl-in-save-buffer nil)
 240
 241 (defun hexl-save-buffer ()
 242   "Save a hexl format buffer as binary in visited file if modified."
 243   (interactive)
 244   (if hexl-in-save-buffer nil
 245     (set-buffer-modified-p (if (buffer-modified-p)
 246                                (save-excursion
 247                                  (let ((buf (generate-new-buffer " hexl"))
 248                                        (name (buffer-name))
 249                                        (file-name (buffer-file-name))
 250                                        (start (point-min))
 251                                        (end (point-max))
 252                                        modified)
 253                                    (set-buffer buf)
 254                                    (insert-buffer-substring name start end)
 255                                    (set-buffer name)
 256                                    (dehexlify-buffer)
 257                                    ;; Prevent infinite recursion.
 258                                    (let ((hexl-in-save-buffer t))
 259                                      (save-buffer))
 260                                    (setq modified (buffer-modified-p))
 261                                    (delete-region (point-min) (point-max))
 262                                    (insert-buffer-substring buf start end)
 263                                    (kill-buffer buf)
 264                                    modified))
 265                              (message "(No changes need to be saved)")
 266                              nil))
 267     ;; Return t to indicate we have saved t
 268     t))
 269
 270 ;;;###autoload
 271 (defun hexl-find-file (filename)
 272   "Edit file FILENAME in hexl-mode.
 273 Switch to a buffer visiting file FILENAME, creating one in none exists."
 274   (interactive "fFilename: ")
 275   (find-file-literally filename)
 276   (if (not (eq major-mode 'hexl-mode))
 277       (hexl-mode)))
 278
 279 (defun hexl-mode-exit (&optional arg)
 280   "Exit Hexl mode, returning to previous mode.
 281 With arg, don't unhexlify buffer."
 282   (interactive "p")
 283   (if (or (eq arg 1) (not arg))
 284       (let ((modified (buffer-modified-p))
 285             (inhibit-read-only t)
 286             (original-point (1+ (hexl-current-address))))
 287         (dehexlify-buffer)
 288         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 289         (set-buffer-modified-p modified)
 290         (goto-char original-point)))
 291
 292   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 293   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 294
 295   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
 296   (setq require-final-newline hexl-mode-old-require-final-newline)
 297   (setq mode-name hexl-mode-old-mode-name)
 298   (use-local-map hexl-mode-old-local-map)
 299   (set-syntax-table hexl-mode-old-syntax-table)
 300   (setq major-mode hexl-mode-old-major-mode)
 301   (force-mode-line-update))
 302
 303 (defun hexl-maybe-dehexlify-buffer ()
 304   "Convert a hexl format buffer to binary.
 305 Ask the user for confirmation."
 306   (if (y-or-n-p "Convert contents back to binary format? ")
 307       (let ((modified (buffer-modified-p))
 308             (inhibit-read-only t)
 309             (original-point (1+ (hexl-current-address))))
 310         (dehexlify-buffer)
 311         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 312         (set-buffer-modified-p modified)
 313         (goto-char original-point))))
 314
 315 (defun hexl-current-address (&optional validate)
 316   "Return current hexl-address."
 317   (interactive)
 318   (let ((current-column (- (% (point) 68) 11))
 319         (hexl-address 0))
 320     (if (< current-column 0)
 321         (if validate
 322             (error "Point is not on a character in the file")
 323           (setq current-column 0)))
 324     (setq hexl-address
 325           (+ (* (/ (point) 68) 16)
 326              (if (>= current-column 41)
 327                  (- current-column 41)
 328                (/ (- current-column  (/ current-column 5)) 2))))
 329     hexl-address))
 330
 331 (defun hexl-address-to-marker (address)
 332   "Return marker for ADDRESS."
 333   (interactive "nAddress: ")
 334   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 335
 336 (defun hexl-goto-address (address)
 337   "Goto hexl-mode (decimal) address ADDRESS.
 338 Signal error if ADDRESS out of range."
 339   (interactive "nAddress: ")
 340   (if (or (< address 0) (> address hexl-max-address))
 341           (error "Out of hexl region"))
 342   (goto-char (hexl-address-to-marker address)))
 343
 344 (defun hexl-goto-hex-address (hex-address)
 345   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 346 Signal error if HEX-ADDRESS is out of range."
 347   (interactive "sHex Address: ")
 348   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 349
 350 (defun hexl-hex-string-to-integer (hex-string)
 351   "Return decimal integer for HEX-STRING."
 352   (interactive "sHex number: ")
 353   (let ((hex-num 0))
 354     (while (not (equal hex-string ""))
 355       (setq hex-num (+ (* hex-num 16)
 356                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 357       (setq hex-string (substring hex-string 1)))
 358     hex-num))
 359
 360 (defun hexl-octal-string-to-integer (octal-string)
 361   "Return decimal integer for OCTAL-STRING."
 362   (interactive "sOctal number: ")
 363   (let ((oct-num 0))
 364     (while (not (equal octal-string ""))
 365       (setq oct-num (+ (* oct-num 8)
 366                        (hexl-oct-char-to-integer
 367                         (string-to-char octal-string))))
 368       (setq octal-string (substring octal-string 1)))
 369     oct-num))
 370
 371 ;; move point functions
 372
 373 (defun hexl-backward-char (arg)
 374   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 375   (interactive "p")
 376   (hexl-goto-address (- (hexl-current-address) arg)))
 377
 378 (defun hexl-forward-char (arg)
 379   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 380   (interactive "p")
 381   (hexl-goto-address (+ (hexl-current-address) arg)))
 382
 383 (defun hexl-backward-short (arg)
 384   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 385   (interactive "p")
 386   (hexl-goto-address (let ((address (hexl-current-address)))
 387                        (if (< arg 0)
 388                            (progn
 389                              (setq arg (- arg))
 390                              (while (> arg 0)
 391                                (if (not (equal address (logior address 3)))
 392                                    (if (> address hexl-max-address)
 393                                        (progn
 394                                          (message "End of buffer.")
 395                                          (setq address hexl-max-address))
 396                                      (setq address (logior address 3)))
 397                                  (if (> address hexl-max-address)
 398                                      (progn
 399                                        (message "End of buffer.")
 400                                        (setq address hexl-max-address))
 401                                    (setq address (+ address 4))))
 402                                (setq arg (1- arg)))
 403                              (if (> address hexl-max-address)
 404                                  (progn
 405                                    (message "End of buffer.")
 406                                    (setq address hexl-max-address))
 407                                (setq address (logior address 3))))
 408                          (while (> arg 0)
 409                            (if (not (equal address (logand address -4)))
 410                                (setq address (logand address -4))
 411                              (if (not (equal address 0))
 412                                  (setq address (- address 4))
 413                                (message "Beginning of buffer.")))
 414                            (setq arg (1- arg))))
 415                        address)))
 416
 417 (defun hexl-forward-short (arg)
 418   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 419   (interactive "p")
 420   (hexl-backward-short (- arg)))
 421
 422 (defun hexl-backward-word (arg)
 423   "Move to left ARG words (right if ARG negative) in hexl-mode."
 424   (interactive "p")
 425   (hexl-goto-address (let ((address (hexl-current-address)))
 426                        (if (< arg 0)
 427                            (progn
 428                              (setq arg (- arg))
 429                              (while (> arg 0)
 430                                (if (not (equal address (logior address 7)))
 431                                    (if (> address hexl-max-address)
 432                                        (progn
 433                                          (message "End of buffer.")
 434                                          (setq address hexl-max-address))
 435                                      (setq address (logior address 7)))
 436                                  (if (> address hexl-max-address)
 437                                      (progn
 438                                        (message "End of buffer.")
 439                                        (setq address hexl-max-address))
 440                                    (setq address (+ address 8))))
 441                                (setq arg (1- arg)))
 442                              (if (> address hexl-max-address)
 443                                  (progn
 444                                    (message "End of buffer.")
 445                                    (setq address hexl-max-address))
 446                                (setq address (logior address 7))))
 447                          (while (> arg 0)
 448                            (if (not (equal address (logand address -8)))
 449                                (setq address (logand address -8))
 450                              (if (not (equal address 0))
 451                                  (setq address (- address 8))
 452                                (message "Beginning of buffer.")))
 453                            (setq arg (1- arg))))
 454                        address)))
 455
 456 (defun hexl-forward-word (arg)
 457   "Move right ARG words (left if ARG negative) in hexl-mode."
 458   (interactive "p")
 459   (hexl-backward-word (- arg)))
 460
 461 (defun hexl-previous-line (arg)
 462   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 463 If there is byte at the target address move to the last byte in that line."
 464   (interactive "p")
 465   (hexl-next-line (- arg)))
 466
 467 (defun hexl-next-line (arg)
 468   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 469 If there is no byte at the target address move to the last byte in that line."
 470   (interactive "p")
 471   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 472                        (if (and (< arg 0) (< address 0))
 473                                 (progn (message "Out of hexl region.")
 474                                        (setq address
 475                                              (% (hexl-current-address) 16)))
 476                          (if (and (> address hexl-max-address)
 477                                   (< (% hexl-max-address 16) (% address 16)))
 478                              (setq address hexl-max-address)
 479                            (if (> address hexl-max-address)
 480                                (progn (message "Out of hexl region.")
 481                                       (setq
 482                                        address
 483                                        (+ (logand hexl-max-address -16)
 484                                           (% (hexl-current-address) 16)))))))
 485                        address)))
 486
 487 (defun hexl-beginning-of-buffer (arg)
 488   "Move to the beginning of the hexl buffer.
 489 Leaves `hexl-mark' at previous position.
 490 With prefix arg N, puts point N bytes of the way from the true beginning."
 491   (interactive "p")
 492   (push-mark (point))
 493   (hexl-goto-address (+ 0 (1- arg))))
 494
 495 (defun hexl-end-of-buffer (arg)
 496   "Go to `hexl-max-address' minus ARG."
 497   (interactive "p")
 498   (push-mark (point))
 499   (hexl-goto-address (- hexl-max-address (1- arg))))
 500
 501 (defun hexl-beginning-of-line ()
 502   "Goto beginning of line in hexl mode."
 503   (interactive)
 504   (goto-char (+ (* (/ (point) 68) 68) 11)))
 505
 506 (defun hexl-end-of-line ()
 507   "Goto end of line in hexl mode."
 508   (interactive)
 509   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 510                        (if (> address hexl-max-address)
 511                            (setq address hexl-max-address))
 512                        address)))
 513
 514 (defun hexl-scroll-down (arg)
 515   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 516   (interactive "P")
 517   (if (null arg)
 518       (setq arg (1- (window-height)))
 519     (setq arg (prefix-numeric-value arg)))
 520   (hexl-scroll-up (- arg)))
 521
 522 (defun hexl-scroll-up (arg)
 523   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 524   (interactive "P")
 525   (if (null arg)
 526       (setq arg (1- (window-height)))
 527     (setq arg (prefix-numeric-value arg)))
 528   (let ((movement (* arg 16))
 529         (address (hexl-current-address)))
 530     (if (or (> (+ address movement) hexl-max-address)
 531             (< (+ address movement) 0))
 532         (message "Out of hexl region.")
 533       (hexl-goto-address (+ address movement))
 534       (recenter 0))))
 535
 536 (defun hexl-beginning-of-1k-page ()
 537   "Go to beginning of 1k boundary."
 538   (interactive)
 539   (hexl-goto-address (logand (hexl-current-address) -1024)))
 540
 541 (defun hexl-end-of-1k-page ()
 542   "Go to end of 1k boundary."
 543   (interactive)
 544   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 545                        (if (> address hexl-max-address)
 546                            (setq address hexl-max-address))
 547                        address)))
 548
 549 (defun hexl-beginning-of-512b-page ()
 550   "Go to beginning of 512 byte boundary."
 551   (interactive)
 552   (hexl-goto-address (logand (hexl-current-address) -512)))
 553
 554 (defun hexl-end-of-512b-page ()
 555   "Go to end of 512 byte boundary."
 556   (interactive)
 557   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 558                        (if (> address hexl-max-address)
 559                            (setq address hexl-max-address))
 560                        address)))
 561
 562 (defun hexl-quoted-insert (arg)
 563   "Read next input character and insert it.
 564 Useful for inserting control characters.
 565 You may also type up to 3 octal digits, to insert a character with that code"
 566   (interactive "p")
 567   (hexl-insert-char (read-quoted-char) arg))
 568
 569 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 570
 571 ;;;###autoload
 572 (defun hexlify-buffer ()
 573   "Convert a binary buffer to hexl format.
 574 This discards the buffer's undo information."
 575   (interactive)
 576   (and buffer-undo-list
 577        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 578            (error "Aborted")))
 579   (setq buffer-undo-list nil)
 580   (let ((binary-process-output nil) ; for Ms-Dos
 581         (binary-process-input buffer-file-type)
 582         ;; If the buffer was read with EOL conversions, be sure to use the
 583         ;; same conversions when passing the region to the `hexl' program.
 584         (coding-system-for-write
 585          (let ((eol-type (coding-system-eol-type buffer-file-coding-system)))
 586            (cond ((eq eol-type 1)
 587                   'raw-text-dos)
 588                  ((eq eol-type 2)
 589                   'raw-text-mac)
 590                  ((eq eol-type 0)
 591                   'raw-text-unix)
 592                  (t 'no-conversion))))
 593         (buffer-undo-list t))
 594     (shell-command-on-region (point-min) (point-max) hexlify-command t)))
 595
 596 (defun dehexlify-buffer ()
 597   "Convert a hexl format buffer to binary.
 598 This discards the buffer's undo information."
 599   (interactive)
 600   (and buffer-undo-list
 601        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 602            (error "Aborted")))
 603   (setq buffer-undo-list nil)
 604   (let ((binary-process-output buffer-file-type) ; for Ms-Dos
 605         (binary-process-input nil)
 606         (coding-system-for-read 'raw-text)
 607         (buffer-undo-list t))
 608     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 609
 610 (defun hexl-char-after-point ()
 611   "Return char for ASCII hex digits at point."
 612   (hexl-htoi (char-after (point))
 613              (char-after (1+ (point)))))
 614
 615 (defun hexl-htoi (lh rh)
 616   "Hex (char) LH (char) RH to integer."
 617     (+ (* (hexl-hex-char-to-integer lh) 16)
 618        (hexl-hex-char-to-integer rh)))
 619
 620 (defun hexl-hex-char-to-integer (character)
 621   "Take a char and return its value as if it was a hex digit."
 622   (if (and (>= character ?0) (<= character ?9))
 623       (- character ?0)
 624     (let ((ch (logior character 32)))
 625       (if (and (>= ch ?a) (<= ch ?f))
 626           (- ch (- ?a 10))
 627         (error "Invalid hex digit `%c'" ch)))))
 628
 629 (defun hexl-oct-char-to-integer (character)
 630   "Take a char and return its value as if it was a octal digit."
 631   (if (and (>= character ?0) (<= character ?7))
 632       (- character ?0)
 633     (error "Invalid octal digit `%c'" character)))
 634
 635 (defun hexl-printable-character (ch)
 636   "Return a displayable string for character CH."
 637   (format "%c" (if hexl-iso
 638                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 639                        46
 640                      ch)
 641                  (if (or (< ch 32) (>= ch 127))
 642                      46
 643                    ch))))
 644
 645 (defun hexl-self-insert-command (arg)
 646   "Insert this character."
 647   (interactive "p")
 648   (hexl-insert-char last-command-char arg))
 649
 650 (defun hexl-insert-char (ch num)
 651   "Insert a character in a hexl buffer."
 652   (let ((address (hexl-current-address t)))
 653     (while (> num 0)
 654       (let ((hex-position
 655              (+ (* (/ address 16) 68)
 656                 11
 657                 (* 2 (% address 16))
 658                 (/ (% address 16) 2)))
 659             (ascii-position
 660              (+ (* (/ address 16) 68) 52 (% address 16)))
 661             at-ascii-position)
 662         (if (= (point) ascii-position)
 663             (setq at-ascii-position t))
 664         (goto-char hex-position)
 665         (delete-char 2)
 666         (insert (format "%02x" ch))
 667         (goto-char ascii-position)
 668         (delete-char 1)
 669         (insert (hexl-printable-character ch))
 670         (or (eq address hexl-max-address)
 671             (setq address (1+ address)))
 672         (hexl-goto-address address)
 673         (if at-ascii-position
 674             (progn
 675               (beginning-of-line)
 676               (forward-char 51)
 677               (forward-char (% address 16)))))
 678       (setq num (1- num)))))
 679
 680 ;; hex conversion
 681
 682 (defun hexl-insert-hex-char (arg)
 683   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 684   (interactive "p")
 685   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 686     (if (or (> num 255) (< num 0))
 687         (error "Hex number out of range")
 688       (hexl-insert-char num arg))))
 689
 690 (defun hexl-insert-decimal-char (arg)
 691   "Insert a ASCII char ARG times at point for a given decimal number."
 692   (interactive "p")
 693   (let ((num (string-to-int (read-string "Decimal Number: "))))
 694     (if (or (> num 255) (< num 0))
 695         (error "Decimal number out of range")
 696       (hexl-insert-char num arg))))
 697
 698 (defun hexl-insert-octal-char (arg)
 699   "Insert a ASCII char ARG times at point for a given octal number."
 700   (interactive "p")
 701   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 702     (if (or (> num 255) (< num 0))
 703         (error "Decimal number out of range")
 704       (hexl-insert-char num arg))))
 705
 706 ;; startup stuff.
 707
 708 (if hexl-mode-map
 709     nil
 710   (setq hexl-mode-map (make-sparse-keymap))
 711
 712   (define-key hexl-mode-map [left] 'hexl-backward-char)
 713   (define-key hexl-mode-map [right] 'hexl-forward-char)
 714   (define-key hexl-mode-map [up] 'hexl-previous-line)
 715   (define-key hexl-mode-map [down] 'hexl-next-line)
 716   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 717   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 718   (define-key hexl-mode-map [next] 'hexl-scroll-up)
 719   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
 720   (define-key hexl-mode-map [home] 'hexl-beginning-of-buffer)
 721   (define-key hexl-mode-map [deletechar] 'undefined)
 722   (define-key hexl-mode-map [deleteline] 'undefined)
 723   (define-key hexl-mode-map [insertline] 'undefined)
 724   (define-key hexl-mode-map [S-delete] 'undefined)
 725   (define-key hexl-mode-map "\177" 'undefined)
 726
 727   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 728   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 729   (define-key hexl-mode-map "\C-d" 'undefined)
 730   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 731   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 732
 733   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 734       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 735
 736   (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 737   (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 738   (define-key hexl-mode-map "\C-k" 'undefined)
 739   (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 740   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 741   (define-key hexl-mode-map "\C-o" 'undefined)
 742   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 743   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 744   (define-key hexl-mode-map "\C-t" 'undefined)
 745   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 746   (define-key hexl-mode-map "\C-w" 'undefined)
 747   (define-key hexl-mode-map "\C-y" 'undefined)
 748
 749   (let ((ch 32))
 750     (while (< ch 127)
 751       (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 752       (setq ch (1+ ch))))
 753
 754   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 755   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 756   (define-key hexl-mode-map "\e\C-c" 'undefined)
 757   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 758   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 759   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 760   (define-key hexl-mode-map "\e\C-g" 'undefined)
 761   (define-key hexl-mode-map "\e\C-h" 'undefined)
 762   (define-key hexl-mode-map "\e\C-i" 'undefined)
 763   (define-key hexl-mode-map "\e\C-j" 'undefined)
 764   (define-key hexl-mode-map "\e\C-k" 'undefined)
 765   (define-key hexl-mode-map "\e\C-l" 'undefined)
 766   (define-key hexl-mode-map "\e\C-m" 'undefined)
 767   (define-key hexl-mode-map "\e\C-n" 'undefined)
 768   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 769   (define-key hexl-mode-map "\e\C-p" 'undefined)
 770   (define-key hexl-mode-map "\e\C-q" 'undefined)
 771   (define-key hexl-mode-map "\e\C-r" 'undefined)
 772   (define-key hexl-mode-map "\e\C-s" 'undefined)
 773   (define-key hexl-mode-map "\e\C-t" 'undefined)
 774   (define-key hexl-mode-map "\e\C-u" 'undefined)
 775
 776   (define-key hexl-mode-map "\e\C-w" 'undefined)
 777   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 778   (define-key hexl-mode-map "\e\C-y" 'undefined)
 779
 780   (define-key hexl-mode-map "\ea" 'undefined)
 781   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 782   (define-key hexl-mode-map "\ec" 'undefined)
 783   (define-key hexl-mode-map "\ed" 'undefined)
 784   (define-key hexl-mode-map "\ee" 'undefined)
 785   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 786   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 787   (define-key hexl-mode-map "\eh" 'undefined)
 788   (define-key hexl-mode-map "\ei" 'undefined)
 789   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 790   (define-key hexl-mode-map "\ek" 'undefined)
 791   (define-key hexl-mode-map "\el" 'undefined)
 792   (define-key hexl-mode-map "\em" 'undefined)
 793   (define-key hexl-mode-map "\en" 'undefined)
 794   (define-key hexl-mode-map "\eo" 'undefined)
 795   (define-key hexl-mode-map "\ep" 'undefined)
 796   (define-key hexl-mode-map "\eq" 'undefined)
 797   (define-key hexl-mode-map "\er" 'undefined)
 798   (define-key hexl-mode-map "\es" 'undefined)
 799   (define-key hexl-mode-map "\et" 'undefined)
 800   (define-key hexl-mode-map "\eu" 'undefined)
 801   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 802   (define-key hexl-mode-map "\ey" 'undefined)
 803   (define-key hexl-mode-map "\ez" 'undefined)
 804   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 805   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 806
 807   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 808
 809   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 810   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 811   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 812   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 813   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 814
 815 (provide 'hexl)
 816
 817 ;;; hexl.el ends here