lisp/isearch.el

   1 ;;; isearch.el --- incremental search minor mode.
   2
   3 ;; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel LaLiberte <liberte@cs.uiuc.edu>
   6
   7 ;; |$Date: 1994/08/30 07:03:33 $|$Revision: 1.72 $
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;;====================================================================
  28 ;; Instructions
  29
  30 ;; For programmed use of isearch-mode, e.g. calling (isearch-forward),
  31 ;; isearch-mode behaves modally and does not return until the search
  32 ;; is completed.  It uses a recursive-edit to behave this way.  Note:
  33 ;; gnus does it wrong: (call-interactively 'isearch-forward).
  34
  35 ;; The key bindings active within isearch-mode are defined below in
  36 ;; `isearch-mode-map' which is given bindings close to the default
  37 ;; characters of the original isearch.el.  With `isearch-mode',
  38 ;; however, you can bind multi-character keys and it should be easier
  39 ;; to add new commands.  One bug though: keys with meta-prefix cannot
  40 ;; be longer than two chars.  Also see minibuffer-local-isearch-map
  41 ;; for bindings active during `isearch-edit-string'.
  42
  43 ;; Note to emacs version 19 users: isearch-mode should work even if
  44 ;; you switch windows with the mouse, in which case isearch-mode is
  45 ;; terminated automatically before the switch.  This is true of lemacs
  46 ;; too, with a few more cleanups I've neglected in this release.
  47 ;; No one has supplied patches for epoch yet.
  48
  49 ;; The search ring and completion commands automatically put you in
  50 ;; the minibuffer to edit the string.  This gives you a chance to
  51 ;; modify the search string before executing the search.  There are
  52 ;; three commands to terminate the editing: C-s and C-r exit the
  53 ;; minibuffer and search forward and reverse respectively, while C-m
  54 ;; exits and does a nonincremental search.
  55
  56 ;; Exiting immediately from isearch uses isearch-edit-string instead
  57 ;; of nonincremental-search, if search-nonincremental-instead is non-nil.
  58 ;; The name of this option should probably be changed if we decide to
  59 ;; keep the behavior.  No point in forcing nonincremental search until
  60 ;; the last possible moment.
  61
  62 ;; TODO
  63 ;; - Integrate the emacs 19 generalized command history.
  64 ;; - Think about incorporating query-replace.
  65 ;; - Hooks and options for failed search.
  66
  67 ;;; Change Log:
  68
  69 ;;; Changes before those recorded in ChangeLog:
  70
  71 ;;; Revision 1.4  92/09/14  16:26:02  liberte
  72 ;;; Added prefix args to isearch-forward, etc. to switch between
  73 ;;;    string and regular expression searching.
  74 ;;; Added some support for lemacs.
  75 ;;; Added general isearch-highlight option - but only for lemacs so far.
  76 ;;; Added support for frame switching in emacs 19.
  77 ;;; Added word search option to isearch-edit-string.
  78 ;;; Renamed isearch-quit to isearch-abort.
  79 ;;; Numerous changes to comments and doc strings.
  80 ;;;
  81 ;;; Revision 1.3  92/06/29  13:10:08  liberte
  82 ;;; Moved modal isearch-mode handling into isearch-mode.
  83 ;;; Got rid of buffer-local isearch variables.
  84 ;;; isearch-edit-string used by ring adjustments, completion, and
  85 ;;; nonincremental searching.  C-s and C-r are additional exit commands.
  86 ;;; Renamed all regex to regexp.
  87 ;;; Got rid of found-start and found-point globals.
  88 ;;; Generalized handling of upper-case chars.
  89
  90 ;;; Revision 1.2  92/05/27  11:33:57  liberte
  91 ;;; Emacs version 19 has a search ring, which is supported here.
  92 ;;; Other fixes found in the version 19 isearch are included here.
  93 ;;;
  94 ;;; Also see variables search-caps-disable-folding,
  95 ;;; search-nonincremental-instead, search-whitespace-regexp, and
  96 ;;; commands isearch-toggle-regexp, isearch-edit-string.
  97 ;;;
  98 ;;; semi-modal isearching is supported.
  99
 100 ;;; Changes for 1.1
 101 ;;; 3/18/92 Fixed invalid-regexp.
 102 ;;; 3/18/92 Fixed yanking in regexps.
 103
 104 ;;; Code:
 105
 106 \f
 107 ;;;=========================================================================
 108 ;;; Emacs features
 109
 110 ;; isearch-mode takes advantage of the features provided by several
 111 ;; different versions of emacs.  Rather than testing the version of
 112 ;; emacs, several constants are defined, one for each of the features.
 113 ;; Each of the tests below must work on any version of emacs.
 114 ;; (Perhaps provide and featurep could be used for this purpose.)
 115
 116 (defconst isearch-gnu-emacs-events (fboundp 'set-frame-height)) ;; emacs 19
 117 (defconst isearch-pre-command-hook-exists (boundp 'pre-command-hook)) ;; lemacs
 118 (defconst isearch-event-data-type nil)  ;; lemacs
 119
 120 (defconst search-exit-option t
 121   "*Non-nil means random control characters terminate incremental search.")
 122
 123 (defvar search-slow-window-lines 1
 124   "*Number of lines in slow search display windows.
 125 These are the short windows used during incremental search on slow terminals.
 126 Negative means put the slow search window at the top (normally it's at bottom)
 127 and the value is minus the number of lines.")
 128
 129 (defvar search-slow-speed 1200
 130   "*Highest terminal speed at which to use \"slow\" style incremental search.
 131 This is the style where a one-line window is created to show the line
 132 that the search has reached.")
 133
 134 ;;;========================================================================
 135 ;;; Some additional options and constants.
 136
 137 (defvar search-upper-case 'not-yanks
 138   "*If non-nil, upper case chars disable case fold searching.
 139 That is, upper and lower case chars must match exactly.
 140 This applies no matter where the chars come from, but does not
 141 apply to chars in regexps that are prefixed with `\\'.
 142 If this value is `not-yanks', yanked text is always downcased.")
 143
 144 (defvar search-nonincremental-instead t
 145   "*If non-nil, do a nonincremental search instead if exiting immediately.
 146 Actually, `isearch-edit-string' is called to let you enter the search
 147 string, and RET terminates editing and does a nonincremental search.")
 148
 149 (defconst search-whitespace-regexp "\\s-+"
 150   "*If non-nil, regular expression to match a sequence of whitespace chars.
 151 You might want to use something like \"[ \\t\\r\\n]+\" instead.")
 152
 153 ;; I removed the * from the doc string because highlighting is not
 154 ;; currently a clean thing to do.  Once highlighting is made clean,
 155 ;; this feature can be re-enabled and advertised.
 156 (defvar search-highlight nil
 157   "*Non-nil means incremental search highlights the current match.")
 158
 159 (defvar isearch-mode-hook nil
 160   "Function(s) to call after starting up an incremental search.")
 161
 162 (defvar isearch-mode-end-hook nil
 163   "Function(s) to call after terminating an incremental search.")
 164
 165 ;;;==================================================================
 166 ;;; Search ring.
 167
 168 (defvar search-ring nil
 169   "List of search string sequences.")
 170 (defvar regexp-search-ring nil
 171   "List of regular expression search string sequences.")
 172
 173 (defconst search-ring-max 16
 174   "*Maximum length of search ring before oldest elements are thrown away.")
 175 (defconst regexp-search-ring-max 16
 176   "*Maximum length of regexp search ring before oldest elements are thrown away.")
 177
 178 (defvar search-ring-yank-pointer nil
 179   "Index in `search-ring' of last string reused.
 180 nil if none yet.")
 181 (defvar regexp-search-ring-yank-pointer nil
 182   "Index in `regexp-search-ring' of last string reused.
 183 nil if none yet.")
 184
 185 (defvar search-ring-update nil
 186   "*Non-nil if advancing or retreating in the search ring should cause search.
 187 Default value, nil, means edit the string instead.")
 188
 189 ;;;====================================================
 190 ;;; Define isearch-mode keymap.
 191
 192 (defvar isearch-mode-map nil
 193   "Keymap for isearch-mode.")
 194
 195 (or isearch-mode-map
 196     (let* ((i 0)
 197            (map (make-keymap)))
 198       (or (vectorp (nth 1 map))
 199           (error "The initialization of isearch-mode-map must be updated"))
 200       ;; Give this map a vector 256 long, for dense binding
 201       ;; of a larger range of ordinary characters.
 202       (setcar (cdr map) (make-vector 256 nil))
 203
 204       ;; Make function keys, etc, exit the search.
 205       (define-key map [t] 'isearch-other-control-char)
 206       ;; Control chars, by default, end isearch mode transparently.
 207       ;; We need these explicit definitions because, in a dense keymap,
 208       ;; the binding for t does not affect characters.
 209       ;; We use a dense keymap to save space.
 210       (while (< i ?\ )
 211         (define-key map (make-string 1 i) 'isearch-other-control-char)
 212         (setq i (1+ i)))
 213
 214       ;; Printing chars extend the search string by default.
 215       (setq i ?\ )
 216       (while (< i (length (nth 1 map)))
 217         (define-key map (vector i) 'isearch-printing-char)
 218         (setq i (1+ i)))
 219
 220       ;; Several non-printing chars change the searching behavior.
 221       (define-key map "\C-s" 'isearch-repeat-forward)
 222       (define-key map "\C-r" 'isearch-repeat-backward)
 223       (define-key map "\177" 'isearch-delete-char)
 224       (define-key map "\C-g" 'isearch-abort)
 225
 226       (define-key map "\C-q" 'isearch-quote-char)
 227
 228       (define-key map "\r" 'isearch-exit)
 229       (define-key map "\C-j" 'isearch-printing-char)
 230       (define-key map "\t" 'isearch-printing-char)
 231       (define-key map " " 'isearch-whitespace-chars)
 232
 233       (define-key map "\C-w" 'isearch-yank-word)
 234       (define-key map "\C-y" 'isearch-yank-line)
 235
 236       ;; Bind the ASCII-equivalent "function keys" explicitly to nil
 237       ;; so that the default binding does not apply.
 238       ;; As a result, these keys translate thru function-key-map
 239       ;; as normal, and they have the effect of the equivalent ASCII char.
 240       ;; We bind [escape] below.
 241       (define-key map [tab] 'nil)
 242       (define-key map [kp-0] 'nil)
 243       (define-key map [kp-1] 'nil)
 244       (define-key map [kp-2] 'nil)
 245       (define-key map [kp-3] 'nil)
 246       (define-key map [kp-4] 'nil)
 247       (define-key map [kp-5] 'nil)
 248       (define-key map [kp-6] 'nil)
 249       (define-key map [kp-7] 'nil)
 250       (define-key map [kp-8] 'nil)
 251       (define-key map [kp-9] 'nil)
 252       (define-key map [kp-add] 'nil)
 253       (define-key map [kp-subtract] 'nil)
 254       (define-key map [kp-multiply] 'nil)
 255       (define-key map [kp-divide] 'nil)
 256       (define-key map [kp-decimal] 'nil)
 257       (define-key map [kp-separator] 'nil)
 258       (define-key map [kp-equal] 'nil)
 259       (define-key map [kp-tab] 'nil)
 260       (define-key map [kp-space] 'nil)
 261       (define-key map [kp-enter] 'nil)
 262       (define-key map [delete] 'nil)
 263       (define-key map [backspace] 'nil)
 264       (define-key map [return] 'nil)
 265       (define-key map [newline] 'nil)
 266
 267       ;; Define keys for regexp chars * ? |.
 268       ;; Nothing special for + because it matches at least once.
 269       (define-key map "*" 'isearch-*-char)
 270       (define-key map "?" 'isearch-*-char)
 271       (define-key map "|" 'isearch-|-char)
 272
 273 ;;; Turned off because I find I expect to get the global definition--rms.
 274 ;;;      ;; Instead bind C-h to special help command for isearch-mode.
 275 ;;;      (define-key map "\C-h" 'isearch-mode-help)
 276
 277       ;; To handle local bindings with meta char prefix keys, define
 278       ;; another full keymap.  This must be done for any other prefix
 279       ;; keys as well, one full keymap per char of the prefix key.  It
 280       ;; would be simpler to disable the global keymap, and/or have a
 281       ;; default local key binding for any key not otherwise bound.
 282       (let ((meta-map (make-sparse-keymap)))
 283         (define-key map (char-to-string meta-prefix-char) meta-map)
 284         (define-key map [escape] meta-map))
 285       (define-key map (vector meta-prefix-char t) 'isearch-other-meta-char)
 286
 287       (define-key map "\M-n" 'isearch-ring-advance)
 288       (define-key map "\M-p" 'isearch-ring-retreat)
 289       (define-key map "\M-y" 'isearch-yank-kill)
 290
 291       (define-key map "\M-\t" 'isearch-complete)
 292
 293       ;; For emacs 19, switching frames should terminate isearch-mode
 294       (if isearch-gnu-emacs-events
 295           (define-key map [switch-frame] 'isearch-switch-frame-handler))
 296
 297       (setq isearch-mode-map map)
 298       ))
 299
 300 ;; Some bindings you may want to put in your isearch-mode-hook.
 301 ;; Suggest some alternates...
 302 ;; (define-key isearch-mode-map "\C-t" 'isearch-toggle-case-fold)
 303 ;; (define-key isearch-mode-map "\C-t" 'isearch-toggle-regexp)
 304 ;; (define-key isearch-mode-map "\C-^" 'isearch-edit-string)
 305
 306
 307 (defvar minibuffer-local-isearch-map nil
 308   "Keymap for editing isearch strings in the minibuffer.")
 309
 310 (or minibuffer-local-isearch-map
 311     (let ((map (copy-keymap minibuffer-local-map)))
 312       (define-key map "\r" 'isearch-nonincremental-exit-minibuffer)
 313       (define-key map "\M-n" 'isearch-ring-advance-edit)
 314       (define-key map "\M-p" 'isearch-ring-retreat-edit)
 315       (define-key map "\M-\t" 'isearch-complete-edit)
 316       (define-key map "\C-s" 'isearch-forward-exit-minibuffer)
 317       (define-key map "\C-r" 'isearch-reverse-exit-minibuffer)
 318       (setq minibuffer-local-isearch-map map)
 319       ))
 320
 321 ;;;========================================================
 322 ;; Internal variables declared globally for byte-compiler.
 323 ;; These are all set with setq while isearching
 324 ;; and bound locally while editing the search string.
 325
 326 (defvar isearch-forward nil)    ; Searching in the forward direction.
 327 (defvar isearch-regexp nil)     ; Searching for a regexp.
 328 (defvar isearch-word nil)       ; Searching for words.
 329
 330 (defvar isearch-cmds nil)   ; Stack of search status sets.
 331 (defvar isearch-string "")  ; The current search string.
 332 (defvar isearch-message "") ; text-char-description version of isearch-string
 333
 334 (defvar isearch-success t)              ; Searching is currently successful.
 335 (defvar isearch-invalid-regexp nil)     ; Regexp not well formed.
 336 (defvar isearch-within-brackets nil)    ; Regexp has unclosed [.
 337 (defvar isearch-other-end nil)  ; Start (end) of match if forward (backward).
 338 (defvar isearch-wrapped nil)    ; Searching restarted from the top (bottom).
 339 (defvar isearch-barrier 0)
 340
 341 ; case-fold-search while searching.
 342 ;   either nil, t, or 'yes.  'yes means the same as t except that mixed
 343 ;   case in the search string is ignored.
 344 (defvar isearch-case-fold-search nil)
 345
 346 (defvar isearch-adjusted nil)
 347 (defvar isearch-slow-terminal-mode nil)
 348 ;;; If t, using a small window.
 349 (defvar isearch-small-window nil)
 350 (defvar isearch-opoint 0)
 351 ;;; The window configuration active at the beginning of the search.
 352 (defvar isearch-window-configuration nil)
 353
 354 ;; Flag to indicate a yank occurred, so don't move the cursor.
 355 (defvar isearch-yank-flag nil)
 356
 357 ;;; A function to be called after each input character is processed.
 358 ;;; (It is not called after characters that exit the search.)
 359 ;;; It is only set from an optional argument to `isearch-mode'.
 360 (defvar isearch-op-fun nil)
 361
 362 ;;;  Is isearch-mode in a recursive edit for modal searching.
 363 (defvar isearch-recursive-edit nil)
 364
 365 ;;; Should isearch be terminated after doing one search?
 366 (defvar isearch-nonincremental nil)
 367
 368 ;; New value of isearch-forward after isearch-edit-string.
 369 (defvar isearch-new-forward nil)
 370
 371
 372 ;;;==============================================================
 373 ;; Minor-mode-alist changes - kind of redundant with the
 374 ;; echo area, but if isearching in multiple windows, it can be useful.
 375
 376 (or (assq 'isearch-mode minor-mode-alist)
 377     (nconc minor-mode-alist
 378            (list '(isearch-mode isearch-mode))))
 379
 380 (defvar isearch-mode nil) ;; Name of the minor mode, if non-nil.
 381 (make-variable-buffer-local 'isearch-mode)
 382
 383 (define-key global-map "\C-s" 'isearch-forward)
 384 (define-key esc-map "\C-s" 'isearch-forward-regexp)
 385 (define-key global-map "\C-r" 'isearch-backward)
 386 (define-key esc-map "\C-r" 'isearch-backward-regexp)
 387
 388 ;;;===============================================================
 389 ;;; Entry points to isearch-mode.
 390 ;;; These four functions should replace those in loaddefs.el
 391 ;;; An alternative is to defalias isearch-forward etc to isearch-mode,
 392 ;;; and look at this-command to set the options accordingly.
 393
 394 (defun isearch-forward (&optional regexp-p no-recursive-edit)
 395   "\
 396 Do incremental search forward.
 397 With a prefix argument, do an incremental regular expression search instead.
 398 \\<isearch-mode-map>
 399 As you type characters, they add to the search string and are found.
 400 The following non-printing keys are bound in `isearch-mode-map'.
 401
 402 Type \\[isearch-delete-char] to cancel characters from end of search string.
 403 Type \\[isearch-exit] to exit, leaving point at location found.
 404 Type LFD (C-j) to match end of line.
 405 Type \\[isearch-repeat-forward] to search again forward,\
 406  \\[isearch-repeat-backward] to search again backward.
 407 Type \\[isearch-yank-word] to yank word from buffer onto end of search\
 408  string and search for it.
 409 Type \\[isearch-yank-line] to yank rest of line onto end of search string\
 410  and search for it.
 411 Type \\[isearch-quote-char] to quote control character to search for it.
 412 \\[isearch-abort] while searching or when search has failed cancels input\
 413  back to what has
 414  been found successfully.
 415 \\[isearch-abort] when search is successful aborts and moves point to\
 416  starting point.
 417
 418 Also supported is a search ring of the previous 16 search strings.
 419 Type \\[isearch-ring-advance] to search for the next item in the search ring.
 420 Type \\[isearch-ring-retreat] to search for the previous item in the search\
 421  ring.
 422 Type \\[isearch-complete] to complete the search string using the search ring.
 423
 424 The above keys, bound in `isearch-mode-map', are often controlled by
 425  options; do M-x apropos on search-.* to find them.
 426 Other control and meta characters terminate the search
 427  and are then executed normally (depending on `search-exit-option').
 428
 429 If this function is called non-interactively, it does not return to
 430 the calling function until the search is done."
 431
 432   (interactive "P\np")
 433   (isearch-mode t (not (null regexp-p)) nil (not no-recursive-edit)))
 434
 435 (defun isearch-forward-regexp (&optional not-regexp no-recursive-edit)
 436   "\
 437 Do incremental search forward for regular expression.
 438 With a prefix argument, do a regular string search instead.
 439 Like ordinary incremental search except that your input
 440 is treated as a regexp.  See \\[isearch-forward] for more info."
 441   (interactive "P\np")
 442   (isearch-mode t (null not-regexp) nil (not no-recursive-edit)))
 443
 444 (defun isearch-backward (&optional regexp-p no-recursive-edit)
 445   "\
 446 Do incremental search backward.
 447 With a prefix argument, do a regular expression search instead.
 448 See \\[isearch-forward] for more information."
 449   (interactive "P\np")
 450   (isearch-mode nil (not (null regexp-p)) nil (not no-recursive-edit)))
 451
 452 (defun isearch-backward-regexp (&optional not-regexp no-recursive-edit)
 453   "\
 454 Do incremental search backward for regular expression.
 455 With a prefix argument, do a regular string search instead.
 456 Like ordinary incremental search except that your input
 457 is treated as a regexp.  See \\[isearch-forward] for more info."
 458   (interactive "P\np")
 459   (isearch-mode nil (null not-regexp) nil (not no-recursive-edit)))
 460
 461
 462 (defun isearch-mode-help ()
 463   (interactive)
 464   (describe-function 'isearch-forward)
 465   (isearch-update))
 466
 467 \f
 468 ;;;==================================================================
 469 ;; isearch-mode only sets up incremental search for the minor mode.
 470 ;; All the work is done by the isearch-mode commands.
 471
 472 ;; Not used yet:
 473 ;;(defconst isearch-commands '(isearch-forward isearch-backward
 474 ;;                           isearch-forward-regexp isearch-backward-regexp)
 475 ;;  "List of commands for which isearch-mode does not recursive-edit.")
 476
 477
 478 (defun isearch-mode (forward &optional regexp op-fun recursive-edit word-p)
 479   "Start isearch minor mode.  Called by isearch-forward, etc."
 480
 481   ;; Initialize global vars.
 482   (setq isearch-forward forward
 483         isearch-regexp regexp
 484         isearch-word word-p
 485         isearch-op-fun op-fun
 486         isearch-case-fold-search case-fold-search
 487         isearch-string ""
 488         isearch-message ""
 489         isearch-cmds nil
 490         isearch-success t
 491         isearch-wrapped nil
 492         isearch-barrier (point)
 493         isearch-adjusted nil
 494         isearch-yank-flag nil
 495         isearch-invalid-regexp nil
 496         isearch-within-brackets nil
 497         ;; Use (baud-rate) for now, for sake of other versions.
 498         isearch-slow-terminal-mode (and (<= (baud-rate) search-slow-speed)
 499                                         (> (window-height)
 500                                            (* 4 search-slow-window-lines)))
 501         isearch-other-end nil
 502         isearch-small-window nil
 503
 504         isearch-opoint (point)
 505         search-ring-yank-pointer nil
 506         regexp-search-ring-yank-pointer nil)
 507   (setq isearch-window-configuration
 508         (if isearch-slow-terminal-mode (current-window-configuration) nil))
 509
 510 ;; This was for Lucid Emacs.  But now that we have pre-command-hook,
 511 ;; it causes trouble.
 512 ;;  (if isearch-pre-command-hook-exists
 513 ;;      (add-hook 'pre-command-hook 'isearch-pre-command-hook))
 514   (setq isearch-mode " Isearch")  ;; forward? regexp?
 515   (set-buffer-modified-p (buffer-modified-p)) ; update modeline
 516
 517   ;; It is ugly to show region highlighting while the search
 518   ;; is going on.  And we don't want the mark active at the end either.
 519   (setq deactivate-mark t)
 520
 521   (isearch-push-state)
 522
 523   (make-local-variable 'overriding-local-map)
 524   (setq overriding-local-map isearch-mode-map)
 525   (isearch-update)
 526   (run-hooks 'isearch-mode-hook)
 527
 528   ;; isearch-mode can be made modal (in the sense of not returning to
 529   ;; the calling function until searching is completed) by entering
 530   ;; a recursive-edit and exiting it when done isearching.
 531   (if recursive-edit
 532       (let ((isearch-recursive-edit t))
 533         (recursive-edit)))
 534   isearch-success)
 535
 536
 537 ;;;====================================================
 538 ;; Some high level utilities.  Others below.
 539
 540 (defun isearch-update ()
 541   ;; Called after each command to update the display.
 542   (if (if isearch-event-data-type
 543           (null unread-command-event)
 544         (if isearch-gnu-emacs-events
 545             (null unread-command-events)
 546           (< unread-command-char 0)))
 547       (progn
 548         (if (not (input-pending-p))
 549             (isearch-message))
 550         (if (and isearch-slow-terminal-mode
 551                  (not (or isearch-small-window
 552                           (pos-visible-in-window-p))))
 553             (let ((found-point (point)))
 554               (setq isearch-small-window t)
 555               (move-to-window-line 0)
 556               (let ((window-min-height 1))
 557                 (split-window nil (if (< search-slow-window-lines 0)
 558                                       (1+ (- search-slow-window-lines))
 559                                     (- (window-height)
 560                                        (1+ search-slow-window-lines)))))
 561               (if (< search-slow-window-lines 0)
 562                   (progn (vertical-motion (- 1 search-slow-window-lines))
 563                          (set-window-start (next-window) (point))
 564                          (set-window-hscroll (next-window)
 565                                              (window-hscroll))
 566                          (set-window-hscroll (selected-window) 0))
 567                 (other-window 1))
 568               (goto-char found-point)))
 569         (if isearch-other-end
 570             (if (< isearch-other-end (point)) ; isearch-forward?
 571                 (isearch-highlight isearch-other-end (point))
 572               (isearch-highlight (point) isearch-other-end))
 573           (isearch-dehighlight nil))
 574         ))
 575   (setq ;; quit-flag nil  not for isearch-mode
 576    isearch-adjusted nil
 577    isearch-yank-flag nil)
 578   )
 579
 580
 581 (defun isearch-done (&optional nopush edit)
 582   ;; Called by all commands that terminate isearch-mode.
 583   ;; If NOPUSH is non-nil, we don't push the string on the search ring.
 584   (setq overriding-local-map nil)
 585   ;; (setq pre-command-hook isearch-old-pre-command-hook) ; for lemacs
 586   (isearch-dehighlight t)
 587   (let ((found-start (window-start (selected-window)))
 588         (found-point (point)))
 589     (if isearch-window-configuration
 590         (set-window-configuration isearch-window-configuration))
 591
 592     (if isearch-small-window
 593         (goto-char found-point)
 594       ;; Exiting the save-window-excursion clobbers window-start; restore it.
 595       (set-window-start (selected-window) found-start t)))
 596
 597     ;; If there was movement, mark the starting position.
 598     ;; Maybe should test difference between and set mark iff > threshold.
 599     (if (/= (point) isearch-opoint)
 600         (progn
 601           (push-mark isearch-opoint t)
 602           (or executing-macro (> (minibuffer-depth) 0)
 603               (message "Mark saved where search started")))
 604       ;; (message "") why is this needed?
 605       )
 606
 607   (setq isearch-mode nil)
 608   (set-buffer-modified-p (buffer-modified-p))  ;; update modeline
 609
 610   (if (and (> (length isearch-string) 0) (not nopush))
 611       ;; Update the ring data.
 612       (if isearch-regexp
 613           (if (or (null regexp-search-ring)
 614                   (not (string= isearch-string (car regexp-search-ring))))
 615               (progn
 616                 (setq regexp-search-ring
 617                       (cons isearch-string regexp-search-ring))
 618                 (if (> (length regexp-search-ring) regexp-search-ring-max)
 619                     (setcdr (nthcdr (1- search-ring-max) regexp-search-ring)
 620                             nil))))
 621         (if (or (null search-ring)
 622                 (not (string= isearch-string (car search-ring))))
 623             (progn
 624               (setq search-ring (cons isearch-string search-ring))
 625               (if (> (length search-ring) search-ring-max)
 626                   (setcdr (nthcdr (1- search-ring-max) search-ring) nil))))))
 627
 628   (run-hooks 'isearch-mode-end-hook)
 629   (and (not edit) isearch-recursive-edit (exit-recursive-edit)))
 630
 631 ;;;=======================================================
 632 ;;; Switching buffers should first terminate isearch-mode.
 633 ;;; This is done quite differently for each variant of emacs.
 634 ;;; For lemacs, see Exiting in lemacs below
 635
 636 ;; For Emacs 19, the frame switch event is handled.
 637 (defun isearch-switch-frame-handler ()
 638   (interactive) ;; Is this necessary?
 639   ;; First terminate isearch-mode.
 640   (isearch-done)
 641   (handle-switch-frame (car (cdr (isearch-last-command-char)))))
 642
 643 ;;;========================================================
 644
 645 \f
 646 ;;;====================================================
 647 ;; Commands active while inside of the isearch minor mode.
 648
 649 (defun isearch-exit ()
 650   "Exit search normally.
 651 However, if this is the first command after starting incremental
 652 search and `search-nonincremental-instead' is non-nil, do a
 653 nonincremental search instead via `isearch-edit-string'."
 654   (interactive)
 655   (if (and search-nonincremental-instead
 656            (= 0 (length isearch-string)))
 657       (let ((isearch-nonincremental t))
 658         (isearch-edit-string)))
 659   (isearch-done))
 660
 661
 662 (defun isearch-edit-string ()
 663   "Edit the search string in the minibuffer.
 664 The following additional command keys are active while editing.
 665 \\<minibuffer-local-isearch-map>
 666 \\[exit-minibuffer] to resume incremental searching with the edited string.
 667 \\[isearch-nonincremental-exit-minibuffer] to do one nonincremental search.
 668 \\[isearch-forward-exit-minibuffer] to resume isearching forward.
 669 \\[isearch-reverse-exit-minibuffer] to resume isearching backward.
 670 \\[isearch-ring-advance-edit] to replace the search string with the next item in the search ring.
 671 \\[isearch-ring-retreat-edit] to replace the search string with the previous item in the search ring.
 672 \\[isearch-complete-edit] to complete the search string using the search ring.
 673 \\<isearch-mode-map>
 674 If first char entered is \\[isearch-yank-word], then do word search instead."
 675
 676   ;; This code is very hairy for several reasons, explained in the code.
 677   ;; Mainly, isearch-mode must be terminated while editing and then restarted.
 678   ;; If there were a way to catch any change of buffer from the minibuffer,
 679   ;; this could be simplified greatly.
 680   ;; Editing doesn't back up the search point.  Should it?
 681   (interactive)
 682   (condition-case err
 683       (let ((isearch-nonincremental isearch-nonincremental)
 684
 685             ;; Locally bind all isearch global variables to protect them
 686             ;; from recursive isearching.
 687             ;; isearch-string -message and -forward are not bound
 688             ;; so they may be changed.  Instead, save the values.
 689             (isearch-new-string isearch-string)
 690             (isearch-new-message isearch-message)
 691             (isearch-new-forward isearch-forward)
 692             (isearch-new-word isearch-word)
 693
 694             (isearch-regexp isearch-regexp)
 695             (isearch-op-fun isearch-op-fun)
 696             (isearch-cmds isearch-cmds)
 697             (isearch-success isearch-success)
 698             (isearch-wrapped isearch-wrapped)
 699             (isearch-barrier isearch-barrier)
 700             (isearch-adjusted isearch-adjusted)
 701             (isearch-yank-flag isearch-yank-flag)
 702             (isearch-invalid-regexp isearch-invalid-regexp)
 703             (isearch-within-brackets isearch-within-brackets)
 704             (isearch-other-end isearch-other-end)
 705             (isearch-opoint isearch-opoint)
 706             (isearch-slow-terminal-mode isearch-slow-terminal-mode)
 707             (isearch-small-window isearch-small-window)
 708             (isearch-recursive-edit isearch-recursive-edit)
 709             ;; Save current configuration so we can restore it here.
 710             (isearch-window-configuration (current-window-configuration))
 711             )
 712
 713         ;; Actually terminate isearching until editing is done.
 714         ;; This is so that the user can do anything without failure,
 715         ;; like switch buffers and start another isearch, and return.
 716         (condition-case err
 717             (isearch-done t t)
 718           (exit nil))                   ; was recursive editing
 719
 720         (isearch-message) ;; for read-char
 721         (unwind-protect
 722             (let* (;; Why does following read-char echo?
 723                    ;;(echo-keystrokes 0) ;; not needed with above message
 724                    (e (let ((cursor-in-echo-area t))
 725                         (read-event)))
 726                    ;; Binding minibuffer-history-symbol to nil is a work-around
 727                    ;; for some incompatibility with gmhist.
 728                    (minibuffer-history-symbol))
 729               ;; If the first character the user types when we prompt them
 730               ;; for a string is the yank-word character, then go into
 731               ;; word-search mode.  Otherwise unread that character and
 732               ;; read a key the normal way.
 733               ;; Word search does not apply (yet) to regexp searches,
 734               ;; no check is made here.
 735               (message (isearch-message-prefix nil nil t))
 736               (if (eq 'isearch-yank-word
 737                       (lookup-key isearch-mode-map (vector e)))
 738                   (setq isearch-word t  ;; so message-prefix is right
 739                         isearch-new-word t)
 740                 (isearch-unread e))
 741               (setq cursor-in-echo-area nil)
 742               (setq isearch-new-string
 743                     (let (junk-ring)
 744                       (read-from-minibuffer (isearch-message-prefix)
 745                                             isearch-string
 746                                             minibuffer-local-isearch-map nil
 747                                             'junk-ring))
 748                     isearch-new-message
 749                     (mapconcat 'isearch-text-char-description
 750                                isearch-new-string "")))
 751           ;; Always resume isearching by restarting it.
 752           (isearch-mode isearch-forward
 753                         isearch-regexp
 754                         isearch-op-fun
 755                         nil
 756                         isearch-word)
 757
 758           ;; Copy new local values to isearch globals
 759           (setq isearch-string isearch-new-string
 760                 isearch-message isearch-new-message
 761                 isearch-forward isearch-new-forward
 762                 isearch-word isearch-new-word))
 763
 764         ;; Empty isearch-string means use default.
 765         (if (= 0 (length isearch-string))
 766             (setq isearch-string (car (if isearch-regexp regexp-search-ring
 767                                         search-ring)))
 768           ;; This used to set the last search string,
 769           ;; but I think it is not right to do that here.
 770           ;; Only the string actually used should be saved.
 771           )
 772
 773         ;; Reinvoke the pending search.
 774         (isearch-push-state)
 775         (isearch-search)
 776         (isearch-update)
 777         (if isearch-nonincremental
 778             (progn
 779               ;; (sit-for 1) ;; needed if isearch-done does: (message "")
 780               (isearch-done))))
 781
 782     (quit  ; handle abort-recursive-edit
 783      (isearch-abort)  ;; outside of let to restore outside global values
 784      )))
 785
 786 (defun isearch-nonincremental-exit-minibuffer ()
 787   (interactive)
 788   (setq isearch-nonincremental t)
 789   (exit-minibuffer))
 790
 791 (defun isearch-forward-exit-minibuffer ()
 792   (interactive)
 793   (setq isearch-new-forward t)
 794   (exit-minibuffer))
 795
 796 (defun isearch-reverse-exit-minibuffer ()
 797   (interactive)
 798   (setq isearch-new-forward nil)
 799   (exit-minibuffer))
 800
 801
 802 (defun isearch-abort ()
 803   "Abort incremental search mode if searching is successful, signalling quit.
 804 Otherwise, revert to previous successful search and continue searching.
 805 Use `isearch-exit' to quit without signalling."
 806   (interactive)
 807 ;;  (ding)  signal instead below, if quitting
 808   (discard-input)
 809   (if isearch-success
 810       ;; If search is successful, move back to starting point
 811       ;; and really do quit.
 812       (progn (goto-char isearch-opoint)
 813              (isearch-done t)   ; exit isearch
 814              (signal 'quit nil))  ; and pass on quit signal
 815     ;; If search is failing, rub out until it is once more successful.
 816     (while (not isearch-success) (isearch-pop-state))
 817     (isearch-update)))
 818
 819
 820 (defun isearch-repeat (direction)
 821   ;; Utility for isearch-repeat-forward and -backward.
 822   (if (eq isearch-forward (eq direction 'forward))
 823       ;; C-s in forward or C-r in reverse.
 824       (if (equal isearch-string "")
 825           ;; If search string is empty, use last one.
 826           (setq isearch-string
 827                 (or (if isearch-regexp
 828                         (car regexp-search-ring)
 829                       (car search-ring))
 830                     "")
 831                 isearch-message
 832                 (mapconcat 'isearch-text-char-description
 833                            isearch-string ""))
 834         ;; If already have what to search for, repeat it.
 835         (or isearch-success
 836             (progn
 837
 838               (goto-char (if isearch-forward (point-min) (point-max)))
 839               (setq isearch-wrapped t))))
 840     ;; C-s in reverse or C-r in forward, change direction.
 841     (setq isearch-forward (not isearch-forward)))
 842
 843   (setq isearch-barrier (point)) ; For subsequent \| if regexp.
 844
 845   (if (equal isearch-string "")
 846       (setq isearch-success t)
 847     (if (and isearch-success (equal (match-end 0) (match-beginning 0)))
 848         ;; If repeating a search that found
 849         ;; an empty string, ensure we advance.
 850         (if (if isearch-forward (eobp) (bobp))
 851             ;; If there's nowhere to advance to, fail (and wrap next time).
 852             (progn
 853               (setq isearch-success nil)
 854               (ding))
 855           (forward-char (if isearch-forward 1 -1))
 856           (isearch-search))
 857       (isearch-search)))
 858
 859   (isearch-push-state)
 860   (isearch-update))
 861
 862 (defun isearch-repeat-forward ()
 863   "Repeat incremental search forwards."
 864   (interactive)
 865   (isearch-repeat 'forward))
 866
 867 (defun isearch-repeat-backward ()
 868   "Repeat incremental search backwards."
 869   (interactive)
 870   (isearch-repeat 'backward))
 871
 872 (defun isearch-toggle-regexp ()
 873   "Toggle regexp searching on or off."
 874   ;; The status stack is left unchanged.
 875   (interactive)
 876   (setq isearch-regexp (not isearch-regexp))
 877   (if isearch-regexp (setq isearch-word nil))
 878   (isearch-update))
 879
 880 (defun isearch-toggle-case-fold ()
 881   "Toggle case folding in searching on or off."
 882   (interactive)
 883   (setq isearch-case-fold-search
 884         (if isearch-case-fold-search nil 'yes))
 885   (message "%s%s [case %ssensitive]"
 886            (isearch-message-prefix)
 887            isearch-message
 888            (if isearch-case-fold-search "in" ""))
 889   (setq isearch-adjusted t)
 890   (sit-for 1)
 891   (isearch-update))
 892
 893 (defun isearch-delete-char ()
 894   "Discard last input item and move point back.
 895 If no previous match was done, just beep."
 896   (interactive)
 897   (if (null (cdr isearch-cmds))
 898       (ding)
 899     (isearch-pop-state))
 900   (isearch-update))
 901
 902
 903 (defun isearch-yank (chunk)
 904   ;; Helper for isearch-yank-word and isearch-yank-line
 905   ;; CHUNK should be word, line or kill.
 906   (let ((string (cond
 907                  ((eq chunk 'kill)
 908                   (current-kill 0))
 909                  (t
 910                   (save-excursion
 911                     (and (not isearch-forward) isearch-other-end
 912                          (goto-char isearch-other-end))
 913                     (buffer-substring
 914                      (point)
 915                      (save-excursion
 916                        (cond
 917                         ((eq chunk 'word)
 918                          (forward-word 1))
 919                         ((eq chunk 'line)
 920                          (end-of-line)))
 921                        (point))))))))
 922     ;; Downcase the string if not supposed to case-fold yanked strings.
 923     (if (and isearch-case-fold-search
 924              (eq 'not-yanks search-upper-case))
 925         (setq string (downcase string)))
 926     (if isearch-regexp (setq string (regexp-quote string)))
 927     (setq isearch-string (concat isearch-string string)
 928           isearch-message
 929           (concat isearch-message
 930                   (mapconcat 'isearch-text-char-description
 931                              string ""))
 932           ;; Don't move cursor in reverse search.
 933           isearch-yank-flag t))
 934   (isearch-search-and-update))
 935
 936 (defun isearch-yank-kill ()
 937   "Pull string from kill ring into search string."
 938   (interactive)
 939   (isearch-yank 'kill))
 940
 941 (defun isearch-yank-word ()
 942   "Pull next word from buffer into search string."
 943   (interactive)
 944   (isearch-yank 'word))
 945
 946 (defun isearch-yank-line ()
 947   "Pull rest of line from buffer into search string."
 948   (interactive)
 949   (isearch-yank 'line))
 950
 951
 952 (defun isearch-search-and-update ()
 953   ;; Do the search and update the display.
 954   (if (and (not isearch-success)
 955            ;; unsuccessful regexp search may become
 956            ;;  successful by addition of characters which
 957            ;;  make isearch-string valid
 958            (not isearch-regexp))
 959       nil
 960     ;; In reverse search, adding stuff at
 961     ;; the end may cause zero or many more chars to be
 962     ;; matched, in the string following point.
 963     ;; Allow all those possibilities without moving point as
 964     ;; long as the match does not extend past search origin.
 965     (if (and (not isearch-forward) (not isearch-adjusted)
 966              (condition-case ()
 967                  (looking-at (if isearch-regexp isearch-string
 968                                (regexp-quote isearch-string)))
 969                (error nil))
 970                (or isearch-yank-flag
 971                    (<= (match-end 0)
 972                        (min isearch-opoint isearch-barrier))))
 973         (setq isearch-success t
 974               isearch-invalid-regexp nil
 975               isearch-within-brackets nil
 976               isearch-other-end (match-end 0))
 977       ;; Not regexp, not reverse, or no match at point.
 978       (if (and isearch-other-end (not isearch-adjusted))
 979           (goto-char (if isearch-forward isearch-other-end
 980                        (min isearch-opoint
 981                             isearch-barrier
 982                             (1+ isearch-other-end)))))
 983       (isearch-search)
 984       ))
 985   (isearch-push-state)
 986   (if isearch-op-fun (funcall isearch-op-fun))
 987   (isearch-update))
 988
 989
 990 ;; *, ?, and | chars can make a regexp more liberal.
 991 ;; They can make a regexp match sooner or make it succeed instead of failing.
 992 ;; So go back to place last successful search started
 993 ;; or to the last ^S/^R (barrier), whichever is nearer.
 994 ;; + needs no special handling because the string must match at least once.
 995
 996 (defun isearch-*-char ()
 997   "Handle * and ? specially in regexps."
 998   (interactive)
 999   (if isearch-regexp
1000
1001       (progn
1002         (setq isearch-adjusted t)
1003         (let ((cs (nth (if isearch-forward
1004                            5            ; isearch-other-end
1005                          2)             ; saved (point)
1006                        (car (cdr isearch-cmds)))))
1007           ;; (car isearch-cmds) is after last search;
1008           ;; (car (cdr isearch-cmds)) is from before it.
1009           (setq cs (or cs isearch-barrier))
1010           (goto-char
1011            (if isearch-forward
1012                (max cs isearch-barrier)
1013              (min cs isearch-barrier))))))
1014   (isearch-process-search-char (isearch-last-command-char)))
1015
1016
1017 (defun isearch-|-char ()
1018   "If in regexp search, jump to the barrier."
1019   (interactive)
1020   (if isearch-regexp
1021       (progn
1022         (setq isearch-adjusted t)
1023         (goto-char isearch-barrier)))
1024   (isearch-process-search-char (isearch-last-command-char)))
1025
1026
1027 (defalias 'isearch-other-control-char 'isearch-other-meta-char)
1028
1029 (defun isearch-other-meta-char ()
1030   "Exit the search normally and reread this key sequence.
1031 But only if `search-exit-option' is non-nil, the default.
1032 If it is the symbol `edit', the search string is edited in the minibuffer
1033 and the meta character is unread so that it applies to editing the string."
1034   (interactive)
1035   (cond ((eq search-exit-option 'edit)
1036          (let ((key (this-command-keys)))
1037            (apply 'isearch-unread (listify-key-sequence key)))
1038          (isearch-edit-string))
1039         (search-exit-option
1040          (let ((key (this-command-keys))
1041                (index 0)
1042                window)
1043            (apply 'isearch-unread (listify-key-sequence key))
1044            ;; Properly handle scroll-bar and mode-line clicks
1045            ;; for which a dummy prefix event was generated as (aref key 0).
1046            (and (> (length key) 1)
1047                 (symbolp (aref key 0))
1048                 (listp (aref key 1))
1049                 ;; These events now have a symbol; they used to have a list.
1050                 ;; Accept either one.  Other events have a number here.
1051                 (not (numberp (posn-point (event-start (aref key 1)))))
1052                 (setq index 1))
1053            ;; If we got a mouse click, maybe it was read with the buffer
1054            ;; it was clicked on.  If so, that buffer, not the current one,
1055            ;; is in isearch mode.  So end the search in that buffer.
1056            (if (and (listp (aref key index))
1057                     (setq window (posn-window (event-start (aref key index))))
1058                     (windowp window))
1059                (save-excursion
1060                  (set-buffer (window-buffer window))
1061                  (isearch-done))
1062              (isearch-done))))
1063         (t;; otherwise nil
1064          (isearch-process-search-string (this-command-keys)
1065                                         (this-command-keys)))))
1066
1067 (defun isearch-quote-char ()
1068   "Quote special characters for incremental search."
1069   (interactive)
1070   (isearch-process-search-char (read-quoted-char (isearch-message t))))
1071
1072 (defun isearch-return-char ()
1073   "Convert return into newline for incremental search.
1074 Obsolete."
1075   (interactive)
1076   (isearch-process-search-char ?\n))
1077
1078 (defun isearch-printing-char ()
1079   "Add this ordinary printing character to the search string and search."
1080   (interactive)
1081   (isearch-process-search-char (isearch-last-command-char)))
1082
1083 (defun isearch-whitespace-chars ()
1084   "Match all whitespace chars, if in regexp mode.
1085 If you want to search for just a space, type C-q SPC."
1086   (interactive)
1087   (if isearch-regexp
1088       (if (and search-whitespace-regexp (not isearch-within-brackets))
1089           (isearch-process-search-string search-whitespace-regexp " ")
1090         (isearch-printing-char))
1091     (progn
1092       ;; This way of doing word search doesn't correctly extend current search.
1093       ;;      (setq isearch-word t)
1094       ;;      (setq isearch-adjusted t)
1095       ;;      (goto-char isearch-barrier)
1096       (isearch-printing-char))))
1097
1098 (defun isearch-process-search-char (char)
1099   ;; Append the char to the search string, update the message and re-search.
1100   (isearch-process-search-string
1101    (isearch-char-to-string char)
1102    (isearch-text-char-description char)))
1103
1104 (defun isearch-process-search-string (string message)
1105   (setq isearch-string (concat isearch-string string)
1106         isearch-message (concat isearch-message message))
1107   (isearch-search-and-update))
1108
1109 \f
1110 ;;===========================================================
1111 ;; Search Ring
1112
1113 (defun isearch-ring-adjust1 (advance)
1114   ;; Helper for isearch-ring-adjust
1115   (let* ((ring (if isearch-regexp regexp-search-ring search-ring))
1116          (length (length ring))
1117          (yank-pointer-name (if isearch-regexp
1118                                 'regexp-search-ring-yank-pointer
1119                               'search-ring-yank-pointer))
1120          (yank-pointer (eval yank-pointer-name)))
1121     (if (zerop length)
1122         ()
1123       (set yank-pointer-name
1124            (setq yank-pointer
1125                  (mod (+ (or yank-pointer 0)
1126                          (if advance -1 1))
1127                       length)))
1128       (setq isearch-string (nth yank-pointer ring)
1129             isearch-message (mapconcat 'isearch-text-char-description
1130                                        isearch-string "")))))
1131
1132 (defun isearch-ring-adjust (advance)
1133   ;; Helper for isearch-ring-advance and isearch-ring-retreat
1134   (if (cdr isearch-cmds)  ;; is there more than one thing on stack?
1135       (isearch-pop-state))
1136   (isearch-ring-adjust1 advance)
1137   (isearch-push-state)
1138   (if search-ring-update
1139       (progn
1140         (isearch-search)
1141         (isearch-update))
1142     (isearch-edit-string)
1143     ))
1144
1145 (defun isearch-ring-advance ()
1146   "Advance to the next search string in the ring."
1147   ;; This could be more general to handle a prefix arg, but who would use it.
1148   (interactive)
1149   (isearch-ring-adjust 'advance))
1150
1151 (defun isearch-ring-retreat ()
1152   "Retreat to the previous search string in the ring."
1153   (interactive)
1154   (isearch-ring-adjust nil))
1155
1156 (defun isearch-ring-advance-edit (n)
1157   "Insert the next element of the search history into the minibuffer."
1158   (interactive "p")
1159   (let* ((yank-pointer-name (if isearch-regexp
1160                                 'regexp-search-ring-yank-pointer
1161                               'search-ring-yank-pointer))
1162          (yank-pointer (eval yank-pointer-name))
1163          (ring (if isearch-regexp regexp-search-ring search-ring))
1164          (length (length ring)))
1165     (if (zerop length)
1166         ()
1167       (set yank-pointer-name
1168            (setq yank-pointer
1169                  (mod (- (or yank-pointer 0) n)
1170                       length)))
1171
1172       (erase-buffer)
1173       (insert (nth yank-pointer ring))
1174       (goto-char (point-max)))))
1175
1176 (defun isearch-ring-retreat-edit (n)
1177   "Inserts the previous element of the search history into the minibuffer."
1178   (interactive "p")
1179   (isearch-ring-advance-edit (- n)))
1180
1181 ;;(defun isearch-ring-adjust-edit (advance)
1182 ;;  "Use the next or previous search string in the ring while in minibuffer."
1183 ;;  (isearch-ring-adjust1 advance)
1184 ;;  (erase-buffer)
1185 ;;  (insert isearch-string))
1186
1187 ;;(defun isearch-ring-advance-edit ()
1188 ;;  (interactive)
1189 ;;  (isearch-ring-adjust-edit 'advance))
1190
1191 ;;(defun isearch-ring-retreat-edit ()
1192 ;;  "Retreat to the previous search string in the ring while in the minibuffer."
1193 ;;  (interactive)
1194 ;;  (isearch-ring-adjust-edit nil))
1195
1196
1197 (defun isearch-complete1 ()
1198   ;; Helper for isearch-complete and isearch-complete-edit
1199   ;; Return t if completion OK, nil if no completion exists.
1200   (let* ((ring (if isearch-regexp regexp-search-ring search-ring))
1201          (alist (mapcar (function (lambda (string) (list string))) ring))
1202          (completion-ignore-case case-fold-search)
1203          (completion (try-completion isearch-string alist)))
1204     (cond
1205      ((eq completion t)
1206       ;; isearch-string stays the same
1207       t)
1208      ((or completion ; not nil, must be a string
1209           (= 0 (length isearch-string))) ; shouldnt have to say this
1210       (if (equal completion isearch-string)  ;; no extension?
1211           (if completion-auto-help
1212               (with-output-to-temp-buffer "*Isearch completions*"
1213                 (display-completion-list
1214                  (all-completions isearch-string alist))))
1215         (setq isearch-string completion))
1216       t)
1217      (t
1218       (message "No completion") ; waits a second if in minibuffer
1219       nil))))
1220
1221 (defun isearch-complete ()
1222   "Complete the search string from the strings on the search ring.
1223 The completed string is then editable in the minibuffer.
1224 If there is no completion possible, say so and continue searching."
1225   (interactive)
1226   (if (isearch-complete1)
1227       (isearch-edit-string)
1228     ;; else
1229     (sit-for 1)
1230     (isearch-update)))
1231
1232 (defun isearch-complete-edit ()
1233   "Same as `isearch-complete' except in the minibuffer."
1234   (interactive)
1235   (setq isearch-string (buffer-string))
1236   (if (isearch-complete1)
1237       (progn
1238         (erase-buffer)
1239         (insert isearch-string))))
1240
1241 \f
1242 ;;;==============================================================
1243 ;; The search status stack (and isearch window-local variables, not used).
1244 ;; Need a structure for this.
1245
1246 (defun isearch-top-state ()
1247   (let ((cmd (car isearch-cmds)))
1248     (setq isearch-string (car cmd)
1249           isearch-message (car (cdr cmd))
1250           isearch-success (nth 3 cmd)
1251           isearch-forward (nth 4 cmd)
1252           isearch-other-end (nth 5 cmd)
1253           isearch-word (nth 6 cmd)
1254           isearch-invalid-regexp (nth 7 cmd)
1255           isearch-wrapped (nth 8 cmd)
1256           isearch-barrier (nth 9 cmd)
1257           isearch-within-brackets (nth 10 cmd)
1258           isearch-case-fold-search (nth 11 cmd))
1259     (goto-char (car (cdr (cdr cmd))))))
1260
1261 (defun isearch-pop-state ()
1262   (setq isearch-cmds (cdr isearch-cmds))
1263   (isearch-top-state)
1264   )
1265
1266 (defun isearch-push-state ()
1267   (setq isearch-cmds
1268         (cons (list isearch-string isearch-message (point)
1269                     isearch-success isearch-forward isearch-other-end
1270                     isearch-word
1271                     isearch-invalid-regexp isearch-wrapped isearch-barrier
1272                     isearch-within-brackets isearch-case-fold-search)
1273               isearch-cmds)))
1274
1275 \f
1276 ;;;==================================================================
1277 ;; Message string
1278
1279 (defun isearch-message (&optional c-q-hack ellipsis)
1280   ;; Generate and print the message string.
1281   (let ((cursor-in-echo-area ellipsis)
1282         (m (concat
1283             (isearch-message-prefix c-q-hack ellipsis isearch-nonincremental)
1284             isearch-message
1285             (isearch-message-suffix c-q-hack ellipsis)
1286             )))
1287     (if c-q-hack m (message "%s" m))))
1288
1289 (defun isearch-message-prefix (&optional c-q-hack ellipsis nonincremental)
1290   ;; If about to search, and previous search regexp was invalid,
1291   ;; check that it still is.  If it is valid now,
1292   ;; let the message we display while searching say that it is valid.
1293   (and isearch-invalid-regexp ellipsis
1294        (condition-case ()
1295            (progn (re-search-forward isearch-string (point) t)
1296                   (setq isearch-invalid-regexp nil
1297                         isearch-within-brackets nil))
1298          (error nil)))
1299   ;; If currently failing, display no ellipsis.
1300   (or isearch-success (setq ellipsis nil))
1301   (let ((m (concat (if isearch-success "" "failing ")
1302                    (if isearch-wrapped "wrapped ")
1303                    (if isearch-word "word " "")
1304                    (if isearch-regexp "regexp " "")
1305                    (if nonincremental "search" "I-search")
1306                    (if isearch-forward ": " " backward: ")
1307                    )))
1308     (aset m 0 (upcase (aref m 0)))
1309     m))
1310
1311
1312 (defun isearch-message-suffix (&optional c-q-hack ellipsis)
1313   (concat (if c-q-hack "^Q" "")
1314           (if isearch-invalid-regexp
1315               (concat " [" isearch-invalid-regexp "]")
1316             "")))
1317
1318 \f
1319 ;;;========================================================
1320 ;;; Searching
1321
1322 (defun isearch-search ()
1323   ;; Do the search with the current search string.
1324   (isearch-message nil t)
1325   (if (and (eq isearch-case-fold-search t) search-upper-case)
1326       (setq isearch-case-fold-search
1327             (isearch-no-upper-case-p isearch-string isearch-regexp)))
1328   (condition-case lossage
1329       (let ((inhibit-quit nil)
1330             (case-fold-search isearch-case-fold-search))
1331         (if isearch-regexp (setq isearch-invalid-regexp nil))
1332         (setq isearch-within-brackets nil)
1333         (setq isearch-success
1334               (funcall
1335                (cond (isearch-word
1336                       (if isearch-forward
1337                           'word-search-forward 'word-search-backward))
1338                      (isearch-regexp
1339                       (if isearch-forward
1340                           're-search-forward 're-search-backward))
1341                      (t
1342                       (if isearch-forward 'search-forward 'search-backward)))
1343                isearch-string nil t))
1344         (if isearch-success
1345             (setq isearch-other-end
1346                   (if isearch-forward (match-beginning 0) (match-end 0)))))
1347
1348     (quit (isearch-unread ?\C-g)
1349           (setq isearch-success nil))
1350
1351     (invalid-regexp
1352      (setq isearch-invalid-regexp (car (cdr lossage)))
1353      (setq isearch-within-brackets (string-match "\\`Unmatched \\["
1354                                                  isearch-invalid-regexp))
1355      (if (string-match
1356           "\\`Premature \\|\\`Unmatched \\|\\`Invalid "
1357           isearch-invalid-regexp)
1358          (setq isearch-invalid-regexp "incomplete input")))
1359     (error
1360      ;; stack overflow in regexp search.
1361      (setq isearch-invalid-regexp (car (cdr lossage)))))
1362
1363   (if isearch-success
1364       nil
1365     ;; Ding if failed this time after succeeding last time.
1366     (and (nth 3 (car isearch-cmds))
1367          (ding))
1368     (goto-char (nth 2 (car isearch-cmds)))))
1369
1370
1371 \f
1372 ;;;========================================================
1373 ;;; Highlighting
1374
1375 (defvar isearch-overlay nil)
1376
1377 (defun isearch-highlight (beg end)
1378   (if (or (null search-highlight) (null window-system))
1379       nil
1380     (or isearch-overlay (setq isearch-overlay (make-overlay beg end)))
1381     (move-overlay isearch-overlay beg end (current-buffer))
1382     (overlay-put isearch-overlay 'face
1383                  (if (internal-find-face 'isearch nil)
1384                      'isearch 'region))))
1385
1386 (defun isearch-dehighlight (totally)
1387   (if isearch-overlay
1388       (delete-overlay isearch-overlay)))
1389
1390 ;;;===========================================================
1391 ;;; General utilities
1392
1393
1394 (defun isearch-no-upper-case-p (string regexp-flag)
1395   "Return t if there are no upper case chars in STRING.
1396 If REGEXP-FLAG is non-nil, disregard letters preceeded by `\\' (but not `\\\\')
1397 since they have special meaning in a regexp."
1398   (let ((case-fold-search nil))
1399     (not (string-match (if regexp-flag "\\(^\\|\\\\\\\\\\|[^\\]\\)[A-Z]"
1400                          "[A-Z]")
1401                        string))))
1402
1403
1404 ;;;=================================================
1405 ;; Portability functions to support various Emacs versions.
1406
1407 ;; To quiet the byte-compiler.
1408 (defvar unread-command-event)
1409 (defvar unread-command-events)
1410 (defvar last-command-event)
1411
1412 (defun isearch-char-to-string (c)
1413   (if (integerp c)
1414       (make-string 1 c)
1415     (if (and (symbolp c) (get c 'ascii-character))
1416         (make-string 1 (get c 'ascii-character))
1417       (make-string 1 (event-to-character c)))))
1418
1419 (defun isearch-text-char-description (c)
1420   (if (and (integerp c) (or (< c ?\ ) (= c ?\^?)))
1421       (text-char-description c)
1422     (isearch-char-to-string c)))
1423
1424 (defun isearch-unread (&rest char-or-events)
1425   ;; General function to unread characters or events.
1426   (if isearch-gnu-emacs-events
1427       (setq unread-command-events
1428             (append char-or-events unread-command-events))
1429     (let ((char (if (cdr char-or-events)
1430                     (progn
1431                       (while (cdr char-or-events)
1432                         (setq char-or-events (cdr char-or-events)))
1433                       (+ 128 (car char-or-events)))
1434                   (car char-or-events))))
1435       (if isearch-event-data-type
1436           (setq unread-command-event char)
1437         (setq unread-command-char char)))))
1438
1439 (defun isearch-last-command-char ()
1440   ;; General function to return the last command character.
1441   (if isearch-event-data-type
1442       last-command-event
1443     last-command-char))
1444
1445 ;;; isearch.el ends here