lisp/progmodes/perl-mode.el

   1 ;;; perl-mode.el --- Perl code editing commands for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1994  Free Software Foundation, Inc.
   4
   5 ;; Author: William F. Mann
   6 ;; Maintainer: FSF
   7 ;; Adapted-By: ESR
   8 ;; Keywords: languages
   9
  10 ;; Adapted from C code editing commands 'c-mode.el', Copyright 1987 by the
  11 ;; Free Software Foundation, under terms of its General Public License.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  28 ;; Boston, MA 02111-1307, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; To enter perl-mode automatically, add (autoload 'perl-mode "perl-mode")
  33 ;; to your .emacs file and change the first line of your perl script to:
  34 ;; #!/usr/bin/perl --    # -*-Perl-*-
  35 ;; With arguments to perl:
  36 ;; #!/usr/bin/perl -P-   # -*-Perl-*-
  37 ;; To handle files included with do 'filename.pl';, add something like
  38 ;; (setq auto-mode-alist (append (list (cons "\\.pl\\'" 'perl-mode))
  39 ;;                               auto-mode-alist))
  40 ;; to your .emacs file; otherwise the .pl suffix defaults to prolog-mode.
  41
  42 ;; This code is based on the 18.53 version c-mode.el, with extensive
  43 ;; rewriting.  Most of the features of c-mode survived intact.
  44
  45 ;; I added a new feature which adds functionality to TAB; it is controlled
  46 ;; by the variable perl-tab-to-comment.  With it enabled, TAB does the
  47 ;; first thing it can from the following list:  change the indentation;
  48 ;; move past leading white space; delete an empty comment; reindent a
  49 ;; comment; move to end of line; create an empty comment; tell you that
  50 ;; the line ends in a quoted string, or has a # which should be a \#.
  51
  52 ;; If your machine is slow, you may want to remove some of the bindings
  53 ;; to electric-perl-terminator.  I changed the indenting defaults to be
  54 ;; what Larry Wall uses in perl/lib, but left in all the options.
  55
  56 ;; I also tuned a few things:  comments and labels starting in column
  57 ;; zero are left there by indent-perl-exp; perl-beginning-of-function
  58 ;; goes back to the first open brace/paren in column zero, the open brace
  59 ;; in 'sub ... {', or the equal sign in 'format ... ='; indent-perl-exp
  60 ;; (meta-^q) indents from the current line through the close of the next
  61 ;; brace/paren, so you don't need to start exactly at a brace or paren.
  62
  63 ;; It may be good style to put a set of redundant braces around your
  64 ;; main program.  This will let you reindent it with meta-^q.
  65
  66 ;; Known problems (these are all caused by limitations in the Emacs Lisp
  67 ;; parsing routine (parse-partial-sexp), which was not designed for such
  68 ;; a rich language; writing a more suitable parser would be a big job):
  69 ;; 1)  Regular expression delimiters do not act as quotes, so special
  70 ;;       characters such as `'"#:;[](){} may need to be backslashed
  71 ;;       in regular expressions and in both parts of s/// and tr///.
  72 ;; 2)  The globbing syntax <pattern> is not recognized, so special
  73 ;;       characters in the pattern string must be backslashed.
  74 ;; 3)  The q, qq, and << quoting operators are not recognized; see below.
  75 ;; 4)  \ (backslash) always quotes the next character, so '\' is
  76 ;;       treated as the start of a string.  Use "\\" as a work-around.
  77 ;; 5)  To make variables such a $' and $#array work, perl-mode treats
  78 ;;       $ just like backslash, so '$' is the same as problem 5.
  79 ;; 6)  Unfortunately, treating $ like \ makes ${var} be treated as an
  80 ;;       unmatched }.  See below.
  81 ;; 7)  When ' (quote) is used as a package name separator, perl-mode
  82 ;;       doesn't understand, and thinks it is seeing a quoted string.
  83
  84 ;; Here are some ugly tricks to bypass some of these problems:  the perl
  85 ;; expression /`/ (that's a back-tick) usually evaluates harmlessly,
  86 ;; but will trick perl-mode into starting a quoted string, which
  87 ;; can be ended with another /`/.  Assuming you have no embedded
  88 ;; back-ticks, this can used to help solve problem 3:
  89 ;;
  90 ;;     /`/; $ugly = q?"'$?; /`/;
  91 ;;
  92 ;; To solve problem 6, add a /{/; before each use of ${var}:
  93 ;;     /{/; while (<${glob_me}>) ...
  94 ;;
  95 ;; Problem 7 is even worse, but this 'fix' does work :-(
  96 ;;     $DB'stop#'
  97 ;;         [$DB'line#'
  98 ;;          ] =~ s/;9$//;
  99
 100 ;;; Code:
 101
 102 (defgroup perl nil
 103   "Major mode for editing Perl code."
 104   :prefix "perl-"
 105   :group 'languages)
 106
 107 (defvar perl-mode-abbrev-table nil
 108   "Abbrev table in use in perl-mode buffers.")
 109 (define-abbrev-table 'perl-mode-abbrev-table ())
 110
 111 (defvar perl-mode-map ()
 112   "Keymap used in Perl mode.")
 113 (if perl-mode-map
 114     ()
 115   (setq perl-mode-map (make-sparse-keymap))
 116   (define-key perl-mode-map "{" 'electric-perl-terminator)
 117   (define-key perl-mode-map "}" 'electric-perl-terminator)
 118   (define-key perl-mode-map ";" 'electric-perl-terminator)
 119   (define-key perl-mode-map ":" 'electric-perl-terminator)
 120   (define-key perl-mode-map "\e\C-a" 'perl-beginning-of-function)
 121   (define-key perl-mode-map "\e\C-e" 'perl-end-of-function)
 122   (define-key perl-mode-map "\e\C-h" 'mark-perl-function)
 123   (define-key perl-mode-map "\e\C-q" 'indent-perl-exp)
 124   (define-key perl-mode-map "\177" 'backward-delete-char-untabify)
 125   (define-key perl-mode-map "\t" 'perl-indent-command))
 126
 127 (autoload 'c-macro-expand "cmacexp"
 128   "Display the result of expanding all C macros occurring in the region.
 129 The expansion is entirely correct because it uses the C preprocessor."
 130   t)
 131
 132 (defvar perl-mode-syntax-table nil
 133   "Syntax table in use in perl-mode buffers.")
 134
 135 (if perl-mode-syntax-table
 136     ()
 137   (setq perl-mode-syntax-table (make-syntax-table (standard-syntax-table)))
 138   (modify-syntax-entry ?\n ">" perl-mode-syntax-table)
 139   (modify-syntax-entry ?# "<" perl-mode-syntax-table)
 140   (modify-syntax-entry ?$ "/" perl-mode-syntax-table)
 141   (modify-syntax-entry ?% "." perl-mode-syntax-table)
 142   (modify-syntax-entry ?& "." perl-mode-syntax-table)
 143   (modify-syntax-entry ?\' "\"" perl-mode-syntax-table)
 144   (modify-syntax-entry ?* "." perl-mode-syntax-table)
 145   (modify-syntax-entry ?+ "." perl-mode-syntax-table)
 146   (modify-syntax-entry ?- "." perl-mode-syntax-table)
 147   (modify-syntax-entry ?/ "." perl-mode-syntax-table)
 148   (modify-syntax-entry ?< "." perl-mode-syntax-table)
 149   (modify-syntax-entry ?= "." perl-mode-syntax-table)
 150   (modify-syntax-entry ?> "." perl-mode-syntax-table)
 151   (modify-syntax-entry ?\\ "\\" perl-mode-syntax-table)
 152   (modify-syntax-entry ?` "\"" perl-mode-syntax-table)
 153   (modify-syntax-entry ?| "." perl-mode-syntax-table)
 154 )
 155
 156 (defvar perl-imenu-generic-expression
 157   '(
 158     ;; Functions
 159     (nil "^sub\\s-+\\([-A-Za-z0-9+_:]+\\)\\(\\s-\\|\n\\)*{" 1 )
 160     ;;Variables
 161     ("Variables" "^\\([$@%][-A-Za-z0-9+_:]+\\)\\s-*=" 1 )
 162     ("Packages" "^package\\s-+\\([-A-Za-z0-9+_:]+\\);" 1 )
 163     )
 164   "Imenu generic expression for Perl mode.  See `imenu-generic-expression'.")
 165
 166 ;; Regexps updated with help from Tom Tromey <tromey@cambric.colorado.edu> and
 167 ;; Jim Campbell <jec@murzim.ca.boeing.com>.
 168
 169 (defconst perl-font-lock-keywords-1
 170   '(;; What is this for?
 171     ;;("\\(--- .* ---\\|=== .* ===\\)" . font-lock-string-face)
 172     ;;
 173     ;; Fontify preprocessor statements as we do in `c-font-lock-keywords'.
 174     ;; Ilya Zakharevich <ilya@math.ohio-state.edu> thinks this is a bad idea.
 175     ("^#[ \t]*include[ \t]+\\(<[^>\"\n]+>\\)" 1 font-lock-string-face)
 176     ("^#[ \t]*define[ \t]+\\(\\sw+\\)(" 1 font-lock-function-name-face)
 177     ("^#[ \t]*if\\>"
 178      ("\\<\\(defined\\)\\>[ \t]*(?\\(\\sw+\\)?" nil nil
 179       (1 font-lock-constant-face) (2 font-lock-variable-name-face nil t)))
 180     ("^#[ \t]*\\(\\sw+\\)\\>[ \t]*\\(\\sw+\\)?"
 181      (1 font-lock-constant-face) (2 font-lock-variable-name-face nil t))
 182     ;;
 183     ;; Fontify function and package names in declarations.
 184     ("\\<\\(package\\|sub\\)\\>[ \t]*\\(\\sw+\\)?"
 185      (1 font-lock-keyword-face) (2 font-lock-function-name-face nil t))
 186     ("\\<\\(import\\|no\\|require\\|use\\)\\>[ \t]*\\(\\sw+\\)?"
 187      (1 font-lock-keyword-face) (2 font-lock-constant-face nil t)))
 188   "Subdued level highlighting for Perl mode.")
 189
 190 (defconst perl-font-lock-keywords-2
 191   (append perl-font-lock-keywords-1
 192    (list
 193     ;;
 194     ;; Fontify keywords, except those fontified otherwise.
 195 ;   (make-regexp '("if" "until" "while" "elsif" "else" "unless" "do" "dump"
 196 ;  "for" "foreach" "exit" "die"
 197 ;  "BEGIN" "END" "return" "exec" "eval"))
 198     (concat "\\<\\("
 199             "BEGIN\\|END\\|d\\(ie\\|o\\|ump\\)\\|"
 200             "e\\(ls\\(e\\|if\\)\\|val\\|x\\(ec\\|it\\)\\)\\|"
 201             "for\\(\\|each\\)\\|if\\|return\\|un\\(less\\|til\\)\\|while"
 202             "\\)\\>")
 203     ;;
 204     ;; Fontify local and my keywords as types.
 205     '("\\<\\(local\\|my\\)\\>" . font-lock-type-face)
 206     ;;
 207     ;; Fontify function, variable and file name references.
 208     '("&\\(\\sw+\\)" 1 font-lock-function-name-face)
 209     ;; Additionally underline non-scalar variables.  Maybe this is a bad idea.
 210     ;;'("[$@%*][#{]?\\(\\sw+\\)" 1 font-lock-variable-name-face)
 211     '("[$*]{?\\(\\sw+\\)" 1 font-lock-variable-name-face)
 212     '("\\([@%]\\|\\$#\\)\\(\\sw+\\)"
 213       (2 (cons font-lock-variable-name-face '(underline))))
 214     '("<\\(\\sw+\\)>" 1 font-lock-constant-face)
 215     ;;
 216     ;; Fontify keywords with/and labels as we do in `c++-font-lock-keywords'.
 217     '("\\<\\(continue\\|goto\\|last\\|next\\|redo\\)\\>[ \t]*\\(\\sw+\\)?"
 218       (1 font-lock-keyword-face) (2 font-lock-constant-face nil t))
 219     '("^[ \t]*\\(\\sw+\\)[ \t]*:[^:]" 1 font-lock-constant-face)))
 220   "Gaudy level highlighting for Perl mode.")
 221
 222 (defvar perl-font-lock-keywords perl-font-lock-keywords-1
 223   "Default expressions to highlight in Perl mode.")
 224
 225
 226 (defcustom perl-indent-level 4
 227   "*Indentation of Perl statements with respect to containing block."
 228   :type 'integer
 229   :group 'perl)
 230 (defcustom perl-continued-statement-offset 4
 231   "*Extra indent for lines not starting new statements."
 232   :type 'integer
 233   :group 'perl)
 234 (defcustom perl-continued-brace-offset -4
 235   "*Extra indent for substatements that start with open-braces.
 236 This is in addition to `perl-continued-statement-offset'."
 237   :type 'integer
 238   :group 'perl)
 239 (defcustom perl-brace-offset 0
 240   "*Extra indentation for braces, compared with other text in same context."
 241   :type 'integer
 242   :group 'perl)
 243 (defcustom perl-brace-imaginary-offset 0
 244   "*Imagined indentation of an open brace that actually follows a statement."
 245   :type 'integer
 246   :group 'perl)
 247 (defcustom perl-label-offset -2
 248   "*Offset of Perl label lines relative to usual indentation."
 249   :type 'integer
 250   :group 'perl)
 251
 252 (defcustom perl-tab-always-indent t
 253   "*Non-nil means TAB in Perl mode always indents the current line.
 254 Otherwise it inserts a tab character if you type it past the first
 255 nonwhite character on the line."
 256   :type 'boolean
 257   :group 'perl)
 258
 259 ;; I changed the default to nil for consistency with general Emacs
 260 ;; conventions -- rms.
 261 (defcustom perl-tab-to-comment nil
 262   "*Non-nil means TAB moves to eol or makes a comment in some cases.
 263 For lines which don't need indenting, TAB either indents an
 264 existing comment, moves to end-of-line, or if at end-of-line already,
 265 create a new comment."
 266   :type 'boolean
 267   :group 'perl)
 268
 269 (defcustom perl-nochange ";?#\\|\f\\|\\s(\\|\\(\\w\\|\\s_\\)+:"
 270   "*Lines starting with this regular expression are not auto-indented."
 271   :type 'regexp
 272   :group 'perl)
 273 \f
 274 ;;;###autoload
 275 (defun perl-mode ()
 276   "Major mode for editing Perl code.
 277 Expression and list commands understand all Perl brackets.
 278 Tab indents for Perl code.
 279 Comments are delimited with # ... \\n.
 280 Paragraphs are separated by blank lines only.
 281 Delete converts tabs to spaces as it moves back.
 282 \\{perl-mode-map}
 283 Variables controlling indentation style:
 284  perl-tab-always-indent
 285     Non-nil means TAB in Perl mode should always indent the current line,
 286     regardless of where in the line point is when the TAB command is used.
 287  perl-tab-to-comment
 288     Non-nil means that for lines which don't need indenting, TAB will
 289     either delete an empty comment, indent an existing comment, move
 290     to end-of-line, or if at end-of-line already, create a new comment.
 291  perl-nochange
 292     Lines starting with this regular expression are not auto-indented.
 293  perl-indent-level
 294     Indentation of Perl statements within surrounding block.
 295     The surrounding block's indentation is the indentation
 296     of the line on which the open-brace appears.
 297  perl-continued-statement-offset
 298     Extra indentation given to a substatement, such as the
 299     then-clause of an if or body of a while.
 300  perl-continued-brace-offset
 301     Extra indentation given to a brace that starts a substatement.
 302     This is in addition to `perl-continued-statement-offset'.
 303  perl-brace-offset
 304     Extra indentation for line if it starts with an open brace.
 305  perl-brace-imaginary-offset
 306     An open brace following other text is treated as if it were
 307     this far to the right of the start of its line.
 308  perl-label-offset
 309     Extra indentation for line that is a label.
 310
 311 Various indentation styles:       K&R  BSD  BLK  GNU  LW
 312   perl-indent-level                5    8    0    2    4
 313   perl-continued-statement-offset  5    8    4    2    4
 314   perl-continued-brace-offset      0    0    0    0   -4
 315   perl-brace-offset               -5   -8    0    0    0
 316   perl-brace-imaginary-offset      0    0    4    0    0
 317   perl-label-offset               -5   -8   -2   -2   -2
 318
 319 Turning on Perl mode runs the normal hook `perl-mode-hook'."
 320   (interactive)
 321   (kill-all-local-variables)
 322   (use-local-map perl-mode-map)
 323   (setq major-mode 'perl-mode)
 324   (setq mode-name "Perl")
 325   (setq local-abbrev-table perl-mode-abbrev-table)
 326   (set-syntax-table perl-mode-syntax-table)
 327   (make-local-variable 'paragraph-start)
 328   (setq paragraph-start (concat "$\\|" page-delimiter))
 329   (make-local-variable 'paragraph-separate)
 330   (setq paragraph-separate paragraph-start)
 331   (make-local-variable 'paragraph-ignore-fill-prefix)
 332   (setq paragraph-ignore-fill-prefix t)
 333   (make-local-variable 'indent-line-function)
 334   (setq indent-line-function 'perl-indent-line)
 335   (make-local-variable 'require-final-newline)
 336   (setq require-final-newline t)
 337   (make-local-variable 'comment-start)
 338   (setq comment-start "# ")
 339   (make-local-variable 'comment-end)
 340   (setq comment-end "")
 341   (make-local-variable 'comment-column)
 342   (setq comment-column 32)
 343   (make-local-variable 'comment-start-skip)
 344   (setq comment-start-skip "\\(^\\|\\s-\\);?#+ *")
 345   (make-local-variable 'comment-indent-function)
 346   (setq comment-indent-function 'perl-comment-indent)
 347   (make-local-variable 'parse-sexp-ignore-comments)
 348   (setq parse-sexp-ignore-comments t)
 349   ;; Tell font-lock.el how to handle Perl.
 350   (make-local-variable 'font-lock-defaults)
 351   (setq font-lock-defaults '((perl-font-lock-keywords
 352                               perl-font-lock-keywords-1
 353                               perl-font-lock-keywords-2)
 354                              nil nil ((?\_ . "w"))))
 355   ;; Tell imenu how to handle Perl.
 356   (make-local-variable 'imenu-generic-expression)
 357   (setq imenu-generic-expression perl-imenu-generic-expression)
 358   (setq imenu-case-fold-search nil)
 359   (run-hooks 'perl-mode-hook))
 360 \f
 361 ;; This is used by indent-for-comment
 362 ;; to decide how much to indent a comment in Perl code
 363 ;; based on its context.
 364 (defun perl-comment-indent ()
 365   (if (and (bolp) (not (eolp)))
 366       0                                 ;Existing comment at bol stays there.
 367     (save-excursion
 368       (skip-chars-backward " \t")
 369       (max (if (bolp)                   ;Else indent at comment column
 370                0                        ; except leave at least one space if
 371              (1+ (current-column)))     ; not at beginning of line.
 372            comment-column))))
 373
 374 (defun electric-perl-terminator (arg)
 375   "Insert character and adjust indentation.
 376 If at end-of-line, and not in a comment or a quote, correct the's indentation."
 377   (interactive "P")
 378   (let ((insertpos (point)))
 379     (and (not arg)                      ; decide whether to indent
 380          (eolp)
 381          (save-excursion
 382            (beginning-of-line)
 383            (and (not                    ; eliminate comments quickly
 384                  (and comment-start-skip
 385                       (re-search-forward comment-start-skip insertpos t)) )
 386                 (or (/= last-command-char ?:)
 387                     ;; Colon is special only after a label ....
 388                     (looking-at "\\s-*\\(\\w\\|\\s_\\)+$"))
 389                 (let ((pps (parse-partial-sexp
 390                             (perl-beginning-of-function) insertpos)))
 391                   (not (or (nth 3 pps) (nth 4 pps) (nth 5 pps))))))
 392          (progn                         ; must insert, indent, delete
 393            (insert-char last-command-char 1)
 394            (perl-indent-line)
 395            (delete-char -1))))
 396   (self-insert-command (prefix-numeric-value arg)))
 397
 398 ;; not used anymore, but may be useful someday:
 399 ;;(defun perl-inside-parens-p ()
 400 ;;  (condition-case ()
 401 ;;      (save-excursion
 402 ;;      (save-restriction
 403 ;;        (narrow-to-region (point)
 404 ;;                          (perl-beginning-of-function))
 405 ;;        (goto-char (point-max))
 406 ;;        (= (char-after (or (scan-lists (point) -1 1) (point-min))) ?\()))
 407 ;;    (error nil)))
 408 \f
 409 (defun perl-indent-command (&optional arg)
 410   "Indent current line as Perl code, or optionally, insert a tab character.
 411
 412 With an argument, indent the current line, regardless of other options.
 413
 414 If `perl-tab-always-indent' is nil and point is not in the indentation
 415 area at the beginning of the line, simply insert a tab.
 416
 417 Otherwise, indent the current line.  If point was within the indentation
 418 area it is moved to the end of the indentation area.  If the line was
 419 already indented properly and point was not within the indentation area,
 420 and if `perl-tab-to-comment' is non-nil (the default), then do the first
 421 possible action from the following list:
 422
 423   1) delete an empty comment
 424   2) move forward to start of comment, indenting if necessary
 425   3) move forward to end of line
 426   4) create an empty comment
 427   5) move backward to start of comment, indenting if necessary."
 428   (interactive "P")
 429   (if arg                               ; If arg, just indent this line
 430       (perl-indent-line "\f")
 431     (if (and (not perl-tab-always-indent)
 432              (> (current-column) (current-indentation)))
 433         (insert-tab)
 434       (let (bof lsexp delta (oldpnt (point)))
 435         (beginning-of-line)
 436         (setq lsexp (point))
 437         (setq bof (perl-beginning-of-function))
 438         (goto-char oldpnt)
 439         (setq delta (perl-indent-line "\f\\|;?#" bof))
 440         (and perl-tab-to-comment
 441              (= oldpnt (point))         ; done if point moved
 442              (if (listp delta)          ; if line starts in a quoted string
 443                  (setq lsexp (or (nth 2 delta) bof))
 444                (= delta 0))             ; done if indenting occurred
 445              (let (eol state)
 446                (end-of-line)
 447                (setq eol (point))
 448                (if (= (char-after bof) ?=)
 449                    (if (= oldpnt eol)
 450                        (message "In a format statement"))
 451                  (setq state (parse-partial-sexp lsexp eol))
 452                  (if (nth 3 state)
 453                      (if (= oldpnt eol) ; already at eol in a string
 454                          (message "In a string which starts with a %c."
 455                                   (nth 3 state)))
 456                    (if (not (nth 4 state))
 457                        (if (= oldpnt eol) ; no comment, create one?
 458                            (indent-for-comment))
 459                      (beginning-of-line)
 460                      (if (and comment-start-skip
 461                               (re-search-forward comment-start-skip eol 'move))
 462                          (if (eolp)
 463                              (progn     ; kill existing comment
 464                                (goto-char (match-beginning 0))
 465                                (skip-chars-backward " \t")
 466                                (kill-region (point) eol))
 467                            (if (or (< oldpnt (point)) (= oldpnt eol))
 468                                (indent-for-comment) ; indent existing comment
 469                              (end-of-line)))
 470                        (if (/= oldpnt eol)
 471                            (end-of-line)
 472                          (message "Use backslash to quote # characters.")
 473                          (ding t))))))))))))
 474
 475 (defun perl-indent-line (&optional nochange parse-start)
 476   "Indent current line as Perl code.
 477 Return the amount the indentation
 478 changed by, or (parse-state) if line starts in a quoted string."
 479   (let ((case-fold-search nil)
 480         (pos (- (point-max) (point)))
 481         (bof (or parse-start (save-excursion (perl-beginning-of-function))))
 482         beg indent shift-amt)
 483     (beginning-of-line)
 484     (setq beg (point))
 485     (setq shift-amt
 486           (cond ((= (char-after bof) ?=) 0)
 487                 ((listp (setq indent (calculate-perl-indent bof))) indent)
 488                 ((looking-at (or nochange perl-nochange)) 0)
 489                 (t
 490                  (skip-chars-forward " \t\f")
 491                  (cond ((looking-at "\\(\\w\\|\\s_\\)+:")
 492                         (setq indent (max 1 (+ indent perl-label-offset))))
 493                        ((= (following-char) ?})
 494                         (setq indent (- indent perl-indent-level)))
 495                        ((= (following-char) ?{)
 496                         (setq indent (+ indent perl-brace-offset))))
 497                  (- indent (current-column)))))
 498     (skip-chars-forward " \t\f")
 499     (if (and (numberp shift-amt) (/= 0 shift-amt))
 500         (progn (delete-region beg (point))
 501                (indent-to indent)))
 502     ;; If initial point was within line's indentation,
 503     ;; position after the indentation.  Else stay at same point in text.
 504     (if (> (- (point-max) pos) (point))
 505         (goto-char (- (point-max) pos)))
 506     shift-amt))
 507
 508 (defun calculate-perl-indent (&optional parse-start)
 509   "Return appropriate indentation for current line as Perl code.
 510 In usual case returns an integer: the column to indent to.
 511 Returns (parse-state) if line starts inside a string."
 512   (save-excursion
 513     (beginning-of-line)
 514     (let ((indent-point (point))
 515           (case-fold-search nil)
 516           (colon-line-end 0)
 517           state containing-sexp)
 518       (if parse-start                   ;used to avoid searching
 519           (goto-char parse-start)
 520         (perl-beginning-of-function))
 521       (while (< (point) indent-point)   ;repeat until right sexp
 522         (setq parse-start (point))
 523         (setq state (parse-partial-sexp (point) indent-point 0))
 524 ; state = (depth_in_parens innermost_containing_list last_complete_sexp
 525 ;          string_terminator_or_nil inside_commentp following_quotep
 526 ;          minimum_paren-depth_this_scan)
 527 ; Parsing stops if depth in parentheses becomes equal to third arg.
 528         (setq containing-sexp (nth 1 state)))
 529       (cond ((nth 3 state) state)       ; In a quoted string?
 530             ((null containing-sexp)     ; Line is at top level.
 531              (skip-chars-forward " \t\f")
 532              (if (= (following-char) ?{)
 533                  0   ; move to beginning of line if it starts a function body
 534                ;; indent a little if this is a continuation line
 535                (perl-backward-to-noncomment)
 536                (if (or (bobp)
 537                        (memq (preceding-char) '(?\; ?\})))
 538                    0 perl-continued-statement-offset)))
 539             ((/= (char-after containing-sexp) ?{)
 540              ;; line is expression, not statement:
 541              ;; indent to just after the surrounding open.
 542              (goto-char (1+ containing-sexp))
 543              (skip-chars-forward " \t")
 544              (current-column))
 545             (t
 546              ;; Statement level.  Is it a continuation or a new statement?
 547              ;; Find previous non-comment character.
 548              (perl-backward-to-noncomment)
 549              ;; Back up over label lines, since they don't
 550              ;; affect whether our line is a continuation.
 551              (while (or (eq (preceding-char) ?\,)
 552                         (and (eq (preceding-char) ?:)
 553                              (memq (char-syntax (char-after (- (point) 2)))
 554                                    '(?w ?_))))
 555                (if (eq (preceding-char) ?\,)
 556                    (perl-backward-to-start-of-continued-exp containing-sexp)
 557                  (beginning-of-line))
 558                (perl-backward-to-noncomment))
 559              ;; Now we get the answer.
 560              (if (not (memq (preceding-char) '(?\; ?\} ?\{)))
 561                  ;; This line is continuation of preceding line's statement;
 562                  ;; indent  perl-continued-statement-offset  more than the
 563                  ;; previous line of the statement.
 564                  (progn
 565                    (perl-backward-to-start-of-continued-exp containing-sexp)
 566                    (+ perl-continued-statement-offset (current-column)
 567                       (if (save-excursion (goto-char indent-point)
 568                                           (looking-at "[ \t]*{"))
 569                           perl-continued-brace-offset 0)))
 570                ;; This line starts a new statement.
 571                ;; Position at last unclosed open.
 572                (goto-char containing-sexp)
 573                (or
 574                  ;; If open paren is in col 0, close brace is special
 575                  (and (bolp)
 576                       (save-excursion (goto-char indent-point)
 577                                       (looking-at "[ \t]*}"))
 578                       perl-indent-level)
 579                  ;; Is line first statement after an open-brace?
 580                  ;; If no, find that first statement and indent like it.
 581                  (save-excursion
 582                    (forward-char 1)
 583                    ;; Skip over comments and labels following openbrace.
 584                    (while (progn
 585                             (skip-chars-forward " \t\f\n")
 586                             (cond ((looking-at ";?#")
 587                                    (forward-line 1) t)
 588                                   ((looking-at "\\(\\w\\|\\s_\\)+:")
 589                                    (save-excursion
 590                                      (end-of-line)
 591                                      (setq colon-line-end (point)))
 592                                    (search-forward ":")))))
 593                    ;; The first following code counts
 594                    ;; if it is before the line we want to indent.
 595                    (and (< (point) indent-point)
 596                         (if (> colon-line-end (point))
 597                             (- (current-indentation) perl-label-offset)
 598                           (current-column))))
 599                  ;; If no previous statement,
 600                  ;; indent it relative to line brace is on.
 601                  ;; For open paren in column zero, don't let statement
 602                  ;; start there too.  If perl-indent-level is zero,
 603                  ;; use perl-brace-offset + perl-continued-statement-offset
 604                  ;; For open-braces not the first thing in a line,
 605                  ;; add in perl-brace-imaginary-offset.
 606                  (+ (if (and (bolp) (zerop perl-indent-level))
 607                         (+ perl-brace-offset perl-continued-statement-offset)
 608                       perl-indent-level)
 609                     ;; Move back over whitespace before the openbrace.
 610                     ;; If openbrace is not first nonwhite thing on the line,
 611                     ;; add the perl-brace-imaginary-offset.
 612                     (progn (skip-chars-backward " \t")
 613                            (if (bolp) 0 perl-brace-imaginary-offset))
 614                     ;; If the openbrace is preceded by a parenthesized exp,
 615                     ;; move to the beginning of that;
 616                     ;; possibly a different line
 617                     (progn
 618                       (if (eq (preceding-char) ?\))
 619                           (forward-sexp -1))
 620                       ;; Get initial indentation of the line we are on.
 621                       (current-indentation))))))))))
 622
 623 (defun perl-backward-to-noncomment ()
 624   "Move point backward to after the first non-white-space, skipping comments."
 625   (interactive)
 626   (let (opoint stop)
 627     (while (not stop)
 628       (setq opoint (point))
 629       (beginning-of-line)
 630       (if (and comment-start-skip
 631                (re-search-forward comment-start-skip opoint 'move 1))
 632           (progn (goto-char (match-end 1))
 633                  (skip-chars-forward ";")))
 634       (skip-chars-backward " \t\f")
 635       (setq stop (or (bobp)
 636                      (not (bolp))
 637                      (forward-char -1))))))
 638
 639 (defun perl-backward-to-start-of-continued-exp (lim)
 640   (if (= (preceding-char) ?\))
 641       (forward-sexp -1))
 642   (beginning-of-line)
 643   (if (<= (point) lim)
 644       (goto-char (1+ lim)))
 645   (skip-chars-forward " \t\f"))
 646 \f
 647 ;; note: this may be slower than the c-mode version, but I can understand it.
 648 (defun indent-perl-exp ()
 649   "Indent each line of the Perl grouping following point."
 650   (interactive)
 651   (let* ((case-fold-search nil)
 652          (oldpnt (point-marker))
 653          (bof-mark (save-excursion
 654                      (end-of-line 2)
 655                      (perl-beginning-of-function)
 656                      (point-marker)))
 657          eol last-mark lsexp-mark delta)
 658     (if (= (char-after (marker-position bof-mark)) ?=)
 659         (message "Can't indent a format statement")
 660       (message "Indenting Perl expression...")
 661       (save-excursion (end-of-line) (setq eol (point)))
 662       (save-excursion                   ; locate matching close paren
 663         (while (and (not (eobp)) (<= (point) eol))
 664           (parse-partial-sexp (point) (point-max) 0))
 665         (setq last-mark (point-marker)))
 666       (setq lsexp-mark bof-mark)
 667       (beginning-of-line)
 668       (while (< (point) (marker-position last-mark))
 669         (setq delta (perl-indent-line nil (marker-position bof-mark)))
 670         (if (numberp delta)             ; unquoted start-of-line?
 671             (progn
 672               (if (eolp)
 673                   (delete-horizontal-space))
 674               (setq lsexp-mark (point-marker))))
 675         (end-of-line)
 676         (setq eol (point))
 677         (if (nth 4 (parse-partial-sexp (marker-position lsexp-mark) eol))
 678             (progn                      ; line ends in a comment
 679               (beginning-of-line)
 680               (if (or (not (looking-at "\\s-*;?#"))
 681                       (listp delta)
 682                       (and (/= 0 delta)
 683                            (= (- (current-indentation) delta) comment-column)))
 684                   (if (and comment-start-skip
 685                            (re-search-forward comment-start-skip eol t))
 686                       (indent-for-comment))))) ; indent existing comment
 687         (forward-line 1))
 688       (goto-char (marker-position oldpnt))
 689       (message "Indenting Perl expression...done"))))
 690 \f
 691 (defun perl-beginning-of-function (&optional arg)
 692   "Move backward to next beginning-of-function, or as far as possible.
 693 With argument, repeat that many times; negative args move forward.
 694 Returns new value of point in all cases."
 695   (interactive "p")
 696   (or arg (setq arg 1))
 697   (if (< arg 0) (forward-char 1))
 698   (and (/= arg 0)
 699        (re-search-backward "^\\s(\\|^\\s-*sub\\b[^{]+{\\|^\\s-*format\\b[^=]*=\\|^\\."
 700                            nil 'move arg)
 701        (goto-char (1- (match-end 0))))
 702   (point))
 703
 704 ;; note: this routine is adapted directly from emacs lisp.el, end-of-defun;
 705 ;; no bugs have been removed :-)
 706 (defun perl-end-of-function (&optional arg)
 707   "Move forward to next end-of-function.
 708 The end of a function is found by moving forward from the beginning of one.
 709 With argument, repeat that many times; negative args move backward."
 710   (interactive "p")
 711   (or arg (setq arg 1))
 712   (let ((first t))
 713     (while (and (> arg 0) (< (point) (point-max)))
 714       (let ((pos (point)) npos)
 715         (while (progn
 716                 (if (and first
 717                          (progn
 718                           (forward-char 1)
 719                           (perl-beginning-of-function 1)
 720                           (not (bobp))))
 721                     nil
 722                   (or (bobp) (forward-char -1))
 723                   (perl-beginning-of-function -1))
 724                 (setq first nil)
 725                 (forward-list 1)
 726                 (skip-chars-forward " \t")
 727                 (if (looking-at "[#\n]")
 728                     (forward-line 1))
 729                 (<= (point) pos))))
 730       (setq arg (1- arg)))
 731     (while (< arg 0)
 732       (let ((pos (point)))
 733         (perl-beginning-of-function 1)
 734         (forward-sexp 1)
 735         (forward-line 1)
 736         (if (>= (point) pos)
 737             (if (progn (perl-beginning-of-function 2) (not (bobp)))
 738                 (progn
 739                   (forward-list 1)
 740                   (skip-chars-forward " \t")
 741                   (if (looking-at "[#\n]")
 742                       (forward-line 1)))
 743               (goto-char (point-min)))))
 744       (setq arg (1+ arg)))))
 745
 746 (defun mark-perl-function ()
 747   "Put mark at end of Perl function, point at beginning."
 748   (interactive)
 749   (push-mark (point))
 750   (perl-end-of-function)
 751   (push-mark (point))
 752   (perl-beginning-of-function)
 753   (backward-paragraph))
 754
 755 (provide 'perl-mode)
 756
 757 ;;; perl-mode.el ends here