lisp/dired.el

   1 ;;; dired.el --- directory-browsing commands
   2
   3 ;; Copyright (C) 1985, 1986, 1992, 1993, 1994, 1995, 1996, 1997, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Maintainer: FSF
   8 ;; Keywords: files
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This is a major mode for directory browsing and editing.  It is
  30 ;; documented in the Emacs manual.
  31
  32 ;; Rewritten in 1990/1991 to add tree features, file marking and
  33 ;; sorting by Sebastian Kremer <sk@thp.uni-koeln.de>.
  34 ;; Finished up by rms in 1992.
  35
  36 ;;; Code:
  37
  38 ;;; Customizable variables
  39
  40 (defgroup dired nil
  41   "Directory editing."
  42   :link '(custom-manual "(emacs)Dired")
  43   :group 'files)
  44
  45 (defgroup dired-mark nil
  46   "Handling marks in Dired."
  47   :prefix "dired-"
  48   :group 'dired)
  49
  50
  51 ;;;###autoload
  52 (defcustom dired-listing-switches "-al"
  53   "*Switches passed to `ls' for Dired.  MUST contain the `l' option.
  54 May contain all other options that don't contradict `-l';
  55 may contain even `F', `b', `i' and `s'.  See also the variable
  56 `dired-ls-F-marks-symlinks' concerning the `F' switch.
  57 On systems such as MS-DOS and MS-Windows, which use `ls' emulation in Lisp,
  58 some of the `ls' switches are not supported; see the doc string of
  59 `insert-directory' in `ls-lisp.el' for more details."
  60   :type 'string
  61   :group 'dired)
  62
  63 (defvar dired-subdir-switches nil
  64   "If non-nil, switches passed to `ls' for inserting subdirectories.
  65 If nil, `dired-listing-switches' is used.")
  66
  67 ; Don't use absolute file names as /bin should be in any PATH and people
  68 ; may prefer /usr/local/gnu/bin or whatever.  However, chown is
  69 ; usually not in PATH.
  70
  71 ;;;###autoload
  72 (defvar dired-chown-program
  73   (if (memq system-type '(hpux usg-unix-v irix linux gnu/linux cygwin))
  74       "chown"
  75     (if (file-exists-p "/usr/sbin/chown")
  76         "/usr/sbin/chown"
  77       "/etc/chown"))
  78   "Name of chown command (usually `chown' or `/etc/chown').")
  79
  80 (defvar dired-use-ls-dired (not (not (string-match "gnu" system-configuration)))
  81   "Non-nil means Dired should use `ls --dired'.")
  82
  83 (defvar dired-chmod-program "chmod"
  84   "Name of chmod command (usually `chmod').")
  85
  86 (defvar dired-touch-program "touch"
  87   "Name of touch command (usually `touch').")
  88
  89 ;;;###autoload
  90 (defcustom dired-ls-F-marks-symlinks nil
  91   "*Informs Dired about how `ls -lF' marks symbolic links.
  92 Set this to t if `ls' (or whatever program is specified by
  93 `insert-directory-program') with `-lF' marks the symbolic link
  94 itself with a trailing @ (usually the case under Ultrix).
  95
  96 Example: if `ln -s foo bar; ls -F bar' gives `bar -> foo', set it to
  97 nil (the default), if it gives `bar@ -> foo', set it to t.
  98
  99 Dired checks if there is really a @ appended.  Thus, if you have a
 100 marking `ls' program on one host and a non-marking on another host, and
 101 don't care about symbolic links which really end in a @, you can
 102 always set this variable to t."
 103   :type 'boolean
 104   :group 'dired-mark)
 105
 106 ;;;###autoload
 107 (defcustom dired-trivial-filenames "^\\.\\.?$\\|^#"
 108   "*Regexp of files to skip when finding first file of a directory.
 109 A value of nil means move to the subdir line.
 110 A value of t means move to first file."
 111   :type '(choice (const :tag "Move to subdir" nil)
 112                  (const :tag "Move to first" t)
 113                  regexp)
 114   :group 'dired)
 115
 116 ;;;###autoload
 117 (defcustom dired-keep-marker-rename t
 118   ;; Use t as default so that moved files "take their markers with them".
 119   "*Controls marking of renamed files.
 120 If t, files keep their previous marks when they are renamed.
 121 If a character, renamed files (whether previously marked or not)
 122 are afterward marked with that character."
 123   :type '(choice (const :tag "Keep" t)
 124                  (character :tag "Mark"))
 125   :group 'dired-mark)
 126
 127 ;;;###autoload
 128 (defcustom dired-keep-marker-copy ?C
 129   "*Controls marking of copied files.
 130 If t, copied files are marked if and as the corresponding original files were.
 131 If a character, copied files are unconditionally marked with that character."
 132   :type '(choice (const :tag "Keep" t)
 133                  (character :tag "Mark"))
 134   :group 'dired-mark)
 135
 136 ;;;###autoload
 137 (defcustom dired-keep-marker-hardlink ?H
 138   "*Controls marking of newly made hard links.
 139 If t, they are marked if and as the files linked to were marked.
 140 If a character, new links are unconditionally marked with that character."
 141   :type '(choice (const :tag "Keep" t)
 142                  (character :tag "Mark"))
 143   :group 'dired-mark)
 144
 145 ;;;###autoload
 146 (defcustom dired-keep-marker-symlink ?Y
 147   "*Controls marking of newly made symbolic links.
 148 If t, they are marked if and as the files linked to were marked.
 149 If a character, new links are unconditionally marked with that character."
 150   :type '(choice (const :tag "Keep" t)
 151                  (character :tag "Mark"))
 152   :group 'dired-mark)
 153
 154 ;;;###autoload
 155 (defcustom dired-dwim-target nil
 156   "*If non-nil, Dired tries to guess a default target directory.
 157 This means: if there is a dired buffer displayed in the next window,
 158 use its current subdir, instead of the current subdir of this dired buffer.
 159
 160 The target is used in the prompt for file copy, rename etc."
 161   :type 'boolean
 162   :group 'dired)
 163
 164 ;;;###autoload
 165 (defcustom dired-copy-preserve-time t
 166   "*If non-nil, Dired preserves the last-modified time in a file copy.
 167 \(This works on only some systems.)"
 168   :type 'boolean
 169   :group 'dired)
 170
 171 ; These variables were deleted and the replacements are on files.el.
 172 ; We leave aliases behind for back-compatibility.
 173 (defvaralias 'dired-free-space-program 'directory-free-space-program)
 174 (defvaralias 'dired-free-space-args 'directory-free-space-args)
 175
 176 ;;; Hook variables
 177
 178 (defcustom dired-load-hook nil
 179   "Run after loading Dired.
 180 You can customize key bindings or load extensions with this."
 181   :group 'dired
 182   :type 'hook)
 183
 184 (defcustom dired-mode-hook nil
 185   "Run at the very end of `dired-mode'."
 186   :group 'dired
 187   :type 'hook)
 188
 189 (defcustom dired-before-readin-hook nil
 190   "This hook is run before a dired buffer is read in (created or reverted)."
 191   :group 'dired
 192   :type 'hook)
 193
 194 (defcustom dired-after-readin-hook nil
 195   "Hook run after each time a file or directory is read by Dired.
 196 After each listing of a file or directory, this hook is run
 197 with the buffer narrowed to the listing."
 198   :group 'dired
 199   :type 'hook)
 200 ;; Note this can't simply be run inside function `dired-ls' as the hook
 201 ;; functions probably depend on the dired-subdir-alist to be OK.
 202
 203 (defcustom dired-dnd-protocol-alist
 204   '(("^file:///" . dired-dnd-handle-local-file)
 205     ("^file://"  . dired-dnd-handle-file)
 206     ("^file:"    . dired-dnd-handle-local-file))
 207   "The functions to call when a drop in `dired-mode' is made.
 208 See `dnd-protocol-alist' for more information.  When nil, behave
 209 as in other buffers.  Changing this option is effective only for
 210 new dired buffers."
 211   :type '(choice (repeat (cons (regexp) (function)))
 212                  (const :tag "Behave as in other buffers" nil))
 213   :version "22.1"
 214   :group 'dired)
 215
 216 ;; Internal variables
 217
 218 (defvar dired-marker-char ?*            ; the answer is 42
 219   ;; so that you can write things like
 220   ;; (let ((dired-marker-char ?X))
 221   ;;    ;; great code using X markers ...
 222   ;;    )
 223   ;; For example, commands operating on two sets of files, A and B.
 224   ;; Or marking files with digits 0-9.  This could implicate
 225   ;; concentric sets or an order for the marked files.
 226   ;; The code depends on dynamic scoping on the marker char.
 227   "In Dired, the current mark character.
 228 This is what the do-commands look for, and what the mark-commands store.")
 229
 230 (defvar dired-del-marker ?D
 231   "Character used to flag files for deletion.")
 232
 233 (defvar dired-shrink-to-fit t
 234 ;; I see no reason ever to make this nil -- rms.
 235 ;;  (> baud-rate search-slow-speed)
 236   "Non-nil means Dired shrinks the display buffer to fit the marked files.")
 237
 238 (defvar dired-flagging-regexp nil);; Last regexp used to flag files.
 239
 240 (defvar dired-file-version-alist)
 241
 242 ;;;###autoload
 243 (defvar dired-directory nil
 244   "The directory name or wildcard spec that this dired directory lists.
 245 Local to each dired buffer.  May be a list, in which case the car is the
 246 directory name and the cdr is the list of files to mention.
 247 The directory name must be absolute, but need not be fully expanded.")
 248
 249 (defvar dired-actual-switches nil
 250   "The value of `dired-listing-switches' used to make this buffer's text.")
 251
 252 (defvar dired-re-inode-size "[0-9 \t]*"
 253   "Regexp for optional initial inode and file size as made by `ls -i -s'.")
 254
 255 ;; These regexps must be tested at beginning-of-line, but are also
 256 ;; used to search for next matches, so neither omitting "^" nor
 257 ;; replacing "^" by "\n" (to make it slightly faster) will work.
 258
 259 (defvar dired-re-mark "^[^ \n]")
 260 ;; "Regexp matching a marked line.
 261 ;; Important: the match ends just after the marker."
 262 (defvar dired-re-maybe-mark "^. ")
 263 ;; The [^:] part after "d" and "l" is to avoid confusion with the
 264 ;; DOS/Windows-style drive letters in directory names, like in "d:/foo".
 265 (defvar dired-re-dir (concat dired-re-maybe-mark dired-re-inode-size "d[^:]"))
 266 (defvar dired-re-sym (concat dired-re-maybe-mark dired-re-inode-size "l[^:]"))
 267 (defvar dired-re-exe;; match ls permission string of an executable file
 268   (mapconcat (function
 269               (lambda (x)
 270                 (concat dired-re-maybe-mark dired-re-inode-size x)))
 271              '("-[-r][-w][xs][-r][-w].[-r][-w]."
 272                "-[-r][-w].[-r][-w][xs][-r][-w]."
 273                "-[-r][-w].[-r][-w].[-r][-w][xst]")
 274              "\\|"))
 275 (defvar dired-re-perms "[-bcdlps][-r][-w].[-r][-w].[-r][-w].")
 276 (defvar dired-re-dot "^.* \\.\\.?/?$")
 277
 278 ;; The subdirectory names in the next two lists are expanded.
 279 (defvar dired-subdir-alist nil
 280   "Association list of subdirectories and their buffer positions.
 281 Each subdirectory has an element: (DIRNAME . STARTMARKER).
 282 The order of elements is the reverse of the order in the buffer.
 283 In simple cases, this list contains one element.")
 284
 285 (defvar dired-switches-alist nil
 286   "Keeps track of which switches to use for inserted subdirectories.
 287 This is an alist of the form (SUBDIR . SWITCHES).")
 288 (make-variable-buffer-local 'dired-switches-alist)
 289
 290 (defvaralias 'dired-move-to-filename-regexp
 291   'directory-listing-before-filename-regexp)
 292
 293 (defvar dired-subdir-regexp "^. \\([^\n\r]+\\)\\(:\\)[\n\r]"
 294   "Regexp matching a maybe hidden subdirectory line in `ls -lR' output.
 295 Subexpression 1 is the subdirectory proper, no trailing colon.
 296 The match starts at the beginning of the line and ends after the end
 297 of the line (\\n or \\r).
 298 Subexpression 2 must end right before the \\n or \\r.")
 299
 300 (defgroup dired-faces nil
 301   "Faces used by Dired."
 302   :group 'dired
 303   :group 'faces)
 304
 305 (defface dired-header
 306   '((t (:inherit font-lock-type-face)))
 307   "Face used for directory headers."
 308   :group 'dired-faces
 309   :version "22.1")
 310 (defvar dired-header-face 'dired-header
 311   "Face name used for directory headers.")
 312
 313 (defface dired-mark
 314   '((t (:inherit font-lock-constant-face)))
 315   "Face used for dired marks."
 316   :group 'dired-faces
 317   :version "22.1")
 318 (defvar dired-mark-face 'dired-mark
 319   "Face name used for dired marks.")
 320
 321 (defface dired-marked
 322   '((t (:inherit font-lock-warning-face)))
 323   "Face used for marked files."
 324   :group 'dired-faces
 325   :version "22.1")
 326 (defvar dired-marked-face 'dired-marked
 327   "Face name used for marked files.")
 328
 329 (defface dired-flagged
 330   '((t (:inherit font-lock-warning-face)))
 331   "Face used for flagged files."
 332   :group 'dired-faces
 333   :version "22.1")
 334 (defvar dired-flagged-face 'dired-flagged
 335   "Face name used for flagged files.")
 336
 337 (defface dired-warning
 338   ;; Inherit from font-lock-warning-face since with min-colors 8
 339   ;; font-lock-comment-face is not colored any more.
 340   '((t (:inherit font-lock-warning-face)))
 341   "Face used to highlight a part of a buffer that needs user attention."
 342   :group 'dired-faces
 343   :version "22.1")
 344 (defvar dired-warning-face 'dired-warning
 345   "Face name used for a part of a buffer that needs user attention.")
 346
 347 (defface dired-perm-write
 348   '((((type w32 pc)) :inherit default)  ;; These default to rw-rw-rw.
 349     ;; Inherit from font-lock-comment-delimiter-face since with min-colors 8
 350     ;; font-lock-comment-face is not colored any more.
 351     (t (:inherit font-lock-comment-delimiter-face)))
 352   "Face used to highlight permissions of group- and world-writable files."
 353   :group 'dired-faces
 354   :version "22.2")
 355 (defvar dired-perm-write-face 'dired-perm-write
 356   "Face name used for permissions of group- and world-writable files.")
 357
 358 (defface dired-directory
 359   '((t (:inherit font-lock-function-name-face)))
 360   "Face used for subdirectories."
 361   :group 'dired-faces
 362   :version "22.1")
 363 (defvar dired-directory-face 'dired-directory
 364   "Face name used for subdirectories.")
 365
 366 (defface dired-symlink
 367   '((t (:inherit font-lock-keyword-face)))
 368   "Face used for symbolic links."
 369   :group 'dired-faces
 370   :version "22.1")
 371 (defvar dired-symlink-face 'dired-symlink
 372   "Face name used for symbolic links.")
 373
 374 (defface dired-ignored
 375   '((t (:inherit shadow)))
 376   "Face used for files suffixed with `completion-ignored-extensions'."
 377   :group 'dired-faces
 378   :version "22.1")
 379 (defvar dired-ignored-face 'dired-ignored
 380   "Face name used for files suffixed with `completion-ignored-extensions'.")
 381
 382 (defvar dired-font-lock-keywords
 383   (list
 384    ;;
 385    ;; Directory headers.
 386    (list dired-subdir-regexp '(1 dired-header-face))
 387    ;;
 388    ;; Dired marks.
 389    (list dired-re-mark '(0 dired-mark-face))
 390    ;;
 391    ;; We make heavy use of MATCH-ANCHORED, since the regexps don't identify the
 392    ;; file name itself.  We search for Dired defined regexps, and then use the
 393    ;; Dired defined function `dired-move-to-filename' before searching for the
 394    ;; simple regexp ".+".  It is that regexp which matches the file name.
 395    ;;
 396    ;; Marked files.
 397    (list (concat "^[" (char-to-string dired-marker-char) "]")
 398          '(".+" (dired-move-to-filename) nil (0 dired-marked-face)))
 399    ;;
 400    ;; Flagged files.
 401    (list (concat "^[" (char-to-string dired-del-marker) "]")
 402          '(".+" (dired-move-to-filename) nil (0 dired-flagged-face)))
 403    ;; People who are paranoid about security would consider this more
 404    ;; important than other things such as whether it is a directory.
 405    ;; But we don't want to encourage paranoia, so our default
 406    ;; should be what's most useful for non-paranoids. -- rms.
 407 ;;;   ;;
 408 ;;;   ;; Files that are group or world writable.
 409 ;;;   (list (concat dired-re-maybe-mark dired-re-inode-size
 410 ;;;              "\\([-d]\\(....w....\\|.......w.\\)\\)")
 411 ;;;      '(1 dired-warning-face)
 412 ;;;      '(".+" (dired-move-to-filename) nil (0 dired-warning-face)))
 413    ;; However, we don't need to highlight the file name, only the
 414    ;; permissions, to win generally.  -- fx.
 415    ;; Fixme: we could also put text properties on the permission
 416    ;; fields with keymaps to frob the permissions, somewhat a la XEmacs.
 417    (list (concat dired-re-maybe-mark dired-re-inode-size
 418                  "[-d]....\\(w\\)....") ; group writable
 419          '(1 dired-perm-write-face))
 420    (list (concat dired-re-maybe-mark dired-re-inode-size
 421                  "[-d].......\\(w\\).") ; world writable
 422          '(1 dired-perm-write-face))
 423    ;;
 424    ;; Subdirectories.
 425    (list dired-re-dir
 426          '(".+" (dired-move-to-filename) nil (0 dired-directory-face)))
 427    ;;
 428    ;; Symbolic links.
 429    (list dired-re-sym
 430          '(".+" (dired-move-to-filename) nil (0 dired-symlink-face)))
 431    ;;
 432    ;; Files suffixed with `completion-ignored-extensions'.
 433    '(eval .
 434      ;; It is quicker to first find just an extension, then go back to the
 435      ;; start of that file name.  So we do this complex MATCH-ANCHORED form.
 436      (list (concat "\\(" (regexp-opt completion-ignored-extensions) "\\|#\\)$")
 437            '(".+" (dired-move-to-filename) nil (0 dired-ignored-face))))
 438    ;;
 439    ;; Files suffixed with `completion-ignored-extensions'
 440    ;; plus a character put in by -F.
 441    '(eval .
 442      (list (concat "\\(" (regexp-opt completion-ignored-extensions)
 443                    "\\|#\\)[*=|]$")
 444            '(".+" (progn
 445                     (end-of-line)
 446                     ;; If the last character is not part of the filename,
 447                     ;; move back to the start of the filename
 448                     ;; so it can be fontified.
 449                     ;; Otherwise, leave point at the end of the line;
 450                     ;; that way, nothing is fontified.
 451                     (unless (get-text-property (1- (point)) 'mouse-face)
 452                       (dired-move-to-filename)))
 453              nil (0 dired-ignored-face))))
 454 )
 455   "Additional expressions to highlight in Dired mode.")
 456
 457 (defvar dnd-protocol-alist)
 458 \f
 459 ;;; Macros must be defined before they are used, for the byte compiler.
 460
 461 (defmacro dired-mark-if (predicate msg)
 462   "Mark all files for which PREDICATE evals to non-nil.
 463 PREDICATE is evaluated on each line, with point at beginning of line.
 464 MSG is a noun phrase for the type of files being marked.
 465 It should end with a noun that can be pluralized by adding `s'.
 466 Return value is the number of files marked, or nil if none were marked."
 467   `(let (buffer-read-only count)
 468     (save-excursion
 469       (setq count 0)
 470       (if ,msg (message "Marking %ss..." ,msg))
 471       (goto-char (point-min))
 472       (while (not (eobp))
 473         (if ,predicate
 474             (progn
 475               (delete-char 1)
 476               (insert dired-marker-char)
 477               (setq count (1+ count))))
 478         (forward-line 1))
 479       (if ,msg (message "%s %s%s %s%s."
 480                         count
 481                         ,msg
 482                         (dired-plural-s count)
 483                         (if (eq dired-marker-char ?\040) "un" "")
 484                         (if (eq dired-marker-char dired-del-marker)
 485                             "flagged" "marked"))))
 486     (and (> count 0) count)))
 487
 488 (defmacro dired-map-over-marks (body arg &optional show-progress
 489                                      distinguish-one-marked)
 490   "Eval BODY with point on each marked line.  Return a list of BODY's results.
 491 If no marked file could be found, execute BODY on the current line.
 492   If ARG is an integer, use the next ARG (or previous -ARG, if ARG<0)
 493   files instead of the marked files.
 494   In that case point is dragged along.  This is so that commands on
 495   the next ARG (instead of the marked) files can be chained easily.
 496   If ARG is otherwise non-nil, use current file instead.
 497 If optional third arg SHOW-PROGRESS evaluates to non-nil,
 498   redisplay the dired buffer after each file is processed.
 499 No guarantee is made about the position on the marked line.
 500   BODY must ensure this itself if it depends on this.
 501 Search starts at the beginning of the buffer, thus the car of the list
 502   corresponds to the line nearest to the buffer's bottom.  This
 503   is also true for (positive and negative) integer values of ARG.
 504 BODY should not be too long as it is expanded four times.
 505
 506 If DISTINGUISH-ONE-MARKED is non-nil, then if we find just one marked file,
 507 return (t FILENAME) instead of (FILENAME)."
 508   ;;
 509   ;;Warning: BODY must not add new lines before point - this may cause an
 510   ;;endless loop.
 511   ;;This warning should not apply any longer, sk  2-Sep-1991 14:10.
 512   `(prog1
 513        (let (buffer-read-only case-fold-search found results)
 514          (if ,arg
 515              (if (integerp ,arg)
 516                  (progn ;; no save-excursion, want to move point.
 517                    (dired-repeat-over-lines
 518                     ,arg
 519                     (function (lambda ()
 520                                 (if ,show-progress (sit-for 0))
 521                                 (setq results (cons ,body results)))))
 522                    (if (< ,arg 0)
 523                        (nreverse results)
 524                      results))
 525                ;; non-nil, non-integer ARG means use current file:
 526                (list ,body))
 527            (let ((regexp (dired-marker-regexp)) next-position)
 528              (save-excursion
 529                (goto-char (point-min))
 530                ;; remember position of next marked file before BODY
 531                ;; can insert lines before the just found file,
 532                ;; confusing us by finding the same marked file again
 533                ;; and again and...
 534                (setq next-position (and (re-search-forward regexp nil t)
 535                                         (point-marker))
 536                      found (not (null next-position)))
 537                (while next-position
 538                  (goto-char next-position)
 539                  (if ,show-progress (sit-for 0))
 540                  (setq results (cons ,body results))
 541                  ;; move after last match
 542                  (goto-char next-position)
 543                  (forward-line 1)
 544                  (set-marker next-position nil)
 545                  (setq next-position (and (re-search-forward regexp nil t)
 546                                           (point-marker)))))
 547              (if (and ,distinguish-one-marked (= (length results) 1))
 548                  (setq results (cons t results)))
 549              (if found
 550                  results
 551                (list ,body)))))
 552      ;; save-excursion loses, again
 553      (dired-move-to-filename)))
 554
 555 (defun dired-get-marked-files (&optional localp arg filter distinguish-one-marked)
 556   "Return the marked files' names as list of strings.
 557 The list is in the same order as the buffer, that is, the car is the
 558   first marked file.
 559 Values returned are normally absolute file names.
 560 Optional arg LOCALP as in `dired-get-filename'.
 561 Optional second argument ARG specifies files near point
 562  instead of marked files.  If ARG is an integer, use the next ARG files.
 563   If ARG is otherwise non-nil, use file.  Usually ARG comes from
 564   the command's prefix arg.
 565 Optional third argument FILTER, if non-nil, is a function to select
 566   some of the files--those for which (funcall FILTER FILENAME) is non-nil.
 567
 568 If DISTINGUISH-ONE-MARKED is non-nil, then if we find just one marked file,
 569 return (t FILENAME) instead of (FILENAME).
 570 Don't use that together with FILTER."
 571   (let* ((all-of-them
 572           (save-excursion
 573             (dired-map-over-marks
 574              (dired-get-filename localp)
 575              arg nil distinguish-one-marked)))
 576          result)
 577     (if (not filter)
 578         (if (and distinguish-one-marked (eq (car all-of-them) t))
 579             all-of-them
 580           (nreverse all-of-them))
 581       (dolist (file all-of-them)
 582         (if (funcall filter file)
 583             (push file result)))
 584       result)))
 585 \f
 586 ;; The dired command
 587
 588 (defun dired-read-dir-and-switches (str)
 589   ;; For use in interactive.
 590   (reverse (list
 591             (if current-prefix-arg
 592                 (read-string "Dired listing switches: "
 593                              dired-listing-switches))
 594             ;; If a dialog is about to be used, call read-directory-name so
 595             ;; the dialog code knows we want directories.  Some dialogs can
 596             ;; only select directories or files when popped up, not both.
 597             (let ((default (and buffer-file-name
 598                                 (abbreviate-file-name buffer-file-name))))
 599               (minibuffer-with-setup-hook
 600                   (lambda () (setq minibuffer-default default))
 601                 (read-directory-name (format "Dired %s(directory): " str)
 602                                      nil default-directory nil))))))
 603
 604 ;;;###autoload (define-key ctl-x-map "d" 'dired)
 605 ;;;###autoload
 606 (defun dired (dirname &optional switches)
 607   "\"Edit\" directory DIRNAME--delete, rename, print, etc. some files in it.
 608 Optional second argument SWITCHES specifies the `ls' options used.
 609 \(Interactively, use a prefix argument to be able to specify SWITCHES.)
 610 Dired displays a list of files in DIRNAME (which may also have
 611 shell wildcards appended to select certain files).  If DIRNAME is a cons,
 612 its first element is taken as the directory name and the rest as an explicit
 613 list of files to make directory entries for.
 614 \\<dired-mode-map>\
 615 You can move around in it with the usual commands.
 616 You can flag files for deletion with \\[dired-flag-file-deletion] and then
 617 delete them by typing \\[dired-do-flagged-delete].
 618 Type \\[describe-mode] after entering Dired for more info.
 619
 620 If DIRNAME is already in a dired buffer, that buffer is used without refresh."
 621   ;; Cannot use (interactive "D") because of wildcards.
 622   (interactive (dired-read-dir-and-switches ""))
 623   (switch-to-buffer (dired-noselect dirname switches)))
 624
 625 ;;;###autoload (define-key ctl-x-4-map "d" 'dired-other-window)
 626 ;;;###autoload
 627 (defun dired-other-window (dirname &optional switches)
 628   "\"Edit\" directory DIRNAME.  Like `dired' but selects in another window."
 629   (interactive (dired-read-dir-and-switches "in other window "))
 630   (switch-to-buffer-other-window (dired-noselect dirname switches)))
 631
 632 ;;;###autoload (define-key ctl-x-5-map "d" 'dired-other-frame)
 633 ;;;###autoload
 634 (defun dired-other-frame (dirname &optional switches)
 635   "\"Edit\" directory DIRNAME.  Like `dired' but makes a new frame."
 636   (interactive (dired-read-dir-and-switches "in other frame "))
 637   (switch-to-buffer-other-frame (dired-noselect dirname switches)))
 638
 639 ;;;###autoload
 640 (defun dired-noselect (dir-or-list &optional switches)
 641   "Like `dired' but returns the dired buffer as value, does not select it."
 642   (or dir-or-list (setq dir-or-list default-directory))
 643   ;; This loses the distinction between "/foo/*/" and "/foo/*" that
 644   ;; some shells make:
 645   (let (dirname initially-was-dirname)
 646     (if (consp dir-or-list)
 647         (setq dirname (car dir-or-list))
 648       (setq dirname dir-or-list))
 649     (setq initially-was-dirname
 650           (string= (file-name-as-directory dirname) dirname))
 651     (setq dirname (abbreviate-file-name
 652                    (expand-file-name (directory-file-name dirname))))
 653     (if find-file-visit-truename
 654         (setq dirname (file-truename dirname)))
 655     ;; If the argument was syntactically  a directory name not a file name,
 656     ;; or if it happens to name a file that is a directory,
 657     ;; convert it syntactically to a directory name.
 658     ;; The reason for checking initially-was-dirname
 659     ;; and not just file-directory-p
 660     ;; is that file-directory-p is slow over ftp.
 661     (if (or initially-was-dirname (file-directory-p dirname))
 662         (setq dirname  (file-name-as-directory dirname)))
 663     (if (consp dir-or-list)
 664         (setq dir-or-list (cons dirname (cdr dir-or-list)))
 665       (setq dir-or-list dirname))
 666     (dired-internal-noselect dir-or-list switches)))
 667
 668 ;; The following is an internal dired function.  It returns non-nil if
 669 ;; the directory visited by the current dired buffer has changed on
 670 ;; disk.  DIRNAME should be the directory name of that directory.
 671 (defun dired-directory-changed-p (dirname)
 672   (not (let ((attributes (file-attributes dirname))
 673              (modtime (visited-file-modtime)))
 674          (or (eq modtime 0)
 675              (not (eq (car attributes) t))
 676              (equal (nth 5 attributes) modtime)))))
 677
 678 (defun dired-buffer-stale-p (&optional noconfirm)
 679   "Return non-nil if current dired buffer needs updating.
 680 If NOCONFIRM is non-nil, then this function always returns nil
 681 for a remote directory.  This feature is used by Auto Revert Mode."
 682   (let ((dirname
 683          (if (consp dired-directory) (car dired-directory) dired-directory)))
 684     (and (stringp dirname)
 685          (not (when noconfirm (file-remote-p dirname)))
 686          (file-readable-p dirname)
 687          (dired-directory-changed-p dirname))))
 688
 689 ;; Separate function from dired-noselect for the sake of dired-vms.el.
 690 (defun dired-internal-noselect (dir-or-list &optional switches mode)
 691   ;; If there is an existing dired buffer for DIRNAME, just leave
 692   ;; buffer as it is (don't even call dired-revert).
 693   ;; This saves time especially for deep trees or with ange-ftp.
 694   ;; The user can type `g' easily, and it is more consistent with find-file.
 695   ;; But if SWITCHES are given they are probably different from the
 696   ;; buffer's old value, so call dired-sort-other, which does
 697   ;; revert the buffer.
 698   ;; A pity we can't possibly do "Directory has changed - refresh? "
 699   ;; like find-file does.
 700   ;; Optional argument MODE is passed to dired-find-buffer-nocreate,
 701   ;; see there.
 702   (let* (dirname
 703          buffer
 704          ;; note that buffer already is in dired-mode, if found
 705          new-buffer-p
 706          (old-buf (current-buffer)))
 707     (if (consp dir-or-list)
 708         (setq dirname (car dir-or-list))
 709       (setq dirname dir-or-list))
 710     ;; Look for an existing buffer.
 711     (setq buffer (dired-find-buffer-nocreate dirname mode)
 712           new-buffer-p (null buffer))
 713     (or buffer
 714         (let ((default-major-mode 'fundamental-mode))
 715           ;; We don't want default-major-mode to run hooks and set auto-fill
 716           ;; or whatever, now that dired-mode does not
 717           ;; kill-all-local-variables any longer.
 718           (setq buffer (create-file-buffer (directory-file-name dirname)))))
 719     (set-buffer buffer)
 720     (if (not new-buffer-p)              ; existing buffer ...
 721         (cond (switches                 ; ... but new switches
 722                ;; file list may have changed
 723                (setq dired-directory dir-or-list)
 724                ;; this calls dired-revert
 725                (dired-sort-other switches))
 726               ;; If directory has changed on disk, offer to revert.
 727               ((when (dired-directory-changed-p dirname)
 728                  (message "%s"
 729                           (substitute-command-keys
 730                            "Directory has changed on disk; type \\[revert-buffer] to update Dired")))))
 731       ;; Else a new buffer
 732       (setq default-directory
 733             ;; We can do this unconditionally
 734             ;; because dired-noselect ensures that the name
 735             ;; is passed in directory name syntax
 736             ;; if it was the name of a directory at all.
 737             (file-name-directory dirname))
 738       (or switches (setq switches dired-listing-switches))
 739       (if mode (funcall mode)
 740         (dired-mode dir-or-list switches))
 741       ;; default-directory and dired-actual-switches are set now
 742       ;; (buffer-local), so we can call dired-readin:
 743       (let ((failed t))
 744         (unwind-protect
 745             (progn (dired-readin)
 746                    (setq failed nil))
 747           ;; dired-readin can fail if parent directories are inaccessible.
 748           ;; Don't leave an empty buffer around in that case.
 749           (if failed (kill-buffer buffer))))
 750       (goto-char (point-min))
 751       (dired-initial-position dirname))
 752     (set-buffer old-buf)
 753     buffer))
 754
 755 (defvar dired-buffers nil
 756   ;; Enlarged by dired-advertise
 757   ;; Queried by function dired-buffers-for-dir. When this detects a
 758   ;; killed buffer, it is removed from this list.
 759   "Alist of expanded directories and their associated dired buffers.")
 760
 761 (defun dired-find-buffer-nocreate (dirname &optional mode)
 762   ;; This differs from dired-buffers-for-dir in that it does not consider
 763   ;; subdirs of default-directory and searches for the first match only.
 764   ;; Also, the major mode must be MODE.
 765   (setq dirname (expand-file-name dirname))
 766   (let (found (blist dired-buffers))    ; was (buffer-list)
 767     (or mode (setq mode 'dired-mode))
 768     (while blist
 769       (if (null (buffer-name (cdr (car blist))))
 770           (setq blist (cdr blist))
 771         (save-excursion
 772           (set-buffer (cdr (car blist)))
 773           (if (and (eq major-mode mode)
 774                    dired-directory  ;; nil during find-alternate-file
 775                    (equal dirname
 776                           (expand-file-name
 777                            (if (consp dired-directory)
 778                                (car dired-directory)
 779                              dired-directory))))
 780               (setq found (cdr (car blist))
 781                     blist nil)
 782             (setq blist (cdr blist))))))
 783     found))
 784
 785 \f
 786 ;; Read in a new dired buffer
 787
 788 (defun dired-readin ()
 789   "Read in a new dired buffer.
 790 Differs from `dired-insert-subdir' in that it accepts
 791 wildcards, erases the buffer, and builds the subdir-alist anew
 792 \(including making it buffer-local and clearing it first)."
 793
 794   ;; default-directory and dired-actual-switches must be buffer-local
 795   ;; and initialized by now.
 796   (let (dirname)
 797     (if (consp dired-directory)
 798         (setq dirname (car dired-directory))
 799       (setq dirname dired-directory))
 800     (setq dirname (expand-file-name dirname))
 801     (save-excursion
 802       ;; This hook which may want to modify dired-actual-switches
 803       ;; based on dired-directory, e.g. with ange-ftp to a SysV host
 804       ;; where ls won't understand -Al switches.
 805       (run-hooks 'dired-before-readin-hook)
 806       (if (consp buffer-undo-list)
 807           (setq buffer-undo-list nil))
 808       (make-local-variable 'file-name-coding-system)
 809       (setq file-name-coding-system
 810             (or coding-system-for-read file-name-coding-system))
 811       (let (buffer-read-only
 812             ;; Don't make undo entries for readin.
 813             (buffer-undo-list t))
 814         (widen)
 815         (erase-buffer)
 816         (dired-readin-insert))
 817       (goto-char (point-min))
 818       ;; Must first make alist buffer local and set it to nil because
 819       ;; dired-build-subdir-alist will call dired-clear-alist first
 820       (set (make-local-variable 'dired-subdir-alist) nil)
 821       (dired-build-subdir-alist)
 822       (let ((attributes (file-attributes dirname)))
 823         (if (eq (car attributes) t)
 824             (set-visited-file-modtime (nth 5 attributes))))
 825       (set-buffer-modified-p nil)
 826       ;; No need to narrow since the whole buffer contains just
 827       ;; dired-readin's output, nothing else.  The hook can
 828       ;; successfully use dired functions (e.g. dired-get-filename)
 829       ;; as the subdir-alist has been built in dired-readin.
 830       (run-hooks 'dired-after-readin-hook))))
 831
 832 ;; Subroutines of dired-readin
 833
 834 (defun dired-readin-insert ()
 835   ;; Insert listing for the specified dir (and maybe file list)
 836   ;; already in dired-directory, assuming a clean buffer.
 837   (let (dir file-list)
 838     (if (consp dired-directory)
 839         (setq dir (car dired-directory)
 840               file-list (cdr dired-directory))
 841       (setq dir dired-directory
 842             file-list nil))
 843     (setq dir (expand-file-name dir))
 844     (if (and (equal "" (file-name-nondirectory dir))
 845              (not file-list))
 846         ;; If we are reading a whole single directory...
 847         (dired-insert-directory dir dired-actual-switches nil nil t)
 848       (if (not (file-readable-p
 849                 (directory-file-name (file-name-directory dir))))
 850           (error "Directory %s inaccessible or nonexistent" dir)
 851         ;; Else treat it as a wildcard spec
 852         ;; unless we have an explicit list of files.
 853         (dired-insert-directory dir dired-actual-switches
 854                                 file-list (not file-list) t)))))
 855
 856 (defun dired-align-file (beg end)
 857   "Align the fields of a file to the ones of surrounding lines.
 858 BEG..END is the line where the file info is located."
 859   ;; Some versions of ls try to adjust the size of each field so as to just
 860   ;; hold the largest element ("largest" in the current invocation, of
 861   ;; course).  So when a single line is output, the size of each field is
 862   ;; just big enough for that one output.  Thus when dired refreshes one
 863   ;; line, the alignment if this line w.r.t the rest is messed up because
 864   ;; the fields of that one line will generally be smaller.
 865   ;;
 866   ;; To work around this problem, we here add spaces to try and
 867   ;; re-align the fields as needed.  Since this is purely aesthetic,
 868   ;; it is of utmost importance that it doesn't mess up anything like
 869   ;; `dired-move-to-filename'.  To this end, we limit ourselves to
 870   ;; adding spaces only, and to only add them at places where there
 871   ;; was already at least one space.  This way, as long as
 872   ;; `directory-listing-before-filename-regexp' always matches spaces
 873   ;; with "*" or "+", we know we haven't made anything worse.  There
 874   ;; is one spot where the exact number of spaces is important, which
 875   ;; is just before the actual filename, so we refrain from adding
 876   ;; spaces there (and within the filename as well, of course).
 877   (save-excursion
 878     (let (file file-col other other-col)
 879       ;; Check the there is indeed a file, and that there is anoter adjacent
 880       ;; file with which to align, and that additional spaces are needed to
 881       ;; align the filenames.
 882       (when (and (setq file (progn (goto-char beg)
 883                                    (dired-move-to-filename nil end)))
 884                  (setq file-col (current-column))
 885                  (setq other
 886                        (or (and (goto-char beg)
 887                                 (zerop (forward-line -1))
 888                                 (dired-move-to-filename))
 889                            (and (goto-char beg)
 890                                 (zerop (forward-line 1))
 891                                 (dired-move-to-filename))))
 892                  (setq other-col (current-column))
 893                  (/= file other)
 894                  ;; Make sure there is some work left to do.
 895                  (> other-col file-col))
 896         ;; If we've only looked at the line above, check to see if the line
 897         ;; below exists as well and if so, align with the shorter one.
 898         (when (and (< other file)
 899                    (goto-char beg)
 900                    (zerop (forward-line 1))
 901                    (dired-move-to-filename))
 902           (let ((alt-col (current-column)))
 903             (when (< alt-col other-col)
 904               (setq other-col alt-col)
 905               (setq other (point)))))
 906         ;; Keep positions uptodate when we insert stuff.
 907         (if (> other file) (setq other (copy-marker other)))
 908         (setq file (copy-marker file))
 909         ;; Main loop.
 910         (goto-char beg)
 911         (skip-chars-forward " ")        ;Skip to the first field.
 912         (while (and (> other-col file-col)
 913                     ;; Don't touch anything just before (and after) the
 914                     ;; beginning of the filename.
 915                     (> file (point)))
 916           ;; We're now just in front of a field, with a space behind us.
 917           (let* ((curcol (current-column))
 918                  ;; Nums are right-aligned.
 919                  (num-align (looking-at "[0-9]"))
 920                  ;; Let's look at the other line, in the same column: we
 921                  ;; should be either near the end of the previous field, or
 922                  ;; in the space between that field and the next.
 923                  ;; [ Of course, it's also possible that we're already within
 924                  ;; the next field or even past it, but that's unlikely since
 925                  ;; other-col > file-col. ]
 926                  ;; Let's find the distance to the alignment-point (either
 927                  ;; the beginning or the end of the next field, depending on
 928                  ;; whether this field is left or right aligned).
 929                  (align-pt-offset
 930                   (save-excursion
 931                     (goto-char other)
 932                     (move-to-column curcol)
 933                     (when (looking-at
 934                            (concat
 935                             (if (eq (char-before) ?\s) " *" "[^ ]* *")
 936                             (if num-align "[0-9][^ ]*")))
 937                       (- (match-end 0) (match-beginning 0)))))
 938                  ;; Now, the number of spaces to insert is align-pt-offset
 939                  ;; minus the distance to the equivalent point on the
 940                  ;; current line.
 941                  (spaces
 942                   (if (not num-align)
 943                       align-pt-offset
 944                     (and align-pt-offset
 945                          (save-excursion
 946                            (skip-chars-forward "^ ")
 947                            (- align-pt-offset (- (current-column) curcol)))))))
 948             (when (and spaces (> spaces 0))
 949               (setq file-col (+ spaces file-col))
 950               (if (> file-col other-col)
 951                   (setq spaces (- spaces (- file-col other-col))))
 952               (insert-char ?\s spaces)
 953               ;; Let's just make really sure we did not mess up.
 954               (unless (save-excursion
 955                         (eq (dired-move-to-filename) (marker-position file)))
 956                 ;; Damn!  We messed up: let's revert the change.
 957                 (delete-char (- spaces)))))
 958           ;; Now skip to next field.
 959           (skip-chars-forward "^ ") (skip-chars-forward " "))
 960         (set-marker file nil)))))
 961
 962
 963 (defun dired-insert-directory (dir switches &optional file-list wildcard hdr)
 964   "Insert a directory listing of DIR, Dired style.
 965 Use SWITCHES to make the listings.
 966 If FILE-LIST is non-nil, list only those files.
 967 Otherwise, if WILDCARD is non-nil, expand wildcards;
 968  in that case, DIR should be a file name that uses wildcards.
 969 In other cases, DIR should be a directory name or a directory filename.
 970 If HDR is non-nil, insert a header line with the directory name."
 971   (let ((opoint (point))
 972         (process-environment (copy-sequence process-environment))
 973         end)
 974     (if (or dired-use-ls-dired (file-remote-p dir))
 975         (setq switches (concat "--dired " switches)))
 976     ;; We used to specify the C locale here, to force English month names;
 977     ;; but this should not be necessary any more,
 978     ;; with the new value of `directory-listing-before-filename-regexp'.
 979     (if file-list
 980         (dolist (f file-list)
 981           (let ((beg (point)))
 982             (insert-directory f switches nil nil)
 983             ;; Re-align fields, if necessary.
 984             (dired-align-file beg (point))))
 985       (insert-directory dir switches wildcard (not wildcard)))
 986     ;; Quote certain characters, unless ls quoted them for us.
 987     (if (not (string-match "b" dired-actual-switches))
 988         (save-excursion
 989           (setq end (point-marker))
 990           (goto-char opoint)
 991           (while (search-forward "\\" end t)
 992             (replace-match (apply #'propertize
 993                                   "\\\\"
 994                                   (text-properties-at (match-beginning 0)))
 995                            nil t))
 996           (goto-char opoint)
 997           (while (search-forward "\^m" end t)
 998             (replace-match (apply #'propertize
 999                                   "\\015"
1000                                   (text-properties-at (match-beginning 0)))
1001                            nil t))
1002           (set-marker end nil)))
1003     (dired-insert-set-properties opoint (point))
1004     ;; If we used --dired and it worked, the lines are already indented.
1005     ;; Otherwise, indent them.
1006     (unless (save-excursion
1007               (goto-char opoint)
1008               (looking-at "  "))
1009       (let ((indent-tabs-mode nil))
1010         (indent-rigidly opoint (point) 2)))
1011     ;; Insert text at the beginning to standardize things.
1012     (save-excursion
1013       (goto-char opoint)
1014       (if (and (or hdr wildcard) (not (looking-at "^  /.*:$")))
1015           ;; Note that dired-build-subdir-alist will replace the name
1016           ;; by its expansion, so it does not matter whether what we insert
1017           ;; here is fully expanded, but it should be absolute.
1018           (insert "  " (directory-file-name (file-name-directory dir)) ":\n"))
1019       (when wildcard
1020         ;; Insert "wildcard" line where "total" line would be for a full dir.
1021         (insert "  wildcard " (file-name-nondirectory dir) "\n")))))
1022
1023 (defun dired-insert-set-properties (beg end)
1024   "Make the file names highlight when the mouse is on them."
1025   (save-excursion
1026     (goto-char beg)
1027     (while (< (point) end)
1028       (condition-case nil
1029           (if (dired-move-to-filename)
1030               (add-text-properties
1031                (point)
1032                (save-excursion
1033                  (dired-move-to-end-of-filename)
1034                  (point))
1035                '(mouse-face highlight
1036                  help-echo "mouse-2: visit this file in other window")))
1037         (error nil))
1038       (forward-line 1))))
1039 \f
1040 ;; Reverting a dired buffer
1041
1042 (defun dired-revert (&optional arg noconfirm)
1043   "Reread the dired buffer.
1044 Must also be called after `dired-actual-switches' have changed.
1045 Should not fail even on completely garbaged buffers.
1046 Preserves old cursor, marks/flags, hidden-p."
1047   (widen)                               ; just in case user narrowed
1048   (let ((modflag (buffer-modified-p))
1049         (opoint (point))
1050         (ofile (dired-get-filename nil t))
1051         (mark-alist nil)                ; save marked files
1052         (hidden-subdirs (dired-remember-hidden))
1053         (old-subdir-alist (cdr (reverse dired-subdir-alist))) ; except pwd
1054         (case-fold-search nil)          ; we check for upper case ls flags
1055         buffer-read-only)
1056     (goto-char (point-min))
1057     (setq mark-alist;; only after dired-remember-hidden since this unhides:
1058           (dired-remember-marks (point-min) (point-max)))
1059     ;; treat top level dir extra (it may contain wildcards)
1060     (dired-uncache
1061      (if (consp dired-directory) (car dired-directory) dired-directory))
1062     ;; Run dired-after-readin-hook just once, below.
1063     (let ((dired-after-readin-hook nil))
1064       (dired-readin)
1065       (dired-insert-old-subdirs old-subdir-alist))
1066     (dired-mark-remembered mark-alist)  ; mark files that were marked
1067     ;; ... run the hook for the whole buffer, and only after markers
1068     ;; have been reinserted (else omitting in dired-x would omit marked files)
1069     (run-hooks 'dired-after-readin-hook)        ; no need to narrow
1070     (or (and ofile (dired-goto-file ofile)) ; move cursor to where it
1071         (goto-char opoint))             ; was before
1072     (dired-move-to-filename)
1073     (save-excursion                     ; hide subdirs that were hidden
1074       (dolist (dir hidden-subdirs)
1075         (if (dired-goto-subdir dir)
1076             (dired-hide-subdir 1))))
1077     (unless modflag (restore-buffer-modified-p nil)))
1078   ;; outside of the let scope
1079 ;;;  Might as well not override the user if the user changed this.
1080 ;;;  (setq buffer-read-only t)
1081   )
1082
1083 ;; Subroutines of dired-revert
1084 ;; Some of these are also used when inserting subdirs.
1085
1086 (defun dired-remember-marks (beg end)
1087   "Return alist of files and their marks, from BEG to END."
1088   (if selective-display                 ; must unhide to make this work.
1089       (let (buffer-read-only)
1090         (subst-char-in-region beg end ?\r ?\n)))
1091   (let (fil chr alist)
1092     (save-excursion
1093       (goto-char beg)
1094       (while (re-search-forward dired-re-mark end t)
1095         (if (setq fil (dired-get-filename nil t))
1096             (setq chr (preceding-char)
1097                   alist (cons (cons fil chr) alist)))))
1098     alist))
1099
1100 (defun dired-mark-remembered (alist)
1101   "Mark all files remembered in ALIST.
1102 Each element of ALIST looks like (FILE . MARKERCHAR)."
1103   (let (elt fil chr)
1104     (while alist
1105       (setq elt (car alist)
1106             alist (cdr alist)
1107             fil (car elt)
1108             chr (cdr elt))
1109       (if (dired-goto-file fil)
1110           (save-excursion
1111             (beginning-of-line)
1112             (delete-char 1)
1113             (insert chr))))))
1114
1115 (defun dired-remember-hidden ()
1116   "Return a list of names of subdirs currently hidden."
1117   (let ((l dired-subdir-alist) dir pos result)
1118     (while l
1119       (setq dir (car (car l))
1120             pos (cdr (car l))
1121             l (cdr l))
1122       (goto-char pos)
1123       (skip-chars-forward "^\r\n")
1124       (if (eq (following-char) ?\r)
1125           (setq result (cons dir result))))
1126     result))
1127
1128 (defun dired-insert-old-subdirs (old-subdir-alist)
1129   "Try to insert all subdirs that were displayed before.
1130 Do so according to the former subdir alist OLD-SUBDIR-ALIST."
1131   (or (string-match "R" dired-actual-switches)
1132       (let (elt dir)
1133         (while old-subdir-alist
1134           (setq elt (car old-subdir-alist)
1135                 old-subdir-alist (cdr old-subdir-alist)
1136                 dir (car elt))
1137           (condition-case ()
1138               (progn
1139                 (dired-uncache dir)
1140                 (dired-insert-subdir dir))
1141             (error nil))))))
1142
1143 (defun dired-uncache (dir)
1144   "Remove directory DIR from any directory cache."
1145   (let ((handler (find-file-name-handler dir 'dired-uncache)))
1146     (if handler
1147         (funcall handler 'dired-uncache dir))))
1148 \f
1149 ;; dired mode key bindings and initialization
1150
1151 (defvar dired-mode-map
1152   ;; This looks ugly when substitute-command-keys uses C-d instead d:
1153   ;;  (define-key dired-mode-map "\C-d" 'dired-flag-file-deletion)
1154   (let ((map (make-keymap)))
1155     (suppress-keymap map)
1156     (define-key map [mouse-2] 'dired-mouse-find-file-other-window)
1157     (define-key map [follow-link] 'mouse-face)
1158     ;; Commands to mark or flag certain categories of files
1159     (define-key map "#" 'dired-flag-auto-save-files)
1160     (define-key map "." 'dired-clean-directory)
1161     (define-key map "~" 'dired-flag-backup-files)
1162     (define-key map "&" 'dired-flag-garbage-files)
1163     ;; Upper case keys (except !) for operating on the marked files
1164     (define-key map "A" 'dired-do-search)
1165     (define-key map "C" 'dired-do-copy)
1166     (define-key map "B" 'dired-do-byte-compile)
1167     (define-key map "D" 'dired-do-delete)
1168     (define-key map "G" 'dired-do-chgrp)
1169     (define-key map "H" 'dired-do-hardlink)
1170     (define-key map "L" 'dired-do-load)
1171     (define-key map "M" 'dired-do-chmod)
1172     (define-key map "O" 'dired-do-chown)
1173     (define-key map "P" 'dired-do-print)
1174     (define-key map "Q" 'dired-do-query-replace-regexp)
1175     (define-key map "R" 'dired-do-rename)
1176     (define-key map "S" 'dired-do-symlink)
1177     (define-key map "T" 'dired-do-touch)
1178     (define-key map "X" 'dired-do-shell-command)
1179     (define-key map "Z" 'dired-do-compress)
1180     (define-key map "!" 'dired-do-shell-command)
1181     ;; Comparison commands
1182     (define-key map "=" 'dired-diff)
1183     (define-key map "\M-=" 'dired-backup-diff)
1184     ;; Tree Dired commands
1185     (define-key map "\M-\C-?" 'dired-unmark-all-files)
1186     (define-key map "\M-\C-d" 'dired-tree-down)
1187     (define-key map "\M-\C-u" 'dired-tree-up)
1188     (define-key map "\M-\C-n" 'dired-next-subdir)
1189     (define-key map "\M-\C-p" 'dired-prev-subdir)
1190     ;; move to marked files
1191     (define-key map "\M-{" 'dired-prev-marked-file)
1192     (define-key map "\M-}" 'dired-next-marked-file)
1193     ;; Make all regexp commands share a `%' prefix:
1194     ;; We used to get to the submap via a symbol dired-regexp-prefix,
1195     ;; but that seems to serve little purpose, and copy-keymap
1196     ;; does a better job without it.
1197     (define-key map "%" nil)
1198     (define-key map "%u" 'dired-upcase)
1199     (define-key map "%l" 'dired-downcase)
1200     (define-key map "%d" 'dired-flag-files-regexp)
1201     (define-key map "%g" 'dired-mark-files-containing-regexp)
1202     (define-key map "%m" 'dired-mark-files-regexp)
1203     (define-key map "%r" 'dired-do-rename-regexp)
1204     (define-key map "%C" 'dired-do-copy-regexp)
1205     (define-key map "%H" 'dired-do-hardlink-regexp)
1206     (define-key map "%R" 'dired-do-rename-regexp)
1207     (define-key map "%S" 'dired-do-symlink-regexp)
1208     ;; Commands for marking and unmarking.
1209     (define-key map "*" nil)
1210     (define-key map "**" 'dired-mark-executables)
1211     (define-key map "*/" 'dired-mark-directories)
1212     (define-key map "*@" 'dired-mark-symlinks)
1213     (define-key map "*%" 'dired-mark-files-regexp)
1214     (define-key map "*c" 'dired-change-marks)
1215     (define-key map "*s" 'dired-mark-subdir-files)
1216     (define-key map "*m" 'dired-mark)
1217     (define-key map "*u" 'dired-unmark)
1218     (define-key map "*?" 'dired-unmark-all-files)
1219     (define-key map "*!" 'dired-unmark-all-marks)
1220     (define-key map "U" 'dired-unmark-all-marks)
1221     (define-key map "*\177" 'dired-unmark-backward)
1222     (define-key map "*\C-n" 'dired-next-marked-file)
1223     (define-key map "*\C-p" 'dired-prev-marked-file)
1224     (define-key map "*t" 'dired-toggle-marks)
1225     ;; Lower keys for commands not operating on all the marked files
1226     (define-key map "a" 'dired-find-alternate-file)
1227     (define-key map "d" 'dired-flag-file-deletion)
1228     (define-key map "e" 'dired-find-file)
1229     (define-key map "f" 'dired-find-file)
1230     (define-key map "\C-m" 'dired-advertised-find-file)
1231     (define-key map "g" 'revert-buffer)
1232     (define-key map "h" 'describe-mode)
1233     (define-key map "i" 'dired-maybe-insert-subdir)
1234     (define-key map "j" 'dired-goto-file)
1235     (define-key map "k" 'dired-do-kill-lines)
1236     (define-key map "l" 'dired-do-redisplay)
1237     (define-key map "m" 'dired-mark)
1238     (define-key map "n" 'dired-next-line)
1239     (define-key map "o" 'dired-find-file-other-window)
1240     (define-key map "\C-o" 'dired-display-file)
1241     (define-key map "p" 'dired-previous-line)
1242     (define-key map "q" 'quit-window)
1243     (define-key map "s" 'dired-sort-toggle-or-edit)
1244     (define-key map "t" 'dired-toggle-marks)
1245     (define-key map "u" 'dired-unmark)
1246     (define-key map "v" 'dired-view-file)
1247     (define-key map "w" 'dired-copy-filename-as-kill)
1248     (define-key map "x" 'dired-do-flagged-delete)
1249     (define-key map "y" 'dired-show-file-type)
1250     (define-key map "+" 'dired-create-directory)
1251     ;; moving
1252     (define-key map "<" 'dired-prev-dirline)
1253     (define-key map ">" 'dired-next-dirline)
1254     (define-key map "^" 'dired-up-directory)
1255     (define-key map " "  'dired-next-line)
1256     (define-key map "\C-n" 'dired-next-line)
1257     (define-key map "\C-p" 'dired-previous-line)
1258     (define-key map [down] 'dired-next-line)
1259     (define-key map [up] 'dired-previous-line)
1260     ;; hiding
1261     (define-key map "$" 'dired-hide-subdir)
1262     (define-key map "\M-$" 'dired-hide-all)
1263     ;; misc
1264     (define-key map "\C-x\C-q" 'dired-toggle-read-only)
1265     (define-key map "?" 'dired-summary)
1266     (define-key map "\177" 'dired-unmark-backward)
1267     (define-key map [remap undo] 'dired-undo)
1268     (define-key map [remap advertised-undo] 'dired-undo)
1269     ;; thumbnail manipulation (image-dired)
1270     (define-key map "\C-td" 'image-dired-display-thumbs)
1271     (define-key map "\C-tt" 'image-dired-tag-files)
1272     (define-key map "\C-tr" 'image-dired-delete-tag)
1273     (define-key map "\C-tj" 'image-dired-jump-thumbnail-buffer)
1274     (define-key map "\C-ti" 'image-dired-dired-display-image)
1275     (define-key map "\C-tx" 'image-dired-dired-display-external)
1276     (define-key map "\C-ta" 'image-dired-display-thumbs-append)
1277     (define-key map "\C-t." 'image-dired-display-thumb)
1278     (define-key map "\C-tc" 'image-dired-dired-comment-files)
1279     (define-key map "\C-tf" 'image-dired-mark-tagged-files)
1280     (define-key map "\C-t\C-t" 'image-dired-dired-insert-marked-thumbs)
1281     (define-key map "\C-te" 'image-dired-dired-edit-comment-and-tags)
1282
1283     ;; Make menu bar items.
1284
1285     ;; No need to fo this, now that top-level items are fewer.
1286     ;;;;
1287     ;; Get rid of the Edit menu bar item to save space.
1288     ;(define-key map [menu-bar edit] 'undefined)
1289
1290     (define-key map [menu-bar subdir]
1291       (cons "Subdir" (make-sparse-keymap "Subdir")))
1292
1293     (define-key map [menu-bar subdir hide-all]
1294       '(menu-item "Hide All" dired-hide-all
1295                   :help "Hide all subdirectories, leave only header lines"))
1296     (define-key map [menu-bar subdir hide-subdir]
1297       '(menu-item "Hide/UnHide Subdir" dired-hide-subdir
1298                   :help "Hide or unhide current directory listing"))
1299     (define-key map [menu-bar subdir tree-down]
1300       '(menu-item "Tree Down" dired-tree-down
1301                   :help "Go to first subdirectory header down the tree"))
1302     (define-key map [menu-bar subdir tree-up]
1303       '(menu-item "Tree Up" dired-tree-up
1304                   :help "Go to first subdirectory header up the tree"))
1305     (define-key map [menu-bar subdir up]
1306       '(menu-item "Up Directory" dired-up-directory
1307                   :help "Edit the parent directory"))
1308     (define-key map [menu-bar subdir prev-subdir]
1309       '(menu-item "Prev Subdir" dired-prev-subdir
1310                   :help "Go to previous subdirectory header line"))
1311     (define-key map [menu-bar subdir next-subdir]
1312       '(menu-item "Next Subdir" dired-next-subdir
1313                   :help "Go to next subdirectory header line"))
1314     (define-key map [menu-bar subdir prev-dirline]
1315       '(menu-item "Prev Dirline" dired-prev-dirline
1316                   :help "Move to next directory-file line"))
1317     (define-key map [menu-bar subdir next-dirline]
1318       '(menu-item "Next Dirline" dired-next-dirline
1319                   :help "Move to previous directory-file line"))
1320     (define-key map [menu-bar subdir insert]
1321       '(menu-item "Insert This Subdir" dired-maybe-insert-subdir
1322                   :help "Insert contents of subdirectory"))
1323
1324     (define-key map [menu-bar immediate]
1325       (cons "Immediate" (make-sparse-keymap "Immediate")))
1326
1327     (define-key map
1328       [menu-bar immediate image-dired-dired-display-external]
1329       '(menu-item "Display Image Externally" image-dired-dired-display-external
1330                   :help "Display image in external viewer"))
1331     (define-key map
1332       [menu-bar immediate image-dired-dired-display-image]
1333       '(menu-item "Display Image" image-dired-dired-display-image
1334                   :help "Display sized image in a separate window"))
1335
1336     (define-key map [menu-bar immediate dashes-4]
1337       '("--"))
1338
1339     (define-key map [menu-bar immediate revert-buffer]
1340       '(menu-item "Refresh" revert-buffer
1341                   :help "Update contents of shown directories"))
1342
1343     (define-key map [menu-bar immediate dashes]
1344       '("--"))
1345
1346     (define-key map [menu-bar immediate compare-directories]
1347       '(menu-item "Compare Directories..." dired-compare-directories
1348                   :help "Mark files with different attributes in two dired buffers"))
1349     (define-key map [menu-bar immediate backup-diff]
1350       '(menu-item "Compare with Backup" dired-backup-diff
1351                   :help "Diff file at cursor with its latest backup"))
1352     (define-key map [menu-bar immediate diff]
1353       '(menu-item "Diff..." dired-diff
1354                   :help "Compare file at cursor with another file"))
1355     (define-key map [menu-bar immediate view]
1356       '(menu-item "View This File" dired-view-file
1357                   :help "Examine file at cursor in read-only mode"))
1358     (define-key map [menu-bar immediate display]
1359       '(menu-item "Display in Other Window" dired-display-file
1360                   :help "Display file at cursor in other window"))
1361     (define-key map [menu-bar immediate find-file-other-window]
1362       '(menu-item "Find in Other Window" dired-find-file-other-window
1363                   :help "Edit file at cursor in other window"))
1364     (define-key map [menu-bar immediate find-file]
1365       '(menu-item "Find This File" dired-find-file
1366                   :help "Edit file at cursor"))
1367     (define-key map [menu-bar immediate create-directory]
1368       '(menu-item "Create Directory..." dired-create-directory))
1369     (define-key map [menu-bar immediate wdired-mode]
1370       '(menu-item "Edit File Names" wdired-change-to-wdired-mode
1371                   :filter (lambda (x) (if (eq major-mode 'dired-mode) x))))
1372
1373     (define-key map [menu-bar regexp]
1374       (cons "Regexp" (make-sparse-keymap "Regexp")))
1375
1376     (define-key map
1377       [menu-bar regexp image-dired-mark-tagged-files]
1378       '(menu-item "Mark From Image Tag..." image-dired-mark-tagged-files
1379                   :help "Mark files whose image tags matches regexp"))
1380
1381     (define-key map [menu-bar regexp dashes-1]
1382       '("--"))
1383
1384     (define-key map [menu-bar regexp downcase]
1385       '(menu-item "Downcase" dired-downcase
1386                   ;; When running on plain MS-DOS, there's only one
1387                   ;; letter-case for file names.
1388                   :enable (or (not (fboundp 'msdos-long-file-names))
1389                               (msdos-long-file-names))
1390                   :help "Rename marked files to lower-case name"))
1391     (define-key map [menu-bar regexp upcase]
1392       '(menu-item "Upcase" dired-upcase
1393                   :enable (or (not (fboundp 'msdos-long-file-names))
1394                               (msdos-long-file-names))
1395                   :help "Rename marked files to upper-case name"))
1396     (define-key map [menu-bar regexp hardlink]
1397       '(menu-item "Hardlink..." dired-do-hardlink-regexp
1398                   :help "Make hard links for files matching regexp"))
1399     (define-key map [menu-bar regexp symlink]
1400       '(menu-item "Symlink..." dired-do-symlink-regexp
1401                   :visible (fboundp 'make-symbolic-link)
1402                   :help "Make symbolic links for files matching regexp"))
1403     (define-key map [menu-bar regexp rename]
1404       '(menu-item "Rename..." dired-do-rename-regexp
1405                   :help "Rename marked files matching regexp"))
1406     (define-key map [menu-bar regexp copy]
1407       '(menu-item "Copy..." dired-do-copy-regexp
1408                   :help "Copy marked files matching regexp"))
1409     (define-key map [menu-bar regexp flag]
1410       '(menu-item "Flag..." dired-flag-files-regexp
1411                   :help "Flag files matching regexp for deletion"))
1412     (define-key map [menu-bar regexp mark]
1413       '(menu-item "Mark..." dired-mark-files-regexp
1414                   :help "Mark files matching regexp for future operations"))
1415     (define-key map [menu-bar regexp mark-cont]
1416       '(menu-item "Mark Containing..." dired-mark-files-containing-regexp
1417                   :help "Mark files whose contents matches regexp"))
1418
1419     (define-key map [menu-bar mark]
1420       (cons "Mark" (make-sparse-keymap "Mark")))
1421
1422     (define-key map [menu-bar mark prev]
1423       '(menu-item "Previous Marked" dired-prev-marked-file
1424                   :help "Move to previous marked file"))
1425     (define-key map [menu-bar mark next]
1426       '(menu-item "Next Marked" dired-next-marked-file
1427                   :help "Move to next marked file"))
1428     (define-key map [menu-bar mark marks]
1429       '(menu-item "Change Marks..." dired-change-marks
1430                   :help "Replace marker with another character"))
1431     (define-key map [menu-bar mark unmark-all]
1432       '(menu-item "Unmark All" dired-unmark-all-marks))
1433     (define-key map [menu-bar mark symlinks]
1434       '(menu-item "Mark Symlinks" dired-mark-symlinks
1435                   :visible (fboundp 'make-symbolic-link)
1436                   :help "Mark all symbolic links"))
1437     (define-key map [menu-bar mark directories]
1438       '(menu-item "Mark Directories" dired-mark-directories
1439                   :help "Mark all directories except `.' and `..'"))
1440     (define-key map [menu-bar mark directory]
1441       '(menu-item "Mark Old Backups" dired-clean-directory
1442                   :help "Flag old numbered backups for deletion"))
1443     (define-key map [menu-bar mark executables]
1444       '(menu-item "Mark Executables" dired-mark-executables
1445                   :help "Mark all executable files"))
1446     (define-key map [menu-bar mark garbage-files]
1447       '(menu-item "Flag Garbage Files" dired-flag-garbage-files
1448                   :help "Flag unneeded files for deletion"))
1449     (define-key map [menu-bar mark backup-files]
1450       '(menu-item "Flag Backup Files" dired-flag-backup-files
1451                   :help "Flag all backup files for deletion"))
1452     (define-key map [menu-bar mark auto-save-files]
1453       '(menu-item "Flag Auto-save Files" dired-flag-auto-save-files
1454                   :help "Flag auto-save files for deletion"))
1455     (define-key map [menu-bar mark deletion]
1456       '(menu-item "Flag" dired-flag-file-deletion
1457                   :help "Flag current line's file for deletion"))
1458     (define-key map [menu-bar mark unmark]
1459       '(menu-item "Unmark" dired-unmark
1460                   :help "Unmark or unflag current line's file"))
1461     (define-key map [menu-bar mark mark]
1462       '(menu-item "Mark" dired-mark
1463                   :help "Mark current line's file for future operations"))
1464     (define-key map [menu-bar mark toggle-marks]
1465       '(menu-item "Toggle Marks" dired-toggle-marks
1466                   :help "Mark unmarked files, unmark marked ones"))
1467
1468     (define-key map [menu-bar operate]
1469       (cons "Operate" (make-sparse-keymap "Operate")))
1470
1471     (define-key map
1472       [menu-bar operate image-dired-delete-tag]
1473       '(menu-item "Delete Image Tag..." image-dired-delete-tag
1474                   :help "Delete image tag from current or marked files"))
1475     (define-key map
1476       [menu-bar operate image-dired-tag-files]
1477       '(menu-item "Add Image Tags..." image-dired-tag-files
1478                   :help "Add image tags to current or marked files"))
1479     (define-key map
1480       [menu-bar operate image-dired-dired-comment-files]
1481       '(menu-item "Add Image Comment..." image-dired-dired-comment-files
1482                   :help "Add image comment to current or marked files"))
1483     (define-key map
1484       [menu-bar operate image-dired-display-thumbs]
1485       '(menu-item "Display Image-Dired" image-dired-display-thumbs
1486                   :help "Display image-dired for current or marked image files"))
1487
1488     (define-key map [menu-bar operate dashes-3]
1489       '("--"))
1490
1491     (define-key map [menu-bar operate query-replace]
1492       '(menu-item "Query Replace in Files..." dired-do-query-replace-regexp
1493                   :help "Replace regexp in marked files"))
1494     (define-key map [menu-bar operate search]
1495       '(menu-item "Search Files..." dired-do-search
1496                   :help "Search marked files for regexp"))
1497     (define-key map [menu-bar operate chown]
1498       '(menu-item "Change Owner..." dired-do-chown
1499                   :visible (not (memq system-type '(ms-dos windows-nt)))
1500                   :help "Change the owner of marked files"))
1501     (define-key map [menu-bar operate chgrp]
1502       '(menu-item "Change Group..." dired-do-chgrp
1503                   :visible (not (memq system-type '(ms-dos windows-nt)))
1504                   :help "Change the group of marked files"))
1505     (define-key map [menu-bar operate chmod]
1506       '(menu-item "Change Mode..." dired-do-chmod
1507                   :help "Change mode (attributes) of marked files"))
1508     (define-key map [menu-bar operate touch]
1509       '(menu-item "Change Timestamp..." dired-do-touch
1510                   :help "Change timestamp of marked files"))
1511     (define-key map [menu-bar operate load]
1512       '(menu-item "Load" dired-do-load
1513                   :help "Load marked Emacs Lisp files"))
1514     (define-key map [menu-bar operate compile]
1515       '(menu-item "Byte-compile" dired-do-byte-compile
1516                   :help "Byte-compile marked Emacs Lisp files"))
1517     (define-key map [menu-bar operate compress]
1518       '(menu-item "Compress" dired-do-compress
1519                   :help "Compress/uncompress marked files"))
1520     (define-key map [menu-bar operate print]
1521       '(menu-item "Print..." dired-do-print
1522                   :help "Ask for print command and print marked files"))
1523     (define-key map [menu-bar operate hardlink]
1524       '(menu-item "Hardlink to..." dired-do-hardlink
1525                   :help "Make hard links for current or marked files"))
1526     (define-key map [menu-bar operate symlink]
1527       '(menu-item "Symlink to..." dired-do-symlink
1528                   :visible (fboundp 'make-symbolic-link)
1529                   :help "Make symbolic links for current or marked files"))
1530     (define-key map [menu-bar operate command]
1531       '(menu-item "Shell Command..." dired-do-shell-command
1532                   :help "Run a shell command on each of marked files"))
1533     (define-key map [menu-bar operate delete]
1534       '(menu-item "Delete" dired-do-delete
1535                   :help "Delete current file or all marked files"))
1536     (define-key map [menu-bar operate rename]
1537       '(menu-item "Rename to..." dired-do-rename
1538                   :help "Rename current file or move marked files"))
1539     (define-key map [menu-bar operate copy]
1540       '(menu-item "Copy to..." dired-do-copy
1541                   :help "Copy current file or all marked files"))
1542
1543     map)
1544   "Local keymap for `dired-mode' buffers.")
1545 \f
1546 ;; Dired mode is suitable only for specially formatted data.
1547 (put 'dired-mode 'mode-class 'special)
1548
1549 ;; Autoload cookie needed by desktop.el
1550 ;;;###autoload
1551 (defun dired-mode (&optional dirname switches)
1552   "\
1553 Mode for \"editing\" directory listings.
1554 In Dired, you are \"editing\" a list of the files in a directory and
1555   \(optionally) its subdirectories, in the format of `ls -lR'.
1556   Each directory is a page: use \\[backward-page] and \\[forward-page] to move pagewise.
1557 \"Editing\" means that you can run shell commands on files, visit,
1558   compress, load or byte-compile them, change their file attributes
1559   and insert subdirectories into the same buffer.  You can \"mark\"
1560   files for later commands or \"flag\" them for deletion, either file
1561   by file or all files matching certain criteria.
1562 You can move using the usual cursor motion commands.\\<dired-mode-map>
1563 Letters no longer insert themselves.  Digits are prefix arguments.
1564 Instead, type \\[dired-flag-file-deletion] to flag a file for Deletion.
1565 Type \\[dired-mark] to Mark a file or subdirectory for later commands.
1566   Most commands operate on the marked files and use the current file
1567   if no files are marked.  Use a numeric prefix argument to operate on
1568   the next ARG (or previous -ARG if ARG<0) files, or just `1'
1569   to operate on the current file only.  Prefix arguments override marks.
1570   Mark-using commands display a list of failures afterwards.  Type \\[dired-summary]
1571   to see why something went wrong.
1572 Type \\[dired-unmark] to Unmark a file or all files of a subdirectory.
1573 Type \\[dired-unmark-backward] to back up one line and unflag.
1574 Type \\[dired-do-flagged-delete] to eXecute the deletions requested.
1575 Type \\[dired-advertised-find-file] to Find the current line's file
1576   (or dired it in another buffer, if it is a directory).
1577 Type \\[dired-find-file-other-window] to find file or dired directory in Other window.
1578 Type \\[dired-maybe-insert-subdir] to Insert a subdirectory in this buffer.
1579 Type \\[dired-do-rename] to Rename a file or move the marked files to another directory.
1580 Type \\[dired-do-copy] to Copy files.
1581 Type \\[dired-sort-toggle-or-edit] to toggle Sorting by name/date or change the `ls' switches.
1582 Type \\[revert-buffer] to read all currently expanded directories aGain.
1583   This retains all marks and hides subdirs again that were hidden before.
1584 SPC and DEL can be used to move down and up by lines.
1585
1586 If Dired ever gets confused, you can either type \\[revert-buffer] \
1587 to read the
1588 directories again, type \\[dired-do-redisplay] \
1589 to relist a single or the marked files or a
1590 subdirectory, or type \\[dired-build-subdir-alist] to parse the buffer
1591 again for the directory tree.
1592
1593 Customization variables (rename this buffer and type \\[describe-variable] on each line
1594 for more info):
1595
1596   `dired-listing-switches'
1597   `dired-trivial-filenames'
1598   `dired-shrink-to-fit'
1599   `dired-marker-char'
1600   `dired-del-marker'
1601   `dired-keep-marker-rename'
1602   `dired-keep-marker-copy'
1603   `dired-keep-marker-hardlink'
1604   `dired-keep-marker-symlink'
1605
1606 Hooks (use \\[describe-variable] to see their documentation):
1607
1608   `dired-before-readin-hook'
1609   `dired-after-readin-hook'
1610   `dired-mode-hook'
1611   `dired-load-hook'
1612
1613 Keybindings:
1614 \\{dired-mode-map}"
1615   ;; Not to be called interactively (e.g. dired-directory will be set
1616   ;; to default-directory, which is wrong with wildcards).
1617   (kill-all-local-variables)
1618   (use-local-map dired-mode-map)
1619   (dired-advertise)                     ; default-directory is already set
1620   (setq major-mode 'dired-mode
1621         mode-name "Dired"
1622         ;; case-fold-search nil
1623         buffer-read-only t
1624         selective-display t             ; for subdirectory hiding
1625         mode-line-buffer-identification
1626         (propertized-buffer-identification "%17b"))
1627   (set (make-local-variable 'revert-buffer-function)
1628        (function dired-revert))
1629   (set (make-local-variable 'buffer-stale-function)
1630        (function dired-buffer-stale-p))
1631   (set (make-local-variable 'page-delimiter)
1632        "\n\n")
1633   (set (make-local-variable 'dired-directory)
1634        (or dirname default-directory))
1635   ;; list-buffers uses this to display the dir being edited in this buffer.
1636   (set (make-local-variable 'list-buffers-directory)
1637        (expand-file-name (if (listp dired-directory)
1638                              (car dired-directory)
1639                            dired-directory)))
1640   (set (make-local-variable 'dired-actual-switches)
1641        (or switches dired-listing-switches))
1642   (set (make-local-variable 'font-lock-defaults)
1643        '(dired-font-lock-keywords t nil nil beginning-of-line))
1644   (set (make-local-variable 'desktop-save-buffer)
1645        'dired-desktop-buffer-misc-data)
1646   (setq dired-switches-alist nil)
1647   (dired-sort-other dired-actual-switches t)
1648   (when (featurep 'dnd)
1649     (set (make-local-variable 'dnd-protocol-alist)
1650          (append dired-dnd-protocol-alist dnd-protocol-alist)))
1651   (run-mode-hooks 'dired-mode-hook))
1652 \f
1653 ;; Idiosyncratic dired commands that don't deal with marks.
1654
1655 (defun dired-summary ()
1656   "Summarize basic Dired commands and show recent dired errors."
1657   (interactive)
1658   (dired-why)
1659   ;>> this should check the key-bindings and use substitute-command-keys if non-standard
1660   (message
1661    "d-elete, u-ndelete, x-punge, f-ind, o-ther window, R-ename, C-opy, h-elp"))
1662
1663 (defun dired-undo ()
1664   "Undo in a dired buffer.
1665 This doesn't recover lost files, it just undoes changes in the buffer itself.
1666 You can use it to recover marks, killed lines or subdirs."
1667   (interactive)
1668   (let (buffer-read-only)
1669     (undo))
1670   (dired-build-subdir-alist)
1671   (message "Change in dired buffer undone.
1672 Actual changes in files cannot be undone by Emacs."))
1673
1674 (defun dired-toggle-read-only ()
1675   "Edit dired buffer with Wdired, or set it read-only.
1676 Call `wdired-change-to-wdired-mode' in dired buffers whose editing is
1677 supported by Wdired (the major mode of the dired buffer is `dired-mode').
1678 Otherwise, for buffers inheriting from dired-mode, call `toggle-read-only'."
1679   (interactive)
1680   (if (eq major-mode 'dired-mode)
1681       (wdired-change-to-wdired-mode)
1682     (toggle-read-only)))
1683
1684 (defun dired-next-line (arg)
1685   "Move down lines then position at filename.
1686 Optional prefix ARG says how many lines to move; default is one line."
1687   (interactive "p")
1688   (forward-line arg)
1689   (dired-move-to-filename))
1690
1691 (defun dired-previous-line (arg)
1692   "Move up lines then position at filename.
1693 Optional prefix ARG says how many lines to move; default is one line."
1694   (interactive "p")
1695   (forward-line (- arg))
1696   (dired-move-to-filename))
1697
1698 (defun dired-next-dirline (arg &optional opoint)
1699   "Goto ARG'th next directory file line."
1700   (interactive "p")
1701   (or opoint (setq opoint (point)))
1702   (if (if (> arg 0)
1703           (re-search-forward dired-re-dir nil t arg)
1704         (beginning-of-line)
1705         (re-search-backward dired-re-dir nil t (- arg)))
1706       (dired-move-to-filename)          ; user may type `i' or `f'
1707     (goto-char opoint)
1708     (error "No more subdirectories")))
1709
1710 (defun dired-prev-dirline (arg)
1711   "Goto ARG'th previous directory file line."
1712   (interactive "p")
1713   (dired-next-dirline (- arg)))
1714
1715 (defun dired-up-directory (&optional other-window)
1716   "Run Dired on parent directory of current directory.
1717 Find the parent directory either in this buffer or another buffer.
1718 Creates a buffer if necessary."
1719   (interactive "P")
1720   (let* ((dir (dired-current-directory))
1721          (up (file-name-directory (directory-file-name dir))))
1722     (or (dired-goto-file (directory-file-name dir))
1723         ;; Only try dired-goto-subdir if buffer has more than one dir.
1724         (and (cdr dired-subdir-alist)
1725              (dired-goto-subdir up))
1726         (progn
1727           (if other-window
1728               (dired-other-window up)
1729             (dired up))
1730           (dired-goto-file dir)))))
1731
1732 (defun dired-get-file-for-visit ()
1733   "Get the current line's file name, with an error if file does not exist."
1734   (interactive)
1735   ;; We pass t for second arg so that we don't get error for `.' and `..'.
1736   (let ((raw (dired-get-filename nil t))
1737         file-name)
1738     (if (null raw)
1739         (error "No file on this line"))
1740     (setq file-name (file-name-sans-versions raw t))
1741     (if (file-exists-p file-name)
1742         file-name
1743       (if (file-symlink-p file-name)
1744           (error "File is a symlink to a nonexistent target")
1745         (error "File no longer exists; type `g' to update dired buffer")))))
1746
1747 ;; Force `f' rather than `e' in the mode doc:
1748 (defalias 'dired-advertised-find-file 'dired-find-file)
1749 (defun dired-find-file ()
1750   "In Dired, visit the file or directory named on this line."
1751   (interactive)
1752   ;; Bind `find-file-run-dired' so that the command works on directories
1753   ;; too, independent of the user's setting.
1754   (let ((find-file-run-dired t))
1755     (find-file (dired-get-file-for-visit))))
1756
1757 (defun dired-find-alternate-file ()
1758   "In Dired, visit this file or directory instead of the dired buffer."
1759   (interactive)
1760   (set-buffer-modified-p nil)
1761   (find-alternate-file (dired-get-file-for-visit)))
1762 ;; Don't override the setting from .emacs.
1763 ;;;###autoload (put 'dired-find-alternate-file 'disabled t)
1764
1765 (defun dired-mouse-find-file-other-window (event)
1766   "In Dired, visit the file or directory name you click on."
1767   (interactive "e")
1768   (let (window pos file)
1769     (save-excursion
1770       (setq window (posn-window (event-end event))
1771             pos (posn-point (event-end event)))
1772       (if (not (windowp window))
1773           (error "No file chosen"))
1774       (set-buffer (window-buffer window))
1775       (goto-char pos)
1776       (setq file (dired-get-file-for-visit)))
1777     (if (file-directory-p file)
1778         (or (and (cdr dired-subdir-alist)
1779                  (dired-goto-subdir file))
1780             (progn
1781               (select-window window)
1782               (dired-other-window file)))
1783       (select-window window)
1784       (find-file-other-window (file-name-sans-versions file t)))))
1785
1786 (defun dired-view-file ()
1787   "In Dired, examine a file in view mode, returning to Dired when done.
1788 When file is a directory, show it in this buffer if it is inserted.
1789 Otherwise, display it in another buffer."
1790   (interactive)
1791   (let ((file (dired-get-file-for-visit)))
1792     (if (file-directory-p file)
1793         (or (and (cdr dired-subdir-alist)
1794                  (dired-goto-subdir file))
1795             (dired file))
1796       (view-file file))))
1797
1798 (defun dired-find-file-other-window ()
1799   "In Dired, visit this file or directory in another window."
1800   (interactive)
1801   (find-file-other-window (dired-get-file-for-visit)))
1802
1803 (defun dired-display-file ()
1804   "In Dired, display this file or directory in another window."
1805   (interactive)
1806   (display-buffer (find-file-noselect (dired-get-file-for-visit))))
1807 \f
1808 ;;; Functions for extracting and manipulating file names in Dired buffers.
1809
1810 (defun dired-get-filename (&optional localp no-error-if-not-filep)
1811   "In Dired, return name of file mentioned on this line.
1812 Value returned normally includes the directory name.
1813 Optional arg LOCALP with value `no-dir' means don't include directory
1814 name in result.  A value of `verbatim' means to return the name exactly as
1815 it occurs in the buffer, and a value of t means construct name relative to
1816 `default-directory', which still may contain slashes if in a subdirectory.
1817 Optional arg NO-ERROR-IF-NOT-FILEP means treat `.' and `..' as
1818 regular filenames and return nil if no filename on this line.
1819 Otherwise, an error occurs in these cases."
1820   (let (case-fold-search file p1 p2 already-absolute)
1821     (save-excursion
1822       (if (setq p1 (dired-move-to-filename (not no-error-if-not-filep)))
1823           (setq p2 (dired-move-to-end-of-filename no-error-if-not-filep))))
1824     ;; nil if no file on this line, but no-error-if-not-filep is t:
1825     (if (setq file (and p1 p2 (buffer-substring p1 p2)))
1826         (progn
1827           ;; Get rid of the mouse-face property that file names have.
1828           (set-text-properties 0 (length file) nil file)
1829           ;; Unquote names quoted by ls or by dired-insert-directory.
1830           ;; Using read to unquote is much faster than substituting
1831           ;; \007 (4 chars) -> ^G  (1 char) etc. in a lisp loop.
1832           (setq file
1833                 (read
1834                  (concat "\""
1835                          ;; Some ls -b don't escape quotes, argh!
1836                          ;; This is not needed for GNU ls, though.
1837                          (or (dired-string-replace-match
1838                               "\\([^\\]\\|\\`\\)\"" file "\\1\\\\\"" nil t)
1839                              file)
1840                          "\"")))
1841           ;; The above `read' will return a unibyte string if FILE
1842           ;; contains eight-bit-control/graphic characters.
1843           (if (and enable-multibyte-characters
1844                    (not (multibyte-string-p file)))
1845               (setq file (string-to-multibyte file)))))
1846     (and file (file-name-absolute-p file)
1847          ;; A relative file name can start with ~.
1848          ;; Don't treat it as absolute in this context.
1849          (not (eq (aref file 0) ?~))
1850          (setq already-absolute t))
1851     (cond
1852      ((null file)
1853       nil)
1854      ((eq localp 'verbatim)
1855       file)
1856      ((and (not no-error-if-not-filep)
1857            (member file '("." "..")))
1858       (error "Cannot operate on `.' or `..'"))
1859      ((and (eq localp 'no-dir) already-absolute)
1860       (file-name-nondirectory file))
1861      (already-absolute
1862       (let ((handler (find-file-name-handler file nil)))
1863         ;; check for safe-magic property so that we won't
1864         ;; put /: for names that don't really need them.
1865         ;; For instance, .gz files when auto-compression-mode is on.
1866         (if (and handler (not (get handler 'safe-magic)))
1867             (concat "/:" file)
1868           file)))
1869      ((eq localp 'no-dir)
1870       file)
1871      ((equal (dired-current-directory) "/")
1872       (setq file (concat (dired-current-directory localp) file))
1873       (let ((handler (find-file-name-handler file nil)))
1874         ;; check for safe-magic property so that we won't
1875         ;; put /: for names that don't really need them.
1876         ;; For instance, .gz files when auto-compression-mode is on.
1877         (if (and handler (not (get handler 'safe-magic)))
1878             (concat "/:" file)
1879           file)))
1880      (t
1881       (concat (dired-current-directory localp) file)))))
1882
1883 (defun dired-string-replace-match (regexp string newtext
1884                                    &optional literal global)
1885   "Replace first match of REGEXP in STRING with NEWTEXT.
1886 If it does not match, nil is returned instead of the new string.
1887 Optional arg LITERAL means to take NEWTEXT literally.
1888 Optional arg GLOBAL means to replace all matches."
1889   (if global
1890       (let ((start 0) ret)
1891         (while (string-match regexp string start)
1892           (let ((from-end (- (length string) (match-end 0))))
1893             (setq ret (setq string (replace-match newtext t literal string)))
1894             (setq start (- (length string) from-end))))
1895           ret)
1896     (if (not (string-match regexp string 0))
1897         nil
1898       (replace-match newtext t literal string))))
1899
1900 (defun dired-make-absolute (file &optional dir)
1901   ;;"Convert FILE (a file name relative to DIR) to an absolute file name."
1902   ;; We can't always use expand-file-name as this would get rid of `.'
1903   ;; or expand in / instead default-directory if DIR=="".
1904   ;; This should be good enough for ange-ftp, but might easily be
1905   ;; redefined (for VMS?).
1906   ;; It should be reasonably fast, though, as it is called in
1907   ;; dired-get-filename.
1908   (concat (or dir default-directory) file))
1909
1910 (defun dired-make-relative (file &optional dir ignore)
1911   "Convert FILE (an absolute file name) to a name relative to DIR.
1912 If this is impossible, return FILE unchanged.
1913 DIR must be a directory name, not a file name."
1914   (or dir (setq dir default-directory))
1915   ;; This case comes into play if default-directory is set to
1916   ;; use ~.
1917   (if (and (> (length dir) 0) (= (aref dir 0) ?~))
1918       (setq dir (expand-file-name dir)))
1919   (if (string-match (concat "^" (regexp-quote dir)) file)
1920       (substring file (match-end 0))
1921 ;;;  (or no-error
1922 ;;;     (error "%s: not in directory tree growing at %s" file dir))
1923     file))
1924 \f
1925 ;;; Functions for finding the file name in a dired buffer line.
1926
1927 (defvar dired-permission-flags-regexp
1928   "\\([^ ]\\)[-r][-w]\\([^ ]\\)[-r][-w]\\([^ ]\\)[-r][-w]\\([^ ]\\)"
1929   "Regular expression to match the permission flags in `ls -l'.")
1930
1931 ;; Move to first char of filename on this line.
1932 ;; Returns position (point) or nil if no filename on this line."
1933 (defun dired-move-to-filename (&optional raise-error eol)
1934   "Move to the beginning of the filename on the current line.
1935 Return the position of the beginning of the filename, or nil if none found."
1936   ;; This is the UNIX version.
1937   (or eol (setq eol (line-end-position)))
1938   (beginning-of-line)
1939   ;; First try assuming `ls --dired' was used.
1940   (let ((change (next-single-property-change (point) 'dired-filename nil eol)))
1941     (cond
1942      ((and change (< change eol))
1943       (goto-char change))
1944      ((re-search-forward directory-listing-before-filename-regexp eol t)
1945       (goto-char (match-end 0)))
1946      ((re-search-forward dired-permission-flags-regexp eol t)
1947       ;; Ha!  There *is* a file.  Our regexp-from-hell just failed to find it.
1948       (if raise-error
1949           (error "Unrecognized line!  Check directory-listing-before-filename-regexp"))
1950       (beginning-of-line)
1951       nil)
1952      (raise-error
1953       (error "No file on this line")))))
1954
1955 (defun dired-move-to-end-of-filename (&optional no-error)
1956   ;; Assumes point is at beginning of filename,
1957   ;; thus the rwx bit re-search-backward below will succeed in *this*
1958   ;; line if at all.  So, it should be called only after
1959   ;; (dired-move-to-filename t).
1960   ;; On failure, signals an error (with non-nil NO-ERROR just returns nil).
1961   ;; This is the UNIX version.
1962   (if (get-text-property (point) 'dired-filename)
1963       (goto-char (next-single-property-change (point) 'dired-filename))
1964     (let (opoint file-type executable symlink hidden case-fold-search used-F eol)
1965       ;; case-fold-search is nil now, so we can test for capital F:
1966       (setq used-F (string-match "F" dired-actual-switches)
1967             opoint (point)
1968             eol (save-excursion (end-of-line) (point))
1969             hidden (and selective-display
1970                         (save-excursion (search-forward "\r" eol t))))
1971       (if hidden
1972           nil
1973         (save-excursion ;; Find out what kind of file this is:
1974           ;; Restrict perm bits to be non-blank,
1975           ;; otherwise this matches one char to early (looking backward):
1976           ;; "l---------" (some systems make symlinks that way)
1977           ;; "----------" (plain file with zero perms)
1978           (if (re-search-backward
1979                dired-permission-flags-regexp nil t)
1980               (setq file-type (char-after (match-beginning 1))
1981                     symlink (eq file-type ?l)
1982                     ;; Only with -F we need to know whether it's an executable
1983                     executable (and
1984                                 used-F
1985                                 (string-match
1986                                  "[xst]" ;; execute bit set anywhere?
1987                                  (concat
1988                                   (match-string 2)
1989                                   (match-string 3)
1990                                   (match-string 4)))))
1991             (or no-error (error "No file on this line"))))
1992         ;; Move point to end of name:
1993         (if symlink
1994             (if (search-forward " -> " eol t)
1995                 (progn
1996                   (forward-char -4)
1997                   (and used-F
1998                        dired-ls-F-marks-symlinks
1999                        (eq (preceding-char) ?@) ;; did ls really mark the link?
2000                        (forward-char -1))))
2001           (goto-char eol) ;; else not a symbolic link
2002           ;; ls -lF marks dirs, sockets, fifos and executables with exactly
2003           ;; one trailing character. (Executable bits on symlinks ain't mean
2004           ;; a thing, even to ls, but we know it's not a symlink.)
2005           (and used-F
2006                (or (memq file-type '(?d ?s ?p))
2007                    executable)
2008                (forward-char -1))))
2009       (or no-error
2010           (not (eq opoint (point)))
2011           (error "%s" (if hidden
2012                      (substitute-command-keys
2013                       "File line is hidden, type \\[dired-hide-subdir] to unhide")
2014                    "No file on this line")))
2015       (if (eq opoint (point))
2016           nil
2017         (point)))))
2018
2019 \f
2020 ;;; COPY NAMES OF MARKED FILES INTO KILL-RING.
2021
2022 (defun dired-copy-filename-as-kill (&optional arg)
2023   "Copy names of marked (or next ARG) files into the kill ring.
2024 The names are separated by a space.
2025 With a zero prefix arg, use the absolute file name of each marked file.
2026 With \\[universal-argument], use the file name relative to the dired buffer's
2027 `default-directory'.  (This still may contain slashes if in a subdirectory.)
2028
2029 If on a subdir headerline, use absolute subdirname instead;
2030 prefix arg and marked files are ignored in this case.
2031
2032 You can then feed the file name(s) to other commands with \\[yank]."
2033   (interactive "P")
2034   (let ((string
2035          (or (dired-get-subdir)
2036              (mapconcat (function identity)
2037                         (if arg
2038                             (cond ((zerop (prefix-numeric-value arg))
2039                                    (dired-get-marked-files))
2040                                   ((consp arg)
2041                                    (dired-get-marked-files t))
2042                                   (t
2043                                    (dired-get-marked-files
2044                                     'no-dir (prefix-numeric-value arg))))
2045                           (dired-get-marked-files 'no-dir))
2046                         " "))))
2047     (if (eq last-command 'kill-region)
2048         (kill-append string nil)
2049       (kill-new string))
2050     (message "%s" string)))
2051
2052 \f
2053 ;; Keeping Dired buffers in sync with the filesystem and with each other
2054
2055 (defun dired-buffers-for-dir (dir &optional file)
2056 ;; Return a list of buffers that dired DIR (top level or in-situ subdir).
2057 ;; If FILE is non-nil, include only those whose wildcard pattern (if any)
2058 ;; matches FILE.
2059 ;; The list is in reverse order of buffer creation, most recent last.
2060 ;; As a side effect, killed dired buffers for DIR are removed from
2061 ;; dired-buffers.
2062   (setq dir (file-name-as-directory dir))
2063   (let ((alist dired-buffers) result elt buf)
2064     (while alist
2065       (setq elt (car alist)
2066             buf (cdr elt))
2067       (if (buffer-name buf)
2068           (if (dired-in-this-tree dir (car elt))
2069               (with-current-buffer buf
2070                 (and (assoc dir dired-subdir-alist)
2071                      (or (null file)
2072                          (let ((wildcards
2073                                 (file-name-nondirectory dired-directory)))
2074                            (or (= 0 (length wildcards))
2075                                (string-match (dired-glob-regexp wildcards)
2076                                              file))))
2077                      (setq result (cons buf result)))))
2078         ;; else buffer is killed - clean up:
2079         (setq dired-buffers (delq elt dired-buffers)))
2080       (setq alist (cdr alist)))
2081     result))
2082
2083 (defun dired-glob-regexp (pattern)
2084   "Convert glob-pattern PATTERN to a regular expression."
2085   (let ((matched-in-pattern 0)  ;; How many chars of PATTERN we've handled.
2086         regexp)
2087     (while (string-match "[[?*]" pattern matched-in-pattern)
2088       (let ((op-end (match-end 0))
2089             (next-op (aref pattern (match-beginning 0))))
2090         (setq regexp (concat regexp
2091                              (regexp-quote
2092                               (substring pattern matched-in-pattern
2093                                          (match-beginning 0)))))
2094         (cond ((= next-op ??)
2095                (setq regexp (concat regexp "."))
2096                (setq matched-in-pattern op-end))
2097               ((= next-op ?\[)
2098                ;; Fails to handle ^ yet ????
2099                (let* ((set-start (match-beginning 0))
2100                       (set-cont
2101                        (if (= (aref pattern (1+ set-start)) ?^)
2102                            (+ 3 set-start)
2103                          (+ 2 set-start)))
2104                       (set-end (string-match "]" pattern set-cont))
2105                       (set (substring pattern set-start (1+ set-end))))
2106                  (setq regexp (concat regexp set))
2107                  (setq matched-in-pattern (1+ set-end))))
2108               ((= next-op ?*)
2109                (setq regexp (concat regexp ".*"))
2110                (setq matched-in-pattern op-end)))))
2111     (concat "\\`"
2112             regexp
2113             (regexp-quote
2114              (substring pattern matched-in-pattern))
2115             "\\'")))
2116
2117
2118
2119 (defun dired-advertise ()
2120   ;;"Advertise in variable `dired-buffers' that we dired `default-directory'."
2121   ;; With wildcards we actually advertise too much.
2122   (let ((expanded-default (expand-file-name default-directory)))
2123     (if (memq (current-buffer) (dired-buffers-for-dir expanded-default))
2124         t                               ; we have already advertised ourselves
2125       (setq dired-buffers
2126             (cons (cons expanded-default (current-buffer))
2127                   dired-buffers)))))
2128
2129 (defun dired-unadvertise (dir)
2130   ;; Remove DIR from the buffer alist in variable dired-buffers.
2131   ;; This has the effect of removing any buffer whose main directory is DIR.
2132   ;; It does not affect buffers in which DIR is a subdir.
2133   ;; Removing is also done as a side-effect in dired-buffer-for-dir.
2134   (setq dired-buffers
2135         (delq (assoc (expand-file-name dir) dired-buffers) dired-buffers)))
2136 \f
2137 ;; Tree Dired
2138
2139 ;;; utility functions
2140
2141 (defun dired-in-this-tree (file dir)
2142   ;;"Is FILE part of the directory tree starting at DIR?"
2143   (let (case-fold-search)
2144     (string-match (concat "^" (regexp-quote dir)) file)))
2145
2146 (defun dired-normalize-subdir (dir)
2147   ;; Prepend default-directory to DIR if relative file name.
2148   ;; dired-get-filename must be able to make a valid file name from a
2149   ;; file and its directory DIR.
2150   (file-name-as-directory
2151    (if (file-name-absolute-p dir)
2152        dir
2153      (expand-file-name dir default-directory))))
2154
2155 (defun dired-get-subdir ()
2156   ;;"Return the subdir name on this line, or nil if not on a headerline."
2157   ;; Look up in the alist whether this is a headerline.
2158   (save-excursion
2159     (let ((cur-dir (dired-current-directory)))
2160       (beginning-of-line)               ; alist stores b-o-l positions
2161       (and (zerop (- (point)
2162                      (dired-get-subdir-min (assoc cur-dir
2163                                                   dired-subdir-alist))))
2164            cur-dir))))
2165
2166 ;(defun dired-get-subdir-min (elt)
2167 ;  (cdr elt))
2168 ;; can't use macro,  must be redefinable for other alist format in dired-nstd.
2169 (defalias 'dired-get-subdir-min 'cdr)
2170
2171 (defun dired-get-subdir-max (elt)
2172   (save-excursion
2173     (goto-char (dired-get-subdir-min elt))
2174     (dired-subdir-max)))
2175
2176 (defun dired-clear-alist ()
2177   (while dired-subdir-alist
2178     (set-marker (dired-get-subdir-min (car dired-subdir-alist)) nil)
2179     (setq dired-subdir-alist (cdr dired-subdir-alist))))
2180
2181 (defun dired-subdir-index (dir)
2182   ;; Return an index into alist for use with nth
2183   ;; for the sake of subdir moving commands.
2184   (let (found (index 0) (alist dired-subdir-alist))
2185     (while alist
2186       (if (string= dir (car (car alist)))
2187           (setq alist nil found t)
2188         (setq alist (cdr alist) index (1+ index))))
2189     (if found index nil)))
2190
2191 (defun dired-next-subdir (arg &optional no-error-if-not-found no-skip)
2192   "Go to next subdirectory, regardless of level."
2193   ;; Use 0 arg to go to this directory's header line.
2194   ;; NO-SKIP prevents moving to end of header line, returning whatever
2195   ;; position was found in dired-subdir-alist.
2196   (interactive "p")
2197   (let ((this-dir (dired-current-directory))
2198         pos index)
2199     ;; nth with negative arg does not return nil but the first element
2200     (setq index (- (dired-subdir-index this-dir) arg))
2201     (setq pos (if (>= index 0)
2202                   (dired-get-subdir-min (nth index dired-subdir-alist))))
2203     (if pos
2204         (progn
2205           (goto-char pos)
2206           (or no-skip (skip-chars-forward "^\n\r"))
2207           (point))
2208       (if no-error-if-not-found
2209           nil                           ; return nil if not found
2210         (error "%s directory" (if (> arg 0) "Last" "First"))))))
2211
2212 (defun dired-build-subdir-alist (&optional switches)
2213   "Build `dired-subdir-alist' by parsing the buffer.
2214 Returns the new value of the alist.
2215 If optional arg SWITCHES is non-nil, use its value
2216 instead of `dired-actual-switches'."
2217   (interactive)
2218   (dired-clear-alist)
2219   (save-excursion
2220     (let* ((count 0)
2221            (buffer-read-only nil)
2222            (buffer-undo-list t)
2223            (switches (or switches dired-actual-switches))
2224            new-dir-name
2225            (R-ftp-base-dir-regex
2226             ;; Used to expand subdirectory names correctly in recursive
2227             ;; ange-ftp listings.
2228             (and (string-match "R" switches)
2229                  (string-match "\\`/.*:\\(/.*\\)" default-directory)
2230                  (concat "\\`" (match-string 1 default-directory)))))
2231       (goto-char (point-min))
2232       (setq dired-subdir-alist nil)
2233       (while (re-search-forward dired-subdir-regexp nil t)
2234         ;; Avoid taking a file name ending in a colon
2235         ;; as a subdir name.
2236         (unless (save-excursion
2237                   (goto-char (match-beginning 0))
2238                   (beginning-of-line)
2239                   (forward-char 2)
2240                   (save-match-data (looking-at dired-re-perms)))
2241           (save-excursion
2242             (goto-char (match-beginning 1))
2243             (setq new-dir-name
2244                   (buffer-substring-no-properties (point) (match-end 1))
2245                   new-dir-name
2246                   (save-match-data
2247                     (if (and R-ftp-base-dir-regex
2248                              (not (string= new-dir-name default-directory))
2249                              (string-match R-ftp-base-dir-regex new-dir-name))
2250                         (concat default-directory
2251                                 (substring new-dir-name (match-end 0)))
2252                       (expand-file-name new-dir-name))))
2253             (delete-region (point) (match-end 1))
2254             (insert new-dir-name))
2255           (setq count (1+ count))
2256           (dired-alist-add-1 new-dir-name
2257                              ;; Place a sub directory boundary between lines.
2258                              (save-excursion
2259                                (goto-char (match-beginning 0))
2260                                (beginning-of-line)
2261                                (point-marker)))))
2262       (if (and (> count 1) (interactive-p))
2263           (message "Buffer includes %d directories" count)))
2264     ;; We don't need to sort it because it is in buffer order per
2265     ;; constructionem.  Return new alist:
2266     dired-subdir-alist))
2267
2268 (defun dired-alist-add-1 (dir new-marker)
2269   ;; Add new DIR at NEW-MARKER.  Don't sort.
2270   (setq dired-subdir-alist
2271         (cons (cons (dired-normalize-subdir dir) new-marker)
2272               dired-subdir-alist)))
2273
2274 (defun dired-goto-next-nontrivial-file ()
2275   ;; Position point on first nontrivial file after point.
2276   (dired-goto-next-file);; so there is a file to compare with
2277   (if (stringp dired-trivial-filenames)
2278       (while (and (not (eobp))
2279                   (string-match dired-trivial-filenames
2280                                 (file-name-nondirectory
2281                                  (or (dired-get-filename nil t) ""))))
2282         (forward-line 1)
2283         (dired-move-to-filename))))
2284
2285 (defun dired-goto-next-file ()
2286   (let ((max (1- (dired-subdir-max))))
2287     (while (and (not (dired-move-to-filename)) (< (point) max))
2288       (forward-line 1))))
2289
2290 (defun dired-goto-file (file)
2291   "Go to line describing file FILE in this dired buffer."
2292   ;; Return value of point on success, else nil.
2293   ;; FILE must be an absolute file name.
2294   ;; Loses if FILE contains control chars like "\007" for which ls
2295   ;; either inserts "?" or "\\007" into the buffer, so we won't find
2296   ;; it in the buffer.
2297   (interactive
2298    (prog1                               ; let push-mark display its message
2299        (list (expand-file-name
2300               (read-file-name "Goto file: "
2301                               (dired-current-directory))))
2302      (push-mark)))
2303   (setq file (directory-file-name file)) ; does no harm if no directory
2304   (let (found case-fold-search dir)
2305     (setq dir (or (file-name-directory file)
2306                   (error "File name `%s' is not absolute" file)))
2307     (save-excursion
2308       ;; The hair here is to get the result of dired-goto-subdir
2309       ;; without really calling it if we don't have any subdirs.
2310       (if (if (string= dir (expand-file-name default-directory))
2311               (goto-char (point-min))
2312             (and (cdr dired-subdir-alist)
2313                  (dired-goto-subdir dir)))
2314           (let ((base (file-name-nondirectory file))
2315                 search-string
2316                 (boundary (dired-subdir-max)))
2317             (setq search-string
2318                   (replace-regexp-in-string "\^m" "\\^m" base nil t))
2319             (setq search-string
2320                   (replace-regexp-in-string "\\\\" "\\\\" search-string nil t))
2321             (while (and (not found)
2322                         ;; filenames are preceded by SPC, this makes
2323                         ;; the search faster (e.g. for the filename "-"!).
2324                         (search-forward (concat " " search-string)
2325                                         boundary 'move))
2326               ;; Match could have BASE just as initial substring or
2327               ;; or in permission bits or date or
2328               ;; not be a proper filename at all:
2329               (if (equal base (dired-get-filename 'no-dir t))
2330                     ;; Must move to filename since an (actually
2331                     ;; correct) match could have been elsewhere on the
2332                     ;; ;; line (e.g. "-" would match somewhere in the
2333                     ;; permission bits).
2334                   (setq found (dired-move-to-filename))
2335                 ;; If this isn't the right line, move forward to avoid
2336                 ;; trying this line again.
2337                 (forward-line 1))))))
2338     (and found
2339          ;; return value of point (i.e., FOUND):
2340          (goto-char found))))
2341
2342 (defun dired-initial-position (dirname)
2343   ;; Where point should go in a new listing of DIRNAME.
2344   ;; Point assumed at beginning of new subdir line.
2345   ;; You may redefine this function as you wish, e.g. like in dired-x.el.
2346   (end-of-line)
2347   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
2348 \f
2349 ;; These are hooks which make tree dired work.
2350 ;; They are in this file because other parts of dired need to call them.
2351 ;; But they don't call the rest of tree dired unless there are subdirs loaded.
2352
2353 ;; This function is called for each retrieved filename.
2354 ;; It could stand to be faster, though it's mostly function call
2355 ;; overhead.  Avoiding the function call seems to save about 10% in
2356 ;; dired-get-filename.  Make it a defsubst?
2357 (defun dired-current-directory (&optional localp)
2358   "Return the name of the subdirectory to which this line belongs.
2359 This returns a string with trailing slash, like `default-directory'.
2360 Optional argument means return a file name relative to `default-directory'."
2361   (let ((here (point))
2362         (alist (or dired-subdir-alist
2363                    ;; probably because called in a non-dired buffer
2364                    (error "No subdir-alist in %s" (current-buffer))))
2365         elt dir)
2366     (while alist
2367       (setq elt (car alist)
2368             dir (car elt)
2369             ;; use `<=' (not `<') as subdir line is part of subdir
2370             alist (if (<= (dired-get-subdir-min elt) here)
2371                       nil               ; found
2372                     (cdr alist))))
2373     (if localp
2374         (dired-make-relative dir default-directory)
2375       dir)))
2376
2377 ;; Subdirs start at the beginning of their header lines and end just
2378 ;; before the beginning of the next header line (or end of buffer).
2379
2380 (defun dired-subdir-max ()
2381   (save-excursion
2382     (if (or (null (cdr dired-subdir-alist)) (not (dired-next-subdir 1 t t)))
2383         (point-max)
2384       (point))))
2385 \f
2386 ;; Deleting files
2387
2388 (defcustom dired-recursive-deletes 'top
2389   "*Decide whether recursive deletes are allowed.
2390 A value of nil means no recursive deletes.
2391 `always' means delete recursively without asking.  This is DANGEROUS!
2392 `top' means ask for each directory at top level, but delete its subdirectories
2393 without asking.
2394 Anything else means ask for each directory."
2395   :type '(choice :tag "Delete non-empty directories"
2396                  (const :tag "Yes" always)
2397                  (const :tag "No--only delete empty directories" nil)
2398                  (const :tag "Confirm for each directory" t)
2399                  (const :tag "Confirm for each top directory only" top))
2400   :group 'dired)
2401
2402 ;; Match anything but `.' and `..'.
2403 (defvar dired-re-no-dot "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")
2404
2405 ;; Delete file, possibly delete a directory and all its files.
2406 ;; This function is usefull outside of dired.  One could change it's name
2407 ;; to e.g. recursive-delete-file and put it somewhere else.
2408 (defun dired-delete-file (file &optional recursive) "\
2409 Delete FILE or directory (possibly recursively if optional RECURSIVE is true.)
2410 RECURSIVE determines what to do with a non-empty directory.  If RECURSIVE is:
2411 nil, do not delete.
2412 `always', delete recursively without asking.
2413 `top', ask for each directory at top level.
2414 Anything else, ask for each sub-directory."
2415   (let (files)
2416      ;; This test is equivalent to
2417      ;; (and (file-directory-p fn) (not (file-symlink-p fn)))
2418      ;; but more efficient
2419     (if (not (eq t (car (file-attributes file))))
2420         (delete-file file)
2421       (when (and recursive
2422                (setq files
2423                      (directory-files file t dired-re-no-dot)) ; Not empty.
2424                (or (eq recursive 'always)
2425                    (yes-or-no-p (format "Recursive delete of %s? "
2426                                         (dired-make-relative file)))))
2427         (if (eq recursive 'top) (setq recursive 'always)) ; Don't ask again.
2428         (while files            ; Recursively delete (possibly asking).
2429             (dired-delete-file (car files) recursive)
2430             (setq files (cdr files))))
2431       (delete-directory file))))
2432
2433 (defun dired-do-flagged-delete (&optional nomessage)
2434   "In Dired, delete the files flagged for deletion.
2435 If NOMESSAGE is non-nil, we don't display any message
2436 if there are no flagged files.
2437 `dired-recursive-deletes' controls whether deletion of
2438 non-empty directories is allowed."
2439   (interactive)
2440   (let* ((dired-marker-char dired-del-marker)
2441          (regexp (dired-marker-regexp))
2442          case-fold-search)
2443     (if (save-excursion (goto-char (point-min))
2444                         (re-search-forward regexp nil t))
2445         (dired-internal-do-deletions
2446          ;; this can't move point since ARG is nil
2447          (dired-map-over-marks (cons (dired-get-filename) (point))
2448                                nil)
2449          nil)
2450       (or nomessage
2451           (message "(No deletions requested)")))))
2452
2453 (defun dired-do-delete (&optional arg)
2454   "Delete all marked (or next ARG) files.
2455 `dired-recursive-deletes' controls whether deletion of
2456 non-empty directories is allowed."
2457   ;; This is more consistent with the file marking feature than
2458   ;; dired-do-flagged-delete.
2459   (interactive "P")
2460   (dired-internal-do-deletions
2461    ;; this may move point if ARG is an integer
2462    (dired-map-over-marks (cons (dired-get-filename) (point))
2463                          arg)
2464    arg))
2465
2466 (defvar dired-deletion-confirmer 'yes-or-no-p) ; or y-or-n-p?
2467
2468 (defun dired-internal-do-deletions (l arg)
2469   ;; L is an alist of files to delete, with their buffer positions.
2470   ;; ARG is the prefix arg.
2471   ;; Filenames are absolute (VMS needs this for logical search paths).
2472   ;; (car L) *must* be the *last* (bottommost) file in the dired buffer.
2473   ;; That way as changes are made in the buffer they do not shift the
2474   ;; lines still to be changed, so the (point) values in L stay valid.
2475   ;; Also, for subdirs in natural order, a subdir's files are deleted
2476   ;; before the subdir itself - the other way around would not work.
2477   (let ((files (mapcar (function car) l))
2478         (count (length l))
2479         (succ 0))
2480     ;; canonicalize file list for pop up
2481     (setq files (nreverse (mapcar (function dired-make-relative) files)))
2482     (if (dired-mark-pop-up
2483          " *Deletions*" 'delete files dired-deletion-confirmer
2484          (format "Delete %s " (dired-mark-prompt arg files)))
2485         (save-excursion
2486           (let (failures);; files better be in reverse order for this loop!
2487             (while l
2488               (goto-char (cdr (car l)))
2489               (let (buffer-read-only)
2490                 (condition-case err
2491                     (let ((fn (car (car l))))
2492                       (dired-delete-file fn dired-recursive-deletes)
2493                       ;; if we get here, removing worked
2494                       (setq succ (1+ succ))
2495                       (message "%s of %s deletions" succ count)
2496                       (dired-fun-in-all-buffers
2497                        (file-name-directory fn) (file-name-nondirectory fn)
2498                        (function dired-delete-entry) fn))
2499                   (error;; catch errors from failed deletions
2500                    (dired-log "%s\n" err)
2501                    (setq failures (cons (car (car l)) failures)))))
2502               (setq l (cdr l)))
2503             (if (not failures)
2504                 (message "%d deletion%s done" count (dired-plural-s count))
2505               (dired-log-summary
2506                (format "%d of %d deletion%s failed"
2507                        (length failures) count
2508                        (dired-plural-s count))
2509                failures))))
2510       (message "(No deletions performed)")))
2511   (dired-move-to-filename))
2512
2513 (defun dired-fun-in-all-buffers (directory file fun &rest args)
2514   ;; In all buffers dired'ing DIRECTORY, run FUN with ARGS.
2515   ;; If the buffer has a wildcard pattern, check that it matches FILE.
2516   ;; (FILE does not include a directory component.)
2517   ;; FILE may be nil, in which case ignore it.
2518   ;; Return list of buffers where FUN succeeded (i.e., returned non-nil).
2519   (let (success-list)
2520     (dolist (buf (dired-buffers-for-dir (expand-file-name directory)
2521                                         file))
2522       (with-current-buffer buf
2523         (if (apply fun args)
2524             (setq success-list (cons (buffer-name buf) success-list)))))
2525     success-list))
2526
2527 ;; Delete the entry for FILE from
2528 (defun dired-delete-entry (file)
2529   (save-excursion
2530     (and (dired-goto-file file)
2531          (let (buffer-read-only)
2532            (delete-region (progn (beginning-of-line) (point))
2533                           (save-excursion (forward-line 1) (point))))))
2534   (dired-clean-up-after-deletion file))
2535
2536 ;; This is a separate function for the sake of dired-x.el.
2537 (defun dired-clean-up-after-deletion (fn)
2538   ;; Clean up after a deleted file or directory FN.
2539   (save-excursion (and (cdr dired-subdir-alist)
2540                        (dired-goto-subdir fn)
2541                        (dired-kill-subdir))))
2542 \f
2543 ;; Confirmation
2544
2545 (defun dired-marker-regexp ()
2546   (concat "^" (regexp-quote (char-to-string dired-marker-char))))
2547
2548 (defun dired-plural-s (count)
2549   (if (= 1 count) "" "s"))
2550
2551 (defun dired-mark-prompt (arg files)
2552   "Return a string for use in a prompt, either the current file
2553 name, or the marker and a count of marked files."
2554   ;; distinguish-one-marked can cause the first element to be just t.
2555   (if (eq (car files) t) (setq files (cdr files)))
2556   (let ((count (length files)))
2557     (if (= count 1)
2558         (car files)
2559       ;; more than 1 file:
2560       (if (integerp arg)
2561           ;; abs(arg) = count
2562           ;; Perhaps this is nicer, but it also takes more screen space:
2563           ;;(format "[%s %d files]" (if (> arg 0) "next" "previous")
2564           ;;                        count)
2565           (format "[next %d files]" arg)
2566         (format "%c [%d files]" dired-marker-char count)))))
2567
2568 (defun dired-pop-to-buffer (buf)
2569   ;; Pop up buffer BUF.
2570   ;; If dired-shrink-to-fit is t, make its window fit its contents.
2571   (if (not dired-shrink-to-fit)
2572       (pop-to-buffer (get-buffer-create buf))
2573     ;; let window shrink to fit:
2574     (let ((window (selected-window))
2575           target-lines w2)
2576       (cond ;; if split-height-threshold is enabled, use the largest window
2577             ((and (> (window-height (setq w2 (get-largest-window)))
2578                      split-height-threshold)
2579                   (window-full-width-p w2))
2580              (setq window w2))
2581             ;; if the least-recently-used window is big enough, use it
2582             ((and (> (window-height (setq w2 (get-lru-window)))
2583                      (* 2 window-min-height))
2584                   (window-full-width-p w2))
2585              (setq window w2)))
2586       (save-excursion
2587         (set-buffer buf)
2588         (goto-char (point-max))
2589         (skip-chars-backward "\n\r\t ")
2590         (setq target-lines (count-lines (point-min) (point)))
2591         ;; Don't forget to count the last line.
2592         (if (not (bolp))
2593             (setq target-lines (1+ target-lines))))
2594       (if (<= (window-height window) (* 2 window-min-height))
2595           ;; At this point, every window on the frame is too small to split.
2596           (setq w2 (display-buffer buf))
2597         (setq w2 (split-window window
2598                   (max window-min-height
2599                        (- (window-height window)
2600                           (1+ (max window-min-height target-lines)))))))
2601       (set-window-buffer w2 buf)
2602       (if (< (1- (window-height w2)) target-lines)
2603           (progn
2604             (select-window w2)
2605             (enlarge-window (- target-lines (1- (window-height w2))))))
2606       (set-window-start w2 1)
2607       )))
2608
2609 (defcustom dired-no-confirm nil
2610   "A list of symbols for commands Dired should not confirm.
2611 Command symbols are `byte-compile', `chgrp', `chmod', `chown', `compress',
2612 `copy', `delete', `hardlink', `load', `move', `print', `shell', `symlink',
2613 `touch' and `uncompress'."
2614   :group 'dired
2615   :type '(set (const byte-compile) (const chgrp)
2616               (const chmod) (const chown) (const compress)
2617               (const copy) (const delete) (const hardlink)
2618               (const load) (const move) (const print)
2619               (const shell) (const symlink) (const touch)
2620               (const uncompress)))
2621
2622 (defun dired-mark-pop-up (bufname op-symbol files function &rest args)
2623   "Return FUNCTION's result on ARGS after showing which files are marked.
2624 Displays the file names in a buffer named BUFNAME;
2625  nil gives \" *Marked Files*\".
2626 This uses function `dired-pop-to-buffer' to do that.
2627
2628 FUNCTION should not manipulate files, just read input
2629  (an argument or confirmation).
2630 The window is not shown if there is just one file or
2631  OP-SYMBOL is a member of the list in `dired-no-confirm'.
2632 FILES is the list of marked files.  It can also be (t FILENAME)
2633 in the case of one marked file, to distinguish that from using
2634 just the current file."
2635   (or bufname (setq bufname  " *Marked Files*"))
2636   (if (or (eq dired-no-confirm t)
2637           (memq op-symbol dired-no-confirm)
2638           ;; If FILES defaulted to the current line's file.
2639           (= (length files) 1))
2640       (apply function args)
2641     (with-current-buffer (get-buffer-create bufname)
2642       (erase-buffer)
2643       ;; Handle (t FILE) just like (FILE), here.
2644       ;; That value is used (only in some cases), to mean
2645       ;; just one file that was marked, rather than the current line file.
2646       (dired-format-columns-of-files (if (eq (car files) t) (cdr files) files))
2647       (remove-text-properties (point-min) (point-max)
2648                               '(mouse-face nil help-echo nil)))
2649     (save-window-excursion
2650       (dired-pop-to-buffer bufname)
2651       (apply function args))))
2652
2653 (defun dired-format-columns-of-files (files)
2654   ;; Files should be in forward order for this loop.
2655   ;; i.e., (car files) = first file in buffer.
2656   ;; Returns the number of lines used.
2657   (let* ((maxlen (+ 2 (apply 'max (mapcar 'length files))))
2658          (width (- (window-width (selected-window)) 2))
2659          (columns (max 1 (/ width maxlen)))
2660          (nfiles (length files))
2661          (rows (+ (/ nfiles columns)
2662                   (if (zerop (% nfiles columns)) 0 1)))
2663          (i 0)
2664          (j 0))
2665     (setq files (nconc (copy-sequence files) ; fill up with empty fns
2666                        (make-list (- (* columns rows) nfiles) "")))
2667     (setcdr (nthcdr (1- (length files)) files) files) ; make circular
2668     (while (< j rows)
2669       (while (< i columns)
2670         (indent-to (* i maxlen))
2671         (insert (car files))
2672         (setq files (nthcdr rows files)
2673               i (1+ i)))
2674       (insert "\n")
2675       (setq i 0
2676             j (1+ j)
2677             files (cdr files)))
2678     rows))
2679 \f
2680 ;; Commands to mark or flag file(s) at or near current line.
2681
2682 (defun dired-repeat-over-lines (arg function)
2683   ;; This version skips non-file lines.
2684   (let ((pos (make-marker)))
2685     (beginning-of-line)
2686     (while (and (> arg 0) (not (eobp)))
2687       (setq arg (1- arg))
2688       (beginning-of-line)
2689       (while (and (not (eobp)) (dired-between-files)) (forward-line 1))
2690       (save-excursion
2691         (forward-line 1)
2692         (move-marker pos (1+ (point))))
2693       (save-excursion (funcall function))
2694       ;; Advance to the next line--actually, to the line that *was* next.
2695       ;; (If FUNCTION inserted some new lines in between, skip them.)
2696       (goto-char pos))
2697     (while (and (< arg 0) (not (bobp)))
2698       (setq arg (1+ arg))
2699       (forward-line -1)
2700       (while (and (not (bobp)) (dired-between-files)) (forward-line -1))
2701       (beginning-of-line)
2702       (save-excursion (funcall function)))
2703     (move-marker pos nil)
2704     (dired-move-to-filename)))
2705
2706 (defun dired-between-files ()
2707   ;; This used to be a regexp match of the `total ...' line output by
2708   ;; ls, which is slightly faster, but that is not very robust; notably,
2709   ;; it fails for non-english locales.
2710   (save-excursion (not (dired-move-to-filename))))
2711
2712 (defun dired-next-marked-file (arg &optional wrap opoint)
2713   "Move to the next marked file, wrapping around the end of the buffer."
2714   (interactive "p\np")
2715   (or opoint (setq opoint (point)));; return to where interactively started
2716   (if (if (> arg 0)
2717           (re-search-forward dired-re-mark nil t arg)
2718         (beginning-of-line)
2719         (re-search-backward dired-re-mark nil t (- arg)))
2720       (dired-move-to-filename)
2721     (if (null wrap)
2722         (progn
2723           (goto-char opoint)
2724           (error "No next marked file"))
2725       (message "(Wraparound for next marked file)")
2726       (goto-char (if (> arg 0) (point-min) (point-max)))
2727       (dired-next-marked-file arg nil opoint))))
2728
2729 (defun dired-prev-marked-file (arg &optional wrap)
2730   "Move to the previous marked file, wrapping around the end of the buffer."
2731   (interactive "p\np")
2732   (dired-next-marked-file (- arg) wrap))
2733
2734 (defun dired-file-marker (file)
2735   ;; Return FILE's marker, or nil if unmarked.
2736   (save-excursion
2737     (and (dired-goto-file file)
2738          (progn
2739            (beginning-of-line)
2740            (if (not (equal ?\040 (following-char)))
2741                (following-char))))))
2742
2743 (defun dired-mark-files-in-region (start end)
2744   (let (buffer-read-only)
2745     (if (> start end)
2746         (error "start > end"))
2747     (goto-char start)                   ; assumed at beginning of line
2748     (while (< (point) end)
2749       ;; Skip subdir line and following garbage like the `total' line:
2750       (while (and (< (point) end) (dired-between-files))
2751         (forward-line 1))
2752       (if (and (not (looking-at dired-re-dot))
2753                (dired-get-filename nil t))
2754           (progn
2755             (delete-char 1)
2756             (insert dired-marker-char)))
2757       (forward-line 1))))
2758
2759 (defun dired-mark (arg)
2760   "Mark the current (or next ARG) files.
2761 If on a subdir headerline, mark all its files except `.' and `..'.
2762
2763 Use \\[dired-unmark-all-files] to remove all marks
2764 and \\[dired-unmark] on a subdir to remove the marks in
2765 this subdir."
2766   (interactive "P")
2767   (if (dired-get-subdir)
2768       (save-excursion (dired-mark-subdir-files))
2769     (let (buffer-read-only)
2770       (dired-repeat-over-lines
2771        (prefix-numeric-value arg)
2772        (function (lambda () (delete-char 1) (insert dired-marker-char)))))))
2773
2774 (defun dired-unmark (arg)
2775   "Unmark the current (or next ARG) files.
2776 If looking at a subdir, unmark all its files except `.' and `..'."
2777   (interactive "P")
2778   (let ((dired-marker-char ?\040))
2779     (dired-mark arg)))
2780
2781 (defun dired-flag-file-deletion (arg)
2782   "In Dired, flag the current line's file for deletion.
2783 With prefix arg, repeat over several lines.
2784
2785 If on a subdir headerline, mark all its files except `.' and `..'."
2786   (interactive "P")
2787   (let ((dired-marker-char dired-del-marker))
2788     (dired-mark arg)))
2789
2790 (defun dired-unmark-backward (arg)
2791   "In Dired, move up lines and remove deletion flag there.
2792 Optional prefix ARG says how many lines to unflag; default is one line."
2793   (interactive "p")
2794   (dired-unmark (- arg)))
2795
2796 (defun dired-toggle-marks ()
2797   "Toggle marks: marked files become unmarked, and vice versa.
2798 Files marked with other flags (such as `D') are not affected.
2799 `.' and `..' are never toggled.
2800 As always, hidden subdirs are not affected."
2801   (interactive)
2802   (save-excursion
2803     (goto-char (point-min))
2804     (let (buffer-read-only)
2805       (while (not (eobp))
2806         (or (dired-between-files)
2807             (looking-at dired-re-dot)
2808             ;; use subst instead of insdel because it does not move
2809             ;; the gap and thus should be faster and because
2810             ;; other characters are left alone automatically
2811             (apply 'subst-char-in-region
2812                    (point) (1+ (point))
2813                    (if (eq ?\040 (following-char)) ; SPC
2814                        (list ?\040 dired-marker-char)
2815                      (list dired-marker-char ?\040))))
2816         (forward-line 1)))))
2817 \f
2818 ;;; Commands to mark or flag files based on their characteristics or names.
2819
2820 (defvar dired-regexp-history nil
2821   "History list of regular expressions used in Dired commands.")
2822
2823 (defun dired-read-regexp (prompt)
2824   (read-from-minibuffer prompt nil nil nil 'dired-regexp-history))
2825
2826 (defun dired-mark-files-regexp (regexp &optional marker-char)
2827   "Mark all files matching REGEXP for use in later commands.
2828 A prefix argument means to unmark them instead.
2829 `.' and `..' are never marked.
2830
2831 REGEXP is an Emacs regexp, not a shell wildcard.  Thus, use `\\.o$' for
2832 object files--just `.o' will mark more than you might think."
2833   (interactive
2834    (list (dired-read-regexp (concat (if current-prefix-arg "Unmark" "Mark")
2835                                     " files (regexp): "))
2836          (if current-prefix-arg ?\040)))
2837   (let ((dired-marker-char (or marker-char dired-marker-char)))
2838     (dired-mark-if
2839      (and (not (looking-at dired-re-dot))
2840           (not (eolp))                  ; empty line
2841           (let ((fn (dired-get-filename nil t)))
2842             (and fn (string-match regexp (file-name-nondirectory fn)))))
2843      "matching file")))
2844
2845 (defun dired-mark-files-containing-regexp (regexp &optional marker-char)
2846   "Mark all files with contents containing REGEXP for use in later commands.
2847 A prefix argument means to unmark them instead.
2848 `.' and `..' are never marked."
2849   (interactive
2850    (list (dired-read-regexp (concat (if current-prefix-arg "Unmark" "Mark")
2851                                     " files containing (regexp): "))
2852          (if current-prefix-arg ?\040)))
2853   (let ((dired-marker-char (or marker-char dired-marker-char)))
2854     (dired-mark-if
2855      (and (not (looking-at dired-re-dot))
2856           (not (eolp))                  ; empty line
2857           (let ((fn (dired-get-filename nil t)))
2858             (when (and fn (file-readable-p fn)
2859                        (not (file-directory-p fn)))
2860               (let ((prebuf (get-file-buffer fn)))
2861                 (message "Checking %s" fn)
2862                 ;; For now we do it inside emacs
2863                 ;; Grep might be better if there are a lot of files
2864                 (if prebuf
2865                     (with-current-buffer prebuf
2866                       (save-excursion
2867                         (goto-char (point-min))
2868                         (re-search-forward regexp nil t)))
2869                   (with-temp-buffer
2870                     (insert-file-contents fn)
2871                     (goto-char (point-min))
2872                     (re-search-forward regexp nil t))))
2873                       )))
2874      "matching file")))
2875
2876 (defun dired-flag-files-regexp (regexp)
2877   "In Dired, flag all files containing the specified REGEXP for deletion.
2878 The match is against the non-directory part of the filename.  Use `^'
2879   and `$' to anchor matches.  Exclude subdirs by hiding them.
2880 `.' and `..' are never flagged."
2881   (interactive (list (dired-read-regexp "Flag for deletion (regexp): ")))
2882   (dired-mark-files-regexp regexp dired-del-marker))
2883
2884 (defun dired-mark-symlinks (unflag-p)
2885   "Mark all symbolic links.
2886 With prefix argument, unflag all those files."
2887   (interactive "P")
2888   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
2889     (dired-mark-if (looking-at dired-re-sym) "symbolic link")))
2890
2891 (defun dired-mark-directories (unflag-p)
2892   "Mark all directory file lines except `.' and `..'.
2893 With prefix argument, unflag all those files."
2894   (interactive "P")
2895   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
2896     (dired-mark-if (and (looking-at dired-re-dir)
2897                         (not (looking-at dired-re-dot)))
2898                    "directory file")))
2899
2900 (defun dired-mark-executables (unflag-p)
2901   "Mark all executable files.
2902 With prefix argument, unflag all those files."
2903   (interactive "P")
2904   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
2905     (dired-mark-if (looking-at dired-re-exe) "executable file")))
2906
2907 ;; dired-x.el has a dired-mark-sexp interactive command: mark
2908 ;; files for which PREDICATE returns non-nil.
2909
2910 (defun dired-flag-auto-save-files (&optional unflag-p)
2911   "Flag for deletion files whose names suggest they are auto save files.
2912 A prefix argument says to unflag those files instead."
2913   (interactive "P")
2914   (let ((dired-marker-char (if unflag-p ?\040 dired-del-marker)))
2915     (dired-mark-if
2916      ;; It is less than general to check for # here,
2917      ;; but it's the only way this runs fast enough.
2918      (and (save-excursion (end-of-line)
2919                           (or
2920                            (eq (preceding-char) ?#)
2921                            ;; Handle executables in case of -F option.
2922                            ;; We need not worry about the other kinds
2923                            ;; of markings that -F makes, since they won't
2924                            ;; appear on real auto-save files.
2925                            (if (eq (preceding-char) ?*)
2926                                (progn
2927                                  (forward-char -1)
2928                                  (eq (preceding-char) ?#)))))
2929           (not (looking-at dired-re-dir))
2930           (let ((fn (dired-get-filename t t)))
2931             (if fn (auto-save-file-name-p
2932                     (file-name-nondirectory fn)))))
2933      "auto save file")))
2934
2935 (defcustom dired-garbage-files-regexp
2936   ;; `log' here is dubious, since it's typically used for useful log
2937   ;; files, not just TeX stuff.  -- fx
2938   (concat (regexp-opt
2939            '(".log" ".toc" ".dvi" ".bak" ".orig" ".rej" ".aux"))
2940           "\\'")
2941   "Regular expression to match \"garbage\" files for `dired-flag-garbage-files'."
2942   :type 'regexp
2943   :group 'dired)
2944
2945 (defun dired-flag-garbage-files ()
2946   "Flag for deletion all files that match `dired-garbage-files-regexp'."
2947   (interactive)
2948   (dired-flag-files-regexp dired-garbage-files-regexp))
2949
2950 (defun dired-flag-backup-files (&optional unflag-p)
2951   "Flag all backup files (names ending with `~') for deletion.
2952 With prefix argument, unflag these files."
2953   (interactive "P")
2954   (let ((dired-marker-char (if unflag-p ?\s dired-del-marker)))
2955     (dired-mark-if
2956      ;; Don't call backup-file-name-p unless the last character looks like
2957      ;; it might be the end of a backup file name.  This isn't very general,
2958      ;; but it's the only way this runs fast enough.
2959      (and (save-excursion (end-of-line)
2960                           ;; Handle executables in case of -F option.
2961                           ;; We need not worry about the other kinds
2962                           ;; of markings that -F makes, since they won't
2963                           ;; appear on real backup files.
2964                           (if (eq (preceding-char) ?*)
2965                               (forward-char -1))
2966                           (eq (preceding-char) ?~))
2967           (not (looking-at dired-re-dir))
2968           (let ((fn (dired-get-filename t t)))
2969             (if fn (backup-file-name-p fn))))
2970      "backup file")))
2971
2972 (defun dired-change-marks (&optional old new)
2973   "Change all OLD marks to NEW marks.
2974 OLD and NEW are both characters used to mark files."
2975   (interactive
2976    (let* ((cursor-in-echo-area t)
2977           (old (progn (message "Change (old mark): ") (read-char)))
2978           (new (progn (message  "Change %c marks to (new mark): " old)
2979                       (read-char))))
2980      (list old new)))
2981   (if (or (eq old ?\r) (eq new ?\r))
2982       (ding)
2983     (let ((string (format "\n%c" old))
2984           (buffer-read-only))
2985       (save-excursion
2986         (goto-char (point-min))
2987         (while (search-forward string nil t)
2988           (if (if (= old ?\s)
2989                   (save-match-data
2990                     (dired-get-filename 'no-dir t))
2991                 t)
2992               (subst-char-in-region (match-beginning 0)
2993                                     (match-end 0) old new)))))))
2994
2995 (defun dired-unmark-all-marks ()
2996   "Remove all marks from all files in the dired buffer."
2997   (interactive)
2998   (dired-unmark-all-files ?\r))
2999
3000 (defun dired-unmark-all-files (mark &optional arg)
3001   "Remove a specific mark (or any mark) from every file.
3002 After this command, type the mark character to remove,
3003 or type RET to remove all marks.
3004 With prefix arg, query for each marked file.
3005 Type \\[help-command] at that time for help."
3006   (interactive "cRemove marks (RET means all): \nP")
3007   (save-excursion
3008     (let* ((count 0)
3009            buffer-read-only case-fold-search query
3010            (string (format "\n%c" mark))
3011            (help-form "\
3012 Type SPC or `y' to unmark one file, DEL or `n' to skip to next,
3013 `!' to unmark all remaining files with no more questions."))
3014       (goto-char (point-min))
3015       (while (if (eq mark ?\r)
3016                  (re-search-forward dired-re-mark nil t)
3017                (search-forward string nil t))
3018         (if (or (not arg)
3019                 (let ((file (dired-get-filename t t)))
3020                   (and file
3021                        (dired-query 'query "Unmark file `%s'? "
3022                                     file))))
3023             (progn (subst-char-in-region (1- (point)) (point)
3024                                          (preceding-char) ?\s)
3025                    (setq count (1+ count)))))
3026       (message (if (= count 1) "1 mark removed"
3027                  "%d marks removed")
3028                count))))
3029 \f
3030 ;; Logging failures operating on files, and showing the results.
3031
3032 (defvar dired-log-buffer "*Dired log*")
3033
3034 (defun dired-why ()
3035   "Pop up a buffer with error log output from Dired.
3036 A group of errors from a single command ends with a formfeed.
3037 Thus, use \\[backward-page] to find the beginning of a group of errors."
3038   (interactive)
3039   (if (get-buffer dired-log-buffer)
3040       (let ((owindow (selected-window))
3041             (window (display-buffer (get-buffer dired-log-buffer))))
3042         (unwind-protect
3043             (progn
3044               (select-window window)
3045               (goto-char (point-max))
3046               (forward-line -1)
3047               (backward-page 1)
3048               (recenter 0))
3049           (select-window owindow)))))
3050
3051 (defun dired-log (log &rest args)
3052   ;; Log a message or the contents of a buffer.
3053   ;; If LOG is a string and there are more args, it is formatted with
3054   ;; those ARGS.  Usually the LOG string ends with a \n.
3055   ;; End each bunch of errors with (dired-log t):
3056   ;; this inserts the current time and buffer at the start of the page,
3057   ;; and \f (formfeed) at the end.
3058   (let ((obuf (current-buffer)))
3059     (with-current-buffer (get-buffer-create dired-log-buffer)
3060       (goto-char (point-max))
3061       (let ((inhibit-read-only t))
3062         (cond ((stringp log)
3063                (insert (if args
3064                            (apply (function format) log args)
3065                          log)))
3066               ((bufferp log)
3067                (insert-buffer-substring log))
3068               ((eq t log)
3069                (backward-page 1)
3070                (unless (bolp)
3071                  (insert "\n"))
3072                (insert (current-time-string)
3073                        "\tBuffer `" (buffer-name obuf) "'\n")
3074                (goto-char (point-max))
3075                (insert "\f\n")))))))
3076
3077 (defun dired-log-summary (string failures)
3078   "State a summary of a command's failures, in echo area and log buffer.
3079 STRING is an overall summary of the failures.
3080 FAILURES is a list of file names that we failed to operate on,
3081 or nil if file names are not applicable."
3082   (if (= (length failures) 1)
3083       (message "%s"
3084                (with-current-buffer dired-log-buffer
3085                  (goto-char (point-max))
3086                  (backward-page 1)
3087                  (if (eolp) (forward-line 1))
3088                  (buffer-substring (point) (point-max))))
3089     (message (if failures "%s--type ? for details (%s)"
3090                "%s--type ? for details")
3091              string failures))
3092   ;; Log a summary describing a bunch of errors.
3093   (dired-log (concat "\n" string "\n"))
3094   (dired-log t))
3095 \f
3096 ;;; Sorting
3097
3098 ;; Most ls can only sort by name or by date (with -t), nothing else.
3099 ;; GNU ls sorts on size with -S, on extension with -X, and unsorted with -U.
3100 ;; So anything that does not contain these is sort "by name".
3101
3102 (defvar dired-ls-sorting-switches "SXU"
3103   "String of `ls' switches \(single letters\) except \"t\" that influence sorting.
3104
3105 This indicates to Dired which option switches to watch out for because they
3106 will change the sorting order behavior of `ls'.
3107
3108 To change the default sorting order \(e.g. add a `-v' option\), see the
3109 variable `dired-listing-switches'.  To temporarily override the listing
3110 format, use `\\[universal-argument] \\[dired]'.")
3111
3112 (defvar dired-sort-by-date-regexp
3113   (concat "^-[^" dired-ls-sorting-switches
3114           "]*t[^" dired-ls-sorting-switches "]*$")
3115   "Regexp recognized by Dired to set `by date' mode.")
3116
3117 (defvar dired-sort-by-name-regexp
3118   (concat "^-[^t" dired-ls-sorting-switches "]+$")
3119   "Regexp recognized by Dired to set `by name' mode.")
3120
3121 (defvar dired-sort-inhibit nil
3122   "Non-nil means the Dired sort command is disabled.
3123 The idea is to set this buffer-locally in special dired buffers.")
3124
3125 (defun dired-sort-set-modeline ()
3126   ;; Set modeline display according to dired-actual-switches.
3127   ;; Modeline display of "by name" or "by date" guarantees the user a
3128   ;; match with the corresponding regexps.  Non-matching switches are
3129   ;; shown literally.
3130   (when (eq major-mode 'dired-mode)
3131     (setq mode-name
3132           (let (case-fold-search)
3133             (cond ((string-match
3134                     dired-sort-by-name-regexp dired-actual-switches)
3135                    "Dired by name")
3136                   ((string-match
3137                     dired-sort-by-date-regexp dired-actual-switches)
3138                    "Dired by date")
3139                   (t
3140                    (concat "Dired " dired-actual-switches)))))
3141     (force-mode-line-update)))
3142
3143 (defun dired-sort-toggle-or-edit (&optional arg)
3144   "Toggle between sort by date/name and refresh the dired buffer.
3145 With a prefix argument you can edit the current listing switches instead."
3146   (interactive "P")
3147   (when dired-sort-inhibit
3148     (error "Cannot sort this dired buffer"))
3149   (if arg
3150       (dired-sort-other
3151        (read-string "ls switches (must contain -l): " dired-actual-switches))
3152     (dired-sort-toggle)))
3153
3154 (defun dired-sort-toggle ()
3155   ;; Toggle between sort by date/name.  Reverts the buffer.
3156   (setq dired-actual-switches
3157         (let (case-fold-search)
3158           (if (string-match " " dired-actual-switches)
3159               ;; New toggle scheme: add/remove a trailing " -t"
3160               (if (string-match " -t\\'" dired-actual-switches)
3161                   (substring dired-actual-switches 0 (match-beginning 0))
3162                 (concat dired-actual-switches " -t"))
3163             ;; old toggle scheme: look for some 't' switch and add/remove it
3164             (concat
3165              "-l"
3166              (dired-replace-in-string (concat "[-lt"
3167                                               dired-ls-sorting-switches "]")
3168                                       ""
3169                                       dired-actual-switches)
3170              (if (string-match (concat "[t" dired-ls-sorting-switches "]")
3171                                dired-actual-switches)
3172                  ""
3173                "t")))))
3174   (dired-sort-set-modeline)
3175   (revert-buffer))
3176
3177 ;; Some user code loads dired especially for this.
3178 ;; Don't do that--use replace-regexp-in-string instead.
3179 (defun dired-replace-in-string (regexp newtext string)
3180   ;; Replace REGEXP with NEWTEXT everywhere in STRING and return result.
3181   ;; NEWTEXT is taken literally---no \\DIGIT escapes will be recognized.
3182   (let ((result "") (start 0) mb me)
3183     (while (string-match regexp string start)
3184       (setq mb (match-beginning 0)
3185             me (match-end 0)
3186             result (concat result (substring string start mb) newtext)
3187             start me))
3188     (concat result (substring string start))))
3189
3190 (defun dired-sort-other (switches &optional no-revert)
3191   "Specify new `ls' SWITCHES for current dired buffer.
3192 Values matching `dired-sort-by-date-regexp' or `dired-sort-by-name-regexp'
3193 set the minor mode accordingly, others appear literally in the mode line.
3194 With optional second arg NO-REVERT, don't refresh the listing afterwards."
3195   (dired-sort-R-check switches)
3196   (setq dired-actual-switches switches)
3197   (dired-sort-set-modeline)
3198   (or no-revert (revert-buffer)))
3199
3200 (defvar dired-subdir-alist-pre-R nil
3201   "Value of `dired-subdir-alist' before -R switch added.")
3202 (make-variable-buffer-local 'dired-subdir-alist-pre-R)
3203
3204 (defun dired-sort-R-check (switches)
3205   "Additional processing of -R in ls option string SWITCHES.
3206 Saves `dired-subdir-alist' when R is set and restores saved value
3207 minus any directories explicitly deleted when R is cleared.
3208 To be called first in body of `dired-sort-other', etc."
3209   (cond
3210    ((and (string-match "R" switches)
3211          (not (string-match "R" dired-actual-switches)))
3212     ;; Adding -R to ls switches -- save `dired-subdir-alist':
3213     (setq dired-subdir-alist-pre-R dired-subdir-alist))
3214    ((and (string-match "R" dired-actual-switches)
3215          (not (string-match "R" switches)))
3216     ;; Deleting -R from ls switches -- revert to pre-R subdirs
3217     ;; that are still present:
3218     (setq dired-subdir-alist
3219           (if dired-subdir-alist-pre-R
3220               (let (subdirs)
3221                 (while dired-subdir-alist-pre-R
3222                   (if (assoc (caar dired-subdir-alist-pre-R)
3223                              dired-subdir-alist)
3224                       ;; subdir still present...
3225                       (setq subdirs
3226                             (cons (car dired-subdir-alist-pre-R)
3227                                   subdirs)))
3228                   (setq dired-subdir-alist-pre-R
3229                         (cdr dired-subdir-alist-pre-R)))
3230                 (reverse subdirs))
3231             ;; No pre-R subdir alist, so revert to main directory
3232             ;; listing:
3233             (list (car (reverse dired-subdir-alist))))))))
3234 \f
3235
3236 ;;;;  Drag and drop support
3237
3238 (defcustom dired-recursive-copies 'top
3239   "*Decide whether recursive copies are allowed.
3240 A value of nil means no recursive copies.
3241 `always' means copy recursively without asking.
3242 `top' means ask for each directory at top level.
3243 Anything else means ask for each directory."
3244   :type '(choice :tag "Copy directories"
3245                  (const :tag "No recursive copies" nil)
3246                  (const :tag "Ask for each directory" t)
3247                  (const :tag "Ask for each top directory only" top)
3248                  (const :tag "Copy directories without asking" always))
3249   :group 'dired)
3250
3251 (defun dired-dnd-popup-notice ()
3252   (message-box
3253    "Recursive copies not enabled.\nSee variable dired-recursive-copies."))
3254
3255
3256 (defun dired-dnd-do-ask-action (uri)
3257   ;; No need to get actions and descriptions from the source,
3258   ;; we only have three actions anyway.
3259   (let ((action (x-popup-menu
3260                  t
3261                  (list "What action?"
3262                        (cons ""
3263                              '(("Copy here" . copy)
3264                                ("Move here" . move)
3265                                ("Link here" . link)
3266                                "--"
3267                                ("Cancel" . nil)))))))
3268     (if action
3269         (dired-dnd-handle-local-file uri action)
3270       nil)))
3271
3272 (declare-function dired-relist-entry "dired-aux" (file))
3273 (declare-function make-symbolic-link "fileio.c")
3274
3275 (defun dired-dnd-handle-local-file (uri action)
3276   "Copy, move or link a file to the dired directory.
3277 URI is the file to handle, ACTION is one of copy, move, link or ask.
3278 Ask means pop up a menu for the user to select one of copy, move or link."
3279   (require 'dired-aux)
3280   (let* ((from (dnd-get-local-file-name uri t))
3281          (to (when from
3282                (concat (dired-current-directory)
3283                        (file-name-nondirectory from)))))
3284     (when from
3285       (cond ((eq action 'ask)
3286              (dired-dnd-do-ask-action uri))
3287             ;; If copying a directory and dired-recursive-copies is
3288             ;; nil, dired-copy-file fails.  Pop up a notice.
3289             ((and (memq action '(copy private))
3290                   (file-directory-p from)
3291                   (not dired-recursive-copies))
3292              (dired-dnd-popup-notice))
3293             ((memq action '(copy private move link))
3294              (let ((overwrite (and (file-exists-p to)
3295                                    (y-or-n-p
3296                                     (format "Overwrite existing file `%s'? " to))))
3297                    ;; Binding dired-overwrite-confirmed to nil makes
3298                    ;; dired-handle-overwrite a no-op.  We instead use
3299                    ;; y-or-n-p, which pops a graphical menu.
3300                    dired-overwrite-confirmed backup-file)
3301                (when (and overwrite
3302                           ;; d-b-o is defined in dired-aux.
3303                           (boundp 'dired-backup-overwrite)
3304                           dired-backup-overwrite
3305                           (setq backup-file
3306                                 (car (find-backup-file-name to)))
3307                           (or (eq dired-backup-overwrite 'always)
3308                               (y-or-n-p
3309                                (format
3310                                 "Make backup for existing file `%s'? " to))))
3311                  (rename-file to backup-file 0)
3312                  (dired-relist-entry backup-file))
3313                (cond ((memq action '(copy private))
3314                       (dired-copy-file from to overwrite))
3315                      ((eq action 'move)
3316                       (dired-rename-file from to overwrite))
3317                      ((eq action 'link)
3318                       (make-symbolic-link from to overwrite)))
3319                (dired-relist-entry to)
3320                action))))))
3321
3322 (defun dired-dnd-handle-file (uri action)
3323   "Copy, move or link a file to the dired directory if it is a local file.
3324 URI is the file to handle.  If the hostname in the URI isn't local, do nothing.
3325 ACTION is one of copy, move, link or ask.
3326 Ask means pop up a menu for the user to select one of copy, move or link."
3327   (let ((local-file (dnd-get-local-file-uri uri)))
3328     (if local-file (dired-dnd-handle-local-file local-file action)
3329       nil)))
3330 \f
3331
3332 ;;;;  Desktop support
3333
3334 (eval-when-compile (require 'desktop))
3335
3336 (defun dired-desktop-buffer-misc-data (desktop-dirname)
3337   "Auxiliary information to be saved in desktop file."
3338   (cons
3339    ;; Value of `dired-directory'.
3340    (if (consp dired-directory)
3341        ;; Directory name followed by list of files.
3342        (cons (desktop-file-name (car dired-directory) desktop-dirname)
3343              (cdr dired-directory))
3344      ;; Directory name, optionally with shell wildcard.
3345      (desktop-file-name dired-directory desktop-dirname))
3346    ;; Subdirectories in `dired-subdir-alist'.
3347    (cdr
3348      (nreverse
3349        (mapcar
3350          (function (lambda (f) (desktop-file-name (car f) desktop-dirname)))
3351          dired-subdir-alist)))))
3352
3353 (defun dired-restore-desktop-buffer (desktop-buffer-file-name
3354                                      desktop-buffer-name
3355                                      desktop-buffer-misc)
3356   "Restore a dired buffer specified in a desktop file."
3357   ;; First element of `desktop-buffer-misc' is the value of `dired-directory'.
3358   ;; This value is a directory name, optionally with shell wildcard or
3359   ;; a directory name followed by list of files.
3360   (let* ((dired-dir (car desktop-buffer-misc))
3361          (dir (if (consp dired-dir) (car dired-dir) dired-dir)))
3362     (if (file-directory-p (file-name-directory dir))
3363         (progn
3364           (dired dired-dir)
3365           ;; The following elements of `desktop-buffer-misc' are the keys
3366           ;; from `dired-subdir-alist'.
3367           (mapc 'dired-maybe-insert-subdir (cdr desktop-buffer-misc))
3368           (current-buffer))
3369       (message "Desktop: Directory %s no longer exists." dir)
3370       (when desktop-missing-file-warning (sit-for 1))
3371       nil)))
3372
3373 (add-to-list 'desktop-buffer-mode-handlers
3374              '(dired-mode . dired-restore-desktop-buffer))
3375
3376 \f
3377 (if (eq system-type 'vax-vms)
3378     (load "dired-vms"))
3379
3380 (provide 'dired)
3381
3382 (run-hooks 'dired-load-hook)            ; for your customizations
3383
3384 ;; arch-tag: e1af7a8f-691c-41a0-aac1-ddd4d3c87517
3385 ;;; dired.el ends here