lisp/bookmark.el

   1 ;;; bookmark.el --- set bookmarks, maybe annotate them, jump to them later.
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1996 Free Software Foundation
   4
   5 ;; Author: Karl Fogel <kfogel@red-bean.com>
   6 ;; Maintainer: Karl Fogel <kfogel@red-bean.com>
   7 ;; Created: July, 1993
   8 ;; Author's Update Number: see variable `bookmark-version'.
   9 ;; Keywords: bookmarks, placeholders, annotations
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package is for setting "bookmarks" in files.  A bookmark
  31 ;; associates a string with a location in a certain file.  Thus, you
  32 ;; can navigate your way to that location by providing the string.
  33 ;; See the "User Variables" section for customizations.
  34
  35 ;; Thanks to David Bremner <bremner@cs.sfu.ca> for thinking of and
  36 ;; then implementing the bookmark-current-bookmark idea.  He even
  37 ;; sent *patches*, bless his soul...
  38
  39 ;; Thanks to Gregory M. Saunders <saunders@cis.ohio-state.edu> for
  40 ;; fixing and improving bookmark-time-to-save-p.
  41
  42 ;; Thanks go to Andrew V. Klein <avk@cig.mot.com> for the code that
  43 ;; sorts the alist before presenting it to the user (in bookmark-bmenu-list
  44 ;; and the menu-bar).
  45
  46 ;; And much thanks to David Hughes <djh@harston.cv.com> for many small
  47 ;; suggestions and the code to implement them (like
  48 ;; bookmark-bmenu-check-position, and some of the Lucid compatibility
  49 ;; stuff).
  50
  51 ;; Kudos (whatever they are) go to Jim Blandy <jimb@red-bean.com>
  52 ;; for his eminently sensible suggestion to separate bookmark-jump
  53 ;; into bookmark-jump and bookmark-jump-noselect, which made many
  54 ;; other things cleaner as well.
  55
  56 ;; Thanks to Roland McGrath for encouragement and help with defining
  57 ;; autoloads on the menu-bar.
  58
  59 ;; Jonathan Stigelman <stig@hackvan.com> gave patches for default
  60 ;; values in bookmark-jump and bookmark-set.  Everybody please keep
  61 ;; all the keystrokes they save thereby and send them to him at the
  62 ;; end of each year :-)  (No, seriously, thanks Jonathan!)
  63
  64 ;; Buckets of gratitude to John Grabowski <johng@media.mit.edu> for
  65 ;; thinking up the annotations feature and implementing it so well.
  66
  67 ;; Based on info-bookmark.el, by Karl Fogel and Ken Olstad
  68 ;; <olstad@msc.edu>.
  69
  70 ;; Thanks to Mikio Nakajima <PBC01764@niftyserve.or.jp> for many bugs
  71 ;; reported and fixed.
  72
  73 ;; Thank you, Michael Kifer, for contributing the XEmacs support.
  74
  75 ;; Enough with the credits already, get on to the good stuff:
  76
  77 ;; FAVORITE CHINESE RESTAURANT:
  78 ;; Boy, that's a tough one.  Probably Hong Min, or maybe Emperor's
  79 ;; Choice (both in Chicago's Chinatown).  Well, both.  How about you?
  80 \f
  81 ;;;; Code:
  82
  83 (require 'pp)
  84
  85 (defconst bookmark-version "2.6.4"
  86   "Version number of bookmark.el.  This is not related to the version
  87 of Emacs bookmark comes with; it is used solely by bookmark's
  88 maintainers to avoid version confusion.")
  89
  90 ;;; Misc comments:
  91 ;;
  92 ;; If variable bookmark-use-annotations is non-nil, an annotation is
  93 ;; queried for when setting a bookmark.
  94 ;;
  95 ;; The bookmark list is sorted lexically by default, but you can turn
  96 ;; this off by setting bookmark-sort-flag to nil.  If it is nil, then
  97 ;; the list will be presented in the order it is recorded
  98 ;; (chronologically), which is actually fairly useful as well.
  99
 100 ;;; User Variables
 101
 102 (defvar bookmark-use-annotations nil
 103   "*If non-nil, saving a bookmark will query for an annotation in a
 104 buffer.")
 105
 106
 107 (defvar bookmark-save-flag t
 108   "*Controls when Emacs saves bookmarks to a file.
 109 --> Nil means never save bookmarks, except when `bookmark-save' is
 110     explicitly called \(\\[bookmark-save]\).
 111 --> t means save bookmarks when Emacs is killed.
 112 --> Otherwise, it should be a number that is the frequency with which
 113     the bookmark list is saved \(i.e.: the number of times which
 114     Emacs' bookmark list may be modified before it is automatically
 115     saved.\).  If it is a number, Emacs will also automatically save
 116     bookmarks when it is killed.
 117
 118 Therefore, the way to get it to save every time you make or delete a
 119 bookmark is to set this variable to 1 \(or 0, which produces the same
 120 behavior.\)
 121
 122 To specify the file in which to save them, modify the variable
 123 bookmark-default-file, which is `~/.emacs.bmk' by default.")
 124
 125
 126 (defconst bookmark-old-default-file "~/.emacs-bkmrks"
 127   "*The .emacs.bmk file used to be called this.")
 128
 129
 130 ;; defvarred to avoid a compilation warning:
 131 (defvar bookmark-file nil
 132   "Old name for `bookmark-default-file'.")
 133
 134 (defvar bookmark-default-file
 135   (if bookmark-file
 136       ;; In case user set `bookmark-file' in her .emacs:
 137       bookmark-file
 138     (convert-standard-filename "~/.emacs.bmk"))
 139   "*File in which to save bookmarks by default.")
 140
 141
 142 (defvar bookmark-version-control 'nospecial
 143   "*Whether or not to make numbered backups of the bookmark file.
 144 It can have four values: t, nil, `never', and `nospecial'.
 145 The first three have the same meaning that they do for the
 146 variable `version-control', and the final value `nospecial' means just
 147 use the value of `version-control'.")
 148
 149
 150 (defvar bookmark-completion-ignore-case t
 151   "*Non-nil means bookmark functions ignore case in completion.")
 152
 153
 154 (defvar bookmark-sort-flag t
 155   "*Non-nil means that bookmarks will be displayed sorted by bookmark
 156 name.  Otherwise they will be displayed in LIFO order (that is, most
 157 recently set ones come first, oldest ones come last).")
 158
 159
 160 (defvar bookmark-automatically-show-annotations t
 161   "*Nil means don't show annotations when jumping to a bookmark.")
 162
 163
 164 (defvar bookmark-bmenu-file-column 30
 165   "*Column at which to display filenames in a buffer listing bookmarks.
 166 You can toggle whether files are shown with \\<bookmark-bmenu-mode-map>\\[bookmark-bmenu-toggle-filenames].")
 167
 168
 169 (defvar bookmark-bmenu-toggle-filenames t
 170   "*Non-nil means show filenames when listing bookmarks.
 171 This may result in truncated bookmark names.  To disable this, put the
 172 following in your .emacs:
 173
 174 \(setq bookmark-bmenu-toggle-filenames nil\)")
 175
 176
 177 (defvar bookmark-menu-length 70
 178   "*Maximum length of a bookmark name displayed on a popup menu.")
 179
 180
 181 ;;; No user-serviceable parts beyond this point.
 182
 183 ;; Is it XEmacs?
 184 (defconst bookmark-xemacsp
 185   (string-match "\\(Lucid\\|Xemacs\\)" emacs-version))
 186
 187
 188 ;; Added  for lucid emacs  compatibility, db
 189 (or (fboundp 'defalias)  (fset 'defalias 'fset))
 190
 191 ;; suggested for lucid compatibility by david hughes:
 192 (or (fboundp 'frame-height)  (defalias 'frame-height 'screen-height))
 193
 194 ;; This variable is probably obsolete now...
 195 (or (boundp 'baud-rate)
 196     ;; some random value higher than 9600
 197     (setq baud-rate 19200))
 198
 199 ;; XEmacs apparently call this `buffer-substring-without-properties',
 200 ;; sigh.
 201 (or (fboundp 'buffer-substring-no-properties)
 202     (if (fboundp 'buffer-substring-without-properties)
 203         (fset 'buffer-substring-no-properties
 204               'buffer-substring-without-properties)
 205       (fset 'buffer-substring-no-properties 'buffer-substring)))
 206
 207 \f
 208 ;;; Keymap stuff:
 209 ;; some people have C-x r set to rmail or whatever.  We don't want to
 210 ;; assume that C-x r is a prefix map just because it's distributed
 211 ;; that way...
 212 ;; These are the distribution keybindings suggested by RMS, everything
 213 ;; else will be done with M-x or the menubar:
 214 ;;;###autoload
 215 (if (symbolp (key-binding "\C-xr"))
 216     nil
 217   (progn (define-key ctl-x-map "rb" 'bookmark-jump)
 218          (define-key ctl-x-map "rm" 'bookmark-set)
 219          (define-key ctl-x-map "rl" 'bookmark-bmenu-list)))
 220
 221 ;; define the map, so it can be bound by those who desire to do so:
 222
 223 ;;;###autoload
 224 (defvar bookmark-map nil
 225   "Keymap containing bindings to bookmark functions.
 226 It is not bound to any key by default: to bind it
 227 so that you have a bookmark prefix, just use `global-set-key' and bind a
 228 key of your choice to `bookmark-map'.  All interactive bookmark
 229 functions have a binding in this keymap.")
 230
 231 ;;;###autoload
 232 (define-prefix-command 'bookmark-map)
 233
 234 ;; Read the help on all of these functions for details...
 235 ;;;###autoload
 236 (define-key bookmark-map "x" 'bookmark-set)
 237 ;;;###autoload
 238 (define-key bookmark-map "m" 'bookmark-set) ; "m" for "mark"
 239 ;;;###autoload
 240 (define-key bookmark-map "j" 'bookmark-jump)
 241 ;;;###autoload
 242 (define-key bookmark-map "g" 'bookmark-jump) ; "g" for "go"
 243 ;;;###autoload
 244 (define-key bookmark-map "i" 'bookmark-insert)
 245 ;;;###autoload
 246 (define-key bookmark-map "e" 'edit-bookmarks)
 247 ;;;###autoload
 248 (define-key bookmark-map "f" 'bookmark-insert-location) ; "f" for "find"
 249 ;;;###autoload
 250 (define-key bookmark-map "r" 'bookmark-rename)
 251 ;;;###autoload
 252 (define-key bookmark-map "d" 'bookmark-delete)
 253 ;;;###autoload
 254 (define-key bookmark-map "l" 'bookmark-load)
 255 ;;;###autoload
 256 (define-key bookmark-map "w" 'bookmark-write)
 257 ;;;###autoload
 258 (define-key bookmark-map "s" 'bookmark-save)
 259
 260
 261 ;;; The annotation maps.
 262 (defvar bookmark-read-annotation-mode-map (copy-keymap text-mode-map)
 263   "Keymap for composing an annotation for a bookmark.")
 264
 265 (define-key bookmark-read-annotation-mode-map "\C-c\C-c"
 266   'bookmark-send-annotation)
 267
 268
 269 \f
 270 ;;; Core variables and data structures:
 271 (defvar bookmark-alist ()
 272   "Association list of bookmarks and their records.
 273 You probably don't want to change the value of this alist yourself;
 274 instead, let the various bookmark functions do it for you.
 275
 276 The format of the alist is
 277
 278        \(BOOKMARK1 BOOKMARK2 ...\)
 279
 280 where each BOOKMARK is of the form
 281
 282 \(NAME
 283   \(filename . FILE\)
 284   \(front-context-string . FRONT-STR\)
 285   \(rear-context-string  . REAR-STR\)
 286   \(position . POS\)
 287   \(info-node . POS\)
 288   \(annotation . ANNOTATION\)\)
 289
 290 So the cdr of each bookmark is an alist too.
 291 `info-node' is optional, by the way.")
 292
 293
 294 (defvar bookmarks-already-loaded nil)
 295
 296
 297 ;; just add the hook to make sure that people don't lose bookmarks
 298 ;; when they kill Emacs, unless they don't want to save them.
 299 ;;;###autoload
 300 (add-hook 'kill-emacs-hook
 301           (function
 302            (lambda () (and (featurep 'bookmark)
 303                            bookmark-alist
 304                            (bookmark-time-to-save-p t)
 305                            (bookmark-save)))))
 306
 307 ;; more stuff added by db.
 308
 309 (defvar bookmark-current-bookmark nil
 310   "Name of bookmark most recently used in the current file.
 311 It is buffer local, used to make moving a bookmark forward
 312 through a file easier.")
 313
 314 (make-variable-buffer-local 'bookmark-current-bookmark)
 315
 316
 317 (defvar bookmark-alist-modification-count 0
 318   "Number of modifications to bookmark list since it was last saved.")
 319
 320
 321 (defvar bookmark-search-size 16
 322   "Length of the context strings recorded on either side of a bookmark.")
 323
 324
 325 (defvar bookmark-current-point 0)
 326 (defvar bookmark-yank-point 0)
 327 (defvar bookmark-current-buffer nil)
 328
 329
 330 \f
 331 ;; Helper functions.
 332
 333 ;; Only functions on this page and the next one (file formats) need to
 334 ;; know anything about the format of bookmark-alist entries.
 335 ;; Everyone else should go through them.
 336
 337 (defun bookmark-name-from-full-record (full-record)
 338   "Return name of FULL-RECORD \(an alist element instead of a string\)."
 339   (car full-record))
 340
 341
 342 (defun bookmark-all-names ()
 343   "Return a list of all current bookmark names."
 344   (bookmark-maybe-load-default-file)
 345   (mapcar
 346    (lambda (full-record)
 347      (bookmark-name-from-full-record full-record))
 348    bookmark-alist))
 349
 350
 351 (defun bookmark-get-bookmark (bookmark)
 352   "Return the full entry for BOOKMARK in bookmark-alist."
 353   (assoc bookmark bookmark-alist))
 354
 355
 356 (defun bookmark-get-bookmark-record (bookmark)
 357   "Return the guts of the entry for BOOKMARK in bookmark-alist.
 358 That is, all information but the name."
 359   (car (cdr (bookmark-get-bookmark bookmark))))
 360
 361
 362 (defun bookmark-set-name (bookmark newname)
 363   "Set BOOKMARK's name to NEWNAME."
 364   (setcar (bookmark-get-bookmark bookmark) newname))
 365
 366
 367 (defun bookmark-get-annotation (bookmark)
 368   "Return the annotation of BOOKMARK, or nil if none."
 369   (cdr (assq 'annotation (bookmark-get-bookmark-record bookmark))))
 370
 371
 372 (defun bookmark-set-annotation (bookmark ann)
 373   "Set the annotation of BOOKMARK to ANN."
 374   (let ((cell (assq 'annotation (bookmark-get-bookmark-record bookmark))))
 375     (if cell
 376         (setcdr cell ann)
 377       (nconc (bookmark-get-bookmark-record bookmark)
 378              (list (cons 'annotation ann))))))
 379
 380
 381 (defun bookmark-get-filename (bookmark)
 382   "Return the full filename of BOOKMARK."
 383   (cdr (assq 'filename (bookmark-get-bookmark-record bookmark))))
 384
 385
 386 (defun bookmark-set-filename (bookmark filename)
 387   "Set the full filename of BOOKMARK to FILENAME."
 388   (let ((cell (assq 'filename (bookmark-get-bookmark-record bookmark))))
 389     (if cell
 390         (setcdr cell filename)
 391       (nconc (bookmark-get-bookmark-record bookmark)
 392              (list (cons 'filename filename))))))
 393
 394
 395 (defun bookmark-get-position (bookmark)
 396   "Return the position \(i.e.: point\) of BOOKMARK."
 397   (cdr (assq 'position (bookmark-get-bookmark-record bookmark))))
 398
 399
 400 (defun bookmark-set-position (bookmark position)
 401   "Set the position \(i.e.: point\) of BOOKMARK to POSITION."
 402   (let ((cell (assq 'position (bookmark-get-bookmark-record bookmark))))
 403     (if cell
 404         (setcdr cell position)
 405       (nconc (bookmark-get-bookmark-record bookmark)
 406              (list (cons 'position position))))))
 407
 408
 409 (defun bookmark-get-front-context-string (bookmark)
 410   "Return the front-context-string of BOOKMARK."
 411   (cdr (assq 'front-context-string (bookmark-get-bookmark-record bookmark))))
 412
 413
 414 (defun bookmark-set-front-context-string (bookmark string)
 415   "Set the front-context-string of BOOKMARK to STRING."
 416   (let ((cell (assq 'front-context-string
 417                     (bookmark-get-bookmark-record bookmark))))
 418     (if cell
 419         (setcdr cell string)
 420       (nconc (bookmark-get-bookmark-record bookmark)
 421              (list (cons 'front-context-string string))))))
 422
 423
 424 (defun bookmark-get-rear-context-string (bookmark)
 425   "Return the rear-context-string of BOOKMARK."
 426   (cdr (assq 'rear-context-string (bookmark-get-bookmark-record bookmark))))
 427
 428
 429 (defun bookmark-set-rear-context-string (bookmark string)
 430   "Set the rear-context-string of BOOKMARK to STRING."
 431   (let ((cell (assq 'rear-context-string
 432                     (bookmark-get-bookmark-record bookmark))))
 433     (if cell
 434         (setcdr cell string)
 435       (nconc (bookmark-get-bookmark-record bookmark)
 436              (list (cons 'rear-context-string string))))))
 437
 438
 439 (defun bookmark-get-info-node (bookmark)
 440   "Get the info node associated with BOOKMARK."
 441   (cdr (assq 'info-node (bookmark-get-bookmark-record bookmark))))
 442
 443
 444 (defun bookmark-set-info-node (bookmark node)
 445   "Set the Info node of BOOKMARK to NODE."
 446   (let ((cell (assq 'info-node
 447                     (bookmark-get-bookmark-record bookmark))))
 448     (if cell
 449         (setcdr cell node)
 450       (nconc (bookmark-get-bookmark-record bookmark)
 451              (list (cons 'info-node node)))))
 452
 453   (message "%S" (assq 'info-node (bookmark-get-bookmark-record bookmark)))
 454   (sit-for 4)
 455   )
 456
 457
 458 (defvar bookmark-history nil
 459   "The history list for bookmark functions.")
 460
 461
 462 (defun bookmark-completing-read (prompt &optional default)
 463   "Prompting with PROMPT, read a bookmark name in completion.
 464 PROMPT will get a \": \" stuck on the end no matter what, so you
 465 probably don't want to include one yourself.
 466 Optional second arg DEFAULT is a string to return if the user enters
 467 the empty string."
 468   (bookmark-maybe-load-default-file) ; paranoia
 469   (let* ((completion-ignore-case bookmark-completion-ignore-case)
 470          (default default)
 471          (prompt (if default
 472                      (concat prompt (format " (%s): " default))
 473                    (concat prompt ": ")))
 474          (str
 475           (completing-read prompt
 476                            bookmark-alist
 477                            nil
 478                            0
 479                            nil
 480                            'bookmark-history)))
 481     (if (string-equal "" str)
 482         (list default)
 483       (list str))))
 484
 485
 486 (defmacro bookmark-maybe-historicize-string (string)
 487   "Put STRING into the bookmark prompt history, if caller non-interactive.
 488 We need this because sometimes bookmark functions are invoked from
 489 menus, so `completing-read' never gets a chance to set `bookmark-history'."
 490   (` (or
 491       (interactive-p)
 492       (setq bookmark-history (cons (, string) bookmark-history)))))
 493
 494
 495 (defun bookmark-make (name &optional annotation overwrite info-node)
 496   "Make a bookmark named NAME.
 497 Optional second arg ANNOTATION gives it an annotation.
 498 Optional third arg OVERWRITE means replace any existing bookmarks with
 499 this name.
 500 Optional fourth arg INFO-NODE means this bookmark is at info node
 501 INFO-NODE, so record this fact in the bookmark's entry."
 502   (bookmark-maybe-load-default-file)
 503   (let ((stripped-name (copy-sequence name)))
 504     (or bookmark-xemacsp
 505         ;; XEmacs's `set-text-properties' doesn't work on
 506         ;; free-standing strings, apparently.
 507         (set-text-properties 0 (length stripped-name) nil stripped-name))
 508     (if (and (bookmark-get-bookmark stripped-name) (not overwrite))
 509         ;; already existing bookmark under that name and
 510         ;; no prefix arg means just overwrite old bookmark
 511         (setcdr (bookmark-get-bookmark stripped-name)
 512                 (list (bookmark-make-cell annotation info-node)))
 513
 514       ;; otherwise just cons it onto the front (either the bookmark
 515       ;; doesn't exist already, or there is no prefix arg.  In either
 516       ;; case, we want the new bookmark consed onto the alist...)
 517
 518       (setq bookmark-alist
 519             (cons
 520              (list stripped-name
 521                    (bookmark-make-cell annotation info-node))
 522              bookmark-alist)))
 523
 524     ;; Added by db
 525     (setq bookmark-current-bookmark stripped-name)
 526     (setq bookmark-alist-modification-count
 527           (1+ bookmark-alist-modification-count))
 528     (if (bookmark-time-to-save-p)
 529         (bookmark-save))))
 530
 531
 532 (defun bookmark-make-cell (annotation &optional info-node)
 533   "Return the record part of a new bookmark, given ANNOTATION.
 534 Must be at the correct position in the buffer in which the bookmark is
 535 being set.  This might change someday.
 536 Optional second arg INFO-NODE means this bookmark is at info node
 537 INFO-NODE, so record this fact in the bookmark's entry."
 538   (let ((the-record
 539          (` ((filename . (, (bookmark-buffer-file-name)))
 540              (front-context-string
 541               . (, (if (>= (- (point-max) (point)) bookmark-search-size)
 542                        (buffer-substring-no-properties
 543                         (point)
 544                         (+ (point) bookmark-search-size))
 545                      nil)))
 546              (rear-context-string
 547               . (, (if (>= (- (point) (point-min)) bookmark-search-size)
 548                        (buffer-substring-no-properties
 549                         (point)
 550                         (- (point) bookmark-search-size))
 551                      nil)))
 552              (position . (, (point)))
 553              ))))
 554
 555     ;; Now fill in the optional parts:
 556     (if annotation
 557         (nconc the-record (list (cons 'annotation annotation))))
 558     (if info-node
 559         (nconc the-record (list (cons 'info-node info-node))))
 560
 561     ;; Finally, return the completed record.
 562     the-record))
 563
 564
 565 \f
 566 ;;; File format stuff
 567
 568 ;; The OLD format of the bookmark-alist was:
 569 ;;
 570 ;;       ((bookmark-name (filename
 571 ;;                        string-in-front
 572 ;;                        string-behind
 573 ;;                        point))
 574 ;;        ...)
 575 ;;
 576 ;; The NEW format of the bookmark-alist is:
 577 ;;
 578 ;;       ((bookmark-name ((filename . FILENAME)
 579 ;;                        (front-context-string . string-in-front)
 580 ;;                        (rear-context-string  . string-behind)
 581 ;;                        (position . POINT)
 582 ;;                        (annotation . annotation)
 583 ;;                        (whatever   . VALUE)
 584 ;;                        ...
 585 ;;                        ))
 586 ;;        ...)
 587 ;;
 588 ;;
 589 ;; I switched to using an internal as well as external alist because I
 590 ;; felt that would be a more flexible framework in which to add
 591 ;; features.  It means that the order in which values appear doesn't
 592 ;; matter, and it means that arbitrary values can be added without
 593 ;; risk of interfering with existing ones.
 594 ;;
 595 ;; BOOKMARK-NAME is the string the user gives the bookmark and
 596 ;; accesses it by from then on.
 597 ;;
 598 ;; FILENAME is the location of the file in which the bookmark is set.
 599 ;;
 600 ;; STRING-IN-FRONT is a string of `bookmark-search-size' chars of
 601 ;; context in front of the point at which the bookmark is set.
 602 ;;
 603 ;; STRING-BEHIND is the same thing, but after the point.
 604 ;;
 605 ;; The context strings exist so that modifications to a file don't
 606 ;; necessarily cause a bookmark's position to be invalidated.
 607 ;; bookmark-jump will search for STRING-BEHIND and STRING-IN-FRONT in
 608 ;; case the file has changed since the bookmark was set.  It will
 609 ;; attempt to place the user before the changes, if there were any.
 610 ;; ANNOTATION is the annotation for the bookmark; it may not exist
 611 ;; (for backward compatibility), be nil (no annotation), or be a
 612 ;; string.
 613
 614
 615 (defconst bookmark-file-format-version 1
 616   "The current version of the format used by bookmark files.
 617 You should never need to change this.")
 618
 619
 620 (defconst bookmark-end-of-version-stamp-marker
 621   "-*- End Of Bookmark File Format Version Stamp -*-\n"
 622   "This string marks the end of the version stamp in a bookmark file.")
 623
 624
 625 (defun bookmark-alist-from-buffer ()
 626   "Return a bookmark-alist (in any format) from the current buffer.
 627 The buffer must of course contain bookmark format information.
 628 Does not care from where in the buffer it is called, and does not
 629 affect point."
 630   (save-excursion
 631     (goto-char (point-min))
 632     (if (search-forward bookmark-end-of-version-stamp-marker nil t)
 633         (read (current-buffer))
 634       ;; Else we're dealing with format version 0
 635       (if (search-forward "(" nil t)
 636           (progn
 637             (forward-char -1)
 638             (read (current-buffer)))
 639         ;; Else no hope of getting information here.
 640         (error "Not bookmark format")))))
 641
 642
 643 (defun bookmark-upgrade-version-0-alist (old-list)
 644   "Upgrade a version 0 alist OLD-LIST to the current version."
 645   (mapcar
 646    (lambda (bookmark)
 647      (let* ((name      (car bookmark))
 648             (record    (car (cdr bookmark)))
 649             (filename  (nth 0 record))
 650             (front-str (nth 1 record))
 651             (rear-str  (nth 2 record))
 652             (position  (nth 3 record))
 653             (ann       (nth 4 record)))
 654        (list
 655         name
 656         (` ((filename             .    (, filename))
 657             (front-context-string .    (, (or front-str "")))
 658             (rear-context-string  .    (, (or rear-str  "")))
 659             (position             .    (, position))
 660             (annotation           .    (, ann)))))))
 661    old-list))
 662
 663
 664 (defun bookmark-upgrade-file-format-from-0 ()
 665   "Upgrade a bookmark file of format 0 (the original format) to format 1.
 666 This expects to be called from point-min in a bookmark file."
 667   (message "Upgrading bookmark format from 0 to %d..."
 668            bookmark-file-format-version)
 669   (let* ((old-list (bookmark-alist-from-buffer))
 670          (new-list (bookmark-upgrade-version-0-alist old-list)))
 671     (delete-region (point-min) (point-max))
 672     (bookmark-insert-file-format-version-stamp)
 673     (pp new-list (current-buffer))
 674     (save-buffer))
 675   (goto-char (point-min))
 676   (message "Upgrading bookmark format from 0 to %d...done"
 677            bookmark-file-format-version)
 678   )
 679
 680
 681 (defun bookmark-grok-file-format-version ()
 682   "Return an integer which is the file-format version of this bookmark file.
 683 This expects to be called from point-min in a bookmark file."
 684   (if (looking-at "^;;;;")
 685       (save-excursion
 686         (save-match-data
 687           (re-search-forward "[0-9]")
 688           (forward-char -1)
 689           (read (current-buffer))))
 690     ;; Else this is format version 0, the original one, which didn't
 691     ;; even have version stamps.
 692     0))
 693
 694
 695 (defun bookmark-maybe-upgrade-file-format ()
 696   "Check the file-format version of this bookmark file.
 697 If the version is not up-to-date, upgrade it automatically.
 698 This expects to be called from point-min in a bookmark file."
 699   (let ((version (bookmark-grok-file-format-version)))
 700     (cond
 701      ((= version bookmark-file-format-version)
 702       ) ; home free -- version is current
 703      ((= version 0)
 704       (bookmark-upgrade-file-format-from-0))
 705      (t
 706       (error "Bookmark file format version strangeness")))))
 707
 708
 709 (defun bookmark-insert-file-format-version-stamp ()
 710   "Insert text indicating current version of bookmark file format."
 711   (insert
 712    (format ";;;; Emacs Bookmark Format Version %d ;;;;\n"
 713            bookmark-file-format-version))
 714   (insert ";;; This format is meant to be slightly human-readable;\n"
 715           ";;; nevertheless, you probably don't want to edit it.\n"
 716           ";;; "
 717           bookmark-end-of-version-stamp-marker))
 718
 719
 720 ;;; end file-format stuff
 721
 722 \f
 723 ;;; Core code:
 724
 725 ;;;###autoload
 726 (defun bookmark-set (&optional name parg)
 727   "Set a bookmark named NAME inside a file.
 728 If name is nil, then the user will be prompted.
 729 With prefix arg, will not overwrite a bookmark that has the same name
 730 as NAME if such a bookmark already exists, but instead will \"push\"
 731 the new bookmark onto the bookmark alist.  Thus the most recently set
 732 bookmark with name NAME would be the one in effect at any given time,
 733 but the others are still there, should you decide to delete the most
 734 recent one.
 735
 736 To yank words from the text of the buffer and use them as part of the
 737 bookmark name, type C-w while setting a bookmark.  Successive C-w's
 738 yank successive words.
 739
 740 Typing C-u inserts the name of the last bookmark used in the buffer
 741 \(as an aid in using a single bookmark name to track your progress
 742 through a large file\).  If no bookmark was used, then C-u inserts the
 743 name of the file being visited.
 744
 745 Use \\[bookmark-delete] to remove bookmarks \(you give it a name,
 746 and it removes only the first instance of a bookmark with that name from
 747 the list of bookmarks.\)"
 748   (interactive (list nil current-prefix-arg))
 749   (or
 750    (bookmark-buffer-file-name)
 751    (error "Buffer not visiting a file or directory"))
 752
 753   (bookmark-maybe-load-default-file)
 754
 755   (setq bookmark-current-point (point))
 756   (setq bookmark-yank-point (point))
 757   (setq bookmark-current-buffer (current-buffer))
 758
 759   (let* ((default (or bookmark-current-bookmark
 760                       (bookmark-buffer-name)))
 761          (str
 762           (or name
 763               (read-from-minibuffer
 764                (format "Set bookmark (%s): " default)
 765                nil
 766                (let ((now-map (copy-keymap minibuffer-local-map)))
 767                  (progn (define-key now-map  "\C-w"
 768                           'bookmark-yank-word)
 769                         (define-key now-map  "\C-u"
 770                           'bookmark-insert-current-bookmark))
 771                  now-map))))
 772          (annotation nil))
 773     (and (string-equal str "") (setq str default))
 774     ;; Ask for an annotation buffer for this bookmark
 775     (if bookmark-use-annotations
 776         (bookmark-read-annotation parg str)
 777       (progn
 778         (bookmark-make str annotation parg (bookmark-info-current-node))
 779         (setq bookmark-current-bookmark str)
 780         (bookmark-bmenu-surreptitiously-rebuild-list)
 781         (goto-char bookmark-current-point)))))
 782
 783
 784 (defun bookmark-info-current-node ()
 785   "If in Info-mode, return current node name (a string), else nil."
 786   (if (eq major-mode 'Info-mode)
 787       Info-current-node))
 788
 789
 790 (defun bookmark-kill-line (&optional newline-too)
 791   "Kill from point to end of line.
 792 If optional arg NEWLINE-TOO is non-nil, delete the newline too.
 793 Does not affect the kill-ring."
 794   (let ((eol (save-excursion (end-of-line) (point))))
 795     (delete-region (point) eol)
 796     (if (and newline-too (looking-at "\n"))
 797         (delete-char 1))))
 798
 799
 800 ;; Defvars to avoid compilation warnings:
 801 (defvar bookmark-annotation-paragraph nil)
 802 (defvar bookmark-annotation-name nil)
 803 (defvar bookmark-annotation-buffer nil)
 804 (defvar bookmark-annotation-file nil)
 805 (defvar bookmark-annotation-point nil)
 806
 807
 808 (defun bookmark-send-annotation ()
 809   "Use buffer contents as the annotation for a bookmark.
 810 Exclude lines that begin with `#'.
 811 Store the annotation text in the bookmark list with
 812 the bookmark (and file, and point) specified in buffer local variables."
 813   (interactive)
 814   (if (not (eq major-mode 'bookmark-read-annotation-mode))
 815       (error "Not in bookmark-read-annotation-mode"))
 816   (goto-char (point-min))
 817   (while (< (point) (point-max))
 818     (if (looking-at "^#")
 819         (bookmark-kill-line t)
 820       (forward-line 1)))
 821   (let ((annotation (buffer-substring (point-min) (point-max)))
 822         (parg bookmark-annotation-paragraph)
 823         (bookmark bookmark-annotation-name)
 824         (pt bookmark-annotation-point)
 825         (buf bookmark-annotation-buffer))
 826     ;; for bookmark-make-cell to work, we need to be
 827     ;; in the relevant buffer, at the relevant point.
 828     ;; Actually, bookmark-make-cell should probably be re-written,
 829     ;; to avoid this need.  Should I handle the error if a buffer is
 830     ;; killed between "C-x r m" and a "C-c C-c" in the annotation buffer?
 831     (save-excursion
 832       (pop-to-buffer buf)
 833       (goto-char pt)
 834       (bookmark-make bookmark annotation parg (bookmark-info-current-node))
 835       (setq bookmark-current-bookmark bookmark))
 836     (bookmark-bmenu-surreptitiously-rebuild-list)
 837     (goto-char bookmark-current-point))
 838   (kill-buffer (current-buffer)))
 839
 840
 841 (defun bookmark-default-annotation-text (bookmark)
 842   (concat "#  Type the annotation for bookmark '" bookmark "' here.\n"
 843           "#  All lines which start with a '#' will be deleted.\n"
 844           "#  Type C-c C-c when done.\n#\n"
 845           "#  Author: " (user-full-name) " <" (user-login-name) "@"
 846           (system-name) ">\n"
 847           "#  Date:    " (current-time-string) "\n"))
 848
 849
 850 (defvar bookmark-read-annotation-text-func 'bookmark-default-annotation-text
 851   "Function to return default text to use for a bookmark annotation.
 852 It takes the name of the bookmark, as a string, as an arg.")
 853
 854 (defun bookmark-read-annotation-mode (buf point parg bookmark)
 855   "Mode for composing annotations for a bookmark.
 856 Wants BUF POINT PARG and BOOKMARK.
 857 When you have finished composing, type \\[bookmark-send-annotation] to send
 858 the annotation.
 859
 860 \\{bookmark-read-annotation-mode-map}
 861 "
 862   (interactive)
 863   (kill-all-local-variables)
 864   (make-local-variable 'bookmark-annotation-paragraph)
 865   (make-local-variable 'bookmark-annotation-name)
 866   (make-local-variable 'bookmark-annotation-buffer)
 867   (make-local-variable 'bookmark-annotation-file)
 868   (make-local-variable 'bookmark-annotation-point)
 869   (setq bookmark-annotation-paragraph parg)
 870   (setq bookmark-annotation-name bookmark)
 871   (setq bookmark-annotation-buffer buf)
 872   (setq bookmark-annotation-file (buffer-file-name buf))
 873   (setq bookmark-annotation-point point)
 874   (use-local-map bookmark-read-annotation-mode-map)
 875   (setq major-mode 'bookmark-read-annotation-mode)
 876   (insert (funcall bookmark-read-annotation-text-func bookmark))
 877   (run-hooks 'text-mode-hook))
 878
 879
 880 (defun bookmark-read-annotation (parg bookmark)
 881   "Pop up a buffer for entering a bookmark annotation.
 882 Text surrounding the bookmark is PARG; the bookmark name is BOOKMARK."
 883   (let ((buf (current-buffer))
 884         (point (point)))
 885     (pop-to-buffer (generate-new-buffer-name "*Bookmark Annotation Compose*"))
 886     (bookmark-read-annotation-mode buf point parg bookmark)))
 887
 888
 889 (defvar bookmark-edit-annotation-mode-map (copy-keymap text-mode-map)
 890   "Keymap for editing an annotation of a bookmark.")
 891
 892
 893 (define-key bookmark-edit-annotation-mode-map "\C-c\C-c"
 894   'bookmark-send-edited-annotation)
 895
 896
 897 (defun bookmark-edit-annotation-mode (bookmark)
 898   "Mode for editing the annotation of bookmark BOOKMARK.
 899 When you have finished composing, type \\[bookmark-send-annotation].
 900
 901 \\{bookmark-edit-annotation-mode-map}
 902 "
 903   (interactive)
 904   (kill-all-local-variables)
 905   (make-local-variable 'bookmark-annotation-name)
 906   (setq bookmark-annotation-name bookmark)
 907   (use-local-map bookmark-edit-annotation-mode-map)
 908   (setq major-mode 'bookmark-edit-annotation-mode)
 909   (insert (funcall bookmark-read-annotation-text-func bookmark))
 910   (let ((annotation (bookmark-get-annotation bookmark)))
 911     (if (and (not (eq annotation nil))
 912              (not (string-equal annotation "")))
 913         (insert annotation)))
 914   (run-hooks 'text-mode-hook))
 915
 916
 917 (defun bookmark-send-edited-annotation ()
 918   "Use buffer contents (minus beginning with `#' as annotation for a bookmark."
 919   (interactive)
 920   (if (not (eq major-mode 'bookmark-edit-annotation-mode))
 921       (error "Not in bookmark-edit-annotation-mode"))
 922   (goto-char (point-min))
 923   (while (< (point) (point-max))
 924     (if (looking-at "^#")
 925         (bookmark-kill-line t)
 926       (forward-line 1)))
 927   (let ((annotation (buffer-substring (point-min) (point-max)))
 928         (bookmark bookmark-annotation-name))
 929     (bookmark-set-annotation bookmark annotation)
 930     (bookmark-bmenu-surreptitiously-rebuild-list)
 931     (goto-char bookmark-current-point))
 932   (kill-buffer (current-buffer)))
 933
 934
 935 (defun bookmark-edit-annotation (bookmark)
 936   "Pop up a buffer for editing bookmark BOOKMARK's annotation."
 937   (let ((buf (current-buffer))
 938         (point (point)))
 939     (pop-to-buffer (generate-new-buffer-name "*Bookmark Annotation Compose*"))
 940     (bookmark-edit-annotation-mode bookmark)))
 941
 942
 943 (defun bookmark-insert-current-bookmark ()
 944   "Insert this buffer's value of bookmark-current-bookmark.
 945 Default to file name if it's nil."
 946   (interactive)
 947   (let ((str
 948          (save-excursion
 949            (set-buffer bookmark-current-buffer)
 950            bookmark-current-bookmark)))
 951     (if str (insert str) (bookmark-insert-buffer-name))))
 952
 953
 954 (defun bookmark-insert-buffer-name ()
 955   "Insert the current file name into the bookmark name being set.
 956 The directory part of the file name is not used."
 957   (interactive)
 958   (let ((str
 959          (save-excursion
 960            (set-buffer bookmark-current-buffer)
 961            (bookmark-buffer-name))))
 962     (insert str)))
 963
 964
 965 (defun bookmark-buffer-name ()
 966   "Return the name of the current buffer's file, non-directory.
 967 In Info, return the current node."
 968   (cond
 969    ;; Are we in Info?
 970    ((string-equal mode-name "Info") Info-current-node)
 971    ;; Or are we a file?
 972    (buffer-file-name (file-name-nondirectory buffer-file-name))
 973    ;; Or are we a directory?
 974    ((and (boundp 'dired-directory) dired-directory)
 975     (let* ((dirname (if (stringp dired-directory)
 976                         dired-directory
 977                       (car dired-directory)))
 978            (idx (1- (length dirname))))
 979       ;; Strip the trailing slash.
 980       (if (= ?/ (aref dirname idx))
 981           (file-name-nondirectory (substring dirname 0 idx))
 982         ;; Else return the current-buffer
 983         (buffer-name (current-buffer)))))
 984    ;; If all else fails, use the buffer's name.
 985    (t
 986     (buffer-name (current-buffer)))))
 987
 988
 989 (defun bookmark-yank-word ()
 990   (interactive)
 991   ;; get the next word from the buffer and append it to the name of
 992   ;; the bookmark currently being set.
 993   (let ((string (save-excursion
 994                     (set-buffer bookmark-current-buffer)
 995                     (goto-char bookmark-yank-point)
 996                     (buffer-substring-no-properties
 997                      (point)
 998                      (save-excursion
 999                        (forward-word 1)
1000                        (setq bookmark-yank-point (point)))))))
1001     (insert string)))
1002
1003
1004 (defun bookmark-buffer-file-name ()
1005   "Return the current buffer's file in a way useful for bookmarks.
1006 For example, if this is a Info buffer, return the Info file's name."
1007   (if (eq major-mode 'Info-mode)
1008         Info-current-file
1009     (or
1010      buffer-file-name
1011      (if (and (boundp 'dired-directory) dired-directory)
1012          (if (stringp dired-directory)
1013              dired-directory
1014            (car dired-directory))))))
1015
1016
1017 (defun bookmark-maybe-load-default-file ()
1018   (and (not bookmarks-already-loaded)
1019        (null bookmark-alist)
1020        (prog2
1021            (and
1022             ;; Possibly the old bookmark file, "~/.emacs-bkmrks", needs
1023             ;; to be renamed.
1024             (file-exists-p (expand-file-name bookmark-old-default-file))
1025             (not (file-exists-p (expand-file-name bookmark-default-file)))
1026             (rename-file (expand-file-name bookmark-old-default-file)
1027                          (expand-file-name bookmark-default-file)))
1028            ;; return t so the `and' will continue...
1029            t)
1030
1031        (file-readable-p (expand-file-name bookmark-default-file))
1032        (progn
1033          (bookmark-load bookmark-default-file t t)
1034          (setq bookmarks-already-loaded t))))
1035
1036
1037 (defun bookmark-maybe-sort-alist ()
1038   ;;Return the bookmark-alist for display.  If the bookmark-sort-flag
1039   ;;is non-nil, then return a sorted copy of the alist.
1040   (if bookmark-sort-flag
1041       (setq bookmark-alist
1042             (sort (copy-alist bookmark-alist)
1043                   (function
1044                    (lambda (x y) (string-lessp (car x) (car y))))))))
1045
1046
1047 ;;;###autoload
1048 (defun bookmark-jump (bookmark)
1049   "Jump to bookmark BOOKMARK (a point in some file).
1050 You may have a problem using this function if the value of variable
1051 `bookmark-alist' is nil.  If that happens, you need to load in some
1052 bookmarks.  See help on function `bookmark-load' for more about
1053 this.
1054
1055 If the file pointed to by BOOKMARK no longer exists, you will be asked
1056 if you wish to give the bookmark a new location, and bookmark-jump
1057 will then jump to the new location, as well as recording it in place
1058 of the old one in the permanent bookmark record."
1059   (interactive
1060    (bookmark-completing-read "Jump to bookmark" bookmark-current-bookmark))
1061   (bookmark-maybe-historicize-string bookmark)
1062   (let ((cell (bookmark-jump-noselect bookmark)))
1063     (and cell
1064          (switch-to-buffer (car cell))
1065          (goto-char (cdr cell))
1066          (if bookmark-automatically-show-annotations
1067              ;; if there is an annotation for this bookmark,
1068              ;; show it in a buffer.
1069              (bookmark-show-annotation bookmark)))))
1070
1071
1072 (defun bookmark-jump-noselect (str)
1073   ;; a leetle helper for bookmark-jump :-)
1074   ;; returns (BUFFER . POINT)
1075   (bookmark-maybe-load-default-file)
1076   (let* ((file (expand-file-name (bookmark-get-filename str)))
1077          (forward-str            (bookmark-get-front-context-string str))
1078          (behind-str             (bookmark-get-rear-context-string str))
1079          (place                  (bookmark-get-position str))
1080          (info-node              (bookmark-get-info-node str))
1081          (orig-file              file)
1082          )
1083     (if (or
1084          (file-exists-p file)
1085          ;; else try some common compression extensions
1086          ;; and Emacs better handle it right!
1087          ;; Sigh: I think it may *not* be handled at the moment.  What
1088          ;; to do about this?
1089          (setq file
1090                (or
1091                 (let ((altname (concat file ".Z")))
1092                   (and (file-exists-p altname)
1093                        altname))
1094                 (let ((altname (concat file ".gz")))
1095                   (and (file-exists-p altname)
1096                        altname))
1097                 (let ((altname (concat file ".z")))
1098                   (and (file-exists-p altname)
1099                        altname)))))
1100         (save-excursion
1101           (if info-node
1102               ;; Info nodes must be visited with care.
1103               (progn
1104                 (require 'info)
1105                 (Info-find-node file info-node))
1106             ;; Else no Info.  Can do an ordinary find-file:
1107             (set-buffer (find-file-noselect file))
1108             (goto-char place))
1109
1110           ;; Go searching forward first.  Then, if forward-str exists and
1111           ;; was found in the file, we can search backward for behind-str.
1112           ;; Rationale is that if text was inserted between the two in the
1113           ;; file, it's better to be put before it so you can read it,
1114           ;; rather than after and remain perhaps unaware of the changes.
1115           (if forward-str
1116               (if (search-forward forward-str (point-max) t)
1117                   (backward-char (length forward-str))))
1118           (if behind-str
1119               (if (search-backward behind-str (point-min) t)
1120                   (forward-char (length behind-str))))
1121           ;; added by db
1122           (setq bookmark-current-bookmark str)
1123           (cons (current-buffer) (point)))
1124       (progn
1125         (ding)
1126         (if (y-or-n-p (concat (file-name-nondirectory orig-file)
1127                               " nonexistent.  Relocate \""
1128                               str
1129                               "\"? "))
1130             (progn
1131               (bookmark-relocate str)
1132               ;; gasp!  It's a recursive function call in Emacs Lisp!
1133               (bookmark-jump-noselect str))
1134           (message
1135            "Bookmark not relocated; consider removing it \(%s\)." str)
1136           nil)))))
1137
1138
1139 ;;;###autoload
1140 (defun bookmark-relocate (bookmark)
1141   "Relocate BOOKMARK to another file (reading file name with minibuffer).
1142 This makes an already existing bookmark point to that file, instead of
1143 the one it used to point at.  Useful when a file has been renamed
1144 after a bookmark was set in it."
1145   (interactive (bookmark-completing-read "Bookmark to relocate"))
1146   (bookmark-maybe-historicize-string bookmark)
1147   (bookmark-maybe-load-default-file)
1148   (let* ((bmrk-filename (bookmark-get-filename bookmark))
1149          (newloc (expand-file-name
1150                   (read-file-name
1151                    (format "Relocate %s to: " bookmark)
1152                    (file-name-directory bmrk-filename)))))
1153     (bookmark-set-filename bookmark newloc)))
1154
1155
1156 ;;;###autoload
1157 (defun bookmark-insert-location (bookmark &optional no-history)
1158   "Insert the name of the file associated with BOOKMARK.
1159 Optional second arg NO-HISTORY means don't record this in the
1160 minibuffer history list `bookmark-history'."
1161   (interactive (bookmark-completing-read "Insert bookmark location"))
1162   (or no-history (bookmark-maybe-historicize-string bookmark))
1163   (insert (bookmark-location bookmark)))
1164
1165 ;;;###autoload
1166 (defalias 'bookmark-locate 'bookmark-insert-location)
1167
1168 (defun bookmark-location (bookmark)
1169   "Return the name of the file associated with BOOKMARK."
1170   (bookmark-maybe-load-default-file)
1171   (bookmark-get-filename bookmark))
1172
1173
1174 ;;;###autoload
1175 (defun bookmark-rename (old &optional new)
1176   "Change the name of OLD bookmark to NEW name.
1177 If called from keyboard, prompt for OLD and NEW.  If called from
1178 menubar, select OLD from a menu and prompt for NEW.
1179
1180 If called from Lisp, prompt for NEW if only OLD was passed as an
1181 argument.  If called with two strings, then no prompting is done.  You
1182 must pass at least OLD when calling from Lisp.
1183
1184 While you are entering the new name, consecutive C-w's insert
1185 consecutive words from the text of the buffer into the new bookmark
1186 name."
1187   (interactive (bookmark-completing-read "Old bookmark name"))
1188   (bookmark-maybe-historicize-string old)
1189   (bookmark-maybe-load-default-file)
1190   (progn
1191     (setq bookmark-current-point (point))
1192     (setq bookmark-yank-point (point))
1193     (setq bookmark-current-buffer (current-buffer))
1194     (let ((newname
1195            (or new   ; use second arg, if non-nil
1196                (read-from-minibuffer
1197                 "New name: "
1198                 nil
1199                 (let ((now-map (copy-keymap minibuffer-local-map)))
1200                   (define-key now-map  "\C-w" 'bookmark-yank-word)
1201                   now-map)
1202                 nil
1203                 'bookmark-history))))
1204       (progn
1205         (bookmark-set-name old newname)
1206         (setq bookmark-current-bookmark newname)
1207         (bookmark-bmenu-surreptitiously-rebuild-list)
1208         (setq bookmark-alist-modification-count
1209               (1+ bookmark-alist-modification-count))
1210         (if (bookmark-time-to-save-p)
1211             (bookmark-save))))))
1212
1213
1214 ;;;###autoload
1215 (defun bookmark-insert (bookmark)
1216   "Insert the text of the file pointed to by bookmark BOOKMARK.
1217 You may have a problem using this function if the value of variable
1218 `bookmark-alist' is nil.  If that happens, you need to load in some
1219 bookmarks.  See help on function `bookmark-load' for more about
1220 this."
1221   (interactive (bookmark-completing-read "Insert bookmark contents"))
1222   (bookmark-maybe-historicize-string bookmark)
1223   (bookmark-maybe-load-default-file)
1224   (let ((orig-point (point))
1225         (str-to-insert
1226          (save-excursion
1227            (set-buffer (car (bookmark-jump-noselect bookmark)))
1228            (buffer-substring (point-min) (point-max)))))
1229     (insert str-to-insert)
1230     (push-mark)
1231     (goto-char orig-point)))
1232
1233
1234 ;;;###autoload
1235 (defun bookmark-delete (bookmark &optional batch)
1236   "Delete BOOKMARK from the bookmark list.
1237 Removes only the first instance of a bookmark with that name.  If
1238 there are one or more other bookmarks with the same name, they will
1239 not be deleted.  Defaults to the \"current\" bookmark \(that is, the
1240 one most recently used in this file, if any\).
1241 Optional second arg BATCH means don't update the bookmark list buffer,
1242 probably because we were called from there."
1243   (interactive
1244    (bookmark-completing-read "Delete bookmark" bookmark-current-bookmark))
1245   (bookmark-maybe-historicize-string bookmark)
1246   (bookmark-maybe-load-default-file)
1247   (let ((will-go (bookmark-get-bookmark bookmark)))
1248     (setq bookmark-alist (delq will-go bookmark-alist))
1249     ;; Added by db, nil bookmark-current-bookmark if the last
1250     ;; occurrence has been deleted
1251     (or (bookmark-get-bookmark bookmark-current-bookmark)
1252         (setq bookmark-current-bookmark nil)))
1253   ;; Don't rebuild the list
1254   (if batch
1255       nil
1256     (bookmark-bmenu-surreptitiously-rebuild-list)
1257     (setq bookmark-alist-modification-count
1258           (1+ bookmark-alist-modification-count))
1259     (if (bookmark-time-to-save-p)
1260         (bookmark-save))))
1261
1262
1263 (defun bookmark-time-to-save-p (&optional last-time)
1264   ;; By Gregory M. Saunders <saunders@cis.ohio-state.edu>
1265   ;; finds out whether it's time to save bookmarks to a file, by
1266   ;; examining the value of variable bookmark-save-flag, and maybe
1267   ;; bookmark-alist-modification-count.  Returns t if they should be
1268   ;; saved, nil otherwise.  if last-time is non-nil, then this is
1269   ;; being called when emacs is killed.
1270   (cond (last-time
1271          (and (> bookmark-alist-modification-count 0)
1272               bookmark-save-flag))
1273         ((numberp bookmark-save-flag)
1274          (>= bookmark-alist-modification-count bookmark-save-flag))
1275         (t
1276          nil)))
1277
1278
1279 ;;;###autoload
1280 (defun bookmark-write ()
1281   "Write bookmarks to a file (reading the file name with the minibuffer).
1282 Don't use this in Lisp programs; use `bookmark-save' instead."
1283   (interactive)
1284   (bookmark-maybe-load-default-file)
1285   (bookmark-save t))
1286
1287
1288 ;;;###autoload
1289 (defun bookmark-save (&optional parg file)
1290   "Save currently defined bookmarks.
1291 Saves by default in the file defined by the variable
1292 `bookmark-default-file'.  With a prefix arg, save it in file FILE
1293 \(second argument\).
1294
1295 If you are calling this from Lisp, the two arguments are PREFIX-ARG
1296 and FILE, and if you just want it to write to the default file, then
1297 pass no arguments.  Or pass in nil and FILE, and it will save in FILE
1298 instead.  If you pass in one argument, and it is non-nil, then the
1299 user will be interactively queried for a file to save in.
1300
1301 When you want to load in the bookmarks from a file, use
1302 \`bookmark-load\', \\[bookmark-load].  That function will prompt you
1303 for a file, defaulting to the file defined by variable
1304 `bookmark-default-file'."
1305   (interactive "P")
1306   (bookmark-maybe-load-default-file)
1307   (cond
1308    ((and (null parg) (null file))
1309     ;;whether interactive or not, write to default file
1310     (bookmark-write-file bookmark-default-file))
1311    ((and (null parg) file)
1312     ;;whether interactive or not, write to given file
1313     (bookmark-write-file file))
1314    ((and parg (not file))
1315     ;;have been called interactively w/ prefix arg
1316     (let ((file (read-file-name "File to save bookmarks in: ")))
1317       (bookmark-write-file file)))
1318    (t ; someone called us with prefix-arg *and* a file, so just write to file
1319     (bookmark-write-file file)))
1320   ;; signal that we have synced the bookmark file by setting this to
1321   ;; 0.  If there was an error at any point before, it will not get
1322   ;; set, which is what we want.
1323   (setq bookmark-alist-modification-count 0))
1324
1325
1326 \f
1327 (defun bookmark-write-file (file)
1328   (save-excursion
1329     (save-window-excursion
1330       (if (>= baud-rate 9600)
1331           (message "Saving bookmarks to file %s..." file))
1332       (set-buffer (let ((enable-local-variables nil))
1333                     (find-file-noselect file)))
1334       (goto-char (point-min))
1335       (delete-region (point-min) (point-max))
1336       (bookmark-insert-file-format-version-stamp)
1337       (pp bookmark-alist (current-buffer))
1338       (let ((version-control
1339              (cond
1340               ((null bookmark-version-control) nil)
1341               ((eq 'never bookmark-version-control) 'never)
1342               ((eq 'nospecial bookmark-version-control) version-control)
1343               (t
1344                t))))
1345         (write-file file)
1346         (kill-buffer (current-buffer))
1347         (if (>= baud-rate 9600)
1348             (message "Saving bookmarks to file %s...done" file))
1349         ))))
1350
1351
1352 ;;;###autoload
1353 (defun bookmark-load (file &optional revert no-msg)
1354   "Load bookmarks from FILE (which must be in bookmark format).
1355 Appends loaded bookmarks to the front of the list of bookmarks.  If
1356 optional second argument REVERT is non-nil, existing bookmarks are
1357 destroyed.  Optional third arg NO-MSG means don't display any messages
1358 while loading.
1359
1360 If you load a file that doesn't contain a proper bookmark alist, you
1361 will corrupt Emacs's bookmark list.  Generally, you should only load
1362 in files that were created with the bookmark functions in the first
1363 place.  Your own personal bookmark file, `~/.emacs.bmk', is
1364 maintained automatically by Emacs; you shouldn't need to load it
1365 explicitly."
1366   (interactive
1367    (list (read-file-name
1368           (format "Load bookmarks from: (%s) "
1369                   bookmark-default-file)
1370           ;;Default might not be used often,
1371           ;;but there's no better default, and
1372           ;;I guess it's better than none at all.
1373           "~/" bookmark-default-file 'confirm)))
1374   (setq file (expand-file-name file))
1375   (if (file-readable-p file)
1376       (save-excursion
1377         (save-window-excursion
1378           (if (and (null no-msg) (>= baud-rate 9600))
1379               (message "Loading bookmarks from %s..." file))
1380           (set-buffer (let ((enable-local-variables nil))
1381                         (find-file-noselect file)))
1382           (goto-char (point-min))
1383           (bookmark-maybe-upgrade-file-format)
1384           (let ((blist (bookmark-alist-from-buffer)))
1385             (if (listp blist)
1386                 (progn
1387                   (if (not revert)
1388                       (setq bookmark-alist-modification-count
1389                             (1+ bookmark-alist-modification-count))
1390                     (setq bookmark-alist-modification-count 0))
1391                   (setq bookmark-alist
1392                         (append blist (if (not revert) bookmark-alist)))
1393                   (bookmark-bmenu-surreptitiously-rebuild-list))
1394               (error "Invalid bookmark list in %s" file)))
1395           (kill-buffer (current-buffer)))
1396         (if (and (null no-msg) (>= baud-rate 9600))
1397             (message "Loading bookmarks from %s...done" file)))
1398     (error "Cannot read bookmark file %s" file)))
1399
1400
1401 \f
1402 ;;; Code supporting the dired-like bookmark menu.  Prefix is
1403 ;;; "bookmark-bmenu" for "buffer-menu":
1404
1405
1406 (defvar bookmark-bmenu-bookmark-column nil)
1407
1408
1409 (defvar bookmark-bmenu-hidden-bookmarks ())
1410
1411
1412 (defvar bookmark-bmenu-mode-map nil)
1413
1414
1415 (if bookmark-bmenu-mode-map
1416     nil
1417   (setq bookmark-bmenu-mode-map (make-keymap))
1418   (suppress-keymap bookmark-bmenu-mode-map t)
1419   (define-key bookmark-bmenu-mode-map "q" 'bookmark-bmenu-quit)
1420   (define-key bookmark-bmenu-mode-map "v" 'bookmark-bmenu-select)
1421   (define-key bookmark-bmenu-mode-map "w" 'bookmark-bmenu-locate)
1422   (define-key bookmark-bmenu-mode-map "2" 'bookmark-bmenu-2-window)
1423   (define-key bookmark-bmenu-mode-map "1" 'bookmark-bmenu-1-window)
1424   (define-key bookmark-bmenu-mode-map "j" 'bookmark-bmenu-this-window)
1425   (define-key bookmark-bmenu-mode-map "\C-c\C-c" 'bookmark-bmenu-this-window)
1426   (define-key bookmark-bmenu-mode-map "f" 'bookmark-bmenu-this-window)
1427   (define-key bookmark-bmenu-mode-map "o" 'bookmark-bmenu-other-window)
1428   (define-key bookmark-bmenu-mode-map "\C-o"
1429     'bookmark-bmenu-switch-other-window)
1430   (define-key bookmark-bmenu-mode-map "s" 'bookmark-bmenu-save)
1431   (define-key bookmark-bmenu-mode-map "k" 'bookmark-bmenu-delete)
1432   (define-key bookmark-bmenu-mode-map "\C-d" 'bookmark-bmenu-delete-backwards)
1433   (define-key bookmark-bmenu-mode-map "x" 'bookmark-bmenu-execute-deletions)
1434   (define-key bookmark-bmenu-mode-map "d" 'bookmark-bmenu-delete)
1435   (define-key bookmark-bmenu-mode-map " " 'next-line)
1436   (define-key bookmark-bmenu-mode-map "n" 'next-line)
1437   (define-key bookmark-bmenu-mode-map "p" 'previous-line)
1438   (define-key bookmark-bmenu-mode-map "\177" 'bookmark-bmenu-backup-unmark)
1439   (define-key bookmark-bmenu-mode-map "?" 'describe-mode)
1440   (define-key bookmark-bmenu-mode-map "u" 'bookmark-bmenu-unmark)
1441   (define-key bookmark-bmenu-mode-map "m" 'bookmark-bmenu-mark)
1442   (define-key bookmark-bmenu-mode-map "l" 'bookmark-bmenu-load)
1443   (define-key bookmark-bmenu-mode-map "r" 'bookmark-bmenu-rename)
1444   (define-key bookmark-bmenu-mode-map "t" 'bookmark-bmenu-toggle-filenames)
1445   (define-key bookmark-bmenu-mode-map "a" 'bookmark-bmenu-show-annotation)
1446   (define-key bookmark-bmenu-mode-map "A" 'bookmark-bmenu-show-all-annotations)
1447   (define-key bookmark-bmenu-mode-map "e" 'bookmark-bmenu-edit-annotation))
1448
1449
1450
1451 ;; Bookmark Buffer Menu mode is suitable only for specially formatted
1452 ;; data.
1453 (put 'bookmark-bmenu-mode 'mode-class 'special)
1454
1455
1456 ;; todo: need to display whether or not bookmark exists as a buffer in
1457 ;; flag column.
1458
1459 ;; Format:
1460 ;; FLAGS  BOOKMARK [ LOCATION ]
1461
1462
1463 (defun bookmark-bmenu-surreptitiously-rebuild-list ()
1464   "Rebuild the Bookmark List if it exists.
1465 Don't affect the buffer ring order."
1466   (if (get-buffer "*Bookmark List*")
1467       (save-excursion
1468         (save-window-excursion
1469           (bookmark-bmenu-list)))))
1470
1471
1472 ;;;###autoload
1473 (defun bookmark-bmenu-list ()
1474   "Display a list of existing bookmarks.
1475 The list is displayed in a buffer named `*Bookmark List*'.
1476 The leftmost column displays a D if the bookmark is flagged for
1477 deletion, or > if it is flagged for displaying."
1478   (interactive)
1479   (bookmark-maybe-load-default-file)
1480   (if (interactive-p)
1481       (switch-to-buffer (get-buffer-create "*Bookmark List*"))
1482     (set-buffer (get-buffer-create "*Bookmark List*")))
1483   (let ((buffer-read-only nil))
1484     (delete-region (point-max) (point-min))
1485     (goto-char (point-min)) ;sure are playing it safe...
1486     (insert "% Bookmark\n- --------\n")
1487     (bookmark-maybe-sort-alist)
1488     (mapcar
1489      (lambda (full-record)
1490        ;; if a bookmark has an annotation, prepend a "*"
1491        ;; in the list of bookmarks.
1492        (let ((annotation (bookmark-get-annotation
1493                           (bookmark-name-from-full-record full-record))))
1494          (if (and (not (eq annotation nil))
1495                   (not (string-equal annotation "")))
1496              (insert " *")
1497            (insert "  "))
1498          (insert (concat (bookmark-name-from-full-record full-record) "\n"))))
1499      bookmark-alist))
1500   (goto-char (point-min))
1501   (forward-line 2)
1502   (bookmark-bmenu-mode)
1503   (if bookmark-bmenu-toggle-filenames
1504       (bookmark-bmenu-toggle-filenames t)))
1505
1506 ;;;###autoload
1507 (defalias 'list-bookmarks 'bookmark-bmenu-list)
1508 ;;;###autoload
1509 (defalias 'edit-bookmarks 'bookmark-bmenu-list)
1510
1511
1512
1513 (defun bookmark-bmenu-mode ()
1514   "Major mode for editing a list of bookmarks.
1515 Each line describes one of the bookmarks in Emacs.
1516 Letters do not insert themselves; instead, they are commands.
1517 Bookmark names preceded by a \"*\" have annotations.
1518 \\<bookmark-bmenu-mode-map>
1519 \\[bookmark-bmenu-mark] -- mark bookmark to be displayed.
1520 \\[bookmark-bmenu-select] -- select bookmark of line point is on.
1521   Also show bookmarks marked using m in other windows.
1522 \\[bookmark-bmenu-toggle-filenames] -- toggle displaying of filenames (they may obscure long bookmark names).
1523 \\[bookmark-bmenu-locate] -- display (in minibuffer) location of this bookmark.
1524 \\[bookmark-bmenu-1-window] -- select this bookmark in full-frame window.
1525 \\[bookmark-bmenu-2-window] -- select this bookmark in one window,
1526   together with bookmark selected before this one in another window.
1527 \\[bookmark-bmenu-this-window] -- select this bookmark in place of the bookmark menu buffer.
1528 \\[bookmark-bmenu-other-window] -- select this bookmark in another window,
1529   so the bookmark menu bookmark remains visible in its window.
1530 \\[bookmark-bmenu-switch-other-window] -- switch the other window to this bookmark.
1531 \\[bookmark-bmenu-rename] -- rename this bookmark \(prompts for new name\).
1532 \\[bookmark-bmenu-delete] -- mark this bookmark to be deleted, and move down.
1533 \\[bookmark-bmenu-delete-backwards] -- mark this bookmark to be deleted, and move up.
1534 \\[bookmark-bmenu-execute-deletions] -- delete bookmarks marked with `\\[bookmark-bmenu-delete]'.
1535 \\[bookmark-bmenu-save] -- save the current bookmark list in the default file.
1536   With a prefix arg, prompts for a file to save in.
1537 \\[bookmark-bmenu-load] -- load in a file of bookmarks (prompts for file.)
1538 \\[bookmark-bmenu-unmark] -- remove all kinds of marks from current line.
1539   With prefix argument, also move up one line.
1540 \\[bookmark-bmenu-backup-unmark] -- back up a line and remove marks.
1541 \\[bookmark-bmenu-show-annotation] -- show the annotation, if it exists, for the current bookmark
1542   in another buffer.
1543 \\[bookmark-bmenu-show-all-annotations] -- show the annotations of all bookmarks in another buffer.
1544 \\[bookmark-bmenu-edit-annotation] -- edit the annotation for the current bookmark."
1545   (kill-all-local-variables)
1546   (use-local-map bookmark-bmenu-mode-map)
1547   (setq truncate-lines t)
1548   (setq buffer-read-only t)
1549   (setq major-mode 'bookmark-bmenu-mode)
1550   (setq mode-name "Bookmark Menu")
1551   (run-hooks 'bookmark-bmenu-mode-hook))
1552
1553
1554 (defun bookmark-bmenu-toggle-filenames (&optional show)
1555   "Toggle whether filenames are shown in the bookmark list.
1556 Optional argument SHOW means show them unconditionally."
1557   (interactive)
1558   (cond
1559    (show
1560     (setq bookmark-bmenu-toggle-filenames nil)
1561     (bookmark-bmenu-show-filenames)
1562     (setq bookmark-bmenu-toggle-filenames t))
1563    (bookmark-bmenu-toggle-filenames
1564     (bookmark-bmenu-hide-filenames)
1565     (setq bookmark-bmenu-toggle-filenames nil))
1566    (t
1567     (bookmark-bmenu-show-filenames)
1568     (setq bookmark-bmenu-toggle-filenames t))))
1569
1570
1571 (defun bookmark-bmenu-show-filenames (&optional force)
1572   (if (and (not force) bookmark-bmenu-toggle-filenames)
1573       nil ;already shown, so do nothing
1574     (save-excursion
1575       (save-window-excursion
1576         (goto-char (point-min))
1577         (forward-line 2)
1578         (setq bookmark-bmenu-hidden-bookmarks ())
1579         (let ((buffer-read-only nil))
1580           (while (< (point) (point-max))
1581             (let ((bmrk (bookmark-bmenu-bookmark)))
1582               (setq bookmark-bmenu-hidden-bookmarks
1583                     (cons bmrk bookmark-bmenu-hidden-bookmarks))
1584               (move-to-column bookmark-bmenu-file-column t)
1585               (delete-region (point) (progn (end-of-line) (point)))
1586               (insert "  ")
1587               ;; Pass the NO-HISTORY arg:
1588               (bookmark-insert-location bmrk t)
1589               (forward-line 1))))))))
1590
1591
1592 (defun bookmark-bmenu-hide-filenames (&optional force)
1593   (if (and (not force) bookmark-bmenu-toggle-filenames)
1594       ;; nothing to hide if above is nil
1595       (save-excursion
1596         (save-window-excursion
1597           (goto-char (point-min))
1598           (forward-line 2)
1599           (setq bookmark-bmenu-hidden-bookmarks
1600                 (nreverse bookmark-bmenu-hidden-bookmarks))
1601           (save-excursion
1602             (goto-char (point-min))
1603             (search-forward "Bookmark")
1604             (backward-word 1)
1605             (setq bookmark-bmenu-bookmark-column (current-column)))
1606           (save-excursion
1607             (let ((buffer-read-only nil))
1608               (while bookmark-bmenu-hidden-bookmarks
1609                 (move-to-column bookmark-bmenu-bookmark-column t)
1610                 (bookmark-kill-line)
1611                 (insert (car bookmark-bmenu-hidden-bookmarks))
1612                 (setq bookmark-bmenu-hidden-bookmarks
1613                       (cdr bookmark-bmenu-hidden-bookmarks))
1614                 (forward-line 1))))))))
1615
1616
1617 ;; if you look at this next function from far away, it resembles a
1618 ;; gun.  But only with this comment above...
1619 (defun bookmark-bmenu-check-position ()
1620   ;; Returns t if on a line with a bookmark.
1621   ;; Otherwise, repositions and returns t.
1622   ;; written by David Hughes <djh@harston.cv.com>
1623   ;; Mucho thanks, David!  -karl
1624   (cond ((< (count-lines (point-min) (point)) 2)
1625          (goto-char (point-min))
1626          (forward-line 2)
1627          t)
1628         ((and (bolp) (eobp))
1629          (beginning-of-line 0)
1630          t)
1631         (t
1632          t)))
1633
1634
1635 (defun bookmark-bmenu-bookmark ()
1636   ;; return a string which is bookmark of this line.
1637   (if (bookmark-bmenu-check-position)
1638       (save-excursion
1639         (save-window-excursion
1640           (goto-char (point-min))
1641           (search-forward "Bookmark")
1642           (backward-word 1)
1643           (setq bookmark-bmenu-bookmark-column (current-column)))))
1644   (if bookmark-bmenu-toggle-filenames
1645       (bookmark-bmenu-hide-filenames))
1646   (save-excursion
1647     (save-window-excursion
1648       (beginning-of-line)
1649       (forward-char bookmark-bmenu-bookmark-column)
1650       (prog1
1651           (buffer-substring (point)
1652                             (progn
1653                               (end-of-line)
1654                               (point)))
1655         ;; well, this is certainly crystal-clear:
1656         (if bookmark-bmenu-toggle-filenames
1657             (bookmark-bmenu-toggle-filenames t))))))
1658
1659
1660 (defun bookmark-show-annotation (bookmark)
1661   "Display the annotation for bookmark named BOOKMARK in a buffer,
1662 if an annotation exists."
1663   (let ((annotation (bookmark-get-annotation bookmark)))
1664     (if (and (not (eq annotation nil))
1665              (not (string-equal annotation "")))
1666         (progn
1667           (save-excursion
1668             (let ((old-buf (current-buffer)))
1669               (pop-to-buffer (get-buffer-create "*Bookmark Annotation*") t)
1670               (delete-region (point-min) (point-max))
1671               ; (insert (concat "Annotation for bookmark '" bookmark "':\n\n"))
1672               (insert annotation)
1673               (goto-char (point-min))
1674               (pop-to-buffer old-buf)))))))
1675
1676
1677 (defun bookmark-show-all-annotations ()
1678   "Display the annotations for all bookmarks in a buffer."
1679   (let ((old-buf (current-buffer)))
1680     (pop-to-buffer (get-buffer-create "*Bookmark Annotation*") t)
1681     (delete-region (point-min) (point-max))
1682     (mapcar
1683      (lambda (full-record)
1684        (let* ((name (bookmark-name-from-full-record full-record))
1685               (ann  (bookmark-get-annotation name)))
1686          (insert (concat name ":\n"))
1687          (if (and (not (eq ann nil)) (not (string-equal ann "")))
1688              ;; insert the annotation, indented by 4 spaces.
1689              (progn
1690                (save-excursion (insert ann))
1691                (while (< (point) (point-max))
1692                  (beginning-of-line) ; paranoia
1693                  (insert "    ")
1694                  (forward-line)
1695                  (end-of-line))))))
1696      bookmark-alist)
1697     (goto-char (point-min))
1698     (pop-to-buffer old-buf)))
1699
1700
1701 (defun bookmark-bmenu-mark ()
1702   "Mark bookmark on this line to be displayed by \\<bookmark-bmenu-mode-map>\\[bookmark-bmenu-select]."
1703   (interactive)
1704   (beginning-of-line)
1705   (if (bookmark-bmenu-check-position)
1706       (let ((buffer-read-only nil))
1707         (delete-char 1)
1708         (insert ?>)
1709         (forward-line 1))))
1710
1711
1712 (defun bookmark-bmenu-select ()
1713   "Select this line's bookmark; also display bookmarks marked with `>'.
1714 You can mark bookmarks with the \\<bookmark-bmenu-mode-map>\\[bookmark-bmenu-mark] command."
1715   (interactive)
1716   (if (bookmark-bmenu-check-position)
1717       (let ((bmrk (bookmark-bmenu-bookmark))
1718             (menu (current-buffer))
1719             (others ())
1720             tem)
1721         (goto-char (point-min))
1722         (while (re-search-forward "^>" nil t)
1723           (setq tem (bookmark-bmenu-bookmark))
1724           (let ((buffer-read-only nil))
1725             (delete-char -1)
1726             (insert ?\ ))
1727           (or (string-equal tem bmrk)
1728               (member tem others)
1729               (setq others (cons tem others))))
1730         (setq others (nreverse others)
1731               tem (/ (1- (frame-height)) (1+ (length others))))
1732         (delete-other-windows)
1733         (bookmark-jump bmrk)
1734         (bury-buffer menu)
1735         (if others
1736             (while others
1737               (split-window nil tem)
1738               (other-window 1)
1739               (bookmark-jump (car others))
1740               (setq others (cdr others)))
1741           (other-window 1)))))
1742
1743
1744 (defun bookmark-bmenu-save (parg)
1745   "Save the current list into a bookmark file.
1746 With a prefix arg, prompts for a file to save them in."
1747   (interactive "P")
1748   (save-excursion
1749     (save-window-excursion
1750       (bookmark-save parg))))
1751
1752
1753 (defun bookmark-bmenu-load ()
1754   "Load the bookmark file and rebuild the bookmark menu-buffer."
1755   (interactive)
1756   (if (bookmark-bmenu-check-position)
1757       (save-excursion
1758         (save-window-excursion
1759           ;; This will call `bookmark-bmenu-list'
1760           (call-interactively 'bookmark-load)))))
1761
1762
1763 (defun bookmark-bmenu-1-window ()
1764   "Select this line's bookmark, alone, in full frame."
1765   (interactive)
1766   (if (bookmark-bmenu-check-position)
1767       (progn
1768         (bookmark-jump (bookmark-bmenu-bookmark))
1769         (bury-buffer (other-buffer))
1770         (delete-other-windows))))
1771
1772
1773 (defun bookmark-bmenu-2-window ()
1774   "Select this line's bookmark, with previous buffer in second window."
1775   (interactive)
1776   (if (bookmark-bmenu-check-position)
1777       (let ((bmrk (bookmark-bmenu-bookmark))
1778             (menu (current-buffer))
1779             (pop-up-windows t))
1780         (delete-other-windows)
1781         (switch-to-buffer (other-buffer))
1782         (let* ((pair (bookmark-jump-noselect bmrk))
1783                (buff (car pair))
1784                (pos  (cdr pair)))
1785           (pop-to-buffer buff)
1786           (goto-char pos))
1787         (bury-buffer menu))))
1788
1789
1790 (defun bookmark-bmenu-this-window ()
1791   "Select this line's bookmark in this window."
1792   (interactive)
1793   (if (bookmark-bmenu-check-position)
1794       (bookmark-jump (bookmark-bmenu-bookmark))))
1795
1796
1797 (defun bookmark-bmenu-other-window ()
1798   "Select this line's bookmark in other window, leaving bookmark menu visible."
1799   (interactive)
1800   (let ((bookmark (bookmark-bmenu-bookmark)))
1801     (if (bookmark-bmenu-check-position)
1802         (let* ((pair (bookmark-jump-noselect bookmark))
1803                (buff (car pair))
1804                (pos  (cdr pair)))
1805           (switch-to-buffer-other-window buff)
1806           (goto-char pos)
1807           (set-window-point (get-buffer-window buff) pos)
1808           (bookmark-show-annotation bookmark)))))
1809
1810
1811 (defun bookmark-bmenu-switch-other-window ()
1812   "Make the other window select this line's bookmark.
1813 The current window remains selected."
1814   (interactive)
1815   (let ((bookmark (bookmark-bmenu-bookmark)))
1816     (if (bookmark-bmenu-check-position)
1817         (let* ((pair (bookmark-jump-noselect bookmark))
1818                (buff (car pair))
1819                (pos  (cdr pair)))
1820           (display-buffer buff)
1821           (let ((o-buffer (current-buffer)))
1822             ;; save-excursion won't do
1823             (set-buffer buff)
1824             (goto-char pos)
1825             (set-window-point (get-buffer-window buff) pos)
1826             (set-buffer o-buffer))
1827           (bookmark-show-annotation bookmark)))))
1828
1829
1830 (defun bookmark-bmenu-show-annotation ()
1831   "Show the annotation for the current bookmark in another window."
1832   (interactive)
1833   (let ((bookmark (bookmark-bmenu-bookmark)))
1834     (if (bookmark-bmenu-check-position)
1835         (bookmark-show-annotation bookmark))))
1836
1837
1838 (defun bookmark-bmenu-show-all-annotations ()
1839   "Show the annotation for all bookmarks in another window."
1840   (interactive)
1841   (bookmark-show-all-annotations))
1842
1843
1844 (defun bookmark-bmenu-edit-annotation ()
1845   "Edit the annotation for the current bookmark in another window."
1846   (interactive)
1847   (let ((bookmark (bookmark-bmenu-bookmark)))
1848     (if (bookmark-bmenu-check-position)
1849         (bookmark-edit-annotation bookmark))))
1850
1851
1852 (defun bookmark-bmenu-quit ()
1853   "Quit the bookmark menu."
1854   (interactive)
1855   (let ((buffer (current-buffer)))
1856     (switch-to-buffer (other-buffer))
1857     (bury-buffer buffer)))
1858
1859
1860 (defun bookmark-bmenu-unmark (&optional backup)
1861   "Cancel all requested operations on bookmark on this line and move down.
1862 Optional BACKUP means move up."
1863   (interactive "P")
1864   (beginning-of-line)
1865   (if (bookmark-bmenu-check-position)
1866       (progn
1867         (let ((buffer-read-only nil))
1868           (delete-char 1)
1869           ;; any flags to reset according to circumstances?  How about a
1870           ;; flag indicating whether this bookmark is being visited?
1871           ;; well, we don't have this now, so maybe later.
1872           (insert " "))
1873         (forward-line (if backup -1 1)))))
1874
1875
1876 (defun bookmark-bmenu-backup-unmark ()
1877   "Move up and cancel all requested operations on bookmark on line above."
1878   (interactive)
1879   (forward-line -1)
1880   (if (bookmark-bmenu-check-position)
1881       (progn
1882         (bookmark-bmenu-unmark)
1883         (forward-line -1))))
1884
1885
1886 (defun bookmark-bmenu-delete ()
1887   "Mark bookmark on this line to be deleted.
1888 To carry out the deletions that you've marked, use \\<bookmark-bmenu-mode-map>\\[bookmark-bmenu-execute-deletions]."
1889   (interactive)
1890   (beginning-of-line)
1891   (if (bookmark-bmenu-check-position)
1892       (let ((buffer-read-only nil))
1893         (delete-char 1)
1894         (insert ?D)
1895         (forward-line 1))))
1896
1897
1898 (defun bookmark-bmenu-delete-backwards ()
1899   "Mark bookmark on this line to be deleted, then move up one line.
1900 To carry out the deletions that you've marked, use \\<bookmark-bmenu-mode-map>\\[bookmark-bmenu-execute-deletions]."
1901   (interactive)
1902   (bookmark-bmenu-delete)
1903   (forward-line -2)
1904   (if (bookmark-bmenu-check-position)
1905       (forward-line 1)))
1906
1907
1908 (defun bookmark-bmenu-execute-deletions ()
1909   "Delete bookmarks marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
1910   (interactive)
1911   (message "Deleting bookmarks...")
1912   (let ((hide-em bookmark-bmenu-toggle-filenames)
1913         (o-point  (point))
1914         (o-str    (save-excursion
1915                     (beginning-of-line)
1916                     (if (looking-at "^D")
1917                         nil
1918                       (buffer-substring
1919                        (point)
1920                        (progn (end-of-line) (point))))))
1921         (o-col     (current-column)))
1922     (if hide-em (bookmark-bmenu-hide-filenames))
1923     (setq bookmark-bmenu-toggle-filenames nil)
1924     (goto-char (point-min))
1925     (forward-line 1)
1926     (while (re-search-forward "^D" (point-max) t)
1927       (bookmark-delete (bookmark-bmenu-bookmark) t)) ; pass BATCH arg
1928     (bookmark-bmenu-list)
1929     (setq bookmark-bmenu-toggle-filenames hide-em)
1930     (if bookmark-bmenu-toggle-filenames
1931         (bookmark-bmenu-toggle-filenames t))
1932     (if o-str
1933         (progn
1934           (goto-char (point-min))
1935           (search-forward o-str)
1936           (beginning-of-line)
1937           (forward-char o-col))
1938       (goto-char o-point))
1939     (beginning-of-line)
1940     (setq bookmark-alist-modification-count
1941           (1+ bookmark-alist-modification-count))
1942     (if (bookmark-time-to-save-p)
1943         (bookmark-save))
1944     (message "Deleting bookmarks...done")
1945     ))
1946
1947
1948 (defun bookmark-bmenu-rename ()
1949   "Rename bookmark on current line.  Prompts for a new name."
1950   (interactive)
1951   (if (bookmark-bmenu-check-position)
1952       (let ((bmrk (bookmark-bmenu-bookmark))
1953             (thispoint (point)))
1954         (bookmark-rename bmrk)
1955         (bookmark-bmenu-list)
1956         (goto-char thispoint))))
1957
1958
1959 (defun bookmark-bmenu-locate ()
1960   "Display location of this bookmark.  Displays in the minibuffer."
1961   (interactive)
1962   (if (bookmark-bmenu-check-position)
1963       (let ((bmrk (bookmark-bmenu-bookmark)))
1964         (message (bookmark-location bmrk)))))
1965
1966
1967 \f
1968 ;;; Menu bar stuff.  Prefix is "bookmark-menu".
1969
1970 (defun bookmark-menu-build-paned-menu (name entries)
1971   "Build a multi-paned menu named NAME from the strings in ENTRIES.
1972 That is, ENTRIES is a list of strings which appear as the choices
1973 in the menu.  The number of panes depends on the number of entries.
1974 The visible entries are truncated to `bookmark-menu-length', but the
1975 strings returned are not."
1976   (let* ((f-height (/ (frame-height) 2))
1977          (pane-list
1978           (let (temp-pane-list
1979                 (iter 0))
1980             (while entries
1981               (let (lst
1982                     (count 0))
1983                 (while (and (< count f-height) entries)
1984                   (let ((str (car entries)))
1985                     (setq lst (cons
1986                                (cons
1987                                 (if (> (length str) bookmark-menu-length)
1988                                     (substring str 0 bookmark-menu-length)
1989                                   str)
1990                                 str)
1991                                lst))
1992                     (setq entries (cdr entries))
1993                     (setq count (1+ count))))
1994                 (setq iter (1+ iter))
1995                 (setq
1996                  temp-pane-list
1997                  (cons
1998                   (cons
1999                    (format "-*- %s (%d) -*-" name iter)
2000                    (nreverse lst))
2001                   temp-pane-list))))
2002             (nreverse temp-pane-list))))
2003
2004     ;; Return the menu:
2005     (cons (concat "-*- " name " -*-") pane-list)))
2006
2007
2008 (defun bookmark-build-xemacs-menu (name entries function)
2009   "Build a menu named NAME from the strings in ENTRIES.
2010 That is, ENTRIES is a list of strings that appear as the choices
2011 in the menu.
2012 The visible entries are truncated to `bookmark-menu-length', but the
2013 strings returned are not."
2014   (let* (lst
2015          (pane-list
2016           (progn
2017             (while entries
2018               (let ((str (car entries)))
2019                 (setq lst (cons
2020                            (vector
2021                             (if (> (length str) bookmark-menu-length)
2022                                 (substring str 0 bookmark-menu-length)
2023                               str)
2024                             (list function str)
2025                             t)
2026                            lst))
2027                 (setq entries (cdr entries))))
2028             (nreverse lst))))
2029
2030     ;; Return the menu:
2031     (append (if popup-menu-titles (list (concat "-*- " name " -*-")))
2032             pane-list)))
2033
2034
2035 (defun bookmark-menu-popup-paned-menu (event name entries)
2036   "Pop up multi-paned menu at EVENT, return string chosen from ENTRIES.
2037 That is, ENTRIES is a list of strings which appear as the choices
2038 in the menu.
2039 The number of panes depends on the number of entries."
2040   (interactive "e")
2041   (x-popup-menu event (bookmark-menu-build-paned-menu name entries)))
2042
2043
2044 (defun bookmark-menu-popup-paned-bookmark-menu (event name)
2045   "Pop up menu of bookmarks, return chosen bookmark.
2046 Pop up at EVENT, menu's name is NAME.
2047 The number of panes depends on the number of bookmarks."
2048   (bookmark-menu-popup-paned-menu event name (bookmark-all-names)))
2049
2050
2051 (defun bookmark-popup-menu-and-apply-function (func-sym menu-label event)
2052   ;; help function for making menus that need to apply a bookmark
2053   ;; function to a string.
2054   (let* ((choice (bookmark-menu-popup-paned-bookmark-menu
2055                   event menu-label)))
2056     (if choice (apply func-sym (list choice)))))
2057
2058
2059 ;;;###autoload
2060 (defun bookmark-menu-insert (event)
2061   "Insert the text of the file pointed to by bookmark BOOKMARK.
2062 You may have a problem using this function if the value of variable
2063 `bookmark-alist' is nil.  If that happens, you need to load in some
2064 bookmarks.  See help on function `bookmark-load' for more about
2065 this.
2066
2067 Warning: this function only takes an EVENT as argument.  Use the
2068 corresponding bookmark function from Lisp \(the one without the
2069 \"-menu-\" in its name\)."
2070   (interactive "e")
2071   (bookmark-popup-menu-and-apply-function
2072    'bookmark-insert "Insert Bookmark Contents" event))
2073
2074
2075 ;;;###autoload
2076 (defun bookmark-menu-jump (event)
2077   "Jump to bookmark BOOKMARK (a point in some file).
2078 You may have a problem using this function if the value of variable
2079 `bookmark-alist' is nil.  If that happens, you need to load in some
2080 bookmarks.  See help on function `bookmark-load' for more about
2081 this.
2082
2083 Warning: this function only takes an EVENT as argument.  Use the
2084 corresponding bookmark function from Lisp \(the one without the
2085 \"-menu-\" in its name\)."
2086   (interactive "e")
2087   (bookmark-popup-menu-and-apply-function
2088    'bookmark-jump "Jump to Bookmark" event))
2089
2090
2091 ;;;###autoload
2092 (defun bookmark-menu-locate (event)
2093   "Insert the name of the file associated with BOOKMARK.
2094 \(This is not the same as the contents of that file\).
2095
2096 Warning: this function only takes an EVENT as argument.  Use the
2097 corresponding bookmark function from Lisp \(the one without the
2098 \"-menu-\" in its name\)."
2099   (interactive "e")
2100   (bookmark-popup-menu-and-apply-function
2101    'bookmark-insert-location "Insert Bookmark Location" event))
2102
2103
2104 ;;;###autoload
2105 (defun bookmark-menu-rename (event)
2106   "Change the name of OLD-BOOKMARK to NEWNAME.
2107 If called from keyboard, prompts for OLD-BOOKMARK and NEWNAME.
2108 If called from menubar, OLD-BOOKMARK is selected from a menu, and
2109 prompts for NEWNAME.
2110 If called from Lisp, prompts for NEWNAME if only OLD-BOOKMARK was
2111 passed as an argument.  If called with two strings, then no prompting
2112 is done.  You must pass at least OLD-BOOKMARK when calling from Lisp.
2113
2114 While you are entering the new name, consecutive C-w's insert
2115 consecutive words from the text of the buffer into the new bookmark
2116 name.
2117
2118 Warning: this function only takes an EVENT as argument.  Use the
2119 corresponding bookmark function from Lisp \(the one without the
2120 \"-menu-\" in its name\)."
2121   (interactive "e")
2122   (bookmark-popup-menu-and-apply-function
2123    'bookmark-rename "Rename Bookmark" event))
2124
2125
2126 ;;;###autoload
2127 (defun bookmark-menu-delete (event)
2128   "Delete the bookmark named NAME from the bookmark list.
2129 Removes only the first instance of a bookmark with that name.  If
2130 there are one or more other bookmarks with the same name, they will
2131 not be deleted.  Defaults to the \"current\" bookmark \(that is, the
2132 one most recently used in this file, if any\).
2133
2134 Warning: this function only takes an EVENT as argument.  Use the
2135 corresponding bookmark function from Lisp \(the one without the
2136 \"-menu-\" in its name\)."
2137   (interactive "e")
2138   (bookmark-popup-menu-and-apply-function
2139    'bookmark-delete "Delete Bookmark" event))
2140
2141
2142 ;; Thanks to Roland McGrath for fixing menubar.el so that the
2143 ;; following works, and for explaining what to do to make it work.
2144
2145 ;; We MUST autoload EACH form used to set up this variable's value, so
2146 ;; that the whole job is done in loaddefs.el.
2147
2148 ;; Emacs menubar stuff.
2149
2150 ;;;###autoload
2151 (defvar menu-bar-bookmark-map (make-sparse-keymap "Bookmark functions"))
2152
2153 ;;;###autoload
2154 (defalias 'menu-bar-bookmark-map (symbol-value 'menu-bar-bookmark-map))
2155
2156 ;; make bookmarks appear toward the right side of the menu.
2157 (if (boundp 'menu-bar-final-items)
2158     (if menu-bar-final-items
2159         (setq menu-bar-final-items
2160               (cons 'bookmark menu-bar-final-items)))
2161   (setq menu-bar-final-items '(bookmark)))
2162
2163 ;;;###autoload
2164 (define-key menu-bar-bookmark-map [load]
2165   '("Load a Bookmark File..." . bookmark-load))
2166
2167 ;;;###autoload
2168 (define-key menu-bar-bookmark-map [write]
2169   '("Save Bookmarks As..." . bookmark-write))
2170
2171 ;;;###autoload
2172 (define-key menu-bar-bookmark-map [save]
2173   '("Save Bookmarks" . bookmark-save))
2174
2175 ;;;###autoload
2176 (define-key menu-bar-bookmark-map [edit]
2177   '("Edit Bookmark List" . bookmark-bmenu-list))
2178
2179 ;;;###autoload
2180 (define-key menu-bar-bookmark-map [delete]
2181   '("Delete Bookmark" . bookmark-menu-delete))
2182
2183 ;;;###autoload
2184 (define-key menu-bar-bookmark-map [rename]
2185   '("Rename Bookmark" . bookmark-menu-rename))
2186
2187 ;;;###autoload
2188 (define-key menu-bar-bookmark-map [locate]
2189   '("Insert Location" . bookmark-menu-locate))
2190
2191 ;;;###autoload
2192 (define-key menu-bar-bookmark-map [insert]
2193   '("Insert Contents" . bookmark-menu-insert))
2194
2195 ;;;###autoload
2196 (define-key menu-bar-bookmark-map [set]
2197   '("Set Bookmark" . bookmark-set))
2198
2199 ;;;###autoload
2200 (define-key menu-bar-bookmark-map [jump]
2201   '("Jump to Bookmark" . bookmark-menu-jump))
2202
2203 ;;;; end bookmark menu stuff ;;;;
2204
2205 \f
2206 ;;; Load Hook
2207 (defvar bookmark-load-hook nil
2208   "Hook to run at the end of loading bookmark.")
2209
2210 (run-hooks 'bookmark-load-hook)
2211
2212 (provide 'bookmark)
2213
2214 ;;; bookmark.el ends here