lisp/uniquify.el

   1 ;;; uniquify.el --- unique buffer names dependent on file name
   2
   3 ;; Copyright (C) 1989, 1995, 1996, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Dick King <king@reasoning.com>
   7 ;; Maintainer: FSF
   8 ;; Keywords: files
   9 ;; Created: 15 May 86
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Emacs's standard method for making buffer names unique adds <2>, <3>,
  31 ;; etc. to the end of (all but one of) the buffers.  This file replaces
  32 ;; that behavior, for buffers visiting files and dired buffers, with a
  33 ;; uniquification that adds parts of the file name until the buffer names
  34 ;; are unique.  For instance, buffers visiting /u/mernst/tmp/Makefile and
  35 ;; /usr/projects/zaphod/Makefile would be named Makefile|tmp and
  36 ;; Makefile|zaphod, respectively (instead of Makefile and Makefile<2>).
  37 ;; Other buffer name styles are also available.
  38
  39 ;; To use this file, do (require 'uniquify)
  40 ;; and set uniquify-buffer-name-style to one of its non-nil alternative values.
  41
  42 ;; For other options, see "User-visible variables", below.
  43
  44 ;; A version of uniquify.el that works under Emacs 18, Emacs 19, XEmacs,
  45 ;; and InfoDock is available from the maintainer.
  46
  47 ;;; Change Log:
  48
  49 ;; Originally by Dick King <king@reasoning.com> 15 May 86
  50 ;; Converted for Emacs 18 by Stephen Gildea <gildea@stop.mail-abuse.org>
  51 ;; Make uniquify-min-dir-content 0 truly non-invasive.  gildea 23 May 89
  52 ;; Some cleanup.  uniquify-min-dir-content default 0.  gildea 01 Jun 89
  53 ;; Don't rename to "".  Michael Ernst <mernst@theory.lcs.mit.edu> 15 Jun 94
  54 ;; Add kill-buffer-hook.  Kenneth Manheimer <ken.manheimer@nist.gov> 09 May 95
  55 ;; Add advice for rename-buffer and create-file-buffer, handle dired buffers,
  56 ;;  kill-buffer-rationalize-buffer-names-p, documentation.  mernst 24 May 95
  57 ;; Remove free variables, fix typos.  mernst 5 Jun 95
  58 ;; Efficiently support Emacs 19.27 & earlier.  ken.manheimer, mernst 10 Jun 95
  59 ;; Rename user options to "uniquify-...", add uniquify-reverse-dir-content-p,
  60 ;;  add uniquify-ask-about-buffer-names-p.  king, mernst 13 Jun 95
  61 ;; Prefix functions by "uniquify-..."; rename mnemonic-buffer-names to
  62 ;;  uniquify-buffer-name-style; add 'forward and 'post-forward-angle-brackets
  63 ;;  styles; remove uniquify-reverse-dir-content-p; add
  64 ;;  uniquify-trailing-separator-p.  mernst 4 Aug 95
  65 ;; Don't call expand-file-name on nil.  mernst 7 Jan 96
  66 ;; Check whether list-buffers-directory is bound.  mernst 11 Oct 96
  67 ;; Ignore non-file non-dired buffers. Colin Rafferty <craffert@ml.com> 3 Mar 97
  68 ;; Use last component, not "", for file name of directories.  mernst 27 Jun 97
  69 ;; Use directory-file-name; code cleanup.  mernst 6 Sep 97
  70 ;; Add uniquify-ignore-buffers-re.
  71 ;;  Andre Srinivasan <andre@visigenic.com> 9 Sep 97
  72 ;; Add uniquify-list-buffers-directory-modes
  73 ;;   Stefan Monnier <monnier@cs.yale.edu> 17 Nov 2000
  74 ;; Algorithm and data structure changed to reduce consing with lots of buffers
  75 ;;   Francesco Potortì <pot@gnu.org> (ideas by rms and monnier) 2001-07-18
  76
  77 ;; Valuable feedback was provided by
  78 ;; Paul Smith <psmith@baynetworks.com>,
  79 ;; Alastair Burt <burt@dfki.uni-kl.de>,
  80 ;; Bob Weiner <weiner@footloose.sps.mot.com>,
  81 ;; Albert L. Ting <alt@vlibs.com>,
  82 ;; gyro@reasoning.com,
  83 ;; Bryan O'Sullivan <bos@eng.sun.com>.
  84
  85
  86 ;;; Code:
  87
  88 (eval-when-compile (require 'cl))
  89
  90 ;;; User-visible variables
  91
  92 (defgroup uniquify nil
  93   "Unique buffer names dependent on file name."
  94   :group 'applications)
  95
  96
  97 (defcustom uniquify-buffer-name-style nil
  98   "If non-nil, buffer names are uniquified with parts of directory name.
  99 The value determines the buffer name style and is one of `forward',
 100 `reverse', `post-forward', or `post-forward-angle-brackets'.
 101 For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name'
 102 would have the following buffer names in the various styles:
 103   forward        bar/mumble/name  quux/mumble/name
 104   reverse        name\\mumble\\bar  name\\mumble\\quux
 105   post-forward   name|bar/mumble  name|quux/mumble
 106   post-forward-angle-brackets   name<bar/mumble>  name<quux/mumble>
 107   nil            name  name<2>
 108 Of course, the \"mumble\" part may be stripped as well, depending on the setting
 109 of `uniquify-strip-common-suffix'."
 110   :type '(radio (const forward)
 111                 (const reverse)
 112                 (const post-forward)
 113                 (const post-forward-angle-brackets)
 114                 (const :tag "standard Emacs behavior (nil)" nil))
 115   :require 'uniquify
 116   :group 'uniquify)
 117
 118 (defcustom uniquify-after-kill-buffer-p t
 119   "If non-nil, rerationalize buffer names after a buffer has been killed."
 120   :type 'boolean
 121   :group 'uniquify)
 122
 123 (defcustom uniquify-ask-about-buffer-names-p nil
 124   "If non-nil, permit user to choose names for buffers with same base file.
 125 If the user chooses to name a buffer, uniquification is preempted and no
 126 other buffer names are changed."
 127   :type 'boolean
 128   :group 'uniquify)
 129
 130 ;; The default value matches certain Gnus buffers.
 131 (defcustom uniquify-ignore-buffers-re nil
 132   "Regular expression matching buffer names that should not be uniquified.
 133 For instance, set this to \"^draft-[0-9]+$\" to avoid having uniquify rename
 134 draft buffers even if `uniquify-after-kill-buffer-p' is non-nil and the
 135 visited file name isn't the same as that of the buffer."
 136   :type '(choice (const :tag "Uniquify all buffers" nil) regexp)
 137   :group 'uniquify)
 138
 139 (defcustom uniquify-min-dir-content 0
 140   "Minimum number of directory name components included in buffer name."
 141   :type 'integer
 142   :group 'uniquify)
 143
 144 (defcustom uniquify-separator nil
 145   "String separator for buffer name components.
 146 When `uniquify-buffer-name-style' is `post-forward', separates
 147 base file name from directory part in buffer names (default \"|\").
 148 When `uniquify-buffer-name-style' is `reverse', separates all
 149 file name components (default \"\\\")."
 150   :type '(choice (const nil) string)
 151   :group 'uniquify)
 152
 153 (defcustom uniquify-trailing-separator-p nil
 154   "If non-nil, add a file name separator to dired buffer names.
 155 If `uniquify-buffer-name-style' is `forward', add the separator at the end;
 156 if it is `reverse', add the separator at the beginning; otherwise, this
 157 variable is ignored."
 158   :type 'boolean
 159   :group 'uniquify)
 160
 161 (defcustom uniquify-strip-common-suffix
 162   ;; Using it when uniquify-min-dir-content>0 doesn't make much sense.
 163   (eq 0 uniquify-min-dir-content)
 164   "If non-nil, strip common directory suffixes of conflicting files.
 165 E.g. if you open /a1/b/c/d and /a2/b/c/d, the buffer names will say
 166 \"d|a1\" and \"d|a2\" instead of \"d|a1/b/c\" and \"d|a2/b/c\".
 167 This can be handy when you have deep parallel hierarchies."
 168   :type 'boolean
 169   :group 'uniquify)
 170
 171 (defvar uniquify-list-buffers-directory-modes '(dired-mode cvs-mode)
 172   "List of modes for which uniquify should obey `list-buffers-directory'.
 173 That means that when `buffer-file-name' is set to nil, `list-buffers-directory'
 174 contains the name of the directory which the buffer is visiting.")
 175
 176 ;;; Utilities
 177
 178 ;; uniquify-fix-list data structure
 179 (defstruct (uniquify-item
 180             (:constructor nil) (:copier nil)
 181             (:constructor uniquify-make-item
 182              (base dirname buffer &optional proposed)))
 183   base dirname buffer proposed)
 184
 185 ;; Internal variables used free
 186 (defvar uniquify-possibly-resolvable nil)
 187
 188 (defvar uniquify-managed nil
 189   "Non-nil if the name of this buffer is managed by uniquify.
 190 It actually holds the list of `uniquify-item's corresponding to the conflict.")
 191 (make-variable-buffer-local 'uniquify-managed)
 192 (put 'uniquify-managed 'permanent-local t)
 193
 194 ;; Used in desktop.el to save the non-uniquified buffer name
 195 (defun uniquify-buffer-base-name ()
 196   "Return the base name of the current buffer.
 197 Return nil if the buffer is not managed by uniquify."
 198   (and uniquify-managed
 199        (uniquify-item-base (car uniquify-managed))))
 200
 201 ;;; Main entry point.
 202
 203 (defun uniquify-rationalize-file-buffer-names (base dirname newbuf)
 204   "Make file buffer names unique by adding segments from file name.
 205 If `uniquify-min-dir-content' > 0, always pulls that many
 206 file name elements.
 207 Arguments BASE, DIRNAME, and NEWBUF specify the new buffer that causes
 208 this rationalization."
 209   (interactive
 210    (list (if uniquify-managed
 211              (uniquify-item-base (car uniquify-managed)) (buffer-name))
 212          (uniquify-buffer-file-name (current-buffer))
 213          (current-buffer)))
 214   ;; Make sure we don't get confused by outdated uniquify-managed info in
 215   ;; this buffer.
 216   (with-current-buffer newbuf (setq uniquify-managed nil))
 217   (when dirname
 218     (setq dirname (expand-file-name (directory-file-name dirname)))
 219     (let ((fix-list (list (uniquify-make-item base dirname newbuf)))
 220           items)
 221       (dolist (buffer (buffer-list))
 222         (when (and (not (and uniquify-ignore-buffers-re
 223                              (string-match uniquify-ignore-buffers-re
 224                                            (buffer-name buffer))))
 225                    ;; Only try to rename buffers we actually manage.
 226                    (setq items (buffer-local-value 'uniquify-managed buffer))
 227                    (equal base (uniquify-item-base (car items)))
 228                    ;; Don't re-add stuff we already have.  Actually this
 229                    ;; whole `and' test should only match at most once.
 230                    (not (memq (car items) fix-list)))
 231           (unless (cdr items)
 232             ;; If there was no conflict, the buffer-name is equal to the
 233             ;; base-name and we may have missed a rename-buffer because
 234             ;; of code like in set-visited-file-name:
 235             ;; (or (string= new-name (buffer-name)) (rename-buffer new-name t))
 236             ;; So we need to refresh the dirname of the uniquify-item.
 237             (setf (uniquify-item-dirname (car items))
 238                   (uniquify-buffer-file-name
 239                    (uniquify-item-buffer (car items))))
 240             ;; This shouldn't happen, but maybe there's no dirname any more.
 241             (unless (uniquify-item-dirname (car items))
 242               (with-current-buffer (uniquify-item-buffer (car items))
 243                 (setq uniquify-managed nil))
 244               (setq items nil)))
 245           ;; In case we missed some calls to kill-buffer, there may be dead
 246           ;; buffers in uniquify-managed, so filter them out.
 247           (setq items
 248                 (delq nil (mapcar
 249                            (lambda (item)
 250                              (if (buffer-live-p (uniquify-item-buffer item))
 251                                  item))
 252                            items)))
 253           (setq fix-list (append fix-list items))))
 254       ;; selects buffers whose names may need changing, and others that
 255       ;; may conflict, then bring conflicting names together
 256       (uniquify-rationalize fix-list))))
 257
 258 ;; uniquify's version of buffer-file-name; result never contains trailing slash
 259 (defun uniquify-buffer-file-name (buffer)
 260   "Return name of directory, file BUFFER is visiting, or nil if none.
 261 Works on ordinary file-visiting buffers and buffers whose mode is mentioned
 262 in `uniquify-list-buffers-directory-modes', otherwise returns nil."
 263   (with-current-buffer buffer
 264     (let ((filename
 265            (or buffer-file-name
 266                (if (memq major-mode uniquify-list-buffers-directory-modes)
 267                    list-buffers-directory))))
 268       (when filename
 269         (directory-file-name
 270          (file-name-directory
 271           (expand-file-name
 272            (directory-file-name filename))))))))
 273
 274 (defun uniquify-rerationalize-w/o-cb (fix-list)
 275   "Re-rationalize the buffers in FIX-LIST, but ignoring `current-buffer'."
 276   (let ((new-fix-list nil))
 277     (dolist (item fix-list)
 278       (let ((buf (uniquify-item-buffer item)))
 279         (unless (or (eq buf (current-buffer)) (not (buffer-live-p buf)))
 280           (push item new-fix-list))))
 281     (when new-fix-list
 282       (uniquify-rationalize new-fix-list))))
 283
 284 (defun uniquify-rationalize (fix-list)
 285   ;; Set up uniquify to re-rationalize after killing/renaming
 286   ;; if there is a conflict.
 287   (dolist (item fix-list)
 288     (with-current-buffer (uniquify-item-buffer item)
 289       ;; Refresh the dirnames and proposed names.
 290       (setf (uniquify-item-proposed item)
 291             (uniquify-get-proposed-name (uniquify-item-base item)
 292                                         (uniquify-item-dirname item)))
 293       (setq uniquify-managed fix-list)))
 294   ;; Strip any shared last directory names of the dirname.
 295   (when (and (cdr fix-list) uniquify-strip-common-suffix)
 296     (let ((strip t))
 297       (while (let* ((base (file-name-nondirectory
 298                            (uniquify-item-dirname (car fix-list))))
 299                     (items fix-list))
 300                (when (> (length base) 0)
 301                  (while (and strip items)
 302                    (unless (equal base (file-name-nondirectory
 303                                         (uniquify-item-dirname (pop items))))
 304                      (setq strip nil)))
 305                  strip))
 306         ;; It's all the same => strip.
 307         (dolist (item (prog1 fix-list (setq fix-list nil)))
 308           ;; Create new items because the old ones are kept (with the true
 309           ;; `dirname') for later rerationalizing.
 310           (push (uniquify-make-item (uniquify-item-base item)
 311                                     (let ((f (file-name-directory
 312                                               (uniquify-item-dirname item))))
 313                                       (and f (directory-file-name f)))
 314                                     (uniquify-item-buffer item)
 315                                     (uniquify-item-proposed item))
 316                 fix-list)))))
 317   ;; If uniquify-min-dir-content is 0, this will end up just
 318   ;; passing fix-list to uniquify-rationalize-conflicting-sublist.
 319   (uniquify-rationalize-a-list fix-list))
 320
 321 (defun uniquify-item-greaterp (item1 item2)
 322   (string-lessp (uniquify-item-proposed item2)
 323                 (uniquify-item-proposed item1)))
 324
 325 (defun uniquify-rationalize-a-list (fix-list &optional depth)
 326   (unless depth (setq depth uniquify-min-dir-content))
 327   (let (conflicting-sublist     ; all elements have the same proposed name
 328         (old-proposed "")
 329         proposed)
 330     ;; Divide fix-list into items with same proposed names and pass them
 331     ;; to uniquify-rationalize-conflicting-sublist.
 332     (dolist (item (sort (copy-sequence fix-list) 'uniquify-item-greaterp))
 333       (setq proposed (uniquify-item-proposed item))
 334       (unless (equal proposed old-proposed)
 335         (uniquify-rationalize-conflicting-sublist conflicting-sublist
 336                                                   old-proposed depth)
 337         (setq conflicting-sublist nil))
 338       (push item conflicting-sublist)
 339       (setq old-proposed proposed))
 340     (uniquify-rationalize-conflicting-sublist conflicting-sublist
 341                                               old-proposed depth)))
 342
 343 (defun uniquify-get-proposed-name (base dirname &optional depth)
 344   (unless depth (setq depth uniquify-min-dir-content))
 345   (assert (equal (directory-file-name dirname) dirname))  ;No trailing slash.
 346
 347   ;; Distinguish directories by adding extra separator.
 348   (if (and uniquify-trailing-separator-p
 349            (file-directory-p (expand-file-name base dirname))
 350            (not (string-equal base "")))
 351       (cond ((eq uniquify-buffer-name-style 'forward)
 352              (setq base (file-name-as-directory base)))
 353             ;; (setq base (concat base "/")))
 354             ((eq uniquify-buffer-name-style 'reverse)
 355              (setq base (concat (or uniquify-separator "\\") base)))))
 356
 357   (let ((extra-string nil)
 358         (n depth))
 359     (while (and (> n 0) dirname)
 360       (let ((file (file-name-nondirectory dirname)))
 361         (when (setq dirname (file-name-directory dirname))
 362           (setq dirname (directory-file-name dirname)))
 363         (setq n (1- n))
 364         (push (if (zerop (length file)) ;nil or "".
 365                   (prog1 "" (setq dirname nil)) ;Could be `dirname' iso "".
 366                 file)
 367               extra-string)))
 368     (when (zerop n)
 369       (if (and dirname extra-string
 370                (equal dirname (file-name-directory dirname)))
 371           ;; We're just before the root.  Let's add the leading / already.
 372           ;; With "/a/b"+"/c/d/b" this leads to "/a/b" and "d/b" but with
 373           ;; "/a/b"+"/c/a/b" this leads to "/a/b" and "a/b".
 374           (push "" extra-string))
 375       (setq uniquify-possibly-resolvable t))
 376
 377     (cond
 378      ((null extra-string) base)
 379      ((string-equal base "") ;Happens for dired buffers on the root directory.
 380       (mapconcat 'identity extra-string "/"))
 381      ((eq uniquify-buffer-name-style 'reverse)
 382       (mapconcat 'identity
 383                  (cons base (nreverse extra-string))
 384                  (or uniquify-separator "\\")))
 385      ((eq uniquify-buffer-name-style 'forward)
 386       (mapconcat 'identity (nconc extra-string (list base))
 387                  "/"))
 388      ((eq uniquify-buffer-name-style 'post-forward)
 389       (concat base (or uniquify-separator "|")
 390               (mapconcat 'identity extra-string "/")))
 391      ((eq uniquify-buffer-name-style 'post-forward-angle-brackets)
 392       (concat base "<" (mapconcat 'identity extra-string "/")
 393               ">"))
 394      (t (error "Bad value for uniquify-buffer-name-style: %s"
 395                uniquify-buffer-name-style)))))
 396
 397
 398 ;; Deal with conflicting-sublist, all of whose elements have identical
 399 ;; "base" components.
 400 (defun uniquify-rationalize-conflicting-sublist (conf-list old-name depth)
 401   (when conf-list
 402     (if (or (cdr conf-list)
 403             ;; Check that the proposed name doesn't conflict with some
 404             ;; existing buffer.
 405             (let ((buf (get-buffer old-name)))
 406               (and buf (not (eq buf (uniquify-item-buffer (car conf-list)))))))
 407         (when uniquify-possibly-resolvable
 408           (setq uniquify-possibly-resolvable nil
 409                 depth (1+ depth))
 410           (dolist (item conf-list)
 411             (setf (uniquify-item-proposed item)
 412                   (uniquify-get-proposed-name
 413                    (uniquify-item-base item)
 414                    (uniquify-item-dirname item)
 415                    depth)))
 416           (uniquify-rationalize-a-list conf-list depth))
 417       (unless (string= old-name "")
 418         (uniquify-rename-buffer (car conf-list) old-name)))))
 419
 420
 421 (defun uniquify-rename-buffer (item newname)
 422   (let ((buffer (uniquify-item-buffer item)))
 423     (unless (equal newname (buffer-name buffer))
 424       (with-current-buffer buffer
 425         (let ((uniquify-buffer-name-style nil)) ;Avoid hooks on rename-buffer.
 426           ;; Pass the `unique' arg, so the advice doesn't mark it as unmanaged.
 427           (rename-buffer newname t))))))
 428
 429 ;;; Hooks from the rest of Emacs
 430
 431 ;; Buffer deletion
 432 ;; Rerationalize after a buffer is killed, to reduce coinciding buffer names.
 433 ;; This mechanism uses `kill-buffer-hook', which runs *before* deletion, so
 434 ;; it calls `uniquify-rerationalize-w/o-cb' to rerationalize the buffer list
 435 ;; ignoring the current buffer (which is going to be deleted anyway).
 436 (defun uniquify-maybe-rerationalize-w/o-cb ()
 437   "Re-rationalize buffer names, ignoring current buffer.
 438 For use on `kill-buffer-hook'."
 439   (if (and (cdr uniquify-managed)
 440            uniquify-buffer-name-style
 441            uniquify-after-kill-buffer-p)
 442       (uniquify-rerationalize-w/o-cb uniquify-managed)))
 443
 444 ;; Ideally we'd like to add it buffer-locally, but that doesn't work
 445 ;; because kill-buffer-hook is not permanent-local :-(
 446 (add-hook 'kill-buffer-hook 'uniquify-maybe-rerationalize-w/o-cb)
 447
 448 ;; The logical place to put all this code is in generate-new-buffer-name.
 449 ;; It's written in C, so we would add a generate-new-buffer-name-function
 450 ;; which, if non-nil, would be called instead of the C.  One problem with
 451 ;; that is that generate-new-buffer-name takes a potential buffer name as
 452 ;; its argument -- not other information, such as what file the buffer will
 453 ;; visit.
 454
 455 ;; The below solution works because generate-new-buffer-name is called
 456 ;; only by rename-buffer (which, as of 19.29, is never called from C) and
 457 ;; generate-new-buffer, which is called only by Lisp functions
 458 ;; create-file-buffer and rename-uniquely.  Rename-uniquely generally
 459 ;; isn't used for buffers visiting files, so it's sufficient to hook
 460 ;; rename-buffer and create-file-buffer.  (Setting find-file-hook isn't
 461 ;; sufficient.)
 462
 463 (defadvice rename-buffer (after rename-buffer-uniquify activate)
 464   "Uniquify buffer names with parts of directory name."
 465   (uniquify-maybe-rerationalize-w/o-cb)
 466   (if (null (ad-get-arg 1))             ; no UNIQUE argument.
 467       ;; Mark this buffer so it won't be renamed by uniquify.
 468       (setq uniquify-managed nil)
 469     (when uniquify-buffer-name-style
 470       ;; Rerationalize w.r.t the new name.
 471       (uniquify-rationalize-file-buffer-names
 472        (ad-get-arg 0)
 473        (uniquify-buffer-file-name (current-buffer))
 474        (current-buffer))
 475       (setq ad-return-value (buffer-name (current-buffer))))))
 476
 477 (defadvice create-file-buffer (after create-file-buffer-uniquify activate)
 478   "Uniquify buffer names with parts of directory name."
 479   (if uniquify-buffer-name-style
 480       (let ((filename (expand-file-name (directory-file-name (ad-get-arg 0)))))
 481         (uniquify-rationalize-file-buffer-names
 482          (file-name-nondirectory filename)
 483          (file-name-directory filename) ad-return-value))))
 484
 485 ;;; The End
 486
 487 (defun uniquify-unload-function ()
 488   "Unload the uniquify library."
 489   (save-current-buffer
 490     (let ((buffers nil))
 491       (dolist (buf (buffer-list))
 492         (set-buffer buf)
 493         (when uniquify-managed
 494           (push (cons buf (uniquify-item-base (car uniquify-managed))) buffers)))
 495       (dolist (fun '(rename-buffer create-file-buffer))
 496         (ad-remove-advice fun 'after (intern (concat (symbol-name fun) "-uniquify")))
 497         (ad-update fun))
 498       (dolist (buf buffers)
 499         (set-buffer (car buf))
 500         (rename-buffer (cdr buf) t))))
 501   ;; continue standard unloading
 502   nil)
 503
 504 (provide 'uniquify)
 505
 506 ;; arch-tag: e763faa3-56c9-4903-8eb8-26e1c45a0065
 507 ;;; uniquify.el ends here