lisp/emacs-lisp/debug.el

   1 ;;; debug.el --- debuggers and related commands for Emacs  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1994, 2001-2014 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: lisp, tools, maint
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This is a major mode documented in the Emacs Lisp manual.
  27
  28 ;;; Code:
  29
  30 (require 'button)
  31
  32 (defgroup debugger nil
  33   "Debuggers and related commands for Emacs."
  34   :prefix "debugger-"
  35   :group 'debug)
  36
  37 (defcustom debugger-mode-hook nil
  38   "Hooks run when `debugger-mode' is turned on."
  39   :type 'hook
  40   :group 'debugger
  41   :version "20.3")
  42
  43 (defcustom debugger-batch-max-lines 40
  44   "Maximum lines to show in debugger buffer in a noninteractive Emacs.
  45 When the debugger is entered and Emacs is running in batch mode,
  46 if the backtrace text has more than this many lines,
  47 the middle is discarded, and just the beginning and end are displayed."
  48   :type 'integer
  49   :group 'debugger
  50   :version "21.1")
  51
  52 (defcustom debugger-bury-or-kill 'bury
  53   "What to do with the debugger buffer when exiting `debug'.
  54 The value affects the behavior of operations on any window
  55 previously showing the debugger buffer.
  56
  57 `nil' means that if its window is not deleted when exiting the
  58   debugger, invoking `switch-to-prev-buffer' will usually show
  59   the debugger buffer again.
  60
  61 `append' means that if the window is not deleted, the debugger
  62   buffer moves to the end of the window's previous buffers so
  63   it's less likely that a future invocation of
  64   `switch-to-prev-buffer' will switch to it.  Also, it moves the
  65   buffer to the end of the frame's buffer list.
  66
  67 `bury' means that if the window is not deleted, its buffer is
  68   removed from the window's list of previous buffers.  Also, it
  69   moves the buffer to the end of the frame's buffer list.  This
  70   value provides the most reliable remedy to not have
  71   `switch-to-prev-buffer' switch to the debugger buffer again
  72   without killing the buffer.
  73
  74 `kill' means to kill the debugger buffer.
  75
  76 The value used here is passed to `quit-restore-window'."
  77   :type '(choice
  78           (const :tag "Keep alive" nil)
  79           (const :tag "Append" append)
  80           (const :tag "Bury" bury)
  81           (const :tag "Kill" kill))
  82   :group 'debugger
  83   :version "24.3")
  84
  85 (defvar debugger-step-after-exit nil
  86   "Non-nil means \"single-step\" after the debugger exits.")
  87
  88 (defvar debugger-value nil
  89   "This is the value for the debugger to return, when it returns.")
  90
  91 (defvar debugger-old-buffer nil
  92   "This is the buffer that was current when the debugger was entered.")
  93
  94 (defvar debugger-previous-window nil
  95   "This is the window last showing the debugger buffer.")
  96
  97 (defvar debugger-previous-window-height nil
  98   "The last recorded height of `debugger-previous-window'.")
  99
 100 (defvar debugger-previous-backtrace nil
 101   "The contents of the previous backtrace (including text properties).
 102 This is to optimize `debugger-make-xrefs'.")
 103
 104 (defvar debugger-outer-match-data)
 105 (defvar debugger-will-be-back nil
 106   "Non-nil if we expect to get back in the debugger soon.")
 107
 108 (defvar inhibit-debug-on-entry nil
 109   "Non-nil means that debug-on-entry is disabled.")
 110
 111 (defvar debugger-jumping-flag nil
 112   "Non-nil means that debug-on-entry is disabled.
 113 This variable is used by `debugger-jump', `debugger-step-through',
 114 and `debugger-reenable' to temporarily disable debug-on-entry.")
 115
 116 (defvar inhibit-trace)                  ;Not yet implemented.
 117
 118 (defvar debugger-args nil
 119   "Arguments with which the debugger was called.
 120 It is a list expected to take the form (CAUSE . REST)
 121 where CAUSE can be:
 122 - debug: called for entry to a flagged function.
 123 - t: called because of debug-on-next-call.
 124 - lambda: same thing but via `funcall'.
 125 - exit: called because of exit of a flagged function.
 126 - error: called because of `debug-on-error'.")
 127
 128 ;;;###autoload
 129 (setq debugger 'debug)
 130 ;;;###autoload
 131 (defun debug (&rest args)
 132   "Enter debugger.  \\<debugger-mode-map>`\\[debugger-continue]' returns from the debugger.
 133 Arguments are mainly for use when this is called from the internals
 134 of the evaluator.
 135
 136 You may call with no args, or you may pass nil as the first arg and
 137 any other args you like.  In that case, the list of args after the
 138 first will be printed into the backtrace buffer."
 139   (interactive)
 140   (if inhibit-redisplay
 141       ;; Don't really try to enter debugger within an eval from redisplay.
 142       debugger-value
 143     (unless noninteractive
 144       (message "Entering debugger..."))
 145     (let (debugger-value
 146           (debugger-previous-state
 147            (if (get-buffer "*Backtrace*")
 148                (with-current-buffer (get-buffer "*Backtrace*")
 149                  (list major-mode (buffer-string)))))
 150           (debugger-args args)
 151           (debugger-buffer (get-buffer-create "*Backtrace*"))
 152           (debugger-old-buffer (current-buffer))
 153           (debugger-window nil)
 154           (debugger-step-after-exit nil)
 155           (debugger-will-be-back nil)
 156           ;; Don't keep reading from an executing kbd macro!
 157           (executing-kbd-macro nil)
 158           ;; Save the outer values of these vars for the `e' command
 159           ;; before we replace the values.
 160           (debugger-outer-match-data (match-data))
 161           (debugger-with-timeout-suspend (with-timeout-suspend)))
 162       ;; Set this instead of binding it, so that `q'
 163       ;; will not restore it.
 164       (setq overriding-terminal-local-map nil)
 165       ;; Don't let these magic variables affect the debugger itself.
 166       (let ((last-command nil) this-command track-mouse
 167             (inhibit-trace t)
 168             (inhibit-debug-on-entry t)
 169             unread-command-events
 170             unread-post-input-method-events
 171             last-input-event last-command-event last-nonmenu-event
 172             last-event-frame
 173             overriding-local-map
 174             load-read-function
 175             ;; If we are inside a minibuffer, allow nesting
 176             ;; so that we don't get an error from the `e' command.
 177             (enable-recursive-minibuffers
 178              (or enable-recursive-minibuffers (> (minibuffer-depth) 0)))
 179             (standard-input t) (standard-output t)
 180             inhibit-redisplay
 181             (cursor-in-echo-area nil)
 182             (window-configuration (current-window-configuration)))
 183         (unwind-protect
 184             (save-excursion
 185               (when (eq (car debugger-args) 'debug)
 186                 ;; Skip the frames for backtrace-debug, byte-code,
 187                 ;; debug--implement-debug-on-entry and the advice's `apply'.
 188                 (backtrace-debug 4 t)
 189                 ;; Place an extra debug-on-exit for macro's.
 190                 (when (eq 'lambda (car-safe (cadr (backtrace-frame 4))))
 191                   (backtrace-debug 5 t)))
 192               (pop-to-buffer
 193                debugger-buffer
 194                `((display-buffer-reuse-window
 195                   display-buffer-in-previous-window)
 196                   . (,(when debugger-previous-window
 197                         `(previous-window . ,debugger-previous-window)))))
 198               (setq debugger-window (selected-window))
 199               (if (eq debugger-previous-window debugger-window)
 200                   (when debugger-jumping-flag
 201                     ;; Try to restore previous height of debugger
 202                     ;; window.
 203                     (condition-case nil
 204                         (window-resize
 205                          debugger-window
 206                          (- debugger-previous-window-height
 207                             (window-total-height debugger-window)))
 208                       (error nil)))
 209                 (setq debugger-previous-window debugger-window))
 210               (debugger-mode)
 211               (debugger-setup-buffer debugger-args)
 212               (when noninteractive
 213                 ;; If the backtrace is long, save the beginning
 214                 ;; and the end, but discard the middle.
 215                 (when (> (count-lines (point-min) (point-max))
 216                          debugger-batch-max-lines)
 217                   (goto-char (point-min))
 218                   (forward-line (/ 2 debugger-batch-max-lines))
 219                   (let ((middlestart (point)))
 220                     (goto-char (point-max))
 221                     (forward-line (- (/ 2 debugger-batch-max-lines)
 222                                      debugger-batch-max-lines))
 223                     (delete-region middlestart (point)))
 224                   (insert "...\n"))
 225                 (goto-char (point-min))
 226                 (message "%s" (buffer-string))
 227                 (kill-emacs -1))
 228               (message "")
 229               (let ((standard-output nil)
 230                     (buffer-read-only t))
 231                 (message "")
 232                 ;; Make sure we unbind buffer-read-only in the right buffer.
 233                 (save-excursion
 234                   (recursive-edit))))
 235           (when (and (window-live-p debugger-window)
 236                      (eq (window-buffer debugger-window) debugger-buffer))
 237             ;; Record height of debugger window.
 238             (setq debugger-previous-window-height
 239                   (window-total-height debugger-window)))
 240           (if debugger-will-be-back
 241               ;; Restore previous window configuration (Bug#12623).
 242               (set-window-configuration window-configuration)
 243             (when (and (window-live-p debugger-window)
 244                        (eq (window-buffer debugger-window) debugger-buffer))
 245               (progn
 246                 ;; Unshow debugger-buffer.
 247                 (quit-restore-window debugger-window debugger-bury-or-kill)
 248                 ;; Restore current buffer (Bug#12502).
 249                 (set-buffer debugger-old-buffer))))
 250           ;; Restore previous state of debugger-buffer in case we were
 251           ;; in a recursive invocation of the debugger, otherwise just
 252           ;; erase the buffer and put it into fundamental mode.
 253           (when (buffer-live-p debugger-buffer)
 254             (with-current-buffer debugger-buffer
 255               (let ((inhibit-read-only t))
 256                 (erase-buffer)
 257                 (if (null debugger-previous-state)
 258                     (fundamental-mode)
 259                   (insert (nth 1 debugger-previous-state))
 260                   (funcall (nth 0 debugger-previous-state))))))
 261           (with-timeout-unsuspend debugger-with-timeout-suspend)
 262           (set-match-data debugger-outer-match-data)))
 263       (setq debug-on-next-call debugger-step-after-exit)
 264       debugger-value)))
 265 \f
 266 (defun debugger-setup-buffer (args)
 267   "Initialize the `*Backtrace*' buffer for entry to the debugger.
 268 That buffer should be current already."
 269   (setq buffer-read-only nil)
 270   (erase-buffer)
 271   (set-buffer-multibyte t)              ;Why was it nil ?  -stef
 272   (setq buffer-undo-list t)
 273   (let ((standard-output (current-buffer))
 274         (print-escape-newlines t)
 275         (print-level 8)
 276         (print-length 50))
 277     (backtrace))
 278   (goto-char (point-min))
 279   (insert "Debugger entered")
 280   ;; lambda is for debug-on-call when a function call is next.
 281   ;; debug is for debug-on-entry function called.
 282   (let ((pos (point)))
 283     (pcase (car args)
 284       ((or `lambda `debug)
 285        (insert "--entering a function:\n")
 286        (setq pos (1- (point))))
 287       ;; Exiting a function.
 288       (`exit
 289        (insert "--returning value: ")
 290        (setq pos (point))
 291        (setq debugger-value (nth 1 args))
 292        (prin1 debugger-value (current-buffer))
 293        (insert ?\n)
 294        (delete-char 1)
 295        (insert ? )
 296        (beginning-of-line))
 297       ;; Debugger entered for an error.
 298       (`error
 299        (insert "--Lisp error: ")
 300        (setq pos (point))
 301        (prin1 (nth 1 args) (current-buffer))
 302        (insert ?\n))
 303       ;; debug-on-call, when the next thing is an eval.
 304       (`t
 305        (insert "--beginning evaluation of function call form:\n")
 306        (setq pos (1- (point))))
 307       ;; User calls debug directly.
 308       (_
 309        (insert ": ")
 310        (setq pos (point))
 311        (prin1 (if (eq (car args) 'nil)
 312                   (cdr args) args)
 313               (current-buffer))
 314        (insert ?\n)))
 315     ;; Place point on "stack frame 0" (bug#15101).
 316     (goto-char pos))
 317   ;; After any frame that uses eval-buffer,
 318   ;; insert a line that states the buffer position it's reading at.
 319   (save-excursion
 320     (let ((tem eval-buffer-list))
 321       (while (and tem
 322                   (re-search-forward "^  eval-\\(buffer\\|region\\)(" nil t))
 323         (end-of-line)
 324         (insert (format "  ; Reading at buffer position %d"
 325                         ;; This will get the wrong result
 326                         ;; if there are two nested eval-region calls
 327                         ;; for the same buffer.  That's not a very useful case.
 328                         (with-current-buffer (car tem)
 329                           (point))))
 330         (pop tem))))
 331   (debugger-make-xrefs))
 332
 333 (defun debugger-make-xrefs (&optional buffer)
 334   "Attach cross-references to function names in the `*Backtrace*' buffer."
 335   (interactive "b")
 336   (with-current-buffer (or buffer (current-buffer))
 337     (save-excursion
 338       (setq buffer (current-buffer))
 339       (let ((inhibit-read-only t)
 340             (old-end (point-min)) (new-end (point-min)))
 341         ;; If we saved an old backtrace, find the common part
 342         ;; between the new and the old.
 343         ;; Compare line by line, starting from the end,
 344         ;; because that's the part that is likely to be unchanged.
 345         (if debugger-previous-backtrace
 346             (let (old-start new-start (all-match t))
 347               (goto-char (point-max))
 348               (with-temp-buffer
 349                 (insert debugger-previous-backtrace)
 350                 (while (and all-match (not (bobp)))
 351                   (setq old-end (point))
 352                   (forward-line -1)
 353                   (setq old-start (point))
 354                   (with-current-buffer buffer
 355                     (setq new-end (point))
 356                     (forward-line -1)
 357                     (setq new-start (point)))
 358                   (if (not (zerop
 359                             (let ((case-fold-search nil))
 360                               (compare-buffer-substrings
 361                                (current-buffer) old-start old-end
 362                                buffer new-start new-end))))
 363                       (setq all-match nil))))
 364               ;; Now new-end is the position of the start of the
 365               ;; unchanged part in the current buffer, and old-end is
 366               ;; the position of that same text in the saved old
 367               ;; backtrace.  But we must subtract (point-min) since strings are
 368               ;; indexed in origin 0.
 369
 370               ;; Replace the unchanged part of the backtrace
 371               ;; with the text from debugger-previous-backtrace,
 372               ;; since that already has the proper xrefs.
 373               ;; With this optimization, we only need to scan
 374               ;; the changed part of the backtrace.
 375               (delete-region new-end (point-max))
 376               (goto-char (point-max))
 377               (insert (substring debugger-previous-backtrace
 378                                  (- old-end (point-min))))
 379               ;; Make the unchanged part of the backtrace inaccessible
 380               ;; so it won't be scanned.
 381               (narrow-to-region (point-min) new-end)))
 382
 383         ;; Scan the new part of the backtrace, inserting xrefs.
 384         (goto-char (point-min))
 385         (while (progn
 386                  (goto-char (+ (point) 2))
 387                  (skip-syntax-forward "^w_")
 388                  (not (eobp)))
 389           (let* ((beg (point))
 390                  (end (progn (skip-syntax-forward "w_") (point)))
 391                  (sym (intern-soft (buffer-substring-no-properties
 392                                     beg end)))
 393                  (file (and sym (symbol-file sym 'defun))))
 394             (when file
 395               (goto-char beg)
 396               ;; help-xref-button needs to operate on something matched
 397               ;; by a regexp, so set that up for it.
 398               (re-search-forward "\\(\\sw\\|\\s_\\)+")
 399               (help-xref-button 0 'help-function-def sym file)))
 400           (forward-line 1))
 401         (widen))
 402       (setq debugger-previous-backtrace (buffer-string)))))
 403 \f
 404 (defun debugger-step-through ()
 405   "Proceed, stepping through subexpressions of this expression.
 406 Enter another debugger on next entry to eval, apply or funcall."
 407   (interactive)
 408   (setq debugger-step-after-exit t)
 409   (setq debugger-jumping-flag t)
 410   (setq debugger-will-be-back t)
 411   (add-hook 'post-command-hook 'debugger-reenable)
 412   (message "Proceeding, will debug on next eval or call.")
 413   (exit-recursive-edit))
 414
 415 (defun debugger-continue ()
 416   "Continue, evaluating this expression without stopping."
 417   (interactive)
 418   (unless debugger-may-continue
 419     (error "Cannot continue"))
 420   (message "Continuing.")
 421   (save-excursion
 422     ;; Check to see if we've flagged some frame for debug-on-exit, in which
 423     ;; case we'll probably come back to the debugger soon.
 424     (goto-char (point-min))
 425     (if (re-search-forward "^\\* " nil t)
 426         (setq debugger-will-be-back t)))
 427   (exit-recursive-edit))
 428
 429 (defun debugger-return-value (val)
 430   "Continue, specifying value to return.
 431 This is only useful when the value returned from the debugger
 432 will be used, such as in a debug on exit from a frame."
 433   (interactive "XReturn value (evaluated): ")
 434   (when (memq (car debugger-args) '(t lambda error debug))
 435     (error "Cannot return a value %s"
 436            (if (eq (car debugger-args) 'error)
 437                "from an error" "at function entrance")))
 438   (setq debugger-value val)
 439   (princ "Returning " t)
 440   (prin1 debugger-value)
 441   (save-excursion
 442     ;; Check to see if we've flagged some frame for debug-on-exit, in which
 443     ;; case we'll probably come back to the debugger soon.
 444     (goto-char (point-min))
 445     (if (re-search-forward "^\\* " nil t)
 446         (setq debugger-will-be-back t)))
 447   (exit-recursive-edit))
 448
 449 (defun debugger-jump ()
 450   "Continue to exit from this frame, with all debug-on-entry suspended."
 451   (interactive)
 452   (debugger-frame)
 453   (setq debugger-jumping-flag t)
 454   (add-hook 'post-command-hook 'debugger-reenable)
 455   (message "Continuing through this frame")
 456   (setq debugger-will-be-back t)
 457   (exit-recursive-edit))
 458
 459 (defun debugger-reenable ()
 460   "Turn all debug-on-entry functions back on.
 461 This function is put on `post-command-hook' by `debugger-jump' and
 462 removes itself from that hook."
 463   (setq debugger-jumping-flag nil)
 464   (remove-hook 'post-command-hook 'debugger-reenable))
 465
 466 (defun debugger-frame-number (&optional skip-base)
 467   "Return number of frames in backtrace before the one point points at."
 468   (save-excursion
 469     (beginning-of-line)
 470     (if (looking-at " *;;;\\|[a-z]")
 471         (error "This line is not a function call"))
 472     (let ((opoint (point))
 473           (count 0))
 474       (unless skip-base
 475         (while (not (eq (cadr (backtrace-frame count)) 'debug))
 476           (setq count (1+ count)))
 477         ;; Skip debug--implement-debug-on-entry frame.
 478         (when (eq 'debug--implement-debug-on-entry
 479                   (cadr (backtrace-frame (1+ count))))
 480           (setq count (+ 2 count))))
 481       (goto-char (point-min))
 482       (when (looking-at "Debugger entered--\\(Lisp error\\|returning value\\):")
 483         (goto-char (match-end 0))
 484         (forward-sexp 1))
 485       (forward-line 1)
 486       (while (progn
 487                (forward-char 2)
 488                (cond ((debugger--locals-visible-p)
 489                       (goto-char (next-single-char-property-change
 490                                   (point) 'locals-visible)))
 491                      ((= (following-char) ?\()
 492                       (forward-sexp 1))
 493                      (t
 494                       (forward-sexp 2)))
 495                (forward-line 1)
 496                (<= (point) opoint))
 497         (if (looking-at " *;;;")
 498             (forward-line 1))
 499         (setq count (1+ count)))
 500       count)))
 501
 502 (defun debugger-frame ()
 503   "Request entry to debugger when this frame exits.
 504 Applies to the frame whose line point is on in the backtrace."
 505   (interactive)
 506   (backtrace-debug (debugger-frame-number) t)
 507   (beginning-of-line)
 508   (if (= (following-char) ? )
 509       (let ((inhibit-read-only t))
 510         (delete-char 1)
 511         (insert ?*)))
 512   (beginning-of-line))
 513
 514 (defun debugger-frame-clear ()
 515   "Do not enter debugger when this frame exits.
 516 Applies to the frame whose line point is on in the backtrace."
 517   (interactive)
 518   (backtrace-debug (debugger-frame-number) nil)
 519   (beginning-of-line)
 520   (if (= (following-char) ?*)
 521       (let ((inhibit-read-only t))
 522         (delete-char 1)
 523         (insert ? )))
 524   (beginning-of-line))
 525
 526 (defmacro debugger-env-macro (&rest body)
 527   "Run BODY in original environment."
 528   (declare (indent 0))
 529   `(save-excursion
 530     (if (null (buffer-live-p debugger-old-buffer))
 531         ;; old buffer deleted
 532         (setq debugger-old-buffer (current-buffer)))
 533     (set-buffer debugger-old-buffer)
 534     (set-match-data debugger-outer-match-data)
 535     (prog1
 536         (progn ,@body)
 537       (setq debugger-outer-match-data (match-data)))))
 538
 539 (defun debugger--backtrace-base ()
 540   "Return the function name that marks the top of the backtrace.
 541 See `backtrace-frame'."
 542   (cond ((eq 'debug--implement-debug-on-entry
 543              (cadr (backtrace-frame 1 'debug)))
 544          'debug--implement-debug-on-entry)
 545         (t 'debug)))
 546
 547 (defun debugger-eval-expression (exp &optional nframe)
 548   "Eval an expression, in an environment like that outside the debugger.
 549 The environment used is the one when entering the activation frame at point."
 550   (interactive
 551    (list (read--expression "Eval in stack frame: ")))
 552   (let ((nframe (or nframe
 553                     (condition-case nil (1+ (debugger-frame-number 'skip-base))
 554                       (error 0)))) ;; If on first line.
 555         (base (debugger--backtrace-base)))
 556     (debugger-env-macro
 557       (let ((val (backtrace-eval exp nframe base)))
 558         (prog1
 559             (prin1 val t)
 560           (let ((str (eval-expression-print-format val)))
 561             (if str (princ str t))))))))
 562
 563 (defun debugger--locals-visible-p ()
 564   "Are the local variables of the current stack frame visible?"
 565   (save-excursion
 566     (move-to-column 2)
 567     (get-text-property (point) 'locals-visible)))
 568
 569 (defun debugger--insert-locals (locals)
 570   "Insert the local variables LOCALS at point."
 571   (cond ((null locals)
 572          (insert "\n    [no locals]"))
 573         (t
 574          (let ((print-escape-newlines t))
 575            (dolist (s+v locals)
 576              (let ((symbol (car s+v))
 577                    (value (cdr s+v)))
 578                (insert "\n    ")
 579                (prin1 symbol (current-buffer))
 580                (insert " = ")
 581                (prin1 value (current-buffer))))))))
 582
 583 (defun debugger--show-locals ()
 584   "For the frame at point, insert locals and add text properties."
 585   (let* ((nframe (1+ (debugger-frame-number 'skip-base)))
 586          (base (debugger--backtrace-base))
 587          (locals (backtrace--locals nframe base))
 588          (inhibit-read-only t))
 589     (save-excursion
 590       (let ((start (progn
 591                      (move-to-column 2)
 592                      (point))))
 593         (end-of-line)
 594         (debugger--insert-locals locals)
 595         (add-text-properties start (point) '(locals-visible t))))))
 596
 597 (defun debugger--hide-locals ()
 598   "Delete local variables and remove the text property."
 599   (let* ((col (current-column))
 600          (end (progn
 601                 (move-to-column 2)
 602                 (next-single-char-property-change (point) 'locals-visible)))
 603          (start (previous-single-char-property-change end 'locals-visible))
 604          (inhibit-read-only t))
 605     (remove-text-properties start end '(locals-visible))
 606     (goto-char start)
 607     (end-of-line)
 608     (delete-region (point) end)
 609     (move-to-column col)))
 610
 611 (defun debugger-toggle-locals ()
 612   "Show or hide local variables of the current stack frame."
 613   (interactive)
 614   (cond ((debugger--locals-visible-p)
 615          (debugger--hide-locals))
 616         (t
 617          (debugger--show-locals))))
 618
 619 \f
 620 (defvar debugger-mode-map
 621   (let ((map (make-keymap))
 622         (menu-map (make-sparse-keymap)))
 623     (set-keymap-parent map button-buffer-map)
 624     (suppress-keymap map)
 625     (define-key map "-" 'negative-argument)
 626     (define-key map "b" 'debugger-frame)
 627     (define-key map "c" 'debugger-continue)
 628     (define-key map "j" 'debugger-jump)
 629     (define-key map "r" 'debugger-return-value)
 630     (define-key map "u" 'debugger-frame-clear)
 631     (define-key map "d" 'debugger-step-through)
 632     (define-key map "l" 'debugger-list-functions)
 633     (define-key map "h" 'describe-mode)
 634     (define-key map "q" 'top-level)
 635     (define-key map "e" 'debugger-eval-expression)
 636     (define-key map "v" 'debugger-toggle-locals) ; "v" is for "variables".
 637     (define-key map " " 'next-line)
 638     (define-key map "R" 'debugger-record-expression)
 639     (define-key map "\C-m" 'debug-help-follow)
 640     (define-key map [mouse-2] 'push-button)
 641     (define-key map [menu-bar debugger] (cons "Debugger" menu-map))
 642     (define-key menu-map [deb-top]
 643       '(menu-item "Quit" top-level
 644                   :help "Quit debugging and return to top level"))
 645     (define-key menu-map [deb-s0] '("--"))
 646     (define-key menu-map [deb-descr]
 647       '(menu-item "Describe Debugger Mode" describe-mode
 648                   :help "Display documentation for debugger-mode"))
 649     (define-key menu-map [deb-hfol]
 650       '(menu-item "Help Follow" debug-help-follow
 651                   :help "Follow cross-reference"))
 652     (define-key menu-map [deb-nxt]
 653       '(menu-item "Next Line" next-line
 654                   :help "Move cursor down"))
 655     (define-key menu-map [deb-s1] '("--"))
 656     (define-key menu-map [deb-lfunc]
 657       '(menu-item "List debug on entry functions" debugger-list-functions
 658                   :help "Display a list of all the functions now set to debug on entry"))
 659     (define-key menu-map [deb-fclear]
 660       '(menu-item "Cancel debug frame" debugger-frame-clear
 661                   :help "Do not enter debugger when this frame exits"))
 662     (define-key menu-map [deb-frame]
 663       '(menu-item "Debug frame" debugger-frame
 664                   :help "Request entry to debugger when this frame exits"))
 665     (define-key menu-map [deb-s2] '("--"))
 666     (define-key menu-map [deb-ret]
 667       '(menu-item "Return value..." debugger-return-value
 668                   :help "Continue, specifying value to return."))
 669     (define-key menu-map [deb-rec]
 670       '(menu-item "Display and Record Expression" debugger-record-expression
 671                   :help "Display a variable's value and record it in `*Backtrace-record*' buffer"))
 672     (define-key menu-map [deb-eval]
 673       '(menu-item "Eval Expression..." debugger-eval-expression
 674                   :help "Eval an expression, in an environment like that outside the debugger"))
 675     (define-key menu-map [deb-jump]
 676       '(menu-item "Jump" debugger-jump
 677                   :help "Continue to exit from this frame, with all debug-on-entry suspended"))
 678     (define-key menu-map [deb-cont]
 679       '(menu-item "Continue" debugger-continue
 680         :help "Continue, evaluating this expression without stopping"))
 681     (define-key menu-map [deb-step]
 682       '(menu-item "Step through" debugger-step-through
 683         :help "Proceed, stepping through subexpressions of this expression"))
 684     map))
 685
 686 (put 'debugger-mode 'mode-class 'special)
 687
 688 (define-derived-mode debugger-mode fundamental-mode "Debugger"
 689   "Mode for backtrace buffers, selected in debugger.
 690 \\<debugger-mode-map>
 691 A line starts with `*' if exiting that frame will call the debugger.
 692 Type \\[debugger-frame] or \\[debugger-frame-clear] to set or remove the `*'.
 693
 694 When in debugger due to frame being exited,
 695 use the \\[debugger-return-value] command to override the value
 696 being returned from that frame.
 697
 698 Use \\[debug-on-entry] and \\[cancel-debug-on-entry] to control
 699 which functions will enter the debugger when called.
 700
 701 Complete list of commands:
 702 \\{debugger-mode-map}"
 703   (setq truncate-lines t)
 704   (set-syntax-table emacs-lisp-mode-syntax-table)
 705   (use-local-map debugger-mode-map))
 706 \f
 707 (defcustom debugger-record-buffer "*Debugger-record*"
 708   "Buffer name for expression values, for \\[debugger-record-expression]."
 709   :type 'string
 710   :group 'debugger
 711   :version "20.3")
 712
 713 (defun debugger-record-expression  (exp)
 714   "Display a variable's value and record it in `*Backtrace-record*' buffer."
 715   (interactive
 716    (list (read--expression "Record Eval: ")))
 717   (let* ((buffer (get-buffer-create debugger-record-buffer))
 718          (standard-output buffer))
 719     (princ (format "Debugger Eval (%s): " exp))
 720     (princ (debugger-eval-expression exp))
 721     (terpri))
 722
 723   (with-current-buffer (get-buffer debugger-record-buffer)
 724     (message "%s"
 725              (buffer-substring (line-beginning-position 0)
 726                                (line-end-position 0)))))
 727
 728 (declare-function help-xref-interned "help-mode" (symbol))
 729
 730 (defun debug-help-follow (&optional pos)
 731   "Follow cross-reference at POS, defaulting to point.
 732
 733 For the cross-reference format, see `help-make-xrefs'."
 734   (interactive "d")
 735   (require 'help-mode)
 736   ;; Ideally we'd just do (call-interactively 'help-follow) except that this
 737   ;; assumes we're already in a *Help* buffer and reuses it, so it ends up
 738   ;; incorrectly "reusing" the *Backtrace* buffer to show the help info.
 739   (unless pos
 740     (setq pos (point)))
 741   (unless (push-button pos)
 742     ;; check if the symbol under point is a function or variable
 743     (let ((sym
 744            (intern
 745             (save-excursion
 746               (goto-char pos) (skip-syntax-backward "w_")
 747               (buffer-substring (point)
 748                                 (progn (skip-syntax-forward "w_")
 749                                        (point)))))))
 750       (when (or (boundp sym) (fboundp sym) (facep sym))
 751         (help-xref-interned sym)))))
 752 \f
 753 ;; When you change this, you may also need to change the number of
 754 ;; frames that the debugger skips.
 755 (defun debug--implement-debug-on-entry (&rest _ignore)
 756   "Conditionally call the debugger.
 757 A call to this function is inserted by `debug-on-entry' to cause
 758 functions to break on entry."
 759   (if (or inhibit-debug-on-entry debugger-jumping-flag)
 760       nil
 761     (funcall debugger 'debug)))
 762
 763 ;;;###autoload
 764 (defun debug-on-entry (function)
 765   "Request FUNCTION to invoke debugger each time it is called.
 766
 767 When called interactively, prompt for FUNCTION in the minibuffer.
 768
 769 This works by modifying the definition of FUNCTION.  If you tell the
 770 debugger to continue, FUNCTION's execution proceeds.  If FUNCTION is a
 771 normal function or a macro written in Lisp, you can also step through
 772 its execution.  FUNCTION can also be a primitive that is not a special
 773 form, in which case stepping is not possible.  Break-on-entry for
 774 primitive functions only works when that function is called from Lisp.
 775
 776 Use \\[cancel-debug-on-entry] to cancel the effect of this command.
 777 Redefining FUNCTION also cancels it."
 778   (interactive
 779    (let ((fn (function-called-at-point)) val)
 780      (when (special-form-p fn)
 781        (setq fn nil))
 782      (setq val (completing-read
 783                 (if fn
 784                     (format "Debug on entry to function (default %s): " fn)
 785                   "Debug on entry to function: ")
 786                 obarray
 787                 #'(lambda (symbol)
 788                     (and (fboundp symbol)
 789                          (not (special-form-p symbol))))
 790                 t nil nil (symbol-name fn)))
 791      (list (if (equal val "") fn (intern val)))))
 792   (advice-add function :before #'debug--implement-debug-on-entry
 793               '((depth . -100)))
 794   function)
 795
 796 (defun debug--function-list ()
 797   "List of functions currently set for debug on entry."
 798   (let ((funs '()))
 799     (mapatoms
 800      (lambda (s)
 801        (when (advice-member-p #'debug--implement-debug-on-entry s)
 802          (push s funs))))
 803     funs))
 804
 805 ;;;###autoload
 806 (defun cancel-debug-on-entry (&optional function)
 807   "Undo effect of \\[debug-on-entry] on FUNCTION.
 808 If FUNCTION is nil, cancel debug-on-entry for all functions.
 809 When called interactively, prompt for FUNCTION in the minibuffer.
 810 To specify a nil argument interactively, exit with an empty minibuffer."
 811   (interactive
 812    (list (let ((name
 813                 (completing-read
 814                  "Cancel debug on entry to function (default all functions): "
 815                  (mapcar #'symbol-name (debug--function-list)) nil t)))
 816            (when name
 817              (unless (string= name "")
 818                (intern name))))))
 819   (if function
 820       (progn
 821         (advice-remove function #'debug--implement-debug-on-entry)
 822         function)
 823     (message "Canceling debug-on-entry for all functions")
 824     (mapcar #'cancel-debug-on-entry (debug--function-list))))
 825
 826 (defun debugger-list-functions ()
 827   "Display a list of all the functions now set to debug on entry."
 828   (interactive)
 829   (require 'help-mode)
 830   (help-setup-xref '(debugger-list-functions)
 831                    (called-interactively-p 'interactive))
 832   (with-output-to-temp-buffer (help-buffer)
 833     (with-current-buffer standard-output
 834       (let ((funs (debug--function-list)))
 835         (if (null funs)
 836             (princ "No debug-on-entry functions now\n")
 837           (princ "Functions set to debug on entry:\n\n")
 838           (dolist (fun funs)
 839             (make-text-button (point) (progn (prin1 fun) (point))
 840                               'type 'help-function
 841                               'help-args (list fun))
 842             (terpri))
 843           (terpri)
 844           (princ "Note: if you have redefined a function, then it may no longer\n")
 845           (princ "be set to debug on entry, even if it is in the list."))))))
 846
 847 (provide 'debug)
 848
 849 ;;; debug.el ends here