lisp/emacs-lisp/cl.el

   1 ;;; cl.el --- Compatibility aliases for the old CL library.  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords: extensions
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is a compatibility file which provides the old names provided by CL
  26 ;; before we cleaned up its namespace usage.
  27
  28 ;;; Code:
  29
  30 (require 'cl-lib)
  31 (require 'macroexp)
  32
  33 ;; (defun cl--rename ()
  34 ;;   (let ((vdefs ())
  35 ;;         (fdefs ())
  36 ;;         (case-fold-search nil)
  37 ;;         (files '("cl.el" "cl-macs.el" "cl-seq.el" "cl-extra.el")))
  38 ;;     (dolist (file files)
  39 ;;       (with-current-buffer (find-file-noselect file)
  40 ;;         (goto-char (point-min))
  41 ;;         (while (re-search-forward
  42 ;;                 "^(\\(def[^ \t\n]*\\) +'?\\(\\(\\sw\\|\\s_\\)+\\)" nil t)
  43 ;;           (let ((name (match-string-no-properties 2))
  44 ;;                 (type (match-string-no-properties 1)))
  45 ;;             (unless (string-match-p "\\`cl-" name)
  46 ;;               (cond
  47 ;;                ((member type '("defvar" "defconst"))
  48 ;;                 (unless (member name vdefs) (push name vdefs)))
  49 ;;                ((member type '("defun" "defsubst" "defalias" "defmacro"))
  50 ;;                 (unless (member name fdefs) (push name fdefs)))
  51 ;;                ((member type '("def-edebug-spec" "defsetf" "define-setf-method"
  52 ;;                                "define-compiler-macro"))
  53 ;;                 nil)
  54 ;;                (t (error "Unknown type %S" type))))))))
  55 ;;     (let ((re (concat "\\_<" (regexp-opt (append vdefs fdefs)) "\\_>"))
  56 ;;           (conflicts ()))
  57 ;;       (dolist (file files)
  58 ;;         (with-current-buffer (find-file-noselect file)
  59 ;;           (goto-char (point-min))
  60 ;;           (while (re-search-forward re nil t)
  61 ;;             (replace-match "cl-\\&"))
  62 ;;           (save-buffer))))
  63 ;;     (with-current-buffer (find-file-noselect "cl-rename.el")
  64 ;;       (dolist (def vdefs)
  65 ;;         (insert (format "(defvaralias '%s 'cl-%s)\n" def def)))
  66 ;;       (dolist (def fdefs)
  67 ;;         (insert (format "(defalias '%s 'cl-%s)\n" def def)))
  68 ;;       (save-buffer))))
  69
  70 ;; (defun cl--unrename ()
  71 ;;   ;; Taken from "Naming Conventions" node of the doc.
  72 ;;   (let* ((names '(defun* defsubst* defmacro* function* member*
  73 ;;                          assoc* rassoc* get* remove* delete*
  74 ;;                          mapcar* sort* floor* ceiling* truncate*
  75 ;;                          round* mod* rem* random*))
  76 ;;          (files '("cl.el" "cl-lib.el" "cl-macs.el" "cl-seq.el" "cl-extra.el"))
  77 ;;          (re (concat "\\_<cl-" (regexp-opt (mapcar #'symbol-name names))
  78 ;;                      "\\_>")))
  79 ;;     (dolist (file files)
  80 ;;       (with-current-buffer (find-file-noselect file)
  81 ;;         (goto-char (point-min))
  82 ;;         (while (re-search-forward re nil t)
  83 ;;           (delete-region (1- (point)) (point)))
  84 ;;         (save-buffer)))))
  85
  86 ;;; Aliases to cl-lib's features.
  87
  88 (dolist (var '(
  89                ;; loop-result-var
  90                ;; loop-result
  91                ;; loop-initially
  92                ;; loop-finally
  93                ;; loop-bindings
  94                ;; loop-args
  95                ;; bind-inits
  96                ;; bind-block
  97                ;; lambda-list-keywords
  98                float-negative-epsilon
  99                float-epsilon
 100                least-negative-normalized-float
 101                least-positive-normalized-float
 102                least-negative-float
 103                least-positive-float
 104                most-negative-float
 105                most-positive-float
 106                ;; custom-print-functions
 107                ))
 108   (defvaralias var (intern (format "cl-%s" var))))
 109
 110 ;; Before overwriting subr.el's `dotimes' and `dolist', let's remember
 111 ;; them under a different name, so we can use them in our implementation
 112 ;; of `dotimes' and `dolist'.
 113 (unless (fboundp 'cl--dotimes)
 114   (defalias 'cl--dotimes (symbol-function 'dotimes) "The non-CL `dotimes'."))
 115 (unless (fboundp 'cl--dolist)
 116   (defalias 'cl--dolist (symbol-function 'dolist) "The non-CL `dolist'."))
 117
 118 (dolist (fun '(
 119                (get* . cl-get)
 120                (random* . cl-random)
 121                (rem* . cl-rem)
 122                (mod* . cl-mod)
 123                (round* . cl-round)
 124                (truncate* . cl-truncate)
 125                (ceiling* . cl-ceiling)
 126                (floor* . cl-floor)
 127                (rassoc* . cl-rassoc)
 128                (assoc* . cl-assoc)
 129                (member* . cl-member)
 130                (delete* . cl-delete)
 131                (remove* . cl-remove)
 132                (defsubst* . cl-defsubst)
 133                (sort* . cl-sort)
 134                (function* . cl-function)
 135                (defmacro* . cl-defmacro)
 136                (defun* . cl-defun)
 137                (mapcar* . cl-mapcar)
 138
 139                remprop
 140                getf
 141                tailp
 142                list-length
 143                nreconc
 144                revappend
 145                concatenate
 146                subseq
 147                random-state-p
 148                make-random-state
 149                signum
 150                isqrt
 151                lcm
 152                gcd
 153                notevery
 154                notany
 155                every
 156                some
 157                mapcon
 158                mapcan
 159                mapl
 160                maplist
 161                map
 162                equalp
 163                coerce
 164                tree-equal
 165                nsublis
 166                sublis
 167                nsubst-if-not
 168                nsubst-if
 169                nsubst
 170                subst-if-not
 171                subst-if
 172                subsetp
 173                nset-exclusive-or
 174                set-exclusive-or
 175                nset-difference
 176                set-difference
 177                nintersection
 178                intersection
 179                nunion
 180                union
 181                rassoc-if-not
 182                rassoc-if
 183                assoc-if-not
 184                assoc-if
 185                member-if-not
 186                member-if
 187                merge
 188                stable-sort
 189                search
 190                mismatch
 191                count-if-not
 192                count-if
 193                count
 194                position-if-not
 195                position-if
 196                position
 197                find-if-not
 198                find-if
 199                find
 200                nsubstitute-if-not
 201                nsubstitute-if
 202                nsubstitute
 203                substitute-if-not
 204                substitute-if
 205                substitute
 206                delete-duplicates
 207                remove-duplicates
 208                delete-if-not
 209                delete-if
 210                remove-if-not
 211                remove-if
 212                replace
 213                fill
 214                reduce
 215                compiler-macroexpand
 216                define-compiler-macro
 217                assert
 218                check-type
 219                typep
 220                deftype
 221                defstruct
 222                callf2
 223                callf
 224                letf*
 225                ;; letf
 226                rotatef
 227                shiftf
 228                remf
 229                psetf
 230                (define-setf-method . define-setf-expander)
 231                declare
 232                the
 233                locally
 234                multiple-value-setq
 235                multiple-value-bind
 236                symbol-macrolet
 237                macrolet
 238                progv
 239                psetq
 240                do-all-symbols
 241                do-symbols
 242                dotimes
 243                dolist
 244                do*
 245                do
 246                loop
 247                return-from
 248                return
 249                block
 250                etypecase
 251                typecase
 252                ecase
 253                case
 254                load-time-value
 255                eval-when
 256                destructuring-bind
 257                gentemp
 258                gensym
 259                pairlis
 260                acons
 261                subst
 262                adjoin
 263                copy-list
 264                ldiff
 265                list*
 266                cddddr
 267                cdddar
 268                cddadr
 269                cddaar
 270                cdaddr
 271                cdadar
 272                cdaadr
 273                cdaaar
 274                cadddr
 275                caddar
 276                cadadr
 277                cadaar
 278                caaddr
 279                caadar
 280                caaadr
 281                caaaar
 282                cdddr
 283                cddar
 284                cdadr
 285                cdaar
 286                caddr
 287                cadar
 288                caadr
 289                caaar
 290                tenth
 291                ninth
 292                eighth
 293                seventh
 294                sixth
 295                fifth
 296                fourth
 297                third
 298                endp
 299                rest
 300                second
 301                first
 302                svref
 303                copy-seq
 304                evenp
 305                oddp
 306                minusp
 307                plusp
 308                floatp-safe
 309                declaim
 310                proclaim
 311                nth-value
 312                multiple-value-call
 313                multiple-value-apply
 314                multiple-value-list
 315                values-list
 316                values
 317                pushnew
 318                decf
 319                incf
 320                ))
 321   (let ((new (if (consp fun) (prog1 (cdr fun) (setq fun (car fun)))
 322                (intern (format "cl-%s" fun)))))
 323     (defalias fun new)))
 324
 325 ;;; Features provided a bit differently in Elisp.
 326
 327 ;; First, the old lexical-let is now better served by `lexical-binding', tho
 328 ;; it's not 100% compatible.
 329
 330 (defvar cl-closure-vars nil)
 331 (defvar cl--function-convert-cache nil)
 332
 333 (defun cl--function-convert (f)
 334   "Special macro-expander for special cases of (function F).
 335 The two cases that are handled are:
 336 - closure-conversion of lambda expressions for `lexical-let'.
 337 - renaming of F when it's a function defined via `cl-labels' or `labels'."
 338   (require 'cl-macs)
 339   (declare-function cl--expr-contains-any "cl-macs" (x y))
 340   (cond
 341    ;; ¡¡Big Ugly Hack!! We can't use a compiler-macro because those are checked
 342    ;; *after* handling `function', but we want to stop macroexpansion from
 343    ;; being applied infinitely, so we use a cache to return the exact `form'
 344    ;; being expanded even though we don't receive it.
 345    ((eq f (car cl--function-convert-cache)) (cdr cl--function-convert-cache))
 346    ((eq (car-safe f) 'lambda)
 347     (let ((body (mapcar (lambda (f)
 348                           (macroexpand-all f macroexpand-all-environment))
 349                         (cddr f))))
 350       (if (and cl-closure-vars
 351                (cl--expr-contains-any body cl-closure-vars))
 352           (let* ((new (mapcar 'cl-gensym cl-closure-vars))
 353                  (sub (cl-pairlis cl-closure-vars new)) (decls nil))
 354             (while (or (stringp (car body))
 355                        (eq (car-safe (car body)) 'interactive))
 356               (push (list 'quote (pop body)) decls))
 357             (put (car (last cl-closure-vars)) 'used t)
 358             `(list 'lambda '(&rest --cl-rest--)
 359                    ,@(cl-sublis sub (nreverse decls))
 360                    (list 'apply
 361                          (list 'quote
 362                                #'(lambda ,(append new (cadr f))
 363                                    ,@(cl-sublis sub body)))
 364                          ,@(nconc (mapcar (lambda (x) `(list 'quote ,x))
 365                                           cl-closure-vars)
 366                                   '((quote --cl-rest--))))))
 367         (let* ((newf `(lambda ,(cadr f) ,@body))
 368                (res `(function ,newf)))
 369           (setq cl--function-convert-cache (cons newf res))
 370           res))))
 371    (t
 372     (let ((found (assq f macroexpand-all-environment)))
 373       (if (and found (ignore-errors
 374                        (eq (cadr (cl-caddr found)) 'cl-labels-args)))
 375           (cadr (cl-caddr (cl-cadddr found)))
 376         (let ((res `(function ,f)))
 377           (setq cl--function-convert-cache (cons f res))
 378           res))))))
 379
 380 (defmacro lexical-let (bindings &rest body)
 381   "Like `let', but lexically scoped.
 382 The main visible difference is that lambdas inside BODY will create
 383 lexical closures as in Common Lisp.
 384 \n(fn BINDINGS BODY)"
 385   (declare (indent 1) (debug let))
 386   (let* ((cl-closure-vars cl-closure-vars)
 387          (vars (mapcar (function
 388                         (lambda (x)
 389                           (or (consp x) (setq x (list x)))
 390                           (push (make-symbol (format "--cl-%s--" (car x)))
 391                                 cl-closure-vars)
 392                           (set (car cl-closure-vars) [bad-lexical-ref])
 393                           (list (car x) (cadr x) (car cl-closure-vars))))
 394                        bindings))
 395          (ebody
 396           (macroexpand-all
 397            `(cl-symbol-macrolet
 398                 ,(mapcar (lambda (x)
 399                            `(,(car x) (symbol-value ,(cl-caddr x))))
 400                          vars)
 401               ,@body)
 402            (cons (cons 'function #'cl--function-convert)
 403                  macroexpand-all-environment))))
 404     (if (not (get (car (last cl-closure-vars)) 'used))
 405         ;; Turn (let ((foo (cl-gensym)))
 406         ;;        (set foo <val>) ...(symbol-value foo)...)
 407         ;; into (let ((foo <val>)) ...(symbol-value 'foo)...).
 408         ;; This is good because it's more efficient but it only works with
 409         ;; dynamic scoping, since with lexical scoping we'd need
 410         ;; (let ((foo <val>)) ...foo...).
 411         `(progn
 412            ,@(mapcar (lambda (x) `(defvar ,(cl-caddr x))) vars)
 413            (let ,(mapcar (lambda (x) (list (cl-caddr x) (cadr x))) vars)
 414            ,(cl-sublis (mapcar (lambda (x)
 415                               (cons (cl-caddr x)
 416                                     `',(cl-caddr x)))
 417                             vars)
 418                     ebody)))
 419       `(let ,(mapcar (lambda (x)
 420                        (list (cl-caddr x)
 421                              `(make-symbol ,(format "--%s--" (car x)))))
 422                      vars)
 423          (setf ,@(apply #'append
 424                         (mapcar (lambda (x)
 425                                   (list `(symbol-value ,(cl-caddr x)) (cadr x)))
 426                                 vars)))
 427          ,ebody))))
 428
 429 (defmacro lexical-let* (bindings &rest body)
 430   "Like `let*', but lexically scoped.
 431 The main visible difference is that lambdas inside BODY, and in
 432 successive bindings within BINDINGS, will create lexical closures
 433 as in Common Lisp.  This is similar to the behavior of `let*' in
 434 Common Lisp.
 435 \n(fn BINDINGS BODY)"
 436   (declare (indent 1) (debug let))
 437   (if (null bindings) (cons 'progn body)
 438     (setq bindings (reverse bindings))
 439     (while bindings
 440       (setq body (list `(lexical-let (,(pop bindings)) ,@body))))
 441     (car body)))
 442
 443 ;; This should really have some way to shadow 'byte-compile properties, etc.
 444 (defmacro flet (bindings &rest body)
 445   "Make temporary overriding function definitions.
 446 This is an analogue of a dynamically scoped `let' that operates on the function
 447 cell of FUNCs rather than their value cell.
 448 If you want the Common-Lisp style of `flet', you should use `cl-flet'.
 449 The FORMs are evaluated with the specified function definitions in place,
 450 then the definitions are undone (the FUNCs go back to their previous
 451 definitions, or lack thereof).
 452
 453 \(fn ((FUNC ARGLIST BODY...) ...) FORM...)"
 454   (declare (indent 1) (debug cl-flet)
 455            (obsolete "use either `cl-flet' or `cl-letf'."  "24.3"))
 456   `(letf ,(mapcar
 457            (lambda (x)
 458              (if (or (and (fboundp (car x))
 459                           (eq (car-safe (symbol-function (car x))) 'macro))
 460                      (cdr (assq (car x) macroexpand-all-environment)))
 461                  (error "Use `labels', not `flet', to rebind macro names"))
 462              (let ((func `(cl-function
 463                            (lambda ,(cadr x)
 464                              (cl-block ,(car x) ,@(cddr x))))))
 465                (when (cl--compiling-file)
 466                  ;; Bug#411.  It would be nice to fix this.
 467                  (and (get (car x) 'byte-compile)
 468                       (error "Byte-compiling a redefinition of `%s' \
 469 will not work - use `labels' instead" (symbol-name (car x))))
 470                  ;; FIXME This affects the rest of the file, when it
 471                  ;; should be restricted to the flet body.
 472                  (and (boundp 'byte-compile-function-environment)
 473                       (push (cons (car x) (eval func))
 474                             byte-compile-function-environment)))
 475                (list `(symbol-function ',(car x)) func)))
 476            bindings)
 477      ,@body))
 478
 479 (defmacro labels (bindings &rest body)
 480   "Make temporary function bindings.
 481 Like `cl-labels' except that the lexical scoping is handled via `lexical-let'
 482 rather than relying on `lexical-binding'."
 483   (declare (indent 1) (debug cl-flet) (obsolete cl-labels "24.3"))
 484   (let ((vars nil) (sets nil) (newenv macroexpand-all-environment))
 485     (dolist (binding bindings)
 486       ;; It's important that (not (eq (symbol-name var1) (symbol-name var2)))
 487       ;; because these var's *names* get added to the macro-environment.
 488       (let ((var (make-symbol (format "--cl-%s--" (car binding)))))
 489         (push var vars)
 490         (push `(cl-function (lambda . ,(cdr binding))) sets)
 491         (push var sets)
 492         (push (cons (car binding)
 493                     `(lambda (&rest cl-labels-args)
 494                        (cl-list* 'funcall ',var
 495                                  cl-labels-args)))
 496               newenv)))
 497     (macroexpand-all `(lexical-let ,vars (setq ,@sets) ,@body) newenv)))
 498
 499 ;; Generalized variables are provided by gv.el, but some details are
 500 ;; not 100% compatible: not worth the trouble to add them to cl-lib.el, but we
 501 ;; still need to support old users of cl.el.
 502
 503 (defmacro cl--symbol-function (symbol)
 504   "Like `symbol-function' but return `cl--unbound' if not bound."
 505   ;; (declare (gv-setter (lambda (store)
 506   ;;                       `(if (eq ,store 'cl--unbound)
 507   ;;                            (fmakunbound ,symbol) (fset ,symbol ,store)))))
 508   `(if (fboundp ,symbol) (symbol-function ,symbol) 'cl--unbound))
 509 (gv-define-setter cl--symbol-function (store symbol)
 510   `(if (eq ,store 'cl--unbound) (fmakunbound ,symbol) (fset ,symbol ,store)))
 511
 512 (defmacro letf (bindings &rest body)
 513   "Dynamically scoped let-style bindings for places.
 514 For more details, see `cl-letf'.  This macro behaves like that one
 515 in almost every respect (apart from details that relate to some
 516 deprecated usage of `symbol-function' in place forms)."  ; bug#12760
 517   (declare (indent 1) (debug cl-letf))
 518   ;; Like cl-letf, but with special handling of symbol-function.
 519   `(cl-letf ,(mapcar (lambda (x) (if (eq (car-safe (car x)) 'symbol-function)
 520                                 `((cl--symbol-function ,@(cdar x)) ,@(cdr x))
 521                               x))
 522                      bindings)
 523             ,@body))
 524
 525 (defun cl--gv-adapt (cl-gv do)
 526   ;; This function is used by all .elc files that use define-setf-expander and
 527   ;; were compiled with Emacs>=24.3.
 528   (let ((vars (nth 0 cl-gv))
 529         (vals (nth 1 cl-gv))
 530         (binds ())
 531         (substs ()))
 532     ;; Use cl-sublis as was done in cl-setf-do-modify.
 533     (while vars
 534       (if (macroexp-copyable-p (car vals))
 535           (push (cons (pop vars) (pop vals)) substs)
 536         (push (list (pop vars) (pop vals)) binds)))
 537     (macroexp-let*
 538      binds
 539      (funcall do (cl-sublis substs (nth 4 cl-gv))
 540               ;; We'd like to do something like
 541               ;; (lambda ,(nth 2 cl-gv) ,(nth 3 cl-gv)).
 542               (lambda (exp)
 543                 (macroexp-let2 macroexp-copyable-p v exp
 544                   (cl-sublis (cons (cons (car (nth 2 cl-gv)) v)
 545                                    substs)
 546                              (nth 3 cl-gv))))))))
 547
 548 (defmacro define-setf-expander (name arglist &rest body)
 549   "Define a `setf' method.
 550 This method shows how to handle `setf's to places of the form
 551 \(NAME ARGS...).  The argument forms ARGS are bound according to
 552 ARGLIST, as if NAME were going to be expanded as a macro, then
 553 the BODY forms are executed and must return a list of five elements:
 554 a temporary-variables list, a value-forms list, a store-variables list
 555 \(of length one), a store-form, and an access- form.
 556
 557 See `gv-define-expander', and `gv-define-setter' for better and
 558 simpler ways to define setf-methods."
 559   (declare (debug
 560             (&define name cl-lambda-list cl-declarations-or-string def-body)))
 561   `(progn
 562      ,@(if (stringp (car body))
 563            (list `(put ',name 'setf-documentation ,(pop body))))
 564      (gv-define-expander ,name
 565        (cl-function
 566         (lambda (do ,@arglist)
 567           (cl--gv-adapt (progn ,@body) do))))))
 568
 569 (defmacro defsetf (name arg1 &rest args)
 570   "Define a `setf' method.
 571 This macro is an easy-to-use substitute for `define-setf-expander'
 572 that works well for simple place forms.
 573
 574 In the simple `defsetf' form, `setf's of the form (setf (NAME
 575 ARGS...) VAL) are transformed to function or macro calls of the
 576 form (FUNC ARGS... VAL).  For example:
 577
 578   (defsetf aref aset)
 579
 580 You can replace this form with `gv-define-simple-setter'.
 581
 582 Alternate form: (defsetf NAME ARGLIST (STORE) BODY...).
 583
 584 Here, the above `setf' call is expanded by binding the argument
 585 forms ARGS according to ARGLIST, binding the value form VAL to
 586 STORE, then executing BODY, which must return a Lisp form that
 587 does the necessary `setf' operation.  Actually, ARGLIST and STORE
 588 may be bound to temporary variables which are introduced
 589 automatically to preserve proper execution order of the arguments.
 590 For example:
 591
 592   (defsetf nth (n x) (v) `(setcar (nthcdr ,n ,x) ,v))
 593
 594 You can replace this form with `gv-define-setter'.
 595
 596 \(fn NAME [FUNC | ARGLIST (STORE) BODY...])"
 597   (declare (debug
 598             (&define name
 599                      [&or [symbolp &optional stringp]
 600                           [cl-lambda-list (symbolp)]]
 601                      cl-declarations-or-string def-body)))
 602   (if (and (listp arg1) (consp args))
 603       ;; Like `gv-define-setter' but with `cl-function'.
 604       `(gv-define-expander ,name
 605          (lambda (do &rest args)
 606            (gv--defsetter ',name
 607                           (cl-function
 608                            (lambda (,@(car args) ,@arg1) ,@(cdr args)))
 609                           do args)))
 610     `(gv-define-simple-setter ,name ,arg1 ,(car args))))
 611
 612 ;; FIXME: CL used to provide a setf method for `apply', but I haven't been able
 613 ;; to find a case where it worked.  The code below tries to handle it as well.
 614 ;; (defun cl--setf-apply (form last-witness last)
 615 ;;   (cond
 616 ;;    ((not (consp form)) form)
 617 ;;    ((eq (ignore-errors (car (last form))) last-witness)
 618 ;;     `(apply #',(car form) ,@(butlast (cdr form)) ,last))
 619 ;;    ((and (memq (car form) '(let let*))
 620 ;;          (rassoc (list last-witness) (cadr form)))
 621 ;;     (let ((rebind (rassoc (list last-witness) (cadr form))))
 622 ;;     `(,(car form) ,(remq rebind (cadr form))
 623 ;;       ,@(mapcar (lambda (form) (cl--setf-apply form (car rebind) last))
 624 ;;                 (cddr form)))))
 625 ;;    (t (mapcar (lambda (form) (cl--setf-apply form last-witness last)) form))))
 626 ;; (gv-define-setter apply (val fun &rest args)
 627 ;;   (pcase fun (`#',(and (pred symbolp) f) (setq fun f))
 628 ;;          (_ (error "First arg to apply in setf is not #'SYM: %S" fun)))
 629 ;;   (let* ((butlast (butlast args))
 630 ;;          (last (car (last args)))
 631 ;;          (last-witness (make-symbol "--cl-tailarg--"))
 632 ;;          (setter (macroexpand `(setf (,fun ,@butlast ,last-witness) ,val)
 633 ;;                               macroexpand-all-environment)))
 634 ;;     (cl--setf-apply setter last-witness last)))
 635
 636
 637 ;; FIXME: CL used to provide get-setf-method, which was used by some
 638 ;; setf-expanders, but now that we use gv.el, it is a lot more difficult
 639 ;; and in general impossible to provide get-setf-method.  Hopefully, it
 640 ;; won't be needed.  If needed, we'll have to do something nasty along the
 641 ;; lines of
 642 ;; (defun get-setf-method (place &optional env)
 643 ;;   (let* ((witness (list 'cl-gsm))
 644 ;;          (expansion (gv-letplace (getter setter) place
 645 ;;                      `(,witness ,getter ,(funcall setter witness)))))
 646 ;;     ...find "let prefix" of expansion, extract getter and setter from
 647 ;;     ...the rest, and build the 5-tuple))
 648 (make-obsolete 'get-setf-method 'gv-letplace "24.3")
 649
 650 (defmacro define-modify-macro (name arglist func &optional doc)
 651   "Define a `setf'-like modify macro.
 652 If NAME is called, it combines its PLACE argument with the other
 653 arguments from ARGLIST using FUNC.  For example:
 654
 655   (define-modify-macro incf (&optional (n 1)) +)
 656
 657 You can replace this macro with `gv-letplace'."
 658   (declare (debug
 659             (&define name cl-lambda-list ;; should exclude &key
 660                      symbolp &optional stringp)))
 661   (if (memq '&key arglist)
 662       (error "&key not allowed in define-modify-macro"))
 663   (let ((place (make-symbol "--cl-place--")))
 664     `(cl-defmacro ,name (,place ,@arglist)
 665        ,doc
 666        (,(if (memq '&rest arglist) #'cl-list* #'list)
 667         #'cl-callf ',func ,place
 668         ,@(cl--arglist-args arglist)))))
 669
 670 ;;; Additional compatibility code.
 671 ;; For names that were clean but really aren't needed any more.
 672
 673 (define-obsolete-function-alias 'cl-macroexpand 'macroexpand "24.3")
 674 (define-obsolete-variable-alias 'cl-macro-environment
 675   'macroexpand-all-environment "24.3")
 676 (define-obsolete-function-alias 'cl-macroexpand-all 'macroexpand-all "24.3")
 677
 678 ;;; Hash tables.
 679 ;; This is just kept for compatibility with code byte-compiled by Emacs-20.
 680
 681 ;; No idea if this might still be needed.
 682 (defun cl-not-hash-table (x &optional y &rest _z)
 683   (declare (obsolete nil "24.3"))
 684   (signal 'wrong-type-argument (list 'cl-hash-table-p (or y x))))
 685
 686 (defvar cl-builtin-gethash (symbol-function 'gethash))
 687 (make-obsolete-variable 'cl-builtin-gethash nil "24.3")
 688 (defvar cl-builtin-remhash (symbol-function 'remhash))
 689 (make-obsolete-variable 'cl-builtin-remhash nil "24.3")
 690 (defvar cl-builtin-clrhash (symbol-function 'clrhash))
 691 (make-obsolete-variable 'cl-builtin-clrhash nil "24.3")
 692 (defvar cl-builtin-maphash (symbol-function 'maphash))
 693
 694 (make-obsolete-variable 'cl-builtin-maphash nil "24.3")
 695 (define-obsolete-function-alias 'cl-map-keymap 'map-keymap "24.3")
 696 (define-obsolete-function-alias 'cl-copy-tree 'copy-tree "24.3")
 697 (define-obsolete-function-alias 'cl-gethash 'gethash "24.3")
 698 (define-obsolete-function-alias 'cl-puthash 'puthash "24.3")
 699 (define-obsolete-function-alias 'cl-remhash 'remhash "24.3")
 700 (define-obsolete-function-alias 'cl-clrhash 'clrhash "24.3")
 701 (define-obsolete-function-alias 'cl-maphash 'maphash "24.3")
 702 (define-obsolete-function-alias 'cl-make-hash-table 'make-hash-table "24.3")
 703 (define-obsolete-function-alias 'cl-hash-table-p 'hash-table-p "24.3")
 704 (define-obsolete-function-alias 'cl-hash-table-count 'hash-table-count "24.3")
 705
 706 (define-obsolete-function-alias 'cl-map-keymap-recursively
 707   'cl--map-keymap-recursively "24.3")
 708 (define-obsolete-function-alias 'cl-map-intervals 'cl--map-intervals "24.3")
 709 (define-obsolete-function-alias 'cl-map-extents 'cl--map-overlays "24.3")
 710
 711 (defun cl-maclisp-member (item list)
 712   (declare (obsolete member "24.3"))
 713   (while (and list (not (equal item (car list)))) (setq list (cdr list)))
 714   list)
 715
 716 ;; Used in the expansion of the old `defstruct'.
 717 (defun cl-struct-setf-expander (x name accessor pred-form pos)
 718   (declare (obsolete nil "24.3"))
 719   (let* ((temp (make-symbol "--cl-x--")) (store (make-symbol "--cl-store--")))
 720     (list (list temp) (list x) (list store)
 721           `(progn
 722              ,@(and pred-form
 723                     (list `(or ,(cl-subst temp 'cl-x pred-form)
 724                                (error ,(format
 725                                         "%s storing a non-%s"
 726                                         accessor name)))))
 727              ,(if (eq (car (get name 'cl-struct-type)) 'vector)
 728                   `(aset ,temp ,pos ,store)
 729                 `(setcar
 730                   ,(if (<= pos 5)
 731                        (let ((xx temp))
 732                          (while (>= (setq pos (1- pos)) 0)
 733                            (setq xx `(cdr ,xx)))
 734                          xx)
 735                      `(nthcdr ,pos ,temp))
 736                   ,store)))
 737           (list accessor temp))))
 738
 739 (provide 'cl)
 740 ;;; cl.el ends here