lisp/gnus/nnkiboze.el

   1 ;;; nnkiboze.el --- select virtual news access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The other access methods (nntp, nnspool, etc) are general news
  29 ;; access methods.  This module relies on Gnus and can't be used
  30 ;; separately.
  31
  32 ;;; Code:
  33
  34 (require 'nntp)
  35 (require 'nnheader)
  36 (require 'gnus)
  37 (require 'gnus-score)
  38 (require 'nnoo)
  39 (require 'mm-util)
  40 (eval-when-compile (require 'cl))
  41
  42 (nnoo-declare nnkiboze)
  43 (defvoo nnkiboze-directory (nnheader-concat gnus-directory "kiboze/")
  44   "nnkiboze will put its files in this directory.")
  45
  46 (defvoo nnkiboze-level 9
  47   "The maximum level to be searched for articles.")
  48
  49 (defvoo nnkiboze-remove-read-articles t
  50   "If non-nil, nnkiboze will remove read articles from the kiboze group.")
  51
  52 (defvoo nnkiboze-ephemeral nil
  53   "If non-nil, don't store any data anywhere.")
  54
  55 (defvoo nnkiboze-scores nil
  56   "Score rules for generating the nnkiboze group.")
  57
  58 (defvoo nnkiboze-regexp nil
  59   "Regexp for matching component groups.")
  60
  61 (defvoo nnkiboze-file-coding-system mm-text-coding-system
  62   "Coding system for nnkiboze files.")
  63
  64 \f
  65
  66 (defconst nnkiboze-version "nnkiboze 1.0")
  67
  68 (defvoo nnkiboze-current-group nil)
  69 (defvoo nnkiboze-status-string "")
  70
  71 (defvoo nnkiboze-headers nil)
  72
  73 \f
  74
  75 ;;; Interface functions.
  76
  77 (nnoo-define-basics nnkiboze)
  78
  79 (deffoo nnkiboze-retrieve-headers (articles &optional group server fetch-old)
  80   (nnkiboze-possibly-change-group group)
  81   (unless gnus-nov-is-evil
  82     (if (stringp (car articles))
  83         'headers
  84       (let ((nov (nnkiboze-nov-file-name)))
  85         (when (file-exists-p nov)
  86           (save-excursion
  87             (set-buffer nntp-server-buffer)
  88             (erase-buffer)
  89             (let ((nnheader-file-coding-system nnkiboze-file-coding-system))
  90               (nnheader-insert-file-contents nov))
  91             (nnheader-nov-delete-outside-range
  92              (car articles) (car (last articles)))
  93             'nov))))))
  94
  95 (deffoo nnkiboze-request-article (article &optional newsgroup server buffer)
  96   (nnkiboze-possibly-change-group newsgroup)
  97   (if (not (numberp article))
  98       ;; This is a real kludge.  It might not work at times, but it
  99       ;; does no harm I think.  The only alternative is to offer no
 100       ;; article fetching by message-id at all.
 101       (nntp-request-article article newsgroup gnus-nntp-server buffer)
 102     (let* ((header (gnus-summary-article-header article))
 103            (xref (mail-header-xref header))
 104            num group)
 105       (unless xref
 106         (error "nnkiboze: No xref"))
 107       (unless (string-match " \\([^ ]+\\):\\([0-9]+\\)" xref)
 108         (error "nnkiboze: Malformed xref"))
 109       (setq num (string-to-number (match-string 2 xref))
 110             group (match-string 1 xref))
 111       (or (with-current-buffer buffer
 112             (or (and gnus-use-cache (gnus-cache-request-article num group))
 113                 (gnus-agent-request-article num group)))
 114           (gnus-request-article num group buffer)))))
 115
 116 (deffoo nnkiboze-request-scan (&optional group server)
 117   (nnkiboze-possibly-change-group group)
 118   (nnkiboze-generate-group (concat "nnkiboze:" group)))
 119
 120 (deffoo nnkiboze-request-group (group &optional server dont-check)
 121   "Make GROUP the current newsgroup."
 122   (nnkiboze-possibly-change-group group)
 123   (if dont-check
 124       t
 125     (let ((nov-file (nnkiboze-nov-file-name))
 126           beg end total)
 127       (save-excursion
 128         (set-buffer nntp-server-buffer)
 129         (erase-buffer)
 130         (unless (file-exists-p nov-file)
 131           (nnkiboze-request-scan group))
 132         (if (not (file-exists-p nov-file))
 133             (nnheader-report 'nnkiboze "Can't select group %s" group)
 134           (let ((nnheader-file-coding-system nnkiboze-file-coding-system))
 135             (nnheader-insert-file-contents nov-file))
 136           (if (zerop (buffer-size))
 137               (nnheader-insert "211 0 0 0 %s\n" group)
 138             (goto-char (point-min))
 139             (when (looking-at "[0-9]+")
 140               (setq beg (read (current-buffer))))
 141             (goto-char (point-max))
 142             (when (re-search-backward "^[0-9]" nil t)
 143               (setq end (read (current-buffer))))
 144             (setq total (count-lines (point-min) (point-max)))
 145             (nnheader-insert "211 %d %d %d %s\n" total beg end group)))))))
 146
 147 (deffoo nnkiboze-close-group (group &optional server)
 148   (nnkiboze-possibly-change-group group)
 149   ;; Remove NOV lines of articles that are marked as read.
 150   (when (and (file-exists-p (nnkiboze-nov-file-name))
 151              nnkiboze-remove-read-articles)
 152     (let ((coding-system-for-write nnkiboze-file-coding-system))
 153       (with-temp-file (nnkiboze-nov-file-name)
 154         (let ((cur (current-buffer))
 155               (nnheader-file-coding-system nnkiboze-file-coding-system))
 156           (nnheader-insert-file-contents (nnkiboze-nov-file-name))
 157           (goto-char (point-min))
 158           (while (not (eobp))
 159             (if (not (gnus-article-read-p (read cur)))
 160                 (forward-line 1)
 161               (gnus-delete-line))))))
 162     (setq nnkiboze-current-group nil)))
 163
 164 (deffoo nnkiboze-open-server (server &optional defs)
 165   (unless (assq 'nnkiboze-regexp defs)
 166     (push `(nnkiboze-regexp ,server)
 167           defs))
 168   (nnoo-change-server 'nnkiboze server defs))
 169
 170 (deffoo nnkiboze-request-delete-group (group &optional force server)
 171   (nnkiboze-possibly-change-group group)
 172   (when force
 173     (let ((files (nconc
 174                   (nnkiboze-score-file group)
 175                   (list (nnkiboze-nov-file-name)
 176                         (nnkiboze-nov-file-name ".newsrc")))))
 177       (while files
 178         (and (file-exists-p (car files))
 179              (file-writable-p (car files))
 180              (delete-file (car files)))
 181         (setq files (cdr files)))))
 182   (setq nnkiboze-current-group nil)
 183   t)
 184
 185 (nnoo-define-skeleton nnkiboze)
 186
 187 \f
 188 ;;; Internal functions.
 189
 190 (defun nnkiboze-possibly-change-group (group)
 191   (setq nnkiboze-current-group group))
 192
 193 (defun nnkiboze-prefixed-name (group)
 194   (gnus-group-prefixed-name group '(nnkiboze "")))
 195
 196 ;;;###autoload
 197 (defun nnkiboze-generate-groups ()
 198   "\"Usage: emacs -batch -l nnkiboze -f nnkiboze-generate-groups\".
 199 Finds out what articles are to be part of the nnkiboze groups."
 200   (interactive)
 201   (let ((mail-sources nil)
 202         (gnus-use-dribble-file nil)
 203         (gnus-read-active-file t)
 204         (gnus-expert-user t))
 205     (gnus))
 206   (let* ((gnus-newsrc-alist (gnus-copy-sequence gnus-newsrc-alist))
 207          (newsrc (cdr gnus-newsrc-alist))
 208          gnus-newsrc-hashtb info)
 209     (gnus-make-hashtable-from-newsrc-alist)
 210     ;; We have copied all the newsrc alist info over to local copies
 211     ;; so that we can mess all we want with these lists.
 212     (while (setq info (pop newsrc))
 213       (when (string-match "nnkiboze" (gnus-info-group info))
 214         ;; For each kiboze group, we call this function to generate
 215         ;; it.
 216         (nnkiboze-generate-group (gnus-info-group info) t))))
 217   (save-excursion
 218     (set-buffer gnus-group-buffer)
 219     (gnus-group-list-groups)))
 220
 221 (defun nnkiboze-score-file (group)
 222   (list (expand-file-name
 223          (concat (file-name-as-directory gnus-kill-files-directory)
 224                  (nnheader-translate-file-chars
 225                   (concat (nnkiboze-prefixed-name nnkiboze-current-group)
 226                           "." gnus-score-file-suffix))))))
 227
 228 (defun nnkiboze-generate-group (group &optional inhibit-list-groups)
 229   (let* ((info (gnus-get-info group))
 230          (newsrc-file (concat nnkiboze-directory
 231                               (nnheader-translate-file-chars
 232                                (concat group ".newsrc"))))
 233          (nov-file (concat nnkiboze-directory
 234                            (nnheader-translate-file-chars
 235                             (concat group ".nov"))))
 236          method nnkiboze-newsrc gname newsrc active
 237          ginfo lowest glevel orig-info nov-buffer
 238          ;; Bind various things to nil to make group entry faster.
 239          (gnus-expert-user t)
 240          (gnus-large-newsgroup nil)
 241          (gnus-score-find-score-files-function 'nnkiboze-score-file)
 242          ;; Use only nnkiboze-score-file!
 243          (gnus-score-use-all-scores nil)
 244          (gnus-use-scoring t)
 245          (gnus-verbose (min gnus-verbose 3))
 246          gnus-select-group-hook gnus-summary-prepare-hook
 247          gnus-thread-sort-functions gnus-show-threads
 248          gnus-visual gnus-suppress-duplicates num-unread)
 249     (unless info
 250       (error "No such group: %s" group))
 251     ;; Load the kiboze newsrc file for this group.
 252     (mm-with-unibyte
 253       (when (file-exists-p newsrc-file)
 254         (load newsrc-file))
 255       (let ((coding-system-for-write nnkiboze-file-coding-system))
 256         (gnus-make-directory (file-name-directory nov-file))
 257         (with-temp-file nov-file
 258           (when (file-exists-p nov-file)
 259             (insert-file-contents nov-file))
 260           (setq nov-buffer (current-buffer))
 261           ;; Go through the active hashtb and add new all groups that match the
 262           ;; kiboze regexp.
 263           (mapatoms
 264            (lambda (group)
 265              (and (string-match nnkiboze-regexp
 266                                 (setq gname (symbol-name group))) ; Match
 267                   (not (assoc gname nnkiboze-newsrc)) ; It isn't registered
 268                   (numberp (car (symbol-value group))) ; It is active
 269                   (or (> nnkiboze-level 7)
 270                       (and (setq glevel
 271                                  (gnus-info-level (gnus-get-info gname)))
 272                            (>= nnkiboze-level glevel)))
 273                   (not (string-match "^nnkiboze:" gname)) ; Exclude kibozes
 274                   (push (cons gname (1- (car (symbol-value group))))
 275                         nnkiboze-newsrc)))
 276            gnus-active-hashtb)
 277           ;; `newsrc' is set to the list of groups that possibly are
 278           ;; component groups to this kiboze group.  This list has elements
 279           ;; on the form `(GROUP . NUMBER)', where NUMBER is the highest
 280           ;; number that has been kibozed in GROUP in this kiboze group.
 281           (setq newsrc nnkiboze-newsrc)
 282           (while newsrc
 283             (if (not (setq active (gnus-active (caar newsrc))))
 284                 ;; This group isn't active after all, so we remove it from
 285                 ;; the list of component groups.
 286                 (setq nnkiboze-newsrc (delq (car newsrc) nnkiboze-newsrc))
 287               (setq lowest (cdar newsrc))
 288               ;; Ok, we have a valid component group, so we jump to it.
 289               (switch-to-buffer gnus-group-buffer)
 290               (gnus-group-jump-to-group (caar newsrc))
 291               (gnus-message 3 "nnkiboze: Checking %s..." (caar newsrc))
 292               (setq ginfo (gnus-get-info (gnus-group-group-name))
 293                     orig-info (gnus-copy-sequence ginfo)
 294                     num-unread (gnus-group-unread (caar newsrc)))
 295               (unwind-protect
 296                   (progn
 297                     ;; We set all list of article marks to nil.  Since we operate
 298                     ;; on copies of the real lists, we can destroy anything we
 299                     ;; want here.
 300                     (when (nth 3 ginfo)
 301                       (setcar (nthcdr 3 ginfo) nil))
 302                     ;; We set the list of read articles to be what we expect for
 303                     ;; this kiboze group -- either nil or `(1 . LOWEST)'.
 304                     (when ginfo
 305                       (setcar (nthcdr 2 ginfo)
 306                               (and (not (= lowest 1)) (cons 1 lowest))))
 307                     (when (and (or (not ginfo)
 308                                    (> (length (gnus-list-of-unread-articles
 309                                                (car ginfo)))
 310                                       0))
 311                                (progn
 312                                  (ignore-errors
 313                                    (gnus-group-select-group nil))
 314                                  (eq major-mode 'gnus-summary-mode)))
 315                       ;; We are now in the group where we want to be.
 316                       (setq method (gnus-find-method-for-group
 317                                     gnus-newsgroup-name))
 318                       (when (eq method gnus-select-method)
 319                         (setq method nil))
 320                       ;; We go through the list of scored articles.
 321                       (while gnus-newsgroup-scored
 322                         (when (> (caar gnus-newsgroup-scored) lowest)
 323                           ;; If it has a good score, then we enter this article
 324                           ;; into the kiboze group.
 325                           (nnkiboze-enter-nov
 326                            nov-buffer
 327                            (gnus-summary-article-header
 328                             (caar gnus-newsgroup-scored))
 329                            gnus-newsgroup-name))
 330                         (setq gnus-newsgroup-scored (cdr gnus-newsgroup-scored)))
 331                       ;; That's it.  We exit this group.
 332                       (when (eq major-mode 'gnus-summary-mode)
 333                         (kill-buffer (current-buffer)))))
 334                 ;; Restore the proper info.
 335                 (when ginfo
 336                   (setcdr ginfo (cdr orig-info)))
 337                 (setcar (gnus-group-entry (caar newsrc)) num-unread)))
 338             (setcdr (car newsrc) (cdr active))
 339             (gnus-message 3 "nnkiboze: Checking %s...done" (caar newsrc))
 340             (setq newsrc (cdr newsrc)))))
 341       ;; We save the kiboze newsrc for this group.
 342       (gnus-make-directory (file-name-directory newsrc-file))
 343       (with-temp-file newsrc-file
 344         (insert "(setq nnkiboze-newsrc '")
 345         (gnus-prin1 nnkiboze-newsrc)
 346         (insert ")\n")))
 347   (unless inhibit-list-groups
 348     (save-excursion
 349       (set-buffer gnus-group-buffer)
 350       (gnus-group-list-groups)))
 351   t))
 352
 353 (defun nnkiboze-enter-nov (buffer header group)
 354   (save-excursion
 355     (set-buffer buffer)
 356     (goto-char (point-max))
 357     (let ((prefix (gnus-group-real-prefix group))
 358           (oheader (copy-sequence header))
 359           article)
 360       (if (zerop (forward-line -1))
 361           (progn
 362             (setq article (1+ (read (current-buffer))))
 363             (forward-line 1))
 364         (setq article 1))
 365       (mail-header-set-number oheader article)
 366       (with-temp-buffer
 367         (insert (or (mail-header-xref oheader) ""))
 368         (goto-char (point-min))
 369         (if (re-search-forward " [^ ]+:[0-9]+" nil t)
 370             (goto-char (match-beginning 0))
 371           (or (eobp) (forward-char 1)))
 372         ;; The first Xref has to be the group this article
 373         ;; really came for - this is the article nnkiboze
 374         ;; will request when it is asked for the article.
 375         (insert " " group ":"
 376                 (int-to-string (mail-header-number header)) " ")
 377         (while (re-search-forward " [^ ]+:[0-9]+" nil t)
 378           (goto-char (1+ (match-beginning 0)))
 379           (insert prefix))
 380         (mail-header-set-xref oheader (buffer-string)))
 381       (nnheader-insert-nov oheader))))
 382
 383 (defun nnkiboze-nov-file-name (&optional suffix)
 384   (concat (file-name-as-directory nnkiboze-directory)
 385           (nnheader-translate-file-chars
 386            (concat (nnkiboze-prefixed-name nnkiboze-current-group)
 387                    (or suffix ".nov")))))
 388
 389 (provide 'nnkiboze)
 390
 391 ;; arch-tag: 66068271-bdc9-4801-bcde-779702e73a05
 392 ;;; nnkiboze.el ends here