lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 86, 87, 93, 94, 95, 96, 97, 98, 1999, 2001, 03, 2004
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defgroup compilation nil
  74   "Run compiler as inferior of Emacs, parse error messages."
  75   :group 'tools
  76   :group 'processes)
  77
  78
  79 ;;;###autoload
  80 (defcustom compilation-mode-hook nil
  81   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  82   :type 'hook
  83   :group 'compilation)
  84
  85 ;;;###autoload
  86 (defcustom compilation-window-height nil
  87   "*Number of lines in a compilation window.  If nil, use Emacs default."
  88   :type '(choice (const :tag "Default" nil)
  89                  integer)
  90   :group 'compilation)
  91
  92 (defvar compilation-first-column 1
  93   "*This is how compilers number the first column, usually 1 or 0.")
  94
  95 (defvar compilation-parse-errors-filename-function nil
  96   "Function to call to post-process filenames while parsing error messages.
  97 It takes one arg FILENAME which is the name of a file as found
  98 in the compilation output, and should return a transformed file name.")
  99
 100 ;;;###autoload
 101 (defvar compilation-process-setup-function nil
 102   "*Function to call to customize the compilation process.
 103 This function is called immediately before the compilation process is
 104 started.  It can be used to set any variables or functions that are used
 105 while processing the output of the compilation process.  The function
 106 is called with variables `compilation-buffer' and `compilation-window'
 107 bound to the compilation buffer and window, respectively.")
 108
 109 ;;;###autoload
 110 (defvar compilation-buffer-name-function nil
 111   "Function to compute the name of a compilation buffer.
 112 The function receives one argument, the name of the major mode of the
 113 compilation buffer.  It should return a string.
 114 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 115
 116 ;;;###autoload
 117 (defvar compilation-finish-function nil
 118   "Function to call when a compilation process finishes.
 119 It is called with two arguments: the compilation buffer, and a string
 120 describing how the process finished.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-functions nil
 124   "Functions to call when a compilation process finishes.
 125 Each function is called with two arguments: the compilation buffer,
 126 and a string describing how the process finished.")
 127
 128 (defvar compilation-in-progress nil
 129   "List of compilation processes now running.")
 130 (or (assq 'compilation-in-progress minor-mode-alist)
 131     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 132                                  minor-mode-alist)))
 133
 134 (defvar compilation-error "error"
 135   "Stem of message to print when no matches are found.")
 136
 137 (defvar compilation-arguments nil
 138   "Arguments that were given to `compilation-start'.")
 139
 140 (defvar compilation-num-errors-found)
 141
 142 (defconst compilation-error-regexp-alist-alist
 143   '((absoft
 144      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 145 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 146
 147     (ada
 148      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 149
 150     (aix
 151      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 152
 153     (ant
 154      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 155 \\( warning\\)?" 1 2 3 (4))
 156
 157     (bash
 158      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 159
 160     (borland
 161      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 162 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 163  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 164
 165     (caml
 166      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 167 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 168      2 (3 . 4) (5 . 6) (7))
 169
 170     (comma
 171      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 172 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 173
 174     (epc
 175      "^Error [0-9]+ at (\\([0-9]*\\):\\([^)\n]+\\))" 2 1)
 176
 177     (iar
 178      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 179      1 2 nil (3))
 180
 181     (ibm
 182      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 183  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 184
 185     ;; fixme: should be `mips'
 186     (irix
 187      "^[-[:alnum:]_/]+: \\(?:[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*:\
 188  \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 189
 190     (java
 191      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 192
 193     (jikes-file
 194      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 195     (jikes-line
 196      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 197      nil 1 nil 2 0
 198      (2 (compilation-face '(3))))
 199
 200     (gcc-include
 201      "^\\(?:In file included\\|                \\) from \
 202 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 203
 204     (gnu
 205      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 206 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\): ?\
 207 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 208 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 209 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 210  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 211      1 (2 . 5) (4 . 6) (7 . 8))
 212
 213     (lcc
 214      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 215      2 3 4 (1))
 216
 217     (makepp
 218      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 219 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 220      4 5 nil (1 . 2) 3
 221      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 222       (2 compilation-info-face)
 223       (3 compilation-line-face nil t)
 224       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 225          append)))
 226
 227     ;; Should be lint-1, lint-2 (SysV lint)
 228     (mips-1
 229      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 230     (mips-2
 231      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 232
 233     (msft
 234      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 235 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 236
 237     (oracle
 238      "^Semantic error at line \\([0-9]+\\), column \\([0-9]+\\), file \\(.*\\):$"
 239      3 1 2)
 240
 241     (perl
 242      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 243
 244     (rxp
 245      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 246  \\([0-9]+\\) of file://\\(.+\\)"
 247      4 2 3 (1))
 248
 249     (sparc-pascal-file
 250      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 251  [12][09][0-9][0-9] +\\(.*\\):$"
 252      1 nil nil 0)
 253     (sparc-pascal-line
 254      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 255      nil 3 nil (2) nil (1 (compilation-face '(2))))
 256     (sparc-pascal-example
 257      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 258      nil 1 nil (3) nil (2 (compilation-face '(3))))
 259
 260     (sun
 261      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 262 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 263      3 4 5 (1 . 2))
 264
 265     (sun-ada
 266      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 267
 268     ;; Redundant with `mips'
 269 ;;    (ultrix
 270 ;;      "^\\(?:cfe\\|fort\\): \\(Warning\\)?[^:\n]*: \\([^ \n]*\\), line \\([0-9]+\\):" 2 3 nil (1))
 271
 272     (4bsd
 273      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 274 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3)))
 275   "Alist of values for `compilation-error-regexp-alist'.")
 276
 277 (defcustom compilation-error-regexp-alist
 278   (mapcar 'car compilation-error-regexp-alist-alist)
 279   "Alist that specifies how to match errors in compiler output.
 280 Note that on Unix everything is a valid filename, so these
 281 matchers must make some common sense assumptions, which catch
 282 normal cases.  A shorter list will be lighter on resource usage.
 283
 284 Instead of an alist element, you can use a symbol, which is
 285 looked up in `compilation-error-regexp-alist-alist'.  You can see
 286 the predefined symbols and their effects in the file
 287 `etc/compilation.txt' (linked below if you are customizing this).
 288
 289 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 290 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 291 gives the file name, and the LINE'th subexpression gives the line
 292 number.  The COLUMN'th subexpression gives the column number on
 293 that line.
 294
 295 If FILE, LINE or COLUMN are nil or that index didn't match, that
 296 information is not present on the matched line.  In that case the
 297 file name is assumed to be the same as the previous one in the
 298 buffer, line number defaults to 1 and column defaults to
 299 beginning of line's indentation.
 300
 301 FILE can also have the form (FILE FORMAT...), where the FORMATs
 302 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 303 name, until a file of that name is found.  Or FILE can also be a
 304 function to return the filename.
 305
 306 LINE can also be of the form (LINE . END-LINE) meaning a range
 307 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 308 meaning a range of columns starting on LINE and ending on
 309 END-LINE, if that matched.
 310
 311 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 312 TYPE can also be of the form (WARNING . INFO).  In that case this
 313 will be equivalent to 1 if the WARNING'th subexpression matched
 314 or else equivalent to 0 if the INFO'th subexpression matched.
 315 See `compilation-error-face', `compilation-warning-face',
 316 `compilation-info-face' and `compilation-skip-threshold'.
 317
 318 What matched the HYPERLINK'th subexpression has `mouse-face' and
 319 `compilation-message-face' applied.  If this is nil, the text
 320 matched by the whole REGEXP becomes the hyperlink.
 321
 322 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 323 be added."
 324   :type `(set :menu-tag "Pick"
 325               ,@(mapcar (lambda (elt)
 326                           (list 'const (car elt)))
 327                         compilation-error-regexp-alist-alist))
 328   :link `(file-link :tag "example file"
 329                     ,(concat doc-directory "compilation.txt"))
 330   :group 'compilation)
 331
 332 (defvar compilation-directory nil
 333   "Directory to restore to when doing `recompile'.")
 334
 335 (defvar compilation-directory-matcher
 336   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 337   "A list for tracking when directories are entered or left.
 338 Nil means not to track directories, e.g. if all file names are absolute.  The
 339 first element is the REGEXP matching these messages.  It can match any number
 340 of variants, e.g. different languages.  The remaining elements are all of the
 341 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 342 matches, that is a directory name.  If LEAVE is nil or the corresponding
 343 LEAVE'th subexpression doesn't match, this message is about going into another
 344 directory.  If it does match anything, this message is about going back to the
 345 directory we were in before the last entering message.  If you change this,
 346 you may also want to change `compilation-page-delimiter'.")
 347
 348 (defvar compilation-page-delimiter
 349   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 350   "Value of `page-delimiter' in Compilation mode.")
 351
 352 (defvar compilation-mode-font-lock-keywords
 353    '(;; configure output lines.
 354      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 355       (1 font-lock-variable-name-face)
 356       (2 (compilation-face '(4 . 3))))
 357      ;; Command output lines.  Recognize `make[n]:' lines too.
 358      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 359       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 360      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 361      ("^Compilation finished" . compilation-info-face)
 362      ("^Compilation exited abnormally" . compilation-error-face))
 363    "Additional things to highlight in Compilation mode.
 364 This gets tacked on the end of the generated expressions.")
 365
 366 (defvar compilation-highlight-regexp t
 367   "Regexp matching part of visited source lines to highlight temporarily.
 368 Highlight entire line if t; don't highlight source lines if nil.")
 369
 370 (defvar compilation-highlight-overlay nil
 371   "Overlay used to temporarily highlight compilation matches.")
 372
 373 (defcustom compilation-error-screen-columns t
 374   "*If non-nil, column numbers in error messages are screen columns.
 375 Otherwise they are interpreted as character positions, with
 376 each character occupying one column.
 377 The default is to use screen columns, which requires that the compilation
 378 program and Emacs agree about the display width of the characters,
 379 especially the TAB character."
 380   :type 'boolean
 381   :group 'compilation
 382   :version "20.4")
 383
 384 (defcustom compilation-read-command t
 385   "*Non-nil means \\[compile] reads the compilation command to use.
 386 Otherwise, \\[compile] just uses the value of `compile-command'."
 387   :type 'boolean
 388   :group 'compilation)
 389
 390 ;;;###autoload
 391 (defcustom compilation-ask-about-save t
 392   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 393 Otherwise, it saves all modified buffers without asking."
 394   :type 'boolean
 395   :group 'compilation)
 396
 397 ;;;###autoload
 398 (defcustom compilation-search-path '(nil)
 399   "*List of directories to search for source files named in error messages.
 400 Elements should be directory names, not file names of directories.
 401 nil as an element means to try the default directory."
 402   :type '(repeat (choice (const :tag "Default" nil)
 403                          (string :tag "Directory")))
 404   :group 'compilation)
 405
 406 (defcustom compile-command "make -k "
 407   "*Last shell command used to do a compilation; default for next compilation.
 408
 409 Sometimes it is useful for files to supply local values for this variable.
 410 You might also use mode hooks to specify it in certain modes, like this:
 411
 412     (add-hook 'c-mode-hook
 413        (lambda ()
 414          (unless (or (file-exists-p \"makefile\")
 415                      (file-exists-p \"Makefile\"))
 416            (set (make-local-variable 'compile-command)
 417                 (concat \"make -k \"
 418                         (file-name-sans-extension buffer-file-name))))))"
 419   :type 'string
 420   :group 'compilation)
 421
 422 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 423 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 424 ;; key.  This holds the tree seen from root, for storing new nodes.
 425 (defvar compilation-locs ())
 426
 427 (defvar compilation-debug nil
 428   "*Set this to t before creating a *compilation* buffer.
 429 Then every error line will have a debug text property with the matcher that
 430 fit this line and the match data.  Use `describe-text-properties'.")
 431
 432 (defvar compilation-exit-message-function nil "\
 433 If non-nil, called when a compilation process dies to return a status message.
 434 This should be a function of three arguments: process status, exit status,
 435 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 436 write into the compilation buffer, and to put in its mode line.")
 437
 438 (defvar compilation-environment nil
 439   "*List of environment variables for compilation to inherit.
 440 Each element should be a string of the form ENVVARNAME=VALUE.
 441 This list is temporarily prepended to `process-environment' prior to
 442 starting the compilation process.")
 443
 444 ;; History of compile commands.
 445 (defvar compile-history nil)
 446
 447 (defface compilation-warning-face
 448   '((((type tty) (class color)) (:foreground "cyan" :weight bold))
 449     (((class color)) (:foreground "Orange" :weight bold))
 450     (t (:weight bold)))
 451   "Face used to highlight compiler warnings."
 452   :group 'font-lock-highlighting-faces
 453   :version "21.4")
 454
 455 (defface compilation-info-face
 456   '((((type tty) (class color)) (:foreground "green" :weight bold))
 457     (((class color) (background light)) (:foreground "Green3" :weight bold))
 458     (((class color) (background dark)) (:foreground "Green" :weight bold))
 459     (t (:weight bold)))
 460   "Face used to highlight compiler warnings."
 461   :group 'font-lock-highlighting-faces
 462   :version "21.4")
 463
 464 (defvar compilation-message-face nil
 465   "Face name to use for whole messages.
 466 Faces `compilation-error-face', `compilation-warning-face',
 467 `compilation-info-face', `compilation-line-face' and
 468 `compilation-column-face' get prepended to this, when applicable.")
 469
 470 (defvar compilation-error-face 'font-lock-warning-face
 471   "Face name to use for file name in error messages.")
 472
 473 (defvar compilation-warning-face 'compilation-warning-face
 474   "Face name to use for file name in warning messages.")
 475
 476 (defvar compilation-info-face 'compilation-info-face
 477   "Face name to use for file name in informational messages.")
 478
 479 (defvar compilation-line-face 'font-lock-variable-name-face
 480   "Face name to use for line number in message.")
 481
 482 (defvar compilation-column-face 'font-lock-type-face
 483   "Face name to use for column number in message.")
 484
 485 ;; same faces as dired uses
 486 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 487   "Face name to use for column number in message.")
 488
 489 (defvar compilation-leave-directory-face 'font-lock-type-face
 490   "Face name to use for column number in message.")
 491
 492
 493
 494 ;; Used for compatibility with the old compile.el.
 495 (defvar compilation-parsing-end (make-marker))
 496 (defvar compilation-parse-errors-function nil)
 497 (defvar compilation-error-list nil)
 498 (defvar compilation-old-error-list nil)
 499
 500 (defun compilation-face (type)
 501   (or (and (car type) (match-end (car type)) compilation-warning-face)
 502       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 503       compilation-error-face))
 504
 505 (defun compilation-directory-properties (idx leave)
 506   (if leave (setq leave (match-end leave)))
 507   ;; find previous stack, and push onto it, or if `leave' pop it
 508   (let ((dir (previous-single-property-change (point) 'directory)))
 509     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 510                           (get-text-property dir 'directory))))
 511     `(face ,(if leave
 512                 compilation-leave-directory-face
 513               compilation-enter-directory-face)
 514       directory ,(if leave
 515                      (or (cdr dir)
 516                          '(nil))        ; nil only isn't a property-change
 517                    (cons (match-string-no-properties idx) dir))
 518       mouse-face highlight
 519       keymap compilation-button-map
 520       help-echo "mouse-2: visit current directory")))
 521
 522 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 523 ;; KEY element from the ALIST, creating it in the right position if not already
 524 ;; present. ALIST structure is
 525 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 526 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 527 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 528 ;; numbers can be inserted in front and searching can abort after half the
 529 ;; list on average.
 530 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 531 (defmacro compilation-assq (key alist)
 532   `(let* ((l1 ,alist)
 533           (l2 (cdr l1)))
 534      (car (if (if (null ,key)
 535                   (if l2 (null (caar l2)))
 536                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 537                   (setq l1 l2
 538                         l2 (cdr l1)))
 539                 (if l2 (eq ,key (caar l2))))
 540               l2
 541             (setcdr l1 (cons (list ,key) l2)))))))
 542
 543
 544 ;; This function is the central driver, called when font-locking to gather
 545 ;; all information needed to later jump to corresponding source code.
 546 ;; Return a property list with all meta information on this error location.
 547 (defun compilation-error-properties (file line end-line col end-col type fmt)
 548   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 549              (point))
 550     (if file
 551         (if (functionp file)
 552             (setq file (funcall file))
 553           (let (dir)
 554             (setq file (match-string-no-properties file))
 555             (unless (file-name-absolute-p file)
 556               (setq dir (previous-single-property-change (point) 'directory)
 557                     dir (if dir (or (get-text-property (1- dir) 'directory)
 558                                     (get-text-property dir 'directory)))))
 559             (setq file (cons file (car dir)))))
 560       ;; This message didn't mention one, get it from previous
 561       (setq file (previous-single-property-change (point) 'message)
 562             file (or (if file
 563                          (car (nth 2 (car (or (get-text-property (1- file) 'message)
 564                                          (get-text-property file 'message))))))
 565                      '("*unknown*"))))
 566     ;; All of these fields are optional, get them only if we have an index, and
 567     ;; it matched some part of the message.
 568     (and line
 569          (setq line (match-string-no-properties line))
 570          (setq line (string-to-number line)))
 571     (and end-line
 572          (setq end-line (match-string-no-properties end-line))
 573          (setq end-line (string-to-number end-line)))
 574     (and col
 575          (setq col (match-string-no-properties col))
 576          (setq col (- (string-to-number col) compilation-first-column)))
 577     (if (and end-col (setq end-col (match-string-no-properties end-col)))
 578         (setq end-col (- (string-to-number end-col) compilation-first-column))
 579       (if end-line (setq end-col -1)))
 580     (if (consp type)                    ; not a static type, check what it is.
 581         (setq type (or (and (car type) (match-end (car type)) 1)
 582                        (and (cdr type) (match-end (cdr type)) 0)
 583                        2)))
 584     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 585
 586 (defun compilation-internal-error-properties (file line end-line col end-col type fmt)
 587   "Get the meta-info that will be added as text-properties.
 588 LINE, END-LINE, COL, END-COL are integers or nil.
 589 TYPE can be 0, 1, or 2.
 590 FILE should be (FILENAME . DIRNAME) or nil."
 591   (unless file (setq file '("*unknown*")))
 592   (setq file (or (gethash file compilation-locs)
 593                  (puthash file (list file fmt) compilation-locs)))
 594   ;; Get first already existing marker (if any has one, all have one).
 595   ;; Do this first, as the compilation-assq`s may create new nodes.
 596   (let* ((marker-line (car (cddr file)))        ; a line structure
 597          (marker (nth 3 (cadr marker-line)))    ; its marker
 598          (compilation-error-screen-columns compilation-error-screen-columns)
 599          end-marker loc end-loc)
 600     (if (not (and marker (marker-buffer marker)))
 601         (setq marker)                   ; no valid marker for this file
 602       (setq loc (or line 1)             ; normalize no linenumber to line 1
 603             marker-line)
 604       (catch 'marker                 ; find nearest loc, at least one exists
 605         (dolist (x (cddr file))         ; loop over lines
 606           (if (> (or (car x) 1) loc)    ; still bigger
 607               (setq marker-line x)
 608             (if (or (not marker-line)   ; first in list
 609                     (> (- (or (car marker-line) 1) loc)
 610                        (- loc (or (car x) 1)))) ; current line is nearer
 611                 (setq marker-line x))
 612             (throw 'marker t))))
 613       (setq marker (nth 3 (cadr marker-line))
 614             marker-line (car marker-line))
 615       (with-current-buffer (marker-buffer marker)
 616         (save-restriction
 617           (widen)
 618           (goto-char (marker-position marker))
 619           (when (or end-col end-line)
 620             (beginning-of-line (- (or end-line line) marker-line -1))
 621             (if (< end-col 0)
 622                 (end-of-line)
 623               (if compilation-error-screen-columns
 624                   (move-to-column end-col)
 625                 (forward-char end-col)))
 626             (setq end-marker (list (point-marker))))
 627           (beginning-of-line (if end-line
 628                                  (- end-line line -1)
 629                                (- loc marker-line -1)))
 630           (if col
 631               (if compilation-error-screen-columns
 632                   (move-to-column col)
 633                 (forward-char col))
 634             (forward-to-indentation 0))
 635           (setq marker (list (point-marker))))))
 636
 637     (setq loc (compilation-assq line (cdr file)))
 638     (if end-line
 639         (setq end-loc (compilation-assq end-line (cdr file))
 640               end-loc (compilation-assq end-col end-loc))
 641       (if end-col                       ; use same line element
 642           (setq end-loc (compilation-assq end-col loc))))
 643     (setq loc (compilation-assq col loc))
 644     ;; If they are new, make the loc(s) reference the file they point to.
 645     (or (cdr loc) (setcdr loc `(,line ,file ,@marker)))
 646     (if end-loc
 647         (or (cdr end-loc) (setcdr end-loc `(,(or end-line line) ,file ,@end-marker))))
 648
 649     ;; Must start with face
 650     `(face ,compilation-message-face
 651            message (,loc ,type ,end-loc)
 652            ,@(if compilation-debug
 653                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 654                           ,@(match-data))))
 655            help-echo ,(if col
 656                           "mouse-2: visit this file, line and column"
 657                         (if line
 658                             "mouse-2: visit this file and line"
 659                           "mouse-2: visit this file"))
 660            keymap compilation-button-map
 661            mouse-face highlight)))
 662
 663 (defun compilation-mode-font-lock-keywords ()
 664   "Return expressions to highlight in Compilation mode."
 665   (if compilation-parse-errors-function
 666       ;; An old package!  Try the compatibility code.
 667       '((compilation-compat-parse-errors))
 668     (append
 669      ;; make directory tracking
 670      (if compilation-directory-matcher
 671          `((,(car compilation-directory-matcher)
 672             ,@(mapcar (lambda (elt)
 673                         `(,(car elt)
 674                           (compilation-directory-properties
 675                            ,(car elt) ,(cdr elt))
 676                           t))
 677                       (cdr compilation-directory-matcher)))))
 678
 679      ;; Compiler warning/error lines.
 680      (mapcar
 681       (lambda (item)
 682         (if (symbolp item)
 683             (setq item (cdr (assq item
 684                                   compilation-error-regexp-alist-alist))))
 685         (let ((file (nth 1 item))
 686               (line (nth 2 item))
 687               (col (nth 3 item))
 688               (type (nth 4 item))
 689               end-line end-col fmt)
 690           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 691           (if (consp line)      (setq end-line (cdr line) line (car line)))
 692           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 693
 694           (if (functionp line)
 695               ;; The old compile.el had here an undocumented hook that
 696               ;; allowed `line' to be a function that computed the actual
 697               ;; error location.  Let's do our best.
 698               `(,(car item)
 699                 (0 (compilation-compat-error-properties
 700                     (funcall ',line (cons (match-string ,file)
 701                                           (cons default-directory
 702                                                 ',(nthcdr 4 item)))
 703                              ,(if col `(match-string ,col)))))
 704                 (,file compilation-error-face t))
 705
 706             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 707               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 708
 709             `(,(nth 0 item)
 710
 711               ,@(when (integerp file)
 712                   `((,file ,(if (consp type)
 713                                 `(compilation-face ',type)
 714                               (aref [compilation-info-face
 715                                      compilation-warning-face
 716                                      compilation-error-face]
 717                                     (or type 2))))))
 718
 719               ,@(when line
 720                   `((,line compilation-line-face nil t)))
 721               ,@(when end-line
 722                   `((,end-line compilation-line-face nil t)))
 723
 724               ,@(when col
 725                   `((,col compilation-column-face nil t)))
 726               ,@(when end-col
 727                   `((,end-col compilation-column-face nil t)))
 728
 729               ,@(nthcdr 6 item)
 730               (,(or (nth 5 item) 0)
 731                (compilation-error-properties ',file ,line ,end-line
 732                                              ,col ,end-col ',(or type 2)
 733                                              ',fmt)
 734                append)))))              ; for compilation-message-face
 735       compilation-error-regexp-alist)
 736
 737      compilation-mode-font-lock-keywords)))
 738
 739 \f
 740 ;;;###autoload
 741 (defun compile (command &optional comint)
 742   "Compile the program including the current buffer.  Default: run `make'.
 743 Runs COMMAND, a shell command, in a separate process asynchronously
 744 with output going to the buffer `*compilation*'.
 745
 746 If optional second arg COMINT is t the buffer will be in Comint mode with
 747 `compilation-shell-minor-mode'.
 748
 749 You can then use the command \\[next-error] to find the next error message
 750 and move to the source code that caused it.
 751
 752 Interactively, prompts for the command if `compilation-read-command' is
 753 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 754
 755 To run more than one compilation at once, start one and rename
 756 the \`*compilation*' buffer to some other name with
 757 \\[rename-buffer].  Then start the next one.  On most systems,
 758 termination of the main compilation process kills its
 759 subprocesses.
 760
 761 The name used for the buffer is actually whatever is returned by
 762 the function in `compilation-buffer-name-function', so you can set that
 763 to a function that generates a unique name."
 764   (interactive
 765    (if (or compilation-read-command current-prefix-arg)
 766        (list (read-from-minibuffer "Compile command: "
 767                                  (eval compile-command) nil nil
 768                                  '(compile-history . 1)))
 769      (list (eval compile-command))))
 770   (unless (equal command (eval compile-command))
 771     (setq compile-command command))
 772   (save-some-buffers (not compilation-ask-about-save) nil)
 773   (setq compilation-directory default-directory)
 774   (compilation-start command comint))
 775
 776 ;; run compile with the default command line
 777 (defun recompile ()
 778   "Re-compile the program including the current buffer.
 779 If this is run in a Compilation mode buffer, re-use the arguments from the
 780 original use.  Otherwise, recompile using `compile-command'."
 781   (interactive)
 782   (save-some-buffers (not compilation-ask-about-save) nil)
 783   (let ((default-directory (or compilation-directory default-directory)))
 784     (apply 'compilation-start (or compilation-arguments
 785                                   `(,(eval compile-command))))))
 786
 787 (defcustom compilation-scroll-output nil
 788   "*Non-nil to scroll the *compilation* buffer window as output appears.
 789
 790 Setting it causes the Compilation mode commands to put point at the
 791 end of their output window so that the end of the output is always
 792 visible rather than the beginning."
 793   :type 'boolean
 794   :version "20.3"
 795   :group 'compilation)
 796
 797
 798 (defun compilation-buffer-name (mode-name name-function)
 799   "Return the name of a compilation buffer to use.
 800 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 801 to determine the buffer name.
 802 Likewise if `compilation-buffer-name-function' is non-nil.
 803 If current buffer is in Compilation mode for the same mode name
 804 return the name of the current buffer, so that it gets reused.
 805 Otherwise, construct a buffer name from MODE-NAME."
 806   (cond (name-function
 807          (funcall name-function mode-name))
 808         (compilation-buffer-name-function
 809          (funcall compilation-buffer-name-function mode-name))
 810         ((and (eq major-mode 'compilation-mode)
 811               (equal mode-name (nth 2 compilation-arguments)))
 812          (buffer-name))
 813         (t
 814          (concat "*" (downcase mode-name) "*"))))
 815
 816 ;; This is a rough emulation of the old hack, until the transition to new
 817 ;; compile is complete.
 818 (defun compile-internal (command error-message
 819                                  &optional name-of-mode parser
 820                                  error-regexp-alist name-function
 821                                  enter-regexp-alist leave-regexp-alist
 822                                  file-regexp-alist nomessage-regexp-alist
 823                                  no-async highlight-regexp local-map)
 824   (if parser
 825       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 826   (let ((compilation-error-regexp-alist
 827          (append file-regexp-alist (or error-regexp-alist
 828                                        compilation-error-regexp-alist)))
 829         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 830                                                      "\\1" error-message)))
 831     (compilation-start command nil name-function highlight-regexp)))
 832 (make-obsolete 'compile-internal 'compilation-start)
 833
 834 (defun compilation-start (command &optional mode name-function highlight-regexp)
 835   "Run compilation command COMMAND (low level interface).
 836 The rest of the arguments are optional; for them, nil means use the default.
 837
 838 MODE is the major mode to set in the compilation buffer.  Mode
 839 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 840 NAME-FUNCTION is a function called to name the buffer.
 841
 842 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 843 the matching section of the visited source line; the default is to use the
 844 global value of `compilation-highlight-regexp'.
 845
 846 Returns the compilation buffer created."
 847   (or mode (setq mode 'compilation-mode))
 848   (let ((name-of-mode
 849          (if (eq mode t)
 850              (prog1 "compilation" (require 'comint))
 851            (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 852         (process-environment
 853          (append
 854           compilation-environment
 855           (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
 856                   system-uses-terminfo)
 857               (list "TERM=dumb" "TERMCAP="
 858                     (format "COLUMNS=%d" (window-width)))
 859             (list "TERM=emacs"
 860                   (format "TERMCAP=emacs:co#%d:tc=unknown:"
 861                           (window-width))))
 862           ;; Set the EMACS variable, but
 863           ;; don't override users' setting of $EMACS.
 864           (unless (getenv "EMACS") '("EMACS=t"))
 865           process-environment))
 866         (thisdir default-directory)
 867         outwin outbuf)
 868     (with-current-buffer
 869         (setq outbuf
 870               (get-buffer-create
 871                (compilation-buffer-name name-of-mode name-function)))
 872       (let ((comp-proc (get-buffer-process (current-buffer))))
 873         (if comp-proc
 874             (if (or (not (eq (process-status comp-proc) 'run))
 875                     (yes-or-no-p
 876                      (format "A %s process is running; kill it? "
 877                              name-of-mode)))
 878                 (condition-case ()
 879                     (progn
 880                       (interrupt-process comp-proc)
 881                       (sit-for 1)
 882                       (delete-process comp-proc))
 883                   (error nil))
 884               (error "Cannot have two processes in `%s' at once"
 885                      (buffer-name)))))
 886       ;; Clear out the compilation buffer and make it writable.
 887       ;; Change its default-directory to the directory where the compilation
 888       ;; will happen, and insert a `cd' command to indicate this.
 889       (setq buffer-read-only nil)
 890       (buffer-disable-undo (current-buffer))
 891       (erase-buffer)
 892       (buffer-enable-undo (current-buffer))
 893       (setq default-directory thisdir)
 894       ;; output a mode setter, for saving and later reloading this buffer
 895       (insert "cd " thisdir "   # -*-" name-of-mode
 896               "-*-\nEntering directory `" thisdir "'\n" command "\n")
 897       (set-buffer-modified-p nil))
 898     ;; If we're already in the compilation buffer, go to the end
 899     ;; of the buffer, so point will track the compilation output.
 900     (if (eq outbuf (current-buffer))
 901         (goto-char (point-max)))
 902     ;; Pop up the compilation buffer.
 903     (setq outwin (display-buffer outbuf nil t))
 904     (with-current-buffer outbuf
 905       (if (not (eq mode t))
 906           (funcall mode)
 907         (with-no-warnings (comint-mode))
 908         (compilation-shell-minor-mode))
 909       ;; In what way is it non-ergonomic ?  -stef
 910       ;; (toggle-read-only 1) ;;; Non-ergonomic.
 911       (if highlight-regexp
 912           (set (make-local-variable 'compilation-highlight-regexp)
 913                highlight-regexp))
 914       (set (make-local-variable 'compilation-arguments)
 915            (list command mode name-function highlight-regexp))
 916       (set (make-local-variable 'revert-buffer-function)
 917            'compilation-revert-buffer)
 918       (set-window-start outwin (point-min))
 919       (or (eq outwin (selected-window))
 920           (set-window-point outwin (if compilation-scroll-output
 921                                        (point)
 922                                      (point-min))))
 923       ;; The setup function is called before compilation-set-window-height
 924       ;; so it can set the compilation-window-height buffer locally.
 925       (if compilation-process-setup-function
 926           (funcall compilation-process-setup-function))
 927       (compilation-set-window-height outwin)
 928       ;; Start the compilation.
 929       (if (fboundp 'start-process)
 930           (let ((proc (if (eq mode t)
 931                           (get-buffer-process
 932                            (with-no-warnings
 933                             (comint-exec outbuf (downcase mode-name)
 934                                          shell-file-name nil `("-c" ,command))))
 935                         (start-process-shell-command (downcase mode-name)
 936                                                      outbuf command))))
 937             ;; Make the buffer's mode line show process state.
 938             (setq mode-line-process '(":%s"))
 939             (set-process-sentinel proc 'compilation-sentinel)
 940             (set-process-filter proc 'compilation-filter)
 941             (set-marker (process-mark proc) (point) outbuf)
 942             (setq compilation-in-progress
 943                   (cons proc compilation-in-progress)))
 944         ;; No asynchronous processes available.
 945         (message "Executing `%s'..." command)
 946         ;; Fake modeline display as if `start-process' were run.
 947         (setq mode-line-process ":run")
 948         (force-mode-line-update)
 949         (let ((status (call-process shell-file-name nil outbuf nil "-c"
 950                                     command)))
 951           (cond ((numberp status)
 952                  (compilation-handle-exit 'exit status
 953                                           (if (zerop status)
 954                                               "finished\n"
 955                                             (format "\
 956 exited abnormally with code %d\n"
 957                                                     status))))
 958                 ((stringp status)
 959                  (compilation-handle-exit 'signal status
 960                                           (concat status "\n")))
 961                 (t
 962                  (compilation-handle-exit 'bizarre status status))))
 963         (message "Executing `%s'...done" command)))
 964     (if (buffer-local-value 'compilation-scroll-output outbuf)
 965         (save-selected-window
 966           (select-window outwin)
 967           (goto-char (point-max))))
 968     ;; Make it so the next C-x ` will use this buffer.
 969     (setq next-error-last-buffer outbuf)))
 970
 971 (defun compilation-set-window-height (window)
 972   "Set the height of WINDOW according to `compilation-window-height'."
 973   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
 974     (and height
 975          (= (window-width window) (frame-width (window-frame window)))
 976          ;; If window is alone in its frame, aside from a minibuffer,
 977          ;; don't change its height.
 978          (not (eq window (frame-root-window (window-frame window))))
 979          ;; This save-current-buffer prevents us from changing the current
 980          ;; buffer, which might not be the same as the selected window's buffer.
 981          (save-current-buffer
 982            (save-selected-window
 983              (select-window window)
 984              (enlarge-window (- height (window-height))))))))
 985
 986 (defvar compilation-menu-map
 987   (let ((map (make-sparse-keymap "Errors")))
 988     (define-key map [stop-subjob]
 989       '("Stop Compilation" . kill-compilation))
 990     (define-key map [compilation-mode-separator2]
 991       '("----" . nil))
 992     (define-key map [compilation-first-error]
 993       '("First Error" . first-error))
 994     (define-key map [compilation-previous-error]
 995       '("Previous Error" . previous-error))
 996     (define-key map [compilation-next-error]
 997       '("Next Error" . next-error))
 998     map))
 999
1000 (defvar compilation-minor-mode-map
1001   (let ((map (make-sparse-keymap)))
1002     (define-key map [mouse-2] 'compile-goto-error)
1003     (define-key map "\C-c\C-c" 'compile-goto-error)
1004     (define-key map "\C-m" 'compile-goto-error)
1005     (define-key map "\C-c\C-k" 'kill-compilation)
1006     (define-key map "\M-n" 'compilation-next-error)
1007     (define-key map "\M-p" 'compilation-previous-error)
1008     (define-key map "\M-{" 'compilation-previous-file)
1009     (define-key map "\M-}" 'compilation-next-file)
1010     ;; Set up the menu-bar
1011     (define-key map [menu-bar compilation]
1012       (cons "Errors" compilation-menu-map))
1013     map)
1014   "Keymap for `compilation-minor-mode'.")
1015
1016 (defvar compilation-shell-minor-mode-map
1017   (let ((map (make-sparse-keymap)))
1018     (define-key map "\M-\C-m" 'compile-goto-error)
1019     (define-key map "\M-\C-n" 'compilation-next-error)
1020     (define-key map "\M-\C-p" 'compilation-previous-error)
1021     (define-key map "\M-{" 'compilation-previous-file)
1022     (define-key map "\M-}" 'compilation-next-file)
1023     ;; Set up the menu-bar
1024     (define-key map [menu-bar compilation]
1025       (cons "Errors" compilation-menu-map))
1026     map)
1027   "Keymap for `compilation-shell-minor-mode'.")
1028
1029 (defvar compilation-button-map
1030   (let ((map (make-sparse-keymap)))
1031     (define-key map [mouse-2] 'compile-goto-error)
1032     (define-key map "\C-m" 'compile-goto-error)
1033     map)
1034   "Keymap for compilation-message buttons.")
1035 (fset 'compilation-button-map compilation-button-map)
1036
1037 (defvar compilation-mode-map
1038   (let ((map (make-sparse-keymap)))
1039     (set-keymap-parent map compilation-minor-mode-map)
1040     (define-key map " " 'scroll-up)
1041     (define-key map "\^?" 'scroll-down)
1042
1043     ;; Set up the menu-bar
1044     (define-key map [menu-bar compilation]
1045       (cons "Compile" (make-sparse-keymap "Compile")))
1046     (define-key map [menu-bar compilation compilation-separator2]
1047       '("----" . nil))
1048     (define-key map [menu-bar compilation compilation-grep]
1049       '("Search Files (grep)" . grep))
1050     (define-key map [menu-bar compilation compilation-recompile]
1051       '("Recompile" . recompile))
1052     (define-key map [menu-bar compilation compilation-compile]
1053       '("Compile..." . compile))
1054     map)
1055   "Keymap for compilation log buffers.
1056 `compilation-minor-mode-map' is a parent of this.")
1057
1058 (put 'compilation-mode 'mode-class 'special)
1059
1060 (defvar compilation-skip-to-next-location t
1061   "*If non-nil, skip multiple error messages for the same source location.")
1062
1063 (defcustom compilation-skip-threshold 1
1064   "*Compilation motion commands skip less important messages.
1065 The value can be either 2 -- skip anything less than error, 1 --
1066 skip anything less than warning or 0 -- don't skip any messages.
1067 Note that all messages not positively identified as warning or
1068 info, are considered errors."
1069   :type '(choice (const :tag "Warnings and info" 2)
1070                  (const :tag "Info" 1)
1071                  (const :tag "None" 0))
1072   :group 'compilation
1073   :version "21.4")
1074
1075 (defcustom compilation-skip-visited nil
1076   "*Compilation motion commands skip visited messages if this is t.
1077 Visited messages are ones for which the file, line and column have been jumped
1078 to from the current content in the current compilation buffer, even if it was
1079 from a different message."
1080   :type 'boolean
1081   :group 'compilation
1082   :version "21.4")
1083
1084 ;;;###autoload
1085 (defun compilation-mode ()
1086   "Major mode for compilation log buffers.
1087 \\<compilation-mode-map>To visit the source for a line-numbered error,
1088 move point to the error message line and type \\[compile-goto-error].
1089 To kill the compilation, type \\[kill-compilation].
1090
1091 Runs `compilation-mode-hook' with `run-hooks' (which see)."
1092   (interactive)
1093   (kill-all-local-variables)
1094   (use-local-map compilation-mode-map)
1095   (setq major-mode 'compilation-mode
1096         mode-name "Compilation")
1097   (set (make-local-variable 'page-delimiter)
1098        compilation-page-delimiter)
1099   (compilation-setup)
1100   ;; note that compilation-next-error-function is for interfacing
1101   ;; with the next-error function in simple.el, and it's only
1102   ;; coincidentally named similarly to compilation-next-error
1103   (setq next-error-function 'compilation-next-error-function)
1104   (run-mode-hooks 'compilation-mode-hook))
1105
1106 (defmacro define-compilation-mode (mode name doc &rest body)
1107   "This is like `define-derived-mode' without the PARENT argument.
1108 The parent is always `compilation-mode' and the customizable `compilation-...'
1109 variables are also set from the name of the mode you have chosen, by replacing
1110 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1111 variable exists."
1112   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1113     `(define-derived-mode ,mode compilation-mode ,name
1114        ,doc
1115        ,@(mapcar (lambda (v)
1116                    (setq v (cons v
1117                                  (intern-soft (replace-regexp-in-string
1118                                                "^compilation" mode-name
1119                                                (symbol-name v)))))
1120                    (and (cdr v)
1121                         (or (boundp (cdr v))
1122                             (if (boundp 'byte-compile-bound-variables)
1123                                 (memq (cdr v) byte-compile-bound-variables)))
1124                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1125                  '(compilation-buffer-name-function
1126                    compilation-directory-matcher
1127                    compilation-error
1128                    compilation-error-regexp-alist
1129                    compilation-error-regexp-alist-alist
1130                    compilation-error-screen-columns
1131                    compilation-finish-function
1132                    compilation-finish-functions
1133                    compilation-first-column
1134                    compilation-mode-font-lock-keywords
1135                    compilation-page-delimiter
1136                    compilation-parse-errors-filename-function
1137                    compilation-process-setup-function
1138                    compilation-scroll-output
1139                    compilation-search-path
1140                    compilation-skip-threshold
1141                    compilation-window-height))
1142        ,@body)))
1143
1144 (defun compilation-revert-buffer (ignore-auto noconfirm)
1145   (if buffer-file-name
1146       (let (revert-buffer-function)
1147         (revert-buffer ignore-auto noconfirm))
1148     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1149         (apply 'compilation-start compilation-arguments))))
1150
1151 (defvar compilation-current-error nil
1152   "Marker to the location from where the next error will be found.
1153 The global commands next/previous/first-error/goto-error use this.")
1154
1155 ;; A function name can't be a hook, must be something with a value.
1156 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1157
1158 (defun compilation-setup (&optional minor)
1159   "Prepare the buffer for the compilation parsing commands to work.
1160 Optional argument MINOR indicates this is called from
1161 `compilation-minor-mode'."
1162   (make-local-variable 'compilation-current-error)
1163   (make-local-variable 'compilation-error-screen-columns)
1164   (make-local-variable 'overlay-arrow-position)
1165   (set (make-local-variable 'font-lock-extra-managed-props)
1166        '(directory message help-echo mouse-face debug))
1167   (set (make-local-variable 'compilation-locs)
1168        (make-hash-table :test 'equal :weakness 'value))
1169   ;; lazy-lock would never find the message unless it's scrolled to.
1170   ;; jit-lock might fontify some things too late.
1171   (set (make-local-variable 'font-lock-support-mode) nil)
1172   (set (make-local-variable 'font-lock-maximum-size) nil)
1173   (let ((fld font-lock-defaults))
1174     (if (and minor fld)
1175         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1176       (setq font-lock-defaults '(compilation-mode-font-lock-keywords t)))
1177     (if minor
1178         (if font-lock-mode
1179             (if fld
1180                 (font-lock-fontify-buffer)
1181               (font-lock-change-mode)
1182               (turn-on-font-lock))
1183           (turn-on-font-lock))
1184       ;; maybe defer font-lock till after derived mode is set up
1185       (run-mode-hooks 'compilation-turn-on-font-lock))))
1186
1187 ;;;###autoload
1188 (define-minor-mode compilation-shell-minor-mode
1189   "Toggle compilation shell minor mode.
1190 With arg, turn compilation mode on if and only if arg is positive.
1191 In this minor mode, all the error-parsing commands of the
1192 Compilation major mode are available but bound to keys that don't
1193 collide with Shell mode.  See `compilation-mode'.
1194 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1195   nil " Shell-Compile"
1196   :group 'compilation
1197   (if compilation-shell-minor-mode
1198       (compilation-setup t)
1199     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1200     (font-lock-fontify-buffer)))
1201
1202 ;;;###autoload
1203 (define-minor-mode compilation-minor-mode
1204   "Toggle compilation minor mode.
1205 With arg, turn compilation mode on if and only if arg is positive.
1206 In this minor mode, all the error-parsing commands of the
1207 Compilation major mode are available.  See `compilation-mode'.
1208 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1209   nil " Compilation"
1210   :group 'compilation
1211   (if compilation-minor-mode
1212       (compilation-setup t)
1213     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1214     (font-lock-fontify-buffer)))
1215
1216 (defun compilation-handle-exit (process-status exit-status msg)
1217   "Write MSG in the current buffer and hack its mode-line-process."
1218   (let ((buffer-read-only nil)
1219         (status (if compilation-exit-message-function
1220                     (funcall compilation-exit-message-function
1221                              process-status exit-status msg)
1222                   (cons msg exit-status)))
1223         (omax (point-max))
1224         (opoint (point)))
1225     ;; Record where we put the message, so we can ignore it later on.
1226     (goto-char omax)
1227     (insert ?\n mode-name " " (car status))
1228     (if (and (numberp compilation-window-height)
1229              (zerop compilation-window-height))
1230         (message "%s" (cdr status)))
1231     (if (bolp)
1232         (forward-char -1))
1233     (insert " at " (substring (current-time-string) 0 19))
1234     (goto-char (point-max))
1235     ;; Prevent that message from being recognized as a compilation error.
1236     (add-text-properties omax (point)
1237                          (append '(compilation-handle-exit t) nil))
1238     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1239     ;; Force mode line redisplay soon.
1240     (force-mode-line-update)
1241     (if (and opoint (< opoint omax))
1242         (goto-char opoint))
1243     (if compilation-finish-function
1244         (funcall compilation-finish-function (current-buffer) msg))
1245     (let ((functions compilation-finish-functions))
1246       (while functions
1247         (funcall (car functions) (current-buffer) msg)
1248         (setq functions (cdr functions))))))
1249
1250 ;; Called when compilation process changes state.
1251 (defun compilation-sentinel (proc msg)
1252   "Sentinel for compilation buffers."
1253   (if (memq (process-status proc) '(exit signal))
1254       (let ((buffer (process-buffer proc)))
1255         (if (null (buffer-name buffer))
1256             ;; buffer killed
1257             (set-process-buffer proc nil)
1258           (with-current-buffer buffer
1259             ;; Write something in the compilation buffer
1260             ;; and hack its mode line.
1261             (compilation-handle-exit (process-status proc)
1262                                      (process-exit-status proc)
1263                                      msg)
1264             ;; Since the buffer and mode line will show that the
1265             ;; process is dead, we can delete it now.  Otherwise it
1266             ;; will stay around until M-x list-processes.
1267             (delete-process proc)))
1268         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1269
1270 (defun compilation-filter (proc string)
1271   "Process filter for compilation buffers.
1272 Just inserts the text, but uses `insert-before-markers'."
1273   (if (buffer-name (process-buffer proc))
1274       (with-current-buffer (process-buffer proc)
1275         (let ((inhibit-read-only t))
1276           (save-excursion
1277             (goto-char (process-mark proc))
1278             (insert-before-markers string)
1279             (run-hooks 'compilation-filter-hook))))))
1280
1281 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1282 (defsubst compilation-buffer-internal-p ()
1283   "Test if inside a compilation buffer."
1284   (local-variable-p 'compilation-locs))
1285
1286 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1287 (defsubst compilation-buffer-p (buffer)
1288   "Test if BUFFER is a compilation buffer."
1289   (with-current-buffer buffer
1290     (compilation-buffer-internal-p)))
1291
1292 (defmacro compilation-loop (< property-change 1+ error)
1293   `(while (,< n 0)
1294       (or (setq pt (,property-change pt 'message))
1295           (error ,error compilation-error))
1296       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1297       (or (setq msg (get-text-property pt 'message))
1298           (if (setq pt (,property-change pt 'message))
1299               (setq msg (get-text-property pt 'message)))
1300           (error ,error compilation-error))
1301       (or (< (cadr msg) compilation-skip-threshold)
1302           (if different-file
1303               (eq (prog1 last (setq last (nth 2 (car msg))))
1304                   last))
1305           (if compilation-skip-visited
1306               (nthcdr 4 (car msg)))
1307           (if compilation-skip-to-next-location
1308               (eq (car msg) loc))
1309           ;; count this message only if none of the above are true
1310           (setq n (,1+ n)))))
1311
1312 (defun compilation-next-error (n &optional different-file pt)
1313   "Move point to the next error in the compilation buffer.
1314 Prefix arg N says how many error messages to move forwards (or
1315 backwards, if negative).
1316 Does NOT find the source line like \\[next-error]."
1317   (interactive "p")
1318   (or (compilation-buffer-p (current-buffer))
1319       (error "Not in a compilation buffer"))
1320   (or pt (setq pt (point)))
1321   (let* ((msg (get-text-property pt 'message))
1322          (loc (car msg))
1323          last)
1324     (if (zerop n)
1325         (unless (or msg                 ; find message near here
1326                     (setq msg (get-text-property (max (1- pt) (point-min))
1327                                                  'message)))
1328           (setq pt (previous-single-property-change pt 'message nil
1329                                                     (line-beginning-position)))
1330           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1331             (setq pt (next-single-property-change pt 'message nil
1332                                                   (line-end-position)))
1333             (or (setq msg (get-text-property pt 'message))
1334                 (setq pt (point)))))
1335       (setq last (nth 2 (car msg)))
1336       (if (>= n 0)
1337           (compilation-loop > next-single-property-change 1-
1338                             (if (get-buffer-process (current-buffer))
1339                                 "No more %ss yet"
1340                               "Moved past last %s"))
1341         ;; Don't move "back" to message at or before point.
1342         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1343         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1344         (compilation-loop < previous-single-property-change 1+
1345                           "Moved back before first %s")))
1346     (goto-char pt)
1347     (or msg
1348         (error "No %s here" compilation-error))))
1349
1350 (defun compilation-previous-error (n)
1351   "Move point to the previous error in the compilation buffer.
1352 Prefix arg N says how many error messages to move backwards (or
1353 forwards, if negative).
1354 Does NOT find the source line like \\[previous-error]."
1355   (interactive "p")
1356   (compilation-next-error (- n)))
1357
1358 (defun compilation-next-file (n)
1359   "Move point to the next error for a different file than the current one.
1360 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1361   (interactive "p")
1362   (compilation-next-error n t))
1363
1364 (defun compilation-previous-file (n)
1365   "Move point to the previous error for a different file than the current one.
1366 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1367   (interactive "p")
1368   (compilation-next-file (- n)))
1369
1370 (defun kill-compilation ()
1371   "Kill the process made by the \\[compile] or \\[grep] commands."
1372   (interactive)
1373   (let ((buffer (compilation-find-buffer)))
1374     (if (get-buffer-process buffer)
1375         (interrupt-process (get-buffer-process buffer))
1376       (error "The compilation process is not running"))))
1377
1378 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1379
1380 (defun compile-goto-error (&optional event)
1381   "Visit the source for the error message at point.
1382 Use this command in a compilation log buffer.  Sets the mark at point there."
1383   (interactive (list last-input-event))
1384   (if event (posn-set-point (event-end event)))
1385   (or (compilation-buffer-p (current-buffer))
1386       (error "Not in a compilation buffer"))
1387   (if (get-text-property (point) 'directory)
1388       (dired-other-window (car (get-text-property (point) 'directory)))
1389     (push-mark)
1390     (setq compilation-current-error (point))
1391     (next-error 0)))
1392
1393 ;; Return a compilation buffer.
1394 ;; If the current buffer is a compilation buffer, return it.
1395 ;; Otherwise, look for a compilation buffer and signal an error
1396 ;; if there are none.
1397 (defun compilation-find-buffer (&optional other-buffer)
1398   (next-error-find-buffer other-buffer 'compilation-buffer-internal-p))
1399
1400 ;;;###autoload
1401 (defun compilation-next-error-function (n &optional reset)
1402   (interactive "p")
1403   (set-buffer (compilation-find-buffer))
1404   (when reset
1405     (setq compilation-current-error nil))
1406   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1407          (last 1)
1408          (loc (compilation-next-error (or n 1) nil
1409                                       (or compilation-current-error (point-min))))
1410          (end-loc (nth 2 loc))
1411          (marker (point-marker)))
1412     (setq compilation-current-error (point-marker)
1413           overlay-arrow-position
1414             (if (bolp)
1415                 compilation-current-error
1416               (save-excursion
1417                 (beginning-of-line)
1418                 (point-marker)))
1419           loc (car loc))
1420     ;; If loc contains no marker, no error in that file has been visited.  If
1421     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1422     ;; markers for that file.
1423     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1424       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1425                                                   (or (cdar (nth 2 loc))
1426                                                       default-directory))
1427         (save-restriction
1428           (widen)
1429           (goto-char (point-min))
1430           ;; Treat file's found lines in forward order, 1 by 1.
1431           (dolist (line (reverse (cddr (nth 2 loc))))
1432             (when (car line)            ; else this is a filename w/o a line#
1433               (beginning-of-line (- (car line) last -1))
1434               (setq last (car line)))
1435             ;; Treat line's found columns and store/update a marker for each.
1436             (dolist (col (cdr line))
1437               (if (car col)
1438                   (if (eq (car col) -1) ; special case for range end
1439                       (end-of-line)
1440                     (if columns
1441                         (move-to-column (car col))
1442                       (beginning-of-line)
1443                       (forward-char (car col))))
1444                 (beginning-of-line)
1445                 (skip-chars-forward " \t"))
1446               (if (nth 3 col)
1447                   (set-marker (nth 3 col) (point))
1448                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1449     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1450     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1451
1452 (defun compilation-fake-loc (marker file &optional line col)
1453   "Preassociate MARKER with FILE.
1454 This is useful when you compile temporary files, but want
1455 automatic translation of the messages to the real buffer from
1456 which the temporary file came.  This only works if done before a
1457 message about FILE appears!
1458
1459 Optional args LINE and COL default to 1 and beginning of
1460 indentation respectively.  The marker is expected to reflect
1461 this.  In the simplest case the marker points to the first line
1462 of the region that was saved to the temp file.
1463
1464 If you concatenate several regions into the temp file (e.g. a
1465 header with variable assignments and a code region), you must
1466 call this several times, once each for the last line of one
1467 region and the first line of the next region."
1468   (or (consp file) (setq file (list file)))
1469   (setq file (or (gethash file compilation-locs)
1470                  (puthash file (list file nil) compilation-locs)))
1471   (let ((loc (compilation-assq (or line 1) (cdr file))))
1472     (setq loc (compilation-assq col loc))
1473     (if (cdr loc)
1474         (setcdr (cddr loc) (list marker))
1475       (setcdr loc (list (or line 1) file marker)))
1476     loc))
1477
1478 (defcustom compilation-context-lines next-screen-context-lines
1479   "*Display this many lines of leading context before message."
1480   :type 'integer
1481   :group 'compilation
1482   :version "21.4")
1483
1484 (defsubst compilation-set-window (w mk)
1485   "Align the compilation output window W with marker MK near top."
1486   (set-window-start w (save-excursion
1487                         (goto-char mk)
1488                         (beginning-of-line (- 1 compilation-context-lines))
1489                         (point)))
1490   (set-window-point w mk))
1491
1492 (defun compilation-goto-locus (msg mk end-mk)
1493   "Jump to an error corresponding to MSG at MK.
1494 All arguments are markers.  If END-MK is non nil, mark is set there."
1495   (if (eq (window-buffer (selected-window))
1496           (marker-buffer msg))
1497       ;; If the compilation buffer window is selected,
1498       ;; keep the compilation buffer in this window;
1499       ;; display the source in another window.
1500       (let ((pop-up-windows t))
1501         (pop-to-buffer (marker-buffer mk)))
1502     (if (window-dedicated-p (selected-window))
1503         (pop-to-buffer (marker-buffer mk))
1504       (switch-to-buffer (marker-buffer mk))))
1505   ;; If narrowing gets in the way of going to the right place, widen.
1506   (unless (eq (goto-char mk) (point))
1507     (widen)
1508     (goto-char mk))
1509   (if end-mk
1510       (push-mark end-mk nil t)
1511     (if mark-active (setq mark-active)))
1512   ;; If hideshow got in the way of
1513   ;; seeing the right place, open permanently.
1514   (dolist (ov (overlays-at (point)))
1515     (when (eq 'hs (overlay-get ov 'invisible))
1516       (delete-overlay ov)
1517       (goto-char mk)))
1518
1519   ;; Show compilation buffer in other window, scrolled to this error.
1520   (let* ((pop-up-windows t)
1521          ;; Use an existing window if it is in a visible frame.
1522          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1523                 ;; Pop up a window.
1524                 (display-buffer (marker-buffer msg))))
1525          (highlight-regexp (with-current-buffer (marker-buffer msg)
1526                              ;; also do this while we change buffer
1527                              (compilation-set-window w msg)
1528                              compilation-highlight-regexp)))
1529     (compilation-set-window-height w)
1530
1531     (when (and highlight-regexp
1532                (not (and end-mk transient-mark-mode)))
1533       (unless compilation-highlight-overlay
1534         (setq compilation-highlight-overlay
1535               (make-overlay (point-min) (point-min)))
1536         (overlay-put compilation-highlight-overlay 'face 'region))
1537       (with-current-buffer (marker-buffer mk)
1538         (save-excursion
1539           (end-of-line)
1540           (let ((end (point)))
1541             (beginning-of-line)
1542             (if (and (stringp highlight-regexp)
1543                      (re-search-forward highlight-regexp end t))
1544                 (progn
1545                   (goto-char (match-beginning 0))
1546                   (move-overlay compilation-highlight-overlay (match-beginning 0) (match-end 0)))
1547               (move-overlay compilation-highlight-overlay (point) end))
1548             (sit-for 0.5)
1549             (delete-overlay compilation-highlight-overlay)))))))
1550
1551 \f
1552 (defun compilation-find-file (marker filename dir &rest formats)
1553   "Find a buffer for file FILENAME.
1554 Search the directories in `compilation-search-path'.
1555 A nil in `compilation-search-path' means to try the
1556 current directory, which is passed in DIR.
1557 If FILENAME is not found at all, ask the user where to find it.
1558 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1559   (or formats (setq formats '("%s")))
1560   (save-excursion
1561     (let ((dirs compilation-search-path)
1562           buffer thisdir fmts name)
1563       (if (file-name-absolute-p filename)
1564           ;; The file name is absolute.  Use its explicit directory as
1565           ;; the first in the search path, and strip it from FILENAME.
1566           (setq filename (abbreviate-file-name (expand-file-name filename))
1567                 dirs (cons (file-name-directory filename) dirs)
1568                 filename (file-name-nondirectory filename)))
1569       ;; Now search the path.
1570       (while (and dirs (null buffer))
1571         (setq thisdir (or (car dirs) dir)
1572               fmts formats)
1573         ;; For each directory, try each format string.
1574         (while (and fmts (null buffer))
1575           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1576                 buffer (and (file-exists-p name)
1577                             (find-file-noselect name))
1578                 fmts (cdr fmts)))
1579         (setq dirs (cdr dirs)))
1580       (or buffer
1581           ;; The file doesn't exist.  Ask the user where to find it.
1582           (let ((pop-up-windows t))
1583             (compilation-set-window (display-buffer (marker-buffer marker))
1584                                     marker)
1585             (let ((name (expand-file-name
1586                          (read-file-name
1587                           (format "Find this error in: (default %s) "
1588                                   filename)
1589                           dir filename t))))
1590               (if (file-directory-p name)
1591                   (setq name (expand-file-name filename name)))
1592               (setq buffer (and (file-exists-p name)
1593                                 (find-file name))))))
1594       ;; Make intangible overlays tangible.
1595       (mapcar (function (lambda (ov)
1596                           (when (overlay-get ov 'intangible)
1597                             (overlay-put ov 'intangible nil))))
1598               (overlays-in (point-min) (point-max)))
1599       buffer)))
1600
1601 (defun compilation-normalize-filename (filename)
1602   "Convert FILENAME string found in an error message to make it usable."
1603
1604   ;; Check for a comint-file-name-prefix and prepend it if
1605   ;; appropriate.  (This is very useful for
1606   ;; compilation-minor-mode in an rlogin-mode buffer.)
1607   (and (boundp 'comint-file-name-prefix)
1608        ;; If file name is relative, default-directory will
1609        ;; already contain the comint-file-name-prefix (done
1610        ;; by compile-abbreviate-directory).
1611        (file-name-absolute-p filename)
1612        (setq filename
1613              (concat (with-no-warnings 'comint-file-name-prefix) filename)))
1614
1615   ;; If compilation-parse-errors-filename-function is
1616   ;; defined, use it to process the filename.
1617   (when compilation-parse-errors-filename-function
1618     (setq filename
1619           (funcall compilation-parse-errors-filename-function
1620                    filename)))
1621
1622   ;; Some compilers (e.g. Sun's java compiler, reportedly)
1623   ;; produce bogus file names like "./bar//foo.c" for file
1624   ;; "bar/foo.c"; expand-file-name will collapse these into
1625   ;; "/foo.c" and fail to find the appropriate file.  So we
1626   ;; look for doubled slashes in the file name and fix them
1627   ;; up in the buffer.
1628   (setq filename (command-line-normalize-file-name filename)))
1629
1630
1631 ;; If directory DIR is a subdir of ORIG or of ORIG's parent,
1632 ;; return a relative name for it starting from ORIG or its parent.
1633 ;; ORIG-EXPANDED is an expanded version of ORIG.
1634 ;; PARENT-EXPANDED is an expanded version of ORIG's parent.
1635 ;; Those two args could be computed here, but we run faster by
1636 ;; having the caller compute them just once.
1637 (defun compile-abbreviate-directory (dir orig orig-expanded parent-expanded)
1638   ;; Apply canonical abbreviations to DIR first thing.
1639   ;; Those abbreviations are already done in the other arguments passed.
1640   (setq dir (abbreviate-file-name dir))
1641
1642   ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1643   ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1644   ;; buffer.)
1645   (if (boundp 'comint-file-name-prefix)
1646       (setq dir (concat comint-file-name-prefix dir)))
1647
1648   (if (and (> (length dir) (length orig-expanded))
1649            (string= orig-expanded
1650                     (substring dir 0 (length orig-expanded))))
1651       (setq dir
1652             (concat orig
1653                     (substring dir (length orig-expanded)))))
1654   (if (and (> (length dir) (length parent-expanded))
1655            (string= parent-expanded
1656                     (substring dir 0 (length parent-expanded))))
1657     (setq dir
1658           (concat (file-name-directory
1659                    (directory-file-name orig))
1660                   (substring dir (length parent-expanded)))))
1661   dir)
1662
1663 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1664
1665 ;;; Compatibility with the old compile.el.
1666
1667 (defun compile-buffer-substring (n) (if n (match-string n)))
1668
1669 (defun compilation-compat-error-properties (err)
1670   "Map old-style error ERR to new-style message."
1671   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1672   ;; (MARKER . MARKER).
1673   (let ((dst (cdr err)))
1674     (if (markerp dst)
1675         ;; Must start with a face, for font-lock.
1676         `(face nil
1677           message ,(list (list nil nil nil dst) 2)
1678           help-echo "mouse-2: visit the source location"
1679           keymap compilation-button-map
1680           mouse-face highlight)
1681       ;; Too difficult to do it by hand: dispatch to the normal code.
1682       (let* ((file (pop dst))
1683              (line (pop dst))
1684              (col (pop dst))
1685              (filename (pop file))
1686              (dirname (pop file))
1687              (fmt (pop file)))
1688         (compilation-internal-error-properties
1689          (cons filename dirname) line nil col nil 2 fmt)))))
1690
1691 (defun compilation-compat-parse-errors (limit)
1692   (when compilation-parse-errors-function
1693     ;; FIXME: We should remove the rest of the compilation keywords
1694     ;; but we can't do that from here because font-lock is using
1695     ;; the value right now.  --stef
1696     (save-excursion
1697       (setq compilation-error-list nil)
1698       ;; Reset compilation-parsing-end each time because font-lock
1699       ;; might force us the re-parse many times (typically because
1700       ;; some code adds some text-property to the output that we
1701       ;; already parsed).  You might say "why reparse", well:
1702       ;; because font-lock has just removed the `message' property so
1703       ;; have to do it all over again.
1704       (if compilation-parsing-end
1705           (set-marker compilation-parsing-end (point))
1706         (setq compilation-parsing-end (point-marker)))
1707       (condition-case nil
1708           ;; Ignore any error: we're calling this function earlier than
1709           ;; in the old compile.el so things might not all be setup yet.
1710           (funcall compilation-parse-errors-function limit nil)
1711         (error nil))
1712       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1713         (let* ((src (car err))
1714                (dst (cdr err))
1715                (loc (cond ((markerp dst) (list nil nil nil dst))
1716                           ((consp dst)
1717                            (list (nth 2 dst) (nth 1 dst)
1718                                  (cons (cdar dst) (caar dst)))))))
1719           (when loc
1720             (goto-char src)
1721             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1722             (put-text-property src (line-end-position)
1723                                'message (list loc 2)))))))
1724   (goto-char limit)
1725   nil)
1726
1727 (defun compilation-forget-errors ()
1728   ;; In case we hit the same file/line specs, we want to recompute a new
1729   ;; marker for them, so flush our cache.
1730   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
1731   ;; FIXME: the old code reset the directory-stack, so maybe we should
1732   ;; put a `directory change' marker of some sort, but where?  -stef
1733   ;;
1734   ;; FIXME: The old code moved compilation-current-error (which was
1735   ;; virtually represented by a mix of compilation-parsing-end and
1736   ;; compilation-error-list) to point-min, but that was only meaningful for
1737   ;; the internal uses of compilation-forget-errors: all calls from external
1738   ;; packages seem to be followed by a move of compilation-parsing-end to
1739   ;; something equivalent to point-max.  So we speculatively move
1740   ;; compilation-current-error to point-max (since the external package
1741   ;; won't know that it should do it).  --stef
1742   (setq compilation-current-error (point-max)))
1743
1744 (provide 'compile)
1745
1746 ;;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1747 ;;; compile.el ends here