lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function-alist
  31   (list (cons nil
  32               (if (fboundp 'tty-create-frame-with-faces)
  33                   'tty-create-frame-with-faces
  34                 (function
  35                  (lambda (parameters)
  36                    (error "Can't create multiple frames without a window system"))))))
  37   "Alist of window-system dependent functions to call to create a new frame.
  38 The window system startup file should add its frame creation
  39 function to this list, which should take an alist of parameters
  40 as its argument.")
  41
  42 (defvar window-system-default-frame-alist nil
  43   "Alist of window-system dependent default frame parameters.
  44 These may be set in your init file, like this:
  45
  46     ;; Disable menubar and toolbar on the console, but enable them under X.
  47     (setq window-system-default-frame-alist
  48           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  49             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  50
  51 Also see `default-frame-alist'.")
  52
  53 ;; The initial value given here used to ask for a minibuffer.
  54 ;; But that's not necessary, because the default is to have one.
  55 ;; By not specifying it here, we let an X resource specify it.
  56 (defcustom initial-frame-alist nil
  57   "*Alist of frame parameters for creating the initial X window frame.
  58 You can set this in your `.emacs' file; for example,
  59  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  60 Parameters specified here supersede the values given in `default-frame-alist'.
  61
  62 If the value calls for a frame without a minibuffer, and you have not created
  63 a minibuffer frame on your own, one is created according to
  64 `minibuffer-frame-alist'.
  65
  66 You can specify geometry-related options for just the initial frame
  67 by setting this variable in your `.emacs' file; however, they won't
  68 take effect until Emacs reads `.emacs', which happens after first creating
  69 the frame.  If you want the frame to have the proper geometry as soon
  70 as it appears, you need to use this three-step process:
  71 * Specify X resources to give the geometry you want.
  72 * Set `default-frame-alist' to override these options so that they
  73   don't affect subsequent frames.
  74 * Set `initial-frame-alist' in a way that matches the X resources,
  75   to override what you put in `default-frame-alist'."
  76   :type '(repeat (cons :format "%v"
  77                        (symbol :tag "Parameter")
  78                        (sexp :tag "Value")))
  79   :group 'frames)
  80
  81 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  82   "*Alist of frame parameters for initially creating a minibuffer frame.
  83 You can set this in your `.emacs' file; for example,
  84  (setq minibuffer-frame-alist
  85    '((top . 1) (left . 1) (width . 80) (height . 2)))
  86 Parameters specified here supersede the values given in
  87 `default-frame-alist', for a minibuffer frame."
  88   :type '(repeat (cons :format "%v"
  89                        (symbol :tag "Parameter")
  90                        (sexp :tag "Value")))
  91   :group 'frames)
  92
  93 (defcustom pop-up-frame-alist nil
  94   "*Alist of frame parameters used when creating pop-up frames.
  95 Pop-up frames are used for completions, help, and the like.
  96 This variable can be set in your init file, like this:
  97   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  98 These supersede the values given in `default-frame-alist',
  99 for pop-up frames."
 100   :type '(repeat (cons :format "%v"
 101                        (symbol :tag "Parameter")
 102                        (sexp :tag "Value")))
 103   :group 'frames)
 104
 105 (setq pop-up-frame-function
 106       ;; Using `function' here caused some sort of problem.
 107       '(lambda ()
 108          (make-frame pop-up-frame-alist)))
 109
 110 (defcustom special-display-frame-alist
 111   '((height . 14) (width . 80) (unsplittable . t))
 112   "*Alist of frame parameters used when creating special frames.
 113 Special frames are used for buffers whose names are in
 114 `special-display-buffer-names' and for buffers whose names match
 115 one of the regular expressions in `special-display-regexps'.
 116 This variable can be set in your init file, like this:
 117   (setq special-display-frame-alist '((width . 80) (height . 20)))
 118 These supersede the values given in `default-frame-alist'."
 119   :type '(repeat (cons :format "%v"
 120                          (symbol :tag "Parameter")
 121                          (sexp :tag "Value")))
 122   :group 'frames)
 123
 124 (defun special-display-popup-frame (buffer &optional args)
 125   "Display BUFFER in its own frame, reusing an existing window if any.
 126 Return the window chosen.
 127 Currently we do not insist on selecting the window within its frame.
 128 If ARGS is an alist, use it as a list of frame parameter specs.
 129 If ARGS is a list whose car is a symbol,
 130 use (car ARGS) as a function to do the work.
 131 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 132   (if (and args (symbolp (car args)))
 133       (apply (car args) buffer (cdr args))
 134     (let ((window (get-buffer-window buffer 0)))
 135       (or
 136        ;; If we have a window already, make it visible.
 137        (when window
 138          (let ((frame (window-frame window)))
 139            (make-frame-visible frame)
 140            (raise-frame frame)
 141            window))
 142        ;; Reuse the current window if the user requested it.
 143        (when (cdr (assq 'same-window args))
 144          (condition-case nil
 145              (progn (switch-to-buffer buffer) (selected-window))
 146            (error nil)))
 147        ;; Stay on the same frame if requested.
 148        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 149          (let* ((pop-up-frames nil) (pop-up-windows t)
 150                 special-display-regexps special-display-buffer-names
 151                 (window (display-buffer buffer)))
 152            ;; Only do it if this is a new window:
 153            ;; (set-window-dedicated-p window t)
 154            window))
 155        ;; If no window yet, make one in a new frame.
 156        (let ((frame
 157               (with-current-buffer buffer
 158                 (make-frame (append args special-display-frame-alist)))))
 159          (set-window-buffer (frame-selected-window frame) buffer)
 160          (set-window-dedicated-p (frame-selected-window frame) t)
 161          (frame-selected-window frame))))))
 162
 163 (defun handle-delete-frame (event)
 164   "Handle delete-frame events from the X server."
 165   (interactive "e")
 166   (let ((frame (posn-window (event-start event)))
 167         (i 0)
 168         (tail (frame-list)))
 169     (while tail
 170       (and (frame-visible-p (car tail))
 171            (not (eq (car tail) frame))
 172           (setq i (1+ i)))
 173       (setq tail (cdr tail)))
 174     (if (> i 0)
 175         (delete-frame frame t)
 176       ;; Gildea@x.org says it is ok to ask questions before terminating.
 177       (save-buffers-kill-emacs))))
 178 \f
 179 ;;;; Arrangement of frames at startup
 180
 181 ;; 1) Load the window system startup file from the lisp library and read the
 182 ;; high-priority arguments (-q and the like).  The window system startup
 183 ;; file should create any frames specified in the window system defaults.
 184 ;;
 185 ;; 2) If no frames have been opened, we open an initial text frame.
 186 ;;
 187 ;; 3) Once the init file is done, we apply any newly set parameters
 188 ;; in initial-frame-alist to the frame.
 189
 190 ;; These are now called explicitly at the proper times,
 191 ;; since that is easier to understand.
 192 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 193 ;; (add-hook 'before-init-hook 'frame-initialize)
 194 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 195
 196 ;; If we create the initial frame, this is it.
 197 (defvar frame-initial-frame nil)
 198
 199 ;; Record the parameters used in frame-initialize to make the initial frame.
 200 (defvar frame-initial-frame-alist)
 201
 202 (defvar frame-initial-geometry-arguments nil)
 203
 204 ;; startup.el calls this function before loading the user's init
 205 ;; file - if there is no frame with a minibuffer open now, create
 206 ;; one to display messages while loading the init file.
 207 (defun frame-initialize ()
 208   "Create an initial frame if necessary."
 209   ;; Are we actually running under a window system at all?
 210   (if (and initial-window-system
 211            (not noninteractive)
 212            (not (eq initial-window-system 'pc)))
 213       (progn
 214         ;; Turn on special-display processing only if there's a window system.
 215         (setq special-display-function 'special-display-popup-frame)
 216
 217         ;; If there is no frame with a minibuffer besides the terminal
 218         ;; frame, then we need to create the opening frame.  Make sure
 219         ;; it has a minibuffer, but let initial-frame-alist omit the
 220         ;; minibuffer spec.
 221         (or (delq terminal-frame (minibuffer-frame-list))
 222             (progn
 223               (setq frame-initial-frame-alist
 224                     (append initial-frame-alist default-frame-alist nil))
 225               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 226                   (setq frame-initial-frame-alist
 227                         (cons '(horizontal-scroll-bars . t)
 228                               frame-initial-frame-alist)))
 229               (setq frame-initial-frame-alist
 230                     (cons (cons 'window-system initial-window-system)
 231                           frame-initial-frame-alist))
 232               (setq default-minibuffer-frame
 233                     (setq frame-initial-frame
 234                           (make-frame frame-initial-frame-alist)))
 235               ;; Delete any specifications for window geometry parameters
 236               ;; so that we won't reapply them in frame-notice-user-settings.
 237               ;; It would be wrong to reapply them then,
 238               ;; because that would override explicit user resizing.
 239               (setq initial-frame-alist
 240                     (frame-remove-geometry-params initial-frame-alist))))
 241         ;; At this point, we know that we have a frame open, so we
 242         ;; can delete the terminal frame.
 243         (delete-frame terminal-frame)
 244         (setq terminal-frame nil))))
 245
 246 (defvar frame-notice-user-settings t
 247   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 248
 249 ;; startup.el calls this function after loading the user's init
 250 ;; file.  Now default-frame-alist and initial-frame-alist contain
 251 ;; information to which we must react; do what needs to be done.
 252 (defun frame-notice-user-settings ()
 253   "Act on user's init file settings of frame parameters.
 254 React to settings of `initial-frame-alist',
 255 `window-system-default-frame-alist' and `default-frame-alist'
 256 there (in decreasing order of priority)."
 257   ;; Make menu-bar-mode and default-frame-alist consistent.
 258   (when (boundp 'menu-bar-mode)
 259     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 260       (if default
 261           (setq menu-bar-mode (not (eq (cdr default) 0)))
 262         (setq default-frame-alist
 263               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 264                     default-frame-alist)))))
 265
 266   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 267   ;; it in batch mode since that would leave a tool-bar-lines
 268   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 269   ;; what we want.
 270   (when (and (boundp 'tool-bar-mode)
 271              (not noninteractive))
 272     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 273       (if default
 274           (setq tool-bar-mode (not (eq (cdr default) 0)))
 275         (setq default-frame-alist
 276               (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 277                     default-frame-alist)))))
 278
 279   ;; Creating and deleting frames may shift the selected frame around,
 280   ;; and thus the current buffer.  Protect against that.  We don't
 281   ;; want to use save-excursion here, because that may also try to set
 282   ;; the buffer of the selected window, which fails when the selected
 283   ;; window is the minibuffer.
 284   (let ((old-buffer (current-buffer))
 285         (window-system-frame-alist (cdr (assq initial-window-system
 286                                               window-system-default-frame-alist))))
 287
 288     (when (and frame-notice-user-settings
 289                (null frame-initial-frame))
 290       ;; This case happens when we don't have a window system, and
 291       ;; also for MS-DOS frames.
 292       (let ((parms (frame-parameters frame-initial-frame)))
 293         ;; Don't change the frame names.
 294         (setq parms (delq (assq 'name parms) parms))
 295         ;; Can't modify the minibuffer parameter, so don't try.
 296         (setq parms (delq (assq 'minibuffer parms) parms))
 297         (modify-frame-parameters nil
 298                                  (if (null initial-window-system)
 299                                      (append initial-frame-alist
 300                                              window-system-frame-alist
 301                                              default-frame-alist
 302                                              parms
 303                                              nil)
 304                                    ;; initial-frame-alist and
 305                                    ;; default-frame-alist were already
 306                                    ;; applied in pc-win.el.
 307                                    parms))
 308         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 309             (let ((newparms (frame-parameters))
 310                   (frame (selected-frame)))
 311               (tty-handle-reverse-video frame newparms)
 312               ;; If we changed the background color, we need to update
 313               ;; the background-mode parameter, and maybe some faces,
 314               ;; too.
 315               (when (assq 'background-color newparms)
 316                 (unless (or (assq 'background-mode initial-frame-alist)
 317                             (assq 'background-mode default-frame-alist))
 318                   (frame-set-background-mode frame))
 319                 (face-set-after-frame-default frame))))))
 320
 321     ;; If the initial frame is still around, apply initial-frame-alist
 322     ;; and default-frame-alist to it.
 323     (when (frame-live-p frame-initial-frame)
 324
 325       ;; When tool-bar has been switched off, correct the frame size
 326       ;; by the lines added in x-create-frame for the tool-bar and
 327       ;; switch `tool-bar-mode' off.
 328       (when (display-graphic-p)
 329         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 330                                   (assq 'tool-bar-lines window-system-frame-alist)
 331                                   (assq 'tool-bar-lines default-frame-alist))))
 332           (when (and tool-bar-originally-present
 333                      (or (null tool-bar-lines)
 334                          (null (cdr tool-bar-lines))
 335                          (eq 0 (cdr tool-bar-lines))))
 336             (let* ((char-height (frame-char-height frame-initial-frame))
 337                    (image-height tool-bar-images-pixel-height)
 338                    (margin (cond ((and (consp tool-bar-button-margin)
 339                                        (integerp (cdr tool-bar-button-margin))
 340                                        (> tool-bar-button-margin 0))
 341                                   (cdr tool-bar-button-margin))
 342                                  ((and (integerp tool-bar-button-margin)
 343                                        (> tool-bar-button-margin 0))
 344                                   tool-bar-button-margin)
 345                                  (t 0)))
 346                    (relief (if (and (integerp tool-bar-button-relief)
 347                                     (> tool-bar-button-relief 0))
 348                                tool-bar-button-relief 3))
 349                    (lines (/ (+ image-height
 350                                 (* 2 margin)
 351                                 (* 2 relief)
 352                                 (1- char-height))
 353                              char-height))
 354                    (height (frame-parameter frame-initial-frame 'height))
 355                    (newparms (list (cons 'height (- height lines))))
 356                    (initial-top (cdr (assq 'top
 357                                            frame-initial-geometry-arguments)))
 358                    (top (frame-parameter frame-initial-frame 'top)))
 359               (when (and (consp initial-top) (eq '- (car initial-top)))
 360                 (let ((adjusted-top
 361                        (cond ((and (consp top)
 362                                    (eq '+ (car top)))
 363                               (list '+
 364                                     (+ (cadr top)
 365                                        (* lines char-height))))
 366                              ((and (consp top)
 367                                    (eq '- (car top)))
 368                               (list '-
 369                                     (- (cadr top)
 370                                        (* lines char-height))))
 371                              (t (+ top (* lines char-height))))))
 372                   (setq newparms
 373                         (append newparms
 374                                 `((top . ,adjusted-top))
 375                                 nil))))
 376               (modify-frame-parameters frame-initial-frame newparms)
 377               (tool-bar-mode -1)))))
 378
 379       ;; The initial frame we create above always has a minibuffer.
 380       ;; If the user wants to remove it, or make it a minibuffer-only
 381       ;; frame, then we'll have to delete the current frame and make a
 382       ;; new one; you can't remove or add a root window to/from an
 383       ;; existing frame.
 384       ;;
 385       ;; NOTE: default-frame-alist was nil when we created the
 386       ;; existing frame.  We need to explicitly include
 387       ;; default-frame-alist in the parameters of the screen we
 388       ;; create here, so that its new value, gleaned from the user's
 389       ;; .emacs file, will be applied to the existing screen.
 390       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 391                             (assq 'minibuffer window-system-frame-alist)
 392                             (assq 'minibuffer default-frame-alist)
 393                             '(minibuffer . t)))
 394                    t))
 395           ;; Create the new frame.
 396           (let (parms new)
 397             ;; If the frame isn't visible yet, wait till it is.
 398             ;; If the user has to position the window,
 399             ;; Emacs doesn't know its real position until
 400             ;; the frame is seen to be visible.
 401             (while (not (cdr (assq 'visibility
 402                                    (frame-parameters frame-initial-frame))))
 403               (sleep-for 1))
 404             (setq parms (frame-parameters frame-initial-frame))
 405
 406             ;; Get rid of `name' unless it was specified explicitly before.
 407             (or (assq 'name frame-initial-frame-alist)
 408                 (setq parms (delq (assq 'name parms) parms)))
 409
 410             (setq parms (append initial-frame-alist
 411                                 window-system-frame-alist
 412                                 default-frame-alist
 413                                 parms
 414                                 nil))
 415
 416             ;; Get rid of `reverse', because that was handled
 417             ;; when we first made the frame.
 418             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 419
 420             (if (assq 'height frame-initial-geometry-arguments)
 421                 (setq parms (assq-delete-all 'height parms)))
 422             (if (assq 'width frame-initial-geometry-arguments)
 423                 (setq parms (assq-delete-all 'width parms)))
 424             (if (assq 'left frame-initial-geometry-arguments)
 425                 (setq parms (assq-delete-all 'left parms)))
 426             (if (assq 'top frame-initial-geometry-arguments)
 427                 (setq parms (assq-delete-all 'top parms)))
 428             (setq new
 429                   (make-frame
 430                    ;; Use the geometry args that created the existing
 431                    ;; frame, rather than the parms we get for it.
 432                    (append frame-initial-geometry-arguments
 433                            '((user-size . t) (user-position . t))
 434                            parms)))
 435             ;; The initial frame, which we are about to delete, may be
 436             ;; the only frame with a minibuffer.  If it is, create a
 437             ;; new one.
 438             (or (delq frame-initial-frame (minibuffer-frame-list))
 439                 (make-initial-minibuffer-frame nil))
 440
 441             ;; If the initial frame is serving as a surrogate
 442             ;; minibuffer frame for any frames, we need to wean them
 443             ;; onto a new frame.  The default-minibuffer-frame
 444             ;; variable must be handled similarly.
 445             (let ((users-of-initial
 446                    (filtered-frame-list
 447                     (function (lambda (frame)
 448                                 (and (not (eq frame frame-initial-frame))
 449                                      (eq (window-frame
 450                                           (minibuffer-window frame))
 451                                          frame-initial-frame)))))))
 452               (if (or users-of-initial
 453                       (eq default-minibuffer-frame frame-initial-frame))
 454
 455                   ;; Choose an appropriate frame.  Prefer frames which
 456                   ;; are only minibuffers.
 457                   (let* ((new-surrogate
 458                           (car
 459                            (or (filtered-frame-list
 460                                 (function
 461                                  (lambda (frame)
 462                                    (eq (cdr (assq 'minibuffer
 463                                                   (frame-parameters frame)))
 464                                        'only))))
 465                                (minibuffer-frame-list))))
 466                          (new-minibuffer (minibuffer-window new-surrogate)))
 467
 468                     (if (eq default-minibuffer-frame frame-initial-frame)
 469                         (setq default-minibuffer-frame new-surrogate))
 470
 471                     ;; Wean the frames using frame-initial-frame as
 472                     ;; their minibuffer frame.
 473                     (mapcar
 474                      (function
 475                       (lambda (frame)
 476                         (modify-frame-parameters
 477                          frame (list (cons 'minibuffer new-minibuffer)))))
 478                      users-of-initial))))
 479
 480            ;; Redirect events enqueued at this frame to the new frame.
 481             ;; Is this a good idea?
 482             (redirect-frame-focus frame-initial-frame new)
 483
 484             ;; Finally, get rid of the old frame.
 485             (delete-frame frame-initial-frame t))
 486
 487         ;; Otherwise, we don't need all that rigamarole; just apply
 488         ;; the new parameters.
 489         (let (newparms allparms tail)
 490           (setq allparms (append initial-frame-alist
 491                                  window-system-frame-alist
 492                                  default-frame-alist nil))
 493           (if (assq 'height frame-initial-geometry-arguments)
 494               (setq allparms (assq-delete-all 'height allparms)))
 495           (if (assq 'width frame-initial-geometry-arguments)
 496               (setq allparms (assq-delete-all 'width allparms)))
 497           (if (assq 'left frame-initial-geometry-arguments)
 498               (setq allparms (assq-delete-all 'left allparms)))
 499           (if (assq 'top frame-initial-geometry-arguments)
 500               (setq allparms (assq-delete-all 'top allparms)))
 501           (setq tail allparms)
 502           ;; Find just the parms that have changed since we first
 503           ;; made this frame.  Those are the ones actually set by
 504           ;; the init file.  For those parms whose values we already knew
 505           ;; (such as those spec'd by command line options)
 506           ;; it is undesirable to specify the parm again
 507           ;; once the user has seen the frame and been able to alter it
 508           ;; manually.
 509           (while tail
 510             (let (newval oldval)
 511               (setq oldval (assq (car (car tail))
 512                                  frame-initial-frame-alist))
 513               (setq newval (cdr (assq (car (car tail)) allparms)))
 514               (or (and oldval (eq (cdr oldval) newval))
 515                   (setq newparms
 516                         (cons (cons (car (car tail)) newval) newparms))))
 517             (setq tail (cdr tail)))
 518           (setq newparms (nreverse newparms))
 519           (modify-frame-parameters frame-initial-frame
 520                                    newparms)
 521           ;; If we changed the background color,
 522           ;; we need to update the background-mode parameter
 523           ;; and maybe some faces too.
 524           (when (assq 'background-color newparms)
 525             (unless (assq 'background-mode newparms)
 526               (frame-set-background-mode frame-initial-frame))
 527             (face-set-after-frame-default frame-initial-frame)))))
 528
 529     ;; Restore the original buffer.
 530     (set-buffer old-buffer)
 531
 532     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 533     ;; Make sure frame-notice-user-settings does nothing if called twice.
 534     (setq frame-notice-user-settings nil)
 535     (setq frame-initial-frame nil)))
 536
 537 (defun make-initial-minibuffer-frame (display)
 538   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 539     (if display
 540         (make-frame-on-display display parms)
 541       (make-frame parms))))
 542
 543 ;;;; Creation of additional frames, and other frame miscellanea
 544
 545 (defun modify-all-frames-parameters (alist)
 546   "Modify all current and future frames' parameters according to ALIST.
 547 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 548 See help of `modify-frame-parameters' for more information."
 549   (let (element)                        ;; temp
 550     (dolist (frame (frame-list))
 551       (modify-frame-parameters frame alist))
 552
 553     (dolist (pair alist)                ;; conses to add/replace
 554       ;; initial-frame-alist needs setting only when
 555       ;; frame-notice-user-settings is true
 556       (and frame-notice-user-settings
 557            (setq element (assoc (car pair) initial-frame-alist))
 558            (setq initial-frame-alist (delq element initial-frame-alist)))
 559       (and (setq element (assoc (car pair) default-frame-alist))
 560            (setq default-frame-alist (delq element default-frame-alist)))))
 561   (and frame-notice-user-settings
 562        (setq initial-frame-alist (append initial-frame-alist alist)))
 563   (setq default-frame-alist (append default-frame-alist alist)))
 564
 565 (defun get-other-frame ()
 566   "Return some frame other than the current frame.
 567 Create one if necessary.  Note that the minibuffer frame, if separate,
 568 is not considered (see `next-frame')."
 569   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 570                (make-frame)
 571              (next-frame (selected-frame)))))
 572     s))
 573
 574 (defun next-multiframe-window ()
 575   "Select the next window, regardless of which frame it is on."
 576   (interactive)
 577   (select-window (next-window (selected-window)
 578                               (> (minibuffer-depth) 0)
 579                               0))
 580   (select-frame-set-input-focus (selected-frame)))
 581
 582 (defun previous-multiframe-window ()
 583   "Select the previous window, regardless of which frame it is on."
 584   (interactive)
 585   (select-window (previous-window (selected-window)
 586                                   (> (minibuffer-depth) 0)
 587                                   0))
 588   (select-frame-set-input-focus (selected-frame)))
 589
 590 (defun make-frame-on-display (display &optional parameters)
 591   "Make a frame on X display DISPLAY.
 592 The optional second argument PARAMETERS specifies additional frame parameters."
 593   (interactive "sMake frame on display: ")
 594   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 595       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 596   (when (and (boundp 'x-initialized) (not x-initialized))
 597     (setq x-display-name display)
 598     (x-initialize-window-system))
 599   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 600
 601 (defun make-frame-on-tty (tty type &optional parameters)
 602   "Make a frame on terminal device TTY.
 603 TTY should be the file name of the tty device to use.  TYPE
 604 should be the terminal type string of TTY, for example \"xterm\"
 605 or \"vt100\".  The optional third argument PARAMETERS specifies
 606 additional frame parameters."
 607   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 608   (unless tty
 609     (error "Invalid terminal device"))
 610   (unless type
 611     (error "Invalid terminal type"))
 612   (make-frame `((window-system . nil) (tty . ,tty) (tty-type . ,type) . ,parameters)))
 613
 614 (defun make-frame-command ()
 615   "Make a new frame, and select it if the terminal displays only one frame."
 616   (interactive)
 617   (if (and window-system (not (eq window-system 'pc)))
 618       (make-frame)
 619     (select-frame (make-frame))))
 620
 621 (defvar before-make-frame-hook nil
 622   "Functions to run before a frame is created.")
 623
 624 (defvar after-make-frame-functions nil
 625   "Functions to run after a frame is created.
 626 The functions are run with one arg, the newly created frame.")
 627
 628 (defvar after-setting-font-hook nil
 629   "Functions to run after a frame's font has been changed.")
 630
 631 ;; Alias, kept temporarily.
 632 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 633
 634 (defun make-frame (&optional parameters)
 635   "Return a newly created frame displaying the current buffer.
 636 Optional argument PARAMETERS is an alist of parameters for the new frame.
 637 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 638
 639  (name . STRING)        The frame should be named STRING.
 640
 641  (width . NUMBER)       The frame should be NUMBER characters in width.
 642  (height . NUMBER)      The frame should be NUMBER text lines high.
 643
 644 You cannot specify either `width' or `height', you must use neither or both.
 645
 646  (minibuffer . t)       The frame should have a minibuffer.
 647  (minibuffer . nil)     The frame should have no minibuffer.
 648  (minibuffer . only)    The frame should contain only a minibuffer.
 649  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 650
 651  (window-system . nil)  The frame should be displayed on a terminal device.
 652  (window-system . x)    The frame should be displayed in an X window.
 653
 654  (device . ID)          The frame should use the display device identified by ID.
 655
 656 Before the frame is created (via `frame-creation-function-alist'), functions on the
 657 hook `before-make-frame-hook' are run.  After the frame is created, functions
 658 on `after-make-frame-functions' are run with one arg, the newly created frame.
 659
 660 This function itself does not make the new frame the selected frame.
 661 The previously selected frame remains selected.  However, the
 662 window system may select the new frame for its own reasons, for
 663 instance if the frame appears under the mouse pointer and your
 664 setup is for focus to follow the pointer."
 665   (interactive)
 666   (let* ((w (cond
 667              ((assq 'device parameters)
 668               (let ((type (display-live-p (cdr (assq 'device parameters)))))
 669                 (cond
 670                  ((eq type t) nil)
 671                  ((eq type nil) (error "Display %s does not exist" (cdr (assq 'device parameters))))
 672                  (t type))))
 673              ((assq 'window-system parameters)
 674               (cdr (assq 'window-system parameters)))
 675              (t window-system)))
 676          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 677          (oldframe (selected-frame))
 678          frame)
 679     (unless frame-creation-function
 680       (error "Don't know how to create a frame on window system %s" w))
 681     (run-hooks 'before-make-frame-hook)
 682     (setq frame (funcall frame-creation-function (append parameters (cdr (assq w window-system-default-frame-alist)))))
 683     (normal-erase-is-backspace-setup-frame frame)
 684     ;; Set up the frame-local environment, if needed.
 685     (when (eq (frame-display frame) (frame-display oldframe))
 686       (let ((env (frame-parameter oldframe 'environment)))
 687         (if (not (framep env))
 688             (setq env oldframe))
 689         (if env
 690             (set-frame-parameter frame 'environment env))))
 691     (run-hook-with-args 'after-make-frame-functions frame)
 692     frame))
 693
 694 (defun filtered-frame-list (predicate)
 695   "Return a list of all live frames which satisfy PREDICATE."
 696   (let* ((frames (frame-list))
 697          (list frames))
 698     (while (consp frames)
 699       (unless (funcall predicate (car frames))
 700         (setcar frames nil))
 701       (setq frames (cdr frames)))
 702     (delq nil list)))
 703
 704 (defun minibuffer-frame-list ()
 705   "Return a list of all frames with their own minibuffers."
 706   (filtered-frame-list
 707    (function (lambda (frame)
 708                (eq frame (window-frame (minibuffer-window frame)))))))
 709
 710 (defun frames-on-display-list (&optional terminal)
 711   "Return a list of all frames on TERMINAL.
 712
 713 TERMINAL should be a terminal identifier (an integer), a frame,
 714 or a name of an X display (a string of the form
 715 HOST:SERVER.SCREEN).
 716
 717 If TERMINAL is omitted or nil, it defaults to the selected
 718 frame's terminal device."
 719   (let* ((terminal (terminal-id terminal))
 720          (func #'(lambda (frame)
 721                    (eq (frame-display frame) terminal))))
 722     (filtered-frame-list func)))
 723
 724 (defun framep-on-display (&optional terminal)
 725   "Return the type of frames on TERMINAL.
 726 TERMINAL may be a terminal id, a display name or a frame.  If it
 727 is a frame, its type is returned.  If TERMINAL is omitted or nil,
 728 it defaults to the selected frame's terminal device.  All frames
 729 on a given display are of the same type."
 730   (or (display-live-p terminal)
 731       (framep terminal)
 732       (framep (car (frames-on-display-list terminal)))))
 733
 734 (defun frame-remove-geometry-params (param-list)
 735   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 736 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 737 `height', `user-size' and `user-position' parameters.
 738 Emacs uses this to avoid overriding explicit moves and resizings from
 739 the user during startup."
 740   (setq param-list (cons nil param-list))
 741   (let ((tail param-list))
 742     (while (consp (cdr tail))
 743       (if (and (consp (car (cdr tail)))
 744                (memq (car (car (cdr tail)))
 745                      '(height width top left user-position user-size)))
 746           (progn
 747             (setq frame-initial-geometry-arguments
 748                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 749             (setcdr tail (cdr (cdr tail))))
 750         (setq tail (cdr tail)))))
 751   (setq frame-initial-geometry-arguments
 752         (nreverse frame-initial-geometry-arguments))
 753   (cdr param-list))
 754
 755 (defcustom focus-follows-mouse t
 756   "*Non-nil if window system changes focus when you move the mouse.
 757 You should set this variable to tell Emacs how your window manager
 758 handles focus, since there is no way in general for Emacs to find out
 759 automatically."
 760   :type 'boolean
 761   :group 'frames
 762   :version "20.3")
 763
 764 (defun select-frame-set-input-focus (frame)
 765   "Select FRAME, raise it, and set input focus, if possible."
 766     (select-frame frame)
 767     (raise-frame frame)
 768     ;; Ensure, if possible, that frame gets input focus.
 769     (cond ((eq (window-system frame) 'x)
 770            (x-focus-frame frame))
 771           ((eq (window-system frame) 'w32)
 772            (w32-focus-frame frame)))
 773     (cond (focus-follows-mouse
 774            (set-mouse-position (selected-frame) (1- (frame-width)) 0))))
 775
 776 (defun other-frame (arg)
 777   "Select the ARG'th different visible frame on current display, and raise it.
 778 All frames are arranged in a cyclic order.
 779 This command selects the frame ARG steps away in that order.
 780 A negative ARG moves in the opposite order.
 781
 782 To make this command work properly, you must tell Emacs
 783 how the system (or the window manager) generally handles
 784 focus-switching between windows.  If moving the mouse onto a window
 785 selects it (gives it focus), set `focus-follows-mouse' to t.
 786 Otherwise, that variable should be nil."
 787   (interactive "p")
 788   (let ((frame (selected-frame)))
 789     (while (> arg 0)
 790       (setq frame (next-frame frame))
 791       (while (not (eq (frame-visible-p frame) t))
 792         (setq frame (next-frame frame)))
 793       (setq arg (1- arg)))
 794     (while (< arg 0)
 795       (setq frame (previous-frame frame))
 796       (while (not (eq (frame-visible-p frame) t))
 797         (setq frame (previous-frame frame)))
 798       (setq arg (1+ arg)))
 799     (select-frame-set-input-focus frame)))
 800
 801 (defun iconify-or-deiconify-frame ()
 802   "Iconify the selected frame, or deiconify if it's currently an icon."
 803   (interactive)
 804   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 805       (iconify-frame)
 806     (make-frame-visible)))
 807
 808 (defun suspend-frame ()
 809   "Do whatever is right to suspend the current frame.
 810 Calls `suspend-emacs' if invoked from the controlling tty device,
 811 `suspend-tty' from a secondary tty device, and
 812 `iconify-or-deiconify-frame' from an X frame."
 813   (interactive)
 814   (let ((type (framep (selected-frame))))
 815     (cond
 816      ((eq type 'x) (iconify-or-deiconify-frame))
 817      ((eq type t)
 818       (if (display-controlling-tty-p)
 819           (suspend-emacs)
 820         (suspend-tty)))
 821      (t (suspend-emacs)))))
 822
 823 (defun make-frame-names-alist ()
 824   (let* ((current-frame (selected-frame))
 825          (falist
 826           (cons
 827            (cons (frame-parameter current-frame 'name) current-frame) nil))
 828          (frame (next-frame nil t)))
 829     (while (not (eq frame current-frame))
 830       (progn
 831         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 832         (setq frame (next-frame frame t))))
 833     falist))
 834
 835 (defvar frame-name-history nil)
 836 (defun select-frame-by-name (name)
 837   "Select the frame on the current terminal whose name is NAME and raise it.
 838 If there is no frame by that name, signal an error."
 839   (interactive
 840    (let* ((frame-names-alist (make-frame-names-alist))
 841            (default (car (car frame-names-alist)))
 842            (input (completing-read
 843                    (format "Select Frame (default %s): " default)
 844                    frame-names-alist nil t nil 'frame-name-history)))
 845      (if (= (length input) 0)
 846          (list default)
 847        (list input))))
 848   (let* ((frame-names-alist (make-frame-names-alist))
 849          (frame (cdr (assoc name frame-names-alist))))
 850     (or frame
 851         (error "There is no frame named `%s'" name))
 852     (make-frame-visible frame)
 853     (raise-frame frame)
 854     (select-frame frame)
 855     ;; Ensure, if possible, that frame gets input focus.
 856     (cond ((eq (window-system frame) 'x)
 857            (x-focus-frame frame))
 858           ((eq (window-system frame) 'w32)
 859            (w32-focus-frame frame)))
 860     (when focus-follows-mouse
 861       (set-mouse-position frame (1- (frame-width frame)) 0))))
 862 \f
 863 ;;;; Frame configurations
 864
 865 (defun current-frame-configuration ()
 866   "Return a list describing the positions and states of all frames.
 867 Its car is `frame-configuration'.
 868 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 869 where
 870   FRAME is a frame object,
 871   ALIST is an association list specifying some of FRAME's parameters, and
 872   WINDOW-CONFIG is a window configuration object for FRAME."
 873   (cons 'frame-configuration
 874         (mapcar (function
 875                  (lambda (frame)
 876                    (list frame
 877                          (frame-parameters frame)
 878                          (current-window-configuration frame))))
 879                 (frame-list))))
 880
 881 (defun set-frame-configuration (configuration &optional nodelete)
 882   "Restore the frames to the state described by CONFIGURATION.
 883 Each frame listed in CONFIGURATION has its position, size, window
 884 configuration, and other parameters set as specified in CONFIGURATION.
 885 However, this function does not restore deleted frames.
 886
 887 Ordinarily, this function deletes all existing frames not
 888 listed in CONFIGURATION.  But if optional second argument NODELETE
 889 is given and non-nil, the unwanted frames are iconified instead."
 890   (or (frame-configuration-p configuration)
 891       (signal 'wrong-type-argument
 892               (list 'frame-configuration-p configuration)))
 893   (let ((config-alist (cdr configuration))
 894         frames-to-delete)
 895     (mapcar (function
 896              (lambda (frame)
 897                (let ((parameters (assq frame config-alist)))
 898                  (if parameters
 899                      (progn
 900                        (modify-frame-parameters
 901                         frame
 902                         ;; Since we can't set a frame's minibuffer status,
 903                         ;; we might as well omit the parameter altogether.
 904                         (let* ((parms (nth 1 parameters))
 905                                (mini (assq 'minibuffer parms)))
 906                           (if mini (setq parms (delq mini parms)))
 907                           parms))
 908                        (set-window-configuration (nth 2 parameters)))
 909                    (setq frames-to-delete (cons frame frames-to-delete))))))
 910             (frame-list))
 911     (if nodelete
 912         ;; Note: making frames invisible here was tried
 913         ;; but led to some strange behavior--each time the frame
 914         ;; was made visible again, the window manager asked afresh
 915         ;; for where to put it.
 916         (mapcar 'iconify-frame frames-to-delete)
 917       (mapcar 'delete-frame frames-to-delete))))
 918 \f
 919 ;;;; Convenience functions for accessing and interactively changing
 920 ;;;; frame parameters.
 921
 922 (defun frame-height (&optional frame)
 923   "Return number of lines available for display on FRAME.
 924 If FRAME is omitted, describe the currently selected frame."
 925   (cdr (assq 'height (frame-parameters frame))))
 926
 927 (defun frame-width (&optional frame)
 928   "Return number of columns available for display on FRAME.
 929 If FRAME is omitted, describe the currently selected frame."
 930   (cdr (assq 'width (frame-parameters frame))))
 931
 932 (defalias 'set-default-font 'set-frame-font)
 933 (defun set-frame-font (font-name &optional keep-size)
 934   "Set the font of the selected frame to FONT-NAME.
 935 When called interactively, prompt for the name of the font to use.
 936 To get the frame's current default font, use `frame-parameters'.
 937
 938 The default behavior is to keep the numbers of lines and columns in
 939 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
 940 non-nil (interactively, prefix argument) the current frame size (in
 941 pixels) is kept by adjusting the numbers of the lines and columns."
 942   (interactive
 943    (let* ((completion-ignore-case t)
 944           (font (completing-read "Font name: "
 945                          (mapcar #'list
 946                                  ;; x-list-fonts will fail with an error
 947                                  ;; if this frame doesn't support fonts.
 948                                  (x-list-fonts "*" nil (selected-frame)))
 949                          nil nil nil nil
 950                          (frame-parameter nil 'font))))
 951      (list font current-prefix-arg)))
 952   (let (fht fwd)
 953     (if keep-size
 954         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
 955               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
 956     (modify-frame-parameters (selected-frame)
 957                              (list (cons 'font font-name)))
 958     (if keep-size
 959         (modify-frame-parameters
 960          (selected-frame)
 961          (list (cons 'height (round fht (frame-char-height)))
 962                (cons 'width (round fwd (frame-char-width)))))))
 963   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
 964
 965 (defun set-frame-parameter (frame parameter value)
 966   "Set frame parameter PARAMETER to VALUE on FRAME.
 967 If FRAME is nil, it defaults to the selected frame.
 968 See `modify-frame-parameters.'"
 969   (modify-frame-parameters frame (list (cons parameter value))))
 970
 971 (defun set-background-color (color-name)
 972   "Set the background color of the selected frame to COLOR-NAME.
 973 When called interactively, prompt for the name of the color to use.
 974 To get the frame's current background color, use `frame-parameters'."
 975   (interactive (list (facemenu-read-color "Background color: ")))
 976   (modify-frame-parameters (selected-frame)
 977                            (list (cons 'background-color color-name)))
 978   (or window-system
 979       (face-set-after-frame-default (selected-frame))))
 980
 981 (defun set-foreground-color (color-name)
 982   "Set the foreground color of the selected frame to COLOR-NAME.
 983 When called interactively, prompt for the name of the color to use.
 984 To get the frame's current foreground color, use `frame-parameters'."
 985   (interactive (list (facemenu-read-color "Foreground color: ")))
 986   (modify-frame-parameters (selected-frame)
 987                            (list (cons 'foreground-color color-name)))
 988   (or window-system
 989       (face-set-after-frame-default (selected-frame))))
 990
 991 (defun set-cursor-color (color-name)
 992   "Set the text cursor color of the selected frame to COLOR-NAME.
 993 When called interactively, prompt for the name of the color to use.
 994 To get the frame's current cursor color, use `frame-parameters'."
 995   (interactive (list (facemenu-read-color "Cursor color: ")))
 996   (modify-frame-parameters (selected-frame)
 997                            (list (cons 'cursor-color color-name))))
 998
 999 (defun set-mouse-color (color-name)
1000   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
1001 When called interactively, prompt for the name of the color to use.
1002 To get the frame's current mouse color, use `frame-parameters'."
1003   (interactive (list (facemenu-read-color "Mouse color: ")))
1004   (modify-frame-parameters (selected-frame)
1005                            (list (cons 'mouse-color
1006                                        (or color-name
1007                                            (cdr (assq 'mouse-color
1008                                                       (frame-parameters))))))))
1009
1010 (defun set-border-color (color-name)
1011   "Set the color of the border of the selected frame to COLOR-NAME.
1012 When called interactively, prompt for the name of the color to use.
1013 To get the frame's current border color, use `frame-parameters'."
1014   (interactive (list (facemenu-read-color "Border color: ")))
1015   (modify-frame-parameters (selected-frame)
1016                            (list (cons 'border-color color-name))))
1017
1018 (defun auto-raise-mode (arg)
1019   "Toggle whether or not the selected frame should auto-raise.
1020 With arg, turn auto-raise mode on if and only if arg is positive.
1021 Note that this controls Emacs's own auto-raise feature.
1022 Some window managers allow you to enable auto-raise for certain windows.
1023 You can use that for Emacs windows if you wish, but if you do,
1024 that is beyond the control of Emacs and this command has no effect on it."
1025   (interactive "P")
1026   (if (null arg)
1027       (setq arg
1028             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1029                 -1 1)))
1030   (if (> arg 0)
1031       (raise-frame (selected-frame)))
1032   (modify-frame-parameters (selected-frame)
1033                            (list (cons 'auto-raise (> arg 0)))))
1034
1035 (defun auto-lower-mode (arg)
1036   "Toggle whether or not the selected frame should auto-lower.
1037 With arg, turn auto-lower mode on if and only if arg is positive.
1038 Note that this controls Emacs's own auto-lower feature.
1039 Some window managers allow you to enable auto-lower for certain windows.
1040 You can use that for Emacs windows if you wish, but if you do,
1041 that is beyond the control of Emacs and this command has no effect on it."
1042   (interactive "P")
1043   (if (null arg)
1044       (setq arg
1045             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1046                 -1 1)))
1047   (modify-frame-parameters (selected-frame)
1048                            (list (cons 'auto-lower (> arg 0)))))
1049 (defun set-frame-name (name)
1050   "Set the name of the selected frame to NAME.
1051 When called interactively, prompt for the name of the frame.
1052 The frame name is displayed on the modeline if the terminal displays only
1053 one frame, otherwise the name is displayed on the frame's caption bar."
1054   (interactive "sFrame name: ")
1055   (modify-frame-parameters (selected-frame)
1056                            (list (cons 'name name))))
1057
1058 (defun frame-current-scroll-bars (&optional frame)
1059   "Return the current scroll-bar settings in frame FRAME.
1060 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1061 current location of the vertical scroll-bars (left, right, or nil),
1062 and HORIZONTAL specifies the current location of the horizontal scroll
1063 bars (top, bottom, or nil)."
1064   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1065         (hor nil))
1066     (unless (memq vert '(left right nil))
1067       (setq vert default-frame-scroll-bars))
1068     (cons vert hor)))
1069 \f
1070 ;;;; Frame/display capabilities.
1071 (defun selected-display ()
1072   "Return the display that is now selected."
1073   (frame-display (selected-frame)))
1074
1075 (defun display-mouse-p (&optional display)
1076   "Return non-nil if DISPLAY has a mouse available.
1077 DISPLAY can be a display name, a frame, or nil (meaning the selected
1078 frame's display)."
1079   (let ((frame-type (framep-on-display display)))
1080     (cond
1081      ((eq frame-type 'pc)
1082       (msdos-mouse-p))
1083      ((eq system-type 'windows-nt)
1084       (with-no-warnings
1085        (> w32-num-mouse-buttons 0)))
1086      ((memq frame-type '(x mac))
1087       t)    ;; We assume X and Mac *always* have a pointing device
1088      (t
1089       (or (and (featurep 'xt-mouse)
1090                xterm-mouse-mode)
1091           ;; t-mouse is distributed with the GPM package.  It doesn't have
1092           ;; a toggle.
1093           (featurep 't-mouse))))))
1094
1095 (defun display-popup-menus-p (&optional display)
1096   "Return non-nil if popup menus are supported on DISPLAY.
1097 DISPLAY can be a display name, a frame, or nil (meaning the selected
1098 frame's display).
1099 Support for popup menus requires that the mouse be available."
1100   (and
1101    (let ((frame-type (framep-on-display display)))
1102      (memq frame-type '(x w32 pc mac)))
1103    (display-mouse-p display)))
1104
1105 (defun display-graphic-p (&optional display)
1106   "Return non-nil if DISPLAY is a graphic display.
1107 Graphical displays are those which are capable of displaying several
1108 frames and several different fonts at once.  This is true for displays
1109 that use a window system such as X, and false for text-only terminals.
1110 DISPLAY can be a display name, a frame, or nil (meaning the selected
1111 frame's display)."
1112   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1113
1114 (defun display-images-p (&optional display)
1115   "Return non-nil if DISPLAY can display images.
1116
1117 DISPLAY can be a display name, a frame, or nil (meaning the selected
1118 frame's display)."
1119   (and (display-graphic-p display)
1120        (fboundp 'image-mask-p)
1121        (fboundp 'image-size)))
1122
1123 (defalias 'display-multi-frame-p 'display-graphic-p)
1124 (defalias 'display-multi-font-p 'display-graphic-p)
1125
1126 (defun display-selections-p (&optional display)
1127   "Return non-nil if DISPLAY supports selections.
1128 A selection is a way to transfer text or other data between programs
1129 via special system buffers called `selection' or `cut buffer' or
1130 `clipboard'.
1131 DISPLAY can be a display name, a frame, or nil (meaning the selected
1132 frame's display)."
1133   (let ((frame-type (framep-on-display display)))
1134     (cond
1135      ((eq frame-type 'pc)
1136       ;; MS-DOG frames support selections when Emacs runs inside
1137       ;; the Windows' DOS Box.
1138       (with-no-warnings
1139        (not (null dos-windows-version))))
1140      ((memq frame-type '(x w32 mac))
1141       t)    ;; FIXME?
1142      (t
1143       nil))))
1144
1145 (defun display-screens (&optional display)
1146   "Return the number of screens associated with DISPLAY."
1147   (let ((frame-type (framep-on-display display)))
1148     (cond
1149      ((memq frame-type '(x w32 mac))
1150       (x-display-screens display))
1151      (t
1152       1))))
1153
1154 (defun display-pixel-height (&optional display)
1155   "Return the height of DISPLAY's screen in pixels.
1156 For character terminals, each character counts as a single pixel."
1157   (let ((frame-type (framep-on-display display)))
1158     (cond
1159      ((memq frame-type '(x w32 mac))
1160       (x-display-pixel-height display))
1161      (t
1162       (frame-height (if (framep display) display (selected-frame)))))))
1163
1164 (defun display-pixel-width (&optional display)
1165   "Return the width of DISPLAY's screen in pixels.
1166 For character terminals, each character counts as a single pixel."
1167   (let ((frame-type (framep-on-display display)))
1168     (cond
1169      ((memq frame-type '(x w32 mac))
1170       (x-display-pixel-width display))
1171      (t
1172       (frame-width (if (framep display) display (selected-frame)))))))
1173
1174 (defun display-mm-height (&optional display)
1175   "Return the height of DISPLAY's screen in millimeters.
1176 If the information is unavailable, value is nil."
1177   (and (memq (framep-on-display display) '(x w32 mac))
1178        (x-display-mm-height display)))
1179
1180 (defun display-mm-width (&optional display)
1181   "Return the width of DISPLAY's screen in millimeters.
1182 If the information is unavailable, value is nil."
1183   (and (memq (framep-on-display display) '(x w32 mac))
1184        (x-display-mm-width display)))
1185
1186 (defun display-backing-store (&optional display)
1187   "Return the backing store capability of DISPLAY's screen.
1188 The value may be `always', `when-mapped', `not-useful', or nil if
1189 the question is inapplicable to a certain kind of display."
1190   (let ((frame-type (framep-on-display display)))
1191     (cond
1192      ((memq frame-type '(x w32 mac))
1193       (x-display-backing-store display))
1194      (t
1195       'not-useful))))
1196
1197 (defun display-save-under (&optional display)
1198   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1199   (let ((frame-type (framep-on-display display)))
1200     (cond
1201      ((memq frame-type '(x w32 mac))
1202       (x-display-save-under display))
1203      (t
1204       'not-useful))))
1205
1206 (defun display-planes (&optional display)
1207   "Return the number of planes supported by DISPLAY."
1208   (let ((frame-type (framep-on-display display)))
1209     (cond
1210      ((memq frame-type '(x w32 mac))
1211       (x-display-planes display))
1212      ((eq frame-type 'pc)
1213       4)
1214      (t
1215       (truncate (log (length (tty-color-alist)) 2))))))
1216
1217 (defun display-color-cells (&optional display)
1218   "Return the number of color cells supported by DISPLAY."
1219   (let ((frame-type (framep-on-display display)))
1220     (cond
1221      ((memq frame-type '(x w32 mac))
1222       (x-display-color-cells display))
1223      ((eq frame-type 'pc)
1224       16)
1225      (t
1226       (tty-display-color-cells display)))))
1227
1228 (defun display-visual-class (&optional display)
1229   "Returns the visual class of DISPLAY.
1230 The value is one of the symbols `static-gray', `gray-scale',
1231 `static-color', `pseudo-color', `true-color', or `direct-color'."
1232   (let ((frame-type (framep-on-display display)))
1233     (cond
1234      ((memq frame-type '(x w32 mac))
1235       (x-display-visual-class display))
1236      ((and (memq frame-type '(pc t))
1237            (tty-display-color-p display))
1238       'static-color)
1239      (t
1240       'static-gray))))
1241
1242 \f
1243 ;;;; Aliases for backward compatibility with Emacs 18.
1244 (define-obsolete-function-alias 'screen-height 'frame-height) ;before 19.15
1245 (define-obsolete-function-alias 'screen-width 'frame-width) ;before 19.15
1246
1247 (defun set-screen-width (cols &optional pretend)
1248   "Change the size of the screen to COLS columns.
1249 Optional second arg non-nil means that redisplay should use COLS columns
1250 but that the idea of the actual width of the frame should not be changed.
1251 This function is provided only for compatibility with Emacs 18."
1252   (set-frame-width (selected-frame) cols pretend))
1253
1254 (defun set-screen-height (lines &optional pretend)
1255   "Change the height of the screen to LINES lines.
1256 Optional second arg non-nil means that redisplay should use LINES lines
1257 but that the idea of the actual height of the screen should not be changed.
1258 This function is provided only for compatibility with Emacs 18."
1259   (set-frame-height (selected-frame) lines pretend))
1260
1261 (defun delete-other-frames (&optional frame)
1262   "Delete all frames except FRAME.
1263 If FRAME uses another frame's minibuffer, the minibuffer frame is
1264 left untouched.  FRAME nil or omitted means use the selected frame."
1265   (interactive)
1266   (unless frame
1267     (setq frame (selected-frame)))
1268   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1269          (frames (delq mini-frame (delq frame (frame-list)))))
1270     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1271     ;; signals an error when trying to delete a mini-frame that's
1272     ;; still in use by another frame.
1273     (dolist (frame frames)
1274       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1275         (delete-frame frame)))
1276     ;; Delete minibuffer-only frames.
1277     (dolist (frame frames)
1278       (when (eq (frame-parameter frame 'minibuffer) 'only)
1279         (delete-frame frame)))))
1280
1281 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1282 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1283
1284 ;; miscellaneous obsolescence declarations
1285 (define-obsolete-variable-alias 'delete-frame-hook
1286     'delete-frame-functions "22.1")
1287
1288 \f
1289 ;; Highlighting trailing whitespace.
1290
1291 (make-variable-buffer-local 'show-trailing-whitespace)
1292
1293 (defcustom show-trailing-whitespace nil
1294   "*Non-nil means highlight trailing whitespace.
1295 This is done in the face `trailing-whitespace'."
1296   :type 'boolean
1297   :group 'whitespace-faces)
1298
1299
1300 \f
1301 ;; Scrolling
1302
1303 (defgroup scrolling nil
1304   "Scrolling windows."
1305   :version "21.1"
1306   :group 'frames)
1307
1308 (defcustom auto-hscroll-mode t
1309   "*Allow or disallow automatic scrolling windows horizontally.
1310 If non-nil, windows are automatically scrolled horizontally to make
1311 point visible."
1312   :version "21.1"
1313   :type 'boolean
1314   :group 'scrolling)
1315 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1316
1317 \f
1318 ;; Blinking cursor
1319
1320 (defgroup cursor nil
1321   "Displaying text cursors."
1322   :version "21.1"
1323   :group 'frames)
1324
1325 (defcustom blink-cursor-delay 0.5
1326   "*Seconds of idle time after which cursor starts to blink."
1327   :type 'number
1328   :group 'cursor)
1329
1330 (defcustom blink-cursor-interval 0.5
1331   "*Length of cursor blink interval in seconds."
1332   :type 'number
1333   :group 'cursor)
1334
1335 (defvar blink-cursor-idle-timer nil
1336   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1337 The function `blink-cursor-start' is called when the timer fires.")
1338
1339 (defvar blink-cursor-timer nil
1340   "Timer started from `blink-cursor-start'.
1341 This timer calls `blink-cursor-timer-function' every
1342 `blink-cursor-interval' seconds.")
1343
1344 (define-minor-mode blink-cursor-mode
1345   "Toggle blinking cursor mode.
1346 With a numeric argument, turn blinking cursor mode on iff ARG is positive.
1347 When blinking cursor mode is enabled, the cursor of the selected
1348 window blinks.
1349
1350 Note that this command is effective only when Emacs
1351 displays through a window system, because then Emacs does its own
1352 cursor display.  On a text-only terminal, this is not implemented."
1353   :init-value (not (or noninteractive
1354                        no-blinking-cursor
1355                        (eq system-type 'ms-dos)
1356                        (not (memq initial-window-system '(x w32 mac)))))
1357   :initialize 'custom-initialize-safe-default
1358   :group 'cursor
1359   :global t
1360   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1361   (if blink-cursor-timer (cancel-timer blink-cursor-timer))
1362   (setq blink-cursor-idle-timer nil
1363         blink-cursor-timer nil)
1364   (if blink-cursor-mode
1365       (progn
1366         ;; Hide the cursor.
1367         ;;(internal-show-cursor nil nil)
1368         (setq blink-cursor-idle-timer
1369               (run-with-idle-timer blink-cursor-delay
1370                                    blink-cursor-delay
1371                                    'blink-cursor-start)))
1372     (internal-show-cursor nil t)))
1373
1374 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1375
1376 (defun blink-cursor-start ()
1377   "Timer function called from the timer `blink-cursor-idle-timer'.
1378 This starts the timer `blink-cursor-timer', which makes the cursor blink
1379 if appropriate.  It also arranges to cancel that timer when the next
1380 command starts, by installing a pre-command hook."
1381   (when (null blink-cursor-timer)
1382     (add-hook 'pre-command-hook 'blink-cursor-end)
1383     (internal-show-cursor nil nil)
1384     (setq blink-cursor-timer
1385           (run-with-timer blink-cursor-interval blink-cursor-interval
1386                           'blink-cursor-timer-function))))
1387
1388 (defun blink-cursor-timer-function ()
1389   "Timer function of timer `blink-cursor-timer'."
1390   (internal-show-cursor nil (not (internal-show-cursor-p))))
1391
1392 (defun blink-cursor-end ()
1393   "Stop cursor blinking.
1394 This is installed as a pre-command hook by `blink-cursor-start'.
1395 When run, it cancels the timer `blink-cursor-timer' and removes
1396 itself as a pre-command hook."
1397   (remove-hook 'pre-command-hook 'blink-cursor-end)
1398   (internal-show-cursor nil t)
1399   (cancel-timer blink-cursor-timer)
1400   (setq blink-cursor-timer nil))
1401
1402
1403 \f
1404 ;; Hourglass pointer
1405
1406 (defcustom display-hourglass t
1407   "*Non-nil means show an hourglass pointer, when Emacs is busy.
1408 This feature only works when on a window system that can change
1409 cursor shapes."
1410   :type 'boolean
1411   :group 'cursor)
1412
1413 (defcustom hourglass-delay 1
1414   "*Seconds to wait before displaying an hourglass pointer when Emacs is busy."
1415   :type 'number
1416   :group 'cursor)
1417
1418 \f
1419 (defcustom cursor-in-non-selected-windows t
1420   "*Non-nil means show a hollow box cursor in non-selected windows.
1421 If nil, don't show a cursor except in the selected window.
1422 Use Custom to set this variable to get the display updated."
1423   :tag "Cursor In Non-selected Windows"
1424   :type 'boolean
1425   :group 'cursor
1426   :set #'(lambda (symbol value)
1427            (set-default symbol value)
1428            (force-mode-line-update t)))
1429
1430 \f
1431 ;;;; Key bindings
1432
1433 (define-key ctl-x-5-map "2" 'make-frame-command)
1434 (define-key ctl-x-5-map "1" 'delete-other-frames)
1435 (define-key ctl-x-5-map "0" 'delete-frame)
1436 (define-key ctl-x-5-map "o" 'other-frame)
1437
1438 (provide 'frame)
1439
1440 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1441 ;;; frame.el ends here