lisp/dired.el

   1 ;;; dired.el --- directory-browsing commands
   2
   3 ;; Copyright (C) 1985, 1986, 1992, 1993, 1994, 1995, 1996, 1997, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Maintainer: FSF
   8 ;; Keywords: files
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This is a major mode for directory browsing and editing.  It is
  30 ;; documented in the Emacs manual.
  31
  32 ;; Rewritten in 1990/1991 to add tree features, file marking and
  33 ;; sorting by Sebastian Kremer <sk@thp.uni-koeln.de>.
  34 ;; Finished up by rms in 1992.
  35
  36 ;;; Code:
  37
  38 ;;; Customizable variables
  39
  40 (defgroup dired nil
  41   "Directory editing."
  42   :link '(custom-manual "(emacs)Dired")
  43   :group 'files)
  44
  45 (defgroup dired-mark nil
  46   "Handling marks in Dired."
  47   :prefix "dired-"
  48   :group 'dired)
  49
  50
  51 ;;;###autoload
  52 (defcustom dired-listing-switches "-al"
  53   "*Switches passed to `ls' for Dired.  MUST contain the `l' option.
  54 May contain all other options that don't contradict `-l';
  55 may contain even `F', `b', `i' and `s'.  See also the variable
  56 `dired-ls-F-marks-symlinks' concerning the `F' switch.
  57 On systems such as MS-DOS and MS-Windows, which use `ls' emulation in Lisp,
  58 some of the `ls' switches are not supported; see the doc string of
  59 `insert-directory' in `ls-lisp.el' for more details."
  60   :type 'string
  61   :group 'dired)
  62
  63 (defvar dired-subdir-switches nil
  64   "If non-nil, switches passed to `ls' for inserting subdirectories.
  65 If nil, `dired-listing-switches' is used.")
  66
  67 ; Don't use absolute file names as /bin should be in any PATH and people
  68 ; may prefer /usr/local/gnu/bin or whatever.  However, chown is
  69 ; usually not in PATH.
  70
  71 ;;;###autoload
  72 (defvar dired-chown-program
  73   (if (memq system-type '(hpux dgux usg-unix-v irix linux gnu/linux cygwin))
  74       "chown"
  75     (if (file-exists-p "/usr/sbin/chown")
  76         "/usr/sbin/chown"
  77       "/etc/chown"))
  78   "Name of chown command (usually `chown' or `/etc/chown').")
  79
  80 (defvar dired-use-ls-dired (not (not (string-match "gnu" system-configuration)))
  81   "Non-nil means Dired should use `ls --dired'.")
  82
  83 (defvar dired-chmod-program "chmod"
  84   "Name of chmod command (usually `chmod').")
  85
  86 (defvar dired-touch-program "touch"
  87   "Name of touch command (usually `touch').")
  88
  89 ;;;###autoload
  90 (defcustom dired-ls-F-marks-symlinks nil
  91   "*Informs Dired about how `ls -lF' marks symbolic links.
  92 Set this to t if `ls' (or whatever program is specified by
  93 `insert-directory-program') with `-lF' marks the symbolic link
  94 itself with a trailing @ (usually the case under Ultrix).
  95
  96 Example: if `ln -s foo bar; ls -F bar' gives `bar -> foo', set it to
  97 nil (the default), if it gives `bar@ -> foo', set it to t.
  98
  99 Dired checks if there is really a @ appended.  Thus, if you have a
 100 marking `ls' program on one host and a non-marking on another host, and
 101 don't care about symbolic links which really end in a @, you can
 102 always set this variable to t."
 103   :type 'boolean
 104   :group 'dired-mark)
 105
 106 ;;;###autoload
 107 (defcustom dired-trivial-filenames "^\\.\\.?$\\|^#"
 108   "*Regexp of files to skip when finding first file of a directory.
 109 A value of nil means move to the subdir line.
 110 A value of t means move to first file."
 111   :type '(choice (const :tag "Move to subdir" nil)
 112                  (const :tag "Move to first" t)
 113                  regexp)
 114   :group 'dired)
 115
 116 ;;;###autoload
 117 (defcustom dired-keep-marker-rename t
 118   ;; Use t as default so that moved files "take their markers with them".
 119   "*Controls marking of renamed files.
 120 If t, files keep their previous marks when they are renamed.
 121 If a character, renamed files (whether previously marked or not)
 122 are afterward marked with that character."
 123   :type '(choice (const :tag "Keep" t)
 124                  (character :tag "Mark"))
 125   :group 'dired-mark)
 126
 127 ;;;###autoload
 128 (defcustom dired-keep-marker-copy ?C
 129   "*Controls marking of copied files.
 130 If t, copied files are marked if and as the corresponding original files were.
 131 If a character, copied files are unconditionally marked with that character."
 132   :type '(choice (const :tag "Keep" t)
 133                  (character :tag "Mark"))
 134   :group 'dired-mark)
 135
 136 ;;;###autoload
 137 (defcustom dired-keep-marker-hardlink ?H
 138   "*Controls marking of newly made hard links.
 139 If t, they are marked if and as the files linked to were marked.
 140 If a character, new links are unconditionally marked with that character."
 141   :type '(choice (const :tag "Keep" t)
 142                  (character :tag "Mark"))
 143   :group 'dired-mark)
 144
 145 ;;;###autoload
 146 (defcustom dired-keep-marker-symlink ?Y
 147   "*Controls marking of newly made symbolic links.
 148 If t, they are marked if and as the files linked to were marked.
 149 If a character, new links are unconditionally marked with that character."
 150   :type '(choice (const :tag "Keep" t)
 151                  (character :tag "Mark"))
 152   :group 'dired-mark)
 153
 154 ;;;###autoload
 155 (defcustom dired-dwim-target nil
 156   "*If non-nil, Dired tries to guess a default target directory.
 157 This means: if there is a dired buffer displayed in the next window,
 158 use its current subdir, instead of the current subdir of this dired buffer.
 159
 160 The target is used in the prompt for file copy, rename etc."
 161   :type 'boolean
 162   :group 'dired)
 163
 164 ;;;###autoload
 165 (defcustom dired-copy-preserve-time t
 166   "*If non-nil, Dired preserves the last-modified time in a file copy.
 167 \(This works on only some systems.)"
 168   :type 'boolean
 169   :group 'dired)
 170
 171 ; These variables were deleted and the replacements are on files.el.
 172 ; We leave aliases behind for back-compatibility.
 173 (defvaralias 'dired-free-space-program 'directory-free-space-program)
 174 (defvaralias 'dired-free-space-args 'directory-free-space-args)
 175
 176 ;;; Hook variables
 177
 178 (defcustom dired-load-hook nil
 179   "Run after loading Dired.
 180 You can customize key bindings or load extensions with this."
 181   :group 'dired
 182   :type 'hook)
 183
 184 (defcustom dired-mode-hook nil
 185   "Run at the very end of `dired-mode'."
 186   :group 'dired
 187   :type 'hook)
 188
 189 (defcustom dired-before-readin-hook nil
 190   "This hook is run before a dired buffer is read in (created or reverted)."
 191   :group 'dired
 192   :type 'hook)
 193
 194 (defcustom dired-after-readin-hook nil
 195   "Hook run after each time a file or directory is read by Dired.
 196 After each listing of a file or directory, this hook is run
 197 with the buffer narrowed to the listing."
 198   :group 'dired
 199   :type 'hook)
 200 ;; Note this can't simply be run inside function `dired-ls' as the hook
 201 ;; functions probably depend on the dired-subdir-alist to be OK.
 202
 203 (defcustom dired-dnd-protocol-alist
 204   '(("^file:///" . dired-dnd-handle-local-file)
 205     ("^file://"  . dired-dnd-handle-file)
 206     ("^file:"    . dired-dnd-handle-local-file))
 207   "The functions to call when a drop in `dired-mode' is made.
 208 See `dnd-protocol-alist' for more information.  When nil, behave
 209 as in other buffers.  Changing this option is effective only for
 210 new dired buffers."
 211   :type '(choice (repeat (cons (regexp) (function)))
 212                  (const :tag "Behave as in other buffers" nil))
 213   :version "22.1"
 214   :group 'dired)
 215
 216 ;; Internal variables
 217
 218 (defvar dired-marker-char ?*            ; the answer is 42
 219   ;; so that you can write things like
 220   ;; (let ((dired-marker-char ?X))
 221   ;;    ;; great code using X markers ...
 222   ;;    )
 223   ;; For example, commands operating on two sets of files, A and B.
 224   ;; Or marking files with digits 0-9.  This could implicate
 225   ;; concentric sets or an order for the marked files.
 226   ;; The code depends on dynamic scoping on the marker char.
 227   "In Dired, the current mark character.
 228 This is what the do-commands look for, and what the mark-commands store.")
 229
 230 (defvar dired-del-marker ?D
 231   "Character used to flag files for deletion.")
 232
 233 (defvar dired-shrink-to-fit t
 234 ;; I see no reason ever to make this nil -- rms.
 235 ;;  (> baud-rate search-slow-speed)
 236   "Non-nil means Dired shrinks the display buffer to fit the marked files.")
 237
 238 (defvar dired-flagging-regexp nil);; Last regexp used to flag files.
 239
 240 (defvar dired-file-version-alist)
 241
 242 ;;;###autoload
 243 (defvar dired-directory nil
 244   "The directory name or wildcard spec that this dired directory lists.
 245 Local to each dired buffer.  May be a list, in which case the car is the
 246 directory name and the cdr is the list of files to mention.
 247 The directory name must be absolute, but need not be fully expanded.")
 248
 249 (defvar dired-actual-switches nil
 250   "The value of `dired-listing-switches' used to make this buffer's text.")
 251
 252 (defvar dired-re-inode-size "[0-9 \t]*"
 253   "Regexp for optional initial inode and file size as made by `ls -i -s'.")
 254
 255 ;; These regexps must be tested at beginning-of-line, but are also
 256 ;; used to search for next matches, so neither omitting "^" nor
 257 ;; replacing "^" by "\n" (to make it slightly faster) will work.
 258
 259 (defvar dired-re-mark "^[^ \n]")
 260 ;; "Regexp matching a marked line.
 261 ;; Important: the match ends just after the marker."
 262 (defvar dired-re-maybe-mark "^. ")
 263 ;; The [^:] part after "d" and "l" is to avoid confusion with the
 264 ;; DOS/Windows-style drive letters in directory names, like in "d:/foo".
 265 (defvar dired-re-dir (concat dired-re-maybe-mark dired-re-inode-size "d[^:]"))
 266 (defvar dired-re-sym (concat dired-re-maybe-mark dired-re-inode-size "l[^:]"))
 267 (defvar dired-re-exe;; match ls permission string of an executable file
 268   (mapconcat (function
 269               (lambda (x)
 270                 (concat dired-re-maybe-mark dired-re-inode-size x)))
 271              '("-[-r][-w][xs][-r][-w].[-r][-w]."
 272                "-[-r][-w].[-r][-w][xs][-r][-w]."
 273                "-[-r][-w].[-r][-w].[-r][-w][xst]")
 274              "\\|"))
 275 (defvar dired-re-perms "[-bcdlps][-r][-w].[-r][-w].[-r][-w].")
 276 (defvar dired-re-dot "^.* \\.\\.?/?$")
 277
 278 ;; The subdirectory names in the next two lists are expanded.
 279 (defvar dired-subdir-alist nil
 280   "Association list of subdirectories and their buffer positions.
 281 Each subdirectory has an element: (DIRNAME . STARTMARKER).
 282 The order of elements is the reverse of the order in the buffer.
 283 In simple cases, this list contains one element.")
 284
 285 (defvar dired-switches-alist nil
 286   "Keeps track of which switches to use for inserted subdirectories.
 287 This is an alist of the form (SUBDIR . SWITCHES).")
 288 (make-variable-buffer-local 'dired-switches-alist)
 289
 290 (defvaralias 'dired-move-to-filename-regexp
 291   'directory-listing-before-filename-regexp)
 292
 293 (defvar dired-subdir-regexp "^. \\([^\n\r]+\\)\\(:\\)[\n\r]"
 294   "Regexp matching a maybe hidden subdirectory line in `ls -lR' output.
 295 Subexpression 1 is the subdirectory proper, no trailing colon.
 296 The match starts at the beginning of the line and ends after the end
 297 of the line (\\n or \\r).
 298 Subexpression 2 must end right before the \\n or \\r.")
 299
 300 (defgroup dired-faces nil
 301   "Faces used by Dired."
 302   :group 'dired
 303   :group 'faces)
 304
 305 (defface dired-header
 306   '((t (:inherit font-lock-type-face)))
 307   "Face used for directory headers."
 308   :group 'dired-faces
 309   :version "22.1")
 310 (defvar dired-header-face 'dired-header
 311   "Face name used for directory headers.")
 312
 313 (defface dired-mark
 314   '((t (:inherit font-lock-constant-face)))
 315   "Face used for dired marks."
 316   :group 'dired-faces
 317   :version "22.1")
 318 (defvar dired-mark-face 'dired-mark
 319   "Face name used for dired marks.")
 320
 321 (defface dired-marked
 322   '((t (:inherit font-lock-warning-face)))
 323   "Face used for marked files."
 324   :group 'dired-faces
 325   :version "22.1")
 326 (defvar dired-marked-face 'dired-marked
 327   "Face name used for marked files.")
 328
 329 (defface dired-flagged
 330   '((t (:inherit font-lock-warning-face)))
 331   "Face used for flagged files."
 332   :group 'dired-faces
 333   :version "22.1")
 334 (defvar dired-flagged-face 'dired-flagged
 335   "Face name used for flagged files.")
 336
 337 (defface dired-warning
 338   ;; Inherit from font-lock-warning-face since with min-colors 8
 339   ;; font-lock-comment-face is not colored any more.
 340   '((t (:inherit font-lock-warning-face)))
 341   "Face used to highlight a part of a buffer that needs user attention."
 342   :group 'dired-faces
 343   :version "22.1")
 344 (defvar dired-warning-face 'dired-warning
 345   "Face name used for a part of a buffer that needs user attention.")
 346
 347 (defface dired-warn-writable
 348   '((((type w32 pc)) :inherit default)  ;; These default to rw-rw-rw.
 349     (t (:inherit font-lock-warning-face)))
 350   "Face used to highlight permissions of group- and world-writable files."
 351   :group 'dired-faces
 352   :version "22.2")
 353 (defvar dired-warn-writable-face 'dired-warn-writable
 354   "Face name used for permissions of group- and world-writable files.")
 355
 356 (defface dired-directory
 357   '((t (:inherit font-lock-function-name-face)))
 358   "Face used for subdirectories."
 359   :group 'dired-faces
 360   :version "22.1")
 361 (defvar dired-directory-face 'dired-directory
 362   "Face name used for subdirectories.")
 363
 364 (defface dired-symlink
 365   '((t (:inherit font-lock-keyword-face)))
 366   "Face used for symbolic links."
 367   :group 'dired-faces
 368   :version "22.1")
 369 (defvar dired-symlink-face 'dired-symlink
 370   "Face name used for symbolic links.")
 371
 372 (defface dired-ignored
 373   '((t (:inherit shadow)))
 374   "Face used for files suffixed with `completion-ignored-extensions'."
 375   :group 'dired-faces
 376   :version "22.1")
 377 (defvar dired-ignored-face 'dired-ignored
 378   "Face name used for files suffixed with `completion-ignored-extensions'.")
 379
 380 (defvar dired-font-lock-keywords
 381   (list
 382    ;;
 383    ;; Directory headers.
 384    (list dired-subdir-regexp '(1 dired-header-face))
 385    ;;
 386    ;; Dired marks.
 387    (list dired-re-mark '(0 dired-mark-face))
 388    ;;
 389    ;; We make heavy use of MATCH-ANCHORED, since the regexps don't identify the
 390    ;; file name itself.  We search for Dired defined regexps, and then use the
 391    ;; Dired defined function `dired-move-to-filename' before searching for the
 392    ;; simple regexp ".+".  It is that regexp which matches the file name.
 393    ;;
 394    ;; Marked files.
 395    (list (concat "^[" (char-to-string dired-marker-char) "]")
 396          '(".+" (dired-move-to-filename) nil (0 dired-marked-face)))
 397    ;;
 398    ;; Flagged files.
 399    (list (concat "^[" (char-to-string dired-del-marker) "]")
 400          '(".+" (dired-move-to-filename) nil (0 dired-flagged-face)))
 401    ;; People who are paranoid about security would consider this more
 402    ;; important than other things such as whether it is a directory.
 403    ;; But we don't want to encourage paranoia, so our default
 404    ;; should be what's most useful for non-paranoids. -- rms.
 405 ;;;   ;;
 406 ;;;   ;; Files that are group or world writable.
 407 ;;;   (list (concat dired-re-maybe-mark dired-re-inode-size
 408 ;;;              "\\([-d]\\(....w....\\|.......w.\\)\\)")
 409 ;;;      '(1 dired-warning-face)
 410 ;;;      '(".+" (dired-move-to-filename) nil (0 dired-warning-face)))
 411    ;; However, we don't need to highlight the file name, only the
 412    ;; permissions, to win generally.  -- fx.
 413    ;; Fixme: we could also put text properties on the permission
 414    ;; fields with keymaps to frob the permissions, somewhat a la XEmacs.
 415    (list (concat dired-re-maybe-mark dired-re-inode-size
 416                  "[-d]....\\(w\\)....") ; group writable
 417          '(1 dired-warn-writable-face))
 418    (list (concat dired-re-maybe-mark dired-re-inode-size
 419                  "[-d].......\\(w\\).") ; world writable
 420          '(1 dired-warn-writable-face))
 421    ;;
 422    ;; Subdirectories.
 423    (list dired-re-dir
 424          '(".+" (dired-move-to-filename) nil (0 dired-directory-face)))
 425    ;;
 426    ;; Symbolic links.
 427    (list dired-re-sym
 428          '(".+" (dired-move-to-filename) nil (0 dired-symlink-face)))
 429    ;;
 430    ;; Files suffixed with `completion-ignored-extensions'.
 431    '(eval .
 432      ;; It is quicker to first find just an extension, then go back to the
 433      ;; start of that file name.  So we do this complex MATCH-ANCHORED form.
 434      (list (concat "\\(" (regexp-opt completion-ignored-extensions) "\\|#\\)$")
 435            '(".+" (dired-move-to-filename) nil (0 dired-ignored-face))))
 436    ;;
 437    ;; Files suffixed with `completion-ignored-extensions'
 438    ;; plus a character put in by -F.
 439    '(eval .
 440      (list (concat "\\(" (regexp-opt completion-ignored-extensions)
 441                    "\\|#\\)[*=|]$")
 442            '(".+" (progn
 443                     (end-of-line)
 444                     ;; If the last character is not part of the filename,
 445                     ;; move back to the start of the filename
 446                     ;; so it can be fontified.
 447                     ;; Otherwise, leave point at the end of the line;
 448                     ;; that way, nothing is fontified.
 449                     (unless (get-text-property (1- (point)) 'mouse-face)
 450                       (dired-move-to-filename)))
 451              nil (0 dired-ignored-face))))
 452 )
 453   "Additional expressions to highlight in Dired mode.")
 454
 455 (defvar dnd-protocol-alist)
 456 \f
 457 ;;; Macros must be defined before they are used, for the byte compiler.
 458
 459 (defmacro dired-mark-if (predicate msg)
 460   "Mark all files for which PREDICATE evals to non-nil.
 461 PREDICATE is evaluated on each line, with point at beginning of line.
 462 MSG is a noun phrase for the type of files being marked.
 463 It should end with a noun that can be pluralized by adding `s'.
 464 Return value is the number of files marked, or nil if none were marked."
 465   `(let (buffer-read-only count)
 466     (save-excursion
 467       (setq count 0)
 468       (if ,msg (message "Marking %ss..." ,msg))
 469       (goto-char (point-min))
 470       (while (not (eobp))
 471         (if ,predicate
 472             (progn
 473               (delete-char 1)
 474               (insert dired-marker-char)
 475               (setq count (1+ count))))
 476         (forward-line 1))
 477       (if ,msg (message "%s %s%s %s%s."
 478                         count
 479                         ,msg
 480                         (dired-plural-s count)
 481                         (if (eq dired-marker-char ?\040) "un" "")
 482                         (if (eq dired-marker-char dired-del-marker)
 483                             "flagged" "marked"))))
 484     (and (> count 0) count)))
 485
 486 (defmacro dired-map-over-marks (body arg &optional show-progress
 487                                      distinguish-one-marked)
 488   "Eval BODY with point on each marked line.  Return a list of BODY's results.
 489 If no marked file could be found, execute BODY on the current line.
 490   If ARG is an integer, use the next ARG (or previous -ARG, if ARG<0)
 491   files instead of the marked files.
 492   In that case point is dragged along.  This is so that commands on
 493   the next ARG (instead of the marked) files can be chained easily.
 494   If ARG is otherwise non-nil, use current file instead.
 495 If optional third arg SHOW-PROGRESS evaluates to non-nil,
 496   redisplay the dired buffer after each file is processed.
 497 No guarantee is made about the position on the marked line.
 498   BODY must ensure this itself if it depends on this.
 499 Search starts at the beginning of the buffer, thus the car of the list
 500   corresponds to the line nearest to the buffer's bottom.  This
 501   is also true for (positive and negative) integer values of ARG.
 502 BODY should not be too long as it is expanded four times.
 503
 504 If DISTINGUISH-ONE-MARKED is non-nil, then if we find just one marked file,
 505 return (t FILENAME) instead of (FILENAME)."
 506   ;;
 507   ;;Warning: BODY must not add new lines before point - this may cause an
 508   ;;endless loop.
 509   ;;This warning should not apply any longer, sk  2-Sep-1991 14:10.
 510   `(prog1
 511        (let (buffer-read-only case-fold-search found results)
 512          (if ,arg
 513              (if (integerp ,arg)
 514                  (progn ;; no save-excursion, want to move point.
 515                    (dired-repeat-over-lines
 516                     ,arg
 517                     (function (lambda ()
 518                                 (if ,show-progress (sit-for 0))
 519                                 (setq results (cons ,body results)))))
 520                    (if (< ,arg 0)
 521                        (nreverse results)
 522                      results))
 523                ;; non-nil, non-integer ARG means use current file:
 524                (list ,body))
 525            (let ((regexp (dired-marker-regexp)) next-position)
 526              (save-excursion
 527                (goto-char (point-min))
 528                ;; remember position of next marked file before BODY
 529                ;; can insert lines before the just found file,
 530                ;; confusing us by finding the same marked file again
 531                ;; and again and...
 532                (setq next-position (and (re-search-forward regexp nil t)
 533                                         (point-marker))
 534                      found (not (null next-position)))
 535                (while next-position
 536                  (goto-char next-position)
 537                  (if ,show-progress (sit-for 0))
 538                  (setq results (cons ,body results))
 539                  ;; move after last match
 540                  (goto-char next-position)
 541                  (forward-line 1)
 542                  (set-marker next-position nil)
 543                  (setq next-position (and (re-search-forward regexp nil t)
 544                                           (point-marker)))))
 545              (if (and ,distinguish-one-marked (= (length results) 1))
 546                  (setq results (cons t results)))
 547              (if found
 548                  results
 549                (list ,body)))))
 550      ;; save-excursion loses, again
 551      (dired-move-to-filename)))
 552
 553 (defun dired-get-marked-files (&optional localp arg filter distinguish-one-marked)
 554   "Return the marked files' names as list of strings.
 555 The list is in the same order as the buffer, that is, the car is the
 556   first marked file.
 557 Values returned are normally absolute file names.
 558 Optional arg LOCALP as in `dired-get-filename'.
 559 Optional second argument ARG specifies files near point
 560  instead of marked files.  If ARG is an integer, use the next ARG files.
 561   If ARG is otherwise non-nil, use file.  Usually ARG comes from
 562   the command's prefix arg.
 563 Optional third argument FILTER, if non-nil, is a function to select
 564   some of the files--those for which (funcall FILTER FILENAME) is non-nil.
 565
 566 If DISTINGUISH-ONE-MARKED is non-nil, then if we find just one marked file,
 567 return (t FILENAME) instead of (FILENAME).
 568 Don't use that together with FILTER."
 569   (let* ((all-of-them
 570           (save-excursion
 571             (dired-map-over-marks
 572              (dired-get-filename localp)
 573              arg nil distinguish-one-marked)))
 574          result)
 575     (if (not filter)
 576         (if (and distinguish-one-marked (eq (car all-of-them) t))
 577             all-of-them
 578           (nreverse all-of-them))
 579       (dolist (file all-of-them)
 580         (if (funcall filter file)
 581             (push file result)))
 582       result)))
 583 \f
 584 ;; The dired command
 585
 586 (defun dired-read-dir-and-switches (str)
 587   ;; For use in interactive.
 588   (reverse (list
 589             (if current-prefix-arg
 590                 (read-string "Dired listing switches: "
 591                              dired-listing-switches))
 592             ;; If a dialog is about to be used, call read-directory-name so
 593             ;; the dialog code knows we want directories.  Some dialogs can
 594             ;; only select directories or files when popped up, not both.
 595             (if (next-read-file-uses-dialog-p)
 596                 (read-directory-name (format "Dired %s(directory): " str)
 597                                      nil default-directory nil)
 598               (read-file-name (format "Dired %s(directory): " str)
 599                               nil default-directory nil)))))
 600
 601 ;;;###autoload (define-key ctl-x-map "d" 'dired)
 602 ;;;###autoload
 603 (defun dired (dirname &optional switches)
 604   "\"Edit\" directory DIRNAME--delete, rename, print, etc. some files in it.
 605 Optional second argument SWITCHES specifies the `ls' options used.
 606 \(Interactively, use a prefix argument to be able to specify SWITCHES.)
 607 Dired displays a list of files in DIRNAME (which may also have
 608 shell wildcards appended to select certain files).  If DIRNAME is a cons,
 609 its first element is taken as the directory name and the rest as an explicit
 610 list of files to make directory entries for.
 611 \\<dired-mode-map>\
 612 You can move around in it with the usual commands.
 613 You can flag files for deletion with \\[dired-flag-file-deletion] and then
 614 delete them by typing \\[dired-do-flagged-delete].
 615 Type \\[describe-mode] after entering Dired for more info.
 616
 617 If DIRNAME is already in a dired buffer, that buffer is used without refresh."
 618   ;; Cannot use (interactive "D") because of wildcards.
 619   (interactive (dired-read-dir-and-switches ""))
 620   (switch-to-buffer (dired-noselect dirname switches)))
 621
 622 ;;;###autoload (define-key ctl-x-4-map "d" 'dired-other-window)
 623 ;;;###autoload
 624 (defun dired-other-window (dirname &optional switches)
 625   "\"Edit\" directory DIRNAME.  Like `dired' but selects in another window."
 626   (interactive (dired-read-dir-and-switches "in other window "))
 627   (switch-to-buffer-other-window (dired-noselect dirname switches)))
 628
 629 ;;;###autoload (define-key ctl-x-5-map "d" 'dired-other-frame)
 630 ;;;###autoload
 631 (defun dired-other-frame (dirname &optional switches)
 632   "\"Edit\" directory DIRNAME.  Like `dired' but makes a new frame."
 633   (interactive (dired-read-dir-and-switches "in other frame "))
 634   (switch-to-buffer-other-frame (dired-noselect dirname switches)))
 635
 636 ;;;###autoload
 637 (defun dired-noselect (dir-or-list &optional switches)
 638   "Like `dired' but returns the dired buffer as value, does not select it."
 639   (or dir-or-list (setq dir-or-list default-directory))
 640   ;; This loses the distinction between "/foo/*/" and "/foo/*" that
 641   ;; some shells make:
 642   (let (dirname initially-was-dirname)
 643     (if (consp dir-or-list)
 644         (setq dirname (car dir-or-list))
 645       (setq dirname dir-or-list))
 646     (setq initially-was-dirname
 647           (string= (file-name-as-directory dirname) dirname))
 648     (setq dirname (abbreviate-file-name
 649                    (expand-file-name (directory-file-name dirname))))
 650     (if find-file-visit-truename
 651         (setq dirname (file-truename dirname)))
 652     ;; If the argument was syntactically  a directory name not a file name,
 653     ;; or if it happens to name a file that is a directory,
 654     ;; convert it syntactically to a directory name.
 655     ;; The reason for checking initially-was-dirname
 656     ;; and not just file-directory-p
 657     ;; is that file-directory-p is slow over ftp.
 658     (if (or initially-was-dirname (file-directory-p dirname))
 659         (setq dirname  (file-name-as-directory dirname)))
 660     (if (consp dir-or-list)
 661         (setq dir-or-list (cons dirname (cdr dir-or-list)))
 662       (setq dir-or-list dirname))
 663     (dired-internal-noselect dir-or-list switches)))
 664
 665 ;; The following is an internal dired function.  It returns non-nil if
 666 ;; the directory visited by the current dired buffer has changed on
 667 ;; disk.  DIRNAME should be the directory name of that directory.
 668 (defun dired-directory-changed-p (dirname)
 669   (not (let ((attributes (file-attributes dirname))
 670              (modtime (visited-file-modtime)))
 671          (or (eq modtime 0)
 672              (not (eq (car attributes) t))
 673              (equal (nth 5 attributes) modtime)))))
 674
 675 (defun dired-buffer-stale-p (&optional noconfirm)
 676   "Return non-nil if current dired buffer needs updating.
 677 If NOCONFIRM is non-nil, then this function always returns nil
 678 for a remote directory.  This feature is used by Auto Revert Mode."
 679   (let ((dirname
 680          (if (consp dired-directory) (car dired-directory) dired-directory)))
 681     (and (stringp dirname)
 682          (not (when noconfirm (file-remote-p dirname)))
 683          (file-readable-p dirname)
 684          (dired-directory-changed-p dirname))))
 685
 686 ;; Separate function from dired-noselect for the sake of dired-vms.el.
 687 (defun dired-internal-noselect (dir-or-list &optional switches mode)
 688   ;; If there is an existing dired buffer for DIRNAME, just leave
 689   ;; buffer as it is (don't even call dired-revert).
 690   ;; This saves time especially for deep trees or with ange-ftp.
 691   ;; The user can type `g' easily, and it is more consistent with find-file.
 692   ;; But if SWITCHES are given they are probably different from the
 693   ;; buffer's old value, so call dired-sort-other, which does
 694   ;; revert the buffer.
 695   ;; A pity we can't possibly do "Directory has changed - refresh? "
 696   ;; like find-file does.
 697   ;; Optional argument MODE is passed to dired-find-buffer-nocreate,
 698   ;; see there.
 699   (let* (dirname
 700          buffer
 701          ;; note that buffer already is in dired-mode, if found
 702          new-buffer-p
 703          (old-buf (current-buffer)))
 704     (if (consp dir-or-list)
 705         (setq dirname (car dir-or-list))
 706       (setq dirname dir-or-list))
 707     ;; Look for an existing buffer.
 708     (setq buffer (dired-find-buffer-nocreate dirname mode)
 709           new-buffer-p (null buffer))
 710     (or buffer
 711         (let ((default-major-mode 'fundamental-mode))
 712           ;; We don't want default-major-mode to run hooks and set auto-fill
 713           ;; or whatever, now that dired-mode does not
 714           ;; kill-all-local-variables any longer.
 715           (setq buffer (create-file-buffer (directory-file-name dirname)))))
 716     (set-buffer buffer)
 717     (if (not new-buffer-p)              ; existing buffer ...
 718         (cond (switches                 ; ... but new switches
 719                ;; file list may have changed
 720                (setq dired-directory dir-or-list)
 721                ;; this calls dired-revert
 722                (dired-sort-other switches))
 723               ;; If directory has changed on disk, offer to revert.
 724               ((when (dired-directory-changed-p dirname)
 725                  (message "%s"
 726                           (substitute-command-keys
 727                            "Directory has changed on disk; type \\[revert-buffer] to update Dired")))))
 728       ;; Else a new buffer
 729       (setq default-directory
 730             ;; We can do this unconditionally
 731             ;; because dired-noselect ensures that the name
 732             ;; is passed in directory name syntax
 733             ;; if it was the name of a directory at all.
 734             (file-name-directory dirname))
 735       (or switches (setq switches dired-listing-switches))
 736       (if mode (funcall mode)
 737         (dired-mode dir-or-list switches))
 738       ;; default-directory and dired-actual-switches are set now
 739       ;; (buffer-local), so we can call dired-readin:
 740       (let ((failed t))
 741         (unwind-protect
 742             (progn (dired-readin)
 743                    (setq failed nil))
 744           ;; dired-readin can fail if parent directories are inaccessible.
 745           ;; Don't leave an empty buffer around in that case.
 746           (if failed (kill-buffer buffer))))
 747       (goto-char (point-min))
 748       (dired-initial-position dirname))
 749     (set-buffer old-buf)
 750     buffer))
 751
 752 (defvar dired-buffers nil
 753   ;; Enlarged by dired-advertise
 754   ;; Queried by function dired-buffers-for-dir. When this detects a
 755   ;; killed buffer, it is removed from this list.
 756   "Alist of expanded directories and their associated dired buffers.")
 757
 758 (defun dired-find-buffer-nocreate (dirname &optional mode)
 759   ;; This differs from dired-buffers-for-dir in that it does not consider
 760   ;; subdirs of default-directory and searches for the first match only.
 761   ;; Also, the major mode must be MODE.
 762   (setq dirname (expand-file-name dirname))
 763   (let (found (blist dired-buffers))    ; was (buffer-list)
 764     (or mode (setq mode 'dired-mode))
 765     (while blist
 766       (if (null (buffer-name (cdr (car blist))))
 767           (setq blist (cdr blist))
 768         (save-excursion
 769           (set-buffer (cdr (car blist)))
 770           (if (and (eq major-mode mode)
 771                    dired-directory  ;; nil during find-alternate-file
 772                    (equal dirname
 773                           (expand-file-name
 774                            (if (consp dired-directory)
 775                                (car dired-directory)
 776                              dired-directory))))
 777               (setq found (cdr (car blist))
 778                     blist nil)
 779             (setq blist (cdr blist))))))
 780     found))
 781
 782 \f
 783 ;; Read in a new dired buffer
 784
 785 (defun dired-readin ()
 786   "Read in a new dired buffer.
 787 Differs from `dired-insert-subdir' in that it accepts
 788 wildcards, erases the buffer, and builds the subdir-alist anew
 789 \(including making it buffer-local and clearing it first)."
 790
 791   ;; default-directory and dired-actual-switches must be buffer-local
 792   ;; and initialized by now.
 793   (let (dirname)
 794     (if (consp dired-directory)
 795         (setq dirname (car dired-directory))
 796       (setq dirname dired-directory))
 797     (setq dirname (expand-file-name dirname))
 798     (save-excursion
 799       ;; This hook which may want to modify dired-actual-switches
 800       ;; based on dired-directory, e.g. with ange-ftp to a SysV host
 801       ;; where ls won't understand -Al switches.
 802       (run-hooks 'dired-before-readin-hook)
 803       (if (consp buffer-undo-list)
 804           (setq buffer-undo-list nil))
 805       (make-local-variable 'file-name-coding-system)
 806       (setq file-name-coding-system
 807             (or coding-system-for-read file-name-coding-system))
 808       (let (buffer-read-only
 809             ;; Don't make undo entries for readin.
 810             (buffer-undo-list t))
 811         (widen)
 812         (erase-buffer)
 813         (dired-readin-insert))
 814       (goto-char (point-min))
 815       ;; Must first make alist buffer local and set it to nil because
 816       ;; dired-build-subdir-alist will call dired-clear-alist first
 817       (set (make-local-variable 'dired-subdir-alist) nil)
 818       (dired-build-subdir-alist)
 819       (let ((attributes (file-attributes dirname)))
 820         (if (eq (car attributes) t)
 821             (set-visited-file-modtime (nth 5 attributes))))
 822       (set-buffer-modified-p nil)
 823       ;; No need to narrow since the whole buffer contains just
 824       ;; dired-readin's output, nothing else.  The hook can
 825       ;; successfully use dired functions (e.g. dired-get-filename)
 826       ;; as the subdir-alist has been built in dired-readin.
 827       (run-hooks 'dired-after-readin-hook))))
 828
 829 ;; Subroutines of dired-readin
 830
 831 (defun dired-readin-insert ()
 832   ;; Insert listing for the specified dir (and maybe file list)
 833   ;; already in dired-directory, assuming a clean buffer.
 834   (let (dir file-list)
 835     (if (consp dired-directory)
 836         (setq dir (car dired-directory)
 837               file-list (cdr dired-directory))
 838       (setq dir dired-directory
 839             file-list nil))
 840     (setq dir (expand-file-name dir))
 841     (if (and (equal "" (file-name-nondirectory dir))
 842              (not file-list))
 843         ;; If we are reading a whole single directory...
 844         (dired-insert-directory dir dired-actual-switches nil nil t)
 845       (if (not (file-readable-p
 846                 (directory-file-name (file-name-directory dir))))
 847           (error "Directory %s inaccessible or nonexistent" dir)
 848         ;; Else treat it as a wildcard spec
 849         ;; unless we have an explicit list of files.
 850         (dired-insert-directory dir dired-actual-switches
 851                                 file-list (not file-list) t)))))
 852
 853 (defun dired-align-file (beg end)
 854   "Align the fields of a file to the ones of surrounding lines.
 855 BEG..END is the line where the file info is located."
 856   ;; Some versions of ls try to adjust the size of each field so as to just
 857   ;; hold the largest element ("largest" in the current invocation, of
 858   ;; course).  So when a single line is output, the size of each field is
 859   ;; just big enough for that one output.  Thus when dired refreshes one
 860   ;; line, the alignment if this line w.r.t the rest is messed up because
 861   ;; the fields of that one line will generally be smaller.
 862   ;;
 863   ;; To work around this problem, we here add spaces to try and
 864   ;; re-align the fields as needed.  Since this is purely aesthetic,
 865   ;; it is of utmost importance that it doesn't mess up anything like
 866   ;; `dired-move-to-filename'.  To this end, we limit ourselves to
 867   ;; adding spaces only, and to only add them at places where there
 868   ;; was already at least one space.  This way, as long as
 869   ;; `directory-listing-before-filename-regexp' always matches spaces
 870   ;; with "*" or "+", we know we haven't made anything worse.  There
 871   ;; is one spot where the exact number of spaces is important, which
 872   ;; is just before the actual filename, so we refrain from adding
 873   ;; spaces there (and within the filename as well, of course).
 874   (save-excursion
 875     (let (file file-col other other-col)
 876       ;; Check the there is indeed a file, and that there is anoter adjacent
 877       ;; file with which to align, and that additional spaces are needed to
 878       ;; align the filenames.
 879       (when (and (setq file (progn (goto-char beg)
 880                                    (dired-move-to-filename nil end)))
 881                  (setq file-col (current-column))
 882                  (setq other
 883                        (or (and (goto-char beg)
 884                                 (zerop (forward-line -1))
 885                                 (dired-move-to-filename))
 886                            (and (goto-char beg)
 887                                 (zerop (forward-line 1))
 888                                 (dired-move-to-filename))))
 889                  (setq other-col (current-column))
 890                  (/= file other)
 891                  ;; Make sure there is some work left to do.
 892                  (> other-col file-col))
 893         ;; If we've only looked at the line above, check to see if the line
 894         ;; below exists as well and if so, align with the shorter one.
 895         (when (and (< other file)
 896                    (goto-char beg)
 897                    (zerop (forward-line 1))
 898                    (dired-move-to-filename))
 899           (let ((alt-col (current-column)))
 900             (when (< alt-col other-col)
 901               (setq other-col alt-col)
 902               (setq other (point)))))
 903         ;; Keep positions uptodate when we insert stuff.
 904         (if (> other file) (setq other (copy-marker other)))
 905         (setq file (copy-marker file))
 906         ;; Main loop.
 907         (goto-char beg)
 908         (skip-chars-forward " ")        ;Skip to the first field.
 909         (while (and (> other-col file-col)
 910                     ;; Don't touch anything just before (and after) the
 911                     ;; beginning of the filename.
 912                     (> file (point)))
 913           ;; We're now just in front of a field, with a space behind us.
 914           (let* ((curcol (current-column))
 915                  ;; Nums are right-aligned.
 916                  (num-align (looking-at "[0-9]"))
 917                  ;; Let's look at the other line, in the same column: we
 918                  ;; should be either near the end of the previous field, or
 919                  ;; in the space between that field and the next.
 920                  ;; [ Of course, it's also possible that we're already within
 921                  ;; the next field or even past it, but that's unlikely since
 922                  ;; other-col > file-col. ]
 923                  ;; Let's find the distance to the alignment-point (either
 924                  ;; the beginning or the end of the next field, depending on
 925                  ;; whether this field is left or right aligned).
 926                  (align-pt-offset
 927                   (save-excursion
 928                     (goto-char other)
 929                     (move-to-column curcol)
 930                     (when (looking-at
 931                            (concat
 932                             (if (eq (char-before) ?\s) " *" "[^ ]* *")
 933                             (if num-align "[0-9][^ ]*")))
 934                       (- (match-end 0) (match-beginning 0)))))
 935                  ;; Now, the number of spaces to insert is align-pt-offset
 936                  ;; minus the distance to the equivalent point on the
 937                  ;; current line.
 938                  (spaces
 939                   (if (not num-align)
 940                       align-pt-offset
 941                     (and align-pt-offset
 942                          (save-excursion
 943                            (skip-chars-forward "^ ")
 944                            (- align-pt-offset (- (current-column) curcol)))))))
 945             (when (and spaces (> spaces 0))
 946               (setq file-col (+ spaces file-col))
 947               (if (> file-col other-col)
 948                   (setq spaces (- spaces (- file-col other-col))))
 949               (insert-char ?\s spaces)
 950               ;; Let's just make really sure we did not mess up.
 951               (unless (save-excursion
 952                         (eq (dired-move-to-filename) (marker-position file)))
 953                 ;; Damn!  We messed up: let's revert the change.
 954                 (delete-char (- spaces)))))
 955           ;; Now skip to next field.
 956           (skip-chars-forward "^ ") (skip-chars-forward " "))
 957         (set-marker file nil)))))
 958
 959
 960 (defun dired-insert-directory (dir switches &optional file-list wildcard hdr)
 961   "Insert a directory listing of DIR, Dired style.
 962 Use SWITCHES to make the listings.
 963 If FILE-LIST is non-nil, list only those files.
 964 Otherwise, if WILDCARD is non-nil, expand wildcards;
 965  in that case, DIR should be a file name that uses wildcards.
 966 In other cases, DIR should be a directory name or a directory filename.
 967 If HDR is non-nil, insert a header line with the directory name."
 968   (let ((opoint (point))
 969         (process-environment (copy-sequence process-environment))
 970         end)
 971     (if (or dired-use-ls-dired (file-remote-p dir))
 972         (setq switches (concat "--dired " switches)))
 973     ;; We used to specify the C locale here, to force English month names;
 974     ;; but this should not be necessary any more,
 975     ;; with the new value of `directory-listing-before-filename-regexp'.
 976     (if file-list
 977         (dolist (f file-list)
 978           (let ((beg (point)))
 979             (insert-directory f switches nil nil)
 980             ;; Re-align fields, if necessary.
 981             (dired-align-file beg (point))))
 982       (insert-directory dir switches wildcard (not wildcard)))
 983     ;; Quote certain characters, unless ls quoted them for us.
 984     (if (not (string-match "b" dired-actual-switches))
 985         (save-excursion
 986           (setq end (point-marker))
 987           (goto-char opoint)
 988           (while (search-forward "\\" end t)
 989             (replace-match (apply #'propertize
 990                                   "\\\\"
 991                                   (text-properties-at (match-beginning 0)))
 992                            nil t))
 993           (goto-char opoint)
 994           (while (search-forward "\^m" end t)
 995             (replace-match (apply #'propertize
 996                                   "\\015"
 997                                   (text-properties-at (match-beginning 0)))
 998                            nil t))
 999           (set-marker end nil)))
1000     (dired-insert-set-properties opoint (point))
1001     ;; If we used --dired and it worked, the lines are already indented.
1002     ;; Otherwise, indent them.
1003     (unless (save-excursion
1004               (goto-char opoint)
1005               (looking-at "  "))
1006       (let ((indent-tabs-mode nil))
1007         (indent-rigidly opoint (point) 2)))
1008     ;; Insert text at the beginning to standardize things.
1009     (save-excursion
1010       (goto-char opoint)
1011       (if (and (or hdr wildcard) (not (looking-at "^  /.*:$")))
1012           ;; Note that dired-build-subdir-alist will replace the name
1013           ;; by its expansion, so it does not matter whether what we insert
1014           ;; here is fully expanded, but it should be absolute.
1015           (insert "  " (directory-file-name (file-name-directory dir)) ":\n"))
1016       (when wildcard
1017         ;; Insert "wildcard" line where "total" line would be for a full dir.
1018         (insert "  wildcard " (file-name-nondirectory dir) "\n")))))
1019
1020 (defun dired-insert-set-properties (beg end)
1021   "Make the file names highlight when the mouse is on them."
1022   (save-excursion
1023     (goto-char beg)
1024     (while (< (point) end)
1025       (condition-case nil
1026           (if (dired-move-to-filename)
1027               (add-text-properties
1028                (point)
1029                (save-excursion
1030                  (dired-move-to-end-of-filename)
1031                  (point))
1032                '(mouse-face highlight
1033                  help-echo "mouse-2: visit this file in other window")))
1034         (error nil))
1035       (forward-line 1))))
1036 \f
1037 ;; Reverting a dired buffer
1038
1039 (defun dired-revert (&optional arg noconfirm)
1040   "Reread the dired buffer.
1041 Must also be called after `dired-actual-switches' have changed.
1042 Should not fail even on completely garbaged buffers.
1043 Preserves old cursor, marks/flags, hidden-p."
1044   (widen)                               ; just in case user narrowed
1045   (let ((modflag (buffer-modified-p))
1046         (opoint (point))
1047         (ofile (dired-get-filename nil t))
1048         (mark-alist nil)                ; save marked files
1049         (hidden-subdirs (dired-remember-hidden))
1050         (old-subdir-alist (cdr (reverse dired-subdir-alist))) ; except pwd
1051         (case-fold-search nil)          ; we check for upper case ls flags
1052         buffer-read-only)
1053     (goto-char (point-min))
1054     (setq mark-alist;; only after dired-remember-hidden since this unhides:
1055           (dired-remember-marks (point-min) (point-max)))
1056     ;; treat top level dir extra (it may contain wildcards)
1057     (dired-uncache
1058      (if (consp dired-directory) (car dired-directory) dired-directory))
1059     ;; Run dired-after-readin-hook just once, below.
1060     (let ((dired-after-readin-hook nil))
1061       (dired-readin)
1062       (dired-insert-old-subdirs old-subdir-alist))
1063     (dired-mark-remembered mark-alist)  ; mark files that were marked
1064     ;; ... run the hook for the whole buffer, and only after markers
1065     ;; have been reinserted (else omitting in dired-x would omit marked files)
1066     (run-hooks 'dired-after-readin-hook)        ; no need to narrow
1067     (or (and ofile (dired-goto-file ofile)) ; move cursor to where it
1068         (goto-char opoint))             ; was before
1069     (dired-move-to-filename)
1070     (save-excursion                     ; hide subdirs that were hidden
1071       (dolist (dir hidden-subdirs)
1072         (if (dired-goto-subdir dir)
1073             (dired-hide-subdir 1))))
1074     (unless modflag (restore-buffer-modified-p nil)))
1075   ;; outside of the let scope
1076 ;;;  Might as well not override the user if the user changed this.
1077 ;;;  (setq buffer-read-only t)
1078   )
1079
1080 ;; Subroutines of dired-revert
1081 ;; Some of these are also used when inserting subdirs.
1082
1083 (defun dired-remember-marks (beg end)
1084   "Return alist of files and their marks, from BEG to END."
1085   (if selective-display                 ; must unhide to make this work.
1086       (let (buffer-read-only)
1087         (subst-char-in-region beg end ?\r ?\n)))
1088   (let (fil chr alist)
1089     (save-excursion
1090       (goto-char beg)
1091       (while (re-search-forward dired-re-mark end t)
1092         (if (setq fil (dired-get-filename nil t))
1093             (setq chr (preceding-char)
1094                   alist (cons (cons fil chr) alist)))))
1095     alist))
1096
1097 (defun dired-mark-remembered (alist)
1098   "Mark all files remembered in ALIST.
1099 Each element of ALIST looks like (FILE . MARKERCHAR)."
1100   (let (elt fil chr)
1101     (while alist
1102       (setq elt (car alist)
1103             alist (cdr alist)
1104             fil (car elt)
1105             chr (cdr elt))
1106       (if (dired-goto-file fil)
1107           (save-excursion
1108             (beginning-of-line)
1109             (delete-char 1)
1110             (insert chr))))))
1111
1112 (defun dired-remember-hidden ()
1113   "Return a list of names of subdirs currently hidden."
1114   (let ((l dired-subdir-alist) dir pos result)
1115     (while l
1116       (setq dir (car (car l))
1117             pos (cdr (car l))
1118             l (cdr l))
1119       (goto-char pos)
1120       (skip-chars-forward "^\r\n")
1121       (if (eq (following-char) ?\r)
1122           (setq result (cons dir result))))
1123     result))
1124
1125 (defun dired-insert-old-subdirs (old-subdir-alist)
1126   "Try to insert all subdirs that were displayed before.
1127 Do so according to the former subdir alist OLD-SUBDIR-ALIST."
1128   (or (string-match "R" dired-actual-switches)
1129       (let (elt dir)
1130         (while old-subdir-alist
1131           (setq elt (car old-subdir-alist)
1132                 old-subdir-alist (cdr old-subdir-alist)
1133                 dir (car elt))
1134           (condition-case ()
1135               (progn
1136                 (dired-uncache dir)
1137                 (dired-insert-subdir dir))
1138             (error nil))))))
1139
1140 (defun dired-uncache (dir)
1141   "Remove directory DIR from any directory cache."
1142   (let ((handler (find-file-name-handler dir 'dired-uncache)))
1143     (if handler
1144         (funcall handler 'dired-uncache dir))))
1145 \f
1146 ;; dired mode key bindings and initialization
1147
1148 (defvar dired-mode-map
1149   ;; This looks ugly when substitute-command-keys uses C-d instead d:
1150   ;;  (define-key dired-mode-map "\C-d" 'dired-flag-file-deletion)
1151   (let ((map (make-keymap)))
1152     (suppress-keymap map)
1153     (define-key map [mouse-2] 'dired-mouse-find-file-other-window)
1154     (define-key map [follow-link] 'mouse-face)
1155     ;; Commands to mark or flag certain categories of files
1156     (define-key map "#" 'dired-flag-auto-save-files)
1157     (define-key map "." 'dired-clean-directory)
1158     (define-key map "~" 'dired-flag-backup-files)
1159     (define-key map "&" 'dired-flag-garbage-files)
1160     ;; Upper case keys (except !) for operating on the marked files
1161     (define-key map "A" 'dired-do-search)
1162     (define-key map "C" 'dired-do-copy)
1163     (define-key map "B" 'dired-do-byte-compile)
1164     (define-key map "D" 'dired-do-delete)
1165     (define-key map "G" 'dired-do-chgrp)
1166     (define-key map "H" 'dired-do-hardlink)
1167     (define-key map "L" 'dired-do-load)
1168     (define-key map "M" 'dired-do-chmod)
1169     (define-key map "O" 'dired-do-chown)
1170     (define-key map "P" 'dired-do-print)
1171     (define-key map "Q" 'dired-do-query-replace-regexp)
1172     (define-key map "R" 'dired-do-rename)
1173     (define-key map "S" 'dired-do-symlink)
1174     (define-key map "T" 'dired-do-touch)
1175     (define-key map "X" 'dired-do-shell-command)
1176     (define-key map "Z" 'dired-do-compress)
1177     (define-key map "!" 'dired-do-shell-command)
1178     ;; Comparison commands
1179     (define-key map "=" 'dired-diff)
1180     (define-key map "\M-=" 'dired-backup-diff)
1181     ;; Tree Dired commands
1182     (define-key map "\M-\C-?" 'dired-unmark-all-files)
1183     (define-key map "\M-\C-d" 'dired-tree-down)
1184     (define-key map "\M-\C-u" 'dired-tree-up)
1185     (define-key map "\M-\C-n" 'dired-next-subdir)
1186     (define-key map "\M-\C-p" 'dired-prev-subdir)
1187     ;; move to marked files
1188     (define-key map "\M-{" 'dired-prev-marked-file)
1189     (define-key map "\M-}" 'dired-next-marked-file)
1190     ;; Make all regexp commands share a `%' prefix:
1191     ;; We used to get to the submap via a symbol dired-regexp-prefix,
1192     ;; but that seems to serve little purpose, and copy-keymap
1193     ;; does a better job without it.
1194     (define-key map "%" nil)
1195     (define-key map "%u" 'dired-upcase)
1196     (define-key map "%l" 'dired-downcase)
1197     (define-key map "%d" 'dired-flag-files-regexp)
1198     (define-key map "%g" 'dired-mark-files-containing-regexp)
1199     (define-key map "%m" 'dired-mark-files-regexp)
1200     (define-key map "%r" 'dired-do-rename-regexp)
1201     (define-key map "%C" 'dired-do-copy-regexp)
1202     (define-key map "%H" 'dired-do-hardlink-regexp)
1203     (define-key map "%R" 'dired-do-rename-regexp)
1204     (define-key map "%S" 'dired-do-symlink-regexp)
1205     ;; Commands for marking and unmarking.
1206     (define-key map "*" nil)
1207     (define-key map "**" 'dired-mark-executables)
1208     (define-key map "*/" 'dired-mark-directories)
1209     (define-key map "*@" 'dired-mark-symlinks)
1210     (define-key map "*%" 'dired-mark-files-regexp)
1211     (define-key map "*c" 'dired-change-marks)
1212     (define-key map "*s" 'dired-mark-subdir-files)
1213     (define-key map "*m" 'dired-mark)
1214     (define-key map "*u" 'dired-unmark)
1215     (define-key map "*?" 'dired-unmark-all-files)
1216     (define-key map "*!" 'dired-unmark-all-marks)
1217     (define-key map "U" 'dired-unmark-all-marks)
1218     (define-key map "*\177" 'dired-unmark-backward)
1219     (define-key map "*\C-n" 'dired-next-marked-file)
1220     (define-key map "*\C-p" 'dired-prev-marked-file)
1221     (define-key map "*t" 'dired-toggle-marks)
1222     ;; Lower keys for commands not operating on all the marked files
1223     (define-key map "a" 'dired-find-alternate-file)
1224     (define-key map "d" 'dired-flag-file-deletion)
1225     (define-key map "e" 'dired-find-file)
1226     (define-key map "f" 'dired-find-file)
1227     (define-key map "\C-m" 'dired-advertised-find-file)
1228     (define-key map "g" 'revert-buffer)
1229     (define-key map "h" 'describe-mode)
1230     (define-key map "i" 'dired-maybe-insert-subdir)
1231     (define-key map "j" 'dired-goto-file)
1232     (define-key map "k" 'dired-do-kill-lines)
1233     (define-key map "l" 'dired-do-redisplay)
1234     (define-key map "m" 'dired-mark)
1235     (define-key map "n" 'dired-next-line)
1236     (define-key map "o" 'dired-find-file-other-window)
1237     (define-key map "\C-o" 'dired-display-file)
1238     (define-key map "p" 'dired-previous-line)
1239     (define-key map "q" 'quit-window)
1240     (define-key map "s" 'dired-sort-toggle-or-edit)
1241     (define-key map "t" 'dired-toggle-marks)
1242     (define-key map "u" 'dired-unmark)
1243     (define-key map "v" 'dired-view-file)
1244     (define-key map "w" 'dired-copy-filename-as-kill)
1245     (define-key map "x" 'dired-do-flagged-delete)
1246     (define-key map "y" 'dired-show-file-type)
1247     (define-key map "+" 'dired-create-directory)
1248     ;; moving
1249     (define-key map "<" 'dired-prev-dirline)
1250     (define-key map ">" 'dired-next-dirline)
1251     (define-key map "^" 'dired-up-directory)
1252     (define-key map " "  'dired-next-line)
1253     (define-key map "\C-n" 'dired-next-line)
1254     (define-key map "\C-p" 'dired-previous-line)
1255     (define-key map [down] 'dired-next-line)
1256     (define-key map [up] 'dired-previous-line)
1257     ;; hiding
1258     (define-key map "$" 'dired-hide-subdir)
1259     (define-key map "\M-$" 'dired-hide-all)
1260     ;; misc
1261     (define-key map "\C-x\C-q" 'dired-toggle-read-only)
1262     (define-key map "?" 'dired-summary)
1263     (define-key map "\177" 'dired-unmark-backward)
1264     (define-key map [remap undo] 'dired-undo)
1265     (define-key map [remap advertised-undo] 'dired-undo)
1266     ;; thumbnail manipulation (image-dired)
1267     (define-key map "\C-td" 'image-dired-display-thumbs)
1268     (define-key map "\C-tt" 'image-dired-tag-files)
1269     (define-key map "\C-tr" 'image-dired-delete-tag)
1270     (define-key map "\C-tj" 'image-dired-jump-thumbnail-buffer)
1271     (define-key map "\C-ti" 'image-dired-dired-display-image)
1272     (define-key map "\C-tx" 'image-dired-dired-display-external)
1273     (define-key map "\C-ta" 'image-dired-display-thumbs-append)
1274     (define-key map "\C-t." 'image-dired-display-thumb)
1275     (define-key map "\C-tc" 'image-dired-dired-comment-files)
1276     (define-key map "\C-tf" 'image-dired-mark-tagged-files)
1277     (define-key map "\C-t\C-t" 'image-dired-dired-insert-marked-thumbs)
1278     (define-key map "\C-te" 'image-dired-dired-edit-comment-and-tags)
1279
1280     ;; Make menu bar items.
1281
1282     ;; No need to fo this, now that top-level items are fewer.
1283     ;;;;
1284     ;; Get rid of the Edit menu bar item to save space.
1285     ;(define-key map [menu-bar edit] 'undefined)
1286
1287     (define-key map [menu-bar subdir]
1288       (cons "Subdir" (make-sparse-keymap "Subdir")))
1289
1290     (define-key map [menu-bar subdir hide-all]
1291       '(menu-item "Hide All" dired-hide-all
1292                   :help "Hide all subdirectories, leave only header lines"))
1293     (define-key map [menu-bar subdir hide-subdir]
1294       '(menu-item "Hide/UnHide Subdir" dired-hide-subdir
1295                   :help "Hide or unhide current directory listing"))
1296     (define-key map [menu-bar subdir tree-down]
1297       '(menu-item "Tree Down" dired-tree-down
1298                   :help "Go to first subdirectory header down the tree"))
1299     (define-key map [menu-bar subdir tree-up]
1300       '(menu-item "Tree Up" dired-tree-up
1301                   :help "Go to first subdirectory header up the tree"))
1302     (define-key map [menu-bar subdir up]
1303       '(menu-item "Up Directory" dired-up-directory
1304                   :help "Edit the parent directory"))
1305     (define-key map [menu-bar subdir prev-subdir]
1306       '(menu-item "Prev Subdir" dired-prev-subdir
1307                   :help "Go to previous subdirectory header line"))
1308     (define-key map [menu-bar subdir next-subdir]
1309       '(menu-item "Next Subdir" dired-next-subdir
1310                   :help "Go to next subdirectory header line"))
1311     (define-key map [menu-bar subdir prev-dirline]
1312       '(menu-item "Prev Dirline" dired-prev-dirline
1313                   :help "Move to next directory-file line"))
1314     (define-key map [menu-bar subdir next-dirline]
1315       '(menu-item "Next Dirline" dired-next-dirline
1316                   :help "Move to previous directory-file line"))
1317     (define-key map [menu-bar subdir insert]
1318       '(menu-item "Insert This Subdir" dired-maybe-insert-subdir
1319                   :help "Insert contents of subdirectory"))
1320
1321     (define-key map [menu-bar immediate]
1322       (cons "Immediate" (make-sparse-keymap "Immediate")))
1323
1324     (define-key map
1325       [menu-bar immediate image-dired-dired-display-external]
1326       '(menu-item "Display Image Externally" image-dired-dired-display-external
1327                   :help "Display image in external viewer"))
1328     (define-key map
1329       [menu-bar immediate image-dired-dired-display-image]
1330       '(menu-item "Display Image" image-dired-dired-display-image
1331                   :help "Display sized image in a separate window"))
1332
1333     (define-key map [menu-bar immediate dashes-4]
1334       '("--"))
1335
1336     (define-key map [menu-bar immediate revert-buffer]
1337       '(menu-item "Refresh" revert-buffer
1338                   :help "Update contents of shown directories"))
1339
1340     (define-key map [menu-bar immediate dashes]
1341       '("--"))
1342
1343     (define-key map [menu-bar immediate compare-directories]
1344       '(menu-item "Compare Directories..." dired-compare-directories
1345                   :help "Mark files with different attributes in two dired buffers"))
1346     (define-key map [menu-bar immediate backup-diff]
1347       '(menu-item "Compare with Backup" dired-backup-diff
1348                   :help "Diff file at cursor with its latest backup"))
1349     (define-key map [menu-bar immediate diff]
1350       '(menu-item "Diff..." dired-diff
1351                   :help "Compare file at cursor with another file"))
1352     (define-key map [menu-bar immediate view]
1353       '(menu-item "View This File" dired-view-file
1354                   :help "Examine file at cursor in read-only mode"))
1355     (define-key map [menu-bar immediate display]
1356       '(menu-item "Display in Other Window" dired-display-file
1357                   :help "Display file at cursor in other window"))
1358     (define-key map [menu-bar immediate find-file-other-window]
1359       '(menu-item "Find in Other Window" dired-find-file-other-window
1360                   :help "Edit file at cursor in other window"))
1361     (define-key map [menu-bar immediate find-file]
1362       '(menu-item "Find This File" dired-find-file
1363                   :help "Edit file at cursor"))
1364     (define-key map [menu-bar immediate create-directory]
1365       '(menu-item "Create Directory..." dired-create-directory))
1366     (define-key map [menu-bar immediate wdired-mode]
1367       '(menu-item "Edit File Names" wdired-change-to-wdired-mode
1368                   :filter (lambda (x) (if (eq major-mode 'dired-mode) x))))
1369
1370     (define-key map [menu-bar regexp]
1371       (cons "Regexp" (make-sparse-keymap "Regexp")))
1372
1373     (define-key map
1374       [menu-bar regexp image-dired-mark-tagged-files]
1375       '(menu-item "Mark From Image Tag..." image-dired-mark-tagged-files
1376                   :help "Mark files whose image tags matches regexp"))
1377
1378     (define-key map [menu-bar regexp dashes-1]
1379       '("--"))
1380
1381     (define-key map [menu-bar regexp downcase]
1382       '(menu-item "Downcase" dired-downcase
1383                   ;; When running on plain MS-DOS, there's only one
1384                   ;; letter-case for file names.
1385                   :enable (or (not (fboundp 'msdos-long-file-names))
1386                               (msdos-long-file-names))
1387                   :help "Rename marked files to lower-case name"))
1388     (define-key map [menu-bar regexp upcase]
1389       '(menu-item "Upcase" dired-upcase
1390                   :enable (or (not (fboundp 'msdos-long-file-names))
1391                               (msdos-long-file-names))
1392                   :help "Rename marked files to upper-case name"))
1393     (define-key map [menu-bar regexp hardlink]
1394       '(menu-item "Hardlink..." dired-do-hardlink-regexp
1395                   :help "Make hard links for files matching regexp"))
1396     (define-key map [menu-bar regexp symlink]
1397       '(menu-item "Symlink..." dired-do-symlink-regexp
1398                   :visible (fboundp 'make-symbolic-link)
1399                   :help "Make symbolic links for files matching regexp"))
1400     (define-key map [menu-bar regexp rename]
1401       '(menu-item "Rename..." dired-do-rename-regexp
1402                   :help "Rename marked files matching regexp"))
1403     (define-key map [menu-bar regexp copy]
1404       '(menu-item "Copy..." dired-do-copy-regexp
1405                   :help "Copy marked files matching regexp"))
1406     (define-key map [menu-bar regexp flag]
1407       '(menu-item "Flag..." dired-flag-files-regexp
1408                   :help "Flag files matching regexp for deletion"))
1409     (define-key map [menu-bar regexp mark]
1410       '(menu-item "Mark..." dired-mark-files-regexp
1411                   :help "Mark files matching regexp for future operations"))
1412     (define-key map [menu-bar regexp mark-cont]
1413       '(menu-item "Mark Containing..." dired-mark-files-containing-regexp
1414                   :help "Mark files whose contents matches regexp"))
1415
1416     (define-key map [menu-bar mark]
1417       (cons "Mark" (make-sparse-keymap "Mark")))
1418
1419     (define-key map [menu-bar mark prev]
1420       '(menu-item "Previous Marked" dired-prev-marked-file
1421                   :help "Move to previous marked file"))
1422     (define-key map [menu-bar mark next]
1423       '(menu-item "Next Marked" dired-next-marked-file
1424                   :help "Move to next marked file"))
1425     (define-key map [menu-bar mark marks]
1426       '(menu-item "Change Marks..." dired-change-marks
1427                   :help "Replace marker with another character"))
1428     (define-key map [menu-bar mark unmark-all]
1429       '(menu-item "Unmark All" dired-unmark-all-marks))
1430     (define-key map [menu-bar mark symlinks]
1431       '(menu-item "Mark Symlinks" dired-mark-symlinks
1432                   :visible (fboundp 'make-symbolic-link)
1433                   :help "Mark all symbolic links"))
1434     (define-key map [menu-bar mark directories]
1435       '(menu-item "Mark Directories" dired-mark-directories
1436                   :help "Mark all directories except `.' and `..'"))
1437     (define-key map [menu-bar mark directory]
1438       '(menu-item "Mark Old Backups" dired-clean-directory
1439                   :help "Flag old numbered backups for deletion"))
1440     (define-key map [menu-bar mark executables]
1441       '(menu-item "Mark Executables" dired-mark-executables
1442                   :help "Mark all executable files"))
1443     (define-key map [menu-bar mark garbage-files]
1444       '(menu-item "Flag Garbage Files" dired-flag-garbage-files
1445                   :help "Flag unneeded files for deletion"))
1446     (define-key map [menu-bar mark backup-files]
1447       '(menu-item "Flag Backup Files" dired-flag-backup-files
1448                   :help "Flag all backup files for deletion"))
1449     (define-key map [menu-bar mark auto-save-files]
1450       '(menu-item "Flag Auto-save Files" dired-flag-auto-save-files
1451                   :help "Flag auto-save files for deletion"))
1452     (define-key map [menu-bar mark deletion]
1453       '(menu-item "Flag" dired-flag-file-deletion
1454                   :help "Flag current line's file for deletion"))
1455     (define-key map [menu-bar mark unmark]
1456       '(menu-item "Unmark" dired-unmark
1457                   :help "Unmark or unflag current line's file"))
1458     (define-key map [menu-bar mark mark]
1459       '(menu-item "Mark" dired-mark
1460                   :help "Mark current line's file for future operations"))
1461     (define-key map [menu-bar mark toggle-marks]
1462       '(menu-item "Toggle Marks" dired-toggle-marks
1463                   :help "Mark unmarked files, unmark marked ones"))
1464
1465     (define-key map [menu-bar operate]
1466       (cons "Operate" (make-sparse-keymap "Operate")))
1467
1468     (define-key map
1469       [menu-bar operate image-dired-delete-tag]
1470       '(menu-item "Delete Image Tag..." image-dired-delete-tag
1471                   :help "Delete image tag from current or marked files"))
1472     (define-key map
1473       [menu-bar operate image-dired-tag-files]
1474       '(menu-item "Add Image Tags..." image-dired-tag-files
1475                   :help "Add image tags to current or marked files"))
1476     (define-key map
1477       [menu-bar operate image-dired-dired-comment-files]
1478       '(menu-item "Add Image Comment..." image-dired-dired-comment-files
1479                   :help "Add image comment to current or marked files"))
1480     (define-key map
1481       [menu-bar operate image-dired-display-thumbs]
1482       '(menu-item "Display Image-Dired" image-dired-display-thumbs
1483                   :help "Display image-dired for current or marked image files"))
1484
1485     (define-key map [menu-bar operate dashes-3]
1486       '("--"))
1487
1488     (define-key map [menu-bar operate query-replace]
1489       '(menu-item "Query Replace in Files..." dired-do-query-replace-regexp
1490                   :help "Replace regexp in marked files"))
1491     (define-key map [menu-bar operate search]
1492       '(menu-item "Search Files..." dired-do-search
1493                   :help "Search marked files for regexp"))
1494     (define-key map [menu-bar operate chown]
1495       '(menu-item "Change Owner..." dired-do-chown
1496                   :visible (not (memq system-type '(ms-dos windows-nt)))
1497                   :help "Change the owner of marked files"))
1498     (define-key map [menu-bar operate chgrp]
1499       '(menu-item "Change Group..." dired-do-chgrp
1500                   :visible (not (memq system-type '(ms-dos windows-nt)))
1501                   :help "Change the group of marked files"))
1502     (define-key map [menu-bar operate chmod]
1503       '(menu-item "Change Mode..." dired-do-chmod
1504                   :help "Change mode (attributes) of marked files"))
1505     (define-key map [menu-bar operate touch]
1506       '(menu-item "Change Timestamp..." dired-do-touch
1507                   :help "Change timestamp of marked files"))
1508     (define-key map [menu-bar operate load]
1509       '(menu-item "Load" dired-do-load
1510                   :help "Load marked Emacs Lisp files"))
1511     (define-key map [menu-bar operate compile]
1512       '(menu-item "Byte-compile" dired-do-byte-compile
1513                   :help "Byte-compile marked Emacs Lisp files"))
1514     (define-key map [menu-bar operate compress]
1515       '(menu-item "Compress" dired-do-compress
1516                   :help "Compress/uncompress marked files"))
1517     (define-key map [menu-bar operate print]
1518       '(menu-item "Print..." dired-do-print
1519                   :help "Ask for print command and print marked files"))
1520     (define-key map [menu-bar operate hardlink]
1521       '(menu-item "Hardlink to..." dired-do-hardlink
1522                   :help "Make hard links for current or marked files"))
1523     (define-key map [menu-bar operate symlink]
1524       '(menu-item "Symlink to..." dired-do-symlink
1525                   :visible (fboundp 'make-symbolic-link)
1526                   :help "Make symbolic links for current or marked files"))
1527     (define-key map [menu-bar operate command]
1528       '(menu-item "Shell Command..." dired-do-shell-command
1529                   :help "Run a shell command on each of marked files"))
1530     (define-key map [menu-bar operate delete]
1531       '(menu-item "Delete" dired-do-delete
1532                   :help "Delete current file or all marked files"))
1533     (define-key map [menu-bar operate rename]
1534       '(menu-item "Rename to..." dired-do-rename
1535                   :help "Rename current file or move marked files"))
1536     (define-key map [menu-bar operate copy]
1537       '(menu-item "Copy to..." dired-do-copy
1538                   :help "Copy current file or all marked files"))
1539
1540     map)
1541   "Local keymap for `dired-mode' buffers.")
1542 \f
1543 ;; Dired mode is suitable only for specially formatted data.
1544 (put 'dired-mode 'mode-class 'special)
1545
1546 ;; Autoload cookie needed by desktop.el
1547 ;;;###autoload
1548 (defun dired-mode (&optional dirname switches)
1549   "\
1550 Mode for \"editing\" directory listings.
1551 In Dired, you are \"editing\" a list of the files in a directory and
1552   \(optionally) its subdirectories, in the format of `ls -lR'.
1553   Each directory is a page: use \\[backward-page] and \\[forward-page] to move pagewise.
1554 \"Editing\" means that you can run shell commands on files, visit,
1555   compress, load or byte-compile them, change their file attributes
1556   and insert subdirectories into the same buffer.  You can \"mark\"
1557   files for later commands or \"flag\" them for deletion, either file
1558   by file or all files matching certain criteria.
1559 You can move using the usual cursor motion commands.\\<dired-mode-map>
1560 Letters no longer insert themselves.  Digits are prefix arguments.
1561 Instead, type \\[dired-flag-file-deletion] to flag a file for Deletion.
1562 Type \\[dired-mark] to Mark a file or subdirectory for later commands.
1563   Most commands operate on the marked files and use the current file
1564   if no files are marked.  Use a numeric prefix argument to operate on
1565   the next ARG (or previous -ARG if ARG<0) files, or just `1'
1566   to operate on the current file only.  Prefix arguments override marks.
1567   Mark-using commands display a list of failures afterwards.  Type \\[dired-summary]
1568   to see why something went wrong.
1569 Type \\[dired-unmark] to Unmark a file or all files of a subdirectory.
1570 Type \\[dired-unmark-backward] to back up one line and unflag.
1571 Type \\[dired-do-flagged-delete] to eXecute the deletions requested.
1572 Type \\[dired-advertised-find-file] to Find the current line's file
1573   (or dired it in another buffer, if it is a directory).
1574 Type \\[dired-find-file-other-window] to find file or dired directory in Other window.
1575 Type \\[dired-maybe-insert-subdir] to Insert a subdirectory in this buffer.
1576 Type \\[dired-do-rename] to Rename a file or move the marked files to another directory.
1577 Type \\[dired-do-copy] to Copy files.
1578 Type \\[dired-sort-toggle-or-edit] to toggle Sorting by name/date or change the `ls' switches.
1579 Type \\[revert-buffer] to read all currently expanded directories aGain.
1580   This retains all marks and hides subdirs again that were hidden before.
1581 SPC and DEL can be used to move down and up by lines.
1582
1583 If Dired ever gets confused, you can either type \\[revert-buffer] \
1584 to read the
1585 directories again, type \\[dired-do-redisplay] \
1586 to relist a single or the marked files or a
1587 subdirectory, or type \\[dired-build-subdir-alist] to parse the buffer
1588 again for the directory tree.
1589
1590 Customization variables (rename this buffer and type \\[describe-variable] on each line
1591 for more info):
1592
1593   `dired-listing-switches'
1594   `dired-trivial-filenames'
1595   `dired-shrink-to-fit'
1596   `dired-marker-char'
1597   `dired-del-marker'
1598   `dired-keep-marker-rename'
1599   `dired-keep-marker-copy'
1600   `dired-keep-marker-hardlink'
1601   `dired-keep-marker-symlink'
1602
1603 Hooks (use \\[describe-variable] to see their documentation):
1604
1605   `dired-before-readin-hook'
1606   `dired-after-readin-hook'
1607   `dired-mode-hook'
1608   `dired-load-hook'
1609
1610 Keybindings:
1611 \\{dired-mode-map}"
1612   ;; Not to be called interactively (e.g. dired-directory will be set
1613   ;; to default-directory, which is wrong with wildcards).
1614   (kill-all-local-variables)
1615   (use-local-map dired-mode-map)
1616   (dired-advertise)                     ; default-directory is already set
1617   (setq major-mode 'dired-mode
1618         mode-name "Dired"
1619         ;; case-fold-search nil
1620         buffer-read-only t
1621         selective-display t             ; for subdirectory hiding
1622         mode-line-buffer-identification
1623         (propertized-buffer-identification "%17b"))
1624   (set (make-local-variable 'revert-buffer-function)
1625        (function dired-revert))
1626   (set (make-local-variable 'buffer-stale-function)
1627        (function dired-buffer-stale-p))
1628   (set (make-local-variable 'page-delimiter)
1629        "\n\n")
1630   (set (make-local-variable 'dired-directory)
1631        (or dirname default-directory))
1632   ;; list-buffers uses this to display the dir being edited in this buffer.
1633   (set (make-local-variable 'list-buffers-directory)
1634        (expand-file-name (if (listp dired-directory)
1635                              (car dired-directory)
1636                            dired-directory)))
1637   (set (make-local-variable 'dired-actual-switches)
1638        (or switches dired-listing-switches))
1639   (set (make-local-variable 'font-lock-defaults)
1640        '(dired-font-lock-keywords t nil nil beginning-of-line))
1641   (set (make-local-variable 'desktop-save-buffer)
1642        'dired-desktop-buffer-misc-data)
1643   (setq dired-switches-alist nil)
1644   (dired-sort-other dired-actual-switches t)
1645   (when (featurep 'dnd)
1646     (set (make-local-variable 'dnd-protocol-alist)
1647          (append dired-dnd-protocol-alist dnd-protocol-alist)))
1648   (run-mode-hooks 'dired-mode-hook))
1649 \f
1650 ;; Idiosyncratic dired commands that don't deal with marks.
1651
1652 (defun dired-summary ()
1653   "Summarize basic Dired commands and show recent dired errors."
1654   (interactive)
1655   (dired-why)
1656   ;>> this should check the key-bindings and use substitute-command-keys if non-standard
1657   (message
1658    "d-elete, u-ndelete, x-punge, f-ind, o-ther window, R-ename, C-opy, h-elp"))
1659
1660 (defun dired-undo ()
1661   "Undo in a dired buffer.
1662 This doesn't recover lost files, it just undoes changes in the buffer itself.
1663 You can use it to recover marks, killed lines or subdirs."
1664   (interactive)
1665   (let (buffer-read-only)
1666     (undo))
1667   (dired-build-subdir-alist)
1668   (message "Change in dired buffer undone.
1669 Actual changes in files cannot be undone by Emacs."))
1670
1671 (defun dired-toggle-read-only ()
1672   "Edit dired buffer with Wdired, or set it read-only.
1673 Call `wdired-change-to-wdired-mode' in dired buffers whose editing is
1674 supported by Wdired (the major mode of the dired buffer is `dired-mode').
1675 Otherwise, for buffers inheriting from dired-mode, call `toggle-read-only'."
1676   (interactive)
1677   (if (eq major-mode 'dired-mode)
1678       (wdired-change-to-wdired-mode)
1679     (toggle-read-only)))
1680
1681 (defun dired-next-line (arg)
1682   "Move down lines then position at filename.
1683 Optional prefix ARG says how many lines to move; default is one line."
1684   (interactive "p")
1685   (forward-line arg)
1686   (dired-move-to-filename))
1687
1688 (defun dired-previous-line (arg)
1689   "Move up lines then position at filename.
1690 Optional prefix ARG says how many lines to move; default is one line."
1691   (interactive "p")
1692   (forward-line (- arg))
1693   (dired-move-to-filename))
1694
1695 (defun dired-next-dirline (arg &optional opoint)
1696   "Goto ARG'th next directory file line."
1697   (interactive "p")
1698   (or opoint (setq opoint (point)))
1699   (if (if (> arg 0)
1700           (re-search-forward dired-re-dir nil t arg)
1701         (beginning-of-line)
1702         (re-search-backward dired-re-dir nil t (- arg)))
1703       (dired-move-to-filename)          ; user may type `i' or `f'
1704     (goto-char opoint)
1705     (error "No more subdirectories")))
1706
1707 (defun dired-prev-dirline (arg)
1708   "Goto ARG'th previous directory file line."
1709   (interactive "p")
1710   (dired-next-dirline (- arg)))
1711
1712 (defun dired-up-directory (&optional other-window)
1713   "Run Dired on parent directory of current directory.
1714 Find the parent directory either in this buffer or another buffer.
1715 Creates a buffer if necessary."
1716   (interactive "P")
1717   (let* ((dir (dired-current-directory))
1718          (up (file-name-directory (directory-file-name dir))))
1719     (or (dired-goto-file (directory-file-name dir))
1720         ;; Only try dired-goto-subdir if buffer has more than one dir.
1721         (and (cdr dired-subdir-alist)
1722              (dired-goto-subdir up))
1723         (progn
1724           (if other-window
1725               (dired-other-window up)
1726             (dired up))
1727           (dired-goto-file dir)))))
1728
1729 (defun dired-get-file-for-visit ()
1730   "Get the current line's file name, with an error if file does not exist."
1731   (interactive)
1732   ;; We pass t for second arg so that we don't get error for `.' and `..'.
1733   (let ((raw (dired-get-filename nil t))
1734         file-name)
1735     (if (null raw)
1736         (error "No file on this line"))
1737     (setq file-name (file-name-sans-versions raw t))
1738     (if (file-exists-p file-name)
1739         file-name
1740       (if (file-symlink-p file-name)
1741           (error "File is a symlink to a nonexistent target")
1742         (error "File no longer exists; type `g' to update dired buffer")))))
1743
1744 ;; Force `f' rather than `e' in the mode doc:
1745 (defalias 'dired-advertised-find-file 'dired-find-file)
1746 (defun dired-find-file ()
1747   "In Dired, visit the file or directory named on this line."
1748   (interactive)
1749   ;; Bind `find-file-run-dired' so that the command works on directories
1750   ;; too, independent of the user's setting.
1751   (let ((find-file-run-dired t))
1752     (find-file (dired-get-file-for-visit))))
1753
1754 (defun dired-find-alternate-file ()
1755   "In Dired, visit this file or directory instead of the dired buffer."
1756   (interactive)
1757   (set-buffer-modified-p nil)
1758   (find-alternate-file (dired-get-file-for-visit)))
1759 ;; Don't override the setting from .emacs.
1760 ;;;###autoload (put 'dired-find-alternate-file 'disabled t)
1761
1762 (defun dired-mouse-find-file-other-window (event)
1763   "In Dired, visit the file or directory name you click on."
1764   (interactive "e")
1765   (let (window pos file)
1766     (save-excursion
1767       (setq window (posn-window (event-end event))
1768             pos (posn-point (event-end event)))
1769       (if (not (windowp window))
1770           (error "No file chosen"))
1771       (set-buffer (window-buffer window))
1772       (goto-char pos)
1773       (setq file (dired-get-file-for-visit)))
1774     (if (file-directory-p file)
1775         (or (and (cdr dired-subdir-alist)
1776                  (dired-goto-subdir file))
1777             (progn
1778               (select-window window)
1779               (dired-other-window file)))
1780       (select-window window)
1781       (find-file-other-window (file-name-sans-versions file t)))))
1782
1783 (defun dired-view-file ()
1784   "In Dired, examine a file in view mode, returning to Dired when done.
1785 When file is a directory, show it in this buffer if it is inserted.
1786 Otherwise, display it in another buffer."
1787   (interactive)
1788   (let ((file (dired-get-file-for-visit)))
1789     (if (file-directory-p file)
1790         (or (and (cdr dired-subdir-alist)
1791                  (dired-goto-subdir file))
1792             (dired file))
1793       (view-file file))))
1794
1795 (defun dired-find-file-other-window ()
1796   "In Dired, visit this file or directory in another window."
1797   (interactive)
1798   (find-file-other-window (dired-get-file-for-visit)))
1799
1800 (defun dired-display-file ()
1801   "In Dired, display this file or directory in another window."
1802   (interactive)
1803   (display-buffer (find-file-noselect (dired-get-file-for-visit))))
1804 \f
1805 ;;; Functions for extracting and manipulating file names in Dired buffers.
1806
1807 (defun dired-get-filename (&optional localp no-error-if-not-filep)
1808   "In Dired, return name of file mentioned on this line.
1809 Value returned normally includes the directory name.
1810 Optional arg LOCALP with value `no-dir' means don't include directory
1811 name in result.  A value of `verbatim' means to return the name exactly as
1812 it occurs in the buffer, and a value of t means construct name relative to
1813 `default-directory', which still may contain slashes if in a subdirectory.
1814 Optional arg NO-ERROR-IF-NOT-FILEP means treat `.' and `..' as
1815 regular filenames and return nil if no filename on this line.
1816 Otherwise, an error occurs in these cases."
1817   (let (case-fold-search file p1 p2 already-absolute)
1818     (save-excursion
1819       (if (setq p1 (dired-move-to-filename (not no-error-if-not-filep)))
1820           (setq p2 (dired-move-to-end-of-filename no-error-if-not-filep))))
1821     ;; nil if no file on this line, but no-error-if-not-filep is t:
1822     (if (setq file (and p1 p2 (buffer-substring p1 p2)))
1823         (progn
1824           ;; Get rid of the mouse-face property that file names have.
1825           (set-text-properties 0 (length file) nil file)
1826           ;; Unquote names quoted by ls or by dired-insert-directory.
1827           ;; Using read to unquote is much faster than substituting
1828           ;; \007 (4 chars) -> ^G  (1 char) etc. in a lisp loop.
1829           (setq file
1830                 (read
1831                  (concat "\""
1832                          ;; Some ls -b don't escape quotes, argh!
1833                          ;; This is not needed for GNU ls, though.
1834                          (or (dired-string-replace-match
1835                               "\\([^\\]\\|\\`\\)\"" file "\\1\\\\\"" nil t)
1836                              file)
1837                          "\"")))
1838           ;; The above `read' will return a unibyte string if FILE
1839           ;; contains eight-bit-control/graphic characters.
1840           (if (and enable-multibyte-characters
1841                    (not (multibyte-string-p file)))
1842               (setq file (string-to-multibyte file)))))
1843     (and file (file-name-absolute-p file)
1844          ;; A relative file name can start with ~.
1845          ;; Don't treat it as absolute in this context.
1846          (not (eq (aref file 0) ?~))
1847          (setq already-absolute t))
1848     (cond
1849      ((null file)
1850       nil)
1851      ((eq localp 'verbatim)
1852       file)
1853      ((and (not no-error-if-not-filep)
1854            (member file '("." "..")))
1855       (error "Cannot operate on `.' or `..'"))
1856      ((and (eq localp 'no-dir) already-absolute)
1857       (file-name-nondirectory file))
1858      (already-absolute
1859       (let ((handler (find-file-name-handler file nil)))
1860         ;; check for safe-magic property so that we won't
1861         ;; put /: for names that don't really need them.
1862         ;; For instance, .gz files when auto-compression-mode is on.
1863         (if (and handler (not (get handler 'safe-magic)))
1864             (concat "/:" file)
1865           file)))
1866      ((eq localp 'no-dir)
1867       file)
1868      ((equal (dired-current-directory) "/")
1869       (setq file (concat (dired-current-directory localp) file))
1870       (let ((handler (find-file-name-handler file nil)))
1871         ;; check for safe-magic property so that we won't
1872         ;; put /: for names that don't really need them.
1873         ;; For instance, .gz files when auto-compression-mode is on.
1874         (if (and handler (not (get handler 'safe-magic)))
1875             (concat "/:" file)
1876           file)))
1877      (t
1878       (concat (dired-current-directory localp) file)))))
1879
1880 (defun dired-string-replace-match (regexp string newtext
1881                                    &optional literal global)
1882   "Replace first match of REGEXP in STRING with NEWTEXT.
1883 If it does not match, nil is returned instead of the new string.
1884 Optional arg LITERAL means to take NEWTEXT literally.
1885 Optional arg GLOBAL means to replace all matches."
1886   (if global
1887       (let ((start 0) ret)
1888         (while (string-match regexp string start)
1889           (let ((from-end (- (length string) (match-end 0))))
1890             (setq ret (setq string (replace-match newtext t literal string)))
1891             (setq start (- (length string) from-end))))
1892           ret)
1893     (if (not (string-match regexp string 0))
1894         nil
1895       (replace-match newtext t literal string))))
1896
1897 (defun dired-make-absolute (file &optional dir)
1898   ;;"Convert FILE (a file name relative to DIR) to an absolute file name."
1899   ;; We can't always use expand-file-name as this would get rid of `.'
1900   ;; or expand in / instead default-directory if DIR=="".
1901   ;; This should be good enough for ange-ftp, but might easily be
1902   ;; redefined (for VMS?).
1903   ;; It should be reasonably fast, though, as it is called in
1904   ;; dired-get-filename.
1905   (concat (or dir default-directory) file))
1906
1907 (defun dired-make-relative (file &optional dir ignore)
1908   "Convert FILE (an absolute file name) to a name relative to DIR.
1909 If this is impossible, return FILE unchanged.
1910 DIR must be a directory name, not a file name."
1911   (or dir (setq dir default-directory))
1912   ;; This case comes into play if default-directory is set to
1913   ;; use ~.
1914   (if (and (> (length dir) 0) (= (aref dir 0) ?~))
1915       (setq dir (expand-file-name dir)))
1916   (if (string-match (concat "^" (regexp-quote dir)) file)
1917       (substring file (match-end 0))
1918 ;;;  (or no-error
1919 ;;;     (error "%s: not in directory tree growing at %s" file dir))
1920     file))
1921 \f
1922 ;;; Functions for finding the file name in a dired buffer line.
1923
1924 (defvar dired-permission-flags-regexp
1925   "\\([^ ]\\)[-r][-w]\\([^ ]\\)[-r][-w]\\([^ ]\\)[-r][-w]\\([^ ]\\)"
1926   "Regular expression to match the permission flags in `ls -l'.")
1927
1928 ;; Move to first char of filename on this line.
1929 ;; Returns position (point) or nil if no filename on this line."
1930 (defun dired-move-to-filename (&optional raise-error eol)
1931   "Move to the beginning of the filename on the current line.
1932 Return the position of the beginning of the filename, or nil if none found."
1933   ;; This is the UNIX version.
1934   (or eol (setq eol (line-end-position)))
1935   (beginning-of-line)
1936   ;; First try assuming `ls --dired' was used.
1937   (let ((change (next-single-property-change (point) 'dired-filename nil eol)))
1938     (cond
1939      ((and change (< change eol))
1940       (goto-char change))
1941      ((re-search-forward directory-listing-before-filename-regexp eol t)
1942       (goto-char (match-end 0)))
1943      ((re-search-forward dired-permission-flags-regexp eol t)
1944       ;; Ha!  There *is* a file.  Our regexp-from-hell just failed to find it.
1945       (if raise-error
1946           (error "Unrecognized line!  Check directory-listing-before-filename-regexp"))
1947       (beginning-of-line)
1948       nil)
1949      (raise-error
1950       (error "No file on this line")))))
1951
1952 (defun dired-move-to-end-of-filename (&optional no-error)
1953   ;; Assumes point is at beginning of filename,
1954   ;; thus the rwx bit re-search-backward below will succeed in *this*
1955   ;; line if at all.  So, it should be called only after
1956   ;; (dired-move-to-filename t).
1957   ;; On failure, signals an error (with non-nil NO-ERROR just returns nil).
1958   ;; This is the UNIX version.
1959   (if (get-text-property (point) 'dired-filename)
1960       (goto-char (next-single-property-change (point) 'dired-filename))
1961     (let (opoint file-type executable symlink hidden case-fold-search used-F eol)
1962       ;; case-fold-search is nil now, so we can test for capital F:
1963       (setq used-F (string-match "F" dired-actual-switches)
1964             opoint (point)
1965             eol (save-excursion (end-of-line) (point))
1966             hidden (and selective-display
1967                         (save-excursion (search-forward "\r" eol t))))
1968       (if hidden
1969           nil
1970         (save-excursion ;; Find out what kind of file this is:
1971           ;; Restrict perm bits to be non-blank,
1972           ;; otherwise this matches one char to early (looking backward):
1973           ;; "l---------" (some systems make symlinks that way)
1974           ;; "----------" (plain file with zero perms)
1975           (if (re-search-backward
1976                dired-permission-flags-regexp nil t)
1977               (setq file-type (char-after (match-beginning 1))
1978                     symlink (eq file-type ?l)
1979                     ;; Only with -F we need to know whether it's an executable
1980                     executable (and
1981                                 used-F
1982                                 (string-match
1983                                  "[xst]" ;; execute bit set anywhere?
1984                                  (concat
1985                                   (match-string 2)
1986                                   (match-string 3)
1987                                   (match-string 4)))))
1988             (or no-error (error "No file on this line"))))
1989         ;; Move point to end of name:
1990         (if symlink
1991             (if (search-forward " -> " eol t)
1992                 (progn
1993                   (forward-char -4)
1994                   (and used-F
1995                        dired-ls-F-marks-symlinks
1996                        (eq (preceding-char) ?@) ;; did ls really mark the link?
1997                        (forward-char -1))))
1998           (goto-char eol) ;; else not a symbolic link
1999           ;; ls -lF marks dirs, sockets, fifos and executables with exactly
2000           ;; one trailing character. (Executable bits on symlinks ain't mean
2001           ;; a thing, even to ls, but we know it's not a symlink.)
2002           (and used-F
2003                (or (memq file-type '(?d ?s ?p))
2004                    executable)
2005                (forward-char -1))))
2006       (or no-error
2007           (not (eq opoint (point)))
2008           (error (if hidden
2009                      (substitute-command-keys
2010                       "File line is hidden, type \\[dired-hide-subdir] to unhide")
2011                    "No file on this line")))
2012       (if (eq opoint (point))
2013           nil
2014         (point)))))
2015
2016 \f
2017 ;;; COPY NAMES OF MARKED FILES INTO KILL-RING.
2018
2019 (defun dired-copy-filename-as-kill (&optional arg)
2020   "Copy names of marked (or next ARG) files into the kill ring.
2021 The names are separated by a space.
2022 With a zero prefix arg, use the absolute file name of each marked file.
2023 With \\[universal-argument], use the file name relative to the dired buffer's
2024 `default-directory'.  (This still may contain slashes if in a subdirectory.)
2025
2026 If on a subdir headerline, use absolute subdirname instead;
2027 prefix arg and marked files are ignored in this case.
2028
2029 You can then feed the file name(s) to other commands with \\[yank]."
2030   (interactive "P")
2031   (let ((string
2032          (or (dired-get-subdir)
2033              (mapconcat (function identity)
2034                         (if arg
2035                             (cond ((zerop (prefix-numeric-value arg))
2036                                    (dired-get-marked-files))
2037                                   ((consp arg)
2038                                    (dired-get-marked-files t))
2039                                   (t
2040                                    (dired-get-marked-files
2041                                     'no-dir (prefix-numeric-value arg))))
2042                           (dired-get-marked-files 'no-dir))
2043                         " "))))
2044     (if (eq last-command 'kill-region)
2045         (kill-append string nil)
2046       (kill-new string))
2047     (message "%s" string)))
2048
2049 \f
2050 ;; Keeping Dired buffers in sync with the filesystem and with each other
2051
2052 (defun dired-buffers-for-dir (dir &optional file)
2053 ;; Return a list of buffers that dired DIR (top level or in-situ subdir).
2054 ;; If FILE is non-nil, include only those whose wildcard pattern (if any)
2055 ;; matches FILE.
2056 ;; The list is in reverse order of buffer creation, most recent last.
2057 ;; As a side effect, killed dired buffers for DIR are removed from
2058 ;; dired-buffers.
2059   (setq dir (file-name-as-directory dir))
2060   (let ((alist dired-buffers) result elt buf)
2061     (while alist
2062       (setq elt (car alist)
2063             buf (cdr elt))
2064       (if (buffer-name buf)
2065           (if (dired-in-this-tree dir (car elt))
2066               (with-current-buffer buf
2067                 (and (assoc dir dired-subdir-alist)
2068                      (or (null file)
2069                          (let ((wildcards
2070                                 (file-name-nondirectory dired-directory)))
2071                            (or (= 0 (length wildcards))
2072                                (string-match (dired-glob-regexp wildcards)
2073                                              file))))
2074                      (setq result (cons buf result)))))
2075         ;; else buffer is killed - clean up:
2076         (setq dired-buffers (delq elt dired-buffers)))
2077       (setq alist (cdr alist)))
2078     result))
2079
2080 (defun dired-glob-regexp (pattern)
2081   "Convert glob-pattern PATTERN to a regular expression."
2082   (let ((matched-in-pattern 0)  ;; How many chars of PATTERN we've handled.
2083         regexp)
2084     (while (string-match "[[?*]" pattern matched-in-pattern)
2085       (let ((op-end (match-end 0))
2086             (next-op (aref pattern (match-beginning 0))))
2087         (setq regexp (concat regexp
2088                              (regexp-quote
2089                               (substring pattern matched-in-pattern
2090                                          (match-beginning 0)))))
2091         (cond ((= next-op ??)
2092                (setq regexp (concat regexp "."))
2093                (setq matched-in-pattern op-end))
2094               ((= next-op ?\[)
2095                ;; Fails to handle ^ yet ????
2096                (let* ((set-start (match-beginning 0))
2097                       (set-cont
2098                        (if (= (aref pattern (1+ set-start)) ?^)
2099                            (+ 3 set-start)
2100                          (+ 2 set-start)))
2101                       (set-end (string-match "]" pattern set-cont))
2102                       (set (substring pattern set-start (1+ set-end))))
2103                  (setq regexp (concat regexp set))
2104                  (setq matched-in-pattern (1+ set-end))))
2105               ((= next-op ?*)
2106                (setq regexp (concat regexp ".*"))
2107                (setq matched-in-pattern op-end)))))
2108     (concat "\\`"
2109             regexp
2110             (regexp-quote
2111              (substring pattern matched-in-pattern))
2112             "\\'")))
2113
2114
2115
2116 (defun dired-advertise ()
2117   ;;"Advertise in variable `dired-buffers' that we dired `default-directory'."
2118   ;; With wildcards we actually advertise too much.
2119   (let ((expanded-default (expand-file-name default-directory)))
2120     (if (memq (current-buffer) (dired-buffers-for-dir expanded-default))
2121         t                               ; we have already advertised ourselves
2122       (setq dired-buffers
2123             (cons (cons expanded-default (current-buffer))
2124                   dired-buffers)))))
2125
2126 (defun dired-unadvertise (dir)
2127   ;; Remove DIR from the buffer alist in variable dired-buffers.
2128   ;; This has the effect of removing any buffer whose main directory is DIR.
2129   ;; It does not affect buffers in which DIR is a subdir.
2130   ;; Removing is also done as a side-effect in dired-buffer-for-dir.
2131   (setq dired-buffers
2132         (delq (assoc (expand-file-name dir) dired-buffers) dired-buffers)))
2133 \f
2134 ;; Tree Dired
2135
2136 ;;; utility functions
2137
2138 (defun dired-in-this-tree (file dir)
2139   ;;"Is FILE part of the directory tree starting at DIR?"
2140   (let (case-fold-search)
2141     (string-match (concat "^" (regexp-quote dir)) file)))
2142
2143 (defun dired-normalize-subdir (dir)
2144   ;; Prepend default-directory to DIR if relative file name.
2145   ;; dired-get-filename must be able to make a valid file name from a
2146   ;; file and its directory DIR.
2147   (file-name-as-directory
2148    (if (file-name-absolute-p dir)
2149        dir
2150      (expand-file-name dir default-directory))))
2151
2152 (defun dired-get-subdir ()
2153   ;;"Return the subdir name on this line, or nil if not on a headerline."
2154   ;; Look up in the alist whether this is a headerline.
2155   (save-excursion
2156     (let ((cur-dir (dired-current-directory)))
2157       (beginning-of-line)               ; alist stores b-o-l positions
2158       (and (zerop (- (point)
2159                      (dired-get-subdir-min (assoc cur-dir
2160                                                   dired-subdir-alist))))
2161            cur-dir))))
2162
2163 ;(defun dired-get-subdir-min (elt)
2164 ;  (cdr elt))
2165 ;; can't use macro,  must be redefinable for other alist format in dired-nstd.
2166 (defalias 'dired-get-subdir-min 'cdr)
2167
2168 (defun dired-get-subdir-max (elt)
2169   (save-excursion
2170     (goto-char (dired-get-subdir-min elt))
2171     (dired-subdir-max)))
2172
2173 (defun dired-clear-alist ()
2174   (while dired-subdir-alist
2175     (set-marker (dired-get-subdir-min (car dired-subdir-alist)) nil)
2176     (setq dired-subdir-alist (cdr dired-subdir-alist))))
2177
2178 (defun dired-subdir-index (dir)
2179   ;; Return an index into alist for use with nth
2180   ;; for the sake of subdir moving commands.
2181   (let (found (index 0) (alist dired-subdir-alist))
2182     (while alist
2183       (if (string= dir (car (car alist)))
2184           (setq alist nil found t)
2185         (setq alist (cdr alist) index (1+ index))))
2186     (if found index nil)))
2187
2188 (defun dired-next-subdir (arg &optional no-error-if-not-found no-skip)
2189   "Go to next subdirectory, regardless of level."
2190   ;; Use 0 arg to go to this directory's header line.
2191   ;; NO-SKIP prevents moving to end of header line, returning whatever
2192   ;; position was found in dired-subdir-alist.
2193   (interactive "p")
2194   (let ((this-dir (dired-current-directory))
2195         pos index)
2196     ;; nth with negative arg does not return nil but the first element
2197     (setq index (- (dired-subdir-index this-dir) arg))
2198     (setq pos (if (>= index 0)
2199                   (dired-get-subdir-min (nth index dired-subdir-alist))))
2200     (if pos
2201         (progn
2202           (goto-char pos)
2203           (or no-skip (skip-chars-forward "^\n\r"))
2204           (point))
2205       (if no-error-if-not-found
2206           nil                           ; return nil if not found
2207         (error "%s directory" (if (> arg 0) "Last" "First"))))))
2208
2209 (defun dired-build-subdir-alist (&optional switches)
2210   "Build `dired-subdir-alist' by parsing the buffer.
2211 Returns the new value of the alist.
2212 If optional arg SWITCHES is non-nil, use its value
2213 instead of `dired-actual-switches'."
2214   (interactive)
2215   (dired-clear-alist)
2216   (save-excursion
2217     (let* ((count 0)
2218            (buffer-read-only nil)
2219            (buffer-undo-list t)
2220            (switches (or switches dired-actual-switches))
2221            new-dir-name
2222            (R-ftp-base-dir-regex
2223             ;; Used to expand subdirectory names correctly in recursive
2224             ;; ange-ftp listings.
2225             (and (string-match "R" switches)
2226                  (string-match "\\`/.*:\\(/.*\\)" default-directory)
2227                  (concat "\\`" (match-string 1 default-directory)))))
2228       (goto-char (point-min))
2229       (setq dired-subdir-alist nil)
2230       (while (re-search-forward dired-subdir-regexp nil t)
2231         ;; Avoid taking a file name ending in a colon
2232         ;; as a subdir name.
2233         (unless (save-excursion
2234                   (goto-char (match-beginning 0))
2235                   (beginning-of-line)
2236                   (forward-char 2)
2237                   (save-match-data (looking-at dired-re-perms)))
2238           (save-excursion
2239             (goto-char (match-beginning 1))
2240             (setq new-dir-name
2241                   (buffer-substring-no-properties (point) (match-end 1))
2242                   new-dir-name
2243                   (save-match-data
2244                     (if (and R-ftp-base-dir-regex
2245                              (not (string= new-dir-name default-directory))
2246                              (string-match R-ftp-base-dir-regex new-dir-name))
2247                         (concat default-directory
2248                                 (substring new-dir-name (match-end 0)))
2249                       (expand-file-name new-dir-name))))
2250             (delete-region (point) (match-end 1))
2251             (insert new-dir-name))
2252           (setq count (1+ count))
2253           (dired-alist-add-1 new-dir-name
2254                              ;; Place a sub directory boundary between lines.
2255                              (save-excursion
2256                                (goto-char (match-beginning 0))
2257                                (beginning-of-line)
2258                                (point-marker)))))
2259       (if (and (> count 1) (interactive-p))
2260           (message "Buffer includes %d directories" count)))
2261     ;; We don't need to sort it because it is in buffer order per
2262     ;; constructionem.  Return new alist:
2263     dired-subdir-alist))
2264
2265 (defun dired-alist-add-1 (dir new-marker)
2266   ;; Add new DIR at NEW-MARKER.  Don't sort.
2267   (setq dired-subdir-alist
2268         (cons (cons (dired-normalize-subdir dir) new-marker)
2269               dired-subdir-alist)))
2270
2271 (defun dired-goto-next-nontrivial-file ()
2272   ;; Position point on first nontrivial file after point.
2273   (dired-goto-next-file);; so there is a file to compare with
2274   (if (stringp dired-trivial-filenames)
2275       (while (and (not (eobp))
2276                   (string-match dired-trivial-filenames
2277                                 (file-name-nondirectory
2278                                  (or (dired-get-filename nil t) ""))))
2279         (forward-line 1)
2280         (dired-move-to-filename))))
2281
2282 (defun dired-goto-next-file ()
2283   (let ((max (1- (dired-subdir-max))))
2284     (while (and (not (dired-move-to-filename)) (< (point) max))
2285       (forward-line 1))))
2286
2287 (defun dired-goto-file (file)
2288   "Go to line describing file FILE in this dired buffer."
2289   ;; Return value of point on success, else nil.
2290   ;; FILE must be an absolute file name.
2291   ;; Loses if FILE contains control chars like "\007" for which ls
2292   ;; either inserts "?" or "\\007" into the buffer, so we won't find
2293   ;; it in the buffer.
2294   (interactive
2295    (prog1                               ; let push-mark display its message
2296        (list (expand-file-name
2297               (read-file-name "Goto file: "
2298                               (dired-current-directory))))
2299      (push-mark)))
2300   (setq file (directory-file-name file)) ; does no harm if no directory
2301   (let (found case-fold-search dir)
2302     (setq dir (or (file-name-directory file)
2303                   (error "File name `%s' is not absolute" file)))
2304     (save-excursion
2305       ;; The hair here is to get the result of dired-goto-subdir
2306       ;; without really calling it if we don't have any subdirs.
2307       (if (if (string= dir (expand-file-name default-directory))
2308               (goto-char (point-min))
2309             (and (cdr dired-subdir-alist)
2310                  (dired-goto-subdir dir)))
2311           (let ((base (file-name-nondirectory file))
2312                 search-string
2313                 (boundary (dired-subdir-max)))
2314             (setq search-string
2315                   (replace-regexp-in-string "\^m" "\\^m" base nil t))
2316             (setq search-string
2317                   (replace-regexp-in-string "\\\\" "\\\\" search-string nil t))
2318             (while (and (not found)
2319                         ;; filenames are preceded by SPC, this makes
2320                         ;; the search faster (e.g. for the filename "-"!).
2321                         (search-forward (concat " " search-string)
2322                                         boundary 'move))
2323               ;; Match could have BASE just as initial substring or
2324               ;; or in permission bits or date or
2325               ;; not be a proper filename at all:
2326               (if (equal base (dired-get-filename 'no-dir t))
2327                     ;; Must move to filename since an (actually
2328                     ;; correct) match could have been elsewhere on the
2329                     ;; ;; line (e.g. "-" would match somewhere in the
2330                     ;; permission bits).
2331                   (setq found (dired-move-to-filename))
2332                 ;; If this isn't the right line, move forward to avoid
2333                 ;; trying this line again.
2334                 (forward-line 1))))))
2335     (and found
2336          ;; return value of point (i.e., FOUND):
2337          (goto-char found))))
2338
2339 (defun dired-initial-position (dirname)
2340   ;; Where point should go in a new listing of DIRNAME.
2341   ;; Point assumed at beginning of new subdir line.
2342   ;; You may redefine this function as you wish, e.g. like in dired-x.el.
2343   (end-of-line)
2344   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
2345 \f
2346 ;; These are hooks which make tree dired work.
2347 ;; They are in this file because other parts of dired need to call them.
2348 ;; But they don't call the rest of tree dired unless there are subdirs loaded.
2349
2350 ;; This function is called for each retrieved filename.
2351 ;; It could stand to be faster, though it's mostly function call
2352 ;; overhead.  Avoiding the function call seems to save about 10% in
2353 ;; dired-get-filename.  Make it a defsubst?
2354 (defun dired-current-directory (&optional localp)
2355   "Return the name of the subdirectory to which this line belongs.
2356 This returns a string with trailing slash, like `default-directory'.
2357 Optional argument means return a file name relative to `default-directory'."
2358   (let ((here (point))
2359         (alist (or dired-subdir-alist
2360                    ;; probably because called in a non-dired buffer
2361                    (error "No subdir-alist in %s" (current-buffer))))
2362         elt dir)
2363     (while alist
2364       (setq elt (car alist)
2365             dir (car elt)
2366             ;; use `<=' (not `<') as subdir line is part of subdir
2367             alist (if (<= (dired-get-subdir-min elt) here)
2368                       nil               ; found
2369                     (cdr alist))))
2370     (if localp
2371         (dired-make-relative dir default-directory)
2372       dir)))
2373
2374 ;; Subdirs start at the beginning of their header lines and end just
2375 ;; before the beginning of the next header line (or end of buffer).
2376
2377 (defun dired-subdir-max ()
2378   (save-excursion
2379     (if (or (null (cdr dired-subdir-alist)) (not (dired-next-subdir 1 t t)))
2380         (point-max)
2381       (point))))
2382 \f
2383 ;; Deleting files
2384
2385 (defcustom dired-recursive-deletes 'top
2386   "*Decide whether recursive deletes are allowed.
2387 A value of nil means no recursive deletes.
2388 `always' means delete recursively without asking.  This is DANGEROUS!
2389 `top' means ask for each directory at top level, but delete its subdirectories
2390 without asking.
2391 Anything else means ask for each directory."
2392   :type '(choice :tag "Delete non-empty directories"
2393                  (const :tag "Yes" always)
2394                  (const :tag "No--only delete empty directories" nil)
2395                  (const :tag "Confirm for each directory" t)
2396                  (const :tag "Confirm for each top directory only" top))
2397   :group 'dired)
2398
2399 ;; Match anything but `.' and `..'.
2400 (defvar dired-re-no-dot "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")
2401
2402 ;; Delete file, possibly delete a directory and all its files.
2403 ;; This function is usefull outside of dired.  One could change it's name
2404 ;; to e.g. recursive-delete-file and put it somewhere else.
2405 (defun dired-delete-file (file &optional recursive) "\
2406 Delete FILE or directory (possibly recursively if optional RECURSIVE is true.)
2407 RECURSIVE determines what to do with a non-empty directory.  If RECURSIVE is:
2408 nil, do not delete.
2409 `always', delete recursively without asking.
2410 `top', ask for each directory at top level.
2411 Anything else, ask for each sub-directory."
2412   (let (files)
2413      ;; This test is equivalent to
2414      ;; (and (file-directory-p fn) (not (file-symlink-p fn)))
2415      ;; but more efficient
2416     (if (not (eq t (car (file-attributes file))))
2417         (delete-file file)
2418       (when (and recursive
2419                (setq files
2420                      (directory-files file t dired-re-no-dot)) ; Not empty.
2421                (or (eq recursive 'always)
2422                    (yes-or-no-p (format "Recursive delete of %s? "
2423                                         (dired-make-relative file)))))
2424         (if (eq recursive 'top) (setq recursive 'always)) ; Don't ask again.
2425         (while files            ; Recursively delete (possibly asking).
2426             (dired-delete-file (car files) recursive)
2427             (setq files (cdr files))))
2428       (delete-directory file))))
2429
2430 (defun dired-do-flagged-delete (&optional nomessage)
2431   "In Dired, delete the files flagged for deletion.
2432 If NOMESSAGE is non-nil, we don't display any message
2433 if there are no flagged files.
2434 `dired-recursive-deletes' controls whether deletion of
2435 non-empty directories is allowed."
2436   (interactive)
2437   (let* ((dired-marker-char dired-del-marker)
2438          (regexp (dired-marker-regexp))
2439          case-fold-search)
2440     (if (save-excursion (goto-char (point-min))
2441                         (re-search-forward regexp nil t))
2442         (dired-internal-do-deletions
2443          ;; this can't move point since ARG is nil
2444          (dired-map-over-marks (cons (dired-get-filename) (point))
2445                                nil)
2446          nil)
2447       (or nomessage
2448           (message "(No deletions requested)")))))
2449
2450 (defun dired-do-delete (&optional arg)
2451   "Delete all marked (or next ARG) files.
2452 `dired-recursive-deletes' controls whether deletion of
2453 non-empty directories is allowed."
2454   ;; This is more consistent with the file marking feature than
2455   ;; dired-do-flagged-delete.
2456   (interactive "P")
2457   (dired-internal-do-deletions
2458    ;; this may move point if ARG is an integer
2459    (dired-map-over-marks (cons (dired-get-filename) (point))
2460                          arg)
2461    arg))
2462
2463 (defvar dired-deletion-confirmer 'yes-or-no-p) ; or y-or-n-p?
2464
2465 (defun dired-internal-do-deletions (l arg)
2466   ;; L is an alist of files to delete, with their buffer positions.
2467   ;; ARG is the prefix arg.
2468   ;; Filenames are absolute (VMS needs this for logical search paths).
2469   ;; (car L) *must* be the *last* (bottommost) file in the dired buffer.
2470   ;; That way as changes are made in the buffer they do not shift the
2471   ;; lines still to be changed, so the (point) values in L stay valid.
2472   ;; Also, for subdirs in natural order, a subdir's files are deleted
2473   ;; before the subdir itself - the other way around would not work.
2474   (let ((files (mapcar (function car) l))
2475         (count (length l))
2476         (succ 0))
2477     ;; canonicalize file list for pop up
2478     (setq files (nreverse (mapcar (function dired-make-relative) files)))
2479     (if (dired-mark-pop-up
2480          " *Deletions*" 'delete files dired-deletion-confirmer
2481          (format "Delete %s " (dired-mark-prompt arg files)))
2482         (save-excursion
2483           (let (failures);; files better be in reverse order for this loop!
2484             (while l
2485               (goto-char (cdr (car l)))
2486               (let (buffer-read-only)
2487                 (condition-case err
2488                     (let ((fn (car (car l))))
2489                       (dired-delete-file fn dired-recursive-deletes)
2490                       ;; if we get here, removing worked
2491                       (setq succ (1+ succ))
2492                       (message "%s of %s deletions" succ count)
2493                       (dired-fun-in-all-buffers
2494                        (file-name-directory fn) (file-name-nondirectory fn)
2495                        (function dired-delete-entry) fn))
2496                   (error;; catch errors from failed deletions
2497                    (dired-log "%s\n" err)
2498                    (setq failures (cons (car (car l)) failures)))))
2499               (setq l (cdr l)))
2500             (if (not failures)
2501                 (message "%d deletion%s done" count (dired-plural-s count))
2502               (dired-log-summary
2503                (format "%d of %d deletion%s failed"
2504                        (length failures) count
2505                        (dired-plural-s count))
2506                failures))))
2507       (message "(No deletions performed)")))
2508   (dired-move-to-filename))
2509
2510 (defun dired-fun-in-all-buffers (directory file fun &rest args)
2511   ;; In all buffers dired'ing DIRECTORY, run FUN with ARGS.
2512   ;; If the buffer has a wildcard pattern, check that it matches FILE.
2513   ;; (FILE does not include a directory component.)
2514   ;; FILE may be nil, in which case ignore it.
2515   ;; Return list of buffers where FUN succeeded (i.e., returned non-nil).
2516   (let (success-list)
2517     (dolist (buf (dired-buffers-for-dir (expand-file-name directory)
2518                                         file))
2519       (with-current-buffer buf
2520         (if (apply fun args)
2521             (setq success-list (cons (buffer-name buf) success-list)))))
2522     success-list))
2523
2524 ;; Delete the entry for FILE from
2525 (defun dired-delete-entry (file)
2526   (save-excursion
2527     (and (dired-goto-file file)
2528          (let (buffer-read-only)
2529            (delete-region (progn (beginning-of-line) (point))
2530                           (save-excursion (forward-line 1) (point))))))
2531   (dired-clean-up-after-deletion file))
2532
2533 ;; This is a separate function for the sake of dired-x.el.
2534 (defun dired-clean-up-after-deletion (fn)
2535   ;; Clean up after a deleted file or directory FN.
2536   (save-excursion (and (cdr dired-subdir-alist)
2537                        (dired-goto-subdir fn)
2538                        (dired-kill-subdir))))
2539 \f
2540 ;; Confirmation
2541
2542 (defun dired-marker-regexp ()
2543   (concat "^" (regexp-quote (char-to-string dired-marker-char))))
2544
2545 (defun dired-plural-s (count)
2546   (if (= 1 count) "" "s"))
2547
2548 (defun dired-mark-prompt (arg files)
2549   ;; Return a string for use in a prompt, either the current file
2550   ;; name, or the marker and a count of marked files.
2551   (let ((count (length files)))
2552     (if (= count 1)
2553         (car files)
2554       ;; more than 1 file:
2555       (if (integerp arg)
2556           ;; abs(arg) = count
2557           ;; Perhaps this is nicer, but it also takes more screen space:
2558           ;;(format "[%s %d files]" (if (> arg 0) "next" "previous")
2559           ;;                        count)
2560           (format "[next %d files]" arg)
2561         (format "%c [%d files]" dired-marker-char count)))))
2562
2563 (defun dired-pop-to-buffer (buf)
2564   ;; Pop up buffer BUF.
2565   ;; If dired-shrink-to-fit is t, make its window fit its contents.
2566   (if (not dired-shrink-to-fit)
2567       (pop-to-buffer (get-buffer-create buf))
2568     ;; let window shrink to fit:
2569     (let ((window (selected-window))
2570           target-lines w2)
2571       (cond ;; if split-height-threshold is enabled, use the largest window
2572             ((and (> (window-height (setq w2 (get-largest-window)))
2573                      split-height-threshold)
2574                   (window-full-width-p w2))
2575              (setq window w2))
2576             ;; if the least-recently-used window is big enough, use it
2577             ((and (> (window-height (setq w2 (get-lru-window)))
2578                      (* 2 window-min-height))
2579                   (window-full-width-p w2))
2580              (setq window w2)))
2581       (save-excursion
2582         (set-buffer buf)
2583         (goto-char (point-max))
2584         (skip-chars-backward "\n\r\t ")
2585         (setq target-lines (count-lines (point-min) (point)))
2586         ;; Don't forget to count the last line.
2587         (if (not (bolp))
2588             (setq target-lines (1+ target-lines))))
2589       (if (<= (window-height window) (* 2 window-min-height))
2590           ;; At this point, every window on the frame is too small to split.
2591           (setq w2 (display-buffer buf))
2592         (setq w2 (split-window window
2593                   (max window-min-height
2594                        (- (window-height window)
2595                           (1+ (max window-min-height target-lines)))))))
2596       (set-window-buffer w2 buf)
2597       (if (< (1- (window-height w2)) target-lines)
2598           (progn
2599             (select-window w2)
2600             (enlarge-window (- target-lines (1- (window-height w2))))))
2601       (set-window-start w2 1)
2602       )))
2603
2604 (defcustom dired-no-confirm nil
2605   "A list of symbols for commands Dired should not confirm.
2606 Command symbols are `byte-compile', `chgrp', `chmod', `chown', `compress',
2607 `copy', `delete', `hardlink', `load', `move', `print', `shell', `symlink',
2608 `touch' and `uncompress'."
2609   :group 'dired
2610   :type '(set (const byte-compile) (const chgrp)
2611               (const chmod) (const chown) (const compress)
2612               (const copy) (const delete) (const hardlink)
2613               (const load) (const move) (const print)
2614               (const shell) (const symlink) (const touch)
2615               (const uncompress)))
2616
2617 (defun dired-mark-pop-up (bufname op-symbol files function &rest args)
2618   "Return FUNCTION's result on ARGS after showing which files are marked.
2619 Displays the file names in a buffer named BUFNAME;
2620  nil gives \" *Marked Files*\".
2621 This uses function `dired-pop-to-buffer' to do that.
2622
2623 FUNCTION should not manipulate files, just read input
2624  (an argument or confirmation).
2625 The window is not shown if there is just one file or
2626  OP-SYMBOL is a member of the list in `dired-no-confirm'.
2627 FILES is the list of marked files.  It can also be (t FILENAME)
2628 in the case of one marked file, to distinguish that from using
2629 just the current file."
2630   (or bufname (setq bufname  " *Marked Files*"))
2631   (if (or (eq dired-no-confirm t)
2632           (memq op-symbol dired-no-confirm)
2633           ;; If FILES defaulted to the current line's file.
2634           (= (length files) 1))
2635       (apply function args)
2636     (with-current-buffer (get-buffer-create bufname)
2637       (erase-buffer)
2638       ;; Handle (t FILE) just like (FILE), here.
2639       ;; That value is used (only in some cases), to mean
2640       ;; just one file that was marked, rather than the current line file.
2641       (dired-format-columns-of-files (if (eq (car files) t) (cdr files) files))
2642       (remove-text-properties (point-min) (point-max)
2643                               '(mouse-face nil help-echo nil)))
2644     (save-window-excursion
2645       (dired-pop-to-buffer bufname)
2646       (apply function args))))
2647
2648 (defun dired-format-columns-of-files (files)
2649   ;; Files should be in forward order for this loop.
2650   ;; i.e., (car files) = first file in buffer.
2651   ;; Returns the number of lines used.
2652   (let* ((maxlen (+ 2 (apply 'max (mapcar 'length files))))
2653          (width (- (window-width (selected-window)) 2))
2654          (columns (max 1 (/ width maxlen)))
2655          (nfiles (length files))
2656          (rows (+ (/ nfiles columns)
2657                   (if (zerop (% nfiles columns)) 0 1)))
2658          (i 0)
2659          (j 0))
2660     (setq files (nconc (copy-sequence files) ; fill up with empty fns
2661                        (make-list (- (* columns rows) nfiles) "")))
2662     (setcdr (nthcdr (1- (length files)) files) files) ; make circular
2663     (while (< j rows)
2664       (while (< i columns)
2665         (indent-to (* i maxlen))
2666         (insert (car files))
2667         (setq files (nthcdr rows files)
2668               i (1+ i)))
2669       (insert "\n")
2670       (setq i 0
2671             j (1+ j)
2672             files (cdr files)))
2673     rows))
2674 \f
2675 ;; Commands to mark or flag file(s) at or near current line.
2676
2677 (defun dired-repeat-over-lines (arg function)
2678   ;; This version skips non-file lines.
2679   (let ((pos (make-marker)))
2680     (beginning-of-line)
2681     (while (and (> arg 0) (not (eobp)))
2682       (setq arg (1- arg))
2683       (beginning-of-line)
2684       (while (and (not (eobp)) (dired-between-files)) (forward-line 1))
2685       (save-excursion
2686         (forward-line 1)
2687         (move-marker pos (1+ (point))))
2688       (save-excursion (funcall function))
2689       ;; Advance to the next line--actually, to the line that *was* next.
2690       ;; (If FUNCTION inserted some new lines in between, skip them.)
2691       (goto-char pos))
2692     (while (and (< arg 0) (not (bobp)))
2693       (setq arg (1+ arg))
2694       (forward-line -1)
2695       (while (and (not (bobp)) (dired-between-files)) (forward-line -1))
2696       (beginning-of-line)
2697       (save-excursion (funcall function)))
2698     (move-marker pos nil)
2699     (dired-move-to-filename)))
2700
2701 (defun dired-between-files ()
2702   ;; This used to be a regexp match of the `total ...' line output by
2703   ;; ls, which is slightly faster, but that is not very robust; notably,
2704   ;; it fails for non-english locales.
2705   (save-excursion (not (dired-move-to-filename))))
2706
2707 (defun dired-next-marked-file (arg &optional wrap opoint)
2708   "Move to the next marked file, wrapping around the end of the buffer."
2709   (interactive "p\np")
2710   (or opoint (setq opoint (point)));; return to where interactively started
2711   (if (if (> arg 0)
2712           (re-search-forward dired-re-mark nil t arg)
2713         (beginning-of-line)
2714         (re-search-backward dired-re-mark nil t (- arg)))
2715       (dired-move-to-filename)
2716     (if (null wrap)
2717         (progn
2718           (goto-char opoint)
2719           (error "No next marked file"))
2720       (message "(Wraparound for next marked file)")
2721       (goto-char (if (> arg 0) (point-min) (point-max)))
2722       (dired-next-marked-file arg nil opoint))))
2723
2724 (defun dired-prev-marked-file (arg &optional wrap)
2725   "Move to the previous marked file, wrapping around the end of the buffer."
2726   (interactive "p\np")
2727   (dired-next-marked-file (- arg) wrap))
2728
2729 (defun dired-file-marker (file)
2730   ;; Return FILE's marker, or nil if unmarked.
2731   (save-excursion
2732     (and (dired-goto-file file)
2733          (progn
2734            (beginning-of-line)
2735            (if (not (equal ?\040 (following-char)))
2736                (following-char))))))
2737
2738 (defun dired-mark-files-in-region (start end)
2739   (let (buffer-read-only)
2740     (if (> start end)
2741         (error "start > end"))
2742     (goto-char start)                   ; assumed at beginning of line
2743     (while (< (point) end)
2744       ;; Skip subdir line and following garbage like the `total' line:
2745       (while (and (< (point) end) (dired-between-files))
2746         (forward-line 1))
2747       (if (and (not (looking-at dired-re-dot))
2748                (dired-get-filename nil t))
2749           (progn
2750             (delete-char 1)
2751             (insert dired-marker-char)))
2752       (forward-line 1))))
2753
2754 (defun dired-mark (arg)
2755   "Mark the current (or next ARG) files.
2756 If on a subdir headerline, mark all its files except `.' and `..'.
2757
2758 Use \\[dired-unmark-all-files] to remove all marks
2759 and \\[dired-unmark] on a subdir to remove the marks in
2760 this subdir."
2761   (interactive "P")
2762   (if (dired-get-subdir)
2763       (save-excursion (dired-mark-subdir-files))
2764     (let (buffer-read-only)
2765       (dired-repeat-over-lines
2766        (prefix-numeric-value arg)
2767        (function (lambda () (delete-char 1) (insert dired-marker-char)))))))
2768
2769 (defun dired-unmark (arg)
2770   "Unmark the current (or next ARG) files.
2771 If looking at a subdir, unmark all its files except `.' and `..'."
2772   (interactive "P")
2773   (let ((dired-marker-char ?\040))
2774     (dired-mark arg)))
2775
2776 (defun dired-flag-file-deletion (arg)
2777   "In Dired, flag the current line's file for deletion.
2778 With prefix arg, repeat over several lines.
2779
2780 If on a subdir headerline, mark all its files except `.' and `..'."
2781   (interactive "P")
2782   (let ((dired-marker-char dired-del-marker))
2783     (dired-mark arg)))
2784
2785 (defun dired-unmark-backward (arg)
2786   "In Dired, move up lines and remove deletion flag there.
2787 Optional prefix ARG says how many lines to unflag; default is one line."
2788   (interactive "p")
2789   (dired-unmark (- arg)))
2790
2791 (defun dired-toggle-marks ()
2792   "Toggle marks: marked files become unmarked, and vice versa.
2793 Files marked with other flags (such as `D') are not affected.
2794 `.' and `..' are never toggled.
2795 As always, hidden subdirs are not affected."
2796   (interactive)
2797   (save-excursion
2798     (goto-char (point-min))
2799     (let (buffer-read-only)
2800       (while (not (eobp))
2801         (or (dired-between-files)
2802             (looking-at dired-re-dot)
2803             ;; use subst instead of insdel because it does not move
2804             ;; the gap and thus should be faster and because
2805             ;; other characters are left alone automatically
2806             (apply 'subst-char-in-region
2807                    (point) (1+ (point))
2808                    (if (eq ?\040 (following-char)) ; SPC
2809                        (list ?\040 dired-marker-char)
2810                      (list dired-marker-char ?\040))))
2811         (forward-line 1)))))
2812 \f
2813 ;;; Commands to mark or flag files based on their characteristics or names.
2814
2815 (defvar dired-regexp-history nil
2816   "History list of regular expressions used in Dired commands.")
2817
2818 (defun dired-read-regexp (prompt)
2819   (read-from-minibuffer prompt nil nil nil 'dired-regexp-history))
2820
2821 (defun dired-mark-files-regexp (regexp &optional marker-char)
2822   "Mark all files matching REGEXP for use in later commands.
2823 A prefix argument means to unmark them instead.
2824 `.' and `..' are never marked.
2825
2826 REGEXP is an Emacs regexp, not a shell wildcard.  Thus, use `\\.o$' for
2827 object files--just `.o' will mark more than you might think."
2828   (interactive
2829    (list (dired-read-regexp (concat (if current-prefix-arg "Unmark" "Mark")
2830                                     " files (regexp): "))
2831          (if current-prefix-arg ?\040)))
2832   (let ((dired-marker-char (or marker-char dired-marker-char)))
2833     (dired-mark-if
2834      (and (not (looking-at dired-re-dot))
2835           (not (eolp))                  ; empty line
2836           (let ((fn (dired-get-filename nil t)))
2837             (and fn (string-match regexp (file-name-nondirectory fn)))))
2838      "matching file")))
2839
2840 (defun dired-mark-files-containing-regexp (regexp &optional marker-char)
2841   "Mark all files with contents containing REGEXP for use in later commands.
2842 A prefix argument means to unmark them instead.
2843 `.' and `..' are never marked."
2844   (interactive
2845    (list (dired-read-regexp (concat (if current-prefix-arg "Unmark" "Mark")
2846                                     " files containing (regexp): "))
2847          (if current-prefix-arg ?\040)))
2848   (let ((dired-marker-char (or marker-char dired-marker-char)))
2849     (dired-mark-if
2850      (and (not (looking-at dired-re-dot))
2851           (not (eolp))                  ; empty line
2852           (let ((fn (dired-get-filename nil t)))
2853             (when (and fn (file-readable-p fn)
2854                        (not (file-directory-p fn)))
2855               (let ((prebuf (get-file-buffer fn)))
2856                 (message "Checking %s" fn)
2857                 ;; For now we do it inside emacs
2858                 ;; Grep might be better if there are a lot of files
2859                 (if prebuf
2860                     (with-current-buffer prebuf
2861                       (save-excursion
2862                         (goto-char (point-min))
2863                         (re-search-forward regexp nil t)))
2864                   (with-temp-buffer
2865                     (insert-file-contents fn)
2866                     (goto-char (point-min))
2867                     (re-search-forward regexp nil t))))
2868                       )))
2869      "matching file")))
2870
2871 (defun dired-flag-files-regexp (regexp)
2872   "In Dired, flag all files containing the specified REGEXP for deletion.
2873 The match is against the non-directory part of the filename.  Use `^'
2874   and `$' to anchor matches.  Exclude subdirs by hiding them.
2875 `.' and `..' are never flagged."
2876   (interactive (list (dired-read-regexp "Flag for deletion (regexp): ")))
2877   (dired-mark-files-regexp regexp dired-del-marker))
2878
2879 (defun dired-mark-symlinks (unflag-p)
2880   "Mark all symbolic links.
2881 With prefix argument, unflag all those files."
2882   (interactive "P")
2883   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
2884     (dired-mark-if (looking-at dired-re-sym) "symbolic link")))
2885
2886 (defun dired-mark-directories (unflag-p)
2887   "Mark all directory file lines except `.' and `..'.
2888 With prefix argument, unflag all those files."
2889   (interactive "P")
2890   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
2891     (dired-mark-if (and (looking-at dired-re-dir)
2892                         (not (looking-at dired-re-dot)))
2893                    "directory file")))
2894
2895 (defun dired-mark-executables (unflag-p)
2896   "Mark all executable files.
2897 With prefix argument, unflag all those files."
2898   (interactive "P")
2899   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char)))
2900     (dired-mark-if (looking-at dired-re-exe) "executable file")))
2901
2902 ;; dired-x.el has a dired-mark-sexp interactive command: mark
2903 ;; files for which PREDICATE returns non-nil.
2904
2905 (defun dired-flag-auto-save-files (&optional unflag-p)
2906   "Flag for deletion files whose names suggest they are auto save files.
2907 A prefix argument says to unflag those files instead."
2908   (interactive "P")
2909   (let ((dired-marker-char (if unflag-p ?\040 dired-del-marker)))
2910     (dired-mark-if
2911      ;; It is less than general to check for # here,
2912      ;; but it's the only way this runs fast enough.
2913      (and (save-excursion (end-of-line)
2914                           (or
2915                            (eq (preceding-char) ?#)
2916                            ;; Handle executables in case of -F option.
2917                            ;; We need not worry about the other kinds
2918                            ;; of markings that -F makes, since they won't
2919                            ;; appear on real auto-save files.
2920                            (if (eq (preceding-char) ?*)
2921                                (progn
2922                                  (forward-char -1)
2923                                  (eq (preceding-char) ?#)))))
2924           (not (looking-at dired-re-dir))
2925           (let ((fn (dired-get-filename t t)))
2926             (if fn (auto-save-file-name-p
2927                     (file-name-nondirectory fn)))))
2928      "auto save file")))
2929
2930 (defcustom dired-garbage-files-regexp
2931   ;; `log' here is dubious, since it's typically used for useful log
2932   ;; files, not just TeX stuff.  -- fx
2933   (concat (regexp-opt
2934            '(".log" ".toc" ".dvi" ".bak" ".orig" ".rej" ".aux"))
2935           "\\'")
2936   "Regular expression to match \"garbage\" files for `dired-flag-garbage-files'."
2937   :type 'regexp
2938   :group 'dired)
2939
2940 (defun dired-flag-garbage-files ()
2941   "Flag for deletion all files that match `dired-garbage-files-regexp'."
2942   (interactive)
2943   (dired-flag-files-regexp dired-garbage-files-regexp))
2944
2945 (defun dired-flag-backup-files (&optional unflag-p)
2946   "Flag all backup files (names ending with `~') for deletion.
2947 With prefix argument, unflag these files."
2948   (interactive "P")
2949   (let ((dired-marker-char (if unflag-p ?\s dired-del-marker)))
2950     (dired-mark-if
2951      ;; Don't call backup-file-name-p unless the last character looks like
2952      ;; it might be the end of a backup file name.  This isn't very general,
2953      ;; but it's the only way this runs fast enough.
2954      (and (save-excursion (end-of-line)
2955                           ;; Handle executables in case of -F option.
2956                           ;; We need not worry about the other kinds
2957                           ;; of markings that -F makes, since they won't
2958                           ;; appear on real backup files.
2959                           (if (eq (preceding-char) ?*)
2960                               (forward-char -1))
2961                           (eq (preceding-char) ?~))
2962           (not (looking-at dired-re-dir))
2963           (let ((fn (dired-get-filename t t)))
2964             (if fn (backup-file-name-p fn))))
2965      "backup file")))
2966
2967 (defun dired-change-marks (&optional old new)
2968   "Change all OLD marks to NEW marks.
2969 OLD and NEW are both characters used to mark files."
2970   (interactive
2971    (let* ((cursor-in-echo-area t)
2972           (old (progn (message "Change (old mark): ") (read-char)))
2973           (new (progn (message  "Change %c marks to (new mark): " old)
2974                       (read-char))))
2975      (list old new)))
2976   (if (or (eq old ?\r) (eq new ?\r))
2977       (ding)
2978     (let ((string (format "\n%c" old))
2979           (buffer-read-only))
2980       (save-excursion
2981         (goto-char (point-min))
2982         (while (search-forward string nil t)
2983           (if (if (= old ?\s)
2984                   (save-match-data
2985                     (dired-get-filename 'no-dir t))
2986                 t)
2987               (subst-char-in-region (match-beginning 0)
2988                                     (match-end 0) old new)))))))
2989
2990 (defun dired-unmark-all-marks ()
2991   "Remove all marks from all files in the dired buffer."
2992   (interactive)
2993   (dired-unmark-all-files ?\r))
2994
2995 (defun dired-unmark-all-files (mark &optional arg)
2996   "Remove a specific mark (or any mark) from every file.
2997 After this command, type the mark character to remove,
2998 or type RET to remove all marks.
2999 With prefix arg, query for each marked file.
3000 Type \\[help-command] at that time for help."
3001   (interactive "cRemove marks (RET means all): \nP")
3002   (save-excursion
3003     (let* ((count 0)
3004            buffer-read-only case-fold-search query
3005            (string (format "\n%c" mark))
3006            (help-form "\
3007 Type SPC or `y' to unmark one file, DEL or `n' to skip to next,
3008 `!' to unmark all remaining files with no more questions."))
3009       (goto-char (point-min))
3010       (while (if (eq mark ?\r)
3011                  (re-search-forward dired-re-mark nil t)
3012                (search-forward string nil t))
3013         (if (or (not arg)
3014                 (let ((file (dired-get-filename t t)))
3015                   (and file
3016                        (dired-query 'query "Unmark file `%s'? "
3017                                     file))))
3018             (progn (subst-char-in-region (1- (point)) (point)
3019                                          (preceding-char) ?\s)
3020                    (setq count (1+ count)))))
3021       (message (if (= count 1) "1 mark removed"
3022                  "%d marks removed")
3023                count))))
3024 \f
3025 ;; Logging failures operating on files, and showing the results.
3026
3027 (defvar dired-log-buffer "*Dired log*")
3028
3029 (defun dired-why ()
3030   "Pop up a buffer with error log output from Dired.
3031 A group of errors from a single command ends with a formfeed.
3032 Thus, use \\[backward-page] to find the beginning of a group of errors."
3033   (interactive)
3034   (if (get-buffer dired-log-buffer)
3035       (let ((owindow (selected-window))
3036             (window (display-buffer (get-buffer dired-log-buffer))))
3037         (unwind-protect
3038             (progn
3039               (select-window window)
3040               (goto-char (point-max))
3041               (forward-line -1)
3042               (backward-page 1)
3043               (recenter 0))
3044           (select-window owindow)))))
3045
3046 (defun dired-log (log &rest args)
3047   ;; Log a message or the contents of a buffer.
3048   ;; If LOG is a string and there are more args, it is formatted with
3049   ;; those ARGS.  Usually the LOG string ends with a \n.
3050   ;; End each bunch of errors with (dired-log t):
3051   ;; this inserts the current time and buffer at the start of the page,
3052   ;; and \f (formfeed) at the end.
3053   (let ((obuf (current-buffer)))
3054     (with-current-buffer (get-buffer-create dired-log-buffer)
3055       (goto-char (point-max))
3056       (let ((inhibit-read-only t))
3057         (cond ((stringp log)
3058                (insert (if args
3059                            (apply (function format) log args)
3060                          log)))
3061               ((bufferp log)
3062                (insert-buffer-substring log))
3063               ((eq t log)
3064                (backward-page 1)
3065                (unless (bolp)
3066                  (insert "\n"))
3067                (insert (current-time-string)
3068                        "\tBuffer `" (buffer-name obuf) "'\n")
3069                (goto-char (point-max))
3070                (insert "\f\n")))))))
3071
3072 (defun dired-log-summary (string failures)
3073   "State a summary of a command's failures, in echo area and log buffer.
3074 STRING is an overall summary of the failures.
3075 FAILURES is a list of file names that we failed to operate on,
3076 or nil if file names are not applicable."
3077   (if (= (length failures) 1)
3078       (message "%s"
3079                (with-current-buffer dired-log-buffer
3080                  (goto-char (point-max))
3081                  (backward-page 1)
3082                  (if (eolp) (forward-line 1))
3083                  (buffer-substring (point) (point-max))))
3084     (message (if failures "%s--type ? for details (%s)"
3085                "%s--type ? for details")
3086              string failures))
3087   ;; Log a summary describing a bunch of errors.
3088   (dired-log (concat "\n" string "\n"))
3089   (dired-log t))
3090 \f
3091 ;;; Sorting
3092
3093 ;; Most ls can only sort by name or by date (with -t), nothing else.
3094 ;; GNU ls sorts on size with -S, on extension with -X, and unsorted with -U.
3095 ;; So anything that does not contain these is sort "by name".
3096
3097 (defvar dired-ls-sorting-switches "SXU"
3098   "String of `ls' switches \(single letters\) except \"t\" that influence sorting.
3099
3100 This indicates to Dired which option switches to watch out for because they
3101 will change the sorting order behavior of `ls'.
3102
3103 To change the default sorting order \(e.g. add a `-v' option\), see the
3104 variable `dired-listing-switches'.  To temporarily override the listing
3105 format, use `\\[universal-argument] \\[dired]'.")
3106
3107 (defvar dired-sort-by-date-regexp
3108   (concat "^-[^" dired-ls-sorting-switches
3109           "]*t[^" dired-ls-sorting-switches "]*$")
3110   "Regexp recognized by Dired to set `by date' mode.")
3111
3112 (defvar dired-sort-by-name-regexp
3113   (concat "^-[^t" dired-ls-sorting-switches "]+$")
3114   "Regexp recognized by Dired to set `by name' mode.")
3115
3116 (defvar dired-sort-inhibit nil
3117   "Non-nil means the Dired sort command is disabled.
3118 The idea is to set this buffer-locally in special dired buffers.")
3119
3120 (defun dired-sort-set-modeline ()
3121   ;; Set modeline display according to dired-actual-switches.
3122   ;; Modeline display of "by name" or "by date" guarantees the user a
3123   ;; match with the corresponding regexps.  Non-matching switches are
3124   ;; shown literally.
3125   (when (eq major-mode 'dired-mode)
3126     (setq mode-name
3127           (let (case-fold-search)
3128             (cond ((string-match
3129                     dired-sort-by-name-regexp dired-actual-switches)
3130                    "Dired by name")
3131                   ((string-match
3132                     dired-sort-by-date-regexp dired-actual-switches)
3133                    "Dired by date")
3134                   (t
3135                    (concat "Dired " dired-actual-switches)))))
3136     (force-mode-line-update)))
3137
3138 (defun dired-sort-toggle-or-edit (&optional arg)
3139   "Toggle between sort by date/name and refresh the dired buffer.
3140 With a prefix argument you can edit the current listing switches instead."
3141   (interactive "P")
3142   (when dired-sort-inhibit
3143     (error "Cannot sort this dired buffer"))
3144   (if arg
3145       (dired-sort-other
3146        (read-string "ls switches (must contain -l): " dired-actual-switches))
3147     (dired-sort-toggle)))
3148
3149 (defun dired-sort-toggle ()
3150   ;; Toggle between sort by date/name.  Reverts the buffer.
3151   (setq dired-actual-switches
3152         (let (case-fold-search)
3153           (if (string-match " " dired-actual-switches)
3154               ;; New toggle scheme: add/remove a trailing " -t"
3155               (if (string-match " -t\\'" dired-actual-switches)
3156                   (substring dired-actual-switches 0 (match-beginning 0))
3157                 (concat dired-actual-switches " -t"))
3158             ;; old toggle scheme: look for some 't' switch and add/remove it
3159             (concat
3160              "-l"
3161              (dired-replace-in-string (concat "[-lt"
3162                                               dired-ls-sorting-switches "]")
3163                                       ""
3164                                       dired-actual-switches)
3165              (if (string-match (concat "[t" dired-ls-sorting-switches "]")
3166                                dired-actual-switches)
3167                  ""
3168                "t")))))
3169   (dired-sort-set-modeline)
3170   (revert-buffer))
3171
3172 ;; Some user code loads dired especially for this.
3173 ;; Don't do that--use replace-regexp-in-string instead.
3174 (defun dired-replace-in-string (regexp newtext string)
3175   ;; Replace REGEXP with NEWTEXT everywhere in STRING and return result.
3176   ;; NEWTEXT is taken literally---no \\DIGIT escapes will be recognized.
3177   (let ((result "") (start 0) mb me)
3178     (while (string-match regexp string start)
3179       (setq mb (match-beginning 0)
3180             me (match-end 0)
3181             result (concat result (substring string start mb) newtext)
3182             start me))
3183     (concat result (substring string start))))
3184
3185 (defun dired-sort-other (switches &optional no-revert)
3186   "Specify new `ls' SWITCHES for current dired buffer.
3187 Values matching `dired-sort-by-date-regexp' or `dired-sort-by-name-regexp'
3188 set the minor mode accordingly, others appear literally in the mode line.
3189 With optional second arg NO-REVERT, don't refresh the listing afterwards."
3190   (dired-sort-R-check switches)
3191   (setq dired-actual-switches switches)
3192   (dired-sort-set-modeline)
3193   (or no-revert (revert-buffer)))
3194
3195 (defvar dired-subdir-alist-pre-R nil
3196   "Value of `dired-subdir-alist' before -R switch added.")
3197 (make-variable-buffer-local 'dired-subdir-alist-pre-R)
3198
3199 (defun dired-sort-R-check (switches)
3200   "Additional processing of -R in ls option string SWITCHES.
3201 Saves `dired-subdir-alist' when R is set and restores saved value
3202 minus any directories explicitly deleted when R is cleared.
3203 To be called first in body of `dired-sort-other', etc."
3204   (cond
3205    ((and (string-match "R" switches)
3206          (not (string-match "R" dired-actual-switches)))
3207     ;; Adding -R to ls switches -- save `dired-subdir-alist':
3208     (setq dired-subdir-alist-pre-R dired-subdir-alist))
3209    ((and (string-match "R" dired-actual-switches)
3210          (not (string-match "R" switches)))
3211     ;; Deleting -R from ls switches -- revert to pre-R subdirs
3212     ;; that are still present:
3213     (setq dired-subdir-alist
3214           (if dired-subdir-alist-pre-R
3215               (let (subdirs)
3216                 (while dired-subdir-alist-pre-R
3217                   (if (assoc (caar dired-subdir-alist-pre-R)
3218                              dired-subdir-alist)
3219                       ;; subdir still present...
3220                       (setq subdirs
3221                             (cons (car dired-subdir-alist-pre-R)
3222                                   subdirs)))
3223                   (setq dired-subdir-alist-pre-R
3224                         (cdr dired-subdir-alist-pre-R)))
3225                 (reverse subdirs))
3226             ;; No pre-R subdir alist, so revert to main directory
3227             ;; listing:
3228             (list (car (reverse dired-subdir-alist))))))))
3229 \f
3230
3231 ;;;;  Drag and drop support
3232
3233 (defcustom dired-recursive-copies 'top
3234   "*Decide whether recursive copies are allowed.
3235 A value of nil means no recursive copies.
3236 `always' means copy recursively without asking.
3237 `top' means ask for each directory at top level.
3238 Anything else means ask for each directory."
3239   :type '(choice :tag "Copy directories"
3240                  (const :tag "No recursive copies" nil)
3241                  (const :tag "Ask for each directory" t)
3242                  (const :tag "Ask for each top directory only" top)
3243                  (const :tag "Copy directories without asking" always))
3244   :group 'dired)
3245
3246 (defun dired-dnd-popup-notice ()
3247   (message-box
3248    "Recursive copies not enabled.\nSee variable dired-recursive-copies."))
3249
3250
3251 (defun dired-dnd-do-ask-action (uri)
3252   ;; No need to get actions and descriptions from the source,
3253   ;; we only have three actions anyway.
3254   (let ((action (x-popup-menu
3255                  t
3256                  (list "What action?"
3257                        (cons ""
3258                              '(("Copy here" . copy)
3259                                ("Move here" . move)
3260                                ("Link here" . link)
3261                                "--"
3262                                ("Cancel" . nil)))))))
3263     (if action
3264         (dired-dnd-handle-local-file uri action)
3265       nil)))
3266
3267 (declare-function dired-relist-entry "dired-aux" (file))
3268
3269 (defun dired-dnd-handle-local-file (uri action)
3270   "Copy, move or link a file to the dired directory.
3271 URI is the file to handle, ACTION is one of copy, move, link or ask.
3272 Ask means pop up a menu for the user to select one of copy, move or link."
3273   (require 'dired-aux)
3274   (let* ((from (dnd-get-local-file-name uri t))
3275          (to (if from (concat (dired-current-directory)
3276                            (file-name-nondirectory from))
3277                nil)))
3278     (if from
3279         (cond ((or (eq action 'copy)
3280                    (eq action 'private))        ; Treat private as copy.
3281
3282                ;; If copying a directory and dired-recursive-copies is nil,
3283                ;; dired-copy-file silently fails.  Pop up a notice.
3284                (if (and (file-directory-p from)
3285                         (not dired-recursive-copies))
3286                    (dired-dnd-popup-notice)
3287                  (progn
3288                    (dired-copy-file from to 1)
3289                    (dired-relist-entry to)
3290                    action)))
3291
3292                ((eq action 'move)
3293                 (dired-rename-file from to 1)
3294                 (dired-relist-entry to)
3295                 action)
3296
3297                ((eq action 'link)
3298                 (make-symbolic-link from to 1)
3299                 (dired-relist-entry to)
3300                 action)
3301
3302                ((eq action 'ask)
3303                 (dired-dnd-do-ask-action uri))
3304
3305                (t nil)))))
3306
3307 (defun dired-dnd-handle-file (uri action)
3308   "Copy, move or link a file to the dired directory if it is a local file.
3309 URI is the file to handle.  If the hostname in the URI isn't local, do nothing.
3310 ACTION is one of copy, move, link or ask.
3311 Ask means pop up a menu for the user to select one of copy, move or link."
3312   (let ((local-file (dnd-get-local-file-uri uri)))
3313     (if local-file (dired-dnd-handle-local-file local-file action)
3314       nil)))
3315 \f
3316
3317 ;;;;  Desktop support
3318
3319 (eval-when-compile (require 'desktop))
3320
3321 (defun dired-desktop-buffer-misc-data (desktop-dirname)
3322   "Auxiliary information to be saved in desktop file."
3323   (cons
3324    ;; Value of `dired-directory'.
3325    (if (consp dired-directory)
3326        ;; Directory name followed by list of files.
3327        (cons (desktop-file-name (car dired-directory) desktop-dirname)
3328              (cdr dired-directory))
3329      ;; Directory name, optionally with shell wildcard.
3330      (desktop-file-name dired-directory desktop-dirname))
3331    ;; Subdirectories in `dired-subdir-alist'.
3332    (cdr
3333      (nreverse
3334        (mapcar
3335          (function (lambda (f) (desktop-file-name (car f) desktop-dirname)))
3336          dired-subdir-alist)))))
3337
3338 (defun dired-restore-desktop-buffer (desktop-buffer-file-name
3339                                      desktop-buffer-name
3340                                      desktop-buffer-misc)
3341   "Restore a dired buffer specified in a desktop file."
3342   ;; First element of `desktop-buffer-misc' is the value of `dired-directory'.
3343   ;; This value is a directory name, optionally with shell wildcard or
3344   ;; a directory name followed by list of files.
3345   (let* ((dired-dir (car desktop-buffer-misc))
3346          (dir (if (consp dired-dir) (car dired-dir) dired-dir)))
3347     (if (file-directory-p (file-name-directory dir))
3348         (progn
3349           (dired dired-dir)
3350           ;; The following elements of `desktop-buffer-misc' are the keys
3351           ;; from `dired-subdir-alist'.
3352           (mapc 'dired-maybe-insert-subdir (cdr desktop-buffer-misc))
3353           (current-buffer))
3354       (message "Desktop: Directory %s no longer exists." dir)
3355       (when desktop-missing-file-warning (sit-for 1))
3356       nil)))
3357
3358 (add-to-list 'desktop-buffer-mode-handlers
3359              '(dired-mode . dired-restore-desktop-buffer))
3360
3361 \f
3362 (if (eq system-type 'vax-vms)
3363     (load "dired-vms"))
3364
3365 (provide 'dired)
3366
3367 (run-hooks 'dired-load-hook)            ; for your customizations
3368
3369 ;; arch-tag: e1af7a8f-691c-41a0-aac1-ddd4d3c87517
3370 ;;; dired.el ends here