lisp/resume.el

   1 ;;; resume.el --- process command line args from within a suspended Emacs job
   2
   3 ;; Author: Joe Wells <jbw@bucsf.bu.edu>
   4 ;; Last-Modified: Tue Jun 13 1989
   5 ;; Adapted-By: ESR
   6 ;; Keywords: processes
   7
   8 ;; Copyright (C) 1992 Free Software Foundation, Inc.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 1, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Theory: the first time you start Emacs, command line arguments are
  29 ;; handled normally.  Then, you suspend your emacs job.  When you want to edit
  30 ;; something else, you type "emacs filename" as usual, but instead of
  31 ;; starting a new emacs job, the old job is resumed instead, and the command
  32 ;; line arguments are placed in a file where the old emacs job looks for
  33 ;; them.
  34
  35 ;; Stephan Gildea suggested bug fix (gildea@bbn.com).
  36 ;; Ideas from Michael DeCorte and other people.
  37
  38 ;; For csh users, insert the following alias in your .cshrc file
  39 ;; (after removing the leading double semicolons, of course):
  40 ;;
  41 ;;# The following line could be just EMACS_CMD=emacs, but this depends on
  42 ;;# your site.
  43 ;;if (! $?EMACS_CMD) set EMACS_CMD=emacs
  44 ;;set JOBS_FILE=/tmp/jobs.$USER.$$
  45 ;;set ARGS_FILE=~/.emacs_args
  46 ;;set STOP_PATT='^\[[0-9]*\] *[ +-] Stopped ............ '
  47 ;;set SUNVIEW_CMD='emacstool -nw -f emacstool-init -f server-start'
  48 ;;set X_CMD=\'\''$EMACS_CMD -i -f server-start'
  49 ;;alias emacs \
  50 ;;' \\
  51 ;;   jobs >! "$JOBS_FILE" \\
  52 ;;   && grep "$STOP_PATT$EMACS_CMD" "$JOBS_FILE" >& /dev/null \\
  53 ;;   && echo `pwd` \!* >! "$ARGS_FILE" && ""fg %$EMACS_CMD \\
  54 ;;|| if (! -e ~/.emacs_server || -f ~/.emacs_server) set status=1 \\
  55 ;;   && emacsclient \!* \\
  56 ;;|| @ status=1 - $?DISPLAY && eval "$X_CMD -i \!* &" \\
  57 ;;|| @ status=1 - $?WINDOW_PARENT && eval "$SUNVIEW_CMD \!* &" \\
  58 ;;|| ""$EMACS_CMD -nw \!* \\
  59 ;;'
  60 ;;
  61 ;; The alias works as follows:
  62 ;; 1. If there is a suspended Emacs job that is a child of the
  63 ;; current shell, place its arguments in the ~/.emacs_args file and
  64 ;; resume it.
  65 ;; 2. Else if the ~/.emacs_server socket has been created, presume an
  66 ;; Emacs server is running and attempt to connect to it.  If no Emacs
  67 ;; server is listening on the socket, this will fail.
  68 ;; 3. Else if the DISPLAY environment variable is set, presume we are
  69 ;; running under X Windows and start a new GNU Emacs process in the
  70 ;; background as an X client.
  71 ;; 4. Else if the WINDOW_PARENT environment variable is set, presume we
  72 ;; are running under SunView and start an emacstool process in the
  73 ;; background.
  74 ;; 5. Else start a regular Emacs process.
  75 ;;
  76 ;; Notes:
  77 ;; The output of the "jobs" command is not piped directly into "grep"
  78 ;; because that would run the "jobs" command in a subshell.
  79 ;; Before resuming a suspended emacs, the current directory and all
  80 ;; command line arguments are placed in a file name ~/.emacs_args.
  81 ;; The "-nw" switch to Emacs means no windowing system.
  82
  83 ;; Insert this in your .emacs file:
  84 ;;(setq suspend-resume-hook 'resume-process-args)
  85 ;;(setq suspend-hook 'empty-args-file)
  86 ;;(autoload 'empty-args-file "resume")
  87 ;;(autoload 'resume-process-args "resume")
  88
  89 ;; Finally, put the rest in a file named "resume.el" in a lisp library
  90 ;; directory.
  91
  92 ;;; Code:
  93
  94 (defvar emacs-args-file (expand-file-name "~/.emacs_args")
  95   "*This file is where arguments are placed for a suspended emacs job.")
  96
  97 (defvar emacs-args-buffer " *Command Line Args*"
  98   "Buffer that is used by resume-process-args.")
  99
 100 (defun resume-process-args ()
 101   "This should be called from inside of suspend-resume-hook.  This
 102 grabs the contents of the file whose name is stored in
 103 emacs-args-file, and processes these arguments like command line
 104 options."
 105   (let ((start-buffer (current-buffer))
 106         (args-buffer (get-buffer-create emacs-args-buffer))
 107         length args)
 108     (unwind-protect
 109         (progn
 110           (set-buffer args-buffer)
 111           (erase-buffer)
 112           ;; get the contents of emacs-args-file
 113           (condition-case ()
 114               (let ((result (insert-file-contents emacs-args-file)))
 115                 (setq length (car (cdr result))))
 116             ;; the file doesn't exist, ergo no arguments
 117             (file-error
 118               (erase-buffer)
 119               (setq length 0)))
 120           (if (<= length 0)
 121               (setq args nil)
 122             ;; get the arguments from the buffer
 123             (goto-char (point-min))
 124             (while (not (eobp))
 125               (skip-chars-forward " \t\n")
 126               (let ((begin (point)))
 127                 (skip-chars-forward "^ \t\n")
 128                 (setq args (cons (buffer-substring begin (point)) args)))
 129               (skip-chars-forward " \t\n"))
 130             ;; arguments are now in reverse order
 131             (setq args (nreverse args))
 132             ;; make sure they're not read again
 133             (erase-buffer))
 134           (write-buffer-to-file (current-buffer) emacs-args-file)
 135           ;; if nothing was in buffer, args will be null
 136           (or (null args)
 137               (setq default-directory (file-name-as-directory (car args))
 138                     args (cdr args)))
 139           ;; actually process the arguments
 140           (command-line-1 args))
 141       ;; If the command line args don't result in a find-file, the
 142       ;; buffer will be left in args-buffer.  So we change back to the
 143       ;; original buffer.  The reason I don't just use
 144       ;; (let ((default-directory foo))
 145       ;;    (command-line-1 args))
 146       ;; in the context of the original buffer is because let does not
 147       ;; work properly with buffer-local variables.
 148       (if (eq (current-buffer) args-buffer)
 149           (set-buffer start-buffer)))))
 150
 151 (defun empty-args-file ()
 152   "This empties the contents of the file whose name is specified by
 153 emacs-args-file."
 154   (save-excursion
 155     (set-buffer (get-buffer-create emacs-args-buffer))
 156     (erase-buffer)
 157     (write-buffer-to-file (current-buffer) emacs-args-file)))
 158
 159 (defun write-buffer-to-file (buffer file)
 160   "Writes the contents of BUFFER into FILE, if permissions allow."
 161   (if (not (file-writable-p file))
 162       (error "No permission to write file %s" file))
 163   (save-excursion
 164     (set-buffer buffer)
 165     (clear-visited-file-modtime)
 166     (save-restriction
 167       (widen)
 168       (write-region (point-min) (point-max) file nil 'quiet))
 169     (set-buffer-modified-p nil)))
 170
 171 ;;; resume.el ends here