lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter
   2
   3 ;; Copyright (C) 1989, 1994, 1998, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do `M-x describe-mode'.
  33 ;;
  34 ;; This may be useful in your .emacs:
  35 ;;
  36 ;;      (autoload 'hexl-find-file "hexl"
  37 ;;        "Edit file FILENAME in hexl-mode." t)
  38 ;;
  39 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  40 ;;
  41 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  42 ;;
  43 ;; Currently hexl only supports big endian hex output with 16 bit
  44 ;; grouping.
  45 ;;
  46 ;; -iso in `hexl-options' will allow iso characters to display in the
  47 ;; ASCII region of the screen (if your emacs supports this) instead of
  48 ;; changing them to dots.
  49
  50 ;;; Code:
  51
  52 ;;
  53 ;; vars here
  54 ;;
  55
  56 (defgroup hexl nil
  57   "Edit a file in a hex dump format using the hexl filter."
  58   :group 'data)
  59
  60
  61 (defcustom hexl-program "hexl"
  62   "The program that will hexlify and dehexlify its stdin.
  63 `hexl-program' will always be concatenated with `hexl-options'
  64 and \"-de\" when dehexlifying a buffer."
  65   :type 'string
  66   :group 'hexl)
  67
  68 (defcustom hexl-iso ""
  69   "If your emacs can handle ISO characters, this should be set to
  70 \"-iso\" otherwise it should be \"\"."
  71   :type 'string
  72   :group 'hexl)
  73
  74 (defcustom hexl-options (format "-hex %s" hexl-iso)
  75   "Options to hexl-program that suit your needs."
  76   :type 'string
  77   :group 'hexl)
  78
  79 (defcustom hexlify-command
  80   (format "%s %s"
  81           (shell-quote-argument
  82            (expand-file-name hexl-program exec-directory))
  83           hexl-options)
  84   "The command to use to hexlify a buffer."
  85   :type 'string
  86   :group 'hexl)
  87
  88 (defcustom dehexlify-command
  89   (format "%s -de %s"
  90           (shell-quote-argument
  91            (expand-file-name hexl-program exec-directory))
  92           hexl-options)
  93   "The command to use to unhexlify a buffer."
  94   :type 'string
  95   :group 'hexl)
  96
  97 (defcustom hexl-follow-ascii t
  98   "If non-nil then highlight the ASCII character corresponding to point."
  99   :type 'boolean
 100   :group 'hexl
 101   :version "20.3")
 102
 103 (defvar hexl-max-address 0
 104   "Maximum offset into hexl buffer.")
 105
 106 (defvar hexl-mode-map nil)
 107
 108 (defvar hexl-mode-old-local-map)
 109 (defvar hexl-mode-old-mode-name)
 110 (defvar hexl-mode-old-major-mode)
 111 (defvar hexl-mode-old-write-contents-hooks)
 112 (defvar hexl-mode-old-require-final-newline)
 113 (defvar hexl-mode-old-syntax-table)
 114
 115 (defvar hexl-ascii-overlay nil
 116   "Overlay used to highlight ASCII element corresponding to current point.")
 117 (make-variable-buffer-local 'hexl-ascii-overlay)
 118
 119 ;; routines
 120
 121 (put 'hexl-mode 'mode-class 'special)
 122
 123 ;;;###autoload
 124 (defun hexl-mode (&optional arg)
 125   "\\<hexl-mode-map>A mode for editing binary files in hex dump format.
 126 This is not an ordinary major mode; it alters some aspects
 127 if the current mode's behavior, but not all; also, you can exit
 128 Hexl mode and return to the previous mode using `hexl-mode-exit'.
 129
 130 This function automatically converts a buffer into the hexl format
 131 using the function `hexlify-buffer'.
 132
 133 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 134 representing the offset into the file that the characters on this line
 135 are at and 16 characters from the file (displayed as hexadecimal
 136 values grouped every 16 bits) and as their ASCII values.
 137
 138 If any of the characters (displayed as ASCII characters) are
 139 unprintable (control or meta characters) they will be replaced as
 140 periods.
 141
 142 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 143 in hexl format.
 144
 145 A sample format:
 146
 147   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 148   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 149   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 150   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 151   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 152   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 153   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 154   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 155   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 156   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 157   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 158   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 159   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 160   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 161   000000c0: 7265 6769 6f6e 2e0a                      region..
 162
 163 Movement is as simple as movement in a normal emacs text buffer.  Most
 164 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 165 to move the cursor left, right, down, and up).
 166
 167 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 168 also supported.
 169
 170 There are several ways to change text in hexl mode:
 171
 172 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 173 bound to self-insert so you can simply type the character and it will
 174 insert itself (actually overstrike) into the buffer.
 175
 176 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 177 it isn't bound to self-insert.  An octal number can be supplied in place
 178 of another key to insert the octal number's ASCII representation.
 179
 180 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 181 into the buffer at the current point.
 182
 183 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 184 into the buffer at the current point.
 185
 186 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 187 into the buffer at the current point.
 188
 189 \\[hexl-mode-exit] will exit hexl-mode.
 190
 191 Note: saving the file with any of the usual Emacs commands
 192 will actually convert it back to binary format while saving.
 193
 194 You can use \\[hexl-find-file] to visit a file in Hexl mode.
 195
 196 \\[describe-bindings] for advanced commands."
 197   (interactive "p")
 198   (unless (eq major-mode 'hexl-mode)
 199     (let ((modified (buffer-modified-p))
 200           (inhibit-read-only t)
 201           (original-point (1- (point)))
 202           max-address)
 203       (and (eobp) (not (bobp))
 204            (setq original-point (1- original-point)))
 205       (if (not (or (eq arg 1) (not arg)))
 206           ;; if no argument then we guess at hexl-max-address
 207           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 208         (setq max-address (1- (buffer-size)))
 209         ;; If the buffer's EOL type is -dos, we need to account for
 210         ;; extra CR characters added when hexlify-buffer writes the
 211         ;; buffer to a file.
 212         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 213           (setq max-address (+ (count-lines (point-min) (point-max))
 214                                max-address))
 215           ;; But if there's no newline at the last line, we are off by
 216           ;; one; adjust.
 217           (or (eq (char-before (point-max)) ?\n)
 218               (setq max-address (1- max-address)))
 219           (setq original-point (+ (count-lines (point-min) (point))
 220                                   original-point))
 221           (or (bolp) (setq original-point (1- original-point))))
 222         (hexlify-buffer)
 223         (set-buffer-modified-p modified))
 224       (make-local-variable 'hexl-max-address)
 225       (setq hexl-max-address max-address)
 226       (hexl-goto-address original-point))
 227
 228     ;; We do not turn off the old major mode; instead we just
 229     ;; override most of it.  That way, we can restore it perfectly.
 230     (make-local-variable 'hexl-mode-old-local-map)
 231     (setq hexl-mode-old-local-map (current-local-map))
 232     (use-local-map hexl-mode-map)
 233
 234     (make-local-variable 'hexl-mode-old-mode-name)
 235     (setq hexl-mode-old-mode-name mode-name)
 236     (setq mode-name "Hexl")
 237
 238     (make-local-variable 'hexl-mode-old-major-mode)
 239     (setq hexl-mode-old-major-mode major-mode)
 240     (setq major-mode 'hexl-mode)
 241
 242     (make-local-variable 'hexl-mode-old-syntax-table)
 243     (setq hexl-mode-old-syntax-table (syntax-table))
 244     (set-syntax-table (standard-syntax-table))
 245
 246     (make-local-variable 'hexl-mode-old-write-contents-hooks)
 247     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
 248     (make-local-variable 'write-contents-hooks)
 249     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 250
 251     (make-local-variable 'hexl-mode-old-require-final-newline)
 252     (setq hexl-mode-old-require-final-newline require-final-newline)
 253     (make-local-variable 'require-final-newline)
 254     (setq require-final-newline nil)
 255
 256     ;; Add hooks to rehexlify or dehexlify on various events.
 257     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 258
 259     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 260
 261     (if hexl-follow-ascii (hexl-follow-ascii 1)))
 262   (run-hooks 'hexl-mode-hook))
 263
 264 (defun hexl-after-revert-hook ()
 265   (setq hexl-max-address (1- (buffer-size)))
 266   (hexlify-buffer)
 267   (set-buffer-modified-p nil))
 268
 269 (defvar hexl-in-save-buffer nil)
 270
 271 (defun hexl-save-buffer ()
 272   "Save a hexl format buffer as binary in visited file if modified."
 273   (interactive)
 274   (if hexl-in-save-buffer nil
 275     (set-buffer-modified-p (if (buffer-modified-p)
 276                                (save-excursion
 277                                  (let ((buf (generate-new-buffer " hexl"))
 278                                        (name (buffer-name))
 279                                        (file-name (buffer-file-name))
 280                                        (start (point-min))
 281                                        (end (point-max))
 282                                        modified)
 283                                    (set-buffer buf)
 284                                    (insert-buffer-substring name start end)
 285                                    (set-buffer name)
 286                                    (dehexlify-buffer)
 287                                    ;; Prevent infinite recursion.
 288                                    (let ((hexl-in-save-buffer t))
 289                                      (save-buffer))
 290                                    (setq modified (buffer-modified-p))
 291                                    (delete-region (point-min) (point-max))
 292                                    (insert-buffer-substring buf start end)
 293                                    (kill-buffer buf)
 294                                    modified))
 295                              (message "(No changes need to be saved)")
 296                              nil))
 297     ;; Return t to indicate we have saved t
 298     t))
 299
 300 ;;;###autoload
 301 (defun hexl-find-file (filename)
 302   "Edit file FILENAME in hexl-mode.
 303 Switch to a buffer visiting file FILENAME, creating one in none exists."
 304   (interactive "fFilename: ")
 305   (find-file-literally filename)
 306   (if (not (eq major-mode 'hexl-mode))
 307       (hexl-mode)))
 308
 309 (defun hexl-mode-exit (&optional arg)
 310   "Exit Hexl mode, returning to previous mode.
 311 With arg, don't unhexlify buffer."
 312   (interactive "p")
 313   (if (or (eq arg 1) (not arg))
 314       (let ((modified (buffer-modified-p))
 315             (inhibit-read-only t)
 316             (original-point (1+ (hexl-current-address))))
 317         (dehexlify-buffer)
 318         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 319         (set-buffer-modified-p modified)
 320         (goto-char original-point)
 321         ;; Maybe adjust point for the removed CR characters.
 322         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 323           (setq original-point (- original-point
 324                                   (count-lines (point-min) (point))))
 325           (or (bobp) (setq original-point (1+ original-point))))
 326         (goto-char original-point)))
 327
 328   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 329   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 330   (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 331   (setq hexl-ascii-overlay nil)
 332
 333   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
 334   (setq require-final-newline hexl-mode-old-require-final-newline)
 335   (setq mode-name hexl-mode-old-mode-name)
 336   (use-local-map hexl-mode-old-local-map)
 337   (set-syntax-table hexl-mode-old-syntax-table)
 338   (setq major-mode hexl-mode-old-major-mode)
 339   (force-mode-line-update))
 340
 341 (defun hexl-maybe-dehexlify-buffer ()
 342   "Convert a hexl format buffer to binary.
 343 Ask the user for confirmation."
 344   (if (y-or-n-p "Convert contents back to binary format? ")
 345       (let ((modified (buffer-modified-p))
 346             (inhibit-read-only t)
 347             (original-point (1+ (hexl-current-address))))
 348         (dehexlify-buffer)
 349         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 350         (set-buffer-modified-p modified)
 351         (goto-char original-point))))
 352
 353 (defun hexl-current-address (&optional validate)
 354   "Return current hexl-address."
 355   (interactive)
 356   (let ((current-column (- (% (point) 68) 11))
 357         (hexl-address 0))
 358     (if (< current-column 0)
 359         (if validate
 360             (error "Point is not on a character in the file")
 361           (setq current-column 0)))
 362     (setq hexl-address
 363           (+ (* (/ (point) 68) 16)
 364              (if (>= current-column 41)
 365                  (- current-column 41)
 366                (/ (- current-column  (/ current-column 5)) 2))))
 367     (when (interactive-p)
 368       (message "Current address is %d" hexl-address))
 369     hexl-address))
 370
 371 (defun hexl-address-to-marker (address)
 372   "Return buffer position for ADDRESS."
 373   (interactive "nAddress: ")
 374   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 375
 376 (defun hexl-goto-address (address)
 377   "Goto hexl-mode (decimal) address ADDRESS.
 378 Signal error if ADDRESS out of range."
 379   (interactive "nAddress: ")
 380   (if (or (< address 0) (> address hexl-max-address))
 381           (error "Out of hexl region"))
 382   (goto-char (hexl-address-to-marker address)))
 383
 384 (defun hexl-goto-hex-address (hex-address)
 385   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 386 Signal error if HEX-ADDRESS is out of range."
 387   (interactive "sHex Address: ")
 388   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 389
 390 (defun hexl-hex-string-to-integer (hex-string)
 391   "Return decimal integer for HEX-STRING."
 392   (interactive "sHex number: ")
 393   (let ((hex-num 0))
 394     (while (not (equal hex-string ""))
 395       (setq hex-num (+ (* hex-num 16)
 396                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 397       (setq hex-string (substring hex-string 1)))
 398     hex-num))
 399
 400 (defun hexl-octal-string-to-integer (octal-string)
 401   "Return decimal integer for OCTAL-STRING."
 402   (interactive "sOctal number: ")
 403   (let ((oct-num 0))
 404     (while (not (equal octal-string ""))
 405       (setq oct-num (+ (* oct-num 8)
 406                        (hexl-oct-char-to-integer
 407                         (string-to-char octal-string))))
 408       (setq octal-string (substring octal-string 1)))
 409     oct-num))
 410
 411 ;; move point functions
 412
 413 (defun hexl-backward-char (arg)
 414   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 415   (interactive "p")
 416   (hexl-goto-address (- (hexl-current-address) arg)))
 417
 418 (defun hexl-forward-char (arg)
 419   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 420   (interactive "p")
 421   (hexl-goto-address (+ (hexl-current-address) arg)))
 422
 423 (defun hexl-backward-short (arg)
 424   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 425   (interactive "p")
 426   (hexl-goto-address (let ((address (hexl-current-address)))
 427                        (if (< arg 0)
 428                            (progn
 429                              (setq arg (- arg))
 430                              (while (> arg 0)
 431                                (if (not (equal address (logior address 3)))
 432                                    (if (> address hexl-max-address)
 433                                        (progn
 434                                          (message "End of buffer.")
 435                                          (setq address hexl-max-address))
 436                                      (setq address (logior address 3)))
 437                                  (if (> address hexl-max-address)
 438                                      (progn
 439                                        (message "End of buffer.")
 440                                        (setq address hexl-max-address))
 441                                    (setq address (+ address 4))))
 442                                (setq arg (1- arg)))
 443                              (if (> address hexl-max-address)
 444                                  (progn
 445                                    (message "End of buffer.")
 446                                    (setq address hexl-max-address))
 447                                (setq address (logior address 3))))
 448                          (while (> arg 0)
 449                            (if (not (equal address (logand address -4)))
 450                                (setq address (logand address -4))
 451                              (if (not (equal address 0))
 452                                  (setq address (- address 4))
 453                                (message "Beginning of buffer.")))
 454                            (setq arg (1- arg))))
 455                        address)))
 456
 457 (defun hexl-forward-short (arg)
 458   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 459   (interactive "p")
 460   (hexl-backward-short (- arg)))
 461
 462 (defun hexl-backward-word (arg)
 463   "Move to left ARG words (right if ARG negative) in hexl-mode."
 464   (interactive "p")
 465   (hexl-goto-address (let ((address (hexl-current-address)))
 466                        (if (< arg 0)
 467                            (progn
 468                              (setq arg (- arg))
 469                              (while (> arg 0)
 470                                (if (not (equal address (logior address 7)))
 471                                    (if (> address hexl-max-address)
 472                                        (progn
 473                                          (message "End of buffer.")
 474                                          (setq address hexl-max-address))
 475                                      (setq address (logior address 7)))
 476                                  (if (> address hexl-max-address)
 477                                      (progn
 478                                        (message "End of buffer.")
 479                                        (setq address hexl-max-address))
 480                                    (setq address (+ address 8))))
 481                                (setq arg (1- arg)))
 482                              (if (> address hexl-max-address)
 483                                  (progn
 484                                    (message "End of buffer.")
 485                                    (setq address hexl-max-address))
 486                                (setq address (logior address 7))))
 487                          (while (> arg 0)
 488                            (if (not (equal address (logand address -8)))
 489                                (setq address (logand address -8))
 490                              (if (not (equal address 0))
 491                                  (setq address (- address 8))
 492                                (message "Beginning of buffer.")))
 493                            (setq arg (1- arg))))
 494                        address)))
 495
 496 (defun hexl-forward-word (arg)
 497   "Move right ARG words (left if ARG negative) in hexl-mode."
 498   (interactive "p")
 499   (hexl-backward-word (- arg)))
 500
 501 (defun hexl-previous-line (arg)
 502   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 503 If there is byte at the target address move to the last byte in that line."
 504   (interactive "p")
 505   (hexl-next-line (- arg)))
 506
 507 (defun hexl-next-line (arg)
 508   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 509 If there is no byte at the target address move to the last byte in that line."
 510   (interactive "p")
 511   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 512                        (if (and (< arg 0) (< address 0))
 513                                 (progn (message "Out of hexl region.")
 514                                        (setq address
 515                                              (% (hexl-current-address) 16)))
 516                          (if (and (> address hexl-max-address)
 517                                   (< (% hexl-max-address 16) (% address 16)))
 518                              (setq address hexl-max-address)
 519                            (if (> address hexl-max-address)
 520                                (progn (message "Out of hexl region.")
 521                                       (setq
 522                                        address
 523                                        (+ (logand hexl-max-address -16)
 524                                           (% (hexl-current-address) 16)))))))
 525                        address)))
 526
 527 (defun hexl-beginning-of-buffer (arg)
 528   "Move to the beginning of the hexl buffer.
 529 Leaves `hexl-mark' at previous position.
 530 With prefix arg N, puts point N bytes of the way from the true beginning."
 531   (interactive "p")
 532   (push-mark (point))
 533   (hexl-goto-address (+ 0 (1- arg))))
 534
 535 (defun hexl-end-of-buffer (arg)
 536   "Go to `hexl-max-address' minus ARG."
 537   (interactive "p")
 538   (push-mark (point))
 539   (hexl-goto-address (- hexl-max-address (1- arg))))
 540
 541 (defun hexl-beginning-of-line ()
 542   "Goto beginning of line in hexl mode."
 543   (interactive)
 544   (goto-char (+ (* (/ (point) 68) 68) 11)))
 545
 546 (defun hexl-end-of-line ()
 547   "Goto end of line in hexl mode."
 548   (interactive)
 549   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 550                        (if (> address hexl-max-address)
 551                            (setq address hexl-max-address))
 552                        address)))
 553
 554 (defun hexl-scroll-down (arg)
 555   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 556   (interactive "P")
 557   (if (null arg)
 558       (setq arg (1- (window-height)))
 559     (setq arg (prefix-numeric-value arg)))
 560   (hexl-scroll-up (- arg)))
 561
 562 (defun hexl-scroll-up (arg)
 563   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG.
 564 If there's no byte at the target address, move to the first or last line."
 565   (interactive "P")
 566   (if (null arg)
 567       (setq arg (1- (window-height)))
 568     (setq arg (prefix-numeric-value arg)))
 569   (let* ((movement (* arg 16))
 570          (address (hexl-current-address))
 571          (dest (+ address movement)))
 572     (cond
 573      ;; If possible, try to stay at the same offset from the beginning
 574      ;; of the 16-byte group, even if we move to the first or last
 575      ;; group.
 576      ((and (> dest hexl-max-address)
 577            (>= (% hexl-max-address 16) (% address 16)))
 578       (setq dest (+ (logand hexl-max-address -16) (% address 16))))
 579      ((> dest hexl-max-address)
 580       (setq dest hexl-max-address))
 581      ((< dest 0)
 582       (setq dest (% address 16))))
 583     (if (/= dest (+ address movement))
 584         (message "Out of hexl region."))
 585     (hexl-goto-address dest)
 586     (recenter 0)))
 587
 588 (defun hexl-beginning-of-1k-page ()
 589   "Go to beginning of 1k boundary."
 590   (interactive)
 591   (hexl-goto-address (logand (hexl-current-address) -1024)))
 592
 593 (defun hexl-end-of-1k-page ()
 594   "Go to end of 1k boundary."
 595   (interactive)
 596   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 597                        (if (> address hexl-max-address)
 598                            (setq address hexl-max-address))
 599                        address)))
 600
 601 (defun hexl-beginning-of-512b-page ()
 602   "Go to beginning of 512 byte boundary."
 603   (interactive)
 604   (hexl-goto-address (logand (hexl-current-address) -512)))
 605
 606 (defun hexl-end-of-512b-page ()
 607   "Go to end of 512 byte boundary."
 608   (interactive)
 609   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 610                        (if (> address hexl-max-address)
 611                            (setq address hexl-max-address))
 612                        address)))
 613
 614 (defun hexl-quoted-insert (arg)
 615   "Read next input character and insert it.
 616 Useful for inserting control characters and non-ASCII characters given their
 617 numerical code.
 618 You may also type octal digits, to insert a character with that code."
 619   (interactive "p")
 620   (hexl-insert-multibyte-char (read-quoted-char) arg))
 621
 622 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 623
 624 ;;;###autoload
 625 (defun hexlify-buffer ()
 626   "Convert a binary buffer to hexl format.
 627 This discards the buffer's undo information."
 628   (interactive)
 629   (and buffer-undo-list
 630        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 631            (error "Aborted")))
 632   (setq buffer-undo-list nil)
 633   ;; Don't decode text in the ASCII part of `hexl' program output.
 634   (let ((coding-system-for-read 'raw-text)
 635         (coding-system-for-write buffer-file-coding-system)
 636         (buffer-undo-list t))
 637     (shell-command-on-region (point-min) (point-max) hexlify-command t)
 638     (if (> (point) (hexl-address-to-marker hexl-max-address))
 639         (hexl-goto-address hexl-max-address))))
 640
 641 (defun dehexlify-buffer ()
 642   "Convert a hexl format buffer to binary.
 643 This discards the buffer's undo information."
 644   (interactive)
 645   (and buffer-undo-list
 646        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 647            (error "Aborted")))
 648   (setq buffer-undo-list nil)
 649   (let ((coding-system-for-write 'raw-text)
 650         (coding-system-for-read buffer-file-coding-system)
 651         (buffer-undo-list t))
 652     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 653
 654 (defun hexl-char-after-point ()
 655   "Return char for ASCII hex digits at point."
 656   (hexl-htoi (char-after (point))
 657              (char-after (1+ (point)))))
 658
 659 (defun hexl-htoi (lh rh)
 660   "Hex (char) LH (char) RH to integer."
 661     (+ (* (hexl-hex-char-to-integer lh) 16)
 662        (hexl-hex-char-to-integer rh)))
 663
 664 (defun hexl-hex-char-to-integer (character)
 665   "Take a char and return its value as if it was a hex digit."
 666   (if (and (>= character ?0) (<= character ?9))
 667       (- character ?0)
 668     (let ((ch (logior character 32)))
 669       (if (and (>= ch ?a) (<= ch ?f))
 670           (- ch (- ?a 10))
 671         (error "Invalid hex digit `%c'" ch)))))
 672
 673 (defun hexl-oct-char-to-integer (character)
 674   "Take a char and return its value as if it was a octal digit."
 675   (if (and (>= character ?0) (<= character ?7))
 676       (- character ?0)
 677     (error "Invalid octal digit `%c'" character)))
 678
 679 (defun hexl-printable-character (ch)
 680   "Return a displayable string for character CH."
 681   (format "%c" (if hexl-iso
 682                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 683                        46
 684                      ch)
 685                  (if (or (< ch 32) (>= ch 127))
 686                      46
 687                    ch))))
 688
 689 (defun hexl-insert-multibyte-char (ch num)
 690   "Insert a possibly multibyte character CH NUM times.
 691
 692 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 693 and their encoded form is inserted byte by byte."
 694   (let ((charset (char-charset ch))
 695         (coding (if (or (null buffer-file-coding-system)
 696                         ;; coding-system-type equals t means undecided.
 697                         (eq (coding-system-type buffer-file-coding-system) t))
 698                     default-buffer-file-coding-system
 699                   buffer-file-coding-system)))
 700     (cond ((and (> ch 0) (< ch 256))
 701            (hexl-insert-char ch num))
 702           ((eq charset 'unknown)
 703            (error
 704             "0x%x -- invalid character code; use \\[hexl-insert-hex-string]"
 705             ch))
 706           (t
 707            (let ((encoded (encode-coding-char ch coding))
 708                  (internal (string-as-unibyte (char-to-string ch)))
 709                  internal-hex)
 710              ;; If encode-coding-char returns nil, it means our character
 711              ;; cannot be safely encoded with buffer-file-coding-system.
 712              ;; In that case, we offer to insert the internal representation
 713              ;; of that character, byte by byte.
 714              (when (null encoded)
 715                (setq internal-hex
 716                      (mapconcat (function (lambda (c) (format "%x" c)))
 717                                 internal " "))
 718                (if (yes-or-no-p
 719                     (format
 720                      "Insert char 0x%x's internal representation \"%s\"? "
 721                      ch internal-hex))
 722                    (setq encoded internal)
 723                  (error
 724                   "Can't encode `0x%x' with this buffer's coding system; try \\[hexl-insert-hex-string]"
 725                   ch)))
 726              (while (> num 0)
 727                (mapc
 728                 (function (lambda (c) (hexl-insert-char c 1))) encoded)
 729                (setq num (1- num))))))))
 730
 731 (defun hexl-self-insert-command (arg)
 732   "Insert this character.
 733 Interactively, with a numeric argument, insert this character that many times.
 734
 735 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 736 and their encoded form is inserted byte by byte."
 737   (interactive "p")
 738   (hexl-insert-multibyte-char last-command-char arg))
 739
 740 (defun hexl-insert-char (ch num)
 741   "Insert the character CH NUM times in a hexl buffer.
 742
 743 CH must be a unibyte character whose value is between 0 and 255."
 744   (if (or (< ch 0) (> ch 255))
 745       (error "Invalid character 0x%x -- must be in the range [0..255]"))
 746   (let ((address (hexl-current-address t)))
 747     (while (> num 0)
 748       (let ((hex-position
 749              (+ (* (/ address 16) 68)
 750                 11
 751                 (* 2 (% address 16))
 752                 (/ (% address 16) 2)))
 753             (ascii-position
 754              (+ (* (/ address 16) 68) 52 (% address 16)))
 755             at-ascii-position)
 756         (if (= (point) ascii-position)
 757             (setq at-ascii-position t))
 758         (goto-char hex-position)
 759         (delete-char 2)
 760         (insert (format "%02x" ch))
 761         (goto-char ascii-position)
 762         (delete-char 1)
 763         (insert (hexl-printable-character ch))
 764         (or (eq address hexl-max-address)
 765             (setq address (1+ address)))
 766         (hexl-goto-address address)
 767         (if at-ascii-position
 768             (progn
 769               (beginning-of-line)
 770               (forward-char 51)
 771               (forward-char (% address 16)))))
 772       (setq num (1- num)))))
 773
 774 ;; hex conversion
 775
 776 (defun hexl-insert-hex-char (arg)
 777   "Insert a character given by its hexadecimal code ARG times at point."
 778   (interactive "p")
 779   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 780     (if (< num 0)
 781         (error "Hex number out of range")
 782       (hexl-insert-multibyte-char num arg))))
 783
 784 (defun hexl-insert-hex-string (str arg)
 785   "Insert hexadecimal string STR at point ARG times.
 786 Embedded whitespace, dashes, and periods in the string are ignored."
 787   (interactive "sHex string: \np")
 788   (setq str (replace-regexp-in-string "[- \t.]" "" str))
 789   (let ((chars '()))
 790     (let ((len (length str))
 791           (idx 0))
 792       (if (eq (logand len 1) 1)
 793           (let ((num (hexl-hex-string-to-integer (substring str 0 1))))
 794             (setq chars (cons num chars))
 795             (setq idx 1)))
 796       (while (< idx len)
 797         (let* ((nidx (+ idx 2))
 798                (num (hexl-hex-string-to-integer (substring str idx nidx))))
 799           (setq chars (cons num chars))
 800           (setq idx nidx))))
 801     (setq chars (nreverse chars))
 802     (while (> arg 0)
 803       (let ((chars chars))
 804         (while chars
 805           (hexl-insert-char (car chars) 1)
 806           (setq chars (cdr chars))))
 807       (setq arg (- arg 1)))))
 808
 809 (defun hexl-insert-decimal-char (arg)
 810   "Insert a character given by its decimal code ARG times at point."
 811   (interactive "p")
 812   (let ((num (string-to-int (read-string "Decimal Number: "))))
 813     (if (< num 0)
 814         (error "Decimal number out of range")
 815       (hexl-insert-multibyte-char num arg))))
 816
 817 (defun hexl-insert-octal-char (arg)
 818   "Insert a character given by its octal code ARG times at point."
 819   (interactive "p")
 820   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 821     (if (< num 0)
 822         (error "Decimal number out of range")
 823       (hexl-insert-multibyte-char num arg))))
 824
 825 (defun hexl-follow-ascii (&optional arg)
 826   "Toggle following ASCII in Hexl buffers.
 827 With prefix ARG, turn on following if and only if ARG is positive.
 828 When following is enabled, the ASCII character corresponding to the
 829 element under the point is highlighted.
 830 Customize the variable `hexl-follow-ascii' to disable this feature."
 831   (interactive "P")
 832   (let ((on-p (if arg
 833                   (> (prefix-numeric-value arg) 0)
 834                (not hexl-ascii-overlay))))
 835
 836     (if on-p
 837       ;; turn it on
 838       (if (not hexl-ascii-overlay)
 839           (progn
 840             (setq hexl-ascii-overlay (make-overlay 1 1)
 841                   hexl-follow-ascii t)
 842             (overlay-put hexl-ascii-overlay 'face 'highlight)
 843             (add-hook 'post-command-hook 'hexl-follow-ascii-find nil t)))
 844       ;; turn it off
 845       (if hexl-ascii-overlay
 846           (progn
 847             (delete-overlay hexl-ascii-overlay)
 848             (setq hexl-ascii-overlay nil
 849                   hexl-follow-ascii nil)
 850             (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 851             )))))
 852
 853 (defun hexl-follow-ascii-find ()
 854   "Find and highlight the ASCII element corresponding to current point."
 855   (let ((pos (+ 51
 856                 (- (point) (current-column))
 857                 (mod (hexl-current-address) 16))))
 858     (move-overlay hexl-ascii-overlay pos (1+ pos))
 859     ))
 860
 861 ;; startup stuff.
 862
 863 (if hexl-mode-map
 864     nil
 865   (setq hexl-mode-map (make-keymap))
 866   ;; Make all self-inserting keys go through hexl-self-insert-command,
 867   ;; because we need to convert them to unibyte characters before
 868   ;; inserting them into the buffer.
 869   (substitute-key-definition 'self-insert-command 'hexl-self-insert-command
 870                              hexl-mode-map (current-global-map))
 871
 872   (define-key hexl-mode-map [left] 'hexl-backward-char)
 873   (define-key hexl-mode-map [right] 'hexl-forward-char)
 874   (define-key hexl-mode-map [up] 'hexl-previous-line)
 875   (define-key hexl-mode-map [down] 'hexl-next-line)
 876   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 877   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 878   (define-key hexl-mode-map [next] 'hexl-scroll-up)
 879   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
 880   (define-key hexl-mode-map [home] 'hexl-beginning-of-line)
 881   (define-key hexl-mode-map [end] 'hexl-end-of-line)
 882   (define-key hexl-mode-map [C-home] 'hexl-beginning-of-buffer)
 883   (define-key hexl-mode-map [C-end] 'hexl-end-of-buffer)
 884   (define-key hexl-mode-map [deletechar] 'undefined)
 885   (define-key hexl-mode-map [deleteline] 'undefined)
 886   (define-key hexl-mode-map [insertline] 'undefined)
 887   (define-key hexl-mode-map [S-delete] 'undefined)
 888   (define-key hexl-mode-map "\177" 'undefined)
 889
 890   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 891   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 892   (define-key hexl-mode-map "\C-d" 'undefined)
 893   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 894   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 895
 896   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 897       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 898
 899   (define-key hexl-mode-map "\C-k" 'undefined)
 900   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 901   (define-key hexl-mode-map "\C-o" 'undefined)
 902   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 903   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 904   (define-key hexl-mode-map "\C-t" 'undefined)
 905   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 906   (define-key hexl-mode-map "\C-w" 'undefined)
 907   (define-key hexl-mode-map "\C-y" 'undefined)
 908
 909   (fset 'hexl-ESC-prefix (copy-keymap 'ESC-prefix))
 910   (define-key hexl-mode-map "\e" 'hexl-ESC-prefix)
 911   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 912   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 913   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 914   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 915   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 916   (define-key hexl-mode-map "\e\C-i" 'undefined)
 917   (define-key hexl-mode-map "\e\C-j" 'undefined)
 918   (define-key hexl-mode-map "\e\C-k" 'undefined)
 919   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 920   (define-key hexl-mode-map "\e\C-q" 'undefined)
 921   (define-key hexl-mode-map "\e\C-t" 'undefined)
 922   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 923   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 924   (define-key hexl-mode-map "\ec" 'undefined)
 925   (define-key hexl-mode-map "\ed" 'undefined)
 926   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 927   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 928   (define-key hexl-mode-map "\ei" 'undefined)
 929   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 930   (define-key hexl-mode-map "\ek" 'undefined)
 931   (define-key hexl-mode-map "\el" 'undefined)
 932   (define-key hexl-mode-map "\eq" 'undefined)
 933   (define-key hexl-mode-map "\es" 'undefined)
 934   (define-key hexl-mode-map "\et" 'undefined)
 935   (define-key hexl-mode-map "\eu" 'undefined)
 936   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 937   (define-key hexl-mode-map "\ey" 'undefined)
 938   (define-key hexl-mode-map "\ez" 'undefined)
 939   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 940   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 941
 942   (fset 'hexl-C-c-prefix (copy-keymap mode-specific-map))
 943   (define-key hexl-mode-map "\C-c" 'hexl-C-c-prefix)
 944   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 945
 946   (fset 'hexl-C-x-prefix (copy-keymap 'Control-X-prefix))
 947   (define-key hexl-mode-map "\C-x" 'hexl-C-x-prefix)
 948   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 949   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 950   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 951   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 952   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 953
 954 (provide 'hexl)
 955
 956 ;;; hexl.el ends here