lisp/tar-mode.el

   1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
   2
   3 ;; Copyright (C) 1990,91,93,94,95,96,97,98,99,2000,2001
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 04 Apr 1990
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package attempts to make dealing with Unix 'tar' archives easier.
  31 ;; When this code is loaded, visiting a file whose name ends in '.tar' will
  32 ;; cause the contents of that archive file to be displayed in a Dired-like
  33 ;; listing.  It is then possible to use the customary Dired keybindings to
  34 ;; extract sub-files from that archive, either by reading them into their own
  35 ;; editor buffers, or by copying them directly to arbitrary files on disk.
  36 ;; It is also possible to delete sub-files from within the tar file and write
  37 ;; the modified archive back to disk, or to edit sub-files within the archive
  38 ;; and re-insert the modified files into the archive.  See the documentation
  39 ;; string of tar-mode for more info.
  40
  41 ;; This code now understands the extra fields that GNU tar adds to tar files.
  42
  43 ;; This interacts correctly with "uncompress.el" in the Emacs library,
  44 ;; which you get with
  45 ;;
  46 ;;  (autoload 'uncompress-while-visiting "uncompress")
  47 ;;  (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
  48 ;;                         auto-mode-alist))
  49 ;;
  50 ;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
  51
  52 ;;    ***************   TO DO   ***************
  53 ;;
  54 ;; o  chmod should understand "a+x,og-w".
  55 ;;
  56 ;; o  It's not possible to add a NEW file to a tar archive; not that
  57 ;;    important, but still...
  58 ;;
  59 ;; o  The code is less efficient that it could be - in a lot of places, I
  60 ;;    pull a 512-character string out of the buffer and parse it, when I could
  61 ;;    be parsing it in place, not garbaging a string.  Should redo that.
  62 ;;
  63 ;; o  I'd like a command that searches for a string/regexp in every subfile
  64 ;;    of an archive, where <esc> would leave you in a subfile-edit buffer.
  65 ;;    (Like the Meta-R command of the Zmacs mail reader.)
  66 ;;
  67 ;; o  Sometimes (but not always) reverting the tar-file buffer does not
  68 ;;    re-grind the listing, and you are staring at the binary tar data.
  69 ;;    Typing 'g' again immediately after that will always revert and re-grind
  70 ;;    it, though.  I have no idea why this happens.
  71 ;;
  72 ;; o  Tar-mode interacts poorly with crypt.el and zcat.el because the tar
  73 ;;    write-file-hook actually writes the file.  Instead it should remove the
  74 ;;    header (and conspire to put it back afterwards) so that other write-file
  75 ;;    hooks which frob the buffer have a chance to do their dirty work.  There
  76 ;;    might be a problem if the tar write-file-hook does not come *first* on
  77 ;;    the list.
  78 ;;
  79 ;; o  Block files, sparse files, continuation files, and the various header
  80 ;;    types aren't editable.  Actually I don't know that they work at all.
  81
  82 ;; Rationale:
  83
  84 ;; Why does tar-mode edit the file itself instead of using tar?
  85
  86 ;; That means that you can edit tar files which you don't have room for
  87 ;; on your local disk.
  88
  89 ;; I don't know about recent features in gnu tar, but old versions of tar
  90 ;; can't replace a file in the middle of a tar file with a new version.
  91 ;; Tar-mode can.  I don't think tar can do things like chmod the subfiles.
  92 ;; An implementation which involved unpacking and repacking the file into
  93 ;; some scratch directory would be very wasteful, and wouldn't be able to
  94 ;; preserve the file owners.
  95
  96 ;;; Code:
  97
  98 (defgroup tar nil
  99   "Simple editing of tar files."
 100   :prefix "tar-"
 101   :group 'data)
 102
 103 (defcustom tar-anal-blocksize 20
 104   "*The blocksize of tar files written by Emacs, or nil, meaning don't care.
 105 The blocksize of a tar file is not really the size of the blocks; rather, it is
 106 the number of blocks written with one system call.  When tarring to a tape,
 107 this is the size of the *tape* blocks, but when writing to a file, it doesn't
 108 matter much.  The only noticeable difference is that if a tar file does not
 109 have a blocksize of 20, tar will tell you that; all this really controls is
 110 how many null padding bytes go on the end of the tar file."
 111   :type '(choice integer (const nil))
 112   :group 'tar)
 113
 114 (defcustom tar-update-datestamp nil
 115   "*Non-nil means Tar mode should play fast and loose with sub-file datestamps.
 116 If this is true, then editing and saving a tar file entry back into its
 117 tar file will update its datestamp.  If false, the datestamp is unchanged.
 118 You may or may not want this - it is good in that you can tell when a file
 119 in a tar archive has been changed, but it is bad for the same reason that
 120 editing a file in the tar archive at all is bad - the changed version of
 121 the file never exists on disk."
 122   :type 'boolean
 123   :group 'tar)
 124
 125 (defcustom tar-mode-show-date nil
 126   "*Non-nil means Tar mode should show the date/time of each subfile.
 127 This information is useful, but it takes screen space away from file names."
 128   :type 'boolean
 129   :group 'tar)
 130
 131 (defvar tar-parse-info nil)
 132 (defvar tar-header-offset nil)
 133 (defvar tar-superior-buffer nil)
 134 (defvar tar-superior-descriptor nil)
 135 (defvar tar-subfile-mode nil)
 136 (defvar tar-file-name-coding-system nil)
 137
 138 (put 'tar-parse-info 'permanent-local t)
 139 (put 'tar-header-offset 'permanent-local t)
 140 (put 'tar-superior-buffer 'permanent-local t)
 141 (put 'tar-superior-descriptor 'permanent-local t)
 142 (put 'tar-file-name-coding-system 'permanent-local t)
 143 \f
 144 (defmacro tar-setf (form val)
 145   "A mind-numbingly simple implementation of setf."
 146   (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
 147                                       byte-compile-macro-environment))))
 148     (cond ((symbolp mform) (list 'setq mform val))
 149           ((not (consp mform)) (error "can't setf %s" form))
 150           ((eq (car mform) 'aref)
 151            (list 'aset (nth 1 mform) (nth 2 mform) val))
 152           ((eq (car mform) 'car)
 153            (list 'setcar (nth 1 mform) val))
 154           ((eq (car mform) 'cdr)
 155            (list 'setcdr (nth 1 mform) val))
 156           (t (error "don't know how to setf %s" form)))))
 157 \f
 158 ;;; down to business.
 159
 160 (defmacro make-tar-header (name mode uid git size date ck lt ln
 161                            magic uname gname devmaj devmin)
 162   (list 'vector name mode uid git size date ck lt ln
 163         magic uname gname devmaj devmin))
 164
 165 (defmacro tar-header-name (x) (list 'aref x 0))
 166 (defmacro tar-header-mode (x) (list 'aref x 1))
 167 (defmacro tar-header-uid  (x) (list 'aref x 2))
 168 (defmacro tar-header-gid  (x) (list 'aref x 3))
 169 (defmacro tar-header-size (x) (list 'aref x 4))
 170 (defmacro tar-header-date (x) (list 'aref x 5))
 171 (defmacro tar-header-checksum  (x) (list 'aref x 6))
 172 (defmacro tar-header-link-type (x) (list 'aref x 7))
 173 (defmacro tar-header-link-name (x) (list 'aref x 8))
 174 (defmacro tar-header-magic (x) (list 'aref x 9))
 175 (defmacro tar-header-uname (x) (list 'aref x 10))
 176 (defmacro tar-header-gname (x) (list 'aref x 11))
 177 (defmacro tar-header-dmaj (x) (list 'aref x 12))
 178 (defmacro tar-header-dmin (x) (list 'aref x 13))
 179
 180 (defmacro make-tar-desc (data-start tokens)
 181   (list 'cons data-start tokens))
 182
 183 (defmacro tar-desc-data-start (x) (list 'car x))
 184 (defmacro tar-desc-tokens     (x) (list 'cdr x))
 185
 186 (defconst tar-name-offset 0)
 187 (defconst tar-mode-offset (+ tar-name-offset 100))
 188 (defconst tar-uid-offset  (+ tar-mode-offset 8))
 189 (defconst tar-gid-offset  (+ tar-uid-offset 8))
 190 (defconst tar-size-offset (+ tar-gid-offset 8))
 191 (defconst tar-time-offset (+ tar-size-offset 12))
 192 (defconst tar-chk-offset  (+ tar-time-offset 12))
 193 (defconst tar-linkp-offset (+ tar-chk-offset 8))
 194 (defconst tar-link-offset (+ tar-linkp-offset 1))
 195 ;;; GNU-tar specific slots.
 196 (defconst tar-magic-offset (+ tar-link-offset 100))
 197 (defconst tar-uname-offset (+ tar-magic-offset 8))
 198 (defconst tar-gname-offset (+ tar-uname-offset 32))
 199 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
 200 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
 201 (defconst tar-end-offset (+ tar-dmin-offset 8))
 202
 203 (defun tar-header-block-tokenize (string)
 204   "Return a `tar-header' structure.
 205 This is a list of name, mode, uid, gid, size,
 206 write-date, checksum, link-type, and link-name."
 207   (cond ((< (length string) 512) nil)
 208         (;(some 'plusp string)           ; <-- oops, massive cycle hog!
 209          (or (not (= 0 (aref string 0))) ; This will do.
 210              (not (= 0 (aref string 101))))
 211          (let* ((name-end (1- tar-mode-offset))
 212                 (link-end (1- tar-magic-offset))
 213                 (uname-end (1- tar-gname-offset))
 214                 (gname-end (1- tar-dmaj-offset))
 215                 (link-p (aref string tar-linkp-offset))
 216                 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
 217                 (uname-valid-p (or (string= "ustar  " magic-str) (string= "GNUtar " magic-str)))
 218                 name linkname
 219                 (nulsexp   "[^\000]*\000"))
 220            (when (string-match nulsexp string tar-name-offset)
 221              (setq name-end (min name-end (1- (match-end 0)))))
 222            (when (string-match nulsexp string tar-link-offset)
 223              (setq link-end (min link-end (1- (match-end 0)))))
 224            (when (string-match nulsexp string tar-uname-offset)
 225              (setq uname-end (min uname-end (1- (match-end 0)))))
 226            (when (string-match nulsexp string tar-gname-offset)
 227              (setq gname-end (min gname-end (1- (match-end 0)))))
 228            (setq name (substring string tar-name-offset name-end)
 229                  link-p (if (or (= link-p 0) (= link-p ?0))
 230                             nil
 231                           (- link-p ?0)))
 232            (setq linkname (substring string tar-link-offset link-end))
 233            (if default-enable-multibyte-characters
 234                (setq name
 235                      (decode-coding-string name tar-file-name-coding-system)
 236                      linkname
 237                      (decode-coding-string linkname
 238                                            tar-file-name-coding-system)))
 239            (if (and (null link-p) (string-match "/$" name)) (setq link-p 5)) ; directory
 240            (make-tar-header
 241              name
 242              (tar-parse-octal-integer string tar-mode-offset tar-uid-offset)
 243              (tar-parse-octal-integer string tar-uid-offset tar-gid-offset)
 244              (tar-parse-octal-integer string tar-gid-offset tar-size-offset)
 245              (tar-parse-octal-integer string tar-size-offset tar-time-offset)
 246              (tar-parse-octal-long-integer string tar-time-offset tar-chk-offset)
 247              (tar-parse-octal-integer string tar-chk-offset tar-linkp-offset)
 248              link-p
 249              linkname
 250              uname-valid-p
 251              (and uname-valid-p (substring string tar-uname-offset uname-end))
 252              (and uname-valid-p (substring string tar-gname-offset gname-end))
 253              (tar-parse-octal-integer string tar-dmaj-offset tar-dmin-offset)
 254              (tar-parse-octal-integer string tar-dmin-offset tar-end-offset)
 255              )))
 256         (t 'empty-tar-block)))
 257
 258
 259 (defun tar-parse-octal-integer (string &optional start end)
 260   (if (null start) (setq start 0))
 261   (if (null end) (setq end (length string)))
 262   (if (= (aref string start) 0)
 263       0
 264     (let ((n 0))
 265       (while (< start end)
 266         (setq n (if (< (aref string start) ?0) n
 267                   (+ (* n 8) (- (aref string start) ?0)))
 268               start (1+ start)))
 269       n)))
 270
 271 (defun tar-parse-octal-long-integer (string &optional start end)
 272   (if (null start) (setq start 0))
 273   (if (null end) (setq end (length string)))
 274   (if (= (aref string start) 0)
 275       (list 0 0)
 276     (let ((lo 0)
 277           (hi 0))
 278       (while (< start end)
 279         (if (>= (aref string start) ?0)
 280             (setq lo (+ (* lo 8) (- (aref string start) ?0))
 281                   hi (+ (* hi 8) (ash lo -16))
 282                   lo (logand lo 65535)))
 283         (setq start (1+ start)))
 284       (list hi lo))))
 285
 286 (defun tar-parse-octal-integer-safe (string)
 287   (let ((L (length string)))
 288     (if (= L 0) (error "empty string"))
 289     (dotimes (i L)
 290        (if (or (< (aref string i) ?0)
 291                (> (aref string i) ?7))
 292            (error "`%c' is not an octal digit"))))
 293   (tar-parse-octal-integer string))
 294
 295
 296 (defun tar-header-block-checksum (string)
 297   "Compute and return a tar-acceptable checksum for this block."
 298   (let* ((chk-field-start tar-chk-offset)
 299          (chk-field-end (+ chk-field-start 8))
 300          (sum 0)
 301          (i 0))
 302     ;; Add up all of the characters except the ones in the checksum field.
 303     ;; Add that field as if it were filled with spaces.
 304     (while (< i chk-field-start)
 305       (setq sum (+ sum (multibyte-char-to-unibyte (aref string i)))
 306             i (1+ i)))
 307     (setq i chk-field-end)
 308     (while (< i 512)
 309       (setq sum (+ sum (multibyte-char-to-unibyte (aref string i)))
 310             i (1+ i)))
 311     (+ sum (* 32 8))))
 312
 313 (defun tar-header-block-check-checksum (hblock desired-checksum file-name)
 314   "Beep and print a warning if the checksum doesn't match."
 315   (if (not (= desired-checksum (tar-header-block-checksum hblock)))
 316       (progn (beep) (message "Invalid checksum for file %s!" file-name))))
 317
 318 (defun tar-clip-time-string (time)
 319   (let ((str (current-time-string time)))
 320     (concat " " (substring str 4 16) (substring str 19 24))))
 321
 322 (defun tar-grind-file-mode (mode)
 323   "Construct a `-rw--r--r--' string indicating MODE.
 324 MODE should be an integer which is a file mode value."
 325   (string
 326    (if (zerop (logand 256 mode)) ?- ?r)
 327    (if (zerop (logand 128 mode)) ?- ?w)
 328    (if (zerop (logand 1024 mode)) (if (zerop (logand  64 mode)) ?- ?x) ?s)
 329    (if (zerop (logand  32 mode)) ?- ?r)
 330    (if (zerop (logand  16 mode)) ?- ?w)
 331    (if (zerop (logand 2048 mode)) (if (zerop (logand   8 mode)) ?- ?x) ?s)
 332    (if (zerop (logand   4 mode)) ?- ?r)
 333    (if (zerop (logand   2 mode)) ?- ?w)
 334    (if (zerop (logand   1 mode)) ?- ?x)))
 335
 336 (defun tar-header-block-summarize (tar-hblock &optional mod-p)
 337   "Return a line similar to the output of `tar -vtf'."
 338   (let ((name (tar-header-name tar-hblock))
 339         (mode (tar-header-mode tar-hblock))
 340         (uid (tar-header-uid tar-hblock))
 341         (gid (tar-header-gid tar-hblock))
 342         (uname (tar-header-uname tar-hblock))
 343         (gname (tar-header-gname tar-hblock))
 344         (size (tar-header-size tar-hblock))
 345         (time (tar-header-date tar-hblock))
 346         (ck (tar-header-checksum tar-hblock))
 347         (type (tar-header-link-type tar-hblock))
 348         (link-name (tar-header-link-name tar-hblock)))
 349     (format "%c%c%s%8s/%-8s%7s%s %s%s"
 350             (if mod-p ?* ? )
 351             (cond ((or (eq type nil) (eq type 0)) ?-)
 352                   ((eq type 1) ?l)      ; link
 353                   ((eq type 2) ?s)      ; symlink
 354                   ((eq type 3) ?c)      ; char special
 355                   ((eq type 4) ?b)      ; block special
 356                   ((eq type 5) ?d)      ; directory
 357                   ((eq type 6) ?p)      ; FIFO/pipe
 358                   ((eq type 20) ?*)     ; directory listing
 359                   ((eq type 29) ?M)     ; multivolume continuation
 360                   ((eq type 35) ?S)     ; sparse
 361                   ((eq type 38) ?V)     ; volume header
 362                   (t ?\ )
 363                   )
 364             (tar-grind-file-mode mode)
 365             (if (= 0 (length uname)) uid uname)
 366             (if (= 0 (length gname)) gid gname)
 367             size
 368             (if tar-mode-show-date (tar-clip-time-string time) "")
 369             (propertize name
 370                         'mouse-face 'highlight
 371                         'help-echo "mouse-2: extract this file into a buffer")
 372             (if (or (eq type 1) (eq type 2))
 373                 (concat (if (= type 1) " ==> " " --> ") link-name)
 374               ""))))
 375
 376 (defun tar-summarize-buffer ()
 377   "Parse the contents of the tar file in the current buffer.
 378 Place a dired-like listing on the front;
 379 then narrow to it, so that only that listing
 380 is visible (and the real data of the buffer is hidden)."
 381   (set-buffer-multibyte nil)
 382   (message "Parsing tar file...")
 383   (let* ((result '())
 384          (pos 1)
 385          (bs (max 1 (- (buffer-size) 1024))) ; always 2+ empty blocks at end.
 386          (bs100 (max 1 (/ bs 100)))
 387          tokens)
 388     (while (and (<= (+ pos 512) (point-max))
 389                 (not (eq 'empty-tar-block
 390                          (setq tokens
 391                                (tar-header-block-tokenize
 392                                 (buffer-substring pos (+ pos 512)))))))
 393       (setq pos (+ pos 512))
 394       (message "Parsing tar file...%d%%"
 395                ;(/ (* pos 100) bs)   ; this gets round-off lossage
 396                (/ pos bs100)         ; this doesn't
 397                )
 398       (if (eq (tar-header-link-type tokens) 20)
 399           ;; Foo.  There's an extra empty block after these.
 400           (setq pos (+ pos 512)))
 401       (let ((size (tar-header-size tokens)))
 402         (if (< size 0)
 403             (error "%s has size %s - corrupted"
 404                    (tar-header-name tokens) size))
 405         ;
 406         ; This is just too slow.  Don't really need it anyway....
 407         ;(tar-header-block-check-checksum
 408         ;  hblock (tar-header-block-checksum hblock)
 409         ;  (tar-header-name tokens))
 410
 411         (setq result (cons (make-tar-desc pos tokens) result))
 412
 413         (and (null (tar-header-link-type tokens))
 414              (> size 0)
 415              (setq pos
 416                    (+ pos 512 (ash (ash (1- size) -9) 9))        ; this works
 417                    ;(+ pos (+ size (- 512 (rem (1- size) 512)))) ; this doesn't
 418                    ))))
 419     (make-local-variable 'tar-parse-info)
 420     (setq tar-parse-info (nreverse result))
 421     ;; A tar file should end with a block or two of nulls,
 422     ;; but let's not get a fatal error if it doesn't.
 423     (if (eq tokens 'empty-tar-block)
 424         (message "Parsing tar file...done")
 425       (message "Warning: premature EOF parsing tar file")))
 426   (save-excursion
 427     (goto-char (point-min))
 428     (let ((buffer-read-only nil)
 429           (summaries nil))
 430       ;; Collect summary lines and insert them all at once since tar files
 431       ;; can be pretty big.
 432       (dolist (tar-desc (reverse tar-parse-info))
 433         (setq summaries
 434               (cons (tar-header-block-summarize (tar-desc-tokens tar-desc))
 435                     (cons "\n"
 436                           summaries))))
 437       (if default-enable-multibyte-characters
 438           (set-buffer-multibyte t 'to))
 439       (let ((total-summaries (apply 'concat summaries)))
 440         (insert total-summaries))
 441       (make-local-variable 'tar-header-offset)
 442       (setq tar-header-offset (point))
 443       (narrow-to-region 1 tar-header-offset)
 444       (set-buffer-modified-p nil))))
 445 \f
 446 (defvar tar-mode-map nil "*Local keymap for Tar mode listings.")
 447
 448 (if tar-mode-map
 449     nil
 450   (setq tar-mode-map (make-keymap))
 451   (suppress-keymap tar-mode-map)
 452   (define-key tar-mode-map " " 'tar-next-line)
 453   (define-key tar-mode-map "C" 'tar-copy)
 454   (define-key tar-mode-map "d" 'tar-flag-deleted)
 455   (define-key tar-mode-map "\^D" 'tar-flag-deleted)
 456   (define-key tar-mode-map "e" 'tar-extract)
 457   (define-key tar-mode-map "f" 'tar-extract)
 458   (define-key tar-mode-map "\C-m" 'tar-extract)
 459   (define-key tar-mode-map [mouse-2] 'tar-mouse-extract)
 460   (define-key tar-mode-map "g" 'revert-buffer)
 461   (define-key tar-mode-map "h" 'describe-mode)
 462   (define-key tar-mode-map "n" 'tar-next-line)
 463   (define-key tar-mode-map "\^N" 'tar-next-line)
 464   (define-key tar-mode-map [down] 'tar-next-line)
 465   (define-key tar-mode-map "o" 'tar-extract-other-window)
 466   (define-key tar-mode-map "p" 'tar-previous-line)
 467   (define-key tar-mode-map "q" 'quit-window)
 468   (define-key tar-mode-map "\^P" 'tar-previous-line)
 469   (define-key tar-mode-map [up] 'tar-previous-line)
 470   (define-key tar-mode-map "R" 'tar-rename-entry)
 471   (define-key tar-mode-map "u" 'tar-unflag)
 472   (define-key tar-mode-map "v" 'tar-view)
 473   (define-key tar-mode-map "x" 'tar-expunge)
 474   (define-key tar-mode-map "\177" 'tar-unflag-backwards)
 475   (define-key tar-mode-map "E" 'tar-extract-other-window)
 476   (define-key tar-mode-map "M" 'tar-chmod-entry)
 477   (define-key tar-mode-map "G" 'tar-chgrp-entry)
 478   (define-key tar-mode-map "O" 'tar-chown-entry)
 479   )
 480 \f
 481 ;; Make menu bar items.
 482
 483 ;; Get rid of the Edit menu bar item to save space.
 484 (define-key tar-mode-map [menu-bar edit] 'undefined)
 485
 486 (define-key tar-mode-map [menu-bar immediate]
 487   (cons "Immediate" (make-sparse-keymap "Immediate")))
 488
 489 (define-key tar-mode-map [menu-bar immediate view]
 490   '("View This File" . tar-view))
 491 (define-key tar-mode-map [menu-bar immediate display]
 492   '("Display in Other Window" . tar-display-other-window))
 493 (define-key tar-mode-map [menu-bar immediate find-file-other-window]
 494   '("Find in Other Window" . tar-extract-other-window))
 495 (define-key tar-mode-map [menu-bar immediate find-file]
 496   '("Find This File" . tar-extract))
 497
 498 (define-key tar-mode-map [menu-bar mark]
 499   (cons "Mark" (make-sparse-keymap "Mark")))
 500
 501 (define-key tar-mode-map [menu-bar mark unmark-all]
 502   '("Unmark All" . tar-clear-modification-flags))
 503 (define-key tar-mode-map [menu-bar mark deletion]
 504   '("Flag" . tar-flag-deleted))
 505 (define-key tar-mode-map [menu-bar mark unmark]
 506   '("Unflag" . tar-unflag))
 507
 508 (define-key tar-mode-map [menu-bar operate]
 509   (cons "Operate" (make-sparse-keymap "Operate")))
 510
 511 (define-key tar-mode-map [menu-bar operate chown]
 512   '("Change Owner..." . tar-chown-entry))
 513 (define-key tar-mode-map [menu-bar operate chgrp]
 514   '("Change Group..." . tar-chgrp-entry))
 515 (define-key tar-mode-map [menu-bar operate chmod]
 516   '("Change Mode..." . tar-chmod-entry))
 517 (define-key tar-mode-map [menu-bar operate rename]
 518   '("Rename to..." . tar-rename-entry))
 519 (define-key tar-mode-map [menu-bar operate copy]
 520   '("Copy to..." . tar-copy))
 521 (define-key tar-mode-map [menu-bar operate expunge]
 522   '("Expunge Marked Files" . tar-expunge))
 523 \f
 524 ;; tar mode is suitable only for specially formatted data.
 525 (put 'tar-mode 'mode-class 'special)
 526 (put 'tar-subfile-mode 'mode-class 'special)
 527
 528 ;;;###autoload
 529 (define-derived-mode tar-mode nil "Tar"
 530   "Major mode for viewing a tar file as a dired-like listing of its contents.
 531 You can move around using the usual cursor motion commands.
 532 Letters no longer insert themselves.
 533 Type `e' to pull a file out of the tar file and into its own buffer;
 534 or click mouse-2 on the file's line in the Tar mode buffer.
 535 Type `c' to copy an entry from the tar file into another file on disk.
 536
 537 If you edit a sub-file of this archive (as with the `e' command) and
 538 save it with Control-x Control-s, the contents of that buffer will be
 539 saved back into the tar-file buffer; in this way you can edit a file
 540 inside of a tar archive without extracting it and re-archiving it.
 541
 542 See also: variables `tar-update-datestamp' and `tar-anal-blocksize'.
 543 \\{tar-mode-map}"
 544   ;; this is not interactive because you shouldn't be turning this
 545   ;; mode on and off.  You can corrupt things that way.
 546   ;; rms: with permanent locals, it should now be possible to make this work
 547   ;; interactively in some reasonable fashion.
 548   (make-local-variable 'tar-header-offset)
 549   (make-local-variable 'tar-parse-info)
 550   (set (make-local-variable 'require-final-newline) nil) ; binary data, dude...
 551   (set (make-local-variable 'revert-buffer-function) 'tar-mode-revert)
 552   (set (make-local-variable 'local-enable-local-variables) nil)
 553   (set (make-local-variable 'next-line-add-newlines) nil)
 554   (set (make-local-variable 'tar-file-name-coding-system)
 555        (or file-name-coding-system
 556            default-file-name-coding-system
 557            locale-coding-system))
 558   ;; Prevent loss of data when saving the file.
 559   (set (make-local-variable 'file-precious-flag) t)
 560   (auto-save-mode 0)
 561   (set (make-local-variable 'write-contents-hooks) '(tar-mode-write-file))
 562   (widen)
 563   (if (and (boundp 'tar-header-offset) tar-header-offset)
 564       (narrow-to-region 1 tar-header-offset)
 565     (tar-summarize-buffer)
 566     (tar-next-line 0)))
 567
 568
 569 (defun tar-subfile-mode (p)
 570   "Minor mode for editing an element of a tar-file.
 571 This mode arranges for \"saving\" this buffer to write the data
 572 into the tar-file buffer that it came from.  The changes will actually
 573 appear on disk when you save the tar-file's buffer."
 574   (interactive "P")
 575   (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
 576       (error "This buffer is not an element of a tar file"))
 577 ;;; Don't do this, because it is redundant and wastes mode line space.
 578 ;;;  (or (assq 'tar-subfile-mode minor-mode-alist)
 579 ;;;      (setq minor-mode-alist (append minor-mode-alist
 580 ;;;                                  (list '(tar-subfile-mode " TarFile")))))
 581   (make-local-variable 'tar-subfile-mode)
 582   (setq tar-subfile-mode
 583         (if (null p)
 584             (not tar-subfile-mode)
 585             (> (prefix-numeric-value p) 0)))
 586   (cond (tar-subfile-mode
 587          (make-local-variable 'local-write-file-hooks)
 588          (setq local-write-file-hooks '(tar-subfile-save-buffer))
 589          ;; turn off auto-save.
 590          (auto-save-mode -1)
 591          (setq buffer-auto-save-file-name nil)
 592          (run-hooks 'tar-subfile-mode-hook))
 593         (t
 594          (kill-local-variable 'local-write-file-hooks))))
 595
 596
 597 ;; Revert the buffer and recompute the dired-like listing.
 598 (defun tar-mode-revert (&optional no-auto-save no-confirm)
 599   (let ((revert-buffer-function nil)
 600         (old-offset tar-header-offset)
 601         success)
 602     (setq tar-header-offset nil)
 603     (unwind-protect
 604         (and (revert-buffer t no-confirm)
 605              (progn (widen)
 606                     (setq success t)
 607                     (tar-mode)))
 608       ;; If the revert was canceled,
 609       ;; put back the old value of tar-header-offset.
 610       (or success
 611           (setq tar-header-offset old-offset)))))
 612
 613
 614 (defun tar-next-line (arg)
 615   "Move cursor vertically down ARG lines and to the start of the filename."
 616   (interactive "p")
 617   (forward-line arg)
 618   (if (eobp) nil (forward-char (if tar-mode-show-date 54 36))))
 619
 620 (defun tar-previous-line (arg)
 621   "Move cursor vertically up ARG lines and to the start of the filename."
 622   (interactive "p")
 623   (tar-next-line (- arg)))
 624
 625 (defun tar-current-descriptor (&optional noerror)
 626   "Return the tar-descriptor of the current line, or signals an error."
 627   ;; I wish lines had plists, like in ZMACS...
 628   (or (nth (count-lines (point-min)
 629                         (save-excursion (beginning-of-line) (point)))
 630            tar-parse-info)
 631       (if noerror
 632           nil
 633           (error "This line does not describe a tar-file entry"))))
 634
 635 (defun tar-get-descriptor ()
 636   (let* ((descriptor (tar-current-descriptor))
 637          (tokens (tar-desc-tokens descriptor))
 638          (size (tar-header-size tokens))
 639          (link-p (tar-header-link-type tokens)))
 640     (if link-p
 641         (error "This is a %s, not a real file"
 642                (cond ((eq link-p 5) "directory")
 643                      ((eq link-p 20) "tar directory header")
 644                      ((eq link-p 29) "multivolume-continuation")
 645                      ((eq link-p 35) "sparse entry")
 646                      ((eq link-p 38) "volume header")
 647                      (t "link"))))
 648     (if (zerop size) (error "This is a zero-length file"))
 649     descriptor))
 650
 651 (defun tar-mouse-extract (event)
 652   "Extract a file whose tar directory line you click on."
 653   (interactive "e")
 654   (save-excursion
 655     (set-buffer (window-buffer (posn-window (event-end event))))
 656     (save-excursion
 657       (goto-char (posn-point (event-end event)))
 658       ;; Just make sure this doesn't get an error.
 659       (tar-get-descriptor)))
 660   (select-window (posn-window (event-end event)))
 661   (goto-char (posn-point (event-end event)))
 662   (tar-extract))
 663
 664 (defun tar-extract (&optional other-window-p)
 665   "In Tar mode, extract this entry of the tar file into its own buffer."
 666   (interactive)
 667   (let* ((view-p (eq other-window-p 'view))
 668          (descriptor (tar-get-descriptor))
 669          (tokens (tar-desc-tokens descriptor))
 670          (name (tar-header-name tokens))
 671          (size (tar-header-size tokens))
 672          (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
 673          (end (+ start size)))
 674     (let* ((tar-buffer (current-buffer))
 675            (tar-buffer-multibyte enable-multibyte-characters)
 676            (tarname (buffer-name))
 677            (bufname (concat (file-name-nondirectory name)
 678                             " ("
 679                              tarname
 680                              ")"))
 681            (read-only-p (or buffer-read-only view-p))
 682            (new-buffer-file-name (expand-file-name
 683                                   ;; `:' is not allowed on Windows
 684                                   (concat tarname "!" name)))
 685            (buffer (get-file-buffer new-buffer-file-name))
 686            (just-created nil)
 687            (pos (point)))
 688       (unless buffer
 689         (setq buffer (generate-new-buffer bufname))
 690         (setq bufname (buffer-name buffer))
 691         (setq just-created t)
 692         (unwind-protect
 693             (let (coding)
 694               (narrow-to-region start end)
 695               (goto-char start)
 696               (setq coding (or coding-system-for-read
 697                                (and set-auto-coding-function
 698                                     (funcall set-auto-coding-function
 699                                              name (point-max)))))
 700               (if (or (not coding)
 701                       (eq (coding-system-type coding) 'undecided))
 702                   (setq coding (detect-coding-region start end t)))
 703               (if (eq (coding-system-type coding) 'undecided)
 704                   (setq coding
 705                         (coding-system-change-text-conversion coding
 706                                                               'us-ascii)))
 707               (save-excursion
 708                 (set-buffer buffer)
 709                 (if (and enable-multibyte-characters
 710                          (eq (coding-system-type 'raw-text) coding))
 711                     (set-buffer-multibyte nil))
 712                 (goto-char (point-min))
 713                 (setq buffer-file-name new-buffer-file-name)
 714                 (setq buffer-file-truename
 715                       (abbreviate-file-name buffer-file-name)))
 716               (decode-coding-region start end coding buffer)
 717               (save-excursion
 718                 (set-buffer buffer)
 719                 (goto-char (point-min))
 720                 ;; Set the default-directory to the dir of the
 721                 ;; superior buffer.
 722                 (setq default-directory
 723                       (save-excursion
 724                         (set-buffer tar-buffer)
 725                         default-directory))
 726                 (normal-mode)  ; pick a mode.
 727                 (rename-buffer bufname)
 728                 (make-local-variable 'tar-superior-buffer)
 729                 (make-local-variable 'tar-superior-descriptor)
 730                 (setq tar-superior-buffer tar-buffer)
 731                 (setq tar-superior-descriptor descriptor)
 732                 (setq buffer-read-only read-only-p)
 733                 (set-buffer-modified-p nil)
 734                 (tar-subfile-mode 1))
 735               (set-buffer tar-buffer))
 736           (narrow-to-region 1 tar-header-offset)
 737           (goto-char pos)))
 738       (if view-p
 739           (view-buffer buffer (and just-created 'kill-buffer))
 740         (if (eq other-window-p 'display)
 741             (display-buffer buffer)
 742           (if other-window-p
 743               (switch-to-buffer-other-window buffer)
 744             (switch-to-buffer buffer)))))))
 745
 746
 747 (defun tar-extract-other-window ()
 748   "*In Tar mode, find this entry of the tar file in another window."
 749   (interactive)
 750   (tar-extract t))
 751
 752 (defun tar-display-other-window ()
 753   "*In Tar mode, display this entry of the tar file in another window."
 754   (interactive)
 755   (tar-extract 'display))
 756
 757 (defun tar-view ()
 758   "*In Tar mode, view the tar file entry on this line."
 759   (interactive)
 760   (tar-extract 'view))
 761
 762
 763 (defun tar-read-file-name (&optional prompt)
 764   "Read a file name with this line's entry as the default."
 765   (or prompt (setq prompt "Copy to: "))
 766   (let* ((default-file (expand-file-name
 767                         (tar-header-name (tar-desc-tokens
 768                                           (tar-current-descriptor)))))
 769          (target (expand-file-name
 770                   (read-file-name prompt
 771                                   (file-name-directory default-file)
 772                                   default-file nil))))
 773     (if (or (string= "" (file-name-nondirectory target))
 774             (file-directory-p target))
 775         (setq target (concat (if (string-match "/$" target)
 776                                  (substring target 0 (1- (match-end 0)))
 777                                  target)
 778                              "/"
 779                              (file-name-nondirectory default-file))))
 780     target))
 781
 782
 783 (defun tar-copy (&optional to-file)
 784   "*In Tar mode, extract this entry of the tar file into a file on disk.
 785 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
 786 the current tar-entry."
 787   (interactive (list (tar-read-file-name)))
 788   (let* ((descriptor (tar-get-descriptor))
 789          (tokens (tar-desc-tokens descriptor))
 790          (name (tar-header-name tokens))
 791          (size (tar-header-size tokens))
 792          (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
 793          (end (+ start size))
 794          (inhibit-file-name-handlers inhibit-file-name-handlers)
 795          (inhibit-file-name-operation inhibit-file-name-operation))
 796     (save-restriction
 797       (widen)
 798       ;; Inhibit compressing a subfile again if *both* name and
 799       ;; to-file are handled by jka-compr
 800       (if (and (eq (find-file-name-handler name 'write-region) 'jka-compr-handler)
 801                (eq (find-file-name-handler to-file 'write-region) 'jka-compr-handler))
 802           (setq inhibit-file-name-handlers
 803                 (cons 'jka-compr-handler
 804                       (and (eq inhibit-file-name-operation 'write-region)
 805                            inhibit-file-name-handlers))
 806                 inhibit-file-name-operation 'write-region))
 807       (let ((coding-system-for-write 'no-conversion))
 808         (write-region start end to-file nil nil nil t)))
 809     (message "Copied tar entry %s to %s" name to-file)))
 810
 811 (defun tar-flag-deleted (p &optional unflag)
 812   "*In Tar mode, mark this sub-file to be deleted from the tar file.
 813 With a prefix argument, mark that many files."
 814   (interactive "p")
 815   (beginning-of-line)
 816   (dotimes (i (if (< p 0) (- p) p))
 817     (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
 818         (progn
 819           (delete-char 1)
 820           (insert (if unflag " " "D"))))
 821     (forward-line (if (< p 0) -1 1)))
 822   (if (eobp) nil (forward-char 36)))
 823
 824 (defun tar-unflag (p)
 825   "*In Tar mode, un-mark this sub-file if it is marked to be deleted.
 826 With a prefix argument, un-mark that many files forward."
 827   (interactive "p")
 828   (tar-flag-deleted p t))
 829
 830 (defun tar-unflag-backwards (p)
 831   "*In Tar mode, un-mark this sub-file if it is marked to be deleted.
 832 With a prefix argument, un-mark that many files backward."
 833   (interactive "p")
 834   (tar-flag-deleted (- p) t))
 835
 836
 837 (defun tar-expunge-internal ()
 838   "Expunge the tar-entry specified by the current line."
 839   (let* ((descriptor (tar-current-descriptor))
 840          (tokens (tar-desc-tokens descriptor))
 841          (line (tar-desc-data-start descriptor))
 842          (name (tar-header-name tokens))
 843          (size (tar-header-size tokens))
 844          (link-p (tar-header-link-type tokens))
 845          (start (tar-desc-data-start descriptor))
 846          (following-descs (cdr (memq descriptor tar-parse-info))))
 847     (if link-p (setq size 0)) ; size lies for hard-links.
 848     ;;
 849     ;; delete the current line...
 850     (beginning-of-line)
 851     (let ((line-start (point)))
 852       (end-of-line) (forward-char)
 853       (let ((line-len (- (point) line-start)))
 854         (delete-region line-start (point))
 855         ;;
 856         ;; decrement the header-pointer to be in sync...
 857         (setq tar-header-offset (- tar-header-offset line-len))))
 858     ;;
 859     ;; delete the data pointer...
 860     (setq tar-parse-info (delq descriptor tar-parse-info))
 861     ;;
 862     ;; delete the data from inside the file...
 863     (widen)
 864     (let* ((data-start (+ start tar-header-offset -513))
 865            (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
 866       (delete-region data-start data-end)
 867       ;;
 868       ;; and finally, decrement the start-pointers of all following
 869       ;; entries in the archive.  This is a pig when deleting a bunch
 870       ;; of files at once - we could optimize this to only do the
 871       ;; iteration over the files that remain, or only iterate up to
 872       ;; the next file to be deleted.
 873       (let ((data-length (- data-end data-start)))
 874         (dolist (desc following-descs)
 875           (tar-setf (tar-desc-data-start desc)
 876                     (- (tar-desc-data-start desc) data-length))))
 877       ))
 878   (narrow-to-region 1 tar-header-offset))
 879
 880
 881 (defun tar-expunge (&optional noconfirm)
 882   "*In Tar mode, delete all the archived files flagged for deletion.
 883 This does not modify the disk image; you must save the tar file itself
 884 for this to be permanent."
 885   (interactive)
 886   (if (or noconfirm
 887           (y-or-n-p "Expunge files marked for deletion? "))
 888       (let ((n 0))
 889         (save-excursion
 890           (goto-char (point-min))
 891           (while (not (eobp))
 892             (if (looking-at "D")
 893                 (progn (tar-expunge-internal)
 894                        (setq n (1+ n)))
 895                 (forward-line 1)))
 896           ;; after doing the deletions, add any padding that may be necessary.
 897           (tar-pad-to-blocksize)
 898           (narrow-to-region 1 tar-header-offset))
 899         (if (zerop n)
 900             (message "Nothing to expunge.")
 901             (message "%s files expunged.  Be sure to save this buffer." n)))))
 902
 903
 904 (defun tar-clear-modification-flags ()
 905   "Remove the stars at the beginning of each line."
 906   (interactive)
 907   (save-excursion
 908     (goto-char (point-min))
 909     (while (< (point) tar-header-offset)
 910       (if (not (eq (following-char) ?\ ))
 911           (progn (delete-char 1) (insert " ")))
 912       (forward-line 1))))
 913
 914
 915 (defun tar-chown-entry (new-uid)
 916   "*Change the user-id associated with this entry in the tar file.
 917 If this tar file was written by GNU tar, then you will be able to edit
 918 the user id as a string; otherwise, you must edit it as a number.
 919 You can force editing as a number by calling this with a prefix arg.
 920 This does not modify the disk image; you must save the tar file itself
 921 for this to be permanent."
 922   (interactive (list
 923                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 924                    (if (or current-prefix-arg
 925                            (not (tar-header-magic tokens)))
 926                        (let (n)
 927                          (while (not (numberp (setq n (read-minibuffer
 928                                                         "New UID number: "
 929                                                         (format "%s" (tar-header-uid tokens)))))))
 930                          n)
 931                        (read-string "New UID string: " (tar-header-uname tokens))))))
 932   (cond ((stringp new-uid)
 933          (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
 934                    new-uid)
 935          (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
 936         (t
 937          (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
 938                    new-uid)
 939          (tar-alter-one-field tar-uid-offset
 940            (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
 941
 942
 943 (defun tar-chgrp-entry (new-gid)
 944   "*Change the group-id associated with this entry in the tar file.
 945 If this tar file was written by GNU tar, then you will be able to edit
 946 the group id as a string; otherwise, you must edit it as a number.
 947 You can force editing as a number by calling this with a prefix arg.
 948 This does not modify the disk image; you must save the tar file itself
 949 for this to be permanent."
 950   (interactive (list
 951                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 952                    (if (or current-prefix-arg
 953                            (not (tar-header-magic tokens)))
 954                        (let (n)
 955                          (while (not (numberp (setq n (read-minibuffer
 956                                                         "New GID number: "
 957                                                         (format "%s" (tar-header-gid tokens)))))))
 958                          n)
 959                        (read-string "New GID string: " (tar-header-gname tokens))))))
 960   (cond ((stringp new-gid)
 961          (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
 962                    new-gid)
 963          (tar-alter-one-field tar-gname-offset
 964            (concat new-gid "\000")))
 965         (t
 966          (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
 967                    new-gid)
 968          (tar-alter-one-field tar-gid-offset
 969            (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
 970
 971 (defun tar-rename-entry (new-name)
 972   "*Change the name associated with this entry in the tar file.
 973 This does not modify the disk image; you must save the tar file itself
 974 for this to be permanent."
 975   (interactive
 976     (list (read-string "New name: "
 977             (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
 978   (if (string= "" new-name) (error "zero length name"))
 979   (let ((encoded-new-name (encode-coding-string new-name
 980                                                 tar-file-name-coding-system)))
 981     (if (> (length encoded-new-name) 98) (error "name too long"))
 982     (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
 983               new-name)
 984     (tar-alter-one-field 0
 985      (substring (concat encoded-new-name (make-string 99 0)) 0 99))))
 986
 987
 988 (defun tar-chmod-entry (new-mode)
 989   "*Change the protection bits associated with this entry in the tar file.
 990 This does not modify the disk image; you must save the tar file itself
 991 for this to be permanent."
 992   (interactive (list (tar-parse-octal-integer-safe
 993                        (read-string "New protection (octal): "))))
 994   (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
 995             new-mode)
 996   (tar-alter-one-field tar-mode-offset
 997     (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
 998
 999
1000 (defun tar-alter-one-field (data-position new-data-string)
1001   (let* ((descriptor (tar-current-descriptor))
1002          (tokens (tar-desc-tokens descriptor)))
1003     (unwind-protect
1004         (save-excursion
1005           ;;
1006           ;; update the header-line.
1007           (beginning-of-line)
1008           (let ((p (point)))
1009             (forward-line 1)
1010             (delete-region p (point))
1011             (insert (tar-header-block-summarize tokens) "\n")
1012             (setq tar-header-offset (point-max)))
1013
1014           (widen)
1015           (let* ((start (+ (tar-desc-data-start descriptor) tar-header-offset -513)))
1016             ;;
1017             ;; delete the old field and insert a new one.
1018             (goto-char (+ start data-position))
1019             (delete-region (point) (+ (point) (length new-data-string))) ; <--
1020
1021             ;; As new-data-string is unibyte, just inserting it will
1022             ;; make eight-bit chars to the corresponding multibyte
1023             ;; chars.  This avoid that conversion, i.e., eight-bit
1024             ;; chars are converted to multibyte form of eight-bit
1025             ;; chars.
1026             (insert (string-to-multibyte new-data-string))
1027             ;;
1028             ;; compute a new checksum and insert it.
1029             (let ((chk (tar-header-block-checksum
1030                         (buffer-substring start (+ start 512)))))
1031               (goto-char (+ start tar-chk-offset))
1032               (delete-region (point) (+ (point) 8))
1033               (insert (format "%6o" chk))
1034               (insert 0)
1035               (insert ? )
1036               (tar-setf (tar-header-checksum tokens) chk)
1037               ;;
1038               ;; ok, make sure we didn't botch it.
1039               (tar-header-block-check-checksum
1040                 (buffer-substring start (+ start 512))
1041                 chk (tar-header-name tokens))
1042               )))
1043       (narrow-to-region 1 tar-header-offset)
1044       (tar-next-line 0))))
1045
1046
1047 (defun tar-octal-time (timeval)
1048   ;; Format a timestamp as 11 octal digits.  Ghod, I hope this works...
1049   (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
1050     (insert (format "%05o%01o%05o"
1051                     (lsh hibits -2)
1052                     (logior (lsh (logand 3 hibits) 1) (> (logand lobits 32768) 0))
1053                     (logand 32767 lobits)
1054                     ))))
1055
1056 (defun tar-subfile-save-buffer ()
1057   "In tar subfile mode, save this buffer into its parent tar-file buffer.
1058 This doesn't write anything to disk; you must save the parent tar-file buffer
1059 to make your changes permanent."
1060   (interactive)
1061   (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
1062     (error "This buffer has no superior tar file buffer"))
1063   (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
1064     (error "This buffer doesn't have an index into its superior tar file!"))
1065   (save-excursion
1066   (let ((subfile (current-buffer))
1067         (coding buffer-file-coding-system)
1068         (descriptor tar-superior-descriptor)
1069         subfile-size)
1070     (set-buffer tar-superior-buffer)
1071     (let* ((tokens (tar-desc-tokens descriptor))
1072            (start (tar-desc-data-start descriptor))
1073            (name (tar-header-name tokens))
1074            (size (tar-header-size tokens))
1075            (size-pad (ash (ash (+ size 511) -9) 9))
1076            (head (memq descriptor tar-parse-info))
1077            (following-descs (cdr head)))
1078       (if (not head)
1079         (error "Can't find this tar file entry in its parent tar file!"))
1080       (unwind-protect
1081        (save-excursion
1082         ;; delete the old data...
1083         (let* ((data-start (+ start tar-header-offset -1))
1084                (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
1085           (narrow-to-region data-start data-end)
1086           (delete-region (point-min) (point-max))
1087           ;; insert the new data...
1088           (goto-char data-start)
1089           (save-excursion
1090             (set-buffer subfile)
1091             (save-restriction
1092               (widen)
1093               (encode-coding-region 1 (point-max) coding tar-superior-buffer)))
1094           (setq subfile-size (- (point-max) (point-min)))
1095           ;;
1096           ;; pad the new data out to a multiple of 512...
1097           (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
1098             (goto-char (point-max))
1099             (insert (make-string (- subfile-size-pad subfile-size) 0))
1100             ;;
1101             ;; update the data pointer of this and all following files...
1102             (tar-setf (tar-header-size tokens) subfile-size)
1103             (let ((difference (- subfile-size-pad size-pad)))
1104               (dolist (desc following-descs)
1105                 (tar-setf (tar-desc-data-start desc)
1106                           (+ (tar-desc-data-start desc) difference))))
1107             ;;
1108             ;; Update the size field in the header block.
1109             (widen)
1110             (let ((header-start (- data-start 512)))
1111               (goto-char (+ header-start tar-size-offset))
1112               (delete-region (point) (+ (point) 12))
1113               (insert (format "%11o" subfile-size))
1114               (insert ? )
1115               ;;
1116               ;; Maybe update the datestamp.
1117               (if (not tar-update-datestamp)
1118                   nil
1119                 (goto-char (+ header-start tar-time-offset))
1120                 (delete-region (point) (+ (point) 12))
1121                 (insert (tar-octal-time (current-time)))
1122                 (insert ? ))
1123               ;;
1124               ;; compute a new checksum and insert it.
1125               (let ((chk (tar-header-block-checksum
1126                           (buffer-substring header-start data-start))))
1127                 (goto-char (+ header-start tar-chk-offset))
1128                 (delete-region (point) (+ (point) 8))
1129                 (insert (format "%6o" chk))
1130                 (insert 0)
1131                 (insert ? )
1132                 (tar-setf (tar-header-checksum tokens) chk)))
1133             ;;
1134             ;; alter the descriptor-line...
1135             ;;
1136             (let ((position (- (length tar-parse-info) (length head))))
1137               (goto-char (point-min))
1138               (next-line position)
1139               (beginning-of-line)
1140               (let ((p (point))
1141                     after
1142                     (m (set-marker (make-marker) tar-header-offset)))
1143                 (forward-line 1)
1144                 (setq after (point))
1145                 ;; Insert the new text after the old, before deleting,
1146                 ;; to preserve the window start.
1147                 (let ((line (tar-header-block-summarize tokens t)))
1148                   (insert-before-markers line "\n"))
1149                 (delete-region p after)
1150                 (setq tar-header-offset (marker-position m)))
1151               )))
1152         ;; after doing the insertion, add any final padding that may be necessary.
1153         (tar-pad-to-blocksize))
1154        (narrow-to-region 1 tar-header-offset)))
1155     (set-buffer-modified-p t)   ; mark the tar file as modified
1156     (tar-next-line 0)
1157     (set-buffer subfile)
1158     (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1159     (message "Saved into tar-buffer `%s'.  Be sure to save that buffer!"
1160              (buffer-name tar-superior-buffer))
1161     ;; Prevent basic-save-buffer from changing our coding-system.
1162     (setq last-coding-system-used buffer-file-coding-system)
1163     ;; Prevent ordinary saving from happening.
1164     t)))
1165
1166
1167 ;; When this function is called, it is sure that the buffer is unibyte.
1168 (defun tar-pad-to-blocksize ()
1169   "If we are being anal about tar file blocksizes, fix up the current buffer.
1170 Leaves the region wide."
1171   (if (null tar-anal-blocksize)
1172       nil
1173     (widen)
1174     (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1175            (start (tar-desc-data-start last-desc))
1176            (tokens (tar-desc-tokens last-desc))
1177            (link-p (tar-header-link-type tokens))
1178            (size (if link-p 0 (tar-header-size tokens)))
1179            (data-end (+ start size))
1180            (bbytes (ash tar-anal-blocksize 9))
1181            (pad-to (+ bbytes (* bbytes (/ (1- data-end) bbytes))))
1182            (inhibit-read-only t) ; ##
1183            )
1184       ;; If the padding after the last data is too long, delete some;
1185       ;; else insert some until we are padded out to the right number of blocks.
1186       ;;
1187       (goto-char (+ (or tar-header-offset 0) data-end))
1188       (if (> (1+ (buffer-size)) (+ (or tar-header-offset 0) pad-to))
1189           (delete-region (+ (or tar-header-offset 0) pad-to) (1+ (buffer-size)))
1190           (insert (make-string (- (+ (or tar-header-offset 0) pad-to)
1191                                   (1+ (buffer-size)))
1192                                0)))
1193       )))
1194
1195
1196 ;; Used in write-file-hook to write tar-files out correctly.
1197 (defun tar-mode-write-file ()
1198   (unwind-protect
1199       (save-excursion
1200         (widen)
1201         ;; Doing this here confuses things - the region gets left too wide!
1202         ;; I suppose this is run in a context where changing the buffer is bad.
1203         ;; (tar-pad-to-blocksize)
1204         ;; tar-header-offset turns out to be null for files fetched with W3,
1205         ;; at least.
1206         (let ((coding-system-for-write 'no-conversion))
1207           (write-region (or tar-header-offset
1208                             (point-min))
1209                         (point-max)
1210                         buffer-file-name nil t))
1211         (tar-clear-modification-flags)
1212         (set-buffer-modified-p nil))
1213     (narrow-to-region 1 tar-header-offset))
1214   ;; Return t because we've written the file.
1215   t)
1216 \f
1217 (provide 'tar-mode)
1218
1219 ;;; tar-mode.el ends here