lisp/dired-aux.el

   1 ;;; dired-aux.el --- all of dired except what people usually use
   2
   3 ;; Copyright (C) 1985, 1986, 1992, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>.
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; The parts of dired mode not normally used.  This is a space-saving hack
  26 ;; to avoid having to load a large mode when all that's wanted are a few
  27 ;; functions.
  28
  29 ;; Rewritten in 1990/1991 to add tree features, file marking and
  30 ;; sorting by Sebastian Kremer <sk@thp.uni-koeln.de>.
  31 ;; Finished up by rms in 1992.
  32
  33 ;;; Code:
  34
  35 ;; We need macros in dired.el to compile properly.
  36 (eval-when-compile (require 'dired))
  37
  38 ;;; 15K
  39 ;;;###begin dired-cmd.el
  40 ;; Diffing and compressing
  41
  42 ;;;###autoload
  43 (defun dired-diff (file &optional switches)
  44   "Compare file at point with file FILE using `diff'.
  45 FILE defaults to the file at the mark.
  46 The prompted-for file is the first file given to `diff'.
  47 With prefix arg, prompt for second argument SWITCHES,
  48  which is options for `diff'."
  49   (interactive
  50    (let ((default (if (mark t)
  51                       (save-excursion (goto-char (mark t))
  52                                       (dired-get-filename t t)))))
  53      (require 'diff)
  54      (list (read-file-name (format "Diff %s with: %s"
  55                                    (dired-get-filename t)
  56                                    (if default
  57                                        (concat "(default " default ") ")
  58                                      ""))
  59                            (dired-current-directory) default t)
  60            (if current-prefix-arg
  61                (read-string "Options for diff: "
  62                             (if (stringp diff-switches)
  63                                 diff-switches
  64                               (mapconcat 'identity diff-switches " ")))))))
  65   (diff file (dired-get-filename t) switches))
  66
  67 ;;;###autoload
  68 (defun dired-backup-diff (&optional switches)
  69   "Diff this file with its backup file or vice versa.
  70 Uses the latest backup, if there are several numerical backups.
  71 If this file is a backup, diff it with its original.
  72 The backup file is the first file given to `diff'.
  73 With prefix arg, prompt for argument SWITCHES which is options for `diff'."
  74   (interactive
  75     (if current-prefix-arg
  76         (list (read-string "Options for diff: "
  77                            (if (stringp diff-switches)
  78                                diff-switches
  79                              (mapconcat 'identity diff-switches " "))))
  80       nil))
  81   (diff-backup (dired-get-filename) switches))
  82
  83 (defun dired-do-chxxx (attribute-name program op-symbol arg)
  84   ;; Change file attributes (mode, group, owner) of marked files and
  85   ;; refresh their file lines.
  86   ;; ATTRIBUTE-NAME is a string describing the attribute to the user.
  87   ;; PROGRAM is the program used to change the attribute.
  88   ;; OP-SYMBOL is the type of operation (for use in dired-mark-pop-up).
  89   ;; ARG describes which files to use, as in dired-get-marked-files.
  90   (let* ((files (dired-get-marked-files t arg))
  91          (new-attribute
  92           (dired-mark-read-string
  93            (concat "Change " attribute-name " of %s to: ")
  94            nil op-symbol arg files))
  95          (operation (concat program " " new-attribute))
  96          failures)
  97     (setq failures
  98           (dired-bunch-files 10000
  99                              (function dired-check-process)
 100                              (list operation program new-attribute)
 101                              files))
 102     (dired-do-redisplay arg);; moves point if ARG is an integer
 103     (if failures
 104         (dired-log-summary
 105          (format "%s: error" operation)
 106          nil))))
 107
 108 ;;;###autoload
 109 (defun dired-do-chmod (&optional arg)
 110   "Change the mode of the marked (or next ARG) files.
 111 This calls chmod, thus symbolic modes like `g+w' are allowed."
 112   (interactive "P")
 113   (dired-do-chxxx "Mode" "chmod" 'chmod arg))
 114
 115 ;;;###autoload
 116 (defun dired-do-chgrp (&optional arg)
 117   "Change the group of the marked (or next ARG) files."
 118   (interactive "P")
 119   (dired-do-chxxx "Group" "chgrp" 'chgrp arg))
 120
 121 ;;;###autoload
 122 (defun dired-do-chown (&optional arg)
 123   "Change the owner of the marked (or next ARG) files."
 124   (interactive "P")
 125   (dired-do-chxxx "Owner" dired-chown-program 'chown arg))
 126
 127 ;; Process all the files in FILES in batches of a convenient size,
 128 ;; by means of (FUNCALL FUNCTION ARGS... SOME-FILES...).
 129 ;; Batches are chosen to need less than MAX chars for the file names,
 130 ;; allowing 3 extra characters of separator per file name.
 131 (defun dired-bunch-files (max function args files)
 132   (let (pending
 133         (pending-length 0)
 134         failures)
 135     ;; Accumulate files as long as they fit in MAX chars,
 136     ;; then process the ones accumulated so far.
 137     (while files
 138       (let* ((thisfile (car files))
 139              (thislength (+ (length thisfile) 3))
 140              (rest (cdr files)))
 141         ;; If we have at least 1 pending file
 142         ;; and this file won't fit in the length limit, process now.
 143         (if (and pending (> (+ thislength pending-length) max))
 144             (setq failures
 145                   (nconc (apply function (append args pending))
 146                          failures)
 147                   pending nil
 148                   pending-length 0))
 149         ;; Do (setq pending (cons thisfile pending))
 150         ;; but reuse the cons that was in `files'.
 151         (setcdr files pending)
 152         (setq pending files)
 153         (setq pending-length (+ thislength pending-length))
 154         (setq files rest)))
 155     (nconc (apply function (append args pending))
 156            failures)))
 157
 158 ;;;###autoload
 159 (defun dired-do-print (&optional arg)
 160   "Print the marked (or next ARG) files.
 161 Uses the shell command coming from variables `lpr-command' and
 162 `lpr-switches' as default."
 163   (interactive "P")
 164   (let* ((file-list (dired-get-marked-files t arg))
 165          (command (dired-mark-read-string
 166                    "Print %s with: "
 167                    (apply 'concat lpr-command " " lpr-switches)
 168                    'print arg file-list)))
 169     (dired-run-shell-command (dired-shell-stuff-it command file-list nil))))
 170
 171 ;; Read arguments for a marked-files command that wants a string
 172 ;; that is not a file name,
 173 ;; perhaps popping up the list of marked files.
 174 ;; ARG is the prefix arg and indicates whether the files came from
 175 ;; marks (ARG=nil) or a repeat factor (integerp ARG).
 176 ;; If the current file was used, the list has but one element and ARG
 177 ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)).
 178
 179 (defun dired-mark-read-string (prompt initial op-symbol arg files)
 180   ;; PROMPT for a string, with INITIAL input.
 181   ;; Other args are used to give user feedback and pop-up:
 182   ;; OP-SYMBOL of command, prefix ARG, marked FILES.
 183   (dired-mark-pop-up
 184    nil op-symbol files
 185    (function read-string)
 186    (format prompt (dired-mark-prompt arg files)) initial))
 187 \f
 188 ;;; Cleaning a directory: flagging some backups for deletion.
 189
 190 (defvar dired-file-version-alist)
 191
 192 (defun dired-clean-directory (keep)
 193   "Flag numerical backups for deletion.
 194 Spares `dired-kept-versions' latest versions, and `kept-old-versions' oldest.
 195 Positive prefix arg KEEP overrides `dired-kept-versions';
 196 Negative prefix arg KEEP overrides `kept-old-versions' with KEEP made positive.
 197
 198 To clear the flags on these files, you can use \\[dired-flag-backup-files]
 199 with a prefix argument."
 200   (interactive "P")
 201   (setq keep (if keep (prefix-numeric-value keep) dired-kept-versions))
 202   (let ((early-retention (if (< keep 0) (- keep) kept-old-versions))
 203         (late-retention (if (<= keep 0) dired-kept-versions keep))
 204         (dired-file-version-alist ()))
 205     (message "Cleaning numerical backups (keeping %d late, %d old)..."
 206              late-retention early-retention)
 207     ;; Look at each file.
 208     ;; If the file has numeric backup versions,
 209     ;; put on dired-file-version-alist an element of the form
 210     ;; (FILENAME . VERSION-NUMBER-LIST)
 211     (dired-map-dired-file-lines (function dired-collect-file-versions))
 212     ;; Sort each VERSION-NUMBER-LIST,
 213     ;; and remove the versions not to be deleted.
 214     (let ((fval dired-file-version-alist))
 215       (while fval
 216         (let* ((sorted-v-list (cons 'q (sort (cdr (car fval)) '<)))
 217                (v-count (length sorted-v-list)))
 218           (if (> v-count (+ early-retention late-retention))
 219               (rplacd (nthcdr early-retention sorted-v-list)
 220                       (nthcdr (- v-count late-retention)
 221                               sorted-v-list)))
 222           (rplacd (car fval)
 223                   (cdr sorted-v-list)))
 224         (setq fval (cdr fval))))
 225     ;; Look at each file.  If it is a numeric backup file,
 226     ;; find it in a VERSION-NUMBER-LIST and maybe flag it for deletion.
 227     (dired-map-dired-file-lines (function dired-trample-file-versions))
 228     (message "Cleaning numerical backups...done")))
 229
 230 ;;; Subroutines of dired-clean-directory.
 231
 232 (defun dired-map-dired-file-lines (fun)
 233   ;; Perform FUN with point at the end of each non-directory line.
 234   ;; FUN takes one argument, the filename (complete pathname).
 235   (save-excursion
 236     (let (file buffer-read-only)
 237       (goto-char (point-min))
 238       (while (not (eobp))
 239         (save-excursion
 240           (and (not (looking-at dired-re-dir))
 241                (not (eolp))
 242                (setq file (dired-get-filename nil t)) ; nil on non-file
 243                (progn (end-of-line)
 244                       (funcall fun file))))
 245         (forward-line 1)))))
 246
 247 (defun dired-collect-file-versions (fn)
 248   ;;  "If it looks like file FN has versions, return a list of the versions.
 249   ;;That is a list of strings which are file names.
 250   ;;The caller may want to flag some of these files for deletion."
 251     (let* ((base-versions
 252             (concat (file-name-nondirectory fn) ".~"))
 253            (bv-length (length base-versions))
 254            (possibilities (file-name-all-completions
 255                            base-versions
 256                            (file-name-directory fn)))
 257            (versions (mapcar 'backup-extract-version possibilities)))
 258       (if versions
 259           (setq dired-file-version-alist (cons (cons fn versions)
 260                                                dired-file-version-alist)))))
 261
 262 (defun dired-trample-file-versions (fn)
 263   (let* ((start-vn (string-match "\\.~[0-9]+~$" fn))
 264          base-version-list)
 265     (and start-vn
 266          (setq base-version-list        ; there was a base version to which
 267                (assoc (substring fn 0 start-vn) ; this looks like a
 268                       dired-file-version-alist))        ; subversion
 269          (not (memq (string-to-int (substring fn (+ 2 start-vn)))
 270                     base-version-list)) ; this one doesn't make the cut
 271          (progn (beginning-of-line)
 272                 (delete-char 1)
 273                 (insert dired-del-marker)))))
 274 \f
 275 ;;; Shell commands
 276 ;;>>> install (move this function into simple.el)
 277 (defun dired-shell-quote (filename)
 278   "Quote a file name for inferior shell (see variable `shell-file-name')."
 279   ;; Quote everything except POSIX filename characters.
 280   ;; This should be safe enough even for really weird shells.
 281   (let ((result "") (start 0) end)
 282     (while (string-match "[^-0-9a-zA-Z_./]" filename start)
 283       (setq end (match-beginning 0)
 284             result (concat result (substring filename start end)
 285                            "\\" (substring filename end (1+ end)))
 286             start (1+ end)))
 287     (concat result (substring filename start))))
 288
 289 (defun dired-read-shell-command (prompt arg files)
 290 ;;  "Read a dired shell command prompting with PROMPT (using read-string).
 291 ;;ARG is the prefix arg and may be used to indicate in the prompt which
 292 ;;  files are affected.
 293 ;;This is an extra function so that you can redefine it, e.g., to use gmhist."
 294   (dired-mark-pop-up
 295    nil 'shell files
 296    (function read-string)
 297    (format prompt (dired-mark-prompt arg files))))
 298
 299 ;; The in-background argument is only needed in Emacs 18 where
 300 ;; shell-command doesn't understand an appended ampersand `&'.
 301 ;;;###autoload
 302 (defun dired-do-shell-command (command &optional arg)
 303   "Run a shell command COMMAND on the marked files.
 304 If no files are marked or a specific numeric prefix arg is given,
 305 the next ARG files are used.  Just \\[universal-argument] means the current file.
 306 The prompt mentions the file(s) or the marker, as appropriate.
 307
 308 If there is output, it goes to a separate buffer.
 309
 310 Normally the command is run on each file individually.
 311 However, if there is a `*' in the command then it is run
 312 just once with the entire file list substituted there.
 313
 314 No automatic redisplay of dired buffers is attempted, as there's no
 315 telling what files the command may have changed.  Type
 316 \\[dired-do-redisplay] to redisplay the marked files.
 317
 318 The shell command has the top level directory as working directory, so
 319 output files usually are created there instead of in a subdir."
 320 ;;Functions dired-run-shell-command and dired-shell-stuff-it do the
 321 ;;actual work and can be redefined for customization.
 322   (interactive (list
 323                 ;; Want to give feedback whether this file or marked files are used:
 324                 (dired-read-shell-command (concat "! on "
 325                                                   "%s: ")
 326                                           current-prefix-arg
 327                                           (dired-get-marked-files
 328                                            t current-prefix-arg))
 329                 current-prefix-arg))
 330   (let* ((on-each (not (string-match "\\*" command)))
 331          (file-list (dired-get-marked-files t arg)))
 332     (if on-each
 333         (dired-bunch-files
 334          (- 10000 (length command))
 335          (function (lambda (&rest files)
 336                      (dired-run-shell-command
 337                       (dired-shell-stuff-it command files t arg))))
 338          nil
 339          file-list)
 340       ;; execute the shell command
 341       (dired-run-shell-command
 342        (dired-shell-stuff-it command file-list nil arg)))))
 343
 344 ;; Might use {,} for bash or csh:
 345 (defvar dired-mark-prefix ""
 346   "Prepended to marked files in dired shell commands.")
 347 (defvar dired-mark-postfix ""
 348   "Appended to marked files in dired shell commands.")
 349 (defvar dired-mark-separator " "
 350   "Separates marked files in dired shell commands.")
 351
 352 (defun dired-shell-stuff-it (command file-list on-each &optional raw-arg)
 353 ;; "Make up a shell command line from COMMAND and FILE-LIST.
 354 ;; If ON-EACH is t, COMMAND should be applied to each file, else
 355 ;; simply concat all files and apply COMMAND to this.
 356 ;; FILE-LIST's elements will be quoted for the shell."
 357 ;; Might be redefined for smarter things and could then use RAW-ARG
 358 ;; (coming from interactive P and currently ignored) to decide what to do.
 359 ;; Smart would be a way to access basename or extension of file names.
 360 ;; See dired-trns.el for an approach to this.
 361   ;; Bug: There is no way to quote a *
 362   ;; On the other hand, you can never accidentally get a * into your cmd.
 363   (let ((stuff-it
 364          (if (string-match "\\*" command)
 365              (function (lambda (x)
 366                          (dired-replace-in-string "\\*" x command)))
 367            (function (lambda (x) (concat command " " x))))))
 368     (if on-each
 369         (mapconcat stuff-it (mapcar 'dired-shell-quote file-list) ";")
 370       (let ((fns (mapconcat 'dired-shell-quote
 371                             file-list dired-mark-separator)))
 372         (if (> (length file-list) 1)
 373             (setq fns (concat dired-mark-prefix fns dired-mark-postfix)))
 374         (funcall stuff-it fns)))))
 375
 376 ;; This is an extra function so that it can be redefined by ange-ftp.
 377 (defun dired-run-shell-command (command)
 378   (shell-command command)
 379   ;; Return nil for sake of nconc in dired-bunch-files.
 380   nil)
 381 \f
 382 ;; In Emacs 19 this will return program's exit status.
 383 ;; This is a separate function so that ange-ftp can redefine it.
 384 (defun dired-call-process (program discard &rest arguments)
 385 ;  "Run PROGRAM with output to current buffer unless DISCARD is t.
 386 ;Remaining arguments are strings passed as command arguments to PROGRAM."
 387   (apply 'call-process program nil (not discard) nil arguments))
 388
 389 (defun dired-check-process (msg program &rest arguments)
 390 ;  "Display MSG while running PROGRAM, and check for output.
 391 ;Remaining arguments are strings passed as command arguments to PROGRAM.
 392 ; On error, insert output
 393 ; in a log buffer and return the offending ARGUMENTS or PROGRAM.
 394 ; Caller can cons up a list of failed args.
 395 ;Else returns nil for success."
 396   (let (err-buffer err (dir default-directory))
 397     (message "%s..." msg)
 398     (save-excursion
 399       ;; Get a clean buffer for error output:
 400       (setq err-buffer (get-buffer-create " *dired-check-process output*"))
 401       (set-buffer err-buffer)
 402       (erase-buffer)
 403       (setq default-directory dir       ; caller's default-directory
 404             err (/= 0
 405                  (apply (function dired-call-process) program nil arguments)))
 406       (if err
 407           (progn
 408             (dired-log (concat program " " (prin1-to-string arguments) "\n"))
 409             (dired-log err-buffer)
 410             (or arguments program t))
 411         (kill-buffer err-buffer)
 412         (message "%s...done" msg)
 413         nil))))
 414 \f
 415 ;; Commands that delete or redisplay part of the dired buffer.
 416
 417 (defun dired-kill-line (&optional arg)
 418   (interactive "P")
 419   (setq arg (prefix-numeric-value arg))
 420   (let (buffer-read-only file)
 421     (while (/= 0 arg)
 422       (setq file (dired-get-filename nil t))
 423       (if (not file)
 424           (error "Can only kill file lines.")
 425         (save-excursion (and file
 426                              (dired-goto-subdir file)
 427                              (dired-kill-subdir)))
 428         (delete-region (progn (beginning-of-line) (point))
 429                        (progn (forward-line 1) (point)))
 430         (if (> arg 0)
 431             (setq arg (1- arg))
 432           (setq arg (1+ arg))
 433           (forward-line -1))))
 434     (dired-move-to-filename)))
 435
 436 ;;;###autoload
 437 (defun dired-do-kill-lines (&optional arg fmt)
 438   "Kill all marked lines (not the files).
 439 With a prefix argument, kill that many lines starting with the current line.
 440 \(A negative argument kills lines before the current line.)
 441 To kill an entire subdirectory, go to its directory header line
 442 and use this command with a prefix argument (the value does not matter)."
 443   ;; Returns count of killed lines.  FMT="" suppresses message.
 444   (interactive "P")
 445   (if arg
 446       (if (dired-get-subdir)
 447           (dired-kill-subdir)
 448         (dired-kill-line arg))
 449     (save-excursion
 450       (goto-char (point-min))
 451       (let (buffer-read-only (count 0))
 452         (if (not arg)                   ; kill marked lines
 453             (let ((regexp (dired-marker-regexp)))
 454               (while (and (not (eobp))
 455                           (re-search-forward regexp nil t))
 456                 (setq count (1+ count))
 457                 (delete-region (progn (beginning-of-line) (point))
 458                                (progn (forward-line 1) (point)))))
 459           ;; else kill unmarked lines
 460           (while (not (eobp))
 461             (if (or (dired-between-files)
 462                     (not (looking-at "^  ")))
 463                 (forward-line 1)
 464               (setq count (1+ count))
 465               (delete-region (point) (save-excursion
 466                                        (forward-line 1)
 467                                        (point))))))
 468         (or (equal "" fmt)
 469             (message (or fmt "Killed %d line%s.") count (dired-plural-s count)))
 470         count))))
 471
 472 ;;;###end dired-cmd.el
 473 \f
 474 ;;; 30K
 475 ;;;###begin dired-cp.el
 476
 477 (defun dired-compress ()
 478   ;; Compress or uncompress the current file.
 479   ;; Return nil for success, offending filename else.
 480   (let* (buffer-read-only
 481          (from-file (dired-get-filename))
 482          (new-file (dired-compress-file from-file)))
 483     (if new-file
 484         (let ((start (point)))
 485           ;; Remove any preexisting entry for the name NEW-FILE.
 486           (condition-case nil
 487               (dired-remove-entry new-file)
 488             (error nil))
 489           (goto-char start)
 490           ;; Now replace the current line with an entry for NEW-FILE.
 491           (dired-update-file-line new-file) nil)
 492       (dired-log (concat "Failed to compress" from-file))
 493       from-file)))
 494
 495 ;;;###autoload
 496 (defun dired-compress-file (file)
 497   ;; Compress or uncompress FILE.
 498   ;; Return the name of the compressed or uncompressed file.
 499   ;; Return nil if no change in files.
 500   (let ((handler (find-file-name-handler file 'dired-compress-file)))
 501     (cond (handler
 502            (funcall handler 'dired-compress-file file))
 503           ((file-symlink-p file)
 504            nil)
 505           ((let (case-fold-search)
 506              (string-match "\\.Z$" file))
 507            (if (not (dired-check-process (concat "Uncompressing " file)
 508                                          "uncompress" file))
 509                (substring file 0 -2)))
 510           ((let (case-fold-search)
 511              (string-match "\\.gz$" file))
 512            (if (not (dired-check-process (concat "Uncompressing " file)
 513                                          "gunzip" file))
 514                (substring file 0 -3)))
 515           ;; For .z, try gunzip.  It might be an old gzip file,
 516           ;; or it might be from compact? pack? (which?) but gunzip handles
 517           ;; both.
 518           ((let (case-fold-search)
 519              (string-match "\\.z$" file))
 520            (if (not (dired-check-process (concat "Uncompressing " file)
 521                                          "gunzip" file))
 522                (substring file 0 -2)))
 523           (t
 524            ;;; Try gzip; if we don't have that, use compress.
 525            (condition-case nil
 526                (if (not (dired-check-process (concat "Compressing " file)
 527                                              "gzip" "-f" file))
 528                    (cond ((file-exists-p (concat file ".gz"))
 529                           (concat file ".gz"))
 530                          (t (concat file ".z"))))
 531              (file-error
 532               (if (not (dired-check-process (concat "Compressing " file)
 533                                             "compress" "-f" file))
 534                   (concat file ".Z"))))))))
 535 \f
 536 (defun dired-mark-confirm (op-symbol arg)
 537   ;; Request confirmation from the user that the operation described
 538   ;; by OP-SYMBOL is to be performed on the marked files.
 539   ;; Confirmation consists in a y-or-n question with a file list
 540   ;; pop-up unless OP-SYMBOL is a member of `dired-no-confirm'.
 541   ;; The files used are determined by ARG (as in dired-get-marked-files).
 542   (or (memq op-symbol dired-no-confirm)
 543       (let ((files (dired-get-marked-files t arg))
 544             (string (if (eq op-symbol 'compress) "Compress or uncompress"
 545                       (capitalize (symbol-name op-symbol)))))
 546         (dired-mark-pop-up nil op-symbol files (function y-or-n-p)
 547                            (concat string " "
 548                                    (dired-mark-prompt arg files) "? ")))))
 549
 550 (defun dired-map-over-marks-check (fun arg op-symbol &optional show-progress)
 551 ;  "Map FUN over marked files (with second ARG like in dired-map-over-marks)
 552 ; and display failures.
 553
 554 ; FUN takes zero args.  It returns non-nil (the offending object, e.g.
 555 ; the short form of the filename) for a failure and probably logs a
 556 ; detailed error explanation using function `dired-log'.
 557
 558 ; OP-SYMBOL is a symbol describing the operation performed (e.g.
 559 ; `compress').  It is used with `dired-mark-pop-up' to prompt the user
 560 ; (e.g. with `Compress * [2 files]? ') and to display errors (e.g.
 561 ; `Failed to compress 1 of 2 files - type W to see why ("foo")')
 562
 563 ; SHOW-PROGRESS if non-nil means redisplay dired after each file."
 564   (if (dired-mark-confirm op-symbol arg)
 565       (let* ((total-list;; all of FUN's return values
 566               (dired-map-over-marks (funcall fun) arg show-progress))
 567              (total (length total-list))
 568              (failures (delq nil total-list))
 569              (count (length failures))
 570              (string (if (eq op-symbol 'compress) "Compress or uncompress"
 571                        (capitalize (symbol-name op-symbol)))))
 572         (if (not failures)
 573             (message "%s: %d file%s."
 574                      string total (dired-plural-s total))
 575           ;; end this bunch of errors:
 576           (dired-log-summary
 577            (format "Failed to %s %d of %d file%s"
 578                    (downcase string) count total (dired-plural-s total))
 579            failures)))))
 580
 581 (defvar dired-query-alist
 582   '((?\y . y) (?\040 . y)               ; `y' or SPC means accept once
 583     (?n . n) (?\177 . n)                ; `n' or DEL skips once
 584     (?! . yes)                          ; `!' accepts rest
 585     (?q. no) (?\e . no)                 ; `q' or ESC skips rest
 586     ;; None of these keys quit - use C-g for that.
 587     ))
 588
 589 (defun dired-query (qs-var qs-prompt &rest qs-args)
 590   ;; Query user and return nil or t.
 591   ;; Store answer in symbol VAR (which must initially be bound to nil).
 592   ;; Format PROMPT with ARGS.
 593   ;; Binding variable help-form will help the user who types the help key.
 594   (let* ((char (symbol-value qs-var))
 595          (action (cdr (assoc char dired-query-alist))))
 596     (cond ((eq 'yes action)
 597            t)                           ; accept, and don't ask again
 598           ((eq 'no action)
 599            nil)                         ; skip, and don't ask again
 600           (t;; no lasting effects from last time we asked - ask now
 601            (let ((qprompt (concat qs-prompt
 602                                   (if help-form
 603                                       (format " [Type yn!q or %s] "
 604                                               (key-description
 605                                                (char-to-string help-char)))
 606                                     " [Type y, n, q or !] ")))
 607                  result elt)
 608              ;; Actually it looks nicer without cursor-in-echo-area - you can
 609              ;; look at the dired buffer instead of at the prompt to decide.
 610              (apply 'message qprompt qs-args)
 611              (setq char (set qs-var (read-char)))
 612              (while (not (setq elt (assoc char dired-query-alist)))
 613                (message "Invalid char - type %c for help." help-char)
 614                (ding)
 615                (sit-for 1)
 616                (apply 'message qprompt qs-args)
 617                (setq char (set qs-var (read-char))))
 618              (memq (cdr elt) '(t y yes)))))))
 619 \f
 620 ;;;###autoload
 621 (defun dired-do-compress (&optional arg)
 622   "Compress or uncompress marked (or next ARG) files."
 623   (interactive "P")
 624   (dired-map-over-marks-check (function dired-compress) arg 'compress t))
 625
 626 ;; Commands for Emacs Lisp files - load and byte compile
 627
 628 (defun dired-byte-compile ()
 629   ;; Return nil for success, offending file name else.
 630   (let* ((filename (dired-get-filename))
 631          elc-file buffer-read-only failure)
 632     (condition-case err
 633         (save-excursion (byte-compile-file filename))
 634       (error
 635        (setq failure err)))
 636     (setq elc-file (byte-compile-dest-file filename))
 637     (if failure
 638         (progn
 639           (dired-log "Byte compile error for %s:\n%s\n" filename failure)
 640           (dired-make-relative filename))
 641       (dired-remove-file elc-file)
 642       (forward-line)                    ; insert .elc after its .el file
 643       (dired-add-file elc-file)
 644       nil)))
 645
 646 ;;;###autoload
 647 (defun dired-do-byte-compile (&optional arg)
 648   "Byte compile marked (or next ARG) Emacs Lisp files."
 649   (interactive "P")
 650   (dired-map-over-marks-check (function dired-byte-compile) arg 'byte-compile t))
 651
 652 (defun dired-load ()
 653   ;; Return nil for success, offending file name else.
 654   (let ((file (dired-get-filename)) failure)
 655     (condition-case err
 656       (load file nil nil t)
 657       (error (setq failure err)))
 658     (if (not failure)
 659         nil
 660       (dired-log "Load error for %s:\n%s\n" file failure)
 661       (dired-make-relative file))))
 662
 663 ;;;###autoload
 664 (defun dired-do-load (&optional arg)
 665   "Load the marked (or next ARG) Emacs Lisp files."
 666   (interactive "P")
 667   (dired-map-over-marks-check (function dired-load) arg 'load t))
 668
 669 ;;;###autoload
 670 (defun dired-do-redisplay (&optional arg test-for-subdir)
 671   "Redisplay all marked (or next ARG) files.
 672 If on a subdir line, redisplay that subdirectory.  In that case,
 673 a prefix arg lets you edit the `ls' switches used for the new listing."
 674   ;; Moves point if the next ARG files are redisplayed.
 675   (interactive "P\np")
 676   (if (and test-for-subdir (dired-get-subdir))
 677       (dired-insert-subdir
 678        (dired-get-subdir)
 679        (if arg (read-string "Switches for listing: " dired-actual-switches)))
 680     (message "Redisplaying...")
 681     ;; message much faster than making dired-map-over-marks show progress
 682     (dired-map-over-marks (let ((fname (dired-get-filename)))
 683                             (message "Redisplaying... %s" fname)
 684                             (dired-update-file-line fname))
 685                           arg)
 686     (dired-move-to-filename)
 687     (message "Redisplaying...done")))
 688 \f
 689 (defun dired-update-file-line (file)
 690   ;; Delete the current line, and insert an entry for FILE.
 691   ;; If FILE is nil, then just delete the current line.
 692   ;; Keeps any marks that may be present in column one (doing this
 693   ;; here is faster than with dired-add-entry's optional arg).
 694   ;; Does not update other dired buffers.  Use dired-relist-entry for that.
 695   (beginning-of-line)
 696   (let ((char (following-char)) (opoint (point))
 697         (buffer-read-only))
 698     (delete-region (point) (progn (forward-line 1) (point)))
 699     (if file
 700         (progn
 701           (dired-add-entry file)
 702           ;; Replace space by old marker without moving point.
 703           ;; Faster than goto+insdel inside a save-excursion?
 704           (subst-char-in-region opoint (1+ opoint) ?\040 char))))
 705   (dired-move-to-filename))
 706
 707 (defun dired-fun-in-all-buffers (directory fun &rest args)
 708   ;; In all buffers dired'ing DIRECTORY, run FUN with ARGS.
 709   ;; Return list of buffers where FUN succeeded (i.e., returned non-nil).
 710   (let ((buf-list (dired-buffers-for-dir directory))
 711         (obuf (current-buffer))
 712         buf success-list)
 713     (while buf-list
 714       (setq buf (car buf-list)
 715             buf-list (cdr buf-list))
 716       (unwind-protect
 717           (progn
 718             (set-buffer buf)
 719             (if (apply fun args)
 720                 (setq success-list (cons (buffer-name buf) success-list))))
 721         (set-buffer obuf)))
 722     success-list))
 723
 724 ;;;###autoload
 725 (defun dired-add-file (filename &optional marker-char)
 726   (dired-fun-in-all-buffers
 727    (file-name-directory filename)
 728    (function dired-add-entry) filename marker-char))
 729
 730 (defun dired-add-entry (filename &optional marker-char)
 731   ;; Add a new entry for FILENAME, optionally marking it
 732   ;; with MARKER-CHAR (a character, else dired-marker-char is used).
 733   ;; Note that this adds the entry `out of order' if files sorted by
 734   ;; time, etc.
 735   ;; At least this version inserts in the right subdirectory (if present).
 736   ;; And it skips "." or ".." (see `dired-trivial-filenames').
 737   ;; Hidden subdirs are exposed if a file is added there.
 738   (setq filename (directory-file-name filename))
 739   ;; Entry is always for files, even if they happen to also be directories
 740   (let ((opoint (point))
 741         (cur-dir (dired-current-directory))
 742         (directory (file-name-directory filename))
 743         reason)
 744     (setq filename (file-name-nondirectory filename)
 745           reason
 746           (catch 'not-found
 747             (if (string= directory cur-dir)
 748                 (progn
 749                   (skip-chars-forward "^\r\n")
 750                   (if (eq (following-char) ?\r)
 751                       (dired-unhide-subdir))
 752                   ;; We are already where we should be, except when
 753                   ;; point is before the subdir line or its total line.
 754                   (let ((p (dired-after-subdir-garbage cur-dir)))
 755                     (if (< (point) p)
 756                         (goto-char p))))
 757               ;; else try to find correct place to insert
 758               (if (dired-goto-subdir directory)
 759                   (progn;; unhide if necessary
 760                     (if (looking-at "\r");; point is at end of subdir line
 761                         (dired-unhide-subdir))
 762                     ;; found - skip subdir and `total' line
 763                     ;; and uninteresting files like . and ..
 764                     ;; This better not moves into the next subdir!
 765                     (dired-goto-next-nontrivial-file))
 766                 ;; not found
 767                 (throw 'not-found "Subdir not found")))
 768             (let (buffer-read-only opoint)
 769               (beginning-of-line)
 770               (setq opoint (point))
 771               (dired-add-entry-do-indentation marker-char)
 772               ;; don't expand `.'.  Show just the file name within directory.
 773               (let ((default-directory directory))
 774                 (insert-directory filename
 775                                   (concat dired-actual-switches "d")))
 776               (dired-insert-set-properties opoint (point))
 777               (forward-line -1)
 778               (if dired-after-readin-hook;; the subdir-alist is not affected...
 779                   (save-excursion;; ...so we can run it right now:
 780                     (save-restriction
 781                       (beginning-of-line)
 782                       (narrow-to-region (point) (save-excursion
 783                                                   (forward-line 1) (point)))
 784                       (run-hooks 'dired-after-readin-hook))))
 785               (dired-move-to-filename))
 786             ;; return nil if all went well
 787             nil))
 788     (if reason                          ; don't move away on failure
 789         (goto-char opoint))
 790     (not reason)))                      ; return t on success, nil else
 791
 792 ;; This is a separate function for the sake of nested dired format.
 793 (defun dired-add-entry-do-indentation (marker-char)
 794   ;; two spaces or a marker plus a space:
 795   (insert (if marker-char
 796               (if (integerp marker-char) marker-char dired-marker-char)
 797             ?\040)
 798           ?\040))
 799
 800 (defun dired-after-subdir-garbage (dir)
 801   ;; Return pos of first file line of DIR, skipping header and total
 802   ;; or wildcard lines.
 803   ;; Important: never moves into the next subdir.
 804   ;; DIR is assumed to be unhidden.
 805   ;; Will probably be redefined for VMS etc.
 806   (save-excursion
 807     (or (dired-goto-subdir dir) (error "This cannot happen"))
 808     (forward-line 1)
 809     (while (and (not (eolp))            ; don't cross subdir boundary
 810                 (not (dired-move-to-filename)))
 811         (forward-line 1))
 812     (point)))
 813
 814 ;;;###autoload
 815 (defun dired-remove-file (file)
 816   (dired-fun-in-all-buffers
 817    (file-name-directory file) (function dired-remove-entry) file))
 818
 819 (defun dired-remove-entry (file)
 820   (save-excursion
 821     (and (dired-goto-file file)
 822          (let (buffer-read-only)
 823            (delete-region (progn (beginning-of-line) (point))
 824                           (save-excursion (forward-line 1) (point)))))))
 825
 826 ;;;###autoload
 827 (defun dired-relist-file (file)
 828   (dired-fun-in-all-buffers (file-name-directory file)
 829                             (function dired-relist-entry) file))
 830
 831 (defun dired-relist-entry (file)
 832   ;; Relist the line for FILE, or just add it if it did not exist.
 833   ;; FILE must be an absolute pathname.
 834   (let (buffer-read-only marker)
 835     ;; If cursor is already on FILE's line delete-region will cause
 836     ;; save-excursion to fail because of floating makers,
 837     ;; moving point to beginning of line.  Sigh.
 838     (save-excursion
 839       (and (dired-goto-file file)
 840            (delete-region (progn (beginning-of-line)
 841                                  (setq marker (following-char))
 842                                  (point))
 843                           (save-excursion (forward-line 1) (point))))
 844       (setq file (directory-file-name file))
 845       (dired-add-entry file (if (eq ?\040 marker) nil marker)))))
 846 \f
 847 ;;; Copy, move/rename, making hard and symbolic links
 848
 849 (defvar dired-backup-overwrite nil
 850   "*Non-nil if Dired should ask about making backups before overwriting files.
 851 Special value `always' suppresses confirmation.")
 852
 853 (defvar dired-overwrite-confirmed)
 854
 855 (defun dired-handle-overwrite (to)
 856   ;; Save old version of a to be overwritten file TO.
 857   ;; `dired-overwrite-confirmed' and `overwrite-backup-query' are fluid vars
 858   ;; from dired-create-files.
 859   (if (and dired-backup-overwrite
 860            dired-overwrite-confirmed
 861            (or (eq 'always dired-backup-overwrite)
 862                (dired-query 'overwrite-backup-query
 863                         (format "Make backup for existing file `%s'? " to))))
 864       (let ((backup (car (find-backup-file-name to))))
 865         (rename-file to backup 0)       ; confirm overwrite of old backup
 866         (dired-relist-entry backup))))
 867
 868 ;;;###autoload
 869 (defun dired-copy-file (from to ok-flag)
 870   (dired-handle-overwrite to)
 871   (copy-file from to ok-flag dired-copy-preserve-time))
 872
 873 ;;;###autoload
 874 (defun dired-rename-file (from to ok-flag)
 875   (dired-handle-overwrite to)
 876   (rename-file from to ok-flag)         ; error is caught in -create-files
 877   ;; Silently rename the visited file of any buffer visiting this file.
 878   (and (get-file-buffer from)
 879        (save-excursion
 880          (set-buffer (get-file-buffer from))
 881          (let ((modflag (buffer-modified-p)))
 882            (set-visited-file-name to)
 883            (set-buffer-modified-p modflag))))
 884   (dired-remove-file from)
 885   ;; See if it's an inserted subdir, and rename that, too.
 886   (dired-rename-subdir from to))
 887
 888 (defun dired-rename-subdir (from-dir to-dir)
 889   (setq from-dir (file-name-as-directory from-dir)
 890         to-dir (file-name-as-directory to-dir))
 891   (dired-fun-in-all-buffers from-dir
 892                             (function dired-rename-subdir-1) from-dir to-dir)
 893   ;; Update visited file name of all affected buffers
 894   (let ((blist (buffer-list)))
 895     (while blist
 896       (save-excursion
 897         (set-buffer (car blist))
 898         (if (and buffer-file-name
 899                  (dired-in-this-tree buffer-file-name from-dir))
 900             (let ((modflag (buffer-modified-p))
 901                   (to-file (dired-replace-in-string
 902                             (concat "^" (regexp-quote from-dir))
 903                             to-dir
 904                             buffer-file-name)))
 905               (set-visited-file-name to-file)
 906               (set-buffer-modified-p modflag))))
 907       (setq blist (cdr blist)))))
 908
 909 (defun dired-rename-subdir-1 (dir to)
 910   ;; Rename DIR to TO in headerlines and dired-subdir-alist, if DIR or
 911   ;; one of its subdirectories is expanded in this buffer.
 912   (let ((alist dired-subdir-alist)
 913         (elt nil))
 914     (while alist
 915       (setq elt (car alist)
 916             alist (cdr alist))
 917       (if (dired-in-this-tree (car elt) dir)
 918           ;; ELT's subdir is affected by the rename
 919           (dired-rename-subdir-2 elt dir to)))
 920     (if (equal dir default-directory)
 921         ;; if top level directory was renamed, lots of things have to be
 922         ;; updated:
 923         (progn
 924           (dired-unadvertise dir)       ; we no longer dired DIR...
 925           (setq default-directory to
 926                 dired-directory (expand-file-name;; this is correct
 927                                  ;; with and without wildcards
 928                                  (file-name-nondirectory dired-directory)
 929                                  to))
 930           (let ((new-name (file-name-nondirectory
 931                            (directory-file-name dired-directory))))
 932             ;; try to rename buffer, but just leave old name if new
 933             ;; name would already exist (don't try appending "<%d>")
 934             (or (get-buffer new-name)
 935                 (rename-buffer new-name)))
 936           ;; ... we dired TO now:
 937           (dired-advertise)))))
 938
 939 (defun dired-rename-subdir-2 (elt dir to)
 940   ;; Update the headerline and dired-subdir-alist element of directory
 941   ;; described by alist-element ELT to reflect the moving of DIR to TO.
 942   ;; Thus, ELT describes either DIR itself or a subdir of DIR.
 943   (save-excursion
 944     (let ((regexp (regexp-quote (directory-file-name dir)))
 945           (newtext (directory-file-name to))
 946           buffer-read-only)
 947       (goto-char (dired-get-subdir-min elt))
 948       ;; Update subdir headerline in buffer
 949       (if (not (looking-at dired-subdir-regexp))
 950           (error "%s not found where expected - dired-subdir-alist broken?"
 951                  dir)
 952         (goto-char (match-beginning 1))
 953         (if (re-search-forward regexp (match-end 1) t)
 954             (replace-match newtext t t)
 955           (error "Expected to find `%s' in headerline of %s" dir (car elt))))
 956       ;; Update buffer-local dired-subdir-alist
 957       (setcar elt
 958               (dired-normalize-subdir
 959                (dired-replace-in-string regexp newtext (car elt)))))))
 960 \f
 961 ;; Cloning replace-match to work on strings instead of in buffer:
 962 ;; The FIXEDCASE parameter of replace-match is not implemented.
 963 ;;;###autoload
 964 (defun dired-string-replace-match (regexp string newtext
 965                                           &optional literal global)
 966   "Replace first match of REGEXP in STRING with NEWTEXT.
 967 If it does not match, nil is returned instead of the new string.
 968 Optional arg LITERAL means to take NEWTEXT literally.
 969 Optional arg GLOBAL means to replace all matches."
 970   (if global
 971         (let ((result "") (start 0) mb me)
 972           (while (string-match regexp string start)
 973             (setq mb (match-beginning 0)
 974                   me (match-end 0)
 975                   result (concat result
 976                                  (substring string start mb)
 977                                  (if literal
 978                                      newtext
 979                                    (dired-expand-newtext string newtext)))
 980                   start me))
 981           (if mb                        ; matched at least once
 982               (concat result (substring string start))
 983             nil))
 984     ;; not GLOBAL
 985     (if (not (string-match regexp string 0))
 986         nil
 987       (concat (substring string 0 (match-beginning 0))
 988               (if literal newtext (dired-expand-newtext string newtext))
 989               (substring string (match-end 0))))))
 990
 991 (defun dired-expand-newtext (string newtext)
 992   ;; Expand \& and \1..\9 (referring to STRING) in NEWTEXT, using match data.
 993   ;; Note that in Emacs 18 match data are clipped to current buffer
 994   ;; size...so the buffer should better not be smaller than STRING.
 995   (let ((pos 0)
 996         (len (length newtext))
 997         (expanded-newtext ""))
 998     (while (< pos len)
 999       (setq expanded-newtext
1000             (concat expanded-newtext
1001                     (let ((c (aref newtext pos)))
1002                       (if (= ?\\ c)
1003                           (cond ((= ?\& (setq c
1004                                               (aref newtext
1005                                                     (setq pos (1+ pos)))))
1006                                  (substring string
1007                                             (match-beginning 0)
1008                                             (match-end 0)))
1009                                 ((and (>= c ?1) (<= c ?9))
1010                                  ;; return empty string if N'th
1011                                  ;; sub-regexp did not match:
1012                                  (let ((n (- c ?0)))
1013                                    (if (match-beginning n)
1014                                        (substring string
1015                                                   (match-beginning n)
1016                                                   (match-end n))
1017                                      "")))
1018                                 (t
1019                                  (char-to-string c)))
1020                         (char-to-string c)))))
1021       (setq pos (1+ pos)))
1022     expanded-newtext))
1023 \f
1024 ;; The basic function for half a dozen variations on cp/mv/ln/ln -s.
1025 (defun dired-create-files (file-creator operation fn-list name-constructor
1026                                         &optional marker-char)
1027
1028 ;; Create a new file for each from a list of existing files.  The user
1029 ;; is queried, dired buffers are updated, and at the end a success or
1030 ;; failure message is displayed
1031
1032 ;; FILE-CREATOR must accept three args: oldfile newfile ok-if-already-exists
1033
1034 ;; It is called for each file and must create newfile, the entry of
1035 ;; which will be added.  The user will be queried if the file already
1036 ;; exists.  If oldfile is removed by FILE-CREATOR (i.e, it is a
1037 ;; rename), it is FILE-CREATOR's responsibility to update dired
1038 ;; buffers.  FILE-CREATOR must abort by signalling a file-error if it
1039 ;; could not create newfile.  The error is caught and logged.
1040
1041 ;; OPERATION (a capitalized string, e.g. `Copy') describes the
1042 ;; operation performed.  It is used for error logging.
1043
1044 ;; FN-LIST is the list of files to copy (full absolute pathnames).
1045
1046 ;; NAME-CONSTRUCTOR returns a newfile for every oldfile, or nil to
1047 ;; skip.  If it skips files for other reasons than a direct user
1048 ;; query, it is supposed to tell why (using dired-log).
1049
1050 ;; Optional MARKER-CHAR is a character with which to mark every
1051 ;; newfile's entry, or t to use the current marker character if the
1052 ;; oldfile was marked.
1053
1054   (let (failures skipped (success-count 0) (total (length fn-list)))
1055     (let (to overwrite-query
1056              overwrite-backup-query)    ; for dired-handle-overwrite
1057       (mapcar
1058        (function
1059         (lambda (from)
1060           (setq to (funcall name-constructor from))
1061           (if (equal to from)
1062               (progn
1063                 (setq to nil)
1064                 (dired-log "Cannot %s to same file: %s\n"
1065                            (downcase operation) from)))
1066           (if (not to)
1067               (setq skipped (cons (dired-make-relative from) skipped))
1068             (let* ((overwrite (file-exists-p to))
1069                    (dired-overwrite-confirmed   ; for dired-handle-overwrite
1070                     (and overwrite
1071                          (let ((help-form '(format "\
1072 Type SPC or `y' to overwrite file `%s',
1073 DEL or `n' to skip to next,
1074 ESC or `q' to not overwrite any of the remaining files,
1075 `!' to overwrite all remaining files with no more questions." to)))
1076                            (dired-query 'overwrite-query
1077                                         "Overwrite `%s'?" to))))
1078                    ;; must determine if FROM is marked before file-creator
1079                    ;; gets a chance to delete it (in case of a move).
1080                    (actual-marker-char
1081                     (cond  ((integerp marker-char) marker-char)
1082                            (marker-char (dired-file-marker from)) ; slow
1083                            (t nil))))
1084               (condition-case err
1085                   (progn
1086                     (funcall file-creator from to dired-overwrite-confirmed)
1087                     (if overwrite
1088                         ;; If we get here, file-creator hasn't been aborted
1089                         ;; and the old entry (if any) has to be deleted
1090                         ;; before adding the new entry.
1091                         (dired-remove-file to))
1092                     (setq success-count (1+ success-count))
1093                     (message "%s: %d of %d" operation success-count total)
1094                     (dired-add-file to actual-marker-char))
1095                 (file-error             ; FILE-CREATOR aborted
1096                  (progn
1097                    (setq failures (cons (dired-make-relative from) failures))
1098                    (dired-log "%s `%s' to `%s' failed:\n%s\n"
1099                               operation from to err))))))))
1100        fn-list))
1101     (cond
1102      (failures
1103       (dired-log-summary
1104        (format "%s failed for %d of %d file%s"
1105                 operation (length failures) total
1106                 (dired-plural-s total))
1107        failures))
1108      (skipped
1109       (dired-log-summary
1110        (format "%s: %d of %d file%s skipped"
1111                 operation (length skipped) total
1112                 (dired-plural-s total))
1113        skipped))
1114      (t
1115       (message "%s: %s file%s"
1116                operation success-count (dired-plural-s success-count)))))
1117   (dired-move-to-filename))
1118 \f
1119 (defun dired-do-create-files (op-symbol file-creator operation arg
1120                                              &optional marker-char op1
1121                                              how-to)
1122   ;; Create a new file for each marked file.
1123   ;; Prompts user for target, which is a directory in which to create
1124   ;;   the new files.  Target may be a plain file if only one marked
1125   ;;   file exists.
1126   ;; OP-SYMBOL is the symbol for the operation.  Function `dired-mark-pop-up'
1127   ;;   will determine whether pop-ups are appropriate for this OP-SYMBOL.
1128   ;; FILE-CREATOR and OPERATION as in dired-create-files.
1129   ;; ARG as in dired-get-marked-files.
1130   ;; Optional arg OP1 is an alternate form for OPERATION if there is
1131   ;;   only one file.
1132   ;; Optional arg MARKER-CHAR as in dired-create-files.
1133   ;; Optional arg HOW-TO determines how to treat target:
1134   ;;   If HOW-TO is not given (or nil), and target is a directory, the
1135   ;;     file(s) are created inside the target directory.  If target
1136   ;;     is not a directory, there must be exactly one marked file,
1137   ;;     else error.
1138   ;;   If HOW-TO is t, then target is not modified.  There must be
1139   ;;     exactly one marked file, else error.
1140   ;; Else HOW-TO is assumed to be a function of one argument, target,
1141   ;;     that looks at target and returns a value for the into-dir
1142   ;;     variable.  The function dired-into-dir-with-symlinks is provided
1143   ;;     for the case (common when creating symlinks) that symbolic
1144   ;;     links to directories are not to be considered as directories
1145   ;;     (as file-directory-p would if HOW-TO had been nil).
1146   (or op1 (setq op1 operation))
1147   (let* ((fn-list (dired-get-marked-files nil arg))
1148          (fn-count (length fn-list))
1149          (target (expand-file-name
1150                    (dired-mark-read-file-name
1151                     (concat (if (= 1 fn-count) op1 operation) " %s to: ")
1152                     (dired-dwim-target-directory)
1153                     op-symbol arg (mapcar (function dired-make-relative) fn-list))))
1154          (into-dir (cond ((null how-to) (file-directory-p target))
1155                          ((eq how-to t) nil)
1156                          (t (funcall how-to target)))))
1157     (if (and (> fn-count 1)
1158              (not into-dir))
1159         (error "Marked %s: target must be a directory: %s" operation target))
1160     ;; rename-file bombs when moving directories unless we do this:
1161     (or into-dir (setq target (directory-file-name target)))
1162     (dired-create-files
1163      file-creator operation fn-list
1164      (if into-dir                       ; target is a directory
1165          ;; This function uses fluid vars into-dir and target when called
1166          ;; inside dired-create-files:
1167          (function (lambda (from)
1168                      (expand-file-name (file-name-nondirectory from) target)))
1169        (function (lambda (from) target)))
1170      marker-char)))
1171
1172 ;; Read arguments for a marked-files command that wants a file name,
1173 ;; perhaps popping up the list of marked files.
1174 ;; ARG is the prefix arg and indicates whether the files came from
1175 ;; marks (ARG=nil) or a repeat factor (integerp ARG).
1176 ;; If the current file was used, the list has but one element and ARG
1177 ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)).
1178
1179 (defun dired-mark-read-file-name (prompt dir op-symbol arg files)
1180   (dired-mark-pop-up
1181    nil op-symbol files
1182    (function read-file-name)
1183    (format prompt (dired-mark-prompt arg files)) dir))
1184
1185 (defun dired-dwim-target-directory ()
1186   ;; Try to guess which target directory the user may want.
1187   ;; If there is a dired buffer displayed in the next window, use
1188   ;; its current subdir, else use current subdir of this dired buffer.
1189   (let ((this-dir (and (eq major-mode 'dired-mode)
1190                        (dired-current-directory))))
1191     ;; non-dired buffer may want to profit from this function, e.g. vm-uudecode
1192     (if dired-dwim-target
1193         (let* ((other-buf (window-buffer (next-window)))
1194                (other-dir (save-excursion
1195                             (set-buffer other-buf)
1196                             (and (eq major-mode 'dired-mode)
1197                                  (dired-current-directory)))))
1198           (or other-dir this-dir))
1199       this-dir)))
1200 \f
1201 ;;;###autoload
1202 (defun dired-create-directory (directory)
1203   "Create a directory called DIRECTORY."
1204   (interactive
1205    (list (read-file-name "Create directory: " (dired-current-directory))))
1206   (let ((expanded (directory-file-name (expand-file-name directory))))
1207     (make-directory expanded)
1208     (dired-add-file expanded)
1209     (dired-move-to-filename)))
1210
1211 (defun dired-into-dir-with-symlinks (target)
1212   (and (file-directory-p target)
1213        (not (file-symlink-p target))))
1214 ;; This may not always be what you want, especially if target is your
1215 ;; home directory and it happens to be a symbolic link, as is often the
1216 ;; case with NFS and automounters.  Or if you want to make symlinks
1217 ;; into directories that themselves are only symlinks, also quite
1218 ;; common.
1219
1220 ;; So we don't use this function as value for HOW-TO in
1221 ;; dired-do-symlink, which has the minor disadvantage of
1222 ;; making links *into* a symlinked-dir, when you really wanted to
1223 ;; *overwrite* that symlink.  In that (rare, I guess) case, you'll
1224 ;; just have to remove that symlink by hand before making your marked
1225 ;; symlinks.
1226
1227 ;;;###autoload
1228 (defun dired-do-copy (&optional arg)
1229   "Copy all marked (or next ARG) files, or copy the current file.
1230 This normally preserves the last-modified date when copying.
1231 When operating on just the current file, you specify the new name.
1232 When operating on multiple or marked files, you specify a directory
1233 and new symbolic links are made in that directory
1234 with the same names that the files currently have."
1235   (interactive "P")
1236   (dired-do-create-files 'copy (function dired-copy-file)
1237                            (if dired-copy-preserve-time "Copy [-p]" "Copy")
1238                            arg dired-keep-marker-copy))
1239
1240 ;;;###autoload
1241 (defun dired-do-symlink (&optional arg)
1242   "Make symbolic links to current file or all marked (or next ARG) files.
1243 When operating on just the current file, you specify the new name.
1244 When operating on multiple or marked files, you specify a directory
1245 and new symbolic links are made in that directory
1246 with the same names that the files currently have."
1247   (interactive "P")
1248   (dired-do-create-files 'symlink (function make-symbolic-link)
1249                            "Symlink" arg dired-keep-marker-symlink))
1250
1251 ;;;###autoload
1252 (defun dired-do-hardlink (&optional arg)
1253   "Add names (hard links) current file or all marked (or next ARG) files.
1254 When operating on just the current file, you specify the new name.
1255 When operating on multiple or marked files, you specify a directory
1256 and new hard links are made in that directory
1257 with the same names that the files currently have."
1258   (interactive "P")
1259   (dired-do-create-files 'hardlink (function add-name-to-file)
1260                            "Hardlink" arg dired-keep-marker-hardlink))
1261
1262 ;;;###autoload
1263 (defun dired-do-rename (&optional arg)
1264   "Rename current file or all marked (or next ARG) files.
1265 When renaming just the current file, you specify the new name.
1266 When renaming multiple or marked files, you specify a directory."
1267   (interactive "P")
1268   (dired-do-create-files 'move (function dired-rename-file)
1269                          "Move" arg dired-keep-marker-rename "Rename"))
1270 ;;;###end dired-cp.el
1271 \f
1272 ;;; 5K
1273 ;;;###begin dired-re.el
1274 (defun dired-do-create-files-regexp
1275   (file-creator operation arg regexp newname &optional whole-path marker-char)
1276   ;; Create a new file for each marked file using regexps.
1277   ;; FILE-CREATOR and OPERATION as in dired-create-files.
1278   ;; ARG as in dired-get-marked-files.
1279   ;; Matches each marked file against REGEXP and constructs the new
1280   ;;   filename from NEWNAME (like in function replace-match).
1281   ;; Optional arg WHOLE-PATH means match/replace the whole pathname
1282   ;;   instead of only the non-directory part of the file.
1283   ;; Optional arg MARKER-CHAR as in dired-create-files.
1284   (let* ((fn-list (dired-get-marked-files nil arg))
1285          (fn-count (length fn-list))
1286          (operation-prompt (concat operation " `%s' to `%s'?"))
1287          (rename-regexp-help-form (format "\
1288 Type SPC or `y' to %s one match, DEL or `n' to skip to next,
1289 `!' to %s all remaining matches with no more questions."
1290                                           (downcase operation)
1291                                           (downcase operation)))
1292          (regexp-name-constructor
1293           ;; Function to construct new filename using REGEXP and NEWNAME:
1294           (if whole-path                ; easy (but rare) case
1295               (function
1296                (lambda (from)
1297                  (let ((to (dired-string-replace-match regexp from newname))
1298                        ;; must bind help-form directly around call to
1299                        ;; dired-query
1300                        (help-form rename-regexp-help-form))
1301                    (if to
1302                        (and (dired-query 'rename-regexp-query
1303                                          operation-prompt
1304                                          from
1305                                          to)
1306                             to)
1307                      (dired-log "%s: %s did not match regexp %s\n"
1308                                 operation from regexp)))))
1309             ;; not whole-path, replace non-directory part only
1310             (function
1311              (lambda (from)
1312                (let* ((new (dired-string-replace-match
1313                             regexp (file-name-nondirectory from) newname))
1314                       (to (and new      ; nil means there was no match
1315                                (expand-file-name new
1316                                                  (file-name-directory from))))
1317                       (help-form rename-regexp-help-form))
1318                  (if to
1319                      (and (dired-query 'rename-regexp-query
1320                                        operation-prompt
1321                                        (dired-make-relative from)
1322                                        (dired-make-relative to))
1323                           to)
1324                    (dired-log "%s: %s did not match regexp %s\n"
1325                               operation (file-name-nondirectory from) regexp)))))))
1326          rename-regexp-query)
1327     (dired-create-files
1328      file-creator operation fn-list regexp-name-constructor marker-char)))
1329
1330 (defun dired-mark-read-regexp (operation)
1331   ;; Prompt user about performing OPERATION.
1332   ;; Read and return list of: regexp newname arg whole-path.
1333   (let* ((whole-path
1334           (equal 0 (prefix-numeric-value current-prefix-arg)))
1335          (arg
1336           (if whole-path nil current-prefix-arg))
1337          (regexp
1338           (dired-read-regexp
1339            (concat (if whole-path "Path " "") operation " from (regexp): ")))
1340          (newname
1341           (read-string
1342            (concat (if whole-path "Path " "") operation " " regexp " to: "))))
1343     (list regexp newname arg whole-path)))
1344
1345 ;;;###autoload
1346 (defun dired-do-rename-regexp (regexp newname &optional arg whole-path)
1347   "Rename marked files containing REGEXP to NEWNAME.
1348 As each match is found, the user must type a character saying
1349   what to do with it.  For directions, type \\[help-command] at that time.
1350 NEWNAME may contain \\=\\<n> or \\& as in `query-replace-regexp'.
1351 REGEXP defaults to the last regexp used.
1352 With a zero prefix arg, renaming by regexp affects the complete
1353   pathname - usually only the non-directory part of file names is used
1354   and changed."
1355   (interactive (dired-mark-read-regexp "Rename"))
1356   (dired-do-create-files-regexp
1357    (function dired-rename-file)
1358    "Rename" arg regexp newname whole-path dired-keep-marker-rename))
1359
1360 ;;;###autoload
1361 (defun dired-do-copy-regexp (regexp newname &optional arg whole-path)
1362   "Copy all marked files containing REGEXP to NEWNAME.
1363 See function `dired-rename-regexp' for more info."
1364   (interactive (dired-mark-read-regexp "Copy"))
1365   (dired-do-create-files-regexp
1366    (function dired-copy-file)
1367    (if dired-copy-preserve-time "Copy [-p]" "Copy")
1368    arg regexp newname whole-path dired-keep-marker-copy))
1369
1370 ;;;###autoload
1371 (defun dired-do-hardlink-regexp (regexp newname &optional arg whole-path)
1372   "Hardlink all marked files containing REGEXP to NEWNAME.
1373 See function `dired-rename-regexp' for more info."
1374   (interactive (dired-mark-read-regexp "HardLink"))
1375   (dired-do-create-files-regexp
1376    (function add-name-to-file)
1377    "HardLink" arg regexp newname whole-path dired-keep-marker-hardlink))
1378
1379 ;;;###autoload
1380 (defun dired-do-symlink-regexp (regexp newname &optional arg whole-path)
1381   "Symlink all marked files containing REGEXP to NEWNAME.
1382 See function `dired-rename-regexp' for more info."
1383   (interactive (dired-mark-read-regexp "SymLink"))
1384   (dired-do-create-files-regexp
1385    (function make-symbolic-link)
1386    "SymLink" arg regexp newname whole-path dired-keep-marker-symlink))
1387
1388 (defun dired-create-files-non-directory
1389   (file-creator basename-constructor operation arg)
1390   ;; Perform FILE-CREATOR on the non-directory part of marked files
1391   ;; using function BASENAME-CONSTRUCTOR, with query for each file.
1392   ;; OPERATION like in dired-create-files, ARG as in dired-get-marked-files.
1393   (let (rename-non-directory-query)
1394     (dired-create-files
1395      file-creator
1396      operation
1397      (dired-get-marked-files nil arg)
1398      (function
1399       (lambda (from)
1400         (let ((to (concat (file-name-directory from)
1401                           (funcall basename-constructor
1402                                    (file-name-nondirectory from)))))
1403           (and (let ((help-form (format "\
1404 Type SPC or `y' to %s one file, DEL or `n' to skip to next,
1405 `!' to %s all remaining matches with no more questions."
1406                                         (downcase operation)
1407                                         (downcase operation))))
1408                  (dired-query 'rename-non-directory-query
1409                               (concat operation " `%s' to `%s'")
1410                               (dired-make-relative from)
1411                               (dired-make-relative to)))
1412                to))))
1413      dired-keep-marker-rename)))
1414
1415 (defun dired-rename-non-directory (basename-constructor operation arg)
1416   (dired-create-files-non-directory
1417    (function dired-rename-file)
1418    basename-constructor operation arg))
1419
1420 ;;;###autoload
1421 (defun dired-upcase (&optional arg)
1422   "Rename all marked (or next ARG) files to upper case."
1423   (interactive "P")
1424   (dired-rename-non-directory (function upcase) "Rename upcase" arg))
1425
1426 ;;;###autoload
1427 (defun dired-downcase (&optional arg)
1428   "Rename all marked (or next ARG) files to lower case."
1429   (interactive "P")
1430   (dired-rename-non-directory (function downcase) "Rename downcase" arg))
1431
1432 ;;;###end dired-re.el
1433 \f
1434 ;;; 13K
1435 ;;;###begin dired-ins.el
1436
1437 ;;;###autoload
1438 (defun dired-maybe-insert-subdir (dirname &optional
1439                                           switches no-error-if-not-dir-p)
1440   "Insert this subdirectory into the same dired buffer.
1441 If it is already present, just move to it (type \\[dired-do-redisplay] to refresh),
1442   else inserts it at its natural place (as `ls -lR' would have done).
1443 With a prefix arg, you may edit the ls switches used for this listing.
1444   You can add `R' to the switches to expand the whole tree starting at
1445   this subdirectory.
1446 This function takes some pains to conform to `ls -lR' output."
1447   (interactive
1448    (list (dired-get-filename)
1449          (if current-prefix-arg
1450              (read-string "Switches for listing: " dired-actual-switches))))
1451   (let ((opoint (point)))
1452     ;; We don't need a marker for opoint as the subdir is always
1453     ;; inserted *after* opoint.
1454     (setq dirname (file-name-as-directory dirname))
1455     (or (and (not switches)
1456              (dired-goto-subdir dirname))
1457         (dired-insert-subdir dirname switches no-error-if-not-dir-p))
1458     ;; Push mark so that it's easy to find back.  Do this after the
1459     ;; insert message so that the user sees the `Mark set' message.
1460     (push-mark opoint)))
1461
1462 (defun dired-insert-subdir (dirname &optional switches no-error-if-not-dir-p)
1463   "Insert this subdirectory into the same dired buffer.
1464 If it is already present, overwrites previous entry,
1465   else inserts it at its natural place (as `ls -lR' would have done).
1466 With a prefix arg, you may edit the `ls' switches used for this listing.
1467   You can add `R' to the switches to expand the whole tree starting at
1468   this subdirectory.
1469 This function takes some pains to conform to `ls -lR' output."
1470   ;; NO-ERROR-IF-NOT-DIR-P needed for special filesystems like
1471   ;; Prospero where dired-ls does the right thing, but
1472   ;; file-directory-p has not been redefined.
1473   (interactive
1474    (list (dired-get-filename)
1475          (if current-prefix-arg
1476              (read-string "Switches for listing: " dired-actual-switches))))
1477   (setq dirname (file-name-as-directory (expand-file-name dirname)))
1478   (dired-insert-subdir-validate dirname switches)
1479   (or no-error-if-not-dir-p
1480       (file-directory-p dirname)
1481       (error  "Attempt to insert a non-directory: %s" dirname))
1482   (let ((elt (assoc dirname dired-subdir-alist))
1483          switches-have-R mark-alist case-fold-search buffer-read-only)
1484     ;; case-fold-search is nil now, so we can test for capital `R':
1485     (if (setq switches-have-R (and switches (string-match "R" switches)))
1486         ;; avoid duplicated subdirs
1487         (setq mark-alist (dired-kill-tree dirname t)))
1488     (if elt
1489         ;; If subdir is already present, remove it and remember its marks
1490         (setq mark-alist (nconc (dired-insert-subdir-del elt) mark-alist))
1491       (dired-insert-subdir-newpos dirname)) ; else compute new position
1492     (dired-insert-subdir-doupdate
1493      dirname elt (dired-insert-subdir-doinsert dirname switches))
1494     (if switches-have-R (dired-build-subdir-alist))
1495     (dired-initial-position dirname)
1496     (save-excursion (dired-mark-remembered mark-alist))))
1497
1498 ;; This is a separate function for dired-vms.
1499 (defun dired-insert-subdir-validate (dirname &optional switches)
1500   ;; Check that it is valid to insert DIRNAME with SWITCHES.
1501   ;; Signal an error if invalid (e.g. user typed `i' on `..').
1502   (or (dired-in-this-tree dirname (expand-file-name default-directory))
1503       (error  "%s: not in this directory tree" dirname))
1504   (if switches
1505       (let (case-fold-search)
1506         (mapcar
1507          (function
1508           (lambda (x)
1509             (or (eq (null (string-match x switches))
1510                     (null (string-match x dired-actual-switches)))
1511                 (error "Can't have dirs with and without -%s switches together"
1512                        x))))
1513          ;; all switches that make a difference to dired-get-filename:
1514          '("F" "b")))))
1515
1516 (defun dired-alist-add (dir new-marker)
1517   ;; Add new DIR at NEW-MARKER.  Sort alist.
1518   (dired-alist-add-1 dir new-marker)
1519   (dired-alist-sort))
1520
1521 (defun dired-alist-sort ()
1522   ;; Keep the alist sorted on buffer position.
1523   (setq dired-subdir-alist
1524         (sort dired-subdir-alist
1525               (function (lambda (elt1 elt2)
1526                           (> (dired-get-subdir-min elt1)
1527                              (dired-get-subdir-min elt2)))))))
1528
1529 (defun dired-kill-tree (dirname &optional remember-marks)
1530   ;;"Kill all proper subdirs of DIRNAME, excluding DIRNAME itself.
1531   ;; With optional arg REMEMBER-MARKS, return an alist of marked files."
1532   (interactive "DKill tree below directory: ")
1533   (let ((s-alist dired-subdir-alist) dir m-alist)
1534     (while s-alist
1535       (setq dir (car (car s-alist))
1536             s-alist (cdr s-alist))
1537       (if (and (not (string-equal dir dirname))
1538                (dired-in-this-tree dir dirname)
1539                (dired-goto-subdir dir))
1540           (setq m-alist (nconc (dired-kill-subdir remember-marks) m-alist))))
1541     m-alist))
1542
1543 (defun dired-insert-subdir-newpos (new-dir)
1544   ;; Find pos for new subdir, according to tree order.
1545   ;;(goto-char (point-max))
1546   (let ((alist dired-subdir-alist) elt dir pos new-pos)
1547     (while alist
1548       (setq elt (car alist)
1549             alist (cdr alist)
1550             dir (car elt)
1551             pos (dired-get-subdir-min elt))
1552       (if (dired-tree-lessp dir new-dir)
1553           ;; Insert NEW-DIR after DIR
1554           (setq new-pos (dired-get-subdir-max elt)
1555                 alist nil)))
1556     (goto-char new-pos))
1557   ;; want a separating newline between subdirs
1558   (or (eobp)
1559       (forward-line -1))
1560   (insert "\n")
1561   (point))
1562
1563 (defun dired-insert-subdir-del (element)
1564   ;; Erase an already present subdir (given by ELEMENT) from buffer.
1565   ;; Move to that buffer position.  Return a mark-alist.
1566   (let ((begin-marker (dired-get-subdir-min element)))
1567     (goto-char begin-marker)
1568     ;; Are at beginning of subdir (and inside it!).  Now determine its end:
1569     (goto-char (dired-subdir-max))
1570     (or (eobp);; want a separating newline _between_ subdirs:
1571         (forward-char -1))
1572     (prog1
1573         (dired-remember-marks begin-marker (point))
1574       (delete-region begin-marker (point)))))
1575
1576 (defun dired-insert-subdir-doinsert (dirname switches)
1577   ;; Insert ls output after point and put point on the correct
1578   ;; position for the subdir alist.
1579   ;; Return the boundary of the inserted text (as list of BEG and END).
1580   (let ((begin (point)) end)
1581     (message "Reading directory %s..." dirname)
1582     (let ((dired-actual-switches
1583            (or switches
1584                (dired-replace-in-string "R" "" dired-actual-switches))))
1585       (if (equal dirname (car (car (reverse dired-subdir-alist))))
1586           ;; top level directory may contain wildcards:
1587           (dired-readin-insert dired-directory)
1588         (let ((opoint (point)))
1589           (insert-directory dirname dired-actual-switches nil t)
1590           (dired-insert-set-properties opoint (point)))))
1591     (message "Reading directory %s...done" dirname)
1592     (setq end (point-marker))
1593     (indent-rigidly begin end 2)
1594     ;;  call dired-insert-headerline afterwards, as under VMS dired-ls
1595     ;;  does insert the headerline itself and the insert function just
1596     ;;  moves point.
1597     ;;  Need a marker for END as this inserts text.
1598     (goto-char begin)
1599     (dired-insert-headerline dirname)
1600     ;; point is now like in dired-build-subdir-alist
1601     (prog1
1602         (list begin (marker-position end))
1603       (set-marker end nil))))
1604
1605 (defun dired-insert-subdir-doupdate (dirname elt beg-end)
1606   ;; Point is at the correct subdir alist position for ELT,
1607   ;; BEG-END is the subdir-region (as list of begin and end).
1608   (if elt                               ; subdir was already present
1609       ;; update its position (should actually be unchanged)
1610       (set-marker (dired-get-subdir-min elt) (point-marker))
1611     (dired-alist-add dirname (point-marker)))
1612   ;; The hook may depend on the subdir-alist containing the just
1613   ;; inserted subdir, so run it after dired-alist-add:
1614   (if dired-after-readin-hook
1615       (save-excursion
1616         (let ((begin (nth 0 beg-end))
1617               (end (nth 1 beg-end)))
1618           (goto-char begin)
1619           (save-restriction
1620             (narrow-to-region begin end)
1621             ;; hook may add or delete lines, but the subdir boundary
1622             ;; marker floats
1623             (run-hooks 'dired-after-readin-hook))))))
1624
1625 (defun dired-tree-lessp (dir1 dir2)
1626   ;; Lexicographic order on pathname components, like `ls -lR':
1627   ;; DIR1 < DIR2 iff DIR1 comes *before* DIR2 in an `ls -lR' listing,
1628   ;;   i.e., iff DIR1 is a (grand)parent dir of DIR2,
1629   ;;   or DIR1 and DIR2 are in the same parentdir and their last
1630   ;;   components are string-lessp.
1631   ;; Thus ("/usr/" "/usr/bin") and ("/usr/a/" "/usr/b/") are tree-lessp.
1632   ;; string-lessp could arguably be replaced by file-newer-than-file-p
1633   ;;   if dired-actual-switches contained `t'.
1634   (setq dir1 (file-name-as-directory dir1)
1635         dir2 (file-name-as-directory dir2))
1636   (let ((components-1 (dired-split "/" dir1))
1637         (components-2 (dired-split "/" dir2)))
1638     (while (and components-1
1639                 components-2
1640                 (equal (car components-1) (car components-2)))
1641       (setq components-1 (cdr components-1)
1642             components-2 (cdr components-2)))
1643     (let ((c1 (car components-1))
1644           (c2 (car components-2)))
1645
1646       (cond ((and c1 c2)
1647              (string-lessp c1 c2))
1648             ((and (null c1) (null c2))
1649              nil)                       ; they are equal, not lessp
1650             ((null c1)                  ; c2 is a subdir of c1: c1<c2
1651              t)
1652             ((null c2)                  ; c1 is a subdir of c2: c1>c2
1653              nil)
1654             (t (error "This can't happen"))))))
1655
1656 ;; There should be a builtin split function - inverse to mapconcat.
1657 (defun dired-split (pat str &optional limit)
1658   "Splitting on regexp PAT, turn string STR into a list of substrings.
1659 Optional third arg LIMIT (>= 1) is a limit to the length of the
1660 resulting list.
1661 Thus, if SEP is a regexp that only matches itself,
1662
1663    (mapconcat 'identity (dired-split SEP STRING) SEP)
1664
1665 is always equal to STRING."
1666   (let* ((start (string-match pat str))
1667          (result (list (substring str 0 start)))
1668          (count 1)
1669          (end (if start (match-end 0))))
1670     (if end                             ; else nothing left
1671         (while (and (or (not (integerp limit))
1672                         (< count limit))
1673                     (string-match pat str end))
1674           (setq start (match-beginning 0)
1675                 count (1+ count)
1676                 result (cons (substring str end start) result)
1677                 end (match-end 0)
1678                 start end)
1679           ))
1680     (if (and (or (not (integerp limit))
1681                  (< count limit))
1682              end)                       ; else nothing left
1683         (setq result
1684               (cons (substring str end) result)))
1685     (nreverse result)))
1686 \f
1687 ;;; moving by subdirectories
1688
1689 ;;;###autoload
1690 (defun dired-prev-subdir (arg &optional no-error-if-not-found no-skip)
1691   "Go to previous subdirectory, regardless of level.
1692 When called interactively and not on a subdir line, go to this subdir's line."
1693   ;;(interactive "p")
1694   (interactive
1695    (list (if current-prefix-arg
1696              (prefix-numeric-value current-prefix-arg)
1697            ;; if on subdir start already, don't stay there!
1698            (if (dired-get-subdir) 1 0))))
1699   (dired-next-subdir (- arg) no-error-if-not-found no-skip))
1700
1701 (defun dired-subdir-min ()
1702   (save-excursion
1703     (if (not (dired-prev-subdir 0 t t))
1704         (error "Not in a subdir!")
1705       (point))))
1706
1707 ;;;###autoload
1708 (defun dired-goto-subdir (dir)
1709   "Go to end of header line of DIR in this dired buffer.
1710 Return value of point on success, otherwise return nil.
1711 The next char is either \\n, or \\r if DIR is hidden."
1712   (interactive
1713    (prog1                               ; let push-mark display its message
1714        (list (expand-file-name
1715               (completing-read "Goto in situ directory: " ; prompt
1716                                dired-subdir-alist ; table
1717                                nil      ; predicate
1718                                t        ; require-match
1719                                (dired-current-directory))))
1720      (push-mark)))
1721   (setq dir (file-name-as-directory dir))
1722   (let ((elt (assoc dir dired-subdir-alist)))
1723     (and elt
1724          (goto-char (dired-get-subdir-min elt))
1725          ;; dired-subdir-hidden-p and dired-add-entry depend on point being
1726          ;; at either \r or \n after this function succeeds.
1727          (progn (skip-chars-forward "^\r\n")
1728                 (point)))))
1729 \f
1730 ;;;###autoload
1731 (defun dired-mark-subdir-files ()
1732   "Mark all files except `.' and `..'."
1733   (interactive)
1734   (let ((p-min (dired-subdir-min)))
1735     (dired-mark-files-in-region p-min (dired-subdir-max))))
1736
1737 ;;;###autoload
1738 (defun dired-kill-subdir (&optional remember-marks)
1739   "Remove all lines of current subdirectory.
1740 Lower levels are unaffected."
1741   ;; With optional REMEMBER-MARKS, return a mark-alist.
1742   (interactive)
1743   (let ((beg (dired-subdir-min))
1744         (end (dired-subdir-max))
1745         buffer-read-only cur-dir)
1746     (setq cur-dir (dired-current-directory))
1747     (if (equal cur-dir default-directory)
1748         (error "Attempt to kill top level directory"))
1749     (prog1
1750         (if remember-marks (dired-remember-marks beg end))
1751       (delete-region beg end)
1752       (if (eobp)                        ; don't leave final blank line
1753           (delete-char -1))
1754       (dired-unsubdir cur-dir))))
1755
1756 (defun dired-unsubdir (dir)
1757   ;; Remove DIR from the alist
1758   (setq dired-subdir-alist
1759         (delq (assoc dir dired-subdir-alist) dired-subdir-alist)))
1760
1761 ;;;###autoload
1762 (defun dired-tree-up (arg)
1763   "Go up ARG levels in the dired tree."
1764   (interactive "p")
1765   (let ((dir (dired-current-directory)))
1766     (while (>= arg 1)
1767       (setq arg (1- arg)
1768             dir (file-name-directory (directory-file-name dir))))
1769     ;;(setq dir (expand-file-name dir))
1770     (or (dired-goto-subdir dir)
1771         (error "Cannot go up to %s - not in this tree." dir))))
1772
1773 ;;;###autoload
1774 (defun dired-tree-down ()
1775   "Go down in the dired tree."
1776   (interactive)
1777   (let ((dir (dired-current-directory)) ; has slash
1778         pos case-fold-search)           ; filenames are case sensitive
1779     (let ((rest (reverse dired-subdir-alist)) elt)
1780       (while rest
1781         (setq elt (car rest)
1782               rest (cdr rest))
1783         (if (dired-in-this-tree (directory-file-name (car elt)) dir)
1784             (setq rest nil
1785                   pos (dired-goto-subdir (car elt))))))
1786     (if pos
1787         (goto-char pos)
1788       (error "At the bottom"))))
1789 \f
1790 ;;; hiding
1791
1792 (defun dired-unhide-subdir ()
1793   (let (buffer-read-only)
1794     (subst-char-in-region (dired-subdir-min) (dired-subdir-max) ?\r ?\n)))
1795
1796 (defun dired-hide-check ()
1797   (or selective-display
1798       (error "selective-display must be t for subdir hiding to work!")))
1799
1800 (defun dired-subdir-hidden-p (dir)
1801   (and selective-display
1802        (save-excursion
1803          (dired-goto-subdir dir)
1804          (looking-at "\r"))))
1805
1806 ;;;###autoload
1807 (defun dired-hide-subdir (arg)
1808   "Hide or unhide the current subdirectory and move to next directory.
1809 Optional prefix arg is a repeat factor.
1810 Use \\[dired-hide-all] to (un)hide all directories."
1811   (interactive "p")
1812   (dired-hide-check)
1813   (while (>=  (setq arg (1- arg)) 0)
1814     (let* ((cur-dir (dired-current-directory))
1815            (hidden-p (dired-subdir-hidden-p cur-dir))
1816            (elt (assoc cur-dir dired-subdir-alist))
1817            (end-pos (1- (dired-get-subdir-max elt)))
1818            buffer-read-only)
1819       ;; keep header line visible, hide rest
1820       (goto-char (dired-get-subdir-min elt))
1821       (skip-chars-forward "^\n\r")
1822       (if hidden-p
1823           (subst-char-in-region (point) end-pos ?\r ?\n)
1824         (subst-char-in-region (point) end-pos ?\n ?\r)))
1825     (dired-next-subdir 1 t)))
1826
1827 ;;;###autoload
1828 (defun dired-hide-all (arg)
1829   "Hide all subdirectories, leaving only their header lines.
1830 If there is already something hidden, make everything visible again.
1831 Use \\[dired-hide-subdir] to (un)hide a particular subdirectory."
1832   (interactive "P")
1833   (dired-hide-check)
1834   (let (buffer-read-only)
1835     (if (save-excursion
1836           (goto-char (point-min))
1837           (search-forward "\r" nil t))
1838         ;; unhide - bombs on \r in filenames
1839         (subst-char-in-region (point-min) (point-max) ?\r ?\n)
1840       ;; hide
1841       (let ((pos (point-max))           ; pos of end of last directory
1842             (alist dired-subdir-alist))
1843         (while alist                    ; while there are dirs before pos
1844           (subst-char-in-region (dired-get-subdir-min (car alist)) ; pos of prev dir
1845                                 (save-excursion
1846                                   (goto-char pos) ; current dir
1847                                   ;; we're somewhere on current dir's line
1848                                   (forward-line -1)
1849                                   (point))
1850                                 ?\n ?\r)
1851           (setq pos (dired-get-subdir-min (car alist))) ; prev dir gets current dir
1852           (setq alist (cdr alist)))))))
1853
1854 ;;;###end dired-ins.el
1855
1856 (provide 'dired-aux)
1857
1858 ;;; dired-aux.el ends here