lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2003, 2004, 2005
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function-alist
  31   (list (cons nil
  32               (if (fboundp 'tty-create-frame-with-faces)
  33                   'tty-create-frame-with-faces
  34                 (function
  35                  (lambda (parameters)
  36                    (error "Can't create multiple frames without a window system"))))))
  37   "Alist of window-system dependent functions to call to create a new frame.
  38 The window system startup file should add its frame creation
  39 function to this list, which should take an alist of parameters
  40 as its argument.")
  41
  42 (defvar window-system-default-frame-alist nil
  43   "Alist of window-system dependent default frame parameters.
  44 These may be set in your init file, like this:
  45
  46     ;; Disable menubar and toolbar on the console, but enable them under X.
  47     (setq window-system-default-frame-alist
  48           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  49             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  50
  51 Also see `default-frame-alist'.")
  52
  53 ;; The initial value given here used to ask for a minibuffer.
  54 ;; But that's not necessary, because the default is to have one.
  55 ;; By not specifying it here, we let an X resource specify it.
  56 (defcustom initial-frame-alist nil
  57   "*Alist of frame parameters for creating the initial X window frame.
  58 You can set this in your `.emacs' file; for example,
  59  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  60 Parameters specified here supersede the values given in `default-frame-alist'.
  61
  62 If the value calls for a frame without a minibuffer, and you have not created
  63 a minibuffer frame on your own, one is created according to
  64 `minibuffer-frame-alist'.
  65
  66 You can specify geometry-related options for just the initial frame
  67 by setting this variable in your `.emacs' file; however, they won't
  68 take effect until Emacs reads `.emacs', which happens after first creating
  69 the frame.  If you want the frame to have the proper geometry as soon
  70 as it appears, you need to use this three-step process:
  71 * Specify X resources to give the geometry you want.
  72 * Set `default-frame-alist' to override these options so that they
  73   don't affect subsequent frames.
  74 * Set `initial-frame-alist' in a way that matches the X resources,
  75   to override what you put in `default-frame-alist'."
  76   :type '(repeat (cons :format "%v"
  77                        (symbol :tag "Parameter")
  78                        (sexp :tag "Value")))
  79   :group 'frames)
  80
  81 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  82   "*Alist of frame parameters for initially creating a minibuffer frame.
  83 You can set this in your `.emacs' file; for example,
  84  (setq minibuffer-frame-alist
  85    '((top . 1) (left . 1) (width . 80) (height . 2)))
  86 Parameters specified here supersede the values given in
  87 `default-frame-alist', for a minibuffer frame."
  88   :type '(repeat (cons :format "%v"
  89                        (symbol :tag "Parameter")
  90                        (sexp :tag "Value")))
  91   :group 'frames)
  92
  93 (defcustom pop-up-frame-alist nil
  94   "*Alist of frame parameters used when creating pop-up frames.
  95 Pop-up frames are used for completions, help, and the like.
  96 This variable can be set in your init file, like this:
  97   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  98 These supersede the values given in `default-frame-alist',
  99 for pop-up frames."
 100   :type '(repeat (cons :format "%v"
 101                        (symbol :tag "Parameter")
 102                        (sexp :tag "Value")))
 103   :group 'frames)
 104
 105 (setq pop-up-frame-function
 106       ;; Using `function' here caused some sort of problem.
 107       '(lambda ()
 108          (make-frame pop-up-frame-alist)))
 109
 110 (defcustom special-display-frame-alist
 111   '((height . 14) (width . 80) (unsplittable . t))
 112   "*Alist of frame parameters used when creating special frames.
 113 Special frames are used for buffers whose names are in
 114 `special-display-buffer-names' and for buffers whose names match
 115 one of the regular expressions in `special-display-regexps'.
 116 This variable can be set in your init file, like this:
 117   (setq special-display-frame-alist '((width . 80) (height . 20)))
 118 These supersede the values given in `default-frame-alist'."
 119   :type '(repeat (cons :format "%v"
 120                          (symbol :tag "Parameter")
 121                          (sexp :tag "Value")))
 122   :group 'frames)
 123
 124 (defun special-display-popup-frame (buffer &optional args)
 125   "Display BUFFER in its own frame, reusing an existing window if any.
 126 Return the window chosen.
 127 Currently we do not insist on selecting the window within its frame.
 128 If ARGS is an alist, use it as a list of frame parameter specs.
 129 If ARGS is a list whose car is a symbol,
 130 use (car ARGS) as a function to do the work.
 131 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 132   (if (and args (symbolp (car args)))
 133       (apply (car args) buffer (cdr args))
 134     (let ((window (get-buffer-window buffer 0)))
 135       (or
 136        ;; If we have a window already, make it visible.
 137        (when window
 138          (let ((frame (window-frame window)))
 139            (make-frame-visible frame)
 140            (raise-frame frame)
 141            window))
 142        ;; Reuse the current window if the user requested it.
 143        (when (cdr (assq 'same-window args))
 144          (condition-case nil
 145              (progn (switch-to-buffer buffer) (selected-window))
 146            (error nil)))
 147        ;; Stay on the same frame if requested.
 148        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 149          (let* ((pop-up-frames nil) (pop-up-windows t)
 150                 special-display-regexps special-display-buffer-names
 151                 (window (display-buffer buffer)))
 152            ;; Only do it if this is a new window:
 153            ;; (set-window-dedicated-p window t)
 154            window))
 155        ;; If no window yet, make one in a new frame.
 156        (let ((frame
 157               (with-current-buffer buffer
 158                 (make-frame (append args special-display-frame-alist)))))
 159          (set-window-buffer (frame-selected-window frame) buffer)
 160          (set-window-dedicated-p (frame-selected-window frame) t)
 161          (frame-selected-window frame))))))
 162
 163 (defun handle-delete-frame (event)
 164   "Handle delete-frame events from the X server."
 165   (interactive "e")
 166   (let ((frame (posn-window (event-start event)))
 167         (i 0)
 168         (tail (frame-list)))
 169     (while tail
 170       (and (frame-visible-p (car tail))
 171            (not (eq (car tail) frame))
 172           (setq i (1+ i)))
 173       (setq tail (cdr tail)))
 174     (if (> i 0)
 175         (delete-frame frame t)
 176       ;; Gildea@x.org says it is ok to ask questions before terminating.
 177       (save-buffers-kill-emacs))))
 178 \f
 179 ;;;; Arrangement of frames at startup
 180
 181 ;; 1) Load the window system startup file from the lisp library and read the
 182 ;; high-priority arguments (-q and the like).  The window system startup
 183 ;; file should create any frames specified in the window system defaults.
 184 ;;
 185 ;; 2) If no frames have been opened, we open an initial text frame.
 186 ;;
 187 ;; 3) Once the init file is done, we apply any newly set parameters
 188 ;; in initial-frame-alist to the frame.
 189
 190 ;; These are now called explicitly at the proper times,
 191 ;; since that is easier to understand.
 192 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 193 ;; (add-hook 'before-init-hook 'frame-initialize)
 194 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 195
 196 ;; If we create the initial frame, this is it.
 197 (defvar frame-initial-frame nil)
 198
 199 ;; Record the parameters used in frame-initialize to make the initial frame.
 200 (defvar frame-initial-frame-alist)
 201
 202 (defvar frame-initial-geometry-arguments nil)
 203
 204 ;; startup.el calls this function before loading the user's init
 205 ;; file - if there is no frame with a minibuffer open now, create
 206 ;; one to display messages while loading the init file.
 207 (defun frame-initialize ()
 208   "Create an initial frame if necessary."
 209   ;; Are we actually running under a window system at all?
 210   (if (and initial-window-system
 211            (not noninteractive)
 212            (not (eq initial-window-system 'pc)))
 213       (progn
 214         ;; Turn on special-display processing only if there's a window system.
 215         (setq special-display-function 'special-display-popup-frame)
 216
 217         ;; If there is no frame with a minibuffer besides the terminal
 218         ;; frame, then we need to create the opening frame.  Make sure
 219         ;; it has a minibuffer, but let initial-frame-alist omit the
 220         ;; minibuffer spec.
 221         (or (delq terminal-frame (minibuffer-frame-list))
 222             (progn
 223               (setq frame-initial-frame-alist
 224                     (append initial-frame-alist default-frame-alist nil))
 225               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 226                   (setq frame-initial-frame-alist
 227                         (cons '(horizontal-scroll-bars . t)
 228                               frame-initial-frame-alist)))
 229               (setq frame-initial-frame-alist
 230                     (cons (cons 'window-system initial-window-system)
 231                           frame-initial-frame-alist))
 232               (setq default-minibuffer-frame
 233                     (setq frame-initial-frame
 234                           (make-frame frame-initial-frame-alist)))
 235               ;; Delete any specifications for window geometry parameters
 236               ;; so that we won't reapply them in frame-notice-user-settings.
 237               ;; It would be wrong to reapply them then,
 238               ;; because that would override explicit user resizing.
 239               (setq initial-frame-alist
 240                     (frame-remove-geometry-params initial-frame-alist))))
 241         ;; At this point, we know that we have a frame open, so we
 242         ;; can delete the terminal frame.
 243         (delete-frame terminal-frame)
 244         (setq terminal-frame nil))))
 245
 246 (defvar frame-notice-user-settings t
 247   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 248
 249 ;; startup.el calls this function after loading the user's init
 250 ;; file.  Now default-frame-alist and initial-frame-alist contain
 251 ;; information to which we must react; do what needs to be done.
 252 (defun frame-notice-user-settings ()
 253   "Act on user's init file settings of frame parameters.
 254 React to settings of `default-frame-alist', `initial-frame-alist' there."
 255   ;; Make menu-bar-mode and default-frame-alist consistent.
 256   (when (boundp 'menu-bar-mode)
 257     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 258       (if default
 259           (setq menu-bar-mode (not (eq (cdr default) 0)))
 260         (setq default-frame-alist
 261               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 262                     default-frame-alist)))))
 263
 264   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 265   ;; it in batch mode since that would leave a tool-bar-lines
 266   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 267   ;; what we want.
 268   (when (and (boundp 'tool-bar-mode)
 269              (not noninteractive))
 270     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 271       (if default
 272           (setq tool-bar-mode (not (eq (cdr default) 0)))
 273         (setq default-frame-alist
 274               (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 275                     default-frame-alist)))))
 276
 277   ;; Creating and deleting frames may shift the selected frame around,
 278   ;; and thus the current buffer.  Protect against that.  We don't
 279   ;; want to use save-excursion here, because that may also try to set
 280   ;; the buffer of the selected window, which fails when the selected
 281   ;; window is the minibuffer.
 282   (let ((old-buffer (current-buffer)))
 283
 284     (when (and frame-notice-user-settings
 285                (null frame-initial-frame))
 286       ;; This case happens when we don't have a window system, and
 287       ;; also for MS-DOS frames.
 288       (let ((parms (frame-parameters frame-initial-frame)))
 289         ;; Don't change the frame names.
 290         (setq parms (delq (assq 'name parms) parms))
 291         ;; Can't modify the minibuffer parameter, so don't try.
 292         (setq parms (delq (assq 'minibuffer parms) parms))
 293         (modify-frame-parameters nil
 294                                  (if (null initial-window-system)
 295                                      (append initial-frame-alist
 296                                              default-frame-alist
 297                                              parms
 298                                              nil)
 299                                    ;; initial-frame-alist and
 300                                    ;; default-frame-alist were already
 301                                    ;; applied in pc-win.el.
 302                                    parms))
 303         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 304             (let ((newparms (frame-parameters))
 305                   (frame (selected-frame)))
 306               (tty-handle-reverse-video frame newparms)
 307               ;; If we changed the background color, we need to update
 308               ;; the background-mode parameter, and maybe some faces,
 309               ;; too.
 310               (when (assq 'background-color newparms)
 311                 (unless (or (assq 'background-mode initial-frame-alist)
 312                             (assq 'background-mode default-frame-alist))
 313                   (frame-set-background-mode frame))
 314                 (face-set-after-frame-default frame))))))
 315
 316     ;; If the initial frame is still around, apply initial-frame-alist
 317     ;; and default-frame-alist to it.
 318     (when (frame-live-p frame-initial-frame)
 319
 320       ;; When tool-bar has been switched off, correct the frame size
 321       ;; by the lines added in x-create-frame for the tool-bar and
 322       ;; switch `tool-bar-mode' off.
 323       (when (display-graphic-p)
 324         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 325                                   (assq 'tool-bar-lines default-frame-alist))))
 326           (when (and tool-bar-originally-present
 327                      (or (null tool-bar-lines)
 328                          (null (cdr tool-bar-lines))
 329                          (eq 0 (cdr tool-bar-lines))))
 330             (let* ((char-height (frame-char-height frame-initial-frame))
 331                    (image-height tool-bar-images-pixel-height)
 332                    (margin (cond ((and (consp tool-bar-button-margin)
 333                                        (integerp (cdr tool-bar-button-margin))
 334                                        (> tool-bar-button-margin 0))
 335                                   (cdr tool-bar-button-margin))
 336                                  ((and (integerp tool-bar-button-margin)
 337                                        (> tool-bar-button-margin 0))
 338                                   tool-bar-button-margin)
 339                                  (t 0)))
 340                    (relief (if (and (integerp tool-bar-button-relief)
 341                                     (> tool-bar-button-relief 0))
 342                                tool-bar-button-relief 3))
 343                    (lines (/ (+ image-height
 344                                 (* 2 margin)
 345                                 (* 2 relief)
 346                                 (1- char-height))
 347                              char-height))
 348                    (height (frame-parameter frame-initial-frame 'height))
 349                    (newparms (list (cons 'height (- height lines))))
 350                    (initial-top (cdr (assq 'top
 351                                            frame-initial-geometry-arguments)))
 352                    (top (frame-parameter frame-initial-frame 'top)))
 353               (when (and (consp initial-top) (eq '- (car initial-top)))
 354                 (let ((adjusted-top
 355                        (cond ((and (consp top)
 356                                    (eq '+ (car top)))
 357                               (list '+
 358                                     (+ (cadr top)
 359                                        (* lines char-height))))
 360                              ((and (consp top)
 361                                    (eq '- (car top)))
 362                               (list '-
 363                                     (- (cadr top)
 364                                        (* lines char-height))))
 365                              (t (+ top (* lines char-height))))))
 366                   (setq newparms
 367                         (append newparms
 368                                 `((top . ,adjusted-top))
 369                                 nil))))
 370               (modify-frame-parameters frame-initial-frame newparms)
 371               (tool-bar-mode -1)))))
 372
 373       ;; The initial frame we create above always has a minibuffer.
 374       ;; If the user wants to remove it, or make it a minibuffer-only
 375       ;; frame, then we'll have to delete the current frame and make a
 376       ;; new one; you can't remove or add a root window to/from an
 377       ;; existing frame.
 378       ;;
 379       ;; NOTE: default-frame-alist was nil when we created the
 380       ;; existing frame.  We need to explicitly include
 381       ;; default-frame-alist in the parameters of the screen we
 382       ;; create here, so that its new value, gleaned from the user's
 383       ;; .emacs file, will be applied to the existing screen.
 384       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 385                             (assq 'minibuffer default-frame-alist)
 386                             '(minibuffer . t)))
 387                    t))
 388           ;; Create the new frame.
 389           (let (parms new)
 390             ;; If the frame isn't visible yet, wait till it is.
 391             ;; If the user has to position the window,
 392             ;; Emacs doesn't know its real position until
 393             ;; the frame is seen to be visible.
 394             (while (not (cdr (assq 'visibility
 395                                    (frame-parameters frame-initial-frame))))
 396               (sleep-for 1))
 397             (setq parms (frame-parameters frame-initial-frame))
 398
 399             ;; Get rid of `name' unless it was specified explicitly before.
 400             (or (assq 'name frame-initial-frame-alist)
 401                 (setq parms (delq (assq 'name parms) parms)))
 402
 403             (setq parms (append initial-frame-alist
 404                                 default-frame-alist
 405                                 parms
 406                                 nil))
 407
 408             ;; Get rid of `reverse', because that was handled
 409             ;; when we first made the frame.
 410             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 411
 412             (if (assq 'height frame-initial-geometry-arguments)
 413                 (setq parms (assq-delete-all 'height parms)))
 414             (if (assq 'width frame-initial-geometry-arguments)
 415                 (setq parms (assq-delete-all 'width parms)))
 416             (if (assq 'left frame-initial-geometry-arguments)
 417                 (setq parms (assq-delete-all 'left parms)))
 418             (if (assq 'top frame-initial-geometry-arguments)
 419                 (setq parms (assq-delete-all 'top parms)))
 420             (setq new
 421                   (make-frame
 422                    ;; Use the geometry args that created the existing
 423                    ;; frame, rather than the parms we get for it.
 424                    (append frame-initial-geometry-arguments
 425                            '((user-size . t) (user-position . t))
 426                            parms)))
 427             ;; The initial frame, which we are about to delete, may be
 428             ;; the only frame with a minibuffer.  If it is, create a
 429             ;; new one.
 430             (or (delq frame-initial-frame (minibuffer-frame-list))
 431                 (make-initial-minibuffer-frame nil))
 432
 433             ;; If the initial frame is serving as a surrogate
 434             ;; minibuffer frame for any frames, we need to wean them
 435             ;; onto a new frame.  The default-minibuffer-frame
 436             ;; variable must be handled similarly.
 437             (let ((users-of-initial
 438                    (filtered-frame-list
 439                     (function (lambda (frame)
 440                                 (and (not (eq frame frame-initial-frame))
 441                                      (eq (window-frame
 442                                           (minibuffer-window frame))
 443                                          frame-initial-frame)))))))
 444               (if (or users-of-initial
 445                       (eq default-minibuffer-frame frame-initial-frame))
 446
 447                   ;; Choose an appropriate frame.  Prefer frames which
 448                   ;; are only minibuffers.
 449                   (let* ((new-surrogate
 450                           (car
 451                            (or (filtered-frame-list
 452                                 (function
 453                                  (lambda (frame)
 454                                    (eq (cdr (assq 'minibuffer
 455                                                   (frame-parameters frame)))
 456                                        'only))))
 457                                (minibuffer-frame-list))))
 458                          (new-minibuffer (minibuffer-window new-surrogate)))
 459
 460                     (if (eq default-minibuffer-frame frame-initial-frame)
 461                         (setq default-minibuffer-frame new-surrogate))
 462
 463                     ;; Wean the frames using frame-initial-frame as
 464                     ;; their minibuffer frame.
 465                     (mapcar
 466                      (function
 467                       (lambda (frame)
 468                         (modify-frame-parameters
 469                          frame (list (cons 'minibuffer new-minibuffer)))))
 470                      users-of-initial))))
 471
 472            ;; Redirect events enqueued at this frame to the new frame.
 473             ;; Is this a good idea?
 474             (redirect-frame-focus frame-initial-frame new)
 475
 476             ;; Finally, get rid of the old frame.
 477             (delete-frame frame-initial-frame t))
 478
 479         ;; Otherwise, we don't need all that rigamarole; just apply
 480         ;; the new parameters.
 481         (let (newparms allparms tail)
 482           (setq allparms (append initial-frame-alist
 483                                  default-frame-alist nil))
 484           (if (assq 'height frame-initial-geometry-arguments)
 485               (setq allparms (assq-delete-all 'height allparms)))
 486           (if (assq 'width frame-initial-geometry-arguments)
 487               (setq allparms (assq-delete-all 'width allparms)))
 488           (if (assq 'left frame-initial-geometry-arguments)
 489               (setq allparms (assq-delete-all 'left allparms)))
 490           (if (assq 'top frame-initial-geometry-arguments)
 491               (setq allparms (assq-delete-all 'top allparms)))
 492           (setq tail allparms)
 493           ;; Find just the parms that have changed since we first
 494           ;; made this frame.  Those are the ones actually set by
 495           ;; the init file.  For those parms whose values we already knew
 496           ;; (such as those spec'd by command line options)
 497           ;; it is undesirable to specify the parm again
 498           ;; once the user has seen the frame and been able to alter it
 499           ;; manually.
 500           (while tail
 501             (let (newval oldval)
 502               (setq oldval (assq (car (car tail))
 503                                  frame-initial-frame-alist))
 504               (setq newval (cdr (assq (car (car tail)) allparms)))
 505               (or (and oldval (eq (cdr oldval) newval))
 506                   (setq newparms
 507                         (cons (cons (car (car tail)) newval) newparms))))
 508             (setq tail (cdr tail)))
 509           (setq newparms (nreverse newparms))
 510           (modify-frame-parameters frame-initial-frame
 511                                    newparms)
 512           ;; If we changed the background color,
 513           ;; we need to update the background-mode parameter
 514           ;; and maybe some faces too.
 515           (when (assq 'background-color newparms)
 516             (unless (assq 'background-mode newparms)
 517               (frame-set-background-mode frame-initial-frame))
 518             (face-set-after-frame-default frame-initial-frame)))))
 519
 520     ;; Restore the original buffer.
 521     (set-buffer old-buffer)
 522
 523     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 524     ;; Make sure frame-notice-user-settings does nothing if called twice.
 525     (setq frame-notice-user-settings nil)
 526     (setq frame-initial-frame nil)))
 527
 528 (defun make-initial-minibuffer-frame (display)
 529   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 530     (if display
 531         (make-frame-on-display display parms)
 532       (make-frame parms))))
 533
 534 ;;;; Creation of additional frames, and other frame miscellanea
 535
 536 (defun modify-all-frames-parameters (alist)
 537   "Modify all current and future frames' parameters according to ALIST.
 538 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 539 See help of `modify-frame-parameters' for more information."
 540   (let (element)                        ;; temp
 541     (dolist (frame (frame-list))
 542       (modify-frame-parameters frame alist))
 543
 544     (dolist (pair alist)                ;; conses to add/replace
 545       ;; initial-frame-alist needs setting only when
 546       ;; frame-notice-user-settings is true
 547       (and frame-notice-user-settings
 548            (setq element (assoc (car pair) initial-frame-alist))
 549            (setq initial-frame-alist (delq element initial-frame-alist)))
 550       (and (setq element (assoc (car pair) default-frame-alist))
 551            (setq default-frame-alist (delq element default-frame-alist)))))
 552   (and frame-notice-user-settings
 553        (setq initial-frame-alist (append initial-frame-alist alist)))
 554   (setq default-frame-alist (append default-frame-alist alist)))
 555
 556 (defun get-other-frame ()
 557   "Return some frame other than the current frame.
 558 Create one if necessary.  Note that the minibuffer frame, if separate,
 559 is not considered (see `next-frame')."
 560   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 561                (make-frame)
 562              (next-frame (selected-frame)))))
 563     s))
 564
 565 (defun next-multiframe-window ()
 566   "Select the next window, regardless of which frame it is on."
 567   (interactive)
 568   (select-window (next-window (selected-window)
 569                               (> (minibuffer-depth) 0)
 570                               0))
 571   (select-frame-set-input-focus (selected-frame)))
 572
 573 (defun previous-multiframe-window ()
 574   "Select the previous window, regardless of which frame it is on."
 575   (interactive)
 576   (select-window (previous-window (selected-window)
 577                                   (> (minibuffer-depth) 0)
 578                                   0))
 579   (select-frame-set-input-focus (selected-frame)))
 580
 581 (defun make-frame-on-display (display &optional parameters)
 582   "Make a frame on X display DISPLAY.
 583 The optional second argument PARAMETERS specifies additional frame parameters."
 584   (interactive "sMake frame on display: ")
 585   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 586       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 587   (when (and (boundp 'x-initialized) (not x-initialized))
 588     (setq x-display-name display)
 589     (x-initialize-window-system))
 590   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 591
 592 (defun make-frame-on-tty (device type &optional parameters)
 593   "Make a frame on terminal DEVICE which is of type TYPE (e.g., \"xterm\").
 594 The optional third argument PARAMETERS specifies additional frame parameters."
 595   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 596   (unless device
 597     (error "Invalid terminal device"))
 598   (unless type
 599     (error "Invalid terminal type"))
 600   (make-frame `((window-system . nil) (tty . ,device) (tty-type . ,type) . ,parameters)))
 601
 602 (defun make-frame-command ()
 603   "Make a new frame, and select it if the terminal displays only one frame."
 604   (interactive)
 605   (if (and window-system (not (eq window-system 'pc)))
 606       (make-frame)
 607     (select-frame (make-frame))))
 608
 609 (defvar before-make-frame-hook nil
 610   "Functions to run before a frame is created.")
 611
 612 (defvar after-make-frame-functions nil
 613   "Functions to run after a frame is created.
 614 The functions are run with one arg, the newly created frame.")
 615
 616 (defvar after-setting-font-hook nil
 617   "Functions to run after a frame's font has been changed.")
 618
 619 ;; Alias, kept temporarily.
 620 (defalias 'new-frame 'make-frame)
 621 (make-obsolete 'new-frame 'make-frame "22.1")
 622
 623 (defun make-frame (&optional parameters)
 624   "Return a newly created frame displaying the current buffer.
 625 Optional argument PARAMETERS is an alist of parameters for the new frame.
 626 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 627
 628  (name . STRING)        The frame should be named STRING.
 629
 630  (width . NUMBER)       The frame should be NUMBER characters in width.
 631  (height . NUMBER)      The frame should be NUMBER text lines high.
 632
 633 You cannot specify either `width' or `height', you must use neither or both.
 634
 635  (minibuffer . t)       The frame should have a minibuffer.
 636  (minibuffer . nil)     The frame should have no minibuffer.
 637  (minibuffer . only)    The frame should contain only a minibuffer.
 638  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 639
 640  (window-system . nil)  The frame should be displayed on a terminal device.
 641  (window-system . x)    The frame should be displayed in an X window.
 642
 643  (display-id . ID)      The frame should use the display identified by ID.
 644
 645 Before the frame is created (via `frame-creation-function-alist'), functions on the
 646 hook `before-make-frame-hook' are run.  After the frame is created, functions
 647 on `after-make-frame-functions' are run with one arg, the newly created frame.
 648
 649 This function itself does not make the new frame the selected frame.
 650 The previously selected frame remains selected.  However, the
 651 window system may select the new frame for its own reasons, for
 652 instance if the frame appears under the mouse pointer and your
 653 setup is for focus to follow the pointer."
 654   (interactive)
 655   (let* ((w (cond
 656              ((assq 'display-id parameters)
 657               (let ((type (display-live-p (cdr (assq 'display-id parameters)))))
 658                 (cond
 659                  ((eq type t) nil)
 660                  ((eq type nil) (error "Display %s does not exist" (cdr (assq 'display-id parameters))))
 661                  (t type))))
 662              ((assq 'window-system parameters)
 663               (cdr (assq 'window-system parameters)))
 664              (t window-system)))
 665          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 666          frame)
 667     (unless frame-creation-function
 668       (error "Don't know how to create a frame on window system %s" w))
 669     (run-hooks 'before-make-frame-hook)
 670     (setq frame (funcall frame-creation-function parameters))
 671     (modify-frame-parameters frame
 672                              (cdr (assq w window-system-default-frame-alist)))
 673     (run-hook-with-args 'after-make-frame-functions frame)
 674     frame))
 675
 676 (defun filtered-frame-list (predicate)
 677   "Return a list of all live frames which satisfy PREDICATE."
 678   (let* ((frames (frame-list))
 679          (list frames))
 680     (while (consp frames)
 681       (unless (funcall predicate (car frames))
 682         (setcar frames nil))
 683       (setq frames (cdr frames)))
 684     (delq nil list)))
 685
 686 (defun minibuffer-frame-list ()
 687   "Return a list of all frames with their own minibuffers."
 688   (filtered-frame-list
 689    (function (lambda (frame)
 690                (eq frame (window-frame (minibuffer-window frame)))))))
 691
 692 (defun frames-on-display-list (&optional display)
 693   "Return a list of all frames on DISPLAY.
 694
 695 DISPLAY should be a display identifier (an integer), but it may
 696 also be a name of a display, a string of the form HOST:SERVER.SCREEN.
 697
 698 If DISPLAY is omitted or nil, it defaults to the selected frame's display."
 699   (let* ((display (or display (frame-display)))
 700          (func #'(lambda (frame)
 701                    (or (eq (frame-display frame) display)
 702                        (equal (frame-parameter frame 'display) display)))))
 703     (filtered-frame-list func)))
 704
 705 (defun framep-on-display (&optional display)
 706   "Return the type of frames on DISPLAY.
 707 DISPLAY may be a display id, a display name or a frame.  If it is
 708 a frame, its type is returned.
 709 If DISPLAY is omitted or nil, it defaults to the selected frame's display.
 710 All frames on a given display are of the same type."
 711   (or (display-live-p display)
 712       (framep display)
 713       (framep (car (frames-on-display-list display)))))
 714
 715 (defun frame-remove-geometry-params (param-list)
 716   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 717 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 718 `height', `user-size' and `user-position' parameters.
 719 Emacs uses this to avoid overriding explicit moves and resizings from
 720 the user during startup."
 721   (setq param-list (cons nil param-list))
 722   (let ((tail param-list))
 723     (while (consp (cdr tail))
 724       (if (and (consp (car (cdr tail)))
 725                (memq (car (car (cdr tail)))
 726                      '(height width top left user-position user-size)))
 727           (progn
 728             (setq frame-initial-geometry-arguments
 729                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 730             (setcdr tail (cdr (cdr tail))))
 731         (setq tail (cdr tail)))))
 732   (setq frame-initial-geometry-arguments
 733         (nreverse frame-initial-geometry-arguments))
 734   (cdr param-list))
 735
 736 (defcustom focus-follows-mouse t
 737   "*Non-nil if window system changes focus when you move the mouse.
 738 You should set this variable to tell Emacs how your window manager
 739 handles focus, since there is no way in general for Emacs to find out
 740 automatically."
 741   :type 'boolean
 742   :group 'frames
 743   :version "20.3")
 744
 745 (defun select-frame-set-input-focus (frame)
 746   "Select FRAME, raise it, and set input focus, if possible."
 747     (select-frame frame)
 748     (raise-frame frame)
 749     ;; Ensure, if possible, that frame gets input focus.
 750     (cond ((eq (window-system frame) 'x)
 751            (x-focus-frame frame))
 752           ((eq (window-system frame) 'w32)
 753            (w32-focus-frame frame)))
 754     (cond (focus-follows-mouse
 755            (set-mouse-position (selected-frame) (1- (frame-width)) 0))))
 756
 757 (defun other-frame (arg)
 758   "Select the ARG'th different visible frame on current display, and raise it.
 759 All frames are arranged in a cyclic order.
 760 This command selects the frame ARG steps away in that order.
 761 A negative ARG moves in the opposite order.
 762
 763 To make this command work properly, you must tell Emacs
 764 how the system (or the window manager) generally handles
 765 focus-switching between windows.  If moving the mouse onto a window
 766 selects it (gives it focus), set `focus-follows-mouse' to t.
 767 Otherwise, that variable should be nil."
 768   (interactive "p")
 769   (let ((frame (selected-frame)))
 770     (while (> arg 0)
 771       (setq frame (next-frame frame))
 772       (while (not (eq (frame-visible-p frame) t))
 773         (setq frame (next-frame frame)))
 774       (setq arg (1- arg)))
 775     (while (< arg 0)
 776       (setq frame (previous-frame frame))
 777       (while (not (eq (frame-visible-p frame) t))
 778         (setq frame (previous-frame frame)))
 779       (setq arg (1+ arg)))
 780     (select-frame-set-input-focus frame)))
 781
 782 (defun iconify-or-deiconify-frame ()
 783   "Iconify the selected frame, or deiconify if it's currently an icon."
 784   (interactive)
 785   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 786       (iconify-frame)
 787     (make-frame-visible)))
 788
 789 (defun suspend-frame ()
 790   "Do whatever is right to suspend the current frame.
 791 Calls `suspend-emacs' if invoked from the controlling terminal,
 792 `suspend-tty' from a secondary terminal, and
 793 `iconify-or-deiconify-frame' from an X frame."
 794   (interactive)
 795   (let ((type (framep (selected-frame))))
 796     (cond
 797      ((eq type 'x) (iconify-or-deiconify-frame))
 798      ((eq type t)
 799       (if (display-controlling-tty-p)
 800           (suspend-emacs)
 801         (suspend-tty)))
 802      (t (suspend-emacs)))))
 803
 804
 805 (defun make-frame-names-alist ()
 806   (let* ((current-frame (selected-frame))
 807          (falist
 808           (cons
 809            (cons (frame-parameter current-frame 'name) current-frame) nil))
 810          (frame (next-frame nil t)))
 811     (while (not (eq frame current-frame))
 812       (progn
 813         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 814         (setq frame (next-frame frame t))))
 815     falist))
 816
 817 (defvar frame-name-history nil)
 818 (defun select-frame-by-name (name)
 819   "Select the frame on the current terminal whose name is NAME and raise it.
 820 If there is no frame by that name, signal an error."
 821   (interactive
 822    (let* ((frame-names-alist (make-frame-names-alist))
 823            (default (car (car frame-names-alist)))
 824            (input (completing-read
 825                    (format "Select Frame (default %s): " default)
 826                    frame-names-alist nil t nil 'frame-name-history)))
 827      (if (= (length input) 0)
 828          (list default)
 829        (list input))))
 830   (let* ((frame-names-alist (make-frame-names-alist))
 831          (frame (cdr (assoc name frame-names-alist))))
 832     (or frame
 833         (error "There is no frame named `%s'" name))
 834     (make-frame-visible frame)
 835     (raise-frame frame)
 836     (select-frame frame)
 837     ;; Ensure, if possible, that frame gets input focus.
 838     (cond ((eq (window-system frame) 'x)
 839            (x-focus-frame frame))
 840           ((eq (window-system frame) 'w32)
 841            (w32-focus-frame frame)))
 842     (when focus-follows-mouse
 843       (set-mouse-position frame (1- (frame-width frame)) 0))))
 844 \f
 845 ;;;; Frame configurations
 846
 847 (defun current-frame-configuration ()
 848   "Return a list describing the positions and states of all frames.
 849 Its car is `frame-configuration'.
 850 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 851 where
 852   FRAME is a frame object,
 853   ALIST is an association list specifying some of FRAME's parameters, and
 854   WINDOW-CONFIG is a window configuration object for FRAME."
 855   (cons 'frame-configuration
 856         (mapcar (function
 857                  (lambda (frame)
 858                    (list frame
 859                          (frame-parameters frame)
 860                          (current-window-configuration frame))))
 861                 (frame-list))))
 862
 863 (defun set-frame-configuration (configuration &optional nodelete)
 864   "Restore the frames to the state described by CONFIGURATION.
 865 Each frame listed in CONFIGURATION has its position, size, window
 866 configuration, and other parameters set as specified in CONFIGURATION.
 867 However, this function does not restore deleted frames.
 868
 869 Ordinarily, this function deletes all existing frames not
 870 listed in CONFIGURATION.  But if optional second argument NODELETE
 871 is given and non-nil, the unwanted frames are iconified instead."
 872   (or (frame-configuration-p configuration)
 873       (signal 'wrong-type-argument
 874               (list 'frame-configuration-p configuration)))
 875   (let ((config-alist (cdr configuration))
 876         frames-to-delete)
 877     (mapcar (function
 878              (lambda (frame)
 879                (let ((parameters (assq frame config-alist)))
 880                  (if parameters
 881                      (progn
 882                        (modify-frame-parameters
 883                         frame
 884                         ;; Since we can't set a frame's minibuffer status,
 885                         ;; we might as well omit the parameter altogether.
 886                         (let* ((parms (nth 1 parameters))
 887                                (mini (assq 'minibuffer parms)))
 888                           (if mini (setq parms (delq mini parms)))
 889                           parms))
 890                        (set-window-configuration (nth 2 parameters)))
 891                    (setq frames-to-delete (cons frame frames-to-delete))))))
 892             (frame-list))
 893     (if nodelete
 894         ;; Note: making frames invisible here was tried
 895         ;; but led to some strange behavior--each time the frame
 896         ;; was made visible again, the window manager asked afresh
 897         ;; for where to put it.
 898         (mapcar 'iconify-frame frames-to-delete)
 899       (mapcar 'delete-frame frames-to-delete))))
 900 \f
 901 ;;;; Convenience functions for accessing and interactively changing
 902 ;;;; frame parameters.
 903
 904 (defun frame-height (&optional frame)
 905   "Return number of lines available for display on FRAME.
 906 If FRAME is omitted, describe the currently selected frame."
 907   (cdr (assq 'height (frame-parameters frame))))
 908
 909 (defun frame-width (&optional frame)
 910   "Return number of columns available for display on FRAME.
 911 If FRAME is omitted, describe the currently selected frame."
 912   (cdr (assq 'width (frame-parameters frame))))
 913
 914 (defalias 'set-default-font 'set-frame-font)
 915 (defun set-frame-font (font-name &optional keep-size)
 916   "Set the font of the selected frame to FONT-NAME.
 917 When called interactively, prompt for the name of the font to use.
 918 To get the frame's current default font, use `frame-parameters'.
 919
 920 The default behavior is to keep the numbers of lines and columns in
 921 the frame, thus may change its pixel size. If optional KEEP-SIZE is
 922 non-nil (interactively, prefix argument) the current frame size (in
 923 pixels) is kept by adjusting the numbers of the lines and columns."
 924   (interactive
 925    (let* ((completion-ignore-case t)
 926           (font (completing-read "Font name: "
 927                          (mapcar #'list
 928                                  ;; x-list-fonts will fail with an error
 929                                  ;; if this frame doesn't support fonts.
 930                                  (x-list-fonts "*" nil (selected-frame)))
 931                          nil nil nil nil
 932                          (frame-parameter nil 'font))))
 933      (list font current-prefix-arg)))
 934   (let (fht fwd)
 935     (if keep-size
 936         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
 937               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
 938     (modify-frame-parameters (selected-frame)
 939                              (list (cons 'font font-name)))
 940     (if keep-size
 941         (modify-frame-parameters
 942          (selected-frame)
 943          (list (cons 'height (round fht (frame-char-height)))
 944                (cons 'width (round fwd (frame-char-width)))))))
 945   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
 946
 947 (defun set-frame-parameter (frame parameter value)
 948   (modify-frame-parameters frame (list (cons parameter value))))
 949
 950 (defun set-background-color (color-name)
 951   "Set the background color of the selected frame to COLOR-NAME.
 952 When called interactively, prompt for the name of the color to use.
 953 To get the frame's current background color, use `frame-parameters'."
 954   (interactive (list (facemenu-read-color)))
 955   (modify-frame-parameters (selected-frame)
 956                            (list (cons 'background-color color-name)))
 957   (or window-system
 958       (face-set-after-frame-default (selected-frame))))
 959
 960 (defun set-foreground-color (color-name)
 961   "Set the foreground color of the selected frame to COLOR-NAME.
 962 When called interactively, prompt for the name of the color to use.
 963 To get the frame's current foreground color, use `frame-parameters'."
 964   (interactive (list (facemenu-read-color)))
 965   (modify-frame-parameters (selected-frame)
 966                            (list (cons 'foreground-color color-name)))
 967   (or window-system
 968       (face-set-after-frame-default (selected-frame))))
 969
 970 (defun set-cursor-color (color-name)
 971   "Set the text cursor color of the selected frame to COLOR-NAME.
 972 When called interactively, prompt for the name of the color to use.
 973 To get the frame's current cursor color, use `frame-parameters'."
 974   (interactive (list (facemenu-read-color)))
 975   (modify-frame-parameters (selected-frame)
 976                            (list (cons 'cursor-color color-name))))
 977
 978 (defun set-mouse-color (color-name)
 979   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
 980 When called interactively, prompt for the name of the color to use.
 981 To get the frame's current mouse color, use `frame-parameters'."
 982   (interactive (list (facemenu-read-color)))
 983   (modify-frame-parameters (selected-frame)
 984                            (list (cons 'mouse-color
 985                                        (or color-name
 986                                            (cdr (assq 'mouse-color
 987                                                       (frame-parameters))))))))
 988
 989 (defun set-border-color (color-name)
 990   "Set the color of the border of the selected frame to COLOR-NAME.
 991 When called interactively, prompt for the name of the color to use.
 992 To get the frame's current border color, use `frame-parameters'."
 993   (interactive (list (facemenu-read-color)))
 994   (modify-frame-parameters (selected-frame)
 995                            (list (cons 'border-color color-name))))
 996
 997 (defun auto-raise-mode (arg)
 998   "Toggle whether or not the selected frame should auto-raise.
 999 With arg, turn auto-raise mode on if and only if arg is positive.
1000 Note that this controls Emacs's own auto-raise feature.
1001 Some window managers allow you to enable auto-raise for certain windows.
1002 You can use that for Emacs windows if you wish, but if you do,
1003 that is beyond the control of Emacs and this command has no effect on it."
1004   (interactive "P")
1005   (if (null arg)
1006       (setq arg
1007             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1008                 -1 1)))
1009   (if (> arg 0)
1010       (raise-frame (selected-frame)))
1011   (modify-frame-parameters (selected-frame)
1012                            (list (cons 'auto-raise (> arg 0)))))
1013
1014 (defun auto-lower-mode (arg)
1015   "Toggle whether or not the selected frame should auto-lower.
1016 With arg, turn auto-lower mode on if and only if arg is positive.
1017 Note that this controls Emacs's own auto-lower feature.
1018 Some window managers allow you to enable auto-lower for certain windows.
1019 You can use that for Emacs windows if you wish, but if you do,
1020 that is beyond the control of Emacs and this command has no effect on it."
1021   (interactive "P")
1022   (if (null arg)
1023       (setq arg
1024             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1025                 -1 1)))
1026   (modify-frame-parameters (selected-frame)
1027                            (list (cons 'auto-lower (> arg 0)))))
1028 (defun set-frame-name (name)
1029   "Set the name of the selected frame to NAME.
1030 When called interactively, prompt for the name of the frame.
1031 The frame name is displayed on the modeline if the terminal displays only
1032 one frame, otherwise the name is displayed on the frame's caption bar."
1033   (interactive "sFrame name: ")
1034   (modify-frame-parameters (selected-frame)
1035                            (list (cons 'name name))))
1036
1037 (defun frame-current-scroll-bars (&optional frame)
1038   "Return the current scroll-bar settings in frame FRAME.
1039 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1040 current location of the vertical scroll-bars (left, right, or nil),
1041 and HORIZONTAL specifies the current location of the horizontal scroll
1042 bars (top, bottom, or nil)."
1043   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1044         (hor nil))
1045     (unless (memq vert '(left right nil))
1046       (setq vert default-frame-scroll-bars))
1047     (cons vert hor)))
1048 \f
1049 ;;;; Frame/display capabilities.
1050 (defun selected-display ()
1051   "Return the display that is now selected."
1052   (frame-display (selected-frame)))
1053
1054 (defun display-mouse-p (&optional display)
1055   "Return non-nil if DISPLAY has a mouse available.
1056 DISPLAY can be a display name, a frame, or nil (meaning the selected
1057 frame's display)."
1058   (let ((frame-type (framep-on-display display)))
1059     (cond
1060      ((eq frame-type 'pc)
1061       (msdos-mouse-p))
1062      ((eq system-type 'windows-nt)
1063       (with-no-warnings
1064        (> w32-num-mouse-buttons 0)))
1065      ((memq frame-type '(x mac))
1066       t)    ;; We assume X and Mac *always* have a pointing device
1067      (t
1068       (or (and (featurep 'xt-mouse)
1069                xterm-mouse-mode)
1070           ;; t-mouse is distributed with the GPM package.  It doesn't have
1071           ;; a toggle.
1072           (featurep 't-mouse))))))
1073
1074 (defun display-popup-menus-p (&optional display)
1075   "Return non-nil if popup menus are supported on DISPLAY.
1076 DISPLAY can be a display name, a frame, or nil (meaning the selected
1077 frame's display).
1078 Support for popup menus requires that the mouse be available."
1079   (and
1080    (let ((frame-type (framep-on-display display)))
1081      (memq frame-type '(x w32 pc mac)))
1082    (display-mouse-p display)))
1083
1084 (defun display-graphic-p (&optional display)
1085   "Return non-nil if DISPLAY is a graphic display.
1086 Graphical displays are those which are capable of displaying several
1087 frames and several different fonts at once.  This is true for displays
1088 that use a window system such as X, and false for text-only terminals.
1089 DISPLAY can be a display name, a frame, or nil (meaning the selected
1090 frame's display)."
1091   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1092
1093 (defun display-images-p (&optional display)
1094   "Return non-nil if DISPLAY can display images.
1095
1096 DISPLAY can be a display name, a frame, or nil (meaning the selected
1097 frame's display)."
1098   (and (display-graphic-p display)
1099        (fboundp 'image-mask-p)
1100        (fboundp 'image-size)))
1101
1102 (defalias 'display-multi-frame-p 'display-graphic-p)
1103 (defalias 'display-multi-font-p 'display-graphic-p)
1104
1105 (defun display-selections-p (&optional display)
1106   "Return non-nil if DISPLAY supports selections.
1107 A selection is a way to transfer text or other data between programs
1108 via special system buffers called `selection' or `cut buffer' or
1109 `clipboard'.
1110 DISPLAY can be a display name, a frame, or nil (meaning the selected
1111 frame's display)."
1112   (let ((frame-type (framep-on-display display)))
1113     (cond
1114      ((eq frame-type 'pc)
1115       ;; MS-DOG frames support selections when Emacs runs inside
1116       ;; the Windows' DOS Box.
1117       (with-no-warnings
1118        (not (null dos-windows-version))))
1119      ((memq frame-type '(x w32 mac))
1120       t)    ;; FIXME?
1121      (t
1122       nil))))
1123
1124 (defun display-screens (&optional display)
1125   "Return the number of screens associated with DISPLAY."
1126   (let ((frame-type (framep-on-display display)))
1127     (cond
1128      ((memq frame-type '(x w32))
1129       (x-display-screens display))
1130      (t ;; FIXME: is this correct for the Mac?
1131       1))))
1132
1133 (defun display-pixel-height (&optional display)
1134   "Return the height of DISPLAY's screen in pixels.
1135 For character terminals, each character counts as a single pixel."
1136   (let ((frame-type (framep-on-display display)))
1137     (cond
1138      ((memq frame-type '(x w32 mac))
1139       (x-display-pixel-height display))
1140      (t
1141       (frame-height (if (framep display) display (selected-frame)))))))
1142
1143 (defun display-pixel-width (&optional display)
1144   "Return the width of DISPLAY's screen in pixels.
1145 For character terminals, each character counts as a single pixel."
1146   (let ((frame-type (framep-on-display display)))
1147     (cond
1148      ((memq frame-type '(x w32 mac))
1149       (x-display-pixel-width display))
1150      (t
1151       (frame-width (if (framep display) display (selected-frame)))))))
1152
1153 (defun display-mm-height (&optional display)
1154   "Return the height of DISPLAY's screen in millimeters.
1155 If the information is unavailable, value is nil."
1156   (and (memq (framep-on-display display) '(x w32 mac))
1157        (x-display-mm-height display)))
1158
1159 (defun display-mm-width (&optional display)
1160   "Return the width of DISPLAY's screen in millimeters.
1161 If the information is unavailable, value is nil."
1162   (and (memq (framep-on-display display) '(x w32 mac))
1163        (x-display-mm-width display)))
1164
1165 (defun display-backing-store (&optional display)
1166   "Return the backing store capability of DISPLAY's screen.
1167 The value may be `always', `when-mapped', `not-useful', or nil if
1168 the question is inapplicable to a certain kind of display."
1169   (let ((frame-type (framep-on-display display)))
1170     (cond
1171      ((memq frame-type '(x w32 mac))
1172       (x-display-backing-store display))
1173      (t
1174       'not-useful))))
1175
1176 (defun display-save-under (&optional display)
1177   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1178   (let ((frame-type (framep-on-display display)))
1179     (cond
1180      ((memq frame-type '(x w32 mac))
1181       (x-display-save-under display))
1182      (t
1183       'not-useful))))
1184
1185 (defun display-planes (&optional display)
1186   "Return the number of planes supported by DISPLAY."
1187   (let ((frame-type (framep-on-display display)))
1188     (cond
1189      ((memq frame-type '(x w32 mac))
1190       (x-display-planes display))
1191      ((eq frame-type 'pc)
1192       4)
1193      (t
1194       (truncate (log (length (tty-color-alist)) 2))))))
1195
1196 (defun display-color-cells (&optional display)
1197   "Return the number of color cells supported by DISPLAY."
1198   (let ((frame-type (framep-on-display display)))
1199     (cond
1200      ((memq frame-type '(x w32 mac))
1201       (x-display-color-cells display))
1202      ((eq frame-type 'pc)
1203       16)
1204      (t
1205       (tty-display-color-cells display)))))
1206
1207 (defun display-visual-class (&optional display)
1208   "Returns the visual class of DISPLAY.
1209 The value is one of the symbols `static-gray', `gray-scale',
1210 `static-color', `pseudo-color', `true-color', or `direct-color'."
1211   (let ((frame-type (framep-on-display display)))
1212     (cond
1213      ((memq frame-type '(x w32 mac))
1214       (x-display-visual-class display))
1215      ((and (memq frame-type '(pc t))
1216            (tty-display-color-p display))
1217       'static-color)
1218      (t
1219       'static-gray))))
1220
1221 \f
1222 ;;;; Aliases for backward compatibility with Emacs 18.
1223 (defalias 'screen-height 'frame-height)
1224 (defalias 'screen-width 'frame-width)
1225
1226 (defun set-screen-width (cols &optional pretend)
1227   "Obsolete function to change the size of the screen to COLS columns.
1228 Optional second arg non-nil means that redisplay should use COLS columns
1229 but that the idea of the actual width of the frame should not be changed.
1230 This function is provided only for compatibility with Emacs 18; new code
1231 should use `set-frame-width instead'."
1232   (set-frame-width (selected-frame) cols pretend))
1233
1234 (defun set-screen-height (lines &optional pretend)
1235   "Obsolete function to change the height of the screen to LINES lines.
1236 Optional second arg non-nil means that redisplay should use LINES lines
1237 but that the idea of the actual height of the screen should not be changed.
1238 This function is provided only for compatibility with Emacs 18; new code
1239 should use `set-frame-height' instead."
1240   (set-frame-height (selected-frame) lines pretend))
1241
1242 (defun delete-other-frames (&optional frame)
1243   "Delete all frames except FRAME.
1244 If FRAME uses another frame's minibuffer, the minibuffer frame is
1245 left untouched.  FRAME nil or omitted means use the selected frame."
1246   (interactive)
1247   (unless frame
1248     (setq frame (selected-frame)))
1249   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1250          (frames (delq mini-frame (delq frame (frame-list)))))
1251     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1252     ;; signals an error when trying to delete a mini-frame that's
1253     ;; still in use by another frame.
1254     (dolist (frame frames)
1255       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1256         (delete-frame frame)))
1257     ;; Delete minibuffer-only frames.
1258     (dolist (frame frames)
1259       (when (eq (frame-parameter frame 'minibuffer) 'only)
1260         (delete-frame frame)))))
1261
1262 (make-obsolete 'screen-height 'frame-height) ;before 19.15
1263 (make-obsolete 'screen-width  'frame-width) ;before 19.15
1264 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1265 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1266
1267 ;; miscellaneous obsolescence declarations
1268 (defvaralias 'delete-frame-hook 'delete-frame-functions)
1269 (make-obsolete-variable 'delete-frame-hook 'delete-frame-functions "22.1")
1270
1271 \f
1272 ;; Highlighting trailing whitespace.
1273
1274 (make-variable-buffer-local 'show-trailing-whitespace)
1275
1276 (defcustom show-trailing-whitespace nil
1277   "*Non-nil means highlight trailing whitespace.
1278 This is done in the face `trailing-whitespace'."
1279   :tag "Highlight trailing whitespace."
1280   :type 'boolean
1281   :group 'whitespace-faces)
1282
1283
1284 \f
1285 ;; Scrolling
1286
1287 (defgroup scrolling nil
1288   "Scrolling windows."
1289   :version "21.1"
1290   :group 'frames)
1291
1292 (defcustom auto-hscroll-mode t
1293   "*Allow or disallow automatic scrolling windows horizontally.
1294 If non-nil, windows are automatically scrolled horizontally to make
1295 point visible."
1296   :version "21.1"
1297   :type 'boolean
1298   :group 'scrolling)
1299 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1300
1301 \f
1302 ;; Blinking cursor
1303
1304 (defgroup cursor nil
1305   "Displaying text cursors."
1306   :version "21.1"
1307   :group 'frames)
1308
1309 (defcustom blink-cursor-delay 0.5
1310   "*Seconds of idle time after which cursor starts to blink."
1311   :tag "Delay in seconds."
1312   :type 'number
1313   :group 'cursor)
1314
1315 (defcustom blink-cursor-interval 0.5
1316   "*Length of cursor blink interval in seconds."
1317   :tag "Blink interval in seconds."
1318   :type 'number
1319   :group 'cursor)
1320
1321 (defvar blink-cursor-idle-timer nil
1322   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1323 The function `blink-cursor-start' is called when the timer fires.")
1324
1325 (defvar blink-cursor-timer nil
1326   "Timer started from `blink-cursor-start'.
1327 This timer calls `blink-cursor-timer-function' every
1328 `blink-cursor-interval' seconds.")
1329
1330 ;; We do not know the standard _evaluated_ value yet, because the standard
1331 ;; expression uses values that are not yet set.  The correct evaluated
1332 ;; standard value will be installed in startup.el using exactly the same
1333 ;; expression as in the defcustom.
1334 (define-minor-mode blink-cursor-mode
1335   "Toggle blinking cursor mode.
1336 With a numeric argument, turn blinking cursor mode on iff ARG is positive.
1337 When blinking cursor mode is enabled, the cursor of the selected
1338 window blinks.
1339
1340 Note that this command is effective only when Emacs
1341 displays through a window system, because then Emacs does its own
1342 cursor display.  On a text-only terminal, this is not implemented."
1343   :init-value (not (or noninteractive
1344                        (if (boundp 'no-blinking-cursor) no-blinking-cursor)
1345                        (eq system-type 'ms-dos)
1346                        (not (memq initial-window-system '(x w32)))))
1347   :group 'cursor
1348   :global t
1349   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1350   (if blink-cursor-timer (cancel-timer blink-cursor-timer))
1351   (setq blink-cursor-idle-timer nil
1352         blink-cursor-timer nil)
1353   (if blink-cursor-mode
1354       (progn
1355         ;; Hide the cursor.
1356         ;;(internal-show-cursor nil nil)
1357         (setq blink-cursor-idle-timer
1358               (run-with-idle-timer blink-cursor-delay
1359                                    blink-cursor-delay
1360                                    'blink-cursor-start)))
1361     (internal-show-cursor nil t)))
1362
1363 (defvaralias 'blink-cursor 'blink-cursor-mode)
1364 (make-obsolete-variable 'blink-cursor 'blink-cursor-mode "22.1")
1365
1366 (defun blink-cursor-start ()
1367   "Timer function called from the timer `blink-cursor-idle-timer'.
1368 This starts the timer `blink-cursor-timer', which makes the cursor blink
1369 if appropriate.  It also arranges to cancel that timer when the next
1370 command starts, by installing a pre-command hook."
1371   (when (null blink-cursor-timer)
1372     (add-hook 'pre-command-hook 'blink-cursor-end)
1373     (internal-show-cursor nil nil)
1374     (setq blink-cursor-timer
1375           (run-with-timer blink-cursor-interval blink-cursor-interval
1376                           'blink-cursor-timer-function))))
1377
1378 (defun blink-cursor-timer-function ()
1379   "Timer function of timer `blink-cursor-timer'."
1380   (internal-show-cursor nil (not (internal-show-cursor-p))))
1381
1382 (defun blink-cursor-end ()
1383   "Stop cursor blinking.
1384 This is installed as a pre-command hook by `blink-cursor-start'.
1385 When run, it cancels the timer `blink-cursor-timer' and removes
1386 itself as a pre-command hook."
1387   (remove-hook 'pre-command-hook 'blink-cursor-end)
1388   (internal-show-cursor nil t)
1389   (cancel-timer blink-cursor-timer)
1390   (setq blink-cursor-timer nil))
1391
1392
1393 \f
1394 ;; Hourglass pointer
1395
1396 (defcustom display-hourglass t
1397   "*Non-nil means show an hourglass pointer when running under a window system."
1398   :tag "Hourglass pointer"
1399   :type 'boolean
1400   :group 'cursor)
1401
1402 (defcustom hourglass-delay 1
1403   "*Seconds to wait before displaying an hourglass pointer."
1404   :tag "Hourglass delay"
1405   :type 'number
1406   :group 'cursor)
1407
1408 \f
1409 (defcustom cursor-in-non-selected-windows t
1410   "*Non-nil means show a hollow box cursor in non-selected-windows.
1411 If nil, don't show a cursor except in the selected window.
1412 Use Custom to set this variable to get the display updated."
1413   :tag "Cursor in non-selected windows"
1414   :type 'boolean
1415   :group 'cursor
1416   :set #'(lambda (symbol value)
1417            (set-default symbol value)
1418            (force-mode-line-update t)))
1419
1420 \f
1421 ;;;; Key bindings
1422
1423 (define-key ctl-x-5-map "2" 'make-frame-command)
1424 (define-key ctl-x-5-map "1" 'delete-other-frames)
1425 (define-key ctl-x-5-map "0" 'delete-frame)
1426 (define-key ctl-x-5-map "o" 'other-frame)
1427
1428 (substitute-key-definition 'suspend-emacs 'suspend-frame global-map)
1429
1430
1431 (defun terminal-id (terminal)
1432   "Return the numerical id of terminal TERMINAL.
1433
1434 TERMINAL can be a terminal id, a frame, or nil (meaning the
1435 selected frame's terminal)."
1436   (cond
1437    ((integerp terminal)
1438     terminal)
1439    ((or (null terminal) (framep terminal))
1440     (frame-display terminal))
1441    (t
1442     (error "Invalid argument %s in `terminal-id'" terminal))))
1443
1444 (defvar terminal-parameter-alist nil
1445   "An alist of terminal parameter alists.")
1446
1447 (defun terminal-parameters (&optional terminal)
1448   "Return the paramater-alist of terminal TERMINAL.
1449 It is a list of elements of the form (PARM . VALUE), where PARM is a symbol.
1450
1451 TERMINAL can be a terminal id, a frame, or nil (meaning the
1452 selected frame's terminal)."
1453   (cdr (assq (terminal-id terminal) terminal-parameter-alist)))
1454
1455 (defun terminal-parameter (terminal parameter)
1456   "Return TERMINAL's value for parameter PARAMETER.
1457
1458 TERMINAL can be a terminal id, a frame, or nil (meaning the
1459 selected frame's terminal)."
1460   (cdr (assq parameter (cdr (assq (terminal-id terminal) terminal-parameter-alist)))))
1461
1462 (defun set-terminal-parameter (terminal parameter value)
1463   "Set TERMINAL's value for parameter PARAMETER to VALUE.
1464 Returns the previous value of PARAMETER.
1465
1466 TERMINAL can be a terminal id, a frame, or nil (meaning the
1467 selected frame's terminal)."
1468   (setq terminal (terminal-id terminal))
1469   (let* ((alist (assq terminal terminal-parameter-alist))
1470          (pair (assq parameter (cdr alist)))
1471          (result (cdr pair)))
1472     (cond
1473      (pair (setcdr pair value))
1474      (alist (setcdr alist (cons (cons parameter value) (cdr alist))))
1475      (t (setq terminal-parameter-alist
1476               (cons (cons terminal
1477                           (cons (cons parameter value)
1478                                 nil))
1479                     terminal-parameter-alist))))
1480     result))
1481
1482 (defun terminal-handle-delete-frame (frame)
1483   "Clean up terminal parameters of FRAME, if it's the last frame on its terminal."
1484   ;; XXX We assume that the display is closed immediately after the
1485   ;; last frame is deleted on it.  It would be better to create a hook
1486   ;; called `delete-display-functions', and use it instead.
1487   (when (and (frame-live-p frame)
1488              (= 1 (length (frames-on-display-list (frame-display frame)))))
1489     (setq terminal-parameter-alist
1490           (assq-delete-all (frame-display frame) terminal-parameter-alist))))
1491
1492 (add-hook 'delete-frame-functions 'terminal-handle-delete-frame)
1493
1494 (provide 'frame)
1495
1496 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1497 ;;; frame.el ends here