lisp/telnet.el

   1 ;;; telnet.el --- run a telnet session from within an Emacs buffer
   2
   3 ;;; Copyright (C) 1985, 1988, 1992, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: William F. Schelter
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This mode is intended to be used for telnet or rsh to a remode host;
  27 ;; `telnet' and `rsh' are the two entry points.  Multiple telnet or rsh
  28 ;; sessions are supported.
  29 ;;
  30 ;; Normally, input is sent to the remote telnet/rsh line-by-line, as you
  31 ;; type RET or LFD.  C-c C-c sends a C-c to the remote immediately;
  32 ;; C-c C-z sends C-z immediately.  C-c C-q followed by any character
  33 ;; sends that character immediately.
  34 ;;
  35 ;; All RET characters are filtered out of the output coming back from the
  36 ;; remote system.  The mode tries to do other useful translations based
  37 ;; on what it sees coming back from the other system before the password
  38 ;; query.  It knows about UNIX, ITS, TOPS-20 and Explorer systems.
  39
  40 ;;; Code:
  41
  42 ;; to do fix software types for lispm:
  43 ;; to eval current expression.  Also to try to send escape keys correctly.
  44 ;; essentially we'll want the rubout-handler off.
  45
  46 ;; filter is simplistic but should be okay for typical shell usage.
  47 ;; needs hacking if it is going to deal with asynchronous output in a sane
  48 ;; manner
  49
  50 (require 'comint)
  51
  52 (defvar telnet-new-line "\r")
  53 (defvar telnet-mode-map nil)
  54 (defvar telnet-prompt-pattern "^[^#$%>\n]*[#$%>] *")
  55 (defvar telnet-replace-c-g nil)
  56 (make-variable-buffer-local
  57  (defvar telnet-remote-echoes t
  58    "True if the telnet process will echo input."))
  59 (make-variable-buffer-local
  60  (defvar telnet-interrupt-string "\C-c" "String sent by C-c."))
  61
  62 (defvar telnet-count 0
  63   "Number of output strings from telnet process while looking for password.")
  64 (make-variable-buffer-local 'telnet-count)
  65
  66 (defvar telnet-program "telnet"
  67   "Program to run to open a telnet connection.")
  68
  69 (defvar rsh-program
  70   (if (memq system-type '(hpux usg-unix-v))
  71       "remsh" "rsh")
  72   "Program to run for opening a remote shell.")
  73
  74 (defvar telnet-initial-count -50
  75   "Initial value of `telnet-count'.  Should be set to the negative of the
  76 number of terminal writes telnet will make setting up the host connection.")
  77
  78 (defvar telnet-maximum-count 4
  79   "Maximum value `telnet-count' can have.
  80 After this many passes, we stop looking for initial setup data.
  81 Should be set to the number of terminal writes telnet will make
  82 rejecting one login and prompting again for a username and password.")
  83
  84 (defun telnet-interrupt-subjob ()
  85   (interactive)
  86   "Interrupt the program running through telnet on the remote host."
  87   (send-string nil telnet-interrupt-string))
  88
  89 (defun telnet-c-z ()
  90   (interactive)
  91   (send-string nil "\C-z"))
  92
  93 (defun send-process-next-char ()
  94   (interactive)
  95   (send-string nil
  96                (char-to-string
  97                 (let ((inhibit-quit t))
  98                   (prog1 (read-char)
  99                     (setq quit-flag nil))))))
 100
 101 ; initialization on first load.
 102 (if telnet-mode-map
 103     nil
 104   (setq telnet-mode-map (copy-keymap comint-mode-map))
 105   (define-key telnet-mode-map "\C-m" 'telnet-send-input)
 106 ;  (define-key telnet-mode-map "\C-j" 'telnet-send-input)
 107   (define-key telnet-mode-map "\C-c\C-q" 'send-process-next-char)
 108   (define-key telnet-mode-map "\C-c\C-c" 'telnet-interrupt-subjob)
 109   (define-key telnet-mode-map "\C-c\C-z" 'telnet-c-z))
 110
 111 ;;maybe should have a flag for when have found type
 112 (defun telnet-check-software-type-initialize (string)
 113   "Tries to put correct initializations in.  Needs work."
 114   (let ((case-fold-search t))
 115     (cond ((string-match "unix" string)
 116          (setq telnet-prompt-pattern comint-prompt-regexp)
 117          (setq telnet-new-line "\n"))
 118         ((string-match "tops-20" string) ;;maybe add telnet-replace-c-g
 119          (setq telnet-prompt-pattern  "[@>]*"))
 120         ((string-match "its" string)
 121          (setq telnet-prompt-pattern  "^[^*>\n]*[*>] *"))
 122         ((string-match "explorer" string)  ;;explorer telnet needs work
 123          (setq telnet-replace-c-g ?\n))))
 124   (setq comint-prompt-regexp telnet-prompt-pattern))
 125
 126 (defun telnet-initial-filter (proc string)
 127   ;For reading up to and including password; also will get machine type.
 128   (cond ((string-match "No such host" string)
 129          (kill-buffer (process-buffer proc))
 130          (error "No such host."))
 131         ((string-match "passw" string)
 132          (telnet-filter proc string)
 133          (setq telnet-count 0)
 134          (send-string proc (concat (comint-read-noecho "Password: " t)
 135                                    telnet-new-line)))
 136         (t (telnet-check-software-type-initialize string)
 137            (telnet-filter proc string)
 138            (cond ((> telnet-count telnet-maximum-count)
 139                   (set-process-filter proc 'telnet-filter))
 140                  (t (setq telnet-count (1+ telnet-count)))))))
 141
 142 ;; Identical to comint-simple-send, except that it sends telnet-new-line
 143 ;; instead of "\n".
 144 (defun telnet-simple-send (proc string)
 145   (comint-send-string proc string)
 146   (comint-send-string proc telnet-new-line))
 147
 148 (defun telnet-filter (proc string)
 149   (save-excursion
 150     (set-buffer (process-buffer proc))
 151     (let* ((last-insertion (marker-position (process-mark proc)))
 152            (delta (- (point) last-insertion))
 153            (ie (and comint-last-input-end
 154                     (marker-position comint-last-input-end)))
 155            (w (get-buffer-window (current-buffer)))
 156            (ws (and w (window-start w))))
 157       (goto-char last-insertion)
 158       (insert-before-markers string)
 159       (set-marker (process-mark proc) (point))
 160       (if ws (set-window-start w ws t))
 161       (if ie (set-marker comint-last-input-end ie))
 162       (while (progn (skip-chars-backward "^\C-m" last-insertion)
 163                     (> (point) last-insertion))
 164         (delete-region (1- (point)) (point)))
 165       (goto-char (process-mark proc))
 166       (and telnet-replace-c-g
 167            (subst-char-in-region last-insertion (point) ?\C-g
 168                                  telnet-replace-c-g t))
 169       ;; If point is after the insertion place, move it
 170       ;; along with the text.
 171       (if (> delta 0)
 172           (goto-char (+ (process-mark proc) delta))))))
 173
 174 (defun telnet-send-input ()
 175   (interactive)
 176 ;  (comint-send-input telnet-new-line telnet-remote-echoes)
 177   (comint-send-input)
 178   (if telnet-remote-echoes
 179       (delete-region comint-last-input-start
 180                      comint-last-input-end)))
 181
 182 ;;;###autoload
 183 (defun telnet (host)
 184   "Open a network login connection to host named HOST (a string).
 185 Communication with HOST is recorded in a buffer *HOST-telnet*.
 186 Normally input is edited in Emacs and sent a line at a time."
 187   (interactive "sOpen telnet connection to host: ")
 188   (let* ((comint-delimiter-argument-list '(?\  ?\t))
 189          (name (concat (comint-arguments host 0 nil) "-telnet" ))
 190          (buffer (get-buffer (concat "*" name "*"))))
 191     (if (and buffer (get-buffer-process buffer))
 192         (switch-to-buffer (concat "*" name "*"))
 193       (switch-to-buffer (make-comint name telnet-program))
 194       (set-process-filter (get-process name) 'telnet-initial-filter)
 195       ;; Don't send the `open' cmd till telnet is ready for it.
 196       (accept-process-output (get-process name))
 197       (erase-buffer)
 198       (send-string  name (concat "open " host "\n"))
 199       (telnet-mode)
 200       (setq comint-input-sender 'telnet-simple-send)
 201       (setq telnet-count telnet-initial-count))))
 202
 203 (defun telnet-mode ()
 204   "This mode is for using telnet (or rsh) from a buffer to another host.
 205 It has most of the same commands as comint-mode.
 206 There is a variable ``telnet-interrupt-string'' which is the character
 207 sent to try to stop execution of a job on the remote host.
 208 Data is sent to the remote host when RET is typed.
 209
 210 \\{telnet-mode-map}
 211 "
 212   (interactive)
 213   (comint-mode)
 214   (setq major-mode 'telnet-mode
 215         mode-name "Telnet"
 216         comint-prompt-regexp telnet-prompt-pattern)
 217   (use-local-map telnet-mode-map)
 218   (run-hooks 'telnet-mode-hook))
 219
 220 ;;;###autoload
 221 (defun rsh (host)
 222   "Open a network login connection to host named HOST (a string).
 223 Communication with HOST is recorded in a buffer *HOST-rsh*.
 224 Normally input is edited in Emacs and sent a line at a time."
 225   (interactive "sOpen rsh connection to host: ")
 226   (require 'shell)
 227   (let ((name (concat host "-rsh" )))
 228     (switch-to-buffer (make-comint name rsh-program nil host))
 229     (set-process-filter (get-process name) 'telnet-initial-filter)
 230     (telnet-mode)
 231     (setq telnet-count -16)))
 232
 233 (provide 'telnet)
 234
 235 ;;; telnet.el ends here